qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <common/csqcmodel_settings.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/effects/all.qh>
   6 #include <common/effects/qc/globalsound.qh>
   7 #include <common/ent_cs.qh>
   8 #include <common/gamemodes/_mod.qh>
   9 #include <common/gamemodes/gamemode/nexball/sv_nexball.qh>
  10 #include <common/items/_mod.qh>
  11 #include <common/items/inventory.qh>
  12 #include <common/mapobjects/func/conveyor.qh>
  13 #include <common/mapobjects/func/ladder.qh>
  14 #include <common/mapobjects/subs.qh>
  15 #include <common/mapobjects/target/spawnpoint.qh>
  16 #include <common/mapobjects/teleporters.qh>
  17 #include <common/mapobjects/trigger/counter.qh>
  18 #include <common/mapobjects/trigger/secret.qh>
  19 #include <common/mapobjects/trigger/swamp.qh>
  20 #include <common/mapobjects/triggers.qh>
  21 #include <common/minigames/sv_minigames.qh>
  22 #include <common/monsters/sv_monsters.qh>
  23 #include <common/mutators/mutator/instagib/sv_instagib.qh>
  24 #include <common/mutators/mutator/nades/nades.qh>
  25 #include <common/mutators/mutator/overkill/oknex.qh>
  26 #include <common/mutators/mutator/waypoints/all.qh>
  27 #include <common/net_linked.qh>
  28 #include <common/net_notice.qh>
  29 #include <common/notifications/all.qh>
  30 #include <common/physics/player.qh>
  31 #include <common/playerstats.qh>
  32 #include <common/state.qh>
  33 #include <common/stats.qh>
  34 #include <common/vehicles/all.qh>
  35 #include <common/vehicles/sv_vehicles.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/weapons/_all.qh>
  38 #include <common/weapons/weapon/vortex.qh>
  39 #include <common/wepent.qh>
  40 #include <lib/csqcmodel/sv_model.qh>
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/server.qh>
  43 #include <server/anticheat.qh>
  44 #include <server/antilag.qh>
  45 #include <server/bot/api.qh>
  46 #include <server/bot/default/cvars.qh>
  47 #include <server/campaign.qh>
  48 #include <server/chat.qh>
  49 #include <server/cheats.qh>
  50 #include <server/clientkill.qh>
  51 #include <server/command/common.qh>
  52 #include <server/command/common.qh>
  53 #include <server/command/vote.qh>
  54 #include <server/compat/quake3.qh>
  55 #include <server/damage.qh>
  56 #include <server/gamelog.qh>
  57 #include <server/handicap.qh>
  58 #include <server/hook.qh>
  59 #include <server/impulse.qh>
  60 #include <server/intermission.qh>
  61 #include <server/ipban.qh>
  62 #include <server/main.qh>
  63 #include <server/mutators/_mod.qh>
  64 #include <server/player.qh>
  65 #include <server/portals.qh>
  66 #include <server/race.qh>
  67 #include <server/resources.qh>
  68 #include <server/scores.qh>
  69 #include <server/scores_rules.qh>
  70 #include <server/spawnpoints.qh>
  71 #include <server/teamplay.qh>
  72 #include <server/weapons/accuracy.qh>
  73 #include <server/weapons/common.qh>
  74 #include <server/weapons/hitplot.qh>
  75 #include <server/weapons/selection.qh>
  76 #include <server/weapons/tracing.qh>
  77 #include <server/weapons/weaponsystem.qh>
  78 #include <server/world.qh>
  79
  80 STATIC_METHOD(Client, Add, void(Client this, int _team))
  81 {
  82     ClientConnect(this);
  83     TRANSMUTE(Player, this);
  84     this.frame = 12; // 7
  85     this.team = _team;
  86     PutClientInServer(this);
  87 }
  88
  89 STATIC_METHOD(Client, Remove, void(Client this))
  90 {
  91     TRANSMUTE(Observer, this);
  92     PutClientInServer(this);
  93     ClientDisconnect(this);
  94 }
  95
  96 void send_CSQC_teamnagger() {
  97         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  98 }
  99
 100 int CountSpectators(entity player, entity to)
 101 {
 102         if(!player) { return 0; } // not sure how, but best to be safe
 103
 104         int spec_count = 0;
 105
 106         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 107         {
 108                 spec_count++;
 109         });
 110
 111         return spec_count;
 112 }
 113
 114 void WriteSpectators(entity player, entity to)
 115 {
 116         if(!player) { return; } // not sure how, but best to be safe
 117
 118         int spec_count = 0;
 119         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 120         {
 121                 if(spec_count >= MAX_SPECTATORS)
 122                         break;
 123                 WriteByte(MSG_ENTITY, num_for_edict(it));
 124                 ++spec_count;
 125         });
 126 }
 127
 128 bool ClientData_Send(entity this, entity to, int sf)
 129 {
 130         assert(to == this.owner, return false);
 131
 132         entity e = to;
 133         if (IS_SPEC(e)) e = e.enemy;
 134
 135         sf = 0;
 136         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 137         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 138         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 139         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 140
 141         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 142         WriteByte(MSG_ENTITY, sf);
 143
 144         if (sf & BIT(1))
 145                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 146
 147         if(sf & BIT(4))
 148         {
 149                 float specs = CountSpectators(e, to);
 150                 WriteByte(MSG_ENTITY, specs);
 151                 WriteSpectators(e, to);
 152         }
 153
 154         return true;
 155 }
 156
 157 void ClientData_Attach(entity this)
 158 {
 159         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 160         CS(this).clientdata.drawonlytoclient = this;
 161         CS(this).clientdata.owner = this;
 162 }
 163
 164 void ClientData_Detach(entity this)
 165 {
 166         delete(CS(this).clientdata);
 167         CS(this).clientdata = NULL;
 168 }
 169
 170 void ClientData_Touch(entity e)
 171 {
 172         entity cd = CS(e).clientdata;
 173         if (cd) { cd.SendFlags = 1; }
 174
 175         // make it spectatable
 176         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 177         {
 178                 entity cd = CS(it).clientdata;
 179                 if (cd) { cd.SendFlags = 1; }
 180         });
 181 }
 182
 183
 184 /*
 185 =============
 186 CheckPlayerModel
 187
 188 Checks if the argument string can be a valid playermodel.
 189 Returns a valid one in doubt.
 190 =============
 191 */
 192 string FallbackPlayerModel;
 193 string CheckPlayerModel(string plyermodel) {
 194         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 195         {
 196                 // note: we cannot summon Don Strunzone here, some player may
 197                 // still have the model string set. In case anyone manages how
 198                 // to change a cvar default, we'll have a small leak here.
 199                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 200         }
 201         // only in right path
 202         if(substring(plyermodel, 0, 14) != "models/player/")
 203                 return FallbackPlayerModel;
 204         // only good file extensions
 205         if(substring(plyermodel, -4, 4) != ".iqm"
 206                 && substring(plyermodel, -4, 4) != ".zym"
 207                 && substring(plyermodel, -4, 4) != ".dpm"
 208                 && substring(plyermodel, -4, 4) != ".md3"
 209                 && substring(plyermodel, -4, 4) != ".psk")
 210         {
 211                 return FallbackPlayerModel;
 212         }
 213         // forbid the LOD models
 214         if(substring(plyermodel, -9, 5) == "_lod1" || substring(plyermodel, -9, 5) == "_lod2")
 215                 return FallbackPlayerModel;
 216         if(plyermodel != strtolower(plyermodel))
 217                 return FallbackPlayerModel;
 218         // also, restrict to server models
 219         if(autocvar_sv_servermodelsonly)
 220         {
 221                 if(!fexists(plyermodel))
 222                         return FallbackPlayerModel;
 223         }
 224         return plyermodel;
 225 }
 226
 227 void setplayermodel(entity e, string modelname)
 228 {
 229         precache_model(modelname);
 230         _setmodel(e, modelname);
 231         player_setupanimsformodel(e);
 232         if(!autocvar_g_debug_globalsounds)
 233                 UpdatePlayerSounds(e);
 234 }
 235
 236 /** putting a client as observer in the server */
 237 void PutObserverInServer(entity this)
 238 {
 239         bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 240         PlayerState_detach(this);
 241
 242         if (IS_PLAYER(this))
 243         {
 244                 if(GetResource(this, RES_HEALTH) >= 1)
 245                 {
 246                         // despawn effect
 247                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 248                 }
 249
 250                 // was a player, recount votes and ready status
 251                 if(IS_REAL_CLIENT(this))
 252                 {
 253                         if (vote_called) { VoteCount(false); }
 254                         ReadyCount();
 255                 }
 256                 entcs_update_players(this);
 257         }
 258
 259         entity spot = SelectSpawnPoint(this, true);
 260         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 261         this.angles = vec2(spot.angles);
 262         this.fixangle = true;
 263         // offset it so that the spectator spawns higher off the ground, looks better this way
 264         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 265         if (IS_REAL_CLIENT(this))
 266         {
 267                 msg_entity = this;
 268                 WriteByte(MSG_ONE, SVC_SETVIEW);
 269                 WriteEntity(MSG_ONE, this);
 270         }
 271         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 272         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 273         if(!autocvar_g_debug_globalsounds)
 274         {
 275                 // needed for player sounds
 276                 this.model = "";
 277                 FixPlayermodel(this);
 278         }
 279         setmodel(this, MDL_Null);
 280         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 281         this.view_ofs = '0 0 0';
 282
 283         RemoveGrapplingHooks(this);
 284         Portal_ClearAll(this);
 285         Unfreeze(this, false);
 286         SetSpectatee(this, NULL);
 287
 288         if (this.alivetime)
 289         {
 290                 if (!warmup_stage)
 291                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 292                 this.alivetime = 0;
 293         }
 294
 295         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 296
 297         WaypointSprite_PlayerDead(this);
 298
 299         if (CS(this).killcount != FRAGS_SPECTATOR && !game_stopped && CHAT_NOSPECTATORS())
 300                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 301
 302         accuracy_resend(this);
 303
 304         CS(this).spectatortime = time;
 305         if(this.bot_attack)
 306                 IL_REMOVE(g_bot_targets, this);
 307         this.bot_attack = false;
 308         if(this.monster_attack)
 309                 IL_REMOVE(g_monster_targets, this);
 310         this.monster_attack = false;
 311         STAT(HUD, this) = HUD_NORMAL;
 312         TRANSMUTE(Observer, this);
 313         this.iscreature = false;
 314         this.teleportable = TELEPORT_SIMPLE;
 315         if(this.damagedbycontents)
 316                 IL_REMOVE(g_damagedbycontents, this);
 317         this.damagedbycontents = false;
 318         SetResourceExplicit(this, RES_HEALTH, FRAGS_SPECTATOR);
 319         SetSpectatee_status(this, etof(this));
 320         this.takedamage = DAMAGE_NO;
 321         this.solid = SOLID_NOT;
 322         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 323         this.flags = FL_CLIENT | FL_NOTARGET;
 324         this.effects = 0;
 325         SetResourceExplicit(this, RES_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 326         this.pauserotarmor_finished = 0;
 327         this.pauserothealth_finished = 0;
 328         this.pauseregen_finished = 0;
 329         this.damageforcescale = 0;
 330         this.death_time = 0;
 331         this.respawn_flags = 0;
 332         this.respawn_time = 0;
 333         STAT(RESPAWN_TIME, this) = 0;
 334         this.alpha = 0;
 335         this.scale = 0;
 336         this.fade_time = 0;
 337         this.pain_finished = 0;
 338         STAT(STRENGTH_FINISHED, this) = 0;
 339         STAT(INVINCIBLE_FINISHED, this) = 0;
 340         STAT(SUPERWEAPONS_FINISHED, this) = 0;
 341         STAT(AIR_FINISHED, this) = 0;
 342         //this.dphitcontentsmask = 0;
 343         this.dphitcontentsmask = DPCONTENTS_SOLID;
 344         if (autocvar_g_playerclip_collisions)
 345                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 346         this.pushltime = 0;
 347         this.istypefrag = 0;
 348         setthink(this, func_null);
 349         this.nextthink = 0;
 350         this.deadflag = DEAD_NO;
 351         UNSET_DUCKED(this);
 352         STAT(REVIVE_PROGRESS, this) = 0;
 353         this.revival_time = 0;
 354         this.draggable = drag_undraggable;
 355
 356         this.items = 0;
 357         STAT(WEAPONS, this) = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378         this.event_heal = func_null;
 379
 380         for(int slot = 0; slot < MAX_AXH; ++slot)
 381         {
 382                 entity axh = this.(AuxiliaryXhair[slot]);
 383                 this.(AuxiliaryXhair[slot]) = NULL;
 384
 385                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 386                         delete(axh);
 387         }
 388
 389         if (mutator_returnvalue)
 390         {
 391                 // mutator prevents resetting teams+score
 392         }
 393         else
 394         {
 395                 SetPlayerTeam(this, -1, TEAM_CHANGE_SPECTATOR);
 396                 this.frags = FRAGS_SPECTATOR;
 397         }
 398         if (CS(this).just_joined)
 399                 CS(this).just_joined = false;
 400 }
 401
 402 int player_getspecies(entity this)
 403 {
 404         get_model_parameters(this.model, this.skin);
 405         int s = get_model_parameters_species;
 406         get_model_parameters(string_null, 0);
 407         if (s < 0) return SPECIES_HUMAN;
 408         return s;
 409 }
 410
 411 .float model_randomizer;
 412 void FixPlayermodel(entity player)
 413 {
 414         string defaultmodel = "";
 415         int defaultskin = 0;
 416         if(autocvar_sv_defaultcharacter)
 417         {
 418                 if(teamplay)
 419                 {
 420                         switch(player.team)
 421                         {
 422                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 423                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 424                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 425                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 426                         }
 427                 }
 428
 429                 if(defaultmodel == "")
 430                 {
 431                         defaultmodel = autocvar_sv_defaultplayermodel;
 432                         defaultskin = autocvar_sv_defaultplayerskin;
 433                 }
 434
 435                 int n = tokenize_console(defaultmodel);
 436                 if(n > 0)
 437                 {
 438                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 439                         // However, do NOT randomize if the player-selected model is in the list.
 440                         for (int i = 0; i < n; ++i)
 441                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 442                                         defaultmodel = argv(i);
 443                 }
 444
 445                 int i = strstrofs(defaultmodel, ":", 0);
 446                 if(i >= 0)
 447                 {
 448                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 449                         defaultmodel = substring(defaultmodel, 0, i);
 450                 }
 451         }
 452         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 453         {
 454                 if(teamplay)
 455                 {
 456                         switch(player.team)
 457                         {
 458                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 459                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 460                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 461                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 462                         }
 463                 }
 464
 465                 if(!defaultskin)
 466                         defaultskin = autocvar_sv_defaultplayerskin;
 467         }
 468
 469         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 470         defaultmodel = M_ARGV(0, string);
 471         defaultskin = M_ARGV(1, int);
 472
 473         bool chmdl = false;
 474         int oldskin;
 475         if(defaultmodel != "")
 476         {
 477                 if (defaultmodel != player.model)
 478                 {
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, defaultmodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 oldskin = player.skin;
 487                 player.skin = defaultskin;
 488         } else {
 489                 if (player.playermodel != player.model || player.playermodel == "")
 490                 {
 491                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 492                         vector m1 = player.mins;
 493                         vector m2 = player.maxs;
 494                         setplayermodel (player, player.playermodel);
 495                         setsize (player, m1, m2);
 496                         chmdl = true;
 497                 }
 498
 499                 if(!autocvar_sv_defaultcharacterskin)
 500                 {
 501                         oldskin = player.skin;
 502                         player.skin = stof(player.playerskin);
 503                 }
 504                 else
 505                 {
 506                         oldskin = player.skin;
 507                         player.skin = defaultskin;
 508                 }
 509         }
 510
 511         if(chmdl || oldskin != player.skin) // model or skin has changed
 512         {
 513                 player.species = player_getspecies(player); // update species
 514                 if(!autocvar_g_debug_globalsounds)
 515                         UpdatePlayerSounds(player); // update skin sounds
 516         }
 517
 518         if(!teamplay)
 519                 if(strlen(autocvar_sv_defaultplayercolors))
 520                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 521                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 522 }
 523
 524 void PutPlayerInServer(entity this)
 525 {
 526         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 527
 528         PlayerState_attach(this);
 529         accuracy_resend(this);
 530
 531         if (this.team < 0)
 532                 TeamBalance_JoinBestTeam(this);
 533
 534         entity spot = SelectSpawnPoint(this, false);
 535         if (!spot) {
 536                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 537                 return; // spawn failed
 538         }
 539
 540         TRANSMUTE(Player, this);
 541
 542         CS(this).wasplayer = true;
 543         this.iscreature = true;
 544         this.teleportable = TELEPORT_NORMAL;
 545         if(!this.damagedbycontents)
 546                 IL_PUSH(g_damagedbycontents, this);
 547         this.damagedbycontents = true;
 548         set_movetype(this, MOVETYPE_WALK);
 549         this.solid = SOLID_SLIDEBOX;
 550         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 551         if (autocvar_g_playerclip_collisions)
 552                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 553         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 554                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 555         this.frags = FRAGS_PLAYER;
 556         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 557         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 558         if (autocvar__notarget)
 559                 this.flags |= FL_NOTARGET;
 560         this.takedamage = DAMAGE_AIM;
 561         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 562
 563         if (warmup_stage) {
 564                 SetResource(this, RES_SHELLS, warmup_start_ammo_shells);
 565                 SetResource(this, RES_BULLETS, warmup_start_ammo_nails);
 566                 SetResource(this, RES_ROCKETS, warmup_start_ammo_rockets);
 567                 SetResource(this, RES_CELLS, warmup_start_ammo_cells);
 568                 SetResource(this, RES_PLASMA, warmup_start_ammo_plasma);
 569                 SetResource(this, RES_FUEL, warmup_start_ammo_fuel);
 570                 SetResource(this, RES_HEALTH, warmup_start_health);
 571                 SetResource(this, RES_ARMOR, warmup_start_armorvalue);
 572                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 573         } else {
 574                 SetResource(this, RES_SHELLS, start_ammo_shells);
 575                 SetResource(this, RES_BULLETS, start_ammo_nails);
 576                 SetResource(this, RES_ROCKETS, start_ammo_rockets);
 577                 SetResource(this, RES_CELLS, start_ammo_cells);
 578                 SetResource(this, RES_PLASMA, start_ammo_plasma);
 579                 SetResource(this, RES_FUEL, start_ammo_fuel);
 580                 SetResource(this, RES_HEALTH, start_health);
 581                 SetResource(this, RES_ARMOR, start_armorvalue);
 582                 STAT(WEAPONS, this) = start_weapons;
 583                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 584                 {
 585                         GiveRandomWeapons(this, random_start_weapons_count,
 586                                 autocvar_g_random_start_weapons, random_start_ammo);
 587                 }
 588         }
 589         SetSpectatee_status(this, 0);
 590
 591         PS(this).dual_weapons = '0 0 0';
 592
 593         STAT(SUPERWEAPONS_FINISHED, this) = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 594
 595         this.items = start_items;
 596
 597         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 598         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 599         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 600         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 601         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 602         if (!sv_ready_restart_after_countdown && time < game_starttime)
 603         {
 604                 float f = game_starttime - time;
 605                 this.spawnshieldtime += f;
 606                 this.pauserotarmor_finished += f;
 607                 this.pauserothealth_finished += f;
 608                 this.pauseregen_finished += f;
 609         }
 610
 611         this.damageforcescale = autocvar_g_player_damageforcescale;
 612         this.death_time = 0;
 613         this.respawn_flags = 0;
 614         this.respawn_time = 0;
 615         STAT(RESPAWN_TIME, this) = 0;
 616         bool q3dfcompat = autocvar_sv_q3defragcompat && autocvar_sv_q3defragcompat_changehitbox;
 617         this.scale = ((q3dfcompat) ? 0.9 : autocvar_sv_player_scale);
 618         this.fade_time = 0;
 619         this.pain_finished = 0;
 620         this.pushltime = 0;
 621         setthink(this, func_null); // players have no think function
 622         this.nextthink = 0;
 623         this.dmg_team = 0;
 624         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 625
 626         this.deadflag = DEAD_NO;
 627
 628         this.angles = spot.angles;
 629         this.angles_z = 0; // never spawn tilted even if the spot says to
 630         if (IS_BOT_CLIENT(this))
 631         {
 632                 this.v_angle = this.angles;
 633                 bot_aim_reset(this);
 634         }
 635         this.fixangle = true; // turn this way immediately
 636         this.oldvelocity = this.velocity = '0 0 0';
 637         this.avelocity = '0 0 0';
 638         this.punchangle = '0 0 0';
 639         this.punchvector = '0 0 0';
 640
 641         STAT(STRENGTH_FINISHED, this) = 0;
 642         STAT(INVINCIBLE_FINISHED, this) = 0;
 643         this.fire_endtime = -1;
 644         STAT(REVIVE_PROGRESS, this) = 0;
 645         this.revival_time = 0;
 646
 647         // TODO: we can't set these in the PlayerSpawn hook since the target code is called before it!
 648         STAT(BUFFS, this) = 0;
 649         STAT(BUFF_TIME, this) = 0;
 650
 651         STAT(AIR_FINISHED, this) = 0;
 652         this.waterlevel = WATERLEVEL_NONE;
 653         this.watertype = CONTENT_EMPTY;
 654
 655         entity spawnevent = new_pure(spawnevent);
 656         spawnevent.owner = this;
 657         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 658
 659         // Cut off any still running player sounds.
 660         stopsound(this, CH_PLAYER_SINGLE);
 661
 662         this.model = "";
 663         FixPlayermodel(this);
 664         this.drawonlytoclient = NULL;
 665
 666         this.viewloc = NULL;
 667
 668         for(int slot = 0; slot < MAX_AXH; ++slot)
 669         {
 670                 entity axh = this.(AuxiliaryXhair[slot]);
 671                 this.(AuxiliaryXhair[slot]) = NULL;
 672
 673                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 674                         delete(axh);
 675         }
 676
 677         this.spawnpoint_targ = NULL;
 678
 679         UNSET_DUCKED(this);
 680         this.view_ofs = STAT(PL_VIEW_OFS, this);
 681         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 682         this.spawnorigin = spot.origin;
 683         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 684         // don't reset back to last position, even if new position is stuck in solid
 685         this.oldorigin = this.origin;
 686         if(this.conveyor)
 687                 IL_REMOVE(g_conveyed, this);
 688         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 689         if(this.swampslug)
 690                 IL_REMOVE(g_swamped, this);
 691         this.swampslug = NULL;
 692         this.swamp_interval = 0;
 693         if(this.ladder_entity)
 694                 IL_REMOVE(g_ladderents, this);
 695         this.ladder_entity = NULL;
 696         IL_EACH(g_counters, it.realowner == this,
 697         {
 698                 delete(it);
 699         });
 700         STAT(HUD, this) = HUD_NORMAL;
 701
 702         this.event_damage = PlayerDamage;
 703         this.event_heal = PlayerHeal;
 704
 705         this.draggable = func_null;
 706
 707         if(!this.bot_attack)
 708                 IL_PUSH(g_bot_targets, this);
 709         this.bot_attack = true;
 710         if(!this.monster_attack)
 711                 IL_PUSH(g_monster_targets, this);
 712         this.monster_attack = true;
 713         navigation_dynamicgoal_init(this, false);
 714
 715         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 716
 717         // player was spectator
 718         if (CS(this).killcount == FRAGS_SPECTATOR) {
 719                 PlayerScore_Clear(this);
 720                 CS(this).killcount = 0;
 721                 CS(this).startplaytime = time;
 722         }
 723
 724         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 725         {
 726                 .entity weaponentity = weaponentities[slot];
 727                 CL_SpawnWeaponentity(this, weaponentity);
 728         }
 729         this.alpha = default_player_alpha;
 730         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 731         this.exteriorweaponentity.alpha = default_weapon_alpha;
 732
 733         this.speedrunning = false;
 734
 735         this.counter_cnt = 0;
 736         this.fragsfilter_cnt = 0;
 737
 738         target_voicescript_clear(this);
 739
 740         // reset fields the weapons may use
 741         FOREACH(Weapons, true, {
 742                 it.wr_resetplayer(it, this);
 743                         // reload all reloadable weapons
 744                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 745                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 746                         {
 747                                 .entity weaponentity = weaponentities[slot];
 748                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 749                         }
 750                 }
 751         });
 752
 753         {
 754                 string s = spot.target;
 755                 if(g_assault || g_race) // TODO: make targeting work in assault & race without this hack
 756                         spot.target = string_null;
 757                 SUB_UseTargets(spot, this, NULL);
 758                 if(g_assault || g_race)
 759                         spot.target = s;
 760         }
 761
 762         Unfreeze(this, false);
 763
 764         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 765
 766         if (autocvar_spawn_debug)
 767         {
 768                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 769                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 770         }
 771
 772         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 773         {
 774                 .entity weaponentity = weaponentities[slot];
 775                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 776                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 777                 else
 778                         this.(weaponentity).m_switchweapon = WEP_Null;
 779                 this.(weaponentity).m_weapon = WEP_Null;
 780                 this.(weaponentity).weaponname = "";
 781                 this.(weaponentity).m_switchingweapon = WEP_Null;
 782                 this.(weaponentity).cnt = -1;
 783         }
 784
 785         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 786
 787         if (CS(this).impulse) ImpulseCommands(this);
 788
 789         W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
 790         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 791         {
 792                 .entity weaponentity = weaponentities[slot];
 793                 W_WeaponFrame(this, weaponentity);
 794         }
 795
 796         if (!warmup_stage && !this.alivetime)
 797                 this.alivetime = time;
 798
 799         antilag_clear(this, CS(this));
 800 }
 801
 802 /** Called when a client spawns in the server */
 803 void PutClientInServer(entity this)
 804 {
 805         if (IS_BOT_CLIENT(this)) {
 806                 TRANSMUTE(Player, this);
 807         } else if (IS_REAL_CLIENT(this)) {
 808                 msg_entity = this;
 809                 WriteByte(MSG_ONE, SVC_SETVIEW);
 810                 WriteEntity(MSG_ONE, this);
 811         }
 812         if (game_stopped)
 813                 TRANSMUTE(Observer, this);
 814
 815         SetSpectatee(this, NULL);
 816
 817         // reset player keys
 818         if(PS(this))
 819                 PS(this).itemkeys = 0;
 820
 821         MUTATOR_CALLHOOK(PutClientInServer, this);
 822
 823         if (IS_OBSERVER(this)) {
 824                 PutObserverInServer(this);
 825         } else if (IS_PLAYER(this)) {
 826                 PutPlayerInServer(this);
 827         }
 828 }
 829
 830 // TODO do we need all these fields, or should we stop autodetecting runtime
 831 // changes and just have a console command to update this?
 832 bool ClientInit_SendEntity(entity this, entity to, int sf)
 833 {
 834         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 835         return = true;
 836         msg_entity = to;
 837         // MSG_INIT replacement
 838         // TODO: make easier to use
 839         Registry_send_all();
 840         W_PROP_reload(MSG_ONE, to);
 841         ClientInit_misc(this);
 842         MUTATOR_CALLHOOK(Ent_Init);
 843 }
 844 void ClientInit_misc(entity this)
 845 {
 846         int channel = MSG_ONE;
 847         WriteHeader(channel, ENT_CLIENT_INIT);
 848         WriteByte(channel, g_nexball_meter_period * 32);
 849         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 850         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 851         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 852         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 853         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 854         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 855         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 856         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 857
 858         if(autocvar_sv_foginterval && world.fog != "")
 859                 WriteString(channel, world.fog);
 860         else
 861                 WriteString(channel, "");
 862         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 863         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 864         WriteByte(channel, serverflags);
 865         WriteCoord(channel, autocvar_g_trueaim_minrange);
 866 }
 867
 868 void ClientInit_CheckUpdate(entity this)
 869 {
 870         this.nextthink = time;
 871         if(this.count != autocvar_g_balance_armor_blockpercent)
 872         {
 873                 this.count = autocvar_g_balance_armor_blockpercent;
 874                 this.SendFlags |= 1;
 875         }
 876         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 877         {
 878                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 879                 this.SendFlags |= 1;
 880         }
 881 }
 882
 883 void ClientInit_Spawn()
 884 {
 885         entity e = new_pure(clientinit);
 886         setthink(e, ClientInit_CheckUpdate);
 887         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 888
 889         ClientInit_CheckUpdate(e);
 890 }
 891
 892 /*
 893 =============
 894 SetNewParms
 895 =============
 896 */
 897 void SetNewParms ()
 898 {
 899         // initialize parms for a new player
 900         parm1 = -(86400 * 366);
 901
 902         MUTATOR_CALLHOOK(SetNewParms);
 903 }
 904
 905 /*
 906 =============
 907 SetChangeParms
 908 =============
 909 */
 910 void SetChangeParms (entity this)
 911 {
 912         // save parms for level change
 913         parm1 = CS(this).parm_idlesince - time;
 914
 915         MUTATOR_CALLHOOK(SetChangeParms);
 916 }
 917
 918 /*
 919 =============
 920 DecodeLevelParms
 921 =============
 922 */
 923 void DecodeLevelParms(entity this)
 924 {
 925         // load parms
 926         CS(this).parm_idlesince = parm1;
 927         if (CS(this).parm_idlesince == -(86400 * 366))
 928                 CS(this).parm_idlesince = time;
 929
 930         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 931         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - autocvar_sv_maxidle + 60);
 932
 933         MUTATOR_CALLHOOK(DecodeLevelParms);
 934 }
 935
 936 void FixClientCvars(entity e)
 937 {
 938         // send prediction settings to the client
 939         stuffcmd(e, "\nin_bindmap 0 0\n");
 940         if(autocvar_g_antilag == 3) // client side hitscan
 941                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
 942         if(autocvar_sv_gentle)
 943                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
 944
 945         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
 946         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
 947
 948         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
 949
 950         MUTATOR_CALLHOOK(FixClientCvars, e);
 951 }
 952
 953 bool findinlist_abbrev(string tofind, string list)
 954 {
 955         if(list == "" || tofind == "")
 956                 return false; // empty list or search, just return
 957
 958         // this function allows abbreviated strings!
 959         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
 960         {
 961                 return true;
 962         });
 963
 964         return false;
 965 }
 966
 967 bool PlayerInIPList(entity p, string iplist)
 968 {
 969         // some safety checks (never allow local?)
 970         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
 971                 return false;
 972
 973         return findinlist_abbrev(p.netaddress, iplist);
 974 }
 975
 976 bool PlayerInIDList(entity p, string idlist)
 977 {
 978         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
 979         if(!p.crypto_idfp)
 980                 return false;
 981
 982         return findinlist_abbrev(p.crypto_idfp, idlist);
 983 }
 984
 985 bool PlayerInList(entity player, string list)
 986 {
 987         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
 988 }
 989
 990 #ifdef DP_EXT_PRECONNECT
 991 /*
 992 =============
 993 ClientPreConnect
 994
 995 Called once (not at each match start) when a client begins a connection to the server
 996 =============
 997 */
 998 void ClientPreConnect(entity this)
 999 {
1000         if(autocvar_sv_eventlog)
1001         {
1002                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1003                         this.playerid,
1004                         etof(this),
1005                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1006                 ));
1007         }
1008 }
1009 #endif
1010
1011 string GetClientVersionMessage(entity this)
1012 {
1013         if (CS(this).version_mismatch) {
1014                 if(CS(this).version < autocvar_gameversion) {
1015                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1016                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1017                 } else {
1018                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1019                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1020                 }
1021         } else {
1022                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1023         }
1024 }
1025
1026 string getwelcomemessage(entity this)
1027 {
1028         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1029         string modifications = M_ARGV(0, string);
1030
1031         if(g_weaponarena)
1032         {
1033                 if(g_weaponarena_random)
1034                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1035                 else
1036                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1037         }
1038         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1039                 modifications = strcat(modifications, ", No start weapons");
1040         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1041                 modifications = strcat(modifications, ", Low gravity");
1042         if(g_weapon_stay && !g_cts)
1043                 modifications = strcat(modifications, ", Weapons stay");
1044         if(autocvar_g_jetpack)
1045                 modifications = strcat(modifications, ", Jet pack");
1046         if(autocvar_g_powerups == 0)
1047                 modifications = strcat(modifications, ", No powerups");
1048         if(autocvar_g_powerups > 0)
1049                 modifications = strcat(modifications, ", Powerups");
1050         modifications = substring(modifications, 2, strlen(modifications) - 2);
1051
1052         string versionmessage = GetClientVersionMessage(this);
1053         string s = strcat(versionmessage, "^8\n^8\nhost is ^9", autocvar_hostname, "^8\n");
1054
1055         s = strcat(s, "^8\nmatch type is ^1", gamemode_name, "^8\n");
1056
1057         if(modifications != "")
1058                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1059
1060         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1061         {
1062                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1063                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1064         }
1065
1066         if (cache_mutatormsg != "") {
1067                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1068         }
1069
1070         string mutator_msg = "";
1071         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1072         mutator_msg = M_ARGV(0, string);
1073
1074         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1075
1076         string motd = autocvar_sv_motd;
1077         if (motd != "") {
1078                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1079         }
1080         return s;
1081 }
1082
1083 bool autocvar_sv_qcphysics = true; // TODO this is for testing - remove when qcphysics work
1084
1085 /**
1086 =============
1087 ClientConnect
1088
1089 Called when a client connects to the server
1090 =============
1091 */
1092 void ClientConnect(entity this)
1093 {
1094         if (Ban_MaybeEnforceBanOnce(this)) return;
1095         assert(!IS_CLIENT(this), return);
1096         this.flags |= FL_CLIENT;
1097         assert(player_count >= 0, player_count = 0);
1098
1099         TRANSMUTE(Client, this);
1100         CS(this).version_nagtime = time + 10 + random() * 10;
1101
1102         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1103
1104         bot_clientconnect(this);
1105
1106         Player_DetermineForcedTeam(this);
1107
1108         TRANSMUTE(Observer, this);
1109
1110         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1111
1112         // always track bots, don't ask for cl_allow_uidtracking
1113         if (IS_BOT_CLIENT(this))
1114                 PlayerStats_GameReport_AddPlayer(this);
1115         else
1116                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1117
1118         if (autocvar_sv_eventlog)
1119                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? GameLog_ProcessIP(this.netaddress) : "bot"), ":", playername(this.netname, this.team, false)));
1120
1121         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1122
1123         stuffcmd(this, clientstuff, "\n");
1124         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1125
1126         FixClientCvars(this);
1127
1128         // get version info from player
1129         stuffcmd(this, "cmd clientversion $gameversion\n");
1130
1131         // notify about available teams
1132         if (teamplay)
1133         {
1134                 entity balance = TeamBalance_CheckAllowedTeams(this);
1135                 int t = TeamBalance_GetAllowedTeams(balance);
1136                 TeamBalance_Destroy(balance);
1137                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1138         }
1139         else
1140         {
1141                 stuffcmd(this, "set _teams_available 0\n");
1142         }
1143
1144         bot_relinkplayerlist();
1145
1146         CS(this).spectatortime = time;
1147         if (blockSpectators)
1148         {
1149                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1150         }
1151
1152         CS(this).jointime = time;
1153
1154         if (IS_REAL_CLIENT(this))
1155         {
1156                 if (g_weaponarena_weapons == WEPSET(TUBA))
1157                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1158         }
1159
1160         if (!autocvar_sv_foginterval && world.fog != "")
1161                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1162
1163         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1164                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1165                         send_CSQC_teamnagger();
1166
1167         CSQCMODEL_AUTOINIT(this);
1168
1169         CS(this).model_randomizer = random();
1170
1171         if (IS_REAL_CLIENT(this))
1172                 sv_notice_join(this);
1173
1174         this.move_qcphysics = autocvar_sv_qcphysics;
1175
1176         // update physics stats (players can spawn before physics runs)
1177         Physics_UpdateStats(this);
1178
1179         IL_EACH(g_initforplayer, it.init_for_player, {
1180                 it.init_for_player(it, this);
1181         });
1182
1183         Handicap_Initialize(this);
1184
1185         MUTATOR_CALLHOOK(ClientConnect, this);
1186
1187         if (IS_REAL_CLIENT(this))
1188         {
1189                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1190                 {
1191                         CS(this).motd_actived_time = -1;
1192                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1193                 }
1194         }
1195 }
1196 /*
1197 =============
1198 ClientDisconnect
1199
1200 Called when a client disconnects from the server
1201 =============
1202 */
1203 .entity chatbubbleentity;
1204 void player_powerups_remove_all(entity this);
1205
1206 void ClientDisconnect(entity this)
1207 {
1208         assert(IS_CLIENT(this), return);
1209
1210         PlayerStats_GameReport_FinalizePlayer(this);
1211         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1212         if (CS(this).active_minigame) part_minigame(this);
1213         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1214
1215         if (autocvar_sv_eventlog)
1216                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1217
1218         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1219
1220         if(IS_SPEC(this))
1221                 SetSpectatee(this, NULL);
1222
1223         MUTATOR_CALLHOOK(ClientDisconnect, this);
1224
1225         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1226         strfree(CS_CVAR(this).weaponorder_byimpulse);
1227         ClientState_detach(this);
1228
1229         Portal_ClearAll(this);
1230
1231         Unfreeze(this, false);
1232
1233         RemoveGrapplingHooks(this);
1234
1235         // Here, everything has been done that requires this player to be a client.
1236
1237         this.flags &= ~FL_CLIENT;
1238
1239         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1240         if (this.killindicator) delete(this.killindicator);
1241
1242         IL_EACH(g_counters, it.realowner == this,
1243         {
1244                 delete(it);
1245         });
1246
1247         WaypointSprite_PlayerGone(this);
1248
1249         bot_relinkplayerlist();
1250
1251         strfree(this.clientstatus);
1252         if (this.personal) delete(this.personal);
1253
1254         this.playerid = 0;
1255         ReadyCount();
1256         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1257
1258         player_powerups_remove_all(this); // stop powerup sound
1259
1260         ONREMOVE(this);
1261 }
1262
1263 void ChatBubbleThink(entity this)
1264 {
1265         this.nextthink = time;
1266         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1267         {
1268                 if(this.owner) // but why can that ever be NULL?
1269                         this.owner.chatbubbleentity = NULL;
1270                 delete(this);
1271                 return;
1272         }
1273
1274         this.mdl = "";
1275
1276         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1277         {
1278                 if ( CS(this.owner).active_minigame && PHYS_INPUT_BUTTON_MINIGAME(this.owner) )
1279                         this.mdl = "models/sprites/minigame_busy.iqm";
1280                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1281                         this.mdl = "models/misc/chatbubble.spr";
1282         }
1283
1284         if ( this.model != this.mdl )
1285                 _setmodel(this, this.mdl);
1286
1287 }
1288
1289 void UpdateChatBubble(entity this)
1290 {
1291         if (this.alpha < 0)
1292                 return;
1293         // spawn a chatbubble entity if needed
1294         if (!this.chatbubbleentity)
1295         {
1296                 this.chatbubbleentity = new(chatbubbleentity);
1297                 this.chatbubbleentity.owner = this;
1298                 this.chatbubbleentity.exteriormodeltoclient = this;
1299                 setthink(this.chatbubbleentity, ChatBubbleThink);
1300                 this.chatbubbleentity.nextthink = time;
1301                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1302                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1303                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1304                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1305                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1306                 //this.chatbubbleentity.model = "";
1307                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1308         }
1309 }
1310
1311 void calculate_player_respawn_time(entity this)
1312 {
1313         if(MUTATOR_CALLHOOK(CalculateRespawnTime, this))
1314                 return;
1315
1316         float gametype_setting_tmp;
1317         float sdelay_max = GAMETYPE_DEFAULTED_SETTING(respawn_delay_max);
1318         float sdelay_small = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small);
1319         float sdelay_large = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large);
1320         float sdelay_small_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_small_count);
1321         float sdelay_large_count = GAMETYPE_DEFAULTED_SETTING(respawn_delay_large_count);
1322         float waves = GAMETYPE_DEFAULTED_SETTING(respawn_waves);
1323
1324         float pcount = 1;  // Include myself whether or not team is already set right and I'm a "player".
1325         if (teamplay)
1326         {
1327                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1328                         if(it.team == this.team)
1329                                 ++pcount;
1330                 });
1331                 if (sdelay_small_count == 0)
1332                         sdelay_small_count = 1;
1333                 if (sdelay_large_count == 0)
1334                         sdelay_large_count = 1;
1335         }
1336         else
1337         {
1338                 FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
1339                         ++pcount;
1340                 });
1341                 if (sdelay_small_count == 0)
1342                 {
1343                         if (IS_INDEPENDENT_PLAYER(this))
1344                         {
1345                                 // Players play independently. No point in requiring enemies.
1346                                 sdelay_small_count = 1;
1347                         }
1348                         else
1349                         {
1350                                 // Players play AGAINST each other. Enemies required.
1351                                 sdelay_small_count = 2;
1352                         }
1353                 }
1354                 if (sdelay_large_count == 0)
1355                 {
1356                         if (IS_INDEPENDENT_PLAYER(this))
1357                         {
1358                                 // Players play independently. No point in requiring enemies.
1359                                 sdelay_large_count = 1;
1360                         }
1361                         else
1362                         {
1363                                 // Players play AGAINST each other. Enemies required.
1364                                 sdelay_large_count = 2;
1365                         }
1366                 }
1367         }
1368
1369         float sdelay;
1370
1371         if (pcount <= sdelay_small_count)
1372                 sdelay = sdelay_small;
1373         else if (pcount >= sdelay_large_count)
1374                 sdelay = sdelay_large;
1375         else  // NOTE: this case implies sdelay_large_count > sdelay_small_count.
1376                 sdelay = sdelay_small + (sdelay_large - sdelay_small) * (pcount - sdelay_small_count) / (sdelay_large_count - sdelay_small_count);
1377
1378         if(waves)
1379                 this.respawn_time = ceil((time + sdelay) / waves) * waves;
1380         else
1381                 this.respawn_time = time + sdelay;
1382
1383         if(sdelay < sdelay_max)
1384                 this.respawn_time_max = time + sdelay_max;
1385         else
1386                 this.respawn_time_max = this.respawn_time;
1387
1388         if((sdelay + waves >= 5.0) && (this.respawn_time - time > 1.75))
1389                 this.respawn_countdown = 10; // first number to count down from is 10
1390         else
1391                 this.respawn_countdown = -1; // do not count down
1392
1393         if(autocvar_g_forced_respawn)
1394                 this.respawn_flags = this.respawn_flags | RESPAWN_FORCE;
1395 }
1396
1397 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1398 // added to the model skins
1399 /*void UpdateColorModHack()
1400 {
1401         float c;
1402         c = this.clientcolors & 15;
1403         // LordHavoc: only bothering to support white, green, red, yellow, blue
1404              if (!teamplay) this.colormod = '0 0 0';
1405         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1406         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1407         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1408         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1409         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1410         else this.colormod = '1 1 1';
1411 }*/
1412
1413 void respawn(entity this)
1414 {
1415         bool damagedbycontents_prev = this.damagedbycontents;
1416         if(this.alpha >= 0)
1417         {
1418                 if(autocvar_g_respawn_ghosts)
1419                 {
1420                         this.solid = SOLID_NOT;
1421                         this.takedamage = DAMAGE_NO;
1422                         this.damagedbycontents = false;
1423                         set_movetype(this, MOVETYPE_FLY);
1424                         this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1425                         this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1426                         this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1427                         this.alpha = min(this.alpha, autocvar_g_respawn_ghosts_alpha);
1428                         Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1429                         if(autocvar_g_respawn_ghosts_time > 0)
1430                                 SUB_SetFade(this, time + autocvar_g_respawn_ghosts_time, autocvar_g_respawn_ghosts_fadetime);
1431                 }
1432                 else
1433                         SUB_SetFade (this, time, 1); // fade out the corpse immediately
1434         }
1435
1436         CopyBody(this, 1);
1437         this.damagedbycontents = damagedbycontents_prev;
1438
1439         this.effects |= EF_NODRAW; // prevent another CopyBody
1440         PutClientInServer(this);
1441 }
1442
1443 void play_countdown(entity this, float finished, Sound samp)
1444 {
1445         TC(Sound, samp);
1446         if(IS_REAL_CLIENT(this))
1447                 if(floor(finished - time - frametime) != floor(finished - time))
1448                         if(finished - time < 6)
1449                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1450 }
1451
1452 void player_powerups_remove_all(entity this)
1453 {
1454         if (this.items & (ITEM_Strength.m_itemid | ITEM_Shield.m_itemid | IT_SUPERWEAPON))
1455         {
1456                 // don't play the poweroff sound when the game restarts or the player disconnects
1457                 if (time > game_starttime + 1 && IS_CLIENT(this))
1458                         sound(this, CH_INFO, SND_POWEROFF, VOL_BASE, ATTEN_NORM);
1459                 stopsound(this, CH_TRIGGER_SINGLE); // get rid of the pickup sound
1460                 this.items &= ~ITEM_Strength.m_itemid;
1461                 this.items &= ~ITEM_Shield.m_itemid;
1462                 this.items -= (this.items & IT_SUPERWEAPON);
1463         }
1464 }
1465
1466 void player_powerups(entity this)
1467 {
1468         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1469                 this.modelflags |= MF_ROCKET;
1470         else
1471                 this.modelflags &= ~MF_ROCKET;
1472
1473         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1474
1475         if (IS_DEAD(this))
1476                 player_powerups_remove_all(this);
1477
1478         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1479                 return;
1480
1481         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1482         int items_prev = this.items;
1483
1484         Fire_ApplyDamage(this);
1485         Fire_ApplyEffect(this);
1486
1487         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1488         {
1489                 if (this.items & ITEM_Strength.m_itemid)
1490                 {
1491                         play_countdown(this, STAT(STRENGTH_FINISHED, this), SND_POWEROFF);
1492                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1493                         if (time > STAT(STRENGTH_FINISHED, this))
1494                         {
1495                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1496                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1497                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1498                         }
1499                 }
1500                 else
1501                 {
1502                         if (time < STAT(STRENGTH_FINISHED, this))
1503                         {
1504                                 this.items = this.items | ITEM_Strength.m_itemid;
1505                                 if(!g_cts)
1506                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1507                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1508                         }
1509                 }
1510                 if (this.items & ITEM_Shield.m_itemid)
1511                 {
1512                         play_countdown(this, STAT(INVINCIBLE_FINISHED, this), SND_POWEROFF);
1513                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1514                         if (time > STAT(INVINCIBLE_FINISHED, this))
1515                         {
1516                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1517                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1518                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1519                         }
1520                 }
1521                 else
1522                 {
1523                         if (time < STAT(INVINCIBLE_FINISHED, this))
1524                         {
1525                                 this.items = this.items | ITEM_Shield.m_itemid;
1526                                 if(!g_cts)
1527                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1528                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1529                         }
1530                 }
1531                 if (this.items & IT_SUPERWEAPON)
1532                 {
1533                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1534                         {
1535                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1536                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1537                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1538                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1539                         }
1540                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1541                         {
1542                                 // don't let them run out
1543                         }
1544                         else
1545                         {
1546                                 play_countdown(this, STAT(SUPERWEAPONS_FINISHED, this), SND_POWEROFF);
1547                                 if (time > STAT(SUPERWEAPONS_FINISHED, this))
1548                                 {
1549                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1550                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1551                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1552                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1553                                 }
1554                         }
1555                 }
1556                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1557                 {
1558                         if (time < STAT(SUPERWEAPONS_FINISHED, this) || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1559                         {
1560                                 this.items = this.items | IT_SUPERWEAPON;
1561                                 if(!(this.items & IT_UNLIMITED_SUPERWEAPONS))
1562                                 {
1563                                         if(!g_cts)
1564                                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1565                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1566                                 }
1567                         }
1568                         else
1569                         {
1570                                 STAT(SUPERWEAPONS_FINISHED, this) = 0;
1571                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1572                         }
1573                 }
1574                 else
1575                 {
1576                         STAT(SUPERWEAPONS_FINISHED, this) = 0;
1577                 }
1578         }
1579
1580         if(autocvar_g_nodepthtestplayers)
1581                 this.effects = this.effects | EF_NODEPTHTEST;
1582
1583         if(autocvar_g_fullbrightplayers)
1584                 this.effects = this.effects | EF_FULLBRIGHT;
1585
1586         if (time >= game_starttime)
1587         if (time < this.spawnshieldtime)
1588                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1589
1590         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1591 }
1592
1593 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1594 {
1595         if(current > stable)
1596                 return current;
1597         else if(current > stable - 0.25) // when close enough, "snap"
1598                 return stable;
1599         else
1600                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1601 }
1602
1603 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1604 {
1605         if(current < stable)
1606                 return current;
1607         else if(current < stable + 0.25) // when close enough, "snap"
1608                 return stable;
1609         else
1610                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1611 }
1612
1613 void RotRegen(entity this, int res, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit_mod)
1614 {
1615         float old = GetResource(this, res);
1616         float current = old;
1617         if(current > rotstable)
1618         {
1619                 if(rotframetime > 0)
1620                 {
1621                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1622                         current = max(rotstable, current - rotlinear * rotframetime);
1623                 }
1624         }
1625         else if(current < regenstable)
1626         {
1627                 if(regenframetime > 0)
1628                 {
1629                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1630                         current = min(regenstable, current + regenlinear * regenframetime);
1631                 }
1632         }
1633
1634         float limit = GetResourceLimit(this, res) * limit_mod;
1635         if(current > limit)
1636                 current = limit;
1637
1638         if (current != old)
1639                 SetResource(this, res, current);
1640 }
1641
1642 void player_regen(entity this)
1643 {
1644         float max_mod, regen_mod, rot_mod, limit_mod;
1645         max_mod = regen_mod = rot_mod = limit_mod = 1;
1646
1647         float regen_health = autocvar_g_balance_health_regen;
1648         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1649         float regen_health_rot = autocvar_g_balance_health_rot;
1650         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1651         float regen_health_stable = autocvar_g_balance_health_regenstable;
1652         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1653         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1654                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1655         max_mod = M_ARGV(1, float);
1656         regen_mod = M_ARGV(2, float);
1657         rot_mod = M_ARGV(3, float);
1658         limit_mod = M_ARGV(4, float);
1659         regen_health = M_ARGV(5, float);
1660         regen_health_linear = M_ARGV(6, float);
1661         regen_health_rot = M_ARGV(7, float);
1662         regen_health_rotlinear = M_ARGV(8, float);
1663         regen_health_stable = M_ARGV(9, float);
1664         regen_health_rotstable = M_ARGV(10, float);
1665
1666         if(!mutator_returnvalue)
1667         if(!STAT(FROZEN, this))
1668         {
1669                 float maxa = autocvar_g_balance_armor_rotstable;
1670                 float mina = autocvar_g_balance_armor_regenstable;
1671
1672                 RotRegen(this, RES_ARMOR, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1673                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1674                         rot_mod * frametime * (time > this.pauserotarmor_finished), limit_mod);
1675
1676                 RotRegen(this, RES_HEALTH, regen_health_stable * max_mod, regen_health, regen_health_linear,
1677                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable * max_mod, regen_health_rot, regen_health_rotlinear,
1678                         rot_mod * frametime * (time > this.pauserothealth_finished), limit_mod);
1679         }
1680
1681         // if player rotted to death...  die!
1682         // check this outside above checks, as player may still be able to rot to death
1683         if(GetResource(this, RES_HEALTH) < 1)
1684         {
1685                 if(this.vehicle)
1686                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1687                 if(this.event_damage)
1688                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1689         }
1690
1691         if (!(this.items & IT_UNLIMITED_AMMO))
1692         {
1693                 float maxf = autocvar_g_balance_fuel_rotstable;
1694                 float minf = autocvar_g_balance_fuel_regenstable;
1695
1696                 RotRegen(this, RES_FUEL, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1697                         frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1698                         maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), 1);
1699         }
1700 }
1701
1702 bool zoomstate_set;
1703 void SetZoomState(entity this, float newzoom)
1704 {
1705         if(newzoom != CS(this).zoomstate)
1706         {
1707                 CS(this).zoomstate = newzoom;
1708                 ClientData_Touch(this);
1709         }
1710         zoomstate_set = true;
1711 }
1712
1713 void GetPressedKeys(entity this)
1714 {
1715         MUTATOR_CALLHOOK(GetPressedKeys, this);
1716         if (game_stopped)
1717         {
1718                 CS(this).pressedkeys = 0;
1719                 STAT(PRESSED_KEYS, this) = 0;
1720                 return;
1721         }
1722
1723         // NOTE: GetPressedKeys and PM_dodging_GetPressedKeys use similar code
1724         int keys = STAT(PRESSED_KEYS, this);
1725         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1726         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1727         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1728         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1729
1730         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1731         keys = BITSET(keys, KEY_CROUCH,         IS_DUCKED(this)); // workaround: player can't un-crouch until their path is clear, so we keep the button held here
1732         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1733         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1734         CS(this).pressedkeys = keys; // store for other users
1735
1736         STAT(PRESSED_KEYS, this) = keys;
1737 }
1738
1739 /*
1740 ======================
1741 spectate mode routines
1742 ======================
1743 */
1744
1745 void SpectateCopy(entity this, entity spectatee)
1746 {
1747         TC(Client, this); TC(Client, spectatee);
1748
1749         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1750         PS(this) = PS(spectatee);
1751         this.armortype = spectatee.armortype;
1752         SetResourceExplicit(this, RES_ARMOR, GetResource(spectatee, RES_ARMOR));
1753         SetResourceExplicit(this, RES_CELLS, GetResource(spectatee, RES_CELLS));
1754         SetResourceExplicit(this, RES_PLASMA, GetResource(spectatee, RES_PLASMA));
1755         SetResourceExplicit(this, RES_SHELLS, GetResource(spectatee, RES_SHELLS));
1756         SetResourceExplicit(this, RES_BULLETS, GetResource(spectatee, RES_BULLETS));
1757         SetResourceExplicit(this, RES_ROCKETS, GetResource(spectatee, RES_ROCKETS));
1758         SetResourceExplicit(this, RES_FUEL, GetResource(spectatee, RES_FUEL));
1759         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1760         SetResourceExplicit(this, RES_HEALTH, GetResource(spectatee, RES_HEALTH));
1761         CS(this).impulse = 0;
1762         this.disableclientprediction = 1; // no need to run prediction on a spectator
1763         this.items = spectatee.items;
1764         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1765         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1766         STAT(STRENGTH_FINISHED, this) = STAT(STRENGTH_FINISHED, spectatee);
1767         STAT(INVINCIBLE_FINISHED, this) = STAT(INVINCIBLE_FINISHED, spectatee);
1768         STAT(SUPERWEAPONS_FINISHED, this) = STAT(SUPERWEAPONS_FINISHED, spectatee);
1769         STAT(AIR_FINISHED, this) = STAT(AIR_FINISHED, spectatee);
1770         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1771         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1772         this.punchangle = spectatee.punchangle;
1773         this.view_ofs = spectatee.view_ofs;
1774         this.velocity = spectatee.velocity;
1775         this.dmg_take = spectatee.dmg_take;
1776         this.dmg_save = spectatee.dmg_save;
1777         this.dmg_inflictor = spectatee.dmg_inflictor;
1778         this.v_angle = spectatee.v_angle;
1779         this.angles = spectatee.v_angle;
1780         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1781         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1782         this.viewloc = spectatee.viewloc;
1783         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1784                 this.fixangle = true;
1785         setorigin(this, spectatee.origin);
1786         setsize(this, spectatee.mins, spectatee.maxs);
1787         SetZoomState(this, CS(spectatee).zoomstate);
1788
1789     anticheat_spectatecopy(this, spectatee);
1790         STAT(HUD, this) = STAT(HUD, spectatee);
1791         if(spectatee.vehicle)
1792     {
1793         this.angles = spectatee.v_angle;
1794
1795         //this.fixangle = false;
1796         //this.velocity = spectatee.vehicle.velocity;
1797         this.vehicle_health = spectatee.vehicle_health;
1798         this.vehicle_shield = spectatee.vehicle_shield;
1799         this.vehicle_energy = spectatee.vehicle_energy;
1800         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1801         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1802         this.vehicle_reload1 = spectatee.vehicle_reload1;
1803         this.vehicle_reload2 = spectatee.vehicle_reload2;
1804
1805         //msg_entity = this;
1806
1807        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1808             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1809            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1810            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1811
1812         //WriteByte (MSG_ONE, SVC_SETVIEW);
1813         //    WriteEntity(MSG_ONE, this);
1814         //makevectors(spectatee.v_angle);
1815         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1816     }
1817 }
1818
1819 bool SpectateUpdate(entity this)
1820 {
1821         if(!this.enemy)
1822                 return false;
1823
1824         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1825         {
1826                 SetSpectatee(this, NULL);
1827                 return false;
1828         }
1829
1830         SpectateCopy(this, this.enemy);
1831
1832         return true;
1833 }
1834
1835 bool SpectateSet(entity this)
1836 {
1837         if(!IS_PLAYER(this.enemy))
1838                 return false;
1839
1840         ClientData_Touch(this.enemy);
1841
1842         msg_entity = this;
1843         WriteByte(MSG_ONE, SVC_SETVIEW);
1844         WriteEntity(MSG_ONE, this.enemy);
1845         set_movetype(this, MOVETYPE_NONE);
1846         accuracy_resend(this);
1847
1848         if(!SpectateUpdate(this))
1849                 PutObserverInServer(this);
1850
1851         return true;
1852 }
1853
1854 void SetSpectatee_status(entity this, int spectatee_num)
1855 {
1856         int oldspectatee_status = CS(this).spectatee_status;
1857         CS(this).spectatee_status = spectatee_num;
1858
1859         if (CS(this).spectatee_status != oldspectatee_status)
1860         {
1861                 if (STAT(PRESSED_KEYS, this))
1862                 {
1863                         CS(this).pressedkeys = 0;
1864                         STAT(PRESSED_KEYS, this) = 0;
1865                 }
1866                 ClientData_Touch(this);
1867                 if (g_race || g_cts) race_InitSpectator();
1868         }
1869 }
1870
1871 void SetSpectatee(entity this, entity spectatee)
1872 {
1873         if(IS_BOT_CLIENT(this))
1874                 return; // bots abuse .enemy, this code is useless to them
1875
1876         entity old_spectatee = this.enemy;
1877
1878         this.enemy = spectatee;
1879
1880         // WEAPONTODO
1881         // these are required to fix the spectator bug with arc
1882         if(old_spectatee)
1883         {
1884                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1885                 {
1886                         .entity weaponentity = weaponentities[slot];
1887                         if(old_spectatee.(weaponentity).arc_beam)
1888                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1889                 }
1890         }
1891         if(this.enemy)
1892         {
1893                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1894                 {
1895                         .entity weaponentity = weaponentities[slot];
1896                         if(this.enemy.(weaponentity).arc_beam)
1897                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1898                 }
1899         }
1900
1901         if (this.enemy)
1902                 SetSpectatee_status(this, etof(this.enemy));
1903
1904         // needed to update spectator list
1905         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1906 }
1907
1908 bool Spectate(entity this, entity pl)
1909 {
1910         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1911                 return false;
1912         pl = M_ARGV(1, entity);
1913
1914         SetSpectatee(this, pl);
1915         return SpectateSet(this);
1916 }
1917
1918 bool SpectateNext(entity this)
1919 {
1920         entity ent = find(this.enemy, classname, STR_PLAYER);
1921
1922         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1923                 ent = M_ARGV(1, entity);
1924         else if (!ent)
1925                 ent = find(ent, classname, STR_PLAYER);
1926
1927         if(ent) { SetSpectatee(this, ent); }
1928
1929         return SpectateSet(this);
1930 }
1931
1932 bool SpectatePrev(entity this)
1933 {
1934         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1935         entity ent = findchain(classname, STR_PLAYER);
1936         if (!ent) // no player
1937                 return false;
1938
1939         entity first = ent;
1940         // skip players until current spectated player
1941         if(this.enemy)
1942         while(ent && ent != this.enemy)
1943                 ent = ent.chain;
1944
1945         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1946         {
1947                 case MUT_SPECPREV_FOUND:
1948                         ent = M_ARGV(1, entity);
1949                         break;
1950                 case MUT_SPECPREV_RETURN:
1951                         return true;
1952                 case MUT_SPECPREV_CONTINUE:
1953                 default:
1954                 {
1955                         if(ent.chain)
1956                                 ent = ent.chain;
1957                         else
1958                                 ent = first;
1959                         break;
1960                 }
1961         }
1962
1963         SetSpectatee(this, ent);
1964         return SpectateSet(this);
1965 }
1966
1967 /*
1968 =============
1969 ShowRespawnCountdown()
1970
1971 Update a respawn countdown display.
1972 =============
1973 */
1974 void ShowRespawnCountdown(entity this)
1975 {
1976         float number;
1977         if(!IS_DEAD(this)) // just respawned?
1978                 return;
1979         else
1980         {
1981                 number = ceil(this.respawn_time - time);
1982                 if(number <= 0)
1983                         return;
1984                 if(number <= this.respawn_countdown)
1985                 {
1986                         this.respawn_countdown = number - 1;
1987                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1988                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1989                 }
1990         }
1991 }
1992
1993 .bool team_selected;
1994 bool ShowTeamSelection(entity this)
1995 {
1996         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
1997                 return false;
1998         stuffcmd(this, "menu_showteamselect\n");
1999         return true;
2000 }
2001 void Join(entity this)
2002 {
2003         TRANSMUTE(Player, this);
2004
2005         if(!this.team_selected)
2006         if(autocvar_g_campaign || autocvar_g_balance_teams)
2007                 TeamBalance_JoinBestTeam(this);
2008
2009         if(autocvar_g_campaign)
2010                 campaign_bots_may_start = true;
2011
2012         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2013
2014         PutClientInServer(this);
2015
2016         if(IS_PLAYER(this))
2017         if(teamplay && this.team != -1)
2018         {
2019         }
2020         else
2021                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2022         this.team_selected = false;
2023 }
2024
2025 int GetPlayerLimit()
2026 {
2027         if(g_duel)
2028                 return 2; // TODO: this workaround is needed since the mutator hook from duel can't be activated before the gametype is loaded (e.g. switching modes via gametype vote screen)
2029         int player_limit = autocvar_g_maxplayers;
2030         MUTATOR_CALLHOOK(GetPlayerLimit, player_limit);
2031         player_limit = M_ARGV(0, int);
2032         return player_limit;
2033 }
2034
2035 /**
2036  * Determines whether the player is allowed to join. This depends on cvar
2037  * g_maxplayers, if it isn't used this function always return true, otherwise
2038  * it checks whether the number of currently playing players exceeds g_maxplayers.
2039  * @return int number of free slots for players, 0 if none
2040  */
2041 int nJoinAllowed(entity this, entity ignore)
2042 {
2043         if(!ignore)
2044         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2045         // so report 0 free slots if restricted
2046         {
2047                 if(autocvar_g_forced_team_otherwise == "spectate")
2048                         return 0;
2049                 if(autocvar_g_forced_team_otherwise == "spectator")
2050                         return 0;
2051         }
2052
2053         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2054                 return 0; // forced spectators can never join
2055
2056         // TODO simplify this
2057         int totalClients = 0;
2058         int currentlyPlaying = 0;
2059         FOREACH_CLIENT(true, {
2060                 if(it != ignore)
2061                         ++totalClients;
2062                 if(IS_REAL_CLIENT(it))
2063                 if(IS_PLAYER(it) || it.caplayer)
2064                         ++currentlyPlaying;
2065         });
2066
2067         int player_limit = GetPlayerLimit();
2068
2069         int free_slots = 0;
2070         if (!player_limit)
2071                 free_slots = maxclients - totalClients;
2072         else if(player_limit > 0 && currentlyPlaying < player_limit)
2073                 free_slots = min(maxclients - totalClients, player_limit - currentlyPlaying);
2074
2075         static float msg_time = 0;
2076         if(this && !this.caplayer && ignore && !free_slots && time > msg_time)
2077         {
2078                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2079                 msg_time = time + 0.5;
2080         }
2081
2082         return free_slots;
2083 }
2084
2085 /**
2086  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2087  * g_maxplayers_spectator_blocktime seconds
2088  */
2089 void checkSpectatorBlock(entity this)
2090 {
2091         if(IS_SPEC(this) || IS_OBSERVER(this))
2092         if(!this.caplayer)
2093         if(IS_REAL_CLIENT(this))
2094         {
2095                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2096                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2097                         dropclient(this);
2098                 }
2099         }
2100 }
2101
2102 void PrintWelcomeMessage(entity this)
2103 {
2104         if(CS(this).motd_actived_time == 0)
2105         {
2106                 if (autocvar_g_campaign) {
2107                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2108                                 CS(this).motd_actived_time = time;
2109                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_CAMPAIGN_MESSAGE, Campaign_GetMessage(), Campaign_GetLevelNum());
2110                         }
2111                 } else {
2112                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2113                                 CS(this).motd_actived_time = time;
2114                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2115                         }
2116                 }
2117         }
2118         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2119         {
2120                 if (autocvar_g_campaign) {
2121                         if (PHYS_INPUT_BUTTON_INFO(this))
2122                                 CS(this).motd_actived_time = time;
2123                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2124                                 CS(this).motd_actived_time = 0;
2125                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2126                         }
2127                 } else {
2128                         if (PHYS_INPUT_BUTTON_INFO(this))
2129                                 CS(this).motd_actived_time = time;
2130                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2131                                 CS(this).motd_actived_time = 0;
2132                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2133                         }
2134                 }
2135         }
2136         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2137         {
2138                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2139                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2140                 else if (CS(this).motd_actived_time == -2)
2141                 {
2142                         // instantly hide MOTD
2143                         CS(this).motd_actived_time = 0;
2144                         if (autocvar_g_campaign)
2145                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_CAMPAIGN_MESSAGE);
2146                         else
2147                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2148                 }
2149                 else if (IS_PLAYER(this) || IS_SPEC(this))
2150                 {
2151                         // FIXME occasionally for some reason MOTD never goes away
2152                         // delay MOTD removal a little bit in the hope it fixes this bug
2153                         if (CS(this).motd_actived_time == -1) // MOTD marked to fade away as soon as client becomes player or spectator
2154                                 CS(this).motd_actived_time = -(5 + floor(random() * 10)); // add small delay
2155                         else //if (CS(this).motd_actived_time < -2)
2156                                 CS(this).motd_actived_time++;
2157                 }
2158         }
2159 }
2160
2161 bool joinAllowed(entity this)
2162 {
2163         if (CS(this).version_mismatch) return false;
2164         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2165         if (!nJoinAllowed(this, this)) return false;
2166         if (teamplay && lockteams) return false;
2167         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2168         if (ShowTeamSelection(this)) return false;
2169         return true;
2170 }
2171
2172 .string shootfromfixedorigin;
2173 .bool dualwielding_prev;
2174 bool PlayerThink(entity this)
2175 {
2176         if (game_stopped || intermission_running) {
2177                 this.modelflags &= ~MF_ROCKET;
2178                 if(intermission_running)
2179                         IntermissionThink(this);
2180                 return false;
2181         }
2182
2183         if (timeout_status == TIMEOUT_ACTIVE) {
2184                 // don't allow the player to turn around while game is paused
2185                 // FIXME turn this into CSQC stuff
2186                 this.v_angle = this.lastV_angle;
2187                 this.angles = this.lastV_angle;
2188                 this.fixangle = true;
2189         }
2190
2191         if (frametime) player_powerups(this);
2192
2193         if (IS_DEAD(this)) {
2194                 if (this.personal && g_race_qualifying) {
2195                         if (time > this.respawn_time) {
2196                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2197                                 respawn(this);
2198                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2199                         }
2200                 } else {
2201                         if (frametime) player_anim(this);
2202
2203                         if (this.respawn_flags & RESPAWN_DENY)
2204                         {
2205                                 STAT(RESPAWN_TIME, this) = 0;
2206                                 return false;
2207                         }
2208
2209                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2210
2211                         switch(this.deadflag)
2212                         {
2213                                 case DEAD_DYING:
2214                                 {
2215                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2216                                                 this.deadflag = DEAD_RESPAWNING;
2217                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2218                                                 this.deadflag = DEAD_DEAD;
2219                                         break;
2220                                 }
2221                                 case DEAD_DEAD:
2222                                 {
2223                                         if (button_pressed)
2224                                                 this.deadflag = DEAD_RESPAWNABLE;
2225                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2226                                                 this.deadflag = DEAD_RESPAWNING;
2227                                         break;
2228                                 }
2229                                 case DEAD_RESPAWNABLE:
2230                                 {
2231                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2232                                                 this.deadflag = DEAD_RESPAWNING;
2233                                         break;
2234                                 }
2235                                 case DEAD_RESPAWNING:
2236                                 {
2237                                         if (time > this.respawn_time)
2238                                         {
2239                                                 this.respawn_time = time + 1; // only retry once a second
2240                                                 this.respawn_time_max = this.respawn_time;
2241                                                 respawn(this);
2242                                         }
2243                                         break;
2244                                 }
2245                         }
2246
2247                         ShowRespawnCountdown(this);
2248
2249                         if (this.respawn_flags & RESPAWN_SILENT)
2250                                 STAT(RESPAWN_TIME, this) = 0;
2251                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2252                         {
2253                                 if (time < this.respawn_time)
2254                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2255                                 else if (this.deadflag != DEAD_RESPAWNING)
2256                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2257                         }
2258                         else
2259                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2260                 }
2261
2262                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2263                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2264                         STAT(RESPAWN_TIME, this) *= -1;
2265
2266                 return false;
2267         }
2268
2269         FixPlayermodel(this);
2270
2271         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2272                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2273                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2274         }
2275
2276         // reset gun alignment when dual wielding status changes
2277         // to ensure guns are always aligned right and left
2278         bool dualwielding = W_DualWielding(this);
2279         if(this.dualwielding_prev != dualwielding)
2280         {
2281                 W_ResetGunAlign(this, CS_CVAR(this).cvar_cl_gunalign);
2282                 this.dualwielding_prev = dualwielding;
2283         }
2284
2285         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2286         //if(frametime)
2287         {
2288                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2289                 {
2290                         .entity weaponentity = weaponentities[slot];
2291                         if(WEP_CVAR(vortex, charge_always))
2292                                 W_Vortex_Charge(this, weaponentity, frametime);
2293                         W_WeaponFrame(this, weaponentity);
2294                 }
2295         }
2296
2297         if (frametime)
2298         {
2299                 // WEAPONTODO: Add a weapon request for this
2300                 // rot vortex charge to the charge limit
2301                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2302                 {
2303                         .entity weaponentity = weaponentities[slot];
2304                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2305                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2306                 }
2307
2308                 player_regen(this);
2309                 player_anim(this);
2310                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2311         }
2312
2313         monsters_setstatus(this);
2314
2315         return true;
2316 }
2317
2318 .bool would_spectate;
2319 // merged SpectatorThink and ObserverThink (old names are here so you can grep for them)
2320 void ObserverOrSpectatorThink(entity this)
2321 {
2322         bool is_spec = IS_SPEC(this);
2323         if ( CS(this).impulse )
2324         {
2325                 int r = MinigameImpulse(this, CS(this).impulse);
2326                 if (!is_spec || r)
2327                         CS(this).impulse = 0;
2328
2329                 if (is_spec && CS(this).impulse == IMP_weapon_drop.impulse)
2330                 {
2331                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2332                         CS(this).impulse = 0;
2333                         return;
2334                 }
2335         }
2336
2337         if (this.flags & FL_JUMPRELEASED) {
2338                 if (PHYS_INPUT_BUTTON_JUMP(this) && (joinAllowed(this) || time < CS(this).jointime + MIN_SPEC_TIME)) {
2339                         this.flags &= ~FL_JUMPRELEASED;
2340                         this.flags |= FL_SPAWNING;
2341                 } else if((is_spec && (PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)))
2342                         || (!is_spec && ((PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) || this.would_spectate))) {
2343                         this.flags &= ~FL_JUMPRELEASED;
2344                         if(SpectateNext(this)) {
2345                                 TRANSMUTE(Spectator, this);
2346                         } else if (is_spec) {
2347                                 TRANSMUTE(Observer, this);
2348                                 PutClientInServer(this);
2349                         }
2350                         else
2351                                 this.would_spectate = false; // unable to spectate anyone
2352                         if (is_spec)
2353                                 CS(this).impulse = 0;
2354                 } else if (is_spec) {
2355                         if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2356                                 this.flags &= ~FL_JUMPRELEASED;
2357                                 if(SpectatePrev(this)) {
2358                                         TRANSMUTE(Spectator, this);
2359                                 } else {
2360                                         TRANSMUTE(Observer, this);
2361                                         PutClientInServer(this);
2362                                 }
2363                                 CS(this).impulse = 0;
2364                         } else if(PHYS_INPUT_BUTTON_ATCK2(this)) {
2365                                 this.would_spectate = false;
2366                                 this.flags &= ~FL_JUMPRELEASED;
2367                                 TRANSMUTE(Observer, this);
2368                                 PutClientInServer(this);
2369                         } else if(!SpectateUpdate(this) && !SpectateNext(this)) {
2370                                 PutObserverInServer(this);
2371                                 this.would_spectate = true;
2372                         }
2373                 }
2374                 else {
2375                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS_CVAR(this).cvar_cl_clippedspectating : !CS_CVAR(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2376                         set_movetype(this, preferred_movetype);
2377                 }
2378         } else { // jump pressed
2379                 if ((is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)))
2380                         || (!is_spec && !(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this)))) {
2381                         this.flags |= FL_JUMPRELEASED;
2382                         if(this.flags & FL_SPAWNING)
2383                         {
2384                                 this.flags &= ~FL_SPAWNING;
2385                                 if(joinAllowed(this))
2386                                         Join(this);
2387                                 else if(time < CS(this).jointime + MIN_SPEC_TIME)
2388                                         CS(this).autojoin_checked = -1;
2389                                 return;
2390                         }
2391                 }
2392                 if(is_spec && !SpectateUpdate(this))
2393                         PutObserverInServer(this);
2394         }
2395         if (is_spec)
2396                 this.flags |= FL_CLIENT | FL_NOTARGET;
2397 }
2398
2399 void PlayerUseKey(entity this)
2400 {
2401         if (!IS_PLAYER(this))
2402                 return;
2403
2404         if(this.vehicle)
2405         {
2406                 if(!game_stopped)
2407                 {
2408                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2409                         return;
2410                 }
2411         }
2412         else if(autocvar_g_vehicles_enter)
2413         {
2414                 if(!game_stopped && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2415                 {
2416                         entity head, closest_target = NULL;
2417                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2418
2419                         while(head) // find the closest acceptable target to enter
2420                         {
2421                                 if(IS_VEHICLE(head) && !IS_DEAD(head) && head.takedamage != DAMAGE_NO)
2422                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2423                                 {
2424                                         if(closest_target)
2425                                         {
2426                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2427                                                 { closest_target = head; }
2428                                         }
2429                                         else { closest_target = head; }
2430                                 }
2431
2432                                 head = head.chain;
2433                         }
2434
2435                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2436                 }
2437         }
2438
2439         // a use key was pressed; call handlers
2440         MUTATOR_CALLHOOK(PlayerUseKey, this);
2441 }
2442
2443
2444 /*
2445 =============
2446 PlayerPreThink
2447
2448 Called every frame for each client before the physics are run
2449 =============
2450 */
2451 .float last_vehiclecheck;
2452 void PlayerPreThink (entity this)
2453 {
2454         STAT(GUNALIGN, this) = CS_CVAR(this).cvar_cl_gunalign; // TODO
2455         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS_CVAR(this).cvar_cl_movement_track_canjump;
2456
2457         WarpZone_PlayerPhysics_FixVAngle(this);
2458
2459         if (frametime) {
2460                 // physics frames: update anticheat stuff
2461                 anticheat_prethink(this);
2462         }
2463
2464         if (blockSpectators && frametime) {
2465                 // WORKAROUND: only use dropclient in server frames (frametime set).
2466                 // Never use it in cl_movement frames (frametime zero).
2467                 checkSpectatorBlock(this);
2468         }
2469
2470         zoomstate_set = false;
2471
2472         // Check for nameless players
2473         if (this.netname == "" || this.netname != CS(this).netname_previous)
2474         {
2475                 bool assume_unchanged = (CS(this).netname_previous == "");
2476                 if (autocvar_sv_name_maxlength > 0 && strlennocol(this.netname) > autocvar_sv_name_maxlength)
2477                 {
2478                         int new_length = textLengthUpToLength(this.netname, autocvar_sv_name_maxlength, strlennocol);
2479                         this.netname = strzone(strcat(substring(this.netname, 0, new_length), "^7"));
2480                         sprint(this, sprintf("Warning: your name is longer than %d characters, it has been truncated.\n", autocvar_sv_name_maxlength));
2481                         assume_unchanged = false;
2482                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2483                 }
2484                 if (isInvisibleString(this.netname))
2485                 {
2486                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2487                         sprint(this, "Warning: invisible names are not allowed.\n");
2488                         assume_unchanged = false;
2489                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2490                 }
2491                 if (!assume_unchanged && autocvar_sv_eventlog)
2492                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this.netname, this.team, false)));
2493                 strcpy(CS(this).netname_previous, this.netname);
2494         }
2495
2496         // version nagging
2497         if (CS(this).version_nagtime && CS_CVAR(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2498         CS(this).version_nagtime = 0;
2499         if (strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS_CVAR(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2500             // git client
2501         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2502             // git server
2503             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2504         } else {
2505             int r = vercmp(CS_CVAR(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2506             if (r < 0) { // old client
2507                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2508             } else if (r > 0) { // old server
2509                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS_CVAR(this).cvar_g_xonoticversion);
2510             }
2511         }
2512     }
2513
2514         // GOD MODE info
2515         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2516         {
2517                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2518                 this.max_armorvalue = 0;
2519         }
2520
2521         if (frametime && IS_PLAYER(this) && time >= game_starttime)
2522         {
2523                 if (STAT(FROZEN, this) == FROZEN_TEMP_REVIVING)
2524                 {
2525                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2526                         SetResourceExplicit(this, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2527                         if (this.iceblock)
2528                                 this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2529
2530                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2531                                 Unfreeze(this, false);
2532                 }
2533                 else if (STAT(FROZEN, this) == FROZEN_TEMP_DYING)
2534                 {
2535                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2536                         SetResourceExplicit(this, RES_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2537
2538                         if (GetResource(this, RES_HEALTH) < 1)
2539                         {
2540                                 if (this.vehicle)
2541                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2542                                 if(this.event_damage)
2543                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2544                         }
2545                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2546                                 Unfreeze(this, false);
2547                 }
2548         }
2549
2550         MUTATOR_CALLHOOK(PlayerPreThink, this);
2551
2552         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2553         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this) && !IS_INDEPENDENT_PLAYER(this))
2554         {
2555                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it) && !IS_DEAD(it) && it.takedamage != DAMAGE_NO,
2556                 {
2557                         if(!it.owner)
2558                         {
2559                                 if(!it.team || SAME_TEAM(this, it))
2560                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2561                                 else if(autocvar_g_vehicles_steal)
2562                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2563                         }
2564                         else if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2565                         {
2566                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2567                         }
2568                 });
2569
2570                 this.last_vehiclecheck = time + 1;
2571         }
2572
2573         if(!CS_CVAR(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2574         {
2575                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2576                         PlayerUseKey(this);
2577                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2578         }
2579
2580         if (IS_REAL_CLIENT(this))
2581                 PrintWelcomeMessage(this);
2582
2583         if (IS_PLAYER(this)) {
2584                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2585                         error("Client can't be spawned as player on connection!");
2586                 if(!PlayerThink(this))
2587                         return;
2588         }
2589         else if (game_stopped || intermission_running) {
2590                 if(intermission_running)
2591                         IntermissionThink(this);
2592                 return;
2593         }
2594         else if (IS_REAL_CLIENT(this) && CS(this).autojoin_checked <= 0 && time >= CS(this).jointime + MIN_SPEC_TIME)
2595         {
2596                 bool early_join_requested = (CS(this).autojoin_checked < 0);
2597                 CS(this).autojoin_checked = 1;
2598                 // don't do this in ClientConnect
2599                 // many things can go wrong if a client is spawned as player on connection
2600                 if (early_join_requested || MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2601                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2602                                 && (!teamplay || autocvar_g_balance_teams)))
2603                 {
2604                         campaign_bots_may_start = true;
2605                         if(joinAllowed(this))
2606                                 Join(this);
2607                         return;
2608                 }
2609         }
2610         else if (IS_OBSERVER(this) || IS_SPEC(this)) {
2611                 ObserverOrSpectatorThink(this);
2612         }
2613
2614         // WEAPONTODO: Add weapon request for this
2615         if (!zoomstate_set) {
2616                 bool wep_zoomed = false;
2617                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2618                 {
2619                         .entity weaponentity = weaponentities[slot];
2620                         Weapon thiswep = this.(weaponentity).m_weapon;
2621                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2622                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2623                 }
2624                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2625         }
2626
2627         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2628         {
2629                 CS(this).teamkill_soundtime = 0;
2630
2631                 entity e = CS(this).teamkill_soundsource;
2632                 entity oldpusher = e.pusher;
2633                 e.pusher = this;
2634                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2635                 e.pusher = oldpusher;
2636         }
2637
2638         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2639                 CS(this).taunt_soundtime = 0;
2640                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2641         }
2642
2643         target_voicescript_next(this);
2644 }
2645
2646 void DrownPlayer(entity this)
2647 {
2648         if(IS_DEAD(this) || game_stopped || time < game_starttime || this.vehicle
2649                 || STAT(FROZEN, this) || this.watertype != CONTENT_WATER)
2650         {
2651                 STAT(AIR_FINISHED, this) = 0;
2652                 return;
2653         }
2654
2655         if (this.waterlevel != WATERLEVEL_SUBMERGED)
2656         {
2657                 if(STAT(AIR_FINISHED, this) && STAT(AIR_FINISHED, this) < time)
2658                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2659                 STAT(AIR_FINISHED, this) = 0;
2660         }
2661         else
2662         {
2663                 if (!STAT(AIR_FINISHED, this))
2664                         STAT(AIR_FINISHED, this) = time + autocvar_g_balance_contents_drowndelay;
2665                 if (STAT(AIR_FINISHED, this) < time)
2666                 {       // drown!
2667                         if (this.pain_finished < time)
2668                         {
2669                                 Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2670                                 this.pain_finished = time + 0.5;
2671                         }
2672                 }
2673         }
2674 }
2675
2676 .bool move_qcphysics;
2677
2678 void Player_Physics(entity this)
2679 {
2680         this.movetype = (this.move_qcphysics) ? MOVETYPE_QCPLAYER : this.move_movetype;
2681
2682         if(!this.move_qcphysics)
2683                 return;
2684
2685         if(!frametime && !CS(this).pm_frametime)
2686                 return;
2687
2688         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2689
2690         CS(this).pm_frametime = 0;
2691 }
2692
2693 /*
2694 =============
2695 PlayerPostThink
2696
2697 Called every frame for each client after the physics are run
2698 =============
2699 */
2700 void PlayerPostThink (entity this)
2701 {
2702         Player_Physics(this);
2703
2704         if (autocvar_sv_maxidle > 0)
2705         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2706         if (IS_REAL_CLIENT(this))
2707         if (IS_PLAYER(this) || autocvar_sv_maxidle_spectatorsareidle)
2708         {
2709                 int totalClients = 0;
2710                 if(autocvar_sv_maxidle_slots > 0)
2711                 {
2712                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || autocvar_sv_maxidle_slots_countbots,
2713                         {
2714                                 ++totalClients;
2715                         });
2716                 }
2717
2718                 if (autocvar_sv_maxidle_slots > 0 && (maxclients - totalClients) > autocvar_sv_maxidle_slots)
2719                 { /* do nothing */ }
2720                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2721                 {
2722                         if (CS(this).idlekick_lasttimeleft)
2723                         {
2724                                 CS(this).idlekick_lasttimeleft = 0;
2725                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2726                         }
2727                 }
2728                 else
2729                 {
2730                         float timeleft = ceil(autocvar_sv_maxidle - (time - CS(this).parm_idlesince));
2731                         if (timeleft == min(10, autocvar_sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2732                                 if (!CS(this).idlekick_lasttimeleft)
2733                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2734                         }
2735                         if (timeleft <= 0) {
2736                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2737                                 dropclient(this);
2738                                 return;
2739                         }
2740                         else if (timeleft <= 10) {
2741                                 if (timeleft != CS(this).idlekick_lasttimeleft)
2742                                         Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2743                                 CS(this).idlekick_lasttimeleft = timeleft;
2744                         }
2745                 }
2746         }
2747
2748         CheatFrame(this);
2749
2750         if (game_stopped)
2751         {
2752                 this.solid = SOLID_NOT;
2753                 this.takedamage = DAMAGE_NO;
2754                 set_movetype(this, MOVETYPE_NONE);
2755                 CS(this).teamkill_complain = 0;
2756                 CS(this).teamkill_soundtime = 0;
2757                 CS(this).teamkill_soundsource = NULL;
2758         }
2759
2760         if (IS_PLAYER(this)) {
2761                 if(this.death_time == time && IS_DEAD(this))
2762                 {
2763                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2764                         // once all the damage events of this frame have been processed with normal size
2765                         this.maxs.z = 5;
2766                         setsize(this, this.mins, this.maxs);
2767                 }
2768                 DrownPlayer(this);
2769                 UpdateChatBubble(this);
2770                 if (CS(this).impulse) ImpulseCommands(this);
2771                 GetPressedKeys(this);
2772                 if (game_stopped)
2773                 {
2774                         CSQCMODEL_AUTOUPDATE(this);
2775                         return;
2776                 }
2777         }
2778         else if (IS_OBSERVER(this) && STAT(PRESSED_KEYS, this))
2779         {
2780                 CS(this).pressedkeys = 0;
2781                 STAT(PRESSED_KEYS, this) = 0;
2782         }
2783
2784         if (this.waypointsprite_attachedforcarrier) {
2785                 float hp = healtharmor_maxdamage(GetResource(this, RES_HEALTH), GetResource(this, RES_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id).x;
2786                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, hp);
2787         }
2788
2789         CSQCMODEL_AUTOUPDATE(this);
2790 }
2791
2792 // hack to copy the button fields from the client entity to the Client State
2793 void PM_UpdateButtons(entity this, entity store)
2794 {
2795         if(this.impulse)
2796                 store.impulse = this.impulse;
2797         this.impulse = 0;
2798
2799         bool typing = this.buttonchat || this.button12;
2800
2801         store.button0 = (typing) ? 0 : this.button0;
2802         //button1?!
2803         store.button2 = (typing) ? 0 : this.button2;
2804         store.button3 = (typing) ? 0 : this.button3;
2805         store.button4 = this.button4;
2806         store.button5 = (typing) ? 0 : this.button5;
2807         store.button6 = this.button6;
2808         store.button7 = this.button7;
2809         store.button8 = this.button8;
2810         store.button9 = this.button9;
2811         store.button10 = this.button10;
2812         store.button11 = this.button11;
2813         store.button12 = this.button12;
2814         store.button13 = this.button13;
2815         store.button14 = this.button14;
2816         store.button15 = this.button15;
2817         store.button16 = this.button16;
2818         store.buttonuse = this.buttonuse;
2819         store.buttonchat = this.buttonchat;
2820
2821         store.cursor_active = this.cursor_active;
2822         store.cursor_screen = this.cursor_screen;
2823         store.cursor_trace_start = this.cursor_trace_start;
2824         store.cursor_trace_endpos = this.cursor_trace_endpos;
2825         store.cursor_trace_ent = this.cursor_trace_ent;
2826
2827         store.ping = this.ping;
2828         store.ping_packetloss = this.ping_packetloss;
2829         store.ping_movementloss = this.ping_movementloss;
2830
2831         store.v_angle = this.v_angle;
2832         store.movement = this.movement;
2833 }
2834
2835 NET_HANDLE(fpsreport, bool)
2836 {
2837         int fps = ReadShort();
2838         PlayerScore_Set(sender, SP_FPS, fps);
2839         return true;
2840 }