qcsrc/server/cl_client.qc

   1 void race_send_recordtime(float msg);
   2 void race_SendRankings(float pos, float prevpos, float del, float msg);
   3
   4 void send_CSQC_teamnagger() {
   5         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   6         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   7 }
   8
   9 float ClientData_Send(entity to, float sf)
  10 {
  11         if(to != self.owner)
  12         {
  13                 error("wtf");
  14                 return FALSE;
  15         }
  16
  17         entity e;
  18
  19         e = to;
  20         if(IS_SPEC(to))
  21                 e = to.enemy;
  22
  23         sf = 0;
  24
  25         if(e.race_completed)
  26                 sf |= 1; // forced scoreboard
  27         if(to.spectatee_status)
  28                 sf |= 2; // spectator ent number follows
  29         if(e.zoomstate)
  30                 sf |= 4; // zoomed
  31         if(e.porto_v_angle_held)
  32                 sf |= 8; // angles held
  33
  34         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  35         WriteByte(MSG_ENTITY, sf);
  36
  37         if(sf & 2)
  38                 WriteByte(MSG_ENTITY, to.spectatee_status);
  39
  40         if(sf & 8)
  41         {
  42                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  43                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  44         }
  45
  46         return TRUE;
  47 }
  48
  49 void ClientData_Attach()
  50 {
  51         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  52         self.clientdata.drawonlytoclient = self;
  53         self.clientdata.owner = self;
  54 }
  55
  56 void ClientData_Detach()
  57 {
  58         remove(self.clientdata);
  59         self.clientdata = world;
  60 }
  61
  62 void ClientData_Touch(entity e)
  63 {
  64         e.clientdata.SendFlags = 1;
  65
  66         // make it spectatable
  67         entity e2;
  68         FOR_EACH_REALCLIENT(e2)
  69         {
  70                 if(e2 != e)
  71                         if(IS_SPEC(e2))
  72                                 if(e2.enemy == e)
  73                                         e2.clientdata.SendFlags = 1;
  74         }
  75 }
  76
  77 .string netname_previous;
  78
  79
  80 /*
  81 =============
  82 CheckPlayerModel
  83
  84 Checks if the argument string can be a valid playermodel.
  85 Returns a valid one in doubt.
  86 =============
  87 */
  88 string FallbackPlayerModel;
  89 string CheckPlayerModel(string plyermodel) {
  90         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  91         {
  92                 // note: we cannot summon Don Strunzone here, some player may
  93                 // still have the model string set. In case anyone manages how
  94                 // to change a cvar default, we'll have a small leak here.
  95                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  96         }
  97         // only in right path
  98         if( substring(plyermodel,0,14) != "models/player/")
  99                 return FallbackPlayerModel;
 100         // only good file extensions
 101         if(substring(plyermodel,-4,4) != ".zym")
 102         if(substring(plyermodel,-4,4) != ".dpm")
 103         if(substring(plyermodel,-4,4) != ".iqm")
 104         if(substring(plyermodel,-4,4) != ".md3")
 105         if(substring(plyermodel,-4,4) != ".psk")
 106                 return FallbackPlayerModel;
 107         // forbid the LOD models
 108         if(substring(plyermodel, -9,5) == "_lod1")
 109                 return FallbackPlayerModel;
 110         if(substring(plyermodel, -9,5) == "_lod2")
 111                 return FallbackPlayerModel;
 112         if(plyermodel != strtolower(plyermodel))
 113                 return FallbackPlayerModel;
 114         // also, restrict to server models
 115         if(autocvar_sv_servermodelsonly)
 116         {
 117                 if(!fexists(plyermodel))
 118                         return FallbackPlayerModel;
 119         }
 120         return plyermodel;
 121 }
 122
 123 void setplayermodel(entity e, string modelname)
 124 {
 125         precache_model(modelname);
 126         setmodel(e, modelname);
 127         player_setupanimsformodel();
 128         UpdatePlayerSounds();
 129 }
 130
 131 /*
 132 =============
 133 PutObserverInServer
 134
 135 putting a client as observer in the server
 136 =============
 137 */
 138 void FixPlayermodel();
 139 void PutObserverInServer (void)
 140 {
 141         entity  spot;
 142     self.hud = HUD_NORMAL;
 143         race_PreSpawnObserver();
 144
 145         spot = SelectSpawnPoint (TRUE);
 146         if(!spot)
 147                 error("No spawnpoints for observers?!?\n");
 148         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 149
 150         if(IS_REAL_CLIENT(self))
 151         {
 152                 msg_entity = self;
 153                 WriteByte(MSG_ONE, SVC_SETVIEW);
 154                 WriteEntity(MSG_ONE, self);
 155         }
 156
 157         if((g_race && g_race_qualifying) || g_cts)
 158         {
 159                 if(PlayerScore_Add(self, SP_RACE_FASTEST, 0))
 160                         self.frags = FRAGS_LMS_LOSER;
 161                 else
 162                         self.frags = FRAGS_SPECTATOR;
 163         }
 164         else
 165                 self.frags = FRAGS_SPECTATOR;
 166
 167         MUTATOR_CALLHOOK(MakePlayerObserver);
 168
 169         Portal_ClearAll(self);
 170
 171         Unfreeze(self);
 172
 173         if(self.alivetime)
 174         {
 175                 if(!inWarmupStage)
 176                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 177                 self.alivetime = 0;
 178         }
 179
 180         if(self.vehicle)
 181                 vehicles_exit(VHEF_RELESE);
 182
 183         WaypointSprite_PlayerDead();
 184
 185         if not(g_ca)  // don't reset teams when moving a ca player to the spectators
 186                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 187
 188         if(self.killcount != -666)
 189         {
 190                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 191
 192                 if(self.just_joined == FALSE) {
 193                         LogTeamchange(self.playerid, -1, 4);
 194                 } else
 195                         self.just_joined = FALSE;
 196         }
 197
 198         PlayerScore_Clear(self); // clear scores when needed
 199
 200         accuracy_resend(self);
 201
 202         self.spectatortime = time;
 203
 204         self.classname = "observer";
 205         self.iscreature = FALSE;
 206         self.teleportable = TELEPORT_SIMPLE;
 207         self.damagedbycontents = FALSE;
 208         self.health = -666;
 209         self.takedamage = DAMAGE_NO;
 210         self.solid = SOLID_NOT;
 211         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 212         self.flags = FL_CLIENT | FL_NOTARGET;
 213         self.armorvalue = 666;
 214         self.effects = 0;
 215         self.armorvalue = autocvar_g_balance_armor_start;
 216         self.pauserotarmor_finished = 0;
 217         self.pauserothealth_finished = 0;
 218         self.pauseregen_finished = 0;
 219         self.damageforcescale = 0;
 220         self.death_time = 0;
 221         self.respawn_flags = 0;
 222         self.respawn_time = 0;
 223         self.stat_respawn_time = 0;
 224         self.alpha = 0;
 225         self.scale = 0;
 226         self.fade_time = 0;
 227         self.pain_frame = 0;
 228         self.pain_finished = 0;
 229         self.strength_finished = 0;
 230         self.invincible_finished = 0;
 231         self.superweapons_finished = 0;
 232         self.pushltime = 0;
 233         self.istypefrag = 0;
 234         self.think = func_null;
 235         self.nextthink = 0;
 236         self.hook_time = 0;
 237         self.deadflag = DEAD_NO;
 238         self.angles = spot.angles;
 239         self.angles_z = 0;
 240         self.fixangle = TRUE;
 241         self.crouch = FALSE;
 242
 243         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 244         self.prevorigin = self.origin;
 245         self.items = 0;
 246         WEPSET_CLEAR_E(self);
 247         self.model = "";
 248         FixPlayermodel();
 249         setmodel(self, "null");
 250         self.drawonlytoclient = self;
 251
 252         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 253         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 254
 255         self.weapon = 0;
 256         self.weaponname = "";
 257         self.switchingweapon = 0;
 258         self.weaponmodel = "";
 259         self.weaponentity = world;
 260         self.exteriorweaponentity = world;
 261         self.killcount = -666;
 262         self.velocity = '0 0 0';
 263         self.avelocity = '0 0 0';
 264         self.punchangle = '0 0 0';
 265         self.punchvector = '0 0 0';
 266         self.oldvelocity = self.velocity;
 267         self.fire_endtime = -1;
 268 }
 269
 270 .float model_randomizer;
 271 void FixPlayermodel()
 272 {
 273         string defaultmodel;
 274         float defaultskin, chmdl, oldskin, n, i;
 275         vector m1, m2;
 276
 277         defaultmodel = "";
 278         defaultskin = 0;
 279         chmdl = FALSE;
 280
 281         if(autocvar_sv_defaultcharacter == 1)
 282         {
 283                 if(teamplay)
 284                 {
 285                         string s;
 286                         s = Team_ColorName_Lower(self.team);
 287                         if(s != "neutral")
 288                         {
 289                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 290                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 291                         }
 292                 }
 293
 294                 if(defaultmodel == "")
 295                 {
 296                         defaultmodel = autocvar_sv_defaultplayermodel;
 297                         defaultskin = autocvar_sv_defaultplayerskin;
 298                 }
 299
 300                 n = tokenize_console(defaultmodel);
 301                 if(n > 0)
 302                         defaultmodel = argv(floor(n * self.model_randomizer));
 303
 304                 i = strstrofs(defaultmodel, ":", 0);
 305                 if(i >= 0)
 306                 {
 307                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 308                         defaultmodel = substring(defaultmodel, 0, i);
 309                 }
 310         }
 311
 312         if(defaultmodel != "")
 313         {
 314                 if (defaultmodel != self.model)
 315                 {
 316                         m1 = self.mins;
 317                         m2 = self.maxs;
 318                         setplayermodel (self, defaultmodel);
 319                         setsize (self, m1, m2);
 320                         chmdl = TRUE;
 321                 }
 322
 323                 oldskin = self.skin;
 324                 self.skin = defaultskin;
 325         } else {
 326                 if (self.playermodel != self.model || self.playermodel == "")
 327                 {
 328                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 329                         m1 = self.mins;
 330                         m2 = self.maxs;
 331                         setplayermodel (self, self.playermodel);
 332                         setsize (self, m1, m2);
 333                         chmdl = TRUE;
 334                 }
 335
 336                 oldskin = self.skin;
 337                 self.skin = stof(self.playerskin);
 338         }
 339
 340         if(chmdl || oldskin != self.skin) // model or skin has changed
 341         {
 342                 self.species = player_getspecies(); // update species
 343                 UpdatePlayerSounds(); // update skin sounds
 344         }
 345
 346         if(!teamplay)
 347                 if(strlen(autocvar_sv_defaultplayercolors))
 348                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 349                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 350 }
 351
 352 /*
 353 =============
 354 PutClientInServer
 355
 356 Called when a client spawns in the server
 357 =============
 358 */
 359 float SpawnEvent_Send(entity to, float sf);
 360 void PutClientInServer (void)
 361 {
 362         if(IS_BOT_CLIENT(self))
 363                 self.classname = "player";
 364         else if(IS_REAL_CLIENT(self))
 365         {
 366                 msg_entity = self;
 367                 WriteByte(MSG_ONE, SVC_SETVIEW);
 368                 WriteEntity(MSG_ONE, self);
 369         }
 370
 371         // reset player keys
 372         self.itemkeys = 0;
 373
 374         MUTATOR_CALLHOOK(PutClientInServer);
 375
 376         if(gameover)
 377                 self.classname = "observer";
 378
 379         if(IS_PLAYER(self))
 380         {
 381                 entity spot, oldself;
 382                 float j;
 383
 384                 accuracy_resend(self);
 385
 386                 if(self.team < 0)
 387                         JoinBestTeam(self, FALSE, TRUE);
 388
 389                 race_PreSpawn();
 390
 391                 spot = SelectSpawnPoint (FALSE);
 392                 if(!spot)
 393                 {
 394                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 395                         return; // spawn failed
 396                 }
 397
 398                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 399
 400                 self.classname = "player";
 401                 self.wasplayer = TRUE;
 402                 self.iscreature = TRUE;
 403                 self.teleportable = TELEPORT_NORMAL;
 404                 self.damagedbycontents = TRUE;
 405                 self.movetype = MOVETYPE_WALK;
 406                 self.solid = SOLID_SLIDEBOX;
 407                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 408                 if(autocvar_g_playerclip_collisions)
 409                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 410                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 411                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 412                 self.frags = FRAGS_PLAYER;
 413                 if(INDEPENDENT_PLAYERS)
 414                         MAKE_INDEPENDENT_PLAYER(self);
 415                 self.flags = FL_CLIENT;
 416                 if(autocvar__notarget)
 417                         self.flags |= FL_NOTARGET;
 418                 self.takedamage = DAMAGE_AIM;
 419                 self.effects = 0;
 420                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 421                 self.air_finished = time + 12;
 422                 self.dmg = 2;
 423                 if(autocvar_g_balance_nex_charge)
 424                 {
 425                         if(autocvar_g_balance_nex_secondary_chargepool)
 426                                 self.nex_chargepool_ammo = 1;
 427                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 428                 }
 429
 430                 if(inWarmupStage)
 431                 {
 432                         self.ammo_shells = warmup_start_ammo_shells;
 433                         self.ammo_nails = warmup_start_ammo_nails;
 434                         self.ammo_rockets = warmup_start_ammo_rockets;
 435                         self.ammo_cells = warmup_start_ammo_cells;
 436                         self.ammo_fuel = warmup_start_ammo_fuel;
 437                         self.health = warmup_start_health;
 438                         self.armorvalue = warmup_start_armorvalue;
 439                         WEPSET_COPY_EA(self, warmup_start_weapons);
 440                 }
 441                 else
 442                 {
 443                         self.ammo_shells = start_ammo_shells;
 444                         self.ammo_nails = start_ammo_nails;
 445                         self.ammo_rockets = start_ammo_rockets;
 446                         self.ammo_cells = start_ammo_cells;
 447                         self.ammo_fuel = start_ammo_fuel;
 448                         self.health = start_health;
 449                         self.armorvalue = start_armorvalue;
 450                         WEPSET_COPY_EA(self, start_weapons);
 451                 }
 452
 453                 if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS)) // exception for minstagib, as minstanex is a superweapon
 454                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 455                 else
 456                         self.superweapons_finished = 0;
 457
 458                 if(g_weaponarena_random)
 459                 {
 460                         if(g_weaponarena_random_with_laser)
 461                                 WEPSET_ANDNOT_EW(self, WEP_LASER);
 462                         W_RandomWeapons(self, g_weaponarena_random);
 463                         if(g_weaponarena_random_with_laser)
 464                                 WEPSET_OR_EW(self, WEP_LASER);
 465                 }
 466
 467                 self.items = start_items;
 468
 469                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 470                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 471                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 472                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 473                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 474                 //extend the pause of rotting if client was reset at the beginning of the countdown
 475                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 476                         self.spawnshieldtime += game_starttime - time;
 477                         self.pauserotarmor_finished += game_starttime - time;
 478                         self.pauserothealth_finished += game_starttime - time;
 479                         self.pauseregen_finished += game_starttime - time;
 480                 }
 481                 self.damageforcescale = 2;
 482                 self.death_time = 0;
 483                 self.respawn_flags = 0;
 484                 self.respawn_time = 0;
 485                 self.stat_respawn_time = 0;
 486                 self.scale = 0;
 487                 self.fade_time = 0;
 488                 self.pain_frame = 0;
 489                 self.pain_finished = 0;
 490                 self.strength_finished = 0;
 491                 self.invincible_finished = 0;
 492                 self.pushltime = 0;
 493                 // players have no think function
 494                 self.think = func_null;
 495                 self.nextthink = 0;
 496                 self.hook_time = 0;
 497                 self.dmg_team = 0;
 498                 self.ballistics_density = autocvar_g_ballistics_density_player;
 499
 500                 self.metertime = 0;
 501
 502                 self.deadflag = DEAD_NO;
 503
 504                 self.angles = spot.angles;
 505
 506                 self.angles_z = 0; // never spawn tilted even if the spot says to
 507                 self.fixangle = TRUE; // turn this way immediately
 508                 self.velocity = '0 0 0';
 509                 self.avelocity = '0 0 0';
 510                 self.punchangle = '0 0 0';
 511                 self.punchvector = '0 0 0';
 512                 self.oldvelocity = self.velocity;
 513                 self.fire_endtime = -1;
 514
 515                 entity spawnevent = spawn();
 516                 spawnevent.owner = self;
 517                 Net_LinkEntity(spawnevent, FALSE, 1, SpawnEvent_Send);
 518
 519                 self.model = "";
 520                 FixPlayermodel();
 521                 self.drawonlytoclient = world;
 522
 523                 self.crouch = FALSE;
 524                 self.view_ofs = PL_VIEW_OFS;
 525                 setsize (self, PL_MIN, PL_MAX);
 526                 self.spawnorigin = spot.origin;
 527                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 528                 // don't reset back to last position, even if new position is stuck in solid
 529                 self.oldorigin = self.origin;
 530                 self.prevorigin = self.origin;
 531                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 532                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 533         self.hud = HUD_NORMAL;
 534
 535                 self.event_damage = PlayerDamage;
 536
 537                 self.bot_attack = TRUE;
 538                 self.monster_attack = TRUE;
 539
 540                 self.statdraintime = time + 5;
 541                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 542
 543                 if(self.killcount == -666) {
 544                         PlayerScore_Clear(self);
 545                         self.killcount = 0;
 546                 }
 547
 548                 CL_SpawnWeaponentity();
 549                 self.alpha = default_player_alpha;
 550                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 551                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 552
 553                 self.speedrunning = FALSE;
 554
 555                 race_PostSpawn(spot);
 556
 557                 //stuffcmd(self, "chase_active 0");
 558                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 559
 560                 target_voicescript_clear(self);
 561
 562                 // reset fields the weapons may use
 563                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 564                 {
 565                         weapon_action(j, WR_RESETPLAYER);
 566
 567                         // all weapons must be fully loaded when we spawn
 568                         entity e;
 569                         e = get_weaponinfo(j);
 570                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 571                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 572                 }
 573
 574                 oldself = self;
 575                 self = spot;
 576                         activator = oldself;
 577                                 string s;
 578                                 s = self.target;
 579                                 self.target = string_null;
 580                                 SUB_UseTargets();
 581                                 self.target = s;
 582                         activator = world;
 583                 self = oldself;
 584
 585                 Unfreeze(self);
 586
 587                 spawn_spot = spot;
 588                 MUTATOR_CALLHOOK(PlayerSpawn);
 589
 590                 if(autocvar_spawn_debug)
 591                 {
 592                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 593                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 594                 }
 595
 596                 self.switchweapon = w_getbestweapon(self);
 597                 self.cnt = -1; // W_LastWeapon will not complain
 598                 self.weapon = 0;
 599                 self.weaponname = "";
 600                 self.switchingweapon = 0;
 601
 602                 if(!inWarmupStage)
 603                         if(!self.alivetime)
 604                                 self.alivetime = time;
 605
 606                 antilag_clear(self);
 607         }
 608         else if(IS_OBSERVER(self))
 609         {
 610                 PutObserverInServer ();
 611         }
 612 }
 613
 614 .float ebouncefactor, ebouncestop; // electro's values
 615 // TODO do we need all these fields, or should we stop autodetecting runtime
 616 // changes and just have a console command to update this?
 617 float ClientInit_SendEntity(entity to, float sf)
 618 {
 619         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 620         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 621         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 622         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 623         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 624         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 625         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 626         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 633         if(sv_foginterval && world.fog != "")
 634                 WriteString(MSG_ENTITY, world.fog);
 635         else
 636                 WriteString(MSG_ENTITY, "");
 637         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 638         WriteByte(MSG_ENTITY, self.cnt * 255.0); // g_balance_weaponswitchdelay
 639         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 640         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 641         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 642         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 643         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 644         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 645         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 646         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 647         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 648         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 650         return TRUE;
 651 }
 652
 653 void ClientInit_CheckUpdate()
 654 {
 655         self.nextthink = time;
 656         if(self.count != autocvar_g_balance_armor_blockpercent)
 657         {
 658                 self.count = autocvar_g_balance_armor_blockpercent;
 659                 self.SendFlags |= 1;
 660         }
 661         if(self.cnt != autocvar_g_balance_weaponswitchdelay)
 662         {
 663                 self.cnt = autocvar_g_balance_weaponswitchdelay;
 664                 self.SendFlags |= 1;
 665         }
 666         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 667         {
 668                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 669                 self.SendFlags |= 1;
 670         }
 671         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 672         {
 673                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 674                 self.SendFlags |= 1;
 675         }
 676         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 677         {
 678                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 679                 self.SendFlags |= 1;
 680         }
 681         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 682         {
 683                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 684                 self.SendFlags |= 1;
 685         }
 686 }
 687
 688 void ClientInit_Spawn()
 689 {
 690         entity o;
 691         entity e;
 692         e = spawn();
 693         e.classname = "clientinit";
 694         e.think = ClientInit_CheckUpdate;
 695         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 696
 697         o = self;
 698         self = e;
 699         ClientInit_CheckUpdate();
 700         self = o;
 701 }
 702
 703 /*
 704 =============
 705 SetNewParms
 706 =============
 707 */
 708 void SetNewParms (void)
 709 {
 710         // initialize parms for a new player
 711         parm1 = -(86400 * 366);
 712 }
 713
 714 /*
 715 =============
 716 SetChangeParms
 717 =============
 718 */
 719 void SetChangeParms (void)
 720 {
 721         // save parms for level change
 722         parm1 = self.parm_idlesince - time;
 723 }
 724
 725 /*
 726 =============
 727 DecodeLevelParms
 728 =============
 729 */
 730 void DecodeLevelParms (void)
 731 {
 732         // load parms
 733         self.parm_idlesince = parm1;
 734         if(self.parm_idlesince == -(86400 * 366))
 735                 self.parm_idlesince = time;
 736
 737         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 738         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 739 }
 740
 741 /*
 742 =============
 743 ClientKill
 744
 745 Called when a client types 'kill' in the console
 746 =============
 747 */
 748
 749 .float clientkill_nexttime;
 750 void ClientKill_Now_TeamChange()
 751 {
 752         if(self.killindicator_teamchange == -1)
 753         {
 754                 JoinBestTeam( self, FALSE, TRUE );
 755         }
 756         else if(self.killindicator_teamchange == -2)
 757         {
 758                 if(blockSpectators)
 759                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 760                 PutObserverInServer();
 761         }
 762         else
 763                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 764         self.killindicator_teamchange = 0;
 765 }
 766
 767 void ClientKill_Now()
 768 {
 769         if(self.vehicle)
 770         {
 771             vehicles_exit(VHEF_RELESE);
 772             if(!self.killindicator_teamchange)
 773             {
 774             self.vehicle_health = -1;
 775             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 776             }
 777         }
 778
 779         if(self.killindicator && !wasfreed(self.killindicator))
 780                 remove(self.killindicator);
 781
 782         self.killindicator = world;
 783
 784         if(self.killindicator_teamchange)
 785                 ClientKill_Now_TeamChange();
 786
 787         // in any case:
 788         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 789
 790         // now I am sure the player IS dead
 791 }
 792 void KillIndicator_Think()
 793 {
 794         if (gameover)
 795         {
 796                 self.owner.killindicator = world;
 797                 remove(self);
 798                 return;
 799         }
 800
 801         if (self.owner.alpha < 0 && !self.owner.vehicle)
 802         {
 803                 self.owner.killindicator = world;
 804                 remove(self);
 805                 return;
 806         }
 807
 808         if(self.cnt <= 0)
 809         {
 810                 self = self.owner;
 811                 ClientKill_Now(); // no oldself needed
 812                 return;
 813         }
 814     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 815     {
 816         self.nextthink = time + 1;
 817         self.cnt -= 1;
 818     }
 819         else
 820         {
 821                 if(self.cnt <= 10)
 822                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 823                 if(IS_REAL_CLIENT(self.owner))
 824                 {
 825                         if(self.cnt <= 10)
 826                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(self.cnt)); }
 827                 }
 828                 self.nextthink = time + 1;
 829                 self.cnt -= 1;
 830         }
 831 }
 832
 833 float clientkilltime;
 834 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 835 {
 836         float killtime;
 837         float starttime;
 838         entity e;
 839
 840         if (gameover)
 841                 return;
 842
 843         killtime = autocvar_g_balance_kill_delay;
 844
 845         if(g_race_qualifying || g_cts)
 846                 killtime = 0;
 847
 848     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 849     {
 850                 remove(self.killindicator);
 851                 self.killindicator = world;
 852
 853         ClientKill_Now(); // allow instant kill in this case
 854         return;
 855     }
 856
 857         self.killindicator_teamchange = targetteam;
 858
 859     if(!self.killindicator)
 860         {
 861                 if(self.deadflag == DEAD_NO)
 862                 {
 863                         killtime = max(killtime, self.clientkill_nexttime - time);
 864                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 865                 }
 866
 867                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 868                 {
 869                         ClientKill_Now();
 870                 }
 871                 else
 872                 {
 873                         starttime = max(time, clientkilltime);
 874
 875                         self.killindicator = spawn();
 876                         self.killindicator.owner = self;
 877                         self.killindicator.scale = 0.5;
 878                         setattachment(self.killindicator, self, "");
 879                         setorigin(self.killindicator, '0 0 52');
 880                         self.killindicator.think = KillIndicator_Think;
 881                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 882                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 883                         self.killindicator.cnt = ceil(killtime);
 884                         self.killindicator.count = bound(0, ceil(killtime), 10);
 885                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 886
 887                         for(e = world; (e = find(e, classname, "body")) != world; )
 888                         {
 889                                 if(e.enemy != self)
 890                                         continue;
 891                                 e.killindicator = spawn();
 892                                 e.killindicator.owner = e;
 893                                 e.killindicator.scale = 0.5;
 894                                 setattachment(e.killindicator, e, "");
 895                                 setorigin(e.killindicator, '0 0 52');
 896                                 e.killindicator.think = KillIndicator_Think;
 897                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 898                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 899                                 e.killindicator.cnt = ceil(killtime);
 900                         }
 901                         self.lip = 0;
 902                 }
 903         }
 904         if(self.killindicator)
 905         {
 906                 if(targetteam == 0) // just die
 907                 {
 908                         self.killindicator.colormod = '0 0 0';
 909                         if(IS_REAL_CLIENT(self))
 910                         if(self.killindicator.cnt > 0)
 911                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 912                 }
 913                 else if(targetteam == -1) // auto
 914                 {
 915                         self.killindicator.colormod = '0 1 0';
 916                         if(IS_REAL_CLIENT(self))
 917                         if(self.killindicator.cnt > 0)
 918                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 919                 }
 920                 else if(targetteam == -2) // spectate
 921                 {
 922                         self.killindicator.colormod = '0.5 0.5 0.5';
 923                         if(IS_REAL_CLIENT(self))
 924                         if(self.killindicator.cnt > 0)
 925                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 926                 }
 927                 else
 928                 {
 929                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 930                         if(IS_REAL_CLIENT(self))
 931                         if(self.killindicator.cnt > 0)
 932                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 933                 }
 934         }
 935
 936 }
 937
 938 void ClientKill (void)
 939 {
 940         if(gameover) return;
 941         if(self.player_blocked) return;
 942         if(self.frozen) return;
 943
 944         ClientKill_TeamChange(0);
 945 }
 946
 947 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 948 {
 949     e.killindicator = spawn();
 950     e.killindicator.owner = e;
 951     e.killindicator.think = KillIndicator_Think;
 952     e.killindicator.nextthink = time + (e.lip) * 0.05;
 953     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 954     e.killindicator.health = 1; // this is used to indicate that it should be silent
 955     e.lip = 0;
 956 }
 957
 958 void FixClientCvars(entity e)
 959 {
 960         // send prediction settings to the client
 961         stuffcmd(e, "\nin_bindmap 0 0\n");
 962         if(g_race || g_cts)
 963                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 964         if(autocvar_g_antilag == 3) // client side hitscan
 965                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 966         if(autocvar_sv_gentle)
 967                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 968         /*
 969          * we no longer need to stuff this. Remove this comment block if you feel
 970          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 971         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 972         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 973         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 978         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 983         stuffcmd(e, "cl_movement_edgefriction 1\n");
 984          */
 985 }
 986
 987 float PlayerInIDList(entity p, string idlist)
 988 {
 989         float n, i;
 990         string s;
 991
 992         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 993         if not(p.crypto_idfp)
 994                 return 0;
 995
 996         // this function allows abbreviated player IDs too!
 997         n = tokenize_console(idlist);
 998         for(i = 0; i < n; ++i)
 999         {
1000                 s = argv(i);
1001                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1002                         return 1;
1003         }
1004
1005         return 0;
1006 }
1007
1008 /*
1009 =============
1010 ClientConnect
1011
1012 Called when a client connects to the server
1013 =============
1014 */
1015 void DecodeLevelParms (void);
1016 //void dom_player_join_team(entity pl);
1017 void set_dom_state(entity e);
1018 void ClientConnect (void)
1019 {
1020         float t;
1021
1022         if(IS_CLIENT(self))
1023         {
1024                 print("Warning: ClientConnect, but already connected!\n");
1025                 return;
1026         }
1027
1028         if(Ban_MaybeEnforceBanOnce(self))
1029                 return;
1030
1031         DecodeLevelParms();
1032
1033 #ifdef WATERMARK
1034         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1035 #endif
1036
1037         self.classname = "player_joining";
1038
1039         self.flags = FL_CLIENT;
1040         self.version_nagtime = time + 10 + random() * 10;
1041
1042         if(player_count<0)
1043         {
1044                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1045                 player_count = 0;
1046         }
1047
1048         PlayerScore_Attach(self);
1049         ClientData_Attach();
1050         accuracy_init(self);
1051
1052         bot_clientconnect();
1053
1054         playerdemo_init();
1055
1056         anticheat_init();
1057
1058         race_PreSpawnObserver();
1059
1060         // identify the right forced team
1061         if(autocvar_g_campaign)
1062         {
1063                 if(IS_REAL_CLIENT(self)) // only players, not bots
1064                 {
1065                         switch(autocvar_g_campaign_forceteam)
1066                         {
1067                                 case 1: self.team_forced = NUM_TEAM_1; break;
1068                                 case 2: self.team_forced = NUM_TEAM_2; break;
1069                                 case 3: self.team_forced = NUM_TEAM_3; break;
1070                                 case 4: self.team_forced = NUM_TEAM_4; break;
1071                                 default: self.team_forced = 0;
1072                         }
1073                 }
1074         }
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1076                 self.team_forced = NUM_TEAM_1;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1078                 self.team_forced = NUM_TEAM_2;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1080                 self.team_forced = NUM_TEAM_3;
1081         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1082                 self.team_forced = NUM_TEAM_4;
1083         else if(autocvar_g_forced_team_otherwise == "red")
1084                 self.team_forced = NUM_TEAM_1;
1085         else if(autocvar_g_forced_team_otherwise == "blue")
1086                 self.team_forced = NUM_TEAM_2;
1087         else if(autocvar_g_forced_team_otherwise == "yellow")
1088                 self.team_forced = NUM_TEAM_3;
1089         else if(autocvar_g_forced_team_otherwise == "pink")
1090                 self.team_forced = NUM_TEAM_4;
1091         else if(autocvar_g_forced_team_otherwise == "spectate")
1092                 self.team_forced = -1;
1093         else if(autocvar_g_forced_team_otherwise == "spectator")
1094                 self.team_forced = -1;
1095         else
1096                 self.team_forced = 0;
1097
1098         if(!teamplay)
1099                 if(self.team_forced > 0)
1100                         self.team_forced = 0;
1101
1102         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1103
1104         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1105                 self.classname = "observer";
1106         } else {
1107                 if(teamplay)
1108                 {
1109                         if(autocvar_g_balance_teams)
1110                         {
1111                                 self.classname = "player";
1112                                 campaign_bots_may_start = 1;
1113                         }
1114                         else
1115                         {
1116                                 self.classname = "observer"; // do it anyway
1117                         }
1118                 }
1119                 else
1120                 {
1121                         self.classname = "player";
1122                         campaign_bots_may_start = 1;
1123                 }
1124         }
1125
1126         self.playerid = (playerid_last = playerid_last + 1);
1127
1128         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1129
1130     if(IS_BOT_CLIENT(self))
1131         PlayerStats_AddPlayer(self);
1132
1133         if(autocvar_sv_eventlog)
1134                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1135
1136         LogTeamchange(self.playerid, self.team, 1);
1137
1138         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1139
1140         self.netname_previous = strzone(self.netname);
1141
1142         if(IS_PLAYER(self) && teamplay)
1143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1144         else
1145                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1146
1147         stuffcmd(self, strcat(clientstuff, "\n"));
1148         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1149
1150         FixClientCvars(self);
1151
1152         // spawnfunc_waypoint sprites
1153         WaypointSprite_InitClient(self);
1154
1155         // Wazat's grappling hook
1156         SetGrappleHookBindings();
1157
1158         // get version info from player
1159         stuffcmd(self, "cmd clientversion $gameversion\n");
1160
1161         // get other cvars from player
1162         GetCvars(0);
1163
1164         // notify about available teams
1165         if(teamplay)
1166         {
1167                 CheckAllowedTeams(self);
1168                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1169                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1170         }
1171         else
1172                 stuffcmd(self, "set _teams_available 0\n");
1173
1174         attach_entcs();
1175
1176         bot_relinkplayerlist();
1177
1178         self.spectatortime = time;
1179         if(blockSpectators)
1180         {
1181                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1182         }
1183
1184         self.jointime = time;
1185         self.allowed_timeouts = autocvar_sv_timeout_number;
1186
1187         if(IS_REAL_CLIENT(self))
1188         {
1189                 if(!autocvar_g_campaign)
1190                 {
1191                         self.motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1193                 }
1194
1195                 if(autocvar_g_bugrigs || WEPSET_EQ_AW(g_weaponarena_weapons, WEP_TUBA))
1196                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1197         }
1198
1199         if(!sv_foginterval && world.fog != "")
1200                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1201
1202         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1203         {
1204                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1205                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1206         }
1207         else
1208                 self.hitplotfh = -1;
1209
1210         if(g_race || g_cts) {
1211                 string rr;
1212                 if(g_cts)
1213                         rr = CTS_RECORD;
1214                 else
1215                         rr = RACE_RECORD;
1216
1217                 msg_entity = self;
1218                 race_send_recordtime(MSG_ONE);
1219                 race_send_speedaward(MSG_ONE);
1220
1221                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
1222                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
1223                 race_send_speedaward_alltimebest(MSG_ONE);
1224
1225                 float i;
1226                 for (i = 1; i <= RANKINGS_CNT; ++i) {
1227                         race_SendRankings(i, 0, 0, MSG_ONE);
1228                 }
1229         }
1230         else if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca) // teamnagger is currently bad for ca
1231                 send_CSQC_teamnagger();
1232
1233         CheatInitClient();
1234
1235         CSQCMODEL_AUTOINIT();
1236
1237         self.model_randomizer = random();
1238
1239         if(IS_REAL_CLIENT(self))
1240                 sv_notice_join();
1241
1242         MUTATOR_CALLHOOK(ClientConnect);
1243 }
1244 /*
1245 =============
1246 ClientDisconnect
1247
1248 Called when a client disconnects from the server
1249 =============
1250 */
1251 .entity chatbubbleentity;
1252 void ReadyCount();
1253 void ClientDisconnect (void)
1254 {
1255         if(self.vehicle)
1256             vehicles_exit(VHEF_RELESE);
1257
1258         if not(IS_CLIENT(self))
1259         {
1260                 print("Warning: ClientDisconnect without ClientConnect\n");
1261                 return;
1262         }
1263
1264         PlayerStats_AddGlobalInfo(self);
1265
1266         CheatShutdownClient();
1267
1268         if(self.hitplotfh >= 0)
1269         {
1270                 fclose(self.hitplotfh);
1271                 self.hitplotfh = -1;
1272         }
1273
1274         anticheat_report();
1275         anticheat_shutdown();
1276
1277         playerdemo_shutdown();
1278
1279         bot_clientdisconnect();
1280
1281         if(self.entcs)
1282                 detach_entcs();
1283
1284         if(autocvar_sv_eventlog)
1285                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1286
1287         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1288
1289         MUTATOR_CALLHOOK(ClientDisconnect);
1290
1291         Portal_ClearAll(self);
1292
1293         Unfreeze(self);
1294
1295         RemoveGrapplingHook(self);
1296
1297         // Here, everything has been done that requires this player to be a client.
1298
1299         self.flags &~= FL_CLIENT;
1300
1301         if (self.chatbubbleentity)
1302                 remove (self.chatbubbleentity);
1303
1304         if (self.killindicator)
1305                 remove (self.killindicator);
1306
1307         WaypointSprite_PlayerGone();
1308
1309         bot_relinkplayerlist();
1310
1311         accuracy_free(self);
1312         ClientData_Detach();
1313         PlayerScore_Detach(self);
1314
1315         if(self.netname_previous)
1316                 strunzone(self.netname_previous);
1317         if(self.clientstatus)
1318                 strunzone(self.clientstatus);
1319         if(self.weaponorder_byimpulse)
1320                 strunzone(self.weaponorder_byimpulse);
1321
1322         ClearPlayerSounds();
1323
1324         if(self.personal)
1325                 remove(self.personal);
1326
1327         self.playerid = 0;
1328         ReadyCount();
1329
1330         // free cvars
1331         GetCvars(-1);
1332 }
1333
1334 .float BUTTON_CHAT;
1335 void ChatBubbleThink()
1336 {
1337         self.nextthink = time;
1338         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1339         {
1340                 if(self.owner) // but why can that ever be world?
1341                         self.owner.chatbubbleentity = world;
1342                 remove(self);
1343                 return;
1344         }
1345         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1346 #ifdef TETRIS
1347                 || self.owner.tetris_on
1348 #endif
1349         )
1350                 self.model = self.mdl;
1351         else
1352                 self.model = "";
1353 }
1354
1355 void UpdateChatBubble()
1356 {
1357         if (self.alpha < 0)
1358                 return;
1359         // spawn a chatbubble entity if needed
1360         if (!self.chatbubbleentity)
1361         {
1362                 self.chatbubbleentity = spawn();
1363                 self.chatbubbleentity.owner = self;
1364                 self.chatbubbleentity.exteriormodeltoclient = self;
1365                 self.chatbubbleentity.think = ChatBubbleThink;
1366                 self.chatbubbleentity.nextthink = time;
1367                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1368                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1369                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1370                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1371                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1372                 self.chatbubbleentity.model = "";
1373                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1374         }
1375 }
1376
1377
1378 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1379 // added to the model skins
1380 /*void UpdateColorModHack()
1381 {
1382         float c;
1383         c = self.clientcolors & 15;
1384         // LordHavoc: only bothering to support white, green, red, yellow, blue
1385              if (!teamplay) self.colormod = '0 0 0';
1386         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1387         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1388         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1389         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1390         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1391         else self.colormod = '1 1 1';
1392 }*/
1393
1394 void respawn(void)
1395 {
1396         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1397         {
1398                 self.solid = SOLID_NOT;
1399                 self.takedamage = DAMAGE_NO;
1400                 self.movetype = MOVETYPE_FLY;
1401                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1402                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1403                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1404                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1405                 if(autocvar_g_respawn_ghosts_maxtime)
1406                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1407         }
1408
1409         CopyBody(1);
1410
1411         self.effects |= EF_NODRAW; // prevent another CopyBody
1412         PutClientInServer();
1413 }
1414
1415 void play_countdown(float finished, string samp)
1416 {
1417         if(IS_REAL_CLIENT(self))
1418                 if(floor(finished - time - frametime) != floor(finished - time))
1419                         if(finished - time < 6)
1420                                 sound (self, CH_INFO, samp, VOL_BASE, ATTN_NORM);
1421 }
1422
1423 void player_powerups (void)
1424 {
1425         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1426         olditems = self.items;
1427
1428         if((self.items & IT_USING_JETPACK) && !self.deadflag)
1429                 self.modelflags |= MF_ROCKET;
1430         else
1431                 self.modelflags &~= MF_ROCKET;
1432
1433         self.effects &~= (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1434
1435         if(self.alpha < 0 || self.deadflag) // don't apply the flags if the player is gibbed
1436                 return;
1437
1438         Fire_ApplyDamage(self);
1439         Fire_ApplyEffect(self);
1440
1441         if not(g_minstagib)
1442         {
1443                 if (self.items & IT_STRENGTH)
1444                 {
1445                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1446                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1447                         if (time > self.strength_finished)
1448                         {
1449                                 self.items = self.items - (self.items & IT_STRENGTH);
1450                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1452                         }
1453                 }
1454                 else
1455                 {
1456                         if (time < self.strength_finished)
1457                         {
1458                                 self.items = self.items | IT_STRENGTH;
1459                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1461                         }
1462                 }
1463                 if (self.items & IT_INVINCIBLE)
1464                 {
1465                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1466                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1467                         if (time > self.invincible_finished)
1468                         {
1469                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1470                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1471                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1472                         }
1473                 }
1474                 else
1475                 {
1476                         if (time < self.invincible_finished)
1477                         {
1478                                 self.items = self.items | IT_INVINCIBLE;
1479                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1480                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1481                         }
1482                 }
1483                 if (self.items & IT_SUPERWEAPON)
1484                 {
1485                         if (!WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1486                         {
1487                                 self.superweapons_finished = 0;
1488                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1489                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1490                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1491                         }
1492                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1493                         {
1494                                 // don't let them run out
1495                         }
1496                         else
1497                         {
1498                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1499                                 if (time > self.superweapons_finished)
1500                                 {
1501                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1502                                         WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1503                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1504                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1505                                 }
1506                         }
1507                 }
1508                 else if(WEPSET_CONTAINS_ANY_EA(self, WEPBIT_SUPERWEAPONS))
1509                 {
1510                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1511                         {
1512                                 self.items = self.items | IT_SUPERWEAPON;
1513                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1514                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1515                         }
1516                         else
1517                         {
1518                                 self.superweapons_finished = 0;
1519                                 WEPSET_ANDNOT_EA(self, WEPBIT_SUPERWEAPONS);
1520                         }
1521                 }
1522                 else
1523                 {
1524                         self.superweapons_finished = 0;
1525                 }
1526         }
1527
1528         if(autocvar_g_nodepthtestplayers)
1529                 self.effects = self.effects | EF_NODEPTHTEST;
1530
1531         if(autocvar_g_fullbrightplayers)
1532                 self.effects = self.effects | EF_FULLBRIGHT;
1533
1534         // midair gamemode: damage only while in the air
1535         // if in midair mode, being on ground grants temporary invulnerability
1536         // (this is so that multishot weapon don't clear the ground flag on the
1537         // first damage in the frame, leaving the player vulnerable to the
1538         // remaining hits in the same frame)
1539         if (self.flags & FL_ONGROUND)
1540         if (g_midair)
1541                 self.spawnshieldtime = max(self.spawnshieldtime, time + autocvar_g_midair_shieldtime);
1542
1543         if (time >= game_starttime)
1544         if (time < self.spawnshieldtime)
1545                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1546
1547         MUTATOR_CALLHOOK(PlayerPowerups);
1548 }
1549
1550 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1551 {
1552         if(current > stable)
1553                 return current;
1554         else if(current > stable - 0.25) // when close enough, "snap"
1555                 return stable;
1556         else
1557                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1558 }
1559
1560 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1561 {
1562         if(current < stable)
1563                 return current;
1564         else if(current < stable + 0.25) // when close enough, "snap"
1565                 return stable;
1566         else
1567                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1568 }
1569
1570 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1571 {
1572         if(current > rotstable)
1573         {
1574                 if(rotframetime > 0)
1575                 {
1576                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1577                         current = max(rotstable, current - rotlinear * rotframetime);
1578                 }
1579         }
1580         else if(current < regenstable)
1581         {
1582                 if(regenframetime > 0)
1583                 {
1584                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1585                         current = min(regenstable, current + regenlinear * regenframetime);
1586                 }
1587         }
1588
1589         if(current > limit)
1590                 current = limit;
1591
1592         return current;
1593 }
1594
1595 void player_regen (void)
1596 {
1597         float minh, mina, minf, maxh, maxa, maxf, limith, limita, limitf, max_mod, regen_mod, rot_mod, limit_mod;
1598         maxh = autocvar_g_balance_health_rotstable;
1599         maxa = autocvar_g_balance_armor_rotstable;
1600         maxf = autocvar_g_balance_fuel_rotstable;
1601         minh = autocvar_g_balance_health_regenstable;
1602         mina = autocvar_g_balance_armor_regenstable;
1603         minf = autocvar_g_balance_fuel_regenstable;
1604         limith = autocvar_g_balance_health_limit;
1605         limita = autocvar_g_balance_armor_limit;
1606         limitf = autocvar_g_balance_fuel_limit;
1607
1608         max_mod = regen_mod = rot_mod = limit_mod = 1;
1609
1610         maxh = maxh * max_mod;
1611         //maxa = maxa * max_mod;
1612         //maxf = maxf * max_mod;
1613         minh = minh * max_mod;
1614         //mina = mina * max_mod;
1615         //minf = minf * max_mod;
1616         limith = limith * limit_mod;
1617         limita = limita * limit_mod;
1618         //limitf = limitf * limit_mod;
1619
1620         if(g_ca)
1621                 rot_mod = 0;
1622
1623         if (!g_minstagib && !g_ca && (!g_lms || autocvar_g_lms_regenerate))
1624         {
1625                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1626                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1627
1628                 // if player rotted to death...  die!
1629                 if(self.health < 1)
1630                         self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1631         }
1632
1633         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
1634                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished) * (self.items & IT_FUEL_REGEN != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rot_mod * frametime * (time > self.pauserotfuel_finished), limitf);
1635 }
1636
1637 float zoomstate_set;
1638 void SetZoomState(float z)
1639 {
1640         if(z != self.zoomstate)
1641         {
1642                 self.zoomstate = z;
1643                 ClientData_Touch(self);
1644         }
1645         zoomstate_set = 1;
1646 }
1647
1648 void GetPressedKeys(void) {
1649         MUTATOR_CALLHOOK(GetPressedKeys);
1650         if (self.movement_x > 0) // get if movement keys are pressed
1651         {       // forward key pressed
1652                 self.pressedkeys |= KEY_FORWARD;
1653                 self.pressedkeys &~= KEY_BACKWARD;
1654         }
1655         else if (self.movement_x < 0)
1656         {       // backward key pressed
1657                 self.pressedkeys |= KEY_BACKWARD;
1658                 self.pressedkeys &~= KEY_FORWARD;
1659         }
1660         else
1661         {       // no x input
1662                 self.pressedkeys &~= KEY_FORWARD;
1663                 self.pressedkeys &~= KEY_BACKWARD;
1664         }
1665
1666         if (self.movement_y > 0)
1667         {       // right key pressed
1668                 self.pressedkeys |= KEY_RIGHT;
1669                 self.pressedkeys &~= KEY_LEFT;
1670         }
1671         else if (self.movement_y < 0)
1672         {       // left key pressed
1673                 self.pressedkeys |= KEY_LEFT;
1674                 self.pressedkeys &~= KEY_RIGHT;
1675         }
1676         else
1677         {       // no y input
1678                 self.pressedkeys &~= KEY_RIGHT;
1679                 self.pressedkeys &~= KEY_LEFT;
1680         }
1681
1682         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1683                 self.pressedkeys |= KEY_JUMP;
1684         else
1685                 self.pressedkeys &~= KEY_JUMP;
1686         if (self.BUTTON_CROUCH)
1687                 self.pressedkeys |= KEY_CROUCH;
1688         else
1689                 self.pressedkeys &~= KEY_CROUCH;
1690
1691         if (self.BUTTON_ATCK)
1692                 self.pressedkeys |= KEY_ATCK;
1693         else
1694                 self.pressedkeys &~= KEY_ATCK;
1695         if (self.BUTTON_ATCK2)
1696                 self.pressedkeys |= KEY_ATCK2;
1697         else
1698                 self.pressedkeys &~= KEY_ATCK2;
1699 }
1700
1701 /*
1702 ======================
1703 spectate mode routines
1704 ======================
1705 */
1706
1707 void SpectateCopy(entity spectatee) {
1708         other = spectatee;
1709         MUTATOR_CALLHOOK(SpectateCopy);
1710         self.armortype = spectatee.armortype;
1711         self.armorvalue = spectatee.armorvalue;
1712         self.ammo_cells = spectatee.ammo_cells;
1713         self.ammo_shells = spectatee.ammo_shells;
1714         self.ammo_nails = spectatee.ammo_nails;
1715         self.ammo_rockets = spectatee.ammo_rockets;
1716         self.ammo_fuel = spectatee.ammo_fuel;
1717         self.clip_load = spectatee.clip_load;
1718         self.clip_size = spectatee.clip_size;
1719         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1720         self.health = spectatee.health;
1721         self.impulse = 0;
1722         self.items = spectatee.items;
1723         self.last_pickup = spectatee.last_pickup;
1724         self.hit_time = spectatee.hit_time;
1725         self.metertime = spectatee.metertime;
1726         self.strength_finished = spectatee.strength_finished;
1727         self.invincible_finished = spectatee.invincible_finished;
1728         self.pressedkeys = spectatee.pressedkeys;
1729         WEPSET_COPY_EE(self, spectatee);
1730         self.switchweapon = spectatee.switchweapon;
1731         self.switchingweapon = spectatee.switchingweapon;
1732         self.weapon = spectatee.weapon;
1733         self.nex_charge = spectatee.nex_charge;
1734         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1735         self.hagar_load = spectatee.hagar_load;
1736         self.minelayer_mines = spectatee.minelayer_mines;
1737         self.punchangle = spectatee.punchangle;
1738         self.view_ofs = spectatee.view_ofs;
1739         self.velocity = spectatee.velocity;
1740         self.dmg_take = spectatee.dmg_take;
1741         self.dmg_save = spectatee.dmg_save;
1742         self.dmg_inflictor = spectatee.dmg_inflictor;
1743         self.v_angle = spectatee.v_angle;
1744         self.angles = spectatee.v_angle;
1745         if(!self.BUTTON_USE)
1746                 self.fixangle = TRUE;
1747         setorigin(self, spectatee.origin);
1748         setsize(self, spectatee.mins, spectatee.maxs);
1749         SetZoomState(spectatee.zoomstate);
1750
1751     anticheat_spectatecopy(spectatee);
1752         self.hud = spectatee.hud;
1753         if(spectatee.vehicle)
1754     {
1755         self.fixangle = FALSE;
1756         //self.velocity = spectatee.vehicle.velocity;
1757         self.vehicle_health = spectatee.vehicle_health;
1758         self.vehicle_shield = spectatee.vehicle_shield;
1759         self.vehicle_energy = spectatee.vehicle_energy;
1760         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1761         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1762         self.vehicle_reload1 = spectatee.vehicle_reload1;
1763         self.vehicle_reload2 = spectatee.vehicle_reload2;
1764
1765         msg_entity = self;
1766
1767         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1768             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1769             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1770             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1771
1772         //WriteByte (MSG_ONE, SVC_SETVIEW);
1773         //    WriteEntity(MSG_ONE, self);
1774         //makevectors(spectatee.v_angle);
1775         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1776     }
1777 }
1778
1779 float SpectateUpdate() {
1780         if(!self.enemy)
1781             return 0;
1782
1783         if (self == self.enemy)
1784                 return 0;
1785
1786         if not(IS_PLAYER(self.enemy))
1787                 return 0;
1788
1789         SpectateCopy(self.enemy);
1790
1791         return 1;
1792 }
1793
1794
1795 float SpectateSet()
1796 {
1797         if(self.enemy.classname != "player")
1798                 return FALSE;
1799         /*if(self.enemy.vehicle)
1800         {
1801
1802                 msg_entity = self;
1803                 WriteByte(MSG_ONE, SVC_SETVIEW);
1804                 WriteEntity(MSG_ONE, self.enemy);
1805                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1806
1807                 self.movetype = MOVETYPE_NONE;
1808                 accuracy_resend(self);
1809         }
1810         else
1811         {*/
1812                 msg_entity = self;
1813                 WriteByte(MSG_ONE, SVC_SETVIEW);
1814                 WriteEntity(MSG_ONE, self.enemy);
1815                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1816                 self.movetype = MOVETYPE_NONE;
1817                 accuracy_resend(self);
1818
1819                 if(!SpectateUpdate())
1820                         PutObserverInServer();
1821         //}
1822         return TRUE;
1823 }
1824
1825 float Spectate(entity pl)
1826 {
1827         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1828         if(pl.team != self.team)
1829                 return 0;
1830
1831         self.enemy = pl;
1832         return SpectateSet();
1833 }
1834
1835 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1836 entity CA_SpectateNext(entity start) {
1837         if (start.team == self.team) {
1838                 return start;
1839         }
1840
1841         other = start;
1842         // continue from current player
1843         while(other && other.team != self.team) {
1844                 other = find(other, classname, "player");
1845         }
1846
1847         if (!other) {
1848                 // restart from begining
1849                 other = find(other, classname, "player");
1850                 while(other && other.team != self.team) {
1851                         other = find(other, classname, "player");
1852                 }
1853         }
1854
1855         return other;
1856 }
1857
1858 float SpectateNext()
1859 {
1860         other = find(self.enemy, classname, "player");
1861
1862         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1863                 // CA and ca players when spectating enemies is forbidden
1864                 other = CA_SpectateNext(other);
1865         } else {
1866                 // other modes and ca spectators or spectating enemies is allowed
1867                 if (!other)
1868                         other = find(other, classname, "player");
1869         }
1870
1871         if (other)
1872                 self.enemy = other;
1873
1874         return SpectateSet();
1875 }
1876
1877 float SpectatePrev()
1878 {
1879         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1880         other = findchain(classname, "player");
1881         if not(other) // no player
1882                 return FALSE;
1883
1884         entity first = other;
1885         // skip players until current spectated player
1886         if(self.enemy)
1887         while(other && other != self.enemy)
1888                 other = other.chain;
1889
1890         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1891         {
1892                 do { other = other.chain; }
1893                 while(other && other.team != self.team);
1894
1895                 if not(other)
1896                 {
1897                         other = first;
1898                         while(other.team != self.team)
1899                                 other = other.chain;
1900                         if(other == self.enemy)
1901                                 return TRUE;
1902                 }
1903         }
1904         else
1905         {
1906                 if(other.chain)
1907                         other = other.chain;
1908                 else
1909                         other = first;
1910         }
1911         self.enemy = other;
1912         return SpectateSet();
1913 }
1914
1915 /*
1916 =============
1917 ShowRespawnCountdown()
1918
1919 Update a respawn countdown display.
1920 =============
1921 */
1922 void ShowRespawnCountdown()
1923 {
1924         float number;
1925         if(self.deadflag == DEAD_NO) // just respawned?
1926                 return;
1927         else
1928         {
1929                 number = ceil(self.respawn_time - time);
1930                 if(number <= 0)
1931                         return;
1932                 if(number <= self.respawn_countdown)
1933                 {
1934                         self.respawn_countdown = number - 1;
1935                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1936                                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(number));
1937                 }
1938         }
1939 }
1940
1941 void LeaveSpectatorMode()
1942 {
1943         if(self.caplayer)
1944                 return;
1945         if(nJoinAllowed(self))
1946         {
1947                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1948                 {
1949                         self.classname = "player";
1950
1951                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1952                                 { JoinBestTeam(self, FALSE, TRUE); }
1953
1954                         if(autocvar_g_campaign)
1955                                 { campaign_bots_may_start = 1; }
1956
1957                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1958
1959                         PutClientInServer();
1960
1961                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1962                 }
1963                 else
1964                         stuffcmd(self, "menu_showteamselect\n");
1965         }
1966         else
1967         {
1968                 // Player may not join because g_maxplayers is set
1969                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1970         }
1971 }
1972
1973 /**
1974  * Determines whether the player is allowed to join. This depends on cvar
1975  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1976  * it checks whether the number of currently playing players exceeds g_maxplayers.
1977  * @return int number of free slots for players, 0 if none
1978  */
1979 float nJoinAllowed(entity ignore) {
1980         if(!ignore)
1981         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1982         // so report 0 free slots if restricted
1983         {
1984                 if(autocvar_g_forced_team_otherwise == "spectate")
1985                         return 0;
1986                 if(autocvar_g_forced_team_otherwise == "spectator")
1987                         return 0;
1988         }
1989
1990         if(self.team_forced < 0)
1991                 return 0; // forced spectators can never join
1992
1993         // TODO simplify this
1994         entity e;
1995         float totalClients = 0;
1996         FOR_EACH_CLIENT(e)
1997                 if(e != ignore)
1998                         totalClients += 1;
1999
2000         if (!autocvar_g_maxplayers)
2001                 return maxclients - totalClients;
2002
2003         float currentlyPlaying = 0;
2004         FOR_EACH_REALCLIENT(e)
2005                 if(IS_PLAYER(e) || e.caplayer == 1)
2006                         currentlyPlaying += 1;
2007
2008         if(currentlyPlaying < autocvar_g_maxplayers)
2009                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2010
2011         return 0;
2012 }
2013
2014 /**
2015  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2016  * g_maxplayers_spectator_blocktime seconds
2017  */
2018 void checkSpectatorBlock() {
2019         if(IS_SPEC(self) || IS_OBSERVER(self)) {
2020                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2021                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2022                         dropclient(self);
2023                 }
2024         }
2025 }
2026
2027 void PrintWelcomeMessage()
2028 {
2029         if(self.motd_actived_time == 0)
2030         {
2031                 if (autocvar_g_campaign) {
2032                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2033                                 self.motd_actived_time = time;
2034                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2035                         }
2036                 } else {
2037                         if (self.BUTTON_INFO) {
2038                                 self.motd_actived_time = time;
2039                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2040                         }
2041                 }
2042         }
2043         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2044         {
2045                 if (autocvar_g_campaign) {
2046                         if (self.BUTTON_INFO)
2047                                 self.motd_actived_time = time;
2048                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2049                                 self.motd_actived_time = 0;
2050                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2051                         }
2052                 } else {
2053                         if (self.BUTTON_INFO)
2054                                 self.motd_actived_time = time;
2055                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2056                                 self.motd_actived_time = 0;
2057                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2058                         }
2059                 }
2060         }
2061         else //if(self.motd_actived_time < 0) // just connected, motd is active
2062         {
2063                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2064                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2065                 else if(self.motd_actived_time == -2 || IS_PLAYER(self) || time - self.jointime > autocvar_welcome_message_time)
2066                 {
2067                         // instanctly hide MOTD
2068                         self.motd_actived_time = 0;
2069                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2070                 }
2071         }
2072 }
2073
2074 void ObserverThink()
2075 {
2076         float prefered_movetype;
2077         if (self.flags & FL_JUMPRELEASED) {
2078                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2079                         self.flags &~= FL_JUMPRELEASED;
2080                         self.flags |= FL_SPAWNING;
2081                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2082                         self.flags &~= FL_JUMPRELEASED;
2083                         if(SpectateNext()) {
2084                                 self.classname = "spectator";
2085                         }
2086                 } else {
2087                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2088                         if (self.movetype != prefered_movetype)
2089                                 self.movetype = prefered_movetype;
2090                 }
2091         } else {
2092                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2093                         self.flags |= FL_JUMPRELEASED;
2094                         if(self.flags & FL_SPAWNING)
2095                         {
2096                                 self.flags &~= FL_SPAWNING;
2097                                 LeaveSpectatorMode();
2098                                 return;
2099                         }
2100                 }
2101         }
2102 }
2103
2104 void SpectatorThink()
2105 {
2106         if (self.flags & FL_JUMPRELEASED) {
2107                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2108                         self.flags &~= FL_JUMPRELEASED;
2109                         self.flags |= FL_SPAWNING;
2110                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || self.impulse >= 200 && self.impulse <= 209) {
2111                         self.flags &~= FL_JUMPRELEASED;
2112                         if(SpectateNext()) {
2113                                 self.classname = "spectator";
2114                         } else {
2115                                 self.classname = "observer";
2116                                 PutClientInServer();
2117                         }
2118                         self.impulse = 0;
2119                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || self.impulse >= 220 && self.impulse <= 229) {
2120                         self.flags &~= FL_JUMPRELEASED;
2121                         if(SpectatePrev()) {
2122                                 self.classname = "spectator";
2123                         } else {
2124                                 self.classname = "observer";
2125                                 PutClientInServer();
2126                         }
2127                         self.impulse = 0;
2128                 } else if (self.BUTTON_ATCK2) {
2129                         self.flags &~= FL_JUMPRELEASED;
2130                         self.classname = "observer";
2131                         PutClientInServer();
2132                 } else {
2133                         if(!SpectateUpdate())
2134                                 PutObserverInServer();
2135                 }
2136         } else {
2137                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2138                         self.flags |= FL_JUMPRELEASED;
2139                         if(self.flags & FL_SPAWNING)
2140                         {
2141                                 self.flags &~= FL_SPAWNING;
2142                                 LeaveSpectatorMode();
2143                                 return;
2144                         }
2145                 }
2146                 if(!SpectateUpdate())
2147                         PutObserverInServer();
2148         }
2149
2150         self.flags |= FL_CLIENT | FL_NOTARGET;
2151 }
2152
2153 void PlayerUseKey()
2154 {
2155         if not(IS_PLAYER(self))
2156                 return;
2157
2158         if(self.vehicle)
2159         {
2160         vehicles_exit(VHEF_NORMAL);
2161         return;
2162         }
2163
2164         // a use key was pressed; call handlers
2165         MUTATOR_CALLHOOK(PlayerUseKey);
2166 }
2167
2168 /*
2169 =============
2170 PlayerPreThink
2171
2172 Called every frame for each client before the physics are run
2173 =============
2174 */
2175 .float usekeypressed;
2176 void() nexball_setstatus;
2177 .float items_added;
2178 void PlayerPreThink (void)
2179 {
2180         WarpZone_PlayerPhysics_FixVAngle();
2181
2182         self.stat_game_starttime = game_starttime;
2183         self.stat_round_starttime = round_starttime;
2184         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2185         self.stat_leadlimit = autocvar_leadlimit;
2186
2187         if(frametime)
2188         {
2189                 // physics frames: update anticheat stuff
2190                 anticheat_prethink();
2191         }
2192
2193         if(blockSpectators && frametime)
2194                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2195                 checkSpectatorBlock();
2196
2197         zoomstate_set = 0;
2198
2199         if(self.netname_previous != self.netname)
2200         {
2201                 if(autocvar_sv_eventlog)
2202                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2203                 if(self.netname_previous)
2204                         strunzone(self.netname_previous);
2205                 self.netname_previous = strzone(self.netname);
2206         }
2207
2208         // version nagging
2209         if(self.version_nagtime)
2210                 if(self.cvar_g_xonoticversion)
2211                         if(time > self.version_nagtime)
2212                         {
2213                                 // don't notify git users
2214                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2215                                 {
2216                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2217                                         {
2218                                                 // notify release users if connecting to git
2219                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2220                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2221                                         }
2222                                         else
2223                                         {
2224                                                 float r;
2225                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2226                                                 if(r < 0)
2227                                                 {
2228                                                         // give users new version
2229                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2230                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2231                                                 }
2232                                                 else if(r > 0)
2233                                                 {
2234                                                         // notify users about old server version
2235                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2236                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2237                                                 }
2238                                         }
2239                                 }
2240                                 self.version_nagtime = 0;
2241                         }
2242
2243         // GOD MODE info
2244         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2245         {
2246                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2247                 self.max_armorvalue = 0;
2248         }
2249
2250 #ifdef TETRIS
2251         if (TetrisPreFrame())
2252                 return;
2253 #endif
2254
2255         if(self.frozen == 2)
2256         {
2257                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2258                 self.health = max(1, self.revive_progress * autocvar_g_balance_health_start);
2259
2260                 if(self.revive_progress >= 1)
2261                         Unfreeze(self);
2262         }
2263
2264         MUTATOR_CALLHOOK(PlayerPreThink);
2265
2266         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2267         {
2268                 if(self.BUTTON_USE && !self.usekeypressed)
2269                         PlayerUseKey();
2270                 self.usekeypressed = self.BUTTON_USE;
2271         }
2272
2273         if(IS_REAL_CLIENT(self))
2274                 PrintWelcomeMessage();
2275
2276         if(IS_PLAYER(self))
2277         {
2278
2279                 CheckRules_Player();
2280
2281                 if (intermission_running)
2282                 {
2283                         IntermissionThink ();   // otherwise a button could be missed between
2284                         return;                                 // the think tics
2285                 }
2286
2287                 //don't allow the player to turn around while game is paused!
2288                 if(timeout_status == TIMEOUT_ACTIVE) {
2289                         // FIXME turn this into CSQC stuff
2290                         self.v_angle = self.lastV_angle;
2291                         self.angles = self.lastV_angle;
2292                         self.fixangle = TRUE;
2293                 }
2294
2295                 if(frametime)
2296                 {
2297                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2298                         {
2299                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2300                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2301                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2302
2303                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2304                                 {
2305                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2306                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2307                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2308                                 }
2309                         }
2310                         else
2311                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2312
2313                         player_powerups();
2314                 }
2315
2316                 if (self.deadflag != DEAD_NO)
2317                 {
2318                         if(self.personal && g_race_qualifying)
2319                         {
2320                                 if(time > self.respawn_time)
2321                                 {
2322                                         self.respawn_time = time + 1; // only retry once a second
2323                                         self.stat_respawn_time = self.respawn_time;
2324                                         respawn();
2325                                         self.impulse = 141;
2326                                 }
2327                         }
2328                         else
2329                         {
2330                                 float button_pressed;
2331                                 if(frametime)
2332                                         player_anim();
2333                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2334
2335                                 if (self.deadflag == DEAD_DYING)
2336                                 {
2337                                         if(self.respawn_flags & RESPAWN_FORCE)
2338                                                 self.deadflag = DEAD_RESPAWNING;
2339                                         else if(!button_pressed)
2340                                                 self.deadflag = DEAD_DEAD;
2341                                 }
2342                                 else if (self.deadflag == DEAD_DEAD)
2343                                 {
2344                                         if(button_pressed)
2345                                                 self.deadflag = DEAD_RESPAWNABLE;
2346                                 }
2347                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2348                                 {
2349                                         if(!button_pressed)
2350                                                 self.deadflag = DEAD_RESPAWNING;
2351                                 }
2352                                 else if (self.deadflag == DEAD_RESPAWNING)
2353                                 {
2354                                         if(time > self.respawn_time)
2355                                         {
2356                                                 self.respawn_time = time + 1; // only retry once a second
2357                                                 respawn();
2358                                         }
2359                                 }
2360
2361                                 ShowRespawnCountdown();
2362
2363                                 if(self.respawn_flags & RESPAWN_SILENT)
2364                                         self.stat_respawn_time = 0;
2365                                 else
2366                                         self.stat_respawn_time = self.respawn_time;
2367                         }
2368
2369                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2370                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2371                                 self.stat_respawn_time *= -1;
2372
2373                         return;
2374                 }
2375
2376                 self.prevorigin = self.origin;
2377
2378                 float do_crouch = self.BUTTON_CROUCH;
2379                 if(self.hook.state)
2380                         do_crouch = 0;
2381                 if(self.health <= g_bloodloss)
2382                         do_crouch = 1;
2383                 if(self.vehicle)
2384                         do_crouch = 0;
2385                 if(self.frozen)
2386                         do_crouch = 0;
2387                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2388                         do_crouch = 0;
2389
2390                 if (do_crouch)
2391                 {
2392                         if (!self.crouch)
2393                         {
2394                                 self.crouch = TRUE;
2395                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2396                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2397                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2398                         }
2399                 }
2400                 else
2401                 {
2402                         if (self.crouch)
2403                         {
2404                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2405                                 if (!trace_startsolid)
2406                                 {
2407                                         self.crouch = FALSE;
2408                                         self.view_ofs = PL_VIEW_OFS;
2409                                         setsize (self, PL_MIN, PL_MAX);
2410                                 }
2411                         }
2412                 }
2413
2414                 if(self.health <= g_bloodloss && self.deadflag == DEAD_NO)
2415                 {
2416                         if(self.bloodloss_timer < time)
2417                         {
2418                                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
2419                                 self.bloodloss_timer = time + 0.5 + random() * 0.5;
2420                         }
2421                 }
2422
2423                 FixPlayermodel();
2424
2425                 GrapplingHookFrame();
2426
2427                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2428                 //if(frametime)
2429                 {
2430                         self.items &~= self.items_added;
2431
2432                         W_WeaponFrame();
2433
2434                         self.items_added = 0;
2435                         if(self.items & IT_JETPACK)
2436                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2437                                         self.items_added |= IT_FUEL;
2438
2439                         self.items |= self.items_added;
2440                 }
2441
2442                 player_regen();
2443
2444                 // rot nex charge to the charge limit
2445                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2446                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2447
2448                 if(frametime)
2449                         player_anim();
2450
2451                 if(g_nexball)
2452                         nexball_setstatus();
2453
2454                 // secret status
2455                 secrets_setstatus();
2456
2457                 // monsters status
2458                 monsters_setstatus();
2459
2460                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2461
2462                 //self.angles_y=self.v_angle_y + 90;   // temp
2463         } else if(gameover) {
2464                 if (intermission_running)
2465                         IntermissionThink ();   // otherwise a button could be missed between
2466                 return;
2467         } else if(IS_OBSERVER(self)) {
2468                 ObserverThink();
2469         } else if(IS_SPEC(self)) {
2470                 SpectatorThink();
2471         }
2472
2473         if(!zoomstate_set)
2474                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2475
2476         float oldspectatee_status;
2477         oldspectatee_status = self.spectatee_status;
2478         if(IS_SPEC(self))
2479                 self.spectatee_status = num_for_edict(self.enemy);
2480         else if(IS_OBSERVER(self))
2481                 self.spectatee_status = num_for_edict(self);
2482         else
2483                 self.spectatee_status = 0;
2484         if(self.spectatee_status != oldspectatee_status)
2485         {
2486                 ClientData_Touch(self);
2487                 if(g_race || g_cts)
2488                         race_InitSpectator();
2489         }
2490
2491         if(self.teamkill_soundtime)
2492         if(time > self.teamkill_soundtime)
2493         {
2494                 self.teamkill_soundtime = 0;
2495
2496                 entity oldpusher, oldself;
2497
2498                 oldself = self; self = self.teamkill_soundsource;
2499                 oldpusher = self.pusher; self.pusher = oldself;
2500
2501                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2502
2503                 self.pusher = oldpusher;
2504                 self = oldself;
2505         }
2506
2507         if(self.taunt_soundtime)
2508         if(time > self.taunt_soundtime)
2509         {
2510                 self.taunt_soundtime = 0;
2511                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2512         }
2513
2514         target_voicescript_next(self);
2515
2516         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2517         if(!self.weapon)
2518                 self.clip_load = self.clip_size = 0;
2519 }
2520
2521 float isInvisibleString(string s)
2522 {
2523         float i, n, c;
2524         s = strdecolorize(s);
2525         for((i = 0), (n = strlen(s)); i < n; ++i)
2526         {
2527                 c = str2chr(s, i);
2528                 switch(c)
2529                 {
2530                         case 0:
2531                         case 32: // space
2532                                 break;
2533                         case 192: // charmap space
2534                                 if (!autocvar_utf8_enable)
2535                                         break;
2536                                 return FALSE;
2537                         case 160: // space in unicode fonts
2538                         case 0xE000 + 192: // utf8 charmap space
2539                                 if (autocvar_utf8_enable)
2540                                         break;
2541                         default:
2542                                 return FALSE;
2543                 }
2544         }
2545         return TRUE;
2546 }
2547
2548 /*
2549 =============
2550 PlayerPostThink
2551
2552 Called every frame for each client after the physics are run
2553 =============
2554 */
2555 .float idlekick_lasttimeleft;
2556 void PlayerPostThink (void)
2557 {
2558         // Savage: Check for nameless players
2559         if (isInvisibleString(self.netname)) {
2560                 self.netname = "Player";
2561                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2562         }
2563
2564         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2565         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2566         {
2567                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2568                 {
2569                         if(self.idlekick_lasttimeleft)
2570                         {
2571                                 self.idlekick_lasttimeleft = 0;
2572                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2573                         }
2574                 }
2575                 else
2576                 {
2577                         float timeleft;
2578                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2579                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2580                         {
2581                                 if(!self.idlekick_lasttimeleft)
2582                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2583                         }
2584                         if(timeleft <= 0)
2585                         {
2586                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2587                                 dropclient(self);
2588                                 return;
2589                         }
2590                         else if(timeleft <= 10)
2591                         {
2592                                 if(timeleft != self.idlekick_lasttimeleft)
2593                                         Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(timeleft));
2594                                 self.idlekick_lasttimeleft = timeleft;
2595                         }
2596                 }
2597         }
2598
2599 #ifdef TETRIS
2600         if(self.impulse == 100)
2601                 ImpulseCommands();
2602         if (!TetrisPostFrame())
2603         {
2604 #endif
2605
2606         CheatFrame();
2607
2608         //CheckPlayerJump();
2609
2610         if(IS_PLAYER(self)) {
2611                 CheckRules_Player();
2612                 UpdateChatBubble();
2613                 if (self.impulse)
2614                         ImpulseCommands();
2615                 if (intermission_running)
2616                         return;         // intermission or finale
2617                 GetPressedKeys();
2618         }
2619
2620 #ifdef TETRIS
2621         }
2622 #endif
2623
2624         /*
2625         float i;
2626         for(i = 0; i < 1000; ++i)
2627         {
2628                 vector end;
2629                 end = self.origin + '0 0 1024' + 512 * randomvec();
2630                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2631                 if(trace_fraction < 1)
2632                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2633                 {
2634                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2635                         break;
2636                 }
2637         }
2638         */
2639
2640         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2641
2642         if(self.waypointsprite_attachedforcarrier)
2643                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent));
2644
2645         playerdemo_write();
2646
2647         if((g_cts || g_race) && self.cvar_cl_allow_uidtracking == 1 && self.cvar_cl_allow_uid2name == 1)
2648         {
2649                 if not(self.stored_netname)
2650                         self.stored_netname = strzone(uid2name(self.crypto_idfp));
2651                 if(self.stored_netname != self.netname)
2652                 {
2653                         db_put(ServerProgsDB, strcat("/uid2name/", self.crypto_idfp), self.netname);
2654                         strunzone(self.stored_netname);
2655                         self.stored_netname = strzone(self.netname);
2656                 }
2657         }
2658
2659         /*
2660         if(g_race)
2661                 dprint(sprintf("%f %.6f\n", time, race_GetFractionalLapCount(self)));
2662         */
2663
2664         CSQCMODEL_AUTOUPDATE();
2665 }