qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124
 125         if(sf & 16)
 126         {
 127                 float specs = CountSpectators(e, to);
 128                 WriteByte(MSG_ENTITY, specs);
 129                 WriteSpectators(e, to);
 130         }
 131
 132         return true;
 133 }
 134
 135 void ClientData_Attach(entity this)
 136 {
 137         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 138         this.clientdata.drawonlytoclient = this;
 139         this.clientdata.owner = this;
 140 }
 141
 142 void ClientData_Detach(entity this)
 143 {
 144         delete(this.clientdata);
 145         this.clientdata = NULL;
 146 }
 147
 148 void ClientData_Touch(entity e)
 149 {
 150         e.clientdata.SendFlags = 1;
 151
 152         // make it spectatable
 153         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 154 }
 155
 156 .string netname_previous;
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = spot.angles;
 230         this.angles_z = 0;
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 234         this.prevorigin = this.origin;
 235         if (IS_REAL_CLIENT(this))
 236         {
 237             msg_entity = this;
 238             WriteByte(MSG_ONE, SVC_SETVIEW);
 239             WriteEntity(MSG_ONE, this);
 240         }
 241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 243         if(!autocvar_g_debug_globalsounds)
 244         {
 245                 // needed for player sounds
 246                 this.model = "";
 247                 FixPlayermodel(this);
 248         }
 249         setmodel(this, MDL_Null);
 250         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 251         this.view_ofs = '0 0 0';
 252     }
 253
 254     RemoveGrapplingHooks(this);
 255         Portal_ClearAll(this);
 256         Unfreeze(this);
 257         SetSpectatee(this, NULL);
 258
 259         if (this.alivetime)
 260         {
 261                 if (!warmup_stage)
 262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 263                 this.alivetime = 0;
 264         }
 265
 266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 267
 268         WaypointSprite_PlayerDead(this);
 269
 270         if (mutator_returnvalue) {
 271             // mutator prevents resetting teams+score
 272         } else {
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274         this.frags = FRAGS_SPECTATOR;
 275         PlayerScore_Clear(this);  // clear scores when needed
 276     }
 277
 278         if (this.killcount != FRAGS_SPECTATOR)
 279         {
 280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 281                 if(!intermission_running)
 282                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 284
 285                 if(this.just_joined == false) {
 286                         LogTeamchange(this.playerid, -1, 4);
 287                 } else
 288                         this.just_joined = false;
 289         }
 290
 291         accuracy_resend(this);
 292
 293         this.spectatortime = time;
 294         if(this.bot_attack)
 295                 IL_REMOVE(g_bot_targets, this);
 296         this.bot_attack = false;
 297     this.hud = HUD_NORMAL;
 298         TRANSMUTE(Observer, this);
 299         this.iscreature = false;
 300         this.teleportable = TELEPORT_SIMPLE;
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         this.drawonlytoclient = this;
 338
 339         this.weaponmodel = "";
 340         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 341         {
 342                 if(!this.weaponentities[slot])
 343                         continue; // first load
 344                 this.weaponentities[slot].hook_time = 0;
 345                 this.weaponentities[slot].weaponname = "";
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357 }
 358
 359 int player_getspecies(entity this)
 360 {
 361         get_model_parameters(this.model, this.skin);
 362         int s = get_model_parameters_species;
 363         get_model_parameters(string_null, 0);
 364         if (s < 0) return SPECIES_HUMAN;
 365         return s;
 366 }
 367
 368 .float model_randomizer;
 369 void FixPlayermodel(entity player)
 370 {
 371         string defaultmodel = "";
 372         int defaultskin = 0;
 373         if(autocvar_sv_defaultcharacter)
 374         {
 375                 if(teamplay)
 376                 {
 377                         string s = Static_Team_ColorName_Lower(player.team);
 378                         if (s != "neutral")
 379                         {
 380                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 381                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 382                         }
 383                 }
 384
 385                 if(defaultmodel == "")
 386                 {
 387                         defaultmodel = autocvar_sv_defaultplayermodel;
 388                         defaultskin = autocvar_sv_defaultplayerskin;
 389                 }
 390
 391                 int n = tokenize_console(defaultmodel);
 392                 if(n > 0)
 393                 {
 394                         defaultmodel = argv(floor(n * player.model_randomizer));
 395                         // However, do NOT randomize if the player-selected model is in the list.
 396                         for (int i = 0; i < n; ++i)
 397                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 398                                         defaultmodel = argv(i);
 399                 }
 400
 401                 int i = strstrofs(defaultmodel, ":", 0);
 402                 if(i >= 0)
 403                 {
 404                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 405                         defaultmodel = substring(defaultmodel, 0, i);
 406                 }
 407         }
 408         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 409         {
 410                 if(teamplay)
 411                 {
 412                         string s = Static_Team_ColorName_Lower(player.team);
 413                         if (s != "neutral")
 414                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 415                 }
 416
 417                 if(!defaultskin)
 418                         defaultskin = autocvar_sv_defaultplayerskin;
 419         }
 420
 421         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 422         defaultmodel = M_ARGV(0, string);
 423         defaultskin = M_ARGV(1, int);
 424
 425         bool chmdl = false;
 426         int oldskin;
 427         if(defaultmodel != "")
 428         {
 429                 if (defaultmodel != player.model)
 430                 {
 431                         vector m1 = player.mins;
 432                         vector m2 = player.maxs;
 433                         setplayermodel (player, defaultmodel);
 434                         setsize (player, m1, m2);
 435                         chmdl = true;
 436                 }
 437
 438                 oldskin = player.skin;
 439                 player.skin = defaultskin;
 440         } else {
 441                 if (player.playermodel != player.model || player.playermodel == "")
 442                 {
 443                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, player.playermodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 if(!autocvar_sv_defaultcharacterskin)
 452                 {
 453                         oldskin = player.skin;
 454                         player.skin = stof(player.playerskin);
 455                 }
 456                 else
 457                 {
 458                         oldskin = player.skin;
 459                         player.skin = defaultskin;
 460                 }
 461         }
 462
 463         if(chmdl || oldskin != player.skin) // model or skin has changed
 464         {
 465                 player.species = player_getspecies(player); // update species
 466                 if(!autocvar_g_debug_globalsounds)
 467                         UpdatePlayerSounds(player); // update skin sounds
 468         }
 469
 470         if(!teamplay)
 471                 if(strlen(autocvar_sv_defaultplayercolors))
 472                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 473                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 474 }
 475
 476
 477 /** Called when a client spawns in the server */
 478 void PutClientInServer(entity this)
 479 {
 480         if (IS_BOT_CLIENT(this)) {
 481                 TRANSMUTE(Player, this);
 482         } else if (IS_REAL_CLIENT(this)) {
 483                 msg_entity = this;
 484                 WriteByte(MSG_ONE, SVC_SETVIEW);
 485                 WriteEntity(MSG_ONE, this);
 486         }
 487         if (gameover) {
 488                 TRANSMUTE(Observer, this);
 489         }
 490
 491         SetSpectatee(this, NULL);
 492
 493         // reset player keys
 494         this.itemkeys = 0;
 495
 496         MUTATOR_CALLHOOK(PutClientInServer, this);
 497
 498         if (IS_OBSERVER(this)) {
 499                 PutObserverInServer(this);
 500         } else if (IS_PLAYER(this)) {
 501                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 502
 503                 PlayerState_attach(this);
 504                 accuracy_resend(this);
 505
 506                 if (this.team < 0)
 507                         JoinBestTeam(this, false, true);
 508
 509                 entity spot = SelectSpawnPoint(this, false);
 510                 if (!spot) {
 511                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 512                         return; // spawn failed
 513                 }
 514
 515                 TRANSMUTE(Player, this);
 516
 517                 this.wasplayer = true;
 518                 this.iscreature = true;
 519                 this.teleportable = TELEPORT_NORMAL;
 520                 this.damagedbycontents = true;
 521                 set_movetype(this, MOVETYPE_WALK);
 522                 this.solid = SOLID_SLIDEBOX;
 523                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 524                 if (autocvar_g_playerclip_collisions)
 525                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 526                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 527                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 528                 this.frags = FRAGS_PLAYER;
 529                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 530                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 531                 if (autocvar__notarget)
 532                         this.flags |= FL_NOTARGET;
 533                 this.takedamage = DAMAGE_AIM;
 534                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 535                 this.dmg = 2; // WTF
 536
 537                 if (warmup_stage) {
 538                         this.ammo_shells = warmup_start_ammo_shells;
 539                         this.ammo_nails = warmup_start_ammo_nails;
 540                         this.ammo_rockets = warmup_start_ammo_rockets;
 541                         this.ammo_cells = warmup_start_ammo_cells;
 542                         this.ammo_plasma = warmup_start_ammo_plasma;
 543                         this.ammo_fuel = warmup_start_ammo_fuel;
 544                         this.health = warmup_start_health;
 545                         this.armorvalue = warmup_start_armorvalue;
 546                         this.weapons = WARMUP_START_WEAPONS;
 547                 } else {
 548                         this.ammo_shells = start_ammo_shells;
 549                         this.ammo_nails = start_ammo_nails;
 550                         this.ammo_rockets = start_ammo_rockets;
 551                         this.ammo_cells = start_ammo_cells;
 552                         this.ammo_plasma = start_ammo_plasma;
 553                         this.ammo_fuel = start_ammo_fuel;
 554                         this.health = start_health;
 555                         this.armorvalue = start_armorvalue;
 556                         this.weapons = start_weapons;
 557                 }
 558                 SetSpectatee_status(this, 0);
 559
 560                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 561
 562                 this.items = start_items;
 563
 564                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 565                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 566                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 567                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 568                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 569                 // extend the pause of rotting if client was reset at the beginning of the countdown
 570                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 571                         float f = game_starttime - time;
 572                         this.spawnshieldtime += f;
 573                         this.pauserotarmor_finished += f;
 574                         this.pauserothealth_finished += f;
 575                         this.pauseregen_finished += f;
 576                 }
 577                 this.damageforcescale = 2;
 578                 this.death_time = 0;
 579                 this.respawn_flags = 0;
 580                 this.respawn_time = 0;
 581                 this.stat_respawn_time = 0;
 582                 this.scale = autocvar_sv_player_scale;
 583                 this.fade_time = 0;
 584                 this.pain_frame = 0;
 585                 this.pain_finished = 0;
 586                 this.pushltime = 0;
 587                 setthink(this, func_null); // players have no think function
 588                 this.nextthink = 0;
 589                 this.dmg_team = 0;
 590                 this.ballistics_density = autocvar_g_ballistics_density_player;
 591
 592                 this.deadflag = DEAD_NO;
 593
 594                 this.angles = spot.angles;
 595                 this.angles_z = 0; // never spawn tilted even if the spot says to
 596                 if (IS_BOT_CLIENT(this))
 597                         this.v_angle = this.angles;
 598                 this.fixangle = true; // turn this way immediately
 599                 this.oldvelocity = this.velocity = '0 0 0';
 600                 this.avelocity = '0 0 0';
 601                 this.punchangle = '0 0 0';
 602                 this.punchvector = '0 0 0';
 603
 604                 this.strength_finished = 0;
 605                 this.invincible_finished = 0;
 606                 this.fire_endtime = -1;
 607                 this.revival_time = 0;
 608                 this.air_finished = time + 12;
 609
 610                 entity spawnevent = new_pure(spawnevent);
 611                 spawnevent.owner = this;
 612                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 613
 614                 // Cut off any still running player sounds.
 615                 stopsound(this, CH_PLAYER_SINGLE);
 616
 617                 this.model = "";
 618                 FixPlayermodel(this);
 619                 this.drawonlytoclient = NULL;
 620
 621                 this.viewloc = NULL;
 622
 623                 this.crouch = false;
 624                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 625                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 626                 this.spawnorigin = spot.origin;
 627                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 628                 // don't reset back to last position, even if new position is stuck in solid
 629                 this.oldorigin = this.origin;
 630                 this.prevorigin = this.origin;
 631                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 632                 if(this.conveyor)
 633                         IL_REMOVE(g_conveyed, this);
 634                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 635                 this.hud = HUD_NORMAL;
 636
 637                 this.event_damage = PlayerDamage;
 638
 639                 if(!this.bot_attack)
 640                         IL_PUSH(g_bot_targets, this);
 641                 this.bot_attack = true;
 642                 this.monster_attack = true;
 643
 644                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 645
 646                 if (this.killcount == FRAGS_SPECTATOR) {
 647                         PlayerScore_Clear(this);
 648                         this.killcount = 0;
 649                 }
 650
 651                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 652                 {
 653                         .entity weaponentity = weaponentities[slot];
 654                         CL_SpawnWeaponentity(this, weaponentity);
 655                 }
 656                 this.alpha = default_player_alpha;
 657                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 658                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 659
 660                 this.speedrunning = false;
 661
 662                 target_voicescript_clear(this);
 663
 664                 // reset fields the weapons may use
 665                 FOREACH(Weapons, true, LAMBDA(
 666                         it.wr_resetplayer(it, this);
 667                         // reload all reloadable weapons
 668                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 669                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 670                                 {
 671                                         .entity weaponentity = weaponentities[slot];
 672                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 673                                 }
 674                         }
 675                 ));
 676
 677                 {
 678                         string s = spot.target;
 679                         spot.target = string_null;
 680                         SUB_UseTargets(spot, this, NULL);
 681                         spot.target = s;
 682                 }
 683
 684                 Unfreeze(this);
 685
 686                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 687
 688                 if (autocvar_spawn_debug)
 689                 {
 690                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 691                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 692                 }
 693
 694                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695                 {
 696                         .entity weaponentity = weaponentities[slot];
 697                         if(slot == 0)
 698                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 699                         else
 700                                 this.(weaponentity).m_switchweapon = WEP_Null;
 701                         this.(weaponentity).m_weapon = WEP_Null;
 702                         this.(weaponentity).weaponname = "";
 703                         this.(weaponentity).m_switchingweapon = WEP_Null;
 704                         this.(weaponentity).cnt = -1;
 705                 }
 706
 707                 if (!warmup_stage && !this.alivetime)
 708                         this.alivetime = time;
 709
 710                 antilag_clear(this, CS(this));
 711         }
 712 }
 713
 714 void ClientInit_misc(entity this);
 715
 716 // TODO do we need all these fields, or should we stop autodetecting runtime
 717 // changes and just have a console command to update this?
 718 bool ClientInit_SendEntity(entity this, entity to, int sf)
 719 {
 720         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 721         return = true;
 722         msg_entity = to;
 723         // MSG_INIT replacement
 724         // TODO: make easier to use
 725         Registry_send_all();
 726         W_PROP_reload(MSG_ONE, to);
 727         ClientInit_misc(this);
 728         MUTATOR_CALLHOOK(Ent_Init);
 729 }
 730 void ClientInit_misc(entity this)
 731 {
 732         int channel = MSG_ONE;
 733         WriteHeader(channel, ENT_CLIENT_INIT);
 734         WriteByte(channel, g_nexball_meter_period * 32);
 735         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 736         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 737         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 738         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 739         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 740         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 741         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 742         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 743
 744         if(sv_foginterval && world.fog != "")
 745                 WriteString(channel, world.fog);
 746         else
 747                 WriteString(channel, "");
 748         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 749         WriteByte(channel, serverflags);
 750         WriteCoord(channel, autocvar_g_trueaim_minrange);
 751 }
 752
 753 void ClientInit_CheckUpdate(entity this)
 754 {
 755         this.nextthink = time;
 756         if(this.count != autocvar_g_balance_armor_blockpercent)
 757         {
 758                 this.count = autocvar_g_balance_armor_blockpercent;
 759                 this.SendFlags |= 1;
 760         }
 761 }
 762
 763 void ClientInit_Spawn()
 764 {
 765         entity e = new_pure(clientinit);
 766         setthink(e, ClientInit_CheckUpdate);
 767         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 768
 769         ClientInit_CheckUpdate(e);
 770 }
 771
 772 /*
 773 =============
 774 SetNewParms
 775 =============
 776 */
 777 void SetNewParms ()
 778 {
 779         // initialize parms for a new player
 780         parm1 = -(86400 * 366);
 781
 782         MUTATOR_CALLHOOK(SetNewParms);
 783 }
 784
 785 /*
 786 =============
 787 SetChangeParms
 788 =============
 789 */
 790 void SetChangeParms (entity this)
 791 {
 792         // save parms for level change
 793         parm1 = this.parm_idlesince - time;
 794
 795         MUTATOR_CALLHOOK(SetChangeParms);
 796 }
 797
 798 /*
 799 =============
 800 DecodeLevelParms
 801 =============
 802 */
 803 void DecodeLevelParms(entity this)
 804 {
 805         // load parms
 806         this.parm_idlesince = parm1;
 807         if (this.parm_idlesince == -(86400 * 366))
 808                 this.parm_idlesince = time;
 809
 810         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 811         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 812
 813         MUTATOR_CALLHOOK(DecodeLevelParms);
 814 }
 815
 816 /*
 817 =============
 818 ClientKill
 819
 820 Called when a client types 'kill' in the console
 821 =============
 822 */
 823
 824 .float clientkill_nexttime;
 825 void ClientKill_Now_TeamChange(entity this)
 826 {
 827         if(this.killindicator_teamchange == -1)
 828         {
 829                 JoinBestTeam( this, false, true );
 830         }
 831         else if(this.killindicator_teamchange == -2)
 832         {
 833                 if(blockSpectators)
 834                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 835                 PutObserverInServer(this);
 836         }
 837         else
 838                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 839         this.killindicator_teamchange = 0;
 840 }
 841
 842 void ClientKill_Now(entity this)
 843 {
 844         if(this.vehicle)
 845         {
 846             vehicles_exit(this.vehicle, VHEF_RELEASE);
 847             if(!this.killindicator_teamchange)
 848             {
 849             this.vehicle_health = -1;
 850             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 851             }
 852         }
 853
 854         if(this.killindicator && !wasfreed(this.killindicator))
 855                 delete(this.killindicator);
 856
 857         this.killindicator = NULL;
 858
 859         if(this.killindicator_teamchange)
 860                 ClientKill_Now_TeamChange(this);
 861
 862         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 863                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 864
 865         // now I am sure the player IS dead
 866 }
 867 void KillIndicator_Think(entity this)
 868 {
 869         if (gameover)
 870         {
 871                 this.owner.killindicator = NULL;
 872                 delete(this);
 873                 return;
 874         }
 875
 876         if (this.owner.alpha < 0 && !this.owner.vehicle)
 877         {
 878                 this.owner.killindicator = NULL;
 879                 delete(this);
 880                 return;
 881         }
 882
 883         if(this.cnt <= 0)
 884         {
 885                 ClientKill_Now(this.owner);
 886                 return;
 887         }
 888     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 889     {
 890         this.nextthink = time + 1;
 891         this.cnt -= 1;
 892     }
 893         else
 894         {
 895                 if(this.cnt <= 10)
 896                         setmodel(this, MDL_NUM(this.cnt));
 897                 if(IS_REAL_CLIENT(this.owner))
 898                 {
 899                         if(this.cnt <= 10)
 900                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 901                 }
 902                 this.nextthink = time + 1;
 903                 this.cnt -= 1;
 904         }
 905 }
 906
 907 float clientkilltime;
 908 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 909 {
 910         float killtime;
 911         float starttime;
 912
 913         if (gameover)
 914                 return;
 915
 916         killtime = autocvar_g_balance_kill_delay;
 917
 918         if(g_race_qualifying || g_cts)
 919                 killtime = 0;
 920
 921     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 922         return;
 923
 924         this.killindicator_teamchange = targetteam;
 925
 926     if(!this.killindicator)
 927         {
 928                 if(!IS_DEAD(this))
 929                 {
 930                         killtime = max(killtime, this.clientkill_nexttime - time);
 931                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 932                 }
 933
 934                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 935                 {
 936                         ClientKill_Now(this);
 937                 }
 938                 else
 939                 {
 940                         starttime = max(time, clientkilltime);
 941
 942                         this.killindicator = spawn();
 943                         this.killindicator.owner = this;
 944                         this.killindicator.scale = 0.5;
 945                         setattachment(this.killindicator, this, "");
 946                         setorigin(this.killindicator, '0 0 52');
 947                         setthink(this.killindicator, KillIndicator_Think);
 948                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 949                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 950                         this.killindicator.cnt = ceil(killtime);
 951                         this.killindicator.count = bound(0, ceil(killtime), 10);
 952                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 953
 954                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 955                         {
 956                                 it.killindicator = spawn();
 957                                 it.killindicator.owner = it;
 958                                 it.killindicator.scale = 0.5;
 959                                 setattachment(it.killindicator, it, "");
 960                                 setorigin(it.killindicator, '0 0 52');
 961                                 setthink(it.killindicator, KillIndicator_Think);
 962                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 963                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 964                                 it.killindicator.cnt = ceil(killtime);
 965                         });
 966                         this.lip = 0;
 967                 }
 968         }
 969         if(this.killindicator)
 970         {
 971                 if(targetteam == 0) // just die
 972                 {
 973                         this.killindicator.colormod = '0 0 0';
 974                         if(IS_REAL_CLIENT(this))
 975                         if(this.killindicator.cnt > 0)
 976                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 977                 }
 978                 else if(targetteam == -1) // auto
 979                 {
 980                         this.killindicator.colormod = '0 1 0';
 981                         if(IS_REAL_CLIENT(this))
 982                         if(this.killindicator.cnt > 0)
 983                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 984                 }
 985                 else if(targetteam == -2) // spectate
 986                 {
 987                         this.killindicator.colormod = '0.5 0.5 0.5';
 988                         if(IS_REAL_CLIENT(this))
 989                         if(this.killindicator.cnt > 0)
 990                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 991                 }
 992                 else
 993                 {
 994                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 995                         if(IS_REAL_CLIENT(this))
 996                         if(this.killindicator.cnt > 0)
 997                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 998                 }
 999         }
1000
1001 }
1002
1003 void ClientKill (entity this)
1004 {
1005         if(gameover) return;
1006         if(this.player_blocked) return;
1007         if(STAT(FROZEN, this)) return;
1008
1009         ClientKill_TeamChange(this, 0);
1010 }
1011
1012 void FixClientCvars(entity e)
1013 {
1014         // send prediction settings to the client
1015         stuffcmd(e, "\nin_bindmap 0 0\n");
1016         if(autocvar_g_antilag == 3) // client side hitscan
1017                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1018         if(autocvar_sv_gentle)
1019                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1020
1021         MUTATOR_CALLHOOK(FixClientCvars, e);
1022 }
1023
1024 float PlayerInIDList(entity p, string idlist)
1025 {
1026         float n, i;
1027         string s;
1028
1029         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1030         if (!p.crypto_idfp)
1031                 return 0;
1032
1033         // this function allows abbreviated player IDs too!
1034         n = tokenize_console(idlist);
1035         for(i = 0; i < n; ++i)
1036         {
1037                 s = argv(i);
1038                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1039                         return 1;
1040         }
1041
1042         return 0;
1043 }
1044
1045 #ifdef DP_EXT_PRECONNECT
1046 /*
1047 =============
1048 ClientPreConnect
1049
1050 Called once (not at each match start) when a client begins a connection to the server
1051 =============
1052 */
1053 void ClientPreConnect ()
1054 {ENGINE_EVENT();
1055         if(autocvar_sv_eventlog)
1056         {
1057                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1058                         this.playerid,
1059                         etof(this),
1060                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1061                 ));
1062         }
1063 }
1064 #endif
1065
1066 /**
1067 =============
1068 ClientConnect
1069
1070 Called when a client connects to the server
1071 =============
1072 */
1073 void ClientConnect(entity this)
1074 {
1075         if (Ban_MaybeEnforceBanOnce(this)) return;
1076         assert(!IS_CLIENT(this), return);
1077         this.flags |= FL_CLIENT;
1078         assert(player_count >= 0, player_count = 0);
1079
1080 #ifdef WATERMARK
1081         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1082 #endif
1083         this.version_nagtime = time + 10 + random() * 10;
1084         TRANSMUTE(Client, this);
1085
1086         // identify the right forced team
1087         if (autocvar_g_campaign)
1088         {
1089                 if (IS_REAL_CLIENT(this)) // only players, not bots
1090                 {
1091                         switch (autocvar_g_campaign_forceteam)
1092                         {
1093                                 case 1: this.team_forced = NUM_TEAM_1; break;
1094                                 case 2: this.team_forced = NUM_TEAM_2; break;
1095                                 case 3: this.team_forced = NUM_TEAM_3; break;
1096                                 case 4: this.team_forced = NUM_TEAM_4; break;
1097                                 default: this.team_forced = 0;
1098                         }
1099                 }
1100         }
1101         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1102         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1103         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1104         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1105         else switch (autocvar_g_forced_team_otherwise)
1106         {
1107                 default: this.team_forced = 0; break;
1108                 case "red": this.team_forced = NUM_TEAM_1; break;
1109                 case "blue": this.team_forced = NUM_TEAM_2; break;
1110                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1111                 case "pink": this.team_forced = NUM_TEAM_4; break;
1112                 case "spectate":
1113                 case "spectator":
1114                         this.team_forced = -1;
1115                         break;
1116         }
1117         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1118
1119     {
1120         int id = this.playerid;
1121         this.playerid = 0; // silent
1122             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1123             this.playerid = id;
1124     }
1125
1126         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1127                 TRANSMUTE(Observer, this);
1128         } else {
1129                 if (!teamplay || autocvar_g_balance_teams) {
1130                         TRANSMUTE(Player, this);
1131                         campaign_bots_may_start = true;
1132                 } else {
1133                         TRANSMUTE(Observer, this); // do it anyway
1134                 }
1135         }
1136
1137         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1138
1139         // always track bots, don't ask for cl_allow_uidtracking
1140     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1141
1142         if (autocvar_sv_eventlog)
1143                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1144
1145         LogTeamchange(this.playerid, this.team, 1);
1146
1147         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1148
1149         this.netname_previous = strzone(this.netname);
1150
1151         if(teamplay && IS_PLAYER(this))
1152                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1153         else
1154                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1155
1156         stuffcmd(this, clientstuff, "\n");
1157         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1158
1159         FixClientCvars(this);
1160
1161         // get version info from player
1162         stuffcmd(this, "cmd clientversion $gameversion\n");
1163
1164         // notify about available teams
1165         if (teamplay)
1166         {
1167                 CheckAllowedTeams(this);
1168                 int t = 0;
1169                 if (c1 >= 0) t |= BIT(0);
1170                 if (c2 >= 0) t |= BIT(1);
1171                 if (c3 >= 0) t |= BIT(2);
1172                 if (c4 >= 0) t |= BIT(3);
1173                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1174         }
1175         else
1176         {
1177                 stuffcmd(this, "set _teams_available 0\n");
1178         }
1179
1180         bot_relinkplayerlist();
1181
1182         this.spectatortime = time;
1183         if (blockSpectators)
1184         {
1185                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1186         }
1187
1188         this.jointime = time;
1189         this.allowed_timeouts = autocvar_sv_timeout_number;
1190
1191         if (IS_REAL_CLIENT(this))
1192         {
1193                 if (!autocvar_g_campaign)
1194                 {
1195                         this.motd_actived_time = -1;
1196                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1197                 }
1198
1199                 if (g_weaponarena_weapons == WEPSET(TUBA))
1200                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1201         }
1202
1203         if (!sv_foginterval && world.fog != "")
1204                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1205
1206         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1207                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1208                         send_CSQC_teamnagger();
1209
1210         CSQCMODEL_AUTOINIT(this);
1211
1212         this.model_randomizer = random();
1213
1214         if (IS_REAL_CLIENT(this))
1215                 sv_notice_join(this);
1216
1217         // update physics stats (players can spawn before physics runs)
1218         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1219
1220         IL_EACH(g_initforplayer, it.init_for_player, {
1221                 it.init_for_player(it, this);
1222         });
1223
1224         MUTATOR_CALLHOOK(ClientConnect, this);
1225 }
1226 /*
1227 =============
1228 ClientDisconnect
1229
1230 Called when a client disconnects from the server
1231 =============
1232 */
1233 .entity chatbubbleentity;
1234 void ReadyCount();
1235 void ClientDisconnect(entity this)
1236 {
1237         assert(IS_CLIENT(this), return);
1238
1239         PlayerStats_GameReport_FinalizePlayer(this);
1240         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1241         if (this.active_minigame) part_minigame(this);
1242         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1243
1244         if (autocvar_sv_eventlog)
1245                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1246
1247         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1248
1249         SetSpectatee(this, NULL);
1250
1251     MUTATOR_CALLHOOK(ClientDisconnect, this);
1252
1253         ClientState_detach(this);
1254
1255         Portal_ClearAll(this);
1256
1257         Unfreeze(this);
1258
1259         RemoveGrapplingHooks(this);
1260
1261         // Here, everything has been done that requires this player to be a client.
1262
1263         this.flags &= ~FL_CLIENT;
1264
1265         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1266         if (this.killindicator) delete(this.killindicator);
1267
1268         WaypointSprite_PlayerGone(this);
1269
1270         bot_relinkplayerlist();
1271
1272         if (this.netname_previous) strunzone(this.netname_previous);
1273         if (this.clientstatus) strunzone(this.clientstatus);
1274         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1275         if (this.personal) delete(this.personal);
1276
1277         this.playerid = 0;
1278         ReadyCount();
1279         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1280 }
1281
1282 void ChatBubbleThink(entity this)
1283 {
1284         this.nextthink = time;
1285         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1286         {
1287                 if(this.owner) // but why can that ever be NULL?
1288                         this.owner.chatbubbleentity = NULL;
1289                 delete(this);
1290                 return;
1291         }
1292
1293         this.mdl = "";
1294
1295         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1296         {
1297                 if ( this.owner.active_minigame )
1298                         this.mdl = "models/sprites/minigame_busy.iqm";
1299                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1300                         this.mdl = "models/misc/chatbubble.spr";
1301         }
1302
1303         if ( this.model != this.mdl )
1304                 _setmodel(this, this.mdl);
1305
1306 }
1307
1308 void UpdateChatBubble(entity this)
1309 {
1310         if (this.alpha < 0)
1311                 return;
1312         // spawn a chatbubble entity if needed
1313         if (!this.chatbubbleentity)
1314         {
1315                 this.chatbubbleentity = new(chatbubbleentity);
1316                 this.chatbubbleentity.owner = this;
1317                 this.chatbubbleentity.exteriormodeltoclient = this;
1318                 setthink(this.chatbubbleentity, ChatBubbleThink);
1319                 this.chatbubbleentity.nextthink = time;
1320                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1321                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1322                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1323                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1324                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1325                 //this.chatbubbleentity.model = "";
1326                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1327         }
1328 }
1329
1330
1331 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1332 // added to the model skins
1333 /*void UpdateColorModHack()
1334 {
1335         float c;
1336         c = this.clientcolors & 15;
1337         // LordHavoc: only bothering to support white, green, red, yellow, blue
1338              if (!teamplay) this.colormod = '0 0 0';
1339         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1340         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1341         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1342         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1343         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1344         else this.colormod = '1 1 1';
1345 }*/
1346
1347 void respawn(entity this)
1348 {
1349         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1350         {
1351                 this.solid = SOLID_NOT;
1352                 this.takedamage = DAMAGE_NO;
1353                 set_movetype(this, MOVETYPE_FLY);
1354                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1355                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1356                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1357                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1358                 if(autocvar_g_respawn_ghosts_maxtime)
1359                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1360         }
1361
1362         CopyBody(this, 1);
1363
1364         this.effects |= EF_NODRAW; // prevent another CopyBody
1365         PutClientInServer(this);
1366 }
1367
1368 void play_countdown(entity this, float finished, Sound samp)
1369 {
1370     TC(Sound, samp);
1371         if(IS_REAL_CLIENT(this))
1372                 if(floor(finished - time - frametime) != floor(finished - time))
1373                         if(finished - time < 6)
1374                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1375 }
1376
1377 void player_powerups(entity this)
1378 {
1379         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1380         int items_prev = this.items;
1381
1382         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1383                 this.modelflags |= MF_ROCKET;
1384         else
1385                 this.modelflags &= ~MF_ROCKET;
1386
1387         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1388
1389         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1390                 return;
1391
1392         Fire_ApplyDamage(this);
1393         Fire_ApplyEffect(this);
1394
1395         if (!g_instagib)
1396         {
1397                 if (this.items & ITEM_Strength.m_itemid)
1398                 {
1399                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1400                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1401                         if (time > this.strength_finished)
1402                         {
1403                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1404                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1405                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1406                         }
1407                 }
1408                 else
1409                 {
1410                         if (time < this.strength_finished)
1411                         {
1412                                 this.items = this.items | ITEM_Strength.m_itemid;
1413                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1414                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1415                         }
1416                 }
1417                 if (this.items & ITEM_Shield.m_itemid)
1418                 {
1419                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1420                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1421                         if (time > this.invincible_finished)
1422                         {
1423                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1424                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1425                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1426                         }
1427                 }
1428                 else
1429                 {
1430                         if (time < this.invincible_finished)
1431                         {
1432                                 this.items = this.items | ITEM_Shield.m_itemid;
1433                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1435                         }
1436                 }
1437                 if (this.items & IT_SUPERWEAPON)
1438                 {
1439                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1440                         {
1441                                 this.superweapons_finished = 0;
1442                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1443                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1444                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1445                         }
1446                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1447                         {
1448                                 // don't let them run out
1449                         }
1450                         else
1451                         {
1452                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1453                                 if (time > this.superweapons_finished)
1454                                 {
1455                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1456                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1457                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1458                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1459                                 }
1460                         }
1461                 }
1462                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1463                 {
1464                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1465                         {
1466                                 this.items = this.items | IT_SUPERWEAPON;
1467                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1468                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1469                         }
1470                         else
1471                         {
1472                                 this.superweapons_finished = 0;
1473                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1474                         }
1475                 }
1476                 else
1477                 {
1478                         this.superweapons_finished = 0;
1479                 }
1480         }
1481
1482         if(autocvar_g_nodepthtestplayers)
1483                 this.effects = this.effects | EF_NODEPTHTEST;
1484
1485         if(autocvar_g_fullbrightplayers)
1486                 this.effects = this.effects | EF_FULLBRIGHT;
1487
1488         if (time >= game_starttime)
1489         if (time < this.spawnshieldtime)
1490                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1491
1492         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1493 }
1494
1495 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1496 {
1497         if(current > stable)
1498                 return current;
1499         else if(current > stable - 0.25) // when close enough, "snap"
1500                 return stable;
1501         else
1502                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1503 }
1504
1505 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1506 {
1507         if(current < stable)
1508                 return current;
1509         else if(current < stable + 0.25) // when close enough, "snap"
1510                 return stable;
1511         else
1512                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1513 }
1514
1515 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1516 {
1517         if(current > rotstable)
1518         {
1519                 if(rotframetime > 0)
1520                 {
1521                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1522                         current = max(rotstable, current - rotlinear * rotframetime);
1523                 }
1524         }
1525         else if(current < regenstable)
1526         {
1527                 if(regenframetime > 0)
1528                 {
1529                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1530                         current = min(regenstable, current + regenlinear * regenframetime);
1531                 }
1532         }
1533
1534         if(current > limit)
1535                 current = limit;
1536
1537         return current;
1538 }
1539
1540 void player_regen(entity this)
1541 {
1542         float max_mod, regen_mod, rot_mod, limit_mod;
1543         max_mod = regen_mod = rot_mod = limit_mod = 1;
1544
1545         float regen_health = autocvar_g_balance_health_regen;
1546         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1547         float regen_health_rot = autocvar_g_balance_health_rot;
1548         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1549         float regen_health_stable = autocvar_g_balance_health_regenstable;
1550         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1551         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1552                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1553         max_mod = M_ARGV(1, float);
1554         regen_mod = M_ARGV(2, float);
1555         rot_mod = M_ARGV(3, float);
1556         limit_mod = M_ARGV(4, float);
1557         regen_health = M_ARGV(5, float);
1558         regen_health_linear = M_ARGV(6, float);
1559         regen_health_rot = M_ARGV(7, float);
1560         regen_health_rotlinear = M_ARGV(8, float);
1561         regen_health_stable = M_ARGV(9, float);
1562         regen_health_rotstable = M_ARGV(10, float);
1563
1564
1565         if(!mutator_returnvalue)
1566         if(!STAT(FROZEN, this))
1567         {
1568                 float mina, maxa, limith, limita;
1569                 maxa = autocvar_g_balance_armor_rotstable;
1570                 mina = autocvar_g_balance_armor_regenstable;
1571                 limith = autocvar_g_balance_health_limit;
1572                 limita = autocvar_g_balance_armor_limit;
1573
1574                 regen_health_rotstable = regen_health_rotstable * max_mod;
1575                 regen_health_stable = regen_health_stable * max_mod;
1576                 limith = limith * limit_mod;
1577                 limita = limita * limit_mod;
1578
1579                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1580                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1581         }
1582
1583         // if player rotted to death...  die!
1584         // check this outside above checks, as player may still be able to rot to death
1585         if(this.health < 1)
1586         {
1587                 if(this.vehicle)
1588                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1589                 if(this.event_damage)
1590                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1591         }
1592
1593         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1594         {
1595                 float minf, maxf, limitf;
1596
1597                 maxf = autocvar_g_balance_fuel_rotstable;
1598                 minf = autocvar_g_balance_fuel_regenstable;
1599                 limitf = autocvar_g_balance_fuel_limit;
1600
1601                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1602         }
1603 }
1604
1605 bool zoomstate_set;
1606 void SetZoomState(entity this, float z)
1607 {
1608         if(z != this.zoomstate)
1609         {
1610                 this.zoomstate = z;
1611                 ClientData_Touch(this);
1612         }
1613         zoomstate_set = true;
1614 }
1615
1616 void GetPressedKeys(entity this)
1617 {
1618         MUTATOR_CALLHOOK(GetPressedKeys, this);
1619         int keys = STAT(PRESSED_KEYS, this);
1620         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1621         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1622         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1623         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1624
1625         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1626         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1627         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1628         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1629         this.pressedkeys = keys; // store for other users
1630
1631         STAT(PRESSED_KEYS, this) = keys;
1632 }
1633
1634 /*
1635 ======================
1636 spectate mode routines
1637 ======================
1638 */
1639
1640 void SpectateCopy(entity this, entity spectatee)
1641 {
1642     TC(Client, this); TC(Client, spectatee);
1643
1644         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1645         PS(this) = PS(spectatee);
1646         this.armortype = spectatee.armortype;
1647         this.armorvalue = spectatee.armorvalue;
1648         this.ammo_cells = spectatee.ammo_cells;
1649         this.ammo_plasma = spectatee.ammo_plasma;
1650         this.ammo_shells = spectatee.ammo_shells;
1651         this.ammo_nails = spectatee.ammo_nails;
1652         this.ammo_rockets = spectatee.ammo_rockets;
1653         this.ammo_fuel = spectatee.ammo_fuel;
1654         this.clip_load = spectatee.clip_load;
1655         this.clip_size = spectatee.clip_size;
1656         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1657         this.health = spectatee.health;
1658         this.impulse = 0;
1659         this.items = spectatee.items;
1660         this.last_pickup = spectatee.last_pickup;
1661         this.hit_time = spectatee.hit_time;
1662         this.strength_finished = spectatee.strength_finished;
1663         this.invincible_finished = spectatee.invincible_finished;
1664         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1665         this.weapons = spectatee.weapons;
1666         this.vortex_charge = spectatee.vortex_charge;
1667         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1668         this.hagar_load = spectatee.hagar_load;
1669         this.arc_heat_percent = spectatee.arc_heat_percent;
1670         this.minelayer_mines = spectatee.minelayer_mines;
1671         this.punchangle = spectatee.punchangle;
1672         this.view_ofs = spectatee.view_ofs;
1673         this.velocity = spectatee.velocity;
1674         this.dmg_take = spectatee.dmg_take;
1675         this.dmg_save = spectatee.dmg_save;
1676         this.dmg_inflictor = spectatee.dmg_inflictor;
1677         this.v_angle = spectatee.v_angle;
1678         this.angles = spectatee.v_angle;
1679         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1680         this.revive_progress = spectatee.revive_progress;
1681         this.viewloc = spectatee.viewloc;
1682         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1683                 this.fixangle = true;
1684         setorigin(this, spectatee.origin);
1685         setsize(this, spectatee.mins, spectatee.maxs);
1686         SetZoomState(this, spectatee.zoomstate);
1687
1688         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1689         {
1690                 .entity weaponentity = weaponentities[slot];
1691                 this.(weaponentity) = spectatee.(weaponentity);
1692         }
1693
1694     anticheat_spectatecopy(this, spectatee);
1695         this.hud = spectatee.hud;
1696         if(spectatee.vehicle)
1697     {
1698         this.angles = spectatee.v_angle;
1699
1700         //this.fixangle = false;
1701         //this.velocity = spectatee.vehicle.velocity;
1702         this.vehicle_health = spectatee.vehicle_health;
1703         this.vehicle_shield = spectatee.vehicle_shield;
1704         this.vehicle_energy = spectatee.vehicle_energy;
1705         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1706         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1707         this.vehicle_reload1 = spectatee.vehicle_reload1;
1708         this.vehicle_reload2 = spectatee.vehicle_reload2;
1709
1710         //msg_entity = this;
1711
1712        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1713             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1714            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1715            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1716
1717         //WriteByte (MSG_ONE, SVC_SETVIEW);
1718         //    WriteEntity(MSG_ONE, this);
1719         //makevectors(spectatee.v_angle);
1720         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1721     }
1722 }
1723
1724 bool SpectateUpdate(entity this)
1725 {
1726         if(!this.enemy)
1727                 return false;
1728
1729         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1730         {
1731                 SetSpectatee(this, NULL);
1732                 return false;
1733         }
1734
1735         SpectateCopy(this, this.enemy);
1736
1737         return true;
1738 }
1739
1740 bool SpectateSet(entity this)
1741 {
1742         if(!IS_PLAYER(this.enemy))
1743                 return false;
1744
1745         ClientData_Touch(this.enemy);
1746
1747         msg_entity = this;
1748         WriteByte(MSG_ONE, SVC_SETVIEW);
1749         WriteEntity(MSG_ONE, this.enemy);
1750         set_movetype(this, MOVETYPE_NONE);
1751         accuracy_resend(this);
1752
1753         if(!SpectateUpdate(this))
1754                 PutObserverInServer(this);
1755
1756         return true;
1757 }
1758
1759 void SetSpectatee_status(entity this, int spectatee_num)
1760 {
1761         int oldspectatee_status = this.spectatee_status;
1762         this.spectatee_status = spectatee_num;
1763
1764         if (this.spectatee_status != oldspectatee_status)
1765         {
1766                 ClientData_Touch(this);
1767                 if (g_race || g_cts) race_InitSpectator();
1768         }
1769 }
1770
1771 void SetSpectatee(entity this, entity spectatee)
1772 {
1773         entity old_spectatee = this.enemy;
1774
1775         this.enemy = spectatee;
1776
1777         // WEAPONTODO
1778         // these are required to fix the spectator bug with arc
1779         if(old_spectatee)
1780         {
1781                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1782                 {
1783                         .entity weaponentity = weaponentities[slot];
1784                         if(old_spectatee.(weaponentity).arc_beam)
1785                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1786                 }
1787         }
1788         if(this.enemy)
1789         {
1790                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1791                 {
1792                         .entity weaponentity = weaponentities[slot];
1793                         if(this.enemy.(weaponentity).arc_beam)
1794                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1795                 }
1796         }
1797
1798         if (this.enemy)
1799                 SetSpectatee_status(this, etof(this.enemy));
1800
1801         // needed to update spectator list
1802         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1803 }
1804
1805 bool Spectate(entity this, entity pl)
1806 {
1807         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1808                 return false;
1809         pl = M_ARGV(1, entity);
1810
1811         SetSpectatee(this, pl);
1812         return SpectateSet(this);
1813 }
1814
1815 bool SpectateNext(entity this)
1816 {
1817         entity ent = find(this.enemy, classname, STR_PLAYER);
1818
1819         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1820                 ent = M_ARGV(1, entity);
1821         else if (!ent)
1822                 ent = find(ent, classname, STR_PLAYER);
1823
1824         if(ent) { SetSpectatee(this, ent); }
1825
1826         return SpectateSet(this);
1827 }
1828
1829 bool SpectatePrev(entity this)
1830 {
1831         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1832         entity ent = findchain(classname, STR_PLAYER);
1833         if (!ent) // no player
1834                 return false;
1835
1836         entity first = ent;
1837         // skip players until current spectated player
1838         if(this.enemy)
1839         while(ent && ent != this.enemy)
1840                 ent = ent.chain;
1841
1842         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1843         {
1844                 case MUT_SPECPREV_FOUND:
1845                     ent = M_ARGV(1, entity);
1846                     break;
1847                 case MUT_SPECPREV_RETURN:
1848                     return true;
1849                 case MUT_SPECPREV_CONTINUE:
1850                 default:
1851                 {
1852                         if(ent.chain)
1853                                 ent = ent.chain;
1854                         else
1855                                 ent = first;
1856                         break;
1857                 }
1858         }
1859
1860         SetSpectatee(this, ent);
1861         return SpectateSet(this);
1862 }
1863
1864 /*
1865 =============
1866 ShowRespawnCountdown()
1867
1868 Update a respawn countdown display.
1869 =============
1870 */
1871 void ShowRespawnCountdown(entity this)
1872 {
1873         float number;
1874         if(!IS_DEAD(this)) // just respawned?
1875                 return;
1876         else
1877         {
1878                 number = ceil(this.respawn_time - time);
1879                 if(number <= 0)
1880                         return;
1881                 if(number <= this.respawn_countdown)
1882                 {
1883                         this.respawn_countdown = number - 1;
1884                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1885                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1886                 }
1887         }
1888 }
1889
1890 .bool team_selected;
1891 bool ShowTeamSelection(entity this)
1892 {
1893         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1894                 return false;
1895         stuffcmd(this, "menu_showteamselect\n");
1896         return true;
1897 }
1898 void Join(entity this)
1899 {
1900         TRANSMUTE(Player, this);
1901
1902         if(!this.team_selected)
1903         if(autocvar_g_campaign || autocvar_g_balance_teams)
1904                 JoinBestTeam(this, false, true);
1905
1906         if(autocvar_g_campaign)
1907                 campaign_bots_may_start = true;
1908
1909         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1910
1911         PutClientInServer(this);
1912
1913         if(teamplay && this.team != -1)
1914                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1915         else
1916                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1917         this.team_selected = false;
1918 }
1919
1920 /**
1921  * Determines whether the player is allowed to join. This depends on cvar
1922  * g_maxplayers, if it isn't used this function always return true, otherwise
1923  * it checks whether the number of currently playing players exceeds g_maxplayers.
1924  * @return int number of free slots for players, 0 if none
1925  */
1926 int nJoinAllowed(entity this, entity ignore)
1927 {
1928         if(!ignore)
1929         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1930         // so report 0 free slots if restricted
1931         {
1932                 if(autocvar_g_forced_team_otherwise == "spectate")
1933                         return 0;
1934                 if(autocvar_g_forced_team_otherwise == "spectator")
1935                         return 0;
1936         }
1937
1938         if(this && this.team_forced < 0)
1939                 return 0; // forced spectators can never join
1940
1941         // TODO simplify this
1942         int totalClients = 0;
1943         int currentlyPlaying = 0;
1944         FOREACH_CLIENT(true, LAMBDA(
1945                 if(it != ignore)
1946                         ++totalClients;
1947                 if(IS_REAL_CLIENT(it))
1948                 if(IS_PLAYER(it) || it.caplayer)
1949                         ++currentlyPlaying;
1950         ));
1951
1952         float free_slots = 0;
1953         if (!autocvar_g_maxplayers)
1954                 free_slots = maxclients - totalClients;
1955         else if(currentlyPlaying < autocvar_g_maxplayers)
1956                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1957
1958         static float join_prevent_msg_time = 0;
1959         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1960         {
1961                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1962                 join_prevent_msg_time = time + 3;
1963         }
1964
1965         return free_slots;
1966 }
1967
1968 /**
1969  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1970  * g_maxplayers_spectator_blocktime seconds
1971  */
1972 void checkSpectatorBlock(entity this)
1973 {
1974         if(IS_SPEC(this) || IS_OBSERVER(this))
1975         if(!this.caplayer)
1976         if(IS_REAL_CLIENT(this))
1977         {
1978                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1979                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1980                         dropclient(this);
1981                 }
1982         }
1983 }
1984
1985 void PrintWelcomeMessage(entity this)
1986 {
1987         if(this.motd_actived_time == 0)
1988         {
1989                 if (autocvar_g_campaign) {
1990                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1991                                 this.motd_actived_time = time;
1992                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1993                         }
1994                 } else {
1995                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1996                                 this.motd_actived_time = time;
1997                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1998                         }
1999                 }
2000         }
2001         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2002         {
2003                 if (autocvar_g_campaign) {
2004                         if (PHYS_INPUT_BUTTON_INFO(this))
2005                                 this.motd_actived_time = time;
2006                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2007                                 this.motd_actived_time = 0;
2008                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2009                         }
2010                 } else {
2011                         if (PHYS_INPUT_BUTTON_INFO(this))
2012                                 this.motd_actived_time = time;
2013                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2014                                 this.motd_actived_time = 0;
2015                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2016                         }
2017                 }
2018         }
2019         else //if(this.motd_actived_time < 0) // just connected, motd is active
2020         {
2021                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2022                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2023                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2024                 {
2025                         // instanctly hide MOTD
2026                         this.motd_actived_time = 0;
2027                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2028                 }
2029         }
2030 }
2031
2032 bool joinAllowed(entity this)
2033 {
2034         if (this.version_mismatch) return false;
2035         if (!nJoinAllowed(this, this)) return false;
2036         if (teamplay && lockteams) return false;
2037         if (ShowTeamSelection(this)) return false;
2038         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2039         return true;
2040 }
2041
2042 void ObserverThink(entity this)
2043 {
2044         if ( this.impulse )
2045         {
2046                 MinigameImpulse(this, this.impulse);
2047                 this.impulse = 0;
2048         }
2049
2050         if (this.flags & FL_JUMPRELEASED) {
2051                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2052                         this.flags &= ~FL_JUMPRELEASED;
2053                         this.flags |= FL_SPAWNING;
2054                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2055                         this.flags &= ~FL_JUMPRELEASED;
2056                         if(SpectateNext(this)) {
2057                                 TRANSMUTE(Spectator, this);
2058                         }
2059                 } else {
2060                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2061                         set_movetype(this, preferred_movetype);
2062                 }
2063         } else {
2064                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2065                         this.flags |= FL_JUMPRELEASED;
2066                         if(this.flags & FL_SPAWNING)
2067                         {
2068                                 this.flags &= ~FL_SPAWNING;
2069                                 Join(this);
2070                                 return;
2071                         }
2072                 }
2073         }
2074 }
2075
2076 void SpectatorThink(entity this)
2077 {
2078         if ( this.impulse )
2079         {
2080                 if(MinigameImpulse(this, this.impulse))
2081                         this.impulse = 0;
2082
2083                 if (this.impulse == IMP_weapon_drop.impulse)
2084                 {
2085                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2086                         this.impulse = 0;
2087                         return;
2088                 }
2089         }
2090
2091         if (this.flags & FL_JUMPRELEASED) {
2092                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2093                         this.flags &= ~FL_JUMPRELEASED;
2094                         this.flags |= FL_SPAWNING;
2095                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2096                         this.flags &= ~FL_JUMPRELEASED;
2097                         if(SpectateNext(this)) {
2098                                 TRANSMUTE(Spectator, this);
2099                         } else {
2100                                 TRANSMUTE(Observer, this);
2101                                 PutClientInServer(this);
2102                         }
2103                         this.impulse = 0;
2104                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2105                         this.flags &= ~FL_JUMPRELEASED;
2106                         if(SpectatePrev(this)) {
2107                                 TRANSMUTE(Spectator, this);
2108                         } else {
2109                                 TRANSMUTE(Observer, this);
2110                                 PutClientInServer(this);
2111                         }
2112                         this.impulse = 0;
2113                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2114                         this.flags &= ~FL_JUMPRELEASED;
2115                         TRANSMUTE(Observer, this);
2116                         PutClientInServer(this);
2117                 } else {
2118                         if(!SpectateUpdate(this))
2119                                 PutObserverInServer(this);
2120                 }
2121         } else {
2122                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2123                         this.flags |= FL_JUMPRELEASED;
2124                         if(this.flags & FL_SPAWNING)
2125                         {
2126                                 this.flags &= ~FL_SPAWNING;
2127                                 Join(this);
2128                                 return;
2129                         }
2130                 }
2131                 if(!SpectateUpdate(this))
2132                         PutObserverInServer(this);
2133         }
2134
2135         this.flags |= FL_CLIENT | FL_NOTARGET;
2136 }
2137
2138 void vehicles_enter (entity pl, entity veh);
2139 void PlayerUseKey(entity this)
2140 {
2141         if (!IS_PLAYER(this))
2142                 return;
2143
2144         if(this.vehicle)
2145         {
2146                 if(!gameover)
2147                 {
2148                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2149                         return;
2150                 }
2151         }
2152         else if(autocvar_g_vehicles_enter)
2153         {
2154                 if(!STAT(FROZEN, this))
2155                 if(!IS_DEAD(this))
2156                 if(!gameover)
2157                 {
2158                         entity head, closest_target = NULL;
2159                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2160
2161                         while(head) // find the closest acceptable target to enter
2162                         {
2163                                 if(IS_VEHICLE(head))
2164                                 if(!IS_DEAD(head))
2165                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2166                                 if(head.takedamage != DAMAGE_NO)
2167                                 {
2168                                         if(closest_target)
2169                                         {
2170                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2171                                                 { closest_target = head; }
2172                                         }
2173                                         else { closest_target = head; }
2174                                 }
2175
2176                                 head = head.chain;
2177                         }
2178
2179                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2180                 }
2181         }
2182
2183         // a use key was pressed; call handlers
2184         MUTATOR_CALLHOOK(PlayerUseKey, this);
2185 }
2186
2187
2188 /*
2189 =============
2190 PlayerPreThink
2191
2192 Called every frame for each client before the physics are run
2193 =============
2194 */
2195 .float usekeypressed;
2196 .float last_vehiclecheck;
2197 .int items_added;
2198 void PlayerPreThink (entity this)
2199 {
2200         WarpZone_PlayerPhysics_FixVAngle(this);
2201
2202     STAT(GAMESTARTTIME, this) = game_starttime;
2203         STAT(ROUNDSTARTTIME, this) = round_starttime;
2204         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2205         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2206
2207         STAT(WEAPONSINMAP, this) = weaponsInMap;
2208
2209         if (frametime) {
2210                 // physics frames: update anticheat stuff
2211                 anticheat_prethink(this);
2212         }
2213
2214         if (blockSpectators && frametime) {
2215                 // WORKAROUND: only use dropclient in server frames (frametime set).
2216                 // Never use it in cl_movement frames (frametime zero).
2217                 checkSpectatorBlock(this);
2218     }
2219
2220         zoomstate_set = false;
2221
2222         // Check for nameless players
2223         if (isInvisibleString(this.netname)) {
2224                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2225                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2226         }
2227         if (this.netname != this.netname_previous) {
2228                 if (autocvar_sv_eventlog) {
2229                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2230         }
2231                 if (this.netname_previous) strunzone(this.netname_previous);
2232                 this.netname_previous = strzone(this.netname);
2233         }
2234
2235         // version nagging
2236         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2237         this.version_nagtime = 0;
2238         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2239             // git client
2240         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2241             // git server
2242             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2243         } else {
2244             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2245             if (r < 0) { // old client
2246                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2247             } else if (r > 0) { // old server
2248                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2249             }
2250         }
2251     }
2252
2253         // GOD MODE info
2254         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2255         {
2256                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2257                 this.max_armorvalue = 0;
2258         }
2259
2260         if (STAT(FROZEN, this) == 2)
2261         {
2262                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2263                 this.health = max(1, this.revive_progress * start_health);
2264                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2265
2266                 if (this.revive_progress >= 1)
2267                         Unfreeze(this);
2268         }
2269         else if (STAT(FROZEN, this) == 3)
2270         {
2271                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2272                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2273
2274                 if (this.health < 1)
2275                 {
2276                         if (this.vehicle)
2277                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2278                         if(this.event_damage)
2279                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2280                 }
2281                 else if (this.revive_progress <= 0)
2282                         Unfreeze(this);
2283         }
2284
2285         MUTATOR_CALLHOOK(PlayerPreThink, this);
2286
2287         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2288         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2289         {
2290                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2291                 {
2292                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2293                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2294                         {
2295                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2296                         }
2297                         else if(!it.owner)
2298                         {
2299                                 if(!it.team || SAME_TEAM(this, it))
2300                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2301                                 else if(autocvar_g_vehicles_steal)
2302                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2303                         }
2304                 });
2305
2306                 this.last_vehiclecheck = time + 1;
2307         }
2308
2309         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2310         {
2311                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2312                         PlayerUseKey(this);
2313                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2314         }
2315
2316         if (IS_REAL_CLIENT(this))
2317                 PrintWelcomeMessage(this);
2318
2319         if (IS_PLAYER(this)) {
2320                 CheckRules_Player(this);
2321
2322                 if (intermission_running) {
2323                         IntermissionThink(this);
2324                         return;
2325                 }
2326
2327                 if (timeout_status == TIMEOUT_ACTIVE) {
2328             // don't allow the player to turn around while game is paused
2329                         // FIXME turn this into CSQC stuff
2330                         this.v_angle = this.lastV_angle;
2331                         this.angles = this.lastV_angle;
2332                         this.fixangle = true;
2333                 }
2334
2335                 if (frametime) player_powerups(this);
2336
2337                 if (IS_DEAD(this)) {
2338                         if (this.personal && g_race_qualifying) {
2339                                 if (time > this.respawn_time) {
2340                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2341                                         respawn(this);
2342                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2343                                 }
2344                         } else {
2345                                 if (frametime) player_anim(this);
2346                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2347
2348                                 switch(this.deadflag)
2349                                 {
2350                                         case DEAD_DYING:
2351                                         {
2352                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2353                                                         this.deadflag = DEAD_RESPAWNING;
2354                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2355                                                         this.deadflag = DEAD_DEAD;
2356                                                 break;
2357                                         }
2358                                         case DEAD_DEAD:
2359                                         {
2360                                                 if (button_pressed)
2361                                                         this.deadflag = DEAD_RESPAWNABLE;
2362                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2363                                                         this.deadflag = DEAD_RESPAWNING;
2364                                                 break;
2365                                         }
2366                                         case DEAD_RESPAWNABLE:
2367                                         {
2368                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2369                                                         this.deadflag = DEAD_RESPAWNING;
2370                                                 break;
2371                                         }
2372                                         case DEAD_RESPAWNING:
2373                                         {
2374                                                 if (time > this.respawn_time)
2375                                                 {
2376                                                         this.respawn_time = time + 1; // only retry once a second
2377                                                         this.respawn_time_max = this.respawn_time;
2378                                                         respawn(this);
2379                                                 }
2380                                                 break;
2381                                         }
2382                                 }
2383
2384                                 ShowRespawnCountdown(this);
2385
2386                                 if (this.respawn_flags & RESPAWN_SILENT)
2387                                         STAT(RESPAWN_TIME, this) = 0;
2388                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2389                                 {
2390                                         if (time < this.respawn_time)
2391                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2392                                         else if (this.deadflag != DEAD_RESPAWNING)
2393                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2394                                 }
2395                                 else
2396                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2397                         }
2398
2399                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2400                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2401                                 STAT(RESPAWN_TIME, this) *= -1;
2402
2403                         return;
2404                 }
2405
2406                 this.prevorigin = this.origin;
2407
2408                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2409                 if (this.hook.state) {
2410                         do_crouch = false;
2411                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2412                         do_crouch = false;
2413                 } else if (this.vehicle) {
2414                         do_crouch = false;
2415                 } else if (STAT(FROZEN, this)) {
2416                         do_crouch = false;
2417         }
2418
2419                 if (do_crouch) {
2420                         if (!this.crouch) {
2421                                 this.crouch = true;
2422                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2423                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2424                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2425                         }
2426                 } else if (this.crouch) {
2427             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2428             if (!trace_startsolid) {
2429                 this.crouch = false;
2430                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2431                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2432             }
2433                 }
2434
2435                 FixPlayermodel(this);
2436
2437                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2438                 //if(frametime)
2439                 {
2440                         this.items &= ~this.items_added;
2441
2442                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2443                         {
2444                                 .entity weaponentity = weaponentities[slot];
2445                                 W_WeaponFrame(this, weaponentity);
2446
2447                                 if(slot == 0)
2448                                 {
2449                                         this.clip_load = this.(weaponentity).clip_load;
2450                                         this.clip_size = this.(weaponentity).clip_size;
2451                                 }
2452                         }
2453
2454                         this.items_added = 0;
2455                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2456                 this.items_added |= IT_FUEL;
2457
2458                         this.items |= this.items_added;
2459                 }
2460
2461                 player_regen(this);
2462
2463                 // WEAPONTODO: Add a weapon request for this
2464                 // rot vortex charge to the charge limit
2465                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2466                 {
2467                         .entity weaponentity = weaponentities[slot];
2468                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2469                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2470                 }
2471
2472                 if (frametime) player_anim(this);
2473
2474                 // secret status
2475                 secrets_setstatus(this);
2476
2477                 // monsters status
2478                 monsters_setstatus(this);
2479
2480                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2481         }
2482         else if (gameover) {
2483                 if (intermission_running) IntermissionThink(this);
2484                 return;
2485         }
2486         else if (IS_OBSERVER(this)) {
2487                 ObserverThink(this);
2488         }
2489         else if (IS_SPEC(this)) {
2490                 SpectatorThink(this);
2491         }
2492
2493         // WEAPONTODO: Add weapon request for this
2494         if (!zoomstate_set) {
2495                 bool wep_zoomed = false;
2496                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2497                 {
2498                         .entity weaponentity = weaponentities[slot];
2499                         Weapon thiswep = this.(weaponentity).m_weapon;
2500                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2501                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2502                 }
2503                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2504     }
2505
2506         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2507         {
2508                 this.teamkill_soundtime = 0;
2509
2510                 entity e = this.teamkill_soundsource;
2511                 entity oldpusher = e.pusher;
2512                 e.pusher = this;
2513                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2514                 e.pusher = oldpusher;
2515         }
2516
2517         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2518                 this.taunt_soundtime = 0;
2519                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2520         }
2521
2522         target_voicescript_next(this);
2523
2524         // WEAPONTODO: Move into weaponsystem somehow
2525         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2526         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2527         {
2528                 .entity weaponentity = weaponentities[slot];
2529                 if(this.(weaponentity).m_weapon == WEP_Null)
2530                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2531         }
2532 }
2533
2534 void DrownPlayer(entity this)
2535 {
2536         if(IS_DEAD(this))
2537                 return;
2538
2539         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2540         {
2541                 if(this.air_finished < time)
2542                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2543                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2544                 this.dmg = 2;
2545         }
2546         else if (this.air_finished < time)
2547         {       // drown!
2548                 if (this.pain_finished < time)
2549                 {
2550                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2551                         this.pain_finished = time + 0.5;
2552                 }
2553         }
2554 }
2555
2556 .bool move_qcphysics;
2557
2558 void Player_Physics(entity this)
2559 {
2560         set_movetype(this, this.move_movetype);
2561
2562         if(!this.move_qcphysics)
2563                 return;
2564
2565         if(!frametime && !this.pm_frametime)
2566                 return;
2567
2568         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2569
2570         this.pm_frametime = 0;
2571 }
2572
2573 /*
2574 =============
2575 PlayerPostThink
2576
2577 Called every frame for each client after the physics are run
2578 =============
2579 */
2580 .float idlekick_lasttimeleft;
2581 void PlayerPostThink (entity this)
2582 {
2583         Player_Physics(this);
2584
2585         if (sv_maxidle > 0)
2586         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2587         if (IS_REAL_CLIENT(this))
2588         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2589         {
2590                 int totalClients = 0;
2591                 if(sv_maxidle_slots > 0)
2592                 {
2593                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2594                         {
2595                                 ++totalClients;
2596                         });
2597                 }
2598
2599                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2600                 { /* do nothing */ }
2601                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2602                 {
2603                         if (this.idlekick_lasttimeleft)
2604                         {
2605                                 this.idlekick_lasttimeleft = 0;
2606                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2607                         }
2608                 }
2609                 else
2610                 {
2611                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2612                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2613                                 if (!this.idlekick_lasttimeleft)
2614                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2615                         }
2616                         if (timeleft <= 0) {
2617                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2618                                 dropclient(this);
2619                                 return;
2620                         }
2621                         else if (timeleft <= 10) {
2622                                 if (timeleft != this.idlekick_lasttimeleft) {
2623                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2624                 }
2625                                 this.idlekick_lasttimeleft = timeleft;
2626                         }
2627                 }
2628         }
2629
2630         CheatFrame(this);
2631
2632         //CheckPlayerJump();
2633
2634         if (IS_PLAYER(this)) {
2635                 DrownPlayer(this);
2636                 CheckRules_Player(this);
2637                 UpdateChatBubble(this);
2638                 if (this.impulse) ImpulseCommands(this);
2639                 if (intermission_running) return; // intermission or finale
2640                 GetPressedKeys(this);
2641         }
2642
2643         if (this.waypointsprite_attachedforcarrier) {
2644             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2645                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2646     }
2647
2648         playerdemo_write(this);
2649
2650         CSQCMODEL_AUTOUPDATE(this);
2651 }