qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/miscfunctions.qh>
   6 #include <common/effects/all.qh>
   7 #include "anticheat.qh"
   8 #include "impulse.qh"
   9 #include "player.qh"
  10 #include "ipban.qh"
  11 #include "miscfunctions.qh"
  12 #include "portals.qh"
  13 #include "teamplay.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "damage.qh"
  17 #include "handicap.qh"
  18 #include "hook.qh"
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "clientkill.qh"
  22 #include "cheats.qh"
  23 #include "world.qh"
  24 #include <server/gamelog.qh>
  25 #include "race.qh"
  26 #include <server/main.qh>
  27 #include "antilag.qh"
  28 #include "campaign.qh"
  29 #include "command/common.qh"
  30 #include "scores_rules.qh"
  31 #include "weapons/common.qh"
  32
  33 #include "bot/api.qh"
  34
  35 #include "../common/ent_cs.qh"
  36 #include "../common/wepent.qh"
  37 #include <common/state.qh>
  38
  39 #include "compat/quake3.qh"
  40
  41 #include <common/effects/qc/globalsound.qh>
  42
  43 #include "../common/mapobjects/func/conveyor.qh"
  44 #include <common/mapobjects/func/ladder.qh>
  45 #include "../common/mapobjects/teleporters.qh"
  46 #include "../common/mapobjects/target/spawnpoint.qh"
  47 #include <common/mapobjects/trigger/counter.qh>
  48 #include <common/mapobjects/trigger/swamp.qh>
  49
  50 #include "../common/vehicles/all.qh"
  51
  52 #include "weapons/hitplot.qh"
  53 #include "weapons/selection.qh"
  54 #include "weapons/weaponsystem.qh"
  55
  56 #include "../common/net_notice.qh"
  57 #include "../common/net_linked.qh"
  58 #include "../common/physics/player.qh"
  59
  60 #include <common/vehicles/sv_vehicles.qh>
  61
  62 #include "../common/items/_mod.qh"
  63
  64 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  65
  66 #include "../common/mutators/mutator/waypoints/all.qh"
  67 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  68 #include <common/gamemodes/_mod.qh>
  69
  70 #include "../common/mapobjects/subs.qh"
  71 #include "../common/mapobjects/triggers.qh"
  72 #include "../common/mapobjects/trigger/secret.qh"
  73
  74 #include "../common/minigames/sv_minigames.qh"
  75
  76 #include "../common/items/inventory.qh"
  77
  78 #include "../common/monsters/sv_monsters.qh"
  79
  80 #include "../lib/warpzone/server.qh"
  81
  82 #include <common/mutators/mutator/overkill/oknex.qh>
  83
  84 #include <common/weapons/weapon/vortex.qh>
  85
  86 STATIC_METHOD(Client, Add, void(Client this, int _team))
  87 {
  88     ClientConnect(this);
  89     TRANSMUTE(Player, this);
  90     this.frame = 12; // 7
  91     this.team = _team;
  92     PutClientInServer(this);
  93 }
  94
  95 STATIC_METHOD(Client, Remove, void(Client this))
  96 {
  97     TRANSMUTE(Observer, this);
  98     PutClientInServer(this);
  99     ClientDisconnect(this);
 100 }
 101
 102 void send_CSQC_teamnagger() {
 103         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 104 }
 105
 106 int CountSpectators(entity player, entity to)
 107 {
 108         if(!player) { return 0; } // not sure how, but best to be safe
 109
 110         int spec_count = 0;
 111
 112         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 113         {
 114                 spec_count++;
 115         });
 116
 117         return spec_count;
 118 }
 119
 120 void WriteSpectators(entity player, entity to)
 121 {
 122         if(!player) { return; } // not sure how, but best to be safe
 123
 124         int spec_count = 0;
 125         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 126         {
 127                 if(spec_count >= MAX_SPECTATORS)
 128                         break;
 129                 WriteByte(MSG_ENTITY, num_for_edict(it));
 130                 ++spec_count;
 131         });
 132 }
 133
 134 bool ClientData_Send(entity this, entity to, int sf)
 135 {
 136         assert(to == this.owner, return false);
 137
 138         entity e = to;
 139         if (IS_SPEC(e)) e = e.enemy;
 140
 141         sf = 0;
 142         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 143         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 144         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 145         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 146
 147         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 148         WriteByte(MSG_ENTITY, sf);
 149
 150         if (sf & BIT(1))
 151                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 152
 153         if(sf & BIT(4))
 154         {
 155                 float specs = CountSpectators(e, to);
 156                 WriteByte(MSG_ENTITY, specs);
 157                 WriteSpectators(e, to);
 158         }
 159
 160         return true;
 161 }
 162
 163 void ClientData_Attach(entity this)
 164 {
 165         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 166         CS(this).clientdata.drawonlytoclient = this;
 167         CS(this).clientdata.owner = this;
 168 }
 169
 170 void ClientData_Detach(entity this)
 171 {
 172         delete(CS(this).clientdata);
 173         CS(this).clientdata = NULL;
 174 }
 175
 176 void ClientData_Touch(entity e)
 177 {
 178         entity cd = CS(e).clientdata;
 179         if (cd) { cd.SendFlags = 1; }
 180
 181         // make it spectatable
 182         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 183         {
 184                 entity cd = CS(it).clientdata;
 185                 if (cd) { cd.SendFlags = 1; }
 186         });
 187 }
 188
 189
 190 /*
 191 =============
 192 CheckPlayerModel
 193
 194 Checks if the argument string can be a valid playermodel.
 195 Returns a valid one in doubt.
 196 =============
 197 */
 198 string FallbackPlayerModel;
 199 string CheckPlayerModel(string plyermodel) {
 200         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 201         {
 202                 // note: we cannot summon Don Strunzone here, some player may
 203                 // still have the model string set. In case anyone manages how
 204                 // to change a cvar default, we'll have a small leak here.
 205                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 206         }
 207         // only in right path
 208         if( substring(plyermodel,0,14) != "models/player/")
 209                 return FallbackPlayerModel;
 210         // only good file extensions
 211         if(substring(plyermodel,-4,4) != ".zym")
 212         if(substring(plyermodel,-4,4) != ".dpm")
 213         if(substring(plyermodel,-4,4) != ".iqm")
 214         if(substring(plyermodel,-4,4) != ".md3")
 215         if(substring(plyermodel,-4,4) != ".psk")
 216                 return FallbackPlayerModel;
 217         // forbid the LOD models
 218         if(substring(plyermodel, -9,5) == "_lod1")
 219                 return FallbackPlayerModel;
 220         if(substring(plyermodel, -9,5) == "_lod2")
 221                 return FallbackPlayerModel;
 222         if(plyermodel != strtolower(plyermodel))
 223                 return FallbackPlayerModel;
 224         // also, restrict to server models
 225         if(autocvar_sv_servermodelsonly)
 226         {
 227                 if(!fexists(plyermodel))
 228                         return FallbackPlayerModel;
 229         }
 230         return plyermodel;
 231 }
 232
 233 void setplayermodel(entity e, string modelname)
 234 {
 235         precache_model(modelname);
 236         _setmodel(e, modelname);
 237         player_setupanimsformodel(e);
 238         if(!autocvar_g_debug_globalsounds)
 239                 UpdatePlayerSounds(e);
 240 }
 241
 242 /** putting a client as observer in the server */
 243 void PutObserverInServer(entity this)
 244 {
 245     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 246         PlayerState_detach(this);
 247
 248         if (IS_PLAYER(this))
 249         {
 250                 if(GetResource(this, RES_HEALTH) >= 1)
 251                 {
 252                         // despawn effect
 253                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 254                 }
 255
 256                 // was a player, recount votes and ready status
 257                 if(IS_REAL_CLIENT(this))
 258                 {
 259                         if (vote_called) { VoteCount(false); }
 260                         ReadyCount();
 261                 }
 262     }
 263
 264     {
 265         entity spot = SelectSpawnPoint(this, true);
 266         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267         this.angles = vec2(spot.angles);
 268         this.fixangle = true;
 269         // offset it so that the spectator spawns higher off the ground, looks better this way
 270         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         if (IS_REAL_CLIENT(this))
 272         {
 273             msg_entity = this;
 274             WriteByte(MSG_ONE, SVC_SETVIEW);
 275             WriteEntity(MSG_ONE, this);
 276         }
 277         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 278         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 279         if(!autocvar_g_debug_globalsounds)
 280         {
 281                 // needed for player sounds
 282                 this.model = "";
 283                 FixPlayermodel(this);
 284         }
 285         setmodel(this, MDL_Null);
 286         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 287         this.view_ofs = '0 0 0';
 288     }
 289
 290     RemoveGrapplingHooks(this);
 291         Portal_ClearAll(this);
 292         Unfreeze(this, false);
 293         SetSpectatee(this, NULL);
 294
 295         if (this.alivetime)
 296         {
 297                 if (!warmup_stage)
 298                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 299                 this.alivetime = 0;
 300         }
 301
 302         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 303
 304         WaypointSprite_PlayerDead(this);
 305
 306         if (CS(this).killcount != FRAGS_SPECTATOR)
 307         {
 308                 if(!game_stopped)
 309                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 310                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 311         }
 312
 313         accuracy_resend(this);
 314
 315         CS(this).spectatortime = time;
 316         if(this.bot_attack)
 317                 IL_REMOVE(g_bot_targets, this);
 318         this.bot_attack = false;
 319         if(this.monster_attack)
 320                 IL_REMOVE(g_monster_targets, this);
 321         this.monster_attack = false;
 322     STAT(HUD, this) = HUD_NORMAL;
 323         TRANSMUTE(Observer, this);
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(STRENGTH_FINISHED, this) = 0;
 350         STAT(INVINCIBLE_FINISHED, this) = 0;
 351         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 352         STAT(AIR_FINISHED, this) = 0;
 353         //this.dphitcontentsmask = 0;
 354         this.dphitcontentsmask = DPCONTENTS_SOLID;
 355         if (autocvar_g_playerclip_collisions)
 356                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 357         this.pushltime = 0;
 358         this.istypefrag = 0;
 359         setthink(this, func_null);
 360         this.nextthink = 0;
 361         this.deadflag = DEAD_NO;
 362         UNSET_DUCKED(this);
 363         STAT(REVIVE_PROGRESS, this) = 0;
 364         this.revival_time = 0;
 365         this.draggable = drag_undraggable;
 366
 367         this.items = 0;
 368         STAT(WEAPONS, this) = '0 0 0';
 369         this.drawonlytoclient = this;
 370
 371         this.viewloc = NULL;
 372
 373         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 374
 375         this.weaponmodel = "";
 376         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 377         {
 378                 this.weaponentities[slot] = NULL;
 379         }
 380         this.exteriorweaponentity = NULL;
 381         CS(this).killcount = FRAGS_SPECTATOR;
 382         this.velocity = '0 0 0';
 383         this.avelocity = '0 0 0';
 384         this.punchangle = '0 0 0';
 385         this.punchvector = '0 0 0';
 386         this.oldvelocity = this.velocity;
 387         this.fire_endtime = -1;
 388         this.event_damage = func_null;
 389         this.event_heal = func_null;
 390
 391         for(int slot = 0; slot < MAX_AXH; ++slot)
 392         {
 393                 entity axh = this.(AuxiliaryXhair[slot]);
 394                 this.(AuxiliaryXhair[slot]) = NULL;
 395
 396                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 397                         delete(axh);
 398         }
 399
 400         if (mutator_returnvalue)
 401         {
 402                 // mutator prevents resetting teams+score
 403         }
 404         else
 405         {
 406                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 407                 this.frags = FRAGS_SPECTATOR;
 408         }
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 605
 606         this.items = start_items;
 607
 608         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 609         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 610         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 611         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 612         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 613         if (!sv_ready_restart_after_countdown && time < game_starttime)
 614         {
 615                 float f = game_starttime - time;
 616                 this.spawnshieldtime += f;
 617                 this.pauserotarmor_finished += f;
 618                 this.pauserothealth_finished += f;
 619                 this.pauseregen_finished += f;
 620         }
 621
 622         this.damageforcescale = autocvar_g_player_damageforcescale;
 623         this.death_time = 0;
 624         this.respawn_flags = 0;
 625         this.respawn_time = 0;
 626         STAT(RESPAWN_TIME, this) = 0;
 627         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 628         this.fade_time = 0;
 629         this.pain_finished = 0;
 630         this.pushltime = 0;
 631         setthink(this, func_null); // players have no think function
 632         this.nextthink = 0;
 633         this.dmg_team = 0;
 634         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 635
 636         this.deadflag = DEAD_NO;
 637
 638         this.angles = spot.angles;
 639         this.angles_z = 0; // never spawn tilted even if the spot says to
 640         if (IS_BOT_CLIENT(this))
 641         {
 642                 this.v_angle = this.angles;
 643                 bot_aim_reset(this);
 644         }
 645         this.fixangle = true; // turn this way immediately
 646         this.oldvelocity = this.velocity = '0 0 0';
 647         this.avelocity = '0 0 0';
 648         this.punchangle = '0 0 0';
 649         this.punchvector = '0 0 0';
 650
 651         STAT(STRENGTH_FINISHED, this) = 0;
 652         STAT(INVINCIBLE_FINISHED, this) = 0;
 653         this.fire_endtime = -1;
 654         STAT(REVIVE_PROGRESS, this) = 0;
 655         this.revival_time = 0;
 656
 657         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 658         STAT(BUFFS, this) = 0;
 659         STAT(BUFF_TIME, this) = 0;
 660
 661         STAT(AIR_FINISHED, this) = 0;
 662         this.waterlevel = WATERLEVEL_NONE;
 663         this.watertype = CONTENT_EMPTY;
 664
 665         entity spawnevent = new_pure(spawnevent);
 666         spawnevent.owner = this;
 667         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 668
 669         // Cut off any still running player sounds.
 670         stopsound(this, CH_PLAYER_SINGLE);
 671
 672         this.model = "";
 673         FixPlayermodel(this);
 674         this.drawonlytoclient = NULL;
 675
 676         this.viewloc = NULL;
 677
 678         for(int slot = 0; slot < MAX_AXH; ++slot)
 679         {
 680                 entity axh = this.(AuxiliaryXhair[slot]);
 681                 this.(AuxiliaryXhair[slot]) = NULL;
 682
 683                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 684                         delete(axh);
 685         }
 686
 687         this.spawnpoint_targ = NULL;
 688
 689         UNSET_DUCKED(this);
 690         this.view_ofs = STAT(PL_VIEW_OFS, this);
 691         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 692         this.spawnorigin = spot.origin;
 693         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 694         // don't reset back to last position, even if new position is stuck in solid
 695         this.oldorigin = this.origin;
 696         if(this.conveyor)
 697                 IL_REMOVE(g_conveyed, this);
 698         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 699         if(this.swampslug)
 700                 IL_REMOVE(g_swamped, this);
 701         this.swampslug = NULL;
 702         this.swamp_interval = 0;
 703         if(this.ladder_entity)
 704                 IL_REMOVE(g_ladderents, this);
 705         this.ladder_entity = NULL;
 706         IL_EACH(g_counters, it.realowner == this,
 707         {
 708                 delete(it);
 709         });
 710         STAT(HUD, this) = HUD_NORMAL;
 711
 712         this.event_damage = PlayerDamage;
 713         this.event_heal = PlayerHeal;
 714
 715         this.draggable = func_null;
 716
 717         if(!this.bot_attack)
 718                 IL_PUSH(g_bot_targets, this);
 719         this.bot_attack = true;
 720         if(!this.monster_attack)
 721                 IL_PUSH(g_monster_targets, this);
 722         this.monster_attack = true;
 723         navigation_dynamicgoal_init(this, false);
 724
 725         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 726
 727         // player was spectator
 728         if (CS(this).killcount == FRAGS_SPECTATOR) {
 729                 PlayerScore_Clear(this);
 730                 CS(this).killcount = 0;
 731                 CS(this).startplaytime = time;
 732         }
 733
 734         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 735         {
 736                 .entity weaponentity = weaponentities[slot];
 737                 CL_SpawnWeaponentity(this, weaponentity);
 738         }
 739         this.alpha = default_player_alpha;
 740         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 741         this.exteriorweaponentity.alpha = default_weapon_alpha;
 742
 743         this.speedrunning = false;
 744
 745         this.counter_cnt = 0;
 746         this.fragsfilter_cnt = 0;
 747
 748         target_voicescript_clear(this);
 749
 750         // reset fields the weapons may use
 751         FOREACH(Weapons, true, {
 752                 it.wr_resetplayer(it, this);
 753                         // reload all reloadable weapons
 754                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 755                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 756                         {
 757                                 .entity weaponentity = weaponentities[slot];
 758                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 759                         }
 760                 }
 761         });
 762
 763         {
 764                 string s = spot.target;
 765                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 766                         spot.target = string_null;
 767                 SUB_UseTargets(spot, this, NULL);
 768                 if(g_assault || g_race)
 769                         spot.target = s;
 770         }
 771
 772         Unfreeze(this, false);
 773
 774         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 775
 776         if (autocvar_spawn_debug)
 777         {
 778                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 779                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 780         }
 781
 782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 783         {
 784                 .entity weaponentity = weaponentities[slot];
 785                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 786                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 787                 else
 788                         this.(weaponentity).m_switchweapon = WEP_Null;
 789                 this.(weaponentity).m_weapon = WEP_Null;
 790                 this.(weaponentity).weaponname = "";
 791                 this.(weaponentity).m_switchingweapon = WEP_Null;
 792                 this.(weaponentity).cnt = -1;
 793         }
 794
 795         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 796
 797         if (CS(this).impulse) ImpulseCommands(this);
 798
 799         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 800         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 801         {
 802                 .entity weaponentity = weaponentities[slot];
 803                 W_WeaponFrame(this, weaponentity);
 804         }
 805
 806         if (!warmup_stage && !this.alivetime)
 807                 this.alivetime = time;
 808
 809         antilag_clear(this, CS(this));
 810 }
 811
 812 /** Called when a client spawns in the server */
 813 void PutClientInServer(entity this)
 814 {
 815         if (IS_BOT_CLIENT(this)) {
 816                 TRANSMUTE(Player, this);
 817         } else if (IS_REAL_CLIENT(this)) {
 818                 msg_entity = this;
 819                 WriteByte(MSG_ONE, SVC_SETVIEW);
 820                 WriteEntity(MSG_ONE, this);
 821         }
 822         if (game_stopped)
 823                 TRANSMUTE(Observer, this);
 824
 825         SetSpectatee(this, NULL);
 826
 827         // reset player keys
 828         if(PS(this))
 829                 PS(this).itemkeys = 0;
 830
 831         MUTATOR_CALLHOOK(PutClientInServer, this);
 832
 833         if (IS_OBSERVER(this)) {
 834                 PutObserverInServer(this);
 835         } else if (IS_PLAYER(this)) {
 836                 PutPlayerInServer(this);
 837         }
 838 }
 839
 840 // TODO do we need all these fields, or should we stop autodetecting runtime
 841 // changes and just have a console command to update this?
 842 bool ClientInit_SendEntity(entity this, entity to, int sf)
 843 {
 844         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 845         return = true;
 846         msg_entity = to;
 847         // MSG_INIT replacement
 848         // TODO: make easier to use
 849         Registry_send_all();
 850         W_PROP_reload(MSG_ONE, to);
 851         ClientInit_misc(this);
 852         MUTATOR_CALLHOOK(Ent_Init);
 853 }
 854 void ClientInit_misc(entity this)
 855 {
 856         int channel = MSG_ONE;
 857         WriteHeader(channel, ENT_CLIENT_INIT);
 858         WriteByte(channel, g_nexball_meter_period * 32);
 859         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 863         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 867
 868         if(sv_foginterval && world.fog != "")
 869                 WriteString(channel, world.fog);
 870         else
 871                 WriteString(channel, "");
 872         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 873         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 874         WriteByte(channel, serverflags);
 875         WriteCoord(channel, autocvar_g_trueaim_minrange);
 876 }
 877
 878 void ClientInit_CheckUpdate(entity this)
 879 {
 880         this.nextthink = time;
 881         if(this.count != autocvar_g_balance_armor_blockpercent)
 882         {
 883                 this.count = autocvar_g_balance_armor_blockpercent;
 884                 this.SendFlags |= 1;
 885         }
 886         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 887         {
 888                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 889                 this.SendFlags |= 1;
 890         }
 891 }
 892
 893 void ClientInit_Spawn()
 894 {
 895         entity e = new_pure(clientinit);
 896         setthink(e, ClientInit_CheckUpdate);
 897         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 898
 899         ClientInit_CheckUpdate(e);
 900 }
 901
 902 /*
 903 =============
 904 SetNewParms
 905 =============
 906 */
 907 void SetNewParms ()
 908 {
 909         // initialize parms for a new player
 910         parm1 = -(86400 * 366);
 911
 912         MUTATOR_CALLHOOK(SetNewParms);
 913 }
 914
 915 /*
 916 =============
 917 SetChangeParms
 918 =============
 919 */
 920 void SetChangeParms (entity this)
 921 {
 922         // save parms for level change
 923         parm1 = CS(this).parm_idlesince - time;
 924
 925         MUTATOR_CALLHOOK(SetChangeParms);
 926 }
 927
 928 /*
 929 =============
 930 DecodeLevelParms
 931 =============
 932 */
 933 void DecodeLevelParms(entity this)
 934 {
 935         // load parms
 936         CS(this).parm_idlesince = parm1;
 937         if (CS(this).parm_idlesince == -(86400 * 366))
 938                 CS(this).parm_idlesince = time;
 939
 940         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 941         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 942
 943         MUTATOR_CALLHOOK(DecodeLevelParms);
 944 }
 945
 946 void FixClientCvars(entity e)
 947 {
 948         // send prediction settings to the client
 949         stuffcmd(e, "\nin_bindmap 0 0\n");
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 string GetClientVersionMessage(entity this)
1022 {
1023         if (CS(this).version_mismatch) {
1024                 if(CS(this).version < autocvar_gameversion) {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1027                 } else {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1030                 }
1031         } else {
1032                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1033         }
1034 }
1035
1036 string getwelcomemessage(entity this)
1037 {
1038         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1039         string modifications = M_ARGV(0, string);
1040
1041         if(g_weaponarena)
1042         {
1043                 if(g_weaponarena_random)
1044                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1045                 else
1046                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1047         }
1048         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1049                 modifications = strcat(modifications, ", No start weapons");
1050         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1051                 modifications = strcat(modifications, ", Low gravity");
1052         if(g_weapon_stay && !g_cts)
1053                 modifications = strcat(modifications, ", Weapons stay");
1054         if(g_jetpack)
1055                 modifications = strcat(modifications, ", Jet pack");
1056         if(autocvar_g_powerups == 0)
1057                 modifications = strcat(modifications, ", No powerups");
1058         if(autocvar_g_powerups > 0)
1059                 modifications = strcat(modifications, ", Powerups");
1060         modifications = substring(modifications, 2, strlen(modifications) - 2);
1061
1062         string versionmessage = GetClientVersionMessage(this);
1063         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1064
1065         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1066
1067         if(modifications != "")
1068                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1069
1070         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1071         {
1072                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1073                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1074         }
1075
1076         if (cache_mutatormsg != "") {
1077                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1078         }
1079
1080         string mutator_msg = "";
1081         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1082         mutator_msg = M_ARGV(0, string);
1083
1084         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1085
1086         string motd = autocvar_sv_motd;
1087         if (motd != "") {
1088                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1089         }
1090         return s;
1091 }
1092
1093 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1094
1095 /**
1096 =============
1097 ClientConnect
1098
1099 Called when a client connects to the server
1100 =============
1101 */
1102 void ClientConnect(entity this)
1103 {
1104         if (Ban_MaybeEnforceBanOnce(this)) return;
1105         assert(!IS_CLIENT(this), return);
1106         this.flags |= FL_CLIENT;
1107         assert(player_count >= 0, player_count = 0);
1108
1109 #ifdef WATERMARK
1110         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1111 #endif
1112         TRANSMUTE(Client, this);
1113         CS(this).version_nagtime = time + 10 + random() * 10;
1114
1115         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1116
1117         bot_clientconnect(this);
1118
1119         Player_DetermineForcedTeam(this);
1120
1121         TRANSMUTE(Observer, this);
1122
1123         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1124
1125         // always track bots, don't ask for cl_allow_uidtracking
1126         if (IS_BOT_CLIENT(this))
1127                 PlayerStats_GameReport_AddPlayer(this);
1128         else
1129                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1130
1131         if (autocvar_sv_eventlog)
1132                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this, false)));
1133
1134         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1135
1136         stuffcmd(this, clientstuff, "\n");
1137         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1138
1139         FixClientCvars(this);
1140
1141         // get version info from player
1142         stuffcmd(this, "cmd clientversion $gameversion\n");
1143
1144         // notify about available teams
1145         if (teamplay)
1146         {
1147                 entity balance = TeamBalance_CheckAllowedTeams(this);
1148                 int t = TeamBalance_GetAllowedTeams(balance);
1149                 TeamBalance_Destroy(balance);
1150                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1151         }
1152         else
1153         {
1154                 stuffcmd(this, "set _teams_available 0\n");
1155         }
1156
1157         bot_relinkplayerlist();
1158
1159         CS(this).spectatortime = time;
1160         if (blockSpectators)
1161         {
1162                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1163         }
1164
1165         CS(this).jointime = time;
1166
1167         if (IS_REAL_CLIENT(this))
1168         {
1169                 if (g_weaponarena_weapons == WEPSET(TUBA))
1170                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1171         }
1172
1173         if (!sv_foginterval && world.fog != "")
1174                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1175
1176         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1177                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1178                         send_CSQC_teamnagger();
1179
1180         CSQCMODEL_AUTOINIT(this);
1181
1182         CS(this).model_randomizer = random();
1183
1184         if (IS_REAL_CLIENT(this))
1185                 sv_notice_join(this);
1186
1187         this.move_qcphysics = autocvar_sv_qcphysics;
1188
1189         // update physics stats (players can spawn before physics runs)
1190         Physics_UpdateStats(this);
1191
1192         IL_EACH(g_initforplayer, it.init_for_player, {
1193                 it.init_for_player(it, this);
1194         });
1195
1196         Handicap_Initialize(this);
1197
1198         MUTATOR_CALLHOOK(ClientConnect, this);
1199
1200         if (IS_REAL_CLIENT(this))
1201         {
1202                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1203                 {
1204                         CS(this).motd_actived_time = -1;
1205                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1206                 }
1207         }
1208 }
1209 /*
1210 =============
1211 ClientDisconnect
1212
1213 Called when a client disconnects from the server
1214 =============
1215 */
1216 .entity chatbubbleentity;
1217 void ClientDisconnect(entity this)
1218 {
1219         assert(IS_CLIENT(this), return);
1220
1221         PlayerStats_GameReport_FinalizePlayer(this);
1222         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1223         if (CS(this).active_minigame) part_minigame(this);
1224         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1225
1226         if (autocvar_sv_eventlog)
1227                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1228
1229         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1230
1231         if(IS_SPEC(this))
1232                 SetSpectatee(this, NULL);
1233
1234     MUTATOR_CALLHOOK(ClientDisconnect, this);
1235
1236         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1237         strfree(CS(this).weaponorder_byimpulse);
1238         ClientState_detach(this);
1239
1240         Portal_ClearAll(this);
1241
1242         Unfreeze(this, false);
1243
1244         RemoveGrapplingHooks(this);
1245
1246         // Here, everything has been done that requires this player to be a client.
1247
1248         this.flags &= ~FL_CLIENT;
1249
1250         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1251         if (this.killindicator) delete(this.killindicator);
1252
1253         IL_EACH(g_counters, it.realowner == this,
1254         {
1255                 delete(it);
1256         });
1257
1258         WaypointSprite_PlayerGone(this);
1259
1260         bot_relinkplayerlist();
1261
1262         strfree(this.clientstatus);
1263         if (this.personal) delete(this.personal);
1264
1265         this.playerid = 0;
1266         ReadyCount();
1267         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1268
1269         ONREMOVE(this);
1270 }
1271
1272 void ChatBubbleThink(entity this)
1273 {
1274         this.nextthink = time;
1275         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1276         {
1277                 if(this.owner) // but why can that ever be NULL?
1278                         this.owner.chatbubbleentity = NULL;
1279                 delete(this);
1280                 return;
1281         }
1282
1283         this.mdl = "";
1284
1285         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1286         {
1287                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1288                         this.mdl = "models/sprites/minigame_busy.iqm";
1289                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1290                         this.mdl = "models/misc/chatbubble.spr";
1291         }
1292
1293         if ( this.model != this.mdl )
1294                 _setmodel(this, this.mdl);
1295
1296 }
1297
1298 void UpdateChatBubble(entity this)
1299 {
1300         if (this.alpha < 0)
1301                 return;
1302         // spawn a chatbubble entity if needed
1303         if (!this.chatbubbleentity)
1304         {
1305                 this.chatbubbleentity = new(chatbubbleentity);
1306                 this.chatbubbleentity.owner = this;
1307                 this.chatbubbleentity.exteriormodeltoclient = this;
1308                 setthink(this.chatbubbleentity, ChatBubbleThink);
1309                 this.chatbubbleentity.nextthink = time;
1310                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1311                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1312                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1313                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1314                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1315                 //this.chatbubbleentity.model = "";
1316                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1317         }
1318 }
1319
1320 void calculate_player_respawn_time(entity this)
1321 {
1322         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1323                 return;
1324
1325         float gametype_setting_tmp;
1326         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1327         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1328         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1329         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1330         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1331         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1332
1333         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1334         if (teamplay)
1335         {
1336                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1337                         if(it.team == this.team)
1338                                 ++pcount;
1339                 });
1340                 if (sdelay_small_count == 0)
1341                         sdelay_small_count = 1;
1342                 if (sdelay_large_count == 0)
1343                         sdelay_large_count = 1;
1344         }
1345         else
1346         {
1347                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1348                         ++pcount;
1349                 });
1350                 if (sdelay_small_count == 0)
1351                 {
1352                         if (IS_INDEPENDENT_PLAYER(this))
1353                         {
1354                                 // Players play independently. No point in requiring enemies.
1355                                 sdelay_small_count = 1;
1356                         }
1357                         else
1358                         {
1359                                 // Players play AGAINST each other. Enemies required.
1360                                 sdelay_small_count = 2;
1361                         }
1362                 }
1363                 if (sdelay_large_count == 0)
1364                 {
1365                         if (IS_INDEPENDENT_PLAYER(this))
1366                         {
1367                                 // Players play independently. No point in requiring enemies.
1368                                 sdelay_large_count = 1;
1369                         }
1370                         else
1371                         {
1372                                 // Players play AGAINST each other. Enemies required.
1373                                 sdelay_large_count = 2;
1374                         }
1375                 }
1376         }
1377
1378         float sdelay;
1379
1380         if (pcount <= sdelay_small_count)
1381                 sdelay = sdelay_small;
1382         else if (pcount >= sdelay_large_count)
1383                 sdelay = sdelay_large;
1384         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1385                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1386
1387         if(waves)
1388                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1389         else
1390                 this.respawn_time = time + sdelay;
1391
1392         if(sdelay < sdelay_max)
1393                 this.respawn_time_max = time + sdelay_max;
1394         else
1395                 this.respawn_time_max = this.respawn_time;
1396
1397         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1398                 this.respawn_countdown = 10; // first number to count down from is 10
1399         else
1400                 this.respawn_countdown = -1; // do not count down
1401
1402         if(autocvar_g_forced_respawn)
1403                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1404 }
1405
1406 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1407 // added to the model skins
1408 /*void UpdateColorModHack()
1409 {
1410         float c;
1411         c = this.clientcolors & 15;
1412         // LordHavoc: only bothering to support white, green, red, yellow, blue
1413              if (!teamplay) this.colormod = '0 0 0';
1414         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1415         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1416         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1417         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1418         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1419         else this.colormod = '1 1 1';
1420 }*/
1421
1422 void respawn(entity this)
1423 {
1424         bool damagedbycontents_prev = this.damagedbycontents;
1425         if(this.alpha >= 0)
1426         {
1427                 if(autocvar_g_respawn_ghosts)
1428                 {
1429                         this.solid = SOLID_NOT;
1430                         this.takedamage = DAMAGE_NO;
1431                         this.damagedbycontents = false;
1432                         set_movetype(this, MOVETYPE_FLY);
1433                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1434                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1435                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1436                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1437                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1438                         if(autocvar_g_respawn_ghosts_time > 0)
1439                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1440                 }
1441                 else
1442                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1443         }
1444
1445         CopyBody(this, 1);
1446         this.damagedbycontents = damagedbycontents_prev;
1447
1448         this.effects |= EF_NODRAW; // prevent another CopyBody
1449         PutClientInServer(this);
1450 }
1451
1452 ERASEABLE
1453 void PrintToChat(entity client, string text)
1454 {
1455         text = strcat("\{1}^7", text, "\n");
1456         sprint(client, text);
1457 }
1458
1459 ERASEABLE
1460 void DebugPrintToChat(entity client, string text)
1461 {
1462         if (autocvar_developer > 0)
1463         {
1464                 PrintToChat(client, text);
1465         }
1466 }
1467
1468 ERASEABLE
1469 void PrintToChatAll(string text)
1470 {
1471         text = strcat("\{1}^7", text, "\n");
1472         bprint(text);
1473 }
1474
1475 ERASEABLE
1476 void DebugPrintToChatAll(string text)
1477 {
1478         if (autocvar_developer > 0)
1479         {
1480                 PrintToChatAll(text);
1481         }
1482 }
1483
1484 ERASEABLE
1485 void PrintToChatTeam(int team_num, string text)
1486 {
1487         text = strcat("\{1}^7", text, "\n");
1488         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1489         {
1490                 if (it.team == team_num)
1491                 {
1492                         sprint(it, text);
1493                 }
1494         });
1495 }
1496
1497 ERASEABLE
1498 void DebugPrintToChatTeam(int team_num, string text)
1499 {
1500         if (autocvar_developer > 0)
1501         {
1502                 PrintToChatTeam(team_num, text);
1503         }
1504 }
1505
1506 void play_countdown(entity this, float finished, Sound samp)
1507 {
1508         TC(Sound, samp);
1509         if(IS_REAL_CLIENT(this))
1510                 if(floor(finished - time - frametime) != floor(finished - time))
1511                         if(finished - time < 6)
1512                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1513 }
1514
1515 void player_powerups(entity this)
1516 {
1517         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1518                 this.modelflags |= MF_ROCKET;
1519         else
1520                 this.modelflags &= ~MF_ROCKET;
1521
1522         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1523
1524         if (IS_DEAD(this))
1525         {
1526                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1527                 {
1528                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1529                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1530                         this.items &= ~ITEM_Strength.m_itemid;
1531                         this.items &= ~ITEM_Shield.m_itemid;
1532                         this.items -= (this.items & IT_SUPERWEAPON);
1533                 }
1534         }
1535
1536         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1537                 return;
1538
1539         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1540         int items_prev = this.items;
1541
1542         Fire_ApplyDamage(this);
1543         Fire_ApplyEffect(this);
1544
1545         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1546         {
1547                 if (this.items & ITEM_Strength.m_itemid)
1548                 {
1549                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1550                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1551                         if (time > STAT(STRENGTH_FINISHED, this))
1552                         {
1553                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1554                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1555                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1556                         }
1557                 }
1558                 else
1559                 {
1560                         if (time < STAT(STRENGTH_FINISHED, this))
1561                         {
1562                                 this.items = this.items | ITEM_Strength.m_itemid;
1563                                 if(!g_cts)
1564                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1565                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1566                         }
1567                 }
1568                 if (this.items & ITEM_Shield.m_itemid)
1569                 {
1570                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1571                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1572                         if (time > STAT(INVINCIBLE_FINISHED, this))
1573                         {
1574                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1575                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1576                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1577                         }
1578                 }
1579                 else
1580                 {
1581                         if (time < STAT(INVINCIBLE_FINISHED, this))
1582                         {
1583                                 this.items = this.items | ITEM_Shield.m_itemid;
1584                                 if(!g_cts)
1585                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1586                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1587                         }
1588                 }
1589                 if (this.items & IT_SUPERWEAPON)
1590                 {
1591                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1592                         {
1593                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1594                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1595                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1596                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1597                         }
1598                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1599                         {
1600                                 // don't let them run out
1601                         }
1602                         else
1603                         {
1604                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1605                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1606                                 {
1607                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1608                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1609                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1610                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1611                                 }
1612                         }
1613                 }
1614                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1615                 {
1616                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1617                         {
1618                                 this.items = this.items | IT_SUPERWEAPON;
1619                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1620                                 {
1621                                         if(!g_cts)
1622                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1623                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1624                                 }
1625                         }
1626                         else
1627                         {
1628                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1629                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1630                         }
1631                 }
1632                 else
1633                 {
1634                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1635                 }
1636         }
1637
1638         if(autocvar_g_nodepthtestplayers)
1639                 this.effects = this.effects | EF_NODEPTHTEST;
1640
1641         if(autocvar_g_fullbrightplayers)
1642                 this.effects = this.effects | EF_FULLBRIGHT;
1643
1644         if (time >= game_starttime)
1645         if (time < this.spawnshieldtime)
1646                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1647
1648         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1649 }
1650
1651 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1652 {
1653         if(current > stable)
1654                 return current;
1655         else if(current > stable - 0.25) // when close enough, "snap"
1656                 return stable;
1657         else
1658                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1659 }
1660
1661 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1662 {
1663         if(current < stable)
1664                 return current;
1665         else if(current < stable + 0.25) // when close enough, "snap"
1666                 return stable;
1667         else
1668                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1669 }
1670
1671 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1672 {
1673         float old = GetResource(this, res);
1674         float current = old;
1675         if(current > rotstable)
1676         {
1677                 if(rotframetime > 0)
1678                 {
1679                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1680                         current = max(rotstable, current - rotlinear * rotframetime);
1681                 }
1682         }
1683         else if(current < regenstable)
1684         {
1685                 if(regenframetime > 0)
1686                 {
1687                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1688                         current = min(regenstable, current + regenlinear * regenframetime);
1689                 }
1690         }
1691
1692         float limit = GetResourceLimit(this, res) * limit_mod;
1693         if(current > limit)
1694                 current = limit;
1695
1696         if (current != old)
1697                 SetResource(this, res, current);
1698 }
1699
1700 void player_regen(entity this)
1701 {
1702         float max_mod, regen_mod, rot_mod, limit_mod;
1703         max_mod = regen_mod = rot_mod = limit_mod = 1;
1704
1705         float regen_health = autocvar_g_balance_health_regen;
1706         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1707         float regen_health_rot = autocvar_g_balance_health_rot;
1708         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1709         float regen_health_stable = autocvar_g_balance_health_regenstable;
1710         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1711         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1712                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1713         max_mod = M_ARGV(1, float);
1714         regen_mod = M_ARGV(2, float);
1715         rot_mod = M_ARGV(3, float);
1716         limit_mod = M_ARGV(4, float);
1717         regen_health = M_ARGV(5, float);
1718         regen_health_linear = M_ARGV(6, float);
1719         regen_health_rot = M_ARGV(7, float);
1720         regen_health_rotlinear = M_ARGV(8, float);
1721         regen_health_stable = M_ARGV(9, float);
1722         regen_health_rotstable = M_ARGV(10, float);
1723
1724         if(!mutator_returnvalue)
1725         if(!STAT(FROZEN, this))
1726         {
1727                 float maxa = autocvar_g_balance_armor_rotstable;
1728                 float mina = autocvar_g_balance_armor_regenstable;
1729
1730                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1731                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1732                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1733
1734                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1735                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1736                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1737         }
1738
1739         // if player rotted to death...  die!
1740         // check this outside above checks, as player may still be able to rot to death
1741         if(GetResource(this, RES_HEALTH) < 1)
1742         {
1743                 if(this.vehicle)
1744                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1745                 if(this.event_damage)
1746                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1747         }
1748
1749         if (!(this.items & IT_UNLIMITED_AMMO))
1750         {
1751                 float maxf = autocvar_g_balance_fuel_rotstable;
1752                 float minf = autocvar_g_balance_fuel_regenstable;
1753
1754                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1755                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1756                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1757         }
1758 }
1759
1760 bool zoomstate_set;
1761 void SetZoomState(entity this, float newzoom)
1762 {
1763         if(newzoom != CS(this).zoomstate)
1764         {
1765                 CS(this).zoomstate = newzoom;
1766                 ClientData_Touch(this);
1767         }
1768         zoomstate_set = true;
1769 }
1770
1771 void GetPressedKeys(entity this)
1772 {
1773         MUTATOR_CALLHOOK(GetPressedKeys, this);
1774         int keys = STAT(PRESSED_KEYS, this);
1775         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1776         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1777         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1778         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1779
1780         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1781         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1782         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1783         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1784         CS(this).pressedkeys = keys; // store for other users
1785
1786         STAT(PRESSED_KEYS, this) = keys;
1787 }
1788
1789 /*
1790 ======================
1791 spectate mode routines
1792 ======================
1793 */
1794
1795 void SpectateCopy(entity this, entity spectatee)
1796 {
1797         TC(Client, this); TC(Client, spectatee);
1798
1799         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1800         PS(this) = PS(spectatee);
1801         this.armortype = spectatee.armortype;
1802         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1803         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1804         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1805         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1806         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1807         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1808         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1809         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1810         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1811         CS(this).impulse = 0;
1812         this.disableclientprediction = 1; // no need to run prediction on a spectator
1813         this.items = spectatee.items;
1814         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1815         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1816         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1817         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1818         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1819         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1820         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1821         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1822         this.punchangle = spectatee.punchangle;
1823         this.view_ofs = spectatee.view_ofs;
1824         this.velocity = spectatee.velocity;
1825         this.dmg_take = spectatee.dmg_take;
1826         this.dmg_save = spectatee.dmg_save;
1827         this.dmg_inflictor = spectatee.dmg_inflictor;
1828         this.v_angle = spectatee.v_angle;
1829         this.angles = spectatee.v_angle;
1830         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1831         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1832         this.viewloc = spectatee.viewloc;
1833         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1834                 this.fixangle = true;
1835         setorigin(this, spectatee.origin);
1836         setsize(this, spectatee.mins, spectatee.maxs);
1837         SetZoomState(this, CS(spectatee).zoomstate);
1838
1839     anticheat_spectatecopy(this, spectatee);
1840         STAT(HUD, this) = STAT(HUD, spectatee);
1841         if(spectatee.vehicle)
1842     {
1843         this.angles = spectatee.v_angle;
1844
1845         //this.fixangle = false;
1846         //this.velocity = spectatee.vehicle.velocity;
1847         this.vehicle_health = spectatee.vehicle_health;
1848         this.vehicle_shield = spectatee.vehicle_shield;
1849         this.vehicle_energy = spectatee.vehicle_energy;
1850         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1851         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1852         this.vehicle_reload1 = spectatee.vehicle_reload1;
1853         this.vehicle_reload2 = spectatee.vehicle_reload2;
1854
1855         //msg_entity = this;
1856
1857        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1858             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1859            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1860            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1861
1862         //WriteByte (MSG_ONE, SVC_SETVIEW);
1863         //    WriteEntity(MSG_ONE, this);
1864         //makevectors(spectatee.v_angle);
1865         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1866     }
1867 }
1868
1869 bool SpectateUpdate(entity this)
1870 {
1871         if(!this.enemy)
1872                 return false;
1873
1874         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1875         {
1876                 SetSpectatee(this, NULL);
1877                 return false;
1878         }
1879
1880         SpectateCopy(this, this.enemy);
1881
1882         return true;
1883 }
1884
1885 bool SpectateSet(entity this)
1886 {
1887         if(!IS_PLAYER(this.enemy))
1888                 return false;
1889
1890         ClientData_Touch(this.enemy);
1891
1892         msg_entity = this;
1893         WriteByte(MSG_ONE, SVC_SETVIEW);
1894         WriteEntity(MSG_ONE, this.enemy);
1895         set_movetype(this, MOVETYPE_NONE);
1896         accuracy_resend(this);
1897
1898         if(!SpectateUpdate(this))
1899                 PutObserverInServer(this);
1900
1901         return true;
1902 }
1903
1904 void SetSpectatee_status(entity this, int spectatee_num)
1905 {
1906         int oldspectatee_status = CS(this).spectatee_status;
1907         CS(this).spectatee_status = spectatee_num;
1908
1909         if (CS(this).spectatee_status != oldspectatee_status)
1910         {
1911                 if (STAT(PRESSED_KEYS, this))
1912                 {
1913                         CS(this).pressedkeys = 0;
1914                         STAT(PRESSED_KEYS, this) = 0;
1915                 }
1916                 ClientData_Touch(this);
1917                 if (g_race || g_cts) race_InitSpectator();
1918         }
1919 }
1920
1921 void SetSpectatee(entity this, entity spectatee)
1922 {
1923         if(IS_BOT_CLIENT(this))
1924                 return; // bots abuse .enemy, this code is useless to them
1925
1926         entity old_spectatee = this.enemy;
1927
1928         this.enemy = spectatee;
1929
1930         // WEAPONTODO
1931         // these are required to fix the spectator bug with arc
1932         if(old_spectatee)
1933         {
1934                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1935                 {
1936                         .entity weaponentity = weaponentities[slot];
1937                         if(old_spectatee.(weaponentity).arc_beam)
1938                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1939                 }
1940         }
1941         if(this.enemy)
1942         {
1943                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1944                 {
1945                         .entity weaponentity = weaponentities[slot];
1946                         if(this.enemy.(weaponentity).arc_beam)
1947                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1948                 }
1949         }
1950
1951         if (this.enemy)
1952                 SetSpectatee_status(this, etof(this.enemy));
1953
1954         // needed to update spectator list
1955         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1956 }
1957
1958 bool Spectate(entity this, entity pl)
1959 {
1960         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1961                 return false;
1962         pl = M_ARGV(1, entity);
1963
1964         SetSpectatee(this, pl);
1965         return SpectateSet(this);
1966 }
1967
1968 bool SpectateNext(entity this)
1969 {
1970         entity ent = find(this.enemy, classname, STR_PLAYER);
1971
1972         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1973                 ent = M_ARGV(1, entity);
1974         else if (!ent)
1975                 ent = find(ent, classname, STR_PLAYER);
1976
1977         if(ent) { SetSpectatee(this, ent); }
1978
1979         return SpectateSet(this);
1980 }
1981
1982 bool SpectatePrev(entity this)
1983 {
1984         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1985         entity ent = findchain(classname, STR_PLAYER);
1986         if (!ent) // no player
1987                 return false;
1988
1989         entity first = ent;
1990         // skip players until current spectated player
1991         if(this.enemy)
1992         while(ent && ent != this.enemy)
1993                 ent = ent.chain;
1994
1995         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1996         {
1997                 case MUT_SPECPREV_FOUND:
1998                     ent = M_ARGV(1, entity);
1999                     break;
2000                 case MUT_SPECPREV_RETURN:
2001                     return true;
2002                 case MUT_SPECPREV_CONTINUE:
2003                 default:
2004                 {
2005                         if(ent.chain)
2006                                 ent = ent.chain;
2007                         else
2008                                 ent = first;
2009                         break;
2010                 }
2011         }
2012
2013         SetSpectatee(this, ent);
2014         return SpectateSet(this);
2015 }
2016
2017 /*
2018 =============
2019 ShowRespawnCountdown()
2020
2021 Update a respawn countdown display.
2022 =============
2023 */
2024 void ShowRespawnCountdown(entity this)
2025 {
2026         float number;
2027         if(!IS_DEAD(this)) // just respawned?
2028                 return;
2029         else
2030         {
2031                 number = ceil(this.respawn_time - time);
2032                 if(number <= 0)
2033                         return;
2034                 if(number <= this.respawn_countdown)
2035                 {
2036                         this.respawn_countdown = number - 1;
2037                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2038                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2039                 }
2040         }
2041 }
2042
2043 .bool team_selected;
2044 bool ShowTeamSelection(entity this)
2045 {
2046         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2047                 return false;
2048         stuffcmd(this, "menu_showteamselect\n");
2049         return true;
2050 }
2051 void Join(entity this)
2052 {
2053         TRANSMUTE(Player, this);
2054
2055         if(!this.team_selected)
2056         if(autocvar_g_campaign || autocvar_g_balance_teams)
2057                 TeamBalance_JoinBestTeam(this);
2058
2059         if(autocvar_g_campaign)
2060                 campaign_bots_may_start = true;
2061
2062         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2063
2064         PutClientInServer(this);
2065
2066         if(IS_PLAYER(this))
2067         if(teamplay && this.team != -1)
2068         {
2069         }
2070         else
2071                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2072         this.team_selected = false;
2073 }
2074
2075 int GetPlayerLimit()
2076 {
2077         if(g_duel)
2078                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2079         int player_limit = autocvar_g_maxplayers;
2080         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2081         player_limit = M_ARGV(0, int);
2082         return player_limit;
2083 }
2084
2085 /**
2086  * Determines whether the player is allowed to join. This depends on cvar
2087  * g_maxplayers, if it isn't used this function always return true, otherwise
2088  * it checks whether the number of currently playing players exceeds g_maxplayers.
2089  * @return int number of free slots for players, 0 if none
2090  */
2091 int nJoinAllowed(entity this, entity ignore)
2092 {
2093         if(!ignore)
2094         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2095         // so report 0 free slots if restricted
2096         {
2097                 if(autocvar_g_forced_team_otherwise == "spectate")
2098                         return 0;
2099                 if(autocvar_g_forced_team_otherwise == "spectator")
2100                         return 0;
2101         }
2102
2103         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2104                 return 0; // forced spectators can never join
2105
2106         // TODO simplify this
2107         int totalClients = 0;
2108         int currentlyPlaying = 0;
2109         FOREACH_CLIENT(true, {
2110                 if(it != ignore)
2111                         ++totalClients;
2112                 if(IS_REAL_CLIENT(it))
2113                 if(IS_PLAYER(it) || it.caplayer)
2114                         ++currentlyPlaying;
2115         });
2116
2117         int player_limit = GetPlayerLimit();
2118
2119         int free_slots = 0;
2120         if (!player_limit)
2121                 free_slots = maxclients - totalClients;
2122         else if(player_limit > 0 && currentlyPlaying < player_limit)
2123                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2124
2125         static float msg_time = 0;
2126         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2127         {
2128                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2129                 msg_time = time + 0.5;
2130         }
2131
2132         return free_slots;
2133 }
2134
2135 /**
2136  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2137  * g_maxplayers_spectator_blocktime seconds
2138  */
2139 void checkSpectatorBlock(entity this)
2140 {
2141         if(IS_SPEC(this) || IS_OBSERVER(this))
2142         if(!this.caplayer)
2143         if(IS_REAL_CLIENT(this))
2144         {
2145                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2146                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2147                         dropclient(this);
2148                 }
2149         }
2150 }
2151
2152 void PrintWelcomeMessage(entity this)
2153 {
2154         if(CS(this).motd_actived_time == 0)
2155         {
2156                 if (autocvar_g_campaign) {
2157                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2158                                 CS(this).motd_actived_time = time;
2159                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2160                         }
2161                 } else {
2162                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2163                                 CS(this).motd_actived_time = time;
2164                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2165                         }
2166                 }
2167         }
2168         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2169         {
2170                 if (autocvar_g_campaign) {
2171                         if (PHYS_INPUT_BUTTON_INFO(this))
2172                                 CS(this).motd_actived_time = time;
2173                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2174                                 CS(this).motd_actived_time = 0;
2175                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2176                         }
2177                 } else {
2178                         if (PHYS_INPUT_BUTTON_INFO(this))
2179                                 CS(this).motd_actived_time = time;
2180                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2181                                 CS(this).motd_actived_time = 0;
2182                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2183                         }
2184                 }
2185         }
2186         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2187         {
2188                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2189                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2190                 else if (CS(this).motd_actived_time == -2)
2191                 {
2192                         // instantly hide MOTD
2193                         CS(this).motd_actived_time = 0;
2194                         if (autocvar_g_campaign)
2195                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2196                         else
2197                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2198                 }
2199                 else if (IS_PLAYER(this) || IS_SPEC(this))
2200                 {
2201                         // FIXME occasionally for some reason MOTD never goes away
2202                         // delay MOTD removal a little bit in the hope it fixes this bug
2203                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2204                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2205                         else //if (CS(this).motd_actived_time < -2)
2206                                 CS(this).motd_actived_time++;
2207                 }
2208         }
2209 }
2210
2211 bool joinAllowed(entity this)
2212 {
2213         if (CS(this).version_mismatch) return false;
2214         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2215         if (!nJoinAllowed(this, this)) return false;
2216         if (teamplay && lockteams) return false;
2217         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2218         if (ShowTeamSelection(this)) return false;
2219         return true;
2220 }
2221
2222 .string shootfromfixedorigin;
2223 .bool dualwielding_prev;
2224 bool PlayerThink(entity this)
2225 {
2226         if (game_stopped || intermission_running) {
2227                 this.modelflags &= ~MF_ROCKET;
2228                 if(intermission_running)
2229                         IntermissionThink(this);
2230                 return false;
2231         }
2232
2233         if (timeout_status == TIMEOUT_ACTIVE) {
2234         // don't allow the player to turn around while game is paused
2235                 // FIXME turn this into CSQC stuff
2236                 this.v_angle = this.lastV_angle;
2237                 this.angles = this.lastV_angle;
2238                 this.fixangle = true;
2239         }
2240
2241         if (frametime) player_powerups(this);
2242
2243         if (IS_DEAD(this)) {
2244                 if (this.personal && g_race_qualifying) {
2245                         if (time > this.respawn_time) {
2246                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2247                                 respawn(this);
2248                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2249                         }
2250                 } else {
2251                         if (frametime) player_anim(this);
2252
2253                         if (this.respawn_flags & RESPAWN_DENY)
2254                         {
2255                                 STAT(RESPAWN_TIME, this) = 0;
2256                                 return false;
2257                         }
2258
2259                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2260
2261                         switch(this.deadflag)
2262                         {
2263                                 case DEAD_DYING:
2264                                 {
2265                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2266                                                 this.deadflag = DEAD_RESPAWNING;
2267                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2268                                                 this.deadflag = DEAD_DEAD;
2269                                         break;
2270                                 }
2271                                 case DEAD_DEAD:
2272                                 {
2273                                         if (button_pressed)
2274                                                 this.deadflag = DEAD_RESPAWNABLE;
2275                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2276                                                 this.deadflag = DEAD_RESPAWNING;
2277                                         break;
2278                                 }
2279                                 case DEAD_RESPAWNABLE:
2280                                 {
2281                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2282                                                 this.deadflag = DEAD_RESPAWNING;
2283                                         break;
2284                                 }
2285                                 case DEAD_RESPAWNING:
2286                                 {
2287                                         if (time > this.respawn_time)
2288                                         {
2289                                                 this.respawn_time = time + 1; // only retry once a second
2290                                                 this.respawn_time_max = this.respawn_time;
2291                                                 respawn(this);
2292                                         }
2293                                         break;
2294                                 }
2295                         }
2296
2297                         ShowRespawnCountdown(this);
2298
2299                         if (this.respawn_flags & RESPAWN_SILENT)
2300                                 STAT(RESPAWN_TIME, this) = 0;
2301                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2302                         {
2303                                 if (time < this.respawn_time)
2304                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2305                                 else if (this.deadflag != DEAD_RESPAWNING)
2306                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2307                         }
2308                         else
2309                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2310                 }
2311
2312                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2313                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2314                         STAT(RESPAWN_TIME, this) *= -1;
2315
2316                 return false;
2317         }
2318
2319         FixPlayermodel(this);
2320
2321         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2322                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2323                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2324         }
2325
2326         // reset gun alignment when dual wielding status changes
2327         // to ensure guns are always aligned right and left
2328         bool dualwielding = W_DualWielding(this);
2329         if(this.dualwielding_prev != dualwielding)
2330         {
2331                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2332                 this.dualwielding_prev = dualwielding;
2333         }
2334
2335         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2336         //if(frametime)
2337         {
2338                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2339                 {
2340                         .entity weaponentity = weaponentities[slot];
2341                         if(WEP_CVAR(vortex, charge_always))
2342                                 W_Vortex_Charge(this, weaponentity, frametime);
2343                         W_WeaponFrame(this, weaponentity);
2344                 }
2345         }
2346
2347         if (frametime)
2348         {
2349                 // WEAPONTODO: Add a weapon request for this
2350                 // rot vortex charge to the charge limit
2351                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2352                 {
2353                         .entity weaponentity = weaponentities[slot];
2354                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2355                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2356                 }
2357
2358                 player_regen(this);
2359                 player_anim(this);
2360                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2361         }
2362
2363         monsters_setstatus(this);
2364
2365         return true;
2366 }
2367
2368 .bool would_spectate;
2369 void ObserverOrSpectatorThink(entity this)
2370 {
2371         bool is_spec = IS_SPEC(this);
2372         if ( CS(this).impulse )
2373         {
2374                 int r = MinigameImpulse(this, CS(this).impulse);
2375                 if (!is_spec || r)
2376                         CS(this).impulse = 0;
2377
2378                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2379                 {
2380                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2381                         CS(this).impulse = 0;
2382                         return;
2383                 }
2384         }
2385
2386         if (this.flags & FL_JUMPRELEASED) {
2387                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2388                         this.flags &= ~FL_JUMPRELEASED;
2389                         this.flags |= FL_SPAWNING;
2390                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2391                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2392                         this.flags &= ~FL_JUMPRELEASED;
2393                         if(SpectateNext(this)) {
2394                                 TRANSMUTE(Spectator, this);
2395                         } else if (is_spec) {
2396                                 TRANSMUTE(Observer, this);
2397                                 PutClientInServer(this);
2398                         }
2399                         if (is_spec)
2400                                 CS(this).impulse = 0;
2401                 } else if (is_spec) {
2402                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2403                                 this.flags &= ~FL_JUMPRELEASED;
2404                                 if(SpectatePrev(this)) {
2405                                         TRANSMUTE(Spectator, this);
2406                                 } else {
2407                                         TRANSMUTE(Observer, this);
2408                                         PutClientInServer(this);
2409                                 }
2410                                 CS(this).impulse = 0;
2411                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2412                                 this.would_spectate = false;
2413                                 this.flags &= ~FL_JUMPRELEASED;
2414                                 TRANSMUTE(Observer, this);
2415                                 PutClientInServer(this);
2416                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2417                                 PutObserverInServer(this);
2418                                 this.would_spectate = true;
2419                         }
2420                 }
2421                 else {
2422                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2423                         set_movetype(this, preferred_movetype);
2424                 }
2425         } else {
2426                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2427                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2428                         this.flags |= FL_JUMPRELEASED;
2429                         if(this.flags & FL_SPAWNING)
2430                         {
2431                                 this.flags &= ~FL_SPAWNING;
2432                                 if(joinAllowed(this))
2433                                         Join(this);
2434                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2435                                         CS(this).autojoin_checked = -1;
2436                                 return;
2437                         }
2438                 }
2439                 if(is_spec && !SpectateUpdate(this))
2440                         PutObserverInServer(this);
2441         }
2442         if (is_spec)
2443                 this.flags |= FL_CLIENT | FL_NOTARGET;
2444 }
2445
2446 void PlayerUseKey(entity this)
2447 {
2448         if (!IS_PLAYER(this))
2449                 return;
2450
2451         if(this.vehicle)
2452         {
2453                 if(!game_stopped)
2454                 {
2455                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2456                         return;
2457                 }
2458         }
2459         else if(autocvar_g_vehicles_enter)
2460         {
2461                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2462                 {
2463                         entity head, closest_target = NULL;
2464                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2465
2466                         while(head) // find the closest acceptable target to enter
2467                         {
2468                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2469                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2470                                 {
2471                                         if(closest_target)
2472                                         {
2473                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2474                                                 { closest_target = head; }
2475                                         }
2476                                         else { closest_target = head; }
2477                                 }
2478
2479                                 head = head.chain;
2480                         }
2481
2482                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2483                 }
2484         }
2485
2486         // a use key was pressed; call handlers
2487         MUTATOR_CALLHOOK(PlayerUseKey, this);
2488 }
2489
2490
2491 /*
2492 =============
2493 PlayerPreThink
2494
2495 Called every frame for each client before the physics are run
2496 =============
2497 */
2498 .float last_vehiclecheck;
2499 void PlayerPreThink (entity this)
2500 {
2501         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2502         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2503
2504         WarpZone_PlayerPhysics_FixVAngle(this);
2505
2506         if (frametime) {
2507                 // physics frames: update anticheat stuff
2508                 anticheat_prethink(this);
2509         }
2510
2511         if (blockSpectators && frametime) {
2512                 // WORKAROUND: only use dropclient in server frames (frametime set).
2513                 // Never use it in cl_movement frames (frametime zero).
2514                 checkSpectatorBlock(this);
2515         }
2516
2517         zoomstate_set = false;
2518
2519         // Check for nameless players
2520         if (this.netname == "" || this.netname != CS(this).netname_previous)
2521         {
2522                 bool assume_unchanged = (CS(this).netname_previous == "");
2523                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2524                 {
2525                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2526                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2527                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2528                         assume_unchanged = false;
2529                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2530                 }
2531                 if (isInvisibleString(this.netname))
2532                 {
2533                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2534                         sprint(this, "Warning: invisible names are not allowed.\n");
2535                         assume_unchanged = false;
2536                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2537                 }
2538                 if (!assume_unchanged && autocvar_sv_eventlog)
2539                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2540                 strcpy(CS(this).netname_previous, this.netname);
2541         }
2542
2543         // version nagging
2544         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2545         CS(this).version_nagtime = 0;
2546         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2547             // git client
2548         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2549             // git server
2550             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2551         } else {
2552             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2553             if (r < 0) { // old client
2554                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2555             } else if (r > 0) { // old server
2556                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2557             }
2558         }
2559     }
2560
2561         // GOD MODE info
2562         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2563         {
2564                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2565                 this.max_armorvalue = 0;
2566         }
2567
2568         if (frametime && IS_PLAYER(this))
2569         {
2570                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2571                 {
2572                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2573                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2574                         if (this.iceblock)
2575                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2576
2577                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2578                                 Unfreeze(this, false);
2579                 }
2580                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2581                 {
2582                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2583                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2584
2585                         if (GetResource(this, RES_HEALTH) < 1)
2586                         {
2587                                 if (this.vehicle)
2588                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2589                                 if(this.event_damage)
2590                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2591                         }
2592                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2593                                 Unfreeze(this, false);
2594                 }
2595         }
2596
2597         MUTATOR_CALLHOOK(PlayerPreThink, this);
2598
2599         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2600         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2601         {
2602                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2603                 {
2604                         if(!it.owner)
2605                         {
2606                                 if(!it.team || SAME_TEAM(this, it))
2607                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2608                                 else if(autocvar_g_vehicles_steal)
2609                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2610                         }
2611                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2612                         {
2613                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2614                         }
2615                 });
2616
2617                 this.last_vehiclecheck = time + 1;
2618         }
2619
2620         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2621         {
2622                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2623                         PlayerUseKey(this);
2624                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2625         }
2626
2627         if (IS_REAL_CLIENT(this))
2628                 PrintWelcomeMessage(this);
2629
2630         if (IS_PLAYER(this)) {
2631                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2632                         error("Client can't be spawned as player on connection!");
2633                 if(!PlayerThink(this))
2634                         return;
2635         }
2636         else if (game_stopped || intermission_running) {
2637                 if(intermission_running)
2638                         IntermissionThink(this);
2639                 return;
2640         }
2641         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2642         {
2643                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2644                 CS(this).autojoin_checked = 1;
2645                 // don't do this in ClientConnect
2646                 // many things can go wrong if a client is spawned as player on connection
2647                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2648                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2649                                 && (!teamplay || autocvar_g_balance_teams)))
2650                 {
2651                         campaign_bots_may_start = true;
2652                         if(joinAllowed(this))
2653                                 Join(this);
2654                         return;
2655                 }
2656         }
2657         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2658                 ObserverOrSpectatorThink(this);
2659         }
2660
2661         // WEAPONTODO: Add weapon request for this
2662         if (!zoomstate_set) {
2663                 bool wep_zoomed = false;
2664                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2665                 {
2666                         .entity weaponentity = weaponentities[slot];
2667                         Weapon thiswep = this.(weaponentity).m_weapon;
2668                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2669                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2670                 }
2671                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2672         }
2673
2674         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2675         {
2676                 CS(this).teamkill_soundtime = 0;
2677
2678                 entity e = CS(this).teamkill_soundsource;
2679                 entity oldpusher = e.pusher;
2680                 e.pusher = this;
2681                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2682                 e.pusher = oldpusher;
2683         }
2684
2685         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2686                 CS(this).taunt_soundtime = 0;
2687                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2688         }
2689
2690         target_voicescript_next(this);
2691
2692         // WEAPONTODO: Move into weaponsystem somehow
2693         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2694         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2695         {
2696                 .entity weaponentity = weaponentities[slot];
2697                 if(this.(weaponentity).m_weapon == WEP_Null)
2698                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2699         }
2700 }
2701
2702 void DrownPlayer(entity this)
2703 {
2704         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2705                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2706         {
2707                 STAT(AIR_FINISHED, this) = 0;
2708                 return;
2709         }
2710
2711         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2712         {
2713                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2714                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2715                 STAT(AIR_FINISHED, this) = 0;
2716         }
2717         else
2718         {
2719                 if (!STAT(AIR_FINISHED, this))
2720                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2721                 if (STAT(AIR_FINISHED, this) < time)
2722                 {       // drown!
2723                         if (this.pain_finished < time)
2724                         {
2725                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2726                                 this.pain_finished = time + 0.5;
2727                         }
2728                 }
2729         }
2730 }
2731
2732 .bool move_qcphysics;
2733
2734 void Player_Physics(entity this)
2735 {
2736         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2737
2738         if(!this.move_qcphysics)
2739                 return;
2740
2741         if(!frametime && !CS(this).pm_frametime)
2742                 return;
2743
2744         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2745
2746         CS(this).pm_frametime = 0;
2747 }
2748
2749 /*
2750 =============
2751 PlayerPostThink
2752
2753 Called every frame for each client after the physics are run
2754 =============
2755 */
2756 void PlayerPostThink (entity this)
2757 {
2758         Player_Physics(this);
2759
2760         if (sv_maxidle > 0)
2761         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2762         if (IS_REAL_CLIENT(this))
2763         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2764         {
2765                 int totalClients = 0;
2766                 if(sv_maxidle_slots > 0)
2767                 {
2768                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2769                         {
2770                                 ++totalClients;
2771                         });
2772                 }
2773
2774                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2775                 { /* do nothing */ }
2776                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2777                 {
2778                         if (CS(this).idlekick_lasttimeleft)
2779                         {
2780                                 CS(this).idlekick_lasttimeleft = 0;
2781                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2782                         }
2783                 }
2784                 else
2785                 {
2786                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2787                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2788                                 if (!CS(this).idlekick_lasttimeleft)
2789                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2790                         }
2791                         if (timeleft <= 0) {
2792                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2793                                 dropclient(this);
2794                                 return;
2795                         }
2796                         else if (timeleft <= 10) {
2797                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2798                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2799                 }
2800                                 CS(this).idlekick_lasttimeleft = timeleft;
2801                         }
2802                 }
2803         }
2804
2805         CheatFrame(this);
2806
2807         if (game_stopped)
2808         {
2809                 this.solid = SOLID_NOT;
2810                 this.takedamage = DAMAGE_NO;
2811                 set_movetype(this, MOVETYPE_NONE);
2812                 CS(this).teamkill_complain = 0;
2813                 CS(this).teamkill_soundtime = 0;
2814                 CS(this).teamkill_soundsource = NULL;
2815         }
2816
2817         if (IS_PLAYER(this)) {
2818                 if(this.death_time == time && IS_DEAD(this))
2819                 {
2820                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2821                         // once all the damage events of this frame have been processed with normal size
2822                         this.maxs.z = 5;
2823                         setsize(this, this.mins, this.maxs);
2824                 }
2825                 DrownPlayer(this);
2826                 UpdateChatBubble(this);
2827                 if (CS(this).impulse) ImpulseCommands(this);
2828                 if (game_stopped)
2829                 {
2830                         CSQCMODEL_AUTOUPDATE(this);
2831                         return;
2832                 }
2833                 GetPressedKeys(this);
2834         }
2835         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2836         {
2837                 CS(this).pressedkeys = 0;
2838                 STAT(PRESSED_KEYS, this) = 0;
2839         }
2840
2841         if (this.waypointsprite_attachedforcarrier) {
2842                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2843                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2844         }
2845
2846         CSQCMODEL_AUTOUPDATE(this);
2847 }
2848
2849 /**
2850  * message "": do not say, just test flood control
2851  * return value:
2852  *   1 = accept
2853  *   0 = reject
2854  *  -1 = fake accept
2855  */
2856 int Say(entity source, int teamsay, entity privatesay, string msgin, bool floodcontrol)
2857 {
2858         if (!teamsay && !privatesay && substring(msgin, 0, 1) == " ")
2859                 msgin = substring(msgin, 1, -1); // work around DP say bug (say_team does not have this!)
2860
2861         if (source)
2862                 msgin = formatmessage(source, msgin);
2863
2864         string colorstr;
2865         if (!(IS_PLAYER(source) || source.caplayer))
2866                 colorstr = "^0"; // black for spectators
2867         else if(teamplay)
2868                 colorstr = Team_ColorCode(source.team);
2869         else
2870         {
2871                 colorstr = "";
2872                 teamsay = false;
2873         }
2874
2875         if (!source) {
2876                 colorstr = "";
2877                 teamsay = false;
2878         }
2879
2880         if(msgin != "")
2881                 msgin = trigger_magicear_processmessage_forallears(source, teamsay, privatesay, msgin);
2882
2883         /*
2884          * using bprint solves this... me stupid
2885         // how can we prevent the message from appearing in a listen server?
2886         // for now, just give "say" back and only handle say_team
2887         if(!teamsay)
2888         {
2889                 clientcommand(source, strcat("say ", msgin));
2890                 return;
2891         }
2892         */
2893
2894         string namestr = "";
2895         if (source)
2896                 namestr = playername(source, autocvar_g_chat_teamcolors);
2897
2898         string colorprefix = (strdecolorize(namestr) == namestr) ? "^3" : "^7";
2899
2900         string msgstr = "", cmsgstr = "";
2901         string privatemsgprefix = string_null;
2902         int privatemsgprefixlen = 0;
2903         if (msgin != "")
2904         {
2905                 bool found_me = false;
2906                 if(strstrofs(msgin, "/me", 0) >= 0)
2907                 {
2908                         string newmsgin = "";
2909                         string newnamestr = ((teamsay) ? strcat(colorstr, "(", colorprefix, namestr, colorstr, ")", "^7") : strcat(colorprefix, namestr, "^7"));
2910                         FOREACH_WORD(msgin, true,
2911                         {
2912                                 if(strdecolorize(it) == "/me")
2913                                 {
2914                                         found_me = true;
2915                                         newmsgin = cons(newmsgin, newnamestr);
2916                                 }
2917                                 else
2918                                         newmsgin = cons(newmsgin, it);
2919                         });
2920                         msgin = newmsgin;
2921                 }
2922
2923                 if(privatesay)
2924                 {
2925                         msgstr = strcat("\{1}\{13}* ", colorprefix, namestr, "^3 tells you: ^7");
2926                         privatemsgprefixlen = strlen(msgstr);
2927                         msgstr = strcat(msgstr, msgin);
2928                         cmsgstr = strcat(colorstr, colorprefix, namestr, "^3 tells you:\n^7", msgin);
2929                         privatemsgprefix = strcat("\{1}\{13}* ^3You tell ", playername(privatesay, autocvar_g_chat_teamcolors), ": ^7");
2930                 }
2931                 else if(teamsay)
2932                 {
2933                         if(found_me)
2934                         {
2935                                 //msgin = strreplace("/me", "", msgin);
2936                                 //msgin = substring(msgin, 3, strlen(msgin));
2937                                 //msgin = strreplace("/me", strcat(colorstr, "(", colorprefix, namestr, colorstr, ")^7"), msgin);
2938                                 msgstr = strcat("\{1}\{13}^4* ", "^7", msgin);
2939                         }
2940                         else
2941                                 msgstr = strcat("\{1}\{13}", colorstr, "(", colorprefix, namestr, colorstr, ") ^7", msgin);
2942                         cmsgstr = strcat(colorstr, "(", colorprefix, namestr, colorstr, ")\n^7", msgin);
2943                 }
2944                 else
2945                 {
2946                         if(found_me)
2947                         {
2948                                 //msgin = strreplace("/me", "", msgin);
2949                                 //msgin = substring(msgin, 3, strlen(msgin));
2950                                 //msgin = strreplace("/me", strcat(colorprefix, namestr), msgin);
2951                                 msgstr = strcat("\{1}^4* ^7", msgin);
2952                         }
2953                         else {
2954                                 msgstr = "\{1}";
2955                                 msgstr = strcat(msgstr, (namestr != "") ? strcat(colorprefix, namestr, "^7: ") : "^7");
2956                                 msgstr = strcat(msgstr, msgin);
2957                         }
2958                         cmsgstr = "";
2959                 }
2960                 msgstr = strcat(strreplace("\n", " ", msgstr), "\n"); // newlines only are good for centerprint
2961         }
2962
2963         string fullmsgstr = msgstr;
2964         string fullcmsgstr = cmsgstr;
2965
2966         // FLOOD CONTROL
2967         int flood = 0;
2968         var .float flood_field = floodcontrol_chat;
2969         if(floodcontrol && source)
2970         {
2971                 float flood_spl;
2972                 float flood_burst;
2973                 float flood_lmax;
2974                 float lines;
2975                 if(privatesay)
2976                 {
2977                         flood_spl = autocvar_g_chat_flood_spl_tell;
2978                         flood_burst = autocvar_g_chat_flood_burst_tell;
2979                         flood_lmax = autocvar_g_chat_flood_lmax_tell;
2980                         flood_field = floodcontrol_chattell;
2981                 }
2982                 else if(teamsay)
2983                 {
2984                         flood_spl = autocvar_g_chat_flood_spl_team;
2985                         flood_burst = autocvar_g_chat_flood_burst_team;
2986                         flood_lmax = autocvar_g_chat_flood_lmax_team;
2987                         flood_field = floodcontrol_chatteam;
2988                 }
2989                 else
2990                 {
2991                         flood_spl = autocvar_g_chat_flood_spl;
2992                         flood_burst = autocvar_g_chat_flood_burst;
2993                         flood_lmax = autocvar_g_chat_flood_lmax;
2994                         flood_field = floodcontrol_chat;
2995                 }
2996                 flood_burst = max(0, flood_burst - 1);
2997                 // to match explanation in default.cfg, a value of 3 must allow three-line bursts and not four!
2998
2999                 // do flood control for the default line size
3000                 if(msgstr != "")
3001                 {
3002                         getWrappedLine_remaining = msgstr;
3003                         msgstr = "";
3004                         lines = 0;
3005                         while(getWrappedLine_remaining && (!flood_lmax || lines <= flood_lmax))
3006                         {
3007                                 msgstr = strcat(msgstr, " ", getWrappedLineLen(82.4289758859709, strlennocol)); // perl averagewidth.pl < gfx/vera-sans.width
3008                                 ++lines;
3009                         }
3010                         msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
3011
3012                         if(getWrappedLine_remaining != "")
3013                         {
3014                                 msgstr = strcat(msgstr, "\n");
3015                                 flood = 2;
3016                         }
3017
3018                         if (time >= source.(flood_field))
3019                         {
3020                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + lines * flood_spl;
3021                         }
3022                         else
3023                         {
3024                                 flood = 1;
3025                                 msgstr = fullmsgstr;
3026                         }
3027                 }
3028                 else
3029                 {
3030                         if (time >= source.(flood_field))
3031                                 source.(flood_field) = max(time - flood_burst * flood_spl, source.(flood_field)) + flood_spl;
3032                         else
3033                                 flood = 1;
3034                 }
3035
3036                 if (timeout_status == TIMEOUT_ACTIVE) // when game is paused, no flood protection
3037                         source.(flood_field) = flood = 0;
3038         }
3039
3040         string sourcemsgstr, sourcecmsgstr;
3041         if(flood == 2) // cannot happen for empty msgstr
3042         {
3043                 if(autocvar_g_chat_flood_notify_flooder)
3044                 {
3045                         sourcemsgstr = strcat(msgstr, "\n^3FLOOD CONTROL: ^7message too long, trimmed\n");
3046                         sourcecmsgstr = "";
3047                 }
3048                 else
3049                 {
3050                         sourcemsgstr = fullmsgstr;
3051                         sourcecmsgstr = fullcmsgstr;
3052                 }
3053                 cmsgstr = "";
3054         }
3055         else
3056         {
3057                 sourcemsgstr = msgstr;
3058                 sourcecmsgstr = cmsgstr;
3059         }
3060
3061         if (!privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3062         {
3063                 if (!game_stopped)
3064                 if (teamsay || (autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage))
3065                         teamsay = -1; // spectators
3066         }
3067
3068         if(flood)
3069                 LOG_INFO("NOTE: ", playername(source, true), "^7 is flooding.");
3070
3071         // build sourcemsgstr by cutting off a prefix and replacing it by the other one
3072         if(privatesay)
3073                 sourcemsgstr = strcat(privatemsgprefix, substring(sourcemsgstr, privatemsgprefixlen, -1));
3074
3075         int ret;
3076         if(source && CS(source).muted)
3077         {
3078                 // always fake the message
3079                 ret = -1;
3080         }
3081         else if(flood == 1)
3082         {
3083                 if (autocvar_g_chat_flood_notify_flooder)
3084                 {
3085                         sprint(source, strcat("^3FLOOD CONTROL: ^7wait ^1", ftos(source.(flood_field) - time), "^3 seconds\n"));
3086                         ret = 0;
3087                 }
3088                 else
3089                         ret = -1;
3090         }
3091         else
3092         {
3093                 ret = 1;
3094         }
3095
3096         if (privatesay && source && !(IS_PLAYER(source) || source.caplayer))
3097         {
3098                 if (!game_stopped)
3099                 if ((privatesay && (IS_PLAYER(privatesay) || privatesay.caplayer)) && ((autocvar_g_chat_nospectators == 1) || (autocvar_g_chat_nospectators == 2 && !warmup_stage)))
3100                         ret = -1; // just hide the message completely
3101         }
3102
3103         MUTATOR_CALLHOOK(ChatMessage, source, ret);
3104         ret = M_ARGV(1, int);
3105
3106         string event_log_msg = "";
3107
3108         if(sourcemsgstr != "" && ret != 0)
3109         {
3110                 if(ret < 0) // faked message, because the player is muted
3111                 {
3112                         sprint(source, sourcemsgstr);
3113                         if(sourcecmsgstr != "" && !privatesay)
3114                                 centerprint(source, sourcecmsgstr);
3115                 }
3116                 else if(privatesay) // private message, between 2 people only
3117                 {
3118                         sprint(source, sourcemsgstr);
3119                         if (!autocvar_g_chat_tellprivacy) { dedicated_print(msgstr); } // send to server console too if "tellprivacy" is disabled
3120                         if(!MUTATOR_CALLHOOK(ChatMessageTo, privatesay, source))
3121                         {
3122                                 sprint(privatesay, msgstr);
3123                                 if(cmsgstr != "")
3124                                         centerprint(privatesay, cmsgstr);
3125                         }
3126                 }
3127                 else if ( teamsay && CS(source).active_minigame )
3128                 {
3129                         sprint(source, sourcemsgstr);
3130                         dedicated_print(msgstr); // send to server console too
3131                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && CS(it).active_minigame == CS(source).active_minigame && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3132                                 sprint(it, msgstr);
3133                         });
3134                         event_log_msg = sprintf(":chat_minigame:%d:%s:%s", source.playerid, CS(source).active_minigame.netname, msgin);
3135
3136                 }
3137                 else if(teamsay > 0) // team message, only sent to team mates
3138                 {
3139                         sprint(source, sourcemsgstr);
3140                         dedicated_print(msgstr); // send to server console too
3141                         if(sourcecmsgstr != "")
3142                                 centerprint(source, sourcecmsgstr);
3143                         FOREACH_CLIENT((IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && it.team == source.team && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3144                                 sprint(it, msgstr);
3145                                 if(cmsgstr != "")
3146                                         centerprint(it, cmsgstr);
3147                         });
3148                         event_log_msg = sprintf(":chat_team:%d:%d:%s", source.playerid, source.team, strreplace("\n", " ", msgin));
3149                 }
3150                 else if(teamsay < 0) // spectator message, only sent to spectators
3151                 {
3152                         sprint(source, sourcemsgstr);
3153                         dedicated_print(msgstr); // send to server console too
3154                         FOREACH_CLIENT(!(IS_PLAYER(it) || it.caplayer) && IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3155                                 sprint(it, msgstr);
3156                         });
3157                         event_log_msg = sprintf(":chat_spec:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3158                 }
3159                 else
3160                 {
3161                         if (source) {
3162                                 sprint(source, sourcemsgstr);
3163                                 dedicated_print(msgstr); // send to server console too
3164                                 MX_Say(strcat(playername(source, true), "^7: ", msgin));
3165                         }
3166                         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != source && !MUTATOR_CALLHOOK(ChatMessageTo, it, source), {
3167                                 sprint(it, msgstr);
3168                         });
3169                         event_log_msg = sprintf(":chat:%d:%s", source.playerid, strreplace("\n", " ", msgin));
3170                 }
3171         }
3172
3173         if (autocvar_sv_eventlog && (event_log_msg != "")) {
3174                 GameLogEcho(event_log_msg);
3175         }
3176
3177         return ret;
3178 }
3179
3180 // hack to copy the button fields from the client entity to the Client State
3181 void PM_UpdateButtons(entity this, entity store)
3182 {
3183         if(this.impulse)
3184                 store.impulse = this.impulse;
3185         this.impulse = 0;
3186
3187         bool typing = this.buttonchat || this.button12;
3188
3189         store.button0 = (typing) ? 0 : this.button0;
3190         //button1?!
3191         store.button2 = (typing) ? 0 : this.button2;
3192         store.button3 = (typing) ? 0 : this.button3;
3193         store.button4 = this.button4;
3194         store.button5 = (typing) ? 0 : this.button5;
3195         store.button6 = this.button6;
3196         store.button7 = this.button7;
3197         store.button8 = this.button8;
3198         store.button9 = this.button9;
3199         store.button10 = this.button10;
3200         store.button11 = this.button11;
3201         store.button12 = this.button12;
3202         store.button13 = this.button13;
3203         store.button14 = this.button14;
3204         store.button15 = this.button15;
3205         store.button16 = this.button16;
3206         store.buttonuse = this.buttonuse;
3207         store.buttonchat = this.buttonchat;
3208
3209         store.cursor_active = this.cursor_active;
3210         store.cursor_screen = this.cursor_screen;
3211         store.cursor_trace_start = this.cursor_trace_start;
3212         store.cursor_trace_endpos = this.cursor_trace_endpos;
3213         store.cursor_trace_ent = this.cursor_trace_ent;
3214
3215         store.ping = this.ping;
3216         store.ping_packetloss = this.ping_packetloss;
3217         store.ping_movementloss = this.ping_movementloss;
3218
3219         store.v_angle = this.v_angle;
3220         store.movement = this.movement;
3221 }
3222
3223 NET_HANDLE(fpsreport, bool)
3224 {
3225         int fps = ReadShort();
3226         PlayerScore_Set(sender, SP_FPS, fps);
3227         return true;
3228 }