qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/campaign.qh>
  50 #include <server/chat.qh>
  51 #include <server/cheats.qh>
  52 #include <server/clientkill.qh>
  53 #include <server/command/common.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/vote.qh>
  56 #include <server/compat/quake3.qh>
  57 #include <server/damage.qh>
  58 #include <server/gamelog.qh>
  59 #include <server/handicap.qh>
  60 #include <server/hook.qh>
  61 #include <server/impulse.qh>
  62 #include <server/intermission.qh>
  63 #include <server/ipban.qh>
  64 #include <server/main.qh>
  65 #include <server/mutators/_mod.qh>
  66 #include <server/player.qh>
  67 #include <server/portals.qh>
  68 #include <server/race.qh>
  69 #include <server/scores.qh>
  70 #include <server/scores_rules.qh>
  71 #include <server/spawnpoints.qh>
  72 #include <server/teamplay.qh>
  73 #include <server/weapons/accuracy.qh>
  74 #include <server/weapons/common.qh>
  75 #include <server/weapons/hitplot.qh>
  76 #include <server/weapons/selection.qh>
  77 #include <server/weapons/tracing.qh>
  78 #include <server/weapons/weaponsystem.qh>
  79 #include <server/world.qh>
  80
  81 STATIC_METHOD(Client, Add, void(Client this, int _team))
  82 {
  83     ClientConnect(this);
  84     TRANSMUTE(Player, this);
  85     this.frame = 12; // 7
  86     this.team = _team;
  87     PutClientInServer(this);
  88 }
  89
  90 STATIC_METHOD(Client, Remove, void(Client this))
  91 {
  92     TRANSMUTE(Observer, this);
  93     PutClientInServer(this);
  94     ClientDisconnect(this);
  95 }
  96
  97 void send_CSQC_teamnagger() {
  98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  99 }
 100
 101 int CountSpectators(entity player, entity to)
 102 {
 103         if(!player) { return 0; } // not sure how, but best to be safe
 104
 105         int spec_count = 0;
 106
 107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 108         {
 109                 spec_count++;
 110         });
 111
 112         return spec_count;
 113 }
 114
 115 void WriteSpectators(entity player, entity to)
 116 {
 117         if(!player) { return; } // not sure how, but best to be safe
 118
 119         int spec_count = 0;
 120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 121         {
 122                 if(spec_count >= MAX_SPECTATORS)
 123                         break;
 124                 WriteByte(MSG_ENTITY, num_for_edict(it));
 125                 ++spec_count;
 126         });
 127 }
 128
 129 bool ClientData_Send(entity this, entity to, int sf)
 130 {
 131         assert(to == this.owner, return false);
 132
 133         entity e = to;
 134         if (IS_SPEC(e)) e = e.enemy;
 135
 136         sf = 0;
 137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 140         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 141
 142         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 143         WriteByte(MSG_ENTITY, sf);
 144
 145         if (sf & BIT(1))
 146                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 147
 148         if(sf & BIT(4))
 149         {
 150                 float specs = CountSpectators(e, to);
 151                 WriteByte(MSG_ENTITY, specs);
 152                 WriteSpectators(e, to);
 153         }
 154
 155         return true;
 156 }
 157
 158 void ClientData_Attach(entity this)
 159 {
 160         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 161         CS(this).clientdata.drawonlytoclient = this;
 162         CS(this).clientdata.owner = this;
 163 }
 164
 165 void ClientData_Detach(entity this)
 166 {
 167         delete(CS(this).clientdata);
 168         CS(this).clientdata = NULL;
 169 }
 170
 171 void ClientData_Touch(entity e)
 172 {
 173         entity cd = CS(e).clientdata;
 174         if (cd) { cd.SendFlags = 1; }
 175
 176         // make it spectatable
 177         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 178         {
 179                 entity cd = CS(it).clientdata;
 180                 if (cd) { cd.SendFlags = 1; }
 181         });
 182 }
 183
 184
 185 /*
 186 =============
 187 CheckPlayerModel
 188
 189 Checks if the argument string can be a valid playermodel.
 190 Returns a valid one in doubt.
 191 =============
 192 */
 193 string FallbackPlayerModel;
 194 string CheckPlayerModel(string plyermodel) {
 195         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 196         {
 197                 // note: we cannot summon Don Strunzone here, some player may
 198                 // still have the model string set. In case anyone manages how
 199                 // to change a cvar default, we'll have a small leak here.
 200                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 201         }
 202         // only in right path
 203         if(substring(plyermodel, 0, 14) != "models/player/")
 204                 return FallbackPlayerModel;
 205         // only good file extensions
 206         if(substring(plyermodel, -4, 4) != ".iqm"
 207                 && substring(plyermodel, -4, 4) != ".zym"
 208                 && substring(plyermodel, -4, 4) != ".dpm"
 209                 && substring(plyermodel, -4, 4) != ".md3"
 210                 && substring(plyermodel, -4, 4) != ".psk")
 211         {
 212                 return FallbackPlayerModel;
 213         }
 214         // forbid the LOD models
 215         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 216                 return FallbackPlayerModel;
 217         if(plyermodel != strtolower(plyermodel))
 218                 return FallbackPlayerModel;
 219         // also, restrict to server models
 220         if(autocvar_sv_servermodelsonly)
 221         {
 222                 if(!fexists(plyermodel))
 223                         return FallbackPlayerModel;
 224         }
 225         return plyermodel;
 226 }
 227
 228 void setplayermodel(entity e, string modelname)
 229 {
 230         precache_model(modelname);
 231         _setmodel(e, modelname);
 232         player_setupanimsformodel(e);
 233         if(!autocvar_g_debug_globalsounds)
 234                 UpdatePlayerSounds(e);
 235 }
 236
 237 /** putting a client as observer in the server */
 238 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 239 {
 240         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 241         bool recount_ready = false;
 242         PlayerState_detach(this);
 243
 244         if (IS_PLAYER(this))
 245         {
 246                 if(GetResource(this, RES_HEALTH) >= 1)
 247                 {
 248                         // despawn effect
 249                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 250                 }
 251
 252                 // was a player, recount votes and ready status
 253                 if(IS_REAL_CLIENT(this))
 254                 {
 255                         if (vote_called) { VoteCount(false); }
 256                         this.ready = false;
 257                         recount_ready = true;
 258                 }
 259                 entcs_update_players(this);
 260         }
 261
 262         if (use_spawnpoint)
 263         {
 264                 entity spot = SelectSpawnPoint(this, true);
 265                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 266                 this.angles = vec2(spot.angles);
 267                 // offset it so that the spectator spawns higher off the ground, looks better this way
 268                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 269         }
 270         else // change origin to restore previous view origin
 271                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 272         this.fixangle = true;
 273
 274         if (IS_REAL_CLIENT(this))
 275         {
 276                 msg_entity = this;
 277                 WriteByte(MSG_ONE, SVC_SETVIEW);
 278                 WriteEntity(MSG_ONE, this);
 279         }
 280         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 281         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 282         if(!autocvar_g_debug_globalsounds)
 283         {
 284                 // needed for player sounds
 285                 this.model = "";
 286                 FixPlayermodel(this);
 287         }
 288         setmodel(this, MDL_Null);
 289         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 290         this.view_ofs = '0 0 0';
 291
 292         RemoveGrapplingHooks(this);
 293         Portal_ClearAll(this);
 294         Unfreeze(this, false);
 295         SetSpectatee(this, NULL);
 296
 297         if (this.alivetime)
 298         {
 299                 if (!warmup_stage)
 300                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 301                 this.alivetime = 0;
 302         }
 303
 304         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 305
 306         TRANSMUTE(Observer, this);
 307
 308         if(recount_ready) ReadyCount();
 309
 310         WaypointSprite_PlayerDead(this);
 311         accuracy_resend(this);
 312
 313         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 314                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 315
 316         CS(this).spectatortime = time;
 317         if(this.bot_attack)
 318                 IL_REMOVE(g_bot_targets, this);
 319         this.bot_attack = false;
 320         if(this.monster_attack)
 321                 IL_REMOVE(g_monster_targets, this);
 322         this.monster_attack = false;
 323         STAT(HUD, this) = HUD_NORMAL;
 324         this.iscreature = false;
 325         this.teleportable = TELEPORT_SIMPLE;
 326         if(this.damagedbycontents)
 327                 IL_REMOVE(g_damagedbycontents, this);
 328         this.damagedbycontents = false;
 329         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 330         SetSpectatee_status(this, etof(this));
 331         this.takedamage = DAMAGE_NO;
 332         this.solid = SOLID_NOT;
 333         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 334         this.flags = FL_CLIENT | FL_NOTARGET;
 335         this.effects = 0;
 336         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 337         this.pauserotarmor_finished = 0;
 338         this.pauserothealth_finished = 0;
 339         this.pauseregen_finished = 0;
 340         this.damageforcescale = 0;
 341         this.death_time = 0;
 342         this.respawn_flags = 0;
 343         this.respawn_time = 0;
 344         STAT(RESPAWN_TIME, this) = 0;
 345         this.alpha = 0;
 346         this.scale = 0;
 347         this.fade_time = 0;
 348         this.pain_finished = 0;
 349         STAT(AIR_FINISHED, this) = 0;
 350         //this.dphitcontentsmask = 0;
 351         this.dphitcontentsmask = DPCONTENTS_SOLID;
 352         if (autocvar_g_playerclip_collisions)
 353                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 354         this.pushltime = 0;
 355         this.istypefrag = 0;
 356         setthink(this, func_null);
 357         this.nextthink = 0;
 358         this.deadflag = DEAD_NO;
 359         UNSET_DUCKED(this);
 360         STAT(REVIVE_PROGRESS, this) = 0;
 361         this.revival_time = 0;
 362         this.draggable = drag_undraggable;
 363
 364         player_powerups_remove_all(this);
 365         this.items = 0;
 366         STAT(WEAPONS, this) = '0 0 0';
 367         this.drawonlytoclient = this;
 368
 369         this.viewloc = NULL;
 370
 371         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 372
 373         this.weaponmodel = "";
 374         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 375         {
 376                 this.weaponentities[slot] = NULL;
 377         }
 378         this.exteriorweaponentity = NULL;
 379         CS(this).killcount = FRAGS_SPECTATOR;
 380         this.velocity = '0 0 0';
 381         this.avelocity = '0 0 0';
 382         this.punchangle = '0 0 0';
 383         this.punchvector = '0 0 0';
 384         this.oldvelocity = this.velocity;
 385         this.event_damage = func_null;
 386         this.event_heal = func_null;
 387
 388         for(int slot = 0; slot < MAX_AXH; ++slot)
 389         {
 390                 entity axh = this.(AuxiliaryXhair[slot]);
 391                 this.(AuxiliaryXhair[slot]) = NULL;
 392
 393                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 394                         delete(axh);
 395         }
 396
 397         if (mutator_returnvalue)
 398         {
 399                 // mutator prevents resetting teams+score
 400         }
 401         else
 402         {
 403                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 404                 this.frags = FRAGS_SPECTATOR;
 405         }
 406
 407         bot_relinkplayerlist();
 408
 409         if (CS(this).just_joined)
 410                 CS(this).just_joined = false;
 411 }
 412
 413 int player_getspecies(entity this)
 414 {
 415         get_model_parameters(this.model, this.skin);
 416         int s = get_model_parameters_species;
 417         get_model_parameters(string_null, 0);
 418         if (s < 0) return SPECIES_HUMAN;
 419         return s;
 420 }
 421
 422 .float model_randomizer;
 423 void FixPlayermodel(entity player)
 424 {
 425         string defaultmodel = "";
 426         int defaultskin = 0;
 427         if(autocvar_sv_defaultcharacter)
 428         {
 429                 if(teamplay)
 430                 {
 431                         switch(player.team)
 432                         {
 433                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 434                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 435                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 436                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 437                         }
 438                 }
 439
 440                 if(defaultmodel == "")
 441                 {
 442                         defaultmodel = autocvar_sv_defaultplayermodel;
 443                         defaultskin = autocvar_sv_defaultplayerskin;
 444                 }
 445
 446                 int n = tokenize_console(defaultmodel);
 447                 if(n > 0)
 448                 {
 449                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 450                         // However, do NOT randomize if the player-selected model is in the list.
 451                         for (int i = 0; i < n; ++i)
 452                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 453                                         defaultmodel = argv(i);
 454                 }
 455
 456                 int i = strstrofs(defaultmodel, ":", 0);
 457                 if(i >= 0)
 458                 {
 459                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 460                         defaultmodel = substring(defaultmodel, 0, i);
 461                 }
 462         }
 463         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 464         {
 465                 if(teamplay)
 466                 {
 467                         switch(player.team)
 468                         {
 469                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 470                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 471                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 472                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 473                         }
 474                 }
 475
 476                 if(!defaultskin)
 477                         defaultskin = autocvar_sv_defaultplayerskin;
 478         }
 479
 480         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 481         defaultmodel = M_ARGV(0, string);
 482         defaultskin = M_ARGV(1, int);
 483
 484         bool chmdl = false;
 485         int oldskin;
 486         if(defaultmodel != "")
 487         {
 488                 if (defaultmodel != player.model)
 489                 {
 490                         vector m1 = player.mins;
 491                         vector m2 = player.maxs;
 492                         setplayermodel (player, defaultmodel);
 493                         setsize (player, m1, m2);
 494                         chmdl = true;
 495                 }
 496
 497                 oldskin = player.skin;
 498                 player.skin = defaultskin;
 499         } else {
 500                 if (player.playermodel != player.model || player.playermodel == "")
 501                 {
 502                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 503                         vector m1 = player.mins;
 504                         vector m2 = player.maxs;
 505                         setplayermodel (player, player.playermodel);
 506                         setsize (player, m1, m2);
 507                         chmdl = true;
 508                 }
 509
 510                 if(!autocvar_sv_defaultcharacterskin)
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = stof(player.playerskin);
 514                 }
 515                 else
 516                 {
 517                         oldskin = player.skin;
 518                         player.skin = defaultskin;
 519                 }
 520         }
 521
 522         if(chmdl || oldskin != player.skin) // model or skin has changed
 523         {
 524                 player.species = player_getspecies(player); // update species
 525                 if(!autocvar_g_debug_globalsounds)
 526                         UpdatePlayerSounds(player); // update skin sounds
 527         }
 528
 529         if(!teamplay)
 530                 if(strlen(autocvar_sv_defaultplayercolors))
 531                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 532                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 533 }
 534
 535 void PutPlayerInServer(entity this)
 536 {
 537         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 538
 539         PlayerState_attach(this);
 540         accuracy_resend(this);
 541
 542         if (this.team < 0)
 543                 TeamBalance_JoinBestTeam(this);
 544
 545         entity spot = SelectSpawnPoint(this, false);
 546         if (!spot) {
 547                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 548                 return; // spawn failed
 549         }
 550
 551         TRANSMUTE(Player, this);
 552
 553         CS(this).wasplayer = true;
 554         this.iscreature = true;
 555         this.teleportable = TELEPORT_NORMAL;
 556         if(!this.damagedbycontents)
 557                 IL_PUSH(g_damagedbycontents, this);
 558         this.damagedbycontents = true;
 559         set_movetype(this, MOVETYPE_WALK);
 560         this.solid = SOLID_SLIDEBOX;
 561         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 562         if (autocvar_g_playerclip_collisions)
 563                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 564         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 565                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 566         this.frags = FRAGS_PLAYER;
 567         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 568         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 569         if (autocvar__notarget)
 570                 this.flags |= FL_NOTARGET;
 571         this.takedamage = DAMAGE_AIM;
 572         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 573
 574         if (warmup_stage) {
 575                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 576                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 577                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 578                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 579                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 580                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 581                 SetResource(this, RES_HEALTH, warmup_start_health);
 582                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 583                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 584         } else {
 585                 SetResource(this, RES_SHELLS, start_ammo_shells);
 586                 SetResource(this, RES_BULLETS, start_ammo_nails);
 587                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 588                 SetResource(this, RES_CELLS, start_ammo_cells);
 589                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 590                 SetResource(this, RES_FUEL, start_ammo_fuel);
 591                 SetResource(this, RES_HEALTH, start_health);
 592                 SetResource(this, RES_ARMOR, start_armorvalue);
 593                 STAT(WEAPONS, this) = start_weapons;
 594                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 595                 {
 596                         GiveRandomWeapons(this, random_start_weapons_count,
 597                                 autocvar_g_random_start_weapons, random_start_ammo);
 598                 }
 599         }
 600         SetSpectatee_status(this, 0);
 601
 602         PS(this).dual_weapons = '0 0 0';
 603
 604         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 605                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 606
 607         this.items = start_items;
 608
 609         float shieldtime = time + autocvar_g_spawnshieldtime;
 610
 611         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 612         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 613         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 614         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 615         if (!sv_ready_restart_after_countdown && time < game_starttime)
 616         {
 617                 float f = game_starttime - time;
 618                 shieldtime += f;
 619                 this.pauserotarmor_finished += f;
 620                 this.pauserothealth_finished += f;
 621                 this.pauseregen_finished += f;
 622         }
 623
 624         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 625
 626         this.damageforcescale = autocvar_g_player_damageforcescale;
 627         this.death_time = 0;
 628         this.respawn_flags = 0;
 629         this.respawn_time = 0;
 630         STAT(RESPAWN_TIME, this) = 0;
 631         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 632         this.fade_time = 0;
 633         this.pain_finished = 0;
 634         this.pushltime = 0;
 635         setthink(this, func_null); // players have no think function
 636         this.nextthink = 0;
 637         this.dmg_team = 0;
 638         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 639
 640         this.deadflag = DEAD_NO;
 641
 642         this.angles = spot.angles;
 643         this.angles_z = 0; // never spawn tilted even if the spot says to
 644         if (IS_BOT_CLIENT(this))
 645         {
 646                 this.v_angle = this.angles;
 647                 bot_aim_reset(this);
 648         }
 649         this.fixangle = true; // turn this way immediately
 650         this.oldvelocity = this.velocity = '0 0 0';
 651         this.avelocity = '0 0 0';
 652         this.punchangle = '0 0 0';
 653         this.punchvector = '0 0 0';
 654
 655         STAT(REVIVE_PROGRESS, this) = 0;
 656         this.revival_time = 0;
 657
 658         STAT(AIR_FINISHED, this) = 0;
 659         this.waterlevel = WATERLEVEL_NONE;
 660         this.watertype = CONTENT_EMPTY;
 661
 662         entity spawnevent = new_pure(spawnevent);
 663         spawnevent.owner = this;
 664         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 665
 666         // Cut off any still running player sounds.
 667         stopsound(this, CH_PLAYER_SINGLE);
 668
 669         this.model = "";
 670         FixPlayermodel(this);
 671         this.drawonlytoclient = NULL;
 672
 673         this.viewloc = NULL;
 674
 675         for(int slot = 0; slot < MAX_AXH; ++slot)
 676         {
 677                 entity axh = this.(AuxiliaryXhair[slot]);
 678                 this.(AuxiliaryXhair[slot]) = NULL;
 679
 680                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 681                         delete(axh);
 682         }
 683
 684         this.spawnpoint_targ = NULL;
 685
 686         UNSET_DUCKED(this);
 687         this.view_ofs = STAT(PL_VIEW_OFS, this);
 688         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 689         this.spawnorigin = spot.origin;
 690         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 691         // don't reset back to last position, even if new position is stuck in solid
 692         this.oldorigin = this.origin;
 693         if(this.conveyor)
 694                 IL_REMOVE(g_conveyed, this);
 695         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 696         if(this.swampslug)
 697                 IL_REMOVE(g_swamped, this);
 698         this.swampslug = NULL;
 699         this.swamp_interval = 0;
 700         if(this.ladder_entity)
 701                 IL_REMOVE(g_ladderents, this);
 702         this.ladder_entity = NULL;
 703         IL_EACH(g_counters, it.realowner == this,
 704         {
 705                 delete(it);
 706         });
 707         STAT(HUD, this) = HUD_NORMAL;
 708
 709         this.event_damage = PlayerDamage;
 710         this.event_heal = PlayerHeal;
 711
 712         this.draggable = func_null;
 713
 714         if(!this.bot_attack)
 715                 IL_PUSH(g_bot_targets, this);
 716         this.bot_attack = true;
 717         if(!this.monster_attack)
 718                 IL_PUSH(g_monster_targets, this);
 719         this.monster_attack = true;
 720         navigation_dynamicgoal_init(this, false);
 721
 722         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 723
 724         // player was spectator
 725         if (CS(this).killcount == FRAGS_SPECTATOR) {
 726                 PlayerScore_Clear(this);
 727                 CS(this).killcount = 0;
 728                 CS(this).startplaytime = time;
 729         }
 730
 731         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 732         {
 733                 .entity weaponentity = weaponentities[slot];
 734                 CL_SpawnWeaponentity(this, weaponentity);
 735         }
 736         this.alpha = default_player_alpha;
 737         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 738         this.exteriorweaponentity.alpha = default_weapon_alpha;
 739
 740         this.speedrunning = false;
 741
 742         this.counter_cnt = 0;
 743         this.fragsfilter_cnt = 0;
 744
 745         target_voicescript_clear(this);
 746
 747         // reset fields the weapons may use
 748         FOREACH(Weapons, true, {
 749                 it.wr_resetplayer(it, this);
 750                         // reload all reloadable weapons
 751                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 752                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 753                         {
 754                                 .entity weaponentity = weaponentities[slot];
 755                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 756                         }
 757                 }
 758         });
 759
 760         Unfreeze(this, false);
 761
 762         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 763
 764         {
 765                 string s = spot.target;
 766                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 767                         spot.target = string_null;
 768                 SUB_UseTargets(spot, this, NULL);
 769                 if(g_assault || g_race)
 770                         spot.target = s;
 771         }
 772
 773         if (autocvar_spawn_debug)
 774         {
 775                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 776                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 777         }
 778
 779         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 780         {
 781                 .entity weaponentity = weaponentities[slot];
 782                 entity w_ent = this.(weaponentity);
 783                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 784                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 785                 else
 786                         w_ent.m_switchweapon = WEP_Null;
 787                 w_ent.m_weapon = WEP_Null;
 788                 w_ent.weaponname = "";
 789                 w_ent.m_switchingweapon = WEP_Null;
 790                 w_ent.cnt = -1;
 791         }
 792
 793         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 794
 795         if (CS(this).impulse) ImpulseCommands(this);
 796
 797         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 798         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 799         {
 800                 .entity weaponentity = weaponentities[slot];
 801                 W_WeaponFrame(this, weaponentity);
 802         }
 803
 804         if (!warmup_stage && !this.alivetime)
 805                 this.alivetime = time;
 806
 807         antilag_clear(this, CS(this));
 808 }
 809
 810 /** Called when a client spawns in the server */
 811 void PutClientInServer(entity this)
 812 {
 813         if (IS_BOT_CLIENT(this)) {
 814                 TRANSMUTE(Player, this);
 815         } else if (IS_REAL_CLIENT(this)) {
 816                 msg_entity = this;
 817                 WriteByte(MSG_ONE, SVC_SETVIEW);
 818                 WriteEntity(MSG_ONE, this);
 819         }
 820         if (game_stopped)
 821                 TRANSMUTE(Observer, this);
 822
 823         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 824         SetSpectatee(this, NULL);
 825
 826         // reset player keys
 827         if(PS(this))
 828                 PS(this).itemkeys = 0;
 829
 830         MUTATOR_CALLHOOK(PutClientInServer, this);
 831
 832         if (IS_OBSERVER(this)) {
 833                 PutObserverInServer(this, false, use_spawnpoint);
 834         } else if (IS_PLAYER(this)) {
 835                 PutPlayerInServer(this);
 836         }
 837
 838         bot_relinkplayerlist();
 839 }
 840
 841 // TODO do we need all these fields, or should we stop autodetecting runtime
 842 // changes and just have a console command to update this?
 843 bool ClientInit_SendEntity(entity this, entity to, int sf)
 844 {
 845         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 846         return = true;
 847         msg_entity = to;
 848         // MSG_INIT replacement
 849         // TODO: make easier to use
 850         Registry_send_all();
 851         W_PROP_reload(MSG_ONE, to);
 852         ClientInit_misc(this);
 853         MUTATOR_CALLHOOK(Ent_Init);
 854 }
 855 void ClientInit_misc(entity this)
 856 {
 857         int channel = MSG_ONE;
 858         WriteHeader(channel, ENT_CLIENT_INIT);
 859         WriteByte(channel, g_nexball_meter_period * 32);
 860         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 864         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 868
 869         if(autocvar_sv_foginterval && world.fog != "")
 870                 WriteString(channel, world.fog);
 871         else
 872                 WriteString(channel, "");
 873         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 874         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 875         WriteByte(channel, serverflags);
 876         WriteCoord(channel, autocvar_g_trueaim_minrange);
 877 }
 878
 879 void ClientInit_CheckUpdate(entity this)
 880 {
 881         this.nextthink = time;
 882         if(this.count != autocvar_g_balance_armor_blockpercent)
 883         {
 884                 this.count = autocvar_g_balance_armor_blockpercent;
 885                 this.SendFlags |= 1;
 886         }
 887         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 888         {
 889                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 890                 this.SendFlags |= 1;
 891         }
 892 }
 893
 894 void ClientInit_Spawn()
 895 {
 896         entity e = new_pure(clientinit);
 897         setthink(e, ClientInit_CheckUpdate);
 898         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 899
 900         ClientInit_CheckUpdate(e);
 901 }
 902
 903 /*
 904 =============
 905 SetNewParms
 906 =============
 907 */
 908 void SetNewParms ()
 909 {
 910         // initialize parms for a new player
 911         parm1 = -(86400 * 366);
 912
 913         MUTATOR_CALLHOOK(SetNewParms);
 914 }
 915
 916 /*
 917 =============
 918 SetChangeParms
 919 =============
 920 */
 921 void SetChangeParms (entity this)
 922 {
 923         // save parms for level change
 924         parm1 = CS(this).parm_idlesince - time;
 925
 926         MUTATOR_CALLHOOK(SetChangeParms);
 927 }
 928
 929 /*
 930 =============
 931 DecodeLevelParms
 932 =============
 933 */
 934 void DecodeLevelParms(entity this)
 935 {
 936         // load parms
 937         CS(this).parm_idlesince = parm1;
 938         if (CS(this).parm_idlesince == -(86400 * 366))
 939                 CS(this).parm_idlesince = time;
 940
 941         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 942         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 943
 944         MUTATOR_CALLHOOK(DecodeLevelParms);
 945 }
 946
 947 void FixClientCvars(entity e)
 948 {
 949         // send prediction settings to the client
 950         if(autocvar_g_antilag == 3) // client side hitscan
 951                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 952         if(autocvar_sv_gentle)
 953                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 954
 955         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 957
 958         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 959
 960         MUTATOR_CALLHOOK(FixClientCvars, e);
 961 }
 962
 963 bool findinlist_abbrev(string tofind, string list)
 964 {
 965         if(list == "" || tofind == "")
 966                 return false; // empty list or search, just return
 967
 968         // this function allows abbreviated strings!
 969         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 970         {
 971                 return true;
 972         });
 973
 974         return false;
 975 }
 976
 977 bool PlayerInIPList(entity p, string iplist)
 978 {
 979         // some safety checks (never allow local?)
 980         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 981                 return false;
 982
 983         return findinlist_abbrev(p.netaddress, iplist);
 984 }
 985
 986 bool PlayerInIDList(entity p, string idlist)
 987 {
 988         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 989         if(!p.crypto_idfp)
 990                 return false;
 991
 992         return findinlist_abbrev(p.crypto_idfp, idlist);
 993 }
 994
 995 bool PlayerInList(entity player, string list)
 996 {
 997         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 998 }
 999
1000 #ifdef DP_EXT_PRECONNECT
1001 /*
1002 =============
1003 ClientPreConnect
1004
1005 Called once (not at each match start) when a client begins a connection to the server
1006 =============
1007 */
1008 void ClientPreConnect(entity this)
1009 {
1010         if(autocvar_sv_eventlog)
1011         {
1012                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1013                         this.playerid,
1014                         etof(this),
1015                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1016                 ));
1017         }
1018 }
1019 #endif
1020
1021 string GetClientVersionMessage(entity this)
1022 {
1023         if (CS(this).version_mismatch) {
1024                 if(CS(this).version < autocvar_gameversion) {
1025                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1026                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1027                 } else {
1028                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1029                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1030                 }
1031         } else {
1032                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1033         }
1034 }
1035
1036 void SendWelcomemessage(entity this, bool force_centerprint)
1037 {
1038         msg_entity = this;
1039         WriteHeader(MSG_ONE, TE_CSQC_SERVERINFO);
1040         WriteByte(MSG_ONE, force_centerprint);
1041         WriteString(MSG_ONE, autocvar_hostname);
1042         WriteString(MSG_ONE, GetClientVersionMessage(this));
1043
1044         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1045         string modifications = M_ARGV(0, string);
1046
1047         if(g_weaponarena)
1048         {
1049                 if(g_weaponarena_random)
1050                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1051                 else
1052                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1053         }
1054         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1055                 modifications = strcat(modifications, ", No start weapons");
1056         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1057                 modifications = strcat(modifications, ", Low gravity");
1058         if(g_weapon_stay && !g_cts)
1059                 modifications = strcat(modifications, ", Weapons stay");
1060         if(autocvar_g_jetpack)
1061                 modifications = strcat(modifications, ", Jet pack");
1062         modifications = substring(modifications, 2, strlen(modifications) - 2);
1063
1064         WriteString(MSG_ONE, modifications);
1065
1066         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1067         {
1068                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1069                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1070         }
1071
1072         WriteString(MSG_ONE, cache_mutatormsg);
1073
1074         string mutator_msg = "";
1075         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1076         mutator_msg = M_ARGV(0, string);
1077
1078         WriteString(MSG_ONE, mutator_msg); // trust that the mutator will do proper formatting
1079         WriteString(MSG_ONE, strreplace("\\n", "\n", autocvar_sv_motd));
1080 }
1081
1082 void SendWelcomemessage_onConnection_think(entity this)
1083 {
1084         SendWelcomemessage(this, false);
1085 }
1086
1087 void SendWelcomemessage_onConnection(entity this)
1088 {
1089         // give the client time to sent its version
1090         defer(this, 0.5, SendWelcomemessage_onConnection_think);
1091 }
1092
1093 /**
1094 =============
1095 ClientConnect
1096
1097 Called when a client connects to the server
1098 =============
1099 */
1100 void ClientConnect(entity this)
1101 {
1102         if (Ban_MaybeEnforceBanOnce(this)) return;
1103         assert(!IS_CLIENT(this), return);
1104         this.flags |= FL_CLIENT;
1105         assert(player_count >= 0, player_count = 0);
1106
1107         TRANSMUTE(Client, this);
1108         CS(this).version_nagtime = time + 10 + random() * 10;
1109
1110         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1111
1112         bot_clientconnect(this);
1113
1114         Player_DetermineForcedTeam(this);
1115
1116         TRANSMUTE(Observer, this);
1117
1118         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1119
1120         // always track bots, don't ask for cl_allow_uidtracking
1121         if (IS_BOT_CLIENT(this))
1122                 PlayerStats_GameReport_AddPlayer(this);
1123         else
1124                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1125
1126         if (autocvar_sv_eventlog)
1127                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1128
1129         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1130
1131         stuffcmd(this, clientstuff, "\n");
1132         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1133
1134         FixClientCvars(this);
1135
1136         // get version info from player
1137         stuffcmd(this, "cmd clientversion $gameversion\n");
1138
1139         // notify about available teams
1140         if (teamplay)
1141         {
1142                 entity balance = TeamBalance_CheckAllowedTeams(this);
1143                 int t = TeamBalance_GetAllowedTeams(balance);
1144                 TeamBalance_Destroy(balance);
1145                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1146         }
1147         else
1148         {
1149                 stuffcmd(this, "set _teams_available 0\n");
1150         }
1151
1152         bot_relinkplayerlist();
1153
1154         CS(this).spectatortime = time;
1155         if (blockSpectators)
1156         {
1157                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1158         }
1159
1160         CS(this).jointime = time;
1161
1162         if (IS_REAL_CLIENT(this))
1163         {
1164                 if (g_weaponarena_weapons == WEPSET(TUBA))
1165                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1166         }
1167
1168         if (!autocvar_sv_foginterval && world.fog != "")
1169                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1170
1171         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1172                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1173                         send_CSQC_teamnagger();
1174
1175         CSQCMODEL_AUTOINIT(this);
1176
1177         CS(this).model_randomizer = random();
1178
1179         if (IS_REAL_CLIENT(this))
1180         {
1181                 if (!autocvar_g_campaign)
1182                         SendWelcomemessage_onConnection(this);
1183                 sv_notice_join(this);
1184         }
1185
1186         this.move_qcphysics = autocvar_sv_qcphysics;
1187
1188         // update physics stats (players can spawn before physics runs)
1189         Physics_UpdateStats(this);
1190
1191         IL_EACH(g_initforplayer, it.init_for_player, {
1192                 it.init_for_player(it, this);
1193         });
1194
1195         Handicap_Initialize(this);
1196
1197         MUTATOR_CALLHOOK(ClientConnect, this);
1198
1199         if (IS_REAL_CLIENT(this) && !IS_PLAYER(this) && !autocvar_g_campaign)
1200                 CS(this).motd_actived_time = -1; // the welcome message is shown by the client
1201 }
1202 /*
1203 =============
1204 ClientDisconnect
1205
1206 Called when a client disconnects from the server
1207 =============
1208 */
1209 .entity chatbubbleentity;
1210 void player_powerups_remove_all(entity this);
1211
1212 void ClientDisconnect(entity this)
1213 {
1214         assert(IS_CLIENT(this), return);
1215
1216         PlayerStats_GameReport_FinalizePlayer(this);
1217         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1218         if (CS(this).active_minigame) part_minigame(this);
1219         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1220
1221         if (autocvar_sv_eventlog)
1222                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1223
1224         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1225
1226         if(IS_SPEC(this))
1227                 SetSpectatee(this, NULL);
1228
1229         MUTATOR_CALLHOOK(ClientDisconnect, this);
1230
1231         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1232         strfree(CS_CVAR(this).weaponorder_byimpulse);
1233         ClientState_detach(this);
1234
1235         Portal_ClearAll(this);
1236
1237         Unfreeze(this, false);
1238
1239         RemoveGrapplingHooks(this);
1240
1241         // Here, everything has been done that requires this player to be a client.
1242
1243         this.flags &= ~FL_CLIENT;
1244
1245         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1246         if (this.killindicator) delete(this.killindicator);
1247
1248         IL_EACH(g_counters, it.realowner == this,
1249         {
1250                 delete(it);
1251         });
1252
1253         WaypointSprite_PlayerGone(this);
1254
1255         bot_relinkplayerlist();
1256
1257         strfree(this.clientstatus);
1258         if (this.personal) delete(this.personal);
1259
1260         this.playerid = 0;
1261         ReadyCount();
1262         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1263
1264         player_powerups_remove_all(this); // stop powerup sound
1265
1266         ONREMOVE(this);
1267 }
1268
1269 void ChatBubbleThink(entity this)
1270 {
1271         this.nextthink = time;
1272         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1273         {
1274                 if(this.owner) // but why can that ever be NULL?
1275                         this.owner.chatbubbleentity = NULL;
1276                 delete(this);
1277                 return;
1278         }
1279
1280         this.mdl = "";
1281
1282         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1283         {
1284                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1285                         this.mdl = "models/sprites/minigame_busy.iqm";
1286                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1287                         this.mdl = "models/misc/chatbubble.spr";
1288         }
1289
1290         if ( this.model != this.mdl )
1291                 _setmodel(this, this.mdl);
1292
1293 }
1294
1295 void UpdateChatBubble(entity this)
1296 {
1297         if (this.alpha < 0)
1298                 return;
1299         // spawn a chatbubble entity if needed
1300         if (!this.chatbubbleentity)
1301         {
1302                 this.chatbubbleentity = new(chatbubbleentity);
1303                 this.chatbubbleentity.owner = this;
1304                 this.chatbubbleentity.exteriormodeltoclient = this;
1305                 setthink(this.chatbubbleentity, ChatBubbleThink);
1306                 this.chatbubbleentity.nextthink = time;
1307                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1308                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1309                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1310                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1311                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1312                 //this.chatbubbleentity.model = "";
1313                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1314         }
1315 }
1316
1317 void calculate_player_respawn_time(entity this)
1318 {
1319         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1320                 return;
1321
1322         float gametype_setting_tmp;
1323         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1324         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1325         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1326         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1327         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1328         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1329
1330         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1331         if (teamplay)
1332         {
1333                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1334                         if(it.team == this.team)
1335                                 ++pcount;
1336                 });
1337                 if (sdelay_small_count == 0)
1338                         sdelay_small_count = 1;
1339                 if (sdelay_large_count == 0)
1340                         sdelay_large_count = 1;
1341         }
1342         else
1343         {
1344                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1345                         ++pcount;
1346                 });
1347                 if (sdelay_small_count == 0)
1348                 {
1349                         if (IS_INDEPENDENT_PLAYER(this))
1350                         {
1351                                 // Players play independently. No point in requiring enemies.
1352                                 sdelay_small_count = 1;
1353                         }
1354                         else
1355                         {
1356                                 // Players play AGAINST each other. Enemies required.
1357                                 sdelay_small_count = 2;
1358                         }
1359                 }
1360                 if (sdelay_large_count == 0)
1361                 {
1362                         if (IS_INDEPENDENT_PLAYER(this))
1363                         {
1364                                 // Players play independently. No point in requiring enemies.
1365                                 sdelay_large_count = 1;
1366                         }
1367                         else
1368                         {
1369                                 // Players play AGAINST each other. Enemies required.
1370                                 sdelay_large_count = 2;
1371                         }
1372                 }
1373         }
1374
1375         float sdelay;
1376
1377         if (pcount <= sdelay_small_count)
1378                 sdelay = sdelay_small;
1379         else if (pcount >= sdelay_large_count)
1380                 sdelay = sdelay_large;
1381         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1382                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1383
1384         if(waves)
1385                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1386         else
1387                 this.respawn_time = time + sdelay;
1388
1389         if(sdelay < sdelay_max)
1390                 this.respawn_time_max = time + sdelay_max;
1391         else
1392                 this.respawn_time_max = this.respawn_time;
1393
1394         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1395                 this.respawn_countdown = 10; // first number to count down from is 10
1396         else
1397                 this.respawn_countdown = -1; // do not count down
1398
1399         if(autocvar_g_forced_respawn)
1400                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1401 }
1402
1403 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1404 // added to the model skins
1405 /*void UpdateColorModHack()
1406 {
1407         float c;
1408         c = this.clientcolors & 15;
1409         // LordHavoc: only bothering to support white, green, red, yellow, blue
1410              if (!teamplay) this.colormod = '0 0 0';
1411         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1412         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1413         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1414         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1415         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1416         else this.colormod = '1 1 1';
1417 }*/
1418
1419 void respawn(entity this)
1420 {
1421         bool damagedbycontents_prev = this.damagedbycontents;
1422         if(this.alpha >= 0)
1423         {
1424                 if(autocvar_g_respawn_ghosts)
1425                 {
1426                         this.solid = SOLID_NOT;
1427                         this.takedamage = DAMAGE_NO;
1428                         this.damagedbycontents = false;
1429                         set_movetype(this, MOVETYPE_FLY);
1430                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1431                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1432                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1433                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1434                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1435                         if(autocvar_g_respawn_ghosts_time > 0)
1436                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1437                 }
1438                 else
1439                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1440         }
1441
1442         CopyBody(this, 1);
1443         this.damagedbycontents = damagedbycontents_prev;
1444
1445         this.effects |= EF_NODRAW; // prevent another CopyBody
1446         PutClientInServer(this);
1447 }
1448
1449 void play_countdown(entity this, float finished, Sound samp)
1450 {
1451         TC(Sound, samp);
1452         float time_left = finished - time;
1453         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1454                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1455 }
1456
1457 // it removes special powerups not handled by StatusEffects
1458 void player_powerups_remove_all(entity this)
1459 {
1460         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1461         {
1462                 // don't play the poweroff sound when the game restarts or the player disconnects
1463                 if (time > game_starttime + 1 && IS_CLIENT(this)
1464                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1465                 {
1466                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1467                 }
1468                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1469                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1470                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1471         }
1472 }
1473
1474 void player_powerups(entity this)
1475 {
1476         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1477                 this.modelflags |= MF_ROCKET;
1478         else
1479                 this.modelflags &= ~MF_ROCKET;
1480
1481         this.effects &= ~EF_NODEPTHTEST;
1482
1483         if (IS_DEAD(this))
1484                 player_powerups_remove_all(this);
1485
1486         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1487                 return;
1488
1489         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1490         int items_prev = this.items;
1491
1492         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1493         {
1494                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1495                 if (this.items & IT_SUPERWEAPON)
1496                 {
1497                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1498                         {
1499                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1500                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1501                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1502                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1503                         }
1504                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1505                         {
1506                                 // don't let them run out
1507                         }
1508                         else
1509                         {
1510                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1511                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1512                                 {
1513                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1514                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1515                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1516                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1517                                 }
1518                         }
1519                 }
1520                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1521                 {
1522                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1523                         {
1524                                 this.items = this.items | IT_SUPERWEAPON;
1525                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1526                                 {
1527                                         if(!g_cts)
1528                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1529                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1530                                 }
1531                         }
1532                         else
1533                         {
1534                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1535                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1536                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1537                         }
1538                 }
1539                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1540                 {
1541                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1542                 }
1543         }
1544
1545         if(autocvar_g_nodepthtestplayers)
1546                 this.effects = this.effects | EF_NODEPTHTEST;
1547
1548         if(autocvar_g_fullbrightplayers)
1549                 this.effects = this.effects | EF_FULLBRIGHT;
1550
1551         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1552 }
1553
1554 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1555 {
1556         if(current > stable)
1557                 return current;
1558         else if(current > stable - 0.25) // when close enough, "snap"
1559                 return stable;
1560         else
1561                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1562 }
1563
1564 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1565 {
1566         if(current < stable)
1567                 return current;
1568         else if(current < stable + 0.25) // when close enough, "snap"
1569                 return stable;
1570         else
1571                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1572 }
1573
1574 void RotRegen(entity this, Resource res, float limit_mod,
1575         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1576         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1577 {
1578         float old = GetResource(this, res);
1579         float current = old;
1580         if(current > rotstable)
1581         {
1582                 if(rotframetime > 0)
1583                 {
1584                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1585                         current = max(rotstable, current - rotlinear * rotframetime);
1586                 }
1587         }
1588         else if(current < regenstable)
1589         {
1590                 if(regenframetime > 0)
1591                 {
1592                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1593                         current = min(regenstable, current + regenlinear * regenframetime);
1594                 }
1595         }
1596
1597         float limit = GetResourceLimit(this, res) * limit_mod;
1598         if(current > limit)
1599                 current = limit;
1600
1601         if (current != old)
1602                 SetResource(this, res, current);
1603 }
1604
1605 void player_regen(entity this)
1606 {
1607         float max_mod, regen_mod, rot_mod, limit_mod;
1608         max_mod = regen_mod = rot_mod = limit_mod = 1;
1609
1610         float regen_health = autocvar_g_balance_health_regen;
1611         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1612         float regen_health_rot = autocvar_g_balance_health_rot;
1613         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1614         float regen_health_stable = autocvar_g_balance_health_regenstable;
1615         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1616         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1617                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1618         max_mod = M_ARGV(1, float);
1619         regen_mod = M_ARGV(2, float);
1620         rot_mod = M_ARGV(3, float);
1621         limit_mod = M_ARGV(4, float);
1622         regen_health = M_ARGV(5, float);
1623         regen_health_linear = M_ARGV(6, float);
1624         regen_health_rot = M_ARGV(7, float);
1625         regen_health_rotlinear = M_ARGV(8, float);
1626         regen_health_stable = M_ARGV(9, float);
1627         regen_health_rotstable = M_ARGV(10, float);
1628
1629         float rotstable, regenstable, rotframetime, regenframetime;
1630
1631         if(!mutator_returnvalue)
1632         if(!STAT(FROZEN, this))
1633         {
1634                 regenstable = autocvar_g_balance_armor_regenstable;
1635                 rotstable = autocvar_g_balance_armor_rotstable;
1636                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1637                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1638                 RotRegen(this, RES_ARMOR, limit_mod,
1639                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1640                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1641
1642                 // NOTE: max_mod is only applied to health
1643                 regenstable = regen_health_stable * max_mod;
1644                 rotstable = regen_health_rotstable * max_mod;
1645                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1646                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1647                 RotRegen(this, RES_HEALTH, limit_mod,
1648                         regenstable, regen_health, regen_health_linear, regenframetime,
1649                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1650         }
1651
1652         // if player rotted to death...  die!
1653         // check this outside above checks, as player may still be able to rot to death
1654         if(GetResource(this, RES_HEALTH) < 1)
1655         {
1656                 if(this.vehicle)
1657                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1658                 if(this.event_damage)
1659                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1660         }
1661
1662         if (!(this.items & IT_UNLIMITED_AMMO))
1663         {
1664                 regenstable = autocvar_g_balance_fuel_regenstable;
1665                 rotstable = autocvar_g_balance_fuel_rotstable;
1666                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1667                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1668                 RotRegen(this, RES_FUEL, 1,
1669                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1670                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1671         }
1672 }
1673
1674 bool zoomstate_set;
1675 void SetZoomState(entity this, float newzoom)
1676 {
1677         if(newzoom != CS(this).zoomstate)
1678         {
1679                 CS(this).zoomstate = newzoom;
1680                 ClientData_Touch(this);
1681         }
1682         zoomstate_set = true;
1683 }
1684
1685 void GetPressedKeys(entity this)
1686 {
1687         MUTATOR_CALLHOOK(GetPressedKeys, this);
1688         if (game_stopped)
1689         {
1690                 CS(this).pressedkeys = 0;
1691                 STAT(PRESSED_KEYS, this) = 0;
1692                 return;
1693         }
1694
1695         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1696         int keys = STAT(PRESSED_KEYS, this);
1697         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1698         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1699         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1700         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1701
1702         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1703         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1704         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1705         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1706         CS(this).pressedkeys = keys; // store for other users
1707
1708         STAT(PRESSED_KEYS, this) = keys;
1709 }
1710
1711 /*
1712 ======================
1713 spectate mode routines
1714 ======================
1715 */
1716
1717 void SpectateCopy(entity this, entity spectatee)
1718 {
1719         TC(Client, this); TC(Client, spectatee);
1720
1721         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1722         PS(this) = PS(spectatee);
1723         this.armortype = spectatee.armortype;
1724         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1725         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1726         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1727         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1728         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1729         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1730         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1731         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1732         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1733         CS(this).impulse = 0;
1734         this.disableclientprediction = 1; // no need to run prediction on a spectator
1735         this.items = spectatee.items;
1736         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1737         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1738         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1739         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1740         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1741         this.punchangle = spectatee.punchangle;
1742         this.view_ofs = spectatee.view_ofs;
1743         this.velocity = spectatee.velocity;
1744         this.dmg_take = spectatee.dmg_take;
1745         this.dmg_save = spectatee.dmg_save;
1746         this.dmg_inflictor = spectatee.dmg_inflictor;
1747         this.v_angle = spectatee.v_angle;
1748         this.angles = spectatee.v_angle;
1749         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1750         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1751         this.viewloc = spectatee.viewloc;
1752         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1753                 this.fixangle = true;
1754         setorigin(this, spectatee.origin);
1755         setsize(this, spectatee.mins, spectatee.maxs);
1756         SetZoomState(this, CS(spectatee).zoomstate);
1757
1758     anticheat_spectatecopy(this, spectatee);
1759         STAT(HUD, this) = STAT(HUD, spectatee);
1760         if(spectatee.vehicle)
1761     {
1762         this.angles = spectatee.v_angle;
1763
1764         //this.fixangle = false;
1765         //this.velocity = spectatee.vehicle.velocity;
1766         this.vehicle_health = spectatee.vehicle_health;
1767         this.vehicle_shield = spectatee.vehicle_shield;
1768         this.vehicle_energy = spectatee.vehicle_energy;
1769         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1770         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1771         this.vehicle_reload1 = spectatee.vehicle_reload1;
1772         this.vehicle_reload2 = spectatee.vehicle_reload2;
1773
1774         //msg_entity = this;
1775
1776        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1777             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1778            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1779            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1780
1781         //WriteByte (MSG_ONE, SVC_SETVIEW);
1782         //    WriteEntity(MSG_ONE, this);
1783         //makevectors(spectatee.v_angle);
1784         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1785     }
1786 }
1787
1788 bool SpectateUpdate(entity this)
1789 {
1790         if(!this.enemy)
1791                 return false;
1792
1793         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1794         {
1795                 SetSpectatee(this, NULL);
1796                 return false;
1797         }
1798
1799         SpectateCopy(this, this.enemy);
1800
1801         return true;
1802 }
1803
1804 bool SpectateSet(entity this)
1805 {
1806         if(!IS_PLAYER(this.enemy))
1807                 return false;
1808
1809         ClientData_Touch(this.enemy);
1810
1811         msg_entity = this;
1812         WriteByte(MSG_ONE, SVC_SETVIEW);
1813         WriteEntity(MSG_ONE, this.enemy);
1814         set_movetype(this, MOVETYPE_NONE);
1815         accuracy_resend(this);
1816
1817         if(!SpectateUpdate(this))
1818                 PutObserverInServer(this, false, true);
1819
1820         return true;
1821 }
1822
1823 void SetSpectatee_status(entity this, int spectatee_num)
1824 {
1825         int oldspectatee_status = CS(this).spectatee_status;
1826         CS(this).spectatee_status = spectatee_num;
1827
1828         if (CS(this).spectatee_status != oldspectatee_status)
1829         {
1830                 if (STAT(PRESSED_KEYS, this))
1831                 {
1832                         CS(this).pressedkeys = 0;
1833                         STAT(PRESSED_KEYS, this) = 0;
1834                 }
1835                 ClientData_Touch(this);
1836                 if (g_race || g_cts) race_InitSpectator();
1837         }
1838 }
1839
1840 void SetSpectatee(entity this, entity spectatee)
1841 {
1842         if(IS_BOT_CLIENT(this))
1843                 return; // bots abuse .enemy, this code is useless to them
1844
1845         entity old_spectatee = this.enemy;
1846
1847         this.enemy = spectatee;
1848
1849         // WEAPONTODO
1850         // these are required to fix the spectator bug with arc
1851         if(old_spectatee)
1852         {
1853                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1854                 {
1855                         .entity weaponentity = weaponentities[slot];
1856                         if(old_spectatee.(weaponentity).arc_beam)
1857                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1858                 }
1859         }
1860         if(spectatee)
1861         {
1862                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1863                 {
1864                         .entity weaponentity = weaponentities[slot];
1865                         if(spectatee.(weaponentity).arc_beam)
1866                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1867                 }
1868         }
1869
1870         if (spectatee)
1871                 SetSpectatee_status(this, etof(spectatee));
1872
1873         // needed to update spectator list
1874         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1875 }
1876
1877 bool Spectate(entity this, entity pl)
1878 {
1879         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1880                 return false;
1881         pl = M_ARGV(1, entity);
1882
1883         SetSpectatee(this, pl);
1884         return SpectateSet(this);
1885 }
1886
1887 bool SpectateNext(entity this)
1888 {
1889         entity ent = find(this.enemy, classname, STR_PLAYER);
1890
1891         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1892                 ent = M_ARGV(1, entity);
1893         else if (!ent)
1894                 ent = find(ent, classname, STR_PLAYER);
1895
1896         if(ent) { SetSpectatee(this, ent); }
1897
1898         return SpectateSet(this);
1899 }
1900
1901 bool SpectatePrev(entity this)
1902 {
1903         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1904         entity ent = findchain(classname, STR_PLAYER);
1905         if (!ent) // no player
1906                 return false;
1907
1908         entity first = ent;
1909         // skip players until current spectated player
1910         if(this.enemy)
1911         while(ent && ent != this.enemy)
1912                 ent = ent.chain;
1913
1914         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1915         {
1916                 case MUT_SPECPREV_FOUND:
1917                         ent = M_ARGV(1, entity);
1918                         break;
1919                 case MUT_SPECPREV_RETURN:
1920                         return true;
1921                 case MUT_SPECPREV_CONTINUE:
1922                 default:
1923                 {
1924                         if(ent.chain)
1925                                 ent = ent.chain;
1926                         else
1927                                 ent = first;
1928                         break;
1929                 }
1930         }
1931
1932         SetSpectatee(this, ent);
1933         return SpectateSet(this);
1934 }
1935
1936 /*
1937 =============
1938 ShowRespawnCountdown()
1939
1940 Update a respawn countdown display.
1941 =============
1942 */
1943 void ShowRespawnCountdown(entity this)
1944 {
1945         float number;
1946         if(!IS_DEAD(this)) // just respawned?
1947                 return;
1948         else
1949         {
1950                 number = ceil(this.respawn_time - time);
1951                 if(number <= 0)
1952                         return;
1953                 if(number <= this.respawn_countdown)
1954                 {
1955                         this.respawn_countdown = number - 1;
1956                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1957                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1958                 }
1959         }
1960 }
1961
1962 .bool team_selected;
1963 bool ShowTeamSelection(entity this)
1964 {
1965         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1966                 return false;
1967         stuffcmd(this, "menu_showteamselect\n");
1968         return true;
1969 }
1970 void Join(entity this)
1971 {
1972         TRANSMUTE(Player, this);
1973
1974         if(!this.team_selected)
1975         if(autocvar_g_campaign || autocvar_g_balance_teams)
1976                 TeamBalance_JoinBestTeam(this);
1977
1978         if(autocvar_g_campaign)
1979                 campaign_bots_may_start = true;
1980
1981         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1982
1983         PutClientInServer(this);
1984
1985         if(IS_PLAYER(this))
1986         if(teamplay && this.team != -1)
1987         {
1988         }
1989         else
1990                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1991         this.team_selected = false;
1992 }
1993
1994 int GetPlayerLimit()
1995 {
1996         if(g_duel)
1997                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1998         int player_limit = autocvar_g_maxplayers;
1999         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2000         player_limit = M_ARGV(0, int);
2001         return player_limit;
2002 }
2003
2004 /**
2005  * Determines whether the player is allowed to join. This depends on cvar
2006  * g_maxplayers, if it isn't used this function always return true, otherwise
2007  * it checks whether the number of currently playing players exceeds g_maxplayers.
2008  * @return int number of free slots for players, 0 if none
2009  */
2010 int nJoinAllowed(entity this, entity ignore)
2011 {
2012         if(!ignore)
2013         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2014         // so report 0 free slots if restricted
2015         {
2016                 if(autocvar_g_forced_team_otherwise == "spectate")
2017                         return 0;
2018                 if(autocvar_g_forced_team_otherwise == "spectator")
2019                         return 0;
2020         }
2021
2022         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2023                 return 0; // forced spectators can never join
2024
2025         // TODO simplify this
2026         int totalClients = 0;
2027         int currentlyPlaying = 0;
2028         FOREACH_CLIENT(true, {
2029                 if(it != ignore)
2030                         ++totalClients;
2031                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2032                         ++currentlyPlaying;
2033         });
2034
2035         int player_limit = GetPlayerLimit();
2036
2037         int free_slots = 0;
2038         if (!player_limit)
2039                 free_slots = maxclients - totalClients;
2040         else if(player_limit > 0 && currentlyPlaying < player_limit)
2041                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2042
2043         static float msg_time = 0;
2044         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2045         {
2046                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2047                 msg_time = time + 0.5;
2048         }
2049
2050         return free_slots;
2051 }
2052
2053 void PrintWelcomeMessage(entity this)
2054 {
2055         if(CS(this).motd_actived_time == 0)
2056         {
2057                 if (autocvar_g_campaign) {
2058                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2059                                 CS(this).motd_actived_time = time;
2060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2061                         }
2062                 } else {
2063                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2064                                 CS(this).motd_actived_time = time;
2065                                 SendWelcomemessage(this, true);
2066                         }
2067                 }
2068         }
2069         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2070         {
2071                 if (autocvar_g_campaign) {
2072                         if (PHYS_INPUT_BUTTON_INFO(this))
2073                                 CS(this).motd_actived_time = time;
2074                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2075                                 CS(this).motd_actived_time = 0;
2076                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2077                         }
2078                 } else {
2079                         if (PHYS_INPUT_BUTTON_INFO(this))
2080                                 CS(this).motd_actived_time = time;
2081                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2082                                 CS(this).motd_actived_time = 0;
2083                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2084                         }
2085                 }
2086         }
2087         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2088         {
2089                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2090                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2091                 else if (CS(this).motd_actived_time == -2)
2092                 {
2093                         // instantly hide MOTD
2094                         CS(this).motd_actived_time = 0;
2095                         if (autocvar_g_campaign)
2096                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2097                         else
2098                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2099                 }
2100                 else if (IS_PLAYER(this) || IS_SPEC(this))
2101                 {
2102                         // FIXME occasionally for some reason MOTD never goes away
2103                         // delay MOTD removal a little bit in the hope it fixes this bug
2104                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2105                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2106                         else //if (CS(this).motd_actived_time < -2)
2107                                 CS(this).motd_actived_time++;
2108                 }
2109         }
2110 }
2111
2112 bool joinAllowed(entity this)
2113 {
2114         if (CS(this).version_mismatch) return false;
2115         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2116         if (!nJoinAllowed(this, this)) return false;
2117         if (teamplay && lockteams) return false;
2118         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2119         if (ShowTeamSelection(this)) return false;
2120         return true;
2121 }
2122
2123 .string shootfromfixedorigin;
2124 .bool dualwielding_prev;
2125 bool PlayerThink(entity this)
2126 {
2127         if (game_stopped || intermission_running) {
2128                 this.modelflags &= ~MF_ROCKET;
2129                 if(intermission_running)
2130                         IntermissionThink(this);
2131                 return false;
2132         }
2133
2134         if (timeout_status == TIMEOUT_ACTIVE) {
2135                 // don't allow the player to turn around while game is paused
2136                 // FIXME turn this into CSQC stuff
2137                 this.v_angle = this.lastV_angle;
2138                 this.angles = this.lastV_angle;
2139                 this.fixangle = true;
2140         }
2141
2142         if (frametime) player_powerups(this);
2143
2144         if (IS_DEAD(this)) {
2145                 if (this.personal && g_race_qualifying) {
2146                         if (time > this.respawn_time) {
2147                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2148                                 respawn(this);
2149                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2150                         }
2151                 } else {
2152                         if (frametime) player_anim(this);
2153
2154                         if (this.respawn_flags & RESPAWN_DENY)
2155                         {
2156                                 STAT(RESPAWN_TIME, this) = 0;
2157                                 return false;
2158                         }
2159
2160                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2161
2162                         switch(this.deadflag)
2163                         {
2164                                 case DEAD_DYING:
2165                                 {
2166                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2167                                                 this.deadflag = DEAD_RESPAWNING;
2168                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2169                                                 this.deadflag = DEAD_DEAD;
2170                                         break;
2171                                 }
2172                                 case DEAD_DEAD:
2173                                 {
2174                                         if (button_pressed)
2175                                                 this.deadflag = DEAD_RESPAWNABLE;
2176                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2177                                                 this.deadflag = DEAD_RESPAWNING;
2178                                         break;
2179                                 }
2180                                 case DEAD_RESPAWNABLE:
2181                                 {
2182                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2183                                                 this.deadflag = DEAD_RESPAWNING;
2184                                         break;
2185                                 }
2186                                 case DEAD_RESPAWNING:
2187                                 {
2188                                         if (time > this.respawn_time)
2189                                         {
2190                                                 this.respawn_time = time + 1; // only retry once a second
2191                                                 this.respawn_time_max = this.respawn_time;
2192                                                 respawn(this);
2193                                         }
2194                                         break;
2195                                 }
2196                         }
2197
2198                         ShowRespawnCountdown(this);
2199
2200                         if (this.respawn_flags & RESPAWN_SILENT)
2201                                 STAT(RESPAWN_TIME, this) = 0;
2202                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2203                         {
2204                                 if (time < this.respawn_time)
2205                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2206                                 else if (this.deadflag != DEAD_RESPAWNING)
2207                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2208                         }
2209                         else
2210                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2211                 }
2212
2213                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2214                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2215                         STAT(RESPAWN_TIME, this) *= -1;
2216
2217                 return false;
2218         }
2219
2220         FixPlayermodel(this);
2221
2222         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2223                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2224                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2225         }
2226
2227         // reset gun alignment when dual wielding status changes
2228         // to ensure guns are always aligned right and left
2229         bool dualwielding = W_DualWielding(this);
2230         if(this.dualwielding_prev != dualwielding)
2231         {
2232                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2233                 this.dualwielding_prev = dualwielding;
2234         }
2235
2236         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2237         //if(frametime)
2238         {
2239                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2240                 {
2241                         .entity weaponentity = weaponentities[slot];
2242                         if(WEP_CVAR(vortex, charge_always))
2243                                 W_Vortex_Charge(this, weaponentity, frametime);
2244                         W_WeaponFrame(this, weaponentity);
2245                 }
2246         }
2247
2248         if (frametime)
2249         {
2250                 // WEAPONTODO: Add a weapon request for this
2251                 // rot vortex charge to the charge limit
2252                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2253                 {
2254                         .entity weaponentity = weaponentities[slot];
2255                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2256                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2257                 }
2258
2259                 player_regen(this);
2260                 player_anim(this);
2261                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2262         }
2263
2264         monsters_setstatus(this);
2265
2266         return true;
2267 }
2268
2269 .bool would_spectate;
2270 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2271 void ObserverOrSpectatorThink(entity this)
2272 {
2273         bool is_spec = IS_SPEC(this);
2274         if ( CS(this).impulse )
2275         {
2276                 int r = MinigameImpulse(this, CS(this).impulse);
2277                 if (!is_spec || r)
2278                         CS(this).impulse = 0;
2279
2280                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2281                 {
2282                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2283                         CS(this).impulse = 0;
2284                         return;
2285                 }
2286         }
2287
2288         if (this.flags & FL_JUMPRELEASED) {
2289                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2290                         this.flags &= ~FL_JUMPRELEASED;
2291                         this.flags |= FL_SPAWNING;
2292                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2293                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2294                         this.flags &= ~FL_JUMPRELEASED;
2295                         if(SpectateNext(this)) {
2296                                 TRANSMUTE(Spectator, this);
2297                         } else if (is_spec) {
2298                                 TRANSMUTE(Observer, this);
2299                                 PutClientInServer(this);
2300                         }
2301                         else
2302                                 this.would_spectate = false; // unable to spectate anyone
2303                         if (is_spec)
2304                                 CS(this).impulse = 0;
2305                 } else if (is_spec) {
2306                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2307                                 this.flags &= ~FL_JUMPRELEASED;
2308                                 if(SpectatePrev(this)) {
2309                                         TRANSMUTE(Spectator, this);
2310                                 } else {
2311                                         TRANSMUTE(Observer, this);
2312                                         PutClientInServer(this);
2313                                 }
2314                                 CS(this).impulse = 0;
2315                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2316                                 this.would_spectate = false;
2317                                 this.flags &= ~FL_JUMPRELEASED;
2318                                 TRANSMUTE(Observer, this);
2319                                 PutClientInServer(this);
2320                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2321                                 PutObserverInServer(this, false, true);
2322                                 this.would_spectate = true;
2323                         }
2324                 }
2325                 else {
2326                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2327                         if (PHYS_INPUT_BUTTON_USE(this))
2328                                 wouldclip = !wouldclip;
2329                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2330                         set_movetype(this, preferred_movetype);
2331                 }
2332         } else { // jump pressed
2333                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2334                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2335                         this.flags |= FL_JUMPRELEASED;
2336                         if(this.flags & FL_SPAWNING)
2337                         {
2338                                 this.flags &= ~FL_SPAWNING;
2339                                 if(joinAllowed(this))
2340                                         Join(this);
2341                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2342                                         CS(this).autojoin_checked = -1;
2343                                 return;
2344                         }
2345                 }
2346                 if(is_spec && !SpectateUpdate(this))
2347                         PutObserverInServer(this, false, true);
2348         }
2349         if (is_spec)
2350                 this.flags |= FL_CLIENT | FL_NOTARGET;
2351 }
2352
2353 void PlayerUseKey(entity this)
2354 {
2355         if (!IS_PLAYER(this))
2356                 return;
2357
2358         if(this.vehicle)
2359         {
2360                 if(!game_stopped)
2361                 {
2362                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2363                         return;
2364                 }
2365         }
2366         else if(autocvar_g_vehicles_enter)
2367         {
2368                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2369                 {
2370                         entity head, closest_target = NULL;
2371                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2372
2373                         while(head) // find the closest acceptable target to enter
2374                         {
2375                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2376                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2377                                 {
2378                                         if(closest_target)
2379                                         {
2380                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2381                                                 { closest_target = head; }
2382                                         }
2383                                         else { closest_target = head; }
2384                                 }
2385
2386                                 head = head.chain;
2387                         }
2388
2389                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2390                 }
2391         }
2392
2393         // a use key was pressed; call handlers
2394         MUTATOR_CALLHOOK(PlayerUseKey, this);
2395 }
2396
2397
2398 /*
2399 =============
2400 PlayerPreThink
2401
2402 Called every frame for each client before the physics are run
2403 =============
2404 */
2405 .float last_vehiclecheck;
2406 void PlayerPreThink (entity this)
2407 {
2408         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2409         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2410
2411         WarpZone_PlayerPhysics_FixVAngle(this);
2412
2413         if (frametime) {
2414                 // physics frames: update anticheat stuff
2415                 anticheat_prethink(this);
2416
2417                 // WORKAROUND: only use dropclient in server frames (frametime set).
2418                 // Never use it in cl_movement frames (frametime zero).
2419                 if (blockSpectators && IS_REAL_CLIENT(this)
2420                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2421                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2422                 {
2423                         if (dropclient_schedule(this))
2424                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2425                 }
2426         }
2427
2428         zoomstate_set = false;
2429
2430         // Check for nameless players
2431         if (this.netname == "" || this.netname != CS(this).netname_previous)
2432         {
2433                 bool assume_unchanged = (CS(this).netname_previous == "");
2434                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2435                 {
2436                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2437                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2438                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2439                         assume_unchanged = false;
2440                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2441                 }
2442                 if (isInvisibleString(this.netname))
2443                 {
2444                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2445                         sprint(this, "Warning: invisible names are not allowed.\n");
2446                         assume_unchanged = false;
2447                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2448                 }
2449                 if (!assume_unchanged && autocvar_sv_eventlog)
2450                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2451                 strcpy(CS(this).netname_previous, this.netname);
2452         }
2453
2454         // version nagging
2455         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2456         CS(this).version_nagtime = 0;
2457         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2458             // git client
2459         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2460             // git server
2461             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2462         } else {
2463             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2464             if (r < 0) { // old client
2465                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2466             } else if (r > 0) { // old server
2467                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2468             }
2469         }
2470     }
2471
2472         // GOD MODE info
2473         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2474         {
2475                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2476                 this.max_armorvalue = 0;
2477         }
2478
2479         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2480         {
2481                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2482                 {
2483                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2484                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2485                         if (this.iceblock)
2486                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2487
2488                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2489                                 Unfreeze(this, false);
2490                 }
2491                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2492                 {
2493                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2494                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2495
2496                         if (GetResource(this, RES_HEALTH) < 1)
2497                         {
2498                                 if (this.vehicle)
2499                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2500                                 if(this.event_damage)
2501                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2502                         }
2503                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2504                                 Unfreeze(this, false);
2505                 }
2506         }
2507
2508         MUTATOR_CALLHOOK(PlayerPreThink, this);
2509
2510         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2511         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2512         {
2513                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2514                 {
2515                         if(!it.owner)
2516                         {
2517                                 if(!it.team || SAME_TEAM(this, it))
2518                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2519                                 else if(autocvar_g_vehicles_steal)
2520                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2521                         }
2522                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2523                         {
2524                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2525                         }
2526                 });
2527
2528                 this.last_vehiclecheck = time + 1;
2529         }
2530
2531         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2532                 PlayerUseKey(this);
2533         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2534
2535         if (IS_REAL_CLIENT(this))
2536                 PrintWelcomeMessage(this);
2537
2538         if (IS_PLAYER(this)) {
2539                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2540                         error("Client can't be spawned as player on connection!");
2541                 if(!PlayerThink(this))
2542                         return;
2543         }
2544         else if (game_stopped || intermission_running) {
2545                 if(intermission_running)
2546                         IntermissionThink(this);
2547                 return;
2548         }
2549         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2550         {
2551                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2552                 CS(this).autojoin_checked = 1;
2553                 // don't do this in ClientConnect
2554                 // many things can go wrong if a client is spawned as player on connection
2555                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2556                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2557                                 && (!teamplay || autocvar_g_balance_teams)))
2558                 {
2559                         campaign_bots_may_start = true;
2560                         if(joinAllowed(this))
2561                                 Join(this);
2562                         return;
2563                 }
2564         }
2565         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2566                 ObserverOrSpectatorThink(this);
2567         }
2568
2569         // WEAPONTODO: Add weapon request for this
2570         if (!zoomstate_set) {
2571                 bool wep_zoomed = false;
2572                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2573                 {
2574                         .entity weaponentity = weaponentities[slot];
2575                         Weapon thiswep = this.(weaponentity).m_weapon;
2576                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2577                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2578                 }
2579                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2580         }
2581
2582         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2583         {
2584                 CS(this).teamkill_soundtime = 0;
2585
2586                 entity e = CS(this).teamkill_soundsource;
2587                 entity oldpusher = e.pusher;
2588                 e.pusher = this;
2589                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2590                 e.pusher = oldpusher;
2591         }
2592
2593         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2594                 CS(this).taunt_soundtime = 0;
2595                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2596         }
2597
2598         target_voicescript_next(this);
2599 }
2600
2601 void DrownPlayer(entity this)
2602 {
2603         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2604                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2605         {
2606                 STAT(AIR_FINISHED, this) = 0;
2607                 return;
2608         }
2609
2610         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2611         {
2612                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2613                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2614                 STAT(AIR_FINISHED, this) = 0;
2615         }
2616         else
2617         {
2618                 if (!STAT(AIR_FINISHED, this))
2619                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2620                 if (STAT(AIR_FINISHED, this) < time)
2621                 {       // drown!
2622                         if (this.pain_finished < time)
2623                         {
2624                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2625                                 this.pain_finished = time + 0.5;
2626                         }
2627                 }
2628         }
2629 }
2630
2631 .bool move_qcphysics;
2632
2633 void Player_Physics(entity this)
2634 {
2635         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2636
2637         if(!this.move_qcphysics)
2638                 return;
2639
2640         if(!frametime && !CS(this).pm_frametime)
2641                 return;
2642
2643         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2644
2645         CS(this).pm_frametime = 0;
2646 }
2647
2648 /*
2649 =============
2650 PlayerPostThink
2651
2652 Called every frame for each client after the physics are run
2653 =============
2654 */
2655 void PlayerPostThink (entity this)
2656 {
2657         Player_Physics(this);
2658
2659         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2660         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2661         if (IS_REAL_CLIENT(this))
2662         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2663         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2664         {
2665                 int totalClients = 0;
2666                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2667                 {
2668                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2669                         if (server_is_dedicated)
2670                         {
2671                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2672                                 {
2673                                         ++totalClients;
2674                                 });
2675                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2676                                         totalClients = 0;
2677                         }
2678                 }
2679                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2680                 {
2681                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2682                         {
2683                                 ++totalClients;
2684                         });
2685                 }
2686
2687                 if (totalClients < autocvar_sv_maxidle_minplayers)
2688                 {
2689                         // idle kick disabled
2690                         CS(this).parm_idlesince = time;
2691                 }
2692                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2693                 {
2694                         if (CS(this).idlekick_lasttimeleft)
2695                         {
2696                                 CS(this).idlekick_lasttimeleft = 0;
2697                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2698                         }
2699                 }
2700                 else
2701                 {
2702                         float maxidle_time = autocvar_sv_maxidle;
2703                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2704                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2705                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2706                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2707                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2708                         {
2709                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2710                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2711                                 else
2712                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2713                         }
2714                         if (timeleft <= 0) {
2715                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2716                                 {
2717                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2718                                         PutObserverInServer(this, true, true);
2719                                 }
2720                                 else
2721                                 {
2722                                         if (dropclient_schedule(this))
2723                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2724                                 }
2725                                 return;
2726                         }
2727                         else if (timeleft <= countdown_time) {
2728                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2729                                         play2(this, SND(TALK2));
2730                                 CS(this).idlekick_lasttimeleft = timeleft;
2731                         }
2732                 }
2733         }
2734
2735         CheatFrame(this);
2736
2737         if (game_stopped)
2738         {
2739                 this.solid = SOLID_NOT;
2740                 this.takedamage = DAMAGE_NO;
2741                 set_movetype(this, MOVETYPE_NONE);
2742                 CS(this).teamkill_complain = 0;
2743                 CS(this).teamkill_soundtime = 0;
2744                 CS(this).teamkill_soundsource = NULL;
2745         }
2746
2747         if (IS_PLAYER(this)) {
2748                 if(this.death_time == time && IS_DEAD(this))
2749                 {
2750                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2751                         // once all the damage events of this frame have been processed with normal size
2752                         this.maxs.z = 5;
2753                         setsize(this, this.mins, this.maxs);
2754                 }
2755                 DrownPlayer(this);
2756                 UpdateChatBubble(this);
2757                 if (CS(this).impulse) ImpulseCommands(this);
2758                 GetPressedKeys(this);
2759                 if (game_stopped)
2760                 {
2761                         CSQCMODEL_AUTOUPDATE(this);
2762                         return;
2763                 }
2764         }
2765         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2766         {
2767                 CS(this).pressedkeys = 0;
2768                 STAT(PRESSED_KEYS, this) = 0;
2769         }
2770
2771         if (this.waypointsprite_attachedforcarrier) {
2772                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2773                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2774         }
2775
2776         CSQCMODEL_AUTOUPDATE(this);
2777 }
2778
2779 // hack to copy the button fields from the client entity to the Client State
2780 void PM_UpdateButtons(entity this, entity store)
2781 {
2782         if(this.impulse)
2783                 store.impulse = this.impulse;
2784         this.impulse = 0;
2785
2786         bool typing = this.buttonchat || this.button12;
2787
2788         store.button0 = (typing) ? 0 : this.button0;
2789         //button1?!
2790         store.button2 = (typing) ? 0 : this.button2;
2791         store.button3 = (typing) ? 0 : this.button3;
2792         store.button4 = this.button4;
2793         store.button5 = (typing) ? 0 : this.button5;
2794         store.button6 = this.button6;
2795         store.button7 = this.button7;
2796         store.button8 = this.button8;
2797         store.button9 = this.button9;
2798         store.button10 = this.button10;
2799         store.button11 = this.button11;
2800         store.button12 = this.button12;
2801         store.button13 = this.button13;
2802         store.button14 = this.button14;
2803         store.button15 = this.button15;
2804         store.button16 = this.button16;
2805         store.buttonuse = this.buttonuse;
2806         store.buttonchat = this.buttonchat;
2807
2808         store.cursor_active = this.cursor_active;
2809         store.cursor_screen = this.cursor_screen;
2810         store.cursor_trace_start = this.cursor_trace_start;
2811         store.cursor_trace_endpos = this.cursor_trace_endpos;
2812         store.cursor_trace_ent = this.cursor_trace_ent;
2813
2814         store.ping = this.ping;
2815         store.ping_packetloss = this.ping_packetloss;
2816         store.ping_movementloss = this.ping_movementloss;
2817
2818         store.v_angle = this.v_angle;
2819         store.movement = this.movement;
2820 }
2821
2822 NET_HANDLE(fpsreport, bool)
2823 {
2824         int fps = ReadShort();
2825         PlayerScore_Set(sender, SP_FPS, fps);
2826         return true;
2827 }