qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(cvar_string("sv_weaponstats_killfile") != "" || cvar_string("sv_weaponstats_damagefile") != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,vwep) ((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1)))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, idx, f;
  16         float fh;
  17         string prefix;
  18         if(weaponstats_buffer < 0)
  19                 return;
  20         prefix = strcat(cvar_string("hostname"), "\t", GetGametype(), "_", GetMapname(), "\t");
  21         if(cvar_string("sv_weaponstats_killfile") != "")
  22         {
  23                 fh = fopen(cvar_string("sv_weaponstats_killfile"), FILE_APPEND);
  24                 if(fh >= 0)
  25                 {
  26                         fputs(fh, "#begin killfile\n");
  27                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  29                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  30                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  31                                 {
  32                                         idx = WEAPONSTATS_GETINDEX(i, j);
  33                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '0 1 0';
  34                                         if(f != 0)
  35                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  36                                 }
  37                         fputs(fh, "#end\n\n");
  38                         fclose(fh);
  39                         print("Weapon kill stats written\n");
  40                 }
  41         }
  42         if(cvar_string("sv_weaponstats_damagefile") != "")
  43         {
  44                 fh = fopen(cvar_string("sv_weaponstats_damagefile"), FILE_APPEND);
  45                 if(fh >= 0)
  46                 {
  47                         fputs(fh, "#begin damagefile\n");
  48                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  49                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  50                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
  51                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
  52                                 {
  53                                         idx = WEAPONSTATS_GETINDEX(i, j);
  54                                         f = stov(bufstr_get(weaponstats_buffer, idx)) * '1 0 0';
  55                                         if(f != 0)
  56                                                 fputs(fh, strcat(prefix, ftos(i), "\t", ftos(j), "\t", ftos(f), "\n"));
  57                                 }
  58                         fputs(fh, "#end\n\n");
  59                         fclose(fh);
  60                         print("Weapon damage stats written\n");
  61                 }
  62         }
  63         buf_del(weaponstats_buffer);
  64         weaponstats_buffer = -1;
  65 }
  66
  67 void WeaponStats_LogItem(float awep, float vwep, vector item)
  68 {
  69         float idx;
  70         if(weaponstats_buffer < 0)
  71                 return;
  72         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  73                 return;
  74         if(awep > WEP_LAST || vwep > WEP_LAST)
  75                 return;
  76         idx = WEAPONSTATS_GETINDEX(awep,vwep);
  77         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  78 }
  79 void WeaponStats_LogDamage(float awep, float vwep, float damage)
  80 {
  81         if(damage < 0)
  82                 error("negative damage?");
  83         WeaponStats_LogItem(awep, vwep, '1 0 0' * damage);
  84 }
  85 void WeaponStats_LogKill(float awep, float vwep)
  86 {
  87         WeaponStats_LogItem(awep, vwep, '0 1 0');
  88 }
  89
  90 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  91 // merged player_run and player_stand to player_anim
  92 // added death animations to player_anim
  93 // can now spawn thrown weapons from anywhere, not just from players
  94 // thrown weapons now fade out after 20 seconds
  95 // created PlayerGib function
  96 // PlayerDie no longer uses hitloc or damage
  97 // PlayerDie now supports dying animations as well as gibbing
  98 // cleaned up PlayerDie a lot
  99 // added CopyBody
 100
 101 .entity pusher;
 102 .float pushltime;
 103
 104 void CopyBody(float keepvelocity)
 105 {
 106         local entity oldself;
 107         if (self.effects & EF_NODRAW)
 108                 return;
 109         oldself = self;
 110         self = spawn();
 111         self.enemy = oldself;
 112         self.lip = oldself.lip;
 113         self.colormap = oldself.colormap;
 114         self.iscreature = oldself.iscreature;
 115         self.angles = oldself.angles;
 116         self.avelocity = oldself.avelocity;
 117         self.classname = "body";
 118         self.damageforcescale = oldself.damageforcescale;
 119         self.effects = oldself.effects;
 120         self.event_damage = oldself.event_damage;
 121         self.animstate_startframe = oldself.animstate_startframe;
 122         self.animstate_numframes = oldself.animstate_numframes;
 123         self.animstate_framerate = oldself.animstate_framerate;
 124         self.animstate_starttime = oldself.animstate_starttime;
 125         self.animstate_endtime = oldself.animstate_endtime;
 126         self.animstate_override = oldself.animstate_override;
 127         self.animstate_looping = oldself.animstate_looping;
 128         self.frame = oldself.frame;
 129         self.dead_frame = oldself.dead_frame;
 130         self.pain_finished = oldself.pain_finished;
 131         self.health = oldself.health;
 132         self.armorvalue = oldself.armorvalue;
 133         self.armortype = oldself.armortype;
 134         self.model = oldself.model;
 135         self.modelindex = oldself.modelindex;
 136         self.modelindex_lod0 = oldself.modelindex_lod0;
 137         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 138         self.modelindex_lod1 = oldself.modelindex_lod1;
 139         self.modelindex_lod2 = oldself.modelindex_lod2;
 140         self.skinindex = oldself.skinindex;
 141         self.species = oldself.species;
 142         self.movetype = oldself.movetype;
 143         self.nextthink = oldself.nextthink;
 144         self.solid = oldself.solid;
 145         self.takedamage = oldself.takedamage;
 146         self.think = oldself.think;
 147         self.customizeentityforclient = oldself.customizeentityforclient;
 148         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 149         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 150         if (keepvelocity == 1)
 151                 self.velocity = oldself.velocity;
 152         self.oldvelocity = self.velocity;
 153         self.fade_time = oldself.fade_time;
 154         self.fade_rate = oldself.fade_rate;
 155         //self.weapon = oldself.weapon;
 156         setorigin(self, oldself.origin);
 157         setsize(self, oldself.mins, oldself.maxs);
 158         self.prevorigin = oldself.origin;
 159         self.reset = SUB_Remove;
 160
 161         Drag_MoveDrag(oldself, self);
 162
 163         self = oldself;
 164 }
 165
 166 float player_getspecies()
 167 {
 168         local float glob, i, j, fh, len, s, sk;
 169         local string fn, l;
 170         local float tokens;
 171
 172         s = -1;
 173
 174         glob = search_begin("models/player/*.txt", TRUE, TRUE);
 175         if(glob < 0)
 176                 return s;
 177         for(j = 0; j <= 1; ++j)
 178         {
 179                 for(i = 0; i < search_getsize(glob); ++i)
 180                 {
 181                         fn = search_getfilename(glob, i);
 182                         fh = fopen(fn, FILE_READ);
 183                         if(fh < 0)
 184                                 continue;
 185                         fgets(fh); fgets(fh);
 186                         sk = stof(fgets(fh));
 187                         if(sk == (j ? 0 : self.skinindex)) // 2nd pass skips the skin test
 188                         if(fgets(fh) == self.model)
 189                         {
 190                                 tokens = tokenizebyseparator(fn, ".");
 191                                 UpdatePlayerSounds(argv(0));
 192
 193                                 l = fgets(fh);
 194                                 len = tokenize_console(l);
 195                                 if (len != 2)
 196                                         goto nospecies;
 197                                 if (argv(0) != "species")
 198                                         goto nospecies;
 199                                 switch(argv(1))
 200                                 {
 201                                         case "human":       s = SPECIES_HUMAN;       break;
 202                                         case "alien":       s = SPECIES_ALIEN;       break;
 203                                         case "robot_shiny": s = SPECIES_ROBOT_SHINY; break;
 204                                         case "robot_rusty": s = SPECIES_ROBOT_RUSTY; break;
 205                                         case "robot_solid": s = SPECIES_ROBOT_SOLID; break;
 206                                         case "animal":      s = SPECIES_ANIMAL;      break;
 207                                         case "reserved":    s = SPECIES_RESERVED;    break;
 208                                 }
 209                         }
 210 :nospecies
 211                         fclose(fh);
 212                 }
 213                 if (s >= 0)
 214                         break;
 215         }
 216         search_end(glob);
 217
 218         if (s < 0)
 219                 s = SPECIES_HUMAN;
 220
 221         return s;
 222 }
 223
 224 void player_setupanimsformodel()
 225 {
 226         local string animfilename;
 227         local float animfile;
 228         // defaults for legacy .zym models without animinfo files
 229         self.anim_die1 = '0 1 0.5'; // 2 seconds
 230         self.anim_die2 = '1 1 0.5'; // 2 seconds
 231         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 232         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 233         self.anim_duckwalk = '4 1 1';
 234         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 235         self.anim_duckidle = '6 1 1';
 236         self.anim_idle = '7 1 1';
 237         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 238         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 239         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 240         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 241         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 242         self.anim_run = '13 1 1';
 243         self.anim_runbackwards = '14 1 1';
 244         self.anim_strafeleft = '15 1 1';
 245         self.anim_straferight = '16 1 1';
 246         self.anim_dead1 = '17 1 1';
 247         self.anim_dead2 = '18 1 1';
 248         self.anim_forwardright = '19 1 1';
 249         self.anim_forwardleft = '20 1 1';
 250         self.anim_backright = '21 1 1';
 251         self.anim_backleft  = '22 1 1';
 252         animparseerror = FALSE;
 253         animfilename = strcat(self.model, ".animinfo");
 254         animfile = fopen(animfilename, FILE_READ);
 255         if (animfile >= 0)
 256         {
 257                 self.anim_die1         = animparseline(animfile);
 258                 self.anim_die2         = animparseline(animfile);
 259                 self.anim_draw         = animparseline(animfile);
 260                 self.anim_duck         = animparseline(animfile);
 261                 self.anim_duckwalk     = animparseline(animfile);
 262                 self.anim_duckjump     = animparseline(animfile);
 263                 self.anim_duckidle     = animparseline(animfile);
 264                 self.anim_idle         = animparseline(animfile);
 265                 self.anim_jump         = animparseline(animfile);
 266                 self.anim_pain1        = animparseline(animfile);
 267                 self.anim_pain2        = animparseline(animfile);
 268                 self.anim_shoot        = animparseline(animfile);
 269                 self.anim_taunt        = animparseline(animfile);
 270                 self.anim_run          = animparseline(animfile);
 271                 self.anim_runbackwards = animparseline(animfile);
 272                 self.anim_strafeleft   = animparseline(animfile);
 273                 self.anim_straferight  = animparseline(animfile);
 274                 self.anim_forwardright = animparseline(animfile);
 275                 self.anim_forwardleft  = animparseline(animfile);
 276                 self.anim_backright    = animparseline(animfile);
 277                 self.anim_backleft     = animparseline(animfile);
 278                 fclose(animfile);
 279
 280                 // derived anims
 281                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 282                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 283
 284                 if (animparseerror)
 285                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 286         }
 287         else
 288                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 289         // reset animstate now
 290         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 291 };
 292
 293 void player_anim (void)
 294 {
 295         updateanim(self);
 296         if (self.weaponentity)
 297                 updateanim(self.weaponentity);
 298
 299         if (self.deadflag != DEAD_NO)
 300         {
 301                 if (time > self.animstate_endtime)
 302                 {
 303                         if (self.maxs_z > 5)
 304                         {
 305                                 self.maxs_z = 5;
 306                                 setsize(self, self.mins, self.maxs);
 307                         }
 308                         self.frame = self.dead_frame;
 309                 }
 310                 return;
 311         }
 312
 313         if (!self.animstate_override)
 314         {
 315                 if (!(self.flags & FL_ONGROUND))
 316                 {
 317                         if (self.crouch)
 318                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 319                         else
 320                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 321                         self.restart_jump = FALSE;
 322                 }
 323                 else if (self.crouch)
 324                 {
 325                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 326                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 327                         else
 328                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 329                 }
 330                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 331                 {
 332                         if (self.movement_x > 0 && self.movement_y == 0)
 333                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 334                         else if (self.movement_x < 0 && self.movement_y == 0)
 335                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 336                         else if (self.movement_x == 0 && self.movement_y > 0)
 337                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 338                         else if (self.movement_x == 0 && self.movement_y < 0)
 339                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 340                         else if (self.movement_x > 0 && self.movement_y > 0)
 341                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 342                         else if (self.movement_x > 0 && self.movement_y < 0)
 343                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 344                         else if (self.movement_x < 0 && self.movement_y > 0)
 345                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 346                         else if (self.movement_x < 0 && self.movement_y < 0)
 347                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 348                         else
 349                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 350                 }
 351                 else
 352                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 353         }
 354
 355         if (self.weaponentity)
 356         if (!self.weaponentity.animstate_override)
 357                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 358 }
 359
 360 void SpawnThrownWeapon (vector org, float w)
 361 {
 362         if(g_minstagib)
 363         if(self.ammo_cells <= 0)
 364                 return;
 365
 366         if(g_pinata)
 367         {
 368                 float j;
 369                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 370                 {
 371                         if(self.weapons & W_WeaponBit(j))
 372                                 if(W_IsWeaponThrowable(j))
 373                                         W_ThrowNewWeapon(self, j, FALSE, self.origin, randomvec() * 175 + '0 0 325');
 374                 }
 375         }
 376         else
 377                 W_ThrowWeapon(randomvec() * 125 + '0 0 200', org - self.origin, FALSE);
 378 }
 379
 380 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 381 {
 382         local float take, save;
 383         vector v;
 384         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 385
 386         // damage resistance (ignore most of the damage from a bullet or similar)
 387         damage = max(damage - 5, 1);
 388
 389         v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 390         take = v_x;
 391         save = v_y;
 392
 393         if(sound_allowed(MSG_BROADCAST, attacker))
 394         {
 395                 if (save > 10)
 396                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 397                 else if (take > 30)
 398                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 399                 else if (take > 10)
 400                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 401         }
 402
 403         if (take > 50)
 404                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 405         if (take > 100)
 406                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 407
 408         if (!(self.flags & FL_GODMODE))
 409         {
 410                 self.armorvalue = self.armorvalue - save;
 411                 self.health = self.health - take;
 412                 // pause regeneration for 5 seconds
 413                 self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 414         }
 415         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 416         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 417         self.dmg_inflictor = inflictor;
 418
 419         if (self.health <= -75 && self.modelindex != 0)
 420         {
 421                 // don't use any animations as a gib
 422                 self.frame = 0;
 423                 self.dead_frame = 0;
 424                 // view just above the floor
 425                 self.view_ofs = '0 0 4';
 426
 427                 Violence_GibSplash(self, 1, 1, attacker);
 428                 self.modelindex = 0; // restore later
 429                 self.solid = SOLID_NOT; // restore later
 430         }
 431 }
 432
 433 void ClientKill_Now_TeamChange();
 434
 435 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 436 {
 437         local float take, save, waves, sdelay, dh, da, j;
 438         vector v;
 439         float valid_damage_for_weaponstats;
 440
 441         dh = max(self.health, 0);
 442         da = max(self.armorvalue, 0);
 443
 444         if(!DEATH_ISSPECIAL(deathtype))
 445         {
 446                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 447                 if(self != attacker)
 448                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 449         }
 450
 451         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 452         {
 453                 // tuba causes blood to come out of the ears
 454                 vector ear1, ear2;
 455                 vector d;
 456                 float f;
 457                 ear1 = self.origin;
 458                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 459                 ear2 = ear1;
 460                 makevectors(self.angles);
 461                 ear1 += v_right * -10;
 462                 ear2 += v_right * +10;
 463                 d = inflictor.origin - self.origin;
 464                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 465                 force = v_right * vlen(force);
 466                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 467                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 468                 if(f > 0)
 469                 {
 470                         hitloc = ear1;
 471                         force = force * -1;
 472                 }
 473                 else
 474                 {
 475                         hitloc = ear2;
 476                         // force is already good
 477                 }
 478         }
 479         else
 480                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 481
 482         if((g_arena && numspawned < 2) || (g_ca && player_cnt < 2) && !inWarmupStage)
 483                 return;
 484
 485         if (!g_minstagib)
 486         {
 487                 v = healtharmor_applydamage(self.armorvalue, cvar("g_balance_armor_blockpercent"), damage);
 488                 take = v_x;
 489                 save = v_y;
 490         }
 491         else
 492         {
 493                 save = 0;
 494                 take = damage;
 495         }
 496
 497         if(sound_allowed(MSG_BROADCAST, attacker))
 498         {
 499                 if (save > 10)
 500                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 501                 else if (take > 30)
 502                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 503                 else if (take > 10)
 504                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 505         }
 506
 507         if (take > 50)
 508                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 509         if (take > 100)
 510                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 511
 512         if (time >= self.spawnshieldtime)
 513         {
 514                 if (!(self.flags & FL_GODMODE))
 515                 {
 516                         self.armorvalue = self.armorvalue - save;
 517                         self.health = self.health - take;
 518                         // pause regeneration for 5 seconds
 519                         self.pauseregen_finished = max(self.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
 520
 521                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 522                         {
 523                                 self.pain_finished = time + 0.5;        //Supajoe
 524
 525                                 if(sv_gentle < 1) {
 526                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 527                                         {
 528                                                 if (random() > 0.5)
 529                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 530                                                 else
 531                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 532                                         }
 533
 534                                         if(sound_allowed(MSG_BROADCAST, attacker))
 535                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * cvar("g_balance_laser_primary_damage") * cvar("g_balance_selfdamagepercent") + 1)
 536                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 537                                         {
 538                                                 if(self.health > 75) // TODO make a "gentle" version?
 539                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 540                                                 else if(self.health > 50)
 541                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 542                                                 else if(self.health > 25)
 543                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 544                                                 else if(self.health > 1)
 545                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 546                                         }
 547                                 }
 548
 549                                 // throw off bot aim temporarily
 550                                 local float shake;
 551                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 552                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 553                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 554                         }
 555                 }
 556                 else
 557                         self.max_armorvalue += (save + take);
 558         }
 559         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 560         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 561         self.dmg_inflictor = inflictor;
 562
 563         if(attacker == self)
 564         {
 565                 // don't reset pushltime for self damage as it may be an attempt to
 566                 // escape a lava pit or similar
 567                 //self.pushltime = 0;
 568         }
 569         else if(attacker.classname == "player" || attacker.classname == "gib")
 570         {
 571                 self.pusher = attacker;
 572                 self.pushltime = time + cvar("g_maxpushtime");
 573         }
 574         else if(time < self.pushltime)
 575         {
 576                 attacker = self.pusher;
 577                 self.pushltime = max(self.pushltime, time + 0.6);
 578         }
 579         else
 580                 self.pushltime = 0;
 581
 582         valid_damage_for_weaponstats = 0;
 583         if(clienttype(self) == CLIENTTYPE_REAL)
 584         if(clienttype(attacker) == CLIENTTYPE_REAL)
 585         if(self != attacker)
 586         if(!DEATH_ISSPECIAL(deathtype))
 587         if(IsDifferentTeam(self, attacker))
 588                 valid_damage_for_weaponstats = 1;
 589
 590         if(valid_damage_for_weaponstats)
 591         {
 592                 dh = dh - max(self.health, 0);
 593                 da = da - max(self.armorvalue, 0);
 594                 WeaponStats_LogDamage(DEATH_WEAPONOF(deathtype), self.weapon, dh + da);
 595         }
 596
 597         if (self.health < 1)
 598         {
 599                 float defer_ClientKill_Now_TeamChange;
 600                 defer_ClientKill_Now_TeamChange = FALSE;
 601
 602                 if(valid_damage_for_weaponstats)
 603                         WeaponStats_LogKill(DEATH_WEAPONOF(deathtype), self.weapon);
 604
 605                 if(sv_gentle < 1) // TODO make a "gentle" version?
 606                 if(sound_allowed(MSG_BROADCAST, attacker))
 607                 {
 608                         if(deathtype == DEATH_DROWN)
 609                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 610                         else
 611                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 612                 }
 613
 614                 // get rid of kill indicator
 615                 if(self.killindicator)
 616                 {
 617                         remove(self.killindicator);
 618                         self.killindicator = world;
 619                         if(self.killindicator_teamchange)
 620                                 defer_ClientKill_Now_TeamChange = TRUE;
 621
 622                         if(self.classname == "body")
 623                         if(deathtype == DEATH_KILL)
 624                         {
 625                                 // for the lemmings fans, a small harmless explosion
 626                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 627                         }
 628                 }
 629
 630                 // become fully visible
 631                 self.alpha = 1;
 632                 // clear selected player display
 633                 ClearSelectedPlayer();
 634                 // throw a weapon
 635                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 636                 // print an obituary message
 637                 Obituary (attacker, inflictor, self, deathtype);
 638                 race_PreDie();
 639                 DropAllRunes(self);
 640
 641                 frag_attacker = attacker;
 642                 frag_inflictor = inflictor;
 643                 MUTATOR_CALLHOOK(PlayerDies);
 644
 645                 if(self.flagcarried)
 646                 {
 647                         if(attacker.classname != "player" && attacker.classname != "gib")
 648                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 649                         else if(attacker.team == self.team)
 650                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 651                         else
 652                                 DropFlag(self.flagcarried, world, attacker);
 653                 }
 654                 if(self.ballcarried)
 655                         DropBall(self.ballcarried, self.origin, self.velocity);
 656                 Portal_ClearAllLater(self);
 657                 // clear waypoints
 658                 WaypointSprite_PlayerDead();
 659                 // make the corpse upright (not tilted)
 660                 self.angles_x = 0;
 661                 self.angles_z = 0;
 662                 // don't spin
 663                 self.avelocity = '0 0 0';
 664                 // view from the floor
 665                 self.view_ofs = '0 0 -8';
 666                 // toss the corpse
 667                 self.movetype = MOVETYPE_TOSS;
 668                 // shootable corpse
 669                 self.solid = SOLID_CORPSE;
 670                 // don't stick to the floor
 671                 self.flags &~= FL_ONGROUND;
 672                 // dying animation
 673                 self.deadflag = DEAD_DYING;
 674                 // when to allow respawn
 675                 sdelay = 0;
 676                 waves = 0;
 677                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 678                 if(!sdelay)
 679                         sdelay = cvar("g_respawn_delay");
 680                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 681                 if(!waves)
 682                         waves = cvar("g_respawn_waves");
 683                 if(waves)
 684                         self.death_time = ceil((time + sdelay) / waves) * waves;
 685                 else
 686                         self.death_time = time + sdelay;
 687                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 688                         self.respawn_countdown = 10; // first number to count down from is 10
 689                 else
 690                         self.respawn_countdown = -1; // do not count down
 691                 if (random() < 0.5)
 692                 {
 693                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 694                         self.dead_frame = self.anim_dead1_x;
 695                 }
 696                 else
 697                 {
 698                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 699                         self.dead_frame = self.anim_dead2_x;
 700                 }
 701                 // set damage function to corpse damage
 702                 self.event_damage = PlayerCorpseDamage;
 703                 // call the corpse damage function just in case it wants to gib
 704                 self.event_damage(inflictor, attacker, 0, deathtype, hitloc, force);
 705                 // set up to fade out later
 706                 SUB_SetFade (self, time + 12 + random () * 4, 1);
 707
 708                 // remove laserdot
 709                 if(self.weaponentity)
 710                         if(self.weaponentity.lasertarget)
 711                                 remove(self.weaponentity.lasertarget);
 712
 713                 if(clienttype(self) == CLIENTTYPE_REAL)
 714                 {
 715                         self.fixangle = TRUE;
 716                         //msg_entity = self;
 717                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 718                         //WriteAngle (MSG_ONE, self.v_angle_x);
 719                         //WriteAngle (MSG_ONE, self.v_angle_y);
 720                         //WriteAngle (MSG_ONE, 80);
 721                 }
 722
 723                 if(g_arena)
 724                         Spawnqueue_Unmark(self);
 725
 726                 if(defer_ClientKill_Now_TeamChange)
 727                         ClientKill_Now_TeamChange();
 728
 729                 if(sv_gentle > 0 || cvar("ekg")) {
 730                         // remove corpse
 731                         PlayerCorpseDamage (inflictor, attacker, 100.0, deathtype, hitloc, force);
 732                 }
 733
 734                 // reset fields the weapons may use just in case
 735         for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 736                 {
 737             weapon_action(j, WR_RESETPLAYER);
 738                         ATTACK_FINISHED_FOR(self, j) = 0;
 739                 }
 740         }
 741 }
 742
 743 float UpdateSelectedPlayer_countvalue(float v)
 744 {
 745         return max(0, (v - 1.0) / 0.5);
 746 }
 747
 748 // returns: -2 if no hit, otherwise cos of the angle
 749 // uses the global v_angle
 750 float UpdateSelectedPlayer_canSee(entity p, float mincosangle, float maxdist)
 751 {
 752         vector so, d;
 753         float c;
 754
 755         if(p == self)
 756                 return -2;
 757
 758         if(p.deadflag)
 759                 return -2;
 760
 761         so = self.origin + self.view_ofs;
 762         d = p.origin - so;
 763
 764         // misaimed?
 765         if(dist_point_line(d, '0 0 0', v_forward) > maxdist)
 766                 return -2;
 767
 768         // now find the cos of the angle...
 769         c = normalize(d) * v_forward;
 770
 771         if(c <= mincosangle)
 772                 return -2;
 773
 774         // not visible in any way? forget it
 775         if(!checkpvs(so, p))
 776                 return -2;
 777
 778         traceline(so, p.origin, MOVE_NOMONSTERS, self);
 779         if(trace_fraction < 1)
 780                 return -2;
 781
 782         return c;
 783 }
 784
 785 void ClearSelectedPlayer()
 786 {
 787         if(self.selected_player)
 788         {
 789                 centerprint_expire(self, CENTERPRIO_POINT);
 790                 self.selected_player = world;
 791                 self.selected_player_display_needs_update = FALSE;
 792         }
 793 }
 794
 795 void UpdateSelectedPlayer()
 796 {
 797         entity selected;
 798         float selected_score;
 799         selected = world;
 800         selected_score = 0.95; // 18 degrees
 801
 802         if(!cvar("sv_allow_shownames"))
 803                 return;
 804
 805         if(clienttype(self) != CLIENTTYPE_REAL)
 806                 return;
 807
 808         if(self.cvar_cl_shownames == 0)
 809                 return;
 810
 811         if(self.cvar_cl_shownames == 1 && !teams_matter)
 812                 return;
 813
 814         makevectors(self.v_angle); // sets v_forward
 815
 816         // 1. cursor trace is always right
 817         WarpZone_crosshair_trace(self);
 818         if(trace_ent && trace_ent.classname == "player" && !trace_ent.deadflag)
 819         {
 820                 selected = trace_ent;
 821         }
 822         else
 823         {
 824                 // 2. if we don't have a cursor trace, find the player which is least
 825                 //    mis-aimed at
 826                 entity p;
 827                 FOR_EACH_PLAYER(p)
 828                 {
 829                         float c;
 830                         c = UpdateSelectedPlayer_canSee(p, selected_score, 100); // 100 = 2.5 meters
 831                         if(c >= -1)
 832                         {
 833                                 selected = p;
 834                                 selected_score = c;
 835                         }
 836                 }
 837         }
 838
 839         if(selected)
 840         {
 841                 self.selected_player_display_timeout = time + self.cvar_scr_centertime;
 842         }
 843         else
 844         {
 845                 if(time < self.selected_player_display_timeout)
 846                         if(UpdateSelectedPlayer_canSee(self.selected_player, 0.7, 200) >= -1) // 5 meters, 45 degrees
 847                                 selected = self.selected_player;
 848         }
 849
 850         if(selected)
 851         {
 852                 if(selected == self.selected_player)
 853                 {
 854                         float save;
 855                         save = UpdateSelectedPlayer_countvalue(self.selected_player_count);
 856                         self.selected_player_count = self.selected_player_count + frametime;
 857                         if(save != UpdateSelectedPlayer_countvalue(self.selected_player_count))
 858                         {
 859                                 string namestr, healthstr;
 860                                 namestr = playername(selected);
 861                                 if(teams_matter)
 862                                 {
 863                                         healthstr = ftos(floor(selected.health));
 864                                         if(self.team == selected.team)
 865                                         {
 866                                                 namestr = strcat(namestr, " (", healthstr, "%)");
 867                                                 self.selected_player_display_needs_update = TRUE;
 868                                         }
 869                                 }
 870                                 centerprint_atprio(self, CENTERPRIO_POINT, namestr);
 871                         }
 872                 }
 873                 else
 874                 {
 875                         ClearSelectedPlayer();
 876                         self.selected_player = selected;
 877                         self.selected_player_time = time;
 878                         self.selected_player_count = 0;
 879                         self.selected_player_display_needs_update = FALSE;
 880                 }
 881         }
 882         else
 883         {
 884                 ClearSelectedPlayer();
 885         }
 886
 887         if(self.selected_player)
 888                 self.last_selected_player = self.selected_player;
 889 }
 890
 891 .float muted; // to be used by prvm_edictset server playernumber muted 1
 892 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 893 // message "": do not say, just test flood control
 894 // return value:
 895 //   1 = accept
 896 //   0 = reject
 897 //  -1 = fake accept
 898 {
 899         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 900         float flood, privatemsgprefixlen;
 901         entity head;
 902         float ret;
 903
 904         if(Ban_MaybeEnforceBan(source))
 905                 return 0;
 906
 907         if(!teamsay && !privatesay)
 908                 if(substring(msgin, 0, 1) == " ")
 909                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 910
 911         msgin = formatmessage(msgin);
 912
 913         if(source.classname != "player")
 914                 colorstr = "^0"; // black for spectators
 915         else if(teams_matter)
 916                 colorstr = Team_ColorCode(source.team);
 917         else
 918                 teamsay = FALSE;
 919
 920         if(intermission_running)
 921                 teamsay = FALSE;
 922
 923         if(msgin != "")
 924                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 925
 926         /*
 927          * using bprint solves this... me stupid
 928         // how can we prevent the message from appearing in a listen server?
 929         // for now, just give "say" back and only handle say_team
 930         if(!teamsay)
 931         {
 932                 clientcommand(self, strcat("say ", msgin));
 933                 return;
 934         }
 935         */
 936
 937         if(cvar("g_chat_teamcolors"))
 938                 namestr = playername(source);
 939         else
 940                 namestr = source.netname;
 941
 942         if(msgin != "")
 943         {
 944                 if(privatesay)
 945                 {
 946                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 947                         privatemsgprefixlen = strlen(msgstr);
 948                         msgstr = strcat(msgstr, msgin);
 949                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 950                         if(cvar("g_chat_teamcolors"))
 951                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 952                         else
 953                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 954                 }
 955                 else if(teamsay)
 956                 {
 957                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 958                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 959                 }
 960                 else
 961                 {
 962                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 963                         cmsgstr = "";
 964                 }
 965                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 966         }
 967         else
 968         {
 969                 msgstr = cmsgstr = "";
 970         }
 971
 972         fullmsgstr = msgstr;
 973         fullcmsgstr = cmsgstr;
 974
 975         // FLOOD CONTROL
 976         flood = 0;
 977         if(floodcontrol)
 978         {
 979                 float flood_spl;
 980                 float flood_burst;
 981                 float flood_lmax;
 982                 var .float flood_field;
 983                 float lines;
 984                 if(privatesay)
 985                 {
 986                         flood_spl = cvar("g_chat_flood_spl_tell");
 987                         flood_burst = cvar("g_chat_flood_burst_tell");
 988                         flood_lmax = cvar("g_chat_flood_lmax_tell");
 989                         flood_field = floodcontrol_chattell;
 990                 }
 991                 else if(teamsay)
 992                 {
 993                         flood_spl = cvar("g_chat_flood_spl_team");
 994                         flood_burst = cvar("g_chat_flood_burst_team");
 995                         flood_lmax = cvar("g_chat_flood_lmax_team");
 996                         flood_field = floodcontrol_chatteam;
 997                 }
 998                 else
 999                 {
1000                         flood_spl = cvar("g_chat_flood_spl");
1001                         flood_burst = cvar("g_chat_flood_burst");
1002                         flood_lmax = cvar("g_chat_flood_lmax");
1003                         flood_field = floodcontrol_chat;
1004                 }
1005                 flood_burst = max(0, flood_burst - 1);
1006                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
1007
1008                 // do flood control for the default line size
1009                 if(msgstr != "")
1010                 {
1011                         getWrappedLine_remaining = msgstr;
1012                         msgstr = "";
1013                         lines = 0;
1014                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
1015                         {
1016                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
1017                                 ++lines;
1018                         }
1019                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
1020
1021                         if(getWrappedLine_remaining != "")
1022                         {
1023                                 msgstr = strcat(msgstr, "\n");
1024                                 flood = 2;
1025                         }
1026
1027                         if(time >= source.flood_field)
1028                         {
1029                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
1030                         }
1031                         else
1032                         {
1033                                 flood = 1;
1034                                 msgstr = fullmsgstr;
1035                         }
1036                 }
1037                 else
1038                 {
1039                         if(time >= source.flood_field)
1040                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
1041                         else
1042                                 flood = 1;
1043                 }
1044         }
1045
1046         if (timeoutStatus == 2) //when game is paused, no flood protection
1047                 source.flood_field = flood = 0;
1048
1049         if(flood == 2) // cannot happen for empty msgstr
1050         {
1051                 if(cvar("g_chat_flood_notify_flooder"))
1052                 {
1053                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
1054                         sourcecmsgstr = "";
1055                 }
1056                 else
1057                 {
1058                         sourcemsgstr = fullmsgstr;
1059                         sourcecmsgstr = fullcmsgstr;
1060                 }
1061                 cmsgstr = "";
1062         }
1063         else
1064         {
1065                 sourcemsgstr = msgstr;
1066                 sourcecmsgstr = cmsgstr;
1067         }
1068
1069         if(!privatesay)
1070         if(source.classname != "player")
1071         {
1072                 if(teamsay || (cvar("g_chat_nospectators") == 1) || (cvar("g_chat_nospectators") == 2 && !inWarmupStage))
1073                         teamsay = -1; // spectators
1074         }
1075
1076         if(flood)
1077                 print("NOTE: ", playername(source), "^7 is flooding.\n");
1078
1079         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
1080         if(privatesay)
1081                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
1082
1083         if(source.muted)
1084         {
1085                 // always fake the message
1086                 ret = -1;
1087         }
1088         else if(flood == 1)
1089         {
1090                 if(cvar("g_chat_flood_notify_flooder"))
1091                 {
1092                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
1093                         ret = 0;
1094                 }
1095                 else
1096                         ret = -1;
1097         }
1098         else
1099         {
1100                 ret = 1;
1101         }
1102
1103         if(sourcemsgstr != "" && ret != 0)
1104         {
1105                 if(ret < 0) // fake
1106                 {
1107                         sprint(source, sourcemsgstr);
1108                         if(sourcecmsgstr != "" && !privatesay)
1109                                 centerprint(source, sourcecmsgstr);
1110                 }
1111                 else if(privatesay)
1112                 {
1113                         sprint(source, sourcemsgstr);
1114                         sprint(privatesay, msgstr);
1115                         if(cmsgstr != "")
1116                                 centerprint(privatesay, cmsgstr);
1117                 }
1118                 else if(teamsay > 0)
1119                 {
1120                         sprint(source, sourcemsgstr);
1121                         if(sourcecmsgstr != "")
1122                                 centerprint(source, sourcecmsgstr);
1123                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1124                                 if(head != source)
1125                                 {
1126                                         sprint(head, msgstr);
1127                                         if(cmsgstr != "")
1128                                                 centerprint(head, cmsgstr);
1129                                 }
1130                 }
1131                 else if(teamsay < 0)
1132                 {
1133                         sprint(source, sourcemsgstr);
1134                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1135                                 if(head != source)
1136                                         sprint(head, msgstr);
1137                 }
1138                 else if(sourcemsgstr != msgstr)
1139                 {
1140                         sprint(source, sourcemsgstr);
1141                         FOR_EACH_REALCLIENT(head)
1142                                 if(head != source)
1143                                         sprint(head, msgstr);
1144                 }
1145                 else
1146                         bprint(msgstr);
1147         }
1148
1149         return ret;
1150 }
1151
1152 float GetVoiceMessageVoiceType(string type)
1153 {
1154         if(type == "taunt")
1155                 return VOICETYPE_TAUNT;
1156         if(type == "teamshoot")
1157                 return VOICETYPE_LASTATTACKER;
1158         return VOICETYPE_TEAMRADIO;
1159 }
1160
1161 string allvoicesamples;
1162 float GetPlayerSoundSampleField_notFound;
1163 float GetPlayerSoundSampleField_fixed;
1164 .string GetVoiceMessageSampleField(string type)
1165 {
1166         GetPlayerSoundSampleField_notFound = 0;
1167         GetPlayerSoundSampleField_fixed = 0;
1168         switch(type)
1169         {
1170 #define _VOICEMSG(m) case #m: return playersound_##m;
1171                 ALLVOICEMSGS
1172 #undef _VOICEMSG
1173         }
1174         GetPlayerSoundSampleField_notFound = 1;
1175         return playersound_taunt;
1176 }
1177
1178 .string GetPlayerSoundSampleField(string type)
1179 {
1180         GetPlayerSoundSampleField_notFound = 0;
1181         GetPlayerSoundSampleField_fixed = 0;
1182         switch(type)
1183         {
1184 #define _VOICEMSG(m) case #m: return playersound_##m;
1185                 ALLPLAYERSOUNDS
1186 #undef _VOICEMSG
1187         }
1188         GetPlayerSoundSampleField_notFound = 1;
1189         return playersound_taunt;
1190 }
1191
1192 void PrecacheGlobalSound(string samplestring)
1193 {
1194         float n, i;
1195         tokenize_console(samplestring);
1196         n = stof(argv(1));
1197         if(n > 0)
1198         {
1199                 for(i = 1; i <= n; ++i)
1200                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1201         }
1202         else
1203         {
1204                 precache_sound(strcat(argv(0), ".wav"));
1205         }
1206 }
1207
1208 void PrecachePlayerSounds(string f)
1209 {
1210         float fh;
1211         string s;
1212         fh = fopen(f, FILE_READ);
1213         if(fh < 0)
1214                 return;
1215         while((s = fgets(fh)))
1216         {
1217                 if(tokenize_console(s) != 3)
1218                 {
1219                         dprint("Invalid sound info line: ", s, "\n");
1220                         continue;
1221                 }
1222                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1223         }
1224         fclose(fh);
1225
1226         if not(allvoicesamples)
1227         {
1228 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1229                 ALLVOICEMSGS
1230 #undef _VOICEMSG
1231                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1232         }
1233 }
1234
1235 void ClearPlayerSounds()
1236 {
1237 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1238         ALLPLAYERSOUNDS
1239         ALLVOICEMSGS
1240 #undef _VOICEMSG
1241 }
1242
1243 void LoadPlayerSounds(string f, float first)
1244 {
1245         float fh;
1246         string s;
1247         var .string field;
1248         fh = fopen(f, FILE_READ);
1249         if(fh < 0)
1250                 return;
1251         while((s = fgets(fh)))
1252         {
1253                 if(tokenize_console(s) != 3)
1254                         continue;
1255                 field = GetPlayerSoundSampleField(argv(0));
1256                 if(GetPlayerSoundSampleField_notFound)
1257                         field = GetVoiceMessageSampleField(argv(0));
1258                 if(GetPlayerSoundSampleField_notFound)
1259                         continue;
1260                 if(GetPlayerSoundSampleField_fixed)
1261                         if not(first)
1262                                 continue;
1263                 if(self.field)
1264                         strunzone(self.field);
1265                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1266         }
1267         fclose(fh);
1268 }
1269
1270 .float modelindex_for_playersound;
1271 void UpdatePlayerSounds(string filename)
1272 {
1273         if(self.modelindex == self.modelindex_for_playersound)
1274                 return;
1275         self.modelindex_for_playersound = self.modelindex;
1276         ClearPlayerSounds();
1277         LoadPlayerSounds("sound/player/default.sounds", 1);
1278         if(filename != "")
1279                 LoadPlayerSounds(strcat(filename, ".sounds"), 0);
1280         else
1281                 LoadPlayerSounds(strcat(self.model, ".sounds"), 0); // backwards compatibility
1282 }
1283
1284 void FakeGlobalSound(string sample, float chan, float voicetype)
1285 {
1286         float n;
1287         float tauntrand;
1288
1289         if(sample == "")
1290                 return;
1291
1292         tokenize_console(sample);
1293         n = stof(argv(1));
1294         if(n > 0)
1295                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1296         else
1297                 sample = strcat(argv(0), ".wav"); // randomization
1298
1299         switch(voicetype)
1300         {
1301                 case VOICETYPE_LASTATTACKER_ONLY:
1302                         break;
1303                 case VOICETYPE_LASTATTACKER:
1304                         if(self.pusher)
1305                         {
1306                                 msg_entity = self;
1307                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1308                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1309                         }
1310                         break;
1311                 case VOICETYPE_TEAMRADIO:
1312                         msg_entity = self;
1313                         if(msg_entity.cvar_cl_voice_directional == 1)
1314                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1315                         else
1316                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1317                         break;
1318                 case VOICETYPE_AUTOTAUNT:
1319                         if(!sv_autotaunt)
1320                                 break;
1321                         if(!sv_taunt)
1322                                 break;
1323                         if(sv_gentle)
1324                                 break;
1325                         tauntrand = random();
1326                         msg_entity = self;
1327                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1328                         {
1329                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1330                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1331                                 else
1332                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1333                         }
1334                         break;
1335                 case VOICETYPE_TAUNT:
1336                         if(self.classname == "player")
1337                                 if(self.deadflag == DEAD_NO)
1338                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1339                         if(!sv_taunt)
1340                                 break;
1341                         if(sv_gentle)
1342                                 break;
1343                         msg_entity = self;
1344                         if (msg_entity.cvar_cl_voice_directional >= 1)
1345                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1346                         else
1347                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1348                         break;
1349                 case VOICETYPE_PLAYERSOUND:
1350                         msg_entity = self;
1351                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1352                         break;
1353                 default:
1354                         backtrace("Invalid voice type!");
1355                         break;
1356         }
1357 }
1358
1359 void GlobalSound(string sample, float chan, float voicetype)
1360 {
1361         float n;
1362         float tauntrand;
1363
1364         if(sample == "")
1365                 return;
1366
1367         tokenize_console(sample);
1368         n = stof(argv(1));
1369         if(n > 0)
1370                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1371         else
1372                 sample = strcat(argv(0), ".wav"); // randomization
1373
1374         switch(voicetype)
1375         {
1376                 case VOICETYPE_LASTATTACKER_ONLY:
1377                         if(self.pusher)
1378                         {
1379                                 msg_entity = self.pusher;
1380                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1381                                 {
1382                                         if(msg_entity.cvar_cl_voice_directional == 1)
1383                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1384                                         else
1385                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1386                                 }
1387                         }
1388                         break;
1389                 case VOICETYPE_LASTATTACKER:
1390                         if(self.pusher)
1391                         {
1392                                 msg_entity = self.pusher;
1393                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1394                                 {
1395                                         if(msg_entity.cvar_cl_voice_directional == 1)
1396                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1397                                         else
1398                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1399                                 }
1400                                 msg_entity = self;
1401                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1402                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1403                         }
1404                         break;
1405                 case VOICETYPE_TEAMRADIO:
1406                         FOR_EACH_REALCLIENT(msg_entity)
1407                                 if(!teams_matter || msg_entity.team == self.team)
1408                                 {
1409                                         if(msg_entity.cvar_cl_voice_directional == 1)
1410                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1411                                         else
1412                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1413                                 }
1414                         break;
1415                 case VOICETYPE_AUTOTAUNT:
1416                         if(!sv_autotaunt)
1417                                 break;
1418                         if(!sv_taunt)
1419                                 break;
1420                         if(sv_gentle)
1421                                 break;
1422                         tauntrand = random();
1423                         FOR_EACH_REALCLIENT(msg_entity)
1424                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1425                                 {
1426                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1427                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1428                                         else
1429                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1430                                 }
1431                         break;
1432                 case VOICETYPE_TAUNT:
1433                         if(self.classname == "player")
1434                                 if(self.deadflag == DEAD_NO)
1435                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1436                         if(!sv_taunt)
1437                                 break;
1438                         if(sv_gentle)
1439                                 break;
1440                         FOR_EACH_REALCLIENT(msg_entity)
1441                         {
1442                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1443                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1444                                 else
1445                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1446                         }
1447                         break;
1448                 case VOICETYPE_PLAYERSOUND:
1449                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1450                         break;
1451                 default:
1452                         backtrace("Invalid voice type!");
1453                         break;
1454         }
1455 }
1456
1457 void PlayerSound(.string samplefield, float chan, float voicetype)
1458 {
1459         GlobalSound(self.samplefield, chan, voicetype);
1460 }
1461
1462 void VoiceMessage(string type, string msg)
1463 {
1464         var .string sample;
1465         float voicetype, ownteam;
1466         float flood;
1467         sample = GetVoiceMessageSampleField(type);
1468
1469         if(GetPlayerSoundSampleField_notFound)
1470         {
1471                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1472                 return;
1473         }
1474
1475         voicetype = GetVoiceMessageVoiceType(type);
1476         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1477
1478         flood = Say(self, ownteam, world, msg, 1);
1479
1480         if (flood > 0)
1481                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1482         else if (flood < 0)
1483                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1484 }
1485
1486 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1487 {
1488 //      show_message
1489 //      0 (00) automove centerprint, admin message
1490 //      1 (01) automove centerprint, no admin message
1491 //      2 (10) no centerprint, admin message
1492 //      3 (11) no centerprint, no admin message
1493
1494         float lockteams_backup;
1495
1496         lockteams_backup = lockteams;  // backup any team lock
1497
1498         lockteams = 0;  // disable locked teams
1499
1500         TeamchangeFrags(client);  // move the players frags
1501         SetPlayerColors(client, team_colour - 1);  // set the players colour
1502         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1503
1504         lockteams = lockteams_backup;  // restore the team lock
1505
1506         LogTeamchange(client.playerid, client.team, type);
1507
1508         if not(show_message & 1) // admin message
1509                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1510
1511         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1512 }