qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126
 127 .float CopyBody_nextthink;
 128 .void(void) CopyBody_think;
 129 void CopyBody_Think(void)
 130 {
 131         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 132         {
 133                 self.CopyBody_think();
 134                 if(wasfreed(self))
 135                         return;
 136                 self.CopyBody_nextthink = self.nextthink;
 137                 self.CopyBody_think = self.think;
 138                 self.think = CopyBody_Think;
 139         }
 140         CSQCMODEL_AUTOUPDATE();
 141         self.nextthink = time;
 142 }
 143 void CopyBody(float keepvelocity)
 144 {
 145         entity oldself;
 146         if (self.effects & EF_NODRAW)
 147                 return;
 148         oldself = self;
 149         self = spawn();
 150         self.enemy = oldself;
 151         self.lip = oldself.lip;
 152         self.colormap = oldself.colormap;
 153         self.iscreature = oldself.iscreature;
 154         self.damagedbycontents = oldself.damagedbycontents;
 155         self.angles = oldself.angles;
 156         self.avelocity = oldself.avelocity;
 157         self.classname = "body";
 158         self.damageforcescale = oldself.damageforcescale;
 159         self.effects = oldself.effects;
 160         self.glowmod = oldself.glowmod;
 161         self.event_damage = oldself.event_damage;
 162         self.animstate_startframe = oldself.animstate_startframe;
 163         self.animstate_numframes = oldself.animstate_numframes;
 164         self.animstate_framerate = oldself.animstate_framerate;
 165         self.animstate_starttime = oldself.animstate_starttime;
 166         self.animstate_endtime = oldself.animstate_endtime;
 167         self.animstate_override = oldself.animstate_override;
 168         self.animstate_looping = oldself.animstate_looping;
 169         self.dphitcontentsmask = oldself.dphitcontentsmask;
 170         self.death_time = oldself.death_time;
 171         self.frame = oldself.frame;
 172         self.pain_finished = oldself.pain_finished;
 173         self.health = oldself.health;
 174         self.armorvalue = oldself.armorvalue;
 175         self.armortype = oldself.armortype;
 176         self.model = oldself.model;
 177         self.modelindex = oldself.modelindex;
 178         self.skin = oldself.skin;
 179         self.species = oldself.species;
 180         self.movetype = oldself.movetype;
 181         self.solid = oldself.solid;
 182         self.ballistics_density = oldself.ballistics_density;
 183         self.takedamage = oldself.takedamage;
 184         self.customizeentityforclient = oldself.customizeentityforclient;
 185         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 186         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 187         if (keepvelocity == 1)
 188                 self.velocity = oldself.velocity;
 189         self.oldvelocity = self.velocity;
 190         self.alpha = oldself.alpha;
 191         self.fade_time = oldself.fade_time;
 192         self.fade_rate = oldself.fade_rate;
 193         //self.weapon = oldself.weapon;
 194         setorigin(self, oldself.origin);
 195         setsize(self, oldself.mins, oldself.maxs);
 196         self.prevorigin = oldself.origin;
 197         self.reset = SUB_Remove;
 198
 199         Drag_MoveDrag(oldself, self);
 200
 201         if(self.colormap <= maxclients && self.colormap > 0)
 202                 self.colormap = 1024 + oldself.clientcolors;
 203
 204         CSQCMODEL_AUTOINIT();
 205         self.CopyBody_nextthink = oldself.nextthink;
 206         self.CopyBody_think = oldself.think;
 207         self.nextthink = time;
 208         self.think = CopyBody_Think;
 209
 210         self = oldself;
 211 }
 212
 213 float player_getspecies()
 214 {
 215         float s;
 216         get_model_parameters(self.model, self.skin);
 217         s = get_model_parameters_species;
 218         get_model_parameters(string_null, 0);
 219         if(s < 0)
 220                 return SPECIES_HUMAN;
 221         return s;
 222 }
 223
 224 void player_setupanimsformodel()
 225 {
 226         // defaults for legacy .zym models without animinfo files
 227         self.anim_die1 = animfixfps(self, '0 1 0.5'); // 2 seconds
 228         self.anim_die2 = animfixfps(self, '1 1 0.5'); // 2 seconds
 229         self.anim_draw = animfixfps(self, '2 1 3');
 230         // self.anim_duck = '3 1 100'; // This anim is broken, use slot 3 as a new free slot in the future ;)
 231         self.anim_duckwalk = animfixfps(self, '4 1 1');
 232         self.anim_duckjump = '5 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 233         self.anim_duckidle = animfixfps(self, '6 1 1');
 234         self.anim_idle = animfixfps(self, '7 1 1');
 235         self.anim_jump = '8 1 100'; // NOTE: zym anims keep playing until changed, so this only has to start the anim, landing will end it
 236         self.anim_pain1 = animfixfps(self, '9 1 2'); // 0.5 seconds
 237         self.anim_pain2 = animfixfps(self, '10 1 2'); // 0.5 seconds
 238         self.anim_shoot = animfixfps(self, '11 1 5'); // analyze models and set framerate
 239         self.anim_taunt = animfixfps(self, '12 1 0.33');
 240         self.anim_run = animfixfps(self, '13 1 1');
 241         self.anim_runbackwards = animfixfps(self, '14 1 1');
 242         self.anim_strafeleft = animfixfps(self, '15 1 1');
 243         self.anim_straferight = animfixfps(self, '16 1 1');
 244         //self.anim_dead1 = animfixfps(self, '17 1 1');
 245         //self.anim_dead2 = animfixfps(self, '18 1 1');
 246         self.anim_forwardright = animfixfps(self, '19 1 1');
 247         self.anim_forwardleft = animfixfps(self, '20 1 1');
 248         self.anim_backright = animfixfps(self, '21 1 1');
 249         self.anim_backleft  = animfixfps(self, '22 1 1');
 250         self.anim_melee = animfixfps(self, '23 1 1');
 251         self.anim_duckwalkbackwards = animfixfps(self, '24 1 1');
 252         self.anim_duckwalkstrafeleft = animfixfps(self, '25 1 1');
 253         self.anim_duckwalkstraferight = animfixfps(self, '26 1 1');
 254         self.anim_duckwalkforwardright = animfixfps(self, '27 1 1');
 255         self.anim_duckwalkforwardleft = animfixfps(self, '28 1 1');
 256         self.anim_duckwalkbackright = animfixfps(self, '29 1 1');
 257         self.anim_duckwalkbackleft  = animfixfps(self, '30 1 1');
 258         // TODO introspect models for finding right "fps" value (1/duration)
 259         // reset animstate now
 260         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 261 }
 262
 263 void player_anim (void)
 264 {
 265         updateanim(self);
 266         if (self.weaponentity)
 267                 updateanim(self.weaponentity);
 268
 269         if (self.deadflag != DEAD_NO)
 270                 return;
 271
 272         if (!self.animstate_override)
 273         {
 274                 if (!(self.flags & FL_ONGROUND) || self.BUTTON_JUMP)
 275                 {
 276                         if (self.crouch)
 277                         {
 278                                 if (self.animstate_startframe != self.anim_duckjump_x) // don't perform another trace if already playing the crouch jump anim
 279                                 {
 280                                         traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 281                                         if(!trace_startsolid && trace_fraction == 1 || !(self.animstate_startframe == self.anim_duckwalk_x || self.animstate_startframe == self.anim_duckidle_x)) // don't get stuck on non-crouch anims
 282                                         {
 283                                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 284                                                 self.restart_jump = FALSE;
 285                                         }
 286                                 }
 287                         }
 288                         else
 289                         {
 290                 if (self.animstate_startframe != self.anim_jump_x) // don't perform another trace if already playing the jump anim
 291                 {
 292                     traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 293                     if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == self.anim_idle_x || (self.animstate_startframe == self.anim_melee_x && time - self.animstate_starttime >= 21/20)) // don't get stuck on idle animation in midair, nor melee after it finished
 294                     {
 295                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 296                         self.restart_jump = FALSE;
 297                     }
 298                 }
 299                         }
 300                 }
 301                 else if (self.crouch)
 302                 {
 303                         if (self.movement_x > 0 && self.movement_y == 0)
 304                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 305                         else if (self.movement_x < 0 && self.movement_y == 0)
 306                                 setanim(self, self.anim_duckwalkbackwards, TRUE, FALSE, FALSE);
 307                         else if (self.movement_x == 0 && self.movement_y > 0)
 308                                 setanim(self, self.anim_duckwalkstraferight, TRUE, FALSE, FALSE);
 309                         else if (self.movement_x == 0 && self.movement_y < 0)
 310                                 setanim(self, self.anim_duckwalkstrafeleft, TRUE, FALSE, FALSE);
 311                         else if (self.movement_x > 0 && self.movement_y > 0)
 312                                 setanim(self, self.anim_duckwalkforwardright, TRUE, FALSE, FALSE);
 313                         else if (self.movement_x > 0 && self.movement_y < 0)
 314                                 setanim(self, self.anim_duckwalkforwardleft, TRUE, FALSE, FALSE);
 315                         else if (self.movement_x < 0 && self.movement_y > 0)
 316                                 setanim(self, self.anim_duckwalkbackright, TRUE, FALSE, FALSE);
 317                         else if (self.movement_x < 0 && self.movement_y < 0)
 318                                 setanim(self, self.anim_duckwalkbackleft, TRUE, FALSE, FALSE);
 319                         else
 320                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 321                 }
 322                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 323                 {
 324                         if (self.movement_x > 0 && self.movement_y == 0)
 325                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 326                         else if (self.movement_x < 0 && self.movement_y == 0)
 327                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 328                         else if (self.movement_x == 0 && self.movement_y > 0)
 329                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 330                         else if (self.movement_x == 0 && self.movement_y < 0)
 331                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 332                         else if (self.movement_x > 0 && self.movement_y > 0)
 333                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x > 0 && self.movement_y < 0)
 335                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x < 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x < 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 340                         else
 341                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 342                 }
 343                 else
 344                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 345         }
 346
 347         if (self.weaponentity)
 348         if (!self.weaponentity.animstate_override)
 349                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 350 }
 351
 352 void SpawnThrownWeapon (vector org, float w)
 353 {
 354         if(g_minstagib)
 355         if(self.ammo_cells <= 0)
 356                 return;
 357
 358         if(g_pinata)
 359         {
 360                 float j;
 361                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 362                 {
 363                         if(self.weapons & W_WeaponBit(j))
 364                                 if(W_IsWeaponThrowable(j))
 365                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 366                 }
 367         }
 368         else
 369         {
 370                 if(W_IsWeaponThrowable(self.weapon))
 371                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 372         }
 373 }
 374
 375 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 376 {
 377         float take, save;
 378         vector v;
 379         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 380
 381         // damage resistance (ignore most of the damage from a bullet or similar)
 382         damage = max(damage - 5, 1);
 383
 384         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 385         take = v_x;
 386         save = v_y;
 387
 388         if(sound_allowed(MSG_BROADCAST, attacker))
 389         {
 390                 if (save > 10)
 391                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 392                 else if (take > 30)
 393                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 394                 else if (take > 10)
 395                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 396         }
 397
 398         if (take > 50)
 399                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 400         if (take > 100)
 401                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 402
 403         if (!(self.flags & FL_GODMODE))
 404         {
 405                 self.armorvalue = self.armorvalue - save;
 406                 self.health = self.health - take;
 407                 // pause regeneration for 5 seconds
 408                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 409         }
 410         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 411         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 412         self.dmg_inflictor = inflictor;
 413
 414         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 415         {
 416                 // don't use any animations as a gib
 417                 self.frame = 0;
 418                 // view just above the floor
 419                 self.view_ofs = '0 0 4';
 420
 421                 Violence_GibSplash(self, 1, 1, attacker);
 422                 self.alpha = -1;
 423                 self.solid = SOLID_NOT; // restore later
 424                 self.takedamage = DAMAGE_NO; // restore later
 425         }
 426 }
 427
 428 void ClientKill_Now_TeamChange();
 429 void freezetag_CheckWinner();
 430
 431 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 432 {
 433         float take, save, waves, sdelay, dh, da, j;
 434         vector v;
 435         float valid_damage_for_weaponstats;
 436         float excess;
 437
 438         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 439                 return;
 440
 441         dh = max(self.health, 0);
 442         da = max(self.armorvalue, 0);
 443
 444         if(!DEATH_ISSPECIAL(deathtype))
 445         {
 446                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 447                 if(self != attacker)
 448                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 449         }
 450
 451         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 452         {
 453                 // tuba causes blood to come out of the ears
 454                 vector ear1, ear2;
 455                 vector d;
 456                 float f;
 457                 ear1 = self.origin;
 458                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 459                 ear2 = ear1;
 460                 makevectors(self.angles);
 461                 ear1 += v_right * -10;
 462                 ear2 += v_right * +10;
 463                 d = inflictor.origin - self.origin;
 464                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 465                 force = v_right * vlen(force);
 466                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 467                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 468                 if(f > 0)
 469                 {
 470                         hitloc = ear1;
 471                         force = force * -1;
 472                 }
 473                 else
 474                 {
 475                         hitloc = ear2;
 476                         // force is already good
 477                 }
 478         }
 479         else
 480                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 481
 482         if (!g_minstagib)
 483         {
 484                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 485                 take = v_x;
 486                 save = v_y;
 487         }
 488         else
 489         {
 490                 save = 0;
 491                 take = damage;
 492         }
 493
 494         frag_inflictor = inflictor;
 495         frag_attacker = attacker;
 496         frag_target = self;
 497         damage_take = take;
 498         damage_save = save;
 499         damage_force = force;
 500         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 501         take = bound(0, damage_take, self.health);
 502         save = bound(0, damage_save, self.armorvalue);
 503         excess = max(0, damage - take - save);
 504
 505         if(sound_allowed(MSG_BROADCAST, attacker))
 506         {
 507                 if (save > 10)
 508                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 509                 else if (take > 30)
 510                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 511                 else if (take > 10)
 512                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 513         }
 514
 515         if (take > 50)
 516                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 517         if (take > 100)
 518                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 519
 520         if (time >= self.spawnshieldtime)
 521         {
 522                 if (!(self.flags & FL_GODMODE))
 523                 {
 524                         self.armorvalue = self.armorvalue - save;
 525                         self.health = self.health - take;
 526                         // pause regeneration for 5 seconds
 527                         if(take)
 528                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 529
 530                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 531                         {
 532                                 self.pain_finished = time + 0.5;        //Supajoe
 533
 534                                 if(sv_gentle < 1) {
 535                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 536                                         {
 537                                                 if (!self.animstate_override)
 538                                                 {
 539                                                         if (random() > 0.5)
 540                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 541                                                         else
 542                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 543                                                 }
 544                                         }
 545
 546                                         if(sound_allowed(MSG_BROADCAST, attacker))
 547                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 548                                         if(self.health > 1)
 549                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 550                                         {
 551                                                 if(deathtype == DEATH_FALL)
 552                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 553                                                 else if(self.health > 75) // TODO make a "gentle" version?
 554                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 555                                                 else if(self.health > 50)
 556                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 557                                                 else if(self.health > 25)
 558                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                                                 else
 560                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                                         }
 562                                 }
 563
 564                                 // throw off bot aim temporarily
 565                                 float shake;
 566                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 567                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 568                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 569                         }
 570                 }
 571                 else
 572                         self.max_armorvalue += (save + take);
 573         }
 574         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 575         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 576         self.dmg_inflictor = inflictor;
 577
 578         if(attacker == self)
 579         {
 580                 // don't reset pushltime for self damage as it may be an attempt to
 581                 // escape a lava pit or similar
 582                 //self.pushltime = 0;
 583         }
 584         else if(attacker.classname == "player")
 585         {
 586                 self.pusher = attacker;
 587                 self.pushltime = time + autocvar_g_maxpushtime;
 588         }
 589         else if(time < self.pushltime)
 590         {
 591                 attacker = self.pusher;
 592                 self.pushltime = max(self.pushltime, time + 0.6);
 593         }
 594         else
 595                 self.pushltime = 0;
 596
 597         float abot, vbot, awep;
 598         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 599         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 600
 601         valid_damage_for_weaponstats = 0;
 602         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 603         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 604         if(attacker && self != attacker)
 605         if(IsDifferentTeam(self, attacker))
 606         {
 607                 if(DEATH_ISSPECIAL(deathtype))
 608                         awep = attacker.weapon;
 609                 else
 610                         awep = DEATH_WEAPONOF(deathtype);
 611                 valid_damage_for_weaponstats = 1;
 612         }
 613
 614         if(valid_damage_for_weaponstats)
 615         {
 616                 dh = dh - max(self.health, 0);
 617                 da = da - max(self.armorvalue, 0);
 618                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 619         }
 620
 621         if (self.health < 1)
 622         {
 623                 float defer_ClientKill_Now_TeamChange;
 624                 defer_ClientKill_Now_TeamChange = FALSE;
 625
 626                 if(self.alivetime)
 627                 {
 628                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 629                         self.alivetime = 0;
 630                 }
 631
 632                 if(valid_damage_for_weaponstats)
 633                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 634
 635                 if(sv_gentle < 1) // TODO make a "gentle" version?
 636                 if(sound_allowed(MSG_BROADCAST, attacker))
 637                 {
 638                         if(deathtype == DEATH_DROWN)
 639                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 640                         else
 641                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 642                 }
 643
 644                 // get rid of kill indicator
 645                 if(self.killindicator)
 646                 {
 647                         remove(self.killindicator);
 648                         self.killindicator = world;
 649                         if(self.killindicator_teamchange)
 650                                 defer_ClientKill_Now_TeamChange = TRUE;
 651
 652                         if(self.classname == "body")
 653                         if(deathtype == DEATH_KILL)
 654                         {
 655                                 // for the lemmings fans, a small harmless explosion
 656                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 657                         }
 658                 }
 659
 660                 if(!g_freezetag)
 661                 {
 662                         // become fully visible
 663                         self.alpha = default_player_alpha;
 664                         // throw a weapon
 665                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 666                 }
 667
 668                 // print an obituary message
 669                 Obituary (attacker, inflictor, self, deathtype);
 670                 race_PreDie();
 671                 DropAllRunes(self);
 672
 673         // increment frag counter for used weapon type
 674         float w;
 675         w = DEATH_WEAPONOF(deathtype);
 676         if(WEP_VALID(w))
 677         if(accuracy_isgooddamage(attacker, self))
 678         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 679
 680                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 681                 {
 682                         PutClientInServer();
 683                         count_alive_players(); // re-count players
 684                         freezetag_CheckWinner();
 685                         return;
 686                 }
 687
 688                 frag_attacker = attacker;
 689                 frag_inflictor = inflictor;
 690                 frag_target = self;
 691                 MUTATOR_CALLHOOK(PlayerDies);
 692                 weapon_action(self.weapon, WR_PLAYERDEATH);
 693
 694                 RemoveGrapplingHook(self);
 695
 696                 if(self.flagcarried)
 697                 {
 698                         if(attacker.classname != "player")
 699                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 700                         else if(attacker.team == self.team)
 701                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 702                         else
 703                                 DropFlag(self.flagcarried, world, attacker);
 704                 }
 705                 Portal_ClearAllLater(self);
 706
 707                 if(clienttype(self) == CLIENTTYPE_REAL)
 708                 {
 709                         stuffcmd(self, "-zoom\n");
 710                         self.fixangle = TRUE;
 711                         //msg_entity = self;
 712                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 713                         //WriteAngle (MSG_ONE, self.v_angle_x);
 714                         //WriteAngle (MSG_ONE, self.v_angle_y);
 715                         //WriteAngle (MSG_ONE, 80);
 716                 }
 717
 718                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 719                         ClientKill_Now_TeamChange();
 720
 721                 if(g_arena)
 722                         Spawnqueue_Unmark(self);
 723
 724                 if(g_freezetag)
 725                         return;
 726
 727                 // when we get here, player actually dies
 728                 // clear waypoints (do this AFTER FreezeTag)
 729                 WaypointSprite_PlayerDead();
 730
 731                 // make the corpse upright (not tilted)
 732                 self.angles_x = 0;
 733                 self.angles_z = 0;
 734                 // don't spin
 735                 self.avelocity = '0 0 0';
 736                 // view from the floor
 737                 self.view_ofs = '0 0 -8';
 738                 // toss the corpse
 739                 self.movetype = MOVETYPE_TOSS;
 740                 // shootable corpse
 741                 self.solid = SOLID_CORPSE;
 742                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 743                 // don't stick to the floor
 744                 self.flags &~= FL_ONGROUND;
 745                 // dying animation
 746                 self.deadflag = DEAD_DYING;
 747                 // when to allow respawn
 748                 sdelay = 0;
 749                 waves = 0;
 750                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 751                 if(!sdelay)
 752                 {
 753                         if(g_cts)
 754                                 sdelay = 0; // no respawn delay in CTS
 755                         else
 756                                 sdelay = autocvar_g_respawn_delay;
 757                 }
 758                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 759                 if(!waves)
 760                         waves = autocvar_g_respawn_waves;
 761                 if(waves)
 762                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 763                 else
 764                         self.respawn_time = time + sdelay;
 765                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 766                         self.respawn_countdown = 10; // first number to count down from is 10
 767                 else
 768                         self.respawn_countdown = -1; // do not count down
 769                 self.death_time = time;
 770                 if (random() < 0.5)
 771                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 772                 else
 773                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 774                 if (self.maxs_z > 5)
 775                 {
 776                         self.maxs_z = 5;
 777                         setsize(self, self.mins, self.maxs);
 778                 }
 779                 // set damage function to corpse damage
 780                 self.event_damage = PlayerCorpseDamage;
 781                 // call the corpse damage function just in case it wants to gib
 782                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 783                 // set up to fade out later
 784                 SUB_SetFade (self, time + 6 + random (), 1);
 785
 786                 if(sv_gentle > 0 || autocvar_ekg) {
 787                         // remove corpse
 788                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 789                 }
 790
 791                 // reset fields the weapons may use just in case
 792                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 793                 {
 794                         weapon_action(j, WR_RESETPLAYER);
 795                         ATTACK_FINISHED_FOR(self, j) = 0;
 796                 }
 797         }
 798 }
 799
 800 .float muted; // to be used by prvm_edictset server playernumber muted 1
 801 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 802 // message "": do not say, just test flood control
 803 // return value:
 804 //   1 = accept
 805 //   0 = reject
 806 //  -1 = fake accept
 807 {
 808         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 809         float flood, privatemsgprefixlen;
 810         var .float flood_field;
 811         entity head;
 812         float ret;
 813
 814         if(Ban_MaybeEnforceBan(source))
 815                 return 0;
 816
 817         if(!teamsay && !privatesay)
 818                 if(substring(msgin, 0, 1) == " ")
 819                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 820
 821         msgin = formatmessage(msgin);
 822
 823         if(source.classname != "player")
 824                 colorstr = "^0"; // black for spectators
 825         else if(teamplay)
 826                 colorstr = Team_ColorCode(source.team);
 827         else
 828                 teamsay = FALSE;
 829
 830         if(intermission_running)
 831                 teamsay = FALSE;
 832
 833         if(msgin != "")
 834                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 835
 836         /*
 837          * using bprint solves this... me stupid
 838         // how can we prevent the message from appearing in a listen server?
 839         // for now, just give "say" back and only handle say_team
 840         if(!teamsay)
 841         {
 842                 clientcommand(self, strcat("say ", msgin));
 843                 return;
 844         }
 845         */
 846
 847         if(autocvar_g_chat_teamcolors)
 848                 namestr = playername(source);
 849         else
 850                 namestr = source.netname;
 851
 852         if(msgin != "")
 853         {
 854                 if(privatesay)
 855                 {
 856                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 857                         privatemsgprefixlen = strlen(msgstr);
 858                         msgstr = strcat(msgstr, msgin);
 859                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 860                         if(autocvar_g_chat_teamcolors)
 861                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 862                         else
 863                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 864                 }
 865                 else if(teamsay)
 866                 {
 867                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 868                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 869                 }
 870                 else
 871                 {
 872                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 873                         cmsgstr = "";
 874                 }
 875                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 876         }
 877         else
 878         {
 879                 msgstr = cmsgstr = "";
 880         }
 881
 882         fullmsgstr = msgstr;
 883         fullcmsgstr = cmsgstr;
 884
 885         // FLOOD CONTROL
 886         flood = 0;
 887         if(floodcontrol)
 888         {
 889                 float flood_spl;
 890                 float flood_burst;
 891                 float flood_lmax;
 892                 float lines;
 893                 if(privatesay)
 894                 {
 895                         flood_spl = autocvar_g_chat_flood_spl_tell;
 896                         flood_burst = autocvar_g_chat_flood_burst_tell;
 897                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 898                         flood_field = floodcontrol_chattell;
 899                 }
 900                 else if(teamsay)
 901                 {
 902                         flood_spl = autocvar_g_chat_flood_spl_team;
 903                         flood_burst = autocvar_g_chat_flood_burst_team;
 904                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 905                         flood_field = floodcontrol_chatteam;
 906                 }
 907                 else
 908                 {
 909                         flood_spl = autocvar_g_chat_flood_spl;
 910                         flood_burst = autocvar_g_chat_flood_burst;
 911                         flood_lmax = autocvar_g_chat_flood_lmax;
 912                         flood_field = floodcontrol_chat;
 913                 }
 914                 flood_burst = max(0, flood_burst - 1);
 915                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 916
 917                 // do flood control for the default line size
 918                 if(msgstr != "")
 919                 {
 920                         getWrappedLine_remaining = msgstr;
 921                         msgstr = "";
 922                         lines = 0;
 923                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 924                         {
 925                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 926                                 ++lines;
 927                         }
 928                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 929
 930                         if(getWrappedLine_remaining != "")
 931                         {
 932                                 msgstr = strcat(msgstr, "\n");
 933                                 flood = 2;
 934                         }
 935
 936                         if(time >= source.flood_field)
 937                         {
 938                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 939                         }
 940                         else
 941                         {
 942                                 flood = 1;
 943                                 msgstr = fullmsgstr;
 944                         }
 945                 }
 946                 else
 947                 {
 948                         if(time >= source.flood_field)
 949                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 950                         else
 951                                 flood = 1;
 952                 }
 953
 954                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 955                         source.flood_field = flood = 0;
 956         }
 957
 958         if(flood == 2) // cannot happen for empty msgstr
 959         {
 960                 if(autocvar_g_chat_flood_notify_flooder)
 961                 {
 962                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 963                         sourcecmsgstr = "";
 964                 }
 965                 else
 966                 {
 967                         sourcemsgstr = fullmsgstr;
 968                         sourcecmsgstr = fullcmsgstr;
 969                 }
 970                 cmsgstr = "";
 971         }
 972         else
 973         {
 974                 sourcemsgstr = msgstr;
 975                 sourcecmsgstr = cmsgstr;
 976         }
 977
 978         if(!privatesay)
 979         if(source.classname != "player")
 980         {
 981                 if not(intermission_running)
 982                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 983                                 teamsay = -1; // spectators
 984         }
 985
 986         if(flood)
 987                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 988
 989         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 990         if(privatesay)
 991                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 992
 993         if(source.muted)
 994         {
 995                 // always fake the message
 996                 ret = -1;
 997         }
 998         else if(flood == 1)
 999         {
1000                 if(autocvar_g_chat_flood_notify_flooder)
1001                 {
1002                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1003                         ret = 0;
1004                 }
1005                 else
1006                         ret = -1;
1007         }
1008         else
1009         {
1010                 ret = 1;
1011         }
1012
1013         if(sourcemsgstr != "" && ret != 0)
1014         {
1015                 if(ret < 0) // faked message, because the player is muted
1016                 {
1017                         sprint(source, sourcemsgstr);
1018                         if(sourcecmsgstr != "" && !privatesay)
1019                                 centerprint(source, sourcecmsgstr);
1020                 }
1021                 else if(privatesay) // private message, between 2 people only, not sent to server console
1022                 {
1023                         sprint(source, sourcemsgstr);
1024                         sprint(privatesay, msgstr);
1025                         if(cmsgstr != "")
1026                                 centerprint(privatesay, cmsgstr);
1027                 }
1028                 else if(teamsay > 0) // team message, only sent to team mates
1029                 {
1030                         sprint(source, sourcemsgstr);
1031                         //print(msgstr); // send to server console too
1032                         if(sourcecmsgstr != "")
1033                                 centerprint(source, sourcecmsgstr);
1034                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1035                                 if(head != source)
1036                                 {
1037                                         sprint(head, msgstr);
1038                                         if(cmsgstr != "")
1039                                                 centerprint(head, cmsgstr);
1040                                 }
1041                 }
1042                 else if(teamsay < 0) // spectator message, only sent to spectators
1043                 {
1044                         sprint(source, sourcemsgstr);
1045                         //print(msgstr); // send to server console too
1046                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1047                                 if(head != source)
1048                                         sprint(head, msgstr);
1049                 }
1050                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
1051                 {
1052                         sprint(source, sourcemsgstr);
1053                         //print(msgstr); // send to server console too
1054                         FOR_EACH_REALCLIENT(head)
1055                                 if(head != source)
1056                                         sprint(head, msgstr);
1057                 }
1058                 else
1059                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
1060         }
1061
1062         return ret;
1063 }
1064
1065 float GetVoiceMessageVoiceType(string type)
1066 {
1067         if(type == "taunt")
1068                 return VOICETYPE_TAUNT;
1069         if(type == "teamshoot")
1070                 return VOICETYPE_LASTATTACKER;
1071         return VOICETYPE_TEAMRADIO;
1072 }
1073
1074 string allvoicesamples;
1075 .string GetVoiceMessageSampleField(string type)
1076 {
1077         GetPlayerSoundSampleField_notFound = 0;
1078         switch(type)
1079         {
1080 #define _VOICEMSG(m) case #m: return playersound_##m;
1081                 ALLVOICEMSGS
1082 #undef _VOICEMSG
1083         }
1084         GetPlayerSoundSampleField_notFound = 1;
1085         return playersound_taunt;
1086 }
1087
1088 .string GetPlayerSoundSampleField(string type)
1089 {
1090         GetPlayerSoundSampleField_notFound = 0;
1091         switch(type)
1092         {
1093 #define _VOICEMSG(m) case #m: return playersound_##m;
1094                 ALLPLAYERSOUNDS
1095 #undef _VOICEMSG
1096         }
1097         GetPlayerSoundSampleField_notFound = 1;
1098         return playersound_taunt;
1099 }
1100
1101 void PrecacheGlobalSound(string samplestring)
1102 {
1103         float n, i;
1104         tokenize_console(samplestring);
1105         n = stof(argv(1));
1106         if(n > 0)
1107         {
1108                 for(i = 1; i <= n; ++i)
1109                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1110         }
1111         else
1112         {
1113                 precache_sound(strcat(argv(0), ".wav"));
1114         }
1115 }
1116
1117 void PrecachePlayerSounds(string f)
1118 {
1119         float fh;
1120         string s;
1121         fh = fopen(f, FILE_READ);
1122         if(fh < 0)
1123                 return;
1124         while((s = fgets(fh)))
1125         {
1126                 if(tokenize_console(s) != 3)
1127                 {
1128                         dprint("Invalid sound info line: ", s, "\n");
1129                         continue;
1130                 }
1131                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1132         }
1133         fclose(fh);
1134
1135         if not(allvoicesamples)
1136         {
1137 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1138                 ALLVOICEMSGS
1139 #undef _VOICEMSG
1140                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1141         }
1142 }
1143
1144 void ClearPlayerSounds()
1145 {
1146 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1147         ALLPLAYERSOUNDS
1148         ALLVOICEMSGS
1149 #undef _VOICEMSG
1150 }
1151
1152 float LoadPlayerSounds(string f, float first)
1153 {
1154         float fh;
1155         string s;
1156         var .string field;
1157         fh = fopen(f, FILE_READ);
1158         if(fh < 0)
1159         {
1160                 dprint("Player sound file not found: ", f, "\n");
1161                 return 0;
1162         }
1163         while((s = fgets(fh)))
1164         {
1165                 if(tokenize_console(s) != 3)
1166                         continue;
1167                 field = GetPlayerSoundSampleField(argv(0));
1168                 if(GetPlayerSoundSampleField_notFound)
1169                         field = GetVoiceMessageSampleField(argv(0));
1170                 if(GetPlayerSoundSampleField_notFound)
1171                         continue;
1172                 if(self.field)
1173                         strunzone(self.field);
1174                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1175         }
1176         fclose(fh);
1177         return 1;
1178 }
1179
1180 .float modelindex_for_playersound;
1181 .float skin_for_playersound;
1182 void UpdatePlayerSounds()
1183 {
1184         if(self.modelindex == self.modelindex_for_playersound)
1185         if(self.skin == self.skin_for_playersound)
1186                 return;
1187         self.modelindex_for_playersound = self.modelindex;
1188         self.skin_for_playersound = self.skin;
1189         ClearPlayerSounds();
1190         LoadPlayerSounds("sound/player/default.sounds", 1);
1191         if(!autocvar_g_debug_defaultsounds)
1192                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1193                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1194 }
1195
1196 void FakeGlobalSound(string sample, float chan, float voicetype)
1197 {
1198         float n;
1199         float tauntrand;
1200
1201         if(sample == "")
1202                 return;
1203
1204         tokenize_console(sample);
1205         n = stof(argv(1));
1206         if(n > 0)
1207                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1208         else
1209                 sample = strcat(argv(0), ".wav"); // randomization
1210
1211         switch(voicetype)
1212         {
1213                 case VOICETYPE_LASTATTACKER_ONLY:
1214                         break;
1215                 case VOICETYPE_LASTATTACKER:
1216                         if(self.pusher)
1217                         {
1218                                 msg_entity = self;
1219                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1220                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1221                         }
1222                         break;
1223                 case VOICETYPE_TEAMRADIO:
1224                         msg_entity = self;
1225                         if(msg_entity.cvar_cl_voice_directional == 1)
1226                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1227                         else
1228                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1229                         break;
1230                 case VOICETYPE_AUTOTAUNT:
1231                         if(!sv_autotaunt)
1232                                 break;
1233                         if(!sv_taunt)
1234                                 break;
1235                         if(sv_gentle)
1236                                 break;
1237                         tauntrand = random();
1238                         msg_entity = self;
1239                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1240                         {
1241                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1242                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1243                                 else
1244                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1245                         }
1246                         break;
1247                 case VOICETYPE_TAUNT:
1248                         if(self.classname == "player")
1249                                 if(self.deadflag == DEAD_NO)
1250                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1251                         if(!sv_taunt)
1252                                 break;
1253                         if(sv_gentle)
1254                                 break;
1255                         msg_entity = self;
1256                         if (msg_entity.cvar_cl_voice_directional >= 1)
1257                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1258                         else
1259                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1260                         break;
1261                 case VOICETYPE_PLAYERSOUND:
1262                         msg_entity = self;
1263                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1264                         break;
1265                 default:
1266                         backtrace("Invalid voice type!");
1267                         break;
1268         }
1269 }
1270
1271 void GlobalSound(string sample, float chan, float voicetype)
1272 {
1273         float n;
1274         float tauntrand;
1275
1276         if(sample == "")
1277                 return;
1278
1279         tokenize_console(sample);
1280         n = stof(argv(1));
1281         if(n > 0)
1282                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1283         else
1284                 sample = strcat(argv(0), ".wav"); // randomization
1285
1286         switch(voicetype)
1287         {
1288                 case VOICETYPE_LASTATTACKER_ONLY:
1289                         if(self.pusher)
1290                         {
1291                                 msg_entity = self.pusher;
1292                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1293                                 {
1294                                         if(msg_entity.cvar_cl_voice_directional == 1)
1295                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1296                                         else
1297                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1298                                 }
1299                         }
1300                         break;
1301                 case VOICETYPE_LASTATTACKER:
1302                         if(self.pusher)
1303                         {
1304                                 msg_entity = self.pusher;
1305                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1306                                 {
1307                                         if(msg_entity.cvar_cl_voice_directional == 1)
1308                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1309                                         else
1310                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1311                                 }
1312                                 msg_entity = self;
1313                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1314                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1315                         }
1316                         break;
1317                 case VOICETYPE_TEAMRADIO:
1318                         FOR_EACH_REALCLIENT(msg_entity)
1319                                 if(!teamplay || msg_entity.team == self.team)
1320                                 {
1321                                         if(msg_entity.cvar_cl_voice_directional == 1)
1322                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1323                                         else
1324                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1325                                 }
1326                         break;
1327                 case VOICETYPE_AUTOTAUNT:
1328                         if(!sv_autotaunt)
1329                                 break;
1330                         if(!sv_taunt)
1331                                 break;
1332                         if(sv_gentle)
1333                                 break;
1334                         tauntrand = random();
1335                         FOR_EACH_REALCLIENT(msg_entity)
1336                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1337                                 {
1338                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1339                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1340                                         else
1341                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1342                                 }
1343                         break;
1344                 case VOICETYPE_TAUNT:
1345                         if(self.classname == "player")
1346                                 if(self.deadflag == DEAD_NO)
1347                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1348                         if(!sv_taunt)
1349                                 break;
1350                         if(sv_gentle)
1351                                 break;
1352                         FOR_EACH_REALCLIENT(msg_entity)
1353                         {
1354                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1355                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1356                                 else
1357                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1358                         }
1359                         break;
1360                 case VOICETYPE_PLAYERSOUND:
1361                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1362                         break;
1363                 default:
1364                         backtrace("Invalid voice type!");
1365                         break;
1366         }
1367 }
1368
1369 void PlayerSound(.string samplefield, float chan, float voicetype)
1370 {
1371         GlobalSound(self.samplefield, chan, voicetype);
1372 }
1373
1374 void VoiceMessage(string type, string msg)
1375 {
1376         var .string sample;
1377         float voicetype, ownteam;
1378         float flood;
1379         sample = GetVoiceMessageSampleField(type);
1380
1381         if(GetPlayerSoundSampleField_notFound)
1382         {
1383                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1384                 return;
1385         }
1386
1387         voicetype = GetVoiceMessageVoiceType(type);
1388         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1389
1390         flood = Say(self, ownteam, world, msg, 1);
1391
1392         if (flood > 0)
1393                 GlobalSound(self.sample, CH_VOICE, voicetype);
1394         else if (flood < 0)
1395                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1396 }
1397
1398 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1399 {
1400 //      show_message
1401 //      0 (00) automove centerprint, admin message
1402 //      1 (01) automove centerprint, no admin message
1403 //      2 (10) no centerprint, admin message
1404 //      3 (11) no centerprint, no admin message
1405
1406         float lockteams_backup;
1407
1408         lockteams_backup = lockteams;  // backup any team lock
1409
1410         lockteams = 0;  // disable locked teams
1411
1412         TeamchangeFrags(client);  // move the players frags
1413         SetPlayerColors(client, team_colour - 1);  // set the players colour
1414         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1415
1416         lockteams = lockteams_backup;  // restore the team lock
1417
1418         LogTeamchange(client.playerid, client.team, type);
1419
1420         if not(show_message & 1) // admin message
1421                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1422
1423         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1424 }