qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.dphitcontentsmask = oldself.dphitcontentsmask;
 170         self.death_time = oldself.death_time;
 171         self.frame = oldself.frame;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         if(self.colormap <= maxclients && self.colormap > 0)
 202                 self.colormap = 1024 + oldself.clientcolors;
 203
 204         CSQCMODEL_AUTOINIT();
 205         self.CopyBody_nextthink = oldself.nextthink;
 206         self.CopyBody_think = oldself.think;
 207         self.nextthink = time;
 208         self.think = CopyBody_Think;
 209
 210         self = oldself;
 211 }
 212
 213 float player_getspecies()
 214 {
 215         float s;
 216         get_model_parameters(self.model, self.skin);
 217         s = get_model_parameters_species;
 218         get_model_parameters(string_null, 0);
 219         if(s < 0)
 220                 return SPECIES_HUMAN;
 221         return s;
 222 }
 223
 224 void player_setupanimsformodel()
 225 {
 226         // defaults for legacy .zym models without animinfo files
 227         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 228         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 229         self.anim_draw = animfixfps(self, '2 1 3');
 230         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 231         self.anim_duckwalk = animfixfps(self, '4 1 1');
 232         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 233         self.anim_duckidle = animfixfps(self, '6 1 1');
 234         self.anim_idle = animfixfps(self, '7 1 1');
 235         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 236         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 237         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 238         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 239         self.anim_taunt = animfixfps(self, '12 1 0.33');
 240         self.anim_run = animfixfps(self, '13 1 1');
 241         self.anim_runbackwards = animfixfps(self, '14 1 1');
 242         self.anim_strafeleft = animfixfps(self, '15 1 1');
 243         self.anim_straferight = animfixfps(self, '16 1 1');
 244         //self.anim_dead1 = animfixfps(self, '17 1 1');
 245         //self.anim_dead2 = animfixfps(self, '18 1 1');
 246         self.anim_forwardright = animfixfps(self, '19 1 1');
 247         self.anim_forwardleft = animfixfps(self, '20 1 1');
 248         self.anim_backright = animfixfps(self, '21 1 1');
 249         self.anim_backleft  = animfixfps(self, '22 1 1');
 250         self.anim_melee = animfixfps(self, '23 1 1');
 251         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 252         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 253         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 254         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 255         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 256         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 257         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 258         // TODO introspect models for finding right "fps" value (1/duration)
 259         // reset animstate now
 260         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 261 }
 262
 263 void player_anim (void)
 264 {
 265         updateanim(self);
 266         if (self.weaponentity)
 267                 updateanim(self.weaponentity);
 268
 269         if (self.deadflag != DEAD_NO)
 270                 return;
 271
 272         if (!self.animstate_override)
 273         {
 274                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 275                 {
 276                         if (self.crouch)
 277                         {
 278                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 279                                 {
 280                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 281                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 282                                         {
 283                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 284                                                 self.restart_jump = FALSE;
 285                                         }
 286                                 }
 287                         }
 288                         else
 289                         {
 290                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 291                 {
 292                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 293                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 294                     {
 295                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 296                         self.restart_jump = FALSE;
 297                     }
 298                 }
 299                         }
 300                 }
 301                 else if (self.crouch)
 302                 {
 303                         if (self.movement_x > 0 && self.movement_y == 0)
 304                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x < 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x == 0 && self.movement_y > 0)
 308                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y < 0)
 310                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x > 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x < 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 319                         else
 320                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 321                 }
 322                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 323                 {
 324                         if (self.movement_x > 0 && self.movement_y == 0)
 325                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 326                         else if (self.movement_x < 0 && self.movement_y == 0)
 327                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x == 0 && self.movement_y > 0)
 329                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x == 0 && self.movement_y < 0)
 331                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x > 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x > 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x < 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x < 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 340                         else
 341                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 342                 }
 343                 else
 344                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 345         }
 346
 347         if (self.weaponentity)
 348         if (!self.weaponentity.animstate_override)
 349                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 350 }
 351
 352 void SpawnThrownWeapon (vector org, float w)
 353 {
 354         if(g_minstagib)
 355         if(self.ammo_cells <= 0)
 356                 return;
 357
 358         if(g_pinata)
 359         {
 360                 float j;
 361                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 362                 {
 363                         if(self.weapons & W_WeaponBit(j))
 364                                 if(W_IsWeaponThrowable(j))
 365                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 366                 }
 367         }
 368         else
 369         {
 370                 if(W_IsWeaponThrowable(self.weapon))
 371                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 372         }
 373 }
 374
 375 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 376 {
 377         float take, save;
 378         vector v;
 379         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 380
 381         // damage resistance (ignore most of the damage from a bullet or similar)
 382         damage = max(damage - 5, 1);
 383
 384         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 385         take = v_x;
 386         save = v_y;
 387
 388         if(sound_allowed(MSG_BROADCAST, attacker))
 389         {
 390                 if (save > 10)
 391                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 392                 else if (take > 30)
 393                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 10)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 396         }
 397
 398         if (take > 50)
 399                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 400         if (take > 100)
 401                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 402
 403         if (!(self.flags & FL_GODMODE))
 404         {
 405                 self.armorvalue = self.armorvalue - save;
 406                 self.health = self.health - take;
 407                 // pause regeneration for 5 seconds
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409         }
 410         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 411         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 412         self.dmg_inflictor = inflictor;
 413
 414         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 415         {
 416                 // don't use any animations as a gib
 417                 self.frame = 0;
 418                 // view just above the floor
 419                 self.view_ofs = '0 0 4';
 420
 421                 Violence_GibSplash(self, 1, 1, attacker);
 422                 self.alpha = -1;
 423                 self.solid = SOLID_NOT; // restore later
 424                 self.takedamage = DAMAGE_NO; // restore later
 425         }
 426 }
 427
 428 void ClientKill_Now_TeamChange();
 429 void freezetag_CheckWinner();
 430
 431 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         float take, save, waves, sdelay, dh, da, j;
 434         vector v;
 435         float valid_damage_for_weaponstats;
 436         float excess;
 437
 438         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 439                 return;
 440
 441         dh = max(self.health, 0);
 442         da = max(self.armorvalue, 0);
 443
 444         if(!DEATH_ISSPECIAL(deathtype))
 445         {
 446                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 447                 if(self != attacker)
 448                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 449         }
 450
 451         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 452         {
 453                 // tuba causes blood to come out of the ears
 454                 vector ear1, ear2;
 455                 vector d;
 456                 float f;
 457                 ear1 = self.origin;
 458                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 459                 ear2 = ear1;
 460                 makevectors(self.angles);
 461                 ear1 += v_right * -10;
 462                 ear2 += v_right * +10;
 463                 d = inflictor.origin - self.origin;
 464                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 465                 force = v_right * vlen(force);
 466                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 467                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 468                 if(f > 0)
 469                 {
 470                         hitloc = ear1;
 471                         force = force * -1;
 472                 }
 473                 else
 474                 {
 475                         hitloc = ear2;
 476                         // force is already good
 477                 }
 478         }
 479         else
 480                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 481
 482         if (!g_minstagib)
 483         {
 484                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 485                 take = v_x;
 486                 save = v_y;
 487         }
 488         else
 489         {
 490                 save = 0;
 491                 take = damage;
 492         }
 493
 494         frag_inflictor = inflictor;
 495         frag_attacker = attacker;
 496         frag_target = self;
 497         damage_take = take;
 498         damage_save = save;
 499         damage_force = force;
 500         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 501         take = bound(0, damage_take, self.health);
 502         save = bound(0, damage_save, self.armorvalue);
 503         excess = max(0, damage - take - save);
 504
 505         if(sound_allowed(MSG_BROADCAST, attacker))
 506         {
 507                 if (save > 10)
 508                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 509                 else if (take > 30)
 510                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 511                 else if (take > 10)
 512                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 513         }
 514
 515         if (take > 50)
 516                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 517         if (take > 100)
 518                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 519
 520         if (time >= self.spawnshieldtime)
 521         {
 522                 if (!(self.flags & FL_GODMODE))
 523                 {
 524                         self.armorvalue = self.armorvalue - save;
 525                         self.health = self.health - take;
 526                         // pause regeneration for 5 seconds
 527                         if(take)
 528                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 529
 530                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 531                         {
 532                                 self.pain_finished = time + 0.5;        //Supajoe
 533
 534                                 if(sv_gentle < 1) {
 535                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 536                                         {
 537                                                 if (!self.animstate_override)
 538                                                 {
 539                                                         if (random() > 0.5)
 540                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 541                                                         else
 542                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 543                                                 }
 544                                         }
 545
 546                                         if(sound_allowed(MSG_BROADCAST, attacker))
 547                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 548                                         if(self.health > 1)
 549                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 550                                         {
 551                                                 if(deathtype == DEATH_FALL)
 552                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 553                                                 else if(self.health > 75) // TODO make a "gentle" version?
 554                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else if(self.health > 50)
 556                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                                 else if(self.health > 25)
 558                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                                                 else
 560                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                                         }
 562                                 }
 563
 564                                 // throw off bot aim temporarily
 565                                 float shake;
 566                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 567                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 568                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 569                         }
 570                 }
 571                 else
 572                         self.max_armorvalue += (save + take);
 573         }
 574         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 575         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 576         self.dmg_inflictor = inflictor;
 577
 578         if(attacker == self)
 579         {
 580                 // don't reset pushltime for self damage as it may be an attempt to
 581                 // escape a lava pit or similar
 582                 //self.pushltime = 0;
 583         }
 584         else if(attacker.classname == "player")
 585         {
 586                 self.pusher = attacker;
 587                 self.pushltime = time + autocvar_g_maxpushtime;
 588         }
 589         else if(time < self.pushltime)
 590         {
 591                 attacker = self.pusher;
 592                 self.pushltime = max(self.pushltime, time + 0.6);
 593         }
 594         else
 595                 self.pushltime = 0;
 596
 597         float abot, vbot, awep;
 598         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 599         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 600
 601         valid_damage_for_weaponstats = 0;
 602         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 603         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 604         if(attacker && self != attacker)
 605         if(IsDifferentTeam(self, attacker))
 606         {
 607                 if(DEATH_ISSPECIAL(deathtype))
 608                         awep = attacker.weapon;
 609                 else
 610                         awep = DEATH_WEAPONOF(deathtype);
 611                 valid_damage_for_weaponstats = 1;
 612         }
 613
 614         if(valid_damage_for_weaponstats)
 615         {
 616                 dh = dh - max(self.health, 0);
 617                 da = da - max(self.armorvalue, 0);
 618                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 619         }
 620
 621         if (self.health < 1)
 622         {
 623                 float defer_ClientKill_Now_TeamChange;
 624                 defer_ClientKill_Now_TeamChange = FALSE;
 625
 626                 if(self.alivetime)
 627                 {
 628                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 629                         self.alivetime = 0;
 630                 }
 631
 632                 if(valid_damage_for_weaponstats)
 633                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 634
 635                 if(sv_gentle < 1) // TODO make a "gentle" version?
 636                 if(sound_allowed(MSG_BROADCAST, attacker))
 637                 {
 638                         if(deathtype == DEATH_DROWN)
 639                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 640                         else
 641                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 642                 }
 643
 644                 // get rid of kill indicator
 645                 if(self.killindicator)
 646                 {
 647                         remove(self.killindicator);
 648                         self.killindicator = world;
 649                         if(self.killindicator_teamchange)
 650                                 defer_ClientKill_Now_TeamChange = TRUE;
 651
 652                         if(self.classname == "body")
 653                         if(deathtype == DEATH_KILL)
 654                         {
 655                                 // for the lemmings fans, a small harmless explosion
 656                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 657                         }
 658                 }
 659
 660                 if(!g_freezetag)
 661                 {
 662                         // become fully visible
 663                         self.alpha = default_player_alpha;
 664                         // throw a weapon
 665                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 666                 }
 667
 668                 // print an obituary message
 669                 Obituary (attacker, inflictor, self, deathtype);
 670                 race_PreDie();
 671                 DropAllRunes(self);
 672
 673         // increment frag counter for used weapon type
 674         float w;
 675         w = DEATH_WEAPONOF(deathtype);
 676         if(WEP_VALID(w))
 677         if(accuracy_isgooddamage(attacker, self))
 678         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 679
 680                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 681                 {
 682                         PutClientInServer();
 683                         count_alive_players(); // re-count players
 684                         freezetag_CheckWinner();
 685                         return;
 686                 }
 687
 688                 frag_attacker = attacker;
 689                 frag_inflictor = inflictor;
 690                 frag_target = self;
 691                 MUTATOR_CALLHOOK(PlayerDies);
 692                 weapon_action(self.weapon, WR_PLAYERDEATH);
 693
 694                 RemoveGrapplingHook(self);
 695
 696                 if(self.flagcarried)
 697                 {
 698                         if(attacker.classname != "player")
 699                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 700                         else if(attacker.team == self.team)
 701                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 702                         else
 703                                 DropFlag(self.flagcarried, world, attacker);
 704                 }
 705                 if(self.ballcarried && g_nexball)
 706                         DropBall(self.ballcarried, self.origin, self.velocity);
 707                 Portal_ClearAllLater(self);
 708
 709                 if(clienttype(self) == CLIENTTYPE_REAL)
 710                 {
 711                         stuffcmd(self, "-zoom\n");
 712                         self.fixangle = TRUE;
 713                         //msg_entity = self;
 714                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 715                         //WriteAngle (MSG_ONE, self.v_angle_x);
 716                         //WriteAngle (MSG_ONE, self.v_angle_y);
 717                         //WriteAngle (MSG_ONE, 80);
 718                 }
 719
 720                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 721                         ClientKill_Now_TeamChange();
 722
 723                 if(g_arena)
 724                         Spawnqueue_Unmark(self);
 725
 726                 if(g_freezetag)
 727                         return;
 728
 729                 // when we get here, player actually dies
 730                 // clear waypoints (do this AFTER FreezeTag)
 731                 WaypointSprite_PlayerDead();
 732
 733                 // make the corpse upright (not tilted)
 734                 self.angles_x = 0;
 735                 self.angles_z = 0;
 736                 // don't spin
 737                 self.avelocity = '0 0 0';
 738                 // view from the floor
 739                 self.view_ofs = '0 0 -8';
 740                 // toss the corpse
 741                 self.movetype = MOVETYPE_TOSS;
 742                 // shootable corpse
 743                 self.solid = SOLID_CORPSE;
 744                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 745                 // don't stick to the floor
 746                 self.flags &~= FL_ONGROUND;
 747                 // dying animation
 748                 self.deadflag = DEAD_DYING;
 749                 // when to allow respawn
 750                 sdelay = 0;
 751                 waves = 0;
 752                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 753                 if(!sdelay)
 754                 {
 755                         if(g_cts)
 756                                 sdelay = 0; // no respawn delay in CTS
 757                         else
 758                                 sdelay = autocvar_g_respawn_delay;
 759                 }
 760                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 761                 if(!waves)
 762                         waves = autocvar_g_respawn_waves;
 763                 if(waves)
 764                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 765                 else
 766                         self.respawn_time = time + sdelay;
 767                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 768                         self.respawn_countdown = 10; // first number to count down from is 10
 769                 else
 770                         self.respawn_countdown = -1; // do not count down
 771                 self.death_time = time;
 772                 if (random() < 0.5)
 773                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 774                 else
 775                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 776                 if (self.maxs_z > 5)
 777                 {
 778                         self.maxs_z = 5;
 779                         setsize(self, self.mins, self.maxs);
 780                 }
 781                 // set damage function to corpse damage
 782                 self.event_damage = PlayerCorpseDamage;
 783                 // call the corpse damage function just in case it wants to gib
 784                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 785                 // set up to fade out later
 786                 SUB_SetFade (self, time + 6 + random (), 1);
 787
 788                 if(sv_gentle > 0 || autocvar_ekg) {
 789                         // remove corpse
 790                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 791                 }
 792
 793                 // reset fields the weapons may use just in case
 794                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 795                 {
 796                         weapon_action(j, WR_RESETPLAYER);
 797                         ATTACK_FINISHED_FOR(self, j) = 0;
 798                 }
 799         }
 800 }
 801
 802 .float muted; // to be used by prvm_edictset server playernumber muted 1
 803 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 804 // message "": do not say, just test flood control
 805 // return value:
 806 //   1 = accept
 807 //   0 = reject
 808 //  -1 = fake accept
 809 {
 810         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 811         float flood, privatemsgprefixlen;
 812         var .float flood_field;
 813         entity head;
 814         float ret;
 815
 816         if(Ban_MaybeEnforceBan(source))
 817                 return 0;
 818
 819         if(!teamsay && !privatesay)
 820                 if(substring(msgin, 0, 1) == " ")
 821                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 822
 823         msgin = formatmessage(msgin);
 824
 825         if(source.classname != "player")
 826                 colorstr = "^0"; // black for spectators
 827         else if(teamplay)
 828                 colorstr = Team_ColorCode(source.team);
 829         else
 830                 teamsay = FALSE;
 831
 832         if(intermission_running)
 833                 teamsay = FALSE;
 834
 835         if(msgin != "")
 836                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 837
 838         /*
 839          * using bprint solves this... me stupid
 840         // how can we prevent the message from appearing in a listen server?
 841         // for now, just give "say" back and only handle say_team
 842         if(!teamsay)
 843         {
 844                 clientcommand(self, strcat("say ", msgin));
 845                 return;
 846         }
 847         */
 848
 849         if(autocvar_g_chat_teamcolors)
 850                 namestr = playername(source);
 851         else
 852                 namestr = source.netname;
 853
 854         if(msgin != "")
 855         {
 856                 if(privatesay)
 857                 {
 858                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 859                         privatemsgprefixlen = strlen(msgstr);
 860                         msgstr = strcat(msgstr, msgin);
 861                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 862                         if(autocvar_g_chat_teamcolors)
 863                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 864                         else
 865                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 866                 }
 867                 else if(teamsay)
 868                 {
 869                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 870                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 871                 }
 872                 else
 873                 {
 874                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 875                         cmsgstr = "";
 876                 }
 877                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 878         }
 879         else
 880         {
 881                 msgstr = cmsgstr = "";
 882         }
 883
 884         fullmsgstr = msgstr;
 885         fullcmsgstr = cmsgstr;
 886
 887         // FLOOD CONTROL
 888         flood = 0;
 889         if(floodcontrol)
 890         {
 891                 float flood_spl;
 892                 float flood_burst;
 893                 float flood_lmax;
 894                 float lines;
 895                 if(privatesay)
 896                 {
 897                         flood_spl = autocvar_g_chat_flood_spl_tell;
 898                         flood_burst = autocvar_g_chat_flood_burst_tell;
 899                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 900                         flood_field = floodcontrol_chattell;
 901                 }
 902                 else if(teamsay)
 903                 {
 904                         flood_spl = autocvar_g_chat_flood_spl_team;
 905                         flood_burst = autocvar_g_chat_flood_burst_team;
 906                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 907                         flood_field = floodcontrol_chatteam;
 908                 }
 909                 else
 910                 {
 911                         flood_spl = autocvar_g_chat_flood_spl;
 912                         flood_burst = autocvar_g_chat_flood_burst;
 913                         flood_lmax = autocvar_g_chat_flood_lmax;
 914                         flood_field = floodcontrol_chat;
 915                 }
 916                 flood_burst = max(0, flood_burst - 1);
 917                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 918
 919                 // do flood control for the default line size
 920                 if(msgstr != "")
 921                 {
 922                         getWrappedLine_remaining = msgstr;
 923                         msgstr = "";
 924                         lines = 0;
 925                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 926                         {
 927                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 928                                 ++lines;
 929                         }
 930                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 931
 932                         if(getWrappedLine_remaining != "")
 933                         {
 934                                 msgstr = strcat(msgstr, "\n");
 935                                 flood = 2;
 936                         }
 937
 938                         if(time >= source.flood_field)
 939                         {
 940                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 941                         }
 942                         else
 943                         {
 944                                 flood = 1;
 945                                 msgstr = fullmsgstr;
 946                         }
 947                 }
 948                 else
 949                 {
 950                         if(time >= source.flood_field)
 951                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 952                         else
 953                                 flood = 1;
 954                 }
 955
 956                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 957                         source.flood_field = flood = 0;
 958         }
 959
 960         if(flood == 2) // cannot happen for empty msgstr
 961         {
 962                 if(autocvar_g_chat_flood_notify_flooder)
 963                 {
 964                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 965                         sourcecmsgstr = "";
 966                 }
 967                 else
 968                 {
 969                         sourcemsgstr = fullmsgstr;
 970                         sourcecmsgstr = fullcmsgstr;
 971                 }
 972                 cmsgstr = "";
 973         }
 974         else
 975         {
 976                 sourcemsgstr = msgstr;
 977                 sourcecmsgstr = cmsgstr;
 978         }
 979
 980         if(!privatesay)
 981         if(source.classname != "player")
 982         {
 983                 if not(intermission_running)
 984                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 985                                 teamsay = -1; // spectators
 986         }
 987
 988         if(flood)
 989                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 990
 991         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 992         if(privatesay)
 993                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 994
 995         if(source.muted)
 996         {
 997                 // always fake the message
 998                 ret = -1;
 999         }
1000         else if(flood == 1)
1001         {
1002                 if(autocvar_g_chat_flood_notify_flooder)
1003                 {
1004                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1005                         ret = 0;
1006                 }
1007                 else
1008                         ret = -1;
1009         }
1010         else
1011         {
1012                 ret = 1;
1013         }
1014
1015         if(sourcemsgstr != "" && ret != 0)
1016         {
1017                 if(ret < 0) // faked message, because the player is muted
1018                 {
1019                         sprint(source, sourcemsgstr);
1020                         if(sourcecmsgstr != "" && !privatesay)
1021                                 centerprint(source, sourcecmsgstr);
1022                 }
1023                 else if(privatesay) // private message, between 2 people only, not sent to server console
1024                 {
1025                         sprint(source, sourcemsgstr);
1026                         sprint(privatesay, msgstr);
1027                         if(cmsgstr != "")
1028                                 centerprint(privatesay, cmsgstr);
1029                 }
1030                 else if(teamsay > 0) // team message, only sent to team mates
1031                 {
1032                         sprint(source, sourcemsgstr);
1033                         //print(msgstr); // send to server console too
1034                         if(sourcecmsgstr != "")
1035                                 centerprint(source, sourcecmsgstr);
1036                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1037                                 if(head != source)
1038                                 {
1039                                         sprint(head, msgstr);
1040                                         if(cmsgstr != "")
1041                                                 centerprint(head, cmsgstr);
1042                                 }
1043                 }
1044                 else if(teamsay < 0) // spectator message, only sent to spectators
1045                 {
1046                         sprint(source, sourcemsgstr);
1047                         //print(msgstr); // send to server console too
1048                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1049                                 if(head != source)
1050                                         sprint(head, msgstr);
1051                 }
1052                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1053                 {
1054                         sprint(source, sourcemsgstr);
1055                         //print(msgstr); // send to server console too
1056                         FOR_EACH_REALCLIENT(head)
1057                                 if(head != source)
1058                                         sprint(head, msgstr);
1059                 }
1060                 else
1061                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1062         }
1063
1064         return ret;
1065 }
1066
1067 float GetVoiceMessageVoiceType(string type)
1068 {
1069         if(type == "taunt")
1070                 return VOICETYPE_TAUNT;
1071         if(type == "teamshoot")
1072                 return VOICETYPE_LASTATTACKER;
1073         return VOICETYPE_TEAMRADIO;
1074 }
1075
1076 string allvoicesamples;
1077 .string GetVoiceMessageSampleField(string type)
1078 {
1079         GetPlayerSoundSampleField_notFound = 0;
1080         switch(type)
1081         {
1082 #define _VOICEMSG(m) case #m: return playersound_##m;
1083                 ALLVOICEMSGS
1084 #undef _VOICEMSG
1085         }
1086         GetPlayerSoundSampleField_notFound = 1;
1087         return playersound_taunt;
1088 }
1089
1090 .string GetPlayerSoundSampleField(string type)
1091 {
1092         GetPlayerSoundSampleField_notFound = 0;
1093         switch(type)
1094         {
1095 #define _VOICEMSG(m) case #m: return playersound_##m;
1096                 ALLPLAYERSOUNDS
1097 #undef _VOICEMSG
1098         }
1099         GetPlayerSoundSampleField_notFound = 1;
1100         return playersound_taunt;
1101 }
1102
1103 void PrecacheGlobalSound(string samplestring)
1104 {
1105         float n, i;
1106         tokenize_console(samplestring);
1107         n = stof(argv(1));
1108         if(n > 0)
1109         {
1110                 for(i = 1; i <= n; ++i)
1111                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1112         }
1113         else
1114         {
1115                 precache_sound(strcat(argv(0), ".wav"));
1116         }
1117 }
1118
1119 void PrecachePlayerSounds(string f)
1120 {
1121         float fh;
1122         string s;
1123         fh = fopen(f, FILE_READ);
1124         if(fh < 0)
1125                 return;
1126         while((s = fgets(fh)))
1127         {
1128                 if(tokenize_console(s) != 3)
1129                 {
1130                         dprint("Invalid sound info line: ", s, "\n");
1131                         continue;
1132                 }
1133                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1134         }
1135         fclose(fh);
1136
1137         if not(allvoicesamples)
1138         {
1139 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1140                 ALLVOICEMSGS
1141 #undef _VOICEMSG
1142                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1143         }
1144 }
1145
1146 void ClearPlayerSounds()
1147 {
1148 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1149         ALLPLAYERSOUNDS
1150         ALLVOICEMSGS
1151 #undef _VOICEMSG
1152 }
1153
1154 float LoadPlayerSounds(string f, float first)
1155 {
1156         float fh;
1157         string s;
1158         var .string field;
1159         fh = fopen(f, FILE_READ);
1160         if(fh < 0)
1161         {
1162                 dprint("Player sound file not found: ", f, "\n");
1163                 return 0;
1164         }
1165         while((s = fgets(fh)))
1166         {
1167                 if(tokenize_console(s) != 3)
1168                         continue;
1169                 field = GetPlayerSoundSampleField(argv(0));
1170                 if(GetPlayerSoundSampleField_notFound)
1171                         field = GetVoiceMessageSampleField(argv(0));
1172                 if(GetPlayerSoundSampleField_notFound)
1173                         continue;
1174                 if(self.field)
1175                         strunzone(self.field);
1176                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1177         }
1178         fclose(fh);
1179         return 1;
1180 }
1181
1182 .float modelindex_for_playersound;
1183 .float skin_for_playersound;
1184 void UpdatePlayerSounds()
1185 {
1186         if(self.modelindex == self.modelindex_for_playersound)
1187         if(self.skin == self.skin_for_playersound)
1188                 return;
1189         self.modelindex_for_playersound = self.modelindex;
1190         self.skin_for_playersound = self.skin;
1191         ClearPlayerSounds();
1192         LoadPlayerSounds("sound/player/default.sounds", 1);
1193         if(!autocvar_g_debug_defaultsounds)
1194                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1195                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1196 }
1197
1198 void FakeGlobalSound(string sample, float chan, float voicetype)
1199 {
1200         float n;
1201         float tauntrand;
1202
1203         if(sample == "")
1204                 return;
1205
1206         tokenize_console(sample);
1207         n = stof(argv(1));
1208         if(n > 0)
1209                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1210         else
1211                 sample = strcat(argv(0), ".wav"); // randomization
1212
1213         switch(voicetype)
1214         {
1215                 case VOICETYPE_LASTATTACKER_ONLY:
1216                         break;
1217                 case VOICETYPE_LASTATTACKER:
1218                         if(self.pusher)
1219                         {
1220                                 msg_entity = self;
1221                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1222                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1223                         }
1224                         break;
1225                 case VOICETYPE_TEAMRADIO:
1226                         msg_entity = self;
1227                         if(msg_entity.cvar_cl_voice_directional == 1)
1228                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1229                         else
1230                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1231                         break;
1232                 case VOICETYPE_AUTOTAUNT:
1233                         if(!sv_autotaunt)
1234                                 break;
1235                         if(!sv_taunt)
1236                                 break;
1237                         if(sv_gentle)
1238                                 break;
1239                         tauntrand = random();
1240                         msg_entity = self;
1241                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1242                         {
1243                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1244                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1245                                 else
1246                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1247                         }
1248                         break;
1249                 case VOICETYPE_TAUNT:
1250                         if(self.classname == "player")
1251                                 if(self.deadflag == DEAD_NO)
1252                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1253                         if(!sv_taunt)
1254                                 break;
1255                         if(sv_gentle)
1256                                 break;
1257                         msg_entity = self;
1258                         if (msg_entity.cvar_cl_voice_directional >= 1)
1259                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1260                         else
1261                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1262                         break;
1263                 case VOICETYPE_PLAYERSOUND:
1264                         msg_entity = self;
1265                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1266                         break;
1267                 default:
1268                         backtrace("Invalid voice type!");
1269                         break;
1270         }
1271 }
1272
1273 void GlobalSound(string sample, float chan, float voicetype)
1274 {
1275         float n;
1276         float tauntrand;
1277
1278         if(sample == "")
1279                 return;
1280
1281         tokenize_console(sample);
1282         n = stof(argv(1));
1283         if(n > 0)
1284                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1285         else
1286                 sample = strcat(argv(0), ".wav"); // randomization
1287
1288         switch(voicetype)
1289         {
1290                 case VOICETYPE_LASTATTACKER_ONLY:
1291                         if(self.pusher)
1292                         {
1293                                 msg_entity = self.pusher;
1294                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1295                                 {
1296                                         if(msg_entity.cvar_cl_voice_directional == 1)
1297                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1298                                         else
1299                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1300                                 }
1301                         }
1302                         break;
1303                 case VOICETYPE_LASTATTACKER:
1304                         if(self.pusher)
1305                         {
1306                                 msg_entity = self.pusher;
1307                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1308                                 {
1309                                         if(msg_entity.cvar_cl_voice_directional == 1)
1310                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1311                                         else
1312                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1313                                 }
1314                                 msg_entity = self;
1315                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1316                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1317                         }
1318                         break;
1319                 case VOICETYPE_TEAMRADIO:
1320                         FOR_EACH_REALCLIENT(msg_entity)
1321                                 if(!teamplay || msg_entity.team == self.team)
1322                                 {
1323                                         if(msg_entity.cvar_cl_voice_directional == 1)
1324                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1325                                         else
1326                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1327                                 }
1328                         break;
1329                 case VOICETYPE_AUTOTAUNT:
1330                         if(!sv_autotaunt)
1331                                 break;
1332                         if(!sv_taunt)
1333                                 break;
1334                         if(sv_gentle)
1335                                 break;
1336                         tauntrand = random();
1337                         FOR_EACH_REALCLIENT(msg_entity)
1338                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1339                                 {
1340                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1341                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1342                                         else
1343                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1344                                 }
1345                         break;
1346                 case VOICETYPE_TAUNT:
1347                         if(self.classname == "player")
1348                                 if(self.deadflag == DEAD_NO)
1349                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1350                         if(!sv_taunt)
1351                                 break;
1352                         if(sv_gentle)
1353                                 break;
1354                         FOR_EACH_REALCLIENT(msg_entity)
1355                         {
1356                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1357                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1358                                 else
1359                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1360                         }
1361                         break;
1362                 case VOICETYPE_PLAYERSOUND:
1363                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1364                         break;
1365                 default:
1366                         backtrace("Invalid voice type!");
1367                         break;
1368         }
1369 }
1370
1371 void PlayerSound(.string samplefield, float chan, float voicetype)
1372 {
1373         GlobalSound(self.samplefield, chan, voicetype);
1374 }
1375
1376 void VoiceMessage(string type, string msg)
1377 {
1378         var .string sample;
1379         float voicetype, ownteam;
1380         float flood;
1381         sample = GetVoiceMessageSampleField(type);
1382
1383         if(GetPlayerSoundSampleField_notFound)
1384         {
1385                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1386                 return;
1387         }
1388
1389         voicetype = GetVoiceMessageVoiceType(type);
1390         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1391
1392         flood = Say(self, ownteam, world, msg, 1);
1393
1394         if (flood > 0)
1395                 GlobalSound(self.sample, CH_VOICE, voicetype);
1396         else if (flood < 0)
1397                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1398 }
1399
1400 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1401 {
1402 //      show_message
1403 //      0 (00) automove centerprint, admin message
1404 //      1 (01) automove centerprint, no admin message
1405 //      2 (10) no centerprint, admin message
1406 //      3 (11) no centerprint, no admin message
1407
1408         float lockteams_backup;
1409
1410         lockteams_backup = lockteams;  // backup any team lock
1411
1412         lockteams = 0;  // disable locked teams
1413
1414         TeamchangeFrags(client);  // move the players frags
1415         SetPlayerColors(client, team_colour - 1);  // set the players colour
1416         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1417
1418         lockteams = lockteams_backup;  // restore the team lock
1419
1420         LogTeamchange(client.playerid, client.team, type);
1421
1422         if not(show_message & 1) // admin message
1423                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1424
1425         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1426 }