qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.playermodel, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 333 }
 334
 335 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 336 {
 337         local float take, save;
 338         vector v;
 339         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 340
 341         // damage resistance (ignore most of the damage from a bullet or similar)
 342         damage = max(damage - 5, 1);
 343
 344         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 345         take = v_x;
 346         save = v_y;
 347
 348         if(sound_allowed(MSG_BROADCAST, attacker))
 349         {
 350                 if (save > 10)
 351                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 352                 else if (take > 30)
 353                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 354                 else if (take > 10)
 355                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 356         }
 357
 358         if (take > 50)
 359                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 360         if (take > 100)
 361                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 362
 363         if (!(self.flags & FL_GODMODE))
 364         {
 365                 self.armorvalue = self.armorvalue - save;
 366                 self.health = self.health - take;
 367                 // pause regeneration for 5 seconds
 368                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 369         }
 370         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 371         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 372         self.dmg_inflictor = inflictor;
 373
 374         if (self.health <= -100 && self.modelindex != 0)
 375         {
 376                 // don't use any animations as a gib
 377                 self.frame = 0;
 378                 self.dead_frame = 0;
 379                 // view just above the floor
 380                 self.view_ofs = '0 0 4';
 381
 382                 Violence_GibSplash(self, 1, 1, attacker);
 383                 self.modelindex = 0; // restore later
 384                 self.solid = SOLID_NOT; // restore later
 385         }
 386 }
 387
 388 void ClientKill_Now_TeamChange();
 389
 390 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 391 {
 392         local float take, save, waves, sdelay, dh, da, j;
 393         vector v;
 394         float valid_damage_for_weaponstats;
 395
 396         dh = max(self.health, 0);
 397         da = max(self.armorvalue, 0);
 398
 399         if(!DEATH_ISSPECIAL(deathtype))
 400         {
 401                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 402                 if(self != attacker)
 403                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 404         }
 405
 406         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 407         {
 408                 // tuba causes blood to come out of the ears
 409                 vector ear1, ear2;
 410                 vector d;
 411                 float f;
 412                 ear1 = self.origin;
 413                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 414                 ear2 = ear1;
 415                 makevectors(self.angles);
 416                 ear1 += v_right * -10;
 417                 ear2 += v_right * +10;
 418                 d = inflictor.origin - self.origin;
 419                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 420                 force = v_right * vlen(force);
 421                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 422                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 423                 if(f > 0)
 424                 {
 425                         hitloc = ear1;
 426                         force = force * -1;
 427                 }
 428                 else
 429                 {
 430                         hitloc = ear2;
 431                         // force is already good
 432                 }
 433         }
 434         else
 435                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 436
 437         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 438                 return;
 439
 440         if (!g_minstagib)
 441         {
 442                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 443                 take = v_x;
 444                 save = v_y;
 445         }
 446         else
 447         {
 448                 save = 0;
 449                 take = damage;
 450         }
 451
 452         if(sound_allowed(MSG_BROADCAST, attacker))
 453         {
 454                 if (save > 10)
 455                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 456                 else if (take > 30)
 457                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 458                 else if (take > 10)
 459                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 460         }
 461
 462         if (take > 50)
 463                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 464         if (take > 100)
 465                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 466
 467         if (time >= self.spawnshieldtime)
 468         {
 469                 if (!(self.flags & FL_GODMODE))
 470                 {
 471                         self.armorvalue = self.armorvalue - save;
 472                         self.health = self.health - take;
 473                         // pause regeneration for 5 seconds
 474                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 475
 476                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 477                         {
 478                                 self.pain_finished = time + 0.5;        //Supajoe
 479
 480                                 if(sv_gentle < 1) {
 481                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 482                                         {
 483                                                 if (random() > 0.5)
 484                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 485                                                 else
 486                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 487                                         }
 488
 489                                         if(sound_allowed(MSG_BROADCAST, attacker))
 490                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 491                                         if(self.health > 1)
 492                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 493                                         {
 494                                                 if(deathtype == DEATH_FALL)
 495                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 496                                                 else if(self.health > 75) // TODO make a "gentle" version?
 497                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 498                                                 else if(self.health > 50)
 499                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 500                                                 else if(self.health > 25)
 501                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else
 503                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                         }
 505                                 }
 506
 507                                 // throw off bot aim temporarily
 508                                 local float shake;
 509                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 510                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 511                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 512                         }
 513                 }
 514                 else
 515                         self.max_armorvalue += (save + take);
 516         }
 517         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 518         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 519         self.dmg_inflictor = inflictor;
 520
 521         if(attacker == self)
 522         {
 523                 // don't reset pushltime for self damage as it may be an attempt to
 524                 // escape a lava pit or similar
 525                 //self.pushltime = 0;
 526         }
 527         else if(attacker.classname == "player" || attacker.classname == "gib")
 528         {
 529                 self.pusher = attacker;
 530                 self.pushltime = time + cvar("g_maxpushtime");
 531         }
 532         else if(time < self.pushltime)
 533         {
 534                 attacker = self.pusher;
 535                 self.pushltime = max(self.pushltime, time + 0.6);
 536         }
 537         else
 538                 self.pushltime = 0;
 539
 540         valid_damage_for_weaponstats = 0;
 541         if(clienttype(self) == CLIENTTYPE_REAL)
 542         if(clienttype(attacker) == CLIENTTYPE_REAL)
 543         if(self != attacker)
 544         if(!DEATH_ISSPECIAL(deathtype))
 545         if(IsDifferentTeam(self, attacker))
 546                 valid_damage_for_weaponstats = 1;
 547
 548         if(valid_damage_for_weaponstats)
 549         {
 550                 dh = dh - max(self.health, 0);
 551                 da = da - max(self.armorvalue, 0);
 552                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 553         }
 554
 555         if (self.health < 1)
 556         {
 557                 float defer_ClientKill_Now_TeamChange;
 558                 defer_ClientKill_Now_TeamChange = FALSE;
 559
 560                 if(valid_damage_for_weaponstats)
 561                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 562
 563                 if(sv_gentle < 1) // TODO make a "gentle" version?
 564                 if(sound_allowed(MSG_BROADCAST, attacker))
 565                 {
 566                         if(deathtype == DEATH_DROWN)
 567                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 568                         else
 569                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 570                 }
 571
 572                 // get rid of kill indicator
 573                 if(self.killindicator)
 574                 {
 575                         remove(self.killindicator);
 576                         self.killindicator = world;
 577                         if(self.killindicator_teamchange)
 578                                 defer_ClientKill_Now_TeamChange = TRUE;
 579
 580                         if(self.classname == "body")
 581                         if(deathtype == DEATH_KILL)
 582                         {
 583                                 // for the lemmings fans, a small harmless explosion
 584                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 585                         }
 586                 }
 587
 588                 // become fully visible
 589                 self.alpha = 1;
 590                 // clear selected player display
 591                 ClearSelectedPlayer();
 592                 // throw a weapon
 593                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 594                 // print an obituary message
 595                 Obituary (attacker, inflictor, self, deathtype);
 596                 race_PreDie();
 597                 DropAllRunes(self);
 598
 599                 frag_attacker = attacker;
 600                 frag_inflictor = inflictor;
 601                 frag_target = self;
 602                 MUTATOR_CALLHOOK(PlayerDies);
 603
 604                 if(self.flagcarried)
 605                 {
 606                         if(attacker.classname != "player" && attacker.classname != "gib")
 607                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 608                         else if(attacker.team == self.team)
 609                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 610                         else
 611                                 DropFlag(self.flagcarried, world, attacker);
 612                 }
 613                 if(self.ballcarried)
 614                         DropBall(self.ballcarried, self.origin, self.velocity);
 615                 Portal_ClearAllLater(self);
 616                 // clear waypoints
 617                 WaypointSprite_PlayerDead();
 618                 // make the corpse upright (not tilted)
 619                 self.angles_x = 0;
 620                 self.angles_z = 0;
 621                 // don't spin
 622                 self.avelocity = '0 0 0';
 623                 // view from the floor
 624                 self.view_ofs = '0 0 -8';
 625                 // toss the corpse
 626                 self.movetype = MOVETYPE_TOSS;
 627                 // shootable corpse
 628                 self.solid = SOLID_CORPSE;
 629                 self.ballistics_density = cvar("g_ballistics_density_corpse");
 630                 // don't stick to the floor
 631                 self.flags &~= FL_ONGROUND;
 632                 // dying animation
 633                 self.deadflag = DEAD_DYING;
 634                 // when to allow respawn
 635                 sdelay = 0;
 636                 waves = 0;
 637                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 638                 if(!sdelay)
 639                         sdelay = cvar("g_respawn_delay");
 640                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 641                 if(!waves)
 642                         waves = cvar("g_respawn_waves");
 643                 if(waves)
 644                         self.death_time = ceil((time + sdelay) / waves) * waves;
 645                 else
 646                         self.death_time = time + sdelay;
 647                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 648                         self.respawn_countdown = 10; // first number to count down from is 10
 649                 else
 650                         self.respawn_countdown = -1; // do not count down
 651                 if (random() < 0.5)
 652                 {
 653                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 654                         self.dead_frame = self.anim_dead1_x;
 655                 }
 656                 else
 657                 {
 658                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 659                         self.dead_frame = self.anim_dead2_x;
 660                 }
 661                 // set damage function to corpse damage
 662                 self.event_damage = PlayerCorpseDamage;
 663                 // call the corpse damage function just in case it wants to gib
 664                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 665                 // set up to fade out later
 666                 SUB_SetFade (self, time + 6 + random (), 1);
 667
 668                 if(clienttype(self) == CLIENTTYPE_REAL)
 669                 {
 670                         self.fixangle = TRUE;
 671                         //msg_entity = self;
 672                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 673                         //WriteAngle (MSG_ONE, self.v_angle_x);
 674                         //WriteAngle (MSG_ONE, self.v_angle_y);
 675                         //WriteAngle (MSG_ONE, 80);
 676                 }
 677
 678                 if(g_arena)
 679                         Spawnqueue_Unmark(self);
 680
 681                 if(defer_ClientKill_Now_TeamChange)
 682                         ClientKill_Now_TeamChange();
 683
 684                 if(sv_gentle > 0 || cvar("ekg")) {
 685                         // remove corpse
 686                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 687                 }
 688
 689                 // reset fields the weapons may use just in case
 690         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 691                 {
 692             weapon_action(j, WR_RESETPLAYER);
 693                         ATTACK_FINISHED_FOR(self, j) = 0;
 694                 }
 695         }
 696 }
 697
 698 float UpdateSelectedPlayer_countvalue(float v)
 699 {
 700         return max(0, (v - 1.0) / 0.5);
 701 }
 702
 703 // returns: -2 if no hit, otherwise cos of the angle
 704 // uses the global v_angle
 705 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 706 {
 707         vector so, d;
 708         float c;
 709
 710         if(p == self)
 711                 return -2;
 712
 713         if(p.deadflag)
 714                 return -2;
 715
 716         so = self.origin + self.view_ofs;
 717         d = p.origin - so;
 718
 719         // misaimed?
 720         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 721                 return -2;
 722
 723         // now find the cos of the angle...
 724         c = normalize(d) * v_forward;
 725
 726         if(c <= mincosangle)
 727                 return -2;
 728
 729         // not visible in any way? forget it
 730         if(!checkpvs(so, p))
 731                 return -2;
 732
 733         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 734         if(trace_fraction < 1)
 735                 return -2;
 736
 737         return c;
 738 }
 739
 740 void ClearSelectedPlayer()
 741 {
 742         if(self.selected_player)
 743         {
 744                 centerprint_expire(self, CENTERPRIO_POINT);
 745                 self.selected_player = world;
 746                 self.selected_player_display_needs_update = FALSE;
 747         }
 748 }
 749
 750 void UpdateSelectedPlayer()
 751 {
 752         entity selected;
 753         float selected_score;
 754         selected = world;
 755         selected_score = 0.95; // 18 degrees
 756
 757         if(!cvar("sv_allow_shownames"))
 758                 return;
 759
 760         if(clienttype(self) != CLIENTTYPE_REAL)
 761                 return;
 762
 763         if(self.cvar_cl_shownames == 0)
 764                 return;
 765
 766         if(self.cvar_cl_shownames == 1 && !teams_matter)
 767                 return;
 768
 769         makevectors(self.v_angle); // sets v_forward
 770
 771         // 1. cursor trace is always right
 772         WarpZone_crosshair_trace(self);
 773         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 774         {
 775                 selected = trace_ent;
 776         }
 777         else
 778         {
 779                 // 2. if we don't have a cursor trace, find the player which is least
 780                 //    mis-aimed at
 781                 entity p;
 782                 FOR_EACH_PLAYER(p)
 783                 {
 784                         float c;
 785                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 786                         if(c >= -1)
 787                         {
 788                                 selected = p;
 789                                 selected_score = c;
 790                         }
 791                 }
 792         }
 793
 794         if(selected)
 795         {
 796                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 797         }
 798         else
 799         {
 800                 if(time < self.selected_player_display_timeout)
 801                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 802                                 selected = self.selected_player;
 803         }
 804
 805         if(selected)
 806         {
 807                 if(selected == self.selected_player)
 808                 {
 809                         float save;
 810                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 811                         self.selected_player_count = self.selected_player_count + frametime;
 812                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 813                         {
 814                                 string namestr, healthstr;
 815                                 namestr = playername(selected);
 816                                 if(teams_matter)
 817                                 {
 818                                         healthstr = ftos(floor(selected.health));
 819                                         if(self.team == selected.team)
 820                                         {
 821                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 822                                                 self.selected_player_display_needs_update = TRUE;
 823                                         }
 824                                 }
 825                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 826                         }
 827                 }
 828                 else
 829                 {
 830                         ClearSelectedPlayer();
 831                         self.selected_player = selected;
 832                         self.selected_player_time = time;
 833                         self.selected_player_count = 0;
 834                         self.selected_player_display_needs_update = FALSE;
 835                 }
 836         }
 837         else
 838         {
 839                 ClearSelectedPlayer();
 840         }
 841
 842         if(self.selected_player)
 843                 self.last_selected_player = self.selected_player;
 844 }
 845
 846 .float muted; // to be used by prvm_edictset server playernumber muted 1
 847 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 848 // message "": do not say, just test flood control
 849 // return value:
 850 //   1 = accept
 851 //   0 = reject
 852 //  -1 = fake accept
 853 {
 854         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 855         float flood, privatemsgprefixlen;
 856         var .float flood_field;
 857         entity head;
 858         float ret;
 859
 860         if(Ban_MaybeEnforceBan(source))
 861                 return 0;
 862
 863         if(!teamsay && !privatesay)
 864                 if(substring(msgin, 0, 1) == " ")
 865                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 866
 867         msgin = formatmessage(msgin);
 868
 869         if(source.classname != "player")
 870                 colorstr = "^0"; // black for spectators
 871         else if(teams_matter)
 872                 colorstr = Team_ColorCode(source.team);
 873         else
 874                 teamsay = FALSE;
 875
 876         if(intermission_running)
 877                 teamsay = FALSE;
 878
 879         if(msgin != "")
 880                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 881
 882         /*
 883          * using bprint solves this... me stupid
 884         // how can we prevent the message from appearing in a listen server?
 885         // for now, just give "say" back and only handle say_team
 886         if(!teamsay)
 887         {
 888                 clientcommand(self, strcat("say ", msgin));
 889                 return;
 890         }
 891         */
 892
 893         if(cvar("g_chat_teamcolors"))
 894                 namestr = playername(source);
 895         else
 896                 namestr = source.netname;
 897
 898         if(msgin != "")
 899         {
 900                 if(privatesay)
 901                 {
 902                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 903                         privatemsgprefixlen = strlen(msgstr);
 904                         msgstr = strcat(msgstr, msgin);
 905                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 906                         if(cvar("g_chat_teamcolors"))
 907                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 908                         else
 909                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 910                 }
 911                 else if(teamsay)
 912                 {
 913                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 914                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 915                 }
 916                 else
 917                 {
 918                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 919                         cmsgstr = "";
 920                 }
 921                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 922         }
 923         else
 924         {
 925                 msgstr = cmsgstr = "";
 926         }
 927
 928         fullmsgstr = msgstr;
 929         fullcmsgstr = cmsgstr;
 930
 931         // FLOOD CONTROL
 932         flood = 0;
 933         if(floodcontrol)
 934         {
 935                 float flood_spl;
 936                 float flood_burst;
 937                 float flood_lmax;
 938                 float lines;
 939                 if(privatesay)
 940                 {
 941                         flood_spl = cvar("g_chat_flood_spl_tell");
 942                         flood_burst = cvar("g_chat_flood_burst_tell");
 943                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 944                         flood_field = floodcontrol_chattell;
 945                 }
 946                 else if(teamsay)
 947                 {
 948                         flood_spl = cvar("g_chat_flood_spl_team");
 949                         flood_burst = cvar("g_chat_flood_burst_team");
 950                         flood_lmax = cvar("g_chat_flood_lmax_team");
 951                         flood_field = floodcontrol_chatteam;
 952                 }
 953                 else
 954                 {
 955                         flood_spl = cvar("g_chat_flood_spl");
 956                         flood_burst = cvar("g_chat_flood_burst");
 957                         flood_lmax = cvar("g_chat_flood_lmax");
 958                         flood_field = floodcontrol_chat;
 959                 }
 960                 flood_burst = max(0, flood_burst - 1);
 961                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 962
 963                 // do flood control for the default line size
 964                 if(msgstr != "")
 965                 {
 966                         getWrappedLine_remaining = msgstr;
 967                         msgstr = "";
 968                         lines = 0;
 969                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 970                         {
 971                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 972                                 ++lines;
 973                         }
 974                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 975
 976                         if(getWrappedLine_remaining != "")
 977                         {
 978                                 msgstr = strcat(msgstr, "\n");
 979                                 flood = 2;
 980                         }
 981
 982                         if(time >= source.flood_field)
 983                         {
 984                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 985                         }
 986                         else
 987                         {
 988                                 flood = 1;
 989                                 msgstr = fullmsgstr;
 990                         }
 991                 }
 992                 else
 993                 {
 994                         if(time >= source.flood_field)
 995                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 996                         else
 997                                 flood = 1;
 998                 }
 999
1000                 if (timeoutStatus == 2) //when game is paused, no flood protection
1001                         source.flood_field = flood = 0;
1002         }
1003
1004         if(flood == 2) // cannot happen for empty msgstr
1005         {
1006                 if(cvar("g_chat_flood_notify_flooder"))
1007                 {
1008                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1009                         sourcecmsgstr = "";
1010                 }
1011                 else
1012                 {
1013                         sourcemsgstr = fullmsgstr;
1014                         sourcecmsgstr = fullcmsgstr;
1015                 }
1016                 cmsgstr = "";
1017         }
1018         else
1019         {
1020                 sourcemsgstr = msgstr;
1021                 sourcecmsgstr = cmsgstr;
1022         }
1023
1024         if(!privatesay)
1025         if(source.classname != "player")
1026         {
1027                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1028                         teamsay = -1; // spectators
1029         }
1030
1031         if(flood)
1032                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1033
1034         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1035         if(privatesay)
1036                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1037
1038         if(source.muted)
1039         {
1040                 // always fake the message
1041                 ret = -1;
1042         }
1043         else if(flood == 1)
1044         {
1045                 if(cvar("g_chat_flood_notify_flooder"))
1046                 {
1047                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1048                         ret = 0;
1049                 }
1050                 else
1051                         ret = -1;
1052         }
1053         else
1054         {
1055                 ret = 1;
1056         }
1057
1058         if(sourcemsgstr != "" && ret != 0)
1059         {
1060                 if(ret < 0) // fake
1061                 {
1062                         sprint(source, sourcemsgstr);
1063                         if(sourcecmsgstr != "" && !privatesay)
1064                                 centerprint(source, sourcecmsgstr);
1065                 }
1066                 else if(privatesay)
1067                 {
1068                         sprint(source, sourcemsgstr);
1069                         sprint(privatesay, msgstr);
1070                         if(cmsgstr != "")
1071                                 centerprint(privatesay, cmsgstr);
1072                 }
1073                 else if(teamsay > 0)
1074                 {
1075                         sprint(source, sourcemsgstr);
1076                         if(sourcecmsgstr != "")
1077                                 centerprint(source, sourcecmsgstr);
1078                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1079                                 if(head != source)
1080                                 {
1081                                         sprint(head, msgstr);
1082                                         if(cmsgstr != "")
1083                                                 centerprint(head, cmsgstr);
1084                                 }
1085                 }
1086                 else if(teamsay < 0)
1087                 {
1088                         sprint(source, sourcemsgstr);
1089                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1090                                 if(head != source)
1091                                         sprint(head, msgstr);
1092                 }
1093                 else if(sourcemsgstr != msgstr)
1094                 {
1095                         sprint(source, sourcemsgstr);
1096                         FOR_EACH_REALCLIENT(head)
1097                                 if(head != source)
1098                                         sprint(head, msgstr);
1099                 }
1100                 else
1101                         bprint(msgstr);
1102         }
1103
1104         return ret;
1105 }
1106
1107 float GetVoiceMessageVoiceType(string type)
1108 {
1109         if(type == "taunt")
1110                 return VOICETYPE_TAUNT;
1111         if(type == "teamshoot")
1112                 return VOICETYPE_LASTATTACKER;
1113         return VOICETYPE_TEAMRADIO;
1114 }
1115
1116 string allvoicesamples;
1117 float GetPlayerSoundSampleField_notFound;
1118 float GetPlayerSoundSampleField_fixed;
1119 .string GetVoiceMessageSampleField(string type)
1120 {
1121         GetPlayerSoundSampleField_notFound = 0;
1122         GetPlayerSoundSampleField_fixed = 0;
1123         switch(type)
1124         {
1125 #define _VOICEMSG(m) case #m: return playersound_##m;
1126                 ALLVOICEMSGS
1127 #undef _VOICEMSG
1128         }
1129         GetPlayerSoundSampleField_notFound = 1;
1130         return playersound_taunt;
1131 }
1132
1133 .string GetPlayerSoundSampleField(string type)
1134 {
1135         GetPlayerSoundSampleField_notFound = 0;
1136         GetPlayerSoundSampleField_fixed = 0;
1137         switch(type)
1138         {
1139 #define _VOICEMSG(m) case #m: return playersound_##m;
1140                 ALLPLAYERSOUNDS
1141 #undef _VOICEMSG
1142         }
1143         GetPlayerSoundSampleField_notFound = 1;
1144         return playersound_taunt;
1145 }
1146
1147 void PrecacheGlobalSound(string samplestring)
1148 {
1149         float n, i;
1150         tokenize_console(samplestring);
1151         n = stof(argv(1));
1152         if(n > 0)
1153         {
1154                 for(i = 1; i <= n; ++i)
1155                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1156         }
1157         else
1158         {
1159                 precache_sound(strcat(argv(0), ".wav"));
1160         }
1161 }
1162
1163 void PrecachePlayerSounds(string f)
1164 {
1165         float fh;
1166         string s;
1167         fh = fopen(f, FILE_READ);
1168         if(fh < 0)
1169                 return;
1170         while((s = fgets(fh)))
1171         {
1172                 if(tokenize_console(s) != 3)
1173                 {
1174                         dprint("Invalid sound info line: ", s, "\n");
1175                         continue;
1176                 }
1177                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1178         }
1179         fclose(fh);
1180
1181         if not(allvoicesamples)
1182         {
1183 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1184                 ALLVOICEMSGS
1185 #undef _VOICEMSG
1186                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1187         }
1188 }
1189
1190 void ClearPlayerSounds()
1191 {
1192 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1193         ALLPLAYERSOUNDS
1194         ALLVOICEMSGS
1195 #undef _VOICEMSG
1196 }
1197
1198 void LoadPlayerSounds(string f, float first)
1199 {
1200         float fh;
1201         string s;
1202         var .string field;
1203         fh = fopen(f, FILE_READ);
1204         if(fh < 0)
1205         {
1206                 dprint("Player sound file not found: ", f, "\n");
1207                 return;
1208         }
1209         while((s = fgets(fh)))
1210         {
1211                 if(tokenize_console(s) != 3)
1212                         continue;
1213                 field = GetPlayerSoundSampleField(argv(0));
1214                 if(GetPlayerSoundSampleField_notFound)
1215                         field = GetVoiceMessageSampleField(argv(0));
1216                 if(GetPlayerSoundSampleField_notFound)
1217                         continue;
1218                 if(GetPlayerSoundSampleField_fixed)
1219                         if not(first)
1220                                 continue;
1221                 if(self.field)
1222                         strunzone(self.field);
1223                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1224         }
1225         fclose(fh);
1226 }
1227
1228 .float modelindex_for_playersound;
1229 .float skinindex_for_playersound;
1230 void UpdatePlayerSounds()
1231 {
1232         if(self.modelindex == self.modelindex_for_playersound)
1233         if(self.skinindex == self.skinindex_for_playersound)
1234                 return;
1235         self.modelindex_for_playersound = self.modelindex;
1236         self.skinindex_for_playersound = self.skinindex;
1237         ClearPlayerSounds();
1238         LoadPlayerSounds("sound/player/default.sounds", 1);
1239         LoadPlayerSounds(get_model_datafilename(self.playermodel, self.skinindex, "sounds"), 0);
1240 }
1241
1242 void FakeGlobalSound(string sample, float chan, float voicetype)
1243 {
1244         float n;
1245         float tauntrand;
1246
1247         if(sample == "")
1248                 return;
1249
1250         tokenize_console(sample);
1251         n = stof(argv(1));
1252         if(n > 0)
1253                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1254         else
1255                 sample = strcat(argv(0), ".wav"); // randomization
1256
1257         switch(voicetype)
1258         {
1259                 case VOICETYPE_LASTATTACKER_ONLY:
1260                         break;
1261                 case VOICETYPE_LASTATTACKER:
1262                         if(self.pusher)
1263                         {
1264                                 msg_entity = self;
1265                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1266                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1267                         }
1268                         break;
1269                 case VOICETYPE_TEAMRADIO:
1270                         msg_entity = self;
1271                         if(msg_entity.cvar_cl_voice_directional == 1)
1272                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1273                         else
1274                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1275                         break;
1276                 case VOICETYPE_AUTOTAUNT:
1277                         if(!sv_autotaunt)
1278                                 break;
1279                         if(!sv_taunt)
1280                                 break;
1281                         if(sv_gentle)
1282                                 break;
1283                         tauntrand = random();
1284                         msg_entity = self;
1285                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1286                         {
1287                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1288                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1289                                 else
1290                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1291                         }
1292                         break;
1293                 case VOICETYPE_TAUNT:
1294                         if(self.classname == "player")
1295                                 if(self.deadflag == DEAD_NO)
1296                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1297                         if(!sv_taunt)
1298                                 break;
1299                         if(sv_gentle)
1300                                 break;
1301                         msg_entity = self;
1302                         if (msg_entity.cvar_cl_voice_directional >= 1)
1303                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1304                         else
1305                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1306                         break;
1307                 case VOICETYPE_PLAYERSOUND:
1308                         msg_entity = self;
1309                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1310                         break;
1311                 default:
1312                         backtrace("Invalid voice type!");
1313                         break;
1314         }
1315 }
1316
1317 void GlobalSound(string sample, float chan, float voicetype)
1318 {
1319         float n;
1320         float tauntrand;
1321
1322         if(sample == "")
1323                 return;
1324
1325         tokenize_console(sample);
1326         n = stof(argv(1));
1327         if(n > 0)
1328                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1329         else
1330                 sample = strcat(argv(0), ".wav"); // randomization
1331
1332         switch(voicetype)
1333         {
1334                 case VOICETYPE_LASTATTACKER_ONLY:
1335                         if(self.pusher)
1336                         {
1337                                 msg_entity = self.pusher;
1338                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1339                                 {
1340                                         if(msg_entity.cvar_cl_voice_directional == 1)
1341                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1342                                         else
1343                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1344                                 }
1345                         }
1346                         break;
1347                 case VOICETYPE_LASTATTACKER:
1348                         if(self.pusher)
1349                         {
1350                                 msg_entity = self.pusher;
1351                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1352                                 {
1353                                         if(msg_entity.cvar_cl_voice_directional == 1)
1354                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1355                                         else
1356                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1357                                 }
1358                                 msg_entity = self;
1359                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1360                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1361                         }
1362                         break;
1363                 case VOICETYPE_TEAMRADIO:
1364                         FOR_EACH_REALCLIENT(msg_entity)
1365                                 if(!teams_matter || msg_entity.team == self.team)
1366                                 {
1367                                         if(msg_entity.cvar_cl_voice_directional == 1)
1368                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1369                                         else
1370                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1371                                 }
1372                         break;
1373                 case VOICETYPE_AUTOTAUNT:
1374                         if(!sv_autotaunt)
1375                                 break;
1376                         if(!sv_taunt)
1377                                 break;
1378                         if(sv_gentle)
1379                                 break;
1380                         tauntrand = random();
1381                         FOR_EACH_REALCLIENT(msg_entity)
1382                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1383                                 {
1384                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1385                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1386                                         else
1387                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1388                                 }
1389                         break;
1390                 case VOICETYPE_TAUNT:
1391                         if(self.classname == "player")
1392                                 if(self.deadflag == DEAD_NO)
1393                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1394                         if(!sv_taunt)
1395                                 break;
1396                         if(sv_gentle)
1397                                 break;
1398                         FOR_EACH_REALCLIENT(msg_entity)
1399                         {
1400                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1401                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1402                                 else
1403                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1404                         }
1405                         break;
1406                 case VOICETYPE_PLAYERSOUND:
1407                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1408                         break;
1409                 default:
1410                         backtrace("Invalid voice type!");
1411                         break;
1412         }
1413 }
1414
1415 void PlayerSound(.string samplefield, float chan, float voicetype)
1416 {
1417         GlobalSound(self.samplefield, chan, voicetype);
1418 }
1419
1420 void VoiceMessage(string type, string msg)
1421 {
1422         var .string sample;
1423         float voicetype, ownteam;
1424         float flood;
1425         sample = GetVoiceMessageSampleField(type);
1426
1427         if(GetPlayerSoundSampleField_notFound)
1428         {
1429                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1430                 return;
1431         }
1432
1433         voicetype = GetVoiceMessageVoiceType(type);
1434         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1435
1436         flood = Say(self, ownteam, world, msg, 1);
1437
1438         if (flood > 0)
1439                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1440         else if (flood < 0)
1441                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1442 }
1443
1444 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1445 {
1446 //      show_message
1447 //      0 (00) automove centerprint, admin message
1448 //      1 (01) automove centerprint, no admin message
1449 //      2 (10) no centerprint, admin message
1450 //      3 (11) no centerprint, no admin message
1451
1452         float lockteams_backup;
1453
1454         lockteams_backup = lockteams;  // backup any team lock
1455
1456         lockteams = 0;  // disable locked teams
1457
1458         TeamchangeFrags(client);  // move the players frags
1459         SetPlayerColors(client, team_colour - 1);  // set the players colour
1460         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1461
1462         lockteams = lockteams_backup;  // restore the team lock
1463
1464         LogTeamchange(client.playerid, client.team, type);
1465
1466         if not(show_message & 1) // admin message
1467                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1468
1469         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1470 }