qcsrc/server/cl_player.qc

   1 .entity accuracy;
   2 .float accuracy_frags[WEP_MAXCOUNT];
   3
   4 float weaponstats_buffer;
   5
   6 void WeaponStats_Init()
   7 {
   8         if(autocvar_sv_weaponstats_file != "")
   9                 weaponstats_buffer = buf_create();
  10         else
  11                 weaponstats_buffer = -1;
  12 }
  13
  14 #define WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot) (((vwep) + (awep) * (WEP_LAST - WEP_FIRST + 1) - (WEP_FIRST + WEP_FIRST * (WEP_LAST - WEP_FIRST + 1))) * 4 + (abot) * 2 + (vbot))
  15
  16 void WeaponStats_ready(entity fh, entity pass, float status)
  17 {
  18         float i, j, n, ibot, jbot, idx;
  19         vector v;
  20         string prefix, s;
  21         switch(status)
  22         {
  23                 case URL_READY_CANWRITE:
  24                         // we can write
  25                         prefix = strcat(autocvar_hostname, "\t", GetGametype(), "_", GetMapname(), "\t");
  26                         url_fputs(fh, "#begin statsfile\n");
  27                         url_fputs(fh, strcat("#date ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n"));
  28 #ifdef WATERMARK
  29                         url_fputs(fh, strcat("#version ", WATERMARK, "\n"));
  30 #endif
  31                         url_fputs(fh, strcat("#config ", ftos(crc16(FALSE, cvar_purechanges)), "\n"));
  32                         url_fputs(fh, strcat("#cvar_purechanges ", ftos(cvar_purechanges_count), "\n"));
  33                         n = tokenizebyseparator(cvar_purechanges, "\n");
  34                         for(i = 0; i < n; ++i)
  35                                 url_fputs(fh, strcat("#cvar_purechange ", argv(i), "\n"));
  36                         for(i = WEP_FIRST; i <= WEP_LAST; ++i) for(ibot = 0; ibot <= 1; ++ibot)
  37                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j) for(jbot = 0; jbot <= 1; ++jbot)
  38                                 {
  39                                         idx = WEAPONSTATS_GETINDEX(i, ibot, j, jbot);
  40                                         v = stov(bufstr_get(weaponstats_buffer, idx));
  41                                         if(v != '0 0 0')
  42                                         {
  43                                                 //vector is: kills hits damage
  44                                                 url_fputs(fh, sprintf("%s%d %d\t%d %d\t", prefix, i, ibot, j, jbot));
  45                                                 url_fputs(fh, sprintf("%d %d %g\n", v_x, v_y, v_z));
  46                                         }
  47                                 }
  48                         url_fputs(fh, "#end\n\n");
  49                         url_fclose(fh);
  50                         break;
  51                 case URL_READY_CANREAD:
  52                         // url_fclose is processing, we got a response for writing the data
  53                         // this must come from HTTP
  54                         print("Got response from weapon stats server:\n");
  55                         while((s = url_fgets(fh)))
  56                                 print("  ", s, "\n");
  57                         print("End of response.\n");
  58                         url_fclose(fh);
  59                         break;
  60                 case URL_READY_CLOSED:
  61                         // url_fclose has finished
  62                         print("Weapon stats written\n");
  63                         buf_del(weaponstats_buffer);
  64                         weaponstats_buffer = -1;
  65                         break;
  66                 case URL_READY_ERROR:
  67                 default:
  68                         print("Weapon stats writing failed: ", ftos(status), "\n");
  69                         buf_del(weaponstats_buffer);
  70                         weaponstats_buffer = -1;
  71                         break;
  72         }
  73 }
  74
  75 void WeaponStats_Shutdown()
  76 {
  77         if(weaponstats_buffer < 0)
  78                 return;
  79         if(autocvar_sv_weaponstats_file != "")
  80         {
  81                 url_multi_fopen(autocvar_sv_weaponstats_file, FILE_APPEND, WeaponStats_ready, world);
  82         }
  83         else
  84         {
  85                 buf_del(weaponstats_buffer);
  86                 weaponstats_buffer = -1;
  87         }
  88 }
  89
  90 void WeaponStats_LogItem(float awep, float abot, float vwep, float vbot, vector item)
  91 {
  92         float idx;
  93         if(weaponstats_buffer < 0)
  94                 return;
  95         if(awep < WEP_FIRST || vwep < WEP_FIRST)
  96                 return;
  97         if(awep > WEP_LAST || vwep > WEP_LAST)
  98                 return;
  99         idx = WEAPONSTATS_GETINDEX(awep,abot,vwep,vbot);
 100         bufstr_set(weaponstats_buffer, idx, vtos(stov(bufstr_get(weaponstats_buffer, idx)) + item));
 101 }
 102 void WeaponStats_LogDamage(float awep, float abot, float vwep, float vbot, float damage)
 103 {
 104         if(damage < 0)
 105                 error("negative damage?");
 106         WeaponStats_LogItem(awep, abot, vwep, vbot, '0 0 1' * damage + '0 1 0');
 107 }
 108 void WeaponStats_LogKill(float awep, float abot, float vwep, float vbot)
 109 {
 110         WeaponStats_LogItem(awep, abot, vwep, vbot, '1 0 0');
 111 }
 112
 113 // changes by LordHavoc on 03/29/04 and 03/30/04 at Vermeulen's request
 114 // merged player_run and player_stand to player_anim
 115 // added death animations to player_anim
 116 // can now spawn thrown weapons from anywhere, not just from players
 117 // thrown weapons now fade out after 20 seconds
 118 // created PlayerGib function
 119 // PlayerDie no longer uses hitloc or damage
 120 // PlayerDie now supports dying animations as well as gibbing
 121 // cleaned up PlayerDie a lot
 122 // added CopyBody
 123
 124 .entity pusher;
 125 .float pushltime;
 126 .float istypefrag;
 127
 128 .float CopyBody_nextthink;
 129 .void(void) CopyBody_think;
 130 void CopyBody_Think(void)
 131 {
 132         if(self.CopyBody_nextthink && time > self.CopyBody_nextthink)
 133         {
 134                 self.CopyBody_think();
 135                 if(wasfreed(self))
 136                         return;
 137                 self.CopyBody_nextthink = self.nextthink;
 138                 self.CopyBody_think = self.think;
 139                 self.think = CopyBody_Think;
 140         }
 141         CSQCMODEL_AUTOUPDATE();
 142         self.nextthink = time;
 143 }
 144 void CopyBody(float keepvelocity)
 145 {
 146         entity oldself;
 147         if (self.effects & EF_NODRAW)
 148                 return;
 149         oldself = self;
 150         self = spawn();
 151         self.enemy = oldself;
 152         self.lip = oldself.lip;
 153         self.colormap = oldself.colormap;
 154         self.iscreature = oldself.iscreature;
 155         self.teleportable = oldself.teleportable;
 156         self.damagedbycontents = oldself.damagedbycontents;
 157         self.angles = oldself.angles;
 158         self.avelocity = oldself.avelocity;
 159         self.classname = "body";
 160         self.damageforcescale = oldself.damageforcescale;
 161         self.effects = oldself.effects;
 162         self.glowmod = oldself.glowmod;
 163         self.event_damage = oldself.event_damage;
 164         self.anim_state = oldself.anim_state;
 165         self.anim_time = oldself.anim_time;
 166         self.anim_lower_action = oldself.anim_lower_action;
 167         self.anim_lower_time = oldself.anim_lower_time;
 168         self.anim_upper_action = oldself.anim_upper_action;
 169         self.anim_upper_time = oldself.anim_upper_time;
 170         self.anim_implicit_state = oldself.anim_implicit_state;
 171         self.anim_implicit_time = oldself.anim_implicit_time;
 172         self.anim_lower_implicit_action = oldself.anim_lower_implicit_action;
 173         self.anim_lower_implicit_time = oldself.anim_lower_implicit_time;
 174         self.anim_upper_implicit_action = oldself.anim_upper_implicit_action;
 175         self.anim_upper_implicit_time = oldself.anim_upper_implicit_time;
 176         self.dphitcontentsmask = oldself.dphitcontentsmask;
 177         self.death_time = oldself.death_time;
 178         self.pain_finished = oldself.pain_finished;
 179         self.health = oldself.health;
 180         self.armorvalue = oldself.armorvalue;
 181         self.armortype = oldself.armortype;
 182         self.model = oldself.model;
 183         self.modelindex = oldself.modelindex;
 184         self.skin = oldself.skin;
 185         self.species = oldself.species;
 186         self.movetype = oldself.movetype;
 187         self.solid = oldself.solid;
 188         self.ballistics_density = oldself.ballistics_density;
 189         self.takedamage = oldself.takedamage;
 190         self.customizeentityforclient = oldself.customizeentityforclient;
 191         self.uncustomizeentityforclient = oldself.uncustomizeentityforclient;
 192         self.uncustomizeentityforclient_set = oldself.uncustomizeentityforclient_set;
 193         if (keepvelocity == 1)
 194                 self.velocity = oldself.velocity;
 195         self.oldvelocity = self.velocity;
 196         self.alpha = oldself.alpha;
 197         self.fade_time = oldself.fade_time;
 198         self.fade_rate = oldself.fade_rate;
 199         //self.weapon = oldself.weapon;
 200         setorigin(self, oldself.origin);
 201         setsize(self, oldself.mins, oldself.maxs);
 202         self.prevorigin = oldself.origin;
 203         self.reset = SUB_Remove;
 204
 205         Drag_MoveDrag(oldself, self);
 206
 207         if(self.colormap <= maxclients && self.colormap > 0)
 208                 self.colormap = 1024 + oldself.clientcolors;
 209
 210         CSQCMODEL_AUTOINIT();
 211         self.CopyBody_nextthink = oldself.nextthink;
 212         self.CopyBody_think = oldself.think;
 213         self.nextthink = time;
 214         self.think = CopyBody_Think;
 215         // "bake" the current animation frame for clones (they don't get clientside animation)
 216         animdecide_setframes(self, FALSE, frame, frame1time, frame2, frame2time);
 217
 218         self = oldself;
 219 }
 220
 221 float player_getspecies()
 222 {
 223         float s;
 224         get_model_parameters(self.model, self.skin);
 225         s = get_model_parameters_species;
 226         get_model_parameters(string_null, 0);
 227         if(s < 0)
 228                 return SPECIES_HUMAN;
 229         return s;
 230 }
 231
 232 void player_setupanimsformodel()
 233 {
 234         // load animation info
 235         animdecide_init(self);
 236         animdecide_setstate(self, 0, FALSE);
 237 }
 238
 239 void player_anim (void)
 240 {
 241         float deadbits = (self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
 242         if(self.deadflag && !deadbits)
 243                 if(random() < 0.5)
 244                         deadbits = ANIMSTATE_DEAD1;
 245                 else
 246                         deadbits = ANIMSTATE_DEAD2;
 247         float animbits = deadbits;
 248         if(self.freezetag_frozen)
 249                 animbits |= ANIMSTATE_FROZEN;
 250         if(self.crouch)
 251                 animbits |= ANIMSTATE_DUCK;
 252         animdecide_setstate(self, animbits, FALSE);
 253         animdecide_setimplicitstate(self, (self.flags & FL_ONGROUND));
 254
 255         if (self.weaponentity)
 256         {
 257                 updateanim(self.weaponentity);
 258                 if (!self.weaponentity.animstate_override)
 259                         setanim(self.weaponentity, self.weaponentity.anim_idle, TRUE, FALSE, FALSE);
 260         }
 261 }
 262
 263 void SpawnThrownWeapon (vector org, float w)
 264 {
 265         if(g_minstagib)
 266         if(self.ammo_cells <= 0)
 267                 return;
 268
 269         if(g_pinata)
 270         {
 271                 float j;
 272                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 273                 {
 274                         if(WEPSET_CONTAINS_EW(self, j))
 275                                 if(W_IsWeaponThrowable(j))
 276                                         W_ThrowNewWeapon(self, j, FALSE, org, randomvec() * 175 + '0 0 325');
 277                 }
 278         }
 279         else
 280         {
 281                 if(WEPSET_CONTAINS_EW(self, self.weapon))
 282                         if(W_IsWeaponThrowable(self.weapon))
 283                                 W_ThrowNewWeapon(self, self.weapon, FALSE, org, randomvec() * 125 + '0 0 200');
 284         }
 285 }
 286
 287 void PlayerCorpseDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 288 {
 289         float take, save;
 290         vector v;
 291         Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 292
 293         // damage resistance (ignore most of the damage from a bullet or similar)
 294         damage = max(damage - 5, 1);
 295
 296         v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 297         take = v_x;
 298         save = v_y;
 299
 300         if(sound_allowed(MSG_BROADCAST, attacker))
 301         {
 302                 if (save > 10)
 303                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 304                 else if (take > 30)
 305                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 306                 else if (take > 10)
 307                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM);
 308         }
 309
 310         if (take > 50)
 311                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 312         if (take > 100)
 313                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 314
 315         if (!(self.flags & FL_GODMODE))
 316         {
 317                 self.armorvalue = self.armorvalue - save;
 318                 self.health = self.health - take;
 319                 // pause regeneration for 5 seconds
 320                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 321         }
 322         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 323         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 324         self.dmg_inflictor = inflictor;
 325
 326         if (self.health <= -autocvar_sv_gibhealth && self.alpha >= 0)
 327         {
 328                 // don't use any animations as a gib
 329                 self.frame = 0;
 330                 // view just above the floor
 331                 self.view_ofs = '0 0 4';
 332
 333                 Violence_GibSplash(self, 1, 1, attacker);
 334                 self.alpha = -1;
 335                 self.solid = SOLID_NOT; // restore later
 336                 self.takedamage = DAMAGE_NO; // restore later
 337                 self.damagedbycontents = FALSE;
 338         }
 339 }
 340
 341 void ClientKill_Now_TeamChange();
 342
 343 void PlayerDamage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 344 {
 345         float take, save, waves, sdelay, dh, da, j;
 346         vector v;
 347         float valid_damage_for_weaponstats;
 348         float excess;
 349
 350         dh = max(self.health, 0);
 351         da = max(self.armorvalue, 0);
 352
 353         if(!DEATH_ISSPECIAL(deathtype))
 354         {
 355                 damage *= sqrt(bound(1.0, self.cvar_cl_handicap, 100.0));
 356                 if(self != attacker)
 357                         damage /= sqrt(bound(1.0, attacker.cvar_cl_handicap, 100.0));
 358         }
 359
 360         if(DEATH_ISWEAPON(deathtype, WEP_TUBA))
 361         {
 362                 // tuba causes blood to come out of the ears
 363                 vector ear1, ear2;
 364                 vector d;
 365                 float f;
 366                 ear1 = self.origin;
 367                 ear1_z += 0.125 * self.view_ofs_z + 0.875 * self.maxs_z; // 7/8
 368                 ear2 = ear1;
 369                 makevectors(self.angles);
 370                 ear1 += v_right * -10;
 371                 ear2 += v_right * +10;
 372                 d = inflictor.origin - self.origin;
 373                 f = (d * v_right) / vlen(d); // this is cos of angle of d and v_right!
 374                 force = v_right * vlen(force);
 375                 Violence_GibSplash_At(ear1, force * -1, 2, bound(0, damage, 25) / 2 * (0.5 - 0.5 * f), self, attacker);
 376                 Violence_GibSplash_At(ear2, force,      2, bound(0, damage, 25) / 2 * (0.5 + 0.5 * f), self, attacker);
 377                 if(f > 0)
 378                 {
 379                         hitloc = ear1;
 380                         force = force * -1;
 381                 }
 382                 else
 383                 {
 384                         hitloc = ear2;
 385                         // force is already good
 386                 }
 387         }
 388         else
 389                 Violence_GibSplash_At(hitloc, force, 2, bound(0, damage, 200) / 16, self, attacker);
 390
 391         if (!g_minstagib)
 392         {
 393                 v = healtharmor_applydamage(self.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 394                 take = v_x;
 395                 save = v_y;
 396         }
 397         else
 398         {
 399                 save = 0;
 400                 take = damage;
 401         }
 402
 403         if(attacker == self)
 404         {
 405                 // don't reset pushltime for self damage as it may be an attempt to
 406                 // escape a lava pit or similar
 407                 //self.pushltime = 0;
 408                 self.istypefrag = 0;
 409         }
 410         else if(attacker.classname == "player")
 411         {
 412                 self.pusher = attacker;
 413                 self.pushltime = time + autocvar_g_maxpushtime;
 414                 self.istypefrag = self.BUTTON_CHAT;
 415         }
 416         else if(time < self.pushltime)
 417         {
 418                 attacker = self.pusher;
 419                 self.pushltime = max(self.pushltime, time + 0.6);
 420         }
 421         else
 422         {
 423                 self.pushltime = 0;
 424                 self.istypefrag = 0;
 425         }
 426
 427         frag_inflictor = inflictor;
 428         frag_attacker = attacker;
 429         frag_target = self;
 430         damage_take = take;
 431         damage_save = save;
 432         damage_force = force;
 433         MUTATOR_CALLHOOK(PlayerDamage_SplitHealthArmor);
 434         take = bound(0, damage_take, self.health);
 435         save = bound(0, damage_save, self.armorvalue);
 436         excess = max(0, damage - take - save);
 437
 438         if(sound_allowed(MSG_BROADCAST, attacker))
 439         {
 440                 if (save > 10)
 441                         sound (self, CH_SHOTS, "misc/armorimpact.wav", VOL_BASE, ATTN_NORM);
 442                 else if (take > 30)
 443                         sound (self, CH_SHOTS, "misc/bodyimpact2.wav", VOL_BASE, ATTN_NORM);
 444                 else if (take > 10)
 445                         sound (self, CH_SHOTS, "misc/bodyimpact1.wav", VOL_BASE, ATTN_NORM); // FIXME possibly remove them?
 446         }
 447
 448         if (take > 50)
 449                 Violence_GibSplash_At(hitloc, force * -0.1, 3, 1, self, attacker);
 450         if (take > 100)
 451                 Violence_GibSplash_At(hitloc, force * -0.2, 3, 1, self, attacker);
 452
 453         if (time >= self.spawnshieldtime)
 454         {
 455                 if (!(self.flags & FL_GODMODE))
 456                 {
 457                         self.armorvalue = self.armorvalue - save;
 458                         self.health = self.health - take;
 459                         // pause regeneration for 5 seconds
 460                         if(take)
 461                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_pause_health_regen);
 462
 463                         if (time > self.pain_finished)          //Don't switch pain sequences like crazy
 464                         {
 465                                 self.pain_finished = time + 0.5;        //Supajoe
 466
 467                                 if(autocvar_sv_gentle < 1) {
 468                                         if(self.classname != "body") // pain anim is BORKED on our ZYMs, FIXME remove this once we have good models
 469                                         {
 470                                                 if (!self.animstate_override)
 471                                                 {
 472                                                         if (random() > 0.5)
 473                                                                 animdecide_setaction(self, ANIMACTION_PAIN1, TRUE);
 474                                                         else
 475                                                                 animdecide_setaction(self, ANIMACTION_PAIN2, TRUE);
 476                                                 }
 477                                         }
 478
 479                                         if(sound_allowed(MSG_BROADCAST, attacker))
 480                                         if(!DEATH_ISWEAPON(deathtype, WEP_LASER) || attacker != self || self.health < 2 * autocvar_g_balance_laser_primary_damage * autocvar_g_balance_selfdamagepercent + 1)
 481                                         if(self.health > 1)
 482                                         // exclude pain sounds for laserjumps as long as you aren't REALLY low on health and would die of the next two
 483                                         {
 484                                                 if(deathtype == DEATH_FALL)
 485                                                         PlayerSound(playersound_fall, CH_PAIN, VOICETYPE_PLAYERSOUND);
 486                                                 else if(self.health > 75) // TODO make a "gentle" version?
 487                                                         PlayerSound(playersound_pain100, CH_PAIN, VOICETYPE_PLAYERSOUND);
 488                                                 else if(self.health > 50)
 489                                                         PlayerSound(playersound_pain75, CH_PAIN, VOICETYPE_PLAYERSOUND);
 490                                                 else if(self.health > 25)
 491                                                         PlayerSound(playersound_pain50, CH_PAIN, VOICETYPE_PLAYERSOUND);
 492                                                 else
 493                                                         PlayerSound(playersound_pain25, CH_PAIN, VOICETYPE_PLAYERSOUND);
 494                                         }
 495                                 }
 496
 497                                 // throw off bot aim temporarily
 498                                 float shake;
 499                                 shake = damage * 5 / (bound(0,skill,100) + 1);
 500                                 self.v_angle_x = self.v_angle_x + (random() * 2 - 1) * shake;
 501                                 self.v_angle_y = self.v_angle_y + (random() * 2 - 1) * shake;
 502                         }
 503                 }
 504                 else
 505                         self.max_armorvalue += (save + take);
 506         }
 507         self.dmg_save = self.dmg_save + save;//max(save - 10, 0);
 508         self.dmg_take = self.dmg_take + take;//max(take - 10, 0);
 509         self.dmg_inflictor = inflictor;
 510
 511         if(g_ca && self != attacker && attacker.classname == "player")
 512                 PlayerScore_Add(attacker, SP_SCORE, (damage - excess) * autocvar_g_ca_damage2score_multiplier);
 513
 514         float abot, vbot, awep;
 515         abot = (clienttype(attacker) == CLIENTTYPE_BOT);
 516         vbot = (clienttype(self) == CLIENTTYPE_BOT);
 517
 518         valid_damage_for_weaponstats = 0;
 519         awep = 0;
 520
 521         if(vbot || clienttype(self) == CLIENTTYPE_REAL)
 522         if(abot || clienttype(attacker) == CLIENTTYPE_REAL)
 523         if(attacker && self != attacker)
 524         if(IsDifferentTeam(self, attacker))
 525         {
 526                 if(DEATH_ISSPECIAL(deathtype))
 527                         awep = attacker.weapon;
 528                 else
 529                         awep = DEATH_WEAPONOF(deathtype);
 530                 valid_damage_for_weaponstats = 1;
 531         }
 532
 533         if(valid_damage_for_weaponstats)
 534         {
 535                 dh = dh - max(self.health, 0);
 536                 da = da - max(self.armorvalue, 0);
 537                 WeaponStats_LogDamage(awep, abot, self.weapon, vbot, dh + da);
 538         }
 539
 540         if (self.health < 1)
 541         {
 542                 float defer_ClientKill_Now_TeamChange;
 543                 defer_ClientKill_Now_TeamChange = FALSE;
 544
 545                 if(self.alivetime)
 546                 {
 547                         PlayerStats_Event(self, PLAYERSTATS_ALIVETIME, time - self.alivetime);
 548                         self.alivetime = 0;
 549                 }
 550
 551                 if(valid_damage_for_weaponstats)
 552                         WeaponStats_LogKill(awep, abot, self.weapon, vbot);
 553
 554                 if(autocvar_sv_gentle < 1) // TODO make a "gentle" version?
 555                 if(sound_allowed(MSG_BROADCAST, attacker))
 556                 {
 557                         if(deathtype == DEATH_DROWN)
 558                                 PlayerSound(playersound_drown, CH_PAIN, VOICETYPE_PLAYERSOUND);
 559                         else
 560                                 PlayerSound(playersound_death, CH_PAIN, VOICETYPE_PLAYERSOUND);
 561                 }
 562
 563                 // get rid of kill indicator
 564                 if(self.killindicator)
 565                 {
 566                         remove(self.killindicator);
 567                         self.killindicator = world;
 568                         if(self.killindicator_teamchange)
 569                                 defer_ClientKill_Now_TeamChange = TRUE;
 570
 571                         if(self.classname == "body")
 572                         if(deathtype == DEATH_KILL)
 573                         {
 574                                 // for the lemmings fans, a small harmless explosion
 575                                 pointparticles(particleeffectnum("rocket_explode"), self.origin, '0 0 0', 1);
 576                         }
 577                 }
 578
 579                 // print an obituary message
 580                 Obituary (attacker, inflictor, self, deathtype);
 581                 race_PreDie();
 582
 583         // increment frag counter for used weapon type
 584         float w;
 585         w = DEATH_WEAPONOF(deathtype);
 586         if(WEP_VALID(w))
 587         if(accuracy_isgooddamage(attacker, self))
 588         attacker.accuracy.(accuracy_frags[w-1]) += 1;
 589
 590                 frag_attacker = attacker;
 591                 frag_inflictor = inflictor;
 592                 frag_target = self;
 593                 frag_deathtype = deathtype;
 594                 MUTATOR_CALLHOOK(PlayerDies);
 595
 596                 weapon_action(self.weapon, WR_PLAYERDEATH);
 597
 598                 RemoveGrapplingHook(self);
 599
 600                 Portal_ClearAllLater(self);
 601
 602                 if(clienttype(self) == CLIENTTYPE_REAL)
 603                 {
 604                         self.fixangle = TRUE;
 605                         //msg_entity = self;
 606                         //WriteByte (MSG_ONE, SVC_SETANGLE);
 607                         //WriteAngle (MSG_ONE, self.v_angle_x);
 608                         //WriteAngle (MSG_ONE, self.v_angle_y);
 609                         //WriteAngle (MSG_ONE, 80);
 610                 }
 611
 612                 if(defer_ClientKill_Now_TeamChange)
 613                         ClientKill_Now_TeamChange(); // can turn player into spectator
 614
 615                 // player could have been miraculously resuscitated ;)
 616                 // e.g. players in freezetag get frozen, they don't really die
 617                 if(self.health >= 1 || self.classname != "player")
 618                         return;
 619
 620                 // when we get here, player actually dies
 621
 622                 // clear waypoints
 623                 WaypointSprite_PlayerDead();
 624                 // throw a weapon
 625                 SpawnThrownWeapon (self.origin + (self.mins + self.maxs) * 0.5, self.switchweapon);
 626
 627                 // become fully visible
 628                 self.alpha = default_player_alpha;
 629                 // make the corpse upright (not tilted)
 630                 self.angles_x = 0;
 631                 self.angles_z = 0;
 632                 // don't spin
 633                 self.avelocity = '0 0 0';
 634                 // view from the floor
 635                 self.view_ofs = '0 0 -8';
 636                 // toss the corpse
 637                 self.movetype = MOVETYPE_TOSS;
 638                 // shootable corpse
 639                 self.solid = SOLID_CORPSE;
 640                 self.ballistics_density = autocvar_g_ballistics_density_corpse;
 641                 // don't stick to the floor
 642                 self.flags &~= FL_ONGROUND;
 643                 // dying animation
 644                 self.deadflag = DEAD_DYING;
 645                 // when to allow respawn
 646                 sdelay = 0;
 647                 waves = 0;
 648                 sdelay = cvar(strcat("g_", GetGametype(), "_respawn_delay"));
 649                 if(!sdelay)
 650                 {
 651                         if(g_cts)
 652                                 sdelay = 0; // no respawn delay in CTS
 653                         else
 654                                 sdelay = autocvar_g_respawn_delay;
 655                 }
 656                 waves = cvar(strcat("g_", GetGametype(), "_respawn_waves"));
 657                 if(!waves)
 658                         waves = autocvar_g_respawn_waves;
 659                 if(waves)
 660                         self.respawn_time = ceil((time + sdelay) / waves) * waves;
 661                 else
 662                         self.respawn_time = time + sdelay;
 663                 if((sdelay + waves >= 5.0) && (self.respawn_time - time > 1.75))
 664                         self.respawn_countdown = 10; // first number to count down from is 10
 665                 else
 666                         self.respawn_countdown = -1; // do not count down
 667
 668                 if(g_lms || g_cts || autocvar_g_forced_respawn)
 669                         self.respawn_flags = self.respawn_flags | RESPAWN_FORCE;
 670
 671                 self.death_time = time;
 672                 if (random() < 0.5)
 673                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD1, TRUE);
 674                 else
 675                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DEAD2, TRUE);
 676                 if (self.maxs_z > 5)
 677                 {
 678                         self.maxs_z = 5;
 679                         setsize(self, self.mins, self.maxs);
 680                 }
 681                 // set damage function to corpse damage
 682                 self.event_damage = PlayerCorpseDamage;
 683                 // call the corpse damage function just in case it wants to gib
 684                 self.event_damage(inflictor, attacker, excess, deathtype, hitloc, force);
 685                 // set up to fade out later
 686                 SUB_SetFade (self, time + 6 + random (), 1);
 687
 688                 if(autocvar_sv_gentle > 0 || autocvar_ekg) {
 689                         // remove corpse
 690                         PlayerCorpseDamage (inflictor, attacker, autocvar_sv_gibhealth+1.0, deathtype, hitloc, force);
 691                 }
 692
 693                 // reset fields the weapons may use just in case
 694                 for (j = WEP_FIRST; j <= WEP_LAST; ++j)
 695                 {
 696                         weapon_action(j, WR_RESETPLAYER);
 697                         ATTACK_FINISHED_FOR(self, j) = 0;
 698                 }
 699         }
 700 }
 701
 702 .float muted; // to be used by prvm_edictset server playernumber muted 1
 703 float Say(entity source, float teamsay, entity privatesay, string msgin, float floodcontrol)
 704 // message "": do not say, just test flood control
 705 // return value:
 706 //   1 = accept
 707 //   0 = reject
 708 //  -1 = fake accept
 709 {
 710         string msgstr, colorstr, cmsgstr, namestr, fullmsgstr, sourcemsgstr, fullcmsgstr, sourcecmsgstr;
 711         float flood;
 712         var .float flood_field;
 713         entity head;
 714         float ret;
 715         string privatemsgprefix = string_null; float privatemsgprefixlen = 0;
 716
 717         if(!teamsay && !privatesay)
 718                 if(substring(msgin, 0, 1) == " ")
 719                         msgin = substring(msgin, 1, strlen(msgin) - 1); // work around DP say bug (say_team does not have this!)
 720
 721         msgin = formatmessage(msgin);
 722
 723         if(source.classname != "player")
 724                 colorstr = "^0"; // black for spectators
 725         else if(teamplay)
 726                 colorstr = Team_ColorCode(source.team);
 727         else
 728         {
 729                 colorstr = "";
 730                 teamsay = FALSE;
 731         }
 732
 733         if(intermission_running)
 734                 teamsay = FALSE;
 735
 736         if(msgin != "")
 737                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
 738
 739         /*
 740          * using bprint solves this... me stupid
 741         // how can we prevent the message from appearing in a listen server?
 742         // for now, just give "say" back and only handle say_team
 743         if(!teamsay)
 744         {
 745                 clientcommand(self, strcat("say ", msgin));
 746                 return;
 747         }
 748         */
 749
 750         if(autocvar_g_chat_teamcolors)
 751                 namestr = playername(source);
 752         else
 753                 namestr = source.netname;
 754
 755         if(msgin != "")
 756         {
 757                 if(privatesay)
 758                 {
 759                         msgstr = strcat("\{1}\{13}* ^3", namestr, "^3 tells you: ^7");
 760                         privatemsgprefixlen = strlen(msgstr);
 761                         msgstr = strcat(msgstr, msgin);
 762                         cmsgstr = strcat(colorstr, "^3", namestr, "^3 tells you:\n^7", msgin);
 763                         if(autocvar_g_chat_teamcolors)
 764                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay), ": ^7");
 765                         else
 766                                 privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", privatesay.netname, ": ^7");
 767                 }
 768                 else if(teamsay)
 769                 {
 770                         msgstr = strcat("\{1}\{13}", colorstr, "(^3", namestr, colorstr, ") ^7", msgin);
 771                         cmsgstr = strcat(colorstr, "(^3", namestr, colorstr, ")\n^7", msgin);
 772                 }
 773                 else
 774                 {
 775                         msgstr = strcat("\{1}", namestr, "^7: ", msgin);
 776                         cmsgstr = "";
 777                 }
 778                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
 779         }
 780         else
 781         {
 782                 msgstr = cmsgstr = "";
 783         }
 784
 785         fullmsgstr = msgstr;
 786         fullcmsgstr = cmsgstr;
 787
 788         // FLOOD CONTROL
 789         flood = 0;
 790         flood_field = floodcontrol_chat;
 791         if(floodcontrol)
 792         {
 793                 float flood_spl;
 794                 float flood_burst;
 795                 float flood_lmax;
 796                 float lines;
 797                 if(privatesay)
 798                 {
 799                         flood_spl = autocvar_g_chat_flood_spl_tell;
 800                         flood_burst = autocvar_g_chat_flood_burst_tell;
 801                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
 802                         flood_field = floodcontrol_chattell;
 803                 }
 804                 else if(teamsay)
 805                 {
 806                         flood_spl = autocvar_g_chat_flood_spl_team;
 807                         flood_burst = autocvar_g_chat_flood_burst_team;
 808                         flood_lmax = autocvar_g_chat_flood_lmax_team;
 809                         flood_field = floodcontrol_chatteam;
 810                 }
 811                 else
 812                 {
 813                         flood_spl = autocvar_g_chat_flood_spl;
 814                         flood_burst = autocvar_g_chat_flood_burst;
 815                         flood_lmax = autocvar_g_chat_flood_lmax;
 816                         flood_field = floodcontrol_chat;
 817                 }
 818                 flood_burst = max(0, flood_burst - 1);
 819                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
 820
 821                 // do flood control for the default line size
 822                 if(msgstr != "")
 823                 {
 824                         getWrappedLine_remaining = msgstr;
 825                         msgstr = "";
 826                         lines = 0;
 827                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
 828                         {
 829                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
 830                                 ++lines;
 831                         }
 832                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
 833
 834                         if(getWrappedLine_remaining != "")
 835                         {
 836                                 msgstr = strcat(msgstr, "\n");
 837                                 flood = 2;
 838                         }
 839
 840                         if(time >= source.flood_field)
 841                         {
 842                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + lines * flood_spl;
 843                         }
 844                         else
 845                         {
 846                                 flood = 1;
 847                                 msgstr = fullmsgstr;
 848                         }
 849                 }
 850                 else
 851                 {
 852                         if(time >= source.flood_field)
 853                                 source.flood_field = max(time - flood_burst * flood_spl, source.flood_field) + flood_spl;
 854                         else
 855                                 flood = 1;
 856                 }
 857
 858                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
 859                         source.flood_field = flood = 0;
 860         }
 861
 862         if(flood == 2) // cannot happen for empty msgstr
 863         {
 864                 if(autocvar_g_chat_flood_notify_flooder)
 865                 {
 866                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
 867                         sourcecmsgstr = "";
 868                 }
 869                 else
 870                 {
 871                         sourcemsgstr = fullmsgstr;
 872                         sourcecmsgstr = fullcmsgstr;
 873                 }
 874                 cmsgstr = "";
 875         }
 876         else
 877         {
 878                 sourcemsgstr = msgstr;
 879                 sourcecmsgstr = cmsgstr;
 880         }
 881
 882         if(!privatesay)
 883         if(source.classname != "player")
 884         {
 885                 if not(intermission_running)
 886                         if(teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !(inWarmupStage || gameover)))
 887                                 teamsay = -1; // spectators
 888         }
 889
 890         if(flood)
 891                 print("NOTE: ", playername(source), "^7 is flooding.\n");
 892
 893         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
 894         if(privatesay)
 895                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
 896
 897         if(source.muted)
 898         {
 899                 // always fake the message
 900                 ret = -1;
 901         }
 902         else if(flood == 1)
 903         {
 904                 if(autocvar_g_chat_flood_notify_flooder)
 905                 {
 906                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.flood_field - time), "^3 seconds\n"));
 907                         ret = 0;
 908                 }
 909                 else
 910                         ret = -1;
 911         }
 912         else
 913         {
 914                 ret = 1;
 915         }
 916
 917         if(sourcemsgstr != "" && ret != 0)
 918         {
 919                 if(ret < 0) // faked message, because the player is muted
 920                 {
 921                         sprint(source, sourcemsgstr);
 922                         if(sourcecmsgstr != "" && !privatesay)
 923                                 centerprint(source, sourcecmsgstr);
 924                 }
 925                 else if(privatesay) // private message, between 2 people only
 926                 {
 927                         sprint(source, sourcemsgstr);
 928                         sprint(privatesay, msgstr);
 929                         if not(autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
 930                         if(cmsgstr != "")
 931                                 centerprint(privatesay, cmsgstr);
 932                 }
 933                 else if(teamsay > 0) // team message, only sent to team mates
 934                 {
 935                         sprint(source, sourcemsgstr);
 936                         dedicated_print(msgstr); // send to server console too
 937                         if(sourcecmsgstr != "")
 938                                 centerprint(source, sourcecmsgstr);
 939                         FOR_EACH_REALPLAYER(head) if(head.team == source.team)
 940                                 if(head != source)
 941                                 {
 942                                         sprint(head, msgstr);
 943                                         if(cmsgstr != "")
 944                                                 centerprint(head, cmsgstr);
 945                                 }
 946                 }
 947                 else if(teamsay < 0) // spectator message, only sent to spectators
 948                 {
 949                         sprint(source, sourcemsgstr);
 950                         dedicated_print(msgstr); // send to server console too
 951                         FOR_EACH_REALCLIENT(head) if(head.classname != "player")
 952                                 if(head != source)
 953                                         sprint(head, msgstr);
 954                 }
 955                 else if(sourcemsgstr != msgstr) // trimmed/server fixed message, sent to all players
 956                 {
 957                         sprint(source, sourcemsgstr);
 958                         dedicated_print(msgstr); // send to server console too
 959                         FOR_EACH_REALCLIENT(head)
 960                                 if(head != source)
 961                                         sprint(head, msgstr);
 962                 }
 963                 else
 964                         bprint(msgstr); // entirely normal message, sent to all players -- bprint sends to server console too.
 965         }
 966
 967         return ret;
 968 }
 969
 970 float GetVoiceMessageVoiceType(string type)
 971 {
 972         if(type == "taunt")
 973                 return VOICETYPE_TAUNT;
 974         if(type == "teamshoot")
 975                 return VOICETYPE_LASTATTACKER;
 976         return VOICETYPE_TEAMRADIO;
 977 }
 978
 979 string allvoicesamples;
 980 .string GetVoiceMessageSampleField(string type)
 981 {
 982         GetPlayerSoundSampleField_notFound = 0;
 983         switch(type)
 984         {
 985 #define _VOICEMSG(m) case #m: return playersound_##m;
 986                 ALLVOICEMSGS
 987 #undef _VOICEMSG
 988         }
 989         GetPlayerSoundSampleField_notFound = 1;
 990         return playersound_taunt;
 991 }
 992
 993 .string GetPlayerSoundSampleField(string type)
 994 {
 995         GetPlayerSoundSampleField_notFound = 0;
 996         switch(type)
 997         {
 998 #define _VOICEMSG(m) case #m: return playersound_##m;
 999                 ALLPLAYERSOUNDS
1000 #undef _VOICEMSG
1001         }
1002         GetPlayerSoundSampleField_notFound = 1;
1003         return playersound_taunt;
1004 }
1005
1006 void PrecacheGlobalSound(string samplestring)
1007 {
1008         float n, i;
1009         tokenize_console(samplestring);
1010         n = stof(argv(1));
1011         if(n > 0)
1012         {
1013                 for(i = 1; i <= n; ++i)
1014                         precache_sound(strcat(argv(0), ftos(i), ".wav"));
1015         }
1016         else
1017         {
1018                 precache_sound(strcat(argv(0), ".wav"));
1019         }
1020 }
1021
1022 void PrecachePlayerSounds(string f)
1023 {
1024         float fh;
1025         string s;
1026         fh = fopen(f, FILE_READ);
1027         if(fh < 0)
1028                 return;
1029         while((s = fgets(fh)))
1030         {
1031                 if(tokenize_console(s) != 3)
1032                 {
1033                         dprint("Invalid sound info line: ", s, "\n");
1034                         continue;
1035                 }
1036                 PrecacheGlobalSound(strcat(argv(1), " ", argv(2)));
1037         }
1038         fclose(fh);
1039
1040         if not(allvoicesamples)
1041         {
1042 #define _VOICEMSG(m) allvoicesamples = strcat(allvoicesamples, " ", #m);
1043                 ALLVOICEMSGS
1044 #undef _VOICEMSG
1045                 allvoicesamples = strzone(substring(allvoicesamples, 1, strlen(allvoicesamples) - 1));
1046         }
1047 }
1048
1049 void ClearPlayerSounds()
1050 {
1051 #define _VOICEMSG(m) if(self.playersound_##m) { strunzone(self.playersound_##m); self.playersound_##m = string_null; }
1052         ALLPLAYERSOUNDS
1053         ALLVOICEMSGS
1054 #undef _VOICEMSG
1055 }
1056
1057 float LoadPlayerSounds(string f, float first)
1058 {
1059         float fh;
1060         string s;
1061         var .string field;
1062         fh = fopen(f, FILE_READ);
1063         if(fh < 0)
1064         {
1065                 dprint("Player sound file not found: ", f, "\n");
1066                 return 0;
1067         }
1068         while((s = fgets(fh)))
1069         {
1070                 if(tokenize_console(s) != 3)
1071                         continue;
1072                 field = GetPlayerSoundSampleField(argv(0));
1073                 if(GetPlayerSoundSampleField_notFound)
1074                         field = GetVoiceMessageSampleField(argv(0));
1075                 if(GetPlayerSoundSampleField_notFound)
1076                         continue;
1077                 if(self.field)
1078                         strunzone(self.field);
1079                 self.field = strzone(strcat(argv(1), " ", argv(2)));
1080         }
1081         fclose(fh);
1082         return 1;
1083 }
1084
1085 .float modelindex_for_playersound;
1086 .float skin_for_playersound;
1087 void UpdatePlayerSounds()
1088 {
1089         if(self.modelindex == self.modelindex_for_playersound)
1090         if(self.skin == self.skin_for_playersound)
1091                 return;
1092         self.modelindex_for_playersound = self.modelindex;
1093         self.skin_for_playersound = self.skin;
1094         ClearPlayerSounds();
1095         LoadPlayerSounds("sound/player/default.sounds", 1);
1096         if(!autocvar_g_debug_defaultsounds)
1097                 if(!LoadPlayerSounds(get_model_datafilename(self.model, self.skin, "sounds"), 0))
1098                         LoadPlayerSounds(get_model_datafilename(self.model, 0, "sounds"), 0);
1099 }
1100
1101 void FakeGlobalSound(string sample, float chan, float voicetype)
1102 {
1103         float n;
1104         float tauntrand;
1105
1106         if(sample == "")
1107                 return;
1108
1109         tokenize_console(sample);
1110         n = stof(argv(1));
1111         if(n > 0)
1112                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1113         else
1114                 sample = strcat(argv(0), ".wav"); // randomization
1115
1116         switch(voicetype)
1117         {
1118                 case VOICETYPE_LASTATTACKER_ONLY:
1119                         break;
1120                 case VOICETYPE_LASTATTACKER:
1121                         if(self.pusher)
1122                         {
1123                                 msg_entity = self;
1124                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1125                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1126                         }
1127                         break;
1128                 case VOICETYPE_TEAMRADIO:
1129                         msg_entity = self;
1130                         if(msg_entity.cvar_cl_voice_directional == 1)
1131                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1132                         else
1133                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1134                         break;
1135                 case VOICETYPE_AUTOTAUNT:
1136                         if(!sv_autotaunt)
1137                                 break;
1138                         if(!sv_taunt)
1139                                 break;
1140                         if(autocvar_sv_gentle)
1141                                 break;
1142                         tauntrand = random();
1143                         msg_entity = self;
1144                         if (tauntrand < msg_entity.cvar_cl_autotaunt)
1145                         {
1146                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1147                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1148                                 else
1149                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1150                         }
1151                         break;
1152                 case VOICETYPE_TAUNT:
1153                         if(self.classname == "player")
1154                                 if(self.deadflag == DEAD_NO)
1155                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1156                         if(!sv_taunt)
1157                                 break;
1158                         if(autocvar_sv_gentle)
1159                                 break;
1160                         msg_entity = self;
1161                         if (msg_entity.cvar_cl_voice_directional >= 1)
1162                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1163                         else
1164                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1165                         break;
1166                 case VOICETYPE_PLAYERSOUND:
1167                         msg_entity = self;
1168                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NORM);
1169                         break;
1170                 default:
1171                         backtrace("Invalid voice type!");
1172                         break;
1173         }
1174 }
1175
1176 void GlobalSound(string sample, float chan, float voicetype)
1177 {
1178         float n;
1179         float tauntrand;
1180
1181         if(sample == "")
1182                 return;
1183
1184         tokenize_console(sample);
1185         n = stof(argv(1));
1186         if(n > 0)
1187                 sample = strcat(argv(0), ftos(floor(random() * n + 1)), ".wav"); // randomization
1188         else
1189                 sample = strcat(argv(0), ".wav"); // randomization
1190
1191         switch(voicetype)
1192         {
1193                 case VOICETYPE_LASTATTACKER_ONLY:
1194                         if(self.pusher)
1195                         {
1196                                 msg_entity = self.pusher;
1197                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1198                                 {
1199                                         if(msg_entity.cvar_cl_voice_directional == 1)
1200                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1201                                         else
1202                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1203                                 }
1204                         }
1205                         break;
1206                 case VOICETYPE_LASTATTACKER:
1207                         if(self.pusher)
1208                         {
1209                                 msg_entity = self.pusher;
1210                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1211                                 {
1212                                         if(msg_entity.cvar_cl_voice_directional == 1)
1213                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1214                                         else
1215                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1216                                 }
1217                                 msg_entity = self;
1218                                 if(clienttype(msg_entity) == CLIENTTYPE_REAL)
1219                                         soundto(MSG_ONE, self, chan, sample, VOL_BASE, ATTN_NONE);
1220                         }
1221                         break;
1222                 case VOICETYPE_TEAMRADIO:
1223                         FOR_EACH_REALCLIENT(msg_entity)
1224                                 if(!teamplay || msg_entity.team == self.team)
1225                                 {
1226                                         if(msg_entity.cvar_cl_voice_directional == 1)
1227                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_MIN);
1228                                         else
1229                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1230                                 }
1231                         break;
1232                 case VOICETYPE_AUTOTAUNT:
1233                         if(!sv_autotaunt)
1234                                 break;
1235                         if(!sv_taunt)
1236                                 break;
1237                         if(autocvar_sv_gentle)
1238                                 break;
1239                         tauntrand = random();
1240                         FOR_EACH_REALCLIENT(msg_entity)
1241                                 if (tauntrand < msg_entity.cvar_cl_autotaunt)
1242                                 {
1243                                         if (msg_entity.cvar_cl_voice_directional >= 1)
1244                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1245                                         else
1246                                                 soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1247                                 }
1248                         break;
1249                 case VOICETYPE_TAUNT:
1250                         if(self.classname == "player")
1251                                 if(self.deadflag == DEAD_NO)
1252                                         animdecide_setaction(self, ANIMACTION_TAUNT, TRUE);
1253                         if(!sv_taunt)
1254                                 break;
1255                         if(autocvar_sv_gentle)
1256                                 break;
1257                         FOR_EACH_REALCLIENT(msg_entity)
1258                         {
1259                                 if (msg_entity.cvar_cl_voice_directional >= 1)
1260                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, bound(ATTN_MIN, msg_entity.cvar_cl_voice_directional_taunt_attenuation, ATTN_MAX));
1261                                 else
1262                                         soundto(MSG_ONE, self, chan, sample, VOL_BASEVOICE, ATTN_NONE);
1263                         }
1264                         break;
1265                 case VOICETYPE_PLAYERSOUND:
1266                         sound(self, chan, sample, VOL_BASE, ATTN_NORM);
1267                         break;
1268                 default:
1269                         backtrace("Invalid voice type!");
1270                         break;
1271         }
1272 }
1273
1274 void PlayerSound(.string samplefield, float chan, float voicetype)
1275 {
1276         GlobalSound(self.samplefield, chan, voicetype);
1277 }
1278
1279 void VoiceMessage(string type, string msg)
1280 {
1281         var .string sample;
1282         float voicetype, ownteam;
1283         float flood;
1284         sample = GetVoiceMessageSampleField(type);
1285
1286         if(GetPlayerSoundSampleField_notFound)
1287         {
1288                 sprint(self, strcat("Invalid voice. Use one of: ", allvoicesamples, "\n"));
1289                 return;
1290         }
1291
1292         voicetype = GetVoiceMessageVoiceType(type);
1293         ownteam = (voicetype == VOICETYPE_TEAMRADIO);
1294
1295         flood = Say(self, ownteam, world, msg, 1);
1296
1297         if (flood > 0)
1298                 GlobalSound(self.sample, CH_VOICE, voicetype);
1299         else if (flood < 0)
1300                 FakeGlobalSound(self.sample, CH_VOICE, voicetype);
1301 }
1302
1303 void MoveToTeam(entity client, float team_colour, float type)
1304 {
1305         float lockteams_backup;
1306
1307         lockteams_backup = lockteams;  // backup any team lock
1308
1309         lockteams = 0;  // disable locked teams
1310
1311         TeamchangeFrags(client);  // move the players frags
1312         SetPlayerColors(client, team_colour - 1);  // set the players colour
1313         Damage(client, client, client, 100000, DEATH_AUTOTEAMCHANGE, client.origin, '0 0 0');  // kill the player
1314
1315         lockteams = lockteams_backup;  // restore the team lock
1316
1317         LogTeamchange(client.playerid, client.team, type);
1318 }