qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/status_effects/_mod.qh>
  27 #include <common/mutators/mutator/waypoints/all.qh>
  28 #include <common/net_linked.qh>
  29 #include <common/net_notice.qh>
  30 #include <common/notifications/all.qh>
  31 #include <common/physics/player.qh>
  32 #include <common/playerstats.qh>
  33 #include <common/resources/sv_resources.qh>
  34 #include <common/state.qh>
  35 #include <common/stats.qh>
  36 #include <common/vehicles/all.qh>
  37 #include <common/vehicles/sv_vehicles.qh>
  38 #include <common/viewloc.qh>
  39 #include <common/weapons/_all.qh>
  40 #include <common/weapons/weapon/vortex.qh>
  41 #include <common/wepent.qh>
  42 #include <lib/csqcmodel/sv_model.qh>
  43 #include <lib/warpzone/common.qh>
  44 #include <lib/warpzone/server.qh>
  45 #include <server/anticheat.qh>
  46 #include <server/antilag.qh>
  47 #include <server/bot/api.qh>
  48 #include <server/bot/default/cvars.qh>
  49 #include <server/bot/default/waypoints.qh>
  50 #include <server/campaign.qh>
  51 #include <server/chat.qh>
  52 #include <server/cheats.qh>
  53 #include <server/clientkill.qh>
  54 #include <server/command/common.qh>
  55 #include <server/command/common.qh>
  56 #include <server/command/vote.qh>
  57 #include <server/compat/quake3.qh>
  58 #include <server/damage.qh>
  59 #include <server/gamelog.qh>
  60 #include <server/handicap.qh>
  61 #include <server/hook.qh>
  62 #include <server/impulse.qh>
  63 #include <server/intermission.qh>
  64 #include <server/ipban.qh>
  65 #include <server/main.qh>
  66 #include <server/mutators/_mod.qh>
  67 #include <server/player.qh>
  68 #include <server/portals.qh>
  69 #include <server/race.qh>
  70 #include <server/scores.qh>
  71 #include <server/scores_rules.qh>
  72 #include <server/spawnpoints.qh>
  73 #include <server/teamplay.qh>
  74 #include <server/weapons/accuracy.qh>
  75 #include <server/weapons/common.qh>
  76 #include <server/weapons/hitplot.qh>
  77 #include <server/weapons/selection.qh>
  78 #include <server/weapons/tracing.qh>
  79 #include <server/weapons/weaponsystem.qh>
  80 #include <server/world.qh>
  81
  82 STATIC_METHOD(Client, Add, void(Client this, int _team))
  83 {
  84     ClientConnect(this);
  85     TRANSMUTE(Player, this);
  86     this.frame = 12; // 7
  87     this.team = _team;
  88     PutClientInServer(this);
  89 }
  90
  91 STATIC_METHOD(Client, Remove, void(Client this))
  92 {
  93     TRANSMUTE(Observer, this);
  94     PutClientInServer(this);
  95     ClientDisconnect(this);
  96 }
  97
  98 void send_CSQC_teamnagger() {
  99         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
 100 }
 101
 102 int CountSpectators(entity player, entity to)
 103 {
 104         if(!player) { return 0; } // not sure how, but best to be safe
 105
 106         int spec_count = 0;
 107
 108         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 109         {
 110                 spec_count++;
 111         });
 112
 113         return spec_count;
 114 }
 115
 116 void WriteSpectators(entity player, entity to)
 117 {
 118         if(!player) { return; } // not sure how, but best to be safe
 119
 120         int spec_count = 0;
 121         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 122         {
 123                 if(spec_count >= MAX_SPECTATORS)
 124                         break;
 125                 WriteByte(MSG_ENTITY, num_for_edict(it));
 126                 ++spec_count;
 127         });
 128 }
 129
 130 bool ClientData_Send(entity this, entity to, int sf)
 131 {
 132         assert(to == this.owner, return false);
 133
 134         entity e = to;
 135         if (IS_SPEC(e)) e = e.enemy;
 136
 137         sf = 0;
 138         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 139         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 140         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 141         if (observe_blocked_if_eliminated && INGAME(to))
 142                                         sf |= BIT(3); // observing blocked
 143         if (autocvar_sv_showspectators == 1 || (autocvar_sv_showspectators && IS_SPEC(to)))
 144                                         sf |= BIT(4); // show spectators
 145
 146         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 147         WriteByte(MSG_ENTITY, sf);
 148
 149         if (sf & BIT(1))
 150                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 151
 152         if(sf & BIT(4))
 153         {
 154                 float specs = CountSpectators(e, to);
 155                 WriteByte(MSG_ENTITY, specs);
 156                 WriteSpectators(e, to);
 157         }
 158
 159         return true;
 160 }
 161
 162 void ClientData_Attach(entity this)
 163 {
 164         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 165         CS(this).clientdata.drawonlytoclient = this;
 166         CS(this).clientdata.owner = this;
 167 }
 168
 169 void ClientData_Detach(entity this)
 170 {
 171         delete(CS(this).clientdata);
 172         CS(this).clientdata = NULL;
 173 }
 174
 175 void ClientData_Touch(entity e)
 176 {
 177         entity cd = CS(e).clientdata;
 178         if (cd) { cd.SendFlags = 1; }
 179
 180         // make it spectatable
 181         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 182         {
 183                 entity cd = CS(it).clientdata;
 184                 if (cd) { cd.SendFlags = 1; }
 185         });
 186 }
 187
 188
 189 /*
 190 =============
 191 CheckPlayerModel
 192
 193 Checks if the argument string can be a valid playermodel.
 194 Returns a valid one in doubt.
 195 =============
 196 */
 197 string FallbackPlayerModel;
 198 string CheckPlayerModel(string plyermodel) {
 199         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 200         {
 201                 // note: we cannot summon Don Strunzone here, some player may
 202                 // still have the model string set. In case anyone manages how
 203                 // to change a cvar default, we'll have a small leak here.
 204                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 205         }
 206         // only in right path
 207         if(substring(plyermodel, 0, 14) != "models/player/")
 208                 return FallbackPlayerModel;
 209         // only good file extensions
 210         if(substring(plyermodel, -4, 4) != ".iqm"
 211                 && substring(plyermodel, -4, 4) != ".zym"
 212                 && substring(plyermodel, -4, 4) != ".dpm"
 213                 && substring(plyermodel, -4, 4) != ".md3"
 214                 && substring(plyermodel, -4, 4) != ".psk")
 215         {
 216                 return FallbackPlayerModel;
 217         }
 218         // forbid the LOD models
 219         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 220                 return FallbackPlayerModel;
 221         if(plyermodel != strtolower(plyermodel))
 222                 return FallbackPlayerModel;
 223         // also, restrict to server models
 224         if(autocvar_sv_servermodelsonly)
 225         {
 226                 if(!fexists(plyermodel))
 227                         return FallbackPlayerModel;
 228         }
 229         return plyermodel;
 230 }
 231
 232 void setplayermodel(entity e, string modelname)
 233 {
 234         precache_model(modelname);
 235         _setmodel(e, modelname);
 236         player_setupanimsformodel(e);
 237         if(!autocvar_g_debug_globalsounds)
 238                 UpdatePlayerSounds(e);
 239 }
 240
 241 /** putting a client as observer in the server */
 242 void PutObserverInServer(entity this, bool is_forced, bool use_spawnpoint)
 243 {
 244         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this, is_forced);
 245         bool recount_ready = false;
 246         PlayerState_detach(this);
 247
 248         if (IS_PLAYER(this))
 249         {
 250                 if(GetResource(this, RES_HEALTH) >= 1)
 251                 {
 252                         // despawn effect
 253                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 254                 }
 255
 256                 // was a player, recount votes and ready status
 257                 if(IS_REAL_CLIENT(this))
 258                 {
 259                         if (vote_called) { VoteCount(false); }
 260                         this.ready = false;
 261                         if (warmup_stage || game_starttime > time) recount_ready = true;
 262                 }
 263                 entcs_update_players(this);
 264         }
 265
 266         if (use_spawnpoint)
 267         {
 268                 entity spot = SelectSpawnPoint(this, true);
 269                 if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 270                 this.angles = vec2(spot.angles);
 271                 // offset it so that the spectator spawns higher off the ground, looks better this way
 272                 setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 273         }
 274         else // change origin to restore previous view origin
 275                 setorigin(this, this.origin + STAT(PL_VIEW_OFS, this) - STAT(PL_CROUCH_VIEW_OFS, this));
 276         this.fixangle = true;
 277
 278         if (IS_REAL_CLIENT(this))
 279         {
 280                 msg_entity = this;
 281                 WriteByte(MSG_ONE, SVC_SETVIEW);
 282                 WriteEntity(MSG_ONE, this);
 283         }
 284         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 285         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 286         if(!autocvar_g_debug_globalsounds)
 287         {
 288                 // needed for player sounds
 289                 this.model = "";
 290                 FixPlayermodel(this);
 291         }
 292         setmodel(this, MDL_Null);
 293         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 294         this.view_ofs = '0 0 0';
 295
 296         RemoveGrapplingHooks(this);
 297         Portal_ClearAll(this);
 298         Unfreeze(this, false);
 299         SetSpectatee(this, NULL);
 300
 301         if (this.alivetime)
 302         {
 303                 if (!warmup_stage)
 304                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 305                 this.alivetime = 0;
 306         }
 307
 308         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 309
 310         TRANSMUTE(Observer, this);
 311
 312         if(recount_ready) ReadyCount(); // FIXME: please add comment about why this is delayed
 313
 314         WaypointSprite_PlayerDead(this);
 315         accuracy_resend(this);
 316
 317         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 318                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 319
 320         CS(this).spectatortime = time;
 321         if(this.bot_attack)
 322                 IL_REMOVE(g_bot_targets, this);
 323         this.bot_attack = false;
 324         if(this.monster_attack)
 325                 IL_REMOVE(g_monster_targets, this);
 326         this.monster_attack = false;
 327         STAT(HUD, this) = HUD_NORMAL;
 328         this.iscreature = false;
 329         this.teleportable = TELEPORT_SIMPLE;
 330         if(this.damagedbycontents)
 331                 IL_REMOVE(g_damagedbycontents, this);
 332         this.damagedbycontents = false;
 333         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 334         SetSpectatee_status(this, etof(this));
 335         this.takedamage = DAMAGE_NO;
 336         this.solid = SOLID_NOT;
 337         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 338         this.flags = FL_CLIENT | FL_NOTARGET;
 339         this.effects = 0;
 340         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 341         this.pauserotarmor_finished = 0;
 342         this.pauserothealth_finished = 0;
 343         this.pauseregen_finished = 0;
 344         this.damageforcescale = 0;
 345         this.death_time = 0;
 346         this.respawn_flags = 0;
 347         this.respawn_time = 0;
 348         STAT(RESPAWN_TIME, this) = 0;
 349         this.alpha = 0;
 350         this.scale = 0;
 351         this.fade_time = 0;
 352         this.pain_finished = 0;
 353         STAT(AIR_FINISHED, this) = 0;
 354         //this.dphitcontentsmask = 0;
 355         this.dphitcontentsmask = DPCONTENTS_SOLID;
 356         if (autocvar_g_playerclip_collisions)
 357                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 358         this.pushltime = 0;
 359         this.istypefrag = 0;
 360         setthink(this, func_null);
 361         this.nextthink = 0;
 362         this.deadflag = DEAD_NO;
 363         UNSET_DUCKED(this);
 364         STAT(REVIVE_PROGRESS, this) = 0;
 365         this.revival_time = 0;
 366         this.draggable = drag_undraggable;
 367
 368         player_powerups_remove_all(this);
 369         this.items = 0;
 370         STAT(WEAPONS, this) = '0 0 0';
 371         this.drawonlytoclient = this;
 372
 373         this.viewloc = NULL;
 374
 375         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 376
 377         this.weaponmodel = "";
 378         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 379         {
 380                 this.weaponentities[slot] = NULL;
 381         }
 382         this.exteriorweaponentity = NULL;
 383         CS(this).killcount = FRAGS_SPECTATOR;
 384         this.velocity = '0 0 0';
 385         this.avelocity = '0 0 0';
 386         this.punchangle = '0 0 0';
 387         this.punchvector = '0 0 0';
 388         this.oldvelocity = this.velocity;
 389         this.event_damage = func_null;
 390         this.event_heal = func_null;
 391
 392         for(int slot = 0; slot < MAX_AXH; ++slot)
 393         {
 394                 entity axh = this.(AuxiliaryXhair[slot]);
 395                 this.(AuxiliaryXhair[slot]) = NULL;
 396
 397                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 398                         delete(axh);
 399         }
 400
 401         if (mutator_returnvalue)
 402         {
 403                 // mutator prevents resetting teams+score
 404         }
 405         else
 406         {
 407                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR); // clears scores too in game modes without teams
 408                 this.frags = FRAGS_SPECTATOR;
 409         }
 410
 411         bot_relinkplayerlist();
 412
 413         if (CS(this).just_joined)
 414                 CS(this).just_joined = false;
 415 }
 416
 417 int player_getspecies(entity this)
 418 {
 419         get_model_parameters(this.model, this.skin);
 420         int s = get_model_parameters_species;
 421         get_model_parameters(string_null, 0);
 422         if (s < 0) return SPECIES_HUMAN;
 423         return s;
 424 }
 425
 426 .float model_randomizer;
 427 void FixPlayermodel(entity player)
 428 {
 429         string defaultmodel = "";
 430         int defaultskin = 0;
 431         if(autocvar_sv_defaultcharacter)
 432         {
 433                 if(teamplay)
 434                 {
 435                         switch(player.team)
 436                         {
 437                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 438                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 439                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 440                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 441                         }
 442                 }
 443
 444                 if(defaultmodel == "")
 445                 {
 446                         defaultmodel = autocvar_sv_defaultplayermodel;
 447                         defaultskin = autocvar_sv_defaultplayerskin;
 448                 }
 449
 450                 int n = tokenize_console(defaultmodel);
 451                 if(n > 0)
 452                 {
 453                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 454                         // However, do NOT randomize if the player-selected model is in the list.
 455                         for (int i = 0; i < n; ++i)
 456                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 457                                         defaultmodel = argv(i);
 458                 }
 459
 460                 int i = strstrofs(defaultmodel, ":", 0);
 461                 if(i >= 0)
 462                 {
 463                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 464                         defaultmodel = substring(defaultmodel, 0, i);
 465                 }
 466         }
 467         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 468         {
 469                 if(teamplay)
 470                 {
 471                         switch(player.team)
 472                         {
 473                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 474                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 475                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 476                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 477                         }
 478                 }
 479
 480                 if(!defaultskin)
 481                         defaultskin = autocvar_sv_defaultplayerskin;
 482         }
 483
 484         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 485         defaultmodel = M_ARGV(0, string);
 486         defaultskin = M_ARGV(1, int);
 487
 488         bool chmdl = false;
 489         int oldskin;
 490         if(defaultmodel != "")
 491         {
 492                 if (defaultmodel != player.model)
 493                 {
 494                         vector m1 = player.mins;
 495                         vector m2 = player.maxs;
 496                         setplayermodel (player, defaultmodel);
 497                         setsize (player, m1, m2);
 498                         chmdl = true;
 499                 }
 500
 501                 oldskin = player.skin;
 502                 player.skin = defaultskin;
 503         } else {
 504                 if (player.playermodel != player.model || player.playermodel == "")
 505                 {
 506                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 507                         vector m1 = player.mins;
 508                         vector m2 = player.maxs;
 509                         setplayermodel (player, player.playermodel);
 510                         setsize (player, m1, m2);
 511                         chmdl = true;
 512                 }
 513
 514                 if(!autocvar_sv_defaultcharacterskin)
 515                 {
 516                         oldskin = player.skin;
 517                         player.skin = stof(player.playerskin);
 518                 }
 519                 else
 520                 {
 521                         oldskin = player.skin;
 522                         player.skin = defaultskin;
 523                 }
 524         }
 525
 526         if(chmdl || oldskin != player.skin) // model or skin has changed
 527         {
 528                 player.species = player_getspecies(player); // update species
 529                 if(!autocvar_g_debug_globalsounds)
 530                         UpdatePlayerSounds(player); // update skin sounds
 531         }
 532
 533         if(!teamplay)
 534                 if(strlen(autocvar_sv_defaultplayercolors))
 535                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 536                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 537 }
 538
 539 void PutPlayerInServer(entity this)
 540 {
 541         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 542
 543         PlayerState_attach(this);
 544         accuracy_resend(this);
 545
 546         if (teamplay && this.bot_forced_team)
 547                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 548
 549         if (this.team < 0)
 550                 TeamBalance_JoinBestTeam(this);
 551
 552         entity spot = SelectSpawnPoint(this, false);
 553         if (!spot) {
 554                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 555                 return; // spawn failed
 556         }
 557
 558         TRANSMUTE(Player, this);
 559
 560         CS(this).wasplayer = true;
 561         this.iscreature = true;
 562         this.teleportable = TELEPORT_NORMAL;
 563         if(!this.damagedbycontents)
 564                 IL_PUSH(g_damagedbycontents, this);
 565         this.damagedbycontents = true;
 566         set_movetype(this, MOVETYPE_WALK);
 567         this.solid = SOLID_SLIDEBOX;
 568         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 569         if (autocvar_g_playerclip_collisions)
 570                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 571         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 572                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 573         this.frags = FRAGS_PLAYER;
 574         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 575         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 576         if (autocvar__notarget)
 577                 this.flags |= FL_NOTARGET;
 578         this.takedamage = DAMAGE_AIM;
 579         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 580
 581         if (warmup_stage) {
 582                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 583                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 584                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 585                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 586                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 587                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 588                 SetResource(this, RES_HEALTH, warmup_start_health);
 589                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 590                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 591         } else {
 592                 SetResource(this, RES_SHELLS, start_ammo_shells);
 593                 SetResource(this, RES_BULLETS, start_ammo_nails);
 594                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 595                 SetResource(this, RES_CELLS, start_ammo_cells);
 596                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 597                 SetResource(this, RES_FUEL, start_ammo_fuel);
 598                 SetResource(this, RES_HEALTH, start_health);
 599                 SetResource(this, RES_ARMOR, start_armorvalue);
 600                 STAT(WEAPONS, this) = start_weapons;
 601                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 602                 {
 603                         GiveRandomWeapons(this, random_start_weapons_count,
 604                                 autocvar_g_random_start_weapons, random_start_ammo);
 605                 }
 606         }
 607         SetSpectatee_status(this, 0);
 608
 609         PS(this).dual_weapons = '0 0 0';
 610
 611         if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
 612                 StatusEffects_apply(STATUSEFFECT_Superweapons, this, time + autocvar_g_balance_superweapons_time, 0);
 613
 614         this.items = start_items;
 615
 616         float shieldtime = time + autocvar_g_spawnshieldtime;
 617
 618         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 619         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 620         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 621         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 622         if (!sv_ready_restart_after_countdown && time < game_starttime)
 623         {
 624                 float f = game_starttime - time;
 625                 shieldtime += f;
 626                 this.pauserotarmor_finished += f;
 627                 this.pauserothealth_finished += f;
 628                 this.pauseregen_finished += f;
 629         }
 630
 631         StatusEffects_apply(STATUSEFFECT_SpawnShield, this, shieldtime, 0);
 632
 633         this.damageforcescale = autocvar_g_player_damageforcescale;
 634         this.death_time = 0;
 635         this.respawn_flags = 0;
 636         this.respawn_time = 0;
 637         STAT(RESPAWN_TIME, this) = 0;
 638         this.scale = ((q3compat && autocvar_sv_q3compat_changehitbox) ? 0.9 : autocvar_sv_player_scale);
 639         this.fade_time = 0;
 640         this.pain_finished = 0;
 641         this.pushltime = 0;
 642         setthink(this, func_null); // players have no think function
 643         this.nextthink = 0;
 644         this.dmg_team = 0;
 645         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 646
 647         this.deadflag = DEAD_NO;
 648
 649         this.angles = spot.angles;
 650         this.angles_z = 0; // never spawn tilted even if the spot says to
 651         if (IS_BOT_CLIENT(this))
 652         {
 653                 this.v_angle = this.angles;
 654                 bot_aim_reset(this);
 655         }
 656         this.fixangle = true; // turn this way immediately
 657         this.oldvelocity = this.velocity = '0 0 0';
 658         this.avelocity = '0 0 0';
 659         this.punchangle = '0 0 0';
 660         this.punchvector = '0 0 0';
 661
 662         STAT(REVIVE_PROGRESS, this) = 0;
 663         this.revival_time = 0;
 664
 665         STAT(AIR_FINISHED, this) = 0;
 666         this.waterlevel = WATERLEVEL_NONE;
 667         this.watertype = CONTENT_EMPTY;
 668
 669         entity spawnevent = new_pure(spawnevent);
 670         spawnevent.owner = this;
 671         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 672
 673         // Cut off any still running player sounds.
 674         stopsound(this, CH_PLAYER_SINGLE);
 675
 676         this.model = "";
 677         FixPlayermodel(this);
 678         this.drawonlytoclient = NULL;
 679
 680         this.viewloc = NULL;
 681
 682         for(int slot = 0; slot < MAX_AXH; ++slot)
 683         {
 684                 entity axh = this.(AuxiliaryXhair[slot]);
 685                 this.(AuxiliaryXhair[slot]) = NULL;
 686
 687                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 688                         delete(axh);
 689         }
 690
 691         this.spawnpoint_targ = NULL;
 692
 693         UNSET_DUCKED(this);
 694         this.view_ofs = STAT(PL_VIEW_OFS, this);
 695         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 696         this.spawnorigin = spot.origin;
 697         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 698         // don't reset back to last position, even if new position is stuck in solid
 699         this.oldorigin = this.origin;
 700         if(this.conveyor)
 701                 IL_REMOVE(g_conveyed, this);
 702         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 703         if(this.swampslug)
 704                 IL_REMOVE(g_swamped, this);
 705         this.swampslug = NULL;
 706         this.swamp_interval = 0;
 707         if(this.ladder_entity)
 708                 IL_REMOVE(g_ladderents, this);
 709         this.ladder_entity = NULL;
 710         IL_EACH(g_counters, it.realowner == this,
 711         {
 712                 delete(it);
 713         });
 714         STAT(HUD, this) = HUD_NORMAL;
 715
 716         this.event_damage = PlayerDamage;
 717         this.event_heal = PlayerHeal;
 718
 719         this.draggable = func_null;
 720
 721         if(!this.bot_attack)
 722                 IL_PUSH(g_bot_targets, this);
 723         this.bot_attack = true;
 724         if(!this.monster_attack)
 725                 IL_PUSH(g_monster_targets, this);
 726         this.monster_attack = true;
 727         navigation_dynamicgoal_init(this, false);
 728
 729         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 730
 731         // player was spectator
 732         if (CS(this).killcount == FRAGS_SPECTATOR) {
 733                 PlayerScore_Clear(this);
 734                 CS(this).killcount = 0;
 735                 CS(this).startplaytime = time;
 736         }
 737
 738         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 739         {
 740                 .entity weaponentity = weaponentities[slot];
 741                 CL_SpawnWeaponentity(this, weaponentity);
 742         }
 743         this.alpha = default_player_alpha;
 744         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 745         this.exteriorweaponentity.alpha = default_weapon_alpha;
 746
 747         this.speedrunning = false;
 748
 749         this.counter_cnt = 0;
 750         this.fragsfilter_cnt = 0;
 751
 752         target_voicescript_clear(this);
 753
 754         // reset fields the weapons may use
 755         FOREACH(Weapons, true, {
 756                 it.wr_resetplayer(it, this);
 757                         // reload all reloadable weapons
 758                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 759                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 760                         {
 761                                 .entity weaponentity = weaponentities[slot];
 762                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 763                         }
 764                 }
 765         });
 766
 767         Unfreeze(this, false);
 768
 769         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 770         {
 771                 string s = spot.target;
 772                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 773                         spot.target = string_null;
 774                 SUB_UseTargets(spot, this, NULL);
 775                 if(g_assault || g_race)
 776                         spot.target = s;
 777         }
 778
 779         if (autocvar_spawn_debug)
 780         {
 781                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 782                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 783         }
 784
 785         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 786         {
 787                 .entity weaponentity = weaponentities[slot];
 788                 entity w_ent = this.(weaponentity);
 789                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 790                         w_ent.m_switchweapon = w_getbestweapon(this, weaponentity);
 791                 else
 792                         w_ent.m_switchweapon = WEP_Null;
 793                 w_ent.m_weapon = WEP_Null;
 794                 w_ent.weaponname = "";
 795                 w_ent.m_switchingweapon = WEP_Null;
 796                 w_ent.cnt = -1;
 797         }
 798
 799         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 800
 801         if (CS(this).impulse) ImpulseCommands(this);
 802
 803         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 804         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 805         {
 806                 .entity weaponentity = weaponentities[slot];
 807                 W_WeaponFrame(this, weaponentity);
 808         }
 809
 810         if (!warmup_stage && !this.alivetime)
 811                 this.alivetime = time;
 812
 813         antilag_clear(this, CS(this));
 814
 815         if (warmup_stage == -1)
 816                 ReadyCount();
 817 }
 818
 819 /** Called when a client spawns in the server */
 820 void PutClientInServer(entity this)
 821 {
 822         if (IS_REAL_CLIENT(this)) {
 823                 msg_entity = this;
 824                 WriteByte(MSG_ONE, SVC_SETVIEW);
 825                 WriteEntity(MSG_ONE, this);
 826         }
 827         if (game_stopped)
 828                 TRANSMUTE(Observer, this);
 829
 830         bool use_spawnpoint = (!this.enemy); // check this.enemy here since SetSpectatee will clear it
 831         SetSpectatee(this, NULL);
 832
 833         // reset player keys
 834         if(PS(this))
 835                 PS(this).itemkeys = 0;
 836
 837         MUTATOR_CALLHOOK(PutClientInServer, this);
 838
 839         if (IS_OBSERVER(this)) {
 840                 PutObserverInServer(this, false, use_spawnpoint);
 841         } else if (IS_PLAYER(this)) {
 842                 PutPlayerInServer(this);
 843         }
 844
 845         bot_relinkplayerlist();
 846 }
 847
 848 // TODO do we need all these fields, or should we stop autodetecting runtime
 849 // changes and just have a console command to update this?
 850 bool ClientInit_SendEntity(entity this, entity to, int sf)
 851 {
 852         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 853         return = true;
 854         msg_entity = to;
 855         // MSG_INIT replacement
 856         // TODO: make easier to use
 857         Registry_send_all();
 858         W_PROP_reload(MSG_ONE, to);
 859         ClientInit_misc(this);
 860         MUTATOR_CALLHOOK(Ent_Init);
 861 }
 862 void ClientInit_misc(entity this)
 863 {
 864         int channel = MSG_ONE;
 865         WriteHeader(channel, ENT_CLIENT_INIT);
 866         WriteByte(channel, g_nexball_meter_period * 32);
 867         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 868         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 869         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 870         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 871         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 872         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 873         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 874         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 875
 876         if(autocvar_sv_foginterval && world.fog != "")
 877                 WriteString(channel, world.fog);
 878         else
 879                 WriteString(channel, "");
 880         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 881         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 882         WriteByte(channel, serverflags);
 883         WriteCoord(channel, autocvar_g_trueaim_minrange);
 884 }
 885
 886 void ClientInit_CheckUpdate(entity this)
 887 {
 888         this.nextthink = time;
 889         if(this.count != autocvar_g_balance_armor_blockpercent)
 890         {
 891                 this.count = autocvar_g_balance_armor_blockpercent;
 892                 this.SendFlags |= 1;
 893         }
 894         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 895         {
 896                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 897                 this.SendFlags |= 1;
 898         }
 899 }
 900
 901 void ClientInit_Spawn()
 902 {
 903         entity e = new_pure(clientinit);
 904         setthink(e, ClientInit_CheckUpdate);
 905         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 906
 907         ClientInit_CheckUpdate(e);
 908 }
 909
 910 /*
 911 =============
 912 SetNewParms
 913 =============
 914 */
 915 void SetNewParms ()
 916 {
 917         // initialize parms for a new player
 918         parm1 = -(86400 * 366);
 919
 920         MUTATOR_CALLHOOK(SetNewParms);
 921 }
 922
 923 /*
 924 =============
 925 SetChangeParms
 926 =============
 927 */
 928 void SetChangeParms (entity this)
 929 {
 930         // save parms for level change
 931         parm1 = CS(this).parm_idlesince - time;
 932
 933         MUTATOR_CALLHOOK(SetChangeParms);
 934 }
 935
 936 /*
 937 =============
 938 DecodeLevelParms
 939 =============
 940 */
 941 void DecodeLevelParms(entity this)
 942 {
 943         // load parms
 944         CS(this).parm_idlesince = parm1;
 945         if (CS(this).parm_idlesince == -(86400 * 366))
 946                 CS(this).parm_idlesince = time;
 947
 948         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 949         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 950
 951         MUTATOR_CALLHOOK(DecodeLevelParms);
 952 }
 953
 954 void FixClientCvars(entity e)
 955 {
 956         // send prediction settings to the client
 957         if(autocvar_g_antilag == 3) // client side hitscan
 958                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 959         if(autocvar_sv_gentle)
 960                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 961
 962         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 963         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 964
 965         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 966
 967         MUTATOR_CALLHOOK(FixClientCvars, e);
 968 }
 969
 970 bool findinlist_abbrev(string tofind, string list)
 971 {
 972         if(list == "" || tofind == "")
 973                 return false; // empty list or search, just return
 974
 975         // this function allows abbreviated strings!
 976         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 977         {
 978                 return true;
 979         });
 980
 981         return false;
 982 }
 983
 984 bool PlayerInIPList(entity p, string iplist)
 985 {
 986         // some safety checks (never allow local?)
 987         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 988                 return false;
 989
 990         return findinlist_abbrev(p.netaddress, iplist);
 991 }
 992
 993 bool PlayerInIDList(entity p, string idlist)
 994 {
 995         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 996         if(!p.crypto_idfp)
 997                 return false;
 998
 999         return findinlist_abbrev(p.crypto_idfp, idlist);
1000 }
1001
1002 bool PlayerInList(entity player, string list)
1003 {
1004         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1005 }
1006
1007 #ifdef DP_EXT_PRECONNECT
1008 /*
1009 =============
1010 ClientPreConnect
1011
1012 Called once (not at each match start) when a client begins a connection to the server
1013 =============
1014 */
1015 void ClientPreConnect(entity this)
1016 {
1017         if(autocvar_sv_eventlog)
1018         {
1019                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1020                         this.playerid,
1021                         etof(this),
1022                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1023                 ));
1024         }
1025 }
1026 #endif
1027
1028 // NOTE csqc uses the active mutators list sent by this function
1029 // to understand which mutators are enabled
1030 // also note that they aren't all registered mutators, e.g. jetpack, low gravity
1031 void SendWelcomeMessage(entity this, int msg_type)
1032 {
1033         WriteByte(msg_type, boolean(autocvar_g_campaign));
1034         if (boolean(autocvar_g_campaign))
1035         {
1036                 WriteString(msg_type, Campaign_GetTitle());
1037                 WriteByte(msg_type, Campaign_GetLevelNum());
1038                 WriteString(msg_type, Campaign_GetMessage());
1039                 return;
1040         }
1041         WriteString(msg_type, autocvar_hostname);
1042         WriteString(msg_type, autocvar_g_xonoticversion);
1043         WriteByte(msg_type, CS(this).version_mismatch);
1044         WriteByte(msg_type, (CS(this).version < autocvar_gameversion));
1045         WriteByte(msg_type, map_minplayers);
1046         WriteByte(msg_type, GetPlayerLimit());
1047
1048         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1049         string modifications = M_ARGV(0, string);
1050
1051         if (!g_weaponarena && cvar("g_balance_blaster_weaponstartoverride") == 0)
1052                 modifications = strcat(modifications, ", No start weapons");
1053         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1054                 modifications = strcat(modifications, ", Low gravity");
1055         if(g_weapon_stay && !g_cts)
1056                 modifications = strcat(modifications, ", Weapons stay");
1057         if(autocvar_g_jetpack)
1058                 modifications = strcat(modifications, ", Jetpack");
1059         modifications = substring(modifications, 2, strlen(modifications) - 2);
1060
1061         WriteString(msg_type, modifications);
1062
1063         WriteString(msg_type, g_weaponarena_list);
1064
1065         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1066         {
1067                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1068                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1069         }
1070
1071         WriteString(msg_type, cache_mutatormsg);
1072
1073         WriteString(msg_type, strreplace("\\n", "\n", autocvar_sv_motd));
1074 }
1075
1076 /**
1077 =============
1078 ClientConnect
1079
1080 Called when a client connects to the server
1081 =============
1082 */
1083 void ClientConnect(entity this)
1084 {
1085         if (Ban_MaybeEnforceBanOnce(this)) return;
1086         assert(!IS_CLIENT(this), return);
1087         this.flags |= FL_CLIENT;
1088         assert(player_count >= 0, player_count = 0);
1089
1090         TRANSMUTE(Client, this);
1091         CS(this).version_nagtime = time + 10 + random() * 10;
1092
1093         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1094
1095         bot_clientconnect(this);
1096
1097         Player_DetermineForcedTeam(this);
1098
1099         TRANSMUTE(Observer, this);
1100
1101         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1102
1103         // always track bots, don't ask for cl_allow_uidtracking
1104         if (IS_BOT_CLIENT(this))
1105                 PlayerStats_GameReport_AddPlayer(this);
1106         else
1107                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1108
1109         if (autocvar_sv_eventlog)
1110                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1111
1112         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1113
1114         stuffcmd(this, clientstuff, "\n");
1115         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1116
1117         FixClientCvars(this);
1118
1119         // get version info from player
1120         stuffcmd(this, "cmd clientversion $gameversion\n");
1121
1122         // notify about available teams
1123         if (teamplay)
1124         {
1125                 entity balance = TeamBalance_CheckAllowedTeams(this);
1126                 int t = TeamBalance_GetAllowedTeams(balance);
1127                 TeamBalance_Destroy(balance);
1128                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1129         }
1130         else
1131         {
1132                 stuffcmd(this, "set _teams_available 0\n");
1133         }
1134
1135         bot_relinkplayerlist();
1136
1137         CS(this).spectatortime = time;
1138         if (blockSpectators)
1139         {
1140                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1141         }
1142
1143         CS(this).jointime = time;
1144
1145         if (IS_REAL_CLIENT(this))
1146         {
1147                 if (g_weaponarena_weapons == WEPSET(TUBA))
1148                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1149                 // quickmenu file must be put in a subfolder with an unique name
1150                 // to reduce chances of overriding custom client quickmenus
1151                 if (waypointeditor_enabled)
1152                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", "wpeditor.txt"));
1153                 else if (autocvar_sv_quickmenu_file != "" && strstrofs(autocvar_sv_quickmenu_file, "/", 0) && fexists(autocvar_sv_quickmenu_file))
1154                         stuffcmd(this, sprintf("cl_cmd settemp _hud_panel_quickmenu_file_from_server %s\n", autocvar_sv_quickmenu_file));
1155         }
1156
1157         if (!autocvar_sv_foginterval && world.fog != "")
1158                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1159
1160         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AVAILABLE_TEAMS == 2))
1161                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1162                         send_CSQC_teamnagger();
1163
1164         CSQCMODEL_AUTOINIT(this);
1165
1166         CS(this).model_randomizer = random();
1167
1168         if (IS_REAL_CLIENT(this))
1169                 sv_notice_join(this);
1170
1171         this.move_qcphysics = true;
1172
1173         // update physics stats (players can spawn before physics runs)
1174         Physics_UpdateStats(this);
1175
1176         IL_EACH(g_initforplayer, it.init_for_player, {
1177                 it.init_for_player(it, this);
1178         });
1179
1180         Handicap_Initialize(this);
1181
1182         MUTATOR_CALLHOOK(ClientConnect, this);
1183
1184         if (player_count == 1)
1185                 localcmd("\nsv_hook_firstjoin\n");
1186 }
1187 /*
1188 =============
1189 ClientDisconnect
1190
1191 Called when a client disconnects from the server
1192 =============
1193 */
1194 .entity chatbubbleentity;
1195 void player_powerups_remove_all(entity this);
1196
1197 void ClientDisconnect(entity this)
1198 {
1199         assert(IS_CLIENT(this), return);
1200
1201         PlayerStats_GameReport_FinalizePlayer(this);
1202         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1203         if (CS(this).active_minigame) part_minigame(this);
1204         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1205
1206         if (autocvar_sv_eventlog)
1207                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1208
1209         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1210
1211         if(IS_SPEC(this))
1212                 SetSpectatee(this, NULL);
1213
1214         MUTATOR_CALLHOOK(ClientDisconnect, this);
1215
1216         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1217         strfree(CS_CVAR(this).weaponorder_byimpulse);
1218         ClientState_detach(this);
1219
1220         Portal_ClearAll(this);
1221
1222         Unfreeze(this, false);
1223
1224         RemoveGrapplingHooks(this);
1225
1226         // Here, everything has been done that requires this player to be a client.
1227
1228         this.flags &= ~FL_CLIENT;
1229
1230         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1231         if (this.killindicator) delete(this.killindicator);
1232
1233         IL_EACH(g_counters, it.realowner == this,
1234         {
1235                 delete(it);
1236         });
1237
1238         WaypointSprite_PlayerGone(this);
1239
1240         bot_relinkplayerlist();
1241
1242         strfree(this.clientstatus);
1243         if (this.personal) delete(this.personal);
1244
1245         this.playerid = 0;
1246         if (warmup_stage || game_starttime > time) ReadyCount();
1247         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1248
1249         player_powerups_remove_all(this); // stop powerup sound
1250
1251         ONREMOVE(this);
1252
1253         if (player_count == 0)
1254                 localcmd("\nsv_hook_lastleave\n");
1255 }
1256
1257 void ChatBubbleThink(entity this)
1258 {
1259         this.nextthink = time;
1260         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1261         {
1262                 if(this.owner) // but why can that ever be NULL?
1263                         this.owner.chatbubbleentity = NULL;
1264                 delete(this);
1265                 return;
1266         }
1267
1268         this.mdl = "";
1269
1270         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1271         {
1272                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1273                         this.mdl = "models/sprites/minigame_busy.iqm";
1274                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1275                         this.mdl = "models/misc/chatbubble.spr";
1276         }
1277
1278         if ( this.model != this.mdl )
1279                 _setmodel(this, this.mdl);
1280
1281 }
1282
1283 void UpdateChatBubble(entity this)
1284 {
1285         if (this.alpha < 0)
1286                 return;
1287         // spawn a chatbubble entity if needed
1288         if (!this.chatbubbleentity)
1289         {
1290                 this.chatbubbleentity = new(chatbubbleentity);
1291                 this.chatbubbleentity.owner = this;
1292                 this.chatbubbleentity.exteriormodeltoclient = this;
1293                 setthink(this.chatbubbleentity, ChatBubbleThink);
1294                 this.chatbubbleentity.nextthink = time;
1295                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1296                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1297                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1298                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1299                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1300                 //this.chatbubbleentity.model = "";
1301                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1302         }
1303 }
1304
1305 void calculate_player_respawn_time(entity this)
1306 {
1307         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1308                 return;
1309
1310         float gametype_setting_tmp;
1311         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1312         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1313         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1314         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1315         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1316         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1317
1318         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1319         if (teamplay)
1320         {
1321                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1322                         if(it.team == this.team)
1323                                 ++pcount;
1324                 });
1325                 if (sdelay_small_count == 0)
1326                         sdelay_small_count = 1;
1327                 if (sdelay_large_count == 0)
1328                         sdelay_large_count = 1;
1329         }
1330         else
1331         {
1332                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1333                         ++pcount;
1334                 });
1335                 if (sdelay_small_count == 0)
1336                 {
1337                         if (IS_INDEPENDENT_PLAYER(this))
1338                         {
1339                                 // Players play independently. No point in requiring enemies.
1340                                 sdelay_small_count = 1;
1341                         }
1342                         else
1343                         {
1344                                 // Players play AGAINST each other. Enemies required.
1345                                 sdelay_small_count = 2;
1346                         }
1347                 }
1348                 if (sdelay_large_count == 0)
1349                 {
1350                         if (IS_INDEPENDENT_PLAYER(this))
1351                         {
1352                                 // Players play independently. No point in requiring enemies.
1353                                 sdelay_large_count = 1;
1354                         }
1355                         else
1356                         {
1357                                 // Players play AGAINST each other. Enemies required.
1358                                 sdelay_large_count = 2;
1359                         }
1360                 }
1361         }
1362
1363         float sdelay;
1364
1365         if (pcount <= sdelay_small_count)
1366                 sdelay = sdelay_small;
1367         else if (pcount >= sdelay_large_count)
1368                 sdelay = sdelay_large;
1369         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1370                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1371
1372         if(waves)
1373                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1374         else
1375                 this.respawn_time = time + sdelay;
1376
1377         if(sdelay < sdelay_max)
1378                 this.respawn_time_max = time + sdelay_max;
1379         else
1380                 this.respawn_time_max = this.respawn_time;
1381
1382         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1383                 this.respawn_countdown = 10; // first number to count down from is 10
1384         else
1385                 this.respawn_countdown = -1; // do not count down
1386
1387         if(autocvar_g_forced_respawn)
1388                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1389 }
1390
1391 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1392 // added to the model skins
1393 /*void UpdateColorModHack()
1394 {
1395         float c;
1396         c = this.clientcolors & 15;
1397         // LordHavoc: only bothering to support white, green, red, yellow, blue
1398              if (!teamplay) this.colormod = '0 0 0';
1399         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1400         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1401         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1402         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1403         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1404         else this.colormod = '1 1 1';
1405 }*/
1406
1407 void respawn(entity this)
1408 {
1409         bool damagedbycontents_prev = this.damagedbycontents;
1410         if(this.alpha >= 0)
1411         {
1412                 if(autocvar_g_respawn_ghosts)
1413                 {
1414                         this.solid = SOLID_NOT;
1415                         this.takedamage = DAMAGE_NO;
1416                         this.damagedbycontents = false;
1417                         set_movetype(this, MOVETYPE_FLY);
1418                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1419                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1420                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1421                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1422                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1423                         if(autocvar_g_respawn_ghosts_time > 0)
1424                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1425                 }
1426                 else
1427                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1428         }
1429
1430         CopyBody(this, 1);
1431         this.damagedbycontents = damagedbycontents_prev;
1432
1433         this.effects |= EF_NODRAW; // prevent another CopyBody
1434         PutClientInServer(this);
1435 }
1436
1437 void play_countdown(entity this, float finished, Sound samp)
1438 {
1439         TC(Sound, samp);
1440         float time_left = finished - time;
1441         if(IS_REAL_CLIENT(this) && time_left < 6 && floor(time_left - frametime) != floor(time_left))
1442                 sound(this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1443 }
1444
1445 // it removes special powerups not handled by StatusEffects
1446 void player_powerups_remove_all(entity this)
1447 {
1448         if (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1449         {
1450                 // don't play the poweroff sound when the game restarts or the player disconnects
1451                 if (time > game_starttime + 1 && IS_CLIENT(this)
1452                         && !(start_items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS)))
1453                 {
1454                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1455                 }
1456                 if (this.items & (IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS))
1457                         stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1458                 this.items -= (this.items & (IT_SUPERWEAPON | IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS));
1459         }
1460 }
1461
1462 void player_powerups(entity this)
1463 {
1464         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1465                 this.modelflags |= MF_ROCKET;
1466         else
1467                 this.modelflags &= ~MF_ROCKET;
1468
1469         this.effects &= ~EF_NODEPTHTEST;
1470
1471         if (IS_DEAD(this))
1472                 player_powerups_remove_all(this);
1473
1474         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1475                 return;
1476
1477         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1478         int items_prev = this.items;
1479
1480         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1481         {
1482                 // NOTE: superweapons are a special case and as such are handled here instead of the status effects system
1483                 if (this.items & IT_SUPERWEAPON)
1484                 {
1485                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1486                         {
1487                                 StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_NORMAL);
1488                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1489                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1490                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1491                         }
1492                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1493                         {
1494                                 // don't let them run out
1495                         }
1496                         else
1497                         {
1498                                 play_countdown(this, StatusEffects_gettime(STATUSEFFECT_Superweapons, this), SND_POWEROFF);
1499                                 if (time > StatusEffects_gettime(STATUSEFFECT_Superweapons, this))
1500                                 {
1501                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1502                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1503                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1504                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1505                                 }
1506                         }
1507                 }
1508                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1509                 {
1510                         if (time < StatusEffects_gettime(STATUSEFFECT_Superweapons, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1511                         {
1512                                 this.items = this.items | IT_SUPERWEAPON;
1513                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1514                                 {
1515                                         if(!g_cts)
1516                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1517                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1518                                 }
1519                         }
1520                         else
1521                         {
1522                                 if(StatusEffects_active(STATUSEFFECT_Superweapons, this))
1523                                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_TIMEOUT);
1524                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1525                         }
1526                 }
1527                 else if(StatusEffects_active(STATUSEFFECT_Superweapons, this)) // cheaper to check than to update each frame!
1528                 {
1529                         StatusEffects_remove(STATUSEFFECT_Superweapons, this, STATUSEFFECT_REMOVE_CLEAR);
1530                 }
1531         }
1532
1533         if(autocvar_g_nodepthtestplayers)
1534                 this.effects = this.effects | EF_NODEPTHTEST;
1535
1536         if(autocvar_g_fullbrightplayers)
1537                 this.effects = this.effects | EF_FULLBRIGHT;
1538
1539         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1540 }
1541
1542 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1543 {
1544         if(current > stable)
1545                 return current;
1546         else if(current > stable - 0.25) // when close enough, "snap"
1547                 return stable;
1548         else
1549                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1550 }
1551
1552 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1553 {
1554         if(current < stable)
1555                 return current;
1556         else if(current < stable + 0.25) // when close enough, "snap"
1557                 return stable;
1558         else
1559                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1560 }
1561
1562 void RotRegen(entity this, Resource res, float limit_mod,
1563         float regenstable, float regenfactor, float regenlinear, float regenframetime,
1564         float rotstable, float rotfactor, float rotlinear, float rotframetime)
1565 {
1566         float old = GetResource(this, res);
1567         float current = old;
1568         if(current > rotstable)
1569         {
1570                 if(rotframetime > 0)
1571                 {
1572                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1573                         current = max(rotstable, current - rotlinear * rotframetime);
1574                 }
1575         }
1576         else if(current < regenstable)
1577         {
1578                 if(regenframetime > 0)
1579                 {
1580                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1581                         current = min(regenstable, current + regenlinear * regenframetime);
1582                 }
1583         }
1584
1585         float limit = GetResourceLimit(this, res) * limit_mod;
1586         if(current > limit)
1587                 current = limit;
1588
1589         if (current != old)
1590                 SetResource(this, res, current);
1591 }
1592
1593 void player_regen(entity this)
1594 {
1595         float max_mod, regen_mod, rot_mod, limit_mod;
1596         max_mod = regen_mod = rot_mod = limit_mod = 1;
1597
1598         float regen_health = autocvar_g_balance_health_regen;
1599         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1600         float regen_health_rot = autocvar_g_balance_health_rot;
1601         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1602         float regen_health_stable = autocvar_g_balance_health_regenstable;
1603         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1604         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1605                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1606         max_mod = M_ARGV(1, float);
1607         regen_mod = M_ARGV(2, float);
1608         rot_mod = M_ARGV(3, float);
1609         limit_mod = M_ARGV(4, float);
1610         regen_health = M_ARGV(5, float);
1611         regen_health_linear = M_ARGV(6, float);
1612         regen_health_rot = M_ARGV(7, float);
1613         regen_health_rotlinear = M_ARGV(8, float);
1614         regen_health_stable = M_ARGV(9, float);
1615         regen_health_rotstable = M_ARGV(10, float);
1616
1617         float rotstable, regenstable, rotframetime, regenframetime;
1618
1619         if(!mutator_returnvalue)
1620         if(!STAT(FROZEN, this))
1621         {
1622                 regenstable = autocvar_g_balance_armor_regenstable;
1623                 rotstable = autocvar_g_balance_armor_rotstable;
1624                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1625                 rotframetime = (time > this.pauserotarmor_finished) ? (rot_mod * frametime) : 0;
1626                 RotRegen(this, RES_ARMOR, limit_mod,
1627                         regenstable, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regenframetime,
1628                         rotstable, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rotframetime);
1629
1630                 // NOTE: max_mod is only applied to health
1631                 regenstable = regen_health_stable * max_mod;
1632                 rotstable = regen_health_rotstable * max_mod;
1633                 regenframetime = (time > this.pauseregen_finished) ? (regen_mod * frametime) : 0;
1634                 rotframetime = (time > this.pauserothealth_finished) ? (rot_mod * frametime) : 0;
1635                 RotRegen(this, RES_HEALTH, limit_mod,
1636                         regenstable, regen_health, regen_health_linear, regenframetime,
1637                         rotstable, regen_health_rot, regen_health_rotlinear, rotframetime);
1638         }
1639
1640         // if player rotted to death...  die!
1641         // check this outside above checks, as player may still be able to rot to death
1642         if(GetResource(this, RES_HEALTH) < 1)
1643         {
1644                 if(this.vehicle)
1645                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1646                 if(this.event_damage)
1647                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1648         }
1649
1650         if (!(this.items & IT_UNLIMITED_AMMO))
1651         {
1652                 regenstable = autocvar_g_balance_fuel_regenstable;
1653                 rotstable = autocvar_g_balance_fuel_rotstable;
1654                 regenframetime = ((time > this.pauseregen_finished) && (this.items & ITEM_JetpackRegen.m_itemid)) ? frametime : 0;
1655                 rotframetime = (time > this.pauserotfuel_finished) ? frametime : 0;
1656                 RotRegen(this, RES_FUEL, 1,
1657                         regenstable, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, regenframetime,
1658                         rotstable, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, rotframetime);
1659         }
1660 }
1661
1662 bool zoomstate_set;
1663 void SetZoomState(entity this, float newzoom)
1664 {
1665         if(newzoom != CS(this).zoomstate)
1666         {
1667                 CS(this).zoomstate = newzoom;
1668                 ClientData_Touch(this);
1669         }
1670         zoomstate_set = true;
1671 }
1672
1673 void GetPressedKeys(entity this)
1674 {
1675         MUTATOR_CALLHOOK(GetPressedKeys, this);
1676         if (game_stopped)
1677         {
1678                 CS(this).pressedkeys = 0;
1679                 STAT(PRESSED_KEYS, this) = 0;
1680                 return;
1681         }
1682
1683         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1684         int keys = STAT(PRESSED_KEYS, this);
1685         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1686         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1687         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1688         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1689
1690         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1691         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1692         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1693         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1694         CS(this).pressedkeys = keys; // store for other users
1695
1696         STAT(PRESSED_KEYS, this) = keys;
1697 }
1698
1699 /*
1700 ======================
1701 spectate mode routines
1702 ======================
1703 */
1704
1705 void SpectateCopy(entity this, entity spectatee)
1706 {
1707         TC(Client, this); TC(Client, spectatee);
1708
1709         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1710         PS(this) = PS(spectatee);
1711         this.armortype = spectatee.armortype;
1712         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1713         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1714         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1715         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1716         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1717         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1718         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1719         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1720         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1721         CS(this).impulse = 0;
1722         this.disableclientprediction = 1; // no need to run prediction on a spectator
1723         this.items = spectatee.items;
1724         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1725         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1726         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1727         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1728         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1729         this.punchangle = spectatee.punchangle;
1730         this.view_ofs = spectatee.view_ofs;
1731         this.velocity = spectatee.velocity;
1732         this.dmg_take = spectatee.dmg_take;
1733         this.dmg_save = spectatee.dmg_save;
1734         this.dmg_inflictor = spectatee.dmg_inflictor;
1735         this.v_angle = spectatee.v_angle;
1736         this.angles = spectatee.v_angle;
1737         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1738         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1739         this.viewloc = spectatee.viewloc;
1740         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1741                 this.fixangle = true;
1742         setorigin(this, spectatee.origin);
1743         setsize(this, spectatee.mins, spectatee.maxs);
1744         SetZoomState(this, CS(spectatee).zoomstate);
1745
1746     anticheat_spectatecopy(this, spectatee);
1747         STAT(HUD, this) = STAT(HUD, spectatee);
1748         if(spectatee.vehicle)
1749     {
1750         this.angles = spectatee.v_angle;
1751
1752         //this.fixangle = false;
1753         //this.velocity = spectatee.vehicle.velocity;
1754         this.vehicle_health = spectatee.vehicle_health;
1755         this.vehicle_shield = spectatee.vehicle_shield;
1756         this.vehicle_energy = spectatee.vehicle_energy;
1757         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1758         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1759         this.vehicle_reload1 = spectatee.vehicle_reload1;
1760         this.vehicle_reload2 = spectatee.vehicle_reload2;
1761
1762         //msg_entity = this;
1763
1764        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1765             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1766            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1767            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1768
1769         //WriteByte (MSG_ONE, SVC_SETVIEW);
1770         //    WriteEntity(MSG_ONE, this);
1771         //makevectors(spectatee.v_angle);
1772         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1773     }
1774 }
1775
1776 bool SpectateUpdate(entity this)
1777 {
1778         if(!this.enemy)
1779                 return false;
1780
1781         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1782         {
1783                 SetSpectatee(this, NULL);
1784                 return false;
1785         }
1786
1787         SpectateCopy(this, this.enemy);
1788
1789         return true;
1790 }
1791
1792 bool SpectateSet(entity this)
1793 {
1794         if(!IS_PLAYER(this.enemy))
1795                 return false;
1796
1797         ClientData_Touch(this.enemy);
1798
1799         msg_entity = this;
1800         WriteByte(MSG_ONE, SVC_SETVIEW);
1801         WriteEntity(MSG_ONE, this.enemy);
1802         set_movetype(this, MOVETYPE_NONE);
1803         accuracy_resend(this);
1804
1805         if(!SpectateUpdate(this))
1806                 PutObserverInServer(this, false, true);
1807
1808         return true;
1809 }
1810
1811 void SetSpectatee_status(entity this, int spectatee_num)
1812 {
1813         int oldspectatee_status = CS(this).spectatee_status;
1814         CS(this).spectatee_status = spectatee_num;
1815
1816         if (CS(this).spectatee_status != oldspectatee_status)
1817         {
1818                 if (STAT(PRESSED_KEYS, this))
1819                 {
1820                         CS(this).pressedkeys = 0;
1821                         STAT(PRESSED_KEYS, this) = 0;
1822                 }
1823                 ClientData_Touch(this);
1824                 if (g_race || g_cts) race_InitSpectator();
1825         }
1826 }
1827
1828 void SetSpectatee(entity this, entity spectatee)
1829 {
1830         if(IS_BOT_CLIENT(this))
1831                 return; // bots abuse .enemy, this code is useless to them
1832
1833         entity old_spectatee = this.enemy;
1834
1835         this.enemy = spectatee;
1836
1837         // WEAPONTODO
1838         // these are required to fix the spectator bug with arc
1839         if(old_spectatee)
1840         {
1841                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1842                 {
1843                         .entity weaponentity = weaponentities[slot];
1844                         if(old_spectatee.(weaponentity).arc_beam)
1845                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1846                 }
1847         }
1848         if(spectatee)
1849         {
1850                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1851                 {
1852                         .entity weaponentity = weaponentities[slot];
1853                         if(spectatee.(weaponentity).arc_beam)
1854                                 spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1855                 }
1856         }
1857
1858         if (spectatee)
1859                 SetSpectatee_status(this, etof(spectatee));
1860
1861         // needed to update spectator list
1862         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1863 }
1864
1865 bool Spectate(entity this, entity pl)
1866 {
1867         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1868                 return false;
1869         pl = M_ARGV(1, entity);
1870
1871         SetSpectatee(this, pl);
1872         return SpectateSet(this);
1873 }
1874
1875 bool SpectateNext(entity this)
1876 {
1877         entity ent = find(this.enemy, classname, STR_PLAYER);
1878
1879         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1880                 ent = M_ARGV(1, entity);
1881         else if (!ent)
1882                 ent = find(ent, classname, STR_PLAYER);
1883
1884         if(ent) { SetSpectatee(this, ent); }
1885
1886         return SpectateSet(this);
1887 }
1888
1889 bool SpectatePrev(entity this)
1890 {
1891         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1892         entity ent = findchain(classname, STR_PLAYER);
1893         if (!ent) // no player
1894                 return false;
1895
1896         entity first = ent;
1897         // skip players until current spectated player
1898         if(this.enemy)
1899         while(ent && ent != this.enemy)
1900                 ent = ent.chain;
1901
1902         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1903         {
1904                 case MUT_SPECPREV_FOUND:
1905                         ent = M_ARGV(1, entity);
1906                         break;
1907                 case MUT_SPECPREV_RETURN:
1908                         return true;
1909                 case MUT_SPECPREV_CONTINUE:
1910                 default:
1911                 {
1912                         if(ent.chain)
1913                                 ent = ent.chain;
1914                         else
1915                                 ent = first;
1916                         break;
1917                 }
1918         }
1919
1920         SetSpectatee(this, ent);
1921         return SpectateSet(this);
1922 }
1923
1924 /*
1925 =============
1926 ShowRespawnCountdown()
1927
1928 Update a respawn countdown display.
1929 =============
1930 */
1931 void ShowRespawnCountdown(entity this)
1932 {
1933         float number;
1934         if(!IS_DEAD(this)) // just respawned?
1935                 return;
1936         else
1937         {
1938                 number = ceil(this.respawn_time - time);
1939                 if(number <= 0)
1940                         return;
1941                 if(number <= this.respawn_countdown)
1942                 {
1943                         this.respawn_countdown = number - 1;
1944                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1945                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1946                 }
1947         }
1948 }
1949
1950 .bool team_selected;
1951 bool ShowTeamSelection(entity this)
1952 {
1953         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1954                 return false;
1955         if (frametime) // once per frame is more than enough
1956                 stuffcmd(this, "_scoreboard_team_selection 1\n");
1957         return true;
1958 }
1959 void Join(entity this)
1960 {
1961         if (autocvar_g_campaign && !campaign_bots_may_start && !game_stopped && time >= game_starttime)
1962                 ReadyRestart(true);
1963
1964         TRANSMUTE(Player, this);
1965
1966         if(!this.team_selected)
1967         if(autocvar_g_campaign || autocvar_g_balance_teams)
1968                 TeamBalance_JoinBestTeam(this);
1969
1970         if(autocvar_g_campaign)
1971                 campaign_bots_may_start = true;
1972
1973         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1974
1975         PutClientInServer(this);
1976
1977         if(IS_PLAYER(this))
1978         if(teamplay && this.team != -1)
1979         {
1980         }
1981         else
1982                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1983         this.team_selected = false;
1984 }
1985
1986 int GetPlayerLimit()
1987 {
1988         if(g_duel)
1989                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
1990         // don't return map_maxplayers during intermission as it would interfere with MapHasRightSize()
1991         int player_limit = (autocvar_g_maxplayers >= 0 || intermission_running) ? autocvar_g_maxplayers : map_maxplayers;
1992         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
1993         player_limit = M_ARGV(0, int);
1994         return player_limit < maxclients ? player_limit : 0;
1995 }
1996
1997 /**
1998  * Determines whether the player is allowed to join. This depends on cvar
1999  * g_maxplayers, if it isn't used this function always return true, otherwise
2000  * it checks whether the number of currently playing players exceeds g_maxplayers.
2001  * @return int number of free slots for players, 0 if none
2002  */
2003 int nJoinAllowed(entity this, entity ignore)
2004 {
2005         if(!ignore)
2006         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2007         // so report 0 free slots if restricted
2008         {
2009                 if(autocvar_g_forced_team_otherwise == "spectate")
2010                         return 0;
2011                 if(autocvar_g_forced_team_otherwise == "spectator")
2012                         return 0;
2013         }
2014
2015         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2016                 return 0; // forced spectators can never join
2017
2018         // TODO simplify this
2019         int totalClients = 0;
2020         int currentlyPlaying = 0;
2021         FOREACH_CLIENT(true, {
2022                 if(it != ignore)
2023                         ++totalClients;
2024                 if(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME(it)))
2025                         ++currentlyPlaying;
2026         });
2027
2028         int player_limit = GetPlayerLimit();
2029
2030         int free_slots = 0;
2031         if (!player_limit)
2032                 free_slots = maxclients - totalClients;
2033         else if(player_limit > 0 && currentlyPlaying < player_limit)
2034                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2035
2036         static float msg_time = 0;
2037         if(this && !INGAME(this) && ignore && !free_slots && time > msg_time)
2038         {
2039                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT, player_limit);
2040                 msg_time = time + 0.5;
2041         }
2042
2043         return free_slots;
2044 }
2045
2046 bool joinAllowed(entity this)
2047 {
2048         if (CS(this).version_mismatch) return false;
2049         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2050         if (!nJoinAllowed(this, this)) return false;
2051         if (teamplay && lockteams) return false;
2052         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2053         if (ShowTeamSelection(this)) return false;
2054         return true;
2055 }
2056
2057 .string shootfromfixedorigin;
2058 .bool dualwielding_prev;
2059 bool PlayerThink(entity this)
2060 {
2061         if (game_stopped || intermission_running) {
2062                 this.modelflags &= ~MF_ROCKET;
2063                 if(intermission_running)
2064                         IntermissionThink(this);
2065                 return false;
2066         }
2067
2068         if (timeout_status == TIMEOUT_ACTIVE) {
2069                 // don't allow the player to turn around while game is paused
2070                 // FIXME turn this into CSQC stuff
2071                 this.v_angle = this.lastV_angle;
2072                 this.angles = this.lastV_angle;
2073                 this.fixangle = true;
2074         }
2075
2076         if (frametime) player_powerups(this);
2077
2078         if (IS_DEAD(this)) {
2079                 if (this.personal && g_race_qualifying) {
2080                         if (time > this.respawn_time) {
2081                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2082                                 respawn(this);
2083                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2084                         }
2085                 } else {
2086                         if (frametime) player_anim(this);
2087
2088                         if (this.respawn_flags & RESPAWN_DENY)
2089                         {
2090                                 STAT(RESPAWN_TIME, this) = 0;
2091                                 return false;
2092                         }
2093
2094                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2095
2096                         switch(this.deadflag)
2097                         {
2098                                 case DEAD_DYING:
2099                                 {
2100                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2101                                                 this.deadflag = DEAD_RESPAWNING;
2102                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2103                                                 this.deadflag = DEAD_DEAD;
2104                                         break;
2105                                 }
2106                                 case DEAD_DEAD:
2107                                 {
2108                                         if (button_pressed)
2109                                                 this.deadflag = DEAD_RESPAWNABLE;
2110                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2111                                                 this.deadflag = DEAD_RESPAWNING;
2112                                         break;
2113                                 }
2114                                 case DEAD_RESPAWNABLE:
2115                                 {
2116                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2117                                                 this.deadflag = DEAD_RESPAWNING;
2118                                         break;
2119                                 }
2120                                 case DEAD_RESPAWNING:
2121                                 {
2122                                         if (time > this.respawn_time)
2123                                         {
2124                                                 this.respawn_time = time + 1; // only retry once a second
2125                                                 this.respawn_time_max = this.respawn_time;
2126                                                 respawn(this);
2127                                         }
2128                                         break;
2129                                 }
2130                         }
2131
2132                         ShowRespawnCountdown(this);
2133
2134                         if (this.respawn_flags & RESPAWN_SILENT)
2135                                 STAT(RESPAWN_TIME, this) = 0;
2136                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2137                         {
2138                                 if (time < this.respawn_time)
2139                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2140                                 else if (this.deadflag != DEAD_RESPAWNING)
2141                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2142                         }
2143                         else
2144                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2145                 }
2146
2147                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2148                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2149                         STAT(RESPAWN_TIME, this) *= -1;
2150
2151                 return false;
2152         }
2153
2154         FixPlayermodel(this);
2155
2156         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2157                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2158                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2159         }
2160
2161         // reset gun alignment when dual wielding status changes
2162         // to ensure guns are always aligned right and left
2163         bool dualwielding = W_DualWielding(this);
2164         if(this.dualwielding_prev != dualwielding)
2165         {
2166                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2167                 this.dualwielding_prev = dualwielding;
2168         }
2169
2170         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2171         //if(frametime)
2172         {
2173                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2174                 {
2175                         .entity weaponentity = weaponentities[slot];
2176                         if(WEP_CVAR(vortex, charge_always))
2177                                 W_Vortex_Charge(this, weaponentity, frametime);
2178                         W_WeaponFrame(this, weaponentity);
2179                 }
2180         }
2181
2182         if (frametime)
2183         {
2184                 // WEAPONTODO: Add a weapon request for this
2185                 // rot vortex charge to the charge limit
2186                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2187                 {
2188                         .entity weaponentity = weaponentities[slot];
2189                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2190                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2191                 }
2192
2193                 player_regen(this);
2194                 player_anim(this);
2195                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2196         }
2197
2198         monsters_setstatus(this);
2199
2200         return true;
2201 }
2202
2203 .bool would_spectate;
2204 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2205 void ObserverOrSpectatorThink(entity this)
2206 {
2207         bool is_spec = IS_SPEC(this);
2208         if ( CS(this).impulse )
2209         {
2210                 int r = MinigameImpulse(this, CS(this).impulse);
2211                 if (!is_spec || r)
2212                         CS(this).impulse = 0;
2213
2214                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2215                 {
2216                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2217                         CS(this).impulse = 0;
2218                         return;
2219                 }
2220         }
2221
2222         if (IS_BOT_CLIENT(this) && !CS(this).autojoin_checked)
2223         {
2224                 CS(this).autojoin_checked = true;
2225                 TRANSMUTE(Player, this);
2226                 PutClientInServer(this);
2227                 return;
2228         }
2229
2230         if (this.flags & FL_JUMPRELEASED) {
2231                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2232                         this.flags &= ~FL_JUMPRELEASED;
2233                         this.flags |= FL_SPAWNING;
2234                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2235                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2236                         this.flags &= ~FL_JUMPRELEASED;
2237                         if(SpectateNext(this)) {
2238                                 TRANSMUTE(Spectator, this);
2239                         } else if (is_spec) {
2240                                 TRANSMUTE(Observer, this);
2241                                 PutClientInServer(this);
2242                         }
2243                         else
2244                                 this.would_spectate = false; // unable to spectate anyone
2245                         if (is_spec)
2246                                 CS(this).impulse = 0;
2247                 } else if (is_spec) {
2248                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2249                                 this.flags &= ~FL_JUMPRELEASED;
2250                                 if(SpectatePrev(this)) {
2251                                         TRANSMUTE(Spectator, this);
2252                                 } else {
2253                                         TRANSMUTE(Observer, this);
2254                                         PutClientInServer(this);
2255                                 }
2256                                 CS(this).impulse = 0;
2257                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2258                                 if(!observe_blocked_if_eliminated || !INGAME(this)) {
2259                                         this.would_spectate = false;
2260                                         this.flags &= ~FL_JUMPRELEASED;
2261                                         TRANSMUTE(Observer, this);
2262                                         PutClientInServer(this);
2263                                 }
2264                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2265                                 PutObserverInServer(this, false, true);
2266                                 this.would_spectate = true;
2267                         }
2268                 }
2269                 else {
2270                         bool wouldclip = CS_CVAR(this).cvar_cl_clippedspectating;
2271                         if (PHYS_INPUT_BUTTON_USE(this))
2272                                 wouldclip = !wouldclip;
2273                         int preferred_movetype = (wouldclip ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2274                         set_movetype(this, preferred_movetype);
2275                 }
2276         } else { // jump pressed
2277                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2278                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2279                         this.flags |= FL_JUMPRELEASED;
2280                         if(this.flags & FL_SPAWNING)
2281                         {
2282                                 this.flags &= ~FL_SPAWNING;
2283                                 if(joinAllowed(this))
2284                                         Join(this);
2285                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2286                                         CS(this).autojoin_checked = -1;
2287                                 return;
2288                         }
2289                 }
2290                 if(is_spec && !SpectateUpdate(this))
2291                         PutObserverInServer(this, false, true);
2292         }
2293         if (is_spec)
2294                 this.flags |= FL_CLIENT | FL_NOTARGET;
2295 }
2296
2297 void PlayerUseKey(entity this)
2298 {
2299         if (!IS_PLAYER(this))
2300                 return;
2301
2302         if(this.vehicle)
2303         {
2304                 if(!game_stopped)
2305                 {
2306                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2307                         return;
2308                 }
2309         }
2310         else if(autocvar_g_vehicles_enter)
2311         {
2312                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2313                 {
2314                         entity head, closest_target = NULL;
2315                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2316
2317                         while(head) // find the closest acceptable target to enter
2318                         {
2319                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2320                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2321                                 {
2322                                         if(closest_target)
2323                                         {
2324                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2325                                                 { closest_target = head; }
2326                                         }
2327                                         else { closest_target = head; }
2328                                 }
2329
2330                                 head = head.chain;
2331                         }
2332
2333                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2334                 }
2335         }
2336
2337         // a use key was pressed; call handlers
2338         MUTATOR_CALLHOOK(PlayerUseKey, this);
2339 }
2340
2341
2342 /*
2343 =============
2344 PlayerPreThink
2345
2346 Called every frame for each client before the physics are run
2347 =============
2348 */
2349 .float last_vehiclecheck;
2350 void PlayerPreThink (entity this)
2351 {
2352         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2353         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2354
2355         WarpZone_PlayerPhysics_FixVAngle(this);
2356
2357         if (frametime) {
2358                 // physics frames: update anticheat stuff
2359                 anticheat_prethink(this);
2360
2361                 // WORKAROUND: only use dropclient in server frames (frametime set).
2362                 // Never use it in cl_movement frames (frametime zero).
2363                 if (blockSpectators && IS_REAL_CLIENT(this)
2364                         && (IS_SPEC(this) || IS_OBSERVER(this)) && !INGAME(this)
2365                         && time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime))
2366                 {
2367                         if (dropclient_schedule(this))
2368                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2369                 }
2370         }
2371
2372         zoomstate_set = false;
2373
2374         // Check for nameless players
2375         if (this.netname == "" || this.netname != CS(this).netname_previous)
2376         {
2377                 bool assume_unchanged = (CS(this).netname_previous == "");
2378                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2379                 {
2380                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2381                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2382                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2383                         assume_unchanged = false;
2384                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2385                 }
2386                 if (isInvisibleString(this.netname))
2387                 {
2388                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2389                         sprint(this, "Warning: invisible names are not allowed.\n");
2390                         assume_unchanged = false;
2391                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2392                 }
2393                 if (!assume_unchanged && autocvar_sv_eventlog)
2394                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2395                 strcpy(CS(this).netname_previous, this.netname);
2396         }
2397
2398         // version nagging
2399         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2400         CS(this).version_nagtime = 0;
2401         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2402             // git client
2403         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2404             // git server
2405             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2406         } else {
2407             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2408             if (r < 0) { // old client
2409                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2410             } else if (r > 0) { // old server
2411                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2412             }
2413         }
2414     }
2415
2416         // GOD MODE info
2417         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2418         {
2419                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2420                 this.max_armorvalue = 0;
2421         }
2422
2423         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2424         {
2425                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2426                 {
2427                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2428                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2429                         if (this.iceblock)
2430                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2431
2432                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2433                                 Unfreeze(this, false);
2434                 }
2435                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2436                 {
2437                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2438                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2439
2440                         if (GetResource(this, RES_HEALTH) < 1)
2441                         {
2442                                 if (this.vehicle)
2443                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2444                                 if(this.event_damage)
2445                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2446                         }
2447                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2448                                 Unfreeze(this, false);
2449                 }
2450         }
2451
2452         MUTATOR_CALLHOOK(PlayerPreThink, this);
2453
2454         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2455         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2456         {
2457                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2458                 {
2459                         if(!it.owner)
2460                         {
2461                                 if(!it.team || SAME_TEAM(this, it))
2462                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2463                                 else if(autocvar_g_vehicles_steal)
2464                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2465                         }
2466                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2467                         {
2468                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2469                         }
2470                 });
2471
2472                 this.last_vehiclecheck = time + 1;
2473         }
2474
2475         if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2476                 PlayerUseKey(this);
2477         CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2478
2479         if (IS_PLAYER(this)) {
2480                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2481                         error("Client can't be spawned as player on connection!");
2482                 if(!PlayerThink(this))
2483                         return;
2484         }
2485         else if (game_stopped || intermission_running) {
2486                 if(intermission_running)
2487                         IntermissionThink(this);
2488                 return;
2489         }
2490         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2491         {
2492                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2493                 CS(this).autojoin_checked = 1;
2494                 // don't do this in ClientConnect
2495                 // many things can go wrong if a client is spawned as player on connection
2496                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2497                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2498                                 && (!teamplay || autocvar_g_balance_teams)))
2499                 {
2500                         if(joinAllowed(this))
2501                                 Join(this);
2502                         return;
2503                 }
2504         }
2505         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2506                 ObserverOrSpectatorThink(this);
2507         }
2508
2509         // WEAPONTODO: Add weapon request for this
2510         if (!zoomstate_set) {
2511                 bool wep_zoomed = false;
2512                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2513                 {
2514                         .entity weaponentity = weaponentities[slot];
2515                         Weapon thiswep = this.(weaponentity).m_weapon;
2516                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2517                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2518                 }
2519                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2520         }
2521
2522         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2523         {
2524                 CS(this).teamkill_soundtime = 0;
2525
2526                 entity e = CS(this).teamkill_soundsource;
2527                 entity oldpusher = e.pusher;
2528                 e.pusher = this;
2529                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2530                 e.pusher = oldpusher;
2531         }
2532
2533         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2534                 CS(this).taunt_soundtime = 0;
2535                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2536         }
2537
2538         target_voicescript_next(this);
2539 }
2540
2541 void DrownPlayer(entity this)
2542 {
2543         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2544                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2545         {
2546                 STAT(AIR_FINISHED, this) = 0;
2547                 return;
2548         }
2549
2550         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2551         {
2552                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2553                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2554                 STAT(AIR_FINISHED, this) = 0;
2555         }
2556         else
2557         {
2558                 if (!STAT(AIR_FINISHED, this))
2559                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2560                 if (STAT(AIR_FINISHED, this) < time)
2561                 {       // drown!
2562                         if (this.pain_finished < time)
2563                         {
2564                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2565                                 this.pain_finished = time + 0.5;
2566                         }
2567                 }
2568         }
2569 }
2570
2571 .bool move_qcphysics;
2572
2573 void Player_Physics(entity this)
2574 {
2575         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2576
2577         if(!this.move_qcphysics)
2578                 return;
2579
2580         if(!frametime && !CS(this).pm_frametime)
2581                 return;
2582
2583         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2584
2585         CS(this).pm_frametime = 0;
2586 }
2587
2588 /*
2589 =============
2590 PlayerPostThink
2591
2592 Called every frame for each client after the physics are run
2593 =============
2594 */
2595 void PlayerPostThink (entity this)
2596 {
2597         Player_Physics(this);
2598
2599         if (autocvar_sv_maxidle > 0 || (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0))
2600         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2601         if (IS_REAL_CLIENT(this))
2602         if (IS_PLAYER(this) || autocvar_sv_maxidle_alsokickspectators)
2603         if (!intermission_running) // NextLevel() kills all centerprints after setting this true
2604         {
2605                 int totalClients = 0;
2606                 if(autocvar_sv_maxidle > 0 && autocvar_sv_maxidle_slots > 0)
2607                 {
2608                         // maxidle disabled in local matches by not counting clients (totalClients 0)
2609                         if (server_is_dedicated)
2610                         {
2611                                 FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2612                                 {
2613                                         ++totalClients;
2614                                 });
2615                                 if (maxclients - totalClients > autocvar_sv_maxidle_slots)
2616                                         totalClients = 0;
2617                         }
2618                 }
2619                 else if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2620                 {
2621                         FOREACH_CLIENT(IS_REAL_CLIENT(it),
2622                         {
2623                                 ++totalClients;
2624                         });
2625                 }
2626
2627                 if (totalClients < autocvar_sv_maxidle_minplayers)
2628                 {
2629                         // idle kick disabled
2630                         CS(this).parm_idlesince = time;
2631                 }
2632                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2633                 {
2634                         if (CS(this).idlekick_lasttimeleft)
2635                         {
2636                                 CS(this).idlekick_lasttimeleft = 0;
2637                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2638                         }
2639                 }
2640                 else
2641                 {
2642                         float maxidle_time = autocvar_sv_maxidle;
2643                         if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2644                                 maxidle_time = autocvar_sv_maxidle_playertospectator;
2645                         float timeleft = ceil(maxidle_time - (time - CS(this).parm_idlesince));
2646                         float countdown_time = max(min(10, maxidle_time - 1), ceil(maxidle_time * 0.33)); // - 1 to support maxidle_time <= 10
2647                         if (timeleft == countdown_time && !CS(this).idlekick_lasttimeleft)
2648                         {
2649                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2650                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOVETOSPEC_IDLING, timeleft);
2651                                 else
2652                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2653                         }
2654                         if (timeleft <= 0) {
2655                                 if (IS_PLAYER(this) && autocvar_sv_maxidle_playertospectator > 0)
2656                                 {
2657                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_MOVETOSPEC_IDLING, this.netname, maxidle_time);
2658                                         PutObserverInServer(this, true, true);
2659                                 }
2660                                 else
2661                                 {
2662                                         if (dropclient_schedule(this))
2663                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname, maxidle_time);
2664                                 }
2665                                 return;
2666                         }
2667                         else if (timeleft <= countdown_time) {
2668                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2669                                         play2(this, SND(TALK2));
2670                                 CS(this).idlekick_lasttimeleft = timeleft;
2671                         }
2672                 }
2673         }
2674
2675         CheatFrame(this);
2676
2677         if (game_stopped)
2678         {
2679                 this.solid = SOLID_NOT;
2680                 this.takedamage = DAMAGE_NO;
2681                 set_movetype(this, MOVETYPE_NONE);
2682                 CS(this).teamkill_complain = 0;
2683                 CS(this).teamkill_soundtime = 0;
2684                 CS(this).teamkill_soundsource = NULL;
2685         }
2686
2687         if (IS_PLAYER(this)) {
2688                 if(this.death_time == time && IS_DEAD(this))
2689                 {
2690                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2691                         // once all the damage events of this frame have been processed with normal size
2692                         this.maxs.z = 5;
2693                         setsize(this, this.mins, this.maxs);
2694                 }
2695                 DrownPlayer(this);
2696                 UpdateChatBubble(this);
2697                 if (CS(this).impulse) ImpulseCommands(this);
2698                 GetPressedKeys(this);
2699                 if (game_stopped)
2700                 {
2701                         CSQCMODEL_AUTOUPDATE(this);
2702                         return;
2703                 }
2704         }
2705         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2706         {
2707                 CS(this).pressedkeys = 0;
2708                 STAT(PRESSED_KEYS, this) = 0;
2709         }
2710
2711         if (this.waypointsprite_attachedforcarrier) {
2712                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2713                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2714         }
2715
2716         CSQCMODEL_AUTOUPDATE(this);
2717 }
2718
2719 // hack to copy the button fields from the client entity to the Client State
2720 void PM_UpdateButtons(entity this, entity store)
2721 {
2722         if(this.impulse)
2723                 store.impulse = this.impulse;
2724         this.impulse = 0;
2725
2726         bool typing = this.buttonchat || this.button12;
2727
2728         store.button0 = (typing) ? 0 : this.button0;
2729         //button1?!
2730         store.button2 = (typing) ? 0 : this.button2;
2731         store.button3 = (typing) ? 0 : this.button3;
2732         store.button4 = this.button4;
2733         store.button5 = (typing) ? 0 : this.button5;
2734         store.button6 = this.button6;
2735         store.button7 = this.button7;
2736         store.button8 = this.button8;
2737         store.button9 = this.button9;
2738         store.button10 = this.button10;
2739         store.button11 = this.button11;
2740         store.button12 = this.button12;
2741         store.button13 = this.button13;
2742         store.button14 = this.button14;
2743         store.button15 = this.button15;
2744         store.button16 = this.button16;
2745         store.buttonuse = this.buttonuse;
2746         store.buttonchat = this.buttonchat;
2747
2748         store.cursor_active = this.cursor_active;
2749         store.cursor_screen = this.cursor_screen;
2750         store.cursor_trace_start = this.cursor_trace_start;
2751         store.cursor_trace_endpos = this.cursor_trace_endpos;
2752         store.cursor_trace_ent = this.cursor_trace_ent;
2753
2754         store.ping = this.ping;
2755         store.ping_packetloss = this.ping_packetloss;
2756         store.ping_movementloss = this.ping_movementloss;
2757
2758         store.v_angle = this.v_angle;
2759         store.movement = this.movement;
2760 }
2761
2762 NET_HANDLE(fpsreport, bool)
2763 {
2764         int fps = ReadShort();
2765         PlayerScore_Set(sender, SP_FPS, fps);
2766         return true;
2767 }