qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3 FTEQCC_YOU_SUCK_THIS_IS_NOT_UNREFERENCED(accuracy_frags);
   4
   5 float weaponstats_buffer;
   6
   7 void WeaponStats_Init()
   8 {
   9         if(autocvar_sv_weaponstats_file != "")
  10                 weaponstats_buffer = buf_create();
  11         else
  12                 weaponstats_buffer = -1;
  13 }
  14
  15 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  16
  17 void WeaponStats_Shutdown()
  18 {
  19         float i, j, ibot, jbot, idx;
  20         float fh;
  21         vector v;
  22         string prefix;
  23         if(weaponstats_buffer < 0)
  24                 return;
  25         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26         if(autocvar_sv_weaponstats_file != "")
  27         {
  28                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  29                 if(fh >= 0)
  30                 {
  31                         fputs(fh, "#begin statsfile\n");
  32                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  33                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  34                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  35                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  36                                 {
  37                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  38                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  39                                         if(v != '0 0 0')
  40                                         {
  41                                                 //vector is: kills hits damage
  42                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  43                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  44                                         }
  45                                 }
  46                         fputs(fh, "#end\n\n");
  47                         fclose(fh);
  48                         print("Weapon stats written\n");
  49                 }
  50         }
  51         buf_del(weaponstats_buffer);
  52         weaponstats_buffer = -1;
  53 }
  54
  55 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  56 {
  57         float idx;
  58         if(weaponstats_buffer < 0)
  59                 return;
  60         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  61                 return;
  62         if(awep > WEP_LAST || vwep > WEP_LAST)
  63                 return;
  64         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  65         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  66 }
  67 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  68 {
  69         if(damage < 0)
  70                 error("negative damage?");
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  72 }
  73 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  74 {
  75         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  76 }
  77
  78 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  79 // merged player_run and player_stand to player_anim
  80 // added death animations to player_anim
  81 // can now spawn thrown weapons from anywhere, not just from players
  82 // thrown weapons now fade out after 20 seconds
  83 // created PlayerGib function
  84 // PlayerDie no longer uses hitloc or damage
  85 // PlayerDie now supports dying animations as well as gibbing
  86 // cleaned up PlayerDie a lot
  87 // added CopyBody
  88
  89 .entity pusher;
  90 .float pushltime;
  91
  92 void CopyBody(float keepvelocity)
  93 {
  94         local entity oldself;
  95         if (self.effects & EF_NODRAW)
  96                 return;
  97         oldself = self;
  98         self = spawn();
  99         self.enemy = oldself;
 100         self.lip = oldself.lip;
 101         self.colormap = oldself.colormap;
 102         self.glowmod = oldself.glowmod;
 103         self.iscreature = oldself.iscreature;
 104         self.angles = oldself.angles;
 105         self.avelocity = oldself.avelocity;
 106         self.classname = "body";
 107         self.damageforcescale = oldself.damageforcescale;
 108         self.effects = oldself.effects;
 109         self.event_damage = oldself.event_damage;
 110         self.animstate_startframe = oldself.animstate_startframe;
 111         self.animstate_numframes = oldself.animstate_numframes;
 112         self.animstate_framerate = oldself.animstate_framerate;
 113         self.animstate_starttime = oldself.animstate_starttime;
 114         self.animstate_endtime = oldself.animstate_endtime;
 115         self.animstate_override = oldself.animstate_override;
 116         self.animstate_looping = oldself.animstate_looping;
 117         self.frame = oldself.frame;
 118         self.dead_frame = oldself.dead_frame;
 119         self.pain_finished = oldself.pain_finished;
 120         self.health = oldself.health;
 121         self.armorvalue = oldself.armorvalue;
 122         self.armortype = oldself.armortype;
 123         self.model = oldself.model;
 124         self.modelindex = oldself.modelindex;
 125         self.modelindex_lod0 = oldself.modelindex_lod0;
 126         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 127         self.modelindex_lod1 = oldself.modelindex_lod1;
 128         self.modelindex_lod2 = oldself.modelindex_lod2;
 129         self.skinindex = oldself.skinindex;
 130         self.species = oldself.species;
 131         self.movetype = oldself.movetype;
 132         self.nextthink = oldself.nextthink;
 133         self.solid = oldself.solid;
 134         self.ballistics_density = oldself.ballistics_density;
 135         self.takedamage = oldself.takedamage;
 136         self.think = oldself.think;
 137         self.customizeentityforclient = oldself.customizeentityforclient;
 138         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 139         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 140         if (keepvelocity == 1)
 141                 self.velocity = oldself.velocity;
 142         self.oldvelocity = self.velocity;
 143         self.fade_time = oldself.fade_time;
 144         self.fade_rate = oldself.fade_rate;
 145         //self.weapon = oldself.weapon;
 146         setorigin(self, oldself.origin);
 147         setsize(self, oldself.mins, oldself.maxs);
 148         self.prevorigin = oldself.origin;
 149         self.reset = SUB_Remove;
 150
 151         Drag_MoveDrag(oldself, self);
 152
 153         self = oldself;
 154 }
 155
 156 float player_getspecies()
 157 {
 158         float s;
 159         get_model_parameters(self.model, self.skinindex);
 160         s = get_model_parameters_species;
 161         get_model_parameters(string_null, 0);
 162         if(s < 0)
 163                 return SPECIES_HUMAN;
 164         return s;
 165 }
 166
 167 void player_setupanimsformodel()
 168 {
 169         local string animfilename;
 170         local float animfile;
 171         // defaults for legacy .zym models without animinfo files
 172         self.anim_die1 = '0 1 0.5'; // 2 seconds
 173         self.anim_die2 = '1 1 0.5'; // 2 seconds
 174         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 175         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 176         self.anim_duckwalk = '4 1 1';
 177         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 178         self.anim_duckidle = '6 1 1';
 179         self.anim_idle = '7 1 1';
 180         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 181         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 182         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 183         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 184         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 185         self.anim_run = '13 1 1';
 186         self.anim_runbackwards = '14 1 1';
 187         self.anim_strafeleft = '15 1 1';
 188         self.anim_straferight = '16 1 1';
 189         self.anim_dead1 = '17 1 1';
 190         self.anim_dead2 = '18 1 1';
 191         self.anim_forwardright = '19 1 1';
 192         self.anim_forwardleft = '20 1 1';
 193         self.anim_backright = '21 1 1';
 194         self.anim_backleft  = '22 1 1';
 195         self.anim_melee = '23 1 1';
 196         animparseerror = FALSE;
 197         animfilename = strcat(self.model, ".animinfo");
 198         animfile = fopen(animfilename, FILE_READ);
 199         if (animfile >= 0)
 200         {
 201                 self.anim_die1         = animparseline(animfile);
 202                 self.anim_die2         = animparseline(animfile);
 203                 self.anim_draw         = animparseline(animfile);
 204                 self.anim_duck         = animparseline(animfile);
 205                 self.anim_duckwalk     = animparseline(animfile);
 206                 self.anim_duckjump     = animparseline(animfile);
 207                 self.anim_duckidle     = animparseline(animfile);
 208                 self.anim_idle         = animparseline(animfile);
 209                 self.anim_jump         = animparseline(animfile);
 210                 self.anim_pain1        = animparseline(animfile);
 211                 self.anim_pain2        = animparseline(animfile);
 212                 self.anim_shoot        = animparseline(animfile);
 213                 self.anim_taunt        = animparseline(animfile);
 214                 self.anim_run          = animparseline(animfile);
 215                 self.anim_runbackwards = animparseline(animfile);
 216                 self.anim_strafeleft   = animparseline(animfile);
 217                 self.anim_straferight  = animparseline(animfile);
 218                 self.anim_forwardright = animparseline(animfile);
 219                 self.anim_forwardleft  = animparseline(animfile);
 220                 self.anim_backright    = animparseline(animfile);
 221                 self.anim_backleft     = animparseline(animfile);
 222                 self.anim_melee        = animparseline(animfile);
 223                 fclose(animfile);
 224
 225                 // derived anims
 226                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 227                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 228
 229                 if (animparseerror)
 230                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 231         }
 232         else
 233                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 234         // reset animstate now
 235         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 236 };
 237
 238 void player_anim (void)
 239 {
 240         updateanim(self);
 241         if (self.weaponentity)
 242                 updateanim(self.weaponentity);
 243
 244         if (self.deadflag != DEAD_NO)
 245         {
 246                 if (time > self.animstate_endtime)
 247                 {
 248                         if (self.maxs_z > 5)
 249                         {
 250                                 self.maxs_z = 5;
 251                                 setsize(self, self.mins, self.maxs);
 252                         }
 253                         self.frame = self.dead_frame;
 254                 }
 255                 return;
 256         }
 257
 258         if (!self.animstate_override)
 259         {
 260                 if (!(self.flags & FL_ONGROUND))
 261                 {
 262                         if (self.crouch)
 263                         {
 264                                 traceline(self.origin + '0 0 1' * PL_CROUCH_MIN_z, self.origin + '0 0 1' * (PL_CROUCH_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 265                                 if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == 7) // don't get stuck on idle animation in midair
 266                                 {
 267                                         setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 268                                         self.restart_jump = FALSE;
 269                                 }
 270                         }
 271                         else
 272                         {
 273                                 traceline(self.origin + '0 0 1' * PL_MIN_z, self.origin + '0 0 1' * (PL_MIN_z - autocvar_sv_player_jumpanim_minfall), TRUE, self);
 274                                 if(!trace_startsolid && trace_fraction == 1 || self.animstate_startframe == 7) // don't get stuck on idle animation in midair
 275                                 {
 276                                         setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 277                                         self.restart_jump = FALSE;
 278                                 }
 279                         }
 280                 }
 281                 else if (self.crouch)
 282                 {
 283                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 284                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 285                         else
 286                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 287                 }
 288                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 289                 {
 290                         if (self.movement_x > 0 && self.movement_y == 0)
 291                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 292                         else if (self.movement_x < 0 && self.movement_y == 0)
 293                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 294                         else if (self.movement_x == 0 && self.movement_y > 0)
 295                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 296                         else if (self.movement_x == 0 && self.movement_y < 0)
 297                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 298                         else if (self.movement_x > 0 && self.movement_y > 0)
 299                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 300                         else if (self.movement_x > 0 && self.movement_y < 0)
 301                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 302                         else if (self.movement_x < 0 && self.movement_y > 0)
 303                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 304                         else if (self.movement_x < 0 && self.movement_y < 0)
 305                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 306                         else
 307                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 308                 }
 309                 else
 310                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 311         }
 312
 313         if (self.weaponentity)
 314         if (!self.weaponentity.animstate_override)
 315                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 316 }
 317
 318 void SpawnThrownWeapon (vector org, float w)
 319 {
 320         if(g_minstagib)
 321         if(self.ammo_cells <= 0)
 322                 return;
 323
 324         if(g_pinata)
 325         {
 326                 float j;
 327                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 328                 {
 329                         if(self.weapons & W_WeaponBit(j))
 330                                 if(W_IsWeaponThrowable(j))
 331                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 332                 }
 333         }
 334         else
 335         {
 336                 if(W_IsWeaponThrowable(self.weapon))
 337                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 338         }
 339 }
 340
 341 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 342 {
 343         local float take, save;
 344         vector v;
 345         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 346
 347         // damage resistance (ignore most of the damage from a bullet or similar)
 348         damage = max(damage - 5, 1);
 349
 350         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 351         take = v_x;
 352         save = v_y;
 353
 354         if(sound_allowed(MSG_BROADCAST, attacker))
 355         {
 356                 if (save > 10)
 357                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 358                 else if (take > 30)
 359                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 360                 else if (take > 10)
 361                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 362         }
 363
 364         if (take > 50)
 365                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 366         if (take > 100)
 367                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 368
 369         if (!(self.flags & FL_GODMODE))
 370         {
 371                 self.armorvalue = self.armorvalue - save;
 372                 self.health = self.health - take;
 373                 // pause regeneration for 5 seconds
 374                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 375         }
 376         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 377         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 378         self.dmg_inflictor = inflictor;
 379
 380         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 381         {
 382                 // don't use any animations as a gib
 383                 self.frame = 0;
 384                 self.dead_frame = 0;
 385                 // view just above the floor
 386                 self.view_ofs = '0 0 4';
 387
 388                 Violence_GibSplash(self, 1, 1, attacker);
 389                 self.modelindex = 0; // restore later
 390                 self.solid = SOLID_NOT; // restore later
 391         }
 392 }
 393
 394 void ClientKill_Now_TeamChange();
 395 void freezetag_CheckWinner();
 396
 397 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 398 {
 399         local float take, save, waves, sdelay, dh, da, j;
 400         vector v;
 401         float valid_damage_for_weaponstats;
 402         float excess;
 403
 404         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 405                 return;
 406
 407         dh = max(self.health, 0);
 408         da = max(self.armorvalue, 0);
 409
 410         if(!DEATH_ISSPECIAL(deathtype))
 411         {
 412                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 413                 if(self != attacker)
 414                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 415         }
 416
 417         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 418         {
 419                 // tuba causes blood to come out of the ears
 420                 vector ear1, ear2;
 421                 vector d;
 422                 float f;
 423                 ear1 = self.origin;
 424                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 425                 ear2 = ear1;
 426                 makevectors(self.angles);
 427                 ear1 += v_right * -10;
 428                 ear2 += v_right * +10;
 429                 d = inflictor.origin - self.origin;
 430                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 431                 force = v_right * vlen(force);
 432                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 433                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 434                 if(f > 0)
 435                 {
 436                         hitloc = ear1;
 437                         force = force * -1;
 438                 }
 439                 else
 440                 {
 441                         hitloc = ear2;
 442                         // force is already good
 443                 }
 444         }
 445         else
 446                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 447
 448         if (!g_minstagib)
 449         {
 450                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 451                 take = v_x;
 452                 save = v_y;
 453         }
 454         else
 455         {
 456                 save = 0;
 457                 take = damage;
 458         }
 459
 460         frag_inflictor = inflictor;
 461         frag_attacker = attacker;
 462         frag_target = self;
 463         damage_take = take;
 464         damage_save = save;
 465         damage_force = force;
 466         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 467         take = bound(0, damage_take, self.health);
 468         save = bound(0, damage_save, self.armorvalue);
 469         excess = max(0, damage - take - save);
 470
 471         if(sound_allowed(MSG_BROADCAST, attacker))
 472         {
 473                 if (save > 10)
 474                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 475                 else if (take > 30)
 476                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 477                 else if (take > 10)
 478                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 479         }
 480
 481         if (take > 50)
 482                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 483         if (take > 100)
 484                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 485
 486         if (time >= self.spawnshieldtime)
 487         {
 488                 if (!(self.flags & FL_GODMODE))
 489                 {
 490                         self.armorvalue = self.armorvalue - save;
 491                         self.health = self.health - take;
 492                         // pause regeneration for 5 seconds
 493                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 494
 495                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 496                         {
 497                                 self.pain_finished = time + 0.5;        //Supajoe
 498
 499                                 if(sv_gentle < 1) {
 500                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 501                                         {
 502                                                 if (!self.animstate_override)
 503                                                 {
 504                                                         if (random() > 0.5)
 505                                                                 setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 506                                                         else
 507                                                                 setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 508                                                 }
 509                                         }
 510
 511                                         if(sound_allowed(MSG_BROADCAST, attacker))
 512                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 513                                         if(self.health > 1)
 514                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 515                                         {
 516                                                 if(deathtype == DEATH_FALL)
 517                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 518                                                 else if(self.health > 75) // TODO make a "gentle" version?
 519                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 520                                                 else if(self.health > 50)
 521                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 522                                                 else if(self.health > 25)
 523                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 524                                                 else
 525                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 526                                         }
 527                                 }
 528
 529                                 // throw off bot aim temporarily
 530                                 local float shake;
 531                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 532                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 533                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 534                         }
 535                 }
 536                 else
 537                         self.max_armorvalue += (save + take);
 538         }
 539         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 540         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 541         self.dmg_inflictor = inflictor;
 542
 543         if(attacker == self)
 544         {
 545                 // don't reset pushltime for self damage as it may be an attempt to
 546                 // escape a lava pit or similar
 547                 //self.pushltime = 0;
 548         }
 549         else if(attacker.classname == "player" || attacker.classname == "gib")
 550         {
 551                 self.pusher = attacker;
 552                 self.pushltime = time + autocvar_g_maxpushtime;
 553         }
 554         else if(time < self.pushltime)
 555         {
 556                 attacker = self.pusher;
 557                 self.pushltime = max(self.pushltime, time + 0.6);
 558         }
 559         else
 560                 self.pushltime = 0;
 561
 562         float abot, vbot, awep;
 563         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 564         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 565
 566         valid_damage_for_weaponstats = 0;
 567         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 568         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 569         if(attacker && self != attacker)
 570         if(IsDifferentTeam(self, attacker))
 571         {
 572                 if(DEATH_ISSPECIAL(deathtype))
 573                         awep = attacker.weapon;
 574                 else
 575                         awep = DEATH_WEAPONOF(deathtype);
 576                 valid_damage_for_weaponstats = 1;
 577         }
 578
 579         if(valid_damage_for_weaponstats)
 580         {
 581                 dh = dh - max(self.health, 0);
 582                 da = da - max(self.armorvalue, 0);
 583                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 584         }
 585
 586         if (self.health < 1)
 587         {
 588                 float defer_ClientKill_Now_TeamChange;
 589                 defer_ClientKill_Now_TeamChange = FALSE;
 590
 591                 if(self.alivetime)
 592                 {
 593                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 594                         self.alivetime = 0;
 595                 }
 596
 597                 if(valid_damage_for_weaponstats)
 598                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 599
 600                 if(sv_gentle < 1) // TODO make a "gentle" version?
 601                 if(sound_allowed(MSG_BROADCAST, attacker))
 602                 {
 603                         if(deathtype == DEATH_DROWN)
 604                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 605                         else
 606                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 607                 }
 608
 609                 // get rid of kill indicator
 610                 if(self.killindicator)
 611                 {
 612                         remove(self.killindicator);
 613                         self.killindicator = world;
 614                         if(self.killindicator_teamchange)
 615                                 defer_ClientKill_Now_TeamChange = TRUE;
 616
 617                         if(self.classname == "body")
 618                         if(deathtype == DEATH_KILL)
 619                         {
 620                                 // for the lemmings fans, a small harmless explosion
 621                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 622                         }
 623                 }
 624
 625                 if(!g_freezetag)
 626                 {
 627                         // become fully visible
 628                         self.alpha = 1;
 629                         // throw a weapon
 630                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 631                 }
 632
 633                 // print an obituary message
 634                 Obituary (attacker, inflictor, self, deathtype);
 635                 race_PreDie();
 636                 DropAllRunes(self);
 637
 638         // increment frag counter for used weapon type
 639         float w;
 640         w = DEATH_WEAPONOF(deathtype);
 641         if(WEP_VALID(w))
 642         if(self.classname == "player")
 643         if(self != attacker)
 644         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 645
 646                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 647                 {
 648                         PutClientInServer();
 649                         count_alive_players(); // re-count players
 650                         freezetag_CheckWinner();
 651                         return;
 652                 }
 653
 654                 frag_attacker = attacker;
 655                 frag_inflictor = inflictor;
 656                 frag_target = self;
 657                 MUTATOR_CALLHOOK(PlayerDies);
 658                 weapon_action(self.weapon, WR_PLAYERDEATH);
 659
 660                 if(self.flagcarried)
 661                 {
 662                         if(attacker.classname != "player" && attacker.classname != "gib")
 663                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 664                         else if(attacker.team == self.team)
 665                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 666                         else
 667                                 DropFlag(self.flagcarried, world, attacker);
 668                 }
 669                 if(self.ballcarried && g_nexball)
 670                         DropBall(self.ballcarried, self.origin, self.velocity);
 671                 Portal_ClearAllLater(self);
 672
 673                 if(clienttype(self) == CLIENTTYPE_REAL)
 674                 {
 675                         stuffcmd(self, "-zoom\n");
 676                         self.fixangle = TRUE;
 677                         //msg_entity = self;
 678                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 679                         //WriteAngle (MSG_ONE, self.v_angle_x);
 680                         //WriteAngle (MSG_ONE, self.v_angle_y);
 681                         //WriteAngle (MSG_ONE, 80);
 682                 }
 683
 684                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 685                         ClientKill_Now_TeamChange();
 686
 687                 if(g_arena)
 688                         Spawnqueue_Unmark(self);
 689
 690                 if(g_freezetag)
 691                         return;
 692
 693                 // when we get here, player actually dies
 694                 // clear waypoints (do this AFTER FreezeTag)
 695                 WaypointSprite_PlayerDead();
 696
 697                 // make the corpse upright (not tilted)
 698                 self.angles_x = 0;
 699                 self.angles_z = 0;
 700                 // don't spin
 701                 self.avelocity = '0 0 0';
 702                 // view from the floor
 703                 self.view_ofs = '0 0 -8';
 704                 // toss the corpse
 705                 self.movetype = MOVETYPE_TOSS;
 706                 // shootable corpse
 707                 self.solid = SOLID_CORPSE;
 708                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 709                 // don't stick to the floor
 710                 self.flags &~= FL_ONGROUND;
 711                 // dying animation
 712                 self.deadflag = DEAD_DYING;
 713                 // when to allow respawn
 714                 sdelay = 0;
 715                 waves = 0;
 716                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 717                 if(!sdelay)
 718                 {
 719                         if(g_cts)
 720                                 sdelay = 0; // no respawn delay in CTS
 721                         else
 722                                 sdelay = autocvar_g_respawn_delay;
 723                 }
 724                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 725                 if(!waves)
 726                         waves = autocvar_g_respawn_waves;
 727                 if(waves)
 728                         self.death_time = ceil((time + sdelay) / waves) * waves;
 729                 else
 730                         self.death_time = time + sdelay;
 731                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 732                         self.respawn_countdown = 10; // first number to count down from is 10
 733                 else
 734                         self.respawn_countdown = -1; // do not count down
 735                 if (random() < 0.5)
 736                 {
 737                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 738                         self.dead_frame = self.anim_dead1_x;
 739                 }
 740                 else
 741                 {
 742                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 743                         self.dead_frame = self.anim_dead2_x;
 744                 }
 745                 // set damage function to corpse damage
 746                 self.event_damage = PlayerCorpseDamage;
 747                 // call the corpse damage function just in case it wants to gib
 748                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 749                 // set up to fade out later
 750                 SUB_SetFade (self, time + 6 + random (), 1);
 751
 752                 if(sv_gentle > 0 || autocvar_ekg) {
 753                         // remove corpse
 754                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 755                 }
 756
 757                 // reset fields the weapons may use just in case
 758                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 759                 {
 760                         weapon_action(j, WR_RESETPLAYER);
 761                         ATTACK_FINISHED_FOR(self, j) = 0;
 762                 }
 763         }
 764 }
 765
 766 .float muted; // to be used by prvm_edictset server playernumber muted 1
 767 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 768 // message "": do not say, just test flood control
 769 // return value:
 770 //   1 = accept
 771 //   0 = reject
 772 //  -1 = fake accept
 773 {
 774         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 775         float flood, privatemsgprefixlen;
 776         var .float flood_field;
 777         entity head;
 778         float ret;
 779
 780         if(Ban_MaybeEnforceBan(source))
 781                 return 0;
 782
 783         if(!teamsay && !privatesay)
 784                 if(substring(msgin, 0, 1) == " ")
 785                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 786
 787         msgin = formatmessage(msgin);
 788
 789         if(source.classname != "player")
 790                 colorstr = "^0"; // black for spectators
 791         else if(teams_matter)
 792                 colorstr = Team_ColorCode(source.team);
 793         else
 794                 teamsay = FALSE;
 795
 796         if(intermission_running)
 797                 teamsay = FALSE;
 798
 799         if(msgin != "")
 800                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 801
 802         /*
 803          * using bprint solves this... me stupid
 804         // how can we prevent the message from appearing in a listen server?
 805         // for now, just give "say" back and only handle say_team
 806         if(!teamsay)
 807         {
 808                 clientcommand(self, strcat("say ", msgin));
 809                 return;
 810         }
 811         */
 812
 813         if(autocvar_g_chat_teamcolors)
 814                 namestr = playername(source);
 815         else
 816                 namestr = source.netname;
 817
 818         if(msgin != "")
 819         {
 820                 if(privatesay)
 821                 {
 822                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 823                         privatemsgprefixlen = strlen(msgstr);
 824                         msgstr = strcat(msgstr, msgin);
 825                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 826                         if(autocvar_g_chat_teamcolors)
 827                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 828                         else
 829                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 830                 }
 831                 else if(teamsay)
 832                 {
 833                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 834                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 835                 }
 836                 else
 837                 {
 838                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 839                         cmsgstr = "";
 840                 }
 841                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 842         }
 843         else
 844         {
 845                 msgstr = cmsgstr = "";
 846         }
 847
 848         fullmsgstr = msgstr;
 849         fullcmsgstr = cmsgstr;
 850
 851         // FLOOD CONTROL
 852         flood = 0;
 853         if(floodcontrol)
 854         {
 855                 float flood_spl;
 856                 float flood_burst;
 857                 float flood_lmax;
 858                 float lines;
 859                 if(privatesay)
 860                 {
 861                         flood_spl = autocvar_g_chat_flood_spl_tell;
 862                         flood_burst = autocvar_g_chat_flood_burst_tell;
 863                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 864                         flood_field = floodcontrol_chattell;
 865                 }
 866                 else if(teamsay)
 867                 {
 868                         flood_spl = autocvar_g_chat_flood_spl_team;
 869                         flood_burst = autocvar_g_chat_flood_burst_team;
 870                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 871                         flood_field = floodcontrol_chatteam;
 872                 }
 873                 else
 874                 {
 875                         flood_spl = autocvar_g_chat_flood_spl;
 876                         flood_burst = autocvar_g_chat_flood_burst;
 877                         flood_lmax = autocvar_g_chat_flood_lmax;
 878                         flood_field = floodcontrol_chat;
 879                 }
 880                 flood_burst = max(0, flood_burst - 1);
 881                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 882
 883                 // do flood control for the default line size
 884                 if(msgstr != "")
 885                 {
 886                         getWrappedLine_remaining = msgstr;
 887                         msgstr = "";
 888                         lines = 0;
 889                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 890                         {
 891                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 892                                 ++lines;
 893                         }
 894                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 895
 896                         if(getWrappedLine_remaining != "")
 897                         {
 898                                 msgstr = strcat(msgstr, "\n");
 899                                 flood = 2;
 900                         }
 901
 902                         if(time >= source.flood_field)
 903                         {
 904                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 905                         }
 906                         else
 907                         {
 908                                 flood = 1;
 909                                 msgstr = fullmsgstr;
 910                         }
 911                 }
 912                 else
 913                 {
 914                         if(time >= source.flood_field)
 915                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 916                         else
 917                                 flood = 1;
 918                 }
 919
 920                 if (timeoutStatus == 2) //when game is paused, no flood protection
 921                         source.flood_field = flood = 0;
 922         }
 923
 924         if(flood == 2) // cannot happen for empty msgstr
 925         {
 926                 if(autocvar_g_chat_flood_notify_flooder)
 927                 {
 928                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 929                         sourcecmsgstr = "";
 930                 }
 931                 else
 932                 {
 933                         sourcemsgstr = fullmsgstr;
 934                         sourcecmsgstr = fullcmsgstr;
 935                 }
 936                 cmsgstr = "";
 937         }
 938         else
 939         {
 940                 sourcemsgstr = msgstr;
 941                 sourcecmsgstr = cmsgstr;
 942         }
 943
 944         if(!privatesay)
 945         if(source.classname != "player")
 946         {
 947                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 948                         teamsay = -1; // spectators
 949         }
 950
 951         if(flood)
 952                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 953
 954         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 955         if(privatesay)
 956                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 957
 958         if(source.muted)
 959         {
 960                 // always fake the message
 961                 ret = -1;
 962         }
 963         else if(flood == 1)
 964         {
 965                 if(autocvar_g_chat_flood_notify_flooder)
 966                 {
 967                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 968                         ret = 0;
 969                 }
 970                 else
 971                         ret = -1;
 972         }
 973         else
 974         {
 975                 ret = 1;
 976         }
 977
 978         if(sourcemsgstr != "" && ret != 0)
 979         {
 980                 if(ret < 0) // fake
 981                 {
 982                         sprint(source, sourcemsgstr);
 983                         if(sourcecmsgstr != "" && !privatesay)
 984                                 centerprint(source, sourcecmsgstr);
 985                 }
 986                 else if(privatesay)
 987                 {
 988                         sprint(source, sourcemsgstr);
 989                         sprint(privatesay, msgstr);
 990                         if(cmsgstr != "")
 991                                 centerprint(privatesay, cmsgstr);
 992                 }
 993                 else if(teamsay > 0)
 994                 {
 995                         sprint(source, sourcemsgstr);
 996                         if(sourcecmsgstr != "")
 997                                 centerprint(source, sourcecmsgstr);
 998                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 999                                 if(head != source)
1000                                 {
1001                                         sprint(head, msgstr);
1002                                         if(cmsgstr != "")
1003                                                 centerprint(head, cmsgstr);
1004                                 }
1005                 }
1006                 else if(teamsay < 0)
1007                 {
1008                         sprint(source, sourcemsgstr);
1009                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1010                                 if(head != source)
1011                                         sprint(head, msgstr);
1012                 }
1013                 else if(sourcemsgstr != msgstr)
1014                 {
1015                         sprint(source, sourcemsgstr);
1016                         FOR_EACH_REALCLIENT(head)
1017                                 if(head != source)
1018                                         sprint(head, msgstr);
1019                 }
1020                 else
1021                         bprint(msgstr);
1022         }
1023
1024         return ret;
1025 }
1026
1027 float GetVoiceMessageVoiceType(string type)
1028 {
1029         if(type == "taunt")
1030                 return VOICETYPE_TAUNT;
1031         if(type == "teamshoot")
1032                 return VOICETYPE_LASTATTACKER;
1033         return VOICETYPE_TEAMRADIO;
1034 }
1035
1036 string allvoicesamples;
1037 .string GetVoiceMessageSampleField(string type)
1038 {
1039         GetPlayerSoundSampleField_notFound = 0;
1040         switch(type)
1041         {
1042 #define _VOICEMSG(m) case #m: return playersound_##m;
1043                 ALLVOICEMSGS
1044 #undef _VOICEMSG
1045         }
1046         GetPlayerSoundSampleField_notFound = 1;
1047         return playersound_taunt;
1048 }
1049
1050 .string GetPlayerSoundSampleField(string type)
1051 {
1052         GetPlayerSoundSampleField_notFound = 0;
1053         switch(type)
1054         {
1055 #define _VOICEMSG(m) case #m: return playersound_##m;
1056                 ALLPLAYERSOUNDS
1057 #undef _VOICEMSG
1058         }
1059         GetPlayerSoundSampleField_notFound = 1;
1060         return playersound_taunt;
1061 }
1062
1063 void PrecacheGlobalSound(string samplestring)
1064 {
1065         float n, i;
1066         tokenize_console(samplestring);
1067         n = stof(argv(1));
1068         if(n > 0)
1069         {
1070                 for(i = 1; i <= n; ++i)
1071                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1072         }
1073         else
1074         {
1075                 precache_sound(strcat(argv(0), ".wav"));
1076         }
1077 }
1078
1079 void PrecachePlayerSounds(string f)
1080 {
1081         float fh;
1082         string s;
1083         fh = fopen(f, FILE_READ);
1084         if(fh < 0)
1085                 return;
1086         while((s = fgets(fh)))
1087         {
1088                 if(tokenize_console(s) != 3)
1089                 {
1090                         dprint("Invalid sound info line: ", s, "\n");
1091                         continue;
1092                 }
1093                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1094         }
1095         fclose(fh);
1096
1097         if not(allvoicesamples)
1098         {
1099 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1100                 ALLVOICEMSGS
1101 #undef _VOICEMSG
1102                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1103         }
1104 }
1105
1106 void ClearPlayerSounds()
1107 {
1108 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1109         ALLPLAYERSOUNDS
1110         ALLVOICEMSGS
1111 #undef _VOICEMSG
1112 }
1113
1114 float LoadPlayerSounds(string f, float first)
1115 {
1116         float fh;
1117         string s;
1118         var .string field;
1119         fh = fopen(f, FILE_READ);
1120         if(fh < 0)
1121         {
1122                 dprint("Player sound file not found: ", f, "\n");
1123                 return 0;
1124         }
1125         while((s = fgets(fh)))
1126         {
1127                 if(tokenize_console(s) != 3)
1128                         continue;
1129                 field = GetPlayerSoundSampleField(argv(0));
1130                 if(GetPlayerSoundSampleField_notFound)
1131                         field = GetVoiceMessageSampleField(argv(0));
1132                 if(GetPlayerSoundSampleField_notFound)
1133                         continue;
1134                 if(self.field)
1135                         strunzone(self.field);
1136                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1137         }
1138         fclose(fh);
1139         return 1;
1140 }
1141
1142 .float modelindex_for_playersound;
1143 .float skinindex_for_playersound;
1144 void UpdatePlayerSounds()
1145 {
1146         if(self.modelindex == self.modelindex_for_playersound)
1147         if(self.skinindex == self.skinindex_for_playersound)
1148                 return;
1149         self.modelindex_for_playersound = self.modelindex;
1150         self.skinindex_for_playersound = self.skinindex;
1151         ClearPlayerSounds();
1152         LoadPlayerSounds("sound/player/default.sounds", 1);
1153         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1154                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1155 }
1156
1157 void FakeGlobalSound(string sample, float chan, float voicetype)
1158 {
1159         float n;
1160         float tauntrand;
1161
1162         if(sample == "")
1163                 return;
1164
1165         tokenize_console(sample);
1166         n = stof(argv(1));
1167         if(n > 0)
1168                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1169         else
1170                 sample = strcat(argv(0), ".wav"); // randomization
1171
1172         switch(voicetype)
1173         {
1174                 case VOICETYPE_LASTATTACKER_ONLY:
1175                         break;
1176                 case VOICETYPE_LASTATTACKER:
1177                         if(self.pusher)
1178                         {
1179                                 msg_entity = self;
1180                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1181                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1182                         }
1183                         break;
1184                 case VOICETYPE_TEAMRADIO:
1185                         msg_entity = self;
1186                         if(msg_entity.cvar_cl_voice_directional == 1)
1187                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1188                         else
1189                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1190                         break;
1191                 case VOICETYPE_AUTOTAUNT:
1192                         if(!sv_autotaunt)
1193                                 break;
1194                         if(!sv_taunt)
1195                                 break;
1196                         if(sv_gentle)
1197                                 break;
1198                         tauntrand = random();
1199                         msg_entity = self;
1200                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1201                         {
1202                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1203                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1204                                 else
1205                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1206                         }
1207                         break;
1208                 case VOICETYPE_TAUNT:
1209                         if(self.classname == "player")
1210                                 if(self.deadflag == DEAD_NO)
1211                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1212                         if(!sv_taunt)
1213                                 break;
1214                         if(sv_gentle)
1215                                 break;
1216                         msg_entity = self;
1217                         if (msg_entity.cvar_cl_voice_directional >= 1)
1218                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1219                         else
1220                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1221                         break;
1222                 case VOICETYPE_PLAYERSOUND:
1223                         msg_entity = self;
1224                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1225                         break;
1226                 default:
1227                         backtrace("Invalid voice type!");
1228                         break;
1229         }
1230 }
1231
1232 void GlobalSound(string sample, float chan, float voicetype)
1233 {
1234         float n;
1235         float tauntrand;
1236
1237         if(sample == "")
1238                 return;
1239
1240         tokenize_console(sample);
1241         n = stof(argv(1));
1242         if(n > 0)
1243                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1244         else
1245                 sample = strcat(argv(0), ".wav"); // randomization
1246
1247         switch(voicetype)
1248         {
1249                 case VOICETYPE_LASTATTACKER_ONLY:
1250                         if(self.pusher)
1251                         {
1252                                 msg_entity = self.pusher;
1253                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1254                                 {
1255                                         if(msg_entity.cvar_cl_voice_directional == 1)
1256                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1257                                         else
1258                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1259                                 }
1260                         }
1261                         break;
1262                 case VOICETYPE_LASTATTACKER:
1263                         if(self.pusher)
1264                         {
1265                                 msg_entity = self.pusher;
1266                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1267                                 {
1268                                         if(msg_entity.cvar_cl_voice_directional == 1)
1269                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1270                                         else
1271                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1272                                 }
1273                                 msg_entity = self;
1274                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1275                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1276                         }
1277                         break;
1278                 case VOICETYPE_TEAMRADIO:
1279                         FOR_EACH_REALCLIENT(msg_entity)
1280                                 if(!teams_matter || msg_entity.team == self.team)
1281                                 {
1282                                         if(msg_entity.cvar_cl_voice_directional == 1)
1283                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1284                                         else
1285                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1286                                 }
1287                         break;
1288                 case VOICETYPE_AUTOTAUNT:
1289                         if(!sv_autotaunt)
1290                                 break;
1291                         if(!sv_taunt)
1292                                 break;
1293                         if(sv_gentle)
1294                                 break;
1295                         tauntrand = random();
1296                         FOR_EACH_REALCLIENT(msg_entity)
1297                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1298                                 {
1299                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1300                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1301                                         else
1302                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1303                                 }
1304                         break;
1305                 case VOICETYPE_TAUNT:
1306                         if(self.classname == "player")
1307                                 if(self.deadflag == DEAD_NO)
1308                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1309                         if(!sv_taunt)
1310                                 break;
1311                         if(sv_gentle)
1312                                 break;
1313                         FOR_EACH_REALCLIENT(msg_entity)
1314                         {
1315                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1316                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1317                                 else
1318                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1319                         }
1320                         break;
1321                 case VOICETYPE_PLAYERSOUND:
1322                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1323                         break;
1324                 default:
1325                         backtrace("Invalid voice type!");
1326                         break;
1327         }
1328 }
1329
1330 void PlayerSound(.string samplefield, float chan, float voicetype)
1331 {
1332         GlobalSound(self.samplefield, chan, voicetype);
1333 }
1334
1335 void VoiceMessage(string type, string msg)
1336 {
1337         var .string sample;
1338         float voicetype, ownteam;
1339         float flood;
1340         sample = GetVoiceMessageSampleField(type);
1341
1342         if(GetPlayerSoundSampleField_notFound)
1343         {
1344                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1345                 return;
1346         }
1347
1348         voicetype = GetVoiceMessageVoiceType(type);
1349         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1350
1351         flood = Say(self, ownteam, world, msg, 1);
1352
1353         if (flood > 0)
1354                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1355         else if (flood < 0)
1356                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1357 }
1358
1359 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1360 {
1361 //      show_message
1362 //      0 (00) automove centerprint, admin message
1363 //      1 (01) automove centerprint, no admin message
1364 //      2 (10) no centerprint, admin message
1365 //      3 (11) no centerprint, no admin message
1366
1367         float lockteams_backup;
1368
1369         lockteams_backup = lockteams;  // backup any team lock
1370
1371         lockteams = 0;  // disable locked teams
1372
1373         TeamchangeFrags(client);  // move the players frags
1374         SetPlayerColors(client, team_colour - 1);  // set the players colour
1375         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1376
1377         lockteams = lockteams_backup;  // restore the team lock
1378
1379         LogTeamchange(client.playerid, client.team, type);
1380
1381         if not(show_message & 1) // admin message
1382                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1383
1384         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1385 }