qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/net_linked.qh"
  41 #include "../common/physics/player.qh"
  42
  43 #include "../common/items/_mod.qh"
  44
  45 #include "../common/mutators/mutator/waypoints/all.qh"
  46
  47 #include "../common/triggers/subs.qh"
  48 #include "../common/triggers/triggers.qh"
  49 #include "../common/triggers/trigger/secret.qh"
  50
  51 #include "../common/minigames/sv_minigames.qh"
  52
  53 #include "../common/items/inventory.qh"
  54
  55 #include "../common/monsters/sv_monsters.qh"
  56
  57 #include "../lib/warpzone/server.qh"
  58
  59 STATIC_METHOD(Client, Add, void(Client this, int _team))
  60 {
  61     ClientConnect(this);
  62     TRANSMUTE(Player, this);
  63     this.frame = 12; // 7
  64     this.team = _team;
  65     PutClientInServer(this);
  66 }
  67
  68 void PutObserverInServer(entity this);
  69
  70 STATIC_METHOD(Client, Remove, void(Client this))
  71 {
  72     TRANSMUTE(Observer, this);
  73     PutClientInServer(this);
  74     ClientDisconnect(this);
  75 }
  76
  77 void send_CSQC_teamnagger() {
  78         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  79 }
  80
  81 int CountSpectators(entity player, entity to)
  82 {
  83         if(!player) { return 0; } // not sure how, but best to be safe
  84
  85         int spec_count = 0;
  86
  87         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  88         {
  89                 spec_count++;
  90         });
  91
  92         return spec_count;
  93 }
  94
  95 void WriteSpectators(entity player, entity to)
  96 {
  97         if(!player) { return; } // not sure how, but best to be safe
  98
  99         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 100         {
 101                 WriteByte(MSG_ENTITY, num_for_edict(it));
 102         });
 103 }
 104
 105 bool ClientData_Send(entity this, entity to, int sf)
 106 {
 107         assert(to == this.owner, return false);
 108
 109         entity e = to;
 110         if (IS_SPEC(e)) e = e.enemy;
 111
 112         sf = 0;
 113         if (e.race_completed)       sf |= 1; // forced scoreboard
 114         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 115         if (e.zoomstate)            sf |= 4; // zoomed
 116         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 117
 118         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 119         WriteByte(MSG_ENTITY, sf);
 120
 121         if (sf & 2)
 122         {
 123                 WriteByte(MSG_ENTITY, to.spectatee_status);
 124         }
 125
 126         if(sf & 16)
 127         {
 128                 float specs = CountSpectators(e, to);
 129                 WriteByte(MSG_ENTITY, specs);
 130                 WriteSpectators(e, to);
 131         }
 132
 133         return true;
 134 }
 135
 136 void ClientData_Attach(entity this)
 137 {
 138         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 139         this.clientdata.drawonlytoclient = this;
 140         this.clientdata.owner = this;
 141 }
 142
 143 void ClientData_Detach(entity this)
 144 {
 145         delete(this.clientdata);
 146         this.clientdata = NULL;
 147 }
 148
 149 void ClientData_Touch(entity e)
 150 {
 151         e.clientdata.SendFlags = 1;
 152
 153         // make it spectatable
 154         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 155 }
 156
 157 .string netname_previous;
 158
 159 void SetSpectatee(entity this, entity spectatee);
 160 void SetSpectatee_status(entity this, int spectatee_num);
 161
 162
 163 /*
 164 =============
 165 CheckPlayerModel
 166
 167 Checks if the argument string can be a valid playermodel.
 168 Returns a valid one in doubt.
 169 =============
 170 */
 171 string FallbackPlayerModel;
 172 string CheckPlayerModel(string plyermodel) {
 173         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 174         {
 175                 // note: we cannot summon Don Strunzone here, some player may
 176                 // still have the model string set. In case anyone manages how
 177                 // to change a cvar default, we'll have a small leak here.
 178                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 179         }
 180         // only in right path
 181         if( substring(plyermodel,0,14) != "models/player/")
 182                 return FallbackPlayerModel;
 183         // only good file extensions
 184         if(substring(plyermodel,-4,4) != ".zym")
 185         if(substring(plyermodel,-4,4) != ".dpm")
 186         if(substring(plyermodel,-4,4) != ".iqm")
 187         if(substring(plyermodel,-4,4) != ".md3")
 188         if(substring(plyermodel,-4,4) != ".psk")
 189                 return FallbackPlayerModel;
 190         // forbid the LOD models
 191         if(substring(plyermodel, -9,5) == "_lod1")
 192                 return FallbackPlayerModel;
 193         if(substring(plyermodel, -9,5) == "_lod2")
 194                 return FallbackPlayerModel;
 195         if(plyermodel != strtolower(plyermodel))
 196                 return FallbackPlayerModel;
 197         // also, restrict to server models
 198         if(autocvar_sv_servermodelsonly)
 199         {
 200                 if(!fexists(plyermodel))
 201                         return FallbackPlayerModel;
 202         }
 203         return plyermodel;
 204 }
 205
 206 void setplayermodel(entity e, string modelname)
 207 {
 208         precache_model(modelname);
 209         _setmodel(e, modelname);
 210         player_setupanimsformodel(e);
 211         if(!autocvar_g_debug_globalsounds)
 212                 UpdatePlayerSounds(e);
 213 }
 214
 215 void FixPlayermodel(entity player);
 216 /** putting a client as observer in the server */
 217 void PutObserverInServer(entity this)
 218 {
 219     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 220         PlayerState_detach(this);
 221
 222         if (IS_PLAYER(this) && this.health >= 1) {
 223         // despawn effect
 224                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 225     }
 226
 227     {
 228         entity spot = SelectSpawnPoint(this, true);
 229         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 230         this.angles = spot.angles;
 231         this.angles_z = 0;
 232         this.fixangle = true;
 233         // offset it so that the spectator spawns higher off the ground, looks better this way
 234         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 235         this.prevorigin = this.origin;
 236         if (IS_REAL_CLIENT(this))
 237         {
 238             msg_entity = this;
 239             WriteByte(MSG_ONE, SVC_SETVIEW);
 240             WriteEntity(MSG_ONE, this);
 241         }
 242         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 243         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 244         if(!autocvar_g_debug_globalsounds)
 245         {
 246                 // needed for player sounds
 247                 this.model = "";
 248                 FixPlayermodel(this);
 249         }
 250         setmodel(this, MDL_Null);
 251         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 252         this.view_ofs = '0 0 0';
 253     }
 254
 255     RemoveGrapplingHooks(this);
 256         Portal_ClearAll(this);
 257         Unfreeze(this);
 258         SetSpectatee(this, NULL);
 259
 260         if (this.alivetime)
 261         {
 262                 if (!warmup_stage)
 263                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 264                 this.alivetime = 0;
 265         }
 266
 267         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 268
 269         WaypointSprite_PlayerDead(this);
 270
 271         if (mutator_returnvalue) {
 272             // mutator prevents resetting teams+score
 273         } else {
 274                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 275         this.frags = FRAGS_SPECTATOR;
 276         PlayerScore_Clear(this);  // clear scores when needed
 277     }
 278
 279         if (this.killcount != FRAGS_SPECTATOR)
 280         {
 281                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 282                 if(!gameover)
 283                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 284                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 285
 286                 if(this.just_joined == false) {
 287                         LogTeamchange(this.playerid, -1, 4);
 288                 } else
 289                         this.just_joined = false;
 290         }
 291
 292         accuracy_resend(this);
 293
 294         this.spectatortime = time;
 295         if(this.bot_attack)
 296                 IL_REMOVE(g_bot_targets, this);
 297         this.bot_attack = false;
 298     this.hud = HUD_NORMAL;
 299         TRANSMUTE(Observer, this);
 300         this.iscreature = false;
 301         this.teleportable = TELEPORT_SIMPLE;
 302         if(this.damagedbycontents)
 303                 IL_REMOVE(g_damagedbycontents, this);
 304         this.damagedbycontents = false;
 305         this.health = FRAGS_SPECTATOR;
 306         SetSpectatee_status(this, etof(this));
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.deadflag = DEAD_NO;
 335         this.crouch = false;
 336         this.revive_progress = 0;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponmodel = "";
 344         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 345         {
 346                 if(!this.weaponentities[slot])
 347                         continue; // first load
 348                 this.weaponentities[slot] = NULL;
 349         }
 350         this.exteriorweaponentity = NULL;
 351         this.killcount = FRAGS_SPECTATOR;
 352         this.velocity = '0 0 0';
 353         this.avelocity = '0 0 0';
 354         this.punchangle = '0 0 0';
 355         this.punchvector = '0 0 0';
 356         this.oldvelocity = this.velocity;
 357         this.fire_endtime = -1;
 358         this.event_damage = func_null;
 359 }
 360
 361 int player_getspecies(entity this)
 362 {
 363         get_model_parameters(this.model, this.skin);
 364         int s = get_model_parameters_species;
 365         get_model_parameters(string_null, 0);
 366         if (s < 0) return SPECIES_HUMAN;
 367         return s;
 368 }
 369
 370 .float model_randomizer;
 371 void FixPlayermodel(entity player)
 372 {
 373         string defaultmodel = "";
 374         int defaultskin = 0;
 375         if(autocvar_sv_defaultcharacter)
 376         {
 377                 if(teamplay)
 378                 {
 379                         string s = Static_Team_ColorName_Lower(player.team);
 380                         if (s != "neutral")
 381                         {
 382                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 383                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 384                         }
 385                 }
 386
 387                 if(defaultmodel == "")
 388                 {
 389                         defaultmodel = autocvar_sv_defaultplayermodel;
 390                         defaultskin = autocvar_sv_defaultplayerskin;
 391                 }
 392
 393                 int n = tokenize_console(defaultmodel);
 394                 if(n > 0)
 395                 {
 396                         defaultmodel = argv(floor(n * player.model_randomizer));
 397                         // However, do NOT randomize if the player-selected model is in the list.
 398                         for (int i = 0; i < n; ++i)
 399                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 400                                         defaultmodel = argv(i);
 401                 }
 402
 403                 int i = strstrofs(defaultmodel, ":", 0);
 404                 if(i >= 0)
 405                 {
 406                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 407                         defaultmodel = substring(defaultmodel, 0, i);
 408                 }
 409         }
 410         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 411         {
 412                 if(teamplay)
 413                 {
 414                         string s = Static_Team_ColorName_Lower(player.team);
 415                         if (s != "neutral")
 416                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 417                 }
 418
 419                 if(!defaultskin)
 420                         defaultskin = autocvar_sv_defaultplayerskin;
 421         }
 422
 423         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 424         defaultmodel = M_ARGV(0, string);
 425         defaultskin = M_ARGV(1, int);
 426
 427         bool chmdl = false;
 428         int oldskin;
 429         if(defaultmodel != "")
 430         {
 431                 if (defaultmodel != player.model)
 432                 {
 433                         vector m1 = player.mins;
 434                         vector m2 = player.maxs;
 435                         setplayermodel (player, defaultmodel);
 436                         setsize (player, m1, m2);
 437                         chmdl = true;
 438                 }
 439
 440                 oldskin = player.skin;
 441                 player.skin = defaultskin;
 442         } else {
 443                 if (player.playermodel != player.model || player.playermodel == "")
 444                 {
 445                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 446                         vector m1 = player.mins;
 447                         vector m2 = player.maxs;
 448                         setplayermodel (player, player.playermodel);
 449                         setsize (player, m1, m2);
 450                         chmdl = true;
 451                 }
 452
 453                 if(!autocvar_sv_defaultcharacterskin)
 454                 {
 455                         oldskin = player.skin;
 456                         player.skin = stof(player.playerskin);
 457                 }
 458                 else
 459                 {
 460                         oldskin = player.skin;
 461                         player.skin = defaultskin;
 462                 }
 463         }
 464
 465         if(chmdl || oldskin != player.skin) // model or skin has changed
 466         {
 467                 player.species = player_getspecies(player); // update species
 468                 if(!autocvar_g_debug_globalsounds)
 469                         UpdatePlayerSounds(player); // update skin sounds
 470         }
 471
 472         if(!teamplay)
 473                 if(strlen(autocvar_sv_defaultplayercolors))
 474                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 475                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 476 }
 477
 478
 479 /** Called when a client spawns in the server */
 480 void PutClientInServer(entity this)
 481 {
 482         if (IS_BOT_CLIENT(this)) {
 483                 TRANSMUTE(Player, this);
 484         } else if (IS_REAL_CLIENT(this)) {
 485                 msg_entity = this;
 486                 WriteByte(MSG_ONE, SVC_SETVIEW);
 487                 WriteEntity(MSG_ONE, this);
 488         }
 489         if (gameover) {
 490                 TRANSMUTE(Observer, this);
 491         }
 492
 493         SetSpectatee(this, NULL);
 494
 495         // reset player keys
 496         this.itemkeys = 0;
 497
 498         MUTATOR_CALLHOOK(PutClientInServer, this);
 499
 500         if (IS_OBSERVER(this)) {
 501                 PutObserverInServer(this);
 502         } else if (IS_PLAYER(this)) {
 503                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 504
 505                 PlayerState_attach(this);
 506                 accuracy_resend(this);
 507
 508                 if (this.team < 0)
 509                         JoinBestTeam(this, false, true);
 510
 511                 entity spot = SelectSpawnPoint(this, false);
 512                 if (!spot) {
 513                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 514                         return; // spawn failed
 515                 }
 516
 517                 TRANSMUTE(Player, this);
 518
 519                 this.wasplayer = true;
 520                 this.iscreature = true;
 521                 this.teleportable = TELEPORT_NORMAL;
 522                 if(!this.damagedbycontents)
 523                         IL_PUSH(g_damagedbycontents, this);
 524                 this.damagedbycontents = true;
 525                 set_movetype(this, MOVETYPE_WALK);
 526                 this.solid = SOLID_SLIDEBOX;
 527                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 528                 if (autocvar_g_playerclip_collisions)
 529                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 530                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 531                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 532                 this.frags = FRAGS_PLAYER;
 533                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 534                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 535                 if (autocvar__notarget)
 536                         this.flags |= FL_NOTARGET;
 537                 this.takedamage = DAMAGE_AIM;
 538                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 539                 this.dmg = 2; // WTF
 540
 541                 if (warmup_stage) {
 542                         this.ammo_shells = warmup_start_ammo_shells;
 543                         this.ammo_nails = warmup_start_ammo_nails;
 544                         this.ammo_rockets = warmup_start_ammo_rockets;
 545                         this.ammo_cells = warmup_start_ammo_cells;
 546                         this.ammo_plasma = warmup_start_ammo_plasma;
 547                         this.ammo_fuel = warmup_start_ammo_fuel;
 548                         this.health = warmup_start_health;
 549                         this.armorvalue = warmup_start_armorvalue;
 550                         this.weapons = WARMUP_START_WEAPONS;
 551                 } else {
 552                         this.ammo_shells = start_ammo_shells;
 553                         this.ammo_nails = start_ammo_nails;
 554                         this.ammo_rockets = start_ammo_rockets;
 555                         this.ammo_cells = start_ammo_cells;
 556                         this.ammo_plasma = start_ammo_plasma;
 557                         this.ammo_fuel = start_ammo_fuel;
 558                         this.health = start_health;
 559                         this.armorvalue = start_armorvalue;
 560                         this.weapons = start_weapons;
 561                 }
 562                 SetSpectatee_status(this, 0);
 563
 564                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 565
 566                 this.items = start_items;
 567
 568                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 569                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 570                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 571                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 572                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 573                 // extend the pause of rotting if client was reset at the beginning of the countdown
 574                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 575                         float f = game_starttime - time;
 576                         this.spawnshieldtime += f;
 577                         this.pauserotarmor_finished += f;
 578                         this.pauserothealth_finished += f;
 579                         this.pauseregen_finished += f;
 580                 }
 581                 this.damageforcescale = 2;
 582                 this.death_time = 0;
 583                 this.respawn_flags = 0;
 584                 this.respawn_time = 0;
 585                 this.stat_respawn_time = 0;
 586                 this.scale = autocvar_sv_player_scale;
 587                 this.fade_time = 0;
 588                 this.pain_frame = 0;
 589                 this.pain_finished = 0;
 590                 this.pushltime = 0;
 591                 setthink(this, func_null); // players have no think function
 592                 this.nextthink = 0;
 593                 this.dmg_team = 0;
 594                 this.ballistics_density = autocvar_g_ballistics_density_player;
 595
 596                 this.deadflag = DEAD_NO;
 597
 598                 this.angles = spot.angles;
 599                 this.angles_z = 0; // never spawn tilted even if the spot says to
 600                 if (IS_BOT_CLIENT(this))
 601                         this.v_angle = this.angles;
 602                 this.fixangle = true; // turn this way immediately
 603                 this.oldvelocity = this.velocity = '0 0 0';
 604                 this.avelocity = '0 0 0';
 605                 this.punchangle = '0 0 0';
 606                 this.punchvector = '0 0 0';
 607
 608                 this.strength_finished = 0;
 609                 this.invincible_finished = 0;
 610                 this.fire_endtime = -1;
 611                 this.revive_progress = 0;
 612                 this.revival_time = 0;
 613                 this.air_finished = time + 12;
 614
 615                 entity spawnevent = new_pure(spawnevent);
 616                 spawnevent.owner = this;
 617                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 618
 619                 // Cut off any still running player sounds.
 620                 stopsound(this, CH_PLAYER_SINGLE);
 621
 622                 this.model = "";
 623                 FixPlayermodel(this);
 624                 this.drawonlytoclient = NULL;
 625
 626                 this.viewloc = NULL;
 627
 628                 this.crouch = false;
 629                 this.view_ofs = STAT(PL_VIEW_OFS, this);
 630                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 631                 this.spawnorigin = spot.origin;
 632                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 633                 // don't reset back to last position, even if new position is stuck in solid
 634                 this.oldorigin = this.origin;
 635                 this.prevorigin = this.origin;
 636                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 637                 if(this.conveyor)
 638                         IL_REMOVE(g_conveyed, this);
 639                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 640                 this.hud = HUD_NORMAL;
 641
 642                 this.event_damage = PlayerDamage;
 643
 644                 if(!this.bot_attack)
 645                         IL_PUSH(g_bot_targets, this);
 646                 this.bot_attack = true;
 647                 this.monster_attack = true;
 648
 649                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 650
 651                 if (this.killcount == FRAGS_SPECTATOR) {
 652                         PlayerScore_Clear(this);
 653                         this.killcount = 0;
 654                 }
 655
 656                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 657                 {
 658                         .entity weaponentity = weaponentities[slot];
 659                         CL_SpawnWeaponentity(this, weaponentity);
 660                 }
 661                 this.alpha = default_player_alpha;
 662                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 663                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 664
 665                 this.speedrunning = false;
 666
 667                 target_voicescript_clear(this);
 668
 669                 // reset fields the weapons may use
 670                 FOREACH(Weapons, true, LAMBDA(
 671                         it.wr_resetplayer(it, this);
 672                         // reload all reloadable weapons
 673                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 674                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 675                                 {
 676                                         .entity weaponentity = weaponentities[slot];
 677                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 678                                 }
 679                         }
 680                 ));
 681
 682                 {
 683                         string s = spot.target;
 684                         spot.target = string_null;
 685                         SUB_UseTargets(spot, this, NULL);
 686                         spot.target = s;
 687                 }
 688
 689                 Unfreeze(this);
 690
 691                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 692
 693                 if (autocvar_spawn_debug)
 694                 {
 695                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 696                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 697                 }
 698
 699                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 700                 {
 701                         .entity weaponentity = weaponentities[slot];
 702                         if(slot == 0)
 703                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 704                         else
 705                                 this.(weaponentity).m_switchweapon = WEP_Null;
 706                         this.(weaponentity).m_weapon = WEP_Null;
 707                         this.(weaponentity).weaponname = "";
 708                         this.(weaponentity).m_switchingweapon = WEP_Null;
 709                         this.(weaponentity).cnt = -1;
 710                 }
 711
 712                 if (!warmup_stage && !this.alivetime)
 713                         this.alivetime = time;
 714
 715                 antilag_clear(this, CS(this));
 716         }
 717 }
 718
 719 void ClientInit_misc(entity this);
 720
 721 // TODO do we need all these fields, or should we stop autodetecting runtime
 722 // changes and just have a console command to update this?
 723 bool ClientInit_SendEntity(entity this, entity to, int sf)
 724 {
 725         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 726         return = true;
 727         msg_entity = to;
 728         // MSG_INIT replacement
 729         // TODO: make easier to use
 730         Registry_send_all();
 731         W_PROP_reload(MSG_ONE, to);
 732         ClientInit_misc(this);
 733         MUTATOR_CALLHOOK(Ent_Init);
 734 }
 735 void ClientInit_misc(entity this)
 736 {
 737         int channel = MSG_ONE;
 738         WriteHeader(channel, ENT_CLIENT_INIT);
 739         WriteByte(channel, g_nexball_meter_period * 32);
 740         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 741         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 742         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 743         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 744         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 745         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 746         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 747         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 748
 749         if(sv_foginterval && world.fog != "")
 750                 WriteString(channel, world.fog);
 751         else
 752                 WriteString(channel, "");
 753         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 754         WriteByte(channel, serverflags);
 755         WriteCoord(channel, autocvar_g_trueaim_minrange);
 756 }
 757
 758 void ClientInit_CheckUpdate(entity this)
 759 {
 760         this.nextthink = time;
 761         if(this.count != autocvar_g_balance_armor_blockpercent)
 762         {
 763                 this.count = autocvar_g_balance_armor_blockpercent;
 764                 this.SendFlags |= 1;
 765         }
 766 }
 767
 768 void ClientInit_Spawn()
 769 {
 770         entity e = new_pure(clientinit);
 771         setthink(e, ClientInit_CheckUpdate);
 772         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 773
 774         ClientInit_CheckUpdate(e);
 775 }
 776
 777 /*
 778 =============
 779 SetNewParms
 780 =============
 781 */
 782 void SetNewParms ()
 783 {
 784         // initialize parms for a new player
 785         parm1 = -(86400 * 366);
 786
 787         MUTATOR_CALLHOOK(SetNewParms);
 788 }
 789
 790 /*
 791 =============
 792 SetChangeParms
 793 =============
 794 */
 795 void SetChangeParms (entity this)
 796 {
 797         // save parms for level change
 798         parm1 = this.parm_idlesince - time;
 799
 800         MUTATOR_CALLHOOK(SetChangeParms);
 801 }
 802
 803 /*
 804 =============
 805 DecodeLevelParms
 806 =============
 807 */
 808 void DecodeLevelParms(entity this)
 809 {
 810         // load parms
 811         this.parm_idlesince = parm1;
 812         if (this.parm_idlesince == -(86400 * 366))
 813                 this.parm_idlesince = time;
 814
 815         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 816         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 817
 818         MUTATOR_CALLHOOK(DecodeLevelParms);
 819 }
 820
 821 /*
 822 =============
 823 ClientKill
 824
 825 Called when a client types 'kill' in the console
 826 =============
 827 */
 828
 829 .float clientkill_nexttime;
 830 void ClientKill_Now_TeamChange(entity this)
 831 {
 832         if(this.killindicator_teamchange == -1)
 833         {
 834                 JoinBestTeam( this, false, true );
 835         }
 836         else if(this.killindicator_teamchange == -2)
 837         {
 838                 if(blockSpectators)
 839                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 840                 PutObserverInServer(this);
 841         }
 842         else
 843                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 844         this.killindicator_teamchange = 0;
 845 }
 846
 847 void ClientKill_Now(entity this)
 848 {
 849         if(this.vehicle)
 850         {
 851             vehicles_exit(this.vehicle, VHEF_RELEASE);
 852             if(!this.killindicator_teamchange)
 853             {
 854             this.vehicle_health = -1;
 855             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 856             }
 857         }
 858
 859         if(this.killindicator && !wasfreed(this.killindicator))
 860                 delete(this.killindicator);
 861
 862         this.killindicator = NULL;
 863
 864         if(this.killindicator_teamchange)
 865                 ClientKill_Now_TeamChange(this);
 866
 867         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 868                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 869
 870         // now I am sure the player IS dead
 871 }
 872 void KillIndicator_Think(entity this)
 873 {
 874         if (gameover)
 875         {
 876                 this.owner.killindicator = NULL;
 877                 delete(this);
 878                 return;
 879         }
 880
 881         if (this.owner.alpha < 0 && !this.owner.vehicle)
 882         {
 883                 this.owner.killindicator = NULL;
 884                 delete(this);
 885                 return;
 886         }
 887
 888         if(this.cnt <= 0)
 889         {
 890                 ClientKill_Now(this.owner);
 891                 return;
 892         }
 893     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 894     {
 895         this.nextthink = time + 1;
 896         this.cnt -= 1;
 897     }
 898         else
 899         {
 900                 if(this.cnt <= 10)
 901                         setmodel(this, MDL_NUM(this.cnt));
 902                 if(IS_REAL_CLIENT(this.owner))
 903                 {
 904                         if(this.cnt <= 10)
 905                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 906                 }
 907                 this.nextthink = time + 1;
 908                 this.cnt -= 1;
 909         }
 910 }
 911
 912 float clientkilltime;
 913 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 914 {
 915         float killtime;
 916         float starttime;
 917
 918         if (gameover)
 919                 return;
 920
 921         killtime = autocvar_g_balance_kill_delay;
 922
 923         if(g_race_qualifying || g_cts)
 924                 killtime = 0;
 925
 926     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 927         return;
 928
 929         this.killindicator_teamchange = targetteam;
 930
 931     if(!this.killindicator)
 932         {
 933                 if(!IS_DEAD(this))
 934                 {
 935                         killtime = max(killtime, this.clientkill_nexttime - time);
 936                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 937                 }
 938
 939                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 940                 {
 941                         ClientKill_Now(this);
 942                 }
 943                 else
 944                 {
 945                         starttime = max(time, clientkilltime);
 946
 947                         this.killindicator = spawn();
 948                         this.killindicator.owner = this;
 949                         this.killindicator.scale = 0.5;
 950                         setattachment(this.killindicator, this, "");
 951                         setorigin(this.killindicator, '0 0 52');
 952                         setthink(this.killindicator, KillIndicator_Think);
 953                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 954                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 955                         this.killindicator.cnt = ceil(killtime);
 956                         this.killindicator.count = bound(0, ceil(killtime), 10);
 957                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 958
 959                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 960                         {
 961                                 it.killindicator = spawn();
 962                                 it.killindicator.owner = it;
 963                                 it.killindicator.scale = 0.5;
 964                                 setattachment(it.killindicator, it, "");
 965                                 setorigin(it.killindicator, '0 0 52');
 966                                 setthink(it.killindicator, KillIndicator_Think);
 967                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 968                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 969                                 it.killindicator.cnt = ceil(killtime);
 970                         });
 971                         this.lip = 0;
 972                 }
 973         }
 974         if(this.killindicator)
 975         {
 976                 if(targetteam == 0) // just die
 977                 {
 978                         this.killindicator.colormod = '0 0 0';
 979                         if(IS_REAL_CLIENT(this))
 980                         if(this.killindicator.cnt > 0)
 981                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 982                 }
 983                 else if(targetteam == -1) // auto
 984                 {
 985                         this.killindicator.colormod = '0 1 0';
 986                         if(IS_REAL_CLIENT(this))
 987                         if(this.killindicator.cnt > 0)
 988                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 989                 }
 990                 else if(targetteam == -2) // spectate
 991                 {
 992                         this.killindicator.colormod = '0.5 0.5 0.5';
 993                         if(IS_REAL_CLIENT(this))
 994                         if(this.killindicator.cnt > 0)
 995                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 996                 }
 997                 else
 998                 {
 999                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1000                         if(IS_REAL_CLIENT(this))
1001                         if(this.killindicator.cnt > 0)
1002                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1003                 }
1004         }
1005
1006 }
1007
1008 void ClientKill (entity this)
1009 {
1010         if(gameover) return;
1011         if(this.player_blocked) return;
1012         if(STAT(FROZEN, this)) return;
1013
1014         ClientKill_TeamChange(this, 0);
1015 }
1016
1017 void FixClientCvars(entity e)
1018 {
1019         // send prediction settings to the client
1020         stuffcmd(e, "\nin_bindmap 0 0\n");
1021         if(autocvar_g_antilag == 3) // client side hitscan
1022                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1023         if(autocvar_sv_gentle)
1024                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1025
1026         MUTATOR_CALLHOOK(FixClientCvars, e);
1027 }
1028
1029 float PlayerInIDList(entity p, string idlist)
1030 {
1031         float n, i;
1032         string s;
1033
1034         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1035         if (!p.crypto_idfp)
1036                 return 0;
1037
1038         // this function allows abbreviated player IDs too!
1039         n = tokenize_console(idlist);
1040         for(i = 0; i < n; ++i)
1041         {
1042                 s = argv(i);
1043                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1044                         return 1;
1045         }
1046
1047         return 0;
1048 }
1049
1050 #ifdef DP_EXT_PRECONNECT
1051 /*
1052 =============
1053 ClientPreConnect
1054
1055 Called once (not at each match start) when a client begins a connection to the server
1056 =============
1057 */
1058 void ClientPreConnect(entity this)
1059 {
1060         if(autocvar_sv_eventlog)
1061         {
1062                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1063                         this.playerid,
1064                         etof(this),
1065                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1066                 ));
1067         }
1068 }
1069 #endif
1070
1071 /**
1072 =============
1073 ClientConnect
1074
1075 Called when a client connects to the server
1076 =============
1077 */
1078 void ClientConnect(entity this)
1079 {
1080         if (Ban_MaybeEnforceBanOnce(this)) return;
1081         assert(!IS_CLIENT(this), return);
1082         this.flags |= FL_CLIENT;
1083         assert(player_count >= 0, player_count = 0);
1084
1085 #ifdef WATERMARK
1086         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1087 #endif
1088         this.version_nagtime = time + 10 + random() * 10;
1089         TRANSMUTE(Client, this);
1090
1091         // identify the right forced team
1092         if (autocvar_g_campaign)
1093         {
1094                 if (IS_REAL_CLIENT(this)) // only players, not bots
1095                 {
1096                         switch (autocvar_g_campaign_forceteam)
1097                         {
1098                                 case 1: this.team_forced = NUM_TEAM_1; break;
1099                                 case 2: this.team_forced = NUM_TEAM_2; break;
1100                                 case 3: this.team_forced = NUM_TEAM_3; break;
1101                                 case 4: this.team_forced = NUM_TEAM_4; break;
1102                                 default: this.team_forced = 0;
1103                         }
1104                 }
1105         }
1106         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1107         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1108         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1109         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1110         else switch (autocvar_g_forced_team_otherwise)
1111         {
1112                 default: this.team_forced = 0; break;
1113                 case "red": this.team_forced = NUM_TEAM_1; break;
1114                 case "blue": this.team_forced = NUM_TEAM_2; break;
1115                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1116                 case "pink": this.team_forced = NUM_TEAM_4; break;
1117                 case "spectate":
1118                 case "spectator":
1119                         this.team_forced = -1;
1120                         break;
1121         }
1122         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1123
1124     {
1125         int id = this.playerid;
1126         this.playerid = 0; // silent
1127             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1128             this.playerid = id;
1129     }
1130
1131         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1132                 TRANSMUTE(Observer, this);
1133         } else {
1134                 if (!teamplay || autocvar_g_balance_teams) {
1135                         TRANSMUTE(Player, this);
1136                         campaign_bots_may_start = true;
1137                 } else {
1138                         TRANSMUTE(Observer, this); // do it anyway
1139                 }
1140         }
1141
1142         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1143
1144         // always track bots, don't ask for cl_allow_uidtracking
1145     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1146
1147         if (autocvar_sv_eventlog)
1148                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1149
1150         LogTeamchange(this.playerid, this.team, 1);
1151
1152         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1153
1154         this.netname_previous = strzone(this.netname);
1155
1156         if(teamplay && IS_PLAYER(this))
1157                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1158         else
1159                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1160
1161         stuffcmd(this, clientstuff, "\n");
1162         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1163
1164         FixClientCvars(this);
1165
1166         // get version info from player
1167         stuffcmd(this, "cmd clientversion $gameversion\n");
1168
1169         // notify about available teams
1170         if (teamplay)
1171         {
1172                 CheckAllowedTeams(this);
1173                 int t = 0;
1174                 if (c1 >= 0) t |= BIT(0);
1175                 if (c2 >= 0) t |= BIT(1);
1176                 if (c3 >= 0) t |= BIT(2);
1177                 if (c4 >= 0) t |= BIT(3);
1178                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1179         }
1180         else
1181         {
1182                 stuffcmd(this, "set _teams_available 0\n");
1183         }
1184
1185         bot_relinkplayerlist();
1186
1187         this.spectatortime = time;
1188         if (blockSpectators)
1189         {
1190                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1191         }
1192
1193         this.jointime = time;
1194         this.allowed_timeouts = autocvar_sv_timeout_number;
1195
1196         if (IS_REAL_CLIENT(this))
1197         {
1198                 if (g_weaponarena_weapons == WEPSET(TUBA))
1199                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1200         }
1201
1202         if (!sv_foginterval && world.fog != "")
1203                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1204
1205         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1206                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1207                         send_CSQC_teamnagger();
1208
1209         CSQCMODEL_AUTOINIT(this);
1210
1211         this.model_randomizer = random();
1212
1213         if (IS_REAL_CLIENT(this))
1214                 sv_notice_join(this);
1215
1216         // update physics stats (players can spawn before physics runs)
1217         Physics_UpdateStats(this, PHYS_HIGHSPEED(this));
1218
1219         IL_EACH(g_initforplayer, it.init_for_player, {
1220                 it.init_for_player(it, this);
1221         });
1222
1223         MUTATOR_CALLHOOK(ClientConnect, this);
1224
1225         if (IS_REAL_CLIENT(this))
1226         {
1227                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1228                 {
1229                         this.motd_actived_time = -1;
1230                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1231                 }
1232         }
1233 }
1234 /*
1235 =============
1236 ClientDisconnect
1237
1238 Called when a client disconnects from the server
1239 =============
1240 */
1241 .entity chatbubbleentity;
1242 void ReadyCount();
1243 void ClientDisconnect(entity this)
1244 {
1245         assert(IS_CLIENT(this), return);
1246
1247         PlayerStats_GameReport_FinalizePlayer(this);
1248         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1249         if (this.active_minigame) part_minigame(this);
1250         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1251
1252         if (autocvar_sv_eventlog)
1253                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1254
1255         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1256
1257         SetSpectatee(this, NULL);
1258
1259     MUTATOR_CALLHOOK(ClientDisconnect, this);
1260
1261         ClientState_detach(this);
1262
1263         Portal_ClearAll(this);
1264
1265         Unfreeze(this);
1266
1267         RemoveGrapplingHooks(this);
1268
1269         // Here, everything has been done that requires this player to be a client.
1270
1271         this.flags &= ~FL_CLIENT;
1272
1273         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1274         if (this.killindicator) delete(this.killindicator);
1275
1276         WaypointSprite_PlayerGone(this);
1277
1278         bot_relinkplayerlist();
1279
1280         if (this.netname_previous) strunzone(this.netname_previous);
1281         if (this.clientstatus) strunzone(this.clientstatus);
1282         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1283         if (this.personal) delete(this.personal);
1284
1285         this.playerid = 0;
1286         ReadyCount();
1287         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1288
1289         ONREMOVE(this);
1290 }
1291
1292 void ChatBubbleThink(entity this)
1293 {
1294         this.nextthink = time;
1295         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1296         {
1297                 if(this.owner) // but why can that ever be NULL?
1298                         this.owner.chatbubbleentity = NULL;
1299                 delete(this);
1300                 return;
1301         }
1302
1303         this.mdl = "";
1304
1305         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1306         {
1307                 if ( this.owner.active_minigame )
1308                         this.mdl = "models/sprites/minigame_busy.iqm";
1309                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1310                         this.mdl = "models/misc/chatbubble.spr";
1311         }
1312
1313         if ( this.model != this.mdl )
1314                 _setmodel(this, this.mdl);
1315
1316 }
1317
1318 void UpdateChatBubble(entity this)
1319 {
1320         if (this.alpha < 0)
1321                 return;
1322         // spawn a chatbubble entity if needed
1323         if (!this.chatbubbleentity)
1324         {
1325                 this.chatbubbleentity = new(chatbubbleentity);
1326                 this.chatbubbleentity.owner = this;
1327                 this.chatbubbleentity.exteriormodeltoclient = this;
1328                 setthink(this.chatbubbleentity, ChatBubbleThink);
1329                 this.chatbubbleentity.nextthink = time;
1330                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1331                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1332                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1333                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1334                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1335                 //this.chatbubbleentity.model = "";
1336                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1337         }
1338 }
1339
1340
1341 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1342 // added to the model skins
1343 /*void UpdateColorModHack()
1344 {
1345         float c;
1346         c = this.clientcolors & 15;
1347         // LordHavoc: only bothering to support white, green, red, yellow, blue
1348              if (!teamplay) this.colormod = '0 0 0';
1349         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1350         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1351         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1352         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1353         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1354         else this.colormod = '1 1 1';
1355 }*/
1356
1357 void respawn(entity this)
1358 {
1359         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1360         {
1361                 this.solid = SOLID_NOT;
1362                 this.takedamage = DAMAGE_NO;
1363                 set_movetype(this, MOVETYPE_FLY);
1364                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1365                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1366                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1367                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1368                 if(autocvar_g_respawn_ghosts_maxtime)
1369                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1370         }
1371
1372         CopyBody(this, 1);
1373
1374         this.effects |= EF_NODRAW; // prevent another CopyBody
1375         PutClientInServer(this);
1376 }
1377
1378 void play_countdown(entity this, float finished, Sound samp)
1379 {
1380     TC(Sound, samp);
1381         if(IS_REAL_CLIENT(this))
1382                 if(floor(finished - time - frametime) != floor(finished - time))
1383                         if(finished - time < 6)
1384                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1385 }
1386
1387 void player_powerups(entity this)
1388 {
1389         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1390         int items_prev = this.items;
1391
1392         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1393                 this.modelflags |= MF_ROCKET;
1394         else
1395                 this.modelflags &= ~MF_ROCKET;
1396
1397         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1398
1399         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1400                 return;
1401
1402         Fire_ApplyDamage(this);
1403         Fire_ApplyEffect(this);
1404
1405         if (!g_instagib)
1406         {
1407                 if (this.items & ITEM_Strength.m_itemid)
1408                 {
1409                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1410                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1411                         if (time > this.strength_finished)
1412                         {
1413                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1414                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1415                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1416                         }
1417                 }
1418                 else
1419                 {
1420                         if (time < this.strength_finished)
1421                         {
1422                                 this.items = this.items | ITEM_Strength.m_itemid;
1423                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1424                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1425                         }
1426                 }
1427                 if (this.items & ITEM_Shield.m_itemid)
1428                 {
1429                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1430                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1431                         if (time > this.invincible_finished)
1432                         {
1433                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1434                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1435                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1436                         }
1437                 }
1438                 else
1439                 {
1440                         if (time < this.invincible_finished)
1441                         {
1442                                 this.items = this.items | ITEM_Shield.m_itemid;
1443                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1444                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1445                         }
1446                 }
1447                 if (this.items & IT_SUPERWEAPON)
1448                 {
1449                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1450                         {
1451                                 this.superweapons_finished = 0;
1452                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1453                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1454                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1455                         }
1456                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1457                         {
1458                                 // don't let them run out
1459                         }
1460                         else
1461                         {
1462                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1463                                 if (time > this.superweapons_finished)
1464                                 {
1465                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1466                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1467                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1468                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1469                                 }
1470                         }
1471                 }
1472                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1473                 {
1474                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1475                         {
1476                                 this.items = this.items | IT_SUPERWEAPON;
1477                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1478                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1479                         }
1480                         else
1481                         {
1482                                 this.superweapons_finished = 0;
1483                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1484                         }
1485                 }
1486                 else
1487                 {
1488                         this.superweapons_finished = 0;
1489                 }
1490         }
1491
1492         if(autocvar_g_nodepthtestplayers)
1493                 this.effects = this.effects | EF_NODEPTHTEST;
1494
1495         if(autocvar_g_fullbrightplayers)
1496                 this.effects = this.effects | EF_FULLBRIGHT;
1497
1498         if (time >= game_starttime)
1499         if (time < this.spawnshieldtime)
1500                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1501
1502         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1503 }
1504
1505 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1506 {
1507         if(current > stable)
1508                 return current;
1509         else if(current > stable - 0.25) // when close enough, "snap"
1510                 return stable;
1511         else
1512                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1513 }
1514
1515 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1516 {
1517         if(current < stable)
1518                 return current;
1519         else if(current < stable + 0.25) // when close enough, "snap"
1520                 return stable;
1521         else
1522                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1523 }
1524
1525 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1526 {
1527         if(current > rotstable)
1528         {
1529                 if(rotframetime > 0)
1530                 {
1531                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1532                         current = max(rotstable, current - rotlinear * rotframetime);
1533                 }
1534         }
1535         else if(current < regenstable)
1536         {
1537                 if(regenframetime > 0)
1538                 {
1539                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1540                         current = min(regenstable, current + regenlinear * regenframetime);
1541                 }
1542         }
1543
1544         if(current > limit)
1545                 current = limit;
1546
1547         return current;
1548 }
1549
1550 void player_regen(entity this)
1551 {
1552         float max_mod, regen_mod, rot_mod, limit_mod;
1553         max_mod = regen_mod = rot_mod = limit_mod = 1;
1554
1555         float regen_health = autocvar_g_balance_health_regen;
1556         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1557         float regen_health_rot = autocvar_g_balance_health_rot;
1558         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1559         float regen_health_stable = autocvar_g_balance_health_regenstable;
1560         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1561         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1562                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1563         max_mod = M_ARGV(1, float);
1564         regen_mod = M_ARGV(2, float);
1565         rot_mod = M_ARGV(3, float);
1566         limit_mod = M_ARGV(4, float);
1567         regen_health = M_ARGV(5, float);
1568         regen_health_linear = M_ARGV(6, float);
1569         regen_health_rot = M_ARGV(7, float);
1570         regen_health_rotlinear = M_ARGV(8, float);
1571         regen_health_stable = M_ARGV(9, float);
1572         regen_health_rotstable = M_ARGV(10, float);
1573
1574
1575         if(!mutator_returnvalue)
1576         if(!STAT(FROZEN, this))
1577         {
1578                 float mina, maxa, limith, limita;
1579                 maxa = autocvar_g_balance_armor_rotstable;
1580                 mina = autocvar_g_balance_armor_regenstable;
1581                 limith = autocvar_g_balance_health_limit;
1582                 limita = autocvar_g_balance_armor_limit;
1583
1584                 regen_health_rotstable = regen_health_rotstable * max_mod;
1585                 regen_health_stable = regen_health_stable * max_mod;
1586                 limith = limith * limit_mod;
1587                 limita = limita * limit_mod;
1588
1589                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1590                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1591         }
1592
1593         // if player rotted to death...  die!
1594         // check this outside above checks, as player may still be able to rot to death
1595         if(this.health < 1)
1596         {
1597                 if(this.vehicle)
1598                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1599                 if(this.event_damage)
1600                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1601         }
1602
1603         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1604         {
1605                 float minf, maxf, limitf;
1606
1607                 maxf = autocvar_g_balance_fuel_rotstable;
1608                 minf = autocvar_g_balance_fuel_regenstable;
1609                 limitf = autocvar_g_balance_fuel_limit;
1610
1611                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1612         }
1613 }
1614
1615 bool zoomstate_set;
1616 void SetZoomState(entity this, float newzoom)
1617 {
1618         if(newzoom != this.zoomstate)
1619         {
1620                 this.zoomstate = newzoom;
1621                 ClientData_Touch(this);
1622         }
1623         zoomstate_set = true;
1624 }
1625
1626 void GetPressedKeys(entity this)
1627 {
1628         MUTATOR_CALLHOOK(GetPressedKeys, this);
1629         int keys = STAT(PRESSED_KEYS, this);
1630         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1631         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1632         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1633         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1634
1635         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1636         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1637         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1638         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1639         this.pressedkeys = keys; // store for other users
1640
1641         STAT(PRESSED_KEYS, this) = keys;
1642 }
1643
1644 /*
1645 ======================
1646 spectate mode routines
1647 ======================
1648 */
1649
1650 void SpectateCopy(entity this, entity spectatee)
1651 {
1652     TC(Client, this); TC(Client, spectatee);
1653
1654         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1655         PS(this) = PS(spectatee);
1656         this.armortype = spectatee.armortype;
1657         this.armorvalue = spectatee.armorvalue;
1658         this.ammo_cells = spectatee.ammo_cells;
1659         this.ammo_plasma = spectatee.ammo_plasma;
1660         this.ammo_shells = spectatee.ammo_shells;
1661         this.ammo_nails = spectatee.ammo_nails;
1662         this.ammo_rockets = spectatee.ammo_rockets;
1663         this.ammo_fuel = spectatee.ammo_fuel;
1664         this.clip_load = spectatee.clip_load;
1665         this.clip_size = spectatee.clip_size;
1666         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1667         this.health = spectatee.health;
1668         this.impulse = 0;
1669         this.items = spectatee.items;
1670         this.last_pickup = spectatee.last_pickup;
1671         this.hit_time = spectatee.hit_time;
1672         this.strength_finished = spectatee.strength_finished;
1673         this.invincible_finished = spectatee.invincible_finished;
1674         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1675         this.weapons = spectatee.weapons;
1676         this.vortex_charge = spectatee.vortex_charge;
1677         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1678         this.hagar_load = spectatee.hagar_load;
1679         this.arc_heat_percent = spectatee.arc_heat_percent;
1680         this.minelayer_mines = spectatee.minelayer_mines;
1681         this.punchangle = spectatee.punchangle;
1682         this.view_ofs = spectatee.view_ofs;
1683         this.velocity = spectatee.velocity;
1684         this.dmg_take = spectatee.dmg_take;
1685         this.dmg_save = spectatee.dmg_save;
1686         this.dmg_inflictor = spectatee.dmg_inflictor;
1687         this.v_angle = spectatee.v_angle;
1688         this.angles = spectatee.v_angle;
1689         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1690         this.revive_progress = spectatee.revive_progress;
1691         this.viewloc = spectatee.viewloc;
1692         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1693                 this.fixangle = true;
1694         setorigin(this, spectatee.origin);
1695         setsize(this, spectatee.mins, spectatee.maxs);
1696         SetZoomState(this, spectatee.zoomstate);
1697
1698         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1699         {
1700                 .entity weaponentity = weaponentities[slot];
1701                 this.(weaponentity) = spectatee.(weaponentity);
1702         }
1703
1704     anticheat_spectatecopy(this, spectatee);
1705         this.hud = spectatee.hud;
1706         if(spectatee.vehicle)
1707     {
1708         this.angles = spectatee.v_angle;
1709
1710         //this.fixangle = false;
1711         //this.velocity = spectatee.vehicle.velocity;
1712         this.vehicle_health = spectatee.vehicle_health;
1713         this.vehicle_shield = spectatee.vehicle_shield;
1714         this.vehicle_energy = spectatee.vehicle_energy;
1715         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1716         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1717         this.vehicle_reload1 = spectatee.vehicle_reload1;
1718         this.vehicle_reload2 = spectatee.vehicle_reload2;
1719
1720         //msg_entity = this;
1721
1722        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1723             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1724            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1725            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1726
1727         //WriteByte (MSG_ONE, SVC_SETVIEW);
1728         //    WriteEntity(MSG_ONE, this);
1729         //makevectors(spectatee.v_angle);
1730         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1731     }
1732 }
1733
1734 bool SpectateUpdate(entity this)
1735 {
1736         if(!this.enemy)
1737                 return false;
1738
1739         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1740         {
1741                 SetSpectatee(this, NULL);
1742                 return false;
1743         }
1744
1745         SpectateCopy(this, this.enemy);
1746
1747         return true;
1748 }
1749
1750 bool SpectateSet(entity this)
1751 {
1752         if(!IS_PLAYER(this.enemy))
1753                 return false;
1754
1755         ClientData_Touch(this.enemy);
1756
1757         msg_entity = this;
1758         WriteByte(MSG_ONE, SVC_SETVIEW);
1759         WriteEntity(MSG_ONE, this.enemy);
1760         set_movetype(this, MOVETYPE_NONE);
1761         accuracy_resend(this);
1762
1763         if(!SpectateUpdate(this))
1764                 PutObserverInServer(this);
1765
1766         return true;
1767 }
1768
1769 void SetSpectatee_status(entity this, int spectatee_num)
1770 {
1771         int oldspectatee_status = this.spectatee_status;
1772         this.spectatee_status = spectatee_num;
1773
1774         if (this.spectatee_status != oldspectatee_status)
1775         {
1776                 ClientData_Touch(this);
1777                 if (g_race || g_cts) race_InitSpectator();
1778         }
1779 }
1780
1781 void SetSpectatee(entity this, entity spectatee)
1782 {
1783         entity old_spectatee = this.enemy;
1784
1785         this.enemy = spectatee;
1786
1787         // WEAPONTODO
1788         // these are required to fix the spectator bug with arc
1789         if(old_spectatee)
1790         {
1791                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1792                 {
1793                         .entity weaponentity = weaponentities[slot];
1794                         if(old_spectatee.(weaponentity).arc_beam)
1795                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1796                 }
1797         }
1798         if(this.enemy)
1799         {
1800                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1801                 {
1802                         .entity weaponentity = weaponentities[slot];
1803                         if(this.enemy.(weaponentity).arc_beam)
1804                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1805                 }
1806         }
1807
1808         if (this.enemy)
1809                 SetSpectatee_status(this, etof(this.enemy));
1810
1811         // needed to update spectator list
1812         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1813 }
1814
1815 bool Spectate(entity this, entity pl)
1816 {
1817         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1818                 return false;
1819         pl = M_ARGV(1, entity);
1820
1821         SetSpectatee(this, pl);
1822         return SpectateSet(this);
1823 }
1824
1825 bool SpectateNext(entity this)
1826 {
1827         entity ent = find(this.enemy, classname, STR_PLAYER);
1828
1829         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1830                 ent = M_ARGV(1, entity);
1831         else if (!ent)
1832                 ent = find(ent, classname, STR_PLAYER);
1833
1834         if(ent) { SetSpectatee(this, ent); }
1835
1836         return SpectateSet(this);
1837 }
1838
1839 bool SpectatePrev(entity this)
1840 {
1841         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1842         entity ent = findchain(classname, STR_PLAYER);
1843         if (!ent) // no player
1844                 return false;
1845
1846         entity first = ent;
1847         // skip players until current spectated player
1848         if(this.enemy)
1849         while(ent && ent != this.enemy)
1850                 ent = ent.chain;
1851
1852         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1853         {
1854                 case MUT_SPECPREV_FOUND:
1855                     ent = M_ARGV(1, entity);
1856                     break;
1857                 case MUT_SPECPREV_RETURN:
1858                     return true;
1859                 case MUT_SPECPREV_CONTINUE:
1860                 default:
1861                 {
1862                         if(ent.chain)
1863                                 ent = ent.chain;
1864                         else
1865                                 ent = first;
1866                         break;
1867                 }
1868         }
1869
1870         SetSpectatee(this, ent);
1871         return SpectateSet(this);
1872 }
1873
1874 /*
1875 =============
1876 ShowRespawnCountdown()
1877
1878 Update a respawn countdown display.
1879 =============
1880 */
1881 void ShowRespawnCountdown(entity this)
1882 {
1883         float number;
1884         if(!IS_DEAD(this)) // just respawned?
1885                 return;
1886         else
1887         {
1888                 number = ceil(this.respawn_time - time);
1889                 if(number <= 0)
1890                         return;
1891                 if(number <= this.respawn_countdown)
1892                 {
1893                         this.respawn_countdown = number - 1;
1894                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1895                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1896                 }
1897         }
1898 }
1899
1900 .bool team_selected;
1901 bool ShowTeamSelection(entity this)
1902 {
1903         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1904                 return false;
1905         stuffcmd(this, "menu_showteamselect\n");
1906         return true;
1907 }
1908 void Join(entity this)
1909 {
1910         TRANSMUTE(Player, this);
1911
1912         if(!this.team_selected)
1913         if(autocvar_g_campaign || autocvar_g_balance_teams)
1914                 JoinBestTeam(this, false, true);
1915
1916         if(autocvar_g_campaign)
1917                 campaign_bots_may_start = true;
1918
1919         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1920
1921         PutClientInServer(this);
1922
1923         if(teamplay && this.team != -1)
1924                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1925         else
1926                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1927         this.team_selected = false;
1928 }
1929
1930 /**
1931  * Determines whether the player is allowed to join. This depends on cvar
1932  * g_maxplayers, if it isn't used this function always return true, otherwise
1933  * it checks whether the number of currently playing players exceeds g_maxplayers.
1934  * @return int number of free slots for players, 0 if none
1935  */
1936 int nJoinAllowed(entity this, entity ignore)
1937 {
1938         if(!ignore)
1939         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1940         // so report 0 free slots if restricted
1941         {
1942                 if(autocvar_g_forced_team_otherwise == "spectate")
1943                         return 0;
1944                 if(autocvar_g_forced_team_otherwise == "spectator")
1945                         return 0;
1946         }
1947
1948         if(this && this.team_forced < 0)
1949                 return 0; // forced spectators can never join
1950
1951         // TODO simplify this
1952         int totalClients = 0;
1953         int currentlyPlaying = 0;
1954         FOREACH_CLIENT(true, LAMBDA(
1955                 if(it != ignore)
1956                         ++totalClients;
1957                 if(IS_REAL_CLIENT(it))
1958                 if(IS_PLAYER(it) || it.caplayer)
1959                         ++currentlyPlaying;
1960         ));
1961
1962         float free_slots = 0;
1963         if (!autocvar_g_maxplayers)
1964                 free_slots = maxclients - totalClients;
1965         else if(currentlyPlaying < autocvar_g_maxplayers)
1966                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1967
1968         static float join_prevent_msg_time = 0;
1969         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1970         {
1971                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1972                 join_prevent_msg_time = time + 3;
1973         }
1974
1975         return free_slots;
1976 }
1977
1978 /**
1979  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1980  * g_maxplayers_spectator_blocktime seconds
1981  */
1982 void checkSpectatorBlock(entity this)
1983 {
1984         if(IS_SPEC(this) || IS_OBSERVER(this))
1985         if(!this.caplayer)
1986         if(IS_REAL_CLIENT(this))
1987         {
1988                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1989                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1990                         dropclient(this);
1991                 }
1992         }
1993 }
1994
1995 void PrintWelcomeMessage(entity this)
1996 {
1997         if(this.motd_actived_time == 0)
1998         {
1999                 if (autocvar_g_campaign) {
2000                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2001                                 this.motd_actived_time = time;
2002                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2003                         }
2004                 } else {
2005                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2006                                 this.motd_actived_time = time;
2007                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2008                         }
2009                 }
2010         }
2011         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
2012         {
2013                 if (autocvar_g_campaign) {
2014                         if (PHYS_INPUT_BUTTON_INFO(this))
2015                                 this.motd_actived_time = time;
2016                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2017                                 this.motd_actived_time = 0;
2018                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2019                         }
2020                 } else {
2021                         if (PHYS_INPUT_BUTTON_INFO(this))
2022                                 this.motd_actived_time = time;
2023                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2024                                 this.motd_actived_time = 0;
2025                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2026                         }
2027                 }
2028         }
2029         else //if(this.motd_actived_time < 0) // just connected, motd is active
2030         {
2031                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2032                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2033                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2034                 {
2035                         // instanctly hide MOTD
2036                         this.motd_actived_time = 0;
2037                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2038                 }
2039         }
2040 }
2041
2042 bool joinAllowed(entity this)
2043 {
2044         if (this.version_mismatch) return false;
2045         if (!nJoinAllowed(this, this)) return false;
2046         if (teamplay && lockteams) return false;
2047         if (ShowTeamSelection(this)) return false;
2048         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2049         return true;
2050 }
2051
2052 void ObserverThink(entity this)
2053 {
2054         if ( this.impulse )
2055         {
2056                 MinigameImpulse(this, this.impulse);
2057                 this.impulse = 0;
2058         }
2059
2060         if (this.flags & FL_JUMPRELEASED) {
2061                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2062                         this.flags &= ~FL_JUMPRELEASED;
2063                         this.flags |= FL_SPAWNING;
2064                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2065                         this.flags &= ~FL_JUMPRELEASED;
2066                         if(SpectateNext(this)) {
2067                                 TRANSMUTE(Spectator, this);
2068                         }
2069                 } else {
2070                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2071                         set_movetype(this, preferred_movetype);
2072                 }
2073         } else {
2074                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2075                         this.flags |= FL_JUMPRELEASED;
2076                         if(this.flags & FL_SPAWNING)
2077                         {
2078                                 this.flags &= ~FL_SPAWNING;
2079                                 Join(this);
2080                                 return;
2081                         }
2082                 }
2083         }
2084 }
2085
2086 void SpectatorThink(entity this)
2087 {
2088         if ( this.impulse )
2089         {
2090                 if(MinigameImpulse(this, this.impulse))
2091                         this.impulse = 0;
2092
2093                 if (this.impulse == IMP_weapon_drop.impulse)
2094                 {
2095                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2096                         this.impulse = 0;
2097                         return;
2098                 }
2099         }
2100
2101         if (this.flags & FL_JUMPRELEASED) {
2102                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2103                         this.flags &= ~FL_JUMPRELEASED;
2104                         this.flags |= FL_SPAWNING;
2105                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2106                         this.flags &= ~FL_JUMPRELEASED;
2107                         if(SpectateNext(this)) {
2108                                 TRANSMUTE(Spectator, this);
2109                         } else {
2110                                 TRANSMUTE(Observer, this);
2111                                 PutClientInServer(this);
2112                         }
2113                         this.impulse = 0;
2114                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2115                         this.flags &= ~FL_JUMPRELEASED;
2116                         if(SpectatePrev(this)) {
2117                                 TRANSMUTE(Spectator, this);
2118                         } else {
2119                                 TRANSMUTE(Observer, this);
2120                                 PutClientInServer(this);
2121                         }
2122                         this.impulse = 0;
2123                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2124                         this.flags &= ~FL_JUMPRELEASED;
2125                         TRANSMUTE(Observer, this);
2126                         PutClientInServer(this);
2127                 } else {
2128                         if(!SpectateUpdate(this))
2129                                 PutObserverInServer(this);
2130                 }
2131         } else {
2132                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2133                         this.flags |= FL_JUMPRELEASED;
2134                         if(this.flags & FL_SPAWNING)
2135                         {
2136                                 this.flags &= ~FL_SPAWNING;
2137                                 Join(this);
2138                                 return;
2139                         }
2140                 }
2141                 if(!SpectateUpdate(this))
2142                         PutObserverInServer(this);
2143         }
2144
2145         this.flags |= FL_CLIENT | FL_NOTARGET;
2146 }
2147
2148 void vehicles_enter (entity pl, entity veh);
2149 void PlayerUseKey(entity this)
2150 {
2151         if (!IS_PLAYER(this))
2152                 return;
2153
2154         if(this.vehicle)
2155         {
2156                 if(!gameover)
2157                 {
2158                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2159                         return;
2160                 }
2161         }
2162         else if(autocvar_g_vehicles_enter)
2163         {
2164                 if(!STAT(FROZEN, this))
2165                 if(!IS_DEAD(this))
2166                 if(!gameover)
2167                 {
2168                         entity head, closest_target = NULL;
2169                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2170
2171                         while(head) // find the closest acceptable target to enter
2172                         {
2173                                 if(IS_VEHICLE(head))
2174                                 if(!IS_DEAD(head))
2175                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2176                                 if(head.takedamage != DAMAGE_NO)
2177                                 {
2178                                         if(closest_target)
2179                                         {
2180                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2181                                                 { closest_target = head; }
2182                                         }
2183                                         else { closest_target = head; }
2184                                 }
2185
2186                                 head = head.chain;
2187                         }
2188
2189                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2190                 }
2191         }
2192
2193         // a use key was pressed; call handlers
2194         MUTATOR_CALLHOOK(PlayerUseKey, this);
2195 }
2196
2197
2198 /*
2199 =============
2200 PlayerPreThink
2201
2202 Called every frame for each client before the physics are run
2203 =============
2204 */
2205 .float usekeypressed;
2206 .float last_vehiclecheck;
2207 .int items_added;
2208 void PlayerPreThink (entity this)
2209 {
2210         WarpZone_PlayerPhysics_FixVAngle(this);
2211
2212     STAT(GAMESTARTTIME, this) = game_starttime;
2213         STAT(ROUNDSTARTTIME, this) = round_starttime;
2214         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2215         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2216
2217         STAT(WEAPONSINMAP, this) = weaponsInMap;
2218
2219         if (frametime) {
2220                 // physics frames: update anticheat stuff
2221                 anticheat_prethink(this);
2222         }
2223
2224         if (blockSpectators && frametime) {
2225                 // WORKAROUND: only use dropclient in server frames (frametime set).
2226                 // Never use it in cl_movement frames (frametime zero).
2227                 checkSpectatorBlock(this);
2228     }
2229
2230         zoomstate_set = false;
2231
2232         // Check for nameless players
2233         if (isInvisibleString(this.netname)) {
2234                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2235                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2236         }
2237         if (this.netname != this.netname_previous) {
2238                 if (autocvar_sv_eventlog) {
2239                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2240         }
2241                 if (this.netname_previous) strunzone(this.netname_previous);
2242                 this.netname_previous = strzone(this.netname);
2243         }
2244
2245         // version nagging
2246         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2247         this.version_nagtime = 0;
2248         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2249             // git client
2250         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2251             // git server
2252             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2253         } else {
2254             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2255             if (r < 0) { // old client
2256                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2257             } else if (r > 0) { // old server
2258                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2259             }
2260         }
2261     }
2262
2263         // GOD MODE info
2264         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2265         {
2266                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2267                 this.max_armorvalue = 0;
2268         }
2269
2270         if (STAT(FROZEN, this) == 2)
2271         {
2272                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2273                 this.health = max(1, this.revive_progress * start_health);
2274                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2275
2276                 if (this.revive_progress >= 1)
2277                         Unfreeze(this);
2278         }
2279         else if (STAT(FROZEN, this) == 3)
2280         {
2281                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2282                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2283
2284                 if (this.health < 1)
2285                 {
2286                         if (this.vehicle)
2287                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2288                         if(this.event_damage)
2289                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2290                 }
2291                 else if (this.revive_progress <= 0)
2292                         Unfreeze(this);
2293         }
2294
2295         MUTATOR_CALLHOOK(PlayerPreThink, this);
2296
2297         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2298         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2299         {
2300                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2301                 {
2302                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2303                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2304                         {
2305                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2306                         }
2307                         else if(!it.owner)
2308                         {
2309                                 if(!it.team || SAME_TEAM(this, it))
2310                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2311                                 else if(autocvar_g_vehicles_steal)
2312                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2313                         }
2314                 });
2315
2316                 this.last_vehiclecheck = time + 1;
2317         }
2318
2319         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2320         {
2321                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2322                         PlayerUseKey(this);
2323                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2324         }
2325
2326         if (IS_REAL_CLIENT(this))
2327                 PrintWelcomeMessage(this);
2328
2329         if (IS_PLAYER(this)) {
2330                 CheckRules_Player(this);
2331
2332                 if (gameover || intermission_running) {
2333                         if(intermission_running)
2334                                 IntermissionThink(this);
2335                         return;
2336                 }
2337
2338                 if (timeout_status == TIMEOUT_ACTIVE) {
2339             // don't allow the player to turn around while game is paused
2340                         // FIXME turn this into CSQC stuff
2341                         this.v_angle = this.lastV_angle;
2342                         this.angles = this.lastV_angle;
2343                         this.fixangle = true;
2344                 }
2345
2346                 if (frametime) player_powerups(this);
2347
2348                 if (IS_DEAD(this)) {
2349                         if (this.personal && g_race_qualifying) {
2350                                 if (time > this.respawn_time) {
2351                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2352                                         respawn(this);
2353                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2354                                 }
2355                         } else {
2356                                 if (frametime) player_anim(this);
2357                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2358
2359                                 switch(this.deadflag)
2360                                 {
2361                                         case DEAD_DYING:
2362                                         {
2363                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2364                                                         this.deadflag = DEAD_RESPAWNING;
2365                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2366                                                         this.deadflag = DEAD_DEAD;
2367                                                 break;
2368                                         }
2369                                         case DEAD_DEAD:
2370                                         {
2371                                                 if (button_pressed)
2372                                                         this.deadflag = DEAD_RESPAWNABLE;
2373                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2374                                                         this.deadflag = DEAD_RESPAWNING;
2375                                                 break;
2376                                         }
2377                                         case DEAD_RESPAWNABLE:
2378                                         {
2379                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2380                                                         this.deadflag = DEAD_RESPAWNING;
2381                                                 break;
2382                                         }
2383                                         case DEAD_RESPAWNING:
2384                                         {
2385                                                 if (time > this.respawn_time)
2386                                                 {
2387                                                         this.respawn_time = time + 1; // only retry once a second
2388                                                         this.respawn_time_max = this.respawn_time;
2389                                                         respawn(this);
2390                                                 }
2391                                                 break;
2392                                         }
2393                                 }
2394
2395                                 ShowRespawnCountdown(this);
2396
2397                                 if (this.respawn_flags & RESPAWN_SILENT)
2398                                         STAT(RESPAWN_TIME, this) = 0;
2399                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2400                                 {
2401                                         if (time < this.respawn_time)
2402                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2403                                         else if (this.deadflag != DEAD_RESPAWNING)
2404                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2405                                 }
2406                                 else
2407                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2408                         }
2409
2410                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2411                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2412                                 STAT(RESPAWN_TIME, this) *= -1;
2413
2414                         return;
2415                 }
2416
2417                 this.prevorigin = this.origin;
2418
2419                 bool have_hook = false;
2420                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2421                 {
2422                         .entity weaponentity = weaponentities[slot];
2423                         if(this.(weaponentity).hook.state)
2424                         {
2425                                 have_hook = true;
2426                                 break;
2427                         }
2428                 }
2429                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2430                 if (have_hook) {
2431                         do_crouch = false;
2432                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2433                         do_crouch = false;
2434                 } else if (this.vehicle) {
2435                         do_crouch = false;
2436                 } else if (STAT(FROZEN, this)) {
2437                         do_crouch = false;
2438         }
2439
2440                 if (do_crouch) {
2441                         if (!this.crouch) {
2442                                 this.crouch = true;
2443                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2444                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2445                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2446                         }
2447                 } else if (this.crouch) {
2448             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2449             if (!trace_startsolid) {
2450                 this.crouch = false;
2451                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2452                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2453             }
2454                 }
2455
2456                 FixPlayermodel(this);
2457
2458                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2459                 //if(frametime)
2460                 {
2461                         this.items &= ~this.items_added;
2462
2463                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2464                         {
2465                                 .entity weaponentity = weaponentities[slot];
2466                                 W_WeaponFrame(this, weaponentity);
2467
2468                                 if(slot == 0)
2469                                 {
2470                                         this.clip_load = this.(weaponentity).clip_load;
2471                                         this.clip_size = this.(weaponentity).clip_size;
2472                                 }
2473                         }
2474
2475                         this.items_added = 0;
2476                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2477                 this.items_added |= IT_FUEL;
2478
2479                         this.items |= this.items_added;
2480                 }
2481
2482                 player_regen(this);
2483
2484                 // WEAPONTODO: Add a weapon request for this
2485                 // rot vortex charge to the charge limit
2486                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2487                 {
2488                         .entity weaponentity = weaponentities[slot];
2489                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2490                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2491                 }
2492
2493                 if (frametime) player_anim(this);
2494
2495                 // secret status
2496                 secrets_setstatus(this);
2497
2498                 // monsters status
2499                 monsters_setstatus(this);
2500
2501                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2502         }
2503         else if (gameover || intermission_running) {
2504                 if(intermission_running)
2505                         IntermissionThink(this);
2506                 return;
2507         }
2508         else if (IS_OBSERVER(this)) {
2509                 ObserverThink(this);
2510         }
2511         else if (IS_SPEC(this)) {
2512                 SpectatorThink(this);
2513         }
2514
2515         // WEAPONTODO: Add weapon request for this
2516         if (!zoomstate_set) {
2517                 bool wep_zoomed = false;
2518                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2519                 {
2520                         .entity weaponentity = weaponentities[slot];
2521                         Weapon thiswep = this.(weaponentity).m_weapon;
2522                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2523                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2524                 }
2525                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2526     }
2527
2528         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2529         {
2530                 this.teamkill_soundtime = 0;
2531
2532                 entity e = this.teamkill_soundsource;
2533                 entity oldpusher = e.pusher;
2534                 e.pusher = this;
2535                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2536                 e.pusher = oldpusher;
2537         }
2538
2539         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2540                 this.taunt_soundtime = 0;
2541                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2542         }
2543
2544         target_voicescript_next(this);
2545
2546         // WEAPONTODO: Move into weaponsystem somehow
2547         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2548         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2549         {
2550                 .entity weaponentity = weaponentities[slot];
2551                 if(this.(weaponentity).m_weapon == WEP_Null)
2552                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2553         }
2554 }
2555
2556 void DrownPlayer(entity this)
2557 {
2558         if(IS_DEAD(this))
2559                 return;
2560
2561         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2562         {
2563                 if(this.air_finished < time)
2564                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2565                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2566                 this.dmg = 2;
2567         }
2568         else if (this.air_finished < time)
2569         {       // drown!
2570                 if (this.pain_finished < time)
2571                 {
2572                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2573                         this.pain_finished = time + 0.5;
2574                 }
2575         }
2576 }
2577
2578 .bool move_qcphysics;
2579
2580 void Player_Physics(entity this)
2581 {
2582         set_movetype(this, this.move_movetype);
2583
2584         if(!this.move_qcphysics)
2585                 return;
2586
2587         if(!frametime && !this.pm_frametime)
2588                 return;
2589
2590         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2591
2592         this.pm_frametime = 0;
2593 }
2594
2595 /*
2596 =============
2597 PlayerPostThink
2598
2599 Called every frame for each client after the physics are run
2600 =============
2601 */
2602 .float idlekick_lasttimeleft;
2603 void PlayerPostThink (entity this)
2604 {
2605         Player_Physics(this);
2606
2607         if (sv_maxidle > 0)
2608         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2609         if (IS_REAL_CLIENT(this))
2610         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2611         {
2612                 int totalClients = 0;
2613                 if(sv_maxidle_slots > 0)
2614                 {
2615                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2616                         {
2617                                 ++totalClients;
2618                         });
2619                 }
2620
2621                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2622                 { /* do nothing */ }
2623                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2624                 {
2625                         if (this.idlekick_lasttimeleft)
2626                         {
2627                                 this.idlekick_lasttimeleft = 0;
2628                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2629                         }
2630                 }
2631                 else
2632                 {
2633                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2634                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2635                                 if (!this.idlekick_lasttimeleft)
2636                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2637                         }
2638                         if (timeleft <= 0) {
2639                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2640                                 dropclient(this);
2641                                 return;
2642                         }
2643                         else if (timeleft <= 10) {
2644                                 if (timeleft != this.idlekick_lasttimeleft) {
2645                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2646                 }
2647                                 this.idlekick_lasttimeleft = timeleft;
2648                         }
2649                 }
2650         }
2651
2652         CheatFrame(this);
2653
2654         //CheckPlayerJump();
2655         if (gameover)
2656         {
2657                 this.solid = SOLID_NOT;
2658                 this.takedamage = DAMAGE_NO;
2659                 set_movetype(this, MOVETYPE_NONE);
2660         }
2661
2662         if (IS_PLAYER(this)) {
2663                 DrownPlayer(this);
2664                 CheckRules_Player(this);
2665                 UpdateChatBubble(this);
2666                 if (this.impulse) ImpulseCommands(this);
2667                 if (gameover)
2668                 {
2669                         CSQCMODEL_AUTOUPDATE(this);
2670                         return;
2671                 }
2672                 GetPressedKeys(this);
2673         }
2674
2675         if (this.waypointsprite_attachedforcarrier) {
2676             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2677                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2678     }
2679
2680         playerdemo_write(this);
2681
2682         CSQCMODEL_AUTOUPDATE(this);
2683 }