qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_killfile != "" || autocvar_sv_weaponstats_damagefile != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(autocvar_sv_weaponstats_killfile != "")
  22         {
  23                 fh = fopen(autocvar_sv_weaponstats_killfile, FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(autocvar_sv_weaponstats_damagefile != "")
  43         {
  44                 fh = fopen(autocvar_sv_weaponstats_damagefile, FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.glowmod = oldself.glowmod;
 115         self.iscreature = oldself.iscreature;
 116         self.angles = oldself.angles;
 117         self.avelocity = oldself.avelocity;
 118         self.classname = "body";
 119         self.damageforcescale = oldself.damageforcescale;
 120         self.effects = oldself.effects;
 121         self.event_damage = oldself.event_damage;
 122         self.animstate_startframe = oldself.animstate_startframe;
 123         self.animstate_numframes = oldself.animstate_numframes;
 124         self.animstate_framerate = oldself.animstate_framerate;
 125         self.animstate_starttime = oldself.animstate_starttime;
 126         self.animstate_endtime = oldself.animstate_endtime;
 127         self.animstate_override = oldself.animstate_override;
 128         self.animstate_looping = oldself.animstate_looping;
 129         self.frame = oldself.frame;
 130         self.dead_frame = oldself.dead_frame;
 131         self.pain_finished = oldself.pain_finished;
 132         self.health = oldself.health;
 133         self.armorvalue = oldself.armorvalue;
 134         self.armortype = oldself.armortype;
 135         self.model = oldself.model;
 136         self.modelindex = oldself.modelindex;
 137         self.modelindex_lod0 = oldself.modelindex_lod0;
 138         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 139         self.modelindex_lod1 = oldself.modelindex_lod1;
 140         self.modelindex_lod2 = oldself.modelindex_lod2;
 141         self.skinindex = oldself.skinindex;
 142         self.species = oldself.species;
 143         self.movetype = oldself.movetype;
 144         self.nextthink = oldself.nextthink;
 145         self.solid = oldself.solid;
 146         self.ballistics_density = oldself.ballistics_density;
 147         self.takedamage = oldself.takedamage;
 148         self.think = oldself.think;
 149         self.customizeentityforclient = oldself.customizeentityforclient;
 150         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 151         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 152         if (keepvelocity == 1)
 153                 self.velocity = oldself.velocity;
 154         self.oldvelocity = self.velocity;
 155         self.fade_time = oldself.fade_time;
 156         self.fade_rate = oldself.fade_rate;
 157         //self.weapon = oldself.weapon;
 158         setorigin(self, oldself.origin);
 159         setsize(self, oldself.mins, oldself.maxs);
 160         self.prevorigin = oldself.origin;
 161         self.reset = SUB_Remove;
 162
 163         Drag_MoveDrag(oldself, self);
 164
 165         self = oldself;
 166 }
 167
 168 float player_getspecies()
 169 {
 170         float s;
 171         get_model_parameters(self.model, self.skinindex);
 172         s = get_model_parameters_species;
 173         get_model_parameters(string_null, 0);
 174         if(s < 0)
 175                 return SPECIES_HUMAN;
 176         return s;
 177 }
 178
 179 void player_setupanimsformodel()
 180 {
 181         local string animfilename;
 182         local float animfile;
 183         // defaults for legacy .zym models without animinfo files
 184         self.anim_die1 = '0 1 0.5'; // 2 seconds
 185         self.anim_die2 = '1 1 0.5'; // 2 seconds
 186         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 187         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 188         self.anim_duckwalk = '4 1 1';
 189         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 190         self.anim_duckidle = '6 1 1';
 191         self.anim_idle = '7 1 1';
 192         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 193         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 194         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 195         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 196         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 197         self.anim_run = '13 1 1';
 198         self.anim_runbackwards = '14 1 1';
 199         self.anim_strafeleft = '15 1 1';
 200         self.anim_straferight = '16 1 1';
 201         self.anim_dead1 = '17 1 1';
 202         self.anim_dead2 = '18 1 1';
 203         self.anim_forwardright = '19 1 1';
 204         self.anim_forwardleft = '20 1 1';
 205         self.anim_backright = '21 1 1';
 206         self.anim_backleft  = '22 1 1';
 207         animparseerror = FALSE;
 208         animfilename = strcat(self.model, ".animinfo");
 209         animfile = fopen(animfilename, FILE_READ);
 210         if (animfile >= 0)
 211         {
 212                 self.anim_die1         = animparseline(animfile);
 213                 self.anim_die2         = animparseline(animfile);
 214                 self.anim_draw         = animparseline(animfile);
 215                 self.anim_duck         = animparseline(animfile);
 216                 self.anim_duckwalk     = animparseline(animfile);
 217                 self.anim_duckjump     = animparseline(animfile);
 218                 self.anim_duckidle     = animparseline(animfile);
 219                 self.anim_idle         = animparseline(animfile);
 220                 self.anim_jump         = animparseline(animfile);
 221                 self.anim_pain1        = animparseline(animfile);
 222                 self.anim_pain2        = animparseline(animfile);
 223                 self.anim_shoot        = animparseline(animfile);
 224                 self.anim_taunt        = animparseline(animfile);
 225                 self.anim_run          = animparseline(animfile);
 226                 self.anim_runbackwards = animparseline(animfile);
 227                 self.anim_strafeleft   = animparseline(animfile);
 228                 self.anim_straferight  = animparseline(animfile);
 229                 self.anim_forwardright = animparseline(animfile);
 230                 self.anim_forwardleft  = animparseline(animfile);
 231                 self.anim_backright    = animparseline(animfile);
 232                 self.anim_backleft     = animparseline(animfile);
 233                 fclose(animfile);
 234
 235                 // derived anims
 236                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 237                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 238
 239                 if (animparseerror)
 240                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 241         }
 242         else
 243                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 244         // reset animstate now
 245         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 246 };
 247
 248 void player_anim (void)
 249 {
 250         updateanim(self);
 251         if (self.weaponentity)
 252                 updateanim(self.weaponentity);
 253
 254         if (self.deadflag != DEAD_NO)
 255         {
 256                 if (time > self.animstate_endtime)
 257                 {
 258                         if (self.maxs_z > 5)
 259                         {
 260                                 self.maxs_z = 5;
 261                                 setsize(self, self.mins, self.maxs);
 262                         }
 263                         self.frame = self.dead_frame;
 264                 }
 265                 return;
 266         }
 267
 268         if (!self.animstate_override)
 269         {
 270                 if (!(self.flags & FL_ONGROUND))
 271                 {
 272                         if (self.crouch)
 273                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 274                         else
 275                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 276                         self.restart_jump = FALSE;
 277                 }
 278                 else if (self.crouch)
 279                 {
 280                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 281                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 282                         else
 283                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 284                 }
 285                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 286                 {
 287                         if (self.movement_x > 0 && self.movement_y == 0)
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                         else if (self.movement_x < 0 && self.movement_y == 0)
 290                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 291                         else if (self.movement_x == 0 && self.movement_y > 0)
 292                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 293                         else if (self.movement_x == 0 && self.movement_y < 0)
 294                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 295                         else if (self.movement_x > 0 && self.movement_y > 0)
 296                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 297                         else if (self.movement_x > 0 && self.movement_y < 0)
 298                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 299                         else if (self.movement_x < 0 && self.movement_y > 0)
 300                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 301                         else if (self.movement_x < 0 && self.movement_y < 0)
 302                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 303                         else
 304                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 305                 }
 306                 else
 307                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 308         }
 309
 310         if (self.weaponentity)
 311         if (!self.weaponentity.animstate_override)
 312                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 313 }
 314
 315 void SpawnThrownWeapon (vector org, float w)
 316 {
 317         if(g_minstagib)
 318         if(self.ammo_cells <= 0)
 319                 return;
 320
 321         if(g_pinata)
 322         {
 323                 float j;
 324                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 325                 {
 326                         if(self.weapons & W_WeaponBit(j))
 327                                 if(W_IsWeaponThrowable(j))
 328                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 329                 }
 330         }
 331         else
 332         {
 333                 if(W_IsWeaponThrowable(self.weapon))
 334                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 335         }
 336 }
 337
 338 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 339 {
 340         local float take, save;
 341         vector v;
 342         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 343
 344         // damage resistance (ignore most of the damage from a bullet or similar)
 345         damage = max(damage - 5, 1);
 346
 347         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 348         take = v_x;
 349         save = v_y;
 350
 351         if(sound_allowed(MSG_BROADCAST, attacker))
 352         {
 353                 if (save > 10)
 354                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 355                 else if (take > 30)
 356                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 357                 else if (take > 10)
 358                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 359         }
 360
 361         if (take > 50)
 362                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 363         if (take > 100)
 364                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 365
 366         if (!(self.flags & FL_GODMODE))
 367         {
 368                 self.armorvalue = self.armorvalue - save;
 369                 self.health = self.health - take;
 370                 // pause regeneration for 5 seconds
 371                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 372         }
 373         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 374         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 375         self.dmg_inflictor = inflictor;
 376
 377         if (self.health <= -150 && self.modelindex != 0)
 378         {
 379                 // don't use any animations as a gib
 380                 self.frame = 0;
 381                 self.dead_frame = 0;
 382                 // view just above the floor
 383                 self.view_ofs = '0 0 4';
 384
 385                 Violence_GibSplash(self, 1, 1, attacker);
 386                 self.modelindex = 0; // restore later
 387                 self.solid = SOLID_NOT; // restore later
 388         }
 389 }
 390
 391 void ClientKill_Now_TeamChange();
 392 void freezetag_CheckWinner();
 393
 394 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 395 {
 396         local float take, save, waves, sdelay, dh, da, j;
 397         vector v;
 398         float valid_damage_for_weaponstats;
 399         float excess;
 400
 401         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 402                 return;
 403
 404         dh = max(self.health, 0);
 405         da = max(self.armorvalue, 0);
 406
 407         if(!DEATH_ISSPECIAL(deathtype))
 408         {
 409                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 410                 if(self != attacker)
 411                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 412         }
 413
 414         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 415         {
 416                 // tuba causes blood to come out of the ears
 417                 vector ear1, ear2;
 418                 vector d;
 419                 float f;
 420                 ear1 = self.origin;
 421                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 422                 ear2 = ear1;
 423                 makevectors(self.angles);
 424                 ear1 += v_right * -10;
 425                 ear2 += v_right * +10;
 426                 d = inflictor.origin - self.origin;
 427                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 428                 force = v_right * vlen(force);
 429                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 430                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 431                 if(f > 0)
 432                 {
 433                         hitloc = ear1;
 434                         force = force * -1;
 435                 }
 436                 else
 437                 {
 438                         hitloc = ear2;
 439                         // force is already good
 440                 }
 441         }
 442         else
 443                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 444
 445         if (!g_minstagib)
 446         {
 447                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 448                 take = v_x;
 449                 save = v_y;
 450         }
 451         else
 452         {
 453                 save = 0;
 454                 take = damage;
 455         }
 456
 457         frag_inflictor = inflictor;
 458         frag_attacker = attacker;
 459         frag_target = self;
 460         damage_take = take;
 461         damage_save = save;
 462         damage_force = force;
 463         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 464         take = bound(0, damage_take, self.health);
 465         save = bound(0, damage_save, self.armorvalue);
 466         excess = max(0, damage - take - save);
 467
 468         if(sound_allowed(MSG_BROADCAST, attacker))
 469         {
 470                 if (save > 10)
 471                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 472                 else if (take > 30)
 473                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 474                 else if (take > 10)
 475                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 476         }
 477
 478         if (take > 50)
 479                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 480         if (take > 100)
 481                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 482
 483         if (time >= self.spawnshieldtime)
 484         {
 485                 if (!(self.flags & FL_GODMODE))
 486                 {
 487                         self.armorvalue = self.armorvalue - save;
 488                         self.health = self.health - take;
 489                         // pause regeneration for 5 seconds
 490                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 491
 492                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 493                         {
 494                                 self.pain_finished = time + 0.5;        //Supajoe
 495
 496                                 if(sv_gentle < 1) {
 497                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 498                                         {
 499                                                 if (random() > 0.5)
 500                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 501                                                 else
 502                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 503                                         }
 504
 505                                         if(sound_allowed(MSG_BROADCAST, attacker))
 506                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 507                                         if(self.health > 1)
 508                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 509                                         {
 510                                                 if(deathtype == DEATH_FALL)
 511                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 512                                                 else if(self.health > 75) // TODO make a "gentle" version?
 513                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 514                                                 else if(self.health > 50)
 515                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 516                                                 else if(self.health > 25)
 517                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 518                                                 else
 519                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 520                                         }
 521                                 }
 522
 523                                 // throw off bot aim temporarily
 524                                 local float shake;
 525                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 526                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 527                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 528                         }
 529                 }
 530                 else
 531                         self.max_armorvalue += (save + take);
 532         }
 533         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 534         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 535         self.dmg_inflictor = inflictor;
 536
 537         if(attacker == self)
 538         {
 539                 // don't reset pushltime for self damage as it may be an attempt to
 540                 // escape a lava pit or similar
 541                 //self.pushltime = 0;
 542         }
 543         else if(attacker.classname == "player" || attacker.classname == "gib")
 544         {
 545                 self.pusher = attacker;
 546                 self.pushltime = time + autocvar_g_maxpushtime;
 547         }
 548         else if(time < self.pushltime)
 549         {
 550                 attacker = self.pusher;
 551                 self.pushltime = max(self.pushltime, time + 0.6);
 552         }
 553         else
 554                 self.pushltime = 0;
 555
 556         valid_damage_for_weaponstats = 0;
 557         if(clienttype(self) == CLIENTTYPE_REAL)
 558         if(clienttype(attacker) == CLIENTTYPE_REAL)
 559         if(self != attacker)
 560         if(!DEATH_ISSPECIAL(deathtype))
 561         if(IsDifferentTeam(self, attacker))
 562                 valid_damage_for_weaponstats = 1;
 563
 564         if(valid_damage_for_weaponstats)
 565         {
 566                 dh = dh - max(self.health, 0);
 567                 da = da - max(self.armorvalue, 0);
 568                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 569         }
 570
 571         if (self.health < 1)
 572         {
 573                 float defer_ClientKill_Now_TeamChange;
 574                 defer_ClientKill_Now_TeamChange = FALSE;
 575
 576                 if(self.alivetime)
 577                 {
 578                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 579                         self.alivetime = 0;
 580                 }
 581
 582                 if(valid_damage_for_weaponstats)
 583                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 584
 585                 if(sv_gentle < 1) // TODO make a "gentle" version?
 586                 if(sound_allowed(MSG_BROADCAST, attacker))
 587                 {
 588                         if(deathtype == DEATH_DROWN)
 589                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 590                         else
 591                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 592                 }
 593
 594                 // get rid of kill indicator
 595                 if(self.killindicator)
 596                 {
 597                         remove(self.killindicator);
 598                         self.killindicator = world;
 599                         if(self.killindicator_teamchange)
 600                                 defer_ClientKill_Now_TeamChange = TRUE;
 601
 602                         if(self.classname == "body")
 603                         if(deathtype == DEATH_KILL)
 604                         {
 605                                 // for the lemmings fans, a small harmless explosion
 606                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 607                         }
 608                 }
 609
 610                 if(!g_freezetag)
 611                 {
 612                         // become fully visible
 613                         self.alpha = 1;
 614                         // clear selected player display
 615                         ClearSelectedPlayer();
 616                         // throw a weapon
 617                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 618                 }
 619
 620                 // print an obituary message
 621                 Obituary (attacker, inflictor, self, deathtype);
 622                 race_PreDie();
 623                 DropAllRunes(self);
 624
 625                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 626                 {
 627                         PutClientInServer();
 628                         count_alive_players(); // re-count players
 629                         freezetag_CheckWinner();
 630                         return;
 631                 }
 632
 633                 frag_attacker = attacker;
 634                 frag_inflictor = inflictor;
 635                 frag_target = self;
 636                 MUTATOR_CALLHOOK(PlayerDies);
 637
 638                 if(self.flagcarried)
 639                 {
 640                         if(attacker.classname != "player" && attacker.classname != "gib")
 641                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 642                         else if(attacker.team == self.team)
 643                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 644                         else
 645                                 DropFlag(self.flagcarried, world, attacker);
 646                 }
 647                 if(self.ballcarried && g_nexball)
 648                         DropBall(self.ballcarried, self.origin, self.velocity);
 649                 Portal_ClearAllLater(self);
 650
 651                 if(clienttype(self) == CLIENTTYPE_REAL)
 652                 {
 653                         stuffcmd(self, "-zoom\n");
 654                         self.fixangle = TRUE;
 655                         //msg_entity = self;
 656                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 657                         //WriteAngle (MSG_ONE, self.v_angle_x);
 658                         //WriteAngle (MSG_ONE, self.v_angle_y);
 659                         //WriteAngle (MSG_ONE, 80);
 660                 }
 661
 662                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 663                         ClientKill_Now_TeamChange();
 664
 665                 if(g_arena)
 666                         Spawnqueue_Unmark(self);
 667
 668                 if(g_freezetag)
 669                         return;
 670
 671                 // when we get here, player actually dies
 672                 // clear waypoints (do this AFTER FreezeTag)
 673                 WaypointSprite_PlayerDead();
 674
 675                 // make the corpse upright (not tilted)
 676                 self.angles_x = 0;
 677                 self.angles_z = 0;
 678                 // don't spin
 679                 self.avelocity = '0 0 0';
 680                 // view from the floor
 681                 self.view_ofs = '0 0 -8';
 682                 // toss the corpse
 683                 self.movetype = MOVETYPE_TOSS;
 684                 // shootable corpse
 685                 self.solid = SOLID_CORPSE;
 686                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 687                 // don't stick to the floor
 688                 self.flags &~= FL_ONGROUND;
 689                 // dying animation
 690                 self.deadflag = DEAD_DYING;
 691                 // when to allow respawn
 692                 sdelay = 0;
 693                 waves = 0;
 694                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 695                 if(!sdelay)
 696                 {
 697                         if(g_cts)
 698                                 sdelay = 0; // no respawn delay in CTS
 699                         else
 700                                 sdelay = autocvar_g_respawn_delay;
 701                 }
 702                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 703                 if(!waves)
 704                         waves = autocvar_g_respawn_waves;
 705                 if(waves)
 706                         self.death_time = ceil((time + sdelay) / waves) * waves;
 707                 else
 708                         self.death_time = time + sdelay;
 709                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 710                         self.respawn_countdown = 10; // first number to count down from is 10
 711                 else
 712                         self.respawn_countdown = -1; // do not count down
 713                 if (random() < 0.5)
 714                 {
 715                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 716                         self.dead_frame = self.anim_dead1_x;
 717                 }
 718                 else
 719                 {
 720                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 721                         self.dead_frame = self.anim_dead2_x;
 722                 }
 723                 // set damage function to corpse damage
 724                 self.event_damage = PlayerCorpseDamage;
 725                 // call the corpse damage function just in case it wants to gib
 726                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 727                 // set up to fade out later
 728                 SUB_SetFade (self, time + 6 + random (), 1);
 729
 730                 if(sv_gentle > 0 || autocvar_ekg) {
 731                         // remove corpse
 732                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 733                 }
 734
 735                 // reset fields the weapons may use just in case
 736                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 737                 {
 738                         weapon_action(j, WR_RESETPLAYER);
 739                         ATTACK_FINISHED_FOR(self, j) = 0;
 740                 }
 741         }
 742 }
 743
 744 float UpdateSelectedPlayer_countvalue(float v)
 745 {
 746         return max(0, (v - 1.0) / 0.5);
 747 }
 748
 749 // returns: -2 if no hit, otherwise cos of the angle
 750 // uses the global v_angle
 751 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 752 {
 753         vector so, d;
 754         float c;
 755
 756         if(p == self)
 757                 return -2;
 758
 759         if(p.deadflag)
 760                 return -2;
 761
 762         so = self.origin + self.view_ofs;
 763         d = p.origin - so;
 764
 765         // misaimed?
 766         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 767                 return -2;
 768
 769         // now find the cos of the angle...
 770         c = normalize(d) * v_forward;
 771
 772         if(c <= mincosangle)
 773                 return -2;
 774
 775         // not visible in any way? forget it
 776         if(!checkpvs(so, p))
 777                 return -2;
 778
 779         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 780         if(trace_fraction < 1)
 781                 return -2;
 782
 783         return c;
 784 }
 785
 786 void ClearSelectedPlayer()
 787 {
 788         if(self.selected_player)
 789         {
 790                 centerprint_expire(self, CENTERPRIO_POINT);
 791                 self.selected_player = world;
 792                 self.selected_player_display_needs_update = FALSE;
 793         }
 794 }
 795
 796 void UpdateSelectedPlayer()
 797 {
 798         entity selected;
 799         float selected_score;
 800         selected = world;
 801         selected_score = 0.95; // 18 degrees
 802
 803         if(!autocvar_sv_allow_shownames)
 804                 return;
 805
 806         if(clienttype(self) != CLIENTTYPE_REAL)
 807                 return;
 808
 809         if(self.cvar_cl_shownames == 0)
 810                 return;
 811
 812         if(self.cvar_cl_shownames == 1 && !teams_matter)
 813                 return;
 814
 815         makevectors(self.v_angle); // sets v_forward
 816
 817         // 1. cursor trace is always right
 818         WarpZone_crosshair_trace(self);
 819         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 820         {
 821                 selected = trace_ent;
 822         }
 823         else
 824         {
 825                 // 2. if we don't have a cursor trace, find the player which is least
 826                 //    mis-aimed at
 827                 entity p;
 828                 FOR_EACH_PLAYER(p)
 829                 {
 830                         float c;
 831                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 832                         if(c >= -1)
 833                         {
 834                                 selected = p;
 835                                 selected_score = c;
 836                         }
 837                 }
 838         }
 839
 840         if(selected)
 841         {
 842                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 843         }
 844         else
 845         {
 846                 if(time < self.selected_player_display_timeout)
 847                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 848                                 selected = self.selected_player;
 849         }
 850
 851         if(selected)
 852         {
 853                 if(selected == self.selected_player)
 854                 {
 855                         float save;
 856                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 857                         self.selected_player_count = self.selected_player_count + frametime;
 858                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 859                         {
 860                                 string namestr, healthstr;
 861                                 namestr = playername(selected);
 862                                 if(teams_matter)
 863                                 {
 864                                         healthstr = ftos(floor(selected.health));
 865                                         if(self.team == selected.team)
 866                                         {
 867                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 868                                                 self.selected_player_display_needs_update = TRUE;
 869                                         }
 870                                 }
 871                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 872                         }
 873                 }
 874                 else
 875                 {
 876                         ClearSelectedPlayer();
 877                         self.selected_player = selected;
 878                         self.selected_player_time = time;
 879                         self.selected_player_count = 0;
 880                         self.selected_player_display_needs_update = FALSE;
 881                 }
 882         }
 883         else
 884         {
 885                 ClearSelectedPlayer();
 886         }
 887
 888         if(self.selected_player)
 889                 self.last_selected_player = self.selected_player;
 890 }
 891
 892 .float muted; // to be used by prvm_edictset server playernumber muted 1
 893 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 894 // message "": do not say, just test flood control
 895 // return value:
 896 //   1 = accept
 897 //   0 = reject
 898 //  -1 = fake accept
 899 {
 900         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 901         float flood, privatemsgprefixlen;
 902         var .float flood_field;
 903         entity head;
 904         float ret;
 905
 906         if(Ban_MaybeEnforceBan(source))
 907                 return 0;
 908
 909         if(!teamsay && !privatesay)
 910                 if(substring(msgin, 0, 1) == " ")
 911                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 912
 913         msgin = formatmessage(msgin);
 914
 915         if(source.classname != "player")
 916                 colorstr = "^0"; // black for spectators
 917         else if(teams_matter)
 918                 colorstr = Team_ColorCode(source.team);
 919         else
 920                 teamsay = FALSE;
 921
 922         if(intermission_running)
 923                 teamsay = FALSE;
 924
 925         if(msgin != "")
 926                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 927
 928         /*
 929          * using bprint solves this... me stupid
 930         // how can we prevent the message from appearing in a listen server?
 931         // for now, just give "say" back and only handle say_team
 932         if(!teamsay)
 933         {
 934                 clientcommand(self, strcat("say ", msgin));
 935                 return;
 936         }
 937         */
 938
 939         if(autocvar_g_chat_teamcolors)
 940                 namestr = playername(source);
 941         else
 942                 namestr = source.netname;
 943
 944         if(msgin != "")
 945         {
 946                 if(privatesay)
 947                 {
 948                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 949                         privatemsgprefixlen = strlen(msgstr);
 950                         msgstr = strcat(msgstr, msgin);
 951                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 952                         if(autocvar_g_chat_teamcolors)
 953                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 954                         else
 955                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 956                 }
 957                 else if(teamsay)
 958                 {
 959                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 960                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 961                 }
 962                 else
 963                 {
 964                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 965                         cmsgstr = "";
 966                 }
 967                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 968         }
 969         else
 970         {
 971                 msgstr = cmsgstr = "";
 972         }
 973
 974         fullmsgstr = msgstr;
 975         fullcmsgstr = cmsgstr;
 976
 977         // FLOOD CONTROL
 978         flood = 0;
 979         if(floodcontrol)
 980         {
 981                 float flood_spl;
 982                 float flood_burst;
 983                 float flood_lmax;
 984                 float lines;
 985                 if(privatesay)
 986                 {
 987                         flood_spl = autocvar_g_chat_flood_spl_tell;
 988                         flood_burst = autocvar_g_chat_flood_burst_tell;
 989                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 990                         flood_field = floodcontrol_chattell;
 991                 }
 992                 else if(teamsay)
 993                 {
 994                         flood_spl = autocvar_g_chat_flood_spl_team;
 995                         flood_burst = autocvar_g_chat_flood_burst_team;
 996                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 997                         flood_field = floodcontrol_chatteam;
 998                 }
 999                 else
1000                 {
1001                         flood_spl = autocvar_g_chat_flood_spl;
1002                         flood_burst = autocvar_g_chat_flood_burst;
1003                         flood_lmax = autocvar_g_chat_flood_lmax;
1004                         flood_field = floodcontrol_chat;
1005                 }
1006                 flood_burst = max(0, flood_burst - 1);
1007                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1008
1009                 // do flood control for the default line size
1010                 if(msgstr != "")
1011                 {
1012                         getWrappedLine_remaining = msgstr;
1013                         msgstr = "";
1014                         lines = 0;
1015                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1016                         {
1017                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1018                                 ++lines;
1019                         }
1020                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1021
1022                         if(getWrappedLine_remaining != "")
1023                         {
1024                                 msgstr = strcat(msgstr, "\n");
1025                                 flood = 2;
1026                         }
1027
1028                         if(time >= source.flood_field)
1029                         {
1030                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1031                         }
1032                         else
1033                         {
1034                                 flood = 1;
1035                                 msgstr = fullmsgstr;
1036                         }
1037                 }
1038                 else
1039                 {
1040                         if(time >= source.flood_field)
1041                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1042                         else
1043                                 flood = 1;
1044                 }
1045
1046                 if (timeoutStatus == 2) //when game is paused, no flood protection
1047                         source.flood_field = flood = 0;
1048         }
1049
1050         if(flood == 2) // cannot happen for empty msgstr
1051         {
1052                 if(autocvar_g_chat_flood_notify_flooder)
1053                 {
1054                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1055                         sourcecmsgstr = "";
1056                 }
1057                 else
1058                 {
1059                         sourcemsgstr = fullmsgstr;
1060                         sourcecmsgstr = fullcmsgstr;
1061                 }
1062                 cmsgstr = "";
1063         }
1064         else
1065         {
1066                 sourcemsgstr = msgstr;
1067                 sourcecmsgstr = cmsgstr;
1068         }
1069
1070         if(!privatesay)
1071         if(source.classname != "player")
1072         {
1073                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
1074                         teamsay = -1; // spectators
1075         }
1076
1077         if(flood)
1078                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1079
1080         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1081         if(privatesay)
1082                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1083
1084         if(source.muted)
1085         {
1086                 // always fake the message
1087                 ret = -1;
1088         }
1089         else if(flood == 1)
1090         {
1091                 if(autocvar_g_chat_flood_notify_flooder)
1092                 {
1093                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1094                         ret = 0;
1095                 }
1096                 else
1097                         ret = -1;
1098         }
1099         else
1100         {
1101                 ret = 1;
1102         }
1103
1104         if(sourcemsgstr != "" && ret != 0)
1105         {
1106                 if(ret < 0) // fake
1107                 {
1108                         sprint(source, sourcemsgstr);
1109                         if(sourcecmsgstr != "" && !privatesay)
1110                                 centerprint(source, sourcecmsgstr);
1111                 }
1112                 else if(privatesay)
1113                 {
1114                         sprint(source, sourcemsgstr);
1115                         sprint(privatesay, msgstr);
1116                         if(cmsgstr != "")
1117                                 centerprint(privatesay, cmsgstr);
1118                 }
1119                 else if(teamsay > 0)
1120                 {
1121                         sprint(source, sourcemsgstr);
1122                         if(sourcecmsgstr != "")
1123                                 centerprint(source, sourcecmsgstr);
1124                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1125                                 if(head != source)
1126                                 {
1127                                         sprint(head, msgstr);
1128                                         if(cmsgstr != "")
1129                                                 centerprint(head, cmsgstr);
1130                                 }
1131                 }
1132                 else if(teamsay < 0)
1133                 {
1134                         sprint(source, sourcemsgstr);
1135                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1136                                 if(head != source)
1137                                         sprint(head, msgstr);
1138                 }
1139                 else if(sourcemsgstr != msgstr)
1140                 {
1141                         sprint(source, sourcemsgstr);
1142                         FOR_EACH_REALCLIENT(head)
1143                                 if(head != source)
1144                                         sprint(head, msgstr);
1145                 }
1146                 else
1147                         bprint(msgstr);
1148         }
1149
1150         return ret;
1151 }
1152
1153 float GetVoiceMessageVoiceType(string type)
1154 {
1155         if(type == "taunt")
1156                 return VOICETYPE_TAUNT;
1157         if(type == "teamshoot")
1158                 return VOICETYPE_LASTATTACKER;
1159         return VOICETYPE_TEAMRADIO;
1160 }
1161
1162 string allvoicesamples;
1163 .string GetVoiceMessageSampleField(string type)
1164 {
1165         GetPlayerSoundSampleField_notFound = 0;
1166         switch(type)
1167         {
1168 #define _VOICEMSG(m) case #m: return playersound_##m;
1169                 ALLVOICEMSGS
1170 #undef _VOICEMSG
1171         }
1172         GetPlayerSoundSampleField_notFound = 1;
1173         return playersound_taunt;
1174 }
1175
1176 .string GetPlayerSoundSampleField(string type)
1177 {
1178         GetPlayerSoundSampleField_notFound = 0;
1179         switch(type)
1180         {
1181 #define _VOICEMSG(m) case #m: return playersound_##m;
1182                 ALLPLAYERSOUNDS
1183 #undef _VOICEMSG
1184         }
1185         GetPlayerSoundSampleField_notFound = 1;
1186         return playersound_taunt;
1187 }
1188
1189 void PrecacheGlobalSound(string samplestring)
1190 {
1191         float n, i;
1192         tokenize_console(samplestring);
1193         n = stof(argv(1));
1194         if(n > 0)
1195         {
1196                 for(i = 1; i <= n; ++i)
1197                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1198         }
1199         else
1200         {
1201                 precache_sound(strcat(argv(0), ".wav"));
1202         }
1203 }
1204
1205 void PrecachePlayerSounds(string f)
1206 {
1207         float fh;
1208         string s;
1209         fh = fopen(f, FILE_READ);
1210         if(fh < 0)
1211                 return;
1212         while((s = fgets(fh)))
1213         {
1214                 if(tokenize_console(s) != 3)
1215                 {
1216                         dprint("Invalid sound info line: ", s, "\n");
1217                         continue;
1218                 }
1219                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1220         }
1221         fclose(fh);
1222
1223         if not(allvoicesamples)
1224         {
1225 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1226                 ALLVOICEMSGS
1227 #undef _VOICEMSG
1228                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1229         }
1230 }
1231
1232 void ClearPlayerSounds()
1233 {
1234 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1235         ALLPLAYERSOUNDS
1236         ALLVOICEMSGS
1237 #undef _VOICEMSG
1238 }
1239
1240 float LoadPlayerSounds(string f, float first)
1241 {
1242         float fh;
1243         string s;
1244         var .string field;
1245         fh = fopen(f, FILE_READ);
1246         if(fh < 0)
1247         {
1248                 dprint("Player sound file not found: ", f, "\n");
1249                 return 0;
1250         }
1251         while((s = fgets(fh)))
1252         {
1253                 if(tokenize_console(s) != 3)
1254                         continue;
1255                 field = GetPlayerSoundSampleField(argv(0));
1256                 if(GetPlayerSoundSampleField_notFound)
1257                         field = GetVoiceMessageSampleField(argv(0));
1258                 if(GetPlayerSoundSampleField_notFound)
1259                         continue;
1260                 if(self.field)
1261                         strunzone(self.field);
1262                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1263         }
1264         fclose(fh);
1265         return 1;
1266 }
1267
1268 .float modelindex_for_playersound;
1269 .float skinindex_for_playersound;
1270 void UpdatePlayerSounds()
1271 {
1272         if(self.modelindex == self.modelindex_for_playersound)
1273         if(self.skinindex == self.skinindex_for_playersound)
1274                 return;
1275         self.modelindex_for_playersound = self.modelindex;
1276         self.skinindex_for_playersound = self.skinindex;
1277         ClearPlayerSounds();
1278         LoadPlayerSounds("sound/player/default.sounds", 1);
1279         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1280                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1281 }
1282
1283 void FakeGlobalSound(string sample, float chan, float voicetype)
1284 {
1285         float n;
1286         float tauntrand;
1287
1288         if(sample == "")
1289                 return;
1290
1291         tokenize_console(sample);
1292         n = stof(argv(1));
1293         if(n > 0)
1294                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1295         else
1296                 sample = strcat(argv(0), ".wav"); // randomization
1297
1298         switch(voicetype)
1299         {
1300                 case VOICETYPE_LASTATTACKER_ONLY:
1301                         break;
1302                 case VOICETYPE_LASTATTACKER:
1303                         if(self.pusher)
1304                         {
1305                                 msg_entity = self;
1306                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1307                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1308                         }
1309                         break;
1310                 case VOICETYPE_TEAMRADIO:
1311                         msg_entity = self;
1312                         if(msg_entity.cvar_cl_voice_directional == 1)
1313                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1314                         else
1315                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1316                         break;
1317                 case VOICETYPE_AUTOTAUNT:
1318                         if(!sv_autotaunt)
1319                                 break;
1320                         if(!sv_taunt)
1321                                 break;
1322                         if(sv_gentle)
1323                                 break;
1324                         tauntrand = random();
1325                         msg_entity = self;
1326                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1327                         {
1328                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1329                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1330                                 else
1331                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1332                         }
1333                         break;
1334                 case VOICETYPE_TAUNT:
1335                         if(self.classname == "player")
1336                                 if(self.deadflag == DEAD_NO)
1337                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1338                         if(!sv_taunt)
1339                                 break;
1340                         if(sv_gentle)
1341                                 break;
1342                         msg_entity = self;
1343                         if (msg_entity.cvar_cl_voice_directional >= 1)
1344                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1345                         else
1346                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1347                         break;
1348                 case VOICETYPE_PLAYERSOUND:
1349                         msg_entity = self;
1350                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1351                         break;
1352                 default:
1353                         backtrace("Invalid voice type!");
1354                         break;
1355         }
1356 }
1357
1358 void GlobalSound(string sample, float chan, float voicetype)
1359 {
1360         float n;
1361         float tauntrand;
1362
1363         if(sample == "")
1364                 return;
1365
1366         tokenize_console(sample);
1367         n = stof(argv(1));
1368         if(n > 0)
1369                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1370         else
1371                 sample = strcat(argv(0), ".wav"); // randomization
1372
1373         switch(voicetype)
1374         {
1375                 case VOICETYPE_LASTATTACKER_ONLY:
1376                         if(self.pusher)
1377                         {
1378                                 msg_entity = self.pusher;
1379                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1380                                 {
1381                                         if(msg_entity.cvar_cl_voice_directional == 1)
1382                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1383                                         else
1384                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1385                                 }
1386                         }
1387                         break;
1388                 case VOICETYPE_LASTATTACKER:
1389                         if(self.pusher)
1390                         {
1391                                 msg_entity = self.pusher;
1392                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1393                                 {
1394                                         if(msg_entity.cvar_cl_voice_directional == 1)
1395                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1396                                         else
1397                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1398                                 }
1399                                 msg_entity = self;
1400                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1401                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1402                         }
1403                         break;
1404                 case VOICETYPE_TEAMRADIO:
1405                         FOR_EACH_REALCLIENT(msg_entity)
1406                                 if(!teams_matter || msg_entity.team == self.team)
1407                                 {
1408                                         if(msg_entity.cvar_cl_voice_directional == 1)
1409                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1410                                         else
1411                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1412                                 }
1413                         break;
1414                 case VOICETYPE_AUTOTAUNT:
1415                         if(!sv_autotaunt)
1416                                 break;
1417                         if(!sv_taunt)
1418                                 break;
1419                         if(sv_gentle)
1420                                 break;
1421                         tauntrand = random();
1422                         FOR_EACH_REALCLIENT(msg_entity)
1423                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1424                                 {
1425                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1426                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1427                                         else
1428                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1429                                 }
1430                         break;
1431                 case VOICETYPE_TAUNT:
1432                         if(self.classname == "player")
1433                                 if(self.deadflag == DEAD_NO)
1434                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1435                         if(!sv_taunt)
1436                                 break;
1437                         if(sv_gentle)
1438                                 break;
1439                         FOR_EACH_REALCLIENT(msg_entity)
1440                         {
1441                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1442                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1443                                 else
1444                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1445                         }
1446                         break;
1447                 case VOICETYPE_PLAYERSOUND:
1448                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1449                         break;
1450                 default:
1451                         backtrace("Invalid voice type!");
1452                         break;
1453         }
1454 }
1455
1456 void PlayerSound(.string samplefield, float chan, float voicetype)
1457 {
1458         GlobalSound(self.samplefield, chan, voicetype);
1459 }
1460
1461 void VoiceMessage(string type, string msg)
1462 {
1463         var .string sample;
1464         float voicetype, ownteam;
1465         float flood;
1466         sample = GetVoiceMessageSampleField(type);
1467
1468         if(GetPlayerSoundSampleField_notFound)
1469         {
1470                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1471                 return;
1472         }
1473
1474         voicetype = GetVoiceMessageVoiceType(type);
1475         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1476
1477         flood = Say(self, ownteam, world, msg, 1);
1478
1479         if (flood > 0)
1480                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1481         else if (flood < 0)
1482                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1483 }
1484
1485 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1486 {
1487 //      show_message
1488 //      0 (00) automove centerprint, admin message
1489 //      1 (01) automove centerprint, no admin message
1490 //      2 (10) no centerprint, admin message
1491 //      3 (11) no centerprint, no admin message
1492
1493         float lockteams_backup;
1494
1495         lockteams_backup = lockteams;  // backup any team lock
1496
1497         lockteams = 0;  // disable locked teams
1498
1499         TeamchangeFrags(client);  // move the players frags
1500         SetPlayerColors(client, team_colour - 1);  // set the players colour
1501         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1502
1503         lockteams = lockteams_backup;  // restore the team lock
1504
1505         LogTeamchange(client.playerid, client.team, type);
1506
1507         if not(show_message & 1) // admin message
1508                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1509
1510         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1511 }