qcsrc/server/cl_player.qc

   1 float weaponstats_buffer;
   2
   3 void WeaponStats_Init()
   4 {
   5         if(autocvar_sv_weaponstats_file != "")
   6                 weaponstats_buffer = buf_create();
   7         else
   8                 weaponstats_buffer = -1;
   9 }
  10
  11 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  12
  13 void WeaponStats_Shutdown()
  14 {
  15         float i, j, ibot, jbot, idx;
  16         float fh;
  17         vector v;
  18         string prefix;
  19         if(weaponstats_buffer < 0)
  20                 return;
  21         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  22         if(autocvar_sv_weaponstats_file != "")
  23         {
  24                 fh = fopen(autocvar_sv_weaponstats_file, FILE_APPEND);
  25                 if(fh >= 0)
  26                 {
  27                         fputs(fh, "#begin statsfile\n");
  28                         fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  29                         fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_changes)), "\n"));
  30                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  31                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  32                                 {
  33                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  34                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  35                                         if(v != '0 0 0')
  36                                         {
  37                                                 //vector is: kills hits damage
  38                                                 fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  39                                                 fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  40                                         }
  41                                 }
  42                         fputs(fh, "#end\n\n");
  43                         fclose(fh);
  44                         print("Weapon stats written\n");
  45                 }
  46         }
  47         buf_del(weaponstats_buffer);
  48         weaponstats_buffer = -1;
  49 }
  50
  51 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  52 {
  53         float idx;
  54         if(weaponstats_buffer < 0)
  55                 return;
  56         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  57                 return;
  58         if(awep > WEP_LAST || vwep > WEP_LAST)
  59                 return;
  60         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
  61         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
  62 }
  63 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
  64 {
  65         if(damage < 0)
  66                 error("negative damage?");
  67         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
  68 }
  69 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
  70 {
  71         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
  72 }
  73
  74 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
  75 // merged player_run and player_stand to player_anim
  76 // added death animations to player_anim
  77 // can now spawn thrown weapons from anywhere, not just from players
  78 // thrown weapons now fade out after 20 seconds
  79 // created PlayerGib function
  80 // PlayerDie no longer uses hitloc or damage
  81 // PlayerDie now supports dying animations as well as gibbing
  82 // cleaned up PlayerDie a lot
  83 // added CopyBody
  84
  85 .entity pusher;
  86 .float pushltime;
  87
  88 void CopyBody(float keepvelocity)
  89 {
  90         local entity oldself;
  91         if (self.effects & EF_NODRAW)
  92                 return;
  93         oldself = self;
  94         self = spawn();
  95         self.enemy = oldself;
  96         self.lip = oldself.lip;
  97         self.colormap = oldself.colormap;
  98         self.glowmod = oldself.glowmod;
  99         self.iscreature = oldself.iscreature;
 100         self.angles = oldself.angles;
 101         self.avelocity = oldself.avelocity;
 102         self.classname = "body";
 103         self.damageforcescale = oldself.damageforcescale;
 104         self.effects = oldself.effects;
 105         self.event_damage = oldself.event_damage;
 106         self.animstate_startframe = oldself.animstate_startframe;
 107         self.animstate_numframes = oldself.animstate_numframes;
 108         self.animstate_framerate = oldself.animstate_framerate;
 109         self.animstate_starttime = oldself.animstate_starttime;
 110         self.animstate_endtime = oldself.animstate_endtime;
 111         self.animstate_override = oldself.animstate_override;
 112         self.animstate_looping = oldself.animstate_looping;
 113         self.frame = oldself.frame;
 114         self.dead_frame = oldself.dead_frame;
 115         self.pain_finished = oldself.pain_finished;
 116         self.health = oldself.health;
 117         self.armorvalue = oldself.armorvalue;
 118         self.armortype = oldself.armortype;
 119         self.model = oldself.model;
 120         self.modelindex = oldself.modelindex;
 121         self.modelindex_lod0 = oldself.modelindex_lod0;
 122         self.modelindex_lod0_from_xonotic = oldself.modelindex_lod0_from_xonotic;
 123         self.modelindex_lod1 = oldself.modelindex_lod1;
 124         self.modelindex_lod2 = oldself.modelindex_lod2;
 125         self.skinindex = oldself.skinindex;
 126         self.species = oldself.species;
 127         self.movetype = oldself.movetype;
 128         self.nextthink = oldself.nextthink;
 129         self.solid = oldself.solid;
 130         self.ballistics_density = oldself.ballistics_density;
 131         self.takedamage = oldself.takedamage;
 132         self.think = oldself.think;
 133         self.customizeentityforclient = oldself.customizeentityforclient;
 134         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 135         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 136         if (keepvelocity == 1)
 137                 self.velocity = oldself.velocity;
 138         self.oldvelocity = self.velocity;
 139         self.fade_time = oldself.fade_time;
 140         self.fade_rate = oldself.fade_rate;
 141         //self.weapon = oldself.weapon;
 142         setorigin(self, oldself.origin);
 143         setsize(self, oldself.mins, oldself.maxs);
 144         self.prevorigin = oldself.origin;
 145         self.reset = SUB_Remove;
 146
 147         Drag_MoveDrag(oldself, self);
 148
 149         self = oldself;
 150 }
 151
 152 float player_getspecies()
 153 {
 154         float s;
 155         get_model_parameters(self.model, self.skinindex);
 156         s = get_model_parameters_species;
 157         get_model_parameters(string_null, 0);
 158         if(s < 0)
 159                 return SPECIES_HUMAN;
 160         return s;
 161 }
 162
 163 void player_setupanimsformodel()
 164 {
 165         local string animfilename;
 166         local float animfile;
 167         // defaults for legacy .zym models without animinfo files
 168         self.anim_die1 = '0 1 0.5'; // 2 seconds
 169         self.anim_die2 = '1 1 0.5'; // 2 seconds
 170         self.anim_draw = '2 1 3'; // TODO: analyze models and set framerate
 171         self.anim_duck = '3 1 100'; // this anim seems bogus in most models, so make it play VERY briefly!
 172         self.anim_duckwalk = '4 1 1';
 173         self.anim_duckjump = '5 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 174         self.anim_duckidle = '6 1 1';
 175         self.anim_idle = '7 1 1';
 176         self.anim_jump = '8 1 100'; // zym anims keep playing until changed, so this only has to start the anim, landing will end it
 177         self.anim_pain1 = '9 1 2'; // 0.5 seconds
 178         self.anim_pain2 = '10 1 2'; // 0.5 seconds
 179         self.anim_shoot = '11 1 5'; // TODO: analyze models and set framerate
 180         self.anim_taunt = '12 1 0.33'; // FIXME?  there is no code using this anim
 181         self.anim_run = '13 1 1';
 182         self.anim_runbackwards = '14 1 1';
 183         self.anim_strafeleft = '15 1 1';
 184         self.anim_straferight = '16 1 1';
 185         self.anim_dead1 = '17 1 1';
 186         self.anim_dead2 = '18 1 1';
 187         self.anim_forwardright = '19 1 1';
 188         self.anim_forwardleft = '20 1 1';
 189         self.anim_backright = '21 1 1';
 190         self.anim_backleft  = '22 1 1';
 191         animparseerror = FALSE;
 192         animfilename = strcat(self.model, ".animinfo");
 193         animfile = fopen(animfilename, FILE_READ);
 194         if (animfile >= 0)
 195         {
 196                 self.anim_die1         = animparseline(animfile);
 197                 self.anim_die2         = animparseline(animfile);
 198                 self.anim_draw         = animparseline(animfile);
 199                 self.anim_duck         = animparseline(animfile);
 200                 self.anim_duckwalk     = animparseline(animfile);
 201                 self.anim_duckjump     = animparseline(animfile);
 202                 self.anim_duckidle     = animparseline(animfile);
 203                 self.anim_idle         = animparseline(animfile);
 204                 self.anim_jump         = animparseline(animfile);
 205                 self.anim_pain1        = animparseline(animfile);
 206                 self.anim_pain2        = animparseline(animfile);
 207                 self.anim_shoot        = animparseline(animfile);
 208                 self.anim_taunt        = animparseline(animfile);
 209                 self.anim_run          = animparseline(animfile);
 210                 self.anim_runbackwards = animparseline(animfile);
 211                 self.anim_strafeleft   = animparseline(animfile);
 212                 self.anim_straferight  = animparseline(animfile);
 213                 self.anim_forwardright = animparseline(animfile);
 214                 self.anim_forwardleft  = animparseline(animfile);
 215                 self.anim_backright    = animparseline(animfile);
 216                 self.anim_backleft     = animparseline(animfile);
 217                 fclose(animfile);
 218
 219                 // derived anims
 220                 self.anim_dead1 = '0 1 1' + '1 0 0' * (self.anim_die1_x + self.anim_die1_y - 1);
 221                 self.anim_dead2 = '0 1 1' + '1 0 0' * (self.anim_die2_x + self.anim_die2_y - 1);
 222
 223                 if (animparseerror)
 224                         print("Parse error in ", animfilename, ", some player animations are broken\n");
 225         }
 226         else
 227                 dprint("File ", animfilename, " not found, assuming legacy .zym model animation timings\n");
 228         // reset animstate now
 229         setanim(self, self.anim_idle, TRUE, FALSE, TRUE);
 230 };
 231
 232 void player_anim (void)
 233 {
 234         updateanim(self);
 235         if (self.weaponentity)
 236                 updateanim(self.weaponentity);
 237
 238         if (self.deadflag != DEAD_NO)
 239         {
 240                 if (time > self.animstate_endtime)
 241                 {
 242                         if (self.maxs_z > 5)
 243                         {
 244                                 self.maxs_z = 5;
 245                                 setsize(self, self.mins, self.maxs);
 246                         }
 247                         self.frame = self.dead_frame;
 248                 }
 249                 return;
 250         }
 251
 252         if (!self.animstate_override)
 253         {
 254                 if (!(self.flags & FL_ONGROUND))
 255                 {
 256                         if (self.crouch)
 257                                 setanim(self, self.anim_duckjump, FALSE, TRUE, self.restart_jump);
 258                         else
 259                                 setanim(self, self.anim_jump, FALSE, TRUE, self.restart_jump);
 260                         self.restart_jump = FALSE;
 261                 }
 262                 else if (self.crouch)
 263                 {
 264                         if (self.movement_x * self.movement_x + self.movement_y * self.movement_y > 20)
 265                                 setanim(self, self.anim_duckwalk, TRUE, FALSE, FALSE);
 266                         else
 267                                 setanim(self, self.anim_duckidle, TRUE, FALSE, FALSE);
 268                 }
 269                 else if ((self.movement_x * self.movement_x + self.movement_y * self.movement_y) > 20)
 270                 {
 271                         if (self.movement_x > 0 && self.movement_y == 0)
 272                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 273                         else if (self.movement_x < 0 && self.movement_y == 0)
 274                                 setanim(self, self.anim_runbackwards, TRUE, FALSE, FALSE);
 275                         else if (self.movement_x == 0 && self.movement_y > 0)
 276                                 setanim(self, self.anim_straferight, TRUE, FALSE, FALSE);
 277                         else if (self.movement_x == 0 && self.movement_y < 0)
 278                                 setanim(self, self.anim_strafeleft, TRUE, FALSE, FALSE);
 279                         else if (self.movement_x > 0 && self.movement_y > 0)
 280                                 setanim(self, self.anim_forwardright, TRUE, FALSE, FALSE);
 281                         else if (self.movement_x > 0 && self.movement_y < 0)
 282                                 setanim(self, self.anim_forwardleft, TRUE, FALSE, FALSE);
 283                         else if (self.movement_x < 0 && self.movement_y > 0)
 284                                 setanim(self, self.anim_backright, TRUE, FALSE, FALSE);
 285                         else if (self.movement_x < 0 && self.movement_y < 0)
 286                                 setanim(self, self.anim_backleft, TRUE, FALSE, FALSE);
 287                         else
 288                                 setanim(self, self.anim_run, TRUE, FALSE, FALSE);
 289                 }
 290                 else
 291                         setanim(self, self.anim_idle, TRUE, FALSE, FALSE);
 292         }
 293
 294         if (self.weaponentity)
 295         if (!self.weaponentity.animstate_override)
 296                 setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 297 }
 298
 299 void SpawnThrownWeapon (vector org, float w)
 300 {
 301         if(g_minstagib)
 302         if(self.ammo_cells <= 0)
 303                 return;
 304
 305         if(g_pinata)
 306         {
 307                 float j;
 308                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 309                 {
 310                         if(self.weapons & W_WeaponBit(j))
 311                                 if(W_IsWeaponThrowable(j))
 312                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 313                 }
 314         }
 315         else
 316         {
 317                 if(W_IsWeaponThrowable(self.weapon))
 318                         W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 319         }
 320 }
 321
 322 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 323 {
 324         local float take, save;
 325         vector v;
 326         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 327
 328         // damage resistance (ignore most of the damage from a bullet or similar)
 329         damage = max(damage - 5, 1);
 330
 331         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 332         take = v_x;
 333         save = v_y;
 334
 335         if(sound_allowed(MSG_BROADCAST, attacker))
 336         {
 337                 if (save > 10)
 338                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 339                 else if (take > 30)
 340                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 341                 else if (take > 10)
 342                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 343         }
 344
 345         if (take > 50)
 346                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 347         if (take > 100)
 348                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 349
 350         if (!(self.flags & FL_GODMODE))
 351         {
 352                 self.armorvalue = self.armorvalue - save;
 353                 self.health = self.health - take;
 354                 // pause regeneration for 5 seconds
 355                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 356         }
 357         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 358         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 359         self.dmg_inflictor = inflictor;
 360
 361         if (self.health <= -autocvar_sv_gibhealth && self.modelindex != 0)
 362         {
 363                 // don't use any animations as a gib
 364                 self.frame = 0;
 365                 self.dead_frame = 0;
 366                 // view just above the floor
 367                 self.view_ofs = '0 0 4';
 368
 369                 Violence_GibSplash(self, 1, 1, attacker);
 370                 self.modelindex = 0; // restore later
 371                 self.solid = SOLID_NOT; // restore later
 372         }
 373 }
 374
 375 void ClientKill_Now_TeamChange();
 376 void freezetag_CheckWinner();
 377
 378 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 379 {
 380         local float take, save, waves, sdelay, dh, da, j;
 381         vector v;
 382         float valid_damage_for_weaponstats;
 383         float excess;
 384
 385         if((g_arena && numspawned < 2) || (g_ca && ca_players < required_ca_players) && !inWarmupStage)
 386                 return;
 387
 388         dh = max(self.health, 0);
 389         da = max(self.armorvalue, 0);
 390
 391         if(!DEATH_ISSPECIAL(deathtype))
 392         {
 393                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 394                 if(self != attacker)
 395                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 396         }
 397
 398         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 399         {
 400                 // tuba causes blood to come out of the ears
 401                 vector ear1, ear2;
 402                 vector d;
 403                 float f;
 404                 ear1 = self.origin;
 405                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 406                 ear2 = ear1;
 407                 makevectors(self.angles);
 408                 ear1 += v_right * -10;
 409                 ear2 += v_right * +10;
 410                 d = inflictor.origin - self.origin;
 411                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 412                 force = v_right * vlen(force);
 413                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 414                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 415                 if(f > 0)
 416                 {
 417                         hitloc = ear1;
 418                         force = force * -1;
 419                 }
 420                 else
 421                 {
 422                         hitloc = ear2;
 423                         // force is already good
 424                 }
 425         }
 426         else
 427                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 428
 429         if (!g_minstagib)
 430         {
 431                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 432                 take = v_x;
 433                 save = v_y;
 434         }
 435         else
 436         {
 437                 save = 0;
 438                 take = damage;
 439         }
 440
 441         frag_inflictor = inflictor;
 442         frag_attacker = attacker;
 443         frag_target = self;
 444         damage_take = take;
 445         damage_save = save;
 446         damage_force = force;
 447         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 448         take = bound(0, damage_take, self.health);
 449         save = bound(0, damage_save, self.armorvalue);
 450         excess = max(0, damage - take - save);
 451
 452         if(sound_allowed(MSG_BROADCAST, attacker))
 453         {
 454                 if (save > 10)
 455                         sound (self, CHAN_PROJECTILE, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 456                 else if (take > 30)
 457                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 458                 else if (take > 10)
 459                         sound (self, CHAN_PROJECTILE, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 460         }
 461
 462         if (take > 50)
 463                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 464         if (take > 100)
 465                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 466
 467         if (time >= self.spawnshieldtime)
 468         {
 469                 if (!(self.flags & FL_GODMODE))
 470                 {
 471                         self.armorvalue = self.armorvalue - save;
 472                         self.health = self.health - take;
 473                         // pause regeneration for 5 seconds
 474                         self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 475
 476                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 477                         {
 478                                 self.pain_finished = time + 0.5;        //Supajoe
 479
 480                                 if(sv_gentle < 1) {
 481                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 482                                         {
 483                                                 if (random() > 0.5)
 484                                                         setanim(self, self.anim_pain1, FALSE, TRUE, TRUE);
 485                                                 else
 486                                                         setanim(self, self.anim_pain2, FALSE, TRUE, TRUE);
 487                                         }
 488
 489                                         if(sound_allowed(MSG_BROADCAST, attacker))
 490                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 491                                         if(self.health > 1)
 492                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 493                                         {
 494                                                 if(deathtype == DEATH_FALL)
 495                                                         PlayerSound(playersound_fall, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 496                                                 else if(self.health > 75) // TODO make a "gentle" version?
 497                                                         PlayerSound(playersound_pain100, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 498                                                 else if(self.health > 50)
 499                                                         PlayerSound(playersound_pain75, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 500                                                 else if(self.health > 25)
 501                                                         PlayerSound(playersound_pain50, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 502                                                 else
 503                                                         PlayerSound(playersound_pain25, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 504                                         }
 505                                 }
 506
 507                                 // throw off bot aim temporarily
 508                                 local float shake;
 509                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 510                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 511                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 512                         }
 513                 }
 514                 else
 515                         self.max_armorvalue += (save + take);
 516         }
 517         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 518         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 519         self.dmg_inflictor = inflictor;
 520
 521         if(attacker == self)
 522         {
 523                 // don't reset pushltime for self damage as it may be an attempt to
 524                 // escape a lava pit or similar
 525                 //self.pushltime = 0;
 526         }
 527         else if(attacker.classname == "player" || attacker.classname == "gib")
 528         {
 529                 self.pusher = attacker;
 530                 self.pushltime = time + autocvar_g_maxpushtime;
 531         }
 532         else if(time < self.pushltime)
 533         {
 534                 attacker = self.pusher;
 535                 self.pushltime = max(self.pushltime, time + 0.6);
 536         }
 537         else
 538                 self.pushltime = 0;
 539
 540         float abot, vbot, awep;
 541         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 542         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 543
 544         valid_damage_for_weaponstats = 0;
 545         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 546         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 547         if(attacker && self != attacker)
 548         if(IsDifferentTeam(self, attacker))
 549         {
 550                 if(DEATH_ISSPECIAL(deathtype))
 551                         awep = attacker.weapon;
 552                 else
 553                         awep = DEATH_WEAPONOF(deathtype);
 554                 valid_damage_for_weaponstats = 1;
 555         }
 556
 557         if(valid_damage_for_weaponstats)
 558         {
 559                 dh = dh - max(self.health, 0);
 560                 da = da - max(self.armorvalue, 0);
 561                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 562         }
 563
 564         if (self.health < 1)
 565         {
 566                 float defer_ClientKill_Now_TeamChange;
 567                 defer_ClientKill_Now_TeamChange = FALSE;
 568
 569                 if(self.alivetime)
 570                 {
 571                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 572                         self.alivetime = 0;
 573                 }
 574
 575                 if(valid_damage_for_weaponstats)
 576                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 577
 578                 if(sv_gentle < 1) // TODO make a "gentle" version?
 579                 if(sound_allowed(MSG_BROADCAST, attacker))
 580                 {
 581                         if(deathtype == DEATH_DROWN)
 582                                 PlayerSound(playersound_drown, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 583                         else
 584                                 PlayerSound(playersound_death, CHAN_PAIN, VOICETYPE_PLAYERSOUND);
 585                 }
 586
 587                 // get rid of kill indicator
 588                 if(self.killindicator)
 589                 {
 590                         remove(self.killindicator);
 591                         self.killindicator = world;
 592                         if(self.killindicator_teamchange)
 593                                 defer_ClientKill_Now_TeamChange = TRUE;
 594
 595                         if(self.classname == "body")
 596                         if(deathtype == DEATH_KILL)
 597                         {
 598                                 // for the lemmings fans, a small harmless explosion
 599                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 600                         }
 601                 }
 602
 603                 if(!g_freezetag)
 604                 {
 605                         // become fully visible
 606                         self.alpha = 1;
 607                         // throw a weapon
 608                         SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 609                 }
 610
 611                 // print an obituary message
 612                 Obituary (attacker, inflictor, self, deathtype);
 613                 race_PreDie();
 614                 DropAllRunes(self);
 615
 616                 if(deathtype == DEATH_HURTTRIGGER && g_freezetag)
 617                 {
 618                         PutClientInServer();
 619                         count_alive_players(); // re-count players
 620                         freezetag_CheckWinner();
 621                         return;
 622                 }
 623
 624                 frag_attacker = attacker;
 625                 frag_inflictor = inflictor;
 626                 frag_target = self;
 627                 MUTATOR_CALLHOOK(PlayerDies);
 628
 629                 if(self.flagcarried)
 630                 {
 631                         if(attacker.classname != "player" && attacker.classname != "gib")
 632                                 DropFlag(self.flagcarried, self, attacker); // penalty for flag loss by suicide
 633                         else if(attacker.team == self.team)
 634                                 DropFlag(self.flagcarried, attacker, attacker); // penalty for flag loss by suicide/teamkill
 635                         else
 636                                 DropFlag(self.flagcarried, world, attacker);
 637                 }
 638                 if(self.ballcarried && g_nexball)
 639                         DropBall(self.ballcarried, self.origin, self.velocity);
 640                 Portal_ClearAllLater(self);
 641
 642                 if(clienttype(self) == CLIENTTYPE_REAL)
 643                 {
 644                         stuffcmd(self, "-zoom\n");
 645                         self.fixangle = TRUE;
 646                         //msg_entity = self;
 647                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 648                         //WriteAngle (MSG_ONE, self.v_angle_x);
 649                         //WriteAngle (MSG_ONE, self.v_angle_y);
 650                         //WriteAngle (MSG_ONE, 80);
 651                 }
 652
 653                 if(defer_ClientKill_Now_TeamChange) // TODO does this work with FreezeTag?
 654                         ClientKill_Now_TeamChange();
 655
 656                 if(g_arena)
 657                         Spawnqueue_Unmark(self);
 658
 659                 if(g_freezetag)
 660                         return;
 661
 662                 // when we get here, player actually dies
 663                 // clear waypoints (do this AFTER FreezeTag)
 664                 WaypointSprite_PlayerDead();
 665
 666                 // make the corpse upright (not tilted)
 667                 self.angles_x = 0;
 668                 self.angles_z = 0;
 669                 // don't spin
 670                 self.avelocity = '0 0 0';
 671                 // view from the floor
 672                 self.view_ofs = '0 0 -8';
 673                 // toss the corpse
 674                 self.movetype = MOVETYPE_TOSS;
 675                 // shootable corpse
 676                 self.solid = SOLID_CORPSE;
 677                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 678                 // don't stick to the floor
 679                 self.flags &~= FL_ONGROUND;
 680                 // dying animation
 681                 self.deadflag = DEAD_DYING;
 682                 // when to allow respawn
 683                 sdelay = 0;
 684                 waves = 0;
 685                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 686                 if(!sdelay)
 687                 {
 688                         if(g_cts)
 689                                 sdelay = 0; // no respawn delay in CTS
 690                         else
 691                                 sdelay = autocvar_g_respawn_delay;
 692                 }
 693                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 694                 if(!waves)
 695                         waves = autocvar_g_respawn_waves;
 696                 if(waves)
 697                         self.death_time = ceil((time + sdelay) / waves) * waves;
 698                 else
 699                         self.death_time = time + sdelay;
 700                 if((sdelay + waves >= 5.0) && (self.death_time - time > 1.75))
 701                         self.respawn_countdown = 10; // first number to count down from is 10
 702                 else
 703                         self.respawn_countdown = -1; // do not count down
 704                 if (random() < 0.5)
 705                 {
 706                         setanim(self, self.anim_die1, FALSE, TRUE, TRUE);
 707                         self.dead_frame = self.anim_dead1_x;
 708                 }
 709                 else
 710                 {
 711                         setanim(self, self.anim_die2, FALSE, TRUE, TRUE);
 712                         self.dead_frame = self.anim_dead2_x;
 713                 }
 714                 // set damage function to corpse damage
 715                 self.event_damage = PlayerCorpseDamage;
 716                 // call the corpse damage function just in case it wants to gib
 717                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 718                 // set up to fade out later
 719                 SUB_SetFade (self, time + 6 + random (), 1);
 720
 721                 if(sv_gentle > 0 || autocvar_ekg) {
 722                         // remove corpse
 723                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 724                 }
 725
 726                 // reset fields the weapons may use just in case
 727                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 728                 {
 729                         weapon_action(j, WR_RESETPLAYER);
 730                         ATTACK_FINISHED_FOR(self, j) = 0;
 731                 }
 732         }
 733 }
 734
 735 // sendflags use: 1 = origin, 2 = health/armor, 0x80 = same team (includes health), 4 = entity out of range/culled
 736 float SendEntity_ShowNames(entity to, float sendflags)
 737 {
 738     WriteByte(MSG_ENTITY, ENT_CLIENT_SHOWNAMES);
 739     WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 740
 741     sendflags = sendflags & 127;
 742     if(teams_matter && self.owner.team == to.team)
 743         sendflags |= 128;
 744     else
 745         sendflags &~= 2;
 746     WriteByte(MSG_ENTITY, sendflags);
 747     if(sendflags & 1)
 748     {
 749         WriteShort(MSG_ENTITY, rint(self.origin_x));
 750         WriteShort(MSG_ENTITY, rint(self.origin_y));
 751         WriteShort(MSG_ENTITY, rint(self.origin_z));
 752     }
 753     if(sendflags & 2)
 754     {
 755         WriteByte(MSG_ENTITY, self.health);
 756         WriteByte(MSG_ENTITY, self.armorvalue);
 757     }
 758     return TRUE;
 759 }
 760
 761 const vector SHOWNAMES_ORIGIN_OFFSET = '0 0 48';
 762 void shownames_think()
 763 {
 764     if(self.origin - SHOWNAMES_ORIGIN_OFFSET != self.owner.origin)
 765     {
 766         setorigin(self, self.owner.origin + SHOWNAMES_ORIGIN_OFFSET);
 767         self.SendFlags |= 1;
 768     }
 769     if(self.health != max(0, floor(self.owner.health)) || self.armorvalue != max(0, floor(self.owner.armorvalue)))
 770     {
 771         self.health = max(0, floor(self.owner.health));
 772         self.armorvalue = max(0, floor(self.owner.armorvalue));
 773         self.SendFlags |= 2;
 774     }
 775     self.nextthink = time;
 776 }
 777
 778 float shownames_customize()
 779 {
 780     if(self.owner != other) // no need to spam own coordinates
 781     if(vlen(other.origin - self.origin) < autocvar_sv_shownames_cull_distance) // distance cull
 782     if(self.owner.team == other.team || (self.owner.team != other.team && checkpvs(self.origin, other)))
 783         return TRUE;
 784
 785     return FALSE;
 786 }
 787
 788 .float muted; // to be used by prvm_edictset server playernumber muted 1
 789 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 790 // message "": do not say, just test flood control
 791 // return value:
 792 //   1 = accept
 793 //   0 = reject
 794 //  -1 = fake accept
 795 {
 796         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr, privatemsgprefix;
 797         float flood, privatemsgprefixlen;
 798         var .float flood_field;
 799         entity head;
 800         float ret;
 801
 802         if(Ban_MaybeEnforceBan(source))
 803                 return 0;
 804
 805         if(!teamsay && !privatesay)
 806                 if(substring(msgin, 0, 1) == " ")
 807                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 808
 809         msgin = formatmessage(msgin);
 810
 811         if(source.classname != "player")
 812                 colorstr = "^0"; // black for spectators
 813         else if(teams_matter)
 814                 colorstr = Team_ColorCode(source.team);
 815         else
 816                 teamsay = FALSE;
 817
 818         if(intermission_running)
 819                 teamsay = FALSE;
 820
 821         if(msgin != "")
 822                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 823
 824         /*
 825          * using bprint solves this... me stupid
 826         // how can we prevent the message from appearing in a listen server?
 827         // for now, just give "say" back and only handle say_team
 828         if(!teamsay)
 829         {
 830                 clientcommand(self, strcat("say ", msgin));
 831                 return;
 832         }
 833         */
 834
 835         if(autocvar_g_chat_teamcolors)
 836                 namestr = playername(source);
 837         else
 838                 namestr = source.netname;
 839
 840         if(msgin != "")
 841         {
 842                 if(privatesay)
 843                 {
 844                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 845                         privatemsgprefixlen = strlen(msgstr);
 846                         msgstr = strcat(msgstr, msgin);
 847                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 848                         if(autocvar_g_chat_teamcolors)
 849                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 850                         else
 851                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 852                 }
 853                 else if(teamsay)
 854                 {
 855                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 856                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 857                 }
 858                 else
 859                 {
 860                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 861                         cmsgstr = "";
 862                 }
 863                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 864         }
 865         else
 866         {
 867                 msgstr = cmsgstr = "";
 868         }
 869
 870         fullmsgstr = msgstr;
 871         fullcmsgstr = cmsgstr;
 872
 873         // FLOOD CONTROL
 874         flood = 0;
 875         if(floodcontrol)
 876         {
 877                 float flood_spl;
 878                 float flood_burst;
 879                 float flood_lmax;
 880                 float lines;
 881                 if(privatesay)
 882                 {
 883                         flood_spl = autocvar_g_chat_flood_spl_tell;
 884                         flood_burst = autocvar_g_chat_flood_burst_tell;
 885                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 886                         flood_field = floodcontrol_chattell;
 887                 }
 888                 else if(teamsay)
 889                 {
 890                         flood_spl = autocvar_g_chat_flood_spl_team;
 891                         flood_burst = autocvar_g_chat_flood_burst_team;
 892                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 893                         flood_field = floodcontrol_chatteam;
 894                 }
 895                 else
 896                 {
 897                         flood_spl = autocvar_g_chat_flood_spl;
 898                         flood_burst = autocvar_g_chat_flood_burst;
 899                         flood_lmax = autocvar_g_chat_flood_lmax;
 900                         flood_field = floodcontrol_chat;
 901                 }
 902                 flood_burst = max(0, flood_burst - 1);
 903                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 904
 905                 // do flood control for the default line size
 906                 if(msgstr != "")
 907                 {
 908                         getWrappedLine_remaining = msgstr;
 909                         msgstr = "";
 910                         lines = 0;
 911                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 912                         {
 913                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 914                                 ++lines;
 915                         }
 916                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 917
 918                         if(getWrappedLine_remaining != "")
 919                         {
 920                                 msgstr = strcat(msgstr, "\n");
 921                                 flood = 2;
 922                         }
 923
 924                         if(time >= source.flood_field)
 925                         {
 926                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 927                         }
 928                         else
 929                         {
 930                                 flood = 1;
 931                                 msgstr = fullmsgstr;
 932                         }
 933                 }
 934                 else
 935                 {
 936                         if(time >= source.flood_field)
 937                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 938                         else
 939                                 flood = 1;
 940                 }
 941
 942                 if (timeoutStatus == 2) //when game is paused, no flood protection
 943                         source.flood_field = flood = 0;
 944         }
 945
 946         if(flood == 2) // cannot happen for empty msgstr
 947         {
 948                 if(autocvar_g_chat_flood_notify_flooder)
 949                 {
 950                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 951                         sourcecmsgstr = "";
 952                 }
 953                 else
 954                 {
 955                         sourcemsgstr = fullmsgstr;
 956                         sourcecmsgstr = fullcmsgstr;
 957                 }
 958                 cmsgstr = "";
 959         }
 960         else
 961         {
 962                 sourcemsgstr = msgstr;
 963                 sourcecmsgstr = cmsgstr;
 964         }
 965
 966         if(!privatesay)
 967         if(source.classname != "player")
 968         {
 969                 if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !inWarmupStage))
 970                         teamsay = -1; // spectators
 971         }
 972
 973         if(flood)
 974                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 975
 976         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 977         if(privatesay)
 978                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 979
 980         if(source.muted)
 981         {
 982                 // always fake the message
 983                 ret = -1;
 984         }
 985         else if(flood == 1)
 986         {
 987                 if(autocvar_g_chat_flood_notify_flooder)
 988                 {
 989                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 990                         ret = 0;
 991                 }
 992                 else
 993                         ret = -1;
 994         }
 995         else
 996         {
 997                 ret = 1;
 998         }
 999
1000         if(sourcemsgstr != "" && ret != 0)
1001         {
1002                 if(ret < 0) // fake
1003                 {
1004                         sprint(source, sourcemsgstr);
1005                         if(sourcecmsgstr != "" && !privatesay)
1006                                 centerprint(source, sourcecmsgstr);
1007                 }
1008                 else if(privatesay)
1009                 {
1010                         sprint(source, sourcemsgstr);
1011                         sprint(privatesay, msgstr);
1012                         if(cmsgstr != "")
1013                                 centerprint(privatesay, cmsgstr);
1014                 }
1015                 else if(teamsay > 0)
1016                 {
1017                         sprint(source, sourcemsgstr);
1018                         if(sourcecmsgstr != "")
1019                                 centerprint(source, sourcecmsgstr);
1020                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
1021                                 if(head != source)
1022                                 {
1023                                         sprint(head, msgstr);
1024                                         if(cmsgstr != "")
1025                                                 centerprint(head, cmsgstr);
1026                                 }
1027                 }
1028                 else if(teamsay < 0)
1029                 {
1030                         sprint(source, sourcemsgstr);
1031                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
1032                                 if(head != source)
1033                                         sprint(head, msgstr);
1034                 }
1035                 else if(sourcemsgstr != msgstr)
1036                 {
1037                         sprint(source, sourcemsgstr);
1038                         FOR_EACH_REALCLIENT(head)
1039                                 if(head != source)
1040                                         sprint(head, msgstr);
1041                 }
1042                 else
1043                         bprint(msgstr);
1044         }
1045
1046         return ret;
1047 }
1048
1049 float GetVoiceMessageVoiceType(string type)
1050 {
1051         if(type == "taunt")
1052                 return VOICETYPE_TAUNT;
1053         if(type == "teamshoot")
1054                 return VOICETYPE_LASTATTACKER;
1055         return VOICETYPE_TEAMRADIO;
1056 }
1057
1058 string allvoicesamples;
1059 .string GetVoiceMessageSampleField(string type)
1060 {
1061         GetPlayerSoundSampleField_notFound = 0;
1062         switch(type)
1063         {
1064 #define _VOICEMSG(m) case #m: return playersound_##m;
1065                 ALLVOICEMSGS
1066 #undef _VOICEMSG
1067         }
1068         GetPlayerSoundSampleField_notFound = 1;
1069         return playersound_taunt;
1070 }
1071
1072 .string GetPlayerSoundSampleField(string type)
1073 {
1074         GetPlayerSoundSampleField_notFound = 0;
1075         switch(type)
1076         {
1077 #define _VOICEMSG(m) case #m: return playersound_##m;
1078                 ALLPLAYERSOUNDS
1079 #undef _VOICEMSG
1080         }
1081         GetPlayerSoundSampleField_notFound = 1;
1082         return playersound_taunt;
1083 }
1084
1085 void PrecacheGlobalSound(string samplestring)
1086 {
1087         float n, i;
1088         tokenize_console(samplestring);
1089         n = stof(argv(1));
1090         if(n > 0)
1091         {
1092                 for(i = 1; i <= n; ++i)
1093                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1094         }
1095         else
1096         {
1097                 precache_sound(strcat(argv(0), ".wav"));
1098         }
1099 }
1100
1101 void PrecachePlayerSounds(string f)
1102 {
1103         float fh;
1104         string s;
1105         fh = fopen(f, FILE_READ);
1106         if(fh < 0)
1107                 return;
1108         while((s = fgets(fh)))
1109         {
1110                 if(tokenize_console(s) != 3)
1111                 {
1112                         dprint("Invalid sound info line: ", s, "\n");
1113                         continue;
1114                 }
1115                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1116         }
1117         fclose(fh);
1118
1119         if not(allvoicesamples)
1120         {
1121 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1122                 ALLVOICEMSGS
1123 #undef _VOICEMSG
1124                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1125         }
1126 }
1127
1128 void ClearPlayerSounds()
1129 {
1130 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1131         ALLPLAYERSOUNDS
1132         ALLVOICEMSGS
1133 #undef _VOICEMSG
1134 }
1135
1136 float LoadPlayerSounds(string f, float first)
1137 {
1138         float fh;
1139         string s;
1140         var .string field;
1141         fh = fopen(f, FILE_READ);
1142         if(fh < 0)
1143         {
1144                 dprint("Player sound file not found: ", f, "\n");
1145                 return 0;
1146         }
1147         while((s = fgets(fh)))
1148         {
1149                 if(tokenize_console(s) != 3)
1150                         continue;
1151                 field = GetPlayerSoundSampleField(argv(0));
1152                 if(GetPlayerSoundSampleField_notFound)
1153                         field = GetVoiceMessageSampleField(argv(0));
1154                 if(GetPlayerSoundSampleField_notFound)
1155                         continue;
1156                 if(self.field)
1157                         strunzone(self.field);
1158                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1159         }
1160         fclose(fh);
1161         return 1;
1162 }
1163
1164 .float modelindex_for_playersound;
1165 .float skinindex_for_playersound;
1166 void UpdatePlayerSounds()
1167 {
1168         if(self.modelindex == self.modelindex_for_playersound)
1169         if(self.skinindex == self.skinindex_for_playersound)
1170                 return;
1171         self.modelindex_for_playersound = self.modelindex;
1172         self.skinindex_for_playersound = self.skinindex;
1173         ClearPlayerSounds();
1174         LoadPlayerSounds("sound/player/default.sounds", 1);
1175         if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skinindex, "sounds"), 0))
1176                 LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1177 }
1178
1179 void FakeGlobalSound(string sample, float chan, float voicetype)
1180 {
1181         float n;
1182         float tauntrand;
1183
1184         if(sample == "")
1185                 return;
1186
1187         tokenize_console(sample);
1188         n = stof(argv(1));
1189         if(n > 0)
1190                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1191         else
1192                 sample = strcat(argv(0), ".wav"); // randomization
1193
1194         switch(voicetype)
1195         {
1196                 case VOICETYPE_LASTATTACKER_ONLY:
1197                         break;
1198                 case VOICETYPE_LASTATTACKER:
1199                         if(self.pusher)
1200                         {
1201                                 msg_entity = self;
1202                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1203                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1204                         }
1205                         break;
1206                 case VOICETYPE_TEAMRADIO:
1207                         msg_entity = self;
1208                         if(msg_entity.cvar_cl_voice_directional == 1)
1209                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1210                         else
1211                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1212                         break;
1213                 case VOICETYPE_AUTOTAUNT:
1214                         if(!sv_autotaunt)
1215                                 break;
1216                         if(!sv_taunt)
1217                                 break;
1218                         if(sv_gentle)
1219                                 break;
1220                         tauntrand = random();
1221                         msg_entity = self;
1222                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1223                         {
1224                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1225                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1226                                 else
1227                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1228                         }
1229                         break;
1230                 case VOICETYPE_TAUNT:
1231                         if(self.classname == "player")
1232                                 if(self.deadflag == DEAD_NO)
1233                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1234                         if(!sv_taunt)
1235                                 break;
1236                         if(sv_gentle)
1237                                 break;
1238                         msg_entity = self;
1239                         if (msg_entity.cvar_cl_voice_directional >= 1)
1240                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1241                         else
1242                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1243                         break;
1244                 case VOICETYPE_PLAYERSOUND:
1245                         msg_entity = self;
1246                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1247                         break;
1248                 default:
1249                         backtrace("Invalid voice type!");
1250                         break;
1251         }
1252 }
1253
1254 void GlobalSound(string sample, float chan, float voicetype)
1255 {
1256         float n;
1257         float tauntrand;
1258
1259         if(sample == "")
1260                 return;
1261
1262         tokenize_console(sample);
1263         n = stof(argv(1));
1264         if(n > 0)
1265                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1266         else
1267                 sample = strcat(argv(0), ".wav"); // randomization
1268
1269         switch(voicetype)
1270         {
1271                 case VOICETYPE_LASTATTACKER_ONLY:
1272                         if(self.pusher)
1273                         {
1274                                 msg_entity = self.pusher;
1275                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1276                                 {
1277                                         if(msg_entity.cvar_cl_voice_directional == 1)
1278                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1279                                         else
1280                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1281                                 }
1282                         }
1283                         break;
1284                 case VOICETYPE_LASTATTACKER:
1285                         if(self.pusher)
1286                         {
1287                                 msg_entity = self.pusher;
1288                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1289                                 {
1290                                         if(msg_entity.cvar_cl_voice_directional == 1)
1291                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1292                                         else
1293                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1294                                 }
1295                                 msg_entity = self;
1296                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1297                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1298                         }
1299                         break;
1300                 case VOICETYPE_TEAMRADIO:
1301                         FOR_EACH_REALCLIENT(msg_entity)
1302                                 if(!teams_matter || msg_entity.team == self.team)
1303                                 {
1304                                         if(msg_entity.cvar_cl_voice_directional == 1)
1305                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1306                                         else
1307                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1308                                 }
1309                         break;
1310                 case VOICETYPE_AUTOTAUNT:
1311                         if(!sv_autotaunt)
1312                                 break;
1313                         if(!sv_taunt)
1314                                 break;
1315                         if(sv_gentle)
1316                                 break;
1317                         tauntrand = random();
1318                         FOR_EACH_REALCLIENT(msg_entity)
1319                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1320                                 {
1321                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1322                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1323                                         else
1324                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1325                                 }
1326                         break;
1327                 case VOICETYPE_TAUNT:
1328                         if(self.classname == "player")
1329                                 if(self.deadflag == DEAD_NO)
1330                                         setanim(self, self.anim_taunt, FALSE, TRUE, TRUE);
1331                         if(!sv_taunt)
1332                                 break;
1333                         if(sv_gentle)
1334                                 break;
1335                         FOR_EACH_REALCLIENT(msg_entity)
1336                         {
1337                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1338                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1339                                 else
1340                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1341                         }
1342                         break;
1343                 case VOICETYPE_PLAYERSOUND:
1344                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1345                         break;
1346                 default:
1347                         backtrace("Invalid voice type!");
1348                         break;
1349         }
1350 }
1351
1352 void PlayerSound(.string samplefield, float chan, float voicetype)
1353 {
1354         GlobalSound(self.samplefield, chan, voicetype);
1355 }
1356
1357 void VoiceMessage(string type, string msg)
1358 {
1359         var .string sample;
1360         float voicetype, ownteam;
1361         float flood;
1362         sample = GetVoiceMessageSampleField(type);
1363
1364         if(GetPlayerSoundSampleField_notFound)
1365         {
1366                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1367                 return;
1368         }
1369
1370         voicetype = GetVoiceMessageVoiceType(type);
1371         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1372
1373         flood = Say(self, ownteam, world, msg, 1);
1374
1375         if (flood > 0)
1376                 GlobalSound(self.sample, CHAN_VOICE, voicetype);
1377         else if (flood < 0)
1378                 FakeGlobalSound(self.sample, CHAN_VOICE, voicetype);
1379 }
1380
1381 void MoveToTeam(entity client, float team_colour, float type, float show_message)
1382 {
1383 //      show_message
1384 //      0 (00) automove centerprint, admin message
1385 //      1 (01) automove centerprint, no admin message
1386 //      2 (10) no centerprint, admin message
1387 //      3 (11) no centerprint, no admin message
1388
1389         float lockteams_backup;
1390
1391         lockteams_backup = lockteams;  // backup any team lock
1392
1393         lockteams = 0;  // disable locked teams
1394
1395         TeamchangeFrags(client);  // move the players frags
1396         SetPlayerColors(client, team_colour - 1);  // set the players colour
1397         Damage(client, client, client, 100000, ((show_message & 2) ? DEATH_QUIET : DEATH_AUTOTEAMCHANGE), client.origin, '0 0 0');  // kill the player
1398
1399         lockteams = lockteams_backup;  // restore the team lock
1400
1401         LogTeamchange(client.playerid, client.team, type);
1402
1403         if not(show_message & 1) // admin message
1404                 sprint(client, strcat("\{1}\{13}^3", admin_name(), "^7: You have been moved to the ", Team_ColorNameLowerCase(team_colour), " team\n"));  // send a chat message
1405
1406         bprint(strcat(client.netname, " joined the ", ColoredTeamName(client.team), "\n"));
1407 }