qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (CS(e).race_completed)       sf |= 1; // forced scoreboard
 114         if (CS(to).spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (CS(e).zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 void SetSpectatee(entity this, entity spectatee);
 158 void SetSpectatee_status(entity this, int spectatee_num);
 159
 160
 161 /*
 162 =============
 163 CheckPlayerModel
 164
 165 Checks if the argument string can be a valid playermodel.
 166 Returns a valid one in doubt.
 167 =============
 168 */
 169 string FallbackPlayerModel;
 170 string CheckPlayerModel(string plyermodel) {
 171         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 172         {
 173                 // note: we cannot summon Don Strunzone here, some player may
 174                 // still have the model string set. In case anyone manages how
 175                 // to change a cvar default, we'll have a small leak here.
 176                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 177         }
 178         // only in right path
 179         if( substring(plyermodel,0,14) != "models/player/")
 180                 return FallbackPlayerModel;
 181         // only good file extensions
 182         if(substring(plyermodel,-4,4) != ".zym")
 183         if(substring(plyermodel,-4,4) != ".dpm")
 184         if(substring(plyermodel,-4,4) != ".iqm")
 185         if(substring(plyermodel,-4,4) != ".md3")
 186         if(substring(plyermodel,-4,4) != ".psk")
 187                 return FallbackPlayerModel;
 188         // forbid the LOD models
 189         if(substring(plyermodel, -9,5) == "_lod1")
 190                 return FallbackPlayerModel;
 191         if(substring(plyermodel, -9,5) == "_lod2")
 192                 return FallbackPlayerModel;
 193         if(plyermodel != strtolower(plyermodel))
 194                 return FallbackPlayerModel;
 195         // also, restrict to server models
 196         if(autocvar_sv_servermodelsonly)
 197         {
 198                 if(!fexists(plyermodel))
 199                         return FallbackPlayerModel;
 200         }
 201         return plyermodel;
 202 }
 203
 204 void setplayermodel(entity e, string modelname)
 205 {
 206         precache_model(modelname);
 207         _setmodel(e, modelname);
 208         player_setupanimsformodel(e);
 209         if(!autocvar_g_debug_globalsounds)
 210                 UpdatePlayerSounds(e);
 211 }
 212
 213 void FixPlayermodel(entity player);
 214 /** putting a client as observer in the server */
 215 void PutObserverInServer(entity this)
 216 {
 217     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 218         PlayerState_detach(this);
 219
 220         if (IS_PLAYER(this) && this.health >= 1) {
 221         // despawn effect
 222                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 223     }
 224
 225     {
 226         entity spot = SelectSpawnPoint(this, true);
 227         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 228         this.angles = vec2(spot.angles);
 229         this.fixangle = true;
 230         // offset it so that the spectator spawns higher off the ground, looks better this way
 231         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 232         if (IS_REAL_CLIENT(this))
 233         {
 234             msg_entity = this;
 235             WriteByte(MSG_ONE, SVC_SETVIEW);
 236             WriteEntity(MSG_ONE, this);
 237         }
 238         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 239         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 240         if(!autocvar_g_debug_globalsounds)
 241         {
 242                 // needed for player sounds
 243                 this.model = "";
 244                 FixPlayermodel(this);
 245         }
 246         setmodel(this, MDL_Null);
 247         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 248         this.view_ofs = '0 0 0';
 249     }
 250
 251     RemoveGrapplingHooks(this);
 252         Portal_ClearAll(this);
 253         Unfreeze(this);
 254         SetSpectatee(this, NULL);
 255
 256         if (this.alivetime)
 257         {
 258                 if (!warmup_stage)
 259                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 260                 this.alivetime = 0;
 261         }
 262
 263         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 264
 265         WaypointSprite_PlayerDead(this);
 266
 267         if (mutator_returnvalue) {
 268             // mutator prevents resetting teams+score
 269         } else {
 270                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 271         this.frags = FRAGS_SPECTATOR;
 272         PlayerScore_Clear(this);  // clear scores when needed
 273     }
 274
 275         if (CS(this).killcount != FRAGS_SPECTATOR)
 276         {
 277                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 278                 if(!game_stopped)
 279                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 280                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 281
 282                 if(!CS(this).just_joined)
 283                         LogTeamchange(this.playerid, -1, 4);
 284                 else
 285                         CS(this).just_joined = false;
 286         }
 287
 288         accuracy_resend(this);
 289
 290         CS(this).spectatortime = time;
 291         if(this.bot_attack)
 292                 IL_REMOVE(g_bot_targets, this);
 293         this.bot_attack = false;
 294     this.hud = HUD_NORMAL;
 295         TRANSMUTE(Observer, this);
 296         this.iscreature = false;
 297         this.teleportable = TELEPORT_SIMPLE;
 298         if(this.damagedbycontents)
 299                 IL_REMOVE(g_damagedbycontents, this);
 300         this.damagedbycontents = false;
 301         this.health = FRAGS_SPECTATOR;
 302         SetSpectatee_status(this, etof(this));
 303         this.takedamage = DAMAGE_NO;
 304         this.solid = SOLID_NOT;
 305         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 306         this.flags = FL_CLIENT | FL_NOTARGET;
 307         this.armorvalue = 666;
 308         this.effects = 0;
 309         this.armorvalue = autocvar_g_balance_armor_start;
 310         this.pauserotarmor_finished = 0;
 311         this.pauserothealth_finished = 0;
 312         this.pauseregen_finished = 0;
 313         this.damageforcescale = 0;
 314         this.death_time = 0;
 315         this.respawn_flags = 0;
 316         this.respawn_time = 0;
 317         this.stat_respawn_time = 0;
 318         this.alpha = 0;
 319         this.scale = 0;
 320         this.fade_time = 0;
 321         this.pain_frame = 0;
 322         this.pain_finished = 0;
 323         this.strength_finished = 0;
 324         this.invincible_finished = 0;
 325         this.superweapons_finished = 0;
 326         this.pushltime = 0;
 327         this.istypefrag = 0;
 328         setthink(this, func_null);
 329         this.nextthink = 0;
 330         this.deadflag = DEAD_NO;
 331         this.crouch = false;
 332         this.revive_progress = 0;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         this.drawonlytoclient = this;
 338
 339         this.weaponmodel = "";
 340         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 341         {
 342                 this.weaponentities[slot] = NULL;
 343         }
 344         this.exteriorweaponentity = NULL;
 345         CS(this).killcount = FRAGS_SPECTATOR;
 346         this.velocity = '0 0 0';
 347         this.avelocity = '0 0 0';
 348         this.punchangle = '0 0 0';
 349         this.punchvector = '0 0 0';
 350         this.oldvelocity = this.velocity;
 351         this.fire_endtime = -1;
 352         this.event_damage = func_null;
 353
 354         for(int slot = 0; slot < MAX_AXH; ++slot)
 355         {
 356                 entity axh = this.(AuxiliaryXhair[slot]);
 357                 this.(AuxiliaryXhair[slot]) = NULL;
 358
 359                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 360                         delete(axh);
 361         }
 362 }
 363
 364 int player_getspecies(entity this)
 365 {
 366         get_model_parameters(this.model, this.skin);
 367         int s = get_model_parameters_species;
 368         get_model_parameters(string_null, 0);
 369         if (s < 0) return SPECIES_HUMAN;
 370         return s;
 371 }
 372
 373 .float model_randomizer;
 374 void FixPlayermodel(entity player)
 375 {
 376         string defaultmodel = "";
 377         int defaultskin = 0;
 378         if(autocvar_sv_defaultcharacter)
 379         {
 380                 if(teamplay)
 381                 {
 382                         switch(player.team)
 383                         {
 384                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 385                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 386                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 387                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 388                         }
 389                 }
 390
 391                 if(defaultmodel == "")
 392                 {
 393                         defaultmodel = autocvar_sv_defaultplayermodel;
 394                         defaultskin = autocvar_sv_defaultplayerskin;
 395                 }
 396
 397                 int n = tokenize_console(defaultmodel);
 398                 if(n > 0)
 399                 {
 400                         defaultmodel = argv(floor(n * player.model_randomizer));
 401                         // However, do NOT randomize if the player-selected model is in the list.
 402                         for (int i = 0; i < n; ++i)
 403                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 404                                         defaultmodel = argv(i);
 405                 }
 406
 407                 int i = strstrofs(defaultmodel, ":", 0);
 408                 if(i >= 0)
 409                 {
 410                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 411                         defaultmodel = substring(defaultmodel, 0, i);
 412                 }
 413         }
 414         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 415         {
 416                 if(teamplay)
 417                 {
 418                         switch(player.team)
 419                         {
 420                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 421                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 422                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 423                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 424                         }
 425                 }
 426
 427                 if(!defaultskin)
 428                         defaultskin = autocvar_sv_defaultplayerskin;
 429         }
 430
 431         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 432         defaultmodel = M_ARGV(0, string);
 433         defaultskin = M_ARGV(1, int);
 434
 435         bool chmdl = false;
 436         int oldskin;
 437         if(defaultmodel != "")
 438         {
 439                 if (defaultmodel != player.model)
 440                 {
 441                         vector m1 = player.mins;
 442                         vector m2 = player.maxs;
 443                         setplayermodel (player, defaultmodel);
 444                         setsize (player, m1, m2);
 445                         chmdl = true;
 446                 }
 447
 448                 oldskin = player.skin;
 449                 player.skin = defaultskin;
 450         } else {
 451                 if (player.playermodel != player.model || player.playermodel == "")
 452                 {
 453                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 454                         vector m1 = player.mins;
 455                         vector m2 = player.maxs;
 456                         setplayermodel (player, player.playermodel);
 457                         setsize (player, m1, m2);
 458                         chmdl = true;
 459                 }
 460
 461                 if(!autocvar_sv_defaultcharacterskin)
 462                 {
 463                         oldskin = player.skin;
 464                         player.skin = stof(player.playerskin);
 465                 }
 466                 else
 467                 {
 468                         oldskin = player.skin;
 469                         player.skin = defaultskin;
 470                 }
 471         }
 472
 473         if(chmdl || oldskin != player.skin) // model or skin has changed
 474         {
 475                 player.species = player_getspecies(player); // update species
 476                 if(!autocvar_g_debug_globalsounds)
 477                         UpdatePlayerSounds(player); // update skin sounds
 478         }
 479
 480         if(!teamplay)
 481                 if(strlen(autocvar_sv_defaultplayercolors))
 482                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 483                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 484 }
 485
 486 void PutPlayerInServer(entity this)
 487 {
 488         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 489
 490         PlayerState_attach(this);
 491         accuracy_resend(this);
 492
 493         if (this.team < 0)
 494                 JoinBestTeam(this, false, true);
 495
 496         entity spot = SelectSpawnPoint(this, false);
 497         if (!spot) {
 498                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 499                 return; // spawn failed
 500         }
 501
 502         TRANSMUTE(Player, this);
 503
 504         this.wasplayer = true;
 505         this.iscreature = true;
 506         this.teleportable = TELEPORT_NORMAL;
 507         if(!this.damagedbycontents)
 508                 IL_PUSH(g_damagedbycontents, this);
 509         this.damagedbycontents = true;
 510         set_movetype(this, MOVETYPE_WALK);
 511         this.solid = SOLID_SLIDEBOX;
 512         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 513         if (autocvar_g_playerclip_collisions)
 514                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 515         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 516                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 517         this.frags = FRAGS_PLAYER;
 518         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 519         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 520         if (autocvar__notarget)
 521                 this.flags |= FL_NOTARGET;
 522         this.takedamage = DAMAGE_AIM;
 523         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 524         this.dmg = 2; // WTF
 525
 526         if (warmup_stage) {
 527                 this.ammo_shells = warmup_start_ammo_shells;
 528                 this.ammo_nails = warmup_start_ammo_nails;
 529                 this.ammo_rockets = warmup_start_ammo_rockets;
 530                 this.ammo_cells = warmup_start_ammo_cells;
 531                 this.ammo_plasma = warmup_start_ammo_plasma;
 532                 this.ammo_fuel = warmup_start_ammo_fuel;
 533                 this.health = warmup_start_health;
 534                 this.armorvalue = warmup_start_armorvalue;
 535                 this.weapons = WARMUP_START_WEAPONS;
 536         } else {
 537                 this.ammo_shells = start_ammo_shells;
 538                 this.ammo_nails = start_ammo_nails;
 539                 this.ammo_rockets = start_ammo_rockets;
 540                 this.ammo_cells = start_ammo_cells;
 541                 this.ammo_plasma = start_ammo_plasma;
 542                 this.ammo_fuel = start_ammo_fuel;
 543                 this.health = start_health;
 544                 this.armorvalue = start_armorvalue;
 545                 this.weapons = start_weapons;
 546         }
 547         SetSpectatee_status(this, 0);
 548
 549         PS(this).dual_weapons = '0 0 0';
 550
 551         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 552
 553         this.items = start_items;
 554
 555         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 556         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 557         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 558         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 559         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 560         // extend the pause of rotting if client was reset at the beginning of the countdown
 561         if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 562                 float f = game_starttime - time;
 563                 this.spawnshieldtime += f;
 564                 this.pauserotarmor_finished += f;
 565                 this.pauserothealth_finished += f;
 566                 this.pauseregen_finished += f;
 567         }
 568         this.damageforcescale = 2;
 569         this.death_time = 0;
 570         this.respawn_flags = 0;
 571         this.respawn_time = 0;
 572         this.stat_respawn_time = 0;
 573         this.scale = autocvar_sv_player_scale;
 574         this.fade_time = 0;
 575         this.pain_frame = 0;
 576         this.pain_finished = 0;
 577         this.pushltime = 0;
 578         setthink(this, func_null); // players have no think function
 579         this.nextthink = 0;
 580         this.dmg_team = 0;
 581         this.ballistics_density = autocvar_g_ballistics_density_player;
 582
 583         this.deadflag = DEAD_NO;
 584
 585         this.angles = spot.angles;
 586         this.angles_z = 0; // never spawn tilted even if the spot says to
 587         if (IS_BOT_CLIENT(this))
 588                 this.v_angle = this.angles;
 589         this.fixangle = true; // turn this way immediately
 590         this.oldvelocity = this.velocity = '0 0 0';
 591         this.avelocity = '0 0 0';
 592         this.punchangle = '0 0 0';
 593         this.punchvector = '0 0 0';
 594
 595         this.strength_finished = 0;
 596         this.invincible_finished = 0;
 597         this.fire_endtime = -1;
 598         this.revive_progress = 0;
 599         this.revival_time = 0;
 600         this.air_finished = time + 12;
 601
 602         entity spawnevent = new_pure(spawnevent);
 603         spawnevent.owner = this;
 604         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 605
 606         // Cut off any still running player sounds.
 607         stopsound(this, CH_PLAYER_SINGLE);
 608
 609         this.model = "";
 610         FixPlayermodel(this);
 611         this.drawonlytoclient = NULL;
 612
 613         this.viewloc = NULL;
 614
 615         this.crouch = false;
 616         this.view_ofs = STAT(PL_VIEW_OFS, this);
 617         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 618         this.spawnorigin = spot.origin;
 619         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 620         // don't reset back to last position, even if new position is stuck in solid
 621         this.oldorigin = this.origin;
 622         this.lastteleporttime = time; // prevent insane speeds due to changing origin
 623         if(this.conveyor)
 624                 IL_REMOVE(g_conveyed, this);
 625         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 626         this.hud = HUD_NORMAL;
 627
 628         this.event_damage = PlayerDamage;
 629
 630         if(!this.bot_attack)
 631                 IL_PUSH(g_bot_targets, this);
 632         this.bot_attack = true;
 633         if(!this.monster_attack)
 634                 IL_PUSH(g_monster_targets, this);
 635         this.monster_attack = true;
 636         navigation_dynamicgoal_init(this, false);
 637
 638         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 639
 640         if (CS(this).killcount == FRAGS_SPECTATOR) {
 641                 PlayerScore_Clear(this);
 642                 CS(this).killcount = 0;
 643         }
 644
 645         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 646         {
 647                 .entity weaponentity = weaponentities[slot];
 648                 entity oldwep = this.(weaponentity);
 649                 CL_SpawnWeaponentity(this, weaponentity);
 650                 if(oldwep && oldwep.owner == this)
 651                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 652         }
 653         this.alpha = default_player_alpha;
 654         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 655         this.exteriorweaponentity.alpha = default_weapon_alpha;
 656
 657         this.speedrunning = false;
 658
 659         target_voicescript_clear(this);
 660
 661         // reset fields the weapons may use
 662         FOREACH(Weapons, true, LAMBDA(
 663                 it.wr_resetplayer(it, this);
 664                         // reload all reloadable weapons
 665                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 666                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 667                         {
 668                                 .entity weaponentity = weaponentities[slot];
 669                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 670                         }
 671                 }
 672         ));
 673
 674         {
 675                 string s = spot.target;
 676                 spot.target = string_null;
 677                 SUB_UseTargets(spot, this, NULL);
 678                 spot.target = s;
 679         }
 680
 681         Unfreeze(this);
 682
 683         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 684
 685         if (autocvar_spawn_debug)
 686         {
 687                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 688                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 689         }
 690
 691         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 692         {
 693                 .entity weaponentity = weaponentities[slot];
 694                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 695                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 696                 else
 697                         this.(weaponentity).m_switchweapon = WEP_Null;
 698                 this.(weaponentity).m_weapon = WEP_Null;
 699                 this.(weaponentity).weaponname = "";
 700                 this.(weaponentity).m_switchingweapon = WEP_Null;
 701                 this.(weaponentity).cnt = -1;
 702         }
 703
 704         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 705
 706         if (!warmup_stage && !this.alivetime)
 707                 this.alivetime = time;
 708
 709         antilag_clear(this, CS(this));
 710 }
 711
 712 /** Called when a client spawns in the server */
 713 void PutClientInServer(entity this)
 714 {
 715         if (IS_BOT_CLIENT(this)) {
 716                 TRANSMUTE(Player, this);
 717         } else if (IS_REAL_CLIENT(this)) {
 718                 msg_entity = this;
 719                 WriteByte(MSG_ONE, SVC_SETVIEW);
 720                 WriteEntity(MSG_ONE, this);
 721         }
 722         if (game_stopped)
 723                 TRANSMUTE(Observer, this);
 724
 725         SetSpectatee(this, NULL);
 726
 727         // reset player keys
 728         if(PS(this))
 729                 PS(this).itemkeys = 0;
 730
 731         MUTATOR_CALLHOOK(PutClientInServer, this);
 732
 733         if (IS_OBSERVER(this)) {
 734                 PutObserverInServer(this);
 735         } else if (IS_PLAYER(this)) {
 736                 PutPlayerInServer(this);
 737         }
 738 }
 739
 740 void ClientInit_misc(entity this);
 741
 742 // TODO do we need all these fields, or should we stop autodetecting runtime
 743 // changes and just have a console command to update this?
 744 bool ClientInit_SendEntity(entity this, entity to, int sf)
 745 {
 746         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 747         return = true;
 748         msg_entity = to;
 749         // MSG_INIT replacement
 750         // TODO: make easier to use
 751         Registry_send_all();
 752         W_PROP_reload(MSG_ONE, to);
 753         ClientInit_misc(this);
 754         MUTATOR_CALLHOOK(Ent_Init);
 755 }
 756 void ClientInit_misc(entity this)
 757 {
 758         int channel = MSG_ONE;
 759         WriteHeader(channel, ENT_CLIENT_INIT);
 760         WriteByte(channel, g_nexball_meter_period * 32);
 761         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 762         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 763         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 764         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 765         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 766         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 767         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 768         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 769
 770         if(sv_foginterval && world.fog != "")
 771                 WriteString(channel, world.fog);
 772         else
 773                 WriteString(channel, "");
 774         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 775         WriteByte(channel, serverflags);
 776         WriteCoord(channel, autocvar_g_trueaim_minrange);
 777 }
 778
 779 void ClientInit_CheckUpdate(entity this)
 780 {
 781         this.nextthink = time;
 782         if(this.count != autocvar_g_balance_armor_blockpercent)
 783         {
 784                 this.count = autocvar_g_balance_armor_blockpercent;
 785                 this.SendFlags |= 1;
 786         }
 787 }
 788
 789 void ClientInit_Spawn()
 790 {
 791         entity e = new_pure(clientinit);
 792         setthink(e, ClientInit_CheckUpdate);
 793         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 794
 795         ClientInit_CheckUpdate(e);
 796 }
 797
 798 /*
 799 =============
 800 SetNewParms
 801 =============
 802 */
 803 void SetNewParms ()
 804 {
 805         // initialize parms for a new player
 806         parm1 = -(86400 * 366);
 807
 808         MUTATOR_CALLHOOK(SetNewParms);
 809 }
 810
 811 /*
 812 =============
 813 SetChangeParms
 814 =============
 815 */
 816 void SetChangeParms (entity this)
 817 {
 818         // save parms for level change
 819         parm1 = CS(this).parm_idlesince - time;
 820
 821         MUTATOR_CALLHOOK(SetChangeParms);
 822 }
 823
 824 /*
 825 =============
 826 DecodeLevelParms
 827 =============
 828 */
 829 void DecodeLevelParms(entity this)
 830 {
 831         // load parms
 832         CS(this).parm_idlesince = parm1;
 833         if (CS(this).parm_idlesince == -(86400 * 366))
 834                 CS(this).parm_idlesince = time;
 835
 836         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 837         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 838
 839         MUTATOR_CALLHOOK(DecodeLevelParms);
 840 }
 841
 842 /*
 843 =============
 844 ClientKill
 845
 846 Called when a client types 'kill' in the console
 847 =============
 848 */
 849
 850 .float clientkill_nexttime;
 851 void ClientKill_Now_TeamChange(entity this)
 852 {
 853         if(CS(this).killindicator_teamchange == -1)
 854         {
 855                 JoinBestTeam( this, false, true );
 856         }
 857         else if(CS(this).killindicator_teamchange == -2)
 858         {
 859                 if(blockSpectators)
 860                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 861                 PutObserverInServer(this);
 862         }
 863         else
 864                 SV_ChangeTeam(this, CS(this).killindicator_teamchange - 1);
 865         CS(this).killindicator_teamchange = 0;
 866 }
 867
 868 void ClientKill_Now(entity this)
 869 {
 870         if(this.vehicle)
 871         {
 872             vehicles_exit(this.vehicle, VHEF_RELEASE);
 873             if(!CS(this).killindicator_teamchange)
 874             {
 875             this.vehicle_health = -1;
 876             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 877             }
 878         }
 879
 880         if(this.killindicator && !wasfreed(this.killindicator))
 881                 delete(this.killindicator);
 882
 883         this.killindicator = NULL;
 884
 885         if(CS(this).killindicator_teamchange)
 886                 ClientKill_Now_TeamChange(this);
 887
 888         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 889                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 890
 891         // now I am sure the player IS dead
 892 }
 893 void KillIndicator_Think(entity this)
 894 {
 895         if (game_stopped)
 896         {
 897                 this.owner.killindicator = NULL;
 898                 delete(this);
 899                 return;
 900         }
 901
 902         if (this.owner.alpha < 0 && !this.owner.vehicle)
 903         {
 904                 this.owner.killindicator = NULL;
 905                 delete(this);
 906                 return;
 907         }
 908
 909         if(this.cnt <= 0)
 910         {
 911                 ClientKill_Now(this.owner);
 912                 return;
 913         }
 914     else if(this.health == 1) // health == 1 means that it's silent
 915     {
 916         this.nextthink = time + 1;
 917         this.cnt -= 1;
 918     }
 919         else
 920         {
 921                 if(this.cnt <= 10)
 922                         setmodel(this, MDL_NUM(this.cnt));
 923                 if(IS_REAL_CLIENT(this.owner))
 924                 {
 925                         if(this.cnt <= 10)
 926                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 927                 }
 928                 this.nextthink = time + 1;
 929                 this.cnt -= 1;
 930         }
 931 }
 932
 933 float clientkilltime;
 934 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 935 {
 936         float killtime;
 937         float starttime;
 938
 939         if (game_stopped)
 940                 return;
 941
 942         killtime = autocvar_g_balance_kill_delay;
 943
 944     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 945         return;
 946     killtime = M_ARGV(1, float);
 947
 948         CS(this).killindicator_teamchange = targetteam;
 949
 950     if(!this.killindicator)
 951         {
 952                 if(!IS_DEAD(this))
 953                 {
 954                         killtime = max(killtime, this.clientkill_nexttime - time);
 955                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 956                 }
 957
 958                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 959                 {
 960                         ClientKill_Now(this);
 961                 }
 962                 else
 963                 {
 964                         starttime = max(time, clientkilltime);
 965
 966                         this.killindicator = spawn();
 967                         this.killindicator.owner = this;
 968                         this.killindicator.scale = 0.5;
 969                         setattachment(this.killindicator, this, "");
 970                         setorigin(this.killindicator, '0 0 52');
 971                         setthink(this.killindicator, KillIndicator_Think);
 972                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 973                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 974                         this.killindicator.cnt = ceil(killtime);
 975                         this.killindicator.count = bound(0, ceil(killtime), 10);
 976                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 977
 978                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 979                         {
 980                                 it.killindicator = spawn();
 981                                 it.killindicator.owner = it;
 982                                 it.killindicator.scale = 0.5;
 983                                 setattachment(it.killindicator, it, "");
 984                                 setorigin(it.killindicator, '0 0 52');
 985                                 setthink(it.killindicator, KillIndicator_Think);
 986                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 987                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 988                                 it.killindicator.cnt = ceil(killtime);
 989                         });
 990                         this.lip = 0;
 991                 }
 992         }
 993         if(this.killindicator)
 994         {
 995                 if(targetteam == 0) // just die
 996                 {
 997                         this.killindicator.colormod = '0 0 0';
 998                         if(IS_REAL_CLIENT(this))
 999                         if(this.killindicator.cnt > 0)
1000                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1001                 }
1002                 else if(targetteam == -1) // auto
1003                 {
1004                         this.killindicator.colormod = '0 1 0';
1005                         if(IS_REAL_CLIENT(this))
1006                         if(this.killindicator.cnt > 0)
1007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1008                 }
1009                 else if(targetteam == -2) // spectate
1010                 {
1011                         this.killindicator.colormod = '0.5 0.5 0.5';
1012                         if(IS_REAL_CLIENT(this))
1013                         if(this.killindicator.cnt > 0)
1014                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1015                 }
1016                 else
1017                 {
1018                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1019                         if(IS_REAL_CLIENT(this))
1020                         if(this.killindicator.cnt > 0)
1021                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1022                 }
1023         }
1024
1025 }
1026
1027 void ClientKill (entity this)
1028 {
1029         if(game_stopped) return;
1030         if(this.player_blocked) return;
1031         if(STAT(FROZEN, this)) return;
1032
1033         ClientKill_TeamChange(this, 0);
1034 }
1035
1036 void FixClientCvars(entity e)
1037 {
1038         // send prediction settings to the client
1039         stuffcmd(e, "\nin_bindmap 0 0\n");
1040         if(autocvar_g_antilag == 3) // client side hitscan
1041                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1042         if(autocvar_sv_gentle)
1043                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1044
1045         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1046         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1047
1048         MUTATOR_CALLHOOK(FixClientCvars, e);
1049 }
1050
1051 bool findinlist_abbrev(string tofind, string list)
1052 {
1053         if(list == "" || tofind == "")
1054                 return false; // empty list or search, just return
1055
1056         // this function allows abbreviated strings!
1057         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1058         {
1059                 return true;
1060         });
1061
1062         return false;
1063 }
1064
1065 bool PlayerInIPList(entity p, string iplist)
1066 {
1067         // some safety checks (never allow local?)
1068         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1069                 return false;
1070
1071         return findinlist_abbrev(p.netaddress, iplist);
1072 }
1073
1074 bool PlayerInIDList(entity p, string idlist)
1075 {
1076         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1077         if(!p.crypto_idfp)
1078                 return false;
1079
1080         return findinlist_abbrev(p.crypto_idfp, idlist);
1081 }
1082
1083 bool PlayerInList(entity player, string list)
1084 {
1085         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1086 }
1087
1088 #ifdef DP_EXT_PRECONNECT
1089 /*
1090 =============
1091 ClientPreConnect
1092
1093 Called once (not at each match start) when a client begins a connection to the server
1094 =============
1095 */
1096 void ClientPreConnect(entity this)
1097 {
1098         if(autocvar_sv_eventlog)
1099         {
1100                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1101                         this.playerid,
1102                         etof(this),
1103                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1104                 ));
1105         }
1106 }
1107 #endif
1108
1109 /**
1110 =============
1111 ClientConnect
1112
1113 Called when a client connects to the server
1114 =============
1115 */
1116 void ClientConnect(entity this)
1117 {
1118         if (Ban_MaybeEnforceBanOnce(this)) return;
1119         assert(!IS_CLIENT(this), return);
1120         this.flags |= FL_CLIENT;
1121         assert(player_count >= 0, player_count = 0);
1122
1123 #ifdef WATERMARK
1124         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1125 #endif
1126         TRANSMUTE(Client, this);
1127         CS(this).version_nagtime = time + 10 + random() * 10;
1128
1129         // identify the right forced team
1130         if (autocvar_g_campaign)
1131         {
1132                 if (IS_REAL_CLIENT(this)) // only players, not bots
1133                 {
1134                         switch (autocvar_g_campaign_forceteam)
1135                         {
1136                                 case 1: this.team_forced = NUM_TEAM_1; break;
1137                                 case 2: this.team_forced = NUM_TEAM_2; break;
1138                                 case 3: this.team_forced = NUM_TEAM_3; break;
1139                                 case 4: this.team_forced = NUM_TEAM_4; break;
1140                                 default: this.team_forced = 0;
1141                         }
1142                 }
1143         }
1144         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1145         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1146         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1147         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1148         else switch (autocvar_g_forced_team_otherwise)
1149         {
1150                 default: this.team_forced = 0; break;
1151                 case "red": this.team_forced = NUM_TEAM_1; break;
1152                 case "blue": this.team_forced = NUM_TEAM_2; break;
1153                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1154                 case "pink": this.team_forced = NUM_TEAM_4; break;
1155                 case "spectate":
1156                 case "spectator":
1157                         this.team_forced = -1;
1158                         break;
1159         }
1160         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1161
1162     {
1163         int id = this.playerid;
1164         this.playerid = 0; // silent
1165             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1166             this.playerid = id;
1167     }
1168
1169         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1170                 TRANSMUTE(Observer, this);
1171         } else {
1172                 if (!teamplay || autocvar_g_balance_teams) {
1173                         TRANSMUTE(Player, this);
1174                         campaign_bots_may_start = true;
1175                 } else {
1176                         TRANSMUTE(Observer, this); // do it anyway
1177                 }
1178         }
1179
1180         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1181
1182         // always track bots, don't ask for cl_allow_uidtracking
1183     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1184
1185         if (autocvar_sv_eventlog)
1186                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1187
1188         LogTeamchange(this.playerid, this.team, 1);
1189
1190         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1191
1192         CS(this).netname_previous = strzone(this.netname);
1193
1194         if(teamplay && IS_PLAYER(this))
1195                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1196         else
1197                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1198
1199         stuffcmd(this, clientstuff, "\n");
1200         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1201
1202         FixClientCvars(this);
1203
1204         // get version info from player
1205         stuffcmd(this, "cmd clientversion $gameversion\n");
1206
1207         // notify about available teams
1208         if (teamplay)
1209         {
1210                 CheckAllowedTeams(this);
1211                 int t = 0;
1212                 if (c1 >= 0) t |= BIT(0);
1213                 if (c2 >= 0) t |= BIT(1);
1214                 if (c3 >= 0) t |= BIT(2);
1215                 if (c4 >= 0) t |= BIT(3);
1216                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1217         }
1218         else
1219         {
1220                 stuffcmd(this, "set _teams_available 0\n");
1221         }
1222
1223         bot_relinkplayerlist();
1224
1225         CS(this).spectatortime = time;
1226         if (blockSpectators)
1227         {
1228                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1229         }
1230
1231         CS(this).jointime = time;
1232         CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1233
1234         if (IS_REAL_CLIENT(this))
1235         {
1236                 if (g_weaponarena_weapons == WEPSET(TUBA))
1237                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1238         }
1239
1240         if (!sv_foginterval && world.fog != "")
1241                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1242
1243         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1244                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1245                         send_CSQC_teamnagger();
1246
1247         CSQCMODEL_AUTOINIT(this);
1248
1249         this.model_randomizer = random();
1250
1251         if (IS_REAL_CLIENT(this))
1252                 sv_notice_join(this);
1253
1254         // update physics stats (players can spawn before physics runs)
1255         Physics_UpdateStats(this);
1256
1257         IL_EACH(g_initforplayer, it.init_for_player, {
1258                 it.init_for_player(it, this);
1259         });
1260
1261         MUTATOR_CALLHOOK(ClientConnect, this);
1262
1263         if (IS_REAL_CLIENT(this))
1264         {
1265                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1266                 {
1267                         CS(this).motd_actived_time = -1;
1268                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1269                 }
1270         }
1271 }
1272 /*
1273 =============
1274 ClientDisconnect
1275
1276 Called when a client disconnects from the server
1277 =============
1278 */
1279 .entity chatbubbleentity;
1280 void ReadyCount();
1281 void ClientDisconnect(entity this)
1282 {
1283         assert(IS_CLIENT(this), return);
1284
1285         PlayerStats_GameReport_FinalizePlayer(this);
1286         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1287         if (CS(this).active_minigame) part_minigame(this);
1288         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1289
1290         if (autocvar_sv_eventlog)
1291                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1292
1293         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1294
1295         if(IS_SPEC(this))
1296                 SetSpectatee(this, NULL);
1297
1298     MUTATOR_CALLHOOK(ClientDisconnect, this);
1299
1300         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1301         ClientState_detach(this);
1302
1303         Portal_ClearAll(this);
1304
1305         Unfreeze(this);
1306
1307         RemoveGrapplingHooks(this);
1308
1309         // Here, everything has been done that requires this player to be a client.
1310
1311         this.flags &= ~FL_CLIENT;
1312
1313         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1314         if (this.killindicator) delete(this.killindicator);
1315
1316         WaypointSprite_PlayerGone(this);
1317
1318         bot_relinkplayerlist();
1319
1320         if (this.clientstatus) strunzone(this.clientstatus);
1321         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1322         if (this.personal) delete(this.personal);
1323
1324         this.playerid = 0;
1325         ReadyCount();
1326         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1327
1328         ONREMOVE(this);
1329 }
1330
1331 void ChatBubbleThink(entity this)
1332 {
1333         this.nextthink = time;
1334         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1335         {
1336                 if(this.owner) // but why can that ever be NULL?
1337                         this.owner.chatbubbleentity = NULL;
1338                 delete(this);
1339                 return;
1340         }
1341
1342         this.mdl = "";
1343
1344         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1345         {
1346                 if ( CS(this.owner).active_minigame )
1347                         this.mdl = "models/sprites/minigame_busy.iqm";
1348                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1349                         this.mdl = "models/misc/chatbubble.spr";
1350         }
1351
1352         if ( this.model != this.mdl )
1353                 _setmodel(this, this.mdl);
1354
1355 }
1356
1357 void UpdateChatBubble(entity this)
1358 {
1359         if (this.alpha < 0)
1360                 return;
1361         // spawn a chatbubble entity if needed
1362         if (!this.chatbubbleentity)
1363         {
1364                 this.chatbubbleentity = new(chatbubbleentity);
1365                 this.chatbubbleentity.owner = this;
1366                 this.chatbubbleentity.exteriormodeltoclient = this;
1367                 setthink(this.chatbubbleentity, ChatBubbleThink);
1368                 this.chatbubbleentity.nextthink = time;
1369                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1370                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1371                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1372                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1373                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1374                 //this.chatbubbleentity.model = "";
1375                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1376         }
1377 }
1378
1379
1380 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1381 // added to the model skins
1382 /*void UpdateColorModHack()
1383 {
1384         float c;
1385         c = this.clientcolors & 15;
1386         // LordHavoc: only bothering to support white, green, red, yellow, blue
1387              if (!teamplay) this.colormod = '0 0 0';
1388         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1389         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1390         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1391         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1392         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1393         else this.colormod = '1 1 1';
1394 }*/
1395
1396 void respawn(entity this)
1397 {
1398         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1399         {
1400                 this.solid = SOLID_NOT;
1401                 this.takedamage = DAMAGE_NO;
1402                 set_movetype(this, MOVETYPE_FLY);
1403                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1404                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1405                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1406                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1407                 if(autocvar_g_respawn_ghosts_maxtime)
1408                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1409         }
1410
1411         CopyBody(this, 1);
1412
1413         this.effects |= EF_NODRAW; // prevent another CopyBody
1414         PutClientInServer(this);
1415 }
1416
1417 void play_countdown(entity this, float finished, Sound samp)
1418 {
1419     TC(Sound, samp);
1420         if(IS_REAL_CLIENT(this))
1421                 if(floor(finished - time - frametime) != floor(finished - time))
1422                         if(finished - time < 6)
1423                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1424 }
1425
1426 void player_powerups(entity this)
1427 {
1428         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1429         int items_prev = this.items;
1430
1431         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1432                 this.modelflags |= MF_ROCKET;
1433         else
1434                 this.modelflags &= ~MF_ROCKET;
1435
1436         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1437
1438         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1439                 return;
1440
1441         Fire_ApplyDamage(this);
1442         Fire_ApplyEffect(this);
1443
1444         if (!g_instagib)
1445         {
1446                 if (this.items & ITEM_Strength.m_itemid)
1447                 {
1448                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1449                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1450                         if (time > this.strength_finished)
1451                         {
1452                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1453                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1455                         }
1456                 }
1457                 else
1458                 {
1459                         if (time < this.strength_finished)
1460                         {
1461                                 this.items = this.items | ITEM_Strength.m_itemid;
1462                                 if(!g_cts)
1463                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1464                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1465                         }
1466                 }
1467                 if (this.items & ITEM_Shield.m_itemid)
1468                 {
1469                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1470                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1471                         if (time > this.invincible_finished)
1472                         {
1473                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1474                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1475                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1476                         }
1477                 }
1478                 else
1479                 {
1480                         if (time < this.invincible_finished)
1481                         {
1482                                 this.items = this.items | ITEM_Shield.m_itemid;
1483                                 if(!g_cts)
1484                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1485                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1486                         }
1487                 }
1488                 if (this.items & IT_SUPERWEAPON)
1489                 {
1490                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1491                         {
1492                                 this.superweapons_finished = 0;
1493                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1494                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1495                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1496                         }
1497                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1498                         {
1499                                 // don't let them run out
1500                         }
1501                         else
1502                         {
1503                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1504                                 if (time > this.superweapons_finished)
1505                                 {
1506                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1507                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1508                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1509                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1510                                 }
1511                         }
1512                 }
1513                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1514                 {
1515                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1516                         {
1517                                 this.items = this.items | IT_SUPERWEAPON;
1518                                 if(!g_cts)
1519                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1520                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1521                         }
1522                         else
1523                         {
1524                                 this.superweapons_finished = 0;
1525                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1526                         }
1527                 }
1528                 else
1529                 {
1530                         this.superweapons_finished = 0;
1531                 }
1532         }
1533
1534         if(autocvar_g_nodepthtestplayers)
1535                 this.effects = this.effects | EF_NODEPTHTEST;
1536
1537         if(autocvar_g_fullbrightplayers)
1538                 this.effects = this.effects | EF_FULLBRIGHT;
1539
1540         if (time >= game_starttime)
1541         if (time < this.spawnshieldtime)
1542                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1543
1544         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1545 }
1546
1547 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1548 {
1549         if(current > stable)
1550                 return current;
1551         else if(current > stable - 0.25) // when close enough, "snap"
1552                 return stable;
1553         else
1554                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1555 }
1556
1557 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1558 {
1559         if(current < stable)
1560                 return current;
1561         else if(current < stable + 0.25) // when close enough, "snap"
1562                 return stable;
1563         else
1564                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1565 }
1566
1567 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1568 {
1569         if(current > rotstable)
1570         {
1571                 if(rotframetime > 0)
1572                 {
1573                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1574                         current = max(rotstable, current - rotlinear * rotframetime);
1575                 }
1576         }
1577         else if(current < regenstable)
1578         {
1579                 if(regenframetime > 0)
1580                 {
1581                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1582                         current = min(regenstable, current + regenlinear * regenframetime);
1583                 }
1584         }
1585
1586         if(current > limit)
1587                 current = limit;
1588
1589         return current;
1590 }
1591
1592 void player_regen(entity this)
1593 {
1594         float max_mod, regen_mod, rot_mod, limit_mod;
1595         max_mod = regen_mod = rot_mod = limit_mod = 1;
1596
1597         float regen_health = autocvar_g_balance_health_regen;
1598         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1599         float regen_health_rot = autocvar_g_balance_health_rot;
1600         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1601         float regen_health_stable = autocvar_g_balance_health_regenstable;
1602         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1603         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1604                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1605         max_mod = M_ARGV(1, float);
1606         regen_mod = M_ARGV(2, float);
1607         rot_mod = M_ARGV(3, float);
1608         limit_mod = M_ARGV(4, float);
1609         regen_health = M_ARGV(5, float);
1610         regen_health_linear = M_ARGV(6, float);
1611         regen_health_rot = M_ARGV(7, float);
1612         regen_health_rotlinear = M_ARGV(8, float);
1613         regen_health_stable = M_ARGV(9, float);
1614         regen_health_rotstable = M_ARGV(10, float);
1615
1616
1617         if(!mutator_returnvalue)
1618         if(!STAT(FROZEN, this))
1619         {
1620                 float mina, maxa, limith, limita;
1621                 maxa = autocvar_g_balance_armor_rotstable;
1622                 mina = autocvar_g_balance_armor_regenstable;
1623                 limith = autocvar_g_balance_health_limit;
1624                 limita = autocvar_g_balance_armor_limit;
1625
1626                 regen_health_rotstable = regen_health_rotstable * max_mod;
1627                 regen_health_stable = regen_health_stable * max_mod;
1628                 limith = limith * limit_mod;
1629                 limita = limita * limit_mod;
1630
1631                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1632                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1633         }
1634
1635         // if player rotted to death...  die!
1636         // check this outside above checks, as player may still be able to rot to death
1637         if(this.health < 1)
1638         {
1639                 if(this.vehicle)
1640                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1641                 if(this.event_damage)
1642                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1643         }
1644
1645         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1646         {
1647                 float minf, maxf, limitf;
1648
1649                 maxf = autocvar_g_balance_fuel_rotstable;
1650                 minf = autocvar_g_balance_fuel_regenstable;
1651                 limitf = autocvar_g_balance_fuel_limit;
1652
1653                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1654         }
1655 }
1656
1657 bool zoomstate_set;
1658 void SetZoomState(entity this, float newzoom)
1659 {
1660         if(newzoom != CS(this).zoomstate)
1661         {
1662                 CS(this).zoomstate = newzoom;
1663                 ClientData_Touch(this);
1664         }
1665         zoomstate_set = true;
1666 }
1667
1668 void GetPressedKeys(entity this)
1669 {
1670         MUTATOR_CALLHOOK(GetPressedKeys, this);
1671         int keys = STAT(PRESSED_KEYS, this);
1672         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1673         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1674         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1675         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1676
1677         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1678         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1679         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1680         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1681         CS(this).pressedkeys = keys; // store for other users
1682
1683         STAT(PRESSED_KEYS, this) = keys;
1684 }
1685
1686 /*
1687 ======================
1688 spectate mode routines
1689 ======================
1690 */
1691
1692 void SpectateCopy(entity this, entity spectatee)
1693 {
1694     TC(Client, this); TC(Client, spectatee);
1695
1696         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1697         PS(this) = PS(spectatee);
1698         this.armortype = spectatee.armortype;
1699         this.armorvalue = spectatee.armorvalue;
1700         this.ammo_cells = spectatee.ammo_cells;
1701         this.ammo_plasma = spectatee.ammo_plasma;
1702         this.ammo_shells = spectatee.ammo_shells;
1703         this.ammo_nails = spectatee.ammo_nails;
1704         this.ammo_rockets = spectatee.ammo_rockets;
1705         this.ammo_fuel = spectatee.ammo_fuel;
1706         this.clip_load = spectatee.clip_load;
1707         this.clip_size = spectatee.clip_size;
1708         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1709         this.health = spectatee.health;
1710         CS(this).impulse = 0;
1711         this.items = spectatee.items;
1712         this.last_pickup = spectatee.last_pickup;
1713         this.hit_time = spectatee.hit_time;
1714         this.strength_finished = spectatee.strength_finished;
1715         this.invincible_finished = spectatee.invincible_finished;
1716         this.superweapons_finished = spectatee.superweapons_finished;
1717         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1718         this.weapons = spectatee.weapons;
1719         this.vortex_charge = spectatee.vortex_charge;
1720         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1721         this.hagar_load = spectatee.hagar_load;
1722         this.arc_heat_percent = spectatee.arc_heat_percent;
1723         this.minelayer_mines = spectatee.minelayer_mines;
1724         this.punchangle = spectatee.punchangle;
1725         this.view_ofs = spectatee.view_ofs;
1726         this.velocity = spectatee.velocity;
1727         this.dmg_take = spectatee.dmg_take;
1728         this.dmg_save = spectatee.dmg_save;
1729         this.dmg_inflictor = spectatee.dmg_inflictor;
1730         this.v_angle = spectatee.v_angle;
1731         this.angles = spectatee.v_angle;
1732         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1733         this.revive_progress = spectatee.revive_progress;
1734         this.viewloc = spectatee.viewloc;
1735         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1736                 this.fixangle = true;
1737         setorigin(this, spectatee.origin);
1738         setsize(this, spectatee.mins, spectatee.maxs);
1739         SetZoomState(this, CS(spectatee).zoomstate);
1740
1741         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1742         {
1743                 .entity weaponentity = weaponentities[slot];
1744                 this.(weaponentity) = spectatee.(weaponentity);
1745         }
1746
1747         for(int slot = 0; slot < MAX_AXH; ++slot)
1748         {
1749                 this.(AuxiliaryXhair[slot]) = spectatee.(AuxiliaryXhair[slot]);
1750         }
1751
1752     anticheat_spectatecopy(this, spectatee);
1753         this.hud = spectatee.hud;
1754         if(spectatee.vehicle)
1755     {
1756         this.angles = spectatee.v_angle;
1757
1758         //this.fixangle = false;
1759         //this.velocity = spectatee.vehicle.velocity;
1760         this.vehicle_health = spectatee.vehicle_health;
1761         this.vehicle_shield = spectatee.vehicle_shield;
1762         this.vehicle_energy = spectatee.vehicle_energy;
1763         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1764         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1765         this.vehicle_reload1 = spectatee.vehicle_reload1;
1766         this.vehicle_reload2 = spectatee.vehicle_reload2;
1767
1768         //msg_entity = this;
1769
1770        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1771             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1772            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1773            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1774
1775         //WriteByte (MSG_ONE, SVC_SETVIEW);
1776         //    WriteEntity(MSG_ONE, this);
1777         //makevectors(spectatee.v_angle);
1778         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1779     }
1780 }
1781
1782 bool SpectateUpdate(entity this)
1783 {
1784         if(!this.enemy)
1785                 return false;
1786
1787         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1788         {
1789                 SetSpectatee(this, NULL);
1790                 return false;
1791         }
1792
1793         SpectateCopy(this, this.enemy);
1794
1795         return true;
1796 }
1797
1798 bool SpectateSet(entity this)
1799 {
1800         if(!IS_PLAYER(this.enemy))
1801                 return false;
1802
1803         ClientData_Touch(this.enemy);
1804
1805         msg_entity = this;
1806         WriteByte(MSG_ONE, SVC_SETVIEW);
1807         WriteEntity(MSG_ONE, this.enemy);
1808         set_movetype(this, MOVETYPE_NONE);
1809         accuracy_resend(this);
1810
1811         if(!SpectateUpdate(this))
1812                 PutObserverInServer(this);
1813
1814         return true;
1815 }
1816
1817 void SetSpectatee_status(entity this, int spectatee_num)
1818 {
1819         int oldspectatee_status = CS(this).spectatee_status;
1820         CS(this).spectatee_status = spectatee_num;
1821
1822         if (CS(this).spectatee_status != oldspectatee_status)
1823         {
1824                 ClientData_Touch(this);
1825                 if (g_race || g_cts) race_InitSpectator();
1826         }
1827 }
1828
1829 void SetSpectatee(entity this, entity spectatee)
1830 {
1831         if(IS_BOT_CLIENT(this))
1832                 return; // bots abuse .enemy, this code is useless to them
1833
1834         entity old_spectatee = this.enemy;
1835
1836         this.enemy = spectatee;
1837
1838         // WEAPONTODO
1839         // these are required to fix the spectator bug with arc
1840         if(old_spectatee)
1841         {
1842                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1843                 {
1844                         .entity weaponentity = weaponentities[slot];
1845                         if(old_spectatee.(weaponentity).arc_beam)
1846                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1847                 }
1848         }
1849         if(this.enemy)
1850         {
1851                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1852                 {
1853                         .entity weaponentity = weaponentities[slot];
1854                         if(this.enemy.(weaponentity).arc_beam)
1855                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1856                 }
1857         }
1858
1859         if (this.enemy)
1860                 SetSpectatee_status(this, etof(this.enemy));
1861
1862         // needed to update spectator list
1863         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1864 }
1865
1866 bool Spectate(entity this, entity pl)
1867 {
1868         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1869                 return false;
1870         pl = M_ARGV(1, entity);
1871
1872         SetSpectatee(this, pl);
1873         return SpectateSet(this);
1874 }
1875
1876 bool SpectateNext(entity this)
1877 {
1878         entity ent = find(this.enemy, classname, STR_PLAYER);
1879
1880         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1881                 ent = M_ARGV(1, entity);
1882         else if (!ent)
1883                 ent = find(ent, classname, STR_PLAYER);
1884
1885         if(ent) { SetSpectatee(this, ent); }
1886
1887         return SpectateSet(this);
1888 }
1889
1890 bool SpectatePrev(entity this)
1891 {
1892         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1893         entity ent = findchain(classname, STR_PLAYER);
1894         if (!ent) // no player
1895                 return false;
1896
1897         entity first = ent;
1898         // skip players until current spectated player
1899         if(this.enemy)
1900         while(ent && ent != this.enemy)
1901                 ent = ent.chain;
1902
1903         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1904         {
1905                 case MUT_SPECPREV_FOUND:
1906                     ent = M_ARGV(1, entity);
1907                     break;
1908                 case MUT_SPECPREV_RETURN:
1909                     return true;
1910                 case MUT_SPECPREV_CONTINUE:
1911                 default:
1912                 {
1913                         if(ent.chain)
1914                                 ent = ent.chain;
1915                         else
1916                                 ent = first;
1917                         break;
1918                 }
1919         }
1920
1921         SetSpectatee(this, ent);
1922         return SpectateSet(this);
1923 }
1924
1925 /*
1926 =============
1927 ShowRespawnCountdown()
1928
1929 Update a respawn countdown display.
1930 =============
1931 */
1932 void ShowRespawnCountdown(entity this)
1933 {
1934         float number;
1935         if(!IS_DEAD(this)) // just respawned?
1936                 return;
1937         else
1938         {
1939                 number = ceil(this.respawn_time - time);
1940                 if(number <= 0)
1941                         return;
1942                 if(number <= this.respawn_countdown)
1943                 {
1944                         this.respawn_countdown = number - 1;
1945                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1946                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1947                 }
1948         }
1949 }
1950
1951 .bool team_selected;
1952 bool ShowTeamSelection(entity this)
1953 {
1954         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1955                 return false;
1956         stuffcmd(this, "menu_showteamselect\n");
1957         return true;
1958 }
1959 void Join(entity this)
1960 {
1961         TRANSMUTE(Player, this);
1962
1963         if(!this.team_selected)
1964         if(autocvar_g_campaign || autocvar_g_balance_teams)
1965                 JoinBestTeam(this, false, true);
1966
1967         if(autocvar_g_campaign)
1968                 campaign_bots_may_start = true;
1969
1970         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1971
1972         PutClientInServer(this);
1973
1974         if(IS_PLAYER(this))
1975         if(teamplay && this.team != -1)
1976                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1977         else
1978                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1979         this.team_selected = false;
1980 }
1981
1982 /**
1983  * Determines whether the player is allowed to join. This depends on cvar
1984  * g_maxplayers, if it isn't used this function always return true, otherwise
1985  * it checks whether the number of currently playing players exceeds g_maxplayers.
1986  * @return int number of free slots for players, 0 if none
1987  */
1988 int nJoinAllowed(entity this, entity ignore)
1989 {
1990         if(!ignore)
1991         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1992         // so report 0 free slots if restricted
1993         {
1994                 if(autocvar_g_forced_team_otherwise == "spectate")
1995                         return 0;
1996                 if(autocvar_g_forced_team_otherwise == "spectator")
1997                         return 0;
1998         }
1999
2000         if(this && this.team_forced < 0)
2001                 return 0; // forced spectators can never join
2002
2003         // TODO simplify this
2004         int totalClients = 0;
2005         int currentlyPlaying = 0;
2006         FOREACH_CLIENT(true, LAMBDA(
2007                 if(it != ignore)
2008                         ++totalClients;
2009                 if(IS_REAL_CLIENT(it))
2010                 if(IS_PLAYER(it) || it.caplayer)
2011                         ++currentlyPlaying;
2012         ));
2013
2014         float free_slots = 0;
2015         if (!autocvar_g_maxplayers)
2016                 free_slots = maxclients - totalClients;
2017         else if(currentlyPlaying < autocvar_g_maxplayers)
2018                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2019
2020         static float join_prevent_msg_time = 0;
2021         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2022         {
2023                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2024                 join_prevent_msg_time = time + 3;
2025         }
2026
2027         return free_slots;
2028 }
2029
2030 /**
2031  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2032  * g_maxplayers_spectator_blocktime seconds
2033  */
2034 void checkSpectatorBlock(entity this)
2035 {
2036         if(IS_SPEC(this) || IS_OBSERVER(this))
2037         if(!this.caplayer)
2038         if(IS_REAL_CLIENT(this))
2039         {
2040                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2041                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2042                         dropclient(this);
2043                 }
2044         }
2045 }
2046
2047 void PrintWelcomeMessage(entity this)
2048 {
2049         if(CS(this).motd_actived_time == 0)
2050         {
2051                 if (autocvar_g_campaign) {
2052                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2053                                 CS(this).motd_actived_time = time;
2054                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2055                         }
2056                 } else {
2057                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2058                                 CS(this).motd_actived_time = time;
2059                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2060                         }
2061                 }
2062         }
2063         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2064         {
2065                 if (autocvar_g_campaign) {
2066                         if (PHYS_INPUT_BUTTON_INFO(this))
2067                                 CS(this).motd_actived_time = time;
2068                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2069                                 CS(this).motd_actived_time = 0;
2070                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2071                         }
2072                 } else {
2073                         if (PHYS_INPUT_BUTTON_INFO(this))
2074                                 CS(this).motd_actived_time = time;
2075                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2076                                 CS(this).motd_actived_time = 0;
2077                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2078                         }
2079                 }
2080         }
2081         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2082         {
2083                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2084                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2085                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2086                 {
2087                         // instanctly hide MOTD
2088                         CS(this).motd_actived_time = 0;
2089                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2090                 }
2091         }
2092 }
2093
2094 bool joinAllowed(entity this)
2095 {
2096         if (CS(this).version_mismatch) return false;
2097         if (!nJoinAllowed(this, this)) return false;
2098         if (teamplay && lockteams) return false;
2099         if (ShowTeamSelection(this)) return false;
2100         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2101         return true;
2102 }
2103
2104 .int items_added;
2105 bool PlayerThink(entity this)
2106 {
2107         if (game_stopped || intermission_running) {
2108                 this.modelflags &= ~MF_ROCKET;
2109                 if(intermission_running)
2110                         IntermissionThink(this);
2111                 return false;
2112         }
2113
2114         if (timeout_status == TIMEOUT_ACTIVE) {
2115         // don't allow the player to turn around while game is paused
2116                 // FIXME turn this into CSQC stuff
2117                 this.v_angle = this.lastV_angle;
2118                 this.angles = this.lastV_angle;
2119                 this.fixangle = true;
2120         }
2121
2122         if (frametime) player_powerups(this);
2123
2124         if (IS_DEAD(this)) {
2125                 if (this.personal && g_race_qualifying) {
2126                         if (time > this.respawn_time) {
2127                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2128                                 respawn(this);
2129                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2130                         }
2131                 } else {
2132                         if (frametime) player_anim(this);
2133
2134                         if (this.respawn_flags & RESPAWN_DENY)
2135                         {
2136                                 STAT(RESPAWN_TIME, this) = 0;
2137                                 return false;
2138                         }
2139
2140                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2141
2142                         switch(this.deadflag)
2143                         {
2144                                 case DEAD_DYING:
2145                                 {
2146                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2147                                                 this.deadflag = DEAD_RESPAWNING;
2148                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2149                                                 this.deadflag = DEAD_DEAD;
2150                                         break;
2151                                 }
2152                                 case DEAD_DEAD:
2153                                 {
2154                                         if (button_pressed)
2155                                                 this.deadflag = DEAD_RESPAWNABLE;
2156                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2157                                                 this.deadflag = DEAD_RESPAWNING;
2158                                         break;
2159                                 }
2160                                 case DEAD_RESPAWNABLE:
2161                                 {
2162                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2163                                                 this.deadflag = DEAD_RESPAWNING;
2164                                         break;
2165                                 }
2166                                 case DEAD_RESPAWNING:
2167                                 {
2168                                         if (time > this.respawn_time)
2169                                         {
2170                                                 this.respawn_time = time + 1; // only retry once a second
2171                                                 this.respawn_time_max = this.respawn_time;
2172                                                 respawn(this);
2173                                         }
2174                                         break;
2175                                 }
2176                         }
2177
2178                         ShowRespawnCountdown(this);
2179
2180                         if (this.respawn_flags & RESPAWN_SILENT)
2181                                 STAT(RESPAWN_TIME, this) = 0;
2182                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2183                         {
2184                                 if (time < this.respawn_time)
2185                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2186                                 else if (this.deadflag != DEAD_RESPAWNING)
2187                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2188                         }
2189                         else
2190                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2191                 }
2192
2193                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2194                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2195                         STAT(RESPAWN_TIME, this) *= -1;
2196
2197                 return false;
2198         }
2199
2200         bool have_hook = false;
2201         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2202         {
2203                 .entity weaponentity = weaponentities[slot];
2204                 if(this.(weaponentity).hook.state)
2205                 {
2206                         have_hook = true;
2207                         break;
2208                 }
2209         }
2210         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2211         if (have_hook) {
2212                 do_crouch = false;
2213         } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2214                 do_crouch = false;
2215         } else if (this.vehicle) {
2216                 do_crouch = false;
2217         } else if (STAT(FROZEN, this)) {
2218                 do_crouch = false;
2219     }
2220
2221         if (do_crouch) {
2222                 if (!this.crouch) {
2223                         this.crouch = true;
2224                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2225                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2226                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2227                 }
2228         } else if (this.crouch) {
2229         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2230         if (!trace_startsolid) {
2231             this.crouch = false;
2232             this.view_ofs = STAT(PL_VIEW_OFS, this);
2233             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2234         }
2235         }
2236
2237         FixPlayermodel(this);
2238
2239         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2240         //if(frametime)
2241         {
2242                 this.items &= ~this.items_added;
2243
2244                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2245                 {
2246                         .entity weaponentity = weaponentities[slot];
2247                         W_WeaponFrame(this, weaponentity);
2248
2249                         if(slot == 0)
2250                         {
2251                                 this.clip_load = this.(weaponentity).clip_load;
2252                                 this.clip_size = this.(weaponentity).clip_size;
2253                         }
2254                 }
2255
2256                 this.items_added = 0;
2257                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2258             this.items_added |= IT_FUEL;
2259
2260                 this.items |= this.items_added;
2261         }
2262
2263         player_regen(this);
2264
2265         // WEAPONTODO: Add a weapon request for this
2266         // rot vortex charge to the charge limit
2267         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2268         {
2269                 .entity weaponentity = weaponentities[slot];
2270                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2271                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2272         }
2273
2274         if (frametime) player_anim(this);
2275
2276         // secret status
2277         secrets_setstatus(this);
2278
2279         // monsters status
2280         monsters_setstatus(this);
2281
2282         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2283
2284         return true;
2285 }
2286
2287 void ObserverThink(entity this)
2288 {
2289         if ( CS(this).impulse )
2290         {
2291                 MinigameImpulse(this, CS(this).impulse);
2292                 CS(this).impulse = 0;
2293         }
2294
2295         if (this.flags & FL_JUMPRELEASED) {
2296                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2297                         this.flags &= ~FL_JUMPRELEASED;
2298                         this.flags |= FL_SPAWNING;
2299                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2300                         this.flags &= ~FL_JUMPRELEASED;
2301                         if(SpectateNext(this)) {
2302                                 TRANSMUTE(Spectator, this);
2303                         }
2304                 } else {
2305                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2306                         set_movetype(this, preferred_movetype);
2307                 }
2308         } else {
2309                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2310                         this.flags |= FL_JUMPRELEASED;
2311                         if(this.flags & FL_SPAWNING)
2312                         {
2313                                 this.flags &= ~FL_SPAWNING;
2314                                 Join(this);
2315                                 return;
2316                         }
2317                 }
2318         }
2319 }
2320
2321 void SpectatorThink(entity this)
2322 {
2323         if ( CS(this).impulse )
2324         {
2325                 if(MinigameImpulse(this, CS(this).impulse))
2326                         CS(this).impulse = 0;
2327
2328                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2329                 {
2330                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2331                         CS(this).impulse = 0;
2332                         return;
2333                 }
2334         }
2335
2336         if (this.flags & FL_JUMPRELEASED) {
2337                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2338                         this.flags &= ~FL_JUMPRELEASED;
2339                         this.flags |= FL_SPAWNING;
2340                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2341                         this.flags &= ~FL_JUMPRELEASED;
2342                         if(SpectateNext(this)) {
2343                                 TRANSMUTE(Spectator, this);
2344                         } else {
2345                                 TRANSMUTE(Observer, this);
2346                                 PutClientInServer(this);
2347                         }
2348                         CS(this).impulse = 0;
2349                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2350                         this.flags &= ~FL_JUMPRELEASED;
2351                         if(SpectatePrev(this)) {
2352                                 TRANSMUTE(Spectator, this);
2353                         } else {
2354                                 TRANSMUTE(Observer, this);
2355                                 PutClientInServer(this);
2356                         }
2357                         CS(this).impulse = 0;
2358                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2359                         this.flags &= ~FL_JUMPRELEASED;
2360                         TRANSMUTE(Observer, this);
2361                         PutClientInServer(this);
2362                 } else {
2363                         if(!SpectateUpdate(this))
2364                                 PutObserverInServer(this);
2365                 }
2366         } else {
2367                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2368                         this.flags |= FL_JUMPRELEASED;
2369                         if(this.flags & FL_SPAWNING)
2370                         {
2371                                 this.flags &= ~FL_SPAWNING;
2372                                 Join(this);
2373                                 return;
2374                         }
2375                 }
2376                 if(!SpectateUpdate(this))
2377                         PutObserverInServer(this);
2378         }
2379
2380         this.flags |= FL_CLIENT | FL_NOTARGET;
2381 }
2382
2383 void vehicles_enter (entity pl, entity veh);
2384 void PlayerUseKey(entity this)
2385 {
2386         if (!IS_PLAYER(this))
2387                 return;
2388
2389         if(this.vehicle)
2390         {
2391                 if(!game_stopped)
2392                 {
2393                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2394                         return;
2395                 }
2396         }
2397         else if(autocvar_g_vehicles_enter)
2398         {
2399                 if(!STAT(FROZEN, this))
2400                 if(!IS_DEAD(this))
2401                 if(!game_stopped)
2402                 {
2403                         entity head, closest_target = NULL;
2404                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2405
2406                         while(head) // find the closest acceptable target to enter
2407                         {
2408                                 if(IS_VEHICLE(head))
2409                                 if(!IS_DEAD(head))
2410                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2411                                 if(head.takedamage != DAMAGE_NO)
2412                                 {
2413                                         if(closest_target)
2414                                         {
2415                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2416                                                 { closest_target = head; }
2417                                         }
2418                                         else { closest_target = head; }
2419                                 }
2420
2421                                 head = head.chain;
2422                         }
2423
2424                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2425                 }
2426         }
2427
2428         // a use key was pressed; call handlers
2429         MUTATOR_CALLHOOK(PlayerUseKey, this);
2430 }
2431
2432
2433 /*
2434 =============
2435 PlayerPreThink
2436
2437 Called every frame for each client before the physics are run
2438 =============
2439 */
2440 .float last_vehiclecheck;
2441 void PlayerPreThink (entity this)
2442 {
2443         WarpZone_PlayerPhysics_FixVAngle(this);
2444
2445         if (frametime) {
2446                 // physics frames: update anticheat stuff
2447                 anticheat_prethink(this);
2448         }
2449
2450         if (blockSpectators && frametime) {
2451                 // WORKAROUND: only use dropclient in server frames (frametime set).
2452                 // Never use it in cl_movement frames (frametime zero).
2453                 checkSpectatorBlock(this);
2454     }
2455
2456         zoomstate_set = false;
2457
2458         // Check for nameless players
2459         if (isInvisibleString(this.netname)) {
2460                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2461                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2462         }
2463         if (this.netname != CS(this).netname_previous) {
2464                 if (autocvar_sv_eventlog) {
2465                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2466         }
2467                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2468                 CS(this).netname_previous = strzone(this.netname);
2469         }
2470
2471         // version nagging
2472         if (CS(this).version_nagtime && this.cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2473         CS(this).version_nagtime = 0;
2474         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2475             // git client
2476         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2477             // git server
2478             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2479         } else {
2480             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2481             if (r < 0) { // old client
2482                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2483             } else if (r > 0) { // old server
2484                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2485             }
2486         }
2487     }
2488
2489         // GOD MODE info
2490         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2491         {
2492                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2493                 this.max_armorvalue = 0;
2494         }
2495
2496         if(IS_PLAYER(this))
2497         {
2498                 if (STAT(FROZEN, this) == 2)
2499                 {
2500                         this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2501                         this.health = max(1, this.revive_progress * start_health);
2502                         this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2503
2504                         if (this.revive_progress >= 1)
2505                                 Unfreeze(this);
2506                 }
2507                 else if (STAT(FROZEN, this) == 3)
2508                 {
2509                         this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2510                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2511
2512                         if (this.health < 1)
2513                         {
2514                                 if (this.vehicle)
2515                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2516                                 if(this.event_damage)
2517                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2518                         }
2519                         else if (this.revive_progress <= 0)
2520                                 Unfreeze(this);
2521                 }
2522         }
2523
2524         MUTATOR_CALLHOOK(PlayerPreThink, this);
2525
2526         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2527         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2528         {
2529                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2530                 {
2531                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2532                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2533                         {
2534                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2535                         }
2536                         else if(!it.owner)
2537                         {
2538                                 if(!it.team || SAME_TEAM(this, it))
2539                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2540                                 else if(autocvar_g_vehicles_steal)
2541                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2542                         }
2543                 });
2544
2545                 this.last_vehiclecheck = time + 1;
2546         }
2547
2548         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2549         {
2550                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2551                         PlayerUseKey(this);
2552                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2553         }
2554
2555         if (IS_REAL_CLIENT(this))
2556                 PrintWelcomeMessage(this);
2557
2558         if (IS_PLAYER(this)) {
2559                 if(!PlayerThink(this))
2560                         return;
2561         }
2562         else if (game_stopped || intermission_running) {
2563                 if(intermission_running)
2564                         IntermissionThink(this);
2565                 return;
2566         }
2567         else if (IS_OBSERVER(this)) {
2568                 ObserverThink(this);
2569         }
2570         else if (IS_SPEC(this)) {
2571                 SpectatorThink(this);
2572         }
2573
2574         // WEAPONTODO: Add weapon request for this
2575         if (!zoomstate_set) {
2576                 bool wep_zoomed = false;
2577                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2578                 {
2579                         .entity weaponentity = weaponentities[slot];
2580                         Weapon thiswep = this.(weaponentity).m_weapon;
2581                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2582                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2583                 }
2584                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2585     }
2586
2587         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2588         {
2589                 CS(this).teamkill_soundtime = 0;
2590
2591                 entity e = CS(this).teamkill_soundsource;
2592                 entity oldpusher = e.pusher;
2593                 e.pusher = this;
2594                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2595                 e.pusher = oldpusher;
2596         }
2597
2598         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2599                 CS(this).taunt_soundtime = 0;
2600                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2601         }
2602
2603         target_voicescript_next(this);
2604
2605         // WEAPONTODO: Move into weaponsystem somehow
2606         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2607         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2608         {
2609                 .entity weaponentity = weaponentities[slot];
2610                 if(this.(weaponentity).m_weapon == WEP_Null)
2611                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2612         }
2613 }
2614
2615 void DrownPlayer(entity this)
2616 {
2617         if(IS_DEAD(this))
2618                 return;
2619
2620         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2621         {
2622                 if(this.air_finished < time)
2623                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2624                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2625                 this.dmg = 2;
2626         }
2627         else if (this.air_finished < time)
2628         {       // drown!
2629                 if (this.pain_finished < time)
2630                 {
2631                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2632                         this.pain_finished = time + 0.5;
2633                 }
2634         }
2635 }
2636
2637 .bool move_qcphysics;
2638
2639 void Player_Physics(entity this)
2640 {
2641         set_movetype(this, this.move_movetype);
2642
2643         if(!this.move_qcphysics)
2644                 return;
2645
2646         if(!frametime && !CS(this).pm_frametime)
2647                 return;
2648
2649         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2650
2651         CS(this).pm_frametime = 0;
2652 }
2653
2654 /*
2655 =============
2656 PlayerPostThink
2657
2658 Called every frame for each client after the physics are run
2659 =============
2660 */
2661 void PlayerPostThink (entity this)
2662 {
2663         Player_Physics(this);
2664
2665         if (sv_maxidle > 0)
2666         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2667         if (IS_REAL_CLIENT(this))
2668         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2669         {
2670                 int totalClients = 0;
2671                 if(sv_maxidle_slots > 0)
2672                 {
2673                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2674                         {
2675                                 ++totalClients;
2676                         });
2677                 }
2678
2679                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2680                 { /* do nothing */ }
2681                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2682                 {
2683                         if (CS(this).idlekick_lasttimeleft)
2684                         {
2685                                 CS(this).idlekick_lasttimeleft = 0;
2686                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2687                         }
2688                 }
2689                 else
2690                 {
2691                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2692                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2693                                 if (!CS(this).idlekick_lasttimeleft)
2694                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2695                         }
2696                         if (timeleft <= 0) {
2697                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2698                                 dropclient(this);
2699                                 return;
2700                         }
2701                         else if (timeleft <= 10) {
2702                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2703                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2704                 }
2705                                 CS(this).idlekick_lasttimeleft = timeleft;
2706                         }
2707                 }
2708         }
2709
2710         CheatFrame(this);
2711
2712         if (game_stopped)
2713         {
2714                 this.solid = SOLID_NOT;
2715                 this.takedamage = DAMAGE_NO;
2716                 set_movetype(this, MOVETYPE_NONE);
2717         }
2718
2719         if (IS_PLAYER(this)) {
2720                 DrownPlayer(this);
2721                 UpdateChatBubble(this);
2722                 if (CS(this).impulse) ImpulseCommands(this);
2723                 if (game_stopped)
2724                 {
2725                         CSQCMODEL_AUTOUPDATE(this);
2726                         return;
2727                 }
2728                 GetPressedKeys(this);
2729         }
2730
2731         if (this.waypointsprite_attachedforcarrier) {
2732             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2733                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2734     }
2735
2736         playerdemo_write(this);
2737
2738         CSQCMODEL_AUTOUPDATE(this);
2739 }
2740
2741 // hack to copy the button fields from the client entity to the Client State
2742 void PM_UpdateButtons(entity this, entity store)
2743 {
2744         if(this.impulse)
2745                 store.impulse = this.impulse;
2746         this.impulse = 0;
2747
2748         store.button0 = this.button0;
2749         store.button2 = this.button2;
2750         store.button3 = this.button3;
2751         store.button4 = this.button4;
2752         store.button5 = this.button5;
2753         store.button6 = this.button6;
2754         store.button7 = this.button7;
2755         store.button8 = this.button8;
2756         store.button9 = this.button9;
2757         store.button10 = this.button10;
2758         store.button11 = this.button11;
2759         store.button12 = this.button12;
2760         store.button13 = this.button13;
2761         store.button14 = this.button14;
2762         store.button15 = this.button15;
2763         store.button16 = this.button16;
2764         store.buttonuse = this.buttonuse;
2765         store.buttonchat = this.buttonchat;
2766
2767         store.cursor_active = this.cursor_active;
2768         store.cursor_screen = this.cursor_screen;
2769         store.cursor_trace_start = this.cursor_trace_start;
2770         store.cursor_trace_endpos = this.cursor_trace_endpos;
2771         store.cursor_trace_ent = this.cursor_trace_ent;
2772
2773         store.ping = this.ping;
2774         store.ping_packetloss = this.ping_packetloss;
2775         store.ping_movementloss = this.ping_movementloss;
2776
2777         store.v_angle = this.v_angle;
2778         store.movement = this.movement;
2779 }