Remove legacy MOTD logic
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <common/csqcmodel_settings.qh>
4 #include <common/deathtypes/all.qh>
5 #include <common/effects/all.qh>
6 #include <common/effects/qc/globalsound.qh>
7 #include <common/ent_cs.qh>
8 #include <common/gamemodes/_mod.qh>
9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
10 #include <common/items/_mod.qh>
11 #include <common/items/inventory.qh>
12 #include <common/mapobjects/func/conveyor.qh>
13 #include <common/mapobjects/func/ladder.qh>
14 #include <common/mapobjects/subs.qh>
15 #include <common/mapobjects/target/spawnpoint.qh>
16 #include <common/mapobjects/teleporters.qh>
17 #include <common/mapobjects/trigger/counter.qh>
18 #include <common/mapobjects/trigger/secret.qh>
19 #include <common/mapobjects/trigger/swamp.qh>
20 #include <common/mapobjects/triggers.qh>
21 #include <common/minigames/sv_minigames.qh>
22 #include <common/monsters/sv_monsters.qh>
23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
24 #include <common/mutators/mutator/nades/nades.qh>
25 #include <common/mutators/mutator/overkill/oknex.qh>
26 #include <common/mutators/mutator/status_effects/_mod.qh>
27 #include <common/mutators/mutator/waypoints/all.qh>
28 #include <common/net_linked.qh>
29 #include <common/net_notice.qh>
30 #include <common/notifications/all.qh>
31 #include <common/physics/player.qh>
32 #include <common/playerstats.qh>
33 #include <common/resources/sv_resources.qh>
34 #include <common/state.qh>
35 #include <common/stats.qh>
36 #include <common/vehicles/all.qh>
37 #include <common/vehicles/sv_vehicles.qh>
38 #include <common/viewloc.qh>
39 #include <common/weapons/_all.qh>
40 #include <common/weapons/weapon/vortex.qh>
41 #include <common/wepent.qh>
42 #include <lib/csqcmodel/sv_model.qh>
43 #include <lib/warpzone/common.qh>
44 #include <lib/warpzone/server.qh>
45 #include <server/anticheat.qh>
46 #include <server/antilag.qh>
47 #include <server/bot/api.qh>
48 #include <server/bot/default/cvars.qh>
49 #include <server/campaign.qh>
50 #include <server/chat.qh>
51 #include <server/cheats.qh>
52 #include <server/clientkill.qh>
53 #include <server/command/common.qh>
54 #include <server/command/common.qh>
55 #include <server/command/vote.qh>
56 #include <server/compat/quake3.qh>
57 #include <server/damage.qh>
58 #include <server/gamelog.qh>
59 #include <server/handicap.qh>
60 #include <server/hook.qh>
61 #include <server/impulse.qh>
62 #include <server/intermission.qh>
63 #include <server/ipban.qh>
64 #include <server/main.qh>
65 #include <server/mutators/_mod.qh>
66 #include <server/player.qh>
67 #include <server/portals.qh>
68 #include <server/race.qh>
69 #include <server/scores.qh>
70 #include <server/scores_rules.qh>
71 #include <server/spawnpoints.qh>
72 #include <server/teamplay.qh>
73 #include <server/weapons/accuracy.qh>
74 #include <server/weapons/common.qh>
75 #include <server/weapons/hitplot.qh>
76 #include <server/weapons/selection.qh>
77 #include <server/weapons/tracing.qh>
78 #include <server/weapons/weaponsystem.qh>
79 #include <server/world.qh>
80
81 STATIC_METHOD(Client, Add, void(Client this, int _team))
82 {
83     ClientConnect(this);
84     TRANSMUTE(Player, this);
85     this.frame = 12; // 7
86     this.team = _team;
87     PutClientInServer(this);
88 }
89
90 STATIC_METHOD(Client, Remove, void(Client this))
91 {
92     TRANSMUTE(Observer, this);
93     PutClientInServer(this);
94     ClientDisconnect(this);
95 }
96
97 void send_CSQC_teamnagger() {
98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
99 }
100
101 int CountSpectators(entity player, entity to)
102 {
103         if(!player) { return 0; } // not sure how, but best to be safe
104
105         int spec_count = 0;
106
107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
108         {
109                 spec_count++;
110         });
111
112         return spec_count;
113 }
114
115 void WriteSpectators(entity player, entity to)
116 {
117         if(!player) { return; } // not sure how, but best to be safe
118
119         int spec_count = 0;
120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
121         {
122                 if(spec_count >= MAX_SPECTATORS)
123                         break;
124                 WriteByte(MSG_ENTITY, num_for_edict(it));
125                 ++spec_count;
126         });
127 }
128
129 bool ClientData_Send(entity this, entity to, int sf)
130 {
131         assert(to == this.owner, return false);
132
133         entity e = to;
134         if (IS_SPEC(e)) e = e.enemy;
135
136         sf = 0;
137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
140         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
141                                         sf |= BIT(4); // show spectators
142
143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
144         WriteByte(MSG_ENTITY, sf);
145
146         if (sf & BIT(1))
147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
148
149         if(sf & BIT(4))
150         {
151                 float specs = CountSpectators(e, to);
152                 WriteByte(MSG_ENTITY, specs);
153                 WriteSpectators(e, to);
154         }
155
156         return true;
157 }
158
159 void ClientData_Attach(entity this)
160 {
161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
162         CS(this).clientdata.drawonlytoclient = this;
163         CS(this).clientdata.owner = this;
164 }
165
166 void ClientData_Detach(entity this)
167 {
168         delete(CS(this).clientdata);
169         CS(this).clientdata = NULL;
170 }
171
172 void ClientData_Touch(entity e)
173 {
174         entity cd = CS(e).clientdata;
175         if (cd) { cd.SendFlags = 1; }
176
177         // make it spectatable
178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
179         {
180                 entity cd = CS(it).clientdata;
181                 if (cd) { cd.SendFlags = 1; }
182         });
183 }
184
185
186 /*
187 =============
188 CheckPlayerModel
189
190 Checks if the argument string can be a valid playermodel.
191 Returns a valid one in doubt.
192 =============
193 */
194 string FallbackPlayerModel;
195 string CheckPlayerModel(string plyermodel) {
196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
197         {
198                 // note: we cannot summon Don Strunzone here, some player may
199                 // still have the model string set. In case anyone manages how
200                 // to change a cvar default, we'll have a small leak here.
201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
202         }
203         // only in right path
204         if(substring(plyermodel, 0, 14) != "models/player/")
205                 return FallbackPlayerModel;
206         // only good file extensions
207         if(substring(plyermodel, -4, 4) != ".iqm"
208                 && substring(plyermodel, -4, 4) != ".zym"
209                 && substring(plyermodel, -4, 4) != ".dpm"
210                 && substring(plyermodel, -4, 4) != ".md3"
211                 && substring(plyermodel, -4, 4) != ".psk")
212         {
213                 return FallbackPlayerModel;
214         }
215         // forbid the LOD models
216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
217                 return FallbackPlayerModel;
218         if(plyermodel != strtolower(plyermodel))
219                 return FallbackPlayerModel;
220         // also, restrict to server models
221         if(autocvar_sv_servermodelsonly)
222         {
223                 if(!fexists(plyermodel))
224                         return FallbackPlayerModel;
225         }
226         return plyermodel;
227 }
228
229 void setplayermodel(entity e, string modelname)
230 {
231         precache_model(modelname);
232         _setmodel(e, modelname);
233         player_setupanimsformodel(e);
234         if(!autocvar_g_debug_globalsounds)
235                 UpdatePlayerSounds(e);
236 }
237
238 /** putting a client as observer in the server */
239 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
240 {
241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
242         bool recount_ready = false;
243         PlayerState_detach(this);
244
245         if (IS_PLAYER(this))
246         {
247                 if(GetResource(this, RES_HEALTH) >= 1)
248                 {
249                         // despawn effect
250                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
251                 }
252
253                 // was a player, recount votes and ready status
254                 if(IS_REAL_CLIENT(this))
255                 {
256                         if (vote_called) { VoteCount(false); }
257                         this.ready = false;
258                         recount_ready = true;
259                 }
260                 entcs_update_players(this);
261         }
262
263         if (use_spawnpoint)
264         {
265                 entity spot = SelectSpawnPoint(this, true);
266                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
267                 this.angles = vec2(spot.angles);
268                 // offset it so that the spectator spawns higher off the ground, looks better this way
269                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
270         }
271         else // change origin to restore previous view origin
272                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
273         this.fixangle = true;
274
275         if (IS_REAL_CLIENT(this))
276         {
277                 msg_entity = this;
278                 WriteByte(MSG_ONE, SVC_SETVIEW);
279                 WriteEntity(MSG_ONE, this);
280         }
281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
283         if(!autocvar_g_debug_globalsounds)
284         {
285                 // needed for player sounds
286                 this.model = "";
287                 FixPlayermodel(this);
288         }
289         setmodel(this, MDL_Null);
290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
291         this.view_ofs = '0 0 0';
292
293         RemoveGrapplingHooks(this);
294         Portal_ClearAll(this);
295         Unfreeze(this, false);
296         SetSpectatee(this, NULL);
297
298         if (this.alivetime)
299         {
300                 if (!warmup_stage)
301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
302                 this.alivetime = 0;
303         }
304
305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
306
307         TRANSMUTE(Observer, this);
308
309         if(recount_ready) ReadyCount();
310
311         WaypointSprite_PlayerDead(this);
312         accuracy_resend(this);
313
314         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
315                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
316
317         CS(this).spectatortime = time;
318         if(this.bot_attack)
319                 IL_REMOVE(g_bot_targets, this);
320         this.bot_attack = false;
321         if(this.monster_attack)
322                 IL_REMOVE(g_monster_targets, this);
323         this.monster_attack = false;
324         STAT(HUD, this) = HUD_NORMAL;
325         this.iscreature = false;
326         this.teleportable = TELEPORT_SIMPLE;
327         if(this.damagedbycontents)
328                 IL_REMOVE(g_damagedbycontents, this);
329         this.damagedbycontents = false;
330         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
331         SetSpectatee_status(this, etof(this));
332         this.takedamage = DAMAGE_NO;
333         this.solid = SOLID_NOT;
334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
335         this.flags = FL_CLIENT | FL_NOTARGET;
336         this.effects = 0;
337         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
338         this.pauserotarmor_finished = 0;
339         this.pauserothealth_finished = 0;
340         this.pauseregen_finished = 0;
341         this.damageforcescale = 0;
342         this.death_time = 0;
343         this.respawn_flags = 0;
344         this.respawn_time = 0;
345         STAT(RESPAWN_TIME, this) = 0;
346         this.alpha = 0;
347         this.scale = 0;
348         this.fade_time = 0;
349         this.pain_finished = 0;
350         STAT(AIR_FINISHED, this) = 0;
351         //this.dphitcontentsmask = 0;
352         this.dphitcontentsmask = DPCONTENTS_SOLID;
353         if (autocvar_g_playerclip_collisions)
354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
355         this.pushltime = 0;
356         this.istypefrag = 0;
357         setthink(this, func_null);
358         this.nextthink = 0;
359         this.deadflag = DEAD_NO;
360         UNSET_DUCKED(this);
361         STAT(REVIVE_PROGRESS, this) = 0;
362         this.revival_time = 0;
363         this.draggable = drag_undraggable;
364
365         player_powerups_remove_all(this);
366         this.items = 0;
367         STAT(WEAPONS, this) = '0 0 0';
368         this.drawonlytoclient = this;
369
370         this.viewloc = NULL;
371
372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
373
374         this.weaponmodel = "";
375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
376         {
377                 this.weaponentities[slot] = NULL;
378         }
379         this.exteriorweaponentity = NULL;
380         CS(this).killcount = FRAGS_SPECTATOR;
381         this.velocity = '0 0 0';
382         this.avelocity = '0 0 0';
383         this.punchangle = '0 0 0';
384         this.punchvector = '0 0 0';
385         this.oldvelocity = this.velocity;
386         this.event_damage = func_null;
387         this.event_heal = func_null;
388
389         for(int slot = 0; slot < MAX_AXH; ++slot)
390         {
391                 entity axh = this.(AuxiliaryXhair[slot]);
392                 this.(AuxiliaryXhair[slot]) = NULL;
393
394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
395                         delete(axh);
396         }
397
398         if (mutator_returnvalue)
399         {
400                 // mutator prevents resetting teams+score
401         }
402         else
403         {
404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
405                 this.frags = FRAGS_SPECTATOR;
406         }
407
408         bot_relinkplayerlist();
409
410         if (CS(this).just_joined)
411                 CS(this).just_joined = false;
412 }
413
414 int player_getspecies(entity this)
415 {
416         get_model_parameters(this.model, this.skin);
417         int s = get_model_parameters_species;
418         get_model_parameters(string_null, 0);
419         if (s < 0) return SPECIES_HUMAN;
420         return s;
421 }
422
423 .float model_randomizer;
424 void FixPlayermodel(entity player)
425 {
426         string defaultmodel = "";
427         int defaultskin = 0;
428         if(autocvar_sv_defaultcharacter)
429         {
430                 if(teamplay)
431                 {
432                         switch(player.team)
433                         {
434                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
435                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
436                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
437                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
438                         }
439                 }
440
441                 if(defaultmodel == "")
442                 {
443                         defaultmodel = autocvar_sv_defaultplayermodel;
444                         defaultskin = autocvar_sv_defaultplayerskin;
445                 }
446
447                 int n = tokenize_console(defaultmodel);
448                 if(n > 0)
449                 {
450                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
451                         // However, do NOT randomize if the player-selected model is in the list.
452                         for (int i = 0; i < n; ++i)
453                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
454                                         defaultmodel = argv(i);
455                 }
456
457                 int i = strstrofs(defaultmodel, ":", 0);
458                 if(i >= 0)
459                 {
460                         defaultskin = stof(substring(defaultmodel, i+1, -1));
461                         defaultmodel = substring(defaultmodel, 0, i);
462                 }
463         }
464         if(autocvar_sv_defaultcharacterskin && !defaultskin)
465         {
466                 if(teamplay)
467                 {
468                         switch(player.team)
469                         {
470                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
471                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
472                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
473                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
474                         }
475                 }
476
477                 if(!defaultskin)
478                         defaultskin = autocvar_sv_defaultplayerskin;
479         }
480
481         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
482         defaultmodel = M_ARGV(0, string);
483         defaultskin = M_ARGV(1, int);
484
485         bool chmdl = false;
486         int oldskin;
487         if(defaultmodel != "")
488         {
489                 if (defaultmodel != player.model)
490                 {
491                         vector m1 = player.mins;
492                         vector m2 = player.maxs;
493                         setplayermodel (player, defaultmodel);
494                         setsize (player, m1, m2);
495                         chmdl = true;
496                 }
497
498                 oldskin = player.skin;
499                 player.skin = defaultskin;
500         } else {
501                 if (player.playermodel != player.model || player.playermodel == "")
502                 {
503                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
504                         vector m1 = player.mins;
505                         vector m2 = player.maxs;
506                         setplayermodel (player, player.playermodel);
507                         setsize (player, m1, m2);
508                         chmdl = true;
509                 }
510
511                 if(!autocvar_sv_defaultcharacterskin)
512                 {
513                         oldskin = player.skin;
514                         player.skin = stof(player.playerskin);
515                 }
516                 else
517                 {
518                         oldskin = player.skin;
519                         player.skin = defaultskin;
520                 }
521         }
522
523         if(chmdl || oldskin != player.skin) // model or skin has changed
524         {
525                 player.species = player_getspecies(player); // update species
526                 if(!autocvar_g_debug_globalsounds)
527                         UpdatePlayerSounds(player); // update skin sounds
528         }
529
530         if(!teamplay)
531                 if(strlen(autocvar_sv_defaultplayercolors))
532                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
533                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
534 }
535
536 void PutPlayerInServer(entity this)
537 {
538         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
539
540         PlayerState_attach(this);
541         accuracy_resend(this);
542
543         if (teamplay && this.bot_forced_team)
544                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
545
546         if (this.team < 0)
547                 TeamBalance_JoinBestTeam(this);
548
549         entity spot = SelectSpawnPoint(this, false);
550         if (!spot) {
551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
552                 return; // spawn failed
553         }
554
555         TRANSMUTE(Player, this);
556
557         CS(this).wasplayer = true;
558         this.iscreature = true;
559         this.teleportable = TELEPORT_NORMAL;
560         if(!this.damagedbycontents)
561                 IL_PUSH(g_damagedbycontents, this);
562         this.damagedbycontents = true;
563         set_movetype(this, MOVETYPE_WALK);
564         this.solid = SOLID_SLIDEBOX;
565         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
566         if (autocvar_g_playerclip_collisions)
567                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
568         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
569                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
570         this.frags = FRAGS_PLAYER;
571         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
572         this.flags = FL_CLIENT | FL_PICKUPITEMS;
573         if (autocvar__notarget)
574                 this.flags |= FL_NOTARGET;
575         this.takedamage = DAMAGE_AIM;
576         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
577
578         if (warmup_stage) {
579                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
580                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
581                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
582                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
583                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
584                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
585                 SetResource(this, RES_HEALTH, warmup_start_health);
586                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
587                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
588         } else {
589                 SetResource(this, RES_SHELLS, start_ammo_shells);
590                 SetResource(this, RES_BULLETS, start_ammo_nails);
591                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
592                 SetResource(this, RES_CELLS, start_ammo_cells);
593                 SetResource(this, RES_PLASMA, start_ammo_plasma);
594                 SetResource(this, RES_FUEL, start_ammo_fuel);
595                 SetResource(this, RES_HEALTH, start_health);
596                 SetResource(this, RES_ARMOR, start_armorvalue);
597                 STAT(WEAPONS, this) = start_weapons;
598                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
599                 {
600                         GiveRandomWeapons(this, random_start_weapons_count,
601                                 autocvar_g_random_start_weapons, random_start_ammo);
602                 }
603         }
604         SetSpectatee_status(this, 0);
605
606         PS(this).dual_weapons = '0 0 0';
607
608         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
609                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
610
611         this.items = start_items;
612
613         float shieldtime = time + autocvar_g_spawnshieldtime;
614
615         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
616         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
617         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
618         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
619         if (!sv_ready_restart_after_countdown && time < game_starttime)
620         {
621                 float f = game_starttime - time;
622                 shieldtime += f;
623                 this.pauserotarmor_finished += f;
624                 this.pauserothealth_finished += f;
625                 this.pauseregen_finished += f;
626         }
627
628         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
629
630         this.damageforcescale = autocvar_g_player_damageforcescale;
631         this.death_time = 0;
632         this.respawn_flags = 0;
633         this.respawn_time = 0;
634         STAT(RESPAWN_TIME, this) = 0;
635         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
636         this.fade_time = 0;
637         this.pain_finished = 0;
638         this.pushltime = 0;
639         setthink(this, func_null); // players have no think function
640         this.nextthink = 0;
641         this.dmg_team = 0;
642         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
643
644         this.deadflag = DEAD_NO;
645
646         this.angles = spot.angles;
647         this.angles_z = 0; // never spawn tilted even if the spot says to
648         if (IS_BOT_CLIENT(this))
649         {
650                 this.v_angle = this.angles;
651                 bot_aim_reset(this);
652         }
653         this.fixangle = true; // turn this way immediately
654         this.oldvelocity = this.velocity = '0 0 0';
655         this.avelocity = '0 0 0';
656         this.punchangle = '0 0 0';
657         this.punchvector = '0 0 0';
658
659         STAT(REVIVE_PROGRESS, this) = 0;
660         this.revival_time = 0;
661
662         STAT(AIR_FINISHED, this) = 0;
663         this.waterlevel = WATERLEVEL_NONE;
664         this.watertype = CONTENT_EMPTY;
665
666         entity spawnevent = new_pure(spawnevent);
667         spawnevent.owner = this;
668         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
669
670         // Cut off any still running player sounds.
671         stopsound(this, CH_PLAYER_SINGLE);
672
673         this.model = "";
674         FixPlayermodel(this);
675         this.drawonlytoclient = NULL;
676
677         this.viewloc = NULL;
678
679         for(int slot = 0; slot < MAX_AXH; ++slot)
680         {
681                 entity axh = this.(AuxiliaryXhair[slot]);
682                 this.(AuxiliaryXhair[slot]) = NULL;
683
684                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
685                         delete(axh);
686         }
687
688         this.spawnpoint_targ = NULL;
689
690         UNSET_DUCKED(this);
691         this.view_ofs = STAT(PL_VIEW_OFS, this);
692         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
693         this.spawnorigin = spot.origin;
694         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
695         // don't reset back to last position, even if new position is stuck in solid
696         this.oldorigin = this.origin;
697         if(this.conveyor)
698                 IL_REMOVE(g_conveyed, this);
699         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
700         if(this.swampslug)
701                 IL_REMOVE(g_swamped, this);
702         this.swampslug = NULL;
703         this.swamp_interval = 0;
704         if(this.ladder_entity)
705                 IL_REMOVE(g_ladderents, this);
706         this.ladder_entity = NULL;
707         IL_EACH(g_counters, it.realowner == this,
708         {
709                 delete(it);
710         });
711         STAT(HUD, this) = HUD_NORMAL;
712
713         this.event_damage = PlayerDamage;
714         this.event_heal = PlayerHeal;
715
716         this.draggable = func_null;
717
718         if(!this.bot_attack)
719                 IL_PUSH(g_bot_targets, this);
720         this.bot_attack = true;
721         if(!this.monster_attack)
722                 IL_PUSH(g_monster_targets, this);
723         this.monster_attack = true;
724         navigation_dynamicgoal_init(this, false);
725
726         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
727
728         // player was spectator
729         if (CS(this).killcount == FRAGS_SPECTATOR) {
730                 PlayerScore_Clear(this);
731                 CS(this).killcount = 0;
732                 CS(this).startplaytime = time;
733         }
734
735         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
736         {
737                 .entity weaponentity = weaponentities[slot];
738                 CL_SpawnWeaponentity(this, weaponentity);
739         }
740         this.alpha = default_player_alpha;
741         this.colormod = '1 1 1' * autocvar_g_player_brightness;
742         this.exteriorweaponentity.alpha = default_weapon_alpha;
743
744         this.speedrunning = false;
745
746         this.counter_cnt = 0;
747         this.fragsfilter_cnt = 0;
748
749         target_voicescript_clear(this);
750
751         // reset fields the weapons may use
752         FOREACH(Weapons, true, {
753                 it.wr_resetplayer(it, this);
754                         // reload all reloadable weapons
755                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
756                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757                         {
758                                 .entity weaponentity = weaponentities[slot];
759                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
760                         }
761                 }
762         });
763
764         Unfreeze(this, false);
765
766         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
767         {
768                 string s = spot.target;
769                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
770                         spot.target = string_null;
771                 SUB_UseTargets(spot, this, NULL);
772                 if(g_assault || g_race)
773                         spot.target = s;
774         }
775
776         if (autocvar_spawn_debug)
777         {
778                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
779                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
780         }
781
782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
783         {
784                 .entity weaponentity = weaponentities[slot];
785                 entity w_ent = this.(weaponentity);
786                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
787                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
788                 else
789                         w_ent.m_switchweapon = WEP_Null;
790                 w_ent.m_weapon = WEP_Null;
791                 w_ent.weaponname = "";
792                 w_ent.m_switchingweapon = WEP_Null;
793                 w_ent.cnt = -1;
794         }
795
796         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
797
798         if (CS(this).impulse) ImpulseCommands(this);
799
800         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
801         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
802         {
803                 .entity weaponentity = weaponentities[slot];
804                 W_WeaponFrame(this, weaponentity);
805         }
806
807         if (!warmup_stage && !this.alivetime)
808                 this.alivetime = time;
809
810         antilag_clear(this, CS(this));
811 }
812
813 /** Called when a client spawns in the server */
814 void PutClientInServer(entity this)
815 {
816         if (IS_REAL_CLIENT(this)) {
817                 msg_entity = this;
818                 WriteByte(MSG_ONE, SVC_SETVIEW);
819                 WriteEntity(MSG_ONE, this);
820         }
821         if (game_stopped)
822                 TRANSMUTE(Observer, this);
823
824         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
825         SetSpectatee(this, NULL);
826
827         // reset player keys
828         if(PS(this))
829                 PS(this).itemkeys = 0;
830
831         MUTATOR_CALLHOOK(PutClientInServer, this);
832
833         if (IS_OBSERVER(this)) {
834                 PutObserverInServer(this, false, use_spawnpoint);
835         } else if (IS_PLAYER(this)) {
836                 PutPlayerInServer(this);
837         }
838
839         bot_relinkplayerlist();
840 }
841
842 // TODO do we need all these fields, or should we stop autodetecting runtime
843 // changes and just have a console command to update this?
844 bool ClientInit_SendEntity(entity this, entity to, int sf)
845 {
846         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
847         return = true;
848         msg_entity = to;
849         // MSG_INIT replacement
850         // TODO: make easier to use
851         Registry_send_all();
852         W_PROP_reload(MSG_ONE, to);
853         ClientInit_misc(this);
854         MUTATOR_CALLHOOK(Ent_Init);
855 }
856 void ClientInit_misc(entity this)
857 {
858         int channel = MSG_ONE;
859         WriteHeader(channel, ENT_CLIENT_INIT);
860         WriteByte(channel, g_nexball_meter_period * 32);
861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
869
870         if(autocvar_sv_foginterval && world.fog != "")
871                 WriteString(channel, world.fog);
872         else
873                 WriteString(channel, "");
874         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
875         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
876         WriteByte(channel, serverflags);
877         WriteCoord(channel, autocvar_g_trueaim_minrange);
878 }
879
880 void ClientInit_CheckUpdate(entity this)
881 {
882         this.nextthink = time;
883         if(this.count != autocvar_g_balance_armor_blockpercent)
884         {
885                 this.count = autocvar_g_balance_armor_blockpercent;
886                 this.SendFlags |= 1;
887         }
888         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
889         {
890                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
891                 this.SendFlags |= 1;
892         }
893 }
894
895 void ClientInit_Spawn()
896 {
897         entity e = new_pure(clientinit);
898         setthink(e, ClientInit_CheckUpdate);
899         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
900
901         ClientInit_CheckUpdate(e);
902 }
903
904 /*
905 =============
906 SetNewParms
907 =============
908 */
909 void SetNewParms ()
910 {
911         // initialize parms for a new player
912         parm1 = -(86400 * 366);
913
914         MUTATOR_CALLHOOK(SetNewParms);
915 }
916
917 /*
918 =============
919 SetChangeParms
920 =============
921 */
922 void SetChangeParms (entity this)
923 {
924         // save parms for level change
925         parm1 = CS(this).parm_idlesince - time;
926
927         MUTATOR_CALLHOOK(SetChangeParms);
928 }
929
930 /*
931 =============
932 DecodeLevelParms
933 =============
934 */
935 void DecodeLevelParms(entity this)
936 {
937         // load parms
938         CS(this).parm_idlesince = parm1;
939         if (CS(this).parm_idlesince == -(86400 * 366))
940                 CS(this).parm_idlesince = time;
941
942         // whatever happens, allow 60 seconds of idling directly after connect for map loading
943         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
944
945         MUTATOR_CALLHOOK(DecodeLevelParms);
946 }
947
948 void FixClientCvars(entity e)
949 {
950         // send prediction settings to the client
951         if(autocvar_g_antilag == 3) // client side hitscan
952                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
953         if(autocvar_sv_gentle)
954                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
955
956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
958
959         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
960
961         MUTATOR_CALLHOOK(FixClientCvars, e);
962 }
963
964 bool findinlist_abbrev(string tofind, string list)
965 {
966         if(list == "" || tofind == "")
967                 return false; // empty list or search, just return
968
969         // this function allows abbreviated strings!
970         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
971         {
972                 return true;
973         });
974
975         return false;
976 }
977
978 bool PlayerInIPList(entity p, string iplist)
979 {
980         // some safety checks (never allow local?)
981         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
982                 return false;
983
984         return findinlist_abbrev(p.netaddress, iplist);
985 }
986
987 bool PlayerInIDList(entity p, string idlist)
988 {
989         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
990         if(!p.crypto_idfp)
991                 return false;
992
993         return findinlist_abbrev(p.crypto_idfp, idlist);
994 }
995
996 bool PlayerInList(entity player, string list)
997 {
998         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
999 }
1000
1001 #ifdef DP_EXT_PRECONNECT
1002 /*
1003 =============
1004 ClientPreConnect
1005
1006 Called once (not at each match start) when a client begins a connection to the server
1007 =============
1008 */
1009 void ClientPreConnect(entity this)
1010 {
1011         if(autocvar_sv_eventlog)
1012         {
1013                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1014                         this.playerid,
1015                         etof(this),
1016                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1017                 ));
1018         }
1019 }
1020 #endif
1021
1022 void SendWelcomemessage(entity this, bool force_centerprint)
1023 {
1024         msg_entity = this;
1025         WriteHeader(MSG_ONE, TE_CSQC_SERVERWELCOME);
1026         SendWelcomemessage_msg_type(this, force_centerprint, MSG_ONE);
1027 }
1028
1029 // NOTE csqc uses the active mutators list sent by this function
1030 // to understand which mutators are enabled
1031 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1032 void SendWelcomemessage_msg_type(entity this, bool force_centerprint, int msg_type)
1033 {
1034         WriteByte(msg_type, boolean(autocvar_g_campaign));
1035         if (boolean(autocvar_g_campaign))
1036         {
1037                 WriteString(msg_type, Campaign_GetTitle());
1038                 WriteByte(msg_type, Campaign_GetLevelNum());
1039                 WriteString(msg_type, Campaign_GetMessage());
1040                 return;
1041         }
1042         WriteByte(msg_type, force_centerprint);
1043         WriteString(msg_type, autocvar_hostname);
1044         WriteString(msg_type, autocvar_g_xonoticversion);
1045         WriteByte(msg_type, CS(this).version_mismatch);
1046         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1047
1048         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1049         string modifications = M_ARGV(0, string);
1050
1051         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1052                 modifications = strcat(modifications, ", No start weapons");
1053         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1054                 modifications = strcat(modifications, ", Low gravity");
1055         if(g_weapon_stay && !g_cts)
1056                 modifications = strcat(modifications, ", Weapons stay");
1057         if(autocvar_g_jetpack)
1058                 modifications = strcat(modifications, ", Jetpack");
1059         modifications = substring(modifications, 2, strlen(modifications) - 2);
1060
1061         WriteString(msg_type, modifications);
1062
1063         WriteString(msg_type, g_weaponarena_list);
1064
1065         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1066         {
1067                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1068                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1069         }
1070
1071         WriteString(msg_type, cache_mutatormsg);
1072
1073         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1074 }
1075
1076 /**
1077 =============
1078 ClientConnect
1079
1080 Called when a client connects to the server
1081 =============
1082 */
1083 void ClientConnect(entity this)
1084 {
1085         if (Ban_MaybeEnforceBanOnce(this)) return;
1086         assert(!IS_CLIENT(this), return);
1087         this.flags |= FL_CLIENT;
1088         assert(player_count >= 0, player_count = 0);
1089
1090         TRANSMUTE(Client, this);
1091         CS(this).version_nagtime = time + 10 + random() * 10;
1092
1093         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1094
1095         bot_clientconnect(this);
1096
1097         Player_DetermineForcedTeam(this);
1098
1099         TRANSMUTE(Observer, this);
1100
1101         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1102
1103         // always track bots, don't ask for cl_allow_uidtracking
1104         if (IS_BOT_CLIENT(this))
1105                 PlayerStats_GameReport_AddPlayer(this);
1106         else
1107                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1108
1109         if (autocvar_sv_eventlog)
1110                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1111
1112         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1113
1114         stuffcmd(this, clientstuff, "\n");
1115         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1116
1117         FixClientCvars(this);
1118
1119         // get version info from player
1120         stuffcmd(this, "cmd clientversion $gameversion\n");
1121
1122         // notify about available teams
1123         if (teamplay)
1124         {
1125                 entity balance = TeamBalance_CheckAllowedTeams(this);
1126                 int t = TeamBalance_GetAllowedTeams(balance);
1127                 TeamBalance_Destroy(balance);
1128                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1129         }
1130         else
1131         {
1132                 stuffcmd(this, "set _teams_available 0\n");
1133         }
1134
1135         bot_relinkplayerlist();
1136
1137         CS(this).spectatortime = time;
1138         if (blockSpectators)
1139         {
1140                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1141         }
1142
1143         CS(this).jointime = time;
1144
1145         if (IS_REAL_CLIENT(this))
1146         {
1147                 if (g_weaponarena_weapons == WEPSET(TUBA))
1148                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1149         }
1150
1151         if (!autocvar_sv_foginterval && world.fog != "")
1152                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1153
1154         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1155                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1156                         send_CSQC_teamnagger();
1157
1158         CSQCMODEL_AUTOINIT(this);
1159
1160         CS(this).model_randomizer = random();
1161
1162         if (IS_REAL_CLIENT(this))
1163                 sv_notice_join(this);
1164
1165         this.move_qcphysics = autocvar_sv_qcphysics;
1166
1167         // update physics stats (players can spawn before physics runs)
1168         Physics_UpdateStats(this);
1169
1170         IL_EACH(g_initforplayer, it.init_for_player, {
1171                 it.init_for_player(it, this);
1172         });
1173
1174         Handicap_Initialize(this);
1175
1176         MUTATOR_CALLHOOK(ClientConnect, this);
1177
1178         if (player_count == 1)
1179                 localcmd("\nsv_hook_firstjoin\n");
1180 }
1181 /*
1182 =============
1183 ClientDisconnect
1184
1185 Called when a client disconnects from the server
1186 =============
1187 */
1188 .entity chatbubbleentity;
1189 void player_powerups_remove_all(entity this);
1190
1191 void ClientDisconnect(entity this)
1192 {
1193         assert(IS_CLIENT(this), return);
1194
1195         PlayerStats_GameReport_FinalizePlayer(this);
1196         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1197         if (CS(this).active_minigame) part_minigame(this);
1198         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1199
1200         if (autocvar_sv_eventlog)
1201                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1202
1203         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1204
1205         if(IS_SPEC(this))
1206                 SetSpectatee(this, NULL);
1207
1208         MUTATOR_CALLHOOK(ClientDisconnect, this);
1209
1210         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1211         strfree(CS_CVAR(this).weaponorder_byimpulse);
1212         ClientState_detach(this);
1213
1214         Portal_ClearAll(this);
1215
1216         Unfreeze(this, false);
1217
1218         RemoveGrapplingHooks(this);
1219
1220         // Here, everything has been done that requires this player to be a client.
1221
1222         this.flags &= ~FL_CLIENT;
1223
1224         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1225         if (this.killindicator) delete(this.killindicator);
1226
1227         IL_EACH(g_counters, it.realowner == this,
1228         {
1229                 delete(it);
1230         });
1231
1232         WaypointSprite_PlayerGone(this);
1233
1234         bot_relinkplayerlist();
1235
1236         strfree(this.clientstatus);
1237         if (this.personal) delete(this.personal);
1238
1239         this.playerid = 0;
1240         ReadyCount();
1241         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1242
1243         player_powerups_remove_all(this); // stop powerup sound
1244
1245         ONREMOVE(this);
1246
1247         if (player_count == 0)
1248                 localcmd("\nsv_hook_lastleave\n");
1249 }
1250
1251 void ChatBubbleThink(entity this)
1252 {
1253         this.nextthink = time;
1254         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1255         {
1256                 if(this.owner) // but why can that ever be NULL?
1257                         this.owner.chatbubbleentity = NULL;
1258                 delete(this);
1259                 return;
1260         }
1261
1262         this.mdl = "";
1263
1264         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1265         {
1266                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1267                         this.mdl = "models/sprites/minigame_busy.iqm";
1268                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1269                         this.mdl = "models/misc/chatbubble.spr";
1270         }
1271
1272         if ( this.model != this.mdl )
1273                 _setmodel(this, this.mdl);
1274
1275 }
1276
1277 void UpdateChatBubble(entity this)
1278 {
1279         if (this.alpha < 0)
1280                 return;
1281         // spawn a chatbubble entity if needed
1282         if (!this.chatbubbleentity)
1283         {
1284                 this.chatbubbleentity = new(chatbubbleentity);
1285                 this.chatbubbleentity.owner = this;
1286                 this.chatbubbleentity.exteriormodeltoclient = this;
1287                 setthink(this.chatbubbleentity, ChatBubbleThink);
1288                 this.chatbubbleentity.nextthink = time;
1289                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1290                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1291                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1292                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1293                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1294                 //this.chatbubbleentity.model = "";
1295                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1296         }
1297 }
1298
1299 void calculate_player_respawn_time(entity this)
1300 {
1301         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1302                 return;
1303
1304         float gametype_setting_tmp;
1305         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1306         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1307         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1308         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1309         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1310         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1311
1312         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1313         if (teamplay)
1314         {
1315                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1316                         if(it.team == this.team)
1317                                 ++pcount;
1318                 });
1319                 if (sdelay_small_count == 0)
1320                         sdelay_small_count = 1;
1321                 if (sdelay_large_count == 0)
1322                         sdelay_large_count = 1;
1323         }
1324         else
1325         {
1326                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1327                         ++pcount;
1328                 });
1329                 if (sdelay_small_count == 0)
1330                 {
1331                         if (IS_INDEPENDENT_PLAYER(this))
1332                         {
1333                                 // Players play independently. No point in requiring enemies.
1334                                 sdelay_small_count = 1;
1335                         }
1336                         else
1337                         {
1338                                 // Players play AGAINST each other. Enemies required.
1339                                 sdelay_small_count = 2;
1340                         }
1341                 }
1342                 if (sdelay_large_count == 0)
1343                 {
1344                         if (IS_INDEPENDENT_PLAYER(this))
1345                         {
1346                                 // Players play independently. No point in requiring enemies.
1347                                 sdelay_large_count = 1;
1348                         }
1349                         else
1350                         {
1351                                 // Players play AGAINST each other. Enemies required.
1352                                 sdelay_large_count = 2;
1353                         }
1354                 }
1355         }
1356
1357         float sdelay;
1358
1359         if (pcount <= sdelay_small_count)
1360                 sdelay = sdelay_small;
1361         else if (pcount >= sdelay_large_count)
1362                 sdelay = sdelay_large;
1363         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1364                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1365
1366         if(waves)
1367                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1368         else
1369                 this.respawn_time = time + sdelay;
1370
1371         if(sdelay < sdelay_max)
1372                 this.respawn_time_max = time + sdelay_max;
1373         else
1374                 this.respawn_time_max = this.respawn_time;
1375
1376         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1377                 this.respawn_countdown = 10; // first number to count down from is 10
1378         else
1379                 this.respawn_countdown = -1; // do not count down
1380
1381         if(autocvar_g_forced_respawn)
1382                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1383 }
1384
1385 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1386 // added to the model skins
1387 /*void UpdateColorModHack()
1388 {
1389         float c;
1390         c = this.clientcolors & 15;
1391         // LordHavoc: only bothering to support white, green, red, yellow, blue
1392              if (!teamplay) this.colormod = '0 0 0';
1393         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1394         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1395         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1396         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1397         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1398         else this.colormod = '1 1 1';
1399 }*/
1400
1401 void respawn(entity this)
1402 {
1403         bool damagedbycontents_prev = this.damagedbycontents;
1404         if(this.alpha >= 0)
1405         {
1406                 if(autocvar_g_respawn_ghosts)
1407                 {
1408                         this.solid = SOLID_NOT;
1409                         this.takedamage = DAMAGE_NO;
1410                         this.damagedbycontents = false;
1411                         set_movetype(this, MOVETYPE_FLY);
1412                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1413                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1414                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1415                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1416                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1417                         if(autocvar_g_respawn_ghosts_time > 0)
1418                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1419                 }
1420                 else
1421                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1422         }
1423
1424         CopyBody(this, 1);
1425         this.damagedbycontents = damagedbycontents_prev;
1426
1427         this.effects |= EF_NODRAW; // prevent another CopyBody
1428         PutClientInServer(this);
1429 }
1430
1431 void play_countdown(entity this, float finished, Sound samp)
1432 {
1433         TC(Sound, samp);
1434         float time_left = finished - time;
1435         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1436                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1437 }
1438
1439 // it removes special powerups not handled by StatusEffects
1440 void player_powerups_remove_all(entity this)
1441 {
1442         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1443         {
1444                 // don't play the poweroff sound when the game restarts or the player disconnects
1445                 if (time > game_starttime + 1 && IS_CLIENT(this)
1446                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1447                 {
1448                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1449                 }
1450                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1451                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1452                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1453         }
1454 }
1455
1456 void player_powerups(entity this)
1457 {
1458         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1459                 this.modelflags |= MF_ROCKET;
1460         else
1461                 this.modelflags &= ~MF_ROCKET;
1462
1463         this.effects &= ~EF_NODEPTHTEST;
1464
1465         if (IS_DEAD(this))
1466                 player_powerups_remove_all(this);
1467
1468         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1469                 return;
1470
1471         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1472         int items_prev = this.items;
1473
1474         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1475         {
1476                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1477                 if (this.items & IT_SUPERWEAPON)
1478                 {
1479                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1480                         {
1481                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1482                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1483                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1484                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1485                         }
1486                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1487                         {
1488                                 // don't let them run out
1489                         }
1490                         else
1491                         {
1492                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1493                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1494                                 {
1495                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1496                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1497                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1498                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1499                                 }
1500                         }
1501                 }
1502                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1503                 {
1504                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1505                         {
1506                                 this.items = this.items | IT_SUPERWEAPON;
1507                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1508                                 {
1509                                         if(!g_cts)
1510                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1511                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1512                                 }
1513                         }
1514                         else
1515                         {
1516                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1517                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1518                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1519                         }
1520                 }
1521                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1522                 {
1523                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1524                 }
1525         }
1526
1527         if(autocvar_g_nodepthtestplayers)
1528                 this.effects = this.effects | EF_NODEPTHTEST;
1529
1530         if(autocvar_g_fullbrightplayers)
1531                 this.effects = this.effects | EF_FULLBRIGHT;
1532
1533         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1534 }
1535
1536 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1537 {
1538         if(current > stable)
1539                 return current;
1540         else if(current > stable - 0.25) // when close enough, "snap"
1541                 return stable;
1542         else
1543                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1544 }
1545
1546 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1547 {
1548         if(current < stable)
1549                 return current;
1550         else if(current < stable + 0.25) // when close enough, "snap"
1551                 return stable;
1552         else
1553                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1554 }
1555
1556 void RotRegen(entity this, Resource res, float limit_mod,
1557         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1558         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1559 {
1560         float old = GetResource(this, res);
1561         float current = old;
1562         if(current > rotstable)
1563         {
1564                 if(rotframetime > 0)
1565                 {
1566                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1567                         current = max(rotstable, current - rotlinear * rotframetime);
1568                 }
1569         }
1570         else if(current < regenstable)
1571         {
1572                 if(regenframetime > 0)
1573                 {
1574                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1575                         current = min(regenstable, current + regenlinear * regenframetime);
1576                 }
1577         }
1578
1579         float limit = GetResourceLimit(this, res) * limit_mod;
1580         if(current > limit)
1581                 current = limit;
1582
1583         if (current != old)
1584                 SetResource(this, res, current);
1585 }
1586
1587 void player_regen(entity this)
1588 {
1589         float max_mod, regen_mod, rot_mod, limit_mod;
1590         max_mod = regen_mod = rot_mod = limit_mod = 1;
1591
1592         float regen_health = autocvar_g_balance_health_regen;
1593         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1594         float regen_health_rot = autocvar_g_balance_health_rot;
1595         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1596         float regen_health_stable = autocvar_g_balance_health_regenstable;
1597         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1598         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1599                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1600         max_mod = M_ARGV(1, float);
1601         regen_mod = M_ARGV(2, float);
1602         rot_mod = M_ARGV(3, float);
1603         limit_mod = M_ARGV(4, float);
1604         regen_health = M_ARGV(5, float);
1605         regen_health_linear = M_ARGV(6, float);
1606         regen_health_rot = M_ARGV(7, float);
1607         regen_health_rotlinear = M_ARGV(8, float);
1608         regen_health_stable = M_ARGV(9, float);
1609         regen_health_rotstable = M_ARGV(10, float);
1610
1611         float rotstable, regenstable, rotframetime, regenframetime;
1612
1613         if(!mutator_returnvalue)
1614         if(!STAT(FROZEN, this))
1615         {
1616                 regenstable = autocvar_g_balance_armor_regenstable;
1617                 rotstable = autocvar_g_balance_armor_rotstable;
1618                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1619                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1620                 RotRegen(this, RES_ARMOR, limit_mod,
1621                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1622                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1623
1624                 // NOTE: max_mod is only applied to health
1625                 regenstable = regen_health_stable * max_mod;
1626                 rotstable = regen_health_rotstable * max_mod;
1627                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1628                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1629                 RotRegen(this, RES_HEALTH, limit_mod,
1630                         regenstable, regen_health, regen_health_linear, regenframetime,
1631                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1632         }
1633
1634         // if player rotted to death...  die!
1635         // check this outside above checks, as player may still be able to rot to death
1636         if(GetResource(this, RES_HEALTH) < 1)
1637         {
1638                 if(this.vehicle)
1639                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1640                 if(this.event_damage)
1641                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1642         }
1643
1644         if (!(this.items & IT_UNLIMITED_AMMO))
1645         {
1646                 regenstable = autocvar_g_balance_fuel_regenstable;
1647                 rotstable = autocvar_g_balance_fuel_rotstable;
1648                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1649                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1650                 RotRegen(this, RES_FUEL, 1,
1651                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1652                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1653         }
1654 }
1655
1656 bool zoomstate_set;
1657 void SetZoomState(entity this, float newzoom)
1658 {
1659         if(newzoom != CS(this).zoomstate)
1660         {
1661                 CS(this).zoomstate = newzoom;
1662                 ClientData_Touch(this);
1663         }
1664         zoomstate_set = true;
1665 }
1666
1667 void GetPressedKeys(entity this)
1668 {
1669         MUTATOR_CALLHOOK(GetPressedKeys, this);
1670         if (game_stopped)
1671         {
1672                 CS(this).pressedkeys = 0;
1673                 STAT(PRESSED_KEYS, this) = 0;
1674                 return;
1675         }
1676
1677         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1678         int keys = STAT(PRESSED_KEYS, this);
1679         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1680         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1681         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1682         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1683
1684         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1685         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1686         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1687         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1688         CS(this).pressedkeys = keys; // store for other users
1689
1690         STAT(PRESSED_KEYS, this) = keys;
1691 }
1692
1693 /*
1694 ======================
1695 spectate mode routines
1696 ======================
1697 */
1698
1699 void SpectateCopy(entity this, entity spectatee)
1700 {
1701         TC(Client, this); TC(Client, spectatee);
1702
1703         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1704         PS(this) = PS(spectatee);
1705         this.armortype = spectatee.armortype;
1706         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1707         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1708         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1709         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1710         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1711         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1712         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1713         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1714         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1715         CS(this).impulse = 0;
1716         this.disableclientprediction = 1; // no need to run prediction on a spectator
1717         this.items = spectatee.items;
1718         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1719         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1720         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1721         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1722         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1723         this.punchangle = spectatee.punchangle;
1724         this.view_ofs = spectatee.view_ofs;
1725         this.velocity = spectatee.velocity;
1726         this.dmg_take = spectatee.dmg_take;
1727         this.dmg_save = spectatee.dmg_save;
1728         this.dmg_inflictor = spectatee.dmg_inflictor;
1729         this.v_angle = spectatee.v_angle;
1730         this.angles = spectatee.v_angle;
1731         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1732         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1733         this.viewloc = spectatee.viewloc;
1734         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1735                 this.fixangle = true;
1736         setorigin(this, spectatee.origin);
1737         setsize(this, spectatee.mins, spectatee.maxs);
1738         SetZoomState(this, CS(spectatee).zoomstate);
1739
1740     anticheat_spectatecopy(this, spectatee);
1741         STAT(HUD, this) = STAT(HUD, spectatee);
1742         if(spectatee.vehicle)
1743     {
1744         this.angles = spectatee.v_angle;
1745
1746         //this.fixangle = false;
1747         //this.velocity = spectatee.vehicle.velocity;
1748         this.vehicle_health = spectatee.vehicle_health;
1749         this.vehicle_shield = spectatee.vehicle_shield;
1750         this.vehicle_energy = spectatee.vehicle_energy;
1751         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1752         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1753         this.vehicle_reload1 = spectatee.vehicle_reload1;
1754         this.vehicle_reload2 = spectatee.vehicle_reload2;
1755
1756         //msg_entity = this;
1757
1758        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1759             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1760            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1761            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1762
1763         //WriteByte (MSG_ONE, SVC_SETVIEW);
1764         //    WriteEntity(MSG_ONE, this);
1765         //makevectors(spectatee.v_angle);
1766         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1767     }
1768 }
1769
1770 bool SpectateUpdate(entity this)
1771 {
1772         if(!this.enemy)
1773                 return false;
1774
1775         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1776         {
1777                 SetSpectatee(this, NULL);
1778                 return false;
1779         }
1780
1781         SpectateCopy(this, this.enemy);
1782
1783         return true;
1784 }
1785
1786 bool SpectateSet(entity this)
1787 {
1788         if(!IS_PLAYER(this.enemy))
1789                 return false;
1790
1791         ClientData_Touch(this.enemy);
1792
1793         msg_entity = this;
1794         WriteByte(MSG_ONE, SVC_SETVIEW);
1795         WriteEntity(MSG_ONE, this.enemy);
1796         set_movetype(this, MOVETYPE_NONE);
1797         accuracy_resend(this);
1798
1799         if(!SpectateUpdate(this))
1800                 PutObserverInServer(this, false, true);
1801
1802         return true;
1803 }
1804
1805 void SetSpectatee_status(entity this, int spectatee_num)
1806 {
1807         int oldspectatee_status = CS(this).spectatee_status;
1808         CS(this).spectatee_status = spectatee_num;
1809
1810         if (CS(this).spectatee_status != oldspectatee_status)
1811         {
1812                 if (STAT(PRESSED_KEYS, this))
1813                 {
1814                         CS(this).pressedkeys = 0;
1815                         STAT(PRESSED_KEYS, this) = 0;
1816                 }
1817                 ClientData_Touch(this);
1818                 if (g_race || g_cts) race_InitSpectator();
1819         }
1820 }
1821
1822 void SetSpectatee(entity this, entity spectatee)
1823 {
1824         if(IS_BOT_CLIENT(this))
1825                 return; // bots abuse .enemy, this code is useless to them
1826
1827         entity old_spectatee = this.enemy;
1828
1829         this.enemy = spectatee;
1830
1831         // WEAPONTODO
1832         // these are required to fix the spectator bug with arc
1833         if(old_spectatee)
1834         {
1835                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1836                 {
1837                         .entity weaponentity = weaponentities[slot];
1838                         if(old_spectatee.(weaponentity).arc_beam)
1839                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1840                 }
1841         }
1842         if(spectatee)
1843         {
1844                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1845                 {
1846                         .entity weaponentity = weaponentities[slot];
1847                         if(spectatee.(weaponentity).arc_beam)
1848                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1849                 }
1850         }
1851
1852         if (spectatee)
1853                 SetSpectatee_status(this, etof(spectatee));
1854
1855         // needed to update spectator list
1856         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1857 }
1858
1859 bool Spectate(entity this, entity pl)
1860 {
1861         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1862                 return false;
1863         pl = M_ARGV(1, entity);
1864
1865         SetSpectatee(this, pl);
1866         return SpectateSet(this);
1867 }
1868
1869 bool SpectateNext(entity this)
1870 {
1871         entity ent = find(this.enemy, classname, STR_PLAYER);
1872
1873         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1874                 ent = M_ARGV(1, entity);
1875         else if (!ent)
1876                 ent = find(ent, classname, STR_PLAYER);
1877
1878         if(ent) { SetSpectatee(this, ent); }
1879
1880         return SpectateSet(this);
1881 }
1882
1883 bool SpectatePrev(entity this)
1884 {
1885         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1886         entity ent = findchain(classname, STR_PLAYER);
1887         if (!ent) // no player
1888                 return false;
1889
1890         entity first = ent;
1891         // skip players until current spectated player
1892         if(this.enemy)
1893         while(ent && ent != this.enemy)
1894                 ent = ent.chain;
1895
1896         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1897         {
1898                 case MUT_SPECPREV_FOUND:
1899                         ent = M_ARGV(1, entity);
1900                         break;
1901                 case MUT_SPECPREV_RETURN:
1902                         return true;
1903                 case MUT_SPECPREV_CONTINUE:
1904                 default:
1905                 {
1906                         if(ent.chain)
1907                                 ent = ent.chain;
1908                         else
1909                                 ent = first;
1910                         break;
1911                 }
1912         }
1913
1914         SetSpectatee(this, ent);
1915         return SpectateSet(this);
1916 }
1917
1918 /*
1919 =============
1920 ShowRespawnCountdown()
1921
1922 Update a respawn countdown display.
1923 =============
1924 */
1925 void ShowRespawnCountdown(entity this)
1926 {
1927         float number;
1928         if(!IS_DEAD(this)) // just respawned?
1929                 return;
1930         else
1931         {
1932                 number = ceil(this.respawn_time - time);
1933                 if(number <= 0)
1934                         return;
1935                 if(number <= this.respawn_countdown)
1936                 {
1937                         this.respawn_countdown = number - 1;
1938                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1939                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1940                 }
1941         }
1942 }
1943
1944 .bool team_selected;
1945 bool ShowTeamSelection(entity this)
1946 {
1947         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1948                 return false;
1949         stuffcmd(this, "menu_showteamselect\n");
1950         return true;
1951 }
1952 void Join(entity this)
1953 {
1954         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1955                 ReadyRestart(true);
1956
1957         TRANSMUTE(Player, this);
1958
1959         if(!this.team_selected)
1960         if(autocvar_g_campaign || autocvar_g_balance_teams)
1961                 TeamBalance_JoinBestTeam(this);
1962
1963         if(autocvar_g_campaign)
1964                 campaign_bots_may_start = true;
1965
1966         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1967
1968         PutClientInServer(this);
1969
1970         if(IS_PLAYER(this))
1971         if(teamplay && this.team != -1)
1972         {
1973         }
1974         else
1975                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1976         this.team_selected = false;
1977 }
1978
1979 int GetPlayerLimit()
1980 {
1981         if(g_duel)
1982                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1983         int player_limit = autocvar_g_maxplayers;
1984         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1985         player_limit = M_ARGV(0, int);
1986         return player_limit;
1987 }
1988
1989 /**
1990  * Determines whether the player is allowed to join. This depends on cvar
1991  * g_maxplayers, if it isn't used this function always return true, otherwise
1992  * it checks whether the number of currently playing players exceeds g_maxplayers.
1993  * @return int number of free slots for players, 0 if none
1994  */
1995 int nJoinAllowed(entity this, entity ignore)
1996 {
1997         if(!ignore)
1998         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1999         // so report 0 free slots if restricted
2000         {
2001                 if(autocvar_g_forced_team_otherwise == "spectate")
2002                         return 0;
2003                 if(autocvar_g_forced_team_otherwise == "spectator")
2004                         return 0;
2005         }
2006
2007         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2008                 return 0; // forced spectators can never join
2009
2010         // TODO simplify this
2011         int totalClients = 0;
2012         int currentlyPlaying = 0;
2013         FOREACH_CLIENT(true, {
2014                 if(it != ignore)
2015                         ++totalClients;
2016                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2017                         ++currentlyPlaying;
2018         });
2019
2020         int player_limit = GetPlayerLimit();
2021
2022         int free_slots = 0;
2023         if (!player_limit)
2024                 free_slots = maxclients - totalClients;
2025         else if(player_limit > 0 && currentlyPlaying < player_limit)
2026                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2027
2028         static float msg_time = 0;
2029         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2030         {
2031                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2032                 msg_time = time + 0.5;
2033         }
2034
2035         return free_slots;
2036 }
2037
2038 bool joinAllowed(entity this)
2039 {
2040         if (CS(this).version_mismatch) return false;
2041         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2042         if (!nJoinAllowed(this, this)) return false;
2043         if (teamplay && lockteams) return false;
2044         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2045         if (ShowTeamSelection(this)) return false;
2046         return true;
2047 }
2048
2049 .string shootfromfixedorigin;
2050 .bool dualwielding_prev;
2051 bool PlayerThink(entity this)
2052 {
2053         if (game_stopped || intermission_running) {
2054                 this.modelflags &= ~MF_ROCKET;
2055                 if(intermission_running)
2056                         IntermissionThink(this);
2057                 return false;
2058         }
2059
2060         if (timeout_status == TIMEOUT_ACTIVE) {
2061                 // don't allow the player to turn around while game is paused
2062                 // FIXME turn this into CSQC stuff
2063                 this.v_angle = this.lastV_angle;
2064                 this.angles = this.lastV_angle;
2065                 this.fixangle = true;
2066         }
2067
2068         if (frametime) player_powerups(this);
2069
2070         if (IS_DEAD(this)) {
2071                 if (this.personal && g_race_qualifying) {
2072                         if (time > this.respawn_time) {
2073                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2074                                 respawn(this);
2075                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2076                         }
2077                 } else {
2078                         if (frametime) player_anim(this);
2079
2080                         if (this.respawn_flags & RESPAWN_DENY)
2081                         {
2082                                 STAT(RESPAWN_TIME, this) = 0;
2083                                 return false;
2084                         }
2085
2086                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2087
2088                         switch(this.deadflag)
2089                         {
2090                                 case DEAD_DYING:
2091                                 {
2092                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2093                                                 this.deadflag = DEAD_RESPAWNING;
2094                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2095                                                 this.deadflag = DEAD_DEAD;
2096                                         break;
2097                                 }
2098                                 case DEAD_DEAD:
2099                                 {
2100                                         if (button_pressed)
2101                                                 this.deadflag = DEAD_RESPAWNABLE;
2102                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2103                                                 this.deadflag = DEAD_RESPAWNING;
2104                                         break;
2105                                 }
2106                                 case DEAD_RESPAWNABLE:
2107                                 {
2108                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2109                                                 this.deadflag = DEAD_RESPAWNING;
2110                                         break;
2111                                 }
2112                                 case DEAD_RESPAWNING:
2113                                 {
2114                                         if (time > this.respawn_time)
2115                                         {
2116                                                 this.respawn_time = time + 1; // only retry once a second
2117                                                 this.respawn_time_max = this.respawn_time;
2118                                                 respawn(this);
2119                                         }
2120                                         break;
2121                                 }
2122                         }
2123
2124                         ShowRespawnCountdown(this);
2125
2126                         if (this.respawn_flags & RESPAWN_SILENT)
2127                                 STAT(RESPAWN_TIME, this) = 0;
2128                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2129                         {
2130                                 if (time < this.respawn_time)
2131                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2132                                 else if (this.deadflag != DEAD_RESPAWNING)
2133                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2134                         }
2135                         else
2136                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2137                 }
2138
2139                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2140                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2141                         STAT(RESPAWN_TIME, this) *= -1;
2142
2143                 return false;
2144         }
2145
2146         FixPlayermodel(this);
2147
2148         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2149                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2150                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2151         }
2152
2153         // reset gun alignment when dual wielding status changes
2154         // to ensure guns are always aligned right and left
2155         bool dualwielding = W_DualWielding(this);
2156         if(this.dualwielding_prev != dualwielding)
2157         {
2158                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2159                 this.dualwielding_prev = dualwielding;
2160         }
2161
2162         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2163         //if(frametime)
2164         {
2165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2166                 {
2167                         .entity weaponentity = weaponentities[slot];
2168                         if(WEP_CVAR(vortex, charge_always))
2169                                 W_Vortex_Charge(this, weaponentity, frametime);
2170                         W_WeaponFrame(this, weaponentity);
2171                 }
2172         }
2173
2174         if (frametime)
2175         {
2176                 // WEAPONTODO: Add a weapon request for this
2177                 // rot vortex charge to the charge limit
2178                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2179                 {
2180                         .entity weaponentity = weaponentities[slot];
2181                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2182                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2183                 }
2184
2185                 player_regen(this);
2186                 player_anim(this);
2187                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2188         }
2189
2190         monsters_setstatus(this);
2191
2192         return true;
2193 }
2194
2195 .bool would_spectate;
2196 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2197 void ObserverOrSpectatorThink(entity this)
2198 {
2199         bool is_spec = IS_SPEC(this);
2200         if ( CS(this).impulse )
2201         {
2202                 int r = MinigameImpulse(this, CS(this).impulse);
2203                 if (!is_spec || r)
2204                         CS(this).impulse = 0;
2205
2206                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2207                 {
2208                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2209                         CS(this).impulse = 0;
2210                         return;
2211                 }
2212         }
2213
2214         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2215         {
2216                 CS(this).autojoin_checked = true;
2217                 TRANSMUTE(Player, this);
2218                 PutClientInServer(this);
2219                 return;
2220         }
2221
2222         if (this.flags & FL_JUMPRELEASED) {
2223                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2224                         this.flags &= ~FL_JUMPRELEASED;
2225                         this.flags |= FL_SPAWNING;
2226                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2227                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2228                         this.flags &= ~FL_JUMPRELEASED;
2229                         if(SpectateNext(this)) {
2230                                 TRANSMUTE(Spectator, this);
2231                         } else if (is_spec) {
2232                                 TRANSMUTE(Observer, this);
2233                                 PutClientInServer(this);
2234                         }
2235                         else
2236                                 this.would_spectate = false; // unable to spectate anyone
2237                         if (is_spec)
2238                                 CS(this).impulse = 0;
2239                 } else if (is_spec) {
2240                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2241                                 this.flags &= ~FL_JUMPRELEASED;
2242                                 if(SpectatePrev(this)) {
2243                                         TRANSMUTE(Spectator, this);
2244                                 } else {
2245                                         TRANSMUTE(Observer, this);
2246                                         PutClientInServer(this);
2247                                 }
2248                                 CS(this).impulse = 0;
2249                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2250                                 this.would_spectate = false;
2251                                 this.flags &= ~FL_JUMPRELEASED;
2252                                 TRANSMUTE(Observer, this);
2253                                 PutClientInServer(this);
2254                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2255                                 PutObserverInServer(this, false, true);
2256                                 this.would_spectate = true;
2257                         }
2258                 }
2259                 else {
2260                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2261                         if (PHYS_INPUT_BUTTON_USE(this))
2262                                 wouldclip = !wouldclip;
2263                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2264                         set_movetype(this, preferred_movetype);
2265                 }
2266         } else { // jump pressed
2267                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2268                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2269                         this.flags |= FL_JUMPRELEASED;
2270                         if(this.flags & FL_SPAWNING)
2271                         {
2272                                 this.flags &= ~FL_SPAWNING;
2273                                 if(joinAllowed(this))
2274                                         Join(this);
2275                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2276                                         CS(this).autojoin_checked = -1;
2277                                 return;
2278                         }
2279                 }
2280                 if(is_spec && !SpectateUpdate(this))
2281                         PutObserverInServer(this, false, true);
2282         }
2283         if (is_spec)
2284                 this.flags |= FL_CLIENT | FL_NOTARGET;
2285 }
2286
2287 void PlayerUseKey(entity this)
2288 {
2289         if (!IS_PLAYER(this))
2290                 return;
2291
2292         if(this.vehicle)
2293         {
2294                 if(!game_stopped)
2295                 {
2296                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2297                         return;
2298                 }
2299         }
2300         else if(autocvar_g_vehicles_enter)
2301         {
2302                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2303                 {
2304                         entity head, closest_target = NULL;
2305                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2306
2307                         while(head) // find the closest acceptable target to enter
2308                         {
2309                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2310                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2311                                 {
2312                                         if(closest_target)
2313                                         {
2314                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2315                                                 { closest_target = head; }
2316                                         }
2317                                         else { closest_target = head; }
2318                                 }
2319
2320                                 head = head.chain;
2321                         }
2322
2323                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2324                 }
2325         }
2326
2327         // a use key was pressed; call handlers
2328         MUTATOR_CALLHOOK(PlayerUseKey, this);
2329 }
2330
2331
2332 /*
2333 =============
2334 PlayerPreThink
2335
2336 Called every frame for each client before the physics are run
2337 =============
2338 */
2339 .float last_vehiclecheck;
2340 void PlayerPreThink (entity this)
2341 {
2342         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2343         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2344
2345         WarpZone_PlayerPhysics_FixVAngle(this);
2346
2347         if (frametime) {
2348                 // physics frames: update anticheat stuff
2349                 anticheat_prethink(this);
2350
2351                 // WORKAROUND: only use dropclient in server frames (frametime set).
2352                 // Never use it in cl_movement frames (frametime zero).
2353                 if (blockSpectators && IS_REAL_CLIENT(this)
2354                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2355                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2356                 {
2357                         if (dropclient_schedule(this))
2358                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2359                 }
2360         }
2361
2362         zoomstate_set = false;
2363
2364         // Check for nameless players
2365         if (this.netname == "" || this.netname != CS(this).netname_previous)
2366         {
2367                 bool assume_unchanged = (CS(this).netname_previous == "");
2368                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2369                 {
2370                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2371                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2372                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2373                         assume_unchanged = false;
2374                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2375                 }
2376                 if (isInvisibleString(this.netname))
2377                 {
2378                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2379                         sprint(this, "Warning: invisible names are not allowed.\n");
2380                         assume_unchanged = false;
2381                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2382                 }
2383                 if (!assume_unchanged && autocvar_sv_eventlog)
2384                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2385                 strcpy(CS(this).netname_previous, this.netname);
2386         }
2387
2388         // version nagging
2389         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2390         CS(this).version_nagtime = 0;
2391         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2392             // git client
2393         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2394             // git server
2395             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2396         } else {
2397             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2398             if (r < 0) { // old client
2399                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2400             } else if (r > 0) { // old server
2401                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2402             }
2403         }
2404     }
2405
2406         // GOD MODE info
2407         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2408         {
2409                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2410                 this.max_armorvalue = 0;
2411         }
2412
2413         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2414         {
2415                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2416                 {
2417                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2418                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2419                         if (this.iceblock)
2420                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2421
2422                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2423                                 Unfreeze(this, false);
2424                 }
2425                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2426                 {
2427                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2428                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2429
2430                         if (GetResource(this, RES_HEALTH) < 1)
2431                         {
2432                                 if (this.vehicle)
2433                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2434                                 if(this.event_damage)
2435                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2436                         }
2437                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2438                                 Unfreeze(this, false);
2439                 }
2440         }
2441
2442         MUTATOR_CALLHOOK(PlayerPreThink, this);
2443
2444         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2445         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2446         {
2447                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2448                 {
2449                         if(!it.owner)
2450                         {
2451                                 if(!it.team || SAME_TEAM(this, it))
2452                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2453                                 else if(autocvar_g_vehicles_steal)
2454                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2455                         }
2456                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2457                         {
2458                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2459                         }
2460                 });
2461
2462                 this.last_vehiclecheck = time + 1;
2463         }
2464
2465         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2466                 PlayerUseKey(this);
2467         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2468
2469         if (IS_PLAYER(this)) {
2470                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2471                         error("Client can't be spawned as player on connection!");
2472                 if(!PlayerThink(this))
2473                         return;
2474         }
2475         else if (game_stopped || intermission_running) {
2476                 if(intermission_running)
2477                         IntermissionThink(this);
2478                 return;
2479         }
2480         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2481         {
2482                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2483                 CS(this).autojoin_checked = 1;
2484                 // don't do this in ClientConnect
2485                 // many things can go wrong if a client is spawned as player on connection
2486                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2487                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2488                                 && (!teamplay || autocvar_g_balance_teams)))
2489                 {
2490                         if(joinAllowed(this))
2491                                 Join(this);
2492                         return;
2493                 }
2494         }
2495         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2496                 ObserverOrSpectatorThink(this);
2497         }
2498
2499         // WEAPONTODO: Add weapon request for this
2500         if (!zoomstate_set) {
2501                 bool wep_zoomed = false;
2502                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2503                 {
2504                         .entity weaponentity = weaponentities[slot];
2505                         Weapon thiswep = this.(weaponentity).m_weapon;
2506                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2507                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2508                 }
2509                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2510         }
2511
2512         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2513         {
2514                 CS(this).teamkill_soundtime = 0;
2515
2516                 entity e = CS(this).teamkill_soundsource;
2517                 entity oldpusher = e.pusher;
2518                 e.pusher = this;
2519                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2520                 e.pusher = oldpusher;
2521         }
2522
2523         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2524                 CS(this).taunt_soundtime = 0;
2525                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2526         }
2527
2528         target_voicescript_next(this);
2529 }
2530
2531 void DrownPlayer(entity this)
2532 {
2533         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2534                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2535         {
2536                 STAT(AIR_FINISHED, this) = 0;
2537                 return;
2538         }
2539
2540         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2541         {
2542                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2543                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2544                 STAT(AIR_FINISHED, this) = 0;
2545         }
2546         else
2547         {
2548                 if (!STAT(AIR_FINISHED, this))
2549                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2550                 if (STAT(AIR_FINISHED, this) < time)
2551                 {       // drown!
2552                         if (this.pain_finished < time)
2553                         {
2554                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2555                                 this.pain_finished = time + 0.5;
2556                         }
2557                 }
2558         }
2559 }
2560
2561 .bool move_qcphysics;
2562
2563 void Player_Physics(entity this)
2564 {
2565         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2566
2567         if(!this.move_qcphysics)
2568                 return;
2569
2570         if(!frametime && !CS(this).pm_frametime)
2571                 return;
2572
2573         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2574
2575         CS(this).pm_frametime = 0;
2576 }
2577
2578 /*
2579 =============
2580 PlayerPostThink
2581
2582 Called every frame for each client after the physics are run
2583 =============
2584 */
2585 void PlayerPostThink (entity this)
2586 {
2587         Player_Physics(this);
2588
2589         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2590         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2591         if (IS_REAL_CLIENT(this))
2592         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2593         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2594         {
2595                 int totalClients = 0;
2596                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2597                 {
2598                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2599                         if (server_is_dedicated)
2600                         {
2601                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2602                                 {
2603                                         ++totalClients;
2604                                 });
2605                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2606                                         totalClients = 0;
2607                         }
2608                 }
2609                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2610                 {
2611                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2612                         {
2613                                 ++totalClients;
2614                         });
2615                 }
2616
2617                 if (totalClients < autocvar_sv_maxidle_minplayers)
2618                 {
2619                         // idle kick disabled
2620                         CS(this).parm_idlesince = time;
2621                 }
2622                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2623                 {
2624                         if (CS(this).idlekick_lasttimeleft)
2625                         {
2626                                 CS(this).idlekick_lasttimeleft = 0;
2627                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2628                         }
2629                 }
2630                 else
2631                 {
2632                         float maxidle_time = autocvar_sv_maxidle;
2633                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2634                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2635                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2636                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2637                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2638                         {
2639                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2640                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2641                                 else
2642                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2643                         }
2644                         if (timeleft <= 0) {
2645                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2646                                 {
2647                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2648                                         PutObserverInServer(this, true, true);
2649                                 }
2650                                 else
2651                                 {
2652                                         if (dropclient_schedule(this))
2653                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2654                                 }
2655                                 return;
2656                         }
2657                         else if (timeleft <= countdown_time) {
2658                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2659                                         play2(this, SND(TALK2));
2660                                 CS(this).idlekick_lasttimeleft = timeleft;
2661                         }
2662                 }
2663         }
2664
2665         CheatFrame(this);
2666
2667         if (game_stopped)
2668         {
2669                 this.solid = SOLID_NOT;
2670                 this.takedamage = DAMAGE_NO;
2671                 set_movetype(this, MOVETYPE_NONE);
2672                 CS(this).teamkill_complain = 0;
2673                 CS(this).teamkill_soundtime = 0;
2674                 CS(this).teamkill_soundsource = NULL;
2675         }
2676
2677         if (IS_PLAYER(this)) {
2678                 if(this.death_time == time && IS_DEAD(this))
2679                 {
2680                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2681                         // once all the damage events of this frame have been processed with normal size
2682                         this.maxs.z = 5;
2683                         setsize(this, this.mins, this.maxs);
2684                 }
2685                 DrownPlayer(this);
2686                 UpdateChatBubble(this);
2687                 if (CS(this).impulse) ImpulseCommands(this);
2688                 GetPressedKeys(this);
2689                 if (game_stopped)
2690                 {
2691                         CSQCMODEL_AUTOUPDATE(this);
2692                         return;
2693                 }
2694         }
2695         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2696         {
2697                 CS(this).pressedkeys = 0;
2698                 STAT(PRESSED_KEYS, this) = 0;
2699         }
2700
2701         if (this.waypointsprite_attachedforcarrier) {
2702                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2703                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2704         }
2705
2706         CSQCMODEL_AUTOUPDATE(this);
2707 }
2708
2709 // hack to copy the button fields from the client entity to the Client State
2710 void PM_UpdateButtons(entity this, entity store)
2711 {
2712         if(this.impulse)
2713                 store.impulse = this.impulse;
2714         this.impulse = 0;
2715
2716         bool typing = this.buttonchat || this.button12;
2717
2718         store.button0 = (typing) ? 0 : this.button0;
2719         //button1?!
2720         store.button2 = (typing) ? 0 : this.button2;
2721         store.button3 = (typing) ? 0 : this.button3;
2722         store.button4 = this.button4;
2723         store.button5 = (typing) ? 0 : this.button5;
2724         store.button6 = this.button6;
2725         store.button7 = this.button7;
2726         store.button8 = this.button8;
2727         store.button9 = this.button9;
2728         store.button10 = this.button10;
2729         store.button11 = this.button11;
2730         store.button12 = this.button12;
2731         store.button13 = this.button13;
2732         store.button14 = this.button14;
2733         store.button15 = this.button15;
2734         store.button16 = this.button16;
2735         store.buttonuse = this.buttonuse;
2736         store.buttonchat = this.buttonchat;
2737
2738         store.cursor_active = this.cursor_active;
2739         store.cursor_screen = this.cursor_screen;
2740         store.cursor_trace_start = this.cursor_trace_start;
2741         store.cursor_trace_endpos = this.cursor_trace_endpos;
2742         store.cursor_trace_ent = this.cursor_trace_ent;
2743
2744         store.ping = this.ping;
2745         store.ping_packetloss = this.ping_packetloss;
2746         store.ping_movementloss = this.ping_movementloss;
2747
2748         store.v_angle = this.v_angle;
2749         store.movement = this.movement;
2750 }
2751
2752 NET_HANDLE(fpsreport, bool)
2753 {
2754         int fps = ReadShort();
2755         PlayerScore_Set(sender, SP_FPS, fps);
2756         return true;
2757 }