qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124
 125         if(sf & 16)
 126         {
 127                 float specs = CountSpectators(e, to);
 128                 WriteByte(MSG_ENTITY, specs);
 129                 WriteSpectators(e, to);
 130         }
 131
 132         return true;
 133 }
 134
 135 void ClientData_Attach(entity this)
 136 {
 137         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 138         this.clientdata.drawonlytoclient = this;
 139         this.clientdata.owner = this;
 140 }
 141
 142 void ClientData_Detach(entity this)
 143 {
 144         delete(this.clientdata);
 145         this.clientdata = NULL;
 146 }
 147
 148 void ClientData_Touch(entity e)
 149 {
 150         e.clientdata.SendFlags = 1;
 151
 152         // make it spectatable
 153         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 154 }
 155
 156 .string netname_previous;
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = spot.angles;
 230         this.angles_z = 0;
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 234         this.prevorigin = this.origin;
 235         if (IS_REAL_CLIENT(this))
 236         {
 237             msg_entity = this;
 238             WriteByte(MSG_ONE, SVC_SETVIEW);
 239             WriteEntity(MSG_ONE, this);
 240         }
 241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 243         if(!autocvar_g_debug_globalsounds)
 244         {
 245                 // needed for player sounds
 246                 this.model = "";
 247                 FixPlayermodel(this);
 248         }
 249         setmodel(this, MDL_Null);
 250         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 251         this.view_ofs = '0 0 0';
 252     }
 253
 254     RemoveGrapplingHooks(this);
 255         Portal_ClearAll(this);
 256         Unfreeze(this);
 257         SetSpectatee(this, NULL);
 258
 259         if (this.alivetime)
 260         {
 261                 if (!warmup_stage)
 262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 263                 this.alivetime = 0;
 264         }
 265
 266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 267
 268         WaypointSprite_PlayerDead(this);
 269
 270         if (mutator_returnvalue) {
 271             // mutator prevents resetting teams+score
 272         } else {
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274         this.frags = FRAGS_SPECTATOR;
 275         PlayerScore_Clear(this);  // clear scores when needed
 276     }
 277
 278         if (this.killcount != FRAGS_SPECTATOR)
 279         {
 280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 281                 if(!intermission_running)
 282                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 284
 285                 if(this.just_joined == false) {
 286                         LogTeamchange(this.playerid, -1, 4);
 287                 } else
 288                         this.just_joined = false;
 289         }
 290
 291         accuracy_resend(this);
 292
 293         this.spectatortime = time;
 294         if(this.bot_attack)
 295                 IL_REMOVE(g_bot_targets, this);
 296         this.bot_attack = false;
 297     this.hud = HUD_NORMAL;
 298         TRANSMUTE(Observer, this);
 299         this.iscreature = false;
 300         this.teleportable = TELEPORT_SIMPLE;
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         this.drawonlytoclient = this;
 338
 339         this.weaponmodel = "";
 340         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 341         {
 342                 if(!this.weaponentities[slot])
 343                         continue; // first load
 344                 this.weaponentities[slot].hook_time = 0;
 345                 this.weaponentities[slot].weaponname = "";
 346                 this.weaponentities[slot] = NULL;
 347         }
 348         this.exteriorweaponentity = NULL;
 349         this.killcount = FRAGS_SPECTATOR;
 350         this.velocity = '0 0 0';
 351         this.avelocity = '0 0 0';
 352         this.punchangle = '0 0 0';
 353         this.punchvector = '0 0 0';
 354         this.oldvelocity = this.velocity;
 355         this.fire_endtime = -1;
 356         this.event_damage = func_null;
 357 }
 358
 359 int player_getspecies(entity this)
 360 {
 361         get_model_parameters(this.model, this.skin);
 362         int s = get_model_parameters_species;
 363         get_model_parameters(string_null, 0);
 364         if (s < 0) return SPECIES_HUMAN;
 365         return s;
 366 }
 367
 368 .float model_randomizer;
 369 void FixPlayermodel(entity player)
 370 {
 371         string defaultmodel = "";
 372         int defaultskin = 0;
 373         if(autocvar_sv_defaultcharacter)
 374         {
 375                 if(teamplay)
 376                 {
 377                         string s = Static_Team_ColorName_Lower(player.team);
 378                         if (s != "neutral")
 379                         {
 380                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 381                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 382                         }
 383                 }
 384
 385                 if(defaultmodel == "")
 386                 {
 387                         defaultmodel = autocvar_sv_defaultplayermodel;
 388                         defaultskin = autocvar_sv_defaultplayerskin;
 389                 }
 390
 391                 int n = tokenize_console(defaultmodel);
 392                 if(n > 0)
 393                 {
 394                         defaultmodel = argv(floor(n * player.model_randomizer));
 395                         // However, do NOT randomize if the player-selected model is in the list.
 396                         for (int i = 0; i < n; ++i)
 397                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 398                                         defaultmodel = argv(i);
 399                 }
 400
 401                 int i = strstrofs(defaultmodel, ":", 0);
 402                 if(i >= 0)
 403                 {
 404                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 405                         defaultmodel = substring(defaultmodel, 0, i);
 406                 }
 407         }
 408         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 409         {
 410                 if(teamplay)
 411                 {
 412                         string s = Static_Team_ColorName_Lower(player.team);
 413                         if (s != "neutral")
 414                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 415                 }
 416
 417                 if(!defaultskin)
 418                         defaultskin = autocvar_sv_defaultplayerskin;
 419         }
 420
 421         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 422         defaultmodel = M_ARGV(0, string);
 423         defaultskin = M_ARGV(1, int);
 424
 425         bool chmdl = false;
 426         int oldskin;
 427         if(defaultmodel != "")
 428         {
 429                 if (defaultmodel != player.model)
 430                 {
 431                         vector m1 = player.mins;
 432                         vector m2 = player.maxs;
 433                         setplayermodel (player, defaultmodel);
 434                         setsize (player, m1, m2);
 435                         chmdl = true;
 436                 }
 437
 438                 oldskin = player.skin;
 439                 player.skin = defaultskin;
 440         } else {
 441                 if (player.playermodel != player.model || player.playermodel == "")
 442                 {
 443                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 444                         vector m1 = player.mins;
 445                         vector m2 = player.maxs;
 446                         setplayermodel (player, player.playermodel);
 447                         setsize (player, m1, m2);
 448                         chmdl = true;
 449                 }
 450
 451                 if(!autocvar_sv_defaultcharacterskin)
 452                 {
 453                         oldskin = player.skin;
 454                         player.skin = stof(player.playerskin);
 455                 }
 456                 else
 457                 {
 458                         oldskin = player.skin;
 459                         player.skin = defaultskin;
 460                 }
 461         }
 462
 463         if(chmdl || oldskin != player.skin) // model or skin has changed
 464         {
 465                 player.species = player_getspecies(player); // update species
 466                 if(!autocvar_g_debug_globalsounds)
 467                         UpdatePlayerSounds(player); // update skin sounds
 468         }
 469
 470         if(!teamplay)
 471                 if(strlen(autocvar_sv_defaultplayercolors))
 472                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 473                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 474 }
 475
 476
 477 /** Called when a client spawns in the server */
 478 void PutClientInServer(entity this)
 479 {
 480         if (IS_BOT_CLIENT(this)) {
 481                 TRANSMUTE(Player, this);
 482         } else if (IS_REAL_CLIENT(this)) {
 483                 msg_entity = this;
 484                 WriteByte(MSG_ONE, SVC_SETVIEW);
 485                 WriteEntity(MSG_ONE, this);
 486         }
 487         if (gameover) {
 488                 TRANSMUTE(Observer, this);
 489         }
 490
 491         SetSpectatee(this, NULL);
 492
 493         // reset player keys
 494         this.itemkeys = 0;
 495
 496         MUTATOR_CALLHOOK(PutClientInServer, this);
 497
 498         if (IS_OBSERVER(this)) {
 499                 PutObserverInServer(this);
 500         } else if (IS_PLAYER(this)) {
 501                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 502
 503                 PlayerState_attach(this);
 504                 accuracy_resend(this);
 505
 506                 if (this.team < 0)
 507                         JoinBestTeam(this, false, true);
 508
 509                 entity spot = SelectSpawnPoint(this, false);
 510                 if (!spot) {
 511                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 512                         return; // spawn failed
 513                 }
 514
 515                 TRANSMUTE(Player, this);
 516
 517                 this.wasplayer = true;
 518                 this.iscreature = true;
 519                 this.teleportable = TELEPORT_NORMAL;
 520                 this.damagedbycontents = true;
 521                 set_movetype(this, MOVETYPE_WALK);
 522                 this.solid = SOLID_SLIDEBOX;
 523                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 524                 if (autocvar_g_playerclip_collisions)
 525                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 526                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 527                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 528                 this.frags = FRAGS_PLAYER;
 529                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 530                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 531                 if (autocvar__notarget)
 532                         this.flags |= FL_NOTARGET;
 533                 this.takedamage = DAMAGE_AIM;
 534                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 535                 this.dmg = 2; // WTF
 536
 537                 if (warmup_stage) {
 538                         this.ammo_shells = warmup_start_ammo_shells;
 539                         this.ammo_nails = warmup_start_ammo_nails;
 540                         this.ammo_rockets = warmup_start_ammo_rockets;
 541                         this.ammo_cells = warmup_start_ammo_cells;
 542                         this.ammo_plasma = warmup_start_ammo_plasma;
 543                         this.ammo_fuel = warmup_start_ammo_fuel;
 544                         this.health = warmup_start_health;
 545                         this.armorvalue = warmup_start_armorvalue;
 546                         this.weapons = WARMUP_START_WEAPONS;
 547                 } else {
 548                         this.ammo_shells = start_ammo_shells;
 549                         this.ammo_nails = start_ammo_nails;
 550                         this.ammo_rockets = start_ammo_rockets;
 551                         this.ammo_cells = start_ammo_cells;
 552                         this.ammo_plasma = start_ammo_plasma;
 553                         this.ammo_fuel = start_ammo_fuel;
 554                         this.health = start_health;
 555                         this.armorvalue = start_armorvalue;
 556                         this.weapons = start_weapons;
 557                 }
 558                 SetSpectatee_status(this, 0);
 559
 560                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 561
 562                 this.items = start_items;
 563
 564                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 565                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 566                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 567                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 568                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 569                 // extend the pause of rotting if client was reset at the beginning of the countdown
 570                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 571                         float f = game_starttime - time;
 572                         this.spawnshieldtime += f;
 573                         this.pauserotarmor_finished += f;
 574                         this.pauserothealth_finished += f;
 575                         this.pauseregen_finished += f;
 576                 }
 577                 this.damageforcescale = 2;
 578                 this.death_time = 0;
 579                 this.respawn_flags = 0;
 580                 this.respawn_time = 0;
 581                 this.stat_respawn_time = 0;
 582                 this.scale = autocvar_sv_player_scale;
 583                 this.fade_time = 0;
 584                 this.pain_frame = 0;
 585                 this.pain_finished = 0;
 586                 this.pushltime = 0;
 587                 setthink(this, func_null); // players have no think function
 588                 this.nextthink = 0;
 589                 this.dmg_team = 0;
 590                 this.ballistics_density = autocvar_g_ballistics_density_player;
 591
 592                 this.deadflag = DEAD_NO;
 593
 594                 this.angles = spot.angles;
 595                 this.angles_z = 0; // never spawn tilted even if the spot says to
 596                 if (IS_BOT_CLIENT(this))
 597                         this.v_angle = this.angles;
 598                 this.fixangle = true; // turn this way immediately
 599                 this.oldvelocity = this.velocity = '0 0 0';
 600                 this.avelocity = '0 0 0';
 601                 this.punchangle = '0 0 0';
 602                 this.punchvector = '0 0 0';
 603
 604                 this.strength_finished = 0;
 605                 this.invincible_finished = 0;
 606                 this.fire_endtime = -1;
 607                 this.revival_time = 0;
 608                 this.air_finished = time + 12;
 609
 610                 entity spawnevent = new_pure(spawnevent);
 611                 spawnevent.owner = this;
 612                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 613
 614                 // Cut off any still running player sounds.
 615                 stopsound(this, CH_PLAYER_SINGLE);
 616
 617                 this.model = "";
 618                 FixPlayermodel(this);
 619                 this.drawonlytoclient = NULL;
 620
 621                 this.crouch = false;
 622                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 623                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 624                 this.spawnorigin = spot.origin;
 625                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 626                 // don't reset back to last position, even if new position is stuck in solid
 627                 this.oldorigin = this.origin;
 628                 this.prevorigin = this.origin;
 629                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 630                 if(this.conveyor)
 631                         IL_REMOVE(g_conveyed, this);
 632                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 633                 this.hud = HUD_NORMAL;
 634
 635                 this.event_damage = PlayerDamage;
 636
 637                 if(!this.bot_attack)
 638                         IL_PUSH(g_bot_targets, this);
 639                 this.bot_attack = true;
 640                 this.monster_attack = true;
 641
 642                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 643
 644                 if (this.killcount == FRAGS_SPECTATOR) {
 645                         PlayerScore_Clear(this);
 646                         this.killcount = 0;
 647                 }
 648
 649                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 650                 {
 651                         .entity weaponentity = weaponentities[slot];
 652                         CL_SpawnWeaponentity(this, weaponentity);
 653                 }
 654                 this.alpha = default_player_alpha;
 655                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 656                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 657
 658                 this.speedrunning = false;
 659
 660                 target_voicescript_clear(this);
 661
 662                 // reset fields the weapons may use
 663                 FOREACH(Weapons, true, LAMBDA(
 664                         it.wr_resetplayer(it, this);
 665                         // reload all reloadable weapons
 666                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 667                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 668                                 {
 669                                         .entity weaponentity = weaponentities[slot];
 670                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 671                                 }
 672                         }
 673                 ));
 674
 675                 {
 676                         string s = spot.target;
 677                         spot.target = string_null;
 678                         SUB_UseTargets(spot, this, NULL);
 679                         spot.target = s;
 680                 }
 681
 682                 Unfreeze(this);
 683
 684                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 685
 686                 if (autocvar_spawn_debug)
 687                 {
 688                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 689                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 690                 }
 691
 692                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 693                 {
 694                         .entity weaponentity = weaponentities[slot];
 695                         if(slot == 0)
 696                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 697                         else
 698                                 this.(weaponentity).m_switchweapon = WEP_Null;
 699                         this.(weaponentity).m_weapon = WEP_Null;
 700                         this.(weaponentity).weaponname = "";
 701                         this.(weaponentity).m_switchingweapon = WEP_Null;
 702                         this.(weaponentity).cnt = -1;
 703                 }
 704
 705                 if (!warmup_stage && !this.alivetime)
 706                         this.alivetime = time;
 707
 708                 antilag_clear(this, CS(this));
 709         }
 710 }
 711
 712 void ClientInit_misc(entity this);
 713
 714 .float ebouncefactor, ebouncestop; // electro's values
 715 // TODO do we need all these fields, or should we stop autodetecting runtime
 716 // changes and just have a console command to update this?
 717 bool ClientInit_SendEntity(entity this, entity to, int sf)
 718 {
 719         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 720         return = true;
 721         msg_entity = to;
 722         // MSG_INIT replacement
 723         // TODO: make easier to use
 724         Registry_send_all();
 725         W_PROP_reload(MSG_ONE, to);
 726         ClientInit_misc(this);
 727         MUTATOR_CALLHOOK(Ent_Init);
 728 }
 729 void ClientInit_misc(entity this)
 730 {
 731         int channel = MSG_ONE;
 732         WriteHeader(channel, ENT_CLIENT_INIT);
 733         WriteByte(channel, g_nexball_meter_period * 32);
 734         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 735         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 736         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 737         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 738         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 739         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 740         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 741         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 742
 743         if(sv_foginterval && world.fog != "")
 744                 WriteString(channel, world.fog);
 745         else
 746                 WriteString(channel, "");
 747         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 748         WriteByte(channel, serverflags);
 749         WriteCoord(channel, autocvar_g_trueaim_minrange);
 750 }
 751
 752 void ClientInit_CheckUpdate(entity this)
 753 {
 754         this.nextthink = time;
 755         if(this.count != autocvar_g_balance_armor_blockpercent)
 756         {
 757                 this.count = autocvar_g_balance_armor_blockpercent;
 758                 this.SendFlags |= 1;
 759         }
 760 }
 761
 762 void ClientInit_Spawn()
 763 {
 764         entity e = new_pure(clientinit);
 765         setthink(e, ClientInit_CheckUpdate);
 766         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 767
 768         ClientInit_CheckUpdate(e);
 769 }
 770
 771 /*
 772 =============
 773 SetNewParms
 774 =============
 775 */
 776 void SetNewParms ()
 777 {
 778         // initialize parms for a new player
 779         parm1 = -(86400 * 366);
 780
 781         MUTATOR_CALLHOOK(SetNewParms);
 782 }
 783
 784 /*
 785 =============
 786 SetChangeParms
 787 =============
 788 */
 789 void SetChangeParms (entity this)
 790 {
 791         // save parms for level change
 792         parm1 = this.parm_idlesince - time;
 793
 794         MUTATOR_CALLHOOK(SetChangeParms);
 795 }
 796
 797 /*
 798 =============
 799 DecodeLevelParms
 800 =============
 801 */
 802 void DecodeLevelParms(entity this)
 803 {
 804         // load parms
 805         this.parm_idlesince = parm1;
 806         if (this.parm_idlesince == -(86400 * 366))
 807                 this.parm_idlesince = time;
 808
 809         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 810         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 811
 812         MUTATOR_CALLHOOK(DecodeLevelParms);
 813 }
 814
 815 /*
 816 =============
 817 ClientKill
 818
 819 Called when a client types 'kill' in the console
 820 =============
 821 */
 822
 823 .float clientkill_nexttime;
 824 void ClientKill_Now_TeamChange(entity this)
 825 {
 826         if(this.killindicator_teamchange == -1)
 827         {
 828                 JoinBestTeam( this, false, true );
 829         }
 830         else if(this.killindicator_teamchange == -2)
 831         {
 832                 if(blockSpectators)
 833                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 834                 PutObserverInServer(this);
 835         }
 836         else
 837                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 838         this.killindicator_teamchange = 0;
 839 }
 840
 841 void ClientKill_Now(entity this)
 842 {
 843         if(this.vehicle)
 844         {
 845             vehicles_exit(this.vehicle, VHEF_RELEASE);
 846             if(!this.killindicator_teamchange)
 847             {
 848             this.vehicle_health = -1;
 849             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 850             }
 851         }
 852
 853         if(this.killindicator && !wasfreed(this.killindicator))
 854                 delete(this.killindicator);
 855
 856         this.killindicator = NULL;
 857
 858         if(this.killindicator_teamchange)
 859                 ClientKill_Now_TeamChange(this);
 860
 861         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 862                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 863
 864         // now I am sure the player IS dead
 865 }
 866 void KillIndicator_Think(entity this)
 867 {
 868         if (gameover)
 869         {
 870                 this.owner.killindicator = NULL;
 871                 delete(this);
 872                 return;
 873         }
 874
 875         if (this.owner.alpha < 0 && !this.owner.vehicle)
 876         {
 877                 this.owner.killindicator = NULL;
 878                 delete(this);
 879                 return;
 880         }
 881
 882         if(this.cnt <= 0)
 883         {
 884                 ClientKill_Now(this.owner);
 885                 return;
 886         }
 887     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 888     {
 889         this.nextthink = time + 1;
 890         this.cnt -= 1;
 891     }
 892         else
 893         {
 894                 if(this.cnt <= 10)
 895                         setmodel(this, MDL_NUM(this.cnt));
 896                 if(IS_REAL_CLIENT(this.owner))
 897                 {
 898                         if(this.cnt <= 10)
 899                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 900                 }
 901                 this.nextthink = time + 1;
 902                 this.cnt -= 1;
 903         }
 904 }
 905
 906 float clientkilltime;
 907 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 908 {
 909         float killtime;
 910         float starttime;
 911
 912         if (gameover)
 913                 return;
 914
 915         killtime = autocvar_g_balance_kill_delay;
 916
 917         if(g_race_qualifying || g_cts)
 918                 killtime = 0;
 919
 920     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 921         return;
 922
 923         this.killindicator_teamchange = targetteam;
 924
 925     if(!this.killindicator)
 926         {
 927                 if(!IS_DEAD(this))
 928                 {
 929                         killtime = max(killtime, this.clientkill_nexttime - time);
 930                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 931                 }
 932
 933                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 934                 {
 935                         ClientKill_Now(this);
 936                 }
 937                 else
 938                 {
 939                         starttime = max(time, clientkilltime);
 940
 941                         this.killindicator = spawn();
 942                         this.killindicator.owner = this;
 943                         this.killindicator.scale = 0.5;
 944                         setattachment(this.killindicator, this, "");
 945                         setorigin(this.killindicator, '0 0 52');
 946                         setthink(this.killindicator, KillIndicator_Think);
 947                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 948                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 949                         this.killindicator.cnt = ceil(killtime);
 950                         this.killindicator.count = bound(0, ceil(killtime), 10);
 951                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 952
 953                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 954                         {
 955                                 it.killindicator = spawn();
 956                                 it.killindicator.owner = it;
 957                                 it.killindicator.scale = 0.5;
 958                                 setattachment(it.killindicator, it, "");
 959                                 setorigin(it.killindicator, '0 0 52');
 960                                 setthink(it.killindicator, KillIndicator_Think);
 961                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 962                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 963                                 it.killindicator.cnt = ceil(killtime);
 964                         });
 965                         this.lip = 0;
 966                 }
 967         }
 968         if(this.killindicator)
 969         {
 970                 if(targetteam == 0) // just die
 971                 {
 972                         this.killindicator.colormod = '0 0 0';
 973                         if(IS_REAL_CLIENT(this))
 974                         if(this.killindicator.cnt > 0)
 975                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 976                 }
 977                 else if(targetteam == -1) // auto
 978                 {
 979                         this.killindicator.colormod = '0 1 0';
 980                         if(IS_REAL_CLIENT(this))
 981                         if(this.killindicator.cnt > 0)
 982                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 983                 }
 984                 else if(targetteam == -2) // spectate
 985                 {
 986                         this.killindicator.colormod = '0.5 0.5 0.5';
 987                         if(IS_REAL_CLIENT(this))
 988                         if(this.killindicator.cnt > 0)
 989                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 990                 }
 991                 else
 992                 {
 993                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 994                         if(IS_REAL_CLIENT(this))
 995                         if(this.killindicator.cnt > 0)
 996                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 997                 }
 998         }
 999
1000 }
1001
1002 void ClientKill (entity this)
1003 {
1004         if(gameover) return;
1005         if(this.player_blocked) return;
1006         if(STAT(FROZEN, this)) return;
1007
1008         ClientKill_TeamChange(this, 0);
1009 }
1010
1011 void FixClientCvars(entity e)
1012 {
1013         // send prediction settings to the client
1014         stuffcmd(e, "\nin_bindmap 0 0\n");
1015         if(autocvar_g_antilag == 3) // client side hitscan
1016                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1017         if(autocvar_sv_gentle)
1018                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1019
1020         MUTATOR_CALLHOOK(FixClientCvars, e);
1021 }
1022
1023 float PlayerInIDList(entity p, string idlist)
1024 {
1025         float n, i;
1026         string s;
1027
1028         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1029         if (!p.crypto_idfp)
1030                 return 0;
1031
1032         // this function allows abbreviated player IDs too!
1033         n = tokenize_console(idlist);
1034         for(i = 0; i < n; ++i)
1035         {
1036                 s = argv(i);
1037                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1038                         return 1;
1039         }
1040
1041         return 0;
1042 }
1043
1044 #ifdef DP_EXT_PRECONNECT
1045 /*
1046 =============
1047 ClientPreConnect
1048
1049 Called once (not at each match start) when a client begins a connection to the server
1050 =============
1051 */
1052 void ClientPreConnect ()
1053 {ENGINE_EVENT();
1054         if(autocvar_sv_eventlog)
1055         {
1056                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1057                         this.playerid,
1058                         etof(this),
1059                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1060                 ));
1061         }
1062 }
1063 #endif
1064
1065 /**
1066 =============
1067 ClientConnect
1068
1069 Called when a client connects to the server
1070 =============
1071 */
1072 void ClientConnect(entity this)
1073 {
1074         if (Ban_MaybeEnforceBanOnce(this)) return;
1075         assert(!IS_CLIENT(this), return);
1076         this.flags |= FL_CLIENT;
1077         assert(player_count >= 0, player_count = 0);
1078
1079 #ifdef WATERMARK
1080         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1081 #endif
1082         this.version_nagtime = time + 10 + random() * 10;
1083         TRANSMUTE(Client, this);
1084
1085         // identify the right forced team
1086         if (autocvar_g_campaign)
1087         {
1088                 if (IS_REAL_CLIENT(this)) // only players, not bots
1089                 {
1090                         switch (autocvar_g_campaign_forceteam)
1091                         {
1092                                 case 1: this.team_forced = NUM_TEAM_1; break;
1093                                 case 2: this.team_forced = NUM_TEAM_2; break;
1094                                 case 3: this.team_forced = NUM_TEAM_3; break;
1095                                 case 4: this.team_forced = NUM_TEAM_4; break;
1096                                 default: this.team_forced = 0;
1097                         }
1098                 }
1099         }
1100         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1101         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1102         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1103         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1104         else switch (autocvar_g_forced_team_otherwise)
1105         {
1106                 default: this.team_forced = 0; break;
1107                 case "red": this.team_forced = NUM_TEAM_1; break;
1108                 case "blue": this.team_forced = NUM_TEAM_2; break;
1109                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1110                 case "pink": this.team_forced = NUM_TEAM_4; break;
1111                 case "spectate":
1112                 case "spectator":
1113                         this.team_forced = -1;
1114                         break;
1115         }
1116         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1117
1118     {
1119         int id = this.playerid;
1120         this.playerid = 0; // silent
1121             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1122             this.playerid = id;
1123     }
1124
1125         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1126                 TRANSMUTE(Observer, this);
1127         } else {
1128                 if (!teamplay || autocvar_g_balance_teams) {
1129                         TRANSMUTE(Player, this);
1130                         campaign_bots_may_start = true;
1131                 } else {
1132                         TRANSMUTE(Observer, this); // do it anyway
1133                 }
1134         }
1135
1136         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1137
1138         // always track bots, don't ask for cl_allow_uidtracking
1139     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1140
1141         if (autocvar_sv_eventlog)
1142                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1143
1144         LogTeamchange(this.playerid, this.team, 1);
1145
1146         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1147
1148         this.netname_previous = strzone(this.netname);
1149
1150         if(teamplay && IS_PLAYER(this))
1151                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1152         else
1153                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1154
1155         stuffcmd(this, clientstuff, "\n");
1156         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1157
1158         FixClientCvars(this);
1159
1160         // get version info from player
1161         stuffcmd(this, "cmd clientversion $gameversion\n");
1162
1163         // notify about available teams
1164         if (teamplay)
1165         {
1166                 CheckAllowedTeams(this);
1167                 int t = 0;
1168                 if (c1 >= 0) t |= BIT(0);
1169                 if (c2 >= 0) t |= BIT(1);
1170                 if (c3 >= 0) t |= BIT(2);
1171                 if (c4 >= 0) t |= BIT(3);
1172                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1173         }
1174         else
1175         {
1176                 stuffcmd(this, "set _teams_available 0\n");
1177         }
1178
1179         bot_relinkplayerlist();
1180
1181         this.spectatortime = time;
1182         if (blockSpectators)
1183         {
1184                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1185         }
1186
1187         this.jointime = time;
1188         this.allowed_timeouts = autocvar_sv_timeout_number;
1189
1190         if (IS_REAL_CLIENT(this))
1191         {
1192                 if (!autocvar_g_campaign)
1193                 {
1194                         this.motd_actived_time = -1;
1195                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1196                 }
1197
1198                 if (g_weaponarena_weapons == WEPSET(TUBA))
1199                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1200         }
1201
1202         if (!sv_foginterval && world.fog != "")
1203                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1204
1205         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1206                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1207                         send_CSQC_teamnagger();
1208
1209         CSQCMODEL_AUTOINIT(this);
1210
1211         this.model_randomizer = random();
1212
1213         if (IS_REAL_CLIENT(this))
1214                 sv_notice_join(this);
1215
1216         IL_EACH(g_initforplayer, it.init_for_player, {
1217                 it.init_for_player(it, this);
1218         });
1219
1220         MUTATOR_CALLHOOK(ClientConnect, this);
1221 }
1222 /*
1223 =============
1224 ClientDisconnect
1225
1226 Called when a client disconnects from the server
1227 =============
1228 */
1229 .entity chatbubbleentity;
1230 void ReadyCount();
1231 void ClientDisconnect(entity this)
1232 {
1233         assert(IS_CLIENT(this), return);
1234
1235         PlayerStats_GameReport_FinalizePlayer(this);
1236         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1237         if (this.active_minigame) part_minigame(this);
1238         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1239
1240         if (autocvar_sv_eventlog)
1241                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1242
1243         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1244
1245         SetSpectatee(this, NULL);
1246
1247     MUTATOR_CALLHOOK(ClientDisconnect, this);
1248
1249         ClientState_detach(this);
1250
1251         Portal_ClearAll(this);
1252
1253         Unfreeze(this);
1254
1255         RemoveGrapplingHooks(this);
1256
1257         // Here, everything has been done that requires this player to be a client.
1258
1259         this.flags &= ~FL_CLIENT;
1260
1261         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1262         if (this.killindicator) delete(this.killindicator);
1263
1264         WaypointSprite_PlayerGone(this);
1265
1266         bot_relinkplayerlist();
1267
1268         if (this.netname_previous) strunzone(this.netname_previous);
1269         if (this.clientstatus) strunzone(this.clientstatus);
1270         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1271         if (this.personal) delete(this.personal);
1272
1273         this.playerid = 0;
1274         ReadyCount();
1275         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1276 }
1277
1278 void ChatBubbleThink(entity this)
1279 {
1280         this.nextthink = time;
1281         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1282         {
1283                 if(this.owner) // but why can that ever be NULL?
1284                         this.owner.chatbubbleentity = NULL;
1285                 delete(this);
1286                 return;
1287         }
1288
1289         this.mdl = "";
1290
1291         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1292         {
1293                 if ( this.owner.active_minigame )
1294                         this.mdl = "models/sprites/minigame_busy.iqm";
1295                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1296                         this.mdl = "models/misc/chatbubble.spr";
1297         }
1298
1299         if ( this.model != this.mdl )
1300                 _setmodel(this, this.mdl);
1301
1302 }
1303
1304 void UpdateChatBubble(entity this)
1305 {
1306         if (this.alpha < 0)
1307                 return;
1308         // spawn a chatbubble entity if needed
1309         if (!this.chatbubbleentity)
1310         {
1311                 this.chatbubbleentity = new(chatbubbleentity);
1312                 this.chatbubbleentity.owner = this;
1313                 this.chatbubbleentity.exteriormodeltoclient = this;
1314                 setthink(this.chatbubbleentity, ChatBubbleThink);
1315                 this.chatbubbleentity.nextthink = time;
1316                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1317                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1318                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1319                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1320                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1321                 //this.chatbubbleentity.model = "";
1322                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1323         }
1324 }
1325
1326
1327 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1328 // added to the model skins
1329 /*void UpdateColorModHack()
1330 {
1331         float c;
1332         c = this.clientcolors & 15;
1333         // LordHavoc: only bothering to support white, green, red, yellow, blue
1334              if (!teamplay) this.colormod = '0 0 0';
1335         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1336         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1337         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1338         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1339         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1340         else this.colormod = '1 1 1';
1341 }*/
1342
1343 void respawn(entity this)
1344 {
1345         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1346         {
1347                 this.solid = SOLID_NOT;
1348                 this.takedamage = DAMAGE_NO;
1349                 set_movetype(this, MOVETYPE_FLY);
1350                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1351                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1352                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1353                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1354                 if(autocvar_g_respawn_ghosts_maxtime)
1355                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1356         }
1357
1358         CopyBody(this, 1);
1359
1360         this.effects |= EF_NODRAW; // prevent another CopyBody
1361         PutClientInServer(this);
1362 }
1363
1364 void play_countdown(entity this, float finished, Sound samp)
1365 {
1366     TC(Sound, samp);
1367         if(IS_REAL_CLIENT(this))
1368                 if(floor(finished - time - frametime) != floor(finished - time))
1369                         if(finished - time < 6)
1370                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1371 }
1372
1373 void player_powerups(entity this)
1374 {
1375         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1376         int items_prev = this.items;
1377
1378         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1379                 this.modelflags |= MF_ROCKET;
1380         else
1381                 this.modelflags &= ~MF_ROCKET;
1382
1383         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1384
1385         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1386                 return;
1387
1388         Fire_ApplyDamage(this);
1389         Fire_ApplyEffect(this);
1390
1391         if (!g_instagib)
1392         {
1393                 if (this.items & ITEM_Strength.m_itemid)
1394                 {
1395                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1396                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1397                         if (time > this.strength_finished)
1398                         {
1399                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1400                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1401                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1402                         }
1403                 }
1404                 else
1405                 {
1406                         if (time < this.strength_finished)
1407                         {
1408                                 this.items = this.items | ITEM_Strength.m_itemid;
1409                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1410                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1411                         }
1412                 }
1413                 if (this.items & ITEM_Shield.m_itemid)
1414                 {
1415                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1416                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1417                         if (time > this.invincible_finished)
1418                         {
1419                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1420                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1421                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1422                         }
1423                 }
1424                 else
1425                 {
1426                         if (time < this.invincible_finished)
1427                         {
1428                                 this.items = this.items | ITEM_Shield.m_itemid;
1429                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1430                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1431                         }
1432                 }
1433                 if (this.items & IT_SUPERWEAPON)
1434                 {
1435                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1436                         {
1437                                 this.superweapons_finished = 0;
1438                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1439                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1440                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1441                         }
1442                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1443                         {
1444                                 // don't let them run out
1445                         }
1446                         else
1447                         {
1448                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1449                                 if (time > this.superweapons_finished)
1450                                 {
1451                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1452                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1453                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1454                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1455                                 }
1456                         }
1457                 }
1458                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1459                 {
1460                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1461                         {
1462                                 this.items = this.items | IT_SUPERWEAPON;
1463                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1465                         }
1466                         else
1467                         {
1468                                 this.superweapons_finished = 0;
1469                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1470                         }
1471                 }
1472                 else
1473                 {
1474                         this.superweapons_finished = 0;
1475                 }
1476         }
1477
1478         if(autocvar_g_nodepthtestplayers)
1479                 this.effects = this.effects | EF_NODEPTHTEST;
1480
1481         if(autocvar_g_fullbrightplayers)
1482                 this.effects = this.effects | EF_FULLBRIGHT;
1483
1484         if (time >= game_starttime)
1485         if (time < this.spawnshieldtime)
1486                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1487
1488         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1489 }
1490
1491 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1492 {
1493         if(current > stable)
1494                 return current;
1495         else if(current > stable - 0.25) // when close enough, "snap"
1496                 return stable;
1497         else
1498                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1499 }
1500
1501 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1502 {
1503         if(current < stable)
1504                 return current;
1505         else if(current < stable + 0.25) // when close enough, "snap"
1506                 return stable;
1507         else
1508                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1509 }
1510
1511 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1512 {
1513         if(current > rotstable)
1514         {
1515                 if(rotframetime > 0)
1516                 {
1517                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1518                         current = max(rotstable, current - rotlinear * rotframetime);
1519                 }
1520         }
1521         else if(current < regenstable)
1522         {
1523                 if(regenframetime > 0)
1524                 {
1525                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1526                         current = min(regenstable, current + regenlinear * regenframetime);
1527                 }
1528         }
1529
1530         if(current > limit)
1531                 current = limit;
1532
1533         return current;
1534 }
1535
1536 void player_regen(entity this)
1537 {
1538         float max_mod, regen_mod, rot_mod, limit_mod;
1539         max_mod = regen_mod = rot_mod = limit_mod = 1;
1540
1541         float regen_health = autocvar_g_balance_health_regen;
1542         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1543         float regen_health_rot = autocvar_g_balance_health_rot;
1544         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1545         float regen_health_stable = autocvar_g_balance_health_regenstable;
1546         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1547         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1548                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1549         max_mod = M_ARGV(1, float);
1550         regen_mod = M_ARGV(2, float);
1551         rot_mod = M_ARGV(3, float);
1552         limit_mod = M_ARGV(4, float);
1553         regen_health = M_ARGV(5, float);
1554         regen_health_linear = M_ARGV(6, float);
1555         regen_health_rot = M_ARGV(7, float);
1556         regen_health_rotlinear = M_ARGV(8, float);
1557         regen_health_stable = M_ARGV(9, float);
1558         regen_health_rotstable = M_ARGV(10, float);
1559
1560
1561         if(!mutator_returnvalue)
1562         if(!STAT(FROZEN, this))
1563         {
1564                 float mina, maxa, limith, limita;
1565                 maxa = autocvar_g_balance_armor_rotstable;
1566                 mina = autocvar_g_balance_armor_regenstable;
1567                 limith = autocvar_g_balance_health_limit;
1568                 limita = autocvar_g_balance_armor_limit;
1569
1570                 regen_health_rotstable = regen_health_rotstable * max_mod;
1571                 regen_health_stable = regen_health_stable * max_mod;
1572                 limith = limith * limit_mod;
1573                 limita = limita * limit_mod;
1574
1575                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1576                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1577         }
1578
1579         // if player rotted to death...  die!
1580         // check this outside above checks, as player may still be able to rot to death
1581         if(this.health < 1)
1582         {
1583                 if(this.vehicle)
1584                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1585                 if(this.event_damage)
1586                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1587         }
1588
1589         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1590         {
1591                 float minf, maxf, limitf;
1592
1593                 maxf = autocvar_g_balance_fuel_rotstable;
1594                 minf = autocvar_g_balance_fuel_regenstable;
1595                 limitf = autocvar_g_balance_fuel_limit;
1596
1597                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1598         }
1599 }
1600
1601 bool zoomstate_set;
1602 void SetZoomState(entity this, float z)
1603 {
1604         if(z != this.zoomstate)
1605         {
1606                 this.zoomstate = z;
1607                 ClientData_Touch(this);
1608         }
1609         zoomstate_set = true;
1610 }
1611
1612 void GetPressedKeys(entity this)
1613 {
1614         MUTATOR_CALLHOOK(GetPressedKeys, this);
1615         int keys = this.pressedkeys;
1616         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1617         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1618         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1619         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1620
1621         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1622         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1623         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1624         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1625         this.pressedkeys = keys;
1626 }
1627
1628 /*
1629 ======================
1630 spectate mode routines
1631 ======================
1632 */
1633
1634 void SpectateCopy(entity this, entity spectatee)
1635 {
1636     TC(Client, this); TC(Client, spectatee);
1637
1638         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1639         PS(this) = PS(spectatee);
1640         this.armortype = spectatee.armortype;
1641         this.armorvalue = spectatee.armorvalue;
1642         this.ammo_cells = spectatee.ammo_cells;
1643         this.ammo_plasma = spectatee.ammo_plasma;
1644         this.ammo_shells = spectatee.ammo_shells;
1645         this.ammo_nails = spectatee.ammo_nails;
1646         this.ammo_rockets = spectatee.ammo_rockets;
1647         this.ammo_fuel = spectatee.ammo_fuel;
1648         this.clip_load = spectatee.clip_load;
1649         this.clip_size = spectatee.clip_size;
1650         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1651         this.health = spectatee.health;
1652         this.impulse = 0;
1653         this.items = spectatee.items;
1654         this.last_pickup = spectatee.last_pickup;
1655         this.hit_time = spectatee.hit_time;
1656         this.strength_finished = spectatee.strength_finished;
1657         this.invincible_finished = spectatee.invincible_finished;
1658         this.pressedkeys = spectatee.pressedkeys;
1659         this.weapons = spectatee.weapons;
1660         this.vortex_charge = spectatee.vortex_charge;
1661         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1662         this.hagar_load = spectatee.hagar_load;
1663         this.arc_heat_percent = spectatee.arc_heat_percent;
1664         this.minelayer_mines = spectatee.minelayer_mines;
1665         this.punchangle = spectatee.punchangle;
1666         this.view_ofs = spectatee.view_ofs;
1667         this.velocity = spectatee.velocity;
1668         this.dmg_take = spectatee.dmg_take;
1669         this.dmg_save = spectatee.dmg_save;
1670         this.dmg_inflictor = spectatee.dmg_inflictor;
1671         this.v_angle = spectatee.v_angle;
1672         this.angles = spectatee.v_angle;
1673         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1674         this.revive_progress = spectatee.revive_progress;
1675         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1676                 this.fixangle = true;
1677         setorigin(this, spectatee.origin);
1678         setsize(this, spectatee.mins, spectatee.maxs);
1679         SetZoomState(this, spectatee.zoomstate);
1680
1681     anticheat_spectatecopy(this, spectatee);
1682         this.hud = spectatee.hud;
1683         if(spectatee.vehicle)
1684     {
1685         this.angles = spectatee.v_angle;
1686
1687         //this.fixangle = false;
1688         //this.velocity = spectatee.vehicle.velocity;
1689         this.vehicle_health = spectatee.vehicle_health;
1690         this.vehicle_shield = spectatee.vehicle_shield;
1691         this.vehicle_energy = spectatee.vehicle_energy;
1692         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1693         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1694         this.vehicle_reload1 = spectatee.vehicle_reload1;
1695         this.vehicle_reload2 = spectatee.vehicle_reload2;
1696
1697         //msg_entity = this;
1698
1699        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1700             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1701            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1702            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1703
1704         //WriteByte (MSG_ONE, SVC_SETVIEW);
1705         //    WriteEntity(MSG_ONE, this);
1706         //makevectors(spectatee.v_angle);
1707         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1708     }
1709 }
1710
1711 bool SpectateUpdate(entity this)
1712 {
1713         if(!this.enemy)
1714                 return false;
1715
1716         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1717         {
1718                 SetSpectatee(this, NULL);
1719                 return false;
1720         }
1721
1722         SpectateCopy(this, this.enemy);
1723
1724         return true;
1725 }
1726
1727 bool SpectateSet(entity this)
1728 {
1729         if(!IS_PLAYER(this.enemy))
1730                 return false;
1731
1732         ClientData_Touch(this.enemy);
1733
1734         msg_entity = this;
1735         WriteByte(MSG_ONE, SVC_SETVIEW);
1736         WriteEntity(MSG_ONE, this.enemy);
1737         set_movetype(this, MOVETYPE_NONE);
1738         accuracy_resend(this);
1739
1740         if(!SpectateUpdate(this))
1741                 PutObserverInServer(this);
1742
1743         return true;
1744 }
1745
1746 void SetSpectatee_status(entity this, int spectatee_num)
1747 {
1748         int oldspectatee_status = this.spectatee_status;
1749         this.spectatee_status = spectatee_num;
1750
1751         if (this.spectatee_status != oldspectatee_status)
1752         {
1753                 ClientData_Touch(this);
1754                 if (g_race || g_cts) race_InitSpectator();
1755         }
1756 }
1757
1758 void SetSpectatee(entity this, entity spectatee)
1759 {
1760         entity old_spectatee = this.enemy;
1761
1762         this.enemy = spectatee;
1763
1764         // WEAPONTODO
1765         // these are required to fix the spectator bug with arc
1766         if(old_spectatee)
1767         {
1768                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1769                 {
1770                         .entity weaponentity = weaponentities[slot];
1771                         if(old_spectatee.(weaponentity).arc_beam)
1772                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1773                 }
1774         }
1775         if(this.enemy)
1776         {
1777                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1778                 {
1779                         .entity weaponentity = weaponentities[slot];
1780                         if(this.enemy.(weaponentity).arc_beam)
1781                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1782                 }
1783         }
1784
1785         if (this.enemy)
1786                 SetSpectatee_status(this, etof(this.enemy));
1787
1788         // needed to update spectator list
1789         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1790 }
1791
1792 bool Spectate(entity this, entity pl)
1793 {
1794         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1795                 return false;
1796         pl = M_ARGV(1, entity);
1797
1798         SetSpectatee(this, pl);
1799         return SpectateSet(this);
1800 }
1801
1802 bool SpectateNext(entity this)
1803 {
1804         entity ent = find(this.enemy, classname, STR_PLAYER);
1805
1806         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1807                 ent = M_ARGV(1, entity);
1808         else if (!ent)
1809                 ent = find(ent, classname, STR_PLAYER);
1810
1811         if(ent) { SetSpectatee(this, ent); }
1812
1813         return SpectateSet(this);
1814 }
1815
1816 bool SpectatePrev(entity this)
1817 {
1818         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1819         entity ent = findchain(classname, STR_PLAYER);
1820         if (!ent) // no player
1821                 return false;
1822
1823         entity first = ent;
1824         // skip players until current spectated player
1825         if(this.enemy)
1826         while(ent && ent != this.enemy)
1827                 ent = ent.chain;
1828
1829         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1830         {
1831                 case MUT_SPECPREV_FOUND:
1832                     ent = M_ARGV(1, entity);
1833                     break;
1834                 case MUT_SPECPREV_RETURN:
1835                     return true;
1836                 case MUT_SPECPREV_CONTINUE:
1837                 default:
1838                 {
1839                         if(ent.chain)
1840                                 ent = ent.chain;
1841                         else
1842                                 ent = first;
1843                         break;
1844                 }
1845         }
1846
1847         SetSpectatee(this, ent);
1848         return SpectateSet(this);
1849 }
1850
1851 /*
1852 =============
1853 ShowRespawnCountdown()
1854
1855 Update a respawn countdown display.
1856 =============
1857 */
1858 void ShowRespawnCountdown(entity this)
1859 {
1860         float number;
1861         if(!IS_DEAD(this)) // just respawned?
1862                 return;
1863         else
1864         {
1865                 number = ceil(this.respawn_time - time);
1866                 if(number <= 0)
1867                         return;
1868                 if(number <= this.respawn_countdown)
1869                 {
1870                         this.respawn_countdown = number - 1;
1871                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1872                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1873                 }
1874         }
1875 }
1876
1877 .bool team_selected;
1878 bool ShowTeamSelection(entity this)
1879 {
1880         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1881                 return false;
1882         stuffcmd(this, "menu_showteamselect\n");
1883         return true;
1884 }
1885 void Join(entity this)
1886 {
1887         TRANSMUTE(Player, this);
1888
1889         if(!this.team_selected)
1890         if(autocvar_g_campaign || autocvar_g_balance_teams)
1891                 JoinBestTeam(this, false, true);
1892
1893         if(autocvar_g_campaign)
1894                 campaign_bots_may_start = true;
1895
1896         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1897
1898         PutClientInServer(this);
1899
1900         if(teamplay && this.team != -1)
1901                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1902         else
1903                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1904         this.team_selected = false;
1905 }
1906
1907 /**
1908  * Determines whether the player is allowed to join. This depends on cvar
1909  * g_maxplayers, if it isn't used this function always return true, otherwise
1910  * it checks whether the number of currently playing players exceeds g_maxplayers.
1911  * @return int number of free slots for players, 0 if none
1912  */
1913 int nJoinAllowed(entity this, entity ignore)
1914 {
1915         if(!ignore)
1916         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1917         // so report 0 free slots if restricted
1918         {
1919                 if(autocvar_g_forced_team_otherwise == "spectate")
1920                         return 0;
1921                 if(autocvar_g_forced_team_otherwise == "spectator")
1922                         return 0;
1923         }
1924
1925         if(this && this.team_forced < 0)
1926                 return 0; // forced spectators can never join
1927
1928         // TODO simplify this
1929         int totalClients = 0;
1930         int currentlyPlaying = 0;
1931         FOREACH_CLIENT(true, LAMBDA(
1932                 if(it != ignore)
1933                         ++totalClients;
1934                 if(IS_REAL_CLIENT(it))
1935                 if(IS_PLAYER(it) || it.caplayer)
1936                         ++currentlyPlaying;
1937         ));
1938
1939         float free_slots = 0;
1940         if (!autocvar_g_maxplayers)
1941                 free_slots = maxclients - totalClients;
1942         else if(currentlyPlaying < autocvar_g_maxplayers)
1943                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1944
1945         static float join_prevent_msg_time = 0;
1946         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1947         {
1948                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1949                 join_prevent_msg_time = time + 3;
1950         }
1951
1952         return free_slots;
1953 }
1954
1955 /**
1956  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1957  * g_maxplayers_spectator_blocktime seconds
1958  */
1959 void checkSpectatorBlock(entity this)
1960 {
1961         if(IS_SPEC(this) || IS_OBSERVER(this))
1962         if(!this.caplayer)
1963         if(IS_REAL_CLIENT(this))
1964         {
1965                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1966                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1967                         dropclient(this);
1968                 }
1969         }
1970 }
1971
1972 void PrintWelcomeMessage(entity this)
1973 {
1974         if(this.motd_actived_time == 0)
1975         {
1976                 if (autocvar_g_campaign) {
1977                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1978                                 this.motd_actived_time = time;
1979                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1980                         }
1981                 } else {
1982                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1983                                 this.motd_actived_time = time;
1984                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1985                         }
1986                 }
1987         }
1988         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1989         {
1990                 if (autocvar_g_campaign) {
1991                         if (PHYS_INPUT_BUTTON_INFO(this))
1992                                 this.motd_actived_time = time;
1993                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1994                                 this.motd_actived_time = 0;
1995                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1996                         }
1997                 } else {
1998                         if (PHYS_INPUT_BUTTON_INFO(this))
1999                                 this.motd_actived_time = time;
2000                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2001                                 this.motd_actived_time = 0;
2002                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2003                         }
2004                 }
2005         }
2006         else //if(this.motd_actived_time < 0) // just connected, motd is active
2007         {
2008                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2009                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2010                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2011                 {
2012                         // instanctly hide MOTD
2013                         this.motd_actived_time = 0;
2014                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2015                 }
2016         }
2017 }
2018
2019 bool joinAllowed(entity this)
2020 {
2021         if (this.version_mismatch) return false;
2022         if (!nJoinAllowed(this, this)) return false;
2023         if (teamplay && lockteams) return false;
2024         if (ShowTeamSelection(this)) return false;
2025         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2026         return true;
2027 }
2028
2029 void ObserverThink(entity this)
2030 {
2031         if ( this.impulse )
2032         {
2033                 MinigameImpulse(this, this.impulse);
2034                 this.impulse = 0;
2035         }
2036
2037         if (this.flags & FL_JUMPRELEASED) {
2038                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2039                         this.flags &= ~FL_JUMPRELEASED;
2040                         this.flags |= FL_SPAWNING;
2041                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2042                         this.flags &= ~FL_JUMPRELEASED;
2043                         if(SpectateNext(this)) {
2044                                 TRANSMUTE(Spectator, this);
2045                         }
2046                 } else {
2047                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2048                         set_movetype(this, preferred_movetype);
2049                 }
2050         } else {
2051                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2052                         this.flags |= FL_JUMPRELEASED;
2053                         if(this.flags & FL_SPAWNING)
2054                         {
2055                                 this.flags &= ~FL_SPAWNING;
2056                                 Join(this);
2057                                 return;
2058                         }
2059                 }
2060         }
2061 }
2062
2063 void SpectatorThink(entity this)
2064 {
2065         if ( this.impulse )
2066         {
2067                 if(MinigameImpulse(this, this.impulse))
2068                         this.impulse = 0;
2069
2070                 if (this.impulse == IMP_weapon_drop.impulse)
2071                 {
2072                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2073                         this.impulse = 0;
2074                         return;
2075                 }
2076         }
2077
2078         if (this.flags & FL_JUMPRELEASED) {
2079                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2080                         this.flags &= ~FL_JUMPRELEASED;
2081                         this.flags |= FL_SPAWNING;
2082                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2083                         this.flags &= ~FL_JUMPRELEASED;
2084                         if(SpectateNext(this)) {
2085                                 TRANSMUTE(Spectator, this);
2086                         } else {
2087                                 TRANSMUTE(Observer, this);
2088                                 PutClientInServer(this);
2089                         }
2090                         this.impulse = 0;
2091                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2092                         this.flags &= ~FL_JUMPRELEASED;
2093                         if(SpectatePrev(this)) {
2094                                 TRANSMUTE(Spectator, this);
2095                         } else {
2096                                 TRANSMUTE(Observer, this);
2097                                 PutClientInServer(this);
2098                         }
2099                         this.impulse = 0;
2100                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2101                         this.flags &= ~FL_JUMPRELEASED;
2102                         TRANSMUTE(Observer, this);
2103                         PutClientInServer(this);
2104                 } else {
2105                         if(!SpectateUpdate(this))
2106                                 PutObserverInServer(this);
2107                 }
2108         } else {
2109                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2110                         this.flags |= FL_JUMPRELEASED;
2111                         if(this.flags & FL_SPAWNING)
2112                         {
2113                                 this.flags &= ~FL_SPAWNING;
2114                                 Join(this);
2115                                 return;
2116                         }
2117                 }
2118                 if(!SpectateUpdate(this))
2119                         PutObserverInServer(this);
2120         }
2121
2122         this.flags |= FL_CLIENT | FL_NOTARGET;
2123 }
2124
2125 void vehicles_enter (entity pl, entity veh);
2126 void PlayerUseKey(entity this)
2127 {
2128         if (!IS_PLAYER(this))
2129                 return;
2130
2131         if(this.vehicle)
2132         {
2133                 if(!gameover)
2134                 {
2135                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2136                         return;
2137                 }
2138         }
2139         else if(autocvar_g_vehicles_enter)
2140         {
2141                 if(!STAT(FROZEN, this))
2142                 if(!IS_DEAD(this))
2143                 if(!gameover)
2144                 {
2145                         entity head, closest_target = NULL;
2146                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2147
2148                         while(head) // find the closest acceptable target to enter
2149                         {
2150                                 if(IS_VEHICLE(head))
2151                                 if(!IS_DEAD(head))
2152                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2153                                 if(head.takedamage != DAMAGE_NO)
2154                                 {
2155                                         if(closest_target)
2156                                         {
2157                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2158                                                 { closest_target = head; }
2159                                         }
2160                                         else { closest_target = head; }
2161                                 }
2162
2163                                 head = head.chain;
2164                         }
2165
2166                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2167                 }
2168         }
2169
2170         // a use key was pressed; call handlers
2171         MUTATOR_CALLHOOK(PlayerUseKey, this);
2172 }
2173
2174
2175 /*
2176 =============
2177 PlayerPreThink
2178
2179 Called every frame for each client before the physics are run
2180 =============
2181 */
2182 .float usekeypressed;
2183 .float last_vehiclecheck;
2184 .int items_added;
2185 void PlayerPreThink (entity this)
2186 {
2187         WarpZone_PlayerPhysics_FixVAngle(this);
2188
2189     STAT(GAMESTARTTIME, this) = game_starttime;
2190         STAT(ROUNDSTARTTIME, this) = round_starttime;
2191         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2192         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2193
2194         STAT(WEAPONSINMAP, this) = weaponsInMap;
2195
2196         if (frametime) {
2197                 // physics frames: update anticheat stuff
2198                 anticheat_prethink(this);
2199         }
2200
2201         if (blockSpectators && frametime) {
2202                 // WORKAROUND: only use dropclient in server frames (frametime set).
2203                 // Never use it in cl_movement frames (frametime zero).
2204                 checkSpectatorBlock(this);
2205     }
2206
2207         zoomstate_set = false;
2208
2209         // Check for nameless players
2210         if (isInvisibleString(this.netname)) {
2211                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2212                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2213         }
2214         if (this.netname != this.netname_previous) {
2215                 if (autocvar_sv_eventlog) {
2216                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2217         }
2218                 if (this.netname_previous) strunzone(this.netname_previous);
2219                 this.netname_previous = strzone(this.netname);
2220         }
2221
2222         // version nagging
2223         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2224         this.version_nagtime = 0;
2225         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2226             // git client
2227         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2228             // git server
2229             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2230         } else {
2231             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2232             if (r < 0) { // old client
2233                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2234             } else if (r > 0) { // old server
2235                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2236             }
2237         }
2238     }
2239
2240         // GOD MODE info
2241         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2242         {
2243                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2244                 this.max_armorvalue = 0;
2245         }
2246
2247         if (STAT(FROZEN, this) == 2)
2248         {
2249                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2250                 this.health = max(1, this.revive_progress * start_health);
2251                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2252
2253                 if (this.revive_progress >= 1)
2254                         Unfreeze(this);
2255         }
2256         else if (STAT(FROZEN, this) == 3)
2257         {
2258                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2259                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2260
2261                 if (this.health < 1)
2262                 {
2263                         if (this.vehicle)
2264                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2265                         if(this.event_damage)
2266                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2267                 }
2268                 else if (this.revive_progress <= 0)
2269                         Unfreeze(this);
2270         }
2271
2272         MUTATOR_CALLHOOK(PlayerPreThink, this);
2273
2274         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2275         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2276         {
2277                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2278                 {
2279                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2280                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2281                         {
2282                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2283                         }
2284                         else if(!it.owner)
2285                         {
2286                                 if(!it.team || SAME_TEAM(this, it))
2287                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2288                                 else if(autocvar_g_vehicles_steal)
2289                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2290                         }
2291                 });
2292
2293                 this.last_vehiclecheck = time + 1;
2294         }
2295
2296         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2297         {
2298                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2299                         PlayerUseKey(this);
2300                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2301         }
2302
2303         if (IS_REAL_CLIENT(this))
2304                 PrintWelcomeMessage(this);
2305
2306         if (IS_PLAYER(this)) {
2307                 CheckRules_Player(this);
2308
2309                 if (intermission_running) {
2310                         IntermissionThink(this);
2311                         return;
2312                 }
2313
2314                 if (timeout_status == TIMEOUT_ACTIVE) {
2315             // don't allow the player to turn around while game is paused
2316                         // FIXME turn this into CSQC stuff
2317                         this.v_angle = this.lastV_angle;
2318                         this.angles = this.lastV_angle;
2319                         this.fixangle = true;
2320                 }
2321
2322                 if (frametime) player_powerups(this);
2323
2324                 if (IS_DEAD(this)) {
2325                         if (this.personal && g_race_qualifying) {
2326                                 if (time > this.respawn_time) {
2327                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2328                                         respawn(this);
2329                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2330                                 }
2331                         } else {
2332                                 if (frametime) player_anim(this);
2333                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2334
2335                                 switch(this.deadflag)
2336                                 {
2337                                         case DEAD_DYING:
2338                                         {
2339                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2340                                                         this.deadflag = DEAD_RESPAWNING;
2341                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2342                                                         this.deadflag = DEAD_DEAD;
2343                                                 break;
2344                                         }
2345                                         case DEAD_DEAD:
2346                                         {
2347                                                 if (button_pressed)
2348                                                         this.deadflag = DEAD_RESPAWNABLE;
2349                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2350                                                         this.deadflag = DEAD_RESPAWNING;
2351                                                 break;
2352                                         }
2353                                         case DEAD_RESPAWNABLE:
2354                                         {
2355                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2356                                                         this.deadflag = DEAD_RESPAWNING;
2357                                                 break;
2358                                         }
2359                                         case DEAD_RESPAWNING:
2360                                         {
2361                                                 if (time > this.respawn_time)
2362                                                 {
2363                                                         this.respawn_time = time + 1; // only retry once a second
2364                                                         this.respawn_time_max = this.respawn_time;
2365                                                         respawn(this);
2366                                                 }
2367                                                 break;
2368                                         }
2369                                 }
2370
2371                                 ShowRespawnCountdown(this);
2372
2373                                 if (this.respawn_flags & RESPAWN_SILENT)
2374                                         STAT(RESPAWN_TIME, this) = 0;
2375                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2376                                 {
2377                                         if (time < this.respawn_time)
2378                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2379                                         else if (this.deadflag != DEAD_RESPAWNING)
2380                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2381                                 }
2382                                 else
2383                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2384                         }
2385
2386                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2387                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2388                                 STAT(RESPAWN_TIME, this) *= -1;
2389
2390                         return;
2391                 }
2392
2393                 this.prevorigin = this.origin;
2394
2395                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2396                 if (this.hook.state) {
2397                         do_crouch = false;
2398                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2399                         do_crouch = false;
2400                 } else if (this.vehicle) {
2401                         do_crouch = false;
2402                 } else if (STAT(FROZEN, this)) {
2403                         do_crouch = false;
2404         }
2405
2406                 if (do_crouch) {
2407                         if (!this.crouch) {
2408                                 this.crouch = true;
2409                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2410                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2411                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2412                         }
2413                 } else if (this.crouch) {
2414             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2415             if (!trace_startsolid) {
2416                 this.crouch = false;
2417                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2418                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2419             }
2420                 }
2421
2422                 FixPlayermodel(this);
2423
2424                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2425                 //if(frametime)
2426                 {
2427                         this.items &= ~this.items_added;
2428
2429                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2430                         {
2431                                 .entity weaponentity = weaponentities[slot];
2432                                 W_WeaponFrame(this, weaponentity);
2433
2434                                 if(slot == 0)
2435                                 {
2436                                         this.clip_load = this.(weaponentity).clip_load;
2437                                         this.clip_size = this.(weaponentity).clip_size;
2438                                 }
2439                         }
2440
2441                         this.items_added = 0;
2442                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2443                 this.items_added |= IT_FUEL;
2444
2445                         this.items |= this.items_added;
2446                 }
2447
2448                 player_regen(this);
2449
2450                 // WEAPONTODO: Add a weapon request for this
2451                 // rot vortex charge to the charge limit
2452                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2453                 {
2454                         .entity weaponentity = weaponentities[slot];
2455                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2456                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2457                 }
2458
2459                 if (frametime) player_anim(this);
2460
2461                 // secret status
2462                 secrets_setstatus(this);
2463
2464                 // monsters status
2465                 monsters_setstatus(this);
2466
2467                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2468         }
2469         else if (gameover) {
2470                 if (intermission_running) IntermissionThink(this);
2471                 return;
2472         }
2473         else if (IS_OBSERVER(this)) {
2474                 ObserverThink(this);
2475         }
2476         else if (IS_SPEC(this)) {
2477                 SpectatorThink(this);
2478         }
2479
2480         // WEAPONTODO: Add weapon request for this
2481         if (!zoomstate_set) {
2482                 bool wep_zoomed = false;
2483                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2484                 {
2485                         .entity weaponentity = weaponentities[slot];
2486                         Weapon thiswep = this.(weaponentity).m_weapon;
2487                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2488                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2489                 }
2490                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2491     }
2492
2493         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2494         {
2495                 this.teamkill_soundtime = 0;
2496
2497                 entity e = this.teamkill_soundsource;
2498                 entity oldpusher = e.pusher;
2499                 e.pusher = this;
2500                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2501                 e.pusher = oldpusher;
2502         }
2503
2504         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2505                 this.taunt_soundtime = 0;
2506                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2507         }
2508
2509         target_voicescript_next(this);
2510
2511         // WEAPONTODO: Move into weaponsystem somehow
2512         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2513         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2514         {
2515                 .entity weaponentity = weaponentities[slot];
2516                 if(this.(weaponentity).m_weapon == WEP_Null)
2517                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2518         }
2519 }
2520
2521 void DrownPlayer(entity this)
2522 {
2523         if(IS_DEAD(this))
2524                 return;
2525
2526         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2527         {
2528                 if(this.air_finished < time)
2529                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2530                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2531                 this.dmg = 2;
2532         }
2533         else if (this.air_finished < time)
2534         {       // drown!
2535                 if (this.pain_finished < time)
2536                 {
2537                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2538                         this.pain_finished = time + 0.5;
2539                 }
2540         }
2541 }
2542
2543 .bool move_qcphysics;
2544
2545 void Player_Physics(entity this)
2546 {
2547         set_movetype(this, this.move_movetype);
2548
2549         if(!this.move_qcphysics)
2550                 return;
2551
2552         if(!frametime && !this.pm_frametime)
2553                 return;
2554
2555         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2556
2557         this.pm_frametime = 0;
2558 }
2559
2560 /*
2561 =============
2562 PlayerPostThink
2563
2564 Called every frame for each client after the physics are run
2565 =============
2566 */
2567 .float idlekick_lasttimeleft;
2568 void PlayerPostThink (entity this)
2569 {
2570         Player_Physics(this);
2571
2572         if (sv_maxidle > 0)
2573         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2574         if (IS_REAL_CLIENT(this))
2575         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2576         {
2577                 int totalClients = 0;
2578                 if(sv_maxidle_slots > 0)
2579                 {
2580                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2581                         {
2582                                 ++totalClients;
2583                         });
2584                 }
2585
2586                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2587                 { /* do nothing */ }
2588                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2589                 {
2590                         if (this.idlekick_lasttimeleft)
2591                         {
2592                                 this.idlekick_lasttimeleft = 0;
2593                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2594                         }
2595                 }
2596                 else
2597                 {
2598                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2599                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2600                                 if (!this.idlekick_lasttimeleft)
2601                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2602                         }
2603                         if (timeleft <= 0) {
2604                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2605                                 dropclient(this);
2606                                 return;
2607                         }
2608                         else if (timeleft <= 10) {
2609                                 if (timeleft != this.idlekick_lasttimeleft) {
2610                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2611                 }
2612                                 this.idlekick_lasttimeleft = timeleft;
2613                         }
2614                 }
2615         }
2616
2617         CheatFrame(this);
2618
2619         //CheckPlayerJump();
2620
2621         if (IS_PLAYER(this)) {
2622                 DrownPlayer(this);
2623                 CheckRules_Player(this);
2624                 UpdateChatBubble(this);
2625                 if (this.impulse) ImpulseCommands(this);
2626                 if (intermission_running) return; // intermission or finale
2627                 GetPressedKeys(this);
2628         }
2629
2630         if (this.waypointsprite_attachedforcarrier) {
2631             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2632                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2633     }
2634
2635         playerdemo_write(this);
2636
2637         CSQCMODEL_AUTOUPDATE(this);
2638 }