qcsrc/server/cl_client.qc

   1 void send_CSQC_teamnagger() {
   2         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
   3         WriteByte(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
   4 }
   5
   6 float ClientData_Send(entity to, float sf)
   7 {
   8         if(to != self.owner)
   9         {
  10                 error("wtf");
  11                 return FALSE;
  12         }
  13
  14         entity e;
  15
  16         e = to;
  17         if(IS_SPEC(to))
  18                 e = to.enemy;
  19
  20         sf = 0;
  21
  22         if(e.race_completed)
  23                 sf |= 1; // forced scoreboard
  24         if(to.spectatee_status)
  25                 sf |= 2; // spectator ent number follows
  26         if(e.zoomstate)
  27                 sf |= 4; // zoomed
  28         if(e.porto_v_angle_held)
  29                 sf |= 8; // angles held
  30
  31         WriteByte(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
  32         WriteByte(MSG_ENTITY, sf);
  33
  34         if(sf & 2)
  35                 WriteByte(MSG_ENTITY, to.spectatee_status);
  36
  37         if(sf & 8)
  38         {
  39                 WriteAngle(MSG_ENTITY, e.v_angle_x);
  40                 WriteAngle(MSG_ENTITY, e.v_angle_y);
  41         }
  42
  43         return TRUE;
  44 }
  45
  46 void ClientData_Attach()
  47 {
  48         Net_LinkEntity(self.clientdata = spawn(), FALSE, 0, ClientData_Send);
  49         self.clientdata.drawonlytoclient = self;
  50         self.clientdata.owner = self;
  51 }
  52
  53 void ClientData_Detach()
  54 {
  55         remove(self.clientdata);
  56         self.clientdata = world;
  57 }
  58
  59 void ClientData_Touch(entity e)
  60 {
  61         e.clientdata.SendFlags = 1;
  62
  63         // make it spectatable
  64         entity e2;
  65         FOR_EACH_REALCLIENT(e2)
  66         {
  67                 if(e2 != e)
  68                         if(IS_SPEC(e2))
  69                                 if(e2.enemy == e)
  70                                         e2.clientdata.SendFlags = 1;
  71         }
  72 }
  73
  74 .string netname_previous;
  75
  76
  77 /*
  78 =============
  79 CheckPlayerModel
  80
  81 Checks if the argument string can be a valid playermodel.
  82 Returns a valid one in doubt.
  83 =============
  84 */
  85 string FallbackPlayerModel;
  86 string CheckPlayerModel(string plyermodel) {
  87         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
  88         {
  89                 // note: we cannot summon Don Strunzone here, some player may
  90                 // still have the model string set. In case anyone manages how
  91                 // to change a cvar default, we'll have a small leak here.
  92                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
  93         }
  94         // only in right path
  95         if( substring(plyermodel,0,14) != "models/player/")
  96                 return FallbackPlayerModel;
  97         // only good file extensions
  98         if(substring(plyermodel,-4,4) != ".zym")
  99         if(substring(plyermodel,-4,4) != ".dpm")
 100         if(substring(plyermodel,-4,4) != ".iqm")
 101         if(substring(plyermodel,-4,4) != ".md3")
 102         if(substring(plyermodel,-4,4) != ".psk")
 103                 return FallbackPlayerModel;
 104         // forbid the LOD models
 105         if(substring(plyermodel, -9,5) == "_lod1")
 106                 return FallbackPlayerModel;
 107         if(substring(plyermodel, -9,5) == "_lod2")
 108                 return FallbackPlayerModel;
 109         if(plyermodel != strtolower(plyermodel))
 110                 return FallbackPlayerModel;
 111         // also, restrict to server models
 112         if(autocvar_sv_servermodelsonly)
 113         {
 114                 if(!fexists(plyermodel))
 115                         return FallbackPlayerModel;
 116         }
 117         return plyermodel;
 118 }
 119
 120 void setplayermodel(entity e, string modelname)
 121 {
 122         precache_model(modelname);
 123         setmodel(e, modelname);
 124         player_setupanimsformodel();
 125         UpdatePlayerSounds();
 126 }
 127
 128 /*
 129 =============
 130 PutObserverInServer
 131
 132 putting a client as observer in the server
 133 =============
 134 */
 135 void FixPlayermodel();
 136 void PutObserverInServer (void)
 137 {
 138         entity  spot;
 139     self.hud = HUD_NORMAL;
 140
 141         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
 142
 143         spot = SelectSpawnPoint (TRUE);
 144         if(!spot)
 145                 error("No spawnpoints for observers?!?\n");
 146         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 147
 148         if(IS_REAL_CLIENT(self))
 149         {
 150                 msg_entity = self;
 151                 WriteByte(MSG_ONE, SVC_SETVIEW);
 152                 WriteEntity(MSG_ONE, self);
 153         }
 154
 155         self.frags = FRAGS_SPECTATOR;
 156
 157         MUTATOR_CALLHOOK(MakePlayerObserver);
 158
 159         Portal_ClearAll(self);
 160
 161         Unfreeze(self);
 162
 163         if(self.alivetime)
 164         {
 165                 if(!warmup_stage)
 166                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 167                 self.alivetime = 0;
 168         }
 169
 170         if(self.vehicle)
 171                 vehicles_exit(VHEF_RELESE);
 172
 173         WaypointSprite_PlayerDead();
 174
 175         if (!g_ca)  // don't reset teams when moving a ca player to the spectators
 176                 self.team = -1;  // move this as it is needed to log the player spectating in eventlog
 177
 178         if(self.killcount != -666)
 179         {
 180                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_SPECTATE, self.netname);
 181                 if(autocvar_g_chat_nospectators == 1 || (cvar("g_warmup") && !(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 182                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 183
 184                 if(self.just_joined == FALSE) {
 185                         LogTeamchange(self.playerid, -1, 4);
 186                 } else
 187                         self.just_joined = FALSE;
 188         }
 189
 190         PlayerScore_Clear(self); // clear scores when needed
 191
 192         accuracy_resend(self);
 193
 194         self.spectatortime = time;
 195
 196         self.classname = "observer";
 197         self.iscreature = FALSE;
 198         self.teleportable = TELEPORT_SIMPLE;
 199         self.damagedbycontents = FALSE;
 200         self.health = -666;
 201         self.takedamage = DAMAGE_NO;
 202         self.solid = SOLID_NOT;
 203         self.movetype = MOVETYPE_FLY_WORLDONLY; // user preference is controlled by playerprethink
 204         self.flags = FL_CLIENT | FL_NOTARGET;
 205         self.armorvalue = 666;
 206         self.effects = 0;
 207         self.armorvalue = autocvar_g_balance_armor_start;
 208         self.pauserotarmor_finished = 0;
 209         self.pauserothealth_finished = 0;
 210         self.pauseregen_finished = 0;
 211         self.damageforcescale = 0;
 212         self.death_time = 0;
 213         self.respawn_flags = 0;
 214         self.respawn_time = 0;
 215         self.stat_respawn_time = 0;
 216         self.alpha = 0;
 217         self.scale = 0;
 218         self.fade_time = 0;
 219         self.pain_frame = 0;
 220         self.pain_finished = 0;
 221         self.strength_finished = 0;
 222         self.invincible_finished = 0;
 223         self.superweapons_finished = 0;
 224         self.pushltime = 0;
 225         self.istypefrag = 0;
 226         self.think = func_null;
 227         self.nextthink = 0;
 228         self.hook_time = 0;
 229         self.deadflag = DEAD_NO;
 230         self.angles = spot.angles;
 231         self.angles_z = 0;
 232         self.fixangle = TRUE;
 233         self.crouch = FALSE;
 234         self.revival_time = 0;
 235
 236         setorigin (self, (spot.origin + PL_VIEW_OFS)); // offset it so that the spectator spawns higher off the ground, looks better this way
 237         self.prevorigin = self.origin;
 238         self.items = 0;
 239         self.weapons = '0 0 0';
 240         self.model = "";
 241         FixPlayermodel();
 242         setmodel(self, "null");
 243         self.drawonlytoclient = self;
 244
 245         setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX); // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         self.view_ofs = '0 0 0'; // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247
 248         self.weapon = 0;
 249         self.weaponname = "";
 250         self.switchingweapon = 0;
 251         self.weaponmodel = "";
 252         self.weaponentity = world;
 253         self.exteriorweaponentity = world;
 254         self.killcount = -666;
 255         self.velocity = '0 0 0';
 256         self.avelocity = '0 0 0';
 257         self.punchangle = '0 0 0';
 258         self.punchvector = '0 0 0';
 259         self.oldvelocity = self.velocity;
 260         self.fire_endtime = -1;
 261         self.event_damage = func_null;
 262 }
 263
 264 .float model_randomizer;
 265 void FixPlayermodel()
 266 {
 267         string defaultmodel;
 268         float defaultskin, chmdl, oldskin, n, i;
 269         vector m1, m2;
 270
 271         defaultmodel = "";
 272         defaultskin = 0;
 273         chmdl = FALSE;
 274
 275         if(autocvar_sv_defaultcharacter == 1)
 276         {
 277                 if(teamplay)
 278                 {
 279                         string s;
 280                         s = Static_Team_ColorName_Lower(self.team);
 281                         if(s != "neutral")
 282                         {
 283                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 284                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 285                         }
 286                 }
 287
 288                 if(defaultmodel == "")
 289                 {
 290                         defaultmodel = autocvar_sv_defaultplayermodel;
 291                         defaultskin = autocvar_sv_defaultplayerskin;
 292                 }
 293
 294                 n = tokenize_console(defaultmodel);
 295                 if(n > 0)
 296                 {
 297                         defaultmodel = argv(floor(n * self.model_randomizer));
 298                         // However, do NOT randomize if the player-selected model is in the list.
 299                         for (i = 0; i < n; ++i)
 300                                 if ((argv(i) == self.playermodel && defaultskin == stof(self.playerskin)) || argv(i) == strcat(self.playermodel, ":", self.playerskin))
 301                                         defaultmodel = argv(i);
 302                 }
 303
 304                 i = strstrofs(defaultmodel, ":", 0);
 305                 if(i >= 0)
 306                 {
 307                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 308                         defaultmodel = substring(defaultmodel, 0, i);
 309                 }
 310         }
 311
 312         if(defaultmodel != "")
 313         {
 314                 if (defaultmodel != self.model)
 315                 {
 316                         m1 = self.mins;
 317                         m2 = self.maxs;
 318                         setplayermodel (self, defaultmodel);
 319                         setsize (self, m1, m2);
 320                         chmdl = TRUE;
 321                 }
 322
 323                 oldskin = self.skin;
 324                 self.skin = defaultskin;
 325         } else {
 326                 if (self.playermodel != self.model || self.playermodel == "")
 327                 {
 328                         self.playermodel = CheckPlayerModel(self.playermodel); // this is never "", so no endless loop
 329                         m1 = self.mins;
 330                         m2 = self.maxs;
 331                         setplayermodel (self, self.playermodel);
 332                         setsize (self, m1, m2);
 333                         chmdl = TRUE;
 334                 }
 335
 336                 oldskin = self.skin;
 337                 self.skin = stof(self.playerskin);
 338         }
 339
 340         if(chmdl || oldskin != self.skin) // model or skin has changed
 341         {
 342                 self.species = player_getspecies(); // update species
 343                 UpdatePlayerSounds(); // update skin sounds
 344         }
 345
 346         if(!teamplay)
 347                 if(strlen(autocvar_sv_defaultplayercolors))
 348                         if(self.clientcolors != stof(autocvar_sv_defaultplayercolors))
 349                                 setcolor(self, stof(autocvar_sv_defaultplayercolors));
 350 }
 351
 352 /*
 353 =============
 354 PutClientInServer
 355
 356 Called when a client spawns in the server
 357 =============
 358 */
 359 void PutClientInServer (void)
 360 {
 361         if(IS_BOT_CLIENT(self))
 362                 self.classname = "player";
 363         else if(IS_REAL_CLIENT(self))
 364         {
 365                 msg_entity = self;
 366                 WriteByte(MSG_ONE, SVC_SETVIEW);
 367                 WriteEntity(MSG_ONE, self);
 368         }
 369
 370         // reset player keys
 371         self.itemkeys = 0;
 372
 373         MUTATOR_CALLHOOK(PutClientInServer);
 374
 375         if(gameover)
 376                 self.classname = "observer";
 377
 378         if(IS_PLAYER(self))
 379         {
 380                 entity spot, oldself;
 381                 float j;
 382
 383                 accuracy_resend(self);
 384
 385                 if(self.team < 0)
 386                         JoinBestTeam(self, FALSE, TRUE);
 387
 388                 spot = SelectSpawnPoint (FALSE);
 389                 if(!spot)
 390                 {
 391                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 392                         return; // spawn failed
 393                 }
 394
 395                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 396
 397                 if(self.vehicle)
 398                         vehicles_exit(VHEF_RELESE);
 399
 400                 self.classname = "player";
 401                 self.wasplayer = TRUE;
 402                 self.iscreature = TRUE;
 403                 self.teleportable = TELEPORT_NORMAL;
 404                 self.damagedbycontents = TRUE;
 405                 self.movetype = MOVETYPE_WALK;
 406                 self.solid = SOLID_SLIDEBOX;
 407                 self.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 408                 if(autocvar_g_playerclip_collisions)
 409                         self.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 410                 if(IS_BOT_CLIENT(self) && autocvar_g_botclip_collisions)
 411                         self.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 412                 self.frags = FRAGS_PLAYER;
 413                 if(INDEPENDENT_PLAYERS)
 414                         MAKE_INDEPENDENT_PLAYER(self);
 415                 self.flags = FL_CLIENT;
 416                 if(autocvar__notarget)
 417                         self.flags |= FL_NOTARGET;
 418                 self.takedamage = DAMAGE_AIM;
 419                 self.effects = 0;
 420                 self.effects |= EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 421                 self.air_finished = time + 12;
 422                 self.dmg = 2;
 423                 if(autocvar_g_balance_nex_charge)
 424                 {
 425                         if(autocvar_g_balance_nex_secondary_chargepool)
 426                                 self.nex_chargepool_ammo = 1;
 427                         self.nex_charge = autocvar_g_balance_nex_charge_start;
 428                 }
 429
 430                 if(warmup_stage)
 431                 {
 432                         self.ammo_shells = warmup_start_ammo_shells;
 433                         self.ammo_nails = warmup_start_ammo_nails;
 434                         self.ammo_rockets = warmup_start_ammo_rockets;
 435                         self.ammo_cells = warmup_start_ammo_cells;
 436                         self.ammo_fuel = warmup_start_ammo_fuel;
 437                         self.health = warmup_start_health;
 438                         self.armorvalue = warmup_start_armorvalue;
 439                         self.weapons = WARMUP_START_WEAPONS;
 440                 }
 441                 else
 442                 {
 443                         self.ammo_shells = start_ammo_shells;
 444                         self.ammo_nails = start_ammo_nails;
 445                         self.ammo_rockets = start_ammo_rockets;
 446                         self.ammo_cells = start_ammo_cells;
 447                         self.ammo_fuel = start_ammo_fuel;
 448                         self.health = start_health;
 449                         self.armorvalue = start_armorvalue;
 450                         self.weapons = start_weapons;
 451                 }
 452
 453                 if(self.weapons & WEPSET_SUPERWEAPONS)
 454                         self.superweapons_finished = time + autocvar_g_balance_superweapons_time;
 455                 else
 456                         self.superweapons_finished = 0;
 457
 458                 if(g_weaponarena_random)
 459                 {
 460                         if(g_weaponarena_random_with_laser)
 461                                 self.weapons &= ~WEPSET_LASER;
 462                         W_RandomWeapons(self, g_weaponarena_random);
 463                         if(g_weaponarena_random_with_laser)
 464                                 self.weapons |= WEPSET_LASER;
 465                 }
 466
 467                 self.items = start_items;
 468
 469                 self.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 470                 self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 471                 self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 472                 self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 473                 self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 474                 //extend the pause of rotting if client was reset at the beginning of the countdown
 475                 if(!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 476                         self.spawnshieldtime += game_starttime - time;
 477                         self.pauserotarmor_finished += game_starttime - time;
 478                         self.pauserothealth_finished += game_starttime - time;
 479                         self.pauseregen_finished += game_starttime - time;
 480                 }
 481                 self.damageforcescale = 2;
 482                 self.death_time = 0;
 483                 self.respawn_flags = 0;
 484                 self.respawn_time = 0;
 485                 self.stat_respawn_time = 0;
 486                 self.scale = 0;
 487                 self.fade_time = 0;
 488                 self.pain_frame = 0;
 489                 self.pain_finished = 0;
 490                 self.strength_finished = 0;
 491                 self.invincible_finished = 0;
 492                 self.pushltime = 0;
 493                 // players have no think function
 494                 self.think = func_null;
 495                 self.nextthink = 0;
 496                 self.hook_time = 0;
 497                 self.dmg_team = 0;
 498                 self.ballistics_density = autocvar_g_ballistics_density_player;
 499
 500                 self.metertime = 0;
 501
 502                 self.deadflag = DEAD_NO;
 503
 504                 self.angles = spot.angles;
 505
 506                 self.angles_z = 0; // never spawn tilted even if the spot says to
 507                 if(IS_BOT_CLIENT(self))
 508                         self.v_angle = self.angles;
 509                 self.fixangle = TRUE; // turn this way immediately
 510                 self.velocity = '0 0 0';
 511                 self.avelocity = '0 0 0';
 512                 self.punchangle = '0 0 0';
 513                 self.punchvector = '0 0 0';
 514                 self.oldvelocity = self.velocity;
 515                 self.fire_endtime = -1;
 516                 self.revival_time = 0;
 517
 518                 entity spawnevent = spawn();
 519                 spawnevent.owner = self;
 520                 Net_LinkEntity(spawnevent, FALSE, 0.5, SpawnEvent_Send);
 521
 522                 // Cut off any still running player sounds.
 523                 stopsound(self, CH_PLAYER_SINGLE);
 524
 525                 self.model = "";
 526                 FixPlayermodel();
 527                 self.drawonlytoclient = world;
 528
 529                 self.crouch = FALSE;
 530                 self.view_ofs = PL_VIEW_OFS;
 531                 setsize (self, PL_MIN, PL_MAX);
 532                 self.spawnorigin = spot.origin;
 533                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 534                 // don't reset back to last position, even if new position is stuck in solid
 535                 self.oldorigin = self.origin;
 536                 self.prevorigin = self.origin;
 537                 self.lastrocket = world; // stop rocket guiding, no revenge from the grave!
 538                 self.lastteleporttime = time; // prevent insane speeds due to changing origin
 539         self.hud = HUD_NORMAL;
 540
 541                 self.event_damage = PlayerDamage;
 542
 543                 self.bot_attack = TRUE;
 544                 self.monster_attack = TRUE;
 545
 546                 self.spider_slowness = 0;
 547
 548                 self.statdraintime = time + 5;
 549                 self.BUTTON_ATCK = self.BUTTON_JUMP = self.BUTTON_ATCK2 = 0;
 550
 551                 if(self.killcount == -666) {
 552                         PlayerScore_Clear(self);
 553                         self.killcount = 0;
 554                 }
 555
 556                 CL_SpawnWeaponentity();
 557                 self.alpha = default_player_alpha;
 558                 self.colormod = '1 1 1' * autocvar_g_player_brightness;
 559                 self.exteriorweaponentity.alpha = default_weapon_alpha;
 560
 561                 self.speedrunning = FALSE;
 562
 563                 //stuffcmd(self, "chase_active 0");
 564                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 565
 566                 target_voicescript_clear(self);
 567
 568                 // reset fields the weapons may use
 569                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 570                 {
 571                         weapon_action(j, WR_RESETPLAYER);
 572
 573                         // all weapons must be fully loaded when we spawn
 574                         entity e;
 575                         e = get_weaponinfo(j);
 576                         if(e.spawnflags & WEP_FLAG_RELOADABLE) // prevent accessing undefined cvars
 577                                 self.(weapon_load[j]) = cvar(strcat("g_balance_", e.netname, "_reload_ammo"));
 578                 }
 579
 580                 oldself = self;
 581                 self = spot;
 582                         activator = oldself;
 583                                 string s;
 584                                 s = self.target;
 585                                 self.target = string_null;
 586                                 SUB_UseTargets();
 587                                 self.target = s;
 588                         activator = world;
 589                 self = oldself;
 590
 591                 Unfreeze(self);
 592
 593                 spawn_spot = spot;
 594                 MUTATOR_CALLHOOK(PlayerSpawn);
 595
 596                 if(autocvar_spawn_debug)
 597                 {
 598                         sprint(self, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 599                         remove(spot);   // usefull for checking if there are spawnpoints, that let drop through the floor
 600                 }
 601
 602                 self.switchweapon = w_getbestweapon(self);
 603                 self.cnt = -1; // W_LastWeapon will not complain
 604                 self.weapon = 0;
 605                 self.weaponname = "";
 606                 self.switchingweapon = 0;
 607
 608                 if(!warmup_stage)
 609                         if(!self.alivetime)
 610                                 self.alivetime = time;
 611
 612                 antilag_clear(self);
 613         }
 614         else if(IS_OBSERVER(self))
 615         {
 616                 PutObserverInServer ();
 617         }
 618 }
 619
 620 .float ebouncefactor, ebouncestop; // electro's values
 621 // TODO do we need all these fields, or should we stop autodetecting runtime
 622 // changes and just have a console command to update this?
 623 float ClientInit_SendEntity(entity to, float sf)
 624 {
 625         WriteByte(MSG_ENTITY, ENT_CLIENT_INIT);
 626         WriteByte(MSG_ENTITY, g_nexball_meter_period * 32);
 627         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[0]));
 628         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[1]));
 629         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[2]));
 630         WriteInt24_t(MSG_ENTITY, compressShotOrigin(hook_shotorigin[3]));
 631         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[0]));
 632         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[1]));
 633         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[2]));
 634         WriteInt24_t(MSG_ENTITY, compressShotOrigin(electro_shotorigin[3]));
 635         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[0]));
 636         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[1]));
 637         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[2]));
 638         WriteInt24_t(MSG_ENTITY, compressShotOrigin(gauntlet_shotorigin[3]));
 639         if(sv_foginterval && world.fog != "")
 640                 WriteString(MSG_ENTITY, world.fog);
 641         else
 642                 WriteString(MSG_ENTITY, "");
 643         WriteByte(MSG_ENTITY, self.count * 255.0); // g_balance_armor_blockpercent
 644         WriteCoord(MSG_ENTITY, self.bouncefactor); // g_balance_grenadelauncher_bouncefactor
 645         WriteCoord(MSG_ENTITY, self.bouncestop); // g_balance_grenadelauncher_bouncestop
 646         WriteCoord(MSG_ENTITY, self.ebouncefactor); // g_balance_grenadelauncher_bouncefactor
 647         WriteCoord(MSG_ENTITY, self.ebouncestop); // g_balance_grenadelauncher_bouncestop
 648         WriteByte(MSG_ENTITY, autocvar_g_balance_nex_secondary); // client has to know if it should zoom or not
 649         WriteByte(MSG_ENTITY, autocvar_g_balance_rifle_secondary); // client has to know if it should zoom or not
 650         WriteByte(MSG_ENTITY, serverflags); // client has to know if it should zoom or not
 651         WriteByte(MSG_ENTITY, autocvar_g_balance_minelayer_limit); // minelayer max mines
 652         WriteByte(MSG_ENTITY, autocvar_g_balance_hagar_secondary_load_max); // hagar max loadable rockets
 653         WriteCoord(MSG_ENTITY, autocvar_g_trueaim_minrange);
 654         WriteByte(MSG_ENTITY, autocvar_g_balance_porto_secondary);
 655         return TRUE;
 656 }
 657
 658 void ClientInit_CheckUpdate()
 659 {
 660         self.nextthink = time;
 661         if(self.count != autocvar_g_balance_armor_blockpercent)
 662         {
 663                 self.count = autocvar_g_balance_armor_blockpercent;
 664                 self.SendFlags |= 1;
 665         }
 666         if(self.bouncefactor != autocvar_g_balance_grenadelauncher_bouncefactor)
 667         {
 668                 self.bouncefactor = autocvar_g_balance_grenadelauncher_bouncefactor;
 669                 self.SendFlags |= 1;
 670         }
 671         if(self.bouncestop != autocvar_g_balance_grenadelauncher_bouncestop)
 672         {
 673                 self.bouncestop = autocvar_g_balance_grenadelauncher_bouncestop;
 674                 self.SendFlags |= 1;
 675         }
 676         if(self.ebouncefactor != autocvar_g_balance_electro_secondary_bouncefactor)
 677         {
 678                 self.ebouncefactor = autocvar_g_balance_electro_secondary_bouncefactor;
 679                 self.SendFlags |= 1;
 680         }
 681         if(self.ebouncestop != autocvar_g_balance_electro_secondary_bouncestop)
 682         {
 683                 self.ebouncestop = autocvar_g_balance_electro_secondary_bouncestop;
 684                 self.SendFlags |= 1;
 685         }
 686 }
 687
 688 void ClientInit_Spawn()
 689 {
 690         entity o;
 691         entity e;
 692         e = spawn();
 693         e.classname = "clientinit";
 694         e.think = ClientInit_CheckUpdate;
 695         Net_LinkEntity(e, FALSE, 0, ClientInit_SendEntity);
 696
 697         o = self;
 698         self = e;
 699         ClientInit_CheckUpdate();
 700         self = o;
 701 }
 702
 703 /*
 704 =============
 705 SetNewParms
 706 =============
 707 */
 708 void SetNewParms (void)
 709 {
 710         // initialize parms for a new player
 711         parm1 = -(86400 * 366);
 712 }
 713
 714 /*
 715 =============
 716 SetChangeParms
 717 =============
 718 */
 719 void SetChangeParms (void)
 720 {
 721         // save parms for level change
 722         parm1 = self.parm_idlesince - time;
 723 }
 724
 725 /*
 726 =============
 727 DecodeLevelParms
 728 =============
 729 */
 730 void DecodeLevelParms (void)
 731 {
 732         // load parms
 733         self.parm_idlesince = parm1;
 734         if(self.parm_idlesince == -(86400 * 366))
 735                 self.parm_idlesince = time;
 736
 737         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 738         self.parm_idlesince = max(self.parm_idlesince, time - sv_maxidle + 60);
 739 }
 740
 741 /*
 742 =============
 743 ClientKill
 744
 745 Called when a client types 'kill' in the console
 746 =============
 747 */
 748
 749 .float clientkill_nexttime;
 750 void ClientKill_Now_TeamChange()
 751 {
 752         if(self.killindicator_teamchange == -1)
 753         {
 754                 JoinBestTeam( self, FALSE, TRUE );
 755         }
 756         else if(self.killindicator_teamchange == -2)
 757         {
 758                 if(blockSpectators)
 759                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 760                 PutObserverInServer();
 761         }
 762         else
 763                 SV_ChangeTeam(self.killindicator_teamchange - 1);
 764         self.killindicator_teamchange = 0;
 765 }
 766
 767 void ClientKill_Now()
 768 {
 769         if(self.vehicle)
 770         {
 771             vehicles_exit(VHEF_RELESE);
 772             if(!self.killindicator_teamchange)
 773             {
 774             self.vehicle_health = -1;
 775             Damage(self, self, self, 1 , DEATH_KILL, self.origin, '0 0 0');
 776             }
 777         }
 778
 779         if(self.killindicator && !wasfreed(self.killindicator))
 780                 remove(self.killindicator);
 781
 782         self.killindicator = world;
 783
 784         if(self.killindicator_teamchange)
 785                 ClientKill_Now_TeamChange();
 786
 787         if(IS_PLAYER(self))
 788                 Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 789
 790         // now I am sure the player IS dead
 791 }
 792 void KillIndicator_Think()
 793 {
 794         if (gameover)
 795         {
 796                 self.owner.killindicator = world;
 797                 remove(self);
 798                 return;
 799         }
 800
 801         if (self.owner.alpha < 0 && !self.owner.vehicle)
 802         {
 803                 self.owner.killindicator = world;
 804                 remove(self);
 805                 return;
 806         }
 807
 808         if(self.cnt <= 0)
 809         {
 810                 self = self.owner;
 811                 ClientKill_Now(); // no oldself needed
 812                 return;
 813         }
 814     else if(g_cts && self.health == 1) // health == 1 means that it's silent
 815     {
 816         self.nextthink = time + 1;
 817         self.cnt -= 1;
 818     }
 819         else
 820         {
 821                 if(self.cnt <= 10)
 822                         setmodel(self, strcat("models/sprites/", ftos(self.cnt), ".spr32"));
 823                 if(IS_REAL_CLIENT(self.owner))
 824                 {
 825                         if(self.cnt <= 10)
 826                                 { Send_Notification(NOTIF_ONE, self.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, self.cnt)); }
 827                 }
 828                 self.nextthink = time + 1;
 829                 self.cnt -= 1;
 830         }
 831 }
 832
 833 float clientkilltime;
 834 void ClientKill_TeamChange (float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 835 {
 836         float killtime;
 837         float starttime;
 838         entity e;
 839
 840         if (gameover)
 841                 return;
 842
 843         killtime = autocvar_g_balance_kill_delay;
 844
 845         if(g_race_qualifying || g_cts)
 846                 killtime = 0;
 847
 848     if(g_cts && self.killindicator && self.killindicator.health == 1) // self.killindicator.health == 1 means that the kill indicator was spawned by CTS_ClientKill
 849     {
 850                 remove(self.killindicator);
 851                 self.killindicator = world;
 852
 853         ClientKill_Now(); // allow instant kill in this case
 854         return;
 855     }
 856
 857         self.killindicator_teamchange = targetteam;
 858
 859     if(!self.killindicator)
 860         {
 861                 if(self.deadflag == DEAD_NO)
 862                 {
 863                         killtime = max(killtime, self.clientkill_nexttime - time);
 864                         self.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 865                 }
 866
 867                 if(killtime <= 0 || !IS_PLAYER(self) || self.deadflag != DEAD_NO)
 868                 {
 869                         ClientKill_Now();
 870                 }
 871                 else
 872                 {
 873                         starttime = max(time, clientkilltime);
 874
 875                         self.killindicator = spawn();
 876                         self.killindicator.owner = self;
 877                         self.killindicator.scale = 0.5;
 878                         setattachment(self.killindicator, self, "");
 879                         setorigin(self.killindicator, '0 0 52');
 880                         self.killindicator.think = KillIndicator_Think;
 881                         self.killindicator.nextthink = starttime + (self.lip) * 0.05;
 882                         clientkilltime = max(clientkilltime, self.killindicator.nextthink + 0.05);
 883                         self.killindicator.cnt = ceil(killtime);
 884                         self.killindicator.count = bound(0, ceil(killtime), 10);
 885                         //sprint(self, strcat("^1You'll be dead in ", ftos(self.killindicator.cnt), " seconds\n"));
 886
 887                         for(e = world; (e = find(e, classname, "body")) != world; )
 888                         {
 889                                 if(e.enemy != self)
 890                                         continue;
 891                                 e.killindicator = spawn();
 892                                 e.killindicator.owner = e;
 893                                 e.killindicator.scale = 0.5;
 894                                 setattachment(e.killindicator, e, "");
 895                                 setorigin(e.killindicator, '0 0 52');
 896                                 e.killindicator.think = KillIndicator_Think;
 897                                 e.killindicator.nextthink = starttime + (e.lip) * 0.05;
 898                                 clientkilltime = max(clientkilltime, e.killindicator.nextthink + 0.05);
 899                                 e.killindicator.cnt = ceil(killtime);
 900                         }
 901                         self.lip = 0;
 902                 }
 903         }
 904         if(self.killindicator)
 905         {
 906                 if(targetteam == 0) // just die
 907                 {
 908                         self.killindicator.colormod = '0 0 0';
 909                         if(IS_REAL_CLIENT(self))
 910                         if(self.killindicator.cnt > 0)
 911                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, self.killindicator.cnt);
 912                 }
 913                 else if(targetteam == -1) // auto
 914                 {
 915                         self.killindicator.colormod = '0 1 0';
 916                         if(IS_REAL_CLIENT(self))
 917                         if(self.killindicator.cnt > 0)
 918                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, self.killindicator.cnt);
 919                 }
 920                 else if(targetteam == -2) // spectate
 921                 {
 922                         self.killindicator.colormod = '0.5 0.5 0.5';
 923                         if(IS_REAL_CLIENT(self))
 924                         if(self.killindicator.cnt > 0)
 925                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, self.killindicator.cnt);
 926                 }
 927                 else
 928                 {
 929                         self.killindicator.colormod = Team_ColorRGB(targetteam);
 930                         if(IS_REAL_CLIENT(self))
 931                         if(self.killindicator.cnt > 0)
 932                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, APP_TEAM_NUM_4(targetteam, CENTER_TEAMCHANGE_), self.killindicator.cnt);
 933                 }
 934         }
 935
 936 }
 937
 938 void ClientKill (void)
 939 {
 940         if(gameover) return;
 941         if(self.player_blocked) return;
 942         if(self.frozen) return;
 943
 944         ClientKill_TeamChange(0);
 945 }
 946
 947 void CTS_ClientKill (entity e) // silent version of ClientKill, used when player finishes a CTS run. Useful to prevent cheating by running back to the start line and starting out with more speed
 948 {
 949     e.killindicator = spawn();
 950     e.killindicator.owner = e;
 951     e.killindicator.think = KillIndicator_Think;
 952     e.killindicator.nextthink = time + (e.lip) * 0.05;
 953     e.killindicator.cnt = ceil(autocvar_g_cts_finish_kill_delay);
 954     e.killindicator.health = 1; // this is used to indicate that it should be silent
 955     e.lip = 0;
 956 }
 957
 958 void FixClientCvars(entity e)
 959 {
 960         // send prediction settings to the client
 961         stuffcmd(e, "\nin_bindmap 0 0\n");
 962         if(g_race || g_cts)
 963                 stuffcmd(e, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 964         if(autocvar_g_antilag == 3) // client side hitscan
 965                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 966         if(autocvar_sv_gentle)
 967                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 968         /*
 969          * we no longer need to stuff this. Remove this comment block if you feel
 970          * 2.3 and higher (or was it 2.2.3?) don't need these any more
 971         stuffcmd(e, strcat("cl_gravity ", ftos(autocvar_sv_gravity), "\n"));
 972         stuffcmd(e, strcat("cl_movement_accelerate ", ftos(autocvar_sv_accelerate), "\n"));
 973         stuffcmd(e, strcat("cl_movement_friction ", ftos(autocvar_sv_friction), "\n"));
 974         stuffcmd(e, strcat("cl_movement_maxspeed ", ftos(autocvar_sv_maxspeed), "\n"));
 975         stuffcmd(e, strcat("cl_movement_airaccelerate ", ftos(autocvar_sv_airaccelerate), "\n"));
 976         stuffcmd(e, strcat("cl_movement_maxairspeed ", ftos(autocvar_sv_maxairspeed), "\n"));
 977         stuffcmd(e, strcat("cl_movement_stopspeed ", ftos(autocvar_sv_stopspeed), "\n"));
 978         stuffcmd(e, strcat("cl_movement_jumpvelocity ", ftos(autocvar_sv_jumpvelocity), "\n"));
 979         stuffcmd(e, strcat("cl_movement_stepheight ", ftos(autocvar_sv_stepheight), "\n"));
 980         stuffcmd(e, strcat("set cl_movement_friction_on_land ", ftos(autocvar_sv_friction_on_land), "\n"));
 981         stuffcmd(e, strcat("set cl_movement_airaccel_qw ", ftos(autocvar_sv_airaccel_qw), "\n"));
 982         stuffcmd(e, strcat("set cl_movement_airaccel_sideways_friction ", ftos(autocvar_sv_airaccel_sideways_friction), "\n"));
 983         stuffcmd(e, "cl_movement_edgefriction 1\n");
 984          */
 985 }
 986
 987 float PlayerInIDList(entity p, string idlist)
 988 {
 989         float n, i;
 990         string s;
 991
 992         // NOTE: we do NOT check crypto_keyfp here, an unsigned ID is fine too for this
 993         if (!p.crypto_idfp)
 994                 return 0;
 995
 996         // this function allows abbreviated player IDs too!
 997         n = tokenize_console(idlist);
 998         for(i = 0; i < n; ++i)
 999         {
1000                 s = argv(i);
1001                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1002                         return 1;
1003         }
1004
1005         return 0;
1006 }
1007
1008 /*
1009 =============
1010 ClientConnect
1011
1012 Called when a client connects to the server
1013 =============
1014 */
1015 void DecodeLevelParms (void);
1016 //void dom_player_join_team(entity pl);
1017 void set_dom_state(entity e);
1018 void ClientConnect (void)
1019 {
1020         float t;
1021
1022         if(IS_CLIENT(self))
1023         {
1024                 print("Warning: ClientConnect, but already connected!\n");
1025                 return;
1026         }
1027
1028         if(Ban_MaybeEnforceBanOnce(self))
1029                 return;
1030
1031         DecodeLevelParms();
1032
1033 #ifdef WATERMARK
1034         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_WATERMARK, WATERMARK);
1035 #endif
1036
1037         self.classname = "player_joining";
1038
1039         self.flags = FL_CLIENT;
1040         self.version_nagtime = time + 10 + random() * 10;
1041
1042         if(player_count<0)
1043         {
1044                 dprint("BUG player count is lower than zero, this cannot happen!\n");
1045                 player_count = 0;
1046         }
1047
1048         PlayerScore_Attach(self);
1049         ClientData_Attach();
1050         accuracy_init(self);
1051
1052         bot_clientconnect();
1053
1054         playerdemo_init();
1055
1056         anticheat_init();
1057
1058         // identify the right forced team
1059         if(autocvar_g_campaign)
1060         {
1061                 if(IS_REAL_CLIENT(self)) // only players, not bots
1062                 {
1063                         switch(autocvar_g_campaign_forceteam)
1064                         {
1065                                 case 1: self.team_forced = NUM_TEAM_1; break;
1066                                 case 2: self.team_forced = NUM_TEAM_2; break;
1067                                 case 3: self.team_forced = NUM_TEAM_3; break;
1068                                 case 4: self.team_forced = NUM_TEAM_4; break;
1069                                 default: self.team_forced = 0;
1070                         }
1071                 }
1072         }
1073         else if(PlayerInIDList(self, autocvar_g_forced_team_red))
1074                 self.team_forced = NUM_TEAM_1;
1075         else if(PlayerInIDList(self, autocvar_g_forced_team_blue))
1076                 self.team_forced = NUM_TEAM_2;
1077         else if(PlayerInIDList(self, autocvar_g_forced_team_yellow))
1078                 self.team_forced = NUM_TEAM_3;
1079         else if(PlayerInIDList(self, autocvar_g_forced_team_pink))
1080                 self.team_forced = NUM_TEAM_4;
1081         else if(autocvar_g_forced_team_otherwise == "red")
1082                 self.team_forced = NUM_TEAM_1;
1083         else if(autocvar_g_forced_team_otherwise == "blue")
1084                 self.team_forced = NUM_TEAM_2;
1085         else if(autocvar_g_forced_team_otherwise == "yellow")
1086                 self.team_forced = NUM_TEAM_3;
1087         else if(autocvar_g_forced_team_otherwise == "pink")
1088                 self.team_forced = NUM_TEAM_4;
1089         else if(autocvar_g_forced_team_otherwise == "spectate")
1090                 self.team_forced = -1;
1091         else if(autocvar_g_forced_team_otherwise == "spectator")
1092                 self.team_forced = -1;
1093         else
1094                 self.team_forced = 0;
1095
1096         if(!teamplay)
1097                 if(self.team_forced > 0)
1098                         self.team_forced = 0;
1099
1100         JoinBestTeam(self, FALSE, FALSE); // if the team number is valid, keep it
1101
1102         if((autocvar_sv_spectate == 1) || autocvar_g_campaign || self.team_forced < 0) {
1103                 self.classname = "observer";
1104         } else {
1105                 if(teamplay)
1106                 {
1107                         if(autocvar_g_balance_teams)
1108                         {
1109                                 self.classname = "player";
1110                                 campaign_bots_may_start = 1;
1111                         }
1112                         else
1113                         {
1114                                 self.classname = "observer"; // do it anyway
1115                         }
1116                 }
1117                 else
1118                 {
1119                         self.classname = "player";
1120                         campaign_bots_may_start = 1;
1121                 }
1122         }
1123
1124         self.playerid = (playerid_last = playerid_last + 1);
1125
1126         PlayerStats_AddEvent(sprintf("kills-%d", self.playerid));
1127
1128     if(IS_BOT_CLIENT(self))
1129         PlayerStats_AddPlayer(self);
1130
1131         if(autocvar_sv_eventlog)
1132                 GameLogEcho(strcat(":join:", ftos(self.playerid), ":", ftos(num_for_edict(self)), ":", ((IS_REAL_CLIENT(self)) ? self.netaddress : "bot"), ":", self.netname));
1133
1134         LogTeamchange(self.playerid, self.team, 1);
1135
1136         self.just_joined = TRUE;  // stop spamming the eventlog with additional lines when the client connects
1137
1138         self.netname_previous = strzone(self.netname);
1139
1140         if(IS_PLAYER(self) && teamplay)
1141                 Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_ENT_4(self, INFO_JOIN_CONNECT_TEAM_), self.netname);
1142         else
1143                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_CONNECT, self.netname);
1144
1145         stuffcmd(self, strcat(clientstuff, "\n"));
1146         stuffcmd(self, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1147
1148         FixClientCvars(self);
1149
1150         // spawnfunc_waypoint sprites
1151         WaypointSprite_InitClient(self);
1152
1153         // Wazat's grappling hook
1154         SetGrappleHookBindings();
1155
1156         // get version info from player
1157         stuffcmd(self, "cmd clientversion $gameversion\n");
1158
1159         // get other cvars from player
1160         GetCvars(0);
1161
1162         // notify about available teams
1163         if(teamplay)
1164         {
1165                 CheckAllowedTeams(self);
1166                 t = 0; if(c1 >= 0) t |= 1; if(c2 >= 0) t |= 2; if(c3 >= 0) t |= 4; if(c4 >= 0) t |= 8;
1167                 stuffcmd(self, strcat("set _teams_available ", ftos(t), "\n"));
1168         }
1169         else
1170                 stuffcmd(self, "set _teams_available 0\n");
1171
1172         attach_entcs();
1173
1174         bot_relinkplayerlist();
1175
1176         self.spectatortime = time;
1177         if(blockSpectators)
1178         {
1179                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1180         }
1181
1182         self.jointime = time;
1183         self.allowed_timeouts = autocvar_sv_timeout_number;
1184
1185         if(IS_REAL_CLIENT(self))
1186         {
1187                 if(!autocvar_g_campaign)
1188                 {
1189                         self.motd_actived_time = -1;
1190                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
1191                 }
1192
1193                 if(autocvar_g_bugrigs || (g_weaponarena_weapons == WEPSET_TUBA))
1194                         stuffcmd(self, "cl_cmd settemp chase_active 1\n");
1195         }
1196
1197         if(!sv_foginterval && world.fog != "")
1198                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1199
1200         if(autocvar_g_hitplots || strstrofs(strcat(" ", autocvar_g_hitplots_individuals, " "), strcat(" ", self.netaddress, " "), 0) >= 0)
1201         {
1202                 self.hitplotfh = fopen(strcat("hits-", matchid, "-", self.netaddress, "-", ftos(self.playerid), ".plot"), FILE_WRITE);
1203                 fputs(self.hitplotfh, strcat("#name ", self.netname, "\n"));
1204         }
1205         else
1206                 self.hitplotfh = -1;
1207
1208         if(autocvar_sv_teamnagger && !(autocvar_bot_vs_human && (c3==-1 && c4==-1)) && !g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1209                 send_CSQC_teamnagger();
1210
1211         CheatInitClient();
1212
1213         CSQCMODEL_AUTOINIT();
1214
1215         self.model_randomizer = random();
1216
1217         if(IS_REAL_CLIENT(self))
1218                 sv_notice_join();
1219
1220         MUTATOR_CALLHOOK(ClientConnect);
1221 }
1222 /*
1223 =============
1224 ClientDisconnect
1225
1226 Called when a client disconnects from the server
1227 =============
1228 */
1229 .entity chatbubbleentity;
1230 void ReadyCount();
1231 void ClientDisconnect (void)
1232 {
1233         if(self.vehicle)
1234             vehicles_exit(VHEF_RELESE);
1235
1236         if (!IS_CLIENT(self))
1237         {
1238                 print("Warning: ClientDisconnect without ClientConnect\n");
1239                 return;
1240         }
1241
1242         if(IS_PLAYER(self)) { pointparticles(particleeffectnum("spawn_event_neutral"), self.origin, '0 0 0', 1); }
1243
1244         PlayerStats_AddGlobalInfo(self);
1245
1246         CheatShutdownClient();
1247
1248         if(self.hitplotfh >= 0)
1249         {
1250                 fclose(self.hitplotfh);
1251                 self.hitplotfh = -1;
1252         }
1253
1254         anticheat_report();
1255         anticheat_shutdown();
1256
1257         playerdemo_shutdown();
1258
1259         bot_clientdisconnect();
1260
1261         if(self.entcs)
1262                 detach_entcs();
1263
1264         if(autocvar_sv_eventlog)
1265                 GameLogEcho(strcat(":part:", ftos(self.playerid)));
1266
1267         Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_DISCONNECT, self.netname);
1268
1269         MUTATOR_CALLHOOK(ClientDisconnect);
1270
1271         Portal_ClearAll(self);
1272
1273         Unfreeze(self);
1274
1275         RemoveGrapplingHook(self);
1276
1277         // Here, everything has been done that requires this player to be a client.
1278
1279         self.flags &= ~FL_CLIENT;
1280
1281         if (self.chatbubbleentity)
1282                 remove (self.chatbubbleentity);
1283
1284         if (self.killindicator)
1285                 remove (self.killindicator);
1286
1287         WaypointSprite_PlayerGone();
1288
1289         bot_relinkplayerlist();
1290
1291         accuracy_free(self);
1292         ClientData_Detach();
1293         PlayerScore_Detach(self);
1294
1295         if(self.netname_previous)
1296                 strunzone(self.netname_previous);
1297         if(self.clientstatus)
1298                 strunzone(self.clientstatus);
1299         if(self.weaponorder_byimpulse)
1300                 strunzone(self.weaponorder_byimpulse);
1301
1302         ClearPlayerSounds();
1303
1304         if(self.personal)
1305                 remove(self.personal);
1306
1307         self.playerid = 0;
1308         ReadyCount();
1309
1310         // free cvars
1311         GetCvars(-1);
1312 }
1313
1314 .float BUTTON_CHAT;
1315 void ChatBubbleThink()
1316 {
1317         self.nextthink = time;
1318         if ((self.owner.alpha < 0) || self.owner.chatbubbleentity != self)
1319         {
1320                 if(self.owner) // but why can that ever be world?
1321                         self.owner.chatbubbleentity = world;
1322                 remove(self);
1323                 return;
1324         }
1325         if ((self.owner.BUTTON_CHAT && !self.owner.deadflag)
1326 #ifdef TETRIS
1327                 || self.owner.tetris_on
1328 #endif
1329         )
1330                 self.model = self.mdl;
1331         else
1332                 self.model = "";
1333 }
1334
1335 void UpdateChatBubble()
1336 {
1337         if (self.alpha < 0)
1338                 return;
1339         // spawn a chatbubble entity if needed
1340         if (!self.chatbubbleentity)
1341         {
1342                 self.chatbubbleentity = spawn();
1343                 self.chatbubbleentity.owner = self;
1344                 self.chatbubbleentity.exteriormodeltoclient = self;
1345                 self.chatbubbleentity.think = ChatBubbleThink;
1346                 self.chatbubbleentity.nextthink = time;
1347                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr"); // precision set below
1348                 //setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
1349                 setorigin(self.chatbubbleentity, '0 0 15' + self.maxs_z * '0 0 1');
1350                 setattachment(self.chatbubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
1351                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
1352                 self.chatbubbleentity.model = "";
1353                 self.chatbubbleentity.effects = EF_LOWPRECISION;
1354         }
1355 }
1356
1357
1358 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1359 // added to the model skins
1360 /*void UpdateColorModHack()
1361 {
1362         float c;
1363         c = self.clientcolors & 15;
1364         // LordHavoc: only bothering to support white, green, red, yellow, blue
1365              if (!teamplay) self.colormod = '0 0 0';
1366         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
1367         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
1368         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
1369         else if (c == 12) self.colormod = '1.22 1.22 0.10';
1370         else if (c == 13) self.colormod = '0.10 0.10 1.73';
1371         else self.colormod = '1 1 1';
1372 }*/
1373
1374 void respawn(void)
1375 {
1376         if(self.alpha >= 0 && autocvar_g_respawn_ghosts)
1377         {
1378                 self.solid = SOLID_NOT;
1379                 self.takedamage = DAMAGE_NO;
1380                 self.movetype = MOVETYPE_FLY;
1381                 self.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1382                 self.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1383                 self.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1384                 pointparticles(particleeffectnum("respawn_ghost"), self.origin, '0 0 0', 1);
1385                 if(autocvar_g_respawn_ghosts_maxtime)
1386                         SUB_SetFade (self, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1387         }
1388
1389         CopyBody(1);
1390
1391         self.effects |= EF_NODRAW; // prevent another CopyBody
1392         PutClientInServer();
1393 }
1394
1395 void play_countdown(float finished, string samp)
1396 {
1397         if(IS_REAL_CLIENT(self))
1398                 if(floor(finished - time - frametime) != floor(finished - time))
1399                         if(finished - time < 6)
1400                                 sound (self, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1401 }
1402
1403 void player_powerups (void)
1404 {
1405         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1406         olditems = self.items;
1407
1408         if((self.items & IT_USING_JETPACK) && !self.deadflag && !gameover)
1409                 self.modelflags |= MF_ROCKET;
1410         else
1411                 self.modelflags &= ~MF_ROCKET;
1412
1413         self.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1414
1415         if((self.alpha < 0 || self.deadflag) && !self.vehicle) // don't apply the flags if the player is gibbed
1416                 return;
1417
1418         Fire_ApplyDamage(self);
1419         Fire_ApplyEffect(self);
1420
1421         if (!g_instagib)
1422         {
1423                 if (self.items & IT_STRENGTH)
1424                 {
1425                         play_countdown(self.strength_finished, "misc/poweroff.wav");
1426                         self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1427                         if (time > self.strength_finished)
1428                         {
1429                                 self.items = self.items - (self.items & IT_STRENGTH);
1430                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_STRENGTH, self.netname);
1431                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1432                         }
1433                 }
1434                 else
1435                 {
1436                         if (time < self.strength_finished)
1437                         {
1438                                 self.items = self.items | IT_STRENGTH;
1439                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_STRENGTH, self.netname);
1440                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1441                         }
1442                 }
1443                 if (self.items & IT_INVINCIBLE)
1444                 {
1445                         play_countdown(self.invincible_finished, "misc/poweroff.wav");
1446                         self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1447                         if (time > self.invincible_finished)
1448                         {
1449                                 self.items = self.items - (self.items & IT_INVINCIBLE);
1450                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERDOWN_SHIELD, self.netname);
1451                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1452                         }
1453                 }
1454                 else
1455                 {
1456                         if (time < self.invincible_finished)
1457                         {
1458                                 self.items = self.items | IT_INVINCIBLE;
1459                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_POWERUP_SHIELD, self.netname);
1460                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_POWERUP_SHIELD);
1461                         }
1462                 }
1463                 if (self.items & IT_SUPERWEAPON)
1464                 {
1465                         if (!(self.weapons & WEPSET_SUPERWEAPONS))
1466                         {
1467                                 self.superweapons_finished = 0;
1468                                 self.items = self.items - (self.items & IT_SUPERWEAPON);
1469                                 //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_LOST, self.netname);
1470                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1471                         }
1472                         else if (self.items & IT_UNLIMITED_SUPERWEAPONS)
1473                         {
1474                                 // don't let them run out
1475                         }
1476                         else
1477                         {
1478                                 play_countdown(self.superweapons_finished, "misc/poweroff.wav");
1479                                 if (time > self.superweapons_finished)
1480                                 {
1481                                         self.items = self.items - (self.items & IT_SUPERWEAPON);
1482                                         self.weapons &= ~WEPSET_SUPERWEAPONS;
1483                                         //Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_BROKEN, self.netname);
1484                                         Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1485                                 }
1486                         }
1487                 }
1488                 else if(self.weapons & WEPSET_SUPERWEAPONS)
1489                 {
1490                         if (time < self.superweapons_finished || (self.items & IT_UNLIMITED_SUPERWEAPONS))
1491                         {
1492                                 self.items = self.items | IT_SUPERWEAPON;
1493                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_SUPERWEAPON_PICKUP, self.netname);
1494                                 Send_Notification(NOTIF_ONE, self, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1495                         }
1496                         else
1497                         {
1498                                 self.superweapons_finished = 0;
1499                                 self.weapons &= ~WEPSET_SUPERWEAPONS;
1500                         }
1501                 }
1502                 else
1503                 {
1504                         self.superweapons_finished = 0;
1505                 }
1506         }
1507
1508         if(autocvar_g_nodepthtestplayers)
1509                 self.effects = self.effects | EF_NODEPTHTEST;
1510
1511         if(autocvar_g_fullbrightplayers)
1512                 self.effects = self.effects | EF_FULLBRIGHT;
1513
1514         if (time >= game_starttime)
1515         if (time < self.spawnshieldtime)
1516                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1517
1518         MUTATOR_CALLHOOK(PlayerPowerups);
1519 }
1520
1521 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1522 {
1523         if(current > stable)
1524                 return current;
1525         else if(current > stable - 0.25) // when close enough, "snap"
1526                 return stable;
1527         else
1528                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1529 }
1530
1531 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1532 {
1533         if(current < stable)
1534                 return current;
1535         else if(current < stable + 0.25) // when close enough, "snap"
1536                 return stable;
1537         else
1538                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1539 }
1540
1541 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1542 {
1543         if(current > rotstable)
1544         {
1545                 if(rotframetime > 0)
1546                 {
1547                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1548                         current = max(rotstable, current - rotlinear * rotframetime);
1549                 }
1550         }
1551         else if(current < regenstable)
1552         {
1553                 if(regenframetime > 0)
1554                 {
1555                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1556                         current = min(regenstable, current + regenlinear * regenframetime);
1557                 }
1558         }
1559
1560         if(current > limit)
1561                 current = limit;
1562
1563         return current;
1564 }
1565
1566 void player_regen (void)
1567 {
1568         float max_mod, regen_mod, rot_mod, limit_mod;
1569         max_mod = regen_mod = rot_mod = limit_mod = 1;
1570         regen_mod_max = max_mod;
1571         regen_mod_regen = regen_mod;
1572         regen_mod_rot = rot_mod;
1573         regen_mod_limit = limit_mod;
1574         if(!MUTATOR_CALLHOOK(PlayerRegen))
1575         if(!self.frozen)
1576         {
1577                 float minh, mina, maxh, maxa, limith, limita;
1578                 maxh = autocvar_g_balance_health_rotstable;
1579                 maxa = autocvar_g_balance_armor_rotstable;
1580                 minh = autocvar_g_balance_health_regenstable;
1581                 mina = autocvar_g_balance_armor_regenstable;
1582                 limith = autocvar_g_balance_health_limit;
1583                 limita = autocvar_g_balance_armor_limit;
1584
1585                 max_mod = regen_mod_max;
1586                 regen_mod = regen_mod_regen;
1587                 rot_mod = regen_mod_rot;
1588                 limit_mod = regen_mod_limit;
1589
1590                 maxh = maxh * max_mod;
1591                 minh = minh * max_mod;
1592                 limith = limith * limit_mod;
1593                 limita = limita * limit_mod;
1594
1595                 self.armorvalue = CalcRotRegen(self.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > self.pauserotarmor_finished), limita);
1596                 self.health = CalcRotRegen(self.health, minh, autocvar_g_balance_health_regen, autocvar_g_balance_health_regenlinear, regen_mod * frametime * (time > self.pauseregen_finished), maxh, autocvar_g_balance_health_rot, autocvar_g_balance_health_rotlinear, rot_mod * frametime * (time > self.pauserothealth_finished), limith);
1597         }
1598
1599         // if player rotted to death...  die!
1600         // check this outside above checks, as player may still be able to rot to death
1601         if(self.health < 1)
1602                 self.event_damage(self, self, 1, DEATH_ROT, self.origin, '0 0 0');
1603
1604         if (!(self.items & IT_UNLIMITED_WEAPON_AMMO))
1605         {
1606                 float minf, maxf, limitf;
1607
1608                 maxf = autocvar_g_balance_fuel_rotstable;
1609                 minf = autocvar_g_balance_fuel_regenstable;
1610                 limitf = autocvar_g_balance_fuel_limit;
1611
1612                 self.ammo_fuel = CalcRotRegen(self.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > self.pauseregen_finished) * ((self.items & IT_FUEL_REGEN) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > self.pauserotfuel_finished), limitf);
1613         }
1614 }
1615
1616 float zoomstate_set;
1617 void SetZoomState(float z)
1618 {
1619         if(z != self.zoomstate)
1620         {
1621                 self.zoomstate = z;
1622                 ClientData_Touch(self);
1623         }
1624         zoomstate_set = 1;
1625 }
1626
1627 void GetPressedKeys(void) {
1628         MUTATOR_CALLHOOK(GetPressedKeys);
1629         if (self.movement_x > 0) // get if movement keys are pressed
1630         {       // forward key pressed
1631                 self.pressedkeys |= KEY_FORWARD;
1632                 self.pressedkeys &= ~KEY_BACKWARD;
1633         }
1634         else if (self.movement_x < 0)
1635         {       // backward key pressed
1636                 self.pressedkeys |= KEY_BACKWARD;
1637                 self.pressedkeys &= ~KEY_FORWARD;
1638         }
1639         else
1640         {       // no x input
1641                 self.pressedkeys &= ~KEY_FORWARD;
1642                 self.pressedkeys &= ~KEY_BACKWARD;
1643         }
1644
1645         if (self.movement_y > 0)
1646         {       // right key pressed
1647                 self.pressedkeys |= KEY_RIGHT;
1648                 self.pressedkeys &= ~KEY_LEFT;
1649         }
1650         else if (self.movement_y < 0)
1651         {       // left key pressed
1652                 self.pressedkeys |= KEY_LEFT;
1653                 self.pressedkeys &= ~KEY_RIGHT;
1654         }
1655         else
1656         {       // no y input
1657                 self.pressedkeys &= ~KEY_RIGHT;
1658                 self.pressedkeys &= ~KEY_LEFT;
1659         }
1660
1661         if (self.BUTTON_JUMP) // get if jump and crouch keys are pressed
1662                 self.pressedkeys |= KEY_JUMP;
1663         else
1664                 self.pressedkeys &= ~KEY_JUMP;
1665         if (self.BUTTON_CROUCH)
1666                 self.pressedkeys |= KEY_CROUCH;
1667         else
1668                 self.pressedkeys &= ~KEY_CROUCH;
1669
1670         if (self.BUTTON_ATCK)
1671                 self.pressedkeys |= KEY_ATCK;
1672         else
1673                 self.pressedkeys &= ~KEY_ATCK;
1674         if (self.BUTTON_ATCK2)
1675                 self.pressedkeys |= KEY_ATCK2;
1676         else
1677                 self.pressedkeys &= ~KEY_ATCK2;
1678 }
1679
1680 /*
1681 ======================
1682 spectate mode routines
1683 ======================
1684 */
1685
1686 void SpectateCopy(entity spectatee) {
1687         other = spectatee;
1688         MUTATOR_CALLHOOK(SpectateCopy);
1689         self.armortype = spectatee.armortype;
1690         self.armorvalue = spectatee.armorvalue;
1691         self.ammo_cells = spectatee.ammo_cells;
1692         self.ammo_shells = spectatee.ammo_shells;
1693         self.ammo_nails = spectatee.ammo_nails;
1694         self.ammo_rockets = spectatee.ammo_rockets;
1695         self.ammo_fuel = spectatee.ammo_fuel;
1696         self.clip_load = spectatee.clip_load;
1697         self.clip_size = spectatee.clip_size;
1698         self.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1699         self.health = spectatee.health;
1700         self.impulse = 0;
1701         self.items = spectatee.items;
1702         self.last_pickup = spectatee.last_pickup;
1703         self.hit_time = spectatee.hit_time;
1704         self.metertime = spectatee.metertime;
1705         self.strength_finished = spectatee.strength_finished;
1706         self.invincible_finished = spectatee.invincible_finished;
1707         self.pressedkeys = spectatee.pressedkeys;
1708         self.weapons = spectatee.weapons;
1709         self.switchweapon = spectatee.switchweapon;
1710         self.switchingweapon = spectatee.switchingweapon;
1711         self.weapon = spectatee.weapon;
1712         self.nex_charge = spectatee.nex_charge;
1713         self.nex_chargepool_ammo = spectatee.nex_chargepool_ammo;
1714         self.hagar_load = spectatee.hagar_load;
1715         self.minelayer_mines = spectatee.minelayer_mines;
1716         self.punchangle = spectatee.punchangle;
1717         self.view_ofs = spectatee.view_ofs;
1718         self.velocity = spectatee.velocity;
1719         self.dmg_take = spectatee.dmg_take;
1720         self.dmg_save = spectatee.dmg_save;
1721         self.dmg_inflictor = spectatee.dmg_inflictor;
1722         self.v_angle = spectatee.v_angle;
1723         self.angles = spectatee.v_angle;
1724         self.frozen = spectatee.frozen;
1725         self.revive_progress = spectatee.revive_progress;
1726         if(!self.BUTTON_USE)
1727                 self.fixangle = TRUE;
1728         setorigin(self, spectatee.origin);
1729         setsize(self, spectatee.mins, spectatee.maxs);
1730         SetZoomState(spectatee.zoomstate);
1731
1732     anticheat_spectatecopy(spectatee);
1733         self.hud = spectatee.hud;
1734         if(spectatee.vehicle)
1735     {
1736         self.fixangle = FALSE;
1737         //self.velocity = spectatee.vehicle.velocity;
1738         self.vehicle_health = spectatee.vehicle_health;
1739         self.vehicle_shield = spectatee.vehicle_shield;
1740         self.vehicle_energy = spectatee.vehicle_energy;
1741         self.vehicle_ammo1 = spectatee.vehicle_ammo1;
1742         self.vehicle_ammo2 = spectatee.vehicle_ammo2;
1743         self.vehicle_reload1 = spectatee.vehicle_reload1;
1744         self.vehicle_reload2 = spectatee.vehicle_reload2;
1745
1746         msg_entity = self;
1747
1748         WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1749             WriteAngle(MSG_ONE,  spectatee.v_angle_x);
1750             WriteAngle(MSG_ONE,  spectatee.v_angle_y);
1751             WriteAngle(MSG_ONE,  spectatee.v_angle_z);
1752
1753         //WriteByte (MSG_ONE, SVC_SETVIEW);
1754         //    WriteEntity(MSG_ONE, self);
1755         //makevectors(spectatee.v_angle);
1756         //setorigin(self, spectatee.origin - v_forward * 400 + v_up * 300);*/
1757     }
1758 }
1759
1760 float SpectateUpdate() {
1761         if(!self.enemy)
1762             return 0;
1763
1764         if (self == self.enemy)
1765                 return 0;
1766
1767         if (!IS_PLAYER(self.enemy))
1768                 return 0;
1769
1770         SpectateCopy(self.enemy);
1771
1772         return 1;
1773 }
1774
1775
1776 float SpectateSet()
1777 {
1778         if(self.enemy.classname != "player")
1779                 return FALSE;
1780         /*if(self.enemy.vehicle)
1781         {
1782
1783                 msg_entity = self;
1784                 WriteByte(MSG_ONE, SVC_SETVIEW);
1785                 WriteEntity(MSG_ONE, self.enemy);
1786                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1787
1788                 self.movetype = MOVETYPE_NONE;
1789                 accuracy_resend(self);
1790         }
1791         else
1792         {*/
1793                 msg_entity = self;
1794                 WriteByte(MSG_ONE, SVC_SETVIEW);
1795                 WriteEntity(MSG_ONE, self.enemy);
1796                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1797                 self.movetype = MOVETYPE_NONE;
1798                 accuracy_resend(self);
1799
1800                 if(!SpectateUpdate())
1801                         PutObserverInServer();
1802         //}
1803         return TRUE;
1804 }
1805
1806 float Spectate(entity pl)
1807 {
1808         if(g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1809         if(pl.team != self.team)
1810                 return 0;
1811
1812         self.enemy = pl;
1813         return SpectateSet();
1814 }
1815
1816 // Returns next available player to spectate if g_ca_spectate_enemies == 0
1817 entity CA_SpectateNext(entity start) {
1818         if (start.team == self.team) {
1819                 return start;
1820         }
1821
1822         other = start;
1823         // continue from current player
1824         while(other && other.team != self.team) {
1825                 other = find(other, classname, "player");
1826         }
1827
1828         if (!other) {
1829                 // restart from begining
1830                 other = find(other, classname, "player");
1831                 while(other && other.team != self.team) {
1832                         other = find(other, classname, "player");
1833                 }
1834         }
1835
1836         return other;
1837 }
1838
1839 float SpectateNext()
1840 {
1841         other = find(self.enemy, classname, "player");
1842
1843         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer) {
1844                 // CA and ca players when spectating enemies is forbidden
1845                 other = CA_SpectateNext(other);
1846         } else {
1847                 // other modes and ca spectators or spectating enemies is allowed
1848                 if (!other)
1849                         other = find(other, classname, "player");
1850         }
1851
1852         if (other)
1853                 self.enemy = other;
1854
1855         return SpectateSet();
1856 }
1857
1858 float SpectatePrev()
1859 {
1860         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1861         other = findchain(classname, "player");
1862         if (!other) // no player
1863                 return FALSE;
1864
1865         entity first = other;
1866         // skip players until current spectated player
1867         if(self.enemy)
1868         while(other && other != self.enemy)
1869                 other = other.chain;
1870
1871         if (g_ca && !autocvar_g_ca_spectate_enemies && self.caplayer)
1872         {
1873                 do { other = other.chain; }
1874                 while(other && other.team != self.team);
1875
1876                 if (!other)
1877                 {
1878                         other = first;
1879                         while(other.team != self.team)
1880                                 other = other.chain;
1881                         if(other == self.enemy)
1882                                 return TRUE;
1883                 }
1884         }
1885         else
1886         {
1887                 if(other.chain)
1888                         other = other.chain;
1889                 else
1890                         other = first;
1891         }
1892         self.enemy = other;
1893         return SpectateSet();
1894 }
1895
1896 /*
1897 =============
1898 ShowRespawnCountdown()
1899
1900 Update a respawn countdown display.
1901 =============
1902 */
1903 void ShowRespawnCountdown()
1904 {
1905         float number;
1906         if(self.deadflag == DEAD_NO) // just respawned?
1907                 return;
1908         else
1909         {
1910                 number = ceil(self.respawn_time - time);
1911                 if(number <= 0)
1912                         return;
1913                 if(number <= self.respawn_countdown)
1914                 {
1915                         self.respawn_countdown = number - 1;
1916                         if(ceil(self.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1917                                 { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1918                 }
1919         }
1920 }
1921
1922 void LeaveSpectatorMode()
1923 {
1924         if(self.caplayer)
1925                 return;
1926         if(nJoinAllowed(self))
1927         {
1928                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (self.wasplayer && autocvar_g_changeteam_banned) || self.team_forced > 0)
1929                 {
1930                         self.classname = "player";
1931                         nades_RemoveBonus(self);
1932
1933                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1934                                 { JoinBestTeam(self, FALSE, TRUE); }
1935
1936                         if(autocvar_g_campaign)
1937                                 { campaign_bots_may_start = 1; }
1938
1939                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_PREVENT_JOIN);
1940
1941                         PutClientInServer();
1942
1943                         if(IS_PLAYER(self)) { Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_JOIN_PLAY, self.netname); }
1944                 }
1945                 else
1946                         stuffcmd(self, "menu_showteamselect\n");
1947         }
1948         else
1949         {
1950                 // Player may not join because g_maxplayers is set
1951                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_JOIN_PREVENT);
1952         }
1953 }
1954
1955 /**
1956  * Determines whether the player is allowed to join. This depends on cvar
1957  * g_maxplayers, if it isn't used this function always return TRUE, otherwise
1958  * it checks whether the number of currently playing players exceeds g_maxplayers.
1959  * @return int number of free slots for players, 0 if none
1960  */
1961 float nJoinAllowed(entity ignore) {
1962         if(!ignore)
1963         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1964         // so report 0 free slots if restricted
1965         {
1966                 if(autocvar_g_forced_team_otherwise == "spectate")
1967                         return 0;
1968                 if(autocvar_g_forced_team_otherwise == "spectator")
1969                         return 0;
1970         }
1971
1972         if(self.team_forced < 0)
1973                 return 0; // forced spectators can never join
1974
1975         // TODO simplify this
1976         entity e;
1977         float totalClients = 0;
1978         FOR_EACH_CLIENT(e)
1979                 if(e != ignore)
1980                         totalClients += 1;
1981
1982         if (!autocvar_g_maxplayers)
1983                 return maxclients - totalClients;
1984
1985         float currentlyPlaying = 0;
1986         FOR_EACH_REALCLIENT(e)
1987                 if(IS_PLAYER(e) || e.caplayer)
1988                         currentlyPlaying += 1;
1989
1990         if(currentlyPlaying < autocvar_g_maxplayers)
1991                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1992
1993         return 0;
1994 }
1995
1996 /**
1997  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1998  * g_maxplayers_spectator_blocktime seconds
1999  */
2000 void checkSpectatorBlock() {
2001         if(IS_SPEC(self) || IS_OBSERVER(self))
2002         if(!self.caplayer)
2003         if(IS_REAL_CLIENT(self))
2004         {
2005                 if( time > (self.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2006                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2007                         dropclient(self);
2008                 }
2009         }
2010 }
2011
2012 void PrintWelcomeMessage()
2013 {
2014         if(self.motd_actived_time == 0)
2015         {
2016                 if (autocvar_g_campaign) {
2017                         if ((IS_PLAYER(self) && self.BUTTON_INFO) || (!IS_PLAYER(self))) {
2018                                 self.motd_actived_time = time;
2019                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, campaign_message);
2020                         }
2021                 } else {
2022                         if (self.BUTTON_INFO) {
2023                                 self.motd_actived_time = time;
2024                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_MOTD, getwelcomemessage());
2025                         }
2026                 }
2027         }
2028         else if(self.motd_actived_time > 0) // showing MOTD or campaign message
2029         {
2030                 if (autocvar_g_campaign) {
2031                         if (self.BUTTON_INFO)
2032                                 self.motd_actived_time = time;
2033                         else if ((time - self.motd_actived_time > 2) && IS_PLAYER(self)) { // hide it some seconds after BUTTON_INFO has been released
2034                                 self.motd_actived_time = 0;
2035                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2036                         }
2037                 } else {
2038                         if (self.BUTTON_INFO)
2039                                 self.motd_actived_time = time;
2040                         else if (time - self.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2041                                 self.motd_actived_time = 0;
2042                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2043                         }
2044                 }
2045         }
2046         else //if(self.motd_actived_time < 0) // just connected, motd is active
2047         {
2048                 if(self.BUTTON_INFO) // BUTTON_INFO hides initial MOTD
2049                         self.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2050                 else if(self.motd_actived_time == -2 || IS_PLAYER(self))
2051                 {
2052                         // instanctly hide MOTD
2053                         self.motd_actived_time = 0;
2054                         Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_MOTD);
2055                 }
2056         }
2057 }
2058
2059 void ObserverThink()
2060 {
2061         float prefered_movetype;
2062         if (self.flags & FL_JUMPRELEASED) {
2063                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2064                         self.flags &= ~FL_JUMPRELEASED;
2065                         self.flags |= FL_SPAWNING;
2066                 } else if(self.BUTTON_ATCK && !self.version_mismatch) {
2067                         self.flags &= ~FL_JUMPRELEASED;
2068                         if(SpectateNext()) {
2069                                 self.classname = "spectator";
2070                         }
2071                 } else {
2072                         prefered_movetype = ((!self.BUTTON_USE ? self.cvar_cl_clippedspectating : !self.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2073                         if (self.movetype != prefered_movetype)
2074                                 self.movetype = prefered_movetype;
2075                 }
2076         } else {
2077                 if (!(self.BUTTON_ATCK || self.BUTTON_JUMP)) {
2078                         self.flags |= FL_JUMPRELEASED;
2079                         if(self.flags & FL_SPAWNING)
2080                         {
2081                                 self.flags &= ~FL_SPAWNING;
2082                                 LeaveSpectatorMode();
2083                                 return;
2084                         }
2085                 }
2086         }
2087 }
2088
2089 void SpectatorThink()
2090 {
2091         if (self.flags & FL_JUMPRELEASED) {
2092                 if (self.BUTTON_JUMP && !self.version_mismatch) {
2093                         self.flags &= ~FL_JUMPRELEASED;
2094                         self.flags |= FL_SPAWNING;
2095                 } else if(self.BUTTON_ATCK || self.impulse == 10 || self.impulse == 15 || self.impulse == 18 || (self.impulse >= 200 && self.impulse <= 209)) {
2096                         self.flags &= ~FL_JUMPRELEASED;
2097                         if(SpectateNext()) {
2098                                 self.classname = "spectator";
2099                         } else {
2100                                 self.classname = "observer";
2101                                 PutClientInServer();
2102                         }
2103                         self.impulse = 0;
2104                 } else if(self.impulse == 12 || self.impulse == 16  || self.impulse == 19 || (self.impulse >= 220 && self.impulse <= 229)) {
2105                         self.flags &= ~FL_JUMPRELEASED;
2106                         if(SpectatePrev()) {
2107                                 self.classname = "spectator";
2108                         } else {
2109                                 self.classname = "observer";
2110                                 PutClientInServer();
2111                         }
2112                         self.impulse = 0;
2113                 } else if (self.BUTTON_ATCK2) {
2114                         self.flags &= ~FL_JUMPRELEASED;
2115                         self.classname = "observer";
2116                         PutClientInServer();
2117                 } else {
2118                         if(!SpectateUpdate())
2119                                 PutObserverInServer();
2120                 }
2121         } else {
2122                 if (!(self.BUTTON_ATCK || self.BUTTON_ATCK2)) {
2123                         self.flags |= FL_JUMPRELEASED;
2124                         if(self.flags & FL_SPAWNING)
2125                         {
2126                                 self.flags &= ~FL_SPAWNING;
2127                                 LeaveSpectatorMode();
2128                                 return;
2129                         }
2130                 }
2131                 if(!SpectateUpdate())
2132                         PutObserverInServer();
2133         }
2134
2135         self.flags |= FL_CLIENT | FL_NOTARGET;
2136 }
2137
2138 void PlayerUseKey()
2139 {
2140         if (!IS_PLAYER(self))
2141                 return;
2142
2143         if(self.vehicle)
2144         {
2145         vehicles_exit(VHEF_NORMAL);
2146         return;
2147         }
2148
2149         // a use key was pressed; call handlers
2150         MUTATOR_CALLHOOK(PlayerUseKey);
2151 }
2152
2153 /*
2154 =============
2155 PlayerPreThink
2156
2157 Called every frame for each client before the physics are run
2158 =============
2159 */
2160 .float usekeypressed;
2161 void() nexball_setstatus;
2162 .float items_added;
2163 void PlayerPreThink (void)
2164 {
2165         WarpZone_PlayerPhysics_FixVAngle();
2166
2167         self.stat_game_starttime = game_starttime;
2168         self.stat_round_starttime = round_starttime;
2169         self.stat_allow_oldnexbeam = autocvar_g_allow_oldnexbeam;
2170         self.stat_leadlimit = autocvar_leadlimit;
2171
2172         if(frametime)
2173         {
2174                 // physics frames: update anticheat stuff
2175                 anticheat_prethink();
2176         }
2177
2178         if(blockSpectators && frametime)
2179                 // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2180                 checkSpectatorBlock();
2181
2182         zoomstate_set = 0;
2183
2184         if(self.netname_previous != self.netname)
2185         {
2186                 if(autocvar_sv_eventlog)
2187                         GameLogEcho(strcat(":name:", ftos(self.playerid), ":", self.netname));
2188                 if(self.netname_previous)
2189                         strunzone(self.netname_previous);
2190                 self.netname_previous = strzone(self.netname);
2191         }
2192
2193         // version nagging
2194         if(self.version_nagtime)
2195                 if(self.cvar_g_xonoticversion)
2196                         if(time > self.version_nagtime)
2197                         {
2198                                 // don't notify git users
2199                                 if(strstr(self.cvar_g_xonoticversion, "git", 0) < 0 && strstr(self.cvar_g_xonoticversion, "autobuild", 0) < 0)
2200                                 {
2201                                         if(strstr(autocvar_g_xonoticversion, "git", 0) >= 0 || strstr(autocvar_g_xonoticversion, "autobuild", 0) >= 0)
2202                                         {
2203                                                 // notify release users if connecting to git
2204                                                 dprint("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, " (beta)^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2205                                                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2206                                         }
2207                                         else
2208                                         {
2209                                                 float r;
2210                                                 r = vercmp(self.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2211                                                 if(r < 0)
2212                                                 {
2213                                                         // give users new version
2214                                                         dprint("^1NOTE^7 to ", self.netname, "^7 - ^3Xonotic ", autocvar_g_xonoticversion, "^7 is out, and you still have ^3Xonotic ", self.cvar_g_xonoticversion, "^1 - get the update from ^4http://www.xonotic.org/^1!\n");
2215                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2216                                                 }
2217                                                 else if(r > 0)
2218                                                 {
2219                                                         // notify users about old server version
2220                                                         print("^1NOTE^7 to ", self.netname, "^7 - the server is running ^3Xonotic ", autocvar_g_xonoticversion, "^7, you have ^3Xonotic ", self.cvar_g_xonoticversion, "^1\n");
2221                                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, self.cvar_g_xonoticversion);
2222                                                 }
2223                                         }
2224                                 }
2225                                 self.version_nagtime = 0;
2226                         }
2227
2228         // GOD MODE info
2229         if(!(self.flags & FL_GODMODE)) if(self.max_armorvalue)
2230         {
2231                 Send_Notification(NOTIF_ONE_ONLY, self, MSG_INFO, INFO_GODMODE_OFF, self.max_armorvalue);
2232                 self.max_armorvalue = 0;
2233         }
2234
2235 #ifdef TETRIS
2236         if (TetrisPreFrame())
2237                 return;
2238 #endif
2239
2240         if(self.frozen == 2)
2241         {
2242                 self.revive_progress = bound(0, self.revive_progress + frametime * self.revive_speed, 1);
2243                 self.health = max(1, self.revive_progress * start_health);
2244                 self.iceblock.alpha = bound(0.2, 1 - self.revive_progress, 1);
2245
2246                 if(self.revive_progress >= 1)
2247                         Unfreeze(self);
2248         }
2249         else if(self.frozen == 3)
2250         {
2251                 self.revive_progress = bound(0, self.revive_progress - frametime * self.revive_speed, 1);
2252                 self.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * self.revive_progress );
2253
2254                 if(self.health < 1)
2255                 {
2256                         if(self.vehicle)
2257                                 vehicles_exit(VHEF_RELESE);
2258                         self.event_damage(self, self.frozen_by, 1, DEATH_NADE_ICE_FREEZE, self.origin, '0 0 0');
2259                 }
2260                 else if ( self.revive_progress <= 0 )
2261                         Unfreeze(self);
2262         }
2263
2264         MUTATOR_CALLHOOK(PlayerPreThink);
2265
2266         if(!self.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2267         {
2268                 if(self.BUTTON_USE && !self.usekeypressed)
2269                         PlayerUseKey();
2270                 self.usekeypressed = self.BUTTON_USE;
2271         }
2272
2273         if(IS_REAL_CLIENT(self))
2274                 PrintWelcomeMessage();
2275
2276         if(IS_PLAYER(self))
2277         {
2278
2279                 CheckRules_Player();
2280
2281                 if (intermission_running)
2282                 {
2283                         IntermissionThink ();   // otherwise a button could be missed between
2284                         return;                                 // the think tics
2285                 }
2286
2287                 //don't allow the player to turn around while game is paused!
2288                 if(timeout_status == TIMEOUT_ACTIVE) {
2289                         // FIXME turn this into CSQC stuff
2290                         self.v_angle = self.lastV_angle;
2291                         self.angles = self.lastV_angle;
2292                         self.fixangle = TRUE;
2293                 }
2294
2295                 if(frametime)
2296                 {
2297                         if(self.weapon == WEP_NEX && autocvar_g_balance_nex_charge)
2298                         {
2299                                 self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2300                                 self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2301                                 self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_animlimit);
2302
2303                                 if(self.nex_charge > autocvar_g_balance_nex_charge_animlimit)
2304                                 {
2305                                         self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2306                                         self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2307                                         self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_animlimit) / (1 - autocvar_g_balance_nex_charge_animlimit);
2308                                 }
2309                         }
2310                         else
2311                                 self.weaponentity_glowmod = colormapPaletteColor(self.clientcolors & 0x0F, TRUE) * 2;
2312
2313                         player_powerups();
2314                 }
2315
2316                 if (self.deadflag != DEAD_NO)
2317                 {
2318                         if(self.personal && g_race_qualifying)
2319                         {
2320                                 if(time > self.respawn_time)
2321                                 {
2322                                         self.respawn_time = time + 1; // only retry once a second
2323                                         self.stat_respawn_time = self.respawn_time;
2324                                         respawn();
2325                                         self.impulse = 141;
2326                                 }
2327                         }
2328                         else
2329                         {
2330                                 float button_pressed;
2331                                 if(frametime)
2332                                         player_anim();
2333                                 button_pressed = (self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE);
2334
2335                                 if (self.deadflag == DEAD_DYING)
2336                                 {
2337                                         if((self.respawn_flags & RESPAWN_FORCE) && !autocvar_g_respawn_delay_max)
2338                                                 self.deadflag = DEAD_RESPAWNING;
2339                                         else if(!button_pressed)
2340                                                 self.deadflag = DEAD_DEAD;
2341                                 }
2342                                 else if (self.deadflag == DEAD_DEAD)
2343                                 {
2344                                         if(button_pressed)
2345                                                 self.deadflag = DEAD_RESPAWNABLE;
2346                                         else if(time >= self.respawn_time_max && (self.respawn_flags & RESPAWN_FORCE))
2347                                                 self.deadflag = DEAD_RESPAWNING;
2348                                 }
2349                                 else if (self.deadflag == DEAD_RESPAWNABLE)
2350                                 {
2351                                         if(!button_pressed)
2352                                                 self.deadflag = DEAD_RESPAWNING;
2353                                 }
2354                                 else if (self.deadflag == DEAD_RESPAWNING)
2355                                 {
2356                                         if(time > self.respawn_time)
2357                                         {
2358                                                 self.respawn_time = time + 1; // only retry once a second
2359                                                 self.respawn_time_max = self.respawn_time;
2360                                                 respawn();
2361                                         }
2362                                 }
2363
2364                                 ShowRespawnCountdown();
2365
2366                                 if(self.respawn_flags & RESPAWN_SILENT)
2367                                         self.stat_respawn_time = 0;
2368                                 else if((self.respawn_flags & RESPAWN_FORCE) && autocvar_g_respawn_delay_max)
2369                                         self.stat_respawn_time = self.respawn_time_max;
2370                                 else
2371                                         self.stat_respawn_time = self.respawn_time;
2372                         }
2373
2374                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2375                         if(self.deadflag == DEAD_RESPAWNING && self.stat_respawn_time > 0)
2376                                 self.stat_respawn_time *= -1;
2377
2378                         return;
2379                 }
2380
2381                 self.prevorigin = self.origin;
2382
2383                 float do_crouch = self.BUTTON_CROUCH;
2384                 if(self.hook.state)
2385                         do_crouch = 0;
2386                 if(self.vehicle)
2387                         do_crouch = 0;
2388                 if(self.frozen)
2389                         do_crouch = 0;
2390                 if(self.weapon == WEP_SHOTGUN && self.weaponentity.wframe == WFRAME_FIRE2 && time < self.weapon_nextthink)
2391                         do_crouch = 0;
2392
2393                 if (do_crouch)
2394                 {
2395                         if (!self.crouch)
2396                         {
2397                                 self.crouch = TRUE;
2398                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
2399                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
2400                                 // setanim(self, self.anim_duck, FALSE, TRUE, TRUE); // this anim is BROKEN anyway
2401                         }
2402                 }
2403                 else
2404                 {
2405                         if (self.crouch)
2406                         {
2407                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
2408                                 if (!trace_startsolid)
2409                                 {
2410                                         self.crouch = FALSE;
2411                                         self.view_ofs = PL_VIEW_OFS;
2412                                         setsize (self, PL_MIN, PL_MAX);
2413                                 }
2414                         }
2415                 }
2416
2417                 FixPlayermodel();
2418
2419                 GrapplingHookFrame();
2420
2421                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2422                 //if(frametime)
2423                 {
2424                         self.items &= ~self.items_added;
2425
2426                         W_WeaponFrame();
2427
2428                         self.items_added = 0;
2429                         if(self.items & IT_JETPACK)
2430                                 if(self.items & IT_FUEL_REGEN || self.ammo_fuel >= 0.01)
2431                                         self.items_added |= IT_FUEL;
2432
2433                         self.items |= self.items_added;
2434                 }
2435
2436                 player_regen();
2437
2438                 // rot nex charge to the charge limit
2439                 if(autocvar_g_balance_nex_charge_rot_rate && self.nex_charge > autocvar_g_balance_nex_charge_limit && self.nex_charge_rottime < time)
2440                         self.nex_charge = bound(autocvar_g_balance_nex_charge_limit, self.nex_charge - autocvar_g_balance_nex_charge_rot_rate * frametime / W_TICSPERFRAME, 1);
2441
2442                 if(frametime)
2443                         player_anim();
2444
2445                 // secret status
2446                 secrets_setstatus();
2447
2448                 // monsters status
2449                 monsters_setstatus();
2450
2451                 self.dmg_team = max(0, self.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2452
2453                 //self.angles_y=self.v_angle_y + 90;   // temp
2454         } else if(gameover) {
2455                 if (intermission_running)
2456                         IntermissionThink ();   // otherwise a button could be missed between
2457                 return;
2458         } else if(IS_OBSERVER(self)) {
2459                 ObserverThink();
2460         } else if(IS_SPEC(self)) {
2461                 SpectatorThink();
2462         }
2463
2464         if(!zoomstate_set)
2465                 SetZoomState(self.BUTTON_ZOOM || self.BUTTON_ZOOMSCRIPT || (self.BUTTON_ATCK2 && self.weapon == WEP_NEX) || (self.BUTTON_ATCK2 && self.weapon == WEP_RIFLE && autocvar_g_balance_rifle_secondary == 0));
2466
2467         float oldspectatee_status;
2468         oldspectatee_status = self.spectatee_status;
2469         if(IS_SPEC(self))
2470                 self.spectatee_status = num_for_edict(self.enemy);
2471         else if(IS_OBSERVER(self))
2472                 self.spectatee_status = num_for_edict(self);
2473         else
2474                 self.spectatee_status = 0;
2475         if(self.spectatee_status != oldspectatee_status)
2476         {
2477                 ClientData_Touch(self);
2478         }
2479
2480         if(self.teamkill_soundtime)
2481         if(time > self.teamkill_soundtime)
2482         {
2483                 self.teamkill_soundtime = 0;
2484
2485                 entity oldpusher, oldself;
2486
2487                 oldself = self; self = self.teamkill_soundsource;
2488                 oldpusher = self.pusher; self.pusher = oldself;
2489
2490                 PlayerSound(playersound_teamshoot, CH_VOICE, VOICETYPE_LASTATTACKER_ONLY);
2491
2492                 self.pusher = oldpusher;
2493                 self = oldself;
2494         }
2495
2496         if(self.taunt_soundtime)
2497         if(time > self.taunt_soundtime)
2498         {
2499                 self.taunt_soundtime = 0;
2500                 PlayerSound(playersound_taunt, CH_VOICE, VOICETYPE_AUTOTAUNT);
2501         }
2502
2503         target_voicescript_next(self);
2504
2505         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2506         if(!self.weapon)
2507                 self.clip_load = self.clip_size = 0;
2508 }
2509
2510 float isInvisibleString(string s)
2511 {
2512         float i, n, c;
2513         s = strdecolorize(s);
2514         for((i = 0), (n = strlen(s)); i < n; ++i)
2515         {
2516                 c = str2chr(s, i);
2517                 switch(c)
2518                 {
2519                         case 0:
2520                         case 32: // space
2521                                 break;
2522                         case 192: // charmap space
2523                                 if (!autocvar_utf8_enable)
2524                                         break;
2525                                 return FALSE;
2526                         case 160: // space in unicode fonts
2527                         case 0xE000 + 192: // utf8 charmap space
2528                                 if (autocvar_utf8_enable)
2529                                         break;
2530                         default:
2531                                 return FALSE;
2532                 }
2533         }
2534         return TRUE;
2535 }
2536
2537 /*
2538 =============
2539 PlayerPostThink
2540
2541 Called every frame for each client after the physics are run
2542 =============
2543 */
2544 .float idlekick_lasttimeleft;
2545 void PlayerPostThink (void)
2546 {
2547         // Savage: Check for nameless players
2548         if (isInvisibleString(self.netname)) {
2549                 self.netname = "Player";
2550                 stuffcmd(self, strcat("name ", self.netname, substring(ftos(random()), 2, -1), "\n"));
2551         }
2552
2553         if(sv_maxidle > 0 && frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2554         if(IS_PLAYER(self) || sv_maxidle_spectatorsareidle)
2555         {
2556                 if (time - self.parm_idlesince < 1) // instead of (time == self.parm_idlesince) to support sv_maxidle <= 10
2557                 {
2558                         if(self.idlekick_lasttimeleft)
2559                         {
2560                                 self.idlekick_lasttimeleft = 0;
2561                                 Kill_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER_CPID, CPID_IDLING);
2562                         }
2563                 }
2564                 else
2565                 {
2566                         float timeleft;
2567                         timeleft = ceil(sv_maxidle - (time - self.parm_idlesince));
2568                         if(timeleft == min(10, sv_maxidle - 1)) // - 1 to support sv_maxidle <= 10
2569                         {
2570                                 if(!self.idlekick_lasttimeleft)
2571                                         Send_Notification(NOTIF_ONE_ONLY, self, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2572                         }
2573                         if(timeleft <= 0)
2574                         {
2575                                 Send_Notification(NOTIF_ALL, world, MSG_INFO, INFO_QUIT_KICK_IDLING, self.netname);
2576                                 dropclient(self);
2577                                 return;
2578                         }
2579                         else if(timeleft <= 10)
2580                         {
2581                                 if(timeleft != self.idlekick_lasttimeleft)
2582                                         { Send_Notification(NOTIF_ONE, self, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft)); }
2583                                 self.idlekick_lasttimeleft = timeleft;
2584                         }
2585                 }
2586         }
2587
2588 #ifdef TETRIS
2589         if(self.impulse == 100)
2590                 ImpulseCommands();
2591         if (!TetrisPostFrame())
2592         {
2593 #endif
2594
2595         CheatFrame();
2596
2597         //CheckPlayerJump();
2598
2599         if(IS_PLAYER(self)) {
2600                 CheckRules_Player();
2601                 UpdateChatBubble();
2602                 if (self.impulse)
2603                         ImpulseCommands();
2604                 if (intermission_running)
2605                         return;         // intermission or finale
2606                 GetPressedKeys();
2607         }
2608
2609 #ifdef TETRIS
2610         }
2611 #endif
2612
2613         /*
2614         float i;
2615         for(i = 0; i < 1000; ++i)
2616         {
2617                 vector end;
2618                 end = self.origin + '0 0 1024' + 512 * randomvec();
2619                 tracebox(self.origin, self.mins, self.maxs, end, MOVE_NORMAL, self);
2620                 if(trace_fraction < 1)
2621                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
2622                 {
2623                         print("I HIT SOLID: ", vtos(self.origin), " -> ", vtos(end), "\n");
2624                         break;
2625                 }
2626         }
2627         */
2628
2629         //pointparticles(particleeffectnum("machinegun_impact"), self.origin + self.view_ofs + '0 0 7', '0 0 0', 1);
2630
2631         if(self.waypointsprite_attachedforcarrier)
2632                 WaypointSprite_UpdateHealth(self.waypointsprite_attachedforcarrier, '1 0 0' * healtharmor_maxdamage(self.health, self.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
2633
2634         playerdemo_write();
2635
2636         CSQCMODEL_AUTOUPDATE();
2637 }