qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/weapons/_all.qh>
   4 #include <common/stats.qh>
   5 #include <server/chat.qh>
   6 #include <common/effects/all.qh>
   7 #include "anticheat.qh"
   8 #include "impulse.qh"
   9 #include "player.qh"
  10 #include "ipban.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "damage.qh"
  16 #include "handicap.qh"
  17 #include "hook.qh"
  18 #include <server/intermission.qh>
  19 #include "command/common.qh"
  20 #include "command/vote.qh"
  21 #include "clientkill.qh"
  22 #include "cheats.qh"
  23 #include "world.qh"
  24 #include <server/gamelog.qh>
  25 #include "race.qh"
  26 #include <server/main.qh>
  27 #include <server/mutators/_mod.qh>
  28 #include "antilag.qh"
  29 #include "campaign.qh"
  30 #include "command/common.qh"
  31 #include "scores_rules.qh"
  32 #include "weapons/common.qh"
  33
  34 #include "bot/api.qh"
  35
  36 #include <common/ent_cs.qh>
  37 #include <common/wepent.qh>
  38 #include <common/state.qh>
  39
  40 #include "compat/quake3.qh"
  41
  42 #include <common/effects/qc/globalsound.qh>
  43
  44 #include <common/mapobjects/func/conveyor.qh>
  45 #include <common/mapobjects/func/ladder.qh>
  46 #include <common/mapobjects/teleporters.qh>
  47 #include <common/mapobjects/target/spawnpoint.qh>
  48 #include <common/mapobjects/trigger/counter.qh>
  49 #include <common/mapobjects/trigger/swamp.qh>
  50
  51 #include <common/vehicles/all.qh>
  52
  53 #include "weapons/hitplot.qh"
  54 #include "weapons/selection.qh"
  55 #include "weapons/weaponsystem.qh"
  56
  57 #include <common/net_notice.qh>
  58 #include <common/net_linked.qh>
  59 #include <common/physics/player.qh>
  60
  61 #include <common/vehicles/sv_vehicles.qh>
  62
  63 #include <common/items/_mod.qh>
  64
  65 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  66
  67 #include <common/mutators/mutator/waypoints/all.qh>
  68 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  69 #include <common/gamemodes/_mod.qh>
  70
  71 #include <common/mapobjects/subs.qh>
  72 #include <common/mapobjects/triggers.qh>
  73 #include <common/mapobjects/trigger/secret.qh>
  74
  75 #include <common/minigames/sv_minigames.qh>
  76
  77 #include <common/items/inventory.qh>
  78
  79 #include <common/monsters/sv_monsters.qh>
  80
  81 #include <lib/warpzone/server.qh>
  82
  83 #include <common/mutators/mutator/overkill/oknex.qh>
  84
  85 #include <common/weapons/weapon/vortex.qh>
  86
  87 STATIC_METHOD(Client, Add, void(Client this, int _team))
  88 {
  89     ClientConnect(this);
  90     TRANSMUTE(Player, this);
  91     this.frame = 12; // 7
  92     this.team = _team;
  93     PutClientInServer(this);
  94 }
  95
  96 STATIC_METHOD(Client, Remove, void(Client this))
  97 {
  98     TRANSMUTE(Observer, this);
  99     PutClientInServer(this);
 100     ClientDisconnect(this);
 101 }
 102
 103 void send_CSQC_teamnagger() {
 104         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 105 }
 106
 107 int CountSpectators(entity player, entity to)
 108 {
 109         if(!player) { return 0; } // not sure how, but best to be safe
 110
 111         int spec_count = 0;
 112
 113         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 114         {
 115                 spec_count++;
 116         });
 117
 118         return spec_count;
 119 }
 120
 121 void WriteSpectators(entity player, entity to)
 122 {
 123         if(!player) { return; } // not sure how, but best to be safe
 124
 125         int spec_count = 0;
 126         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 127         {
 128                 if(spec_count >= MAX_SPECTATORS)
 129                         break;
 130                 WriteByte(MSG_ENTITY, num_for_edict(it));
 131                 ++spec_count;
 132         });
 133 }
 134
 135 bool ClientData_Send(entity this, entity to, int sf)
 136 {
 137         assert(to == this.owner, return false);
 138
 139         entity e = to;
 140         if (IS_SPEC(e)) e = e.enemy;
 141
 142         sf = 0;
 143         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 144         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 145         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 146         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 147
 148         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 149         WriteByte(MSG_ENTITY, sf);
 150
 151         if (sf & BIT(1))
 152                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 153
 154         if(sf & BIT(4))
 155         {
 156                 float specs = CountSpectators(e, to);
 157                 WriteByte(MSG_ENTITY, specs);
 158                 WriteSpectators(e, to);
 159         }
 160
 161         return true;
 162 }
 163
 164 void ClientData_Attach(entity this)
 165 {
 166         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 167         CS(this).clientdata.drawonlytoclient = this;
 168         CS(this).clientdata.owner = this;
 169 }
 170
 171 void ClientData_Detach(entity this)
 172 {
 173         delete(CS(this).clientdata);
 174         CS(this).clientdata = NULL;
 175 }
 176
 177 void ClientData_Touch(entity e)
 178 {
 179         entity cd = CS(e).clientdata;
 180         if (cd) { cd.SendFlags = 1; }
 181
 182         // make it spectatable
 183         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 184         {
 185                 entity cd = CS(it).clientdata;
 186                 if (cd) { cd.SendFlags = 1; }
 187         });
 188 }
 189
 190
 191 /*
 192 =============
 193 CheckPlayerModel
 194
 195 Checks if the argument string can be a valid playermodel.
 196 Returns a valid one in doubt.
 197 =============
 198 */
 199 string FallbackPlayerModel;
 200 string CheckPlayerModel(string plyermodel) {
 201         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 202         {
 203                 // note: we cannot summon Don Strunzone here, some player may
 204                 // still have the model string set. In case anyone manages how
 205                 // to change a cvar default, we'll have a small leak here.
 206                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 207         }
 208         // only in right path
 209         if( substring(plyermodel,0,14) != "models/player/")
 210                 return FallbackPlayerModel;
 211         // only good file extensions
 212         if(substring(plyermodel,-4,4) != ".zym")
 213         if(substring(plyermodel,-4,4) != ".dpm")
 214         if(substring(plyermodel,-4,4) != ".iqm")
 215         if(substring(plyermodel,-4,4) != ".md3")
 216         if(substring(plyermodel,-4,4) != ".psk")
 217                 return FallbackPlayerModel;
 218         // forbid the LOD models
 219         if(substring(plyermodel, -9,5) == "_lod1")
 220                 return FallbackPlayerModel;
 221         if(substring(plyermodel, -9,5) == "_lod2")
 222                 return FallbackPlayerModel;
 223         if(plyermodel != strtolower(plyermodel))
 224                 return FallbackPlayerModel;
 225         // also, restrict to server models
 226         if(autocvar_sv_servermodelsonly)
 227         {
 228                 if(!fexists(plyermodel))
 229                         return FallbackPlayerModel;
 230         }
 231         return plyermodel;
 232 }
 233
 234 void setplayermodel(entity e, string modelname)
 235 {
 236         precache_model(modelname);
 237         _setmodel(e, modelname);
 238         player_setupanimsformodel(e);
 239         if(!autocvar_g_debug_globalsounds)
 240                 UpdatePlayerSounds(e);
 241 }
 242
 243 /** putting a client as observer in the server */
 244 void PutObserverInServer(entity this)
 245 {
 246         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 247         PlayerState_detach(this);
 248
 249         if (IS_PLAYER(this))
 250         {
 251                 if(GetResource(this, RES_HEALTH) >= 1)
 252                 {
 253                         // despawn effect
 254                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 255                 }
 256
 257                 // was a player, recount votes and ready status
 258                 if(IS_REAL_CLIENT(this))
 259                 {
 260                         if (vote_called) { VoteCount(false); }
 261                         ReadyCount();
 262                 }
 263         }
 264
 265         entity spot = SelectSpawnPoint(this, true);
 266         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 267         this.angles = vec2(spot.angles);
 268         this.fixangle = true;
 269         // offset it so that the spectator spawns higher off the ground, looks better this way
 270         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 271         if (IS_REAL_CLIENT(this))
 272         {
 273                 msg_entity = this;
 274                 WriteByte(MSG_ONE, SVC_SETVIEW);
 275                 WriteEntity(MSG_ONE, this);
 276         }
 277         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 278         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 279         if(!autocvar_g_debug_globalsounds)
 280         {
 281                 // needed for player sounds
 282                 this.model = "";
 283                 FixPlayermodel(this);
 284         }
 285         setmodel(this, MDL_Null);
 286         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 287         this.view_ofs = '0 0 0';
 288
 289         RemoveGrapplingHooks(this);
 290         Portal_ClearAll(this);
 291         Unfreeze(this, false);
 292         SetSpectatee(this, NULL);
 293
 294         if (this.alivetime)
 295         {
 296                 if (!warmup_stage)
 297                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 298                 this.alivetime = 0;
 299         }
 300
 301         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 302
 303         WaypointSprite_PlayerDead(this);
 304
 305         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 306                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 307
 308         accuracy_resend(this);
 309
 310         CS(this).spectatortime = time;
 311         if(this.bot_attack)
 312                 IL_REMOVE(g_bot_targets, this);
 313         this.bot_attack = false;
 314         if(this.monster_attack)
 315                 IL_REMOVE(g_monster_targets, this);
 316         this.monster_attack = false;
 317         STAT(HUD, this) = HUD_NORMAL;
 318         TRANSMUTE(Observer, this);
 319         this.iscreature = false;
 320         this.teleportable = TELEPORT_SIMPLE;
 321         if(this.damagedbycontents)
 322                 IL_REMOVE(g_damagedbycontents, this);
 323         this.damagedbycontents = false;
 324         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 325         SetSpectatee_status(this, etof(this));
 326         this.takedamage = DAMAGE_NO;
 327         this.solid = SOLID_NOT;
 328         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 329         this.flags = FL_CLIENT | FL_NOTARGET;
 330         this.effects = 0;
 331         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_finished = 0;
 344         STAT(STRENGTH_FINISHED, this) = 0;
 345         STAT(INVINCIBLE_FINISHED, this) = 0;
 346         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 347         STAT(AIR_FINISHED, this) = 0;
 348         //this.dphitcontentsmask = 0;
 349         this.dphitcontentsmask = DPCONTENTS_SOLID;
 350         if (autocvar_g_playerclip_collisions)
 351                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 352         this.pushltime = 0;
 353         this.istypefrag = 0;
 354         setthink(this, func_null);
 355         this.nextthink = 0;
 356         this.deadflag = DEAD_NO;
 357         UNSET_DUCKED(this);
 358         STAT(REVIVE_PROGRESS, this) = 0;
 359         this.revival_time = 0;
 360         this.draggable = drag_undraggable;
 361
 362         this.items = 0;
 363         STAT(WEAPONS, this) = '0 0 0';
 364         this.drawonlytoclient = this;
 365
 366         this.viewloc = NULL;
 367
 368         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 369
 370         this.weaponmodel = "";
 371         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 372         {
 373                 this.weaponentities[slot] = NULL;
 374         }
 375         this.exteriorweaponentity = NULL;
 376         CS(this).killcount = FRAGS_SPECTATOR;
 377         this.velocity = '0 0 0';
 378         this.avelocity = '0 0 0';
 379         this.punchangle = '0 0 0';
 380         this.punchvector = '0 0 0';
 381         this.oldvelocity = this.velocity;
 382         this.fire_endtime = -1;
 383         this.event_damage = func_null;
 384         this.event_heal = func_null;
 385
 386         for(int slot = 0; slot < MAX_AXH; ++slot)
 387         {
 388                 entity axh = this.(AuxiliaryXhair[slot]);
 389                 this.(AuxiliaryXhair[slot]) = NULL;
 390
 391                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 392                         delete(axh);
 393         }
 394
 395         if (mutator_returnvalue)
 396         {
 397                 // mutator prevents resetting teams+score
 398         }
 399         else
 400         {
 401                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 402                 this.frags = FRAGS_SPECTATOR;
 403         }
 404         if (CS(this).just_joined)
 405                 CS(this).just_joined = false;
 406 }
 407
 408 int player_getspecies(entity this)
 409 {
 410         get_model_parameters(this.model, this.skin);
 411         int s = get_model_parameters_species;
 412         get_model_parameters(string_null, 0);
 413         if (s < 0) return SPECIES_HUMAN;
 414         return s;
 415 }
 416
 417 .float model_randomizer;
 418 void FixPlayermodel(entity player)
 419 {
 420         string defaultmodel = "";
 421         int defaultskin = 0;
 422         if(autocvar_sv_defaultcharacter)
 423         {
 424                 if(teamplay)
 425                 {
 426                         switch(player.team)
 427                         {
 428                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 429                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 430                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 431                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 432                         }
 433                 }
 434
 435                 if(defaultmodel == "")
 436                 {
 437                         defaultmodel = autocvar_sv_defaultplayermodel;
 438                         defaultskin = autocvar_sv_defaultplayerskin;
 439                 }
 440
 441                 int n = tokenize_console(defaultmodel);
 442                 if(n > 0)
 443                 {
 444                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 445                         // However, do NOT randomize if the player-selected model is in the list.
 446                         for (int i = 0; i < n; ++i)
 447                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 448                                         defaultmodel = argv(i);
 449                 }
 450
 451                 int i = strstrofs(defaultmodel, ":", 0);
 452                 if(i >= 0)
 453                 {
 454                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 455                         defaultmodel = substring(defaultmodel, 0, i);
 456                 }
 457         }
 458         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 459         {
 460                 if(teamplay)
 461                 {
 462                         switch(player.team)
 463                         {
 464                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 465                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 466                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 467                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 468                         }
 469                 }
 470
 471                 if(!defaultskin)
 472                         defaultskin = autocvar_sv_defaultplayerskin;
 473         }
 474
 475         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 476         defaultmodel = M_ARGV(0, string);
 477         defaultskin = M_ARGV(1, int);
 478
 479         bool chmdl = false;
 480         int oldskin;
 481         if(defaultmodel != "")
 482         {
 483                 if (defaultmodel != player.model)
 484                 {
 485                         vector m1 = player.mins;
 486                         vector m2 = player.maxs;
 487                         setplayermodel (player, defaultmodel);
 488                         setsize (player, m1, m2);
 489                         chmdl = true;
 490                 }
 491
 492                 oldskin = player.skin;
 493                 player.skin = defaultskin;
 494         } else {
 495                 if (player.playermodel != player.model || player.playermodel == "")
 496                 {
 497                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 498                         vector m1 = player.mins;
 499                         vector m2 = player.maxs;
 500                         setplayermodel (player, player.playermodel);
 501                         setsize (player, m1, m2);
 502                         chmdl = true;
 503                 }
 504
 505                 if(!autocvar_sv_defaultcharacterskin)
 506                 {
 507                         oldskin = player.skin;
 508                         player.skin = stof(player.playerskin);
 509                 }
 510                 else
 511                 {
 512                         oldskin = player.skin;
 513                         player.skin = defaultskin;
 514                 }
 515         }
 516
 517         if(chmdl || oldskin != player.skin) // model or skin has changed
 518         {
 519                 player.species = player_getspecies(player); // update species
 520                 if(!autocvar_g_debug_globalsounds)
 521                         UpdatePlayerSounds(player); // update skin sounds
 522         }
 523
 524         if(!teamplay)
 525                 if(strlen(autocvar_sv_defaultplayercolors))
 526                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 527                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 528 }
 529
 530 void PutPlayerInServer(entity this)
 531 {
 532         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 533
 534         PlayerState_attach(this);
 535         accuracy_resend(this);
 536
 537         if (this.team < 0)
 538                 TeamBalance_JoinBestTeam(this);
 539
 540         entity spot = SelectSpawnPoint(this, false);
 541         if (!spot) {
 542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 543                 return; // spawn failed
 544         }
 545
 546         TRANSMUTE(Player, this);
 547
 548         CS(this).wasplayer = true;
 549         this.iscreature = true;
 550         this.teleportable = TELEPORT_NORMAL;
 551         if(!this.damagedbycontents)
 552                 IL_PUSH(g_damagedbycontents, this);
 553         this.damagedbycontents = true;
 554         set_movetype(this, MOVETYPE_WALK);
 555         this.solid = SOLID_SLIDEBOX;
 556         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 557         if (autocvar_g_playerclip_collisions)
 558                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 559         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 560                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 561         this.frags = FRAGS_PLAYER;
 562         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 563         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 564         if (autocvar__notarget)
 565                 this.flags |= FL_NOTARGET;
 566         this.takedamage = DAMAGE_AIM;
 567         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 568
 569         if (warmup_stage) {
 570                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 571                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 572                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 573                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 574                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 575                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 576                 SetResource(this, RES_HEALTH, warmup_start_health);
 577                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 578                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 579         } else {
 580                 SetResource(this, RES_SHELLS, start_ammo_shells);
 581                 SetResource(this, RES_BULLETS, start_ammo_nails);
 582                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 583                 SetResource(this, RES_CELLS, start_ammo_cells);
 584                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 585                 SetResource(this, RES_FUEL, start_ammo_fuel);
 586                 SetResource(this, RES_HEALTH, start_health);
 587                 SetResource(this, RES_ARMOR, start_armorvalue);
 588                 STAT(WEAPONS, this) = start_weapons;
 589                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 590                 {
 591                         GiveRandomWeapons(this, random_start_weapons_count,
 592                                 autocvar_g_random_start_weapons, random_start_ammo);
 593                 }
 594         }
 595         SetSpectatee_status(this, 0);
 596
 597         PS(this).dual_weapons = '0 0 0';
 598
 599         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 600
 601         this.items = start_items;
 602
 603         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 604         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 605         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 606         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 607         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 608         if (!sv_ready_restart_after_countdown && time < game_starttime)
 609         {
 610                 float f = game_starttime - time;
 611                 this.spawnshieldtime += f;
 612                 this.pauserotarmor_finished += f;
 613                 this.pauserothealth_finished += f;
 614                 this.pauseregen_finished += f;
 615         }
 616
 617         this.damageforcescale = autocvar_g_player_damageforcescale;
 618         this.death_time = 0;
 619         this.respawn_flags = 0;
 620         this.respawn_time = 0;
 621         STAT(RESPAWN_TIME, this) = 0;
 622         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 623         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 624         this.fade_time = 0;
 625         this.pain_finished = 0;
 626         this.pushltime = 0;
 627         setthink(this, func_null); // players have no think function
 628         this.nextthink = 0;
 629         this.dmg_team = 0;
 630         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 631
 632         this.deadflag = DEAD_NO;
 633
 634         this.angles = spot.angles;
 635         this.angles_z = 0; // never spawn tilted even if the spot says to
 636         if (IS_BOT_CLIENT(this))
 637         {
 638                 this.v_angle = this.angles;
 639                 bot_aim_reset(this);
 640         }
 641         this.fixangle = true; // turn this way immediately
 642         this.oldvelocity = this.velocity = '0 0 0';
 643         this.avelocity = '0 0 0';
 644         this.punchangle = '0 0 0';
 645         this.punchvector = '0 0 0';
 646
 647         STAT(STRENGTH_FINISHED, this) = 0;
 648         STAT(INVINCIBLE_FINISHED, this) = 0;
 649         this.fire_endtime = -1;
 650         STAT(REVIVE_PROGRESS, this) = 0;
 651         this.revival_time = 0;
 652
 653         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 654         STAT(BUFFS, this) = 0;
 655         STAT(BUFF_TIME, this) = 0;
 656
 657         STAT(AIR_FINISHED, this) = 0;
 658         this.waterlevel = WATERLEVEL_NONE;
 659         this.watertype = CONTENT_EMPTY;
 660
 661         entity spawnevent = new_pure(spawnevent);
 662         spawnevent.owner = this;
 663         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 664
 665         // Cut off any still running player sounds.
 666         stopsound(this, CH_PLAYER_SINGLE);
 667
 668         this.model = "";
 669         FixPlayermodel(this);
 670         this.drawonlytoclient = NULL;
 671
 672         this.viewloc = NULL;
 673
 674         for(int slot = 0; slot < MAX_AXH; ++slot)
 675         {
 676                 entity axh = this.(AuxiliaryXhair[slot]);
 677                 this.(AuxiliaryXhair[slot]) = NULL;
 678
 679                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 680                         delete(axh);
 681         }
 682
 683         this.spawnpoint_targ = NULL;
 684
 685         UNSET_DUCKED(this);
 686         this.view_ofs = STAT(PL_VIEW_OFS, this);
 687         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 688         this.spawnorigin = spot.origin;
 689         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 690         // don't reset back to last position, even if new position is stuck in solid
 691         this.oldorigin = this.origin;
 692         if(this.conveyor)
 693                 IL_REMOVE(g_conveyed, this);
 694         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 695         if(this.swampslug)
 696                 IL_REMOVE(g_swamped, this);
 697         this.swampslug = NULL;
 698         this.swamp_interval = 0;
 699         if(this.ladder_entity)
 700                 IL_REMOVE(g_ladderents, this);
 701         this.ladder_entity = NULL;
 702         IL_EACH(g_counters, it.realowner == this,
 703         {
 704                 delete(it);
 705         });
 706         STAT(HUD, this) = HUD_NORMAL;
 707
 708         this.event_damage = PlayerDamage;
 709         this.event_heal = PlayerHeal;
 710
 711         this.draggable = func_null;
 712
 713         if(!this.bot_attack)
 714                 IL_PUSH(g_bot_targets, this);
 715         this.bot_attack = true;
 716         if(!this.monster_attack)
 717                 IL_PUSH(g_monster_targets, this);
 718         this.monster_attack = true;
 719         navigation_dynamicgoal_init(this, false);
 720
 721         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 722
 723         // player was spectator
 724         if (CS(this).killcount == FRAGS_SPECTATOR) {
 725                 PlayerScore_Clear(this);
 726                 CS(this).killcount = 0;
 727                 CS(this).startplaytime = time;
 728         }
 729
 730         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 731         {
 732                 .entity weaponentity = weaponentities[slot];
 733                 CL_SpawnWeaponentity(this, weaponentity);
 734         }
 735         this.alpha = default_player_alpha;
 736         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 737         this.exteriorweaponentity.alpha = default_weapon_alpha;
 738
 739         this.speedrunning = false;
 740
 741         this.counter_cnt = 0;
 742         this.fragsfilter_cnt = 0;
 743
 744         target_voicescript_clear(this);
 745
 746         // reset fields the weapons may use
 747         FOREACH(Weapons, true, {
 748                 it.wr_resetplayer(it, this);
 749                         // reload all reloadable weapons
 750                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 751                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 752                         {
 753                                 .entity weaponentity = weaponentities[slot];
 754                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 755                         }
 756                 }
 757         });
 758
 759         {
 760                 string s = spot.target;
 761                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 762                         spot.target = string_null;
 763                 SUB_UseTargets(spot, this, NULL);
 764                 if(g_assault || g_race)
 765                         spot.target = s;
 766         }
 767
 768         Unfreeze(this, false);
 769
 770         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 771
 772         if (autocvar_spawn_debug)
 773         {
 774                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 775                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 776         }
 777
 778         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 779         {
 780                 .entity weaponentity = weaponentities[slot];
 781                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 782                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 783                 else
 784                         this.(weaponentity).m_switchweapon = WEP_Null;
 785                 this.(weaponentity).m_weapon = WEP_Null;
 786                 this.(weaponentity).weaponname = "";
 787                 this.(weaponentity).m_switchingweapon = WEP_Null;
 788                 this.(weaponentity).cnt = -1;
 789         }
 790
 791         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 792
 793         if (CS(this).impulse) ImpulseCommands(this);
 794
 795         W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
 796         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 797         {
 798                 .entity weaponentity = weaponentities[slot];
 799                 W_WeaponFrame(this, weaponentity);
 800         }
 801
 802         if (!warmup_stage && !this.alivetime)
 803                 this.alivetime = time;
 804
 805         antilag_clear(this, CS(this));
 806 }
 807
 808 /** Called when a client spawns in the server */
 809 void PutClientInServer(entity this)
 810 {
 811         if (IS_BOT_CLIENT(this)) {
 812                 TRANSMUTE(Player, this);
 813         } else if (IS_REAL_CLIENT(this)) {
 814                 msg_entity = this;
 815                 WriteByte(MSG_ONE, SVC_SETVIEW);
 816                 WriteEntity(MSG_ONE, this);
 817         }
 818         if (game_stopped)
 819                 TRANSMUTE(Observer, this);
 820
 821         SetSpectatee(this, NULL);
 822
 823         // reset player keys
 824         if(PS(this))
 825                 PS(this).itemkeys = 0;
 826
 827         MUTATOR_CALLHOOK(PutClientInServer, this);
 828
 829         if (IS_OBSERVER(this)) {
 830                 PutObserverInServer(this);
 831         } else if (IS_PLAYER(this)) {
 832                 PutPlayerInServer(this);
 833         }
 834 }
 835
 836 // TODO do we need all these fields, or should we stop autodetecting runtime
 837 // changes and just have a console command to update this?
 838 bool ClientInit_SendEntity(entity this, entity to, int sf)
 839 {
 840         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 841         return = true;
 842         msg_entity = to;
 843         // MSG_INIT replacement
 844         // TODO: make easier to use
 845         Registry_send_all();
 846         W_PROP_reload(MSG_ONE, to);
 847         ClientInit_misc(this);
 848         MUTATOR_CALLHOOK(Ent_Init);
 849 }
 850 void ClientInit_misc(entity this)
 851 {
 852         int channel = MSG_ONE;
 853         WriteHeader(channel, ENT_CLIENT_INIT);
 854         WriteByte(channel, g_nexball_meter_period * 32);
 855         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 856         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 857         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 858         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 859         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 860         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 861         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 862         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 863
 864         if(autocvar_sv_foginterval && world.fog != "")
 865                 WriteString(channel, world.fog);
 866         else
 867                 WriteString(channel, "");
 868         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 869         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 870         WriteByte(channel, serverflags);
 871         WriteCoord(channel, autocvar_g_trueaim_minrange);
 872 }
 873
 874 void ClientInit_CheckUpdate(entity this)
 875 {
 876         this.nextthink = time;
 877         if(this.count != autocvar_g_balance_armor_blockpercent)
 878         {
 879                 this.count = autocvar_g_balance_armor_blockpercent;
 880                 this.SendFlags |= 1;
 881         }
 882         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 883         {
 884                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 885                 this.SendFlags |= 1;
 886         }
 887 }
 888
 889 void ClientInit_Spawn()
 890 {
 891         entity e = new_pure(clientinit);
 892         setthink(e, ClientInit_CheckUpdate);
 893         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 894
 895         ClientInit_CheckUpdate(e);
 896 }
 897
 898 /*
 899 =============
 900 SetNewParms
 901 =============
 902 */
 903 void SetNewParms ()
 904 {
 905         // initialize parms for a new player
 906         parm1 = -(86400 * 366);
 907
 908         MUTATOR_CALLHOOK(SetNewParms);
 909 }
 910
 911 /*
 912 =============
 913 SetChangeParms
 914 =============
 915 */
 916 void SetChangeParms (entity this)
 917 {
 918         // save parms for level change
 919         parm1 = CS(this).parm_idlesince - time;
 920
 921         MUTATOR_CALLHOOK(SetChangeParms);
 922 }
 923
 924 /*
 925 =============
 926 DecodeLevelParms
 927 =============
 928 */
 929 void DecodeLevelParms(entity this)
 930 {
 931         // load parms
 932         CS(this).parm_idlesince = parm1;
 933         if (CS(this).parm_idlesince == -(86400 * 366))
 934                 CS(this).parm_idlesince = time;
 935
 936         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 937         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 938
 939         MUTATOR_CALLHOOK(DecodeLevelParms);
 940 }
 941
 942 void FixClientCvars(entity e)
 943 {
 944         // send prediction settings to the client
 945         stuffcmd(e, "\nin_bindmap 0 0\n");
 946         if(autocvar_g_antilag == 3) // client side hitscan
 947                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 948         if(autocvar_sv_gentle)
 949                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 950
 951         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 952         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 953
 954         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 955
 956         MUTATOR_CALLHOOK(FixClientCvars, e);
 957 }
 958
 959 bool findinlist_abbrev(string tofind, string list)
 960 {
 961         if(list == "" || tofind == "")
 962                 return false; // empty list or search, just return
 963
 964         // this function allows abbreviated strings!
 965         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 966         {
 967                 return true;
 968         });
 969
 970         return false;
 971 }
 972
 973 bool PlayerInIPList(entity p, string iplist)
 974 {
 975         // some safety checks (never allow local?)
 976         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 977                 return false;
 978
 979         return findinlist_abbrev(p.netaddress, iplist);
 980 }
 981
 982 bool PlayerInIDList(entity p, string idlist)
 983 {
 984         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 985         if(!p.crypto_idfp)
 986                 return false;
 987
 988         return findinlist_abbrev(p.crypto_idfp, idlist);
 989 }
 990
 991 bool PlayerInList(entity player, string list)
 992 {
 993         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 994 }
 995
 996 #ifdef DP_EXT_PRECONNECT
 997 /*
 998 =============
 999 ClientPreConnect
1000
1001 Called once (not at each match start) when a client begins a connection to the server
1002 =============
1003 */
1004 void ClientPreConnect(entity this)
1005 {
1006         if(autocvar_sv_eventlog)
1007         {
1008                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1009                         this.playerid,
1010                         etof(this),
1011                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1012                 ));
1013         }
1014 }
1015 #endif
1016
1017 string GetClientVersionMessage(entity this)
1018 {
1019         if (CS(this).version_mismatch) {
1020                 if(CS(this).version < autocvar_gameversion) {
1021                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1022                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1023                 } else {
1024                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1025                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1026                 }
1027         } else {
1028                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1029         }
1030 }
1031
1032 string getwelcomemessage(entity this)
1033 {
1034         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1035         string modifications = M_ARGV(0, string);
1036
1037         if(g_weaponarena)
1038         {
1039                 if(g_weaponarena_random)
1040                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1041                 else
1042                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1043         }
1044         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1045                 modifications = strcat(modifications, ", No start weapons");
1046         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1047                 modifications = strcat(modifications, ", Low gravity");
1048         if(g_weapon_stay && !g_cts)
1049                 modifications = strcat(modifications, ", Weapons stay");
1050         if(autocvar_g_jetpack)
1051                 modifications = strcat(modifications, ", Jet pack");
1052         if(autocvar_g_powerups == 0)
1053                 modifications = strcat(modifications, ", No powerups");
1054         if(autocvar_g_powerups > 0)
1055                 modifications = strcat(modifications, ", Powerups");
1056         modifications = substring(modifications, 2, strlen(modifications) - 2);
1057
1058         string versionmessage = GetClientVersionMessage(this);
1059         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1060
1061         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1062
1063         if(modifications != "")
1064                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1065
1066         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1067         {
1068                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1069                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1070         }
1071
1072         if (cache_mutatormsg != "") {
1073                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1074         }
1075
1076         string mutator_msg = "";
1077         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1078         mutator_msg = M_ARGV(0, string);
1079
1080         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1081
1082         string motd = autocvar_sv_motd;
1083         if (motd != "") {
1084                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1085         }
1086         return s;
1087 }
1088
1089 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1090
1091 /**
1092 =============
1093 ClientConnect
1094
1095 Called when a client connects to the server
1096 =============
1097 */
1098 void ClientConnect(entity this)
1099 {
1100         if (Ban_MaybeEnforceBanOnce(this)) return;
1101         assert(!IS_CLIENT(this), return);
1102         this.flags |= FL_CLIENT;
1103         assert(player_count >= 0, player_count = 0);
1104
1105         TRANSMUTE(Client, this);
1106         CS(this).version_nagtime = time + 10 + random() * 10;
1107
1108         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1109
1110         bot_clientconnect(this);
1111
1112         Player_DetermineForcedTeam(this);
1113
1114         TRANSMUTE(Observer, this);
1115
1116         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1117
1118         // always track bots, don't ask for cl_allow_uidtracking
1119         if (IS_BOT_CLIENT(this))
1120                 PlayerStats_GameReport_AddPlayer(this);
1121         else
1122                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1123
1124         if (autocvar_sv_eventlog)
1125                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1126
1127         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1128
1129         stuffcmd(this, clientstuff, "\n");
1130         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1131
1132         FixClientCvars(this);
1133
1134         // get version info from player
1135         stuffcmd(this, "cmd clientversion $gameversion\n");
1136
1137         // notify about available teams
1138         if (teamplay)
1139         {
1140                 entity balance = TeamBalance_CheckAllowedTeams(this);
1141                 int t = TeamBalance_GetAllowedTeams(balance);
1142                 TeamBalance_Destroy(balance);
1143                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1144         }
1145         else
1146         {
1147                 stuffcmd(this, "set _teams_available 0\n");
1148         }
1149
1150         bot_relinkplayerlist();
1151
1152         CS(this).spectatortime = time;
1153         if (blockSpectators)
1154         {
1155                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1156         }
1157
1158         CS(this).jointime = time;
1159
1160         if (IS_REAL_CLIENT(this))
1161         {
1162                 if (g_weaponarena_weapons == WEPSET(TUBA))
1163                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1164         }
1165
1166         if (!autocvar_sv_foginterval && world.fog != "")
1167                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1168
1169         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1170                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1171                         send_CSQC_teamnagger();
1172
1173         CSQCMODEL_AUTOINIT(this);
1174
1175         CS(this).model_randomizer = random();
1176
1177         if (IS_REAL_CLIENT(this))
1178                 sv_notice_join(this);
1179
1180         this.move_qcphysics = autocvar_sv_qcphysics;
1181
1182         // update physics stats (players can spawn before physics runs)
1183         Physics_UpdateStats(this);
1184
1185         IL_EACH(g_initforplayer, it.init_for_player, {
1186                 it.init_for_player(it, this);
1187         });
1188
1189         Handicap_Initialize(this);
1190
1191         MUTATOR_CALLHOOK(ClientConnect, this);
1192
1193         if (IS_REAL_CLIENT(this))
1194         {
1195                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1196                 {
1197                         CS(this).motd_actived_time = -1;
1198                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1199                 }
1200         }
1201 }
1202 /*
1203 =============
1204 ClientDisconnect
1205
1206 Called when a client disconnects from the server
1207 =============
1208 */
1209 .entity chatbubbleentity;
1210 void ClientDisconnect(entity this)
1211 {
1212         assert(IS_CLIENT(this), return);
1213
1214         PlayerStats_GameReport_FinalizePlayer(this);
1215         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1216         if (CS(this).active_minigame) part_minigame(this);
1217         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1218
1219         if (autocvar_sv_eventlog)
1220                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1221
1222         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1223
1224         if(IS_SPEC(this))
1225                 SetSpectatee(this, NULL);
1226
1227         MUTATOR_CALLHOOK(ClientDisconnect, this);
1228
1229         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1230         strfree(CS(this).weaponorder_byimpulse);
1231         ClientState_detach(this);
1232
1233         Portal_ClearAll(this);
1234
1235         Unfreeze(this, false);
1236
1237         RemoveGrapplingHooks(this);
1238
1239         // Here, everything has been done that requires this player to be a client.
1240
1241         this.flags &= ~FL_CLIENT;
1242
1243         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1244         if (this.killindicator) delete(this.killindicator);
1245
1246         IL_EACH(g_counters, it.realowner == this,
1247         {
1248                 delete(it);
1249         });
1250
1251         WaypointSprite_PlayerGone(this);
1252
1253         bot_relinkplayerlist();
1254
1255         strfree(this.clientstatus);
1256         if (this.personal) delete(this.personal);
1257
1258         this.playerid = 0;
1259         ReadyCount();
1260         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1261
1262         ONREMOVE(this);
1263 }
1264
1265 void ChatBubbleThink(entity this)
1266 {
1267         this.nextthink = time;
1268         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1269         {
1270                 if(this.owner) // but why can that ever be NULL?
1271                         this.owner.chatbubbleentity = NULL;
1272                 delete(this);
1273                 return;
1274         }
1275
1276         this.mdl = "";
1277
1278         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1279         {
1280                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1281                         this.mdl = "models/sprites/minigame_busy.iqm";
1282                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1283                         this.mdl = "models/misc/chatbubble.spr";
1284         }
1285
1286         if ( this.model != this.mdl )
1287                 _setmodel(this, this.mdl);
1288
1289 }
1290
1291 void UpdateChatBubble(entity this)
1292 {
1293         if (this.alpha < 0)
1294                 return;
1295         // spawn a chatbubble entity if needed
1296         if (!this.chatbubbleentity)
1297         {
1298                 this.chatbubbleentity = new(chatbubbleentity);
1299                 this.chatbubbleentity.owner = this;
1300                 this.chatbubbleentity.exteriormodeltoclient = this;
1301                 setthink(this.chatbubbleentity, ChatBubbleThink);
1302                 this.chatbubbleentity.nextthink = time;
1303                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1304                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1305                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1306                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1307                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1308                 //this.chatbubbleentity.model = "";
1309                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1310         }
1311 }
1312
1313 void calculate_player_respawn_time(entity this)
1314 {
1315         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1316                 return;
1317
1318         float gametype_setting_tmp;
1319         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1320         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1321         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1322         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1323         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1324         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1325
1326         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1327         if (teamplay)
1328         {
1329                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1330                         if(it.team == this.team)
1331                                 ++pcount;
1332                 });
1333                 if (sdelay_small_count == 0)
1334                         sdelay_small_count = 1;
1335                 if (sdelay_large_count == 0)
1336                         sdelay_large_count = 1;
1337         }
1338         else
1339         {
1340                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1341                         ++pcount;
1342                 });
1343                 if (sdelay_small_count == 0)
1344                 {
1345                         if (IS_INDEPENDENT_PLAYER(this))
1346                         {
1347                                 // Players play independently. No point in requiring enemies.
1348                                 sdelay_small_count = 1;
1349                         }
1350                         else
1351                         {
1352                                 // Players play AGAINST each other. Enemies required.
1353                                 sdelay_small_count = 2;
1354                         }
1355                 }
1356                 if (sdelay_large_count == 0)
1357                 {
1358                         if (IS_INDEPENDENT_PLAYER(this))
1359                         {
1360                                 // Players play independently. No point in requiring enemies.
1361                                 sdelay_large_count = 1;
1362                         }
1363                         else
1364                         {
1365                                 // Players play AGAINST each other. Enemies required.
1366                                 sdelay_large_count = 2;
1367                         }
1368                 }
1369         }
1370
1371         float sdelay;
1372
1373         if (pcount <= sdelay_small_count)
1374                 sdelay = sdelay_small;
1375         else if (pcount >= sdelay_large_count)
1376                 sdelay = sdelay_large;
1377         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1378                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1379
1380         if(waves)
1381                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1382         else
1383                 this.respawn_time = time + sdelay;
1384
1385         if(sdelay < sdelay_max)
1386                 this.respawn_time_max = time + sdelay_max;
1387         else
1388                 this.respawn_time_max = this.respawn_time;
1389
1390         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1391                 this.respawn_countdown = 10; // first number to count down from is 10
1392         else
1393                 this.respawn_countdown = -1; // do not count down
1394
1395         if(autocvar_g_forced_respawn)
1396                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1397 }
1398
1399 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1400 // added to the model skins
1401 /*void UpdateColorModHack()
1402 {
1403         float c;
1404         c = this.clientcolors & 15;
1405         // LordHavoc: only bothering to support white, green, red, yellow, blue
1406              if (!teamplay) this.colormod = '0 0 0';
1407         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1408         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1409         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1410         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1411         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1412         else this.colormod = '1 1 1';
1413 }*/
1414
1415 void respawn(entity this)
1416 {
1417         bool damagedbycontents_prev = this.damagedbycontents;
1418         if(this.alpha >= 0)
1419         {
1420                 if(autocvar_g_respawn_ghosts)
1421                 {
1422                         this.solid = SOLID_NOT;
1423                         this.takedamage = DAMAGE_NO;
1424                         this.damagedbycontents = false;
1425                         set_movetype(this, MOVETYPE_FLY);
1426                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1427                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1428                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1429                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1430                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1431                         if(autocvar_g_respawn_ghosts_time > 0)
1432                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1433                 }
1434                 else
1435                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1436         }
1437
1438         CopyBody(this, 1);
1439         this.damagedbycontents = damagedbycontents_prev;
1440
1441         this.effects |= EF_NODRAW; // prevent another CopyBody
1442         PutClientInServer(this);
1443 }
1444
1445 void play_countdown(entity this, float finished, Sound samp)
1446 {
1447         TC(Sound, samp);
1448         if(IS_REAL_CLIENT(this))
1449                 if(floor(finished - time - frametime) != floor(finished - time))
1450                         if(finished - time < 6)
1451                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1452 }
1453
1454 void player_powerups(entity this)
1455 {
1456         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1457                 this.modelflags |= MF_ROCKET;
1458         else
1459                 this.modelflags &= ~MF_ROCKET;
1460
1461         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1462
1463         if (IS_DEAD(this))
1464         {
1465                 if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1466                 {
1467                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1468                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1469                         this.items &= ~ITEM_Strength.m_itemid;
1470                         this.items &= ~ITEM_Shield.m_itemid;
1471                         this.items -= (this.items & IT_SUPERWEAPON);
1472                 }
1473         }
1474
1475         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1476                 return;
1477
1478         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1479         int items_prev = this.items;
1480
1481         Fire_ApplyDamage(this);
1482         Fire_ApplyEffect(this);
1483
1484         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1485         {
1486                 if (this.items & ITEM_Strength.m_itemid)
1487                 {
1488                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1489                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1490                         if (time > STAT(STRENGTH_FINISHED, this))
1491                         {
1492                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1493                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1494                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1495                         }
1496                 }
1497                 else
1498                 {
1499                         if (time < STAT(STRENGTH_FINISHED, this))
1500                         {
1501                                 this.items = this.items | ITEM_Strength.m_itemid;
1502                                 if(!g_cts)
1503                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1504                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1505                         }
1506                 }
1507                 if (this.items & ITEM_Shield.m_itemid)
1508                 {
1509                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1510                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1511                         if (time > STAT(INVINCIBLE_FINISHED, this))
1512                         {
1513                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1514                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1515                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1516                         }
1517                 }
1518                 else
1519                 {
1520                         if (time < STAT(INVINCIBLE_FINISHED, this))
1521                         {
1522                                 this.items = this.items | ITEM_Shield.m_itemid;
1523                                 if(!g_cts)
1524                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1525                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1526                         }
1527                 }
1528                 if (this.items & IT_SUPERWEAPON)
1529                 {
1530                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1531                         {
1532                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1533                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1534                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1535                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1536                         }
1537                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1538                         {
1539                                 // don't let them run out
1540                         }
1541                         else
1542                         {
1543                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1544                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1545                                 {
1546                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1547                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1548                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1549                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1550                                 }
1551                         }
1552                 }
1553                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1554                 {
1555                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1556                         {
1557                                 this.items = this.items | IT_SUPERWEAPON;
1558                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1559                                 {
1560                                         if(!g_cts)
1561                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1562                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1563                                 }
1564                         }
1565                         else
1566                         {
1567                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1568                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1569                         }
1570                 }
1571                 else
1572                 {
1573                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1574                 }
1575         }
1576
1577         if(autocvar_g_nodepthtestplayers)
1578                 this.effects = this.effects | EF_NODEPTHTEST;
1579
1580         if(autocvar_g_fullbrightplayers)
1581                 this.effects = this.effects | EF_FULLBRIGHT;
1582
1583         if (time >= game_starttime)
1584         if (time < this.spawnshieldtime)
1585                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1586
1587         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1588 }
1589
1590 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1591 {
1592         if(current > stable)
1593                 return current;
1594         else if(current > stable - 0.25) // when close enough, "snap"
1595                 return stable;
1596         else
1597                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1598 }
1599
1600 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1601 {
1602         if(current < stable)
1603                 return current;
1604         else if(current < stable + 0.25) // when close enough, "snap"
1605                 return stable;
1606         else
1607                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1608 }
1609
1610 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1611 {
1612         float old = GetResource(this, res);
1613         float current = old;
1614         if(current > rotstable)
1615         {
1616                 if(rotframetime > 0)
1617                 {
1618                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1619                         current = max(rotstable, current - rotlinear * rotframetime);
1620                 }
1621         }
1622         else if(current < regenstable)
1623         {
1624                 if(regenframetime > 0)
1625                 {
1626                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1627                         current = min(regenstable, current + regenlinear * regenframetime);
1628                 }
1629         }
1630
1631         float limit = GetResourceLimit(this, res) * limit_mod;
1632         if(current > limit)
1633                 current = limit;
1634
1635         if (current != old)
1636                 SetResource(this, res, current);
1637 }
1638
1639 void player_regen(entity this)
1640 {
1641         float max_mod, regen_mod, rot_mod, limit_mod;
1642         max_mod = regen_mod = rot_mod = limit_mod = 1;
1643
1644         float regen_health = autocvar_g_balance_health_regen;
1645         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1646         float regen_health_rot = autocvar_g_balance_health_rot;
1647         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1648         float regen_health_stable = autocvar_g_balance_health_regenstable;
1649         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1650         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1651                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1652         max_mod = M_ARGV(1, float);
1653         regen_mod = M_ARGV(2, float);
1654         rot_mod = M_ARGV(3, float);
1655         limit_mod = M_ARGV(4, float);
1656         regen_health = M_ARGV(5, float);
1657         regen_health_linear = M_ARGV(6, float);
1658         regen_health_rot = M_ARGV(7, float);
1659         regen_health_rotlinear = M_ARGV(8, float);
1660         regen_health_stable = M_ARGV(9, float);
1661         regen_health_rotstable = M_ARGV(10, float);
1662
1663         if(!mutator_returnvalue)
1664         if(!STAT(FROZEN, this))
1665         {
1666                 float maxa = autocvar_g_balance_armor_rotstable;
1667                 float mina = autocvar_g_balance_armor_regenstable;
1668
1669                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1670                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1671                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1672
1673                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1674                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1675                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1676         }
1677
1678         // if player rotted to death...  die!
1679         // check this outside above checks, as player may still be able to rot to death
1680         if(GetResource(this, RES_HEALTH) < 1)
1681         {
1682                 if(this.vehicle)
1683                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1684                 if(this.event_damage)
1685                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1686         }
1687
1688         if (!(this.items & IT_UNLIMITED_AMMO))
1689         {
1690                 float maxf = autocvar_g_balance_fuel_rotstable;
1691                 float minf = autocvar_g_balance_fuel_regenstable;
1692
1693                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1694                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1695                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1696         }
1697 }
1698
1699 bool zoomstate_set;
1700 void SetZoomState(entity this, float newzoom)
1701 {
1702         if(newzoom != CS(this).zoomstate)
1703         {
1704                 CS(this).zoomstate = newzoom;
1705                 ClientData_Touch(this);
1706         }
1707         zoomstate_set = true;
1708 }
1709
1710 void GetPressedKeys(entity this)
1711 {
1712         MUTATOR_CALLHOOK(GetPressedKeys, this);
1713         int keys = STAT(PRESSED_KEYS, this);
1714         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1715         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1716         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1717         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1718
1719         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1720         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1721         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1722         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1723         CS(this).pressedkeys = keys; // store for other users
1724
1725         STAT(PRESSED_KEYS, this) = keys;
1726 }
1727
1728 /*
1729 ======================
1730 spectate mode routines
1731 ======================
1732 */
1733
1734 void SpectateCopy(entity this, entity spectatee)
1735 {
1736         TC(Client, this); TC(Client, spectatee);
1737
1738         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1739         PS(this) = PS(spectatee);
1740         this.armortype = spectatee.armortype;
1741         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1742         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1743         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1744         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1745         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1746         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1747         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1748         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1749         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1750         CS(this).impulse = 0;
1751         this.disableclientprediction = 1; // no need to run prediction on a spectator
1752         this.items = spectatee.items;
1753         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1754         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1755         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1756         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1757         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1758         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1759         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1760         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1761         this.punchangle = spectatee.punchangle;
1762         this.view_ofs = spectatee.view_ofs;
1763         this.velocity = spectatee.velocity;
1764         this.dmg_take = spectatee.dmg_take;
1765         this.dmg_save = spectatee.dmg_save;
1766         this.dmg_inflictor = spectatee.dmg_inflictor;
1767         this.v_angle = spectatee.v_angle;
1768         this.angles = spectatee.v_angle;
1769         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1770         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1771         this.viewloc = spectatee.viewloc;
1772         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1773                 this.fixangle = true;
1774         setorigin(this, spectatee.origin);
1775         setsize(this, spectatee.mins, spectatee.maxs);
1776         SetZoomState(this, CS(spectatee).zoomstate);
1777
1778     anticheat_spectatecopy(this, spectatee);
1779         STAT(HUD, this) = STAT(HUD, spectatee);
1780         if(spectatee.vehicle)
1781     {
1782         this.angles = spectatee.v_angle;
1783
1784         //this.fixangle = false;
1785         //this.velocity = spectatee.vehicle.velocity;
1786         this.vehicle_health = spectatee.vehicle_health;
1787         this.vehicle_shield = spectatee.vehicle_shield;
1788         this.vehicle_energy = spectatee.vehicle_energy;
1789         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1790         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1791         this.vehicle_reload1 = spectatee.vehicle_reload1;
1792         this.vehicle_reload2 = spectatee.vehicle_reload2;
1793
1794         //msg_entity = this;
1795
1796        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1797             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1798            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1799            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1800
1801         //WriteByte (MSG_ONE, SVC_SETVIEW);
1802         //    WriteEntity(MSG_ONE, this);
1803         //makevectors(spectatee.v_angle);
1804         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1805     }
1806 }
1807
1808 bool SpectateUpdate(entity this)
1809 {
1810         if(!this.enemy)
1811                 return false;
1812
1813         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1814         {
1815                 SetSpectatee(this, NULL);
1816                 return false;
1817         }
1818
1819         SpectateCopy(this, this.enemy);
1820
1821         return true;
1822 }
1823
1824 bool SpectateSet(entity this)
1825 {
1826         if(!IS_PLAYER(this.enemy))
1827                 return false;
1828
1829         ClientData_Touch(this.enemy);
1830
1831         msg_entity = this;
1832         WriteByte(MSG_ONE, SVC_SETVIEW);
1833         WriteEntity(MSG_ONE, this.enemy);
1834         set_movetype(this, MOVETYPE_NONE);
1835         accuracy_resend(this);
1836
1837         if(!SpectateUpdate(this))
1838                 PutObserverInServer(this);
1839
1840         return true;
1841 }
1842
1843 void SetSpectatee_status(entity this, int spectatee_num)
1844 {
1845         int oldspectatee_status = CS(this).spectatee_status;
1846         CS(this).spectatee_status = spectatee_num;
1847
1848         if (CS(this).spectatee_status != oldspectatee_status)
1849         {
1850                 if (STAT(PRESSED_KEYS, this))
1851                 {
1852                         CS(this).pressedkeys = 0;
1853                         STAT(PRESSED_KEYS, this) = 0;
1854                 }
1855                 ClientData_Touch(this);
1856                 if (g_race || g_cts) race_InitSpectator();
1857         }
1858 }
1859
1860 void SetSpectatee(entity this, entity spectatee)
1861 {
1862         if(IS_BOT_CLIENT(this))
1863                 return; // bots abuse .enemy, this code is useless to them
1864
1865         entity old_spectatee = this.enemy;
1866
1867         this.enemy = spectatee;
1868
1869         // WEAPONTODO
1870         // these are required to fix the spectator bug with arc
1871         if(old_spectatee)
1872         {
1873                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1874                 {
1875                         .entity weaponentity = weaponentities[slot];
1876                         if(old_spectatee.(weaponentity).arc_beam)
1877                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1878                 }
1879         }
1880         if(this.enemy)
1881         {
1882                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1883                 {
1884                         .entity weaponentity = weaponentities[slot];
1885                         if(this.enemy.(weaponentity).arc_beam)
1886                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1887                 }
1888         }
1889
1890         if (this.enemy)
1891                 SetSpectatee_status(this, etof(this.enemy));
1892
1893         // needed to update spectator list
1894         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1895 }
1896
1897 bool Spectate(entity this, entity pl)
1898 {
1899         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1900                 return false;
1901         pl = M_ARGV(1, entity);
1902
1903         SetSpectatee(this, pl);
1904         return SpectateSet(this);
1905 }
1906
1907 bool SpectateNext(entity this)
1908 {
1909         entity ent = find(this.enemy, classname, STR_PLAYER);
1910
1911         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1912                 ent = M_ARGV(1, entity);
1913         else if (!ent)
1914                 ent = find(ent, classname, STR_PLAYER);
1915
1916         if(ent) { SetSpectatee(this, ent); }
1917
1918         return SpectateSet(this);
1919 }
1920
1921 bool SpectatePrev(entity this)
1922 {
1923         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1924         entity ent = findchain(classname, STR_PLAYER);
1925         if (!ent) // no player
1926                 return false;
1927
1928         entity first = ent;
1929         // skip players until current spectated player
1930         if(this.enemy)
1931         while(ent && ent != this.enemy)
1932                 ent = ent.chain;
1933
1934         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1935         {
1936                 case MUT_SPECPREV_FOUND:
1937                         ent = M_ARGV(1, entity);
1938                         break;
1939                 case MUT_SPECPREV_RETURN:
1940                         return true;
1941                 case MUT_SPECPREV_CONTINUE:
1942                 default:
1943                 {
1944                         if(ent.chain)
1945                                 ent = ent.chain;
1946                         else
1947                                 ent = first;
1948                         break;
1949                 }
1950         }
1951
1952         SetSpectatee(this, ent);
1953         return SpectateSet(this);
1954 }
1955
1956 /*
1957 =============
1958 ShowRespawnCountdown()
1959
1960 Update a respawn countdown display.
1961 =============
1962 */
1963 void ShowRespawnCountdown(entity this)
1964 {
1965         float number;
1966         if(!IS_DEAD(this)) // just respawned?
1967                 return;
1968         else
1969         {
1970                 number = ceil(this.respawn_time - time);
1971                 if(number <= 0)
1972                         return;
1973                 if(number <= this.respawn_countdown)
1974                 {
1975                         this.respawn_countdown = number - 1;
1976                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1977                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1978                 }
1979         }
1980 }
1981
1982 .bool team_selected;
1983 bool ShowTeamSelection(entity this)
1984 {
1985         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1986                 return false;
1987         stuffcmd(this, "menu_showteamselect\n");
1988         return true;
1989 }
1990 void Join(entity this)
1991 {
1992         TRANSMUTE(Player, this);
1993
1994         if(!this.team_selected)
1995         if(autocvar_g_campaign || autocvar_g_balance_teams)
1996                 TeamBalance_JoinBestTeam(this);
1997
1998         if(autocvar_g_campaign)
1999                 campaign_bots_may_start = true;
2000
2001         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2002
2003         PutClientInServer(this);
2004
2005         if(IS_PLAYER(this))
2006         if(teamplay && this.team != -1)
2007         {
2008         }
2009         else
2010                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2011         this.team_selected = false;
2012 }
2013
2014 int GetPlayerLimit()
2015 {
2016         if(g_duel)
2017                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2018         int player_limit = autocvar_g_maxplayers;
2019         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2020         player_limit = M_ARGV(0, int);
2021         return player_limit;
2022 }
2023
2024 /**
2025  * Determines whether the player is allowed to join. This depends on cvar
2026  * g_maxplayers, if it isn't used this function always return true, otherwise
2027  * it checks whether the number of currently playing players exceeds g_maxplayers.
2028  * @return int number of free slots for players, 0 if none
2029  */
2030 int nJoinAllowed(entity this, entity ignore)
2031 {
2032         if(!ignore)
2033         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2034         // so report 0 free slots if restricted
2035         {
2036                 if(autocvar_g_forced_team_otherwise == "spectate")
2037                         return 0;
2038                 if(autocvar_g_forced_team_otherwise == "spectator")
2039                         return 0;
2040         }
2041
2042         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2043                 return 0; // forced spectators can never join
2044
2045         // TODO simplify this
2046         int totalClients = 0;
2047         int currentlyPlaying = 0;
2048         FOREACH_CLIENT(true, {
2049                 if(it != ignore)
2050                         ++totalClients;
2051                 if(IS_REAL_CLIENT(it))
2052                 if(IS_PLAYER(it) || it.caplayer)
2053                         ++currentlyPlaying;
2054         });
2055
2056         int player_limit = GetPlayerLimit();
2057
2058         int free_slots = 0;
2059         if (!player_limit)
2060                 free_slots = maxclients - totalClients;
2061         else if(player_limit > 0 && currentlyPlaying < player_limit)
2062                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2063
2064         static float msg_time = 0;
2065         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2066         {
2067                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2068                 msg_time = time + 0.5;
2069         }
2070
2071         return free_slots;
2072 }
2073
2074 /**
2075  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2076  * g_maxplayers_spectator_blocktime seconds
2077  */
2078 void checkSpectatorBlock(entity this)
2079 {
2080         if(IS_SPEC(this) || IS_OBSERVER(this))
2081         if(!this.caplayer)
2082         if(IS_REAL_CLIENT(this))
2083         {
2084                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2085                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2086                         dropclient(this);
2087                 }
2088         }
2089 }
2090
2091 void PrintWelcomeMessage(entity this)
2092 {
2093         if(CS(this).motd_actived_time == 0)
2094         {
2095                 if (autocvar_g_campaign) {
2096                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2097                                 CS(this).motd_actived_time = time;
2098                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2099                         }
2100                 } else {
2101                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2102                                 CS(this).motd_actived_time = time;
2103                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2104                         }
2105                 }
2106         }
2107         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2108         {
2109                 if (autocvar_g_campaign) {
2110                         if (PHYS_INPUT_BUTTON_INFO(this))
2111                                 CS(this).motd_actived_time = time;
2112                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2113                                 CS(this).motd_actived_time = 0;
2114                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2115                         }
2116                 } else {
2117                         if (PHYS_INPUT_BUTTON_INFO(this))
2118                                 CS(this).motd_actived_time = time;
2119                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2120                                 CS(this).motd_actived_time = 0;
2121                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2122                         }
2123                 }
2124         }
2125         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2126         {
2127                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2128                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2129                 else if (CS(this).motd_actived_time == -2)
2130                 {
2131                         // instantly hide MOTD
2132                         CS(this).motd_actived_time = 0;
2133                         if (autocvar_g_campaign)
2134                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2135                         else
2136                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2137                 }
2138                 else if (IS_PLAYER(this) || IS_SPEC(this))
2139                 {
2140                         // FIXME occasionally for some reason MOTD never goes away
2141                         // delay MOTD removal a little bit in the hope it fixes this bug
2142                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2143                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2144                         else //if (CS(this).motd_actived_time < -2)
2145                                 CS(this).motd_actived_time++;
2146                 }
2147         }
2148 }
2149
2150 bool joinAllowed(entity this)
2151 {
2152         if (CS(this).version_mismatch) return false;
2153         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2154         if (!nJoinAllowed(this, this)) return false;
2155         if (teamplay && lockteams) return false;
2156         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2157         if (ShowTeamSelection(this)) return false;
2158         return true;
2159 }
2160
2161 .string shootfromfixedorigin;
2162 .bool dualwielding_prev;
2163 bool PlayerThink(entity this)
2164 {
2165         if (game_stopped || intermission_running) {
2166                 this.modelflags &= ~MF_ROCKET;
2167                 if(intermission_running)
2168                         IntermissionThink(this);
2169                 return false;
2170         }
2171
2172         if (timeout_status == TIMEOUT_ACTIVE) {
2173                 // don't allow the player to turn around while game is paused
2174                 // FIXME turn this into CSQC stuff
2175                 this.v_angle = this.lastV_angle;
2176                 this.angles = this.lastV_angle;
2177                 this.fixangle = true;
2178         }
2179
2180         if (frametime) player_powerups(this);
2181
2182         if (IS_DEAD(this)) {
2183                 if (this.personal && g_race_qualifying) {
2184                         if (time > this.respawn_time) {
2185                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2186                                 respawn(this);
2187                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2188                         }
2189                 } else {
2190                         if (frametime) player_anim(this);
2191
2192                         if (this.respawn_flags & RESPAWN_DENY)
2193                         {
2194                                 STAT(RESPAWN_TIME, this) = 0;
2195                                 return false;
2196                         }
2197
2198                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2199
2200                         switch(this.deadflag)
2201                         {
2202                                 case DEAD_DYING:
2203                                 {
2204                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2205                                                 this.deadflag = DEAD_RESPAWNING;
2206                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2207                                                 this.deadflag = DEAD_DEAD;
2208                                         break;
2209                                 }
2210                                 case DEAD_DEAD:
2211                                 {
2212                                         if (button_pressed)
2213                                                 this.deadflag = DEAD_RESPAWNABLE;
2214                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2215                                                 this.deadflag = DEAD_RESPAWNING;
2216                                         break;
2217                                 }
2218                                 case DEAD_RESPAWNABLE:
2219                                 {
2220                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2221                                                 this.deadflag = DEAD_RESPAWNING;
2222                                         break;
2223                                 }
2224                                 case DEAD_RESPAWNING:
2225                                 {
2226                                         if (time > this.respawn_time)
2227                                         {
2228                                                 this.respawn_time = time + 1; // only retry once a second
2229                                                 this.respawn_time_max = this.respawn_time;
2230                                                 respawn(this);
2231                                         }
2232                                         break;
2233                                 }
2234                         }
2235
2236                         ShowRespawnCountdown(this);
2237
2238                         if (this.respawn_flags & RESPAWN_SILENT)
2239                                 STAT(RESPAWN_TIME, this) = 0;
2240                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2241                         {
2242                                 if (time < this.respawn_time)
2243                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2244                                 else if (this.deadflag != DEAD_RESPAWNING)
2245                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2246                         }
2247                         else
2248                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2249                 }
2250
2251                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2252                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2253                         STAT(RESPAWN_TIME, this) *= -1;
2254
2255                 return false;
2256         }
2257
2258         FixPlayermodel(this);
2259
2260         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2261                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2262                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2263         }
2264
2265         // reset gun alignment when dual wielding status changes
2266         // to ensure guns are always aligned right and left
2267         bool dualwielding = W_DualWielding(this);
2268         if(this.dualwielding_prev != dualwielding)
2269         {
2270                 W_ResetGunAlign(this, CS(this).cvar_cl_gunalign);
2271                 this.dualwielding_prev = dualwielding;
2272         }
2273
2274         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2275         //if(frametime)
2276         {
2277                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2278                 {
2279                         .entity weaponentity = weaponentities[slot];
2280                         if(WEP_CVAR(vortex, charge_always))
2281                                 W_Vortex_Charge(this, weaponentity, frametime);
2282                         W_WeaponFrame(this, weaponentity);
2283                 }
2284         }
2285
2286         if (frametime)
2287         {
2288                 // WEAPONTODO: Add a weapon request for this
2289                 // rot vortex charge to the charge limit
2290                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2291                 {
2292                         .entity weaponentity = weaponentities[slot];
2293                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2294                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2295                 }
2296
2297                 player_regen(this);
2298                 player_anim(this);
2299                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2300         }
2301
2302         monsters_setstatus(this);
2303
2304         return true;
2305 }
2306
2307 .bool would_spectate;
2308 void ObserverOrSpectatorThink(entity this)
2309 {
2310         bool is_spec = IS_SPEC(this);
2311         if ( CS(this).impulse )
2312         {
2313                 int r = MinigameImpulse(this, CS(this).impulse);
2314                 if (!is_spec || r)
2315                         CS(this).impulse = 0;
2316
2317                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2318                 {
2319                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2320                         CS(this).impulse = 0;
2321                         return;
2322                 }
2323         }
2324
2325         if (this.flags & FL_JUMPRELEASED) {
2326                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2327                         this.flags &= ~FL_JUMPRELEASED;
2328                         this.flags |= FL_SPAWNING;
2329                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2330                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2331                         this.flags &= ~FL_JUMPRELEASED;
2332                         if(SpectateNext(this)) {
2333                                 TRANSMUTE(Spectator, this);
2334                         } else if (is_spec) {
2335                                 TRANSMUTE(Observer, this);
2336                                 PutClientInServer(this);
2337                         }
2338                         if (is_spec)
2339                                 CS(this).impulse = 0;
2340                 } else if (is_spec) {
2341                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2342                                 this.flags &= ~FL_JUMPRELEASED;
2343                                 if(SpectatePrev(this)) {
2344                                         TRANSMUTE(Spectator, this);
2345                                 } else {
2346                                         TRANSMUTE(Observer, this);
2347                                         PutClientInServer(this);
2348                                 }
2349                                 CS(this).impulse = 0;
2350                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2351                                 this.would_spectate = false;
2352                                 this.flags &= ~FL_JUMPRELEASED;
2353                                 TRANSMUTE(Observer, this);
2354                                 PutClientInServer(this);
2355                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2356                                 PutObserverInServer(this);
2357                                 this.would_spectate = true;
2358                         }
2359                 }
2360                 else {
2361                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2362                         set_movetype(this, preferred_movetype);
2363                 }
2364         } else {
2365                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2366                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2367                         this.flags |= FL_JUMPRELEASED;
2368                         if(this.flags & FL_SPAWNING)
2369                         {
2370                                 this.flags &= ~FL_SPAWNING;
2371                                 if(joinAllowed(this))
2372                                         Join(this);
2373                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2374                                         CS(this).autojoin_checked = -1;
2375                                 return;
2376                         }
2377                 }
2378                 if(is_spec && !SpectateUpdate(this))
2379                         PutObserverInServer(this);
2380         }
2381         if (is_spec)
2382                 this.flags |= FL_CLIENT | FL_NOTARGET;
2383 }
2384
2385 void PlayerUseKey(entity this)
2386 {
2387         if (!IS_PLAYER(this))
2388                 return;
2389
2390         if(this.vehicle)
2391         {
2392                 if(!game_stopped)
2393                 {
2394                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2395                         return;
2396                 }
2397         }
2398         else if(autocvar_g_vehicles_enter)
2399         {
2400                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2401                 {
2402                         entity head, closest_target = NULL;
2403                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2404
2405                         while(head) // find the closest acceptable target to enter
2406                         {
2407                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2408                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2409                                 {
2410                                         if(closest_target)
2411                                         {
2412                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2413                                                 { closest_target = head; }
2414                                         }
2415                                         else { closest_target = head; }
2416                                 }
2417
2418                                 head = head.chain;
2419                         }
2420
2421                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2422                 }
2423         }
2424
2425         // a use key was pressed; call handlers
2426         MUTATOR_CALLHOOK(PlayerUseKey, this);
2427 }
2428
2429
2430 /*
2431 =============
2432 PlayerPreThink
2433
2434 Called every frame for each client before the physics are run
2435 =============
2436 */
2437 .float last_vehiclecheck;
2438 void PlayerPreThink (entity this)
2439 {
2440         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2441         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2442
2443         WarpZone_PlayerPhysics_FixVAngle(this);
2444
2445         if (frametime) {
2446                 // physics frames: update anticheat stuff
2447                 anticheat_prethink(this);
2448         }
2449
2450         if (blockSpectators && frametime) {
2451                 // WORKAROUND: only use dropclient in server frames (frametime set).
2452                 // Never use it in cl_movement frames (frametime zero).
2453                 checkSpectatorBlock(this);
2454         }
2455
2456         zoomstate_set = false;
2457
2458         // Check for nameless players
2459         if (this.netname == "" || this.netname != CS(this).netname_previous)
2460         {
2461                 bool assume_unchanged = (CS(this).netname_previous == "");
2462                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2463                 {
2464                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2465                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2466                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2467                         assume_unchanged = false;
2468                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2469                 }
2470                 if (isInvisibleString(this.netname))
2471                 {
2472                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2473                         sprint(this, "Warning: invisible names are not allowed.\n");
2474                         assume_unchanged = false;
2475                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2476                 }
2477                 if (!assume_unchanged && autocvar_sv_eventlog)
2478                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2479                 strcpy(CS(this).netname_previous, this.netname);
2480         }
2481
2482         // version nagging
2483         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2484         CS(this).version_nagtime = 0;
2485         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2486             // git client
2487         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2488             // git server
2489             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2490         } else {
2491             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2492             if (r < 0) { // old client
2493                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2494             } else if (r > 0) { // old server
2495                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2496             }
2497         }
2498     }
2499
2500         // GOD MODE info
2501         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2502         {
2503                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2504                 this.max_armorvalue = 0;
2505         }
2506
2507         if (frametime && IS_PLAYER(this))
2508         {
2509                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2510                 {
2511                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2512                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2513                         if (this.iceblock)
2514                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2515
2516                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2517                                 Unfreeze(this, false);
2518                 }
2519                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2520                 {
2521                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2522                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2523
2524                         if (GetResource(this, RES_HEALTH) < 1)
2525                         {
2526                                 if (this.vehicle)
2527                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2528                                 if(this.event_damage)
2529                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2530                         }
2531                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2532                                 Unfreeze(this, false);
2533                 }
2534         }
2535
2536         MUTATOR_CALLHOOK(PlayerPreThink, this);
2537
2538         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2539         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2540         {
2541                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2542                 {
2543                         if(!it.owner)
2544                         {
2545                                 if(!it.team || SAME_TEAM(this, it))
2546                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2547                                 else if(autocvar_g_vehicles_steal)
2548                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2549                         }
2550                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2551                         {
2552                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2553                         }
2554                 });
2555
2556                 this.last_vehiclecheck = time + 1;
2557         }
2558
2559         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2560         {
2561                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2562                         PlayerUseKey(this);
2563                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2564         }
2565
2566         if (IS_REAL_CLIENT(this))
2567                 PrintWelcomeMessage(this);
2568
2569         if (IS_PLAYER(this)) {
2570                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2571                         error("Client can't be spawned as player on connection!");
2572                 if(!PlayerThink(this))
2573                         return;
2574         }
2575         else if (game_stopped || intermission_running) {
2576                 if(intermission_running)
2577                         IntermissionThink(this);
2578                 return;
2579         }
2580         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2581         {
2582                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2583                 CS(this).autojoin_checked = 1;
2584                 // don't do this in ClientConnect
2585                 // many things can go wrong if a client is spawned as player on connection
2586                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2587                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2588                                 && (!teamplay || autocvar_g_balance_teams)))
2589                 {
2590                         campaign_bots_may_start = true;
2591                         if(joinAllowed(this))
2592                                 Join(this);
2593                         return;
2594                 }
2595         }
2596         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2597                 ObserverOrSpectatorThink(this);
2598         }
2599
2600         // WEAPONTODO: Add weapon request for this
2601         if (!zoomstate_set) {
2602                 bool wep_zoomed = false;
2603                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2604                 {
2605                         .entity weaponentity = weaponentities[slot];
2606                         Weapon thiswep = this.(weaponentity).m_weapon;
2607                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2608                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2609                 }
2610                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2611         }
2612
2613         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2614         {
2615                 CS(this).teamkill_soundtime = 0;
2616
2617                 entity e = CS(this).teamkill_soundsource;
2618                 entity oldpusher = e.pusher;
2619                 e.pusher = this;
2620                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2621                 e.pusher = oldpusher;
2622         }
2623
2624         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2625                 CS(this).taunt_soundtime = 0;
2626                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2627         }
2628
2629         target_voicescript_next(this);
2630
2631         // WEAPONTODO: Move into weaponsystem somehow
2632         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2633         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2634         {
2635                 .entity weaponentity = weaponentities[slot];
2636                 if(this.(weaponentity).m_weapon == WEP_Null)
2637                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2638         }
2639 }
2640
2641 void DrownPlayer(entity this)
2642 {
2643         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2644                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2645         {
2646                 STAT(AIR_FINISHED, this) = 0;
2647                 return;
2648         }
2649
2650         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2651         {
2652                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2653                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2654                 STAT(AIR_FINISHED, this) = 0;
2655         }
2656         else
2657         {
2658                 if (!STAT(AIR_FINISHED, this))
2659                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2660                 if (STAT(AIR_FINISHED, this) < time)
2661                 {       // drown!
2662                         if (this.pain_finished < time)
2663                         {
2664                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2665                                 this.pain_finished = time + 0.5;
2666                         }
2667                 }
2668         }
2669 }
2670
2671 .bool move_qcphysics;
2672
2673 void Player_Physics(entity this)
2674 {
2675         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2676
2677         if(!this.move_qcphysics)
2678                 return;
2679
2680         if(!frametime && !CS(this).pm_frametime)
2681                 return;
2682
2683         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2684
2685         CS(this).pm_frametime = 0;
2686 }
2687
2688 /*
2689 =============
2690 PlayerPostThink
2691
2692 Called every frame for each client after the physics are run
2693 =============
2694 */
2695 void PlayerPostThink (entity this)
2696 {
2697         Player_Physics(this);
2698
2699         if (autocvar_sv_maxidle > 0)
2700         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2701         if (IS_REAL_CLIENT(this))
2702         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2703         {
2704                 int totalClients = 0;
2705                 if(autocvar_sv_maxidle_slots > 0)
2706                 {
2707                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2708                         {
2709                                 ++totalClients;
2710                         });
2711                 }
2712
2713                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2714                 { /* do nothing */ }
2715                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2716                 {
2717                         if (CS(this).idlekick_lasttimeleft)
2718                         {
2719                                 CS(this).idlekick_lasttimeleft = 0;
2720                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2721                         }
2722                 }
2723                 else
2724                 {
2725                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2726                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2727                                 if (!CS(this).idlekick_lasttimeleft)
2728                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2729                         }
2730                         if (timeleft <= 0) {
2731                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2732                                 dropclient(this);
2733                                 return;
2734                         }
2735                         else if (timeleft <= 10) {
2736                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2737                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2738                                 CS(this).idlekick_lasttimeleft = timeleft;
2739                         }
2740                 }
2741         }
2742
2743         CheatFrame(this);
2744
2745         if (game_stopped)
2746         {
2747                 this.solid = SOLID_NOT;
2748                 this.takedamage = DAMAGE_NO;
2749                 set_movetype(this, MOVETYPE_NONE);
2750                 CS(this).teamkill_complain = 0;
2751                 CS(this).teamkill_soundtime = 0;
2752                 CS(this).teamkill_soundsource = NULL;
2753         }
2754
2755         if (IS_PLAYER(this)) {
2756                 if(this.death_time == time && IS_DEAD(this))
2757                 {
2758                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2759                         // once all the damage events of this frame have been processed with normal size
2760                         this.maxs.z = 5;
2761                         setsize(this, this.mins, this.maxs);
2762                 }
2763                 DrownPlayer(this);
2764                 UpdateChatBubble(this);
2765                 if (CS(this).impulse) ImpulseCommands(this);
2766                 if (game_stopped)
2767                 {
2768                         CSQCMODEL_AUTOUPDATE(this);
2769                         return;
2770                 }
2771                 GetPressedKeys(this);
2772         }
2773         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2774         {
2775                 CS(this).pressedkeys = 0;
2776                 STAT(PRESSED_KEYS, this) = 0;
2777         }
2778
2779         if (this.waypointsprite_attachedforcarrier) {
2780                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2781                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2782         }
2783
2784         CSQCMODEL_AUTOUPDATE(this);
2785 }
2786
2787 // hack to copy the button fields from the client entity to the Client State
2788 void PM_UpdateButtons(entity this, entity store)
2789 {
2790         if(this.impulse)
2791                 store.impulse = this.impulse;
2792         this.impulse = 0;
2793
2794         bool typing = this.buttonchat || this.button12;
2795
2796         store.button0 = (typing) ? 0 : this.button0;
2797         //button1?!
2798         store.button2 = (typing) ? 0 : this.button2;
2799         store.button3 = (typing) ? 0 : this.button3;
2800         store.button4 = this.button4;
2801         store.button5 = (typing) ? 0 : this.button5;
2802         store.button6 = this.button6;
2803         store.button7 = this.button7;
2804         store.button8 = this.button8;
2805         store.button9 = this.button9;
2806         store.button10 = this.button10;
2807         store.button11 = this.button11;
2808         store.button12 = this.button12;
2809         store.button13 = this.button13;
2810         store.button14 = this.button14;
2811         store.button15 = this.button15;
2812         store.button16 = this.button16;
2813         store.buttonuse = this.buttonuse;
2814         store.buttonchat = this.buttonchat;
2815
2816         store.cursor_active = this.cursor_active;
2817         store.cursor_screen = this.cursor_screen;
2818         store.cursor_trace_start = this.cursor_trace_start;
2819         store.cursor_trace_endpos = this.cursor_trace_endpos;
2820         store.cursor_trace_ent = this.cursor_trace_ent;
2821
2822         store.ping = this.ping;
2823         store.ping_packetloss = this.ping_packetloss;
2824         store.ping_movementloss = this.ping_movementloss;
2825
2826         store.v_angle = this.v_angle;
2827         store.movement = this.movement;
2828 }
2829
2830 NET_HANDLE(fpsreport, bool)
2831 {
2832         int fps = ReadShort();
2833         PlayerScore_Set(sender, SP_FPS, fps);
2834         return true;
2835 }