qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "clientkill.qh"
  21 #include "cheats.qh"
  22 #include "g_world.qh"
  23 #include "race.qh"
  24 #include "antilag.qh"
  25 #include "campaign.qh"
  26 #include "command/common.qh"
  27 #include "scores_rules.qh"
  28
  29 #include "bot/api.qh"
  30
  31 #include "../common/ent_cs.qh"
  32 #include "../common/wepent.qh"
  33 #include <common/state.qh>
  34
  35 #include <common/effects/qc/globalsound.qh>
  36
  37 #include "../common/mapobjects/func/conveyor.qh"
  38 #include "../common/mapobjects/teleporters.qh"
  39 #include "../common/mapobjects/target/spawnpoint.qh"
  40
  41 #include "../common/vehicles/all.qh"
  42
  43 #include "weapons/hitplot.qh"
  44 #include "weapons/weaponsystem.qh"
  45
  46 #include "../common/net_notice.qh"
  47 #include "../common/net_linked.qh"
  48 #include "../common/physics/player.qh"
  49
  50 #include <common/vehicles/sv_vehicles.qh>
  51
  52 #include "../common/items/_mod.qh"
  53
  54 #include "../common/mutators/mutator/waypoints/all.qh"
  55 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  56 #include <common/gamemodes/_mod.qh>
  57
  58 #include "../common/mapobjects/subs.qh"
  59 #include "../common/mapobjects/triggers.qh"
  60 #include "../common/mapobjects/trigger/secret.qh"
  61
  62 #include "../common/minigames/sv_minigames.qh"
  63
  64 #include "../common/items/inventory.qh"
  65
  66 #include "../common/monsters/sv_monsters.qh"
  67
  68 #include "../lib/warpzone/server.qh"
  69
  70 #include <common/mutators/mutator/overkill/oknex.qh>
  71
  72 STATIC_METHOD(Client, Add, void(Client this, int _team))
  73 {
  74     ClientConnect(this);
  75     TRANSMUTE(Player, this);
  76     this.frame = 12; // 7
  77     this.team = _team;
  78     PutClientInServer(this);
  79 }
  80
  81 STATIC_METHOD(Client, Remove, void(Client this))
  82 {
  83     TRANSMUTE(Observer, this);
  84     PutClientInServer(this);
  85     ClientDisconnect(this);
  86 }
  87
  88 void send_CSQC_teamnagger() {
  89         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  90 }
  91
  92 int CountSpectators(entity player, entity to)
  93 {
  94         if(!player) { return 0; } // not sure how, but best to be safe
  95
  96         int spec_count = 0;
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 spec_count++;
 101         });
 102
 103         return spec_count;
 104 }
 105
 106 void WriteSpectators(entity player, entity to)
 107 {
 108         if(!player) { return; } // not sure how, but best to be safe
 109
 110         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 111         {
 112                 WriteByte(MSG_ENTITY, num_for_edict(it));
 113         });
 114 }
 115
 116 bool ClientData_Send(entity this, entity to, int sf)
 117 {
 118         assert(to == this.owner, return false);
 119
 120         entity e = to;
 121         if (IS_SPEC(e)) e = e.enemy;
 122
 123         sf = 0;
 124         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 125         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 126         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 127         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 128
 129         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 130         WriteByte(MSG_ENTITY, sf);
 131
 132         if (sf & BIT(1))
 133                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 134
 135         if(sf & BIT(4))
 136         {
 137                 float specs = CountSpectators(e, to);
 138                 WriteByte(MSG_ENTITY, specs);
 139                 WriteSpectators(e, to);
 140         }
 141
 142         return true;
 143 }
 144
 145 void ClientData_Attach(entity this)
 146 {
 147         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 148         CS(this).clientdata.drawonlytoclient = this;
 149         CS(this).clientdata.owner = this;
 150 }
 151
 152 void ClientData_Detach(entity this)
 153 {
 154         delete(CS(this).clientdata);
 155         CS(this).clientdata = NULL;
 156 }
 157
 158 void ClientData_Touch(entity e)
 159 {
 160         entity cd = CS(e).clientdata;
 161         if (cd) { cd.SendFlags = 1; }
 162
 163         // make it spectatable
 164         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 165         {
 166                 entity cd = CS(it).clientdata;
 167                 if (cd) { cd.SendFlags = 1; }
 168         });
 169 }
 170
 171
 172 /*
 173 =============
 174 CheckPlayerModel
 175
 176 Checks if the argument string can be a valid playermodel.
 177 Returns a valid one in doubt.
 178 =============
 179 */
 180 string FallbackPlayerModel;
 181 string CheckPlayerModel(string plyermodel) {
 182         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 183         {
 184                 // note: we cannot summon Don Strunzone here, some player may
 185                 // still have the model string set. In case anyone manages how
 186                 // to change a cvar default, we'll have a small leak here.
 187                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 188         }
 189         // only in right path
 190         if( substring(plyermodel,0,14) != "models/player/")
 191                 return FallbackPlayerModel;
 192         // only good file extensions
 193         if(substring(plyermodel,-4,4) != ".zym")
 194         if(substring(plyermodel,-4,4) != ".dpm")
 195         if(substring(plyermodel,-4,4) != ".iqm")
 196         if(substring(plyermodel,-4,4) != ".md3")
 197         if(substring(plyermodel,-4,4) != ".psk")
 198                 return FallbackPlayerModel;
 199         // forbid the LOD models
 200         if(substring(plyermodel, -9,5) == "_lod1")
 201                 return FallbackPlayerModel;
 202         if(substring(plyermodel, -9,5) == "_lod2")
 203                 return FallbackPlayerModel;
 204         if(plyermodel != strtolower(plyermodel))
 205                 return FallbackPlayerModel;
 206         // also, restrict to server models
 207         if(autocvar_sv_servermodelsonly)
 208         {
 209                 if(!fexists(plyermodel))
 210                         return FallbackPlayerModel;
 211         }
 212         return plyermodel;
 213 }
 214
 215 void setplayermodel(entity e, string modelname)
 216 {
 217         precache_model(modelname);
 218         _setmodel(e, modelname);
 219         player_setupanimsformodel(e);
 220         if(!autocvar_g_debug_globalsounds)
 221                 UpdatePlayerSounds(e);
 222 }
 223
 224 /** putting a client as observer in the server */
 225 void PutObserverInServer(entity this)
 226 {
 227     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 228         PlayerState_detach(this);
 229
 230         if (IS_PLAYER(this))
 231         {
 232                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 233                 {
 234                         // despawn effect
 235                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 236                 }
 237
 238                 // was a player, recount votes and ready status
 239                 if(IS_REAL_CLIENT(this))
 240                 {
 241                         if (vote_called) { VoteCount(false); }
 242                         ReadyCount();
 243                 }
 244     }
 245
 246     {
 247         entity spot = SelectSpawnPoint(this, true);
 248         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 249         this.angles = vec2(spot.angles);
 250         this.fixangle = true;
 251         // offset it so that the spectator spawns higher off the ground, looks better this way
 252         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 253         if (IS_REAL_CLIENT(this))
 254         {
 255             msg_entity = this;
 256             WriteByte(MSG_ONE, SVC_SETVIEW);
 257             WriteEntity(MSG_ONE, this);
 258         }
 259         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 260         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 261         if(!autocvar_g_debug_globalsounds)
 262         {
 263                 // needed for player sounds
 264                 this.model = "";
 265                 FixPlayermodel(this);
 266         }
 267         setmodel(this, MDL_Null);
 268         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 269         this.view_ofs = '0 0 0';
 270     }
 271
 272     RemoveGrapplingHooks(this);
 273         Portal_ClearAll(this);
 274         Unfreeze(this);
 275         SetSpectatee(this, NULL);
 276
 277         if (this.alivetime)
 278         {
 279                 if (!warmup_stage)
 280                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 281                 this.alivetime = 0;
 282         }
 283
 284         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 285
 286         WaypointSprite_PlayerDead(this);
 287
 288         if (CS(this).killcount != FRAGS_SPECTATOR)
 289         {
 290                 if(!game_stopped)
 291                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 292                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 293         }
 294
 295         accuracy_resend(this);
 296
 297         CS(this).spectatortime = time;
 298         if(this.bot_attack)
 299                 IL_REMOVE(g_bot_targets, this);
 300         this.bot_attack = false;
 301         if(this.monster_attack)
 302                 IL_REMOVE(g_monster_targets, this);
 303         this.monster_attack = false;
 304     STAT(HUD, this) = HUD_NORMAL;
 305         TRANSMUTE(Observer, this);
 306         this.iscreature = false;
 307         this.teleportable = TELEPORT_SIMPLE;
 308         if(this.damagedbycontents)
 309                 IL_REMOVE(g_damagedbycontents, this);
 310         this.damagedbycontents = false;
 311         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 312         SetSpectatee_status(this, etof(this));
 313         this.takedamage = DAMAGE_NO;
 314         this.solid = SOLID_NOT;
 315         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 316         this.flags = FL_CLIENT | FL_NOTARGET;
 317         this.effects = 0;
 318         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 319         this.pauserotarmor_finished = 0;
 320         this.pauserothealth_finished = 0;
 321         this.pauseregen_finished = 0;
 322         this.damageforcescale = 0;
 323         this.death_time = 0;
 324         this.respawn_flags = 0;
 325         this.respawn_time = 0;
 326         STAT(RESPAWN_TIME, this) = 0;
 327         this.alpha = 0;
 328         this.scale = 0;
 329         this.fade_time = 0;
 330         this.pain_frame = 0;
 331         this.pain_finished = 0;
 332         this.strength_finished = 0;
 333         this.invincible_finished = 0;
 334         this.superweapons_finished = 0;
 335         //this.dphitcontentsmask = 0;
 336         this.dphitcontentsmask = DPCONTENTS_SOLID;
 337         if (autocvar_g_playerclip_collisions)
 338                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 339         this.pushltime = 0;
 340         this.istypefrag = 0;
 341         setthink(this, func_null);
 342         this.nextthink = 0;
 343         this.deadflag = DEAD_NO;
 344         this.crouch = false;
 345         STAT(REVIVE_PROGRESS, this) = 0;
 346         this.revival_time = 0;
 347
 348         this.items = 0;
 349         STAT(WEAPONS, this) = '0 0 0';
 350         this.drawonlytoclient = this;
 351
 352         this.viewloc = NULL;
 353
 354         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 355
 356         this.weaponmodel = "";
 357         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 358         {
 359                 this.weaponentities[slot] = NULL;
 360         }
 361         this.exteriorweaponentity = NULL;
 362         CS(this).killcount = FRAGS_SPECTATOR;
 363         this.velocity = '0 0 0';
 364         this.avelocity = '0 0 0';
 365         this.punchangle = '0 0 0';
 366         this.punchvector = '0 0 0';
 367         this.oldvelocity = this.velocity;
 368         this.fire_endtime = -1;
 369         this.event_damage = func_null;
 370         this.event_heal = func_null;
 371
 372         for(int slot = 0; slot < MAX_AXH; ++slot)
 373         {
 374                 entity axh = this.(AuxiliaryXhair[slot]);
 375                 this.(AuxiliaryXhair[slot]) = NULL;
 376
 377                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 378                         delete(axh);
 379         }
 380
 381         if (mutator_returnvalue)
 382         {
 383                 // mutator prevents resetting teams+score
 384         }
 385         else
 386         {
 387                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 388                 this.frags = FRAGS_SPECTATOR;
 389     }
 390 }
 391
 392 int player_getspecies(entity this)
 393 {
 394         get_model_parameters(this.model, this.skin);
 395         int s = get_model_parameters_species;
 396         get_model_parameters(string_null, 0);
 397         if (s < 0) return SPECIES_HUMAN;
 398         return s;
 399 }
 400
 401 .float model_randomizer;
 402 void FixPlayermodel(entity player)
 403 {
 404         string defaultmodel = "";
 405         int defaultskin = 0;
 406         if(autocvar_sv_defaultcharacter)
 407         {
 408                 if(teamplay)
 409                 {
 410                         switch(player.team)
 411                         {
 412                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 413                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 414                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 415                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 416                         }
 417                 }
 418
 419                 if(defaultmodel == "")
 420                 {
 421                         defaultmodel = autocvar_sv_defaultplayermodel;
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423                 }
 424
 425                 int n = tokenize_console(defaultmodel);
 426                 if(n > 0)
 427                 {
 428                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 429                         // However, do NOT randomize if the player-selected model is in the list.
 430                         for (int i = 0; i < n; ++i)
 431                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 432                                         defaultmodel = argv(i);
 433                 }
 434
 435                 int i = strstrofs(defaultmodel, ":", 0);
 436                 if(i >= 0)
 437                 {
 438                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 439                         defaultmodel = substring(defaultmodel, 0, i);
 440                 }
 441         }
 442         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 443         {
 444                 if(teamplay)
 445                 {
 446                         switch(player.team)
 447                         {
 448                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 449                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 450                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 451                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 452                         }
 453                 }
 454
 455                 if(!defaultskin)
 456                         defaultskin = autocvar_sv_defaultplayerskin;
 457         }
 458
 459         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 460         defaultmodel = M_ARGV(0, string);
 461         defaultskin = M_ARGV(1, int);
 462
 463         bool chmdl = false;
 464         int oldskin;
 465         if(defaultmodel != "")
 466         {
 467                 if (defaultmodel != player.model)
 468                 {
 469                         vector m1 = player.mins;
 470                         vector m2 = player.maxs;
 471                         setplayermodel (player, defaultmodel);
 472                         setsize (player, m1, m2);
 473                         chmdl = true;
 474                 }
 475
 476                 oldskin = player.skin;
 477                 player.skin = defaultskin;
 478         } else {
 479                 if (player.playermodel != player.model || player.playermodel == "")
 480                 {
 481                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, player.playermodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 if(!autocvar_sv_defaultcharacterskin)
 490                 {
 491                         oldskin = player.skin;
 492                         player.skin = stof(player.playerskin);
 493                 }
 494                 else
 495                 {
 496                         oldskin = player.skin;
 497                         player.skin = defaultskin;
 498                 }
 499         }
 500
 501         if(chmdl || oldskin != player.skin) // model or skin has changed
 502         {
 503                 player.species = player_getspecies(player); // update species
 504                 if(!autocvar_g_debug_globalsounds)
 505                         UpdatePlayerSounds(player); // update skin sounds
 506         }
 507
 508         if(!teamplay)
 509                 if(strlen(autocvar_sv_defaultplayercolors))
 510                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 511                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 512 }
 513
 514 void PutPlayerInServer(entity this)
 515 {
 516         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 517
 518         PlayerState_attach(this);
 519         accuracy_resend(this);
 520
 521         if (this.team < 0)
 522                 TeamBalance_JoinBestTeam(this);
 523
 524         entity spot = SelectSpawnPoint(this, false);
 525         if (!spot) {
 526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 527                 return; // spawn failed
 528         }
 529
 530         TRANSMUTE(Player, this);
 531
 532         CS(this).wasplayer = true;
 533         this.iscreature = true;
 534         this.teleportable = TELEPORT_NORMAL;
 535         if(!this.damagedbycontents)
 536                 IL_PUSH(g_damagedbycontents, this);
 537         this.damagedbycontents = true;
 538         set_movetype(this, MOVETYPE_WALK);
 539         this.solid = SOLID_SLIDEBOX;
 540         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 541         if (autocvar_g_playerclip_collisions)
 542                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 543         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 545         this.frags = FRAGS_PLAYER;
 546         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 547         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 548         if (autocvar__notarget)
 549                 this.flags |= FL_NOTARGET;
 550         this.takedamage = DAMAGE_AIM;
 551         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 552
 553         if (warmup_stage) {
 554                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 555                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 556                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 557                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 558                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 559                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 560                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 561                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 562                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 563         } else {
 564                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 565                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 566                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 567                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 568                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 569                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 570                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 571                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 572                 STAT(WEAPONS, this) = start_weapons;
 573                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 574                 {
 575                         GiveRandomWeapons(this, random_start_weapons_count,
 576                                 autocvar_g_random_start_weapons, random_start_ammo);
 577                 }
 578         }
 579         SetSpectatee_status(this, 0);
 580
 581         PS(this).dual_weapons = '0 0 0';
 582
 583         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 584
 585         this.items = start_items;
 586
 587         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 588         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 589         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 590         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 591         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 592         if (!sv_ready_restart_after_countdown && time < game_starttime)
 593         {
 594                 float f = game_starttime - time;
 595                 this.spawnshieldtime += f;
 596                 this.pauserotarmor_finished += f;
 597                 this.pauserothealth_finished += f;
 598                 this.pauseregen_finished += f;
 599         }
 600
 601         this.damageforcescale = 2;
 602         this.death_time = 0;
 603         this.respawn_flags = 0;
 604         this.respawn_time = 0;
 605         STAT(RESPAWN_TIME, this) = 0;
 606         this.scale = autocvar_sv_player_scale;
 607         this.fade_time = 0;
 608         this.pain_frame = 0;
 609         this.pain_finished = 0;
 610         this.pushltime = 0;
 611         setthink(this, func_null); // players have no think function
 612         this.nextthink = 0;
 613         this.dmg_team = 0;
 614         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 615
 616         this.deadflag = DEAD_NO;
 617
 618         this.angles = spot.angles;
 619         this.angles_z = 0; // never spawn tilted even if the spot says to
 620         if (IS_BOT_CLIENT(this))
 621                 this.v_angle = this.angles;
 622         this.fixangle = true; // turn this way immediately
 623         this.oldvelocity = this.velocity = '0 0 0';
 624         this.avelocity = '0 0 0';
 625         this.punchangle = '0 0 0';
 626         this.punchvector = '0 0 0';
 627
 628         this.strength_finished = 0;
 629         this.invincible_finished = 0;
 630         this.fire_endtime = -1;
 631         STAT(REVIVE_PROGRESS, this) = 0;
 632         this.revival_time = 0;
 633
 634         this.air_finished = time + 12;
 635         this.waterlevel = WATERLEVEL_NONE;
 636         this.watertype = CONTENT_EMPTY;
 637
 638         entity spawnevent = new_pure(spawnevent);
 639         spawnevent.owner = this;
 640         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 641
 642         // Cut off any still running player sounds.
 643         stopsound(this, CH_PLAYER_SINGLE);
 644
 645         this.model = "";
 646         FixPlayermodel(this);
 647         this.drawonlytoclient = NULL;
 648
 649         this.viewloc = NULL;
 650
 651         for(int slot = 0; slot < MAX_AXH; ++slot)
 652         {
 653                 entity axh = this.(AuxiliaryXhair[slot]);
 654                 this.(AuxiliaryXhair[slot]) = NULL;
 655
 656                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 657                         delete(axh);
 658         }
 659
 660         this.spawnpoint_targ = NULL;
 661
 662         this.crouch = false;
 663         this.view_ofs = STAT(PL_VIEW_OFS, this);
 664         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 665         this.spawnorigin = spot.origin;
 666         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 667         // don't reset back to last position, even if new position is stuck in solid
 668         this.oldorigin = this.origin;
 669         if(this.conveyor)
 670                 IL_REMOVE(g_conveyed, this);
 671         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 672         STAT(HUD, this) = HUD_NORMAL;
 673
 674         this.event_damage = PlayerDamage;
 675         this.event_heal = PlayerHeal;
 676
 677         if(!this.bot_attack)
 678                 IL_PUSH(g_bot_targets, this);
 679         this.bot_attack = true;
 680         if(!this.monster_attack)
 681                 IL_PUSH(g_monster_targets, this);
 682         this.monster_attack = true;
 683         navigation_dynamicgoal_init(this, false);
 684
 685         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 686
 687         // player was spectator
 688         if (CS(this).killcount == FRAGS_SPECTATOR) {
 689                 PlayerScore_Clear(this);
 690                 CS(this).killcount = 0;
 691                 CS(this).startplaytime = time;
 692         }
 693
 694         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695         {
 696                 .entity weaponentity = weaponentities[slot];
 697                 entity oldwep = this.(weaponentity);
 698                 CL_SpawnWeaponentity(this, weaponentity);
 699                 if(oldwep && oldwep.owner == this)
 700                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 701         }
 702         this.alpha = default_player_alpha;
 703         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 704         this.exteriorweaponentity.alpha = default_weapon_alpha;
 705
 706         this.speedrunning = false;
 707
 708         target_voicescript_clear(this);
 709
 710         // reset fields the weapons may use
 711         FOREACH(Weapons, true, {
 712                 it.wr_resetplayer(it, this);
 713                         // reload all reloadable weapons
 714                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 715                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716                         {
 717                                 .entity weaponentity = weaponentities[slot];
 718                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 719                         }
 720                 }
 721         });
 722
 723         {
 724                 string s = spot.target;
 725                 spot.target = string_null;
 726                 SUB_UseTargets(spot, this, NULL);
 727                 spot.target = s;
 728         }
 729
 730         Unfreeze(this);
 731
 732         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 733
 734         if (autocvar_spawn_debug)
 735         {
 736                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 737                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 738         }
 739
 740         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741         {
 742                 .entity weaponentity = weaponentities[slot];
 743                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 744                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 745                 else
 746                         this.(weaponentity).m_switchweapon = WEP_Null;
 747                 this.(weaponentity).m_weapon = WEP_Null;
 748                 this.(weaponentity).weaponname = "";
 749                 this.(weaponentity).m_switchingweapon = WEP_Null;
 750                 this.(weaponentity).cnt = -1;
 751         }
 752
 753         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 754
 755         if (CS(this).impulse) ImpulseCommands(this);
 756
 757         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758         {
 759                 .entity weaponentity = weaponentities[slot];
 760                 W_WeaponFrame(this, weaponentity);
 761         }
 762
 763         if (!warmup_stage && !this.alivetime)
 764                 this.alivetime = time;
 765
 766         antilag_clear(this, CS(this));
 767 }
 768
 769 /** Called when a client spawns in the server */
 770 void PutClientInServer(entity this)
 771 {
 772         if (IS_BOT_CLIENT(this)) {
 773                 TRANSMUTE(Player, this);
 774         } else if (IS_REAL_CLIENT(this)) {
 775                 msg_entity = this;
 776                 WriteByte(MSG_ONE, SVC_SETVIEW);
 777                 WriteEntity(MSG_ONE, this);
 778         }
 779         if (game_stopped)
 780                 TRANSMUTE(Observer, this);
 781
 782         SetSpectatee(this, NULL);
 783
 784         // reset player keys
 785         if(PS(this))
 786                 PS(this).itemkeys = 0;
 787
 788         MUTATOR_CALLHOOK(PutClientInServer, this);
 789
 790         if (IS_OBSERVER(this)) {
 791                 PutObserverInServer(this);
 792         } else if (IS_PLAYER(this)) {
 793                 PutPlayerInServer(this);
 794         }
 795 }
 796
 797 // TODO do we need all these fields, or should we stop autodetecting runtime
 798 // changes and just have a console command to update this?
 799 bool ClientInit_SendEntity(entity this, entity to, int sf)
 800 {
 801         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 802         return = true;
 803         msg_entity = to;
 804         // MSG_INIT replacement
 805         // TODO: make easier to use
 806         Registry_send_all();
 807         W_PROP_reload(MSG_ONE, to);
 808         ClientInit_misc(this);
 809         MUTATOR_CALLHOOK(Ent_Init);
 810 }
 811 void ClientInit_misc(entity this)
 812 {
 813         int channel = MSG_ONE;
 814         WriteHeader(channel, ENT_CLIENT_INIT);
 815         WriteByte(channel, g_nexball_meter_period * 32);
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 824
 825         if(sv_foginterval && world.fog != "")
 826                 WriteString(channel, world.fog);
 827         else
 828                 WriteString(channel, "");
 829         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 830         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 831         WriteByte(channel, serverflags);
 832         WriteCoord(channel, autocvar_g_trueaim_minrange);
 833 }
 834
 835 void ClientInit_CheckUpdate(entity this)
 836 {
 837         this.nextthink = time;
 838         if(this.count != autocvar_g_balance_armor_blockpercent)
 839         {
 840                 this.count = autocvar_g_balance_armor_blockpercent;
 841                 this.SendFlags |= 1;
 842         }
 843         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 844         {
 845                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 846                 this.SendFlags |= 1;
 847         }
 848 }
 849
 850 void ClientInit_Spawn()
 851 {
 852         entity e = new_pure(clientinit);
 853         setthink(e, ClientInit_CheckUpdate);
 854         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 855
 856         ClientInit_CheckUpdate(e);
 857 }
 858
 859 /*
 860 =============
 861 SetNewParms
 862 =============
 863 */
 864 void SetNewParms ()
 865 {
 866         // initialize parms for a new player
 867         parm1 = -(86400 * 366);
 868
 869         MUTATOR_CALLHOOK(SetNewParms);
 870 }
 871
 872 /*
 873 =============
 874 SetChangeParms
 875 =============
 876 */
 877 void SetChangeParms (entity this)
 878 {
 879         // save parms for level change
 880         parm1 = CS(this).parm_idlesince - time;
 881
 882         MUTATOR_CALLHOOK(SetChangeParms);
 883 }
 884
 885 /*
 886 =============
 887 DecodeLevelParms
 888 =============
 889 */
 890 void DecodeLevelParms(entity this)
 891 {
 892         // load parms
 893         CS(this).parm_idlesince = parm1;
 894         if (CS(this).parm_idlesince == -(86400 * 366))
 895                 CS(this).parm_idlesince = time;
 896
 897         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 898         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 899
 900         MUTATOR_CALLHOOK(DecodeLevelParms);
 901 }
 902
 903 void FixClientCvars(entity e)
 904 {
 905         // send prediction settings to the client
 906         stuffcmd(e, "\nin_bindmap 0 0\n");
 907         if(autocvar_g_antilag == 3) // client side hitscan
 908                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 909         if(autocvar_sv_gentle)
 910                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 911
 912         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 913         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 914
 915         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 916
 917         MUTATOR_CALLHOOK(FixClientCvars, e);
 918 }
 919
 920 bool findinlist_abbrev(string tofind, string list)
 921 {
 922         if(list == "" || tofind == "")
 923                 return false; // empty list or search, just return
 924
 925         // this function allows abbreviated strings!
 926         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 927         {
 928                 return true;
 929         });
 930
 931         return false;
 932 }
 933
 934 bool PlayerInIPList(entity p, string iplist)
 935 {
 936         // some safety checks (never allow local?)
 937         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 938                 return false;
 939
 940         return findinlist_abbrev(p.netaddress, iplist);
 941 }
 942
 943 bool PlayerInIDList(entity p, string idlist)
 944 {
 945         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 946         if(!p.crypto_idfp)
 947                 return false;
 948
 949         return findinlist_abbrev(p.crypto_idfp, idlist);
 950 }
 951
 952 bool PlayerInList(entity player, string list)
 953 {
 954         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 955 }
 956
 957 #ifdef DP_EXT_PRECONNECT
 958 /*
 959 =============
 960 ClientPreConnect
 961
 962 Called once (not at each match start) when a client begins a connection to the server
 963 =============
 964 */
 965 void ClientPreConnect(entity this)
 966 {
 967         if(autocvar_sv_eventlog)
 968         {
 969                 GameLogEcho(sprintf(":connect:%d:%d:%s",
 970                         this.playerid,
 971                         etof(this),
 972                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
 973                 ));
 974         }
 975 }
 976 #endif
 977
 978 string GetClientVersionMessage(entity this)
 979 {
 980         if (CS(this).version_mismatch) {
 981                 if(CS(this).version < autocvar_gameversion) {
 982                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 983                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
 984                 } else {
 985                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
 986                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
 987                 }
 988         } else {
 989                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
 990         }
 991 }
 992
 993 string getwelcomemessage(entity this)
 994 {
 995         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
 996         string modifications = M_ARGV(0, string);
 997
 998         if(g_weaponarena)
 999         {
1000                 if(g_weaponarena_random)
1001                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1002                 else
1003                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1004         }
1005         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1006                 modifications = strcat(modifications, ", No start weapons");
1007         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1008                 modifications = strcat(modifications, ", Low gravity");
1009         if(g_weapon_stay && !g_cts)
1010                 modifications = strcat(modifications, ", Weapons stay");
1011         if(g_jetpack)
1012                 modifications = strcat(modifications, ", Jet pack");
1013         if(autocvar_g_powerups == 0)
1014                 modifications = strcat(modifications, ", No powerups");
1015         if(autocvar_g_powerups > 0)
1016                 modifications = strcat(modifications, ", Powerups");
1017         modifications = substring(modifications, 2, strlen(modifications) - 2);
1018
1019         string versionmessage = GetClientVersionMessage(this);
1020         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1021
1022         if(modifications != "")
1023                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1024
1025         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1026         {
1027                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1028                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1029         }
1030
1031         if (cache_mutatormsg != "") {
1032                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1033         }
1034
1035         string mutator_msg = "";
1036         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1037         mutator_msg = M_ARGV(0, string);
1038
1039         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1040
1041         string motd = autocvar_sv_motd;
1042         if (motd != "") {
1043                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1044         }
1045         return s;
1046 }
1047
1048 /**
1049 =============
1050 ClientConnect
1051
1052 Called when a client connects to the server
1053 =============
1054 */
1055 void ClientConnect(entity this)
1056 {
1057         if (Ban_MaybeEnforceBanOnce(this)) return;
1058         assert(!IS_CLIENT(this), return);
1059         this.flags |= FL_CLIENT;
1060         assert(player_count >= 0, player_count = 0);
1061
1062 #ifdef WATERMARK
1063         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1064 #endif
1065         TRANSMUTE(Client, this);
1066         CS(this).version_nagtime = time + 10 + random() * 10;
1067
1068         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1069
1070         bot_clientconnect(this);
1071
1072         Player_DetermineForcedTeam(this);
1073
1074         TRANSMUTE(Observer, this);
1075
1076         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1077
1078         // always track bots, don't ask for cl_allow_uidtracking
1079         if (IS_BOT_CLIENT(this))
1080                 PlayerStats_GameReport_AddPlayer(this);
1081         else
1082                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1083
1084         if (autocvar_sv_eventlog)
1085                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1086
1087         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1088
1089         stuffcmd(this, clientstuff, "\n");
1090         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1091
1092         FixClientCvars(this);
1093
1094         // get version info from player
1095         stuffcmd(this, "cmd clientversion $gameversion\n");
1096
1097         // notify about available teams
1098         if (teamplay)
1099         {
1100                 entity balance = TeamBalance_CheckAllowedTeams(this);
1101                 int t = TeamBalance_GetAllowedTeams(balance);
1102                 TeamBalance_Destroy(balance);
1103                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1104         }
1105         else
1106         {
1107                 stuffcmd(this, "set _teams_available 0\n");
1108         }
1109
1110         bot_relinkplayerlist();
1111
1112         CS(this).spectatortime = time;
1113         if (blockSpectators)
1114         {
1115                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1116         }
1117
1118         CS(this).jointime = time;
1119
1120         if (IS_REAL_CLIENT(this))
1121         {
1122                 if (g_weaponarena_weapons == WEPSET(TUBA))
1123                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1124         }
1125
1126         if (!sv_foginterval && world.fog != "")
1127                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1128
1129         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1130                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1131                         send_CSQC_teamnagger();
1132
1133         CSQCMODEL_AUTOINIT(this);
1134
1135         CS(this).model_randomizer = random();
1136
1137         if (IS_REAL_CLIENT(this))
1138                 sv_notice_join(this);
1139
1140         // update physics stats (players can spawn before physics runs)
1141         Physics_UpdateStats(this);
1142
1143         IL_EACH(g_initforplayer, it.init_for_player, {
1144                 it.init_for_player(it, this);
1145         });
1146
1147         Handicap_Initialize(this);
1148
1149         MUTATOR_CALLHOOK(ClientConnect, this);
1150
1151         if (IS_REAL_CLIENT(this))
1152         {
1153                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1154                 {
1155                         CS(this).motd_actived_time = -1;
1156                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1157                 }
1158         }
1159 }
1160 /*
1161 =============
1162 ClientDisconnect
1163
1164 Called when a client disconnects from the server
1165 =============
1166 */
1167 .entity chatbubbleentity;
1168 void ClientDisconnect(entity this)
1169 {
1170         assert(IS_CLIENT(this), return);
1171
1172         PlayerStats_GameReport_FinalizePlayer(this);
1173         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1174         if (CS(this).active_minigame) part_minigame(this);
1175         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1176
1177         if (autocvar_sv_eventlog)
1178                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1179
1180         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1181
1182         if(IS_SPEC(this))
1183                 SetSpectatee(this, NULL);
1184
1185     MUTATOR_CALLHOOK(ClientDisconnect, this);
1186
1187         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1188         strfree(CS(this).weaponorder_byimpulse);
1189         ClientState_detach(this);
1190
1191         Portal_ClearAll(this);
1192
1193         Unfreeze(this);
1194
1195         RemoveGrapplingHooks(this);
1196
1197         // Here, everything has been done that requires this player to be a client.
1198
1199         this.flags &= ~FL_CLIENT;
1200
1201         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1202         if (this.killindicator) delete(this.killindicator);
1203
1204         WaypointSprite_PlayerGone(this);
1205
1206         bot_relinkplayerlist();
1207
1208         strfree(this.clientstatus);
1209         if (this.personal) delete(this.personal);
1210
1211         this.playerid = 0;
1212         ReadyCount();
1213         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1214
1215         ONREMOVE(this);
1216 }
1217
1218 void ChatBubbleThink(entity this)
1219 {
1220         this.nextthink = time;
1221         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1222         {
1223                 if(this.owner) // but why can that ever be NULL?
1224                         this.owner.chatbubbleentity = NULL;
1225                 delete(this);
1226                 return;
1227         }
1228
1229         this.mdl = "";
1230
1231         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1232         {
1233                 if ( CS(this.owner).active_minigame )
1234                         this.mdl = "models/sprites/minigame_busy.iqm";
1235                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1236                         this.mdl = "models/misc/chatbubble.spr";
1237         }
1238
1239         if ( this.model != this.mdl )
1240                 _setmodel(this, this.mdl);
1241
1242 }
1243
1244 void UpdateChatBubble(entity this)
1245 {
1246         if (this.alpha < 0)
1247                 return;
1248         // spawn a chatbubble entity if needed
1249         if (!this.chatbubbleentity)
1250         {
1251                 this.chatbubbleentity = new(chatbubbleentity);
1252                 this.chatbubbleentity.owner = this;
1253                 this.chatbubbleentity.exteriormodeltoclient = this;
1254                 setthink(this.chatbubbleentity, ChatBubbleThink);
1255                 this.chatbubbleentity.nextthink = time;
1256                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1257                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1258                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1259                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1260                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1261                 //this.chatbubbleentity.model = "";
1262                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1263         }
1264 }
1265
1266
1267 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1268 // added to the model skins
1269 /*void UpdateColorModHack()
1270 {
1271         float c;
1272         c = this.clientcolors & 15;
1273         // LordHavoc: only bothering to support white, green, red, yellow, blue
1274              if (!teamplay) this.colormod = '0 0 0';
1275         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1276         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1277         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1278         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1279         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1280         else this.colormod = '1 1 1';
1281 }*/
1282
1283 void respawn(entity this)
1284 {
1285         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1286         {
1287                 this.solid = SOLID_NOT;
1288                 this.takedamage = DAMAGE_NO;
1289                 set_movetype(this, MOVETYPE_FLY);
1290                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1291                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1292                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1293                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1294                 if(autocvar_g_respawn_ghosts_maxtime)
1295                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1296         }
1297
1298         CopyBody(this, 1);
1299
1300         this.effects |= EF_NODRAW; // prevent another CopyBody
1301         PutClientInServer(this);
1302 }
1303
1304 void PrintToChat(entity client, string text)
1305 {
1306         text = strcat("\{1}^7", text, "\n");
1307         sprint(client, text);
1308 }
1309
1310 void DebugPrintToChat(entity client, string text)
1311 {
1312         if (autocvar_developer)
1313         {
1314                 PrintToChat(client, text);
1315         }
1316 }
1317
1318 void PrintToChatAll(string text)
1319 {
1320         text = strcat("\{1}^7", text, "\n");
1321         bprint(text);
1322 }
1323
1324 void DebugPrintToChatAll(string text)
1325 {
1326         if (autocvar_developer)
1327         {
1328                 PrintToChatAll(text);
1329         }
1330 }
1331
1332 void PrintToChatTeam(int team_num, string text)
1333 {
1334         text = strcat("\{1}^7", text, "\n");
1335         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1336         {
1337                 if (it.team == team_num)
1338                 {
1339                         sprint(it, text);
1340                 }
1341         });
1342 }
1343
1344 void DebugPrintToChatTeam(int team_num, string text)
1345 {
1346         if (autocvar_developer)
1347         {
1348                 PrintToChatTeam(team_num, text);
1349         }
1350 }
1351
1352 void play_countdown(entity this, float finished, Sound samp)
1353 {
1354         TC(Sound, samp);
1355         if(IS_REAL_CLIENT(this))
1356                 if(floor(finished - time - frametime) != floor(finished - time))
1357                         if(finished - time < 6)
1358                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1359 }
1360
1361 void player_powerups(entity this)
1362 {
1363         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1364         int items_prev = this.items;
1365
1366         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1367                 this.modelflags |= MF_ROCKET;
1368         else
1369                 this.modelflags &= ~MF_ROCKET;
1370
1371         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1372
1373         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1374                 return;
1375
1376         Fire_ApplyDamage(this);
1377         Fire_ApplyEffect(this);
1378
1379         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1380         {
1381                 if (this.items & ITEM_Strength.m_itemid)
1382                 {
1383                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1384                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1385                         if (time > this.strength_finished)
1386                         {
1387                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1388                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1389                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1390                         }
1391                 }
1392                 else
1393                 {
1394                         if (time < this.strength_finished)
1395                         {
1396                                 this.items = this.items | ITEM_Strength.m_itemid;
1397                                 if(!g_cts)
1398                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1399                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1400                         }
1401                 }
1402                 if (this.items & ITEM_Shield.m_itemid)
1403                 {
1404                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1405                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1406                         if (time > this.invincible_finished)
1407                         {
1408                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1409                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1410                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1411                         }
1412                 }
1413                 else
1414                 {
1415                         if (time < this.invincible_finished)
1416                         {
1417                                 this.items = this.items | ITEM_Shield.m_itemid;
1418                                 if(!g_cts)
1419                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1420                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1421                         }
1422                 }
1423                 if (this.items & IT_SUPERWEAPON)
1424                 {
1425                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1426                         {
1427                                 this.superweapons_finished = 0;
1428                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1429                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1430                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1431                         }
1432                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1433                         {
1434                                 // don't let them run out
1435                         }
1436                         else
1437                         {
1438                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1439                                 if (time > this.superweapons_finished)
1440                                 {
1441                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1442                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1443                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1444                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1445                                 }
1446                         }
1447                 }
1448                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1449                 {
1450                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1451                         {
1452                                 this.items = this.items | IT_SUPERWEAPON;
1453                                 if(!g_cts)
1454                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1455                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1456                         }
1457                         else
1458                         {
1459                                 this.superweapons_finished = 0;
1460                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1461                         }
1462                 }
1463                 else
1464                 {
1465                         this.superweapons_finished = 0;
1466                 }
1467         }
1468
1469         if(autocvar_g_nodepthtestplayers)
1470                 this.effects = this.effects | EF_NODEPTHTEST;
1471
1472         if(autocvar_g_fullbrightplayers)
1473                 this.effects = this.effects | EF_FULLBRIGHT;
1474
1475         if (time >= game_starttime)
1476         if (time < this.spawnshieldtime)
1477                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1478
1479         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1480 }
1481
1482 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1483 {
1484         if(current > stable)
1485                 return current;
1486         else if(current > stable - 0.25) // when close enough, "snap"
1487                 return stable;
1488         else
1489                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1490 }
1491
1492 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1493 {
1494         if(current < stable)
1495                 return current;
1496         else if(current < stable + 0.25) // when close enough, "snap"
1497                 return stable;
1498         else
1499                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1500 }
1501
1502 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1503 {
1504         if(current > rotstable)
1505         {
1506                 if(rotframetime > 0)
1507                 {
1508                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1509                         current = max(rotstable, current - rotlinear * rotframetime);
1510                 }
1511         }
1512         else if(current < regenstable)
1513         {
1514                 if(regenframetime > 0)
1515                 {
1516                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1517                         current = min(regenstable, current + regenlinear * regenframetime);
1518                 }
1519         }
1520
1521         if(current > limit)
1522                 current = limit;
1523
1524         return current;
1525 }
1526
1527 void player_regen(entity this)
1528 {
1529         float max_mod, regen_mod, rot_mod, limit_mod;
1530         max_mod = regen_mod = rot_mod = limit_mod = 1;
1531
1532         float regen_health = autocvar_g_balance_health_regen;
1533         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1534         float regen_health_rot = autocvar_g_balance_health_rot;
1535         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1536         float regen_health_stable = autocvar_g_balance_health_regenstable;
1537         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1538         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1539                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1540         max_mod = M_ARGV(1, float);
1541         regen_mod = M_ARGV(2, float);
1542         rot_mod = M_ARGV(3, float);
1543         limit_mod = M_ARGV(4, float);
1544         regen_health = M_ARGV(5, float);
1545         regen_health_linear = M_ARGV(6, float);
1546         regen_health_rot = M_ARGV(7, float);
1547         regen_health_rotlinear = M_ARGV(8, float);
1548         regen_health_stable = M_ARGV(9, float);
1549         regen_health_rotstable = M_ARGV(10, float);
1550
1551         if(!mutator_returnvalue)
1552         if(!STAT(FROZEN, this))
1553         {
1554                 float mina, maxa, limith, limita;
1555                 maxa = autocvar_g_balance_armor_rotstable;
1556                 mina = autocvar_g_balance_armor_regenstable;
1557                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1558                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1559
1560                 regen_health_rotstable = regen_health_rotstable * max_mod;
1561                 regen_health_stable = regen_health_stable * max_mod;
1562                 limith = limith * limit_mod;
1563                 limita = limita * limit_mod;
1564
1565                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1566                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1567                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1568                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1569                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1570                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1571         }
1572
1573         // if player rotted to death...  die!
1574         // check this outside above checks, as player may still be able to rot to death
1575         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1576         {
1577                 if(this.vehicle)
1578                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1579                 if(this.event_damage)
1580                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1581         }
1582
1583         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1584         {
1585                 float minf, maxf, limitf;
1586
1587                 maxf = autocvar_g_balance_fuel_rotstable;
1588                 minf = autocvar_g_balance_fuel_regenstable;
1589                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1590
1591                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1592                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1593                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1594         }
1595 }
1596
1597 bool zoomstate_set;
1598 void SetZoomState(entity this, float newzoom)
1599 {
1600         if(newzoom != CS(this).zoomstate)
1601         {
1602                 CS(this).zoomstate = newzoom;
1603                 ClientData_Touch(this);
1604         }
1605         zoomstate_set = true;
1606 }
1607
1608 void GetPressedKeys(entity this)
1609 {
1610         MUTATOR_CALLHOOK(GetPressedKeys, this);
1611         int keys = STAT(PRESSED_KEYS, this);
1612         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1613         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1614         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1615         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1616
1617         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1618         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1619         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1620         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1621         CS(this).pressedkeys = keys; // store for other users
1622
1623         STAT(PRESSED_KEYS, this) = keys;
1624 }
1625
1626 /*
1627 ======================
1628 spectate mode routines
1629 ======================
1630 */
1631
1632 void SpectateCopy(entity this, entity spectatee)
1633 {
1634         TC(Client, this); TC(Client, spectatee);
1635
1636         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1637         PS(this) = PS(spectatee);
1638         this.armortype = spectatee.armortype;
1639         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1640         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1641         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1642         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1643         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1644         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1645         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1646         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1647         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1648         CS(this).impulse = 0;
1649         this.items = spectatee.items;
1650         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1651         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1652         this.strength_finished = spectatee.strength_finished;
1653         this.invincible_finished = spectatee.invincible_finished;
1654         this.superweapons_finished = spectatee.superweapons_finished;
1655         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1656         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1657         this.punchangle = spectatee.punchangle;
1658         this.view_ofs = spectatee.view_ofs;
1659         this.velocity = spectatee.velocity;
1660         this.dmg_take = spectatee.dmg_take;
1661         this.dmg_save = spectatee.dmg_save;
1662         this.dmg_inflictor = spectatee.dmg_inflictor;
1663         this.v_angle = spectatee.v_angle;
1664         this.angles = spectatee.v_angle;
1665         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1666         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1667         this.viewloc = spectatee.viewloc;
1668         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1669                 this.fixangle = true;
1670         setorigin(this, spectatee.origin);
1671         setsize(this, spectatee.mins, spectatee.maxs);
1672         SetZoomState(this, CS(spectatee).zoomstate);
1673
1674     anticheat_spectatecopy(this, spectatee);
1675         STAT(HUD, this) = STAT(HUD, spectatee);
1676         if(spectatee.vehicle)
1677     {
1678         this.angles = spectatee.v_angle;
1679
1680         //this.fixangle = false;
1681         //this.velocity = spectatee.vehicle.velocity;
1682         this.vehicle_health = spectatee.vehicle_health;
1683         this.vehicle_shield = spectatee.vehicle_shield;
1684         this.vehicle_energy = spectatee.vehicle_energy;
1685         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1686         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1687         this.vehicle_reload1 = spectatee.vehicle_reload1;
1688         this.vehicle_reload2 = spectatee.vehicle_reload2;
1689
1690         //msg_entity = this;
1691
1692        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1693             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1694            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1695            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1696
1697         //WriteByte (MSG_ONE, SVC_SETVIEW);
1698         //    WriteEntity(MSG_ONE, this);
1699         //makevectors(spectatee.v_angle);
1700         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1701     }
1702 }
1703
1704 bool SpectateUpdate(entity this)
1705 {
1706         if(!this.enemy)
1707                 return false;
1708
1709         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1710         {
1711                 SetSpectatee(this, NULL);
1712                 return false;
1713         }
1714
1715         SpectateCopy(this, this.enemy);
1716
1717         return true;
1718 }
1719
1720 bool SpectateSet(entity this)
1721 {
1722         if(!IS_PLAYER(this.enemy))
1723                 return false;
1724
1725         ClientData_Touch(this.enemy);
1726
1727         msg_entity = this;
1728         WriteByte(MSG_ONE, SVC_SETVIEW);
1729         WriteEntity(MSG_ONE, this.enemy);
1730         set_movetype(this, MOVETYPE_NONE);
1731         accuracy_resend(this);
1732
1733         if(!SpectateUpdate(this))
1734                 PutObserverInServer(this);
1735
1736         return true;
1737 }
1738
1739 void SetSpectatee_status(entity this, int spectatee_num)
1740 {
1741         int oldspectatee_status = CS(this).spectatee_status;
1742         CS(this).spectatee_status = spectatee_num;
1743
1744         if (CS(this).spectatee_status != oldspectatee_status)
1745         {
1746                 ClientData_Touch(this);
1747                 if (g_race || g_cts) race_InitSpectator();
1748         }
1749 }
1750
1751 void SetSpectatee(entity this, entity spectatee)
1752 {
1753         if(IS_BOT_CLIENT(this))
1754                 return; // bots abuse .enemy, this code is useless to them
1755
1756         entity old_spectatee = this.enemy;
1757
1758         this.enemy = spectatee;
1759
1760         // WEAPONTODO
1761         // these are required to fix the spectator bug with arc
1762         if(old_spectatee)
1763         {
1764                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1765                 {
1766                         .entity weaponentity = weaponentities[slot];
1767                         if(old_spectatee.(weaponentity).arc_beam)
1768                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1769                 }
1770         }
1771         if(this.enemy)
1772         {
1773                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1774                 {
1775                         .entity weaponentity = weaponentities[slot];
1776                         if(this.enemy.(weaponentity).arc_beam)
1777                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1778                 }
1779         }
1780
1781         if (this.enemy)
1782                 SetSpectatee_status(this, etof(this.enemy));
1783
1784         // needed to update spectator list
1785         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1786 }
1787
1788 bool Spectate(entity this, entity pl)
1789 {
1790         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1791                 return false;
1792         pl = M_ARGV(1, entity);
1793
1794         SetSpectatee(this, pl);
1795         return SpectateSet(this);
1796 }
1797
1798 bool SpectateNext(entity this)
1799 {
1800         entity ent = find(this.enemy, classname, STR_PLAYER);
1801
1802         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1803                 ent = M_ARGV(1, entity);
1804         else if (!ent)
1805                 ent = find(ent, classname, STR_PLAYER);
1806
1807         if(ent) { SetSpectatee(this, ent); }
1808
1809         return SpectateSet(this);
1810 }
1811
1812 bool SpectatePrev(entity this)
1813 {
1814         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1815         entity ent = findchain(classname, STR_PLAYER);
1816         if (!ent) // no player
1817                 return false;
1818
1819         entity first = ent;
1820         // skip players until current spectated player
1821         if(this.enemy)
1822         while(ent && ent != this.enemy)
1823                 ent = ent.chain;
1824
1825         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1826         {
1827                 case MUT_SPECPREV_FOUND:
1828                     ent = M_ARGV(1, entity);
1829                     break;
1830                 case MUT_SPECPREV_RETURN:
1831                     return true;
1832                 case MUT_SPECPREV_CONTINUE:
1833                 default:
1834                 {
1835                         if(ent.chain)
1836                                 ent = ent.chain;
1837                         else
1838                                 ent = first;
1839                         break;
1840                 }
1841         }
1842
1843         SetSpectatee(this, ent);
1844         return SpectateSet(this);
1845 }
1846
1847 /*
1848 =============
1849 ShowRespawnCountdown()
1850
1851 Update a respawn countdown display.
1852 =============
1853 */
1854 void ShowRespawnCountdown(entity this)
1855 {
1856         float number;
1857         if(!IS_DEAD(this)) // just respawned?
1858                 return;
1859         else
1860         {
1861                 number = ceil(this.respawn_time - time);
1862                 if(number <= 0)
1863                         return;
1864                 if(number <= this.respawn_countdown)
1865                 {
1866                         this.respawn_countdown = number - 1;
1867                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1868                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1869                 }
1870         }
1871 }
1872
1873 .bool team_selected;
1874 bool ShowTeamSelection(entity this)
1875 {
1876         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1877                 return false;
1878         stuffcmd(this, "menu_showteamselect\n");
1879         return true;
1880 }
1881 void Join(entity this)
1882 {
1883         TRANSMUTE(Player, this);
1884
1885         if(!this.team_selected)
1886         if(autocvar_g_campaign || autocvar_g_balance_teams)
1887                 TeamBalance_JoinBestTeam(this);
1888
1889         if(autocvar_g_campaign)
1890                 campaign_bots_may_start = true;
1891
1892         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1893
1894         PutClientInServer(this);
1895
1896         if(IS_PLAYER(this))
1897         if(teamplay && this.team != -1)
1898         {
1899         }
1900         else
1901                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1902         this.team_selected = false;
1903 }
1904
1905 /**
1906  * Determines whether the player is allowed to join. This depends on cvar
1907  * g_maxplayers, if it isn't used this function always return true, otherwise
1908  * it checks whether the number of currently playing players exceeds g_maxplayers.
1909  * @return int number of free slots for players, 0 if none
1910  */
1911 int nJoinAllowed(entity this, entity ignore)
1912 {
1913         if(!ignore)
1914         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1915         // so report 0 free slots if restricted
1916         {
1917                 if(autocvar_g_forced_team_otherwise == "spectate")
1918                         return 0;
1919                 if(autocvar_g_forced_team_otherwise == "spectator")
1920                         return 0;
1921         }
1922
1923         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
1924                 return 0; // forced spectators can never join
1925
1926         // TODO simplify this
1927         int totalClients = 0;
1928         int currentlyPlaying = 0;
1929         FOREACH_CLIENT(true, {
1930                 if(it != ignore)
1931                         ++totalClients;
1932                 if(IS_REAL_CLIENT(it))
1933                 if(IS_PLAYER(it) || it.caplayer)
1934                         ++currentlyPlaying;
1935         });
1936
1937         float free_slots = 0;
1938         if (!autocvar_g_maxplayers)
1939                 free_slots = maxclients - totalClients;
1940         else if(currentlyPlaying < autocvar_g_maxplayers)
1941                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1942
1943         static float join_prevent_msg_time = 0;
1944         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1945         {
1946                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1947                 join_prevent_msg_time = time + 3;
1948         }
1949
1950         return free_slots;
1951 }
1952
1953 /**
1954  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1955  * g_maxplayers_spectator_blocktime seconds
1956  */
1957 void checkSpectatorBlock(entity this)
1958 {
1959         if(IS_SPEC(this) || IS_OBSERVER(this))
1960         if(!this.caplayer)
1961         if(IS_REAL_CLIENT(this))
1962         {
1963                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1964                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1965                         dropclient(this);
1966                 }
1967         }
1968 }
1969
1970 void PrintWelcomeMessage(entity this)
1971 {
1972         if(CS(this).motd_actived_time == 0)
1973         {
1974                 if (autocvar_g_campaign) {
1975                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1976                                 CS(this).motd_actived_time = time;
1977                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1978                         }
1979                 } else {
1980                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1981                                 CS(this).motd_actived_time = time;
1982                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1983                         }
1984                 }
1985         }
1986         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
1987         {
1988                 if (autocvar_g_campaign) {
1989                         if (PHYS_INPUT_BUTTON_INFO(this))
1990                                 CS(this).motd_actived_time = time;
1991                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1992                                 CS(this).motd_actived_time = 0;
1993                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1994                         }
1995                 } else {
1996                         if (PHYS_INPUT_BUTTON_INFO(this))
1997                                 CS(this).motd_actived_time = time;
1998                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1999                                 CS(this).motd_actived_time = 0;
2000                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2001                         }
2002                 }
2003         }
2004         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2005         {
2006                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2007                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2008                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2009                 {
2010                         // instanctly hide MOTD
2011                         CS(this).motd_actived_time = 0;
2012                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2013                 }
2014         }
2015 }
2016
2017 const int MIN_SPEC_TIME = 1;
2018 bool joinAllowed(entity this)
2019 {
2020         if (CS(this).version_mismatch) return false;
2021         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2022         if (!nJoinAllowed(this, this)) return false;
2023         if (teamplay && lockteams) return false;
2024         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2025         if (ShowTeamSelection(this)) return false;
2026         return true;
2027 }
2028
2029 .int items_added;
2030 .string shootfromfixedorigin;
2031 bool PlayerThink(entity this)
2032 {
2033         if (game_stopped || intermission_running) {
2034                 this.modelflags &= ~MF_ROCKET;
2035                 if(intermission_running)
2036                         IntermissionThink(this);
2037                 return false;
2038         }
2039
2040         if (timeout_status == TIMEOUT_ACTIVE) {
2041         // don't allow the player to turn around while game is paused
2042                 // FIXME turn this into CSQC stuff
2043                 this.v_angle = this.lastV_angle;
2044                 this.angles = this.lastV_angle;
2045                 this.fixangle = true;
2046         }
2047
2048         if (frametime) player_powerups(this);
2049
2050         if (IS_DEAD(this)) {
2051                 if (this.personal && g_race_qualifying) {
2052                         if (time > this.respawn_time) {
2053                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2054                                 respawn(this);
2055                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2056                         }
2057                 } else {
2058                         if (frametime) player_anim(this);
2059
2060                         if (this.respawn_flags & RESPAWN_DENY)
2061                         {
2062                                 STAT(RESPAWN_TIME, this) = 0;
2063                                 return false;
2064                         }
2065
2066                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2067
2068                         switch(this.deadflag)
2069                         {
2070                                 case DEAD_DYING:
2071                                 {
2072                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2073                                                 this.deadflag = DEAD_RESPAWNING;
2074                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2075                                                 this.deadflag = DEAD_DEAD;
2076                                         break;
2077                                 }
2078                                 case DEAD_DEAD:
2079                                 {
2080                                         if (button_pressed)
2081                                                 this.deadflag = DEAD_RESPAWNABLE;
2082                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2083                                                 this.deadflag = DEAD_RESPAWNING;
2084                                         break;
2085                                 }
2086                                 case DEAD_RESPAWNABLE:
2087                                 {
2088                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2089                                                 this.deadflag = DEAD_RESPAWNING;
2090                                         break;
2091                                 }
2092                                 case DEAD_RESPAWNING:
2093                                 {
2094                                         if (time > this.respawn_time)
2095                                         {
2096                                                 this.respawn_time = time + 1; // only retry once a second
2097                                                 this.respawn_time_max = this.respawn_time;
2098                                                 respawn(this);
2099                                         }
2100                                         break;
2101                                 }
2102                         }
2103
2104                         ShowRespawnCountdown(this);
2105
2106                         if (this.respawn_flags & RESPAWN_SILENT)
2107                                 STAT(RESPAWN_TIME, this) = 0;
2108                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2109                         {
2110                                 if (time < this.respawn_time)
2111                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2112                                 else if (this.deadflag != DEAD_RESPAWNING)
2113                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2114                         }
2115                         else
2116                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2117                 }
2118
2119                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2120                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2121                         STAT(RESPAWN_TIME, this) *= -1;
2122
2123                 return false;
2124         }
2125
2126         FixPlayermodel(this);
2127
2128         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2129                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2130                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2131         }
2132
2133         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2134         //if(frametime)
2135         {
2136                 this.items &= ~this.items_added;
2137
2138                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2139                 {
2140                         .entity weaponentity = weaponentities[slot];
2141                         W_WeaponFrame(this, weaponentity);
2142                 }
2143
2144                 this.items_added = 0;
2145                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2146             this.items_added |= IT_FUEL;
2147
2148                 this.items |= this.items_added;
2149         }
2150
2151         player_regen(this);
2152
2153         // WEAPONTODO: Add a weapon request for this
2154         // rot vortex charge to the charge limit
2155         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2156         {
2157                 .entity weaponentity = weaponentities[slot];
2158                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2159                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2160         }
2161
2162         if (frametime) player_anim(this);
2163
2164         // secret status
2165         secrets_setstatus(this);
2166
2167         // monsters status
2168         monsters_setstatus(this);
2169
2170         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2171
2172         return true;
2173 }
2174
2175 .bool would_spectate;
2176 void ObserverThink(entity this)
2177 {
2178         if ( CS(this).impulse )
2179         {
2180                 MinigameImpulse(this, CS(this).impulse);
2181                 CS(this).impulse = 0;
2182         }
2183
2184         if (this.flags & FL_JUMPRELEASED) {
2185                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2186                         this.flags &= ~FL_JUMPRELEASED;
2187                         this.flags |= FL_SPAWNING;
2188                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2189                         this.flags &= ~FL_JUMPRELEASED;
2190                         if(SpectateNext(this)) {
2191                                 TRANSMUTE(Spectator, this);
2192                         }
2193                 } else {
2194                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2195                         set_movetype(this, preferred_movetype);
2196                 }
2197         } else {
2198                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2199                         this.flags |= FL_JUMPRELEASED;
2200                         if(this.flags & FL_SPAWNING)
2201                         {
2202                                 this.flags &= ~FL_SPAWNING;
2203                                 Join(this);
2204                                 return;
2205                         }
2206                 }
2207         }
2208 }
2209
2210 void SpectatorThink(entity this)
2211 {
2212         if ( CS(this).impulse )
2213         {
2214                 if(MinigameImpulse(this, CS(this).impulse))
2215                         CS(this).impulse = 0;
2216
2217                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2218                 {
2219                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2220                         CS(this).impulse = 0;
2221                         return;
2222                 }
2223         }
2224
2225         if (this.flags & FL_JUMPRELEASED) {
2226                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2227                         this.flags &= ~FL_JUMPRELEASED;
2228                         this.flags |= FL_SPAWNING;
2229                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2230                         this.flags &= ~FL_JUMPRELEASED;
2231                         if(SpectateNext(this)) {
2232                                 TRANSMUTE(Spectator, this);
2233                         } else {
2234                                 TRANSMUTE(Observer, this);
2235                                 PutClientInServer(this);
2236                         }
2237                         CS(this).impulse = 0;
2238                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2239                         this.flags &= ~FL_JUMPRELEASED;
2240                         if(SpectatePrev(this)) {
2241                                 TRANSMUTE(Spectator, this);
2242                         } else {
2243                                 TRANSMUTE(Observer, this);
2244                                 PutClientInServer(this);
2245                         }
2246                         CS(this).impulse = 0;
2247                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2248                         this.would_spectate = false;
2249                         this.flags &= ~FL_JUMPRELEASED;
2250                         TRANSMUTE(Observer, this);
2251                         PutClientInServer(this);
2252                 } else {
2253                         if(!SpectateUpdate(this))
2254                         {
2255                                 if(!SpectateNext(this))
2256                                 {
2257                                         PutObserverInServer(this);
2258                                         this.would_spectate = true;
2259                                 }
2260                         }
2261                 }
2262         } else {
2263                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2264                         this.flags |= FL_JUMPRELEASED;
2265                         if(this.flags & FL_SPAWNING)
2266                         {
2267                                 this.flags &= ~FL_SPAWNING;
2268                                 Join(this);
2269                                 return;
2270                         }
2271                 }
2272                 if(!SpectateUpdate(this))
2273                         PutObserverInServer(this);
2274         }
2275
2276         this.flags |= FL_CLIENT | FL_NOTARGET;
2277 }
2278
2279 void PlayerUseKey(entity this)
2280 {
2281         if (!IS_PLAYER(this))
2282                 return;
2283
2284         if(this.vehicle)
2285         {
2286                 if(!game_stopped)
2287                 {
2288                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2289                         return;
2290                 }
2291         }
2292         else if(autocvar_g_vehicles_enter)
2293         {
2294                 if(!STAT(FROZEN, this))
2295                 if(!IS_DEAD(this))
2296                 if(!game_stopped)
2297                 {
2298                         entity head, closest_target = NULL;
2299                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2300
2301                         while(head) // find the closest acceptable target to enter
2302                         {
2303                                 if(IS_VEHICLE(head))
2304                                 if(!IS_DEAD(head))
2305                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2306                                 if(head.takedamage != DAMAGE_NO)
2307                                 {
2308                                         if(closest_target)
2309                                         {
2310                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2311                                                 { closest_target = head; }
2312                                         }
2313                                         else { closest_target = head; }
2314                                 }
2315
2316                                 head = head.chain;
2317                         }
2318
2319                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2320                 }
2321         }
2322
2323         // a use key was pressed; call handlers
2324         MUTATOR_CALLHOOK(PlayerUseKey, this);
2325 }
2326
2327
2328 /*
2329 =============
2330 PlayerPreThink
2331
2332 Called every frame for each client before the physics are run
2333 =============
2334 */
2335 .float last_vehiclecheck;
2336 void PlayerPreThink (entity this)
2337 {
2338         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2339         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2340
2341         WarpZone_PlayerPhysics_FixVAngle(this);
2342
2343         if (frametime) {
2344                 // physics frames: update anticheat stuff
2345                 anticheat_prethink(this);
2346         }
2347
2348         if (blockSpectators && frametime) {
2349                 // WORKAROUND: only use dropclient in server frames (frametime set).
2350                 // Never use it in cl_movement frames (frametime zero).
2351                 checkSpectatorBlock(this);
2352         }
2353
2354         zoomstate_set = false;
2355
2356         // Check for nameless players
2357         if (this.netname == "" || this.netname != CS(this).netname_previous)
2358         {
2359                 bool assume_unchanged = (CS(this).netname_previous == "");
2360                 if (isInvisibleString(this.netname))
2361                 {
2362                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2363                         assume_unchanged = false;
2364                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2365                 }
2366                 if (!assume_unchanged && autocvar_sv_eventlog)
2367                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2368                 strcpy(CS(this).netname_previous, this.netname);
2369         }
2370
2371         // version nagging
2372         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2373         CS(this).version_nagtime = 0;
2374         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2375             // git client
2376         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2377             // git server
2378             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2379         } else {
2380             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2381             if (r < 0) { // old client
2382                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2383             } else if (r > 0) { // old server
2384                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2385             }
2386         }
2387     }
2388
2389         // GOD MODE info
2390         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2391         {
2392                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2393                 this.max_armorvalue = 0;
2394         }
2395
2396         if(IS_PLAYER(this))
2397         {
2398                 if (STAT(FROZEN, this) == 2)
2399                 {
2400                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2401                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2402                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2403
2404                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2405                                 Unfreeze(this);
2406                 }
2407                 else if (STAT(FROZEN, this) == 3)
2408                 {
2409                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2410                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2411
2412                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2413                         {
2414                                 if (this.vehicle)
2415                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2416                                 if(this.event_damage)
2417                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2418                         }
2419                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2420                                 Unfreeze(this);
2421                 }
2422         }
2423
2424         MUTATOR_CALLHOOK(PlayerPreThink, this);
2425
2426         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2427         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2428         {
2429                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2430                 {
2431                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2432                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2433                         {
2434                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2435                         }
2436                         else if(!it.owner)
2437                         {
2438                                 if(!it.team || SAME_TEAM(this, it))
2439                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2440                                 else if(autocvar_g_vehicles_steal)
2441                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2442                         }
2443                 });
2444
2445                 this.last_vehiclecheck = time + 1;
2446         }
2447
2448         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2449         {
2450                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2451                         PlayerUseKey(this);
2452                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2453         }
2454
2455         if (IS_REAL_CLIENT(this))
2456                 PrintWelcomeMessage(this);
2457
2458         if (IS_PLAYER(this)) {
2459                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2460                         error("Client can't be spawned as player on connection!");
2461                 if(!PlayerThink(this))
2462                         return;
2463         }
2464         else if (game_stopped || intermission_running) {
2465                 if(intermission_running)
2466                         IntermissionThink(this);
2467                 return;
2468         }
2469         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2470         {
2471                 CS(this).autojoin_checked = true;
2472                 // don't do this in ClientConnect
2473                 // many things can go wrong if a client is spawned as player on connection
2474                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2475                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2476                                 && (!teamplay || autocvar_g_balance_teams)))
2477                 {
2478                         campaign_bots_may_start = true;
2479                         Join(this);
2480                         return;
2481                 }
2482         }
2483         else if (IS_OBSERVER(this)) {
2484                 ObserverThink(this);
2485         }
2486         else if (IS_SPEC(this)) {
2487                 SpectatorThink(this);
2488         }
2489
2490         // WEAPONTODO: Add weapon request for this
2491         if (!zoomstate_set) {
2492                 bool wep_zoomed = false;
2493                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2494                 {
2495                         .entity weaponentity = weaponentities[slot];
2496                         Weapon thiswep = this.(weaponentity).m_weapon;
2497                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2498                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2499                 }
2500                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2501     }
2502
2503         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2504         {
2505                 CS(this).teamkill_soundtime = 0;
2506
2507                 entity e = CS(this).teamkill_soundsource;
2508                 entity oldpusher = e.pusher;
2509                 e.pusher = this;
2510                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2511                 e.pusher = oldpusher;
2512         }
2513
2514         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2515                 CS(this).taunt_soundtime = 0;
2516                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2517         }
2518
2519         target_voicescript_next(this);
2520
2521         // WEAPONTODO: Move into weaponsystem somehow
2522         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2523         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2524         {
2525                 .entity weaponentity = weaponentities[slot];
2526                 if(this.(weaponentity).m_weapon == WEP_Null)
2527                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2528         }
2529 }
2530
2531 void DrownPlayer(entity this)
2532 {
2533         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2534                 return;
2535
2536         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2537         {
2538                 if(this.air_finished < time)
2539                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2540                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2541         }
2542         else if (this.air_finished < time)
2543         {       // drown!
2544                 if (this.pain_finished < time)
2545                 {
2546                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2547                         this.pain_finished = time + 0.5;
2548                 }
2549         }
2550 }
2551
2552 .bool move_qcphysics;
2553
2554 void Player_Physics(entity this)
2555 {
2556         set_movetype(this, this.move_movetype);
2557
2558         if(!this.move_qcphysics)
2559                 return;
2560
2561         if(!frametime && !CS(this).pm_frametime)
2562                 return;
2563
2564         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2565
2566         CS(this).pm_frametime = 0;
2567 }
2568
2569 /*
2570 =============
2571 PlayerPostThink
2572
2573 Called every frame for each client after the physics are run
2574 =============
2575 */
2576 void PlayerPostThink (entity this)
2577 {
2578         Player_Physics(this);
2579
2580         if (sv_maxidle > 0)
2581         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2582         if (IS_REAL_CLIENT(this))
2583         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2584         {
2585                 int totalClients = 0;
2586                 if(sv_maxidle_slots > 0)
2587                 {
2588                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2589                         {
2590                                 ++totalClients;
2591                         });
2592                 }
2593
2594                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2595                 { /* do nothing */ }
2596                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2597                 {
2598                         if (CS(this).idlekick_lasttimeleft)
2599                         {
2600                                 CS(this).idlekick_lasttimeleft = 0;
2601                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2602                         }
2603                 }
2604                 else
2605                 {
2606                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2607                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2608                                 if (!CS(this).idlekick_lasttimeleft)
2609                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2610                         }
2611                         if (timeleft <= 0) {
2612                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2613                                 dropclient(this);
2614                                 return;
2615                         }
2616                         else if (timeleft <= 10) {
2617                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2618                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2619                 }
2620                                 CS(this).idlekick_lasttimeleft = timeleft;
2621                         }
2622                 }
2623         }
2624
2625         CheatFrame(this);
2626
2627         if (game_stopped)
2628         {
2629                 this.solid = SOLID_NOT;
2630                 this.takedamage = DAMAGE_NO;
2631                 set_movetype(this, MOVETYPE_NONE);
2632         }
2633
2634         if (IS_PLAYER(this)) {
2635                 if(this.death_time == time && IS_DEAD(this))
2636                 {
2637                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2638                         // once all the damage events of this frame have been processed with normal size
2639                         this.maxs.z = 5;
2640                         setsize(this, this.mins, this.maxs);
2641                 }
2642                 DrownPlayer(this);
2643                 UpdateChatBubble(this);
2644                 if (CS(this).impulse) ImpulseCommands(this);
2645                 if (game_stopped)
2646                 {
2647                         CSQCMODEL_AUTOUPDATE(this);
2648                         return;
2649                 }
2650                 GetPressedKeys(this);
2651         }
2652
2653         if (this.waypointsprite_attachedforcarrier) {
2654             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2655                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2656     }
2657
2658         CSQCMODEL_AUTOUPDATE(this);
2659 }
2660
2661 // hack to copy the button fields from the client entity to the Client State
2662 void PM_UpdateButtons(entity this, entity store)
2663 {
2664         if(this.impulse)
2665                 store.impulse = this.impulse;
2666         this.impulse = 0;
2667
2668         bool typing = this.buttonchat;
2669
2670         store.button0 = (typing) ? 0 : this.button0;
2671         //button1?!
2672         store.button2 = (typing) ? 0 : this.button2;
2673         store.button3 = (typing) ? 0 : this.button3;
2674         store.button4 = this.button4;
2675         store.button5 = (typing) ? 0 : this.button5;
2676         store.button6 = this.button6;
2677         store.button7 = this.button7;
2678         store.button8 = this.button8;
2679         store.button9 = this.button9;
2680         store.button10 = this.button10;
2681         store.button11 = this.button11;
2682         store.button12 = this.button12;
2683         store.button13 = this.button13;
2684         store.button14 = this.button14;
2685         store.button15 = this.button15;
2686         store.button16 = this.button16;
2687         store.buttonuse = this.buttonuse;
2688         store.buttonchat = this.buttonchat;
2689
2690         store.cursor_active = this.cursor_active;
2691         store.cursor_screen = this.cursor_screen;
2692         store.cursor_trace_start = this.cursor_trace_start;
2693         store.cursor_trace_endpos = this.cursor_trace_endpos;
2694         store.cursor_trace_ent = this.cursor_trace_ent;
2695
2696         store.ping = this.ping;
2697         store.ping_packetloss = this.ping_packetloss;
2698         store.ping_movementloss = this.ping_movementloss;
2699
2700         store.v_angle = this.v_angle;
2701         store.movement = (typing) ? '0 0 0' : this.movement;
2702 }
2703
2704 NET_HANDLE(fpsreport, bool)
2705 {
2706         int fps = ReadShort();
2707         PlayerScore_Set(sender, SP_FPS, fps);
2708         return true;
2709 }