qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(accuracy_frags);
   4
   5 float weaponstats_buffer;
   6
   7 void WeaponStats_Init()
   8 {
   9         if(autocvar_sv_weaponstats_file != "")
  10                 weaponstats_buffer = buf_create();
  11         else
  12                 weaponstats_buffer = -1;
  13 }
  14
  15 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  16
  17 void WeaponStats_Shutdown()
  18 {
  19         float i, j, ibot, jbot, idx;
  20         float fh;
  21         vector v;
  22         string prefix;
  23         if(weaponstats_buffer < 0)
  24                 return;
  25         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26         if(autocvar_sv_weaponstats_file != "")
  27         {
  28                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  29                 if(fh >= 0)
  30                 {
  31                         fputs(fh, "#begin statsfile\n");
  32                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  33                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  34                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  35                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  36                                 {
  37                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  38                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  39                                         if(v != '0 0 0')
  40                                         {
  41                                                 //vector is: kills hits damage
  42                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  43                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  44                                         }
  45                                 }
  46                         fputs(fh, "#end\n\n");
  47                         fclose(fh);
  48                         print("Weapon stats written\n");
  49                 }
  50         }
  51         buf_del(weaponstats_buffer);
  52         weaponstats_buffer = -1;
  53 }
  54
  55 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  56 {
  57         float idx;
  58         if(weaponstats_buffer < 0)
  59                 return;
  60         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  61                 return;
  62         if(awep > WEP_LAST || vwep > WEP_LAST)
  63                 return;
  64         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  65         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  66 }
  67 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  68 {
  69         if(damage < 0)
  70                 error("negative damage?");
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  72 }
  73 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  74 {
  75         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  76 }
  77
  78 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  79 // merged player_run and player_stand to player_anim
  80 // added death animations to player_anim
  81 // can now spawn thrown weapons from anywhere, not just from players
  82 // thrown weapons now fade out after 20 seconds
  83 // created PlayerGib function
  84 // PlayerDie no longer uses hitloc or damage
  85 // PlayerDie now supports dying animations as well as gibbing
  86 // cleaned up PlayerDie a lot
  87 // added CopyBody
  88
  89 .entity pusher;
  90 .float pushltime;
  91
  92 void CopyBody(float keepvelocity)
  93 {
  94         local entity oldself;
  95         if (self.effects & EF_NODRAW)
  96                 return;
  97         oldself = self;
  98         self = spawn();
  99         self.enemy = oldself;
 100         self.lip = oldself.lip;
 101         self.colormap = oldself.colormap;
 102         self.glowmod = oldself.glowmod;
 103         self.iscreature = oldself.iscreature;
 104         self.angles = oldself.angles;
 105         self.avelocity = oldself.avelocity;
 106         self.classname = "body";
 107         self.damageforcescale = oldself.damageforcescale;
 108         self.effects = oldself.effects;
 109         self.event_damage = oldself.event_damage;
 110         self.animstate_startframe = oldself.animstate_startframe;
 111         self.animstate_numframes = oldself.animstate_numframes;
 112         self.animstate_framerate = oldself.animstate_framerate;
 113         self.animstate_starttime = oldself.animstate_starttime;
 114         self.animstate_endtime = oldself.animstate_endtime;
 115         self.animstate_override = oldself.animstate_override;
 116         self.animstate_looping = oldself.animstate_looping;
 117         self.frame = oldself.frame;
 118         self.dead_frame = oldself.dead_frame;
 119         self.pain_finished = oldself.pain_finished;
 120         self.health = oldself.health;
 121         self.armorvalue = oldself.armorvalue;
 122         self.armortype = oldself.armortype;
 123         self.model = oldself.model;
 124         self.modelindex = oldself.modelindex;
 125         self.modelindex_lod0 = oldself.modelindex_lod0;
 126         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 127         self.modelindex_lod1 = oldself.modelindex_lod1;
 128         self.modelindex_lod2 = oldself.modelindex_lod2;
 129         self.skinindex = oldself.skinindex;
 130         self.species = oldself.species;
 131         self.movetype = oldself.movetype;
 132         self.nextthink = oldself.nextthink;
 133         self.solid = oldself.solid;
 134         self.ballistics_density = oldself.ballistics_density;
 135         self.takedamage = oldself.takedamage;
 136         self.think = oldself.think;
 137         self.customizeentityforclient = oldself.customizeentityforclient;
 138         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 139         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 140         if (keepvelocity == 1)
 141                 self.velocity = oldself.velocity;
 142         self.oldvelocity = self.velocity;
 143         self.fade_time = oldself.fade_time;
 144         self.fade_rate = oldself.fade_rate;
 145         //self.weapon = oldself.weapon;
 146         setorigin(self, oldself.origin);
 147         setsize(self, oldself.mins, oldself.maxs);
 148         self.prevorigin = oldself.origin;
 149         self.reset = SUB_Remove;
 150
 151         Drag_MoveDrag(oldself, self);
 152
 153         self = oldself;
 154 }
 155
 156 float player_getspecies()
 157 {
 158         float s;
 159         get_model_parameters(self.model, self.skinindex);
 160         s = get_model_parameters_species;
 161         get_model_parameters(string_null, 0);
 162         if(s < 0)
 163                 return SPECIES_HUMAN;
 164         return s;
 165 }
 166
 167 void player_setupanimsformodel()
 168 {
 169         local string animfilename;
 170         local float animfile;
 171         // defaults for legacy .zym models without animinfo files
 172         self.anim_die1 = '0 1 0.5'; // 2 seconds
 173         self.anim_die2 = '1 1 0.5'; // 2 seconds
 174         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 175         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 176         self.anim_duckwalk = '4 1 1';
 177         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 178         self.anim_duckidle = '6 1 1';
 179         self.anim_idle = '7 1 1';
 180         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 181         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 182         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 183         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 184         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 185         self.anim_run = '13 1 1';
 186         self.anim_runbackwards = '14 1 1';
 187         self.anim_strafeleft = '15 1 1';
 188         self.anim_straferight = '16 1 1';
 189         self.anim_dead1 = '17 1 1';
 190         self.anim_dead2 = '18 1 1';
 191         self.anim_forwardright = '19 1 1';
 192         self.anim_forwardleft = '20 1 1';
 193         self.anim_backright = '21 1 1';
 194         self.anim_backleft  = '22 1 1';
 195         self.anim_melee = '23 1 1';
 196         self.anim_fly = '24 1 1';
 197         animparseerror = FALSE;
 198         animfilename = strcat(self.model, ".animinfo");
 199         animfile = fopen(animfilename, FILE_READ);
 200         if (animfile >= 0)
 201         {
 202                 self.anim_die1         = animparseline(animfile);
 203                 self.anim_die2         = animparseline(animfile);
 204                 self.anim_draw         = animparseline(animfile);
 205                 self.anim_duck         = animparseline(animfile);
 206                 self.anim_duckwalk     = animparseline(animfile);
 207                 self.anim_duckjump     = animparseline(animfile);
 208                 self.anim_duckidle     = animparseline(animfile);
 209                 self.anim_idle         = animparseline(animfile);
 210                 self.anim_jump         = animparseline(animfile);
 211                 self.anim_pain1        = animparseline(animfile);
 212                 self.anim_pain2        = animparseline(animfile);
 213                 self.anim_shoot        = animparseline(animfile);
 214                 self.anim_taunt        = animparseline(animfile);
 215                 self.anim_run          = animparseline(animfile);
 216                 self.anim_runbackwards = animparseline(animfile);
 217                 self.anim_strafeleft   = animparseline(animfile);
 218                 self.anim_straferight  = animparseline(animfile);
 219                 self.anim_forwardright = animparseline(animfile);
 220                 self.anim_forwardleft  = animparseline(animfile);
 221                 self.anim_backright    = animparseline(animfile);
 222                 self.anim_backleft     = animparseline(animfile);
 223                 self.anim_melee        = animparseline(animfile);
 224                 self.anim_fly          = animparseline(animfile);
 225                 fclose(animfile);
 226
 227                 // derived anims
 228                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 229                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 230
 231                 if (animparseerror)
 232                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 233         }
 234         else
 235                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 236         // reset animstate now
 237         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 238 };
 239
 240 void player_anim (void)
 241 {
 242         updateanim(self);
 243         if (self.weaponentity)
 244                 updateanim(self.weaponentity);
 245
 246         if (self.deadflag != DEAD_NO)
 247         {
 248                 if (time > self.animstate_endtime)
 249                 {
 250                         if (self.maxs_z > 5)
 251                         {
 252                                 self.maxs_z = 5;
 253                                 setsize(self, self.mins, self.maxs);
 254                         }
 255                         self.frame = self.dead_frame;
 256                 }
 257                 return;
 258         }
 259
 260         if (!self.animstate_override)
 261         {
 262                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 263                 {
 264                         if((self.animstate_startframe == self.anim_jump_x && time - self.animstate_starttime >= 21/25) || (self.animstate_startframe == self.anim_duckjump_x && time - self.animstate_starttime >= 21/25))
 265                                 setanim(self, self.anim_fly, TRUE, FALSE, FALSE);
 266
 267                         if(self.animstate_startframe != self.anim_fly_x) // no tracing if we're in the fly anim
 268                         {
 269                                 if (self.crouch && self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 270                                 {
 271                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 272                                         if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x) // don't get stuck on idle animation in midair
 273                                         {
 274                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 275                                                 self.restart_jump = FALSE;
 276                                         }
 277                                 }
 278                                 else if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 279                                 {
 280                                         traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 281                                         if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x) // don't get stuck on idle animation in midair
 282                                         {
 283                                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 284                                                 self.restart_jump = FALSE;
 285                                         }
 286                                 }
 287                         }
 288                 }
 289                 else if (self.crouch)
 290                 {
 291                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 292                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 293                         else
 294                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 295                 }
 296                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 297                 {
 298                         if (self.movement_x > 0 && self.movement_y == 0)
 299                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x < 0 && self.movement_y == 0)
 301                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x == 0 && self.movement_y > 0)
 303                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x == 0 && self.movement_y < 0)
 305                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 306                         else if (self.movement_x > 0 && self.movement_y > 0)
 307                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 308                         else if (self.movement_x > 0 && self.movement_y < 0)
 309                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 310                         else if (self.movement_x < 0 && self.movement_y > 0)
 311                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 312                         else if (self.movement_x < 0 && self.movement_y < 0)
 313                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 314                         else
 315                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 316                 }
 317                 else
 318                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 319         }
 320
 321         if (self.weaponentity)
 322         if (!self.weaponentity.animstate_override)
 323                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 324 }
 325
 326 void SpawnThrownWeapon (vector org, float w)
 327 {
 328         if(g_minstagib)
 329         if(self.ammo_cells <= 0)
 330                 return;
 331
 332         if(g_pinata)
 333         {
 334                 float j;
 335                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 336                 {
 337                         if(self.weapons & W_WeaponBit(j))
 338                                 if(W_IsWeaponThrowable(j))
 339                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 340                 }
 341         }
 342         else
 343         {
 344                 if(W_IsWeaponThrowable(self.weapon))
 345                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 346         }
 347 }
 348
 349 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 350 {
 351         local float take, save;
 352         vector v;
 353         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 354
 355         // damage resistance (ignore most of the damage from a bullet or similar)
 356         damage = max(damage - 5, 1);
 357
 358         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 359         take = v_x;
 360         save = v_y;
 361
 362         if(sound_allowed(MSG_BROADCAST, attacker))
 363         {
 364                 if (save > 10)
 365                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 366                 else if (take > 30)
 367                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 368                 else if (take > 10)
 369                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 370         }
 371
 372         if (take > 50)
 373                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 374         if (take > 100)
 375                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 376
 377         if (!(self.flags & FL_GODMODE))
 378         {
 379                 self.armorvalue = self.armorvalue - save;
 380                 self.health = self.health - take;
 381                 // pause regeneration for 5 seconds
 382                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 383         }
 384         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 385         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 386         self.dmg_inflictor = inflictor;
 387
 388         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 389         {
 390                 // don't use any animations as a gib
 391                 self.frame = 0;
 392                 self.dead_frame = 0;
 393                 // view just above the floor
 394                 self.view_ofs = '0 0 4';
 395
 396                 Violence_GibSplash(self, 1, 1, attacker);
 397                 self.modelindex = 0; // restore later
 398                 self.solid = SOLID_NOT; // restore later
 399         }
 400 }
 401
 402 void ClientKill_Now_TeamChange();
 403 void freezetag_CheckWinner();
 404
 405 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 406 {
 407         local float take, save, waves, sdelay, dh, da, j;
 408         vector v;
 409         float valid_damage_for_weaponstats;
 410         float excess;
 411
 412         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 413                 return;
 414
 415         dh = max(self.health, 0);
 416         da = max(self.armorvalue, 0);
 417
 418         if(!DEATH_ISSPECIAL(deathtype))
 419         {
 420                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 421                 if(self != attacker)
 422                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 423         }
 424
 425         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 426         {
 427                 // tuba causes blood to come out of the ears
 428                 vector ear1, ear2;
 429                 vector d;
 430                 float f;
 431                 ear1 = self.origin;
 432                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 433                 ear2 = ear1;
 434                 makevectors(self.angles);
 435                 ear1 += v_right * -10;
 436                 ear2 += v_right * +10;
 437                 d = inflictor.origin - self.origin;
 438                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 439                 force = v_right * vlen(force);
 440                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 441                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 442                 if(f > 0)
 443                 {
 444                         hitloc = ear1;
 445                         force = force * -1;
 446                 }
 447                 else
 448                 {
 449                         hitloc = ear2;
 450                         // force is already good
 451                 }
 452         }
 453         else
 454                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 455
 456         if (!g_minstagib)
 457         {
 458                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 459                 take = v_x;
 460                 save = v_y;
 461         }
 462         else
 463         {
 464                 save = 0;
 465                 take = damage;
 466         }
 467
 468         frag_inflictor = inflictor;
 469         frag_attacker = attacker;
 470         frag_target = self;
 471         damage_take = take;
 472         damage_save = save;
 473         damage_force = force;
 474         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 475         take = bound(0, damage_take, self.health);
 476         save = bound(0, damage_save, self.armorvalue);
 477         excess = max(0, damage - take - save);
 478
 479         if(sound_allowed(MSG_BROADCAST, attacker))
 480         {
 481                 if (save > 10)
 482                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 483                 else if (take > 30)
 484                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 485                 else if (take > 10)
 486                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 487         }
 488
 489         if (take > 50)
 490                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 491         if (take > 100)
 492                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 493
 494         if (time >= self.spawnshieldtime)
 495         {
 496                 if (!(self.flags & FL_GODMODE))
 497                 {
 498                         self.armorvalue = self.armorvalue - save;
 499                         self.health = self.health - take;
 500                         // pause regeneration for 5 seconds
 501                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 502
 503                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 504                         {
 505                                 self.pain_finished = time + 0.5;        //Supajoe
 506
 507                                 if(sv_gentle < 1) {
 508                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 509                                         {
 510                                                 if (!self.animstate_override)
 511                                                 {
 512                                                         if (random() > 0.5)
 513                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 514                                                         else
 515                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 516                                                 }
 517                                         }
 518
 519                                         if(sound_allowed(MSG_BROADCAST, attacker))
 520                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 521                                         if(self.health > 1)
 522                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 523                                         {
 524                                                 if(deathtype == DEATH_FALL)
 525                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 526                                                 else if(self.health > 75) // TODO make a "gentle" version?
 527                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 528                                                 else if(self.health > 50)
 529                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 530                                                 else if(self.health > 25)
 531                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 532                                                 else
 533                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 534                                         }
 535                                 }
 536
 537                                 // throw off bot aim temporarily
 538                                 local float shake;
 539                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 540                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 541                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 542                         }
 543                 }
 544                 else
 545                         self.max_armorvalue += (save + take);
 546         }
 547         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 548         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 549         self.dmg_inflictor = inflictor;
 550
 551         if(attacker == self)
 552         {
 553                 // don't reset pushltime for self damage as it may be an attempt to
 554                 // escape a lava pit or similar
 555                 //self.pushltime = 0;
 556         }
 557         else if(attacker.classname == "player" || attacker.classname == "gib")
 558         {
 559                 self.pusher = attacker;
 560                 self.pushltime = time + autocvar_g_maxpushtime;
 561         }
 562         else if(time < self.pushltime)
 563         {
 564                 attacker = self.pusher;
 565                 self.pushltime = max(self.pushltime, time + 0.6);
 566         }
 567         else
 568                 self.pushltime = 0;
 569
 570         float abot, vbot, awep;
 571         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 572         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 573
 574         valid_damage_for_weaponstats = 0;
 575         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 576         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 577         if(attacker && self != attacker)
 578         if(IsDifferentTeam(self, attacker))
 579         {
 580                 if(DEATH_ISSPECIAL(deathtype))
 581                         awep = attacker.weapon;
 582                 else
 583                         awep = DEATH_WEAPONOF(deathtype);
 584                 valid_damage_for_weaponstats = 1;
 585         }
 586
 587         if(valid_damage_for_weaponstats)
 588         {
 589                 dh = dh - max(self.health, 0);
 590                 da = da - max(self.armorvalue, 0);
 591                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 592         }
 593
 594         if (self.health < 1)
 595         {
 596                 float defer_ClientKill_Now_TeamChange;
 597                 defer_ClientKill_Now_TeamChange = FALSE;
 598
 599                 if(self.alivetime)
 600                 {
 601                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 602                         self.alivetime = 0;
 603                 }
 604
 605                 if(valid_damage_for_weaponstats)
 606                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 607
 608                 if(sv_gentle < 1) // TODO make a "gentle" version?
 609                 if(sound_allowed(MSG_BROADCAST, attacker))
 610                 {
 611                         if(deathtype == DEATH_DROWN)
 612                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 613                         else
 614                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 615                 }
 616
 617                 // get rid of kill indicator
 618                 if(self.killindicator)
 619                 {
 620                         remove(self.killindicator);
 621                         self.killindicator = world;
 622                         if(self.killindicator_teamchange)
 623                                 defer_ClientKill_Now_TeamChange = TRUE;
 624
 625                         if(self.classname == "body")
 626                         if(deathtype == DEATH_KILL)
 627                         {
 628                                 // for the lemmings fans, a small harmless explosion
 629                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 630                         }
 631                 }
 632
 633                 if(!g_freezetag)
 634                 {
 635                         // become fully visible
 636                         self.alpha = 1;
 637                         // throw a weapon
 638                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 639                 }
 640
 641                 // print an obituary message
 642                 Obituary (attacker, inflictor, self, deathtype);
 643                 race_PreDie();
 644                 DropAllRunes(self);
 645
 646         // increment frag counter for used weapon type
 647         float w;
 648         w = DEATH_WEAPONOF(deathtype);
 649         if(WEP_VALID(w))
 650         if(self.classname == "player")
 651         if(self != attacker)
 652         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 653
 654                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 655                 {
 656                         PutClientInServer();
 657                         count_alive_players(); // re-count players
 658                         freezetag_CheckWinner();
 659                         return;
 660                 }
 661
 662                 frag_attacker = attacker;
 663                 frag_inflictor = inflictor;
 664                 frag_target = self;
 665                 MUTATOR_CALLHOOK(PlayerDies);
 666                 weapon_action(self.weapon, WR_PLAYERDEATH);
 667
 668                 if(self.flagcarried)
 669                 {
 670                         if(attacker.classname != "player" && attacker.classname != "gib")
 671                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 672                         else if(attacker.team == self.team)
 673                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 674                         else
 675                                 DropFlag(self.flagcarried, world, attacker);
 676                 }
 677                 if(self.ballcarried && g_nexball)
 678                         DropBall(self.ballcarried, self.origin, self.velocity);
 679                 Portal_ClearAllLater(self);
 680
 681                 if(clienttype(self) == CLIENTTYPE_REAL)
 682                 {
 683                         stuffcmd(self, "-zoom\n");
 684                         self.fixangle = TRUE;
 685                         //msg_entity = self;
 686                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 687                         //WriteAngle (MSG_ONE, self.v_angle_x);
 688                         //WriteAngle (MSG_ONE, self.v_angle_y);
 689                         //WriteAngle (MSG_ONE, 80);
 690                 }
 691
 692                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 693                         ClientKill_Now_TeamChange();
 694
 695                 if(g_arena)
 696                         Spawnqueue_Unmark(self);
 697
 698                 if(g_freezetag)
 699                         return;
 700
 701                 // when we get here, player actually dies
 702                 // clear waypoints (do this AFTER FreezeTag)
 703                 WaypointSprite_PlayerDead();
 704
 705                 // make the corpse upright (not tilted)
 706                 self.angles_x = 0;
 707                 self.angles_z = 0;
 708                 // don't spin
 709                 self.avelocity = '0 0 0';
 710                 // view from the floor
 711                 self.view_ofs = '0 0 -8';
 712                 // toss the corpse
 713                 self.movetype = MOVETYPE_TOSS;
 714                 // shootable corpse
 715                 self.solid = SOLID_CORPSE;
 716                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 717                 // don't stick to the floor
 718                 self.flags &~= FL_ONGROUND;
 719                 // dying animation
 720                 self.deadflag = DEAD_DYING;
 721                 // when to allow respawn
 722                 sdelay = 0;
 723                 waves = 0;
 724                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 725                 if(!sdelay)
 726                 {
 727                         if(g_cts)
 728                                 sdelay = 0; // no respawn delay in CTS
 729                         else
 730                                 sdelay = autocvar_g_respawn_delay;
 731                 }
 732                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 733                 if(!waves)
 734                         waves = autocvar_g_respawn_waves;
 735                 if(waves)
 736                         self.death_time = ceil((time + sdelay) / waves) * waves;
 737                 else
 738                         self.death_time = time + sdelay;
 739                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 740                         self.respawn_countdown = 10; // first number to count down from is 10
 741                 else
 742                         self.respawn_countdown = -1; // do not count down
 743                 if (random() < 0.5)
 744                 {
 745                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 746                         self.dead_frame = self.anim_dead1_x;
 747                 }
 748                 else
 749                 {
 750                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 751                         self.dead_frame = self.anim_dead2_x;
 752                 }
 753                 // set damage function to corpse damage
 754                 self.event_damage = PlayerCorpseDamage;
 755                 // call the corpse damage function just in case it wants to gib
 756                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 757                 // set up to fade out later
 758                 SUB_SetFade (self, time + 6 + random (), 1);
 759
 760                 if(sv_gentle > 0 || autocvar_ekg) {
 761                         // remove corpse
 762                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 763                 }
 764
 765                 // reset fields the weapons may use just in case
 766                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 767                 {
 768                         weapon_action(j, WR_RESETPLAYER);
 769                         ATTACK_FINISHED_FOR(self, j) = 0;
 770                 }
 771         }
 772 }
 773
 774 .float muted; // to be used by prvm_edictset server playernumber muted 1
 775 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 776 // message "": do not say, just test flood control
 777 // return value:
 778 //   1 = accept
 779 //   0 = reject
 780 //  -1 = fake accept
 781 {
 782         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 783         float flood, privatemsgprefixlen;
 784         var .float flood_field;
 785         entity head;
 786         float ret;
 787
 788         if(Ban_MaybeEnforceBan(source))
 789                 return 0;
 790
 791         if(!teamsay && !privatesay)
 792                 if(substring(msgin, 0, 1) == " ")
 793                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 794
 795         msgin = formatmessage(msgin);
 796
 797         if(source.classname != "player")
 798                 colorstr = "^0"; // black for spectators
 799         else if(teams_matter)
 800                 colorstr = Team_ColorCode(source.team);
 801         else
 802                 teamsay = FALSE;
 803
 804         if(intermission_running)
 805                 teamsay = FALSE;
 806
 807         if(msgin != "")
 808                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 809
 810         /*
 811          * using bprint solves this... me stupid
 812         // how can we prevent the message from appearing in a listen server?
 813         // for now, just give "say" back and only handle say_team
 814         if(!teamsay)
 815         {
 816                 clientcommand(self, strcat("say ", msgin));
 817                 return;
 818         }
 819         */
 820
 821         if(autocvar_g_chat_teamcolors)
 822                 namestr = playername(source);
 823         else
 824                 namestr = source.netname;
 825
 826         if(msgin != "")
 827         {
 828                 if(privatesay)
 829                 {
 830                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 831                         privatemsgprefixlen = strlen(msgstr);
 832                         msgstr = strcat(msgstr, msgin);
 833                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 834                         if(autocvar_g_chat_teamcolors)
 835                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 836                         else
 837                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 838                 }
 839                 else if(teamsay)
 840                 {
 841                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 842                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 843                 }
 844                 else
 845                 {
 846                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 847                         cmsgstr = "";
 848                 }
 849                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 850         }
 851         else
 852         {
 853                 msgstr = cmsgstr = "";
 854         }
 855
 856         fullmsgstr = msgstr;
 857         fullcmsgstr = cmsgstr;
 858
 859         // FLOOD CONTROL
 860         flood = 0;
 861         if(floodcontrol)
 862         {
 863                 float flood_spl;
 864                 float flood_burst;
 865                 float flood_lmax;
 866                 float lines;
 867                 if(privatesay)
 868                 {
 869                         flood_spl = autocvar_g_chat_flood_spl_tell;
 870                         flood_burst = autocvar_g_chat_flood_burst_tell;
 871                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 872                         flood_field = floodcontrol_chattell;
 873                 }
 874                 else if(teamsay)
 875                 {
 876                         flood_spl = autocvar_g_chat_flood_spl_team;
 877                         flood_burst = autocvar_g_chat_flood_burst_team;
 878                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 879                         flood_field = floodcontrol_chatteam;
 880                 }
 881                 else
 882                 {
 883                         flood_spl = autocvar_g_chat_flood_spl;
 884                         flood_burst = autocvar_g_chat_flood_burst;
 885                         flood_lmax = autocvar_g_chat_flood_lmax;
 886                         flood_field = floodcontrol_chat;
 887                 }
 888                 flood_burst = max(0, flood_burst - 1);
 889                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 890
 891                 // do flood control for the default line size
 892                 if(msgstr != "")
 893                 {
 894                         getWrappedLine_remaining = msgstr;
 895                         msgstr = "";
 896                         lines = 0;
 897                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 898                         {
 899                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 900                                 ++lines;
 901                         }
 902                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 903
 904                         if(getWrappedLine_remaining != "")
 905                         {
 906                                 msgstr = strcat(msgstr, "\n");
 907                                 flood = 2;
 908                         }
 909
 910                         if(time >= source.flood_field)
 911                         {
 912                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 913                         }
 914                         else
 915                         {
 916                                 flood = 1;
 917                                 msgstr = fullmsgstr;
 918                         }
 919                 }
 920                 else
 921                 {
 922                         if(time >= source.flood_field)
 923                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 924                         else
 925                                 flood = 1;
 926                 }
 927
 928                 if (timeoutStatus == 2) //when game is paused, no flood protection
 929                         source.flood_field = flood = 0;
 930         }
 931
 932         if(flood == 2) // cannot happen for empty msgstr
 933         {
 934                 if(autocvar_g_chat_flood_notify_flooder)
 935                 {
 936                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 937                         sourcecmsgstr = "";
 938                 }
 939                 else
 940                 {
 941                         sourcemsgstr = fullmsgstr;
 942                         sourcecmsgstr = fullcmsgstr;
 943                 }
 944                 cmsgstr = "";
 945         }
 946         else
 947         {
 948                 sourcemsgstr = msgstr;
 949                 sourcecmsgstr = cmsgstr;
 950         }
 951
 952         if(!privatesay)
 953         if(source.classname != "player")
 954         {
 955                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 956                         teamsay = -1; // spectators
 957         }
 958
 959         if(flood)
 960                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 961
 962         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 963         if(privatesay)
 964                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 965
 966         if(source.muted)
 967         {
 968                 // always fake the message
 969                 ret = -1;
 970         }
 971         else if(flood == 1)
 972         {
 973                 if(autocvar_g_chat_flood_notify_flooder)
 974                 {
 975                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 976                         ret = 0;
 977                 }
 978                 else
 979                         ret = -1;
 980         }
 981         else
 982         {
 983                 ret = 1;
 984         }
 985
 986         if(sourcemsgstr != "" && ret != 0)
 987         {
 988                 if(ret < 0) // fake
 989                 {
 990                         sprint(source, sourcemsgstr);
 991                         if(sourcecmsgstr != "" && !privatesay)
 992                                 centerprint(source, sourcecmsgstr);
 993                 }
 994                 else if(privatesay)
 995                 {
 996                         sprint(source, sourcemsgstr);
 997                         sprint(privatesay, msgstr);
 998                         if(cmsgstr != "")
 999                                 centerprint(privatesay, cmsgstr);
1000                 }
1001                 else if(teamsay > 0)
1002                 {
1003                         sprint(source, sourcemsgstr);
1004                         if(sourcecmsgstr != "")
1005                                 centerprint(source, sourcecmsgstr);
1006                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1007                                 if(head != source)
1008                                 {
1009                                         sprint(head, msgstr);
1010                                         if(cmsgstr != "")
1011                                                 centerprint(head, cmsgstr);
1012                                 }
1013                 }
1014                 else if(teamsay < 0)
1015                 {
1016                         sprint(source, sourcemsgstr);
1017                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1018                                 if(head != source)
1019                                         sprint(head, msgstr);
1020                 }
1021                 else if(sourcemsgstr != msgstr)
1022                 {
1023                         sprint(source, sourcemsgstr);
1024                         FOR_EACH_REALCLIENT(head)
1025                                 if(head != source)
1026                                         sprint(head, msgstr);
1027                 }
1028                 else
1029                         bprint(msgstr);
1030         }
1031
1032         return ret;
1033 }
1034
1035 float GetVoiceMessageVoiceType(string type)
1036 {
1037         if(type == "taunt")
1038                 return VOICETYPE_TAUNT;
1039         if(type == "teamshoot")
1040                 return VOICETYPE_LASTATTACKER;
1041         return VOICETYPE_TEAMRADIO;
1042 }
1043
1044 string allvoicesamples;
1045 .string GetVoiceMessageSampleField(string type)
1046 {
1047         GetPlayerSoundSampleField_notFound = 0;
1048         switch(type)
1049         {
1050 #define _VOICEMSG(m) case #m: return playersound_##m;
1051                 ALLVOICEMSGS
1052 #undef _VOICEMSG
1053         }
1054         GetPlayerSoundSampleField_notFound = 1;
1055         return playersound_taunt;
1056 }
1057
1058 .string GetPlayerSoundSampleField(string type)
1059 {
1060         GetPlayerSoundSampleField_notFound = 0;
1061         switch(type)
1062         {
1063 #define _VOICEMSG(m) case #m: return playersound_##m;
1064                 ALLPLAYERSOUNDS
1065 #undef _VOICEMSG
1066         }
1067         GetPlayerSoundSampleField_notFound = 1;
1068         return playersound_taunt;
1069 }
1070
1071 void PrecacheGlobalSound(string samplestring)
1072 {
1073         float n, i;
1074         tokenize_console(samplestring);
1075         n = stof(argv(1));
1076         if(n > 0)
1077         {
1078                 for(i = 1; i <= n; ++i)
1079                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1080         }
1081         else
1082         {
1083                 precache_sound(strcat(argv(0), ".wav"));
1084         }
1085 }
1086
1087 void PrecachePlayerSounds(string f)
1088 {
1089         float fh;
1090         string s;
1091         fh = fopen(f, FILE_READ);
1092         if(fh < 0)
1093                 return;
1094         while((s = fgets(fh)))
1095         {
1096                 if(tokenize_console(s) != 3)
1097                 {
1098                         dprint("Invalid sound info line: ", s, "\n");
1099                         continue;
1100                 }
1101                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1102         }
1103         fclose(fh);
1104
1105         if not(allvoicesamples)
1106         {
1107 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1108                 ALLVOICEMSGS
1109 #undef _VOICEMSG
1110                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1111         }
1112 }
1113
1114 void ClearPlayerSounds()
1115 {
1116 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1117         ALLPLAYERSOUNDS
1118         ALLVOICEMSGS
1119 #undef _VOICEMSG
1120 }
1121
1122 float LoadPlayerSounds(string f, float first)
1123 {
1124         float fh;
1125         string s;
1126         var .string field;
1127         fh = fopen(f, FILE_READ);
1128         if(fh < 0)
1129         {
1130                 dprint("Player sound file not found: ", f, "\n");
1131                 return 0;
1132         }
1133         while((s = fgets(fh)))
1134         {
1135                 if(tokenize_console(s) != 3)
1136                         continue;
1137                 field = GetPlayerSoundSampleField(argv(0));
1138                 if(GetPlayerSoundSampleField_notFound)
1139                         field = GetVoiceMessageSampleField(argv(0));
1140                 if(GetPlayerSoundSampleField_notFound)
1141                         continue;
1142                 if(self.field)
1143                         strunzone(self.field);
1144                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1145         }
1146         fclose(fh);
1147         return 1;
1148 }
1149
1150 .float modelindex_for_playersound;
1151 .float skinindex_for_playersound;
1152 void UpdatePlayerSounds()
1153 {
1154         if(self.modelindex == self.modelindex_for_playersound)
1155         if(self.skinindex == self.skinindex_for_playersound)
1156                 return;
1157         self.modelindex_for_playersound = self.modelindex;
1158         self.skinindex_for_playersound = self.skinindex;
1159         ClearPlayerSounds();
1160         LoadPlayerSounds("sound/player/default.sounds", 1);
1161         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1162                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1163 }
1164
1165 void FakeGlobalSound(string sample, float chan, float voicetype)
1166 {
1167         float n;
1168         float tauntrand;
1169
1170         if(sample == "")
1171                 return;
1172
1173         tokenize_console(sample);
1174         n = stof(argv(1));
1175         if(n > 0)
1176                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1177         else
1178                 sample = strcat(argv(0), ".wav"); // randomization
1179
1180         switch(voicetype)
1181         {
1182                 case VOICETYPE_LASTATTACKER_ONLY:
1183                         break;
1184                 case VOICETYPE_LASTATTACKER:
1185                         if(self.pusher)
1186                         {
1187                                 msg_entity = self;
1188                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1189                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1190                         }
1191                         break;
1192                 case VOICETYPE_TEAMRADIO:
1193                         msg_entity = self;
1194                         if(msg_entity.cvar_cl_voice_directional == 1)
1195                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1196                         else
1197                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1198                         break;
1199                 case VOICETYPE_AUTOTAUNT:
1200                         if(!sv_autotaunt)
1201                                 break;
1202                         if(!sv_taunt)
1203                                 break;
1204                         if(sv_gentle)
1205                                 break;
1206                         tauntrand = random();
1207                         msg_entity = self;
1208                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1209                         {
1210                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1211                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1212                                 else
1213                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1214                         }
1215                         break;
1216                 case VOICETYPE_TAUNT:
1217                         if(self.classname == "player")
1218                                 if(self.deadflag == DEAD_NO)
1219                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1220                         if(!sv_taunt)
1221                                 break;
1222                         if(sv_gentle)
1223                                 break;
1224                         msg_entity = self;
1225                         if (msg_entity.cvar_cl_voice_directional >= 1)
1226                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1227                         else
1228                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1229                         break;
1230                 case VOICETYPE_PLAYERSOUND:
1231                         msg_entity = self;
1232                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1233                         break;
1234                 default:
1235                         backtrace("Invalid voice type!");
1236                         break;
1237         }
1238 }
1239
1240 void GlobalSound(string sample, float chan, float voicetype)
1241 {
1242         float n;
1243         float tauntrand;
1244
1245         if(sample == "")
1246                 return;
1247
1248         tokenize_console(sample);
1249         n = stof(argv(1));
1250         if(n > 0)
1251                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1252         else
1253                 sample = strcat(argv(0), ".wav"); // randomization
1254
1255         switch(voicetype)
1256         {
1257                 case VOICETYPE_LASTATTACKER_ONLY:
1258                         if(self.pusher)
1259                         {
1260                                 msg_entity = self.pusher;
1261                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1262                                 {
1263                                         if(msg_entity.cvar_cl_voice_directional == 1)
1264                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1265                                         else
1266                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1267                                 }
1268                         }
1269                         break;
1270                 case VOICETYPE_LASTATTACKER:
1271                         if(self.pusher)
1272                         {
1273                                 msg_entity = self.pusher;
1274                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1275                                 {
1276                                         if(msg_entity.cvar_cl_voice_directional == 1)
1277                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1278                                         else
1279                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1280                                 }
1281                                 msg_entity = self;
1282                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1283                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1284                         }
1285                         break;
1286                 case VOICETYPE_TEAMRADIO:
1287                         FOR_EACH_REALCLIENT(msg_entity)
1288                                 if(!teams_matter || msg_entity.team == self.team)
1289                                 {
1290                                         if(msg_entity.cvar_cl_voice_directional == 1)
1291                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1292                                         else
1293                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1294                                 }
1295                         break;
1296                 case VOICETYPE_AUTOTAUNT:
1297                         if(!sv_autotaunt)
1298                                 break;
1299                         if(!sv_taunt)
1300                                 break;
1301                         if(sv_gentle)
1302                                 break;
1303                         tauntrand = random();
1304                         FOR_EACH_REALCLIENT(msg_entity)
1305                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1306                                 {
1307                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1308                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1309                                         else
1310                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1311                                 }
1312                         break;
1313                 case VOICETYPE_TAUNT:
1314                         if(self.classname == "player")
1315                                 if(self.deadflag == DEAD_NO)
1316                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1317                         if(!sv_taunt)
1318                                 break;
1319                         if(sv_gentle)
1320                                 break;
1321                         FOR_EACH_REALCLIENT(msg_entity)
1322                         {
1323                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1324                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1325                                 else
1326                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1327                         }
1328                         break;
1329                 case VOICETYPE_PLAYERSOUND:
1330                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1331                         break;
1332                 default:
1333                         backtrace("Invalid voice type!");
1334                         break;
1335         }
1336 }
1337
1338 void PlayerSound(.string samplefield, float chan, float voicetype)
1339 {
1340         GlobalSound(self.samplefield, chan, voicetype);
1341 }
1342
1343 void VoiceMessage(string type, string msg)
1344 {
1345         var .string sample;
1346         float voicetype, ownteam;
1347         float flood;
1348         sample = GetVoiceMessageSampleField(type);
1349
1350         if(GetPlayerSoundSampleField_notFound)
1351         {
1352                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1353                 return;
1354         }
1355
1356         voicetype = GetVoiceMessageVoiceType(type);
1357         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1358
1359         flood = Say(self, ownteam, world, msg, 1);
1360
1361         if (flood > 0)
1362                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1363         else if (flood < 0)
1364                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1365 }
1366
1367 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1368 {
1369 //      show_message
1370 //      0 (00) automove centerprint, admin message
1371 //      1 (01) automove centerprint, no admin message
1372 //      2 (10) no centerprint, admin message
1373 //      3 (11) no centerprint, no admin message
1374
1375         float lockteams_backup;
1376
1377         lockteams_backup = lockteams;  // backup any team lock
1378
1379         lockteams = 0;  // disable locked teams
1380
1381         TeamchangeFrags(client);  // move the players frags
1382         SetPlayerColors(client, team_colour - 1);  // set the players colour
1383         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1384
1385         lockteams = lockteams_backup;  // restore the team lock
1386
1387         LogTeamchange(client.playerid, client.team, type);
1388
1389         if not(show_message & 1) // admin message
1390                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1391
1392         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1393 }