Make scoreboard team selection on spacebar press work for old clients. While at it...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / client.qc
1 #include "client.qh"
2
3 #include <common/csqcmodel_settings.qh>
4 #include <common/deathtypes/all.qh>
5 #include <common/effects/all.qh>
6 #include <common/effects/qc/globalsound.qh>
7 #include <common/ent_cs.qh>
8 #include <common/gamemodes/_mod.qh>
9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
10 #include <common/items/_mod.qh>
11 #include <common/items/inventory.qh>
12 #include <common/mapobjects/func/conveyor.qh>
13 #include <common/mapobjects/func/ladder.qh>
14 #include <common/mapobjects/subs.qh>
15 #include <common/mapobjects/target/spawnpoint.qh>
16 #include <common/mapobjects/teleporters.qh>
17 #include <common/mapobjects/trigger/counter.qh>
18 #include <common/mapobjects/trigger/secret.qh>
19 #include <common/mapobjects/trigger/swamp.qh>
20 #include <common/mapobjects/triggers.qh>
21 #include <common/minigames/sv_minigames.qh>
22 #include <common/monsters/sv_monsters.qh>
23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
24 #include <common/mutators/mutator/nades/nades.qh>
25 #include <common/mutators/mutator/overkill/oknex.qh>
26 #include <common/mutators/mutator/status_effects/_mod.qh>
27 #include <common/mutators/mutator/waypoints/all.qh>
28 #include <common/net_linked.qh>
29 #include <common/net_notice.qh>
30 #include <common/notifications/all.qh>
31 #include <common/physics/player.qh>
32 #include <common/playerstats.qh>
33 #include <common/resources/sv_resources.qh>
34 #include <common/state.qh>
35 #include <common/stats.qh>
36 #include <common/vehicles/all.qh>
37 #include <common/vehicles/sv_vehicles.qh>
38 #include <common/viewloc.qh>
39 #include <common/weapons/_all.qh>
40 #include <common/weapons/weapon/vortex.qh>
41 #include <common/wepent.qh>
42 #include <lib/csqcmodel/sv_model.qh>
43 #include <lib/warpzone/common.qh>
44 #include <lib/warpzone/server.qh>
45 #include <server/anticheat.qh>
46 #include <server/antilag.qh>
47 #include <server/bot/api.qh>
48 #include <server/bot/default/cvars.qh>
49 #include <server/campaign.qh>
50 #include <server/chat.qh>
51 #include <server/cheats.qh>
52 #include <server/clientkill.qh>
53 #include <server/command/common.qh>
54 #include <server/command/common.qh>
55 #include <server/command/vote.qh>
56 #include <server/compat/quake3.qh>
57 #include <server/damage.qh>
58 #include <server/gamelog.qh>
59 #include <server/handicap.qh>
60 #include <server/hook.qh>
61 #include <server/impulse.qh>
62 #include <server/intermission.qh>
63 #include <server/ipban.qh>
64 #include <server/main.qh>
65 #include <server/mutators/_mod.qh>
66 #include <server/player.qh>
67 #include <server/portals.qh>
68 #include <server/race.qh>
69 #include <server/scores.qh>
70 #include <server/scores_rules.qh>
71 #include <server/spawnpoints.qh>
72 #include <server/teamplay.qh>
73 #include <server/weapons/accuracy.qh>
74 #include <server/weapons/common.qh>
75 #include <server/weapons/hitplot.qh>
76 #include <server/weapons/selection.qh>
77 #include <server/weapons/tracing.qh>
78 #include <server/weapons/weaponsystem.qh>
79 #include <server/world.qh>
80
81 STATIC_METHOD(Client, Add, void(Client this, int _team))
82 {
83     ClientConnect(this);
84     TRANSMUTE(Player, this);
85     this.frame = 12; // 7
86     this.team = _team;
87     PutClientInServer(this);
88 }
89
90 STATIC_METHOD(Client, Remove, void(Client this))
91 {
92     TRANSMUTE(Observer, this);
93     PutClientInServer(this);
94     ClientDisconnect(this);
95 }
96
97 void send_CSQC_teamnagger() {
98         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
99 }
100
101 int CountSpectators(entity player, entity to)
102 {
103         if(!player) { return 0; } // not sure how, but best to be safe
104
105         int spec_count = 0;
106
107         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
108         {
109                 spec_count++;
110         });
111
112         return spec_count;
113 }
114
115 void WriteSpectators(entity player, entity to)
116 {
117         if(!player) { return; } // not sure how, but best to be safe
118
119         int spec_count = 0;
120         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
121         {
122                 if(spec_count >= MAX_SPECTATORS)
123                         break;
124                 WriteByte(MSG_ENTITY, num_for_edict(it));
125                 ++spec_count;
126         });
127 }
128
129 bool ClientData_Send(entity this, entity to, int sf)
130 {
131         assert(to == this.owner, return false);
132
133         entity e = to;
134         if (IS_SPEC(e)) e = e.enemy;
135
136         sf = 0;
137         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
138         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
139         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
140         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
141                                         sf |= BIT(4); // show spectators
142
143         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
144         WriteByte(MSG_ENTITY, sf);
145
146         if (sf & BIT(1))
147                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
148
149         if(sf & BIT(4))
150         {
151                 float specs = CountSpectators(e, to);
152                 WriteByte(MSG_ENTITY, specs);
153                 WriteSpectators(e, to);
154         }
155
156         return true;
157 }
158
159 void ClientData_Attach(entity this)
160 {
161         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
162         CS(this).clientdata.drawonlytoclient = this;
163         CS(this).clientdata.owner = this;
164 }
165
166 void ClientData_Detach(entity this)
167 {
168         delete(CS(this).clientdata);
169         CS(this).clientdata = NULL;
170 }
171
172 void ClientData_Touch(entity e)
173 {
174         entity cd = CS(e).clientdata;
175         if (cd) { cd.SendFlags = 1; }
176
177         // make it spectatable
178         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
179         {
180                 entity cd = CS(it).clientdata;
181                 if (cd) { cd.SendFlags = 1; }
182         });
183 }
184
185
186 /*
187 =============
188 CheckPlayerModel
189
190 Checks if the argument string can be a valid playermodel.
191 Returns a valid one in doubt.
192 =============
193 */
194 string FallbackPlayerModel;
195 string CheckPlayerModel(string plyermodel) {
196         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
197         {
198                 // note: we cannot summon Don Strunzone here, some player may
199                 // still have the model string set. In case anyone manages how
200                 // to change a cvar default, we'll have a small leak here.
201                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
202         }
203         // only in right path
204         if(substring(plyermodel, 0, 14) != "models/player/")
205                 return FallbackPlayerModel;
206         // only good file extensions
207         if(substring(plyermodel, -4, 4) != ".iqm"
208                 && substring(plyermodel, -4, 4) != ".zym"
209                 && substring(plyermodel, -4, 4) != ".dpm"
210                 && substring(plyermodel, -4, 4) != ".md3"
211                 && substring(plyermodel, -4, 4) != ".psk")
212         {
213                 return FallbackPlayerModel;
214         }
215         // forbid the LOD models
216         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
217                 return FallbackPlayerModel;
218         if(plyermodel != strtolower(plyermodel))
219                 return FallbackPlayerModel;
220         // also, restrict to server models
221         if(autocvar_sv_servermodelsonly)
222         {
223                 if(!fexists(plyermodel))
224                         return FallbackPlayerModel;
225         }
226         return plyermodel;
227 }
228
229 void setplayermodel(entity e, string modelname)
230 {
231         precache_model(modelname);
232         _setmodel(e, modelname);
233         player_setupanimsformodel(e);
234         if(!autocvar_g_debug_globalsounds)
235                 UpdatePlayerSounds(e);
236 }
237
238 /** putting a client as observer in the server */
239 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
240 {
241         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
242         bool recount_ready = false;
243         PlayerState_detach(this);
244
245         if (IS_PLAYER(this))
246         {
247                 if(GetResource(this, RES_HEALTH) >= 1)
248                 {
249                         // despawn effect
250                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
251                 }
252
253                 // was a player, recount votes and ready status
254                 if(IS_REAL_CLIENT(this))
255                 {
256                         if (vote_called) { VoteCount(false); }
257                         this.ready = false;
258                         recount_ready = true;
259                 }
260                 entcs_update_players(this);
261         }
262
263         if (use_spawnpoint)
264         {
265                 entity spot = SelectSpawnPoint(this, true);
266                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
267                 this.angles = vec2(spot.angles);
268                 // offset it so that the spectator spawns higher off the ground, looks better this way
269                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
270         }
271         else // change origin to restore previous view origin
272                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
273         this.fixangle = true;
274
275         if (IS_REAL_CLIENT(this))
276         {
277                 msg_entity = this;
278                 WriteByte(MSG_ONE, SVC_SETVIEW);
279                 WriteEntity(MSG_ONE, this);
280         }
281         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
282         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
283         if(!autocvar_g_debug_globalsounds)
284         {
285                 // needed for player sounds
286                 this.model = "";
287                 FixPlayermodel(this);
288         }
289         setmodel(this, MDL_Null);
290         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
291         this.view_ofs = '0 0 0';
292
293         RemoveGrapplingHooks(this);
294         Portal_ClearAll(this);
295         Unfreeze(this, false);
296         SetSpectatee(this, NULL);
297
298         if (this.alivetime)
299         {
300                 if (!warmup_stage)
301                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
302                 this.alivetime = 0;
303         }
304
305         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
306
307         TRANSMUTE(Observer, this);
308
309         if(recount_ready) ReadyCount();
310
311         WaypointSprite_PlayerDead(this);
312         accuracy_resend(this);
313
314         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
315                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
316
317         CS(this).spectatortime = time;
318         if(this.bot_attack)
319                 IL_REMOVE(g_bot_targets, this);
320         this.bot_attack = false;
321         if(this.monster_attack)
322                 IL_REMOVE(g_monster_targets, this);
323         this.monster_attack = false;
324         STAT(HUD, this) = HUD_NORMAL;
325         this.iscreature = false;
326         this.teleportable = TELEPORT_SIMPLE;
327         if(this.damagedbycontents)
328                 IL_REMOVE(g_damagedbycontents, this);
329         this.damagedbycontents = false;
330         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
331         SetSpectatee_status(this, etof(this));
332         this.takedamage = DAMAGE_NO;
333         this.solid = SOLID_NOT;
334         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
335         this.flags = FL_CLIENT | FL_NOTARGET;
336         this.effects = 0;
337         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
338         this.pauserotarmor_finished = 0;
339         this.pauserothealth_finished = 0;
340         this.pauseregen_finished = 0;
341         this.damageforcescale = 0;
342         this.death_time = 0;
343         this.respawn_flags = 0;
344         this.respawn_time = 0;
345         STAT(RESPAWN_TIME, this) = 0;
346         this.alpha = 0;
347         this.scale = 0;
348         this.fade_time = 0;
349         this.pain_finished = 0;
350         STAT(AIR_FINISHED, this) = 0;
351         //this.dphitcontentsmask = 0;
352         this.dphitcontentsmask = DPCONTENTS_SOLID;
353         if (autocvar_g_playerclip_collisions)
354                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
355         this.pushltime = 0;
356         this.istypefrag = 0;
357         setthink(this, func_null);
358         this.nextthink = 0;
359         this.deadflag = DEAD_NO;
360         UNSET_DUCKED(this);
361         STAT(REVIVE_PROGRESS, this) = 0;
362         this.revival_time = 0;
363         this.draggable = drag_undraggable;
364
365         player_powerups_remove_all(this);
366         this.items = 0;
367         STAT(WEAPONS, this) = '0 0 0';
368         this.drawonlytoclient = this;
369
370         this.viewloc = NULL;
371
372         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
373
374         this.weaponmodel = "";
375         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
376         {
377                 this.weaponentities[slot] = NULL;
378         }
379         this.exteriorweaponentity = NULL;
380         CS(this).killcount = FRAGS_SPECTATOR;
381         this.velocity = '0 0 0';
382         this.avelocity = '0 0 0';
383         this.punchangle = '0 0 0';
384         this.punchvector = '0 0 0';
385         this.oldvelocity = this.velocity;
386         this.event_damage = func_null;
387         this.event_heal = func_null;
388
389         for(int slot = 0; slot < MAX_AXH; ++slot)
390         {
391                 entity axh = this.(AuxiliaryXhair[slot]);
392                 this.(AuxiliaryXhair[slot]) = NULL;
393
394                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
395                         delete(axh);
396         }
397
398         if (mutator_returnvalue)
399         {
400                 // mutator prevents resetting teams+score
401         }
402         else
403         {
404                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
405                 this.frags = FRAGS_SPECTATOR;
406         }
407
408         bot_relinkplayerlist();
409
410         if (CS(this).just_joined)
411                 CS(this).just_joined = false;
412 }
413
414 int player_getspecies(entity this)
415 {
416         get_model_parameters(this.model, this.skin);
417         int s = get_model_parameters_species;
418         get_model_parameters(string_null, 0);
419         if (s < 0) return SPECIES_HUMAN;
420         return s;
421 }
422
423 .float model_randomizer;
424 void FixPlayermodel(entity player)
425 {
426         string defaultmodel = "";
427         int defaultskin = 0;
428         if(autocvar_sv_defaultcharacter)
429         {
430                 if(teamplay)
431                 {
432                         switch(player.team)
433                         {
434                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
435                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
436                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
437                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
438                         }
439                 }
440
441                 if(defaultmodel == "")
442                 {
443                         defaultmodel = autocvar_sv_defaultplayermodel;
444                         defaultskin = autocvar_sv_defaultplayerskin;
445                 }
446
447                 int n = tokenize_console(defaultmodel);
448                 if(n > 0)
449                 {
450                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
451                         // However, do NOT randomize if the player-selected model is in the list.
452                         for (int i = 0; i < n; ++i)
453                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
454                                         defaultmodel = argv(i);
455                 }
456
457                 int i = strstrofs(defaultmodel, ":", 0);
458                 if(i >= 0)
459                 {
460                         defaultskin = stof(substring(defaultmodel, i+1, -1));
461                         defaultmodel = substring(defaultmodel, 0, i);
462                 }
463         }
464         if(autocvar_sv_defaultcharacterskin && !defaultskin)
465         {
466                 if(teamplay)
467                 {
468                         switch(player.team)
469                         {
470                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
471                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
472                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
473                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
474                         }
475                 }
476
477                 if(!defaultskin)
478                         defaultskin = autocvar_sv_defaultplayerskin;
479         }
480
481         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
482         defaultmodel = M_ARGV(0, string);
483         defaultskin = M_ARGV(1, int);
484
485         bool chmdl = false;
486         int oldskin;
487         if(defaultmodel != "")
488         {
489                 if (defaultmodel != player.model)
490                 {
491                         vector m1 = player.mins;
492                         vector m2 = player.maxs;
493                         setplayermodel (player, defaultmodel);
494                         setsize (player, m1, m2);
495                         chmdl = true;
496                 }
497
498                 oldskin = player.skin;
499                 player.skin = defaultskin;
500         } else {
501                 if (player.playermodel != player.model || player.playermodel == "")
502                 {
503                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
504                         vector m1 = player.mins;
505                         vector m2 = player.maxs;
506                         setplayermodel (player, player.playermodel);
507                         setsize (player, m1, m2);
508                         chmdl = true;
509                 }
510
511                 if(!autocvar_sv_defaultcharacterskin)
512                 {
513                         oldskin = player.skin;
514                         player.skin = stof(player.playerskin);
515                 }
516                 else
517                 {
518                         oldskin = player.skin;
519                         player.skin = defaultskin;
520                 }
521         }
522
523         if(chmdl || oldskin != player.skin) // model or skin has changed
524         {
525                 player.species = player_getspecies(player); // update species
526                 if(!autocvar_g_debug_globalsounds)
527                         UpdatePlayerSounds(player); // update skin sounds
528         }
529
530         if(!teamplay)
531                 if(strlen(autocvar_sv_defaultplayercolors))
532                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
533                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
534 }
535
536 void PutPlayerInServer(entity this)
537 {
538         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
539
540         PlayerState_attach(this);
541         accuracy_resend(this);
542
543         if (teamplay && this.bot_forced_team)
544                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
545
546         if (this.team < 0)
547                 TeamBalance_JoinBestTeam(this);
548
549         entity spot = SelectSpawnPoint(this, false);
550         if (!spot) {
551                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
552                 return; // spawn failed
553         }
554
555         TRANSMUTE(Player, this);
556
557         CS(this).wasplayer = true;
558         this.iscreature = true;
559         this.teleportable = TELEPORT_NORMAL;
560         if(!this.damagedbycontents)
561                 IL_PUSH(g_damagedbycontents, this);
562         this.damagedbycontents = true;
563         set_movetype(this, MOVETYPE_WALK);
564         this.solid = SOLID_SLIDEBOX;
565         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
566         if (autocvar_g_playerclip_collisions)
567                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
568         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
569                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
570         this.frags = FRAGS_PLAYER;
571         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
572         this.flags = FL_CLIENT | FL_PICKUPITEMS;
573         if (autocvar__notarget)
574                 this.flags |= FL_NOTARGET;
575         this.takedamage = DAMAGE_AIM;
576         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
577
578         if (warmup_stage) {
579                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
580                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
581                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
582                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
583                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
584                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
585                 SetResource(this, RES_HEALTH, warmup_start_health);
586                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
587                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
588         } else {
589                 SetResource(this, RES_SHELLS, start_ammo_shells);
590                 SetResource(this, RES_BULLETS, start_ammo_nails);
591                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
592                 SetResource(this, RES_CELLS, start_ammo_cells);
593                 SetResource(this, RES_PLASMA, start_ammo_plasma);
594                 SetResource(this, RES_FUEL, start_ammo_fuel);
595                 SetResource(this, RES_HEALTH, start_health);
596                 SetResource(this, RES_ARMOR, start_armorvalue);
597                 STAT(WEAPONS, this) = start_weapons;
598                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
599                 {
600                         GiveRandomWeapons(this, random_start_weapons_count,
601                                 autocvar_g_random_start_weapons, random_start_ammo);
602                 }
603         }
604         SetSpectatee_status(this, 0);
605
606         PS(this).dual_weapons = '0 0 0';
607
608         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
609                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
610
611         this.items = start_items;
612
613         float shieldtime = time + autocvar_g_spawnshieldtime;
614
615         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
616         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
617         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
618         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
619         if (!sv_ready_restart_after_countdown && time < game_starttime)
620         {
621                 float f = game_starttime - time;
622                 shieldtime += f;
623                 this.pauserotarmor_finished += f;
624                 this.pauserothealth_finished += f;
625                 this.pauseregen_finished += f;
626         }
627
628         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
629
630         this.damageforcescale = autocvar_g_player_damageforcescale;
631         this.death_time = 0;
632         this.respawn_flags = 0;
633         this.respawn_time = 0;
634         STAT(RESPAWN_TIME, this) = 0;
635         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
636         this.fade_time = 0;
637         this.pain_finished = 0;
638         this.pushltime = 0;
639         setthink(this, func_null); // players have no think function
640         this.nextthink = 0;
641         this.dmg_team = 0;
642         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
643
644         this.deadflag = DEAD_NO;
645
646         this.angles = spot.angles;
647         this.angles_z = 0; // never spawn tilted even if the spot says to
648         if (IS_BOT_CLIENT(this))
649         {
650                 this.v_angle = this.angles;
651                 bot_aim_reset(this);
652         }
653         this.fixangle = true; // turn this way immediately
654         this.oldvelocity = this.velocity = '0 0 0';
655         this.avelocity = '0 0 0';
656         this.punchangle = '0 0 0';
657         this.punchvector = '0 0 0';
658
659         STAT(REVIVE_PROGRESS, this) = 0;
660         this.revival_time = 0;
661
662         STAT(AIR_FINISHED, this) = 0;
663         this.waterlevel = WATERLEVEL_NONE;
664         this.watertype = CONTENT_EMPTY;
665
666         entity spawnevent = new_pure(spawnevent);
667         spawnevent.owner = this;
668         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
669
670         // Cut off any still running player sounds.
671         stopsound(this, CH_PLAYER_SINGLE);
672
673         this.model = "";
674         FixPlayermodel(this);
675         this.drawonlytoclient = NULL;
676
677         this.viewloc = NULL;
678
679         for(int slot = 0; slot < MAX_AXH; ++slot)
680         {
681                 entity axh = this.(AuxiliaryXhair[slot]);
682                 this.(AuxiliaryXhair[slot]) = NULL;
683
684                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
685                         delete(axh);
686         }
687
688         this.spawnpoint_targ = NULL;
689
690         UNSET_DUCKED(this);
691         this.view_ofs = STAT(PL_VIEW_OFS, this);
692         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
693         this.spawnorigin = spot.origin;
694         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
695         // don't reset back to last position, even if new position is stuck in solid
696         this.oldorigin = this.origin;
697         if(this.conveyor)
698                 IL_REMOVE(g_conveyed, this);
699         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
700         if(this.swampslug)
701                 IL_REMOVE(g_swamped, this);
702         this.swampslug = NULL;
703         this.swamp_interval = 0;
704         if(this.ladder_entity)
705                 IL_REMOVE(g_ladderents, this);
706         this.ladder_entity = NULL;
707         IL_EACH(g_counters, it.realowner == this,
708         {
709                 delete(it);
710         });
711         STAT(HUD, this) = HUD_NORMAL;
712
713         this.event_damage = PlayerDamage;
714         this.event_heal = PlayerHeal;
715
716         this.draggable = func_null;
717
718         if(!this.bot_attack)
719                 IL_PUSH(g_bot_targets, this);
720         this.bot_attack = true;
721         if(!this.monster_attack)
722                 IL_PUSH(g_monster_targets, this);
723         this.monster_attack = true;
724         navigation_dynamicgoal_init(this, false);
725
726         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
727
728         // player was spectator
729         if (CS(this).killcount == FRAGS_SPECTATOR) {
730                 PlayerScore_Clear(this);
731                 CS(this).killcount = 0;
732                 CS(this).startplaytime = time;
733         }
734
735         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
736         {
737                 .entity weaponentity = weaponentities[slot];
738                 CL_SpawnWeaponentity(this, weaponentity);
739         }
740         this.alpha = default_player_alpha;
741         this.colormod = '1 1 1' * autocvar_g_player_brightness;
742         this.exteriorweaponentity.alpha = default_weapon_alpha;
743
744         this.speedrunning = false;
745
746         this.counter_cnt = 0;
747         this.fragsfilter_cnt = 0;
748
749         target_voicescript_clear(this);
750
751         // reset fields the weapons may use
752         FOREACH(Weapons, true, {
753                 it.wr_resetplayer(it, this);
754                         // reload all reloadable weapons
755                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
756                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
757                         {
758                                 .entity weaponentity = weaponentities[slot];
759                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
760                         }
761                 }
762         });
763
764         Unfreeze(this, false);
765
766         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
767         {
768                 string s = spot.target;
769                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
770                         spot.target = string_null;
771                 SUB_UseTargets(spot, this, NULL);
772                 if(g_assault || g_race)
773                         spot.target = s;
774         }
775
776         if (autocvar_spawn_debug)
777         {
778                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
779                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
780         }
781
782         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
783         {
784                 .entity weaponentity = weaponentities[slot];
785                 entity w_ent = this.(weaponentity);
786                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
787                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
788                 else
789                         w_ent.m_switchweapon = WEP_Null;
790                 w_ent.m_weapon = WEP_Null;
791                 w_ent.weaponname = "";
792                 w_ent.m_switchingweapon = WEP_Null;
793                 w_ent.cnt = -1;
794         }
795
796         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
797
798         if (CS(this).impulse) ImpulseCommands(this);
799
800         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
801         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
802         {
803                 .entity weaponentity = weaponentities[slot];
804                 W_WeaponFrame(this, weaponentity);
805         }
806
807         if (!warmup_stage && !this.alivetime)
808                 this.alivetime = time;
809
810         antilag_clear(this, CS(this));
811 }
812
813 /** Called when a client spawns in the server */
814 void PutClientInServer(entity this)
815 {
816         if (IS_REAL_CLIENT(this)) {
817                 msg_entity = this;
818                 WriteByte(MSG_ONE, SVC_SETVIEW);
819                 WriteEntity(MSG_ONE, this);
820         }
821         if (game_stopped)
822                 TRANSMUTE(Observer, this);
823
824         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
825         SetSpectatee(this, NULL);
826
827         // reset player keys
828         if(PS(this))
829                 PS(this).itemkeys = 0;
830
831         MUTATOR_CALLHOOK(PutClientInServer, this);
832
833         if (IS_OBSERVER(this)) {
834                 PutObserverInServer(this, false, use_spawnpoint);
835         } else if (IS_PLAYER(this)) {
836                 PutPlayerInServer(this);
837         }
838
839         bot_relinkplayerlist();
840 }
841
842 // TODO do we need all these fields, or should we stop autodetecting runtime
843 // changes and just have a console command to update this?
844 bool ClientInit_SendEntity(entity this, entity to, int sf)
845 {
846         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
847         return = true;
848         msg_entity = to;
849         // MSG_INIT replacement
850         // TODO: make easier to use
851         Registry_send_all();
852         W_PROP_reload(MSG_ONE, to);
853         ClientInit_misc(this);
854         MUTATOR_CALLHOOK(Ent_Init);
855 }
856 void ClientInit_misc(entity this)
857 {
858         int channel = MSG_ONE;
859         WriteHeader(channel, ENT_CLIENT_INIT);
860         WriteByte(channel, g_nexball_meter_period * 32);
861         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
862         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
863         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
864         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
865         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
866         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
867         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
868         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
869
870         if(autocvar_sv_foginterval && world.fog != "")
871                 WriteString(channel, world.fog);
872         else
873                 WriteString(channel, "");
874         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
875         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
876         WriteByte(channel, serverflags);
877         WriteCoord(channel, autocvar_g_trueaim_minrange);
878 }
879
880 void ClientInit_CheckUpdate(entity this)
881 {
882         this.nextthink = time;
883         if(this.count != autocvar_g_balance_armor_blockpercent)
884         {
885                 this.count = autocvar_g_balance_armor_blockpercent;
886                 this.SendFlags |= 1;
887         }
888         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
889         {
890                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
891                 this.SendFlags |= 1;
892         }
893 }
894
895 void ClientInit_Spawn()
896 {
897         entity e = new_pure(clientinit);
898         setthink(e, ClientInit_CheckUpdate);
899         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
900
901         ClientInit_CheckUpdate(e);
902 }
903
904 /*
905 =============
906 SetNewParms
907 =============
908 */
909 void SetNewParms ()
910 {
911         // initialize parms for a new player
912         parm1 = -(86400 * 366);
913
914         MUTATOR_CALLHOOK(SetNewParms);
915 }
916
917 /*
918 =============
919 SetChangeParms
920 =============
921 */
922 void SetChangeParms (entity this)
923 {
924         // save parms for level change
925         parm1 = CS(this).parm_idlesince - time;
926
927         MUTATOR_CALLHOOK(SetChangeParms);
928 }
929
930 /*
931 =============
932 DecodeLevelParms
933 =============
934 */
935 void DecodeLevelParms(entity this)
936 {
937         // load parms
938         CS(this).parm_idlesince = parm1;
939         if (CS(this).parm_idlesince == -(86400 * 366))
940                 CS(this).parm_idlesince = time;
941
942         // whatever happens, allow 60 seconds of idling directly after connect for map loading
943         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
944
945         MUTATOR_CALLHOOK(DecodeLevelParms);
946 }
947
948 void FixClientCvars(entity e)
949 {
950         // send prediction settings to the client
951         if(autocvar_g_antilag == 3) // client side hitscan
952                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
953         if(autocvar_sv_gentle)
954                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
955
956         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
957         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
958
959         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
960
961         MUTATOR_CALLHOOK(FixClientCvars, e);
962 }
963
964 bool findinlist_abbrev(string tofind, string list)
965 {
966         if(list == "" || tofind == "")
967                 return false; // empty list or search, just return
968
969         // this function allows abbreviated strings!
970         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
971         {
972                 return true;
973         });
974
975         return false;
976 }
977
978 bool PlayerInIPList(entity p, string iplist)
979 {
980         // some safety checks (never allow local?)
981         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
982                 return false;
983
984         return findinlist_abbrev(p.netaddress, iplist);
985 }
986
987 bool PlayerInIDList(entity p, string idlist)
988 {
989         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
990         if(!p.crypto_idfp)
991                 return false;
992
993         return findinlist_abbrev(p.crypto_idfp, idlist);
994 }
995
996 bool PlayerInList(entity player, string list)
997 {
998         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
999 }
1000
1001 #ifdef DP_EXT_PRECONNECT
1002 /*
1003 =============
1004 ClientPreConnect
1005
1006 Called once (not at each match start) when a client begins a connection to the server
1007 =============
1008 */
1009 void ClientPreConnect(entity this)
1010 {
1011         if(autocvar_sv_eventlog)
1012         {
1013                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1014                         this.playerid,
1015                         etof(this),
1016                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1017                 ));
1018         }
1019 }
1020 #endif
1021
1022 // NOTE csqc uses the active mutators list sent by this function
1023 // to understand which mutators are enabled
1024 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1025 void SendWelcomeMessage(entity this, int msg_type)
1026 {
1027         WriteByte(msg_type, boolean(autocvar_g_campaign));
1028         if (boolean(autocvar_g_campaign))
1029         {
1030                 WriteString(msg_type, Campaign_GetTitle());
1031                 WriteByte(msg_type, Campaign_GetLevelNum());
1032                 WriteString(msg_type, Campaign_GetMessage());
1033                 return;
1034         }
1035         WriteString(msg_type, autocvar_hostname);
1036         WriteString(msg_type, autocvar_g_xonoticversion);
1037         WriteByte(msg_type, CS(this).version_mismatch);
1038         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1039
1040         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1041         string modifications = M_ARGV(0, string);
1042
1043         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1044                 modifications = strcat(modifications, ", No start weapons");
1045         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1046                 modifications = strcat(modifications, ", Low gravity");
1047         if(g_weapon_stay && !g_cts)
1048                 modifications = strcat(modifications, ", Weapons stay");
1049         if(autocvar_g_jetpack)
1050                 modifications = strcat(modifications, ", Jetpack");
1051         modifications = substring(modifications, 2, strlen(modifications) - 2);
1052
1053         WriteString(msg_type, modifications);
1054
1055         WriteString(msg_type, g_weaponarena_list);
1056
1057         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1058         {
1059                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1060                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1061         }
1062
1063         WriteString(msg_type, cache_mutatormsg);
1064
1065         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1066 }
1067
1068 /**
1069 =============
1070 ClientConnect
1071
1072 Called when a client connects to the server
1073 =============
1074 */
1075 void ClientConnect(entity this)
1076 {
1077         if (Ban_MaybeEnforceBanOnce(this)) return;
1078         assert(!IS_CLIENT(this), return);
1079         this.flags |= FL_CLIENT;
1080         assert(player_count >= 0, player_count = 0);
1081
1082         TRANSMUTE(Client, this);
1083         CS(this).version_nagtime = time + 10 + random() * 10;
1084
1085         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1086
1087         bot_clientconnect(this);
1088
1089         Player_DetermineForcedTeam(this);
1090
1091         TRANSMUTE(Observer, this);
1092
1093         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1094
1095         // always track bots, don't ask for cl_allow_uidtracking
1096         if (IS_BOT_CLIENT(this))
1097                 PlayerStats_GameReport_AddPlayer(this);
1098         else
1099                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1100
1101         if (autocvar_sv_eventlog)
1102                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1103
1104         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1105
1106         stuffcmd(this, clientstuff, "\n");
1107         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1108
1109         FixClientCvars(this);
1110
1111         // get version info from player
1112         stuffcmd(this, "cmd clientversion $gameversion\n");
1113
1114         // notify about available teams
1115         if (teamplay)
1116         {
1117                 entity balance = TeamBalance_CheckAllowedTeams(this);
1118                 int t = TeamBalance_GetAllowedTeams(balance);
1119                 TeamBalance_Destroy(balance);
1120                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1121         }
1122         else
1123         {
1124                 stuffcmd(this, "set _teams_available 0\n");
1125         }
1126
1127         bot_relinkplayerlist();
1128
1129         CS(this).spectatortime = time;
1130         if (blockSpectators)
1131         {
1132                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1133         }
1134
1135         CS(this).jointime = time;
1136
1137         if (IS_REAL_CLIENT(this))
1138         {
1139                 if (g_weaponarena_weapons == WEPSET(TUBA))
1140                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1141         }
1142
1143         if (!autocvar_sv_foginterval && world.fog != "")
1144                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1145
1146         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1147                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1148                         send_CSQC_teamnagger();
1149
1150         CSQCMODEL_AUTOINIT(this);
1151
1152         CS(this).model_randomizer = random();
1153
1154         if (IS_REAL_CLIENT(this))
1155                 sv_notice_join(this);
1156
1157         this.move_qcphysics = autocvar_sv_qcphysics;
1158
1159         // update physics stats (players can spawn before physics runs)
1160         Physics_UpdateStats(this);
1161
1162         IL_EACH(g_initforplayer, it.init_for_player, {
1163                 it.init_for_player(it, this);
1164         });
1165
1166         Handicap_Initialize(this);
1167
1168         MUTATOR_CALLHOOK(ClientConnect, this);
1169
1170         if (player_count == 1)
1171                 localcmd("\nsv_hook_firstjoin\n");
1172 }
1173 /*
1174 =============
1175 ClientDisconnect
1176
1177 Called when a client disconnects from the server
1178 =============
1179 */
1180 .entity chatbubbleentity;
1181 void player_powerups_remove_all(entity this);
1182
1183 void ClientDisconnect(entity this)
1184 {
1185         assert(IS_CLIENT(this), return);
1186
1187         PlayerStats_GameReport_FinalizePlayer(this);
1188         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1189         if (CS(this).active_minigame) part_minigame(this);
1190         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1191
1192         if (autocvar_sv_eventlog)
1193                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1194
1195         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1196
1197         if(IS_SPEC(this))
1198                 SetSpectatee(this, NULL);
1199
1200         MUTATOR_CALLHOOK(ClientDisconnect, this);
1201
1202         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1203         strfree(CS_CVAR(this).weaponorder_byimpulse);
1204         ClientState_detach(this);
1205
1206         Portal_ClearAll(this);
1207
1208         Unfreeze(this, false);
1209
1210         RemoveGrapplingHooks(this);
1211
1212         // Here, everything has been done that requires this player to be a client.
1213
1214         this.flags &= ~FL_CLIENT;
1215
1216         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1217         if (this.killindicator) delete(this.killindicator);
1218
1219         IL_EACH(g_counters, it.realowner == this,
1220         {
1221                 delete(it);
1222         });
1223
1224         WaypointSprite_PlayerGone(this);
1225
1226         bot_relinkplayerlist();
1227
1228         strfree(this.clientstatus);
1229         if (this.personal) delete(this.personal);
1230
1231         this.playerid = 0;
1232         ReadyCount();
1233         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1234
1235         player_powerups_remove_all(this); // stop powerup sound
1236
1237         ONREMOVE(this);
1238
1239         if (player_count == 0)
1240                 localcmd("\nsv_hook_lastleave\n");
1241 }
1242
1243 void ChatBubbleThink(entity this)
1244 {
1245         this.nextthink = time;
1246         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1247         {
1248                 if(this.owner) // but why can that ever be NULL?
1249                         this.owner.chatbubbleentity = NULL;
1250                 delete(this);
1251                 return;
1252         }
1253
1254         this.mdl = "";
1255
1256         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1257         {
1258                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1259                         this.mdl = "models/sprites/minigame_busy.iqm";
1260                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1261                         this.mdl = "models/misc/chatbubble.spr";
1262         }
1263
1264         if ( this.model != this.mdl )
1265                 _setmodel(this, this.mdl);
1266
1267 }
1268
1269 void UpdateChatBubble(entity this)
1270 {
1271         if (this.alpha < 0)
1272                 return;
1273         // spawn a chatbubble entity if needed
1274         if (!this.chatbubbleentity)
1275         {
1276                 this.chatbubbleentity = new(chatbubbleentity);
1277                 this.chatbubbleentity.owner = this;
1278                 this.chatbubbleentity.exteriormodeltoclient = this;
1279                 setthink(this.chatbubbleentity, ChatBubbleThink);
1280                 this.chatbubbleentity.nextthink = time;
1281                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1282                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1283                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1284                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1285                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1286                 //this.chatbubbleentity.model = "";
1287                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1288         }
1289 }
1290
1291 void calculate_player_respawn_time(entity this)
1292 {
1293         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1294                 return;
1295
1296         float gametype_setting_tmp;
1297         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1298         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1299         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1300         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1301         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1302         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1303
1304         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1305         if (teamplay)
1306         {
1307                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1308                         if(it.team == this.team)
1309                                 ++pcount;
1310                 });
1311                 if (sdelay_small_count == 0)
1312                         sdelay_small_count = 1;
1313                 if (sdelay_large_count == 0)
1314                         sdelay_large_count = 1;
1315         }
1316         else
1317         {
1318                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1319                         ++pcount;
1320                 });
1321                 if (sdelay_small_count == 0)
1322                 {
1323                         if (IS_INDEPENDENT_PLAYER(this))
1324                         {
1325                                 // Players play independently. No point in requiring enemies.
1326                                 sdelay_small_count = 1;
1327                         }
1328                         else
1329                         {
1330                                 // Players play AGAINST each other. Enemies required.
1331                                 sdelay_small_count = 2;
1332                         }
1333                 }
1334                 if (sdelay_large_count == 0)
1335                 {
1336                         if (IS_INDEPENDENT_PLAYER(this))
1337                         {
1338                                 // Players play independently. No point in requiring enemies.
1339                                 sdelay_large_count = 1;
1340                         }
1341                         else
1342                         {
1343                                 // Players play AGAINST each other. Enemies required.
1344                                 sdelay_large_count = 2;
1345                         }
1346                 }
1347         }
1348
1349         float sdelay;
1350
1351         if (pcount <= sdelay_small_count)
1352                 sdelay = sdelay_small;
1353         else if (pcount >= sdelay_large_count)
1354                 sdelay = sdelay_large;
1355         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1356                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1357
1358         if(waves)
1359                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1360         else
1361                 this.respawn_time = time + sdelay;
1362
1363         if(sdelay < sdelay_max)
1364                 this.respawn_time_max = time + sdelay_max;
1365         else
1366                 this.respawn_time_max = this.respawn_time;
1367
1368         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1369                 this.respawn_countdown = 10; // first number to count down from is 10
1370         else
1371                 this.respawn_countdown = -1; // do not count down
1372
1373         if(autocvar_g_forced_respawn)
1374                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1375 }
1376
1377 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1378 // added to the model skins
1379 /*void UpdateColorModHack()
1380 {
1381         float c;
1382         c = this.clientcolors & 15;
1383         // LordHavoc: only bothering to support white, green, red, yellow, blue
1384              if (!teamplay) this.colormod = '0 0 0';
1385         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1386         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1387         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1388         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1389         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1390         else this.colormod = '1 1 1';
1391 }*/
1392
1393 void respawn(entity this)
1394 {
1395         bool damagedbycontents_prev = this.damagedbycontents;
1396         if(this.alpha >= 0)
1397         {
1398                 if(autocvar_g_respawn_ghosts)
1399                 {
1400                         this.solid = SOLID_NOT;
1401                         this.takedamage = DAMAGE_NO;
1402                         this.damagedbycontents = false;
1403                         set_movetype(this, MOVETYPE_FLY);
1404                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1405                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1406                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1407                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1408                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1409                         if(autocvar_g_respawn_ghosts_time > 0)
1410                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1411                 }
1412                 else
1413                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1414         }
1415
1416         CopyBody(this, 1);
1417         this.damagedbycontents = damagedbycontents_prev;
1418
1419         this.effects |= EF_NODRAW; // prevent another CopyBody
1420         PutClientInServer(this);
1421 }
1422
1423 void play_countdown(entity this, float finished, Sound samp)
1424 {
1425         TC(Sound, samp);
1426         float time_left = finished - time;
1427         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1428                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1429 }
1430
1431 // it removes special powerups not handled by StatusEffects
1432 void player_powerups_remove_all(entity this)
1433 {
1434         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1435         {
1436                 // don't play the poweroff sound when the game restarts or the player disconnects
1437                 if (time > game_starttime + 1 && IS_CLIENT(this)
1438                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1439                 {
1440                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1441                 }
1442                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1443                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1444                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1445         }
1446 }
1447
1448 void player_powerups(entity this)
1449 {
1450         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1451                 this.modelflags |= MF_ROCKET;
1452         else
1453                 this.modelflags &= ~MF_ROCKET;
1454
1455         this.effects &= ~EF_NODEPTHTEST;
1456
1457         if (IS_DEAD(this))
1458                 player_powerups_remove_all(this);
1459
1460         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1461                 return;
1462
1463         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1464         int items_prev = this.items;
1465
1466         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1467         {
1468                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1469                 if (this.items & IT_SUPERWEAPON)
1470                 {
1471                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1472                         {
1473                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1474                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1475                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1476                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1477                         }
1478                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1479                         {
1480                                 // don't let them run out
1481                         }
1482                         else
1483                         {
1484                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1485                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1486                                 {
1487                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1488                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1489                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1490                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1491                                 }
1492                         }
1493                 }
1494                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1495                 {
1496                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1497                         {
1498                                 this.items = this.items | IT_SUPERWEAPON;
1499                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1500                                 {
1501                                         if(!g_cts)
1502                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1503                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1504                                 }
1505                         }
1506                         else
1507                         {
1508                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1509                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1510                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1511                         }
1512                 }
1513                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1514                 {
1515                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1516                 }
1517         }
1518
1519         if(autocvar_g_nodepthtestplayers)
1520                 this.effects = this.effects | EF_NODEPTHTEST;
1521
1522         if(autocvar_g_fullbrightplayers)
1523                 this.effects = this.effects | EF_FULLBRIGHT;
1524
1525         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1526 }
1527
1528 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1529 {
1530         if(current > stable)
1531                 return current;
1532         else if(current > stable - 0.25) // when close enough, "snap"
1533                 return stable;
1534         else
1535                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1536 }
1537
1538 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1539 {
1540         if(current < stable)
1541                 return current;
1542         else if(current < stable + 0.25) // when close enough, "snap"
1543                 return stable;
1544         else
1545                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1546 }
1547
1548 void RotRegen(entity this, Resource res, float limit_mod,
1549         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1550         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1551 {
1552         float old = GetResource(this, res);
1553         float current = old;
1554         if(current > rotstable)
1555         {
1556                 if(rotframetime > 0)
1557                 {
1558                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1559                         current = max(rotstable, current - rotlinear * rotframetime);
1560                 }
1561         }
1562         else if(current < regenstable)
1563         {
1564                 if(regenframetime > 0)
1565                 {
1566                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1567                         current = min(regenstable, current + regenlinear * regenframetime);
1568                 }
1569         }
1570
1571         float limit = GetResourceLimit(this, res) * limit_mod;
1572         if(current > limit)
1573                 current = limit;
1574
1575         if (current != old)
1576                 SetResource(this, res, current);
1577 }
1578
1579 void player_regen(entity this)
1580 {
1581         float max_mod, regen_mod, rot_mod, limit_mod;
1582         max_mod = regen_mod = rot_mod = limit_mod = 1;
1583
1584         float regen_health = autocvar_g_balance_health_regen;
1585         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1586         float regen_health_rot = autocvar_g_balance_health_rot;
1587         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1588         float regen_health_stable = autocvar_g_balance_health_regenstable;
1589         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1590         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1591                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1592         max_mod = M_ARGV(1, float);
1593         regen_mod = M_ARGV(2, float);
1594         rot_mod = M_ARGV(3, float);
1595         limit_mod = M_ARGV(4, float);
1596         regen_health = M_ARGV(5, float);
1597         regen_health_linear = M_ARGV(6, float);
1598         regen_health_rot = M_ARGV(7, float);
1599         regen_health_rotlinear = M_ARGV(8, float);
1600         regen_health_stable = M_ARGV(9, float);
1601         regen_health_rotstable = M_ARGV(10, float);
1602
1603         float rotstable, regenstable, rotframetime, regenframetime;
1604
1605         if(!mutator_returnvalue)
1606         if(!STAT(FROZEN, this))
1607         {
1608                 regenstable = autocvar_g_balance_armor_regenstable;
1609                 rotstable = autocvar_g_balance_armor_rotstable;
1610                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1611                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1612                 RotRegen(this, RES_ARMOR, limit_mod,
1613                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1614                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1615
1616                 // NOTE: max_mod is only applied to health
1617                 regenstable = regen_health_stable * max_mod;
1618                 rotstable = regen_health_rotstable * max_mod;
1619                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1620                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1621                 RotRegen(this, RES_HEALTH, limit_mod,
1622                         regenstable, regen_health, regen_health_linear, regenframetime,
1623                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1624         }
1625
1626         // if player rotted to death...  die!
1627         // check this outside above checks, as player may still be able to rot to death
1628         if(GetResource(this, RES_HEALTH) < 1)
1629         {
1630                 if(this.vehicle)
1631                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1632                 if(this.event_damage)
1633                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1634         }
1635
1636         if (!(this.items & IT_UNLIMITED_AMMO))
1637         {
1638                 regenstable = autocvar_g_balance_fuel_regenstable;
1639                 rotstable = autocvar_g_balance_fuel_rotstable;
1640                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1641                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1642                 RotRegen(this, RES_FUEL, 1,
1643                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1644                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1645         }
1646 }
1647
1648 bool zoomstate_set;
1649 void SetZoomState(entity this, float newzoom)
1650 {
1651         if(newzoom != CS(this).zoomstate)
1652         {
1653                 CS(this).zoomstate = newzoom;
1654                 ClientData_Touch(this);
1655         }
1656         zoomstate_set = true;
1657 }
1658
1659 void GetPressedKeys(entity this)
1660 {
1661         MUTATOR_CALLHOOK(GetPressedKeys, this);
1662         if (game_stopped)
1663         {
1664                 CS(this).pressedkeys = 0;
1665                 STAT(PRESSED_KEYS, this) = 0;
1666                 return;
1667         }
1668
1669         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1670         int keys = STAT(PRESSED_KEYS, this);
1671         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1672         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1673         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1674         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1675
1676         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1677         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1678         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1679         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1680         CS(this).pressedkeys = keys; // store for other users
1681
1682         STAT(PRESSED_KEYS, this) = keys;
1683 }
1684
1685 /*
1686 ======================
1687 spectate mode routines
1688 ======================
1689 */
1690
1691 void SpectateCopy(entity this, entity spectatee)
1692 {
1693         TC(Client, this); TC(Client, spectatee);
1694
1695         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1696         PS(this) = PS(spectatee);
1697         this.armortype = spectatee.armortype;
1698         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1699         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1700         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1701         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1702         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1703         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1704         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1705         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1706         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1707         CS(this).impulse = 0;
1708         this.disableclientprediction = 1; // no need to run prediction on a spectator
1709         this.items = spectatee.items;
1710         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1711         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1712         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1713         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1714         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1715         this.punchangle = spectatee.punchangle;
1716         this.view_ofs = spectatee.view_ofs;
1717         this.velocity = spectatee.velocity;
1718         this.dmg_take = spectatee.dmg_take;
1719         this.dmg_save = spectatee.dmg_save;
1720         this.dmg_inflictor = spectatee.dmg_inflictor;
1721         this.v_angle = spectatee.v_angle;
1722         this.angles = spectatee.v_angle;
1723         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1724         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1725         this.viewloc = spectatee.viewloc;
1726         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1727                 this.fixangle = true;
1728         setorigin(this, spectatee.origin);
1729         setsize(this, spectatee.mins, spectatee.maxs);
1730         SetZoomState(this, CS(spectatee).zoomstate);
1731
1732     anticheat_spectatecopy(this, spectatee);
1733         STAT(HUD, this) = STAT(HUD, spectatee);
1734         if(spectatee.vehicle)
1735     {
1736         this.angles = spectatee.v_angle;
1737
1738         //this.fixangle = false;
1739         //this.velocity = spectatee.vehicle.velocity;
1740         this.vehicle_health = spectatee.vehicle_health;
1741         this.vehicle_shield = spectatee.vehicle_shield;
1742         this.vehicle_energy = spectatee.vehicle_energy;
1743         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1744         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1745         this.vehicle_reload1 = spectatee.vehicle_reload1;
1746         this.vehicle_reload2 = spectatee.vehicle_reload2;
1747
1748         //msg_entity = this;
1749
1750        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1751             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1752            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1753            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1754
1755         //WriteByte (MSG_ONE, SVC_SETVIEW);
1756         //    WriteEntity(MSG_ONE, this);
1757         //makevectors(spectatee.v_angle);
1758         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1759     }
1760 }
1761
1762 bool SpectateUpdate(entity this)
1763 {
1764         if(!this.enemy)
1765                 return false;
1766
1767         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1768         {
1769                 SetSpectatee(this, NULL);
1770                 return false;
1771         }
1772
1773         SpectateCopy(this, this.enemy);
1774
1775         return true;
1776 }
1777
1778 bool SpectateSet(entity this)
1779 {
1780         if(!IS_PLAYER(this.enemy))
1781                 return false;
1782
1783         ClientData_Touch(this.enemy);
1784
1785         msg_entity = this;
1786         WriteByte(MSG_ONE, SVC_SETVIEW);
1787         WriteEntity(MSG_ONE, this.enemy);
1788         set_movetype(this, MOVETYPE_NONE);
1789         accuracy_resend(this);
1790
1791         if(!SpectateUpdate(this))
1792                 PutObserverInServer(this, false, true);
1793
1794         return true;
1795 }
1796
1797 void SetSpectatee_status(entity this, int spectatee_num)
1798 {
1799         int oldspectatee_status = CS(this).spectatee_status;
1800         CS(this).spectatee_status = spectatee_num;
1801
1802         if (CS(this).spectatee_status != oldspectatee_status)
1803         {
1804                 if (STAT(PRESSED_KEYS, this))
1805                 {
1806                         CS(this).pressedkeys = 0;
1807                         STAT(PRESSED_KEYS, this) = 0;
1808                 }
1809                 ClientData_Touch(this);
1810                 if (g_race || g_cts) race_InitSpectator();
1811         }
1812 }
1813
1814 void SetSpectatee(entity this, entity spectatee)
1815 {
1816         if(IS_BOT_CLIENT(this))
1817                 return; // bots abuse .enemy, this code is useless to them
1818
1819         entity old_spectatee = this.enemy;
1820
1821         this.enemy = spectatee;
1822
1823         // WEAPONTODO
1824         // these are required to fix the spectator bug with arc
1825         if(old_spectatee)
1826         {
1827                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1828                 {
1829                         .entity weaponentity = weaponentities[slot];
1830                         if(old_spectatee.(weaponentity).arc_beam)
1831                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1832                 }
1833         }
1834         if(spectatee)
1835         {
1836                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1837                 {
1838                         .entity weaponentity = weaponentities[slot];
1839                         if(spectatee.(weaponentity).arc_beam)
1840                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1841                 }
1842         }
1843
1844         if (spectatee)
1845                 SetSpectatee_status(this, etof(spectatee));
1846
1847         // needed to update spectator list
1848         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1849 }
1850
1851 bool Spectate(entity this, entity pl)
1852 {
1853         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1854                 return false;
1855         pl = M_ARGV(1, entity);
1856
1857         SetSpectatee(this, pl);
1858         return SpectateSet(this);
1859 }
1860
1861 bool SpectateNext(entity this)
1862 {
1863         entity ent = find(this.enemy, classname, STR_PLAYER);
1864
1865         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1866                 ent = M_ARGV(1, entity);
1867         else if (!ent)
1868                 ent = find(ent, classname, STR_PLAYER);
1869
1870         if(ent) { SetSpectatee(this, ent); }
1871
1872         return SpectateSet(this);
1873 }
1874
1875 bool SpectatePrev(entity this)
1876 {
1877         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1878         entity ent = findchain(classname, STR_PLAYER);
1879         if (!ent) // no player
1880                 return false;
1881
1882         entity first = ent;
1883         // skip players until current spectated player
1884         if(this.enemy)
1885         while(ent && ent != this.enemy)
1886                 ent = ent.chain;
1887
1888         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1889         {
1890                 case MUT_SPECPREV_FOUND:
1891                         ent = M_ARGV(1, entity);
1892                         break;
1893                 case MUT_SPECPREV_RETURN:
1894                         return true;
1895                 case MUT_SPECPREV_CONTINUE:
1896                 default:
1897                 {
1898                         if(ent.chain)
1899                                 ent = ent.chain;
1900                         else
1901                                 ent = first;
1902                         break;
1903                 }
1904         }
1905
1906         SetSpectatee(this, ent);
1907         return SpectateSet(this);
1908 }
1909
1910 /*
1911 =============
1912 ShowRespawnCountdown()
1913
1914 Update a respawn countdown display.
1915 =============
1916 */
1917 void ShowRespawnCountdown(entity this)
1918 {
1919         float number;
1920         if(!IS_DEAD(this)) // just respawned?
1921                 return;
1922         else
1923         {
1924                 number = ceil(this.respawn_time - time);
1925                 if(number <= 0)
1926                         return;
1927                 if(number <= this.respawn_countdown)
1928                 {
1929                         this.respawn_countdown = number - 1;
1930                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1931                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1932                 }
1933         }
1934 }
1935
1936 .bool team_selected;
1937 bool ShowTeamSelection(entity this)
1938 {
1939         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1940                 return false;
1941         if (frametime) // once per frame is more than enough
1942                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1943         return true;
1944 }
1945 void Join(entity this)
1946 {
1947         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1948                 ReadyRestart(true);
1949
1950         TRANSMUTE(Player, this);
1951
1952         if(!this.team_selected)
1953         if(autocvar_g_campaign || autocvar_g_balance_teams)
1954                 TeamBalance_JoinBestTeam(this);
1955
1956         if(autocvar_g_campaign)
1957                 campaign_bots_may_start = true;
1958
1959         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1960
1961         PutClientInServer(this);
1962
1963         if(IS_PLAYER(this))
1964         if(teamplay && this.team != -1)
1965         {
1966         }
1967         else
1968                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1969         this.team_selected = false;
1970 }
1971
1972 int GetPlayerLimit()
1973 {
1974         if(g_duel)
1975                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1976         int player_limit = autocvar_g_maxplayers;
1977         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1978         player_limit = M_ARGV(0, int);
1979         return player_limit;
1980 }
1981
1982 /**
1983  * Determines whether the player is allowed to join. This depends on cvar
1984  * g_maxplayers, if it isn't used this function always return true, otherwise
1985  * it checks whether the number of currently playing players exceeds g_maxplayers.
1986  * @return int number of free slots for players, 0 if none
1987  */
1988 int nJoinAllowed(entity this, entity ignore)
1989 {
1990         if(!ignore)
1991         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1992         // so report 0 free slots if restricted
1993         {
1994                 if(autocvar_g_forced_team_otherwise == "spectate")
1995                         return 0;
1996                 if(autocvar_g_forced_team_otherwise == "spectator")
1997                         return 0;
1998         }
1999
2000         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2001                 return 0; // forced spectators can never join
2002
2003         // TODO simplify this
2004         int totalClients = 0;
2005         int currentlyPlaying = 0;
2006         FOREACH_CLIENT(true, {
2007                 if(it != ignore)
2008                         ++totalClients;
2009                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2010                         ++currentlyPlaying;
2011         });
2012
2013         int player_limit = GetPlayerLimit();
2014
2015         int free_slots = 0;
2016         if (!player_limit)
2017                 free_slots = maxclients - totalClients;
2018         else if(player_limit > 0 && currentlyPlaying < player_limit)
2019                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2020
2021         static float msg_time = 0;
2022         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2023         {
2024                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2025                 msg_time = time + 0.5;
2026         }
2027
2028         return free_slots;
2029 }
2030
2031 bool joinAllowed(entity this)
2032 {
2033         if (CS(this).version_mismatch) return false;
2034         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2035         if (!nJoinAllowed(this, this)) return false;
2036         if (teamplay && lockteams) return false;
2037         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2038         if (ShowTeamSelection(this)) return false;
2039         return true;
2040 }
2041
2042 .string shootfromfixedorigin;
2043 .bool dualwielding_prev;
2044 bool PlayerThink(entity this)
2045 {
2046         if (game_stopped || intermission_running) {
2047                 this.modelflags &= ~MF_ROCKET;
2048                 if(intermission_running)
2049                         IntermissionThink(this);
2050                 return false;
2051         }
2052
2053         if (timeout_status == TIMEOUT_ACTIVE) {
2054                 // don't allow the player to turn around while game is paused
2055                 // FIXME turn this into CSQC stuff
2056                 this.v_angle = this.lastV_angle;
2057                 this.angles = this.lastV_angle;
2058                 this.fixangle = true;
2059         }
2060
2061         if (frametime) player_powerups(this);
2062
2063         if (IS_DEAD(this)) {
2064                 if (this.personal && g_race_qualifying) {
2065                         if (time > this.respawn_time) {
2066                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2067                                 respawn(this);
2068                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2069                         }
2070                 } else {
2071                         if (frametime) player_anim(this);
2072
2073                         if (this.respawn_flags & RESPAWN_DENY)
2074                         {
2075                                 STAT(RESPAWN_TIME, this) = 0;
2076                                 return false;
2077                         }
2078
2079                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2080
2081                         switch(this.deadflag)
2082                         {
2083                                 case DEAD_DYING:
2084                                 {
2085                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2086                                                 this.deadflag = DEAD_RESPAWNING;
2087                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2088                                                 this.deadflag = DEAD_DEAD;
2089                                         break;
2090                                 }
2091                                 case DEAD_DEAD:
2092                                 {
2093                                         if (button_pressed)
2094                                                 this.deadflag = DEAD_RESPAWNABLE;
2095                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2096                                                 this.deadflag = DEAD_RESPAWNING;
2097                                         break;
2098                                 }
2099                                 case DEAD_RESPAWNABLE:
2100                                 {
2101                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2102                                                 this.deadflag = DEAD_RESPAWNING;
2103                                         break;
2104                                 }
2105                                 case DEAD_RESPAWNING:
2106                                 {
2107                                         if (time > this.respawn_time)
2108                                         {
2109                                                 this.respawn_time = time + 1; // only retry once a second
2110                                                 this.respawn_time_max = this.respawn_time;
2111                                                 respawn(this);
2112                                         }
2113                                         break;
2114                                 }
2115                         }
2116
2117                         ShowRespawnCountdown(this);
2118
2119                         if (this.respawn_flags & RESPAWN_SILENT)
2120                                 STAT(RESPAWN_TIME, this) = 0;
2121                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2122                         {
2123                                 if (time < this.respawn_time)
2124                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2125                                 else if (this.deadflag != DEAD_RESPAWNING)
2126                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2127                         }
2128                         else
2129                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2130                 }
2131
2132                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2133                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2134                         STAT(RESPAWN_TIME, this) *= -1;
2135
2136                 return false;
2137         }
2138
2139         FixPlayermodel(this);
2140
2141         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2142                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2143                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2144         }
2145
2146         // reset gun alignment when dual wielding status changes
2147         // to ensure guns are always aligned right and left
2148         bool dualwielding = W_DualWielding(this);
2149         if(this.dualwielding_prev != dualwielding)
2150         {
2151                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2152                 this.dualwielding_prev = dualwielding;
2153         }
2154
2155         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2156         //if(frametime)
2157         {
2158                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2159                 {
2160                         .entity weaponentity = weaponentities[slot];
2161                         if(WEP_CVAR(vortex, charge_always))
2162                                 W_Vortex_Charge(this, weaponentity, frametime);
2163                         W_WeaponFrame(this, weaponentity);
2164                 }
2165         }
2166
2167         if (frametime)
2168         {
2169                 // WEAPONTODO: Add a weapon request for this
2170                 // rot vortex charge to the charge limit
2171                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2172                 {
2173                         .entity weaponentity = weaponentities[slot];
2174                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2175                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2176                 }
2177
2178                 player_regen(this);
2179                 player_anim(this);
2180                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2181         }
2182
2183         monsters_setstatus(this);
2184
2185         return true;
2186 }
2187
2188 .bool would_spectate;
2189 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2190 void ObserverOrSpectatorThink(entity this)
2191 {
2192         bool is_spec = IS_SPEC(this);
2193         if ( CS(this).impulse )
2194         {
2195                 int r = MinigameImpulse(this, CS(this).impulse);
2196                 if (!is_spec || r)
2197                         CS(this).impulse = 0;
2198
2199                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2200                 {
2201                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2202                         CS(this).impulse = 0;
2203                         return;
2204                 }
2205         }
2206
2207         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2208         {
2209                 CS(this).autojoin_checked = true;
2210                 TRANSMUTE(Player, this);
2211                 PutClientInServer(this);
2212                 return;
2213         }
2214
2215         if (this.flags & FL_JUMPRELEASED) {
2216                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2217                         this.flags &= ~FL_JUMPRELEASED;
2218                         this.flags |= FL_SPAWNING;
2219                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2220                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2221                         this.flags &= ~FL_JUMPRELEASED;
2222                         if(SpectateNext(this)) {
2223                                 TRANSMUTE(Spectator, this);
2224                         } else if (is_spec) {
2225                                 TRANSMUTE(Observer, this);
2226                                 PutClientInServer(this);
2227                         }
2228                         else
2229                                 this.would_spectate = false; // unable to spectate anyone
2230                         if (is_spec)
2231                                 CS(this).impulse = 0;
2232                 } else if (is_spec) {
2233                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2234                                 this.flags &= ~FL_JUMPRELEASED;
2235                                 if(SpectatePrev(this)) {
2236                                         TRANSMUTE(Spectator, this);
2237                                 } else {
2238                                         TRANSMUTE(Observer, this);
2239                                         PutClientInServer(this);
2240                                 }
2241                                 CS(this).impulse = 0;
2242                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2243                                 this.would_spectate = false;
2244                                 this.flags &= ~FL_JUMPRELEASED;
2245                                 TRANSMUTE(Observer, this);
2246                                 PutClientInServer(this);
2247                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2248                                 PutObserverInServer(this, false, true);
2249                                 this.would_spectate = true;
2250                         }
2251                 }
2252                 else {
2253                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2254                         if (PHYS_INPUT_BUTTON_USE(this))
2255                                 wouldclip = !wouldclip;
2256                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2257                         set_movetype(this, preferred_movetype);
2258                 }
2259         } else { // jump pressed
2260                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2261                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2262                         this.flags |= FL_JUMPRELEASED;
2263                         if(this.flags & FL_SPAWNING)
2264                         {
2265                                 this.flags &= ~FL_SPAWNING;
2266                                 if(joinAllowed(this))
2267                                         Join(this);
2268                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2269                                         CS(this).autojoin_checked = -1;
2270                                 return;
2271                         }
2272                 }
2273                 if(is_spec && !SpectateUpdate(this))
2274                         PutObserverInServer(this, false, true);
2275         }
2276         if (is_spec)
2277                 this.flags |= FL_CLIENT | FL_NOTARGET;
2278 }
2279
2280 void PlayerUseKey(entity this)
2281 {
2282         if (!IS_PLAYER(this))
2283                 return;
2284
2285         if(this.vehicle)
2286         {
2287                 if(!game_stopped)
2288                 {
2289                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2290                         return;
2291                 }
2292         }
2293         else if(autocvar_g_vehicles_enter)
2294         {
2295                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2296                 {
2297                         entity head, closest_target = NULL;
2298                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2299
2300                         while(head) // find the closest acceptable target to enter
2301                         {
2302                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2303                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2304                                 {
2305                                         if(closest_target)
2306                                         {
2307                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2308                                                 { closest_target = head; }
2309                                         }
2310                                         else { closest_target = head; }
2311                                 }
2312
2313                                 head = head.chain;
2314                         }
2315
2316                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2317                 }
2318         }
2319
2320         // a use key was pressed; call handlers
2321         MUTATOR_CALLHOOK(PlayerUseKey, this);
2322 }
2323
2324
2325 /*
2326 =============
2327 PlayerPreThink
2328
2329 Called every frame for each client before the physics are run
2330 =============
2331 */
2332 .float last_vehiclecheck;
2333 void PlayerPreThink (entity this)
2334 {
2335         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2336         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2337
2338         WarpZone_PlayerPhysics_FixVAngle(this);
2339
2340         if (frametime) {
2341                 // physics frames: update anticheat stuff
2342                 anticheat_prethink(this);
2343
2344                 // WORKAROUND: only use dropclient in server frames (frametime set).
2345                 // Never use it in cl_movement frames (frametime zero).
2346                 if (blockSpectators && IS_REAL_CLIENT(this)
2347                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2348                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2349                 {
2350                         if (dropclient_schedule(this))
2351                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2352                 }
2353         }
2354
2355         zoomstate_set = false;
2356
2357         // Check for nameless players
2358         if (this.netname == "" || this.netname != CS(this).netname_previous)
2359         {
2360                 bool assume_unchanged = (CS(this).netname_previous == "");
2361                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2362                 {
2363                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2364                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2365                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2366                         assume_unchanged = false;
2367                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2368                 }
2369                 if (isInvisibleString(this.netname))
2370                 {
2371                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2372                         sprint(this, "Warning: invisible names are not allowed.\n");
2373                         assume_unchanged = false;
2374                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2375                 }
2376                 if (!assume_unchanged && autocvar_sv_eventlog)
2377                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2378                 strcpy(CS(this).netname_previous, this.netname);
2379         }
2380
2381         // version nagging
2382         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2383         CS(this).version_nagtime = 0;
2384         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2385             // git client
2386         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2387             // git server
2388             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2389         } else {
2390             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2391             if (r < 0) { // old client
2392                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2393             } else if (r > 0) { // old server
2394                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2395             }
2396         }
2397     }
2398
2399         // GOD MODE info
2400         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2401         {
2402                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2403                 this.max_armorvalue = 0;
2404         }
2405
2406         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2407         {
2408                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2409                 {
2410                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2411                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2412                         if (this.iceblock)
2413                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2414
2415                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2416                                 Unfreeze(this, false);
2417                 }
2418                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2419                 {
2420                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2421                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2422
2423                         if (GetResource(this, RES_HEALTH) < 1)
2424                         {
2425                                 if (this.vehicle)
2426                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2427                                 if(this.event_damage)
2428                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2429                         }
2430                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2431                                 Unfreeze(this, false);
2432                 }
2433         }
2434
2435         MUTATOR_CALLHOOK(PlayerPreThink, this);
2436
2437         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2438         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2439         {
2440                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2441                 {
2442                         if(!it.owner)
2443                         {
2444                                 if(!it.team || SAME_TEAM(this, it))
2445                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2446                                 else if(autocvar_g_vehicles_steal)
2447                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2448                         }
2449                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2450                         {
2451                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2452                         }
2453                 });
2454
2455                 this.last_vehiclecheck = time + 1;
2456         }
2457
2458         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2459                 PlayerUseKey(this);
2460         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2461
2462         if (IS_PLAYER(this)) {
2463                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2464                         error("Client can't be spawned as player on connection!");
2465                 if(!PlayerThink(this))
2466                         return;
2467         }
2468         else if (game_stopped || intermission_running) {
2469                 if(intermission_running)
2470                         IntermissionThink(this);
2471                 return;
2472         }
2473         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2474         {
2475                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2476                 CS(this).autojoin_checked = 1;
2477                 // don't do this in ClientConnect
2478                 // many things can go wrong if a client is spawned as player on connection
2479                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2480                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2481                                 && (!teamplay || autocvar_g_balance_teams)))
2482                 {
2483                         if(joinAllowed(this))
2484                                 Join(this);
2485                         return;
2486                 }
2487         }
2488         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2489                 ObserverOrSpectatorThink(this);
2490         }
2491
2492         // WEAPONTODO: Add weapon request for this
2493         if (!zoomstate_set) {
2494                 bool wep_zoomed = false;
2495                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2496                 {
2497                         .entity weaponentity = weaponentities[slot];
2498                         Weapon thiswep = this.(weaponentity).m_weapon;
2499                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2500                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2501                 }
2502                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2503         }
2504
2505         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2506         {
2507                 CS(this).teamkill_soundtime = 0;
2508
2509                 entity e = CS(this).teamkill_soundsource;
2510                 entity oldpusher = e.pusher;
2511                 e.pusher = this;
2512                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2513                 e.pusher = oldpusher;
2514         }
2515
2516         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2517                 CS(this).taunt_soundtime = 0;
2518                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2519         }
2520
2521         target_voicescript_next(this);
2522 }
2523
2524 void DrownPlayer(entity this)
2525 {
2526         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2527                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2528         {
2529                 STAT(AIR_FINISHED, this) = 0;
2530                 return;
2531         }
2532
2533         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2534         {
2535                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2536                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2537                 STAT(AIR_FINISHED, this) = 0;
2538         }
2539         else
2540         {
2541                 if (!STAT(AIR_FINISHED, this))
2542                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2543                 if (STAT(AIR_FINISHED, this) < time)
2544                 {       // drown!
2545                         if (this.pain_finished < time)
2546                         {
2547                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2548                                 this.pain_finished = time + 0.5;
2549                         }
2550                 }
2551         }
2552 }
2553
2554 .bool move_qcphysics;
2555
2556 void Player_Physics(entity this)
2557 {
2558         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2559
2560         if(!this.move_qcphysics)
2561                 return;
2562
2563         if(!frametime && !CS(this).pm_frametime)
2564                 return;
2565
2566         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2567
2568         CS(this).pm_frametime = 0;
2569 }
2570
2571 /*
2572 =============
2573 PlayerPostThink
2574
2575 Called every frame for each client after the physics are run
2576 =============
2577 */
2578 void PlayerPostThink (entity this)
2579 {
2580         Player_Physics(this);
2581
2582         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2583         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2584         if (IS_REAL_CLIENT(this))
2585         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2586         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2587         {
2588                 int totalClients = 0;
2589                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2590                 {
2591                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2592                         if (server_is_dedicated)
2593                         {
2594                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2595                                 {
2596                                         ++totalClients;
2597                                 });
2598                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2599                                         totalClients = 0;
2600                         }
2601                 }
2602                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2603                 {
2604                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2605                         {
2606                                 ++totalClients;
2607                         });
2608                 }
2609
2610                 if (totalClients < autocvar_sv_maxidle_minplayers)
2611                 {
2612                         // idle kick disabled
2613                         CS(this).parm_idlesince = time;
2614                 }
2615                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2616                 {
2617                         if (CS(this).idlekick_lasttimeleft)
2618                         {
2619                                 CS(this).idlekick_lasttimeleft = 0;
2620                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2621                         }
2622                 }
2623                 else
2624                 {
2625                         float maxidle_time = autocvar_sv_maxidle;
2626                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2627                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2628                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2629                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2630                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2631                         {
2632                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2633                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2634                                 else
2635                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2636                         }
2637                         if (timeleft <= 0) {
2638                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2639                                 {
2640                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2641                                         PutObserverInServer(this, true, true);
2642                                 }
2643                                 else
2644                                 {
2645                                         if (dropclient_schedule(this))
2646                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2647                                 }
2648                                 return;
2649                         }
2650                         else if (timeleft <= countdown_time) {
2651                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2652                                         play2(this, SND(TALK2));
2653                                 CS(this).idlekick_lasttimeleft = timeleft;
2654                         }
2655                 }
2656         }
2657
2658         CheatFrame(this);
2659
2660         if (game_stopped)
2661         {
2662                 this.solid = SOLID_NOT;
2663                 this.takedamage = DAMAGE_NO;
2664                 set_movetype(this, MOVETYPE_NONE);
2665                 CS(this).teamkill_complain = 0;
2666                 CS(this).teamkill_soundtime = 0;
2667                 CS(this).teamkill_soundsource = NULL;
2668         }
2669
2670         if (IS_PLAYER(this)) {
2671                 if(this.death_time == time && IS_DEAD(this))
2672                 {
2673                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2674                         // once all the damage events of this frame have been processed with normal size
2675                         this.maxs.z = 5;
2676                         setsize(this, this.mins, this.maxs);
2677                 }
2678                 DrownPlayer(this);
2679                 UpdateChatBubble(this);
2680                 if (CS(this).impulse) ImpulseCommands(this);
2681                 GetPressedKeys(this);
2682                 if (game_stopped)
2683                 {
2684                         CSQCMODEL_AUTOUPDATE(this);
2685                         return;
2686                 }
2687         }
2688         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2689         {
2690                 CS(this).pressedkeys = 0;
2691                 STAT(PRESSED_KEYS, this) = 0;
2692         }
2693
2694         if (this.waypointsprite_attachedforcarrier) {
2695                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2696                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2697         }
2698
2699         CSQCMODEL_AUTOUPDATE(this);
2700 }
2701
2702 // hack to copy the button fields from the client entity to the Client State
2703 void PM_UpdateButtons(entity this, entity store)
2704 {
2705         if(this.impulse)
2706                 store.impulse = this.impulse;
2707         this.impulse = 0;
2708
2709         bool typing = this.buttonchat || this.button12;
2710
2711         store.button0 = (typing) ? 0 : this.button0;
2712         //button1?!
2713         store.button2 = (typing) ? 0 : this.button2;
2714         store.button3 = (typing) ? 0 : this.button3;
2715         store.button4 = this.button4;
2716         store.button5 = (typing) ? 0 : this.button5;
2717         store.button6 = this.button6;
2718         store.button7 = this.button7;
2719         store.button8 = this.button8;
2720         store.button9 = this.button9;
2721         store.button10 = this.button10;
2722         store.button11 = this.button11;
2723         store.button12 = this.button12;
2724         store.button13 = this.button13;
2725         store.button14 = this.button14;
2726         store.button15 = this.button15;
2727         store.button16 = this.button16;
2728         store.buttonuse = this.buttonuse;
2729         store.buttonchat = this.buttonchat;
2730
2731         store.cursor_active = this.cursor_active;
2732         store.cursor_screen = this.cursor_screen;
2733         store.cursor_trace_start = this.cursor_trace_start;
2734         store.cursor_trace_endpos = this.cursor_trace_endpos;
2735         store.cursor_trace_ent = this.cursor_trace_ent;
2736
2737         store.ping = this.ping;
2738         store.ping_packetloss = this.ping_packetloss;
2739         store.ping_movementloss = this.ping_movementloss;
2740
2741         store.v_angle = this.v_angle;
2742         store.movement = this.movement;
2743 }
2744
2745 NET_HANDLE(fpsreport, bool)
2746 {
2747         int fps = ReadShort();
2748         PlayerScore_Set(sender, SP_FPS, fps);
2749         return true;
2750 }