qcsrc/server/cl_player.qc

   1 .entity pusher;
   2 .float pushltime;
   3 .float istypefrag;
   4
   5 .float CopyBody_nextthink;
   6 .void(void) CopyBody_think;
   7 void CopyBody_Think(void)
   8 {
   9         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
  10         {
  11                 self.CopyBody_think();
  12                 if(wasfreed(self))
  13                         return;
  14                 self.CopyBody_nextthink = self.nextthink;
  15                 self.CopyBody_think = self.think;
  16                 self.think = CopyBody_Think;
  17         }
  18         CSQCMODEL_AUTOUPDATE();
  19         self.nextthink = time;
  20 }
  21 void CopyBody(float keepvelocity)
  22 {
  23         entity oldself;
  24         if (self.effects & EF_NODRAW)
  25                 return;
  26         oldself = self;
  27         self = spawn();
  28         self.enemy = oldself;
  29         self.lip = oldself.lip;
  30         self.colormap = oldself.colormap;
  31         self.iscreature = oldself.iscreature;
  32         self.teleportable = oldself.teleportable;
  33         self.damagedbycontents = oldself.damagedbycontents;
  34         self.angles = oldself.angles;
  35         self.v_angle = oldself.v_angle;
  36         self.avelocity = oldself.avelocity;
  37         self.classname = "body";
  38         self.damageforcescale = oldself.damageforcescale;
  39         self.effects = oldself.effects;
  40         self.glowmod = oldself.glowmod;
  41         self.event_damage = oldself.event_damage;
  42         self.anim_state = oldself.anim_state;
  43         self.anim_time = oldself.anim_time;
  44         self.anim_lower_action = oldself.anim_lower_action;
  45         self.anim_lower_time = oldself.anim_lower_time;
  46         self.anim_upper_action = oldself.anim_upper_action;
  47         self.anim_upper_time = oldself.anim_upper_time;
  48         self.anim_implicit_state = oldself.anim_implicit_state;
  49         self.anim_implicit_time = oldself.anim_implicit_time;
  50         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
  51         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
  52         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
  53         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
  54         self.dphitcontentsmask = oldself.dphitcontentsmask;
  55         self.death_time = oldself.death_time;
  56         self.pain_finished = oldself.pain_finished;
  57         self.health = oldself.health;
  58         self.armorvalue = oldself.armorvalue;
  59         self.armortype = oldself.armortype;
  60         self.model = oldself.model;
  61         self.modelindex = oldself.modelindex;
  62         self.skin = oldself.skin;
  63         self.species = oldself.species;
  64         self.movetype = oldself.movetype;
  65         self.solid = oldself.solid;
  66         self.ballistics_density = oldself.ballistics_density;
  67         self.takedamage = oldself.takedamage;
  68         self.customizeentityforclient = oldself.customizeentityforclient;
  69         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
  70         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
  71         if (keepvelocity == 1)
  72                 self.velocity = oldself.velocity;
  73         self.oldvelocity = self.velocity;
  74         self.alpha = oldself.alpha;
  75         self.fade_time = oldself.fade_time;
  76         self.fade_rate = oldself.fade_rate;
  77         //self.weapon = oldself.weapon;
  78         setorigin(self, oldself.origin);
  79         setsize(self, oldself.mins, oldself.maxs);
  80         self.prevorigin = oldself.origin;
  81         self.reset = SUB_Remove;
  82
  83         Drag_MoveDrag(oldself, self);
  84
  85         if(self.colormap <= maxclients && self.colormap > 0)
  86                 self.colormap = 1024 + oldself.clientcolors;
  87
  88         CSQCMODEL_AUTOINIT();
  89         self.CopyBody_nextthink = oldself.nextthink;
  90         self.CopyBody_think = oldself.think;
  91         self.nextthink = time;
  92         self.think = CopyBody_Think;
  93         // "bake" the current animation frame for clones (they don't get clientside animation)
  94         animdecide_load_if_needed(self);
  95         animdecide_setframes(self, false, frame, frame1time, frame2, frame2time);
  96
  97         self = oldself;
  98 }
  99
 100 float player_getspecies()
 101 {
 102         float s;
 103         get_model_parameters(self.model, self.skin);
 104         s = get_model_parameters_species;
 105         get_model_parameters(string_null, 0);
 106         if(s < 0)
 107                 return SPECIES_HUMAN;
 108         return s;
 109 }
 110
 111 void player_setupanimsformodel()
 112 {
 113         // load animation info
 114         animdecide_load_if_needed(self);
 115         animdecide_setstate(self, 0, false);
 116 }
 117
 118 void player_anim (void)
 119 {
 120         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 121         if(self.deadflag) {
 122                 if (!deadbits) {
 123                         // Decide on which death animation to use.
 124                         if(random() < 0.5)
 125                                 deadbits = ANIMSTATE_DEAD1;
 126                         else
 127                                 deadbits = ANIMSTATE_DEAD2;
 128                 }
 129         } else {
 130                 // Clear a previous death animation.
 131                 deadbits = 0;
 132         }
 133         float animbits = deadbits;
 134         if(self.frozen)
 135                 animbits |= ANIMSTATE_FROZEN;
 136         if(self.crouch)
 137                 animbits |= ANIMSTATE_DUCK;
 138         animdecide_setstate(self, animbits, false);
 139         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 140
 141         if (self.weaponentity)
 142         {
 143                 updateanim(self.weaponentity);
 144                 if (!self.weaponentity.animstate_override)
 145                         setanim(self.weaponentity, self.weaponentity.anim_idle, true, false, false);
 146         }
 147 }
 148
 149 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 150 {
 151         float take, save;
 152         vector v;
 153         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 154
 155         // damage resistance (ignore most of the damage from a bullet or similar)
 156         damage = max(damage - 5, 1);
 157
 158         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 159         take = v.x;
 160         save = v.y;
 161
 162         if(sound_allowed(MSG_BROADCAST, attacker))
 163         {
 164                 if (save > 10)
 165                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 166                 else if (take > 30)
 167                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 168                 else if (take > 10)
 169                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM);
 170         }
 171
 172         if (take > 50)
 173                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 174         if (take > 100)
 175                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 176
 177         self.armorvalue = self.armorvalue - save;
 178         self.health = self.health - take;
 179         // pause regeneration for 5 seconds
 180         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 181
 182         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 183         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 184         self.dmg_inflictor = inflictor;
 185
 186         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 187         {
 188                 // don't use any animations as a gib
 189                 self.frame = 0;
 190                 // view just above the floor
 191                 self.view_ofs = '0 0 4';
 192
 193                 Violence_GibSplash(self, 1, 1, attacker);
 194                 self.alpha = -1;
 195                 self.solid = SOLID_NOT; // restore later
 196                 self.takedamage = DAMAGE_NO; // restore later
 197                 self.damagedbycontents = false;
 198         }
 199 }
 200
 201 // g_<gametype>_str:
 202 // If 0, default is used.
 203 // If <0, 0 is used.
 204 // Otherwise, g_str (default value) is used.
 205 // For consistency, negative values there are mapped to zero too.
 206 #define GAMETYPE_DEFAULTED_SETTING(str) \
 207         ((gametype_setting_tmp = cvar(strcat("g_", GetGametype(), "_" #str))), \
 208          (gametype_setting_tmp < 0) ? 0 : \
 209          (gametype_setting_tmp == 0) ? max(0, autocvar_g_##str) : \
 210          gametype_setting_tmp)
 211
 212
 213 void calculate_player_respawn_time()
 214 {
 215         if(g_ca)
 216                 return;
 217
 218         float gametype_setting_tmp;
 219         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
 220         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
 221         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
 222         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
 223         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
 224         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
 225
 226         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
 227         entity pl;
 228         if (teamplay)
 229         {
 230                 FOR_EACH_PLAYER(pl)
 231                         if (pl != self)
 232                                 if (pl.team == self.team)
 233                                         ++pcount;
 234                 if (sdelay_small_count == 0)
 235                         sdelay_small_count = 1;
 236                 if (sdelay_large_count == 0)
 237                         sdelay_large_count = 1;
 238         }
 239         else
 240         {
 241                 FOR_EACH_PLAYER(pl)
 242                         if (pl != self)
 243                                 ++pcount;
 244                 if (sdelay_small_count == 0)
 245                 {
 246                         if (g_cts)
 247                         {
 248                                 // Players play independently. No point in requiring enemies.
 249                                 sdelay_small_count = 1;
 250                         }
 251                         else
 252                         {
 253                                 // Players play AGAINST each other. Enemies required.
 254                                 sdelay_small_count = 2;
 255                         }
 256                 }
 257                 if (sdelay_large_count == 0)
 258                 {
 259                         if (g_cts)
 260                         {
 261                                 // Players play independently. No point in requiring enemies.
 262                                 sdelay_large_count = 1;
 263                         }
 264                         else
 265                         {
 266                                 // Players play AGAINST each other. Enemies required.
 267                                 sdelay_large_count = 2;
 268                         }
 269                 }
 270         }
 271
 272         float sdelay;
 273
 274         if (pcount <= sdelay_small_count)
 275                 sdelay = sdelay_small;
 276         else if (pcount >= sdelay_large_count)
 277                 sdelay = sdelay_large;
 278         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
 279                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
 280
 281         if(waves)
 282                 self.respawn_time = ceil((time + sdelay) / waves) * waves;
 283         else
 284                 self.respawn_time = time + sdelay;
 285
 286         if(sdelay < sdelay_max)
 287                 self.respawn_time_max = time + sdelay_max;
 288         else
 289                 self.respawn_time_max = self.respawn_time;
 290
 291         if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 292                 self.respawn_countdown = 10; // first number to count down from is 10
 293         else
 294                 self.respawn_countdown = -1; // do not count down
 295
 296         if(autocvar_g_forced_respawn)
 297                 self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 298 }
 299
 300 void ClientKill_Now_TeamChange();
 301
 302 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 303 {
 304         float take, save, dh, da, j;
 305         vector v;
 306         float valid_damage_for_weaponstats;
 307         float excess;
 308
 309         dh = max(self.health, 0);
 310         da = max(self.armorvalue, 0);
 311
 312         if(!DEATH_ISSPECIAL(deathtype))
 313         {
 314                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 315                 if(self != attacker)
 316                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 317         }
 318
 319         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 320         {
 321                 // tuba causes blood to come out of the ears
 322                 vector ear1, ear2;
 323                 vector d;
 324                 float f;
 325                 ear1 = self.origin;
 326                 ear1_z += 0.125 * self.view_ofs.z + 0.875 * self.maxs.z; // 7/8
 327                 ear2 = ear1;
 328                 makevectors(self.angles);
 329                 ear1 += v_right * -10;
 330                 ear2 += v_right * +10;
 331                 d = inflictor.origin - self.origin;
 332                 if (d)
 333                         f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 334                 else
 335                         f = 0;  // Assum ecenter.
 336                 force = v_right * vlen(force);
 337                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 338                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 339                 if(f > 0)
 340                 {
 341                         hitloc = ear1;
 342                         force = force * -1;
 343                 }
 344                 else
 345                 {
 346                         hitloc = ear2;
 347                         // force is already good
 348                 }
 349         }
 350         else
 351                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 352
 353
 354         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, deathtype, damage);
 355         take = v.x;
 356         save = v.y;
 357
 358         if(attacker == self)
 359         {
 360                 // don't reset pushltime for self damage as it may be an attempt to
 361                 // escape a lava pit or similar
 362                 //self.pushltime = 0;
 363                 self.istypefrag = 0;
 364         }
 365         else if(IS_PLAYER(attacker))
 366         {
 367                 self.pusher = attacker;
 368                 self.pushltime = time + autocvar_g_maxpushtime;
 369                 self.istypefrag = self.BUTTON_CHAT;
 370         }
 371         else if(time < self.pushltime)
 372         {
 373                 attacker = self.pusher;
 374                 self.pushltime = max(self.pushltime, time + 0.6);
 375         }
 376         else
 377         {
 378                 self.pushltime = 0;
 379                 self.istypefrag = 0;
 380         }
 381
 382         frag_inflictor = inflictor;
 383         frag_attacker = attacker;
 384         frag_target = self;
 385         frag_damage = damage;
 386         damage_take = take;
 387         damage_save = save;
 388         damage_force = force;
 389         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 390         take = bound(0, damage_take, self.health);
 391         save = bound(0, damage_save, self.armorvalue);
 392         excess = max(0, damage - take - save);
 393
 394         if(sound_allowed(MSG_BROADCAST, attacker))
 395         {
 396                 if (save > 10)
 397                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTEN_NORM);
 398                 else if (take > 30)
 399                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTEN_NORM);
 400                 else if (take > 10)
 401                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTEN_NORM); // FIXME possibly remove them?
 402         }
 403
 404         if (take > 50)
 405                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 406         if (take > 100)
 407                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 408
 409         if (time >= self.spawnshieldtime)
 410         {
 411                 if (!(self.flags & FL_GODMODE))
 412                 {
 413                         self.armorvalue = self.armorvalue - save;
 414                         self.health = self.health - take;
 415                         // pause regeneration for 5 seconds
 416                         if(take)
 417                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 418
 419                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 420                         {
 421                                 self.pain_finished = time + 0.5;        //Supajoe
 422
 423                                 if(autocvar_sv_gentle < 1) {
 424                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 425                                         {
 426                                                 if (!self.animstate_override)
 427                                                 {
 428                                                         if (random() > 0.5)
 429                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, true);
 430                                                         else
 431                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, true);
 432                                                 }
 433                                         }
 434
 435                                         if(sound_allowed(MSG_BROADCAST, attacker))
 436                                         if((self.health < 2 * WEP_CVAR_PRI(blaster, damage) * autocvar_g_balance_selfdamagepercent + 1) || !((get_weaponinfo(DEATH_WEAPONOF(deathtype))).spawnflags & WEP_FLAG_CANCLIMB) || attacker != self) // WEAPONTODO: create separate limit for pain notification with laser
 437                                         if(self.health > 1)
 438                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 439                                         {
 440                                                 if(deathtype == DEATH_FALL)
 441                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 442                                                 else if(self.health > 75) // TODO make a "gentle" version?
 443                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 444                                                 else if(self.health > 50)
 445                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 446                                                 else if(self.health > 25)
 447                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 448                                                 else
 449                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 450                                         }
 451                                 }
 452                         }
 453
 454                         // throw off bot aim temporarily
 455                         float shake;
 456                         if(IS_BOT_CLIENT(self) && self.health >= 1)
 457                         {
 458                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 459                                 self.v_angle_x = self.v_angle.x + (random() * 2 - 1) * shake;
 460                                 self.v_angle_y = self.v_angle.y + (random() * 2 - 1) * shake;
 461                                 self.v_angle_x = bound(-90, self.v_angle.x, 90);
 462                         }
 463                 }
 464                 else
 465                         self.max_armorvalue += (save + take);
 466         }
 467         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 468         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 469         self.dmg_inflictor = inflictor;
 470
 471         float abot, vbot, awep;
 472         abot = (IS_BOT_CLIENT(attacker));
 473         vbot = (IS_BOT_CLIENT(self));
 474
 475         valid_damage_for_weaponstats = 0;
 476         awep = 0;
 477
 478         if(vbot || IS_REAL_CLIENT(self))
 479         if(abot || IS_REAL_CLIENT(attacker))
 480         if(attacker && self != attacker)
 481         if(DIFF_TEAM(self, attacker))
 482         {
 483                 if(DEATH_ISSPECIAL(deathtype))
 484                         awep = attacker.weapon;
 485                 else
 486                         awep = DEATH_WEAPONOF(deathtype);
 487                 valid_damage_for_weaponstats = 1;
 488         }
 489
 490         if(valid_damage_for_weaponstats)
 491         {
 492                 dh = dh - max(self.health, 0);
 493                 da = da - max(self.armorvalue, 0);
 494                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 495         }
 496
 497         if (self.health < 1)
 498         {
 499                 float defer_ClientKill_Now_TeamChange;
 500                 defer_ClientKill_Now_TeamChange = false;
 501
 502                 if(self.alivetime)
 503                 {
 504                         PS_GR_P_ADDVAL(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 505                         self.alivetime = 0;
 506                 }
 507
 508                 if(valid_damage_for_weaponstats)
 509                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 510
 511                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 512                 if(sound_allowed(MSG_BROADCAST, attacker))
 513                 {
 514                         if(deathtype == DEATH_DROWN)
 515                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 516                         else
 517                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 518                 }
 519
 520                 // get rid of kill indicator
 521                 if(self.killindicator)
 522                 {
 523                         remove(self.killindicator);
 524                         self.killindicator = world;
 525                         if(self.killindicator_teamchange)
 526                                 defer_ClientKill_Now_TeamChange = true;
 527
 528                         if(self.classname == "body")
 529                         if(deathtype == DEATH_KILL)
 530                         {
 531                                 // for the lemmings fans, a small harmless explosion
 532                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 533                         }
 534                 }
 535
 536                 // print an obituary message
 537                 if(self.classname != "body")
 538                         Obituary (attacker, inflictor, self, deathtype);
 539
 540         // increment frag counter for used weapon type
 541         float w;
 542         w = DEATH_WEAPONOF(deathtype);
 543         if(WEP_VALID(w))
 544         if(accuracy_isgooddamage(attacker, self))
 545         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 546
 547                 frag_attacker = attacker;
 548                 frag_inflictor = inflictor;
 549                 frag_target = self;
 550                 frag_deathtype = deathtype;
 551                 MUTATOR_CALLHOOK(PlayerDies);
 552
 553                 WEP_ACTION(self.weapon, WR_PLAYERDEATH);
 554
 555                 RemoveGrapplingHook(self);
 556
 557                 Portal_ClearAllLater(self);
 558
 559                 self.fixangle = true;
 560
 561                 if(defer_ClientKill_Now_TeamChange)
 562                         ClientKill_Now_TeamChange(); // can turn player into spectator
 563
 564                 // player could have been miraculously resuscitated ;)
 565                 // e.g. players in freezetag get frozen, they don't really die
 566                 if(self.health >= 1 || !(IS_PLAYER(self) || self.classname == "body"))
 567                         return;
 568
 569                 // when we get here, player actually dies
 570
 571                 Unfreeze(self); // remove any icy remains
 572                 self.health = 0; // Unfreeze resets health, so we need to set it back
 573
 574                 // clear waypoints
 575                 WaypointSprite_PlayerDead();
 576                 // throw a weapon
 577                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 578
 579                 // become fully visible
 580                 self.alpha = default_player_alpha;
 581                 // make the corpse upright (not tilted)
 582                 self.angles_x = 0;
 583                 self.angles_z = 0;
 584                 // don't spin
 585                 self.avelocity = '0 0 0';
 586                 // view from the floor
 587                 self.view_ofs = '0 0 -8';
 588                 // toss the corpse
 589                 self.movetype = MOVETYPE_TOSS;
 590                 // shootable corpse
 591                 self.solid = SOLID_CORPSE;
 592                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 593                 // don't stick to the floor
 594                 self.flags &= ~FL_ONGROUND;
 595                 // dying animation
 596                 self.deadflag = DEAD_DYING;
 597
 598                 // when to allow respawn
 599                 calculate_player_respawn_time();
 600
 601                 self.death_time = time;
 602                 if (random() < 0.5)
 603                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, true);
 604                 else
 605                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, true);
 606                 if (self.maxs.z > 5)
 607                 {
 608                         self.maxs_z = 5;
 609                         setsize(self, self.mins, self.maxs);
 610                 }
 611                 // set damage function to corpse damage
 612                 self.event_damage = PlayerCorpseDamage;
 613                 // call the corpse damage function just in case it wants to gib
 614                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 615
 616                 // set up to fade out later
 617                 SUB_SetFade (self, time + 6 + random (), 1);
 618                 // reset body think wrapper broken by SUB_SetFade
 619                 if(self.classname == "body" && self.think != CopyBody_Think) {
 620                         self.CopyBody_think = self.think;
 621                         self.CopyBody_nextthink = self.nextthink;
 622                         self.think = CopyBody_Think;
 623                         self.nextthink = time;
 624                 }
 625
 626                 if(autocvar_sv_gentle > 0 || autocvar_ekg || self.classname == "body") {
 627                         // remove corpse
 628                         // clones don't run any animation code any more, so we must gib them when they die :(
 629                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 630                 }
 631
 632                 // reset fields the weapons may use just in case
 633                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 634                 {
 635                         WEP_ACTION(j, WR_RESETPLAYER);
 636                         ATTACK_FINISHED_FOR(self, j) = 0;
 637                 }
 638         }
 639 }
 640
 641 .float muted; // to be used by prvm_edictset server playernumber muted 1
 642 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 643 // message "": do not say, just test flood control
 644 // return value:
 645 //   1 = accept
 646 //   0 = reject
 647 //  -1 = fake accept
 648 {
 649         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, colorprefix;
 650         float flood;
 651         var .float flood_field;
 652         entity head;
 653         float ret;
 654         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 655
 656         if(!teamsay && !privatesay)
 657                 if(substring(msgin, 0, 1) == " ")
 658                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 659
 660         msgin = formatmessage(msgin);
 661
 662         if (!IS_PLAYER(source))
 663                 colorstr = "^0"; // black for spectators
 664         else if(teamplay)
 665                 colorstr = Team_ColorCode(source.team);
 666         else
 667         {
 668                 colorstr = "";
 669                 teamsay = false;
 670         }
 671
 672         if(intermission_running)
 673                 teamsay = false;
 674
 675         if(msgin != "")
 676                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 677
 678         /*
 679          * using bprint solves this... me stupid
 680         // how can we prevent the message from appearing in a listen server?
 681         // for now, just give "say" back and only handle say_team
 682         if(!teamsay)
 683         {
 684                 clientcommand(self, strcat("say ", msgin));
 685                 return;
 686         }
 687         */
 688
 689         if(autocvar_g_chat_teamcolors)
 690                 namestr = playername(source);
 691         else
 692                 namestr = source.netname;
 693
 694         if(strdecolorize(namestr) == namestr)
 695                 colorprefix = "^3";
 696         else
 697                 colorprefix = "^7";
 698
 699         if(msgin != "")
 700         {
 701                 if(privatesay)
 702                 {
 703                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
 704                         privatemsgprefixlen = strlen(msgstr);
 705                         msgstr = strcat(msgstr, msgin);
 706                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
 707                         if(autocvar_g_chat_teamcolors)
 708                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 709                         else
 710                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 711                 }
 712                 else if(teamsay)
 713                 {
 714                         msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
 715                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
 716                 }
 717                 else
 718                 {
 719                         msgstr = strcat("\{1}", colorprefix, namestr, "^7: ", msgin);
 720                         cmsgstr = "";
 721                 }
 722                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 723         }
 724         else
 725         {
 726                 msgstr = cmsgstr = "";
 727         }
 728
 729         fullmsgstr = msgstr;
 730         fullcmsgstr = cmsgstr;
 731
 732         // FLOOD CONTROL
 733         flood = 0;
 734         flood_field = floodcontrol_chat;
 735         if(floodcontrol)
 736         {
 737                 float flood_spl;
 738                 float flood_burst;
 739                 float flood_lmax;
 740                 float lines;
 741                 if(privatesay)
 742                 {
 743                         flood_spl = autocvar_g_chat_flood_spl_tell;
 744                         flood_burst = autocvar_g_chat_flood_burst_tell;
 745                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 746                         flood_field = floodcontrol_chattell;
 747                 }
 748                 else if(teamsay)
 749                 {
 750                         flood_spl = autocvar_g_chat_flood_spl_team;
 751                         flood_burst = autocvar_g_chat_flood_burst_team;
 752                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 753                         flood_field = floodcontrol_chatteam;
 754                 }
 755                 else
 756                 {
 757                         flood_spl = autocvar_g_chat_flood_spl;
 758                         flood_burst = autocvar_g_chat_flood_burst;
 759                         flood_lmax = autocvar_g_chat_flood_lmax;
 760                         flood_field = floodcontrol_chat;
 761                 }
 762                 flood_burst = max(0, flood_burst - 1);
 763                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 764
 765                 // do flood control for the default line size
 766                 if(msgstr != "")
 767                 {
 768                         getWrappedLine_remaining = msgstr;
 769                         msgstr = "";
 770                         lines = 0;
 771                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 772                         {
 773                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 774                                 ++lines;
 775                         }
 776                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 777
 778                         if(getWrappedLine_remaining != "")
 779                         {
 780                                 msgstr = strcat(msgstr, "\n");
 781                                 flood = 2;
 782                         }
 783
 784                         if(time >= source.flood_field)
 785                         {
 786                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 787                         }
 788                         else
 789                         {
 790                                 flood = 1;
 791                                 msgstr = fullmsgstr;
 792                         }
 793                 }
 794                 else
 795                 {
 796                         if(time >= source.flood_field)
 797                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 798                         else
 799                                 flood = 1;
 800                 }
 801
 802                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 803                         source.flood_field = flood = 0;
 804         }
 805
 806         if(flood == 2) // cannot happen for empty msgstr
 807         {
 808                 if(autocvar_g_chat_flood_notify_flooder)
 809                 {
 810                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 811                         sourcecmsgstr = "";
 812                 }
 813                 else
 814                 {
 815                         sourcemsgstr = fullmsgstr;
 816                         sourcecmsgstr = fullcmsgstr;
 817                 }
 818                 cmsgstr = "";
 819         }
 820         else
 821         {
 822                 sourcemsgstr = msgstr;
 823                 sourcecmsgstr = cmsgstr;
 824         }
 825
 826         if(!privatesay)
 827         if (!IS_PLAYER(source))
 828         {
 829                 if (!intermission_running)
 830                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(warmup_stage || gameover)))
 831                                 teamsay = -1; // spectators
 832         }
 833
 834         if(flood)
 835                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 836
 837         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 838         if(privatesay)
 839                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 840
 841         if(source.muted)
 842         {
 843                 // always fake the message
 844                 ret = -1;
 845         }
 846         else if(flood == 1)
 847         {
 848                 if(autocvar_g_chat_flood_notify_flooder)
 849                 {
 850                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 851                         ret = 0;
 852                 }
 853                 else
 854                         ret = -1;
 855         }
 856         else
 857         {
 858                 ret = 1;
 859         }
 860
 861         if(sourcemsgstr != "" && ret != 0)
 862         {
 863                 if(ret < 0) // faked message, because the player is muted
 864                 {
 865                         sprint(source, sourcemsgstr);
 866                         if(sourcecmsgstr != "" && !privatesay)
 867                                 centerprint(source, sourcecmsgstr);
 868                 }
 869                 else if(privatesay) // private message, between 2 people only
 870                 {
 871                         sprint(source, sourcemsgstr);
 872                         sprint(privatesay, msgstr);
 873                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 874                         if(cmsgstr != "")
 875                                 centerprint(privatesay, cmsgstr);
 876                 }
 877                 else if(teamsay > 0) // team message, only sent to team mates
 878                 {
 879                         sprint(source, sourcemsgstr);
 880                         dedicated_print(msgstr); // send to server console too
 881                         if(sourcecmsgstr != "")
 882                                 centerprint(source, sourcecmsgstr);
 883                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 884                                 if(head != source)
 885                                 {
 886                                         sprint(head, msgstr);
 887                                         if(cmsgstr != "")
 888                                                 centerprint(head, cmsgstr);
 889                                 }
 890                 }
 891                 else if(teamsay < 0) // spectator message, only sent to spectators
 892                 {
 893                         sprint(source, sourcemsgstr);
 894                         dedicated_print(msgstr); // send to server console too
 895                         FOR_EACH_REALCLIENT(head) if (!IS_PLAYER(head))
 896                                 if(head != source)
 897                                         sprint(head, msgstr);
 898                 }
 899                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 900                 {
 901                         sprint(source, sourcemsgstr);
 902                         dedicated_print(msgstr); // send to server console too
 903                         FOR_EACH_REALCLIENT(head)
 904                                 if(head != source)
 905                                         sprint(head, msgstr);
 906                 }
 907                 else
 908                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 909         }
 910
 911         return ret;
 912 }
 913
 914 float GetVoiceMessageVoiceType(string type)
 915 {
 916         if(type == "taunt")
 917                 return VOICETYPE_TAUNT;
 918         if(type == "teamshoot")
 919                 return VOICETYPE_LASTATTACKER;
 920         return VOICETYPE_TEAMRADIO;
 921 }
 922
 923 string allvoicesamples;
 924 .string GetVoiceMessageSampleField(string type)
 925 {
 926         GetPlayerSoundSampleField_notFound = 0;
 927         switch(type)
 928         {
 929 #define _VOICEMSG(m) case #m: return playersound_##m;
 930                 ALLVOICEMSGS
 931 #undef _VOICEMSG
 932         }
 933         GetPlayerSoundSampleField_notFound = 1;
 934         return playersound_taunt;
 935 }
 936
 937 .string GetPlayerSoundSampleField(string type)
 938 {
 939         GetPlayerSoundSampleField_notFound = 0;
 940         switch(type)
 941         {
 942 #define _VOICEMSG(m) case #m: return playersound_##m;
 943                 ALLPLAYERSOUNDS
 944 #undef _VOICEMSG
 945         }
 946         GetPlayerSoundSampleField_notFound = 1;
 947         return playersound_taunt;
 948 }
 949
 950 void PrecacheGlobalSound(string samplestring)
 951 {
 952         float n, i;
 953         tokenize_console(samplestring);
 954         n = stof(argv(1));
 955         if(n > 0)
 956         {
 957                 for(i = 1; i <= n; ++i)
 958                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
 959         }
 960         else
 961         {
 962                 precache_sound(strcat(argv(0), ".wav"));
 963         }
 964 }
 965
 966 void PrecachePlayerSounds(string f)
 967 {
 968         float fh;
 969         string s;
 970         fh = fopen(f, FILE_READ);
 971         if(fh < 0)
 972                 return;
 973         while((s = fgets(fh)))
 974         {
 975                 if(tokenize_console(s) != 3)
 976                 {
 977                         dprint("Invalid sound info line: ", s, "\n");
 978                         continue;
 979                 }
 980                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
 981         }
 982         fclose(fh);
 983
 984         if (!allvoicesamples)
 985         {
 986 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
 987                 ALLVOICEMSGS
 988 #undef _VOICEMSG
 989                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
 990         }
 991 }
 992
 993 void ClearPlayerSounds()
 994 {
 995 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
 996         ALLPLAYERSOUNDS
 997         ALLVOICEMSGS
 998 #undef _VOICEMSG
 999 }
1000
1001 float LoadPlayerSounds(string f, float first)
1002 {
1003         float fh;
1004         string s;
1005         var .string field;
1006         fh = fopen(f, FILE_READ);
1007         if(fh < 0)
1008         {
1009                 dprint("Player sound file not found: ", f, "\n");
1010                 return 0;
1011         }
1012         while((s = fgets(fh)))
1013         {
1014                 if(tokenize_console(s) != 3)
1015                         continue;
1016                 field = GetPlayerSoundSampleField(argv(0));
1017                 if(GetPlayerSoundSampleField_notFound)
1018                         field = GetVoiceMessageSampleField(argv(0));
1019                 if(GetPlayerSoundSampleField_notFound)
1020                         continue;
1021                 if(self.field)
1022                         strunzone(self.field);
1023                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1024         }
1025         fclose(fh);
1026         return 1;
1027 }
1028
1029 .float modelindex_for_playersound;
1030 .float skin_for_playersound;
1031 void UpdatePlayerSounds()
1032 {
1033         if(self.modelindex == self.modelindex_for_playersound)
1034         if(self.skin == self.skin_for_playersound)
1035                 return;
1036         self.modelindex_for_playersound = self.modelindex;
1037         self.skin_for_playersound = self.skin;
1038         ClearPlayerSounds();
1039         LoadPlayerSounds("sound/player/default.sounds", 1);
1040         if(!autocvar_g_debug_defaultsounds)
1041                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1042                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1043 }
1044
1045 void FakeGlobalSound(string sample, float chan, float voicetype)
1046 {
1047         float n;
1048         float tauntrand;
1049
1050         if(sample == "")
1051                 return;
1052
1053         tokenize_console(sample);
1054         n = stof(argv(1));
1055         if(n > 0)
1056                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1057         else
1058                 sample = strcat(argv(0), ".wav"); // randomization
1059
1060         switch(voicetype)
1061         {
1062                 case VOICETYPE_LASTATTACKER_ONLY:
1063                         break;
1064                 case VOICETYPE_LASTATTACKER:
1065                         if(self.pusher)
1066                         {
1067                                 msg_entity = self;
1068                                 if(IS_REAL_CLIENT(msg_entity))
1069                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1070                         }
1071                         break;
1072                 case VOICETYPE_TEAMRADIO:
1073                         msg_entity = self;
1074                         if(msg_entity.cvar_cl_voice_directional == 1)
1075                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1076                         else
1077                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1078                         break;
1079                 case VOICETYPE_AUTOTAUNT:
1080                         if(!sv_autotaunt)
1081                                 break;
1082                         if(!sv_taunt)
1083                                 break;
1084                         if(autocvar_sv_gentle)
1085                                 break;
1086                         tauntrand = random();
1087                         msg_entity = self;
1088                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1089                         {
1090                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1091                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1092                                 else
1093                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1094                         }
1095                         break;
1096                 case VOICETYPE_TAUNT:
1097                         if(IS_PLAYER(self))
1098                                 if(self.deadflag == DEAD_NO)
1099                                         animdecide_setaction(self, ANIMACTION_TAUNT, true);
1100                         if(!sv_taunt)
1101                                 break;
1102                         if(autocvar_sv_gentle)
1103                                 break;
1104                         msg_entity = self;
1105                         if (msg_entity.cvar_cl_voice_directional >= 1)
1106                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1107                         else
1108                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1109                         break;
1110                 case VOICETYPE_PLAYERSOUND:
1111                         msg_entity = self;
1112                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NORM);
1113                         break;
1114                 default:
1115                         backtrace("Invalid voice type!");
1116                         break;
1117         }
1118 }
1119
1120 void GlobalSound(string sample, float chan, float voicetype)
1121 {
1122         float n;
1123         float tauntrand;
1124
1125         if(sample == "")
1126                 return;
1127
1128         tokenize_console(sample);
1129         n = stof(argv(1));
1130         if(n > 0)
1131                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1132         else
1133                 sample = strcat(argv(0), ".wav"); // randomization
1134
1135         switch(voicetype)
1136         {
1137                 case VOICETYPE_LASTATTACKER_ONLY:
1138                         if(self.pusher)
1139                         {
1140                                 msg_entity = self.pusher;
1141                                 if(IS_REAL_CLIENT(msg_entity))
1142                                 {
1143                                         if(msg_entity.cvar_cl_voice_directional == 1)
1144                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1145                                         else
1146                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1147                                 }
1148                         }
1149                         break;
1150                 case VOICETYPE_LASTATTACKER:
1151                         if(self.pusher)
1152                         {
1153                                 msg_entity = self.pusher;
1154                                 if(IS_REAL_CLIENT(msg_entity))
1155                                 {
1156                                         if(msg_entity.cvar_cl_voice_directional == 1)
1157                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1158                                         else
1159                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1160                                 }
1161                                 msg_entity = self;
1162                                 if(IS_REAL_CLIENT(msg_entity))
1163                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTEN_NONE);
1164                         }
1165                         break;
1166                 case VOICETYPE_TEAMRADIO:
1167                         FOR_EACH_REALCLIENT(msg_entity)
1168                                 if(!teamplay || msg_entity.team == self.team)
1169                                 {
1170                                         if(msg_entity.cvar_cl_voice_directional == 1)
1171                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_MIN);
1172                                         else
1173                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1174                                 }
1175                         break;
1176                 case VOICETYPE_AUTOTAUNT:
1177                         if(!sv_autotaunt)
1178                                 break;
1179                         if(!sv_taunt)
1180                                 break;
1181                         if(autocvar_sv_gentle)
1182                                 break;
1183                         tauntrand = random();
1184                         FOR_EACH_REALCLIENT(msg_entity)
1185                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1186                                 {
1187                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1188                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1189                                         else
1190                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1191                                 }
1192                         break;
1193                 case VOICETYPE_TAUNT:
1194                         if(IS_PLAYER(self))
1195                                 if(self.deadflag == DEAD_NO)
1196                                         animdecide_setaction(self, ANIMACTION_TAUNT, true);
1197                         if(!sv_taunt)
1198                                 break;
1199                         if(autocvar_sv_gentle)
1200                                 break;
1201                         FOR_EACH_REALCLIENT(msg_entity)
1202                         {
1203                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1204                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTEN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTEN_MAX));
1205                                 else
1206                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTEN_NONE);
1207                         }
1208                         break;
1209                 case VOICETYPE_PLAYERSOUND:
1210                         sound(self, chan, sample, VOL_BASE, ATTEN_NORM);
1211                         break;
1212                 default:
1213                         backtrace("Invalid voice type!");
1214                         break;
1215         }
1216 }
1217
1218 void PlayerSound(.string samplefield, float chan, float voicetype)
1219 {
1220         GlobalSound(self.samplefield, chan, voicetype);
1221 }
1222
1223 void VoiceMessage(string type, string msg)
1224 {
1225         var .string sample;
1226         float voicetype, ownteam;
1227         float flood;
1228         sample = GetVoiceMessageSampleField(type);
1229
1230         if(GetPlayerSoundSampleField_notFound)
1231         {
1232                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1233                 return;
1234         }
1235
1236         voicetype = GetVoiceMessageVoiceType(type);
1237         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1238
1239         flood = Say(self, ownteam, world, msg, 1);
1240
1241         if(IS_SPEC(self) || IS_OBSERVER(self) || flood < 0)
1242                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1243         else if (flood > 0)
1244                 GlobalSound(self.sample, CH_VOICE, voicetype);
1245 }
1246
1247 void MoveToTeam(entity client, float team_colour, float type)
1248 {
1249         float lockteams_backup;
1250
1251         lockteams_backup = lockteams;  // backup any team lock
1252
1253         lockteams = 0;  // disable locked teams
1254
1255         TeamchangeFrags(client);  // move the players frags
1256         SetPlayerColors(client, team_colour - 1);  // set the players colour
1257         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1258
1259         lockteams = lockteams_backup;  // restore the team lock
1260
1261         LogTeamchange(client.playerid, client.team, type);
1262 }