qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK(), "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255 #ifndef NO_LEGACY_NETWORKING
 256         if(!self.iscsqcmodel)
 257                 animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 258 #endif
 259
 260         if (self.weaponentity)
 261         {
 262                 updateanim(self.weaponentity);
 263                 if (!self.weaponentity.animstate_override)
 264                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 265         }
 266 }
 267
 268 void SpawnThrownWeapon (vector org, float w)
 269 {
 270         if(g_minstagib)
 271         if(self.ammo_cells <= 0)
 272                 return;
 273
 274         if(g_pinata)
 275         {
 276                 float j;
 277                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 278                 {
 279                         if(WEPSET_CONTAINS_EW(self, j))
 280                                 if(W_IsWeaponThrowable(j))
 281                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 282                 }
 283         }
 284         else
 285         {
 286                 if(W_IsWeaponThrowable(self.weapon))
 287                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 288         }
 289 }
 290
 291 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 292 {
 293         float take, save;
 294         vector v;
 295         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 296
 297         // damage resistance (ignore most of the damage from a bullet or similar)
 298         damage = max(damage - 5, 1);
 299
 300         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 301         take = v_x;
 302         save = v_y;
 303
 304         if(sound_allowed(MSG_BROADCAST, attacker))
 305         {
 306                 if (save > 10)
 307                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 308                 else if (take > 30)
 309                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 310                 else if (take > 10)
 311                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 312         }
 313
 314         if (take > 50)
 315                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 316         if (take > 100)
 317                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 318
 319         if (!(self.flags & FL_GODMODE))
 320         {
 321                 self.armorvalue = self.armorvalue - save;
 322                 self.health = self.health - take;
 323                 // pause regeneration for 5 seconds
 324                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 325         }
 326         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 327         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 328         self.dmg_inflictor = inflictor;
 329
 330         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 331         {
 332                 // don't use any animations as a gib
 333                 self.frame = 0;
 334                 // view just above the floor
 335                 self.view_ofs = '0 0 4';
 336
 337                 Violence_GibSplash(self, 1, 1, attacker);
 338                 self.alpha = -1;
 339                 self.solid = SOLID_NOT; // restore later
 340                 self.takedamage = DAMAGE_NO; // restore later
 341                 self.damagedbycontents = FALSE;
 342         }
 343 }
 344
 345 void ClientKill_Now_TeamChange();
 346 void freezetag_CheckWinner();
 347
 348 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 349 {
 350         float take, save, waves, sdelay, dh, da, j;
 351         vector v;
 352         float valid_damage_for_weaponstats;
 353         float excess;
 354
 355         if((g_arena && numspawned < 2) || (g_ca && allowed_to_spawn) && !inWarmupStage)
 356                 return;
 357
 358         dh = max(self.health, 0);
 359         da = max(self.armorvalue, 0);
 360
 361         if(!DEATH_ISSPECIAL(deathtype))
 362         {
 363                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 364                 if(self != attacker)
 365                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 366         }
 367
 368         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 369         {
 370                 // tuba causes blood to come out of the ears
 371                 vector ear1, ear2;
 372                 vector d;
 373                 float f;
 374                 ear1 = self.origin;
 375                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 376                 ear2 = ear1;
 377                 makevectors(self.angles);
 378                 ear1 += v_right * -10;
 379                 ear2 += v_right * +10;
 380                 d = inflictor.origin - self.origin;
 381                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 382                 force = v_right * vlen(force);
 383                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 384                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 385                 if(f > 0)
 386                 {
 387                         hitloc = ear1;
 388                         force = force * -1;
 389                 }
 390                 else
 391                 {
 392                         hitloc = ear2;
 393                         // force is already good
 394                 }
 395         }
 396         else
 397                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 398
 399         if (!g_minstagib)
 400         {
 401                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 402                 take = v_x;
 403                 save = v_y;
 404         }
 405         else
 406         {
 407                 save = 0;
 408                 take = damage;
 409         }
 410
 411         frag_inflictor = inflictor;
 412         frag_attacker = attacker;
 413         frag_target = self;
 414         damage_take = take;
 415         damage_save = save;
 416         damage_force = force;
 417         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 418         take = bound(0, damage_take, self.health);
 419         save = bound(0, damage_save, self.armorvalue);
 420         excess = max(0, damage - take - save);
 421
 422         if(sound_allowed(MSG_BROADCAST, attacker))
 423         {
 424                 if (save > 10)
 425                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 426                 else if (take > 30)
 427                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 428                 else if (take > 10)
 429                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 430         }
 431
 432         if (take > 50)
 433                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 434         if (take > 100)
 435                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 436
 437         if (time >= self.spawnshieldtime)
 438         {
 439                 if (!(self.flags & FL_GODMODE))
 440                 {
 441                         self.armorvalue = self.armorvalue - save;
 442                         self.health = self.health - take;
 443                         // pause regeneration for 5 seconds
 444                         if(take)
 445                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 446
 447                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 448                         {
 449                                 self.pain_finished = time + 0.5;        //Supajoe
 450
 451                                 if(sv_gentle < 1) {
 452                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 453                                         {
 454                                                 if (!self.animstate_override)
 455                                                 {
 456                                                         if (random() > 0.5)
 457                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 458                                                         else
 459                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 460                                                 }
 461                                         }
 462
 463                                         if(sound_allowed(MSG_BROADCAST, attacker))
 464                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 465                                         if(self.health > 1)
 466                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 467                                         {
 468                                                 if(deathtype == DEATH_FALL)
 469                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 470                                                 else if(self.health > 75) // TODO make a "gentle" version?
 471                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 472                                                 else if(self.health > 50)
 473                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 474                                                 else if(self.health > 25)
 475                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 476                                                 else
 477                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 478                                         }
 479                                 }
 480
 481                                 // throw off bot aim temporarily
 482                                 float shake;
 483                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 484                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 485                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 486                         }
 487                 }
 488                 else
 489                         self.max_armorvalue += (save + take);
 490         }
 491         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 492         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 493         self.dmg_inflictor = inflictor;
 494
 495         if(attacker == self)
 496         {
 497                 // don't reset pushltime for self damage as it may be an attempt to
 498                 // escape a lava pit or similar
 499                 //self.pushltime = 0;
 500                 self.istypefrag = 0;
 501         }
 502         else if(attacker.classname == "player")
 503         {
 504                 self.pusher = attacker;
 505                 self.pushltime = time + autocvar_g_maxpushtime;
 506                 self.istypefrag = self.BUTTON_CHAT;
 507         }
 508         else if(time < self.pushltime)
 509         {
 510                 attacker = self.pusher;
 511                 self.pushltime = max(self.pushltime, time + 0.6);
 512         }
 513         else
 514         {
 515                 self.pushltime = 0;
 516                 self.istypefrag = 0;
 517         }
 518
 519         float abot, vbot, awep;
 520         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 521         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 522
 523         valid_damage_for_weaponstats = 0;
 524         awep = 0;
 525
 526         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 527         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 528         if(attacker && self != attacker)
 529         if(IsDifferentTeam(self, attacker))
 530         {
 531                 if(DEATH_ISSPECIAL(deathtype))
 532                         awep = attacker.weapon;
 533                 else
 534                         awep = DEATH_WEAPONOF(deathtype);
 535                 valid_damage_for_weaponstats = 1;
 536         }
 537
 538         if(valid_damage_for_weaponstats)
 539         {
 540                 dh = dh - max(self.health, 0);
 541                 da = da - max(self.armorvalue, 0);
 542                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 543         }
 544
 545         if (self.health < 1)
 546         {
 547                 float defer_ClientKill_Now_TeamChange;
 548                 defer_ClientKill_Now_TeamChange = FALSE;
 549
 550                 if(self.alivetime)
 551                 {
 552                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 553                         self.alivetime = 0;
 554                 }
 555
 556                 if(valid_damage_for_weaponstats)
 557                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 558
 559                 if(sv_gentle < 1) // TODO make a "gentle" version?
 560                 if(sound_allowed(MSG_BROADCAST, attacker))
 561                 {
 562                         if(deathtype == DEATH_DROWN)
 563                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 564                         else
 565                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 566                 }
 567
 568                 // get rid of kill indicator
 569                 if(self.killindicator)
 570                 {
 571                         remove(self.killindicator);
 572                         self.killindicator = world;
 573                         if(self.killindicator_teamchange)
 574                                 defer_ClientKill_Now_TeamChange = TRUE;
 575
 576                         if(self.classname == "body")
 577                         if(deathtype == DEATH_KILL)
 578                         {
 579                                 // for the lemmings fans, a small harmless explosion
 580                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 581                         }
 582                 }
 583
 584                 if(!g_freezetag)
 585                 {
 586                         // become fully visible
 587                         self.alpha = default_player_alpha;
 588                         // throw a weapon
 589                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 590                 }
 591
 592                 // print an obituary message
 593                 Obituary (attacker, inflictor, self, deathtype);
 594                 race_PreDie();
 595                 DropAllRunes(self);
 596
 597         // increment frag counter for used weapon type
 598         float w;
 599         w = DEATH_WEAPONOF(deathtype);
 600         if(WEP_VALID(w))
 601         if(accuracy_isgooddamage(attacker, self))
 602         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 603
 604                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 605                 {
 606                         PutClientInServer();
 607                         count_alive_players(); // re-count players
 608                         freezetag_CheckWinner();
 609                         return;
 610                 }
 611
 612                 frag_attacker = attacker;
 613                 frag_inflictor = inflictor;
 614                 frag_target = self;
 615                 MUTATOR_CALLHOOK(PlayerDies);
 616                 weapon_action(self.weapon, WR_PLAYERDEATH);
 617
 618                 RemoveGrapplingHook(self);
 619
 620                 Portal_ClearAllLater(self);
 621
 622                 if(clienttype(self) == CLIENTTYPE_REAL)
 623                 {
 624                         stuffcmd(self, "-zoom\n");
 625                         self.fixangle = TRUE;
 626                         //msg_entity = self;
 627                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 628                         //WriteAngle (MSG_ONE, self.v_angle_x);
 629                         //WriteAngle (MSG_ONE, self.v_angle_y);
 630                         //WriteAngle (MSG_ONE, 80);
 631                 }
 632
 633                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 634                         ClientKill_Now_TeamChange();
 635
 636                 if(g_arena)
 637                         Spawnqueue_Unmark(self);
 638
 639                 if(g_freezetag)
 640                         return;
 641
 642                 // when we get here, player actually dies
 643                 // clear waypoints (do this AFTER FreezeTag)
 644                 WaypointSprite_PlayerDead();
 645
 646                 // make the corpse upright (not tilted)
 647                 self.angles_x = 0;
 648                 self.angles_z = 0;
 649                 // don't spin
 650                 self.avelocity = '0 0 0';
 651                 // view from the floor
 652                 self.view_ofs = '0 0 -8';
 653                 // toss the corpse
 654                 self.movetype = MOVETYPE_TOSS;
 655                 // shootable corpse
 656                 self.solid = SOLID_CORPSE;
 657                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 658                 // don't stick to the floor
 659                 self.flags &~= FL_ONGROUND;
 660                 // dying animation
 661                 self.deadflag = DEAD_DYING;
 662                 // when to allow respawn
 663                 sdelay = 0;
 664                 waves = 0;
 665                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 666                 if(!sdelay)
 667                 {
 668                         if(g_cts)
 669                                 sdelay = 0; // no respawn delay in CTS
 670                         else
 671                                 sdelay = autocvar_g_respawn_delay;
 672                 }
 673                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 674                 if(!waves)
 675                         waves = autocvar_g_respawn_waves;
 676                 if(waves)
 677                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 678                 else
 679                         self.respawn_time = time + sdelay;
 680                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 681                         self.respawn_countdown = 10; // first number to count down from is 10
 682                 else
 683                         self.respawn_countdown = -1; // do not count down
 684                 self.death_time = time;
 685                 if (random() < 0.5)
 686                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 687                 else
 688                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 689                 if (self.maxs_z > 5)
 690                 {
 691                         self.maxs_z = 5;
 692                         setsize(self, self.mins, self.maxs);
 693                 }
 694                 // set damage function to corpse damage
 695                 self.event_damage = PlayerCorpseDamage;
 696                 // call the corpse damage function just in case it wants to gib
 697                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 698                 // set up to fade out later
 699                 SUB_SetFade (self, time + 6 + random (), 1);
 700
 701                 if(sv_gentle > 0 || autocvar_ekg) {
 702                         // remove corpse
 703                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 704                 }
 705
 706                 // reset fields the weapons may use just in case
 707                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 708                 {
 709                         weapon_action(j, WR_RESETPLAYER);
 710                         ATTACK_FINISHED_FOR(self, j) = 0;
 711                 }
 712         }
 713 }
 714
 715 .float muted; // to be used by prvm_edictset server playernumber muted 1
 716 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 717 // message "": do not say, just test flood control
 718 // return value:
 719 //   1 = accept
 720 //   0 = reject
 721 //  -1 = fake accept
 722 {
 723         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 724         float flood;
 725         var .float flood_field;
 726         entity head;
 727         float ret;
 728         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 729
 730         if(!teamsay && !privatesay)
 731                 if(substring(msgin, 0, 1) == " ")
 732                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 733
 734         msgin = formatmessage(msgin);
 735
 736         if(source.classname != "player")
 737                 colorstr = "^0"; // black for spectators
 738         else if(teamplay)
 739                 colorstr = Team_ColorCode(source.team);
 740         else
 741         {
 742                 colorstr = "";
 743                 teamsay = FALSE;
 744         }
 745
 746         if(intermission_running)
 747                 teamsay = FALSE;
 748
 749         if(msgin != "")
 750                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 751
 752         /*
 753          * using bprint solves this... me stupid
 754         // how can we prevent the message from appearing in a listen server?
 755         // for now, just give "say" back and only handle say_team
 756         if(!teamsay)
 757         {
 758                 clientcommand(self, strcat("say ", msgin));
 759                 return;
 760         }
 761         */
 762
 763         if(autocvar_g_chat_teamcolors)
 764                 namestr = playername(source);
 765         else
 766                 namestr = source.netname;
 767
 768         if(msgin != "")
 769         {
 770                 if(privatesay)
 771                 {
 772                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 773                         privatemsgprefixlen = strlen(msgstr);
 774                         msgstr = strcat(msgstr, msgin);
 775                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 776                         if(autocvar_g_chat_teamcolors)
 777                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 778                         else
 779                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 780                 }
 781                 else if(teamsay)
 782                 {
 783                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 784                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 785                 }
 786                 else
 787                 {
 788                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 789                         cmsgstr = "";
 790                 }
 791                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 792         }
 793         else
 794         {
 795                 msgstr = cmsgstr = "";
 796         }
 797
 798         fullmsgstr = msgstr;
 799         fullcmsgstr = cmsgstr;
 800
 801         // FLOOD CONTROL
 802         flood = 0;
 803         flood_field = floodcontrol_chat;
 804         if(floodcontrol)
 805         {
 806                 float flood_spl;
 807                 float flood_burst;
 808                 float flood_lmax;
 809                 float lines;
 810                 if(privatesay)
 811                 {
 812                         flood_spl = autocvar_g_chat_flood_spl_tell;
 813                         flood_burst = autocvar_g_chat_flood_burst_tell;
 814                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 815                         flood_field = floodcontrol_chattell;
 816                 }
 817                 else if(teamsay)
 818                 {
 819                         flood_spl = autocvar_g_chat_flood_spl_team;
 820                         flood_burst = autocvar_g_chat_flood_burst_team;
 821                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 822                         flood_field = floodcontrol_chatteam;
 823                 }
 824                 else
 825                 {
 826                         flood_spl = autocvar_g_chat_flood_spl;
 827                         flood_burst = autocvar_g_chat_flood_burst;
 828                         flood_lmax = autocvar_g_chat_flood_lmax;
 829                         flood_field = floodcontrol_chat;
 830                 }
 831                 flood_burst = max(0, flood_burst - 1);
 832                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 833
 834                 // do flood control for the default line size
 835                 if(msgstr != "")
 836                 {
 837                         getWrappedLine_remaining = msgstr;
 838                         msgstr = "";
 839                         lines = 0;
 840                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 841                         {
 842                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 843                                 ++lines;
 844                         }
 845                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 846
 847                         if(getWrappedLine_remaining != "")
 848                         {
 849                                 msgstr = strcat(msgstr, "\n");
 850                                 flood = 2;
 851                         }
 852
 853                         if(time >= source.flood_field)
 854                         {
 855                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 856                         }
 857                         else
 858                         {
 859                                 flood = 1;
 860                                 msgstr = fullmsgstr;
 861                         }
 862                 }
 863                 else
 864                 {
 865                         if(time >= source.flood_field)
 866                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 867                         else
 868                                 flood = 1;
 869                 }
 870
 871                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 872                         source.flood_field = flood = 0;
 873         }
 874
 875         if(flood == 2) // cannot happen for empty msgstr
 876         {
 877                 if(autocvar_g_chat_flood_notify_flooder)
 878                 {
 879                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 880                         sourcecmsgstr = "";
 881                 }
 882                 else
 883                 {
 884                         sourcemsgstr = fullmsgstr;
 885                         sourcecmsgstr = fullcmsgstr;
 886                 }
 887                 cmsgstr = "";
 888         }
 889         else
 890         {
 891                 sourcemsgstr = msgstr;
 892                 sourcecmsgstr = cmsgstr;
 893         }
 894
 895         if(!privatesay)
 896         if(source.classname != "player")
 897         {
 898                 if not(intermission_running)
 899                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 900                                 teamsay = -1; // spectators
 901         }
 902
 903         if(flood)
 904                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 905
 906         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 907         if(privatesay)
 908                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 909
 910         if(source.muted)
 911         {
 912                 // always fake the message
 913                 ret = -1;
 914         }
 915         else if(flood == 1)
 916         {
 917                 if(autocvar_g_chat_flood_notify_flooder)
 918                 {
 919                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 920                         ret = 0;
 921                 }
 922                 else
 923                         ret = -1;
 924         }
 925         else
 926         {
 927                 ret = 1;
 928         }
 929
 930         if(sourcemsgstr != "" && ret != 0)
 931         {
 932                 if(ret < 0) // faked message, because the player is muted
 933                 {
 934                         sprint(source, sourcemsgstr);
 935                         if(sourcecmsgstr != "" && !privatesay)
 936                                 centerprint(source, sourcecmsgstr);
 937                 }
 938                 else if(privatesay) // private message, between 2 people only, not sent to server console
 939                 {
 940                         sprint(source, sourcemsgstr);
 941                         sprint(privatesay, msgstr);
 942                         if(cmsgstr != "")
 943                                 centerprint(privatesay, cmsgstr);
 944                 }
 945                 else if(teamsay > 0) // team message, only sent to team mates
 946                 {
 947                         sprint(source, sourcemsgstr);
 948                         //print(msgstr); // send to server console too
 949                         if(sourcecmsgstr != "")
 950                                 centerprint(source, sourcecmsgstr);
 951                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 952                                 if(head != source)
 953                                 {
 954                                         sprint(head, msgstr);
 955                                         if(cmsgstr != "")
 956                                                 centerprint(head, cmsgstr);
 957                                 }
 958                 }
 959                 else if(teamsay < 0) // spectator message, only sent to spectators
 960                 {
 961                         sprint(source, sourcemsgstr);
 962                         //print(msgstr); // send to server console too
 963                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 964                                 if(head != source)
 965                                         sprint(head, msgstr);
 966                 }
 967                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 968                 {
 969                         sprint(source, sourcemsgstr);
 970                         //print(msgstr); // send to server console too
 971                         FOR_EACH_REALCLIENT(head)
 972                                 if(head != source)
 973                                         sprint(head, msgstr);
 974                 }
 975                 else
 976                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 977         }
 978
 979         return ret;
 980 }
 981
 982 float GetVoiceMessageVoiceType(string type)
 983 {
 984         if(type == "taunt")
 985                 return VOICETYPE_TAUNT;
 986         if(type == "teamshoot")
 987                 return VOICETYPE_LASTATTACKER;
 988         return VOICETYPE_TEAMRADIO;
 989 }
 990
 991 string allvoicesamples;
 992 .string GetVoiceMessageSampleField(string type)
 993 {
 994         GetPlayerSoundSampleField_notFound = 0;
 995         switch(type)
 996         {
 997 #define _VOICEMSG(m) case #m: return playersound_##m;
 998                 ALLVOICEMSGS
 999 #undef _VOICEMSG
1000         }
1001         GetPlayerSoundSampleField_notFound = 1;
1002         return playersound_taunt;
1003 }
1004
1005 .string GetPlayerSoundSampleField(string type)
1006 {
1007         GetPlayerSoundSampleField_notFound = 0;
1008         switch(type)
1009         {
1010 #define _VOICEMSG(m) case #m: return playersound_##m;
1011                 ALLPLAYERSOUNDS
1012 #undef _VOICEMSG
1013         }
1014         GetPlayerSoundSampleField_notFound = 1;
1015         return playersound_taunt;
1016 }
1017
1018 void PrecacheGlobalSound(string samplestring)
1019 {
1020         float n, i;
1021         tokenize_console(samplestring);
1022         n = stof(argv(1));
1023         if(n > 0)
1024         {
1025                 for(i = 1; i <= n; ++i)
1026                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1027         }
1028         else
1029         {
1030                 precache_sound(strcat(argv(0), ".wav"));
1031         }
1032 }
1033
1034 void PrecachePlayerSounds(string f)
1035 {
1036         float fh;
1037         string s;
1038         fh = fopen(f, FILE_READ);
1039         if(fh < 0)
1040                 return;
1041         while((s = fgets(fh)))
1042         {
1043                 if(tokenize_console(s) != 3)
1044                 {
1045                         dprint("Invalid sound info line: ", s, "\n");
1046                         continue;
1047                 }
1048                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1049         }
1050         fclose(fh);
1051
1052         if not(allvoicesamples)
1053         {
1054 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1055                 ALLVOICEMSGS
1056 #undef _VOICEMSG
1057                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1058         }
1059 }
1060
1061 void ClearPlayerSounds()
1062 {
1063 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1064         ALLPLAYERSOUNDS
1065         ALLVOICEMSGS
1066 #undef _VOICEMSG
1067 }
1068
1069 float LoadPlayerSounds(string f, float first)
1070 {
1071         float fh;
1072         string s;
1073         var .string field;
1074         fh = fopen(f, FILE_READ);
1075         if(fh < 0)
1076         {
1077                 dprint("Player sound file not found: ", f, "\n");
1078                 return 0;
1079         }
1080         while((s = fgets(fh)))
1081         {
1082                 if(tokenize_console(s) != 3)
1083                         continue;
1084                 field = GetPlayerSoundSampleField(argv(0));
1085                 if(GetPlayerSoundSampleField_notFound)
1086                         field = GetVoiceMessageSampleField(argv(0));
1087                 if(GetPlayerSoundSampleField_notFound)
1088                         continue;
1089                 if(self.field)
1090                         strunzone(self.field);
1091                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1092         }
1093         fclose(fh);
1094         return 1;
1095 }
1096
1097 .float modelindex_for_playersound;
1098 .float skin_for_playersound;
1099 void UpdatePlayerSounds()
1100 {
1101         if(self.modelindex == self.modelindex_for_playersound)
1102         if(self.skin == self.skin_for_playersound)
1103                 return;
1104         self.modelindex_for_playersound = self.modelindex;
1105         self.skin_for_playersound = self.skin;
1106         ClearPlayerSounds();
1107         LoadPlayerSounds("sound/player/default.sounds", 1);
1108         if(!autocvar_g_debug_defaultsounds)
1109                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1110                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1111 }
1112
1113 void FakeGlobalSound(string sample, float chan, float voicetype)
1114 {
1115         float n;
1116         float tauntrand;
1117
1118         if(sample == "")
1119                 return;
1120
1121         tokenize_console(sample);
1122         n = stof(argv(1));
1123         if(n > 0)
1124                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1125         else
1126                 sample = strcat(argv(0), ".wav"); // randomization
1127
1128         switch(voicetype)
1129         {
1130                 case VOICETYPE_LASTATTACKER_ONLY:
1131                         break;
1132                 case VOICETYPE_LASTATTACKER:
1133                         if(self.pusher)
1134                         {
1135                                 msg_entity = self;
1136                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1137                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1138                         }
1139                         break;
1140                 case VOICETYPE_TEAMRADIO:
1141                         msg_entity = self;
1142                         if(msg_entity.cvar_cl_voice_directional == 1)
1143                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1144                         else
1145                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1146                         break;
1147                 case VOICETYPE_AUTOTAUNT:
1148                         if(!sv_autotaunt)
1149                                 break;
1150                         if(!sv_taunt)
1151                                 break;
1152                         if(sv_gentle)
1153                                 break;
1154                         tauntrand = random();
1155                         msg_entity = self;
1156                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1157                         {
1158                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1159                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1160                                 else
1161                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1162                         }
1163                         break;
1164                 case VOICETYPE_TAUNT:
1165                         if(self.classname == "player")
1166                                 if(self.deadflag == DEAD_NO)
1167                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1168                         if(!sv_taunt)
1169                                 break;
1170                         if(sv_gentle)
1171                                 break;
1172                         msg_entity = self;
1173                         if (msg_entity.cvar_cl_voice_directional >= 1)
1174                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1175                         else
1176                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1177                         break;
1178                 case VOICETYPE_PLAYERSOUND:
1179                         msg_entity = self;
1180                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1181                         break;
1182                 default:
1183                         backtrace("Invalid voice type!");
1184                         break;
1185         }
1186 }
1187
1188 void GlobalSound(string sample, float chan, float voicetype)
1189 {
1190         float n;
1191         float tauntrand;
1192
1193         if(sample == "")
1194                 return;
1195
1196         tokenize_console(sample);
1197         n = stof(argv(1));
1198         if(n > 0)
1199                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1200         else
1201                 sample = strcat(argv(0), ".wav"); // randomization
1202
1203         switch(voicetype)
1204         {
1205                 case VOICETYPE_LASTATTACKER_ONLY:
1206                         if(self.pusher)
1207                         {
1208                                 msg_entity = self.pusher;
1209                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1210                                 {
1211                                         if(msg_entity.cvar_cl_voice_directional == 1)
1212                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1213                                         else
1214                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1215                                 }
1216                         }
1217                         break;
1218                 case VOICETYPE_LASTATTACKER:
1219                         if(self.pusher)
1220                         {
1221                                 msg_entity = self.pusher;
1222                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1223                                 {
1224                                         if(msg_entity.cvar_cl_voice_directional == 1)
1225                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1226                                         else
1227                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1228                                 }
1229                                 msg_entity = self;
1230                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1231                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1232                         }
1233                         break;
1234                 case VOICETYPE_TEAMRADIO:
1235                         FOR_EACH_REALCLIENT(msg_entity)
1236                                 if(!teamplay || msg_entity.team == self.team)
1237                                 {
1238                                         if(msg_entity.cvar_cl_voice_directional == 1)
1239                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1240                                         else
1241                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1242                                 }
1243                         break;
1244                 case VOICETYPE_AUTOTAUNT:
1245                         if(!sv_autotaunt)
1246                                 break;
1247                         if(!sv_taunt)
1248                                 break;
1249                         if(sv_gentle)
1250                                 break;
1251                         tauntrand = random();
1252                         FOR_EACH_REALCLIENT(msg_entity)
1253                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1254                                 {
1255                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1256                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1257                                         else
1258                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1259                                 }
1260                         break;
1261                 case VOICETYPE_TAUNT:
1262                         if(self.classname == "player")
1263                                 if(self.deadflag == DEAD_NO)
1264                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1265                         if(!sv_taunt)
1266                                 break;
1267                         if(sv_gentle)
1268                                 break;
1269                         FOR_EACH_REALCLIENT(msg_entity)
1270                         {
1271                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1272                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1273                                 else
1274                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1275                         }
1276                         break;
1277                 case VOICETYPE_PLAYERSOUND:
1278                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1279                         break;
1280                 default:
1281                         backtrace("Invalid voice type!");
1282                         break;
1283         }
1284 }
1285
1286 void PlayerSound(.string samplefield, float chan, float voicetype)
1287 {
1288         GlobalSound(self.samplefield, chan, voicetype);
1289 }
1290
1291 void VoiceMessage(string type, string msg)
1292 {
1293         var .string sample;
1294         float voicetype, ownteam;
1295         float flood;
1296         sample = GetVoiceMessageSampleField(type);
1297
1298         if(GetPlayerSoundSampleField_notFound)
1299         {
1300                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1301                 return;
1302         }
1303
1304         voicetype = GetVoiceMessageVoiceType(type);
1305         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1306
1307         flood = Say(self, ownteam, world, msg, 1);
1308
1309         if (flood > 0)
1310                 GlobalSound(self.sample, CH_VOICE, voicetype);
1311         else if (flood < 0)
1312                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1313 }
1314
1315 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1316 {
1317 //      show_message
1318 //      0 (00) automove centerprint, admin message
1319 //      1 (01) automove centerprint, no admin message
1320 //      2 (10) no centerprint, admin message
1321 //      3 (11) no centerprint, no admin message
1322
1323         float lockteams_backup;
1324
1325         lockteams_backup = lockteams;  // backup any team lock
1326
1327         lockteams = 0;  // disable locked teams
1328
1329         TeamchangeFrags(client);  // move the players frags
1330         SetPlayerColors(client, team_colour - 1);  // set the players colour
1331         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1332
1333         lockteams = lockteams_backup;  // restore the team lock
1334
1335         LogTeamchange(client.playerid, client.team, type);
1336
1337         if not(show_message & 1) // admin message
1338                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1339
1340         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1341 }