qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include "../common/wepent.qh"
  27 #include <common/state.qh>
  28
  29 #include <common/effects/qc/globalsound.qh>
  30
  31 #include "../common/triggers/func/conveyor.qh"
  32 #include "../common/triggers/teleporters.qh"
  33
  34 #include "../common/vehicles/all.qh"
  35
  36 #include "weapons/hitplot.qh"
  37 #include "weapons/weaponsystem.qh"
  38
  39 #include "../common/net_notice.qh"
  40 #include "../common/physics/player.qh"
  41
  42 #include "../common/items/_mod.qh"
  43
  44 #include "../common/mutators/mutator/waypoints/all.qh"
  45
  46 #include "../common/triggers/subs.qh"
  47 #include "../common/triggers/triggers.qh"
  48 #include "../common/triggers/trigger/secret.qh"
  49
  50 #include "../common/minigames/sv_minigames.qh"
  51
  52 #include "../common/items/inventory.qh"
  53
  54 #include "../common/monsters/sv_monsters.qh"
  55
  56 #include "../lib/warpzone/server.qh"
  57
  58 STATIC_METHOD(Client, Add, void(Client this, int _team))
  59 {
  60     ClientConnect(this);
  61     TRANSMUTE(Player, this);
  62     this.frame = 12; // 7
  63     this.team = _team;
  64     PutClientInServer(this);
  65 }
  66
  67 void PutObserverInServer(entity this);
  68
  69 STATIC_METHOD(Client, Remove, void(Client this))
  70 {
  71     TRANSMUTE(Observer, this);
  72     PutClientInServer(this);
  73     ClientDisconnect(this);
  74 }
  75
  76 void send_CSQC_teamnagger() {
  77         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  78 }
  79
  80 int CountSpectators(entity player, entity to)
  81 {
  82         if(!player) { return 0; } // not sure how, but best to be safe
  83
  84         int spec_count = 0;
  85
  86         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  87         {
  88                 spec_count++;
  89         });
  90
  91         return spec_count;
  92 }
  93
  94 void WriteSpectators(entity player, entity to)
  95 {
  96         if(!player) { return; } // not sure how, but best to be safe
  97
  98         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  99         {
 100                 WriteByte(MSG_ENTITY, num_for_edict(it));
 101         });
 102 }
 103
 104 bool ClientData_Send(entity this, entity to, int sf)
 105 {
 106         assert(to == this.owner, return false);
 107
 108         entity e = to;
 109         if (IS_SPEC(e)) e = e.enemy;
 110
 111         sf = 0;
 112         if (e.race_completed)       sf |= 1; // forced scoreboard
 113         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 114         if (e.zoomstate)            sf |= 4; // zoomed
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124
 125         if(sf & 16)
 126         {
 127                 float specs = CountSpectators(e, to);
 128                 WriteByte(MSG_ENTITY, specs);
 129                 WriteSpectators(e, to);
 130         }
 131
 132         return true;
 133 }
 134
 135 void ClientData_Attach(entity this)
 136 {
 137         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 138         this.clientdata.drawonlytoclient = this;
 139         this.clientdata.owner = this;
 140 }
 141
 142 void ClientData_Detach(entity this)
 143 {
 144         delete(this.clientdata);
 145         this.clientdata = NULL;
 146 }
 147
 148 void ClientData_Touch(entity e)
 149 {
 150         e.clientdata.SendFlags = 1;
 151
 152         // make it spectatable
 153         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 154 }
 155
 156 .string netname_previous;
 157
 158 void SetSpectatee(entity this, entity spectatee);
 159 void SetSpectatee_status(entity this, int spectatee_num);
 160
 161
 162 /*
 163 =============
 164 CheckPlayerModel
 165
 166 Checks if the argument string can be a valid playermodel.
 167 Returns a valid one in doubt.
 168 =============
 169 */
 170 string FallbackPlayerModel;
 171 string CheckPlayerModel(string plyermodel) {
 172         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 173         {
 174                 // note: we cannot summon Don Strunzone here, some player may
 175                 // still have the model string set. In case anyone manages how
 176                 // to change a cvar default, we'll have a small leak here.
 177                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 178         }
 179         // only in right path
 180         if( substring(plyermodel,0,14) != "models/player/")
 181                 return FallbackPlayerModel;
 182         // only good file extensions
 183         if(substring(plyermodel,-4,4) != ".zym")
 184         if(substring(plyermodel,-4,4) != ".dpm")
 185         if(substring(plyermodel,-4,4) != ".iqm")
 186         if(substring(plyermodel,-4,4) != ".md3")
 187         if(substring(plyermodel,-4,4) != ".psk")
 188                 return FallbackPlayerModel;
 189         // forbid the LOD models
 190         if(substring(plyermodel, -9,5) == "_lod1")
 191                 return FallbackPlayerModel;
 192         if(substring(plyermodel, -9,5) == "_lod2")
 193                 return FallbackPlayerModel;
 194         if(plyermodel != strtolower(plyermodel))
 195                 return FallbackPlayerModel;
 196         // also, restrict to server models
 197         if(autocvar_sv_servermodelsonly)
 198         {
 199                 if(!fexists(plyermodel))
 200                         return FallbackPlayerModel;
 201         }
 202         return plyermodel;
 203 }
 204
 205 void setplayermodel(entity e, string modelname)
 206 {
 207         precache_model(modelname);
 208         _setmodel(e, modelname);
 209         player_setupanimsformodel(e);
 210         if(!autocvar_g_debug_globalsounds)
 211                 UpdatePlayerSounds(e);
 212 }
 213
 214 void FixPlayermodel(entity player);
 215 /** putting a client as observer in the server */
 216 void PutObserverInServer(entity this)
 217 {
 218     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 219         PlayerState_detach(this);
 220
 221         if (IS_PLAYER(this) && this.health >= 1) {
 222         // despawn effect
 223                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 224     }
 225
 226     {
 227         entity spot = SelectSpawnPoint(this, true);
 228         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 229         this.angles = spot.angles;
 230         this.angles_z = 0;
 231         this.fixangle = true;
 232         // offset it so that the spectator spawns higher off the ground, looks better this way
 233         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 234         this.prevorigin = this.origin;
 235         if (IS_REAL_CLIENT(this))
 236         {
 237             msg_entity = this;
 238             WriteByte(MSG_ONE, SVC_SETVIEW);
 239             WriteEntity(MSG_ONE, this);
 240         }
 241         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 242         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 243         if(!autocvar_g_debug_globalsounds)
 244         {
 245                 // needed for player sounds
 246                 this.model = "";
 247                 FixPlayermodel(this);
 248         }
 249         setmodel(this, MDL_Null);
 250         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 251         this.view_ofs = '0 0 0';
 252     }
 253
 254     RemoveGrapplingHooks(this);
 255         Portal_ClearAll(this);
 256         Unfreeze(this);
 257         SetSpectatee(this, NULL);
 258
 259         if (this.alivetime)
 260         {
 261                 if (!warmup_stage)
 262                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 263                 this.alivetime = 0;
 264         }
 265
 266         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 267
 268         WaypointSprite_PlayerDead(this);
 269
 270         if (mutator_returnvalue) {
 271             // mutator prevents resetting teams+score
 272         } else {
 273                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 274         this.frags = FRAGS_SPECTATOR;
 275         PlayerScore_Clear(this);  // clear scores when needed
 276     }
 277
 278         if (this.killcount != FRAGS_SPECTATOR)
 279         {
 280                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 281                 if(!intermission_running)
 282                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 283                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 284
 285                 if(this.just_joined == false) {
 286                         LogTeamchange(this.playerid, -1, 4);
 287                 } else
 288                         this.just_joined = false;
 289         }
 290
 291         accuracy_resend(this);
 292
 293         this.spectatortime = time;
 294         if(this.bot_attack)
 295                 IL_REMOVE(g_bot_targets, this);
 296         this.bot_attack = false;
 297     this.hud = HUD_NORMAL;
 298         TRANSMUTE(Observer, this);
 299         this.iscreature = false;
 300         this.teleportable = TELEPORT_SIMPLE;
 301         this.damagedbycontents = false;
 302         this.health = FRAGS_SPECTATOR;
 303         SetSpectatee_status(this, etof(this));
 304         this.takedamage = DAMAGE_NO;
 305         this.solid = SOLID_NOT;
 306         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 307         this.flags = FL_CLIENT | FL_NOTARGET;
 308         this.armorvalue = 666;
 309         this.effects = 0;
 310         this.armorvalue = autocvar_g_balance_armor_start;
 311         this.pauserotarmor_finished = 0;
 312         this.pauserothealth_finished = 0;
 313         this.pauseregen_finished = 0;
 314         this.damageforcescale = 0;
 315         this.death_time = 0;
 316         this.respawn_flags = 0;
 317         this.respawn_time = 0;
 318         this.stat_respawn_time = 0;
 319         this.alpha = 0;
 320         this.scale = 0;
 321         this.fade_time = 0;
 322         this.pain_frame = 0;
 323         this.pain_finished = 0;
 324         this.strength_finished = 0;
 325         this.invincible_finished = 0;
 326         this.superweapons_finished = 0;
 327         this.pushltime = 0;
 328         this.istypefrag = 0;
 329         setthink(this, func_null);
 330         this.nextthink = 0;
 331         this.deadflag = DEAD_NO;
 332         this.crouch = false;
 333         this.revival_time = 0;
 334
 335         this.items = 0;
 336         this.weapons = '0 0 0';
 337         this.drawonlytoclient = this;
 338
 339         this.weaponmodel = "";
 340         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 341         {
 342                 this.weaponentities[slot].hook_time = 0;
 343                 this.weaponentities[slot].weaponname = "";
 344                 this.weaponentities[slot] = NULL;
 345         }
 346         this.exteriorweaponentity = NULL;
 347         this.killcount = FRAGS_SPECTATOR;
 348         this.velocity = '0 0 0';
 349         this.avelocity = '0 0 0';
 350         this.punchangle = '0 0 0';
 351         this.punchvector = '0 0 0';
 352         this.oldvelocity = this.velocity;
 353         this.fire_endtime = -1;
 354         this.event_damage = func_null;
 355 }
 356
 357 int player_getspecies(entity this)
 358 {
 359         get_model_parameters(this.model, this.skin);
 360         int s = get_model_parameters_species;
 361         get_model_parameters(string_null, 0);
 362         if (s < 0) return SPECIES_HUMAN;
 363         return s;
 364 }
 365
 366 .float model_randomizer;
 367 void FixPlayermodel(entity player)
 368 {
 369         string defaultmodel = "";
 370         int defaultskin = 0;
 371         if(autocvar_sv_defaultcharacter)
 372         {
 373                 if(teamplay)
 374                 {
 375                         string s = Static_Team_ColorName_Lower(player.team);
 376                         if (s != "neutral")
 377                         {
 378                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 379                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 380                         }
 381                 }
 382
 383                 if(defaultmodel == "")
 384                 {
 385                         defaultmodel = autocvar_sv_defaultplayermodel;
 386                         defaultskin = autocvar_sv_defaultplayerskin;
 387                 }
 388
 389                 int n = tokenize_console(defaultmodel);
 390                 if(n > 0)
 391                 {
 392                         defaultmodel = argv(floor(n * player.model_randomizer));
 393                         // However, do NOT randomize if the player-selected model is in the list.
 394                         for (int i = 0; i < n; ++i)
 395                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 396                                         defaultmodel = argv(i);
 397                 }
 398
 399                 int i = strstrofs(defaultmodel, ":", 0);
 400                 if(i >= 0)
 401                 {
 402                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 403                         defaultmodel = substring(defaultmodel, 0, i);
 404                 }
 405         }
 406         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 407         {
 408                 if(teamplay)
 409                 {
 410                         string s = Static_Team_ColorName_Lower(player.team);
 411                         if (s != "neutral")
 412                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 413                 }
 414
 415                 if(!defaultskin)
 416                         defaultskin = autocvar_sv_defaultplayerskin;
 417         }
 418
 419         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 420         defaultmodel = M_ARGV(0, string);
 421         defaultskin = M_ARGV(1, int);
 422
 423         bool chmdl = false;
 424         int oldskin;
 425         if(defaultmodel != "")
 426         {
 427                 if (defaultmodel != player.model)
 428                 {
 429                         vector m1 = player.mins;
 430                         vector m2 = player.maxs;
 431                         setplayermodel (player, defaultmodel);
 432                         setsize (player, m1, m2);
 433                         chmdl = true;
 434                 }
 435
 436                 oldskin = player.skin;
 437                 player.skin = defaultskin;
 438         } else {
 439                 if (player.playermodel != player.model || player.playermodel == "")
 440                 {
 441                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 442                         vector m1 = player.mins;
 443                         vector m2 = player.maxs;
 444                         setplayermodel (player, player.playermodel);
 445                         setsize (player, m1, m2);
 446                         chmdl = true;
 447                 }
 448
 449                 if(!autocvar_sv_defaultcharacterskin)
 450                 {
 451                         oldskin = player.skin;
 452                         player.skin = stof(player.playerskin);
 453                 }
 454                 else
 455                 {
 456                         oldskin = player.skin;
 457                         player.skin = defaultskin;
 458                 }
 459         }
 460
 461         if(chmdl || oldskin != player.skin) // model or skin has changed
 462         {
 463                 player.species = player_getspecies(player); // update species
 464                 if(!autocvar_g_debug_globalsounds)
 465                         UpdatePlayerSounds(player); // update skin sounds
 466         }
 467
 468         if(!teamplay)
 469                 if(strlen(autocvar_sv_defaultplayercolors))
 470                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 471                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 472 }
 473
 474
 475 /** Called when a client spawns in the server */
 476 void PutClientInServer(entity this)
 477 {
 478         if (IS_BOT_CLIENT(this)) {
 479                 TRANSMUTE(Player, this);
 480         } else if (IS_REAL_CLIENT(this)) {
 481                 msg_entity = this;
 482                 WriteByte(MSG_ONE, SVC_SETVIEW);
 483                 WriteEntity(MSG_ONE, this);
 484         }
 485         if (gameover) {
 486                 TRANSMUTE(Observer, this);
 487         }
 488
 489         SetSpectatee(this, NULL);
 490
 491         // reset player keys
 492         this.itemkeys = 0;
 493
 494         MUTATOR_CALLHOOK(PutClientInServer, this);
 495
 496         if (IS_OBSERVER(this)) {
 497                 PutObserverInServer(this);
 498         } else if (IS_PLAYER(this)) {
 499                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 500
 501                 PlayerState_attach(this);
 502                 accuracy_resend(this);
 503
 504                 if (this.team < 0)
 505                         JoinBestTeam(this, false, true);
 506
 507                 entity spot = SelectSpawnPoint(this, false);
 508                 if (!spot) {
 509                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 510                         return; // spawn failed
 511                 }
 512
 513                 TRANSMUTE(Player, this);
 514
 515                 this.wasplayer = true;
 516                 this.iscreature = true;
 517                 this.teleportable = TELEPORT_NORMAL;
 518                 this.damagedbycontents = true;
 519                 set_movetype(this, MOVETYPE_WALK);
 520                 this.solid = SOLID_SLIDEBOX;
 521                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 522                 if (autocvar_g_playerclip_collisions)
 523                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 524                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 525                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 526                 this.frags = FRAGS_PLAYER;
 527                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 528                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 529                 if (autocvar__notarget)
 530                         this.flags |= FL_NOTARGET;
 531                 this.takedamage = DAMAGE_AIM;
 532                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 533                 this.dmg = 2; // WTF
 534
 535                 if (warmup_stage) {
 536                         this.ammo_shells = warmup_start_ammo_shells;
 537                         this.ammo_nails = warmup_start_ammo_nails;
 538                         this.ammo_rockets = warmup_start_ammo_rockets;
 539                         this.ammo_cells = warmup_start_ammo_cells;
 540                         this.ammo_plasma = warmup_start_ammo_plasma;
 541                         this.ammo_fuel = warmup_start_ammo_fuel;
 542                         this.health = warmup_start_health;
 543                         this.armorvalue = warmup_start_armorvalue;
 544                         this.weapons = WARMUP_START_WEAPONS;
 545                 } else {
 546                         this.ammo_shells = start_ammo_shells;
 547                         this.ammo_nails = start_ammo_nails;
 548                         this.ammo_rockets = start_ammo_rockets;
 549                         this.ammo_cells = start_ammo_cells;
 550                         this.ammo_plasma = start_ammo_plasma;
 551                         this.ammo_fuel = start_ammo_fuel;
 552                         this.health = start_health;
 553                         this.armorvalue = start_armorvalue;
 554                         this.weapons = start_weapons;
 555                 }
 556                 SetSpectatee_status(this, 0);
 557
 558                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 559
 560                 this.items = start_items;
 561
 562                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 563                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 564                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 565                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 566                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 567                 // extend the pause of rotting if client was reset at the beginning of the countdown
 568                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 569                         float f = game_starttime - time;
 570                         this.spawnshieldtime += f;
 571                         this.pauserotarmor_finished += f;
 572                         this.pauserothealth_finished += f;
 573                         this.pauseregen_finished += f;
 574                 }
 575                 this.damageforcescale = 2;
 576                 this.death_time = 0;
 577                 this.respawn_flags = 0;
 578                 this.respawn_time = 0;
 579                 this.stat_respawn_time = 0;
 580                 this.scale = autocvar_sv_player_scale;
 581                 this.fade_time = 0;
 582                 this.pain_frame = 0;
 583                 this.pain_finished = 0;
 584                 this.pushltime = 0;
 585                 setthink(this, func_null); // players have no think function
 586                 this.nextthink = 0;
 587                 this.dmg_team = 0;
 588                 this.ballistics_density = autocvar_g_ballistics_density_player;
 589
 590                 this.deadflag = DEAD_NO;
 591
 592                 this.angles = spot.angles;
 593                 this.angles_z = 0; // never spawn tilted even if the spot says to
 594                 if (IS_BOT_CLIENT(this))
 595                         this.v_angle = this.angles;
 596                 this.fixangle = true; // turn this way immediately
 597                 this.oldvelocity = this.velocity = '0 0 0';
 598                 this.avelocity = '0 0 0';
 599                 this.punchangle = '0 0 0';
 600                 this.punchvector = '0 0 0';
 601
 602                 this.strength_finished = 0;
 603                 this.invincible_finished = 0;
 604                 this.fire_endtime = -1;
 605                 this.revival_time = 0;
 606                 this.air_finished = time + 12;
 607
 608                 entity spawnevent = new_pure(spawnevent);
 609                 spawnevent.owner = this;
 610                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 611
 612                 // Cut off any still running player sounds.
 613                 stopsound(this, CH_PLAYER_SINGLE);
 614
 615                 this.model = "";
 616                 FixPlayermodel(this);
 617                 this.drawonlytoclient = NULL;
 618
 619                 this.crouch = false;
 620                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 621                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 622                 this.spawnorigin = spot.origin;
 623                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 624                 // don't reset back to last position, even if new position is stuck in solid
 625                 this.oldorigin = this.origin;
 626                 this.prevorigin = this.origin;
 627                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 628                 if(this.conveyor)
 629                         IL_REMOVE(g_conveyed, this);
 630                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 631                 this.hud = HUD_NORMAL;
 632
 633                 this.event_damage = PlayerDamage;
 634
 635                 if(!this.bot_attack)
 636                         IL_PUSH(g_bot_targets, this);
 637                 this.bot_attack = true;
 638                 this.monster_attack = true;
 639
 640                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 641
 642                 if (this.killcount == FRAGS_SPECTATOR) {
 643                         PlayerScore_Clear(this);
 644                         this.killcount = 0;
 645                 }
 646
 647                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 648                 {
 649                         .entity weaponentity = weaponentities[slot];
 650                         CL_SpawnWeaponentity(this, weaponentity);
 651                 }
 652                 this.alpha = default_player_alpha;
 653                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 654                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 655
 656                 this.speedrunning = false;
 657
 658                 target_voicescript_clear(this);
 659
 660                 // reset fields the weapons may use
 661                 FOREACH(Weapons, true, LAMBDA(
 662                         it.wr_resetplayer(it, this);
 663                         // reload all reloadable weapons
 664                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 665                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 666                                 {
 667                                         .entity weaponentity = weaponentities[slot];
 668                                         this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 669                                 }
 670                         }
 671                 ));
 672
 673                 {
 674                         string s = spot.target;
 675                         spot.target = string_null;
 676                         SUB_UseTargets(spot, this, NULL);
 677                         spot.target = s;
 678                 }
 679
 680                 Unfreeze(this);
 681
 682                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 683
 684                 if (autocvar_spawn_debug)
 685                 {
 686                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 687                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 688                 }
 689
 690                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691                 {
 692                         .entity weaponentity = weaponentities[slot];
 693                         if(slot == 0)
 694                                 this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 695                         else
 696                                 this.(weaponentity).m_switchweapon = WEP_Null;
 697                         this.(weaponentity).m_weapon = WEP_Null;
 698                         this.(weaponentity).weaponname = "";
 699                         this.(weaponentity).m_switchingweapon = WEP_Null;
 700                         this.(weaponentity).cnt = -1;
 701                 }
 702
 703                 if (!warmup_stage && !this.alivetime)
 704                         this.alivetime = time;
 705
 706                 antilag_clear(this, CS(this));
 707         }
 708 }
 709
 710 void ClientInit_misc(entity this);
 711
 712 .float ebouncefactor, ebouncestop; // electro's values
 713 // TODO do we need all these fields, or should we stop autodetecting runtime
 714 // changes and just have a console command to update this?
 715 bool ClientInit_SendEntity(entity this, entity to, int sf)
 716 {
 717         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 718         return = true;
 719         msg_entity = to;
 720         // MSG_INIT replacement
 721         // TODO: make easier to use
 722         Registry_send_all();
 723         W_PROP_reload(MSG_ONE, to);
 724         ClientInit_misc(this);
 725         MUTATOR_CALLHOOK(Ent_Init);
 726 }
 727 void ClientInit_misc(entity this)
 728 {
 729         int channel = MSG_ONE;
 730         WriteHeader(channel, ENT_CLIENT_INIT);
 731         WriteByte(channel, g_nexball_meter_period * 32);
 732         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 733         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 734         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 735         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 736         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 737         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 738         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 739         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 740
 741         if(sv_foginterval && world.fog != "")
 742                 WriteString(channel, world.fog);
 743         else
 744                 WriteString(channel, "");
 745         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 746         WriteByte(channel, serverflags);
 747         WriteCoord(channel, autocvar_g_trueaim_minrange);
 748 }
 749
 750 void ClientInit_CheckUpdate(entity this)
 751 {
 752         this.nextthink = time;
 753         if(this.count != autocvar_g_balance_armor_blockpercent)
 754         {
 755                 this.count = autocvar_g_balance_armor_blockpercent;
 756                 this.SendFlags |= 1;
 757         }
 758 }
 759
 760 void ClientInit_Spawn()
 761 {
 762         entity e = new_pure(clientinit);
 763         setthink(e, ClientInit_CheckUpdate);
 764         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 765
 766         ClientInit_CheckUpdate(e);
 767 }
 768
 769 /*
 770 =============
 771 SetNewParms
 772 =============
 773 */
 774 void SetNewParms ()
 775 {
 776         // initialize parms for a new player
 777         parm1 = -(86400 * 366);
 778
 779         MUTATOR_CALLHOOK(SetNewParms);
 780 }
 781
 782 /*
 783 =============
 784 SetChangeParms
 785 =============
 786 */
 787 void SetChangeParms (entity this)
 788 {
 789         // save parms for level change
 790         parm1 = this.parm_idlesince - time;
 791
 792         MUTATOR_CALLHOOK(SetChangeParms);
 793 }
 794
 795 /*
 796 =============
 797 DecodeLevelParms
 798 =============
 799 */
 800 void DecodeLevelParms(entity this)
 801 {
 802         // load parms
 803         this.parm_idlesince = parm1;
 804         if (this.parm_idlesince == -(86400 * 366))
 805                 this.parm_idlesince = time;
 806
 807         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 808         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 809
 810         MUTATOR_CALLHOOK(DecodeLevelParms);
 811 }
 812
 813 /*
 814 =============
 815 ClientKill
 816
 817 Called when a client types 'kill' in the console
 818 =============
 819 */
 820
 821 .float clientkill_nexttime;
 822 void ClientKill_Now_TeamChange(entity this)
 823 {
 824         if(this.killindicator_teamchange == -1)
 825         {
 826                 JoinBestTeam( this, false, true );
 827         }
 828         else if(this.killindicator_teamchange == -2)
 829         {
 830                 if(blockSpectators)
 831                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 832                 PutObserverInServer(this);
 833         }
 834         else
 835                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 836         this.killindicator_teamchange = 0;
 837 }
 838
 839 void ClientKill_Now(entity this)
 840 {
 841         if(this.vehicle)
 842         {
 843             vehicles_exit(this.vehicle, VHEF_RELEASE);
 844             if(!this.killindicator_teamchange)
 845             {
 846             this.vehicle_health = -1;
 847             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 848             }
 849         }
 850
 851         if(this.killindicator && !wasfreed(this.killindicator))
 852                 delete(this.killindicator);
 853
 854         this.killindicator = NULL;
 855
 856         if(this.killindicator_teamchange)
 857                 ClientKill_Now_TeamChange(this);
 858
 859         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 860                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 861
 862         // now I am sure the player IS dead
 863 }
 864 void KillIndicator_Think(entity this)
 865 {
 866         if (gameover)
 867         {
 868                 this.owner.killindicator = NULL;
 869                 delete(this);
 870                 return;
 871         }
 872
 873         if (this.owner.alpha < 0 && !this.owner.vehicle)
 874         {
 875                 this.owner.killindicator = NULL;
 876                 delete(this);
 877                 return;
 878         }
 879
 880         if(this.cnt <= 0)
 881         {
 882                 ClientKill_Now(this.owner);
 883                 return;
 884         }
 885     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 886     {
 887         this.nextthink = time + 1;
 888         this.cnt -= 1;
 889     }
 890         else
 891         {
 892                 if(this.cnt <= 10)
 893                         setmodel(this, MDL_NUM(this.cnt));
 894                 if(IS_REAL_CLIENT(this.owner))
 895                 {
 896                         if(this.cnt <= 10)
 897                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 898                 }
 899                 this.nextthink = time + 1;
 900                 this.cnt -= 1;
 901         }
 902 }
 903
 904 float clientkilltime;
 905 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 906 {
 907         float killtime;
 908         float starttime;
 909
 910         if (gameover)
 911                 return;
 912
 913         killtime = autocvar_g_balance_kill_delay;
 914
 915         if(g_race_qualifying || g_cts)
 916                 killtime = 0;
 917
 918     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 919         return;
 920
 921         this.killindicator_teamchange = targetteam;
 922
 923     if(!this.killindicator)
 924         {
 925                 if(!IS_DEAD(this))
 926                 {
 927                         killtime = max(killtime, this.clientkill_nexttime - time);
 928                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 929                 }
 930
 931                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 932                 {
 933                         ClientKill_Now(this);
 934                 }
 935                 else
 936                 {
 937                         starttime = max(time, clientkilltime);
 938
 939                         this.killindicator = spawn();
 940                         this.killindicator.owner = this;
 941                         this.killindicator.scale = 0.5;
 942                         setattachment(this.killindicator, this, "");
 943                         setorigin(this.killindicator, '0 0 52');
 944                         setthink(this.killindicator, KillIndicator_Think);
 945                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 946                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 947                         this.killindicator.cnt = ceil(killtime);
 948                         this.killindicator.count = bound(0, ceil(killtime), 10);
 949                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 950
 951                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 952                         {
 953                                 it.killindicator = spawn();
 954                                 it.killindicator.owner = it;
 955                                 it.killindicator.scale = 0.5;
 956                                 setattachment(it.killindicator, it, "");
 957                                 setorigin(it.killindicator, '0 0 52');
 958                                 setthink(it.killindicator, KillIndicator_Think);
 959                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 960                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 961                                 it.killindicator.cnt = ceil(killtime);
 962                         });
 963                         this.lip = 0;
 964                 }
 965         }
 966         if(this.killindicator)
 967         {
 968                 if(targetteam == 0) // just die
 969                 {
 970                         this.killindicator.colormod = '0 0 0';
 971                         if(IS_REAL_CLIENT(this))
 972                         if(this.killindicator.cnt > 0)
 973                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 974                 }
 975                 else if(targetteam == -1) // auto
 976                 {
 977                         this.killindicator.colormod = '0 1 0';
 978                         if(IS_REAL_CLIENT(this))
 979                         if(this.killindicator.cnt > 0)
 980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 981                 }
 982                 else if(targetteam == -2) // spectate
 983                 {
 984                         this.killindicator.colormod = '0.5 0.5 0.5';
 985                         if(IS_REAL_CLIENT(this))
 986                         if(this.killindicator.cnt > 0)
 987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 988                 }
 989                 else
 990                 {
 991                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 992                         if(IS_REAL_CLIENT(this))
 993                         if(this.killindicator.cnt > 0)
 994                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 995                 }
 996         }
 997
 998 }
 999
1000 void ClientKill (entity this)
1001 {
1002         if(gameover) return;
1003         if(this.player_blocked) return;
1004         if(STAT(FROZEN, this)) return;
1005
1006         ClientKill_TeamChange(this, 0);
1007 }
1008
1009 void FixClientCvars(entity e)
1010 {
1011         // send prediction settings to the client
1012         stuffcmd(e, "\nin_bindmap 0 0\n");
1013         if(autocvar_g_antilag == 3) // client side hitscan
1014                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1015         if(autocvar_sv_gentle)
1016                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1017
1018         MUTATOR_CALLHOOK(FixClientCvars, e);
1019 }
1020
1021 float PlayerInIDList(entity p, string idlist)
1022 {
1023         float n, i;
1024         string s;
1025
1026         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1027         if (!p.crypto_idfp)
1028                 return 0;
1029
1030         // this function allows abbreviated player IDs too!
1031         n = tokenize_console(idlist);
1032         for(i = 0; i < n; ++i)
1033         {
1034                 s = argv(i);
1035                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1036                         return 1;
1037         }
1038
1039         return 0;
1040 }
1041
1042 #ifdef DP_EXT_PRECONNECT
1043 /*
1044 =============
1045 ClientPreConnect
1046
1047 Called once (not at each match start) when a client begins a connection to the server
1048 =============
1049 */
1050 void ClientPreConnect ()
1051 {ENGINE_EVENT();
1052         if(autocvar_sv_eventlog)
1053         {
1054                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1055                         this.playerid,
1056                         etof(this),
1057                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1058                 ));
1059         }
1060 }
1061 #endif
1062
1063 /**
1064 =============
1065 ClientConnect
1066
1067 Called when a client connects to the server
1068 =============
1069 */
1070 void ClientConnect(entity this)
1071 {
1072         if (Ban_MaybeEnforceBanOnce(this)) return;
1073         assert(!IS_CLIENT(this), return);
1074         this.flags |= FL_CLIENT;
1075         assert(player_count >= 0, player_count = 0);
1076
1077 #ifdef WATERMARK
1078         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1079 #endif
1080         this.version_nagtime = time + 10 + random() * 10;
1081         TRANSMUTE(Client, this);
1082
1083         // identify the right forced team
1084         if (autocvar_g_campaign)
1085         {
1086                 if (IS_REAL_CLIENT(this)) // only players, not bots
1087                 {
1088                         switch (autocvar_g_campaign_forceteam)
1089                         {
1090                                 case 1: this.team_forced = NUM_TEAM_1; break;
1091                                 case 2: this.team_forced = NUM_TEAM_2; break;
1092                                 case 3: this.team_forced = NUM_TEAM_3; break;
1093                                 case 4: this.team_forced = NUM_TEAM_4; break;
1094                                 default: this.team_forced = 0;
1095                         }
1096                 }
1097         }
1098         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1099         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1100         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1101         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1102         else switch (autocvar_g_forced_team_otherwise)
1103         {
1104                 default: this.team_forced = 0; break;
1105                 case "red": this.team_forced = NUM_TEAM_1; break;
1106                 case "blue": this.team_forced = NUM_TEAM_2; break;
1107                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1108                 case "pink": this.team_forced = NUM_TEAM_4; break;
1109                 case "spectate":
1110                 case "spectator":
1111                         this.team_forced = -1;
1112                         break;
1113         }
1114         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1115
1116     {
1117         int id = this.playerid;
1118         this.playerid = 0; // silent
1119             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1120             this.playerid = id;
1121     }
1122
1123         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1124                 TRANSMUTE(Observer, this);
1125         } else {
1126                 if (!teamplay || autocvar_g_balance_teams) {
1127                         TRANSMUTE(Player, this);
1128                         campaign_bots_may_start = true;
1129                 } else {
1130                         TRANSMUTE(Observer, this); // do it anyway
1131                 }
1132         }
1133
1134         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1135
1136         // always track bots, don't ask for cl_allow_uidtracking
1137     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1138
1139         if (autocvar_sv_eventlog)
1140                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1141
1142         LogTeamchange(this.playerid, this.team, 1);
1143
1144         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1145
1146         this.netname_previous = strzone(this.netname);
1147
1148         if(teamplay && IS_PLAYER(this))
1149                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1150         else
1151                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1152
1153         stuffcmd(this, clientstuff, "\n");
1154         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1155
1156         FixClientCvars(this);
1157
1158         // get version info from player
1159         stuffcmd(this, "cmd clientversion $gameversion\n");
1160
1161         // notify about available teams
1162         if (teamplay)
1163         {
1164                 CheckAllowedTeams(this);
1165                 int t = 0;
1166                 if (c1 >= 0) t |= BIT(0);
1167                 if (c2 >= 0) t |= BIT(1);
1168                 if (c3 >= 0) t |= BIT(2);
1169                 if (c4 >= 0) t |= BIT(3);
1170                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1171         }
1172         else
1173         {
1174                 stuffcmd(this, "set _teams_available 0\n");
1175         }
1176
1177         bot_relinkplayerlist();
1178
1179         this.spectatortime = time;
1180         if (blockSpectators)
1181         {
1182                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1183         }
1184
1185         this.jointime = time;
1186         this.allowed_timeouts = autocvar_sv_timeout_number;
1187
1188         if (IS_REAL_CLIENT(this))
1189         {
1190                 if (!autocvar_g_campaign)
1191                 {
1192                         this.motd_actived_time = -1;
1193                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1194                 }
1195
1196                 if (g_weaponarena_weapons == WEPSET(TUBA))
1197                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1198         }
1199
1200         if (!sv_foginterval && world.fog != "")
1201                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1202
1203         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1204                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1205                         send_CSQC_teamnagger();
1206
1207         CSQCMODEL_AUTOINIT(this);
1208
1209         this.model_randomizer = random();
1210
1211         if (IS_REAL_CLIENT(this))
1212                 sv_notice_join(this);
1213
1214         IL_EACH(g_initforplayer, it.init_for_player, {
1215                 it.init_for_player(it, this);
1216         });
1217
1218         MUTATOR_CALLHOOK(ClientConnect, this);
1219 }
1220 /*
1221 =============
1222 ClientDisconnect
1223
1224 Called when a client disconnects from the server
1225 =============
1226 */
1227 .entity chatbubbleentity;
1228 void ReadyCount();
1229 void ClientDisconnect(entity this)
1230 {
1231         assert(IS_CLIENT(this), return);
1232
1233         PlayerStats_GameReport_FinalizePlayer(this);
1234         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1235         if (this.active_minigame) part_minigame(this);
1236         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1237
1238         if (autocvar_sv_eventlog)
1239                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1240
1241         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1242
1243         SetSpectatee(this, NULL);
1244
1245     MUTATOR_CALLHOOK(ClientDisconnect, this);
1246
1247         ClientState_detach(this);
1248
1249         Portal_ClearAll(this);
1250
1251         Unfreeze(this);
1252
1253         RemoveGrapplingHooks(this);
1254
1255         // Here, everything has been done that requires this player to be a client.
1256
1257         this.flags &= ~FL_CLIENT;
1258
1259         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1260         if (this.killindicator) delete(this.killindicator);
1261
1262         WaypointSprite_PlayerGone(this);
1263
1264         bot_relinkplayerlist();
1265
1266         if (this.netname_previous) strunzone(this.netname_previous);
1267         if (this.clientstatus) strunzone(this.clientstatus);
1268         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1269         if (this.personal) delete(this.personal);
1270
1271         this.playerid = 0;
1272         ReadyCount();
1273         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1274 }
1275
1276 void ChatBubbleThink(entity this)
1277 {
1278         this.nextthink = time;
1279         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1280         {
1281                 if(this.owner) // but why can that ever be NULL?
1282                         this.owner.chatbubbleentity = NULL;
1283                 delete(this);
1284                 return;
1285         }
1286
1287         this.mdl = "";
1288
1289         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1290         {
1291                 if ( this.owner.active_minigame )
1292                         this.mdl = "models/sprites/minigame_busy.iqm";
1293                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1294                         this.mdl = "models/misc/chatbubble.spr";
1295         }
1296
1297         if ( this.model != this.mdl )
1298                 _setmodel(this, this.mdl);
1299
1300 }
1301
1302 void UpdateChatBubble(entity this)
1303 {
1304         if (this.alpha < 0)
1305                 return;
1306         // spawn a chatbubble entity if needed
1307         if (!this.chatbubbleentity)
1308         {
1309                 this.chatbubbleentity = new(chatbubbleentity);
1310                 this.chatbubbleentity.owner = this;
1311                 this.chatbubbleentity.exteriormodeltoclient = this;
1312                 setthink(this.chatbubbleentity, ChatBubbleThink);
1313                 this.chatbubbleentity.nextthink = time;
1314                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1315                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1316                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1317                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1318                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1319                 //this.chatbubbleentity.model = "";
1320                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1321         }
1322 }
1323
1324
1325 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1326 // added to the model skins
1327 /*void UpdateColorModHack()
1328 {
1329         float c;
1330         c = this.clientcolors & 15;
1331         // LordHavoc: only bothering to support white, green, red, yellow, blue
1332              if (!teamplay) this.colormod = '0 0 0';
1333         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1334         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1335         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1336         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1337         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1338         else this.colormod = '1 1 1';
1339 }*/
1340
1341 void respawn(entity this)
1342 {
1343         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1344         {
1345                 this.solid = SOLID_NOT;
1346                 this.takedamage = DAMAGE_NO;
1347                 set_movetype(this, MOVETYPE_FLY);
1348                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1349                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1350                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1351                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1352                 if(autocvar_g_respawn_ghosts_maxtime)
1353                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1354         }
1355
1356         CopyBody(this, 1);
1357
1358         this.effects |= EF_NODRAW; // prevent another CopyBody
1359         PutClientInServer(this);
1360 }
1361
1362 void play_countdown(entity this, float finished, Sound samp)
1363 {
1364     TC(Sound, samp);
1365         if(IS_REAL_CLIENT(this))
1366                 if(floor(finished - time - frametime) != floor(finished - time))
1367                         if(finished - time < 6)
1368                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1369 }
1370
1371 void player_powerups(entity this)
1372 {
1373         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1374         int items_prev = this.items;
1375
1376         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1377                 this.modelflags |= MF_ROCKET;
1378         else
1379                 this.modelflags &= ~MF_ROCKET;
1380
1381         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1382
1383         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1384                 return;
1385
1386         Fire_ApplyDamage(this);
1387         Fire_ApplyEffect(this);
1388
1389         if (!g_instagib)
1390         {
1391                 if (this.items & ITEM_Strength.m_itemid)
1392                 {
1393                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1394                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1395                         if (time > this.strength_finished)
1396                         {
1397                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1398                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1399                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1400                         }
1401                 }
1402                 else
1403                 {
1404                         if (time < this.strength_finished)
1405                         {
1406                                 this.items = this.items | ITEM_Strength.m_itemid;
1407                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1408                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1409                         }
1410                 }
1411                 if (this.items & ITEM_Shield.m_itemid)
1412                 {
1413                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1414                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1415                         if (time > this.invincible_finished)
1416                         {
1417                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1418                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1419                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1420                         }
1421                 }
1422                 else
1423                 {
1424                         if (time < this.invincible_finished)
1425                         {
1426                                 this.items = this.items | ITEM_Shield.m_itemid;
1427                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1428                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1429                         }
1430                 }
1431                 if (this.items & IT_SUPERWEAPON)
1432                 {
1433                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1434                         {
1435                                 this.superweapons_finished = 0;
1436                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1437                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1438                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1439                         }
1440                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1441                         {
1442                                 // don't let them run out
1443                         }
1444                         else
1445                         {
1446                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1447                                 if (time > this.superweapons_finished)
1448                                 {
1449                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1450                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1451                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1452                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1453                                 }
1454                         }
1455                 }
1456                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1457                 {
1458                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1459                         {
1460                                 this.items = this.items | IT_SUPERWEAPON;
1461                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1462                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1463                         }
1464                         else
1465                         {
1466                                 this.superweapons_finished = 0;
1467                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1468                         }
1469                 }
1470                 else
1471                 {
1472                         this.superweapons_finished = 0;
1473                 }
1474         }
1475
1476         if(autocvar_g_nodepthtestplayers)
1477                 this.effects = this.effects | EF_NODEPTHTEST;
1478
1479         if(autocvar_g_fullbrightplayers)
1480                 this.effects = this.effects | EF_FULLBRIGHT;
1481
1482         if (time >= game_starttime)
1483         if (time < this.spawnshieldtime)
1484                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1485
1486         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1487 }
1488
1489 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1490 {
1491         if(current > stable)
1492                 return current;
1493         else if(current > stable - 0.25) // when close enough, "snap"
1494                 return stable;
1495         else
1496                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1497 }
1498
1499 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1500 {
1501         if(current < stable)
1502                 return current;
1503         else if(current < stable + 0.25) // when close enough, "snap"
1504                 return stable;
1505         else
1506                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1507 }
1508
1509 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1510 {
1511         if(current > rotstable)
1512         {
1513                 if(rotframetime > 0)
1514                 {
1515                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1516                         current = max(rotstable, current - rotlinear * rotframetime);
1517                 }
1518         }
1519         else if(current < regenstable)
1520         {
1521                 if(regenframetime > 0)
1522                 {
1523                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1524                         current = min(regenstable, current + regenlinear * regenframetime);
1525                 }
1526         }
1527
1528         if(current > limit)
1529                 current = limit;
1530
1531         return current;
1532 }
1533
1534 void player_regen(entity this)
1535 {
1536         float max_mod, regen_mod, rot_mod, limit_mod;
1537         max_mod = regen_mod = rot_mod = limit_mod = 1;
1538
1539         float regen_health = autocvar_g_balance_health_regen;
1540         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1541         float regen_health_rot = autocvar_g_balance_health_rot;
1542         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1543         float regen_health_stable = autocvar_g_balance_health_regenstable;
1544         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1545         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1546                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1547         max_mod = M_ARGV(1, float);
1548         regen_mod = M_ARGV(2, float);
1549         rot_mod = M_ARGV(3, float);
1550         limit_mod = M_ARGV(4, float);
1551         regen_health = M_ARGV(5, float);
1552         regen_health_linear = M_ARGV(6, float);
1553         regen_health_rot = M_ARGV(7, float);
1554         regen_health_rotlinear = M_ARGV(8, float);
1555         regen_health_stable = M_ARGV(9, float);
1556         regen_health_rotstable = M_ARGV(10, float);
1557
1558
1559         if(!mutator_returnvalue)
1560         if(!STAT(FROZEN, this))
1561         {
1562                 float mina, maxa, limith, limita;
1563                 maxa = autocvar_g_balance_armor_rotstable;
1564                 mina = autocvar_g_balance_armor_regenstable;
1565                 limith = autocvar_g_balance_health_limit;
1566                 limita = autocvar_g_balance_armor_limit;
1567
1568                 regen_health_rotstable = regen_health_rotstable * max_mod;
1569                 regen_health_stable = regen_health_stable * max_mod;
1570                 limith = limith * limit_mod;
1571                 limita = limita * limit_mod;
1572
1573                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1574                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1575         }
1576
1577         // if player rotted to death...  die!
1578         // check this outside above checks, as player may still be able to rot to death
1579         if(this.health < 1)
1580         {
1581                 if(this.vehicle)
1582                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1583                 if(this.event_damage)
1584                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1585         }
1586
1587         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1588         {
1589                 float minf, maxf, limitf;
1590
1591                 maxf = autocvar_g_balance_fuel_rotstable;
1592                 minf = autocvar_g_balance_fuel_regenstable;
1593                 limitf = autocvar_g_balance_fuel_limit;
1594
1595                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1596         }
1597 }
1598
1599 bool zoomstate_set;
1600 void SetZoomState(entity this, float z)
1601 {
1602         if(z != this.zoomstate)
1603         {
1604                 this.zoomstate = z;
1605                 ClientData_Touch(this);
1606         }
1607         zoomstate_set = true;
1608 }
1609
1610 void GetPressedKeys(entity this)
1611 {
1612         MUTATOR_CALLHOOK(GetPressedKeys, this);
1613         int keys = this.pressedkeys;
1614         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1615         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1616         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1617         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1618
1619         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1620         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1621         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1622         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1623         this.pressedkeys = keys;
1624 }
1625
1626 /*
1627 ======================
1628 spectate mode routines
1629 ======================
1630 */
1631
1632 void SpectateCopy(entity this, entity spectatee)
1633 {
1634     TC(Client, this); TC(Client, spectatee);
1635
1636         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1637         PS(this) = PS(spectatee);
1638         this.armortype = spectatee.armortype;
1639         this.armorvalue = spectatee.armorvalue;
1640         this.ammo_cells = spectatee.ammo_cells;
1641         this.ammo_plasma = spectatee.ammo_plasma;
1642         this.ammo_shells = spectatee.ammo_shells;
1643         this.ammo_nails = spectatee.ammo_nails;
1644         this.ammo_rockets = spectatee.ammo_rockets;
1645         this.ammo_fuel = spectatee.ammo_fuel;
1646         this.clip_load = spectatee.clip_load;
1647         this.clip_size = spectatee.clip_size;
1648         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1649         this.health = spectatee.health;
1650         this.impulse = 0;
1651         this.items = spectatee.items;
1652         this.last_pickup = spectatee.last_pickup;
1653         this.hit_time = spectatee.hit_time;
1654         this.strength_finished = spectatee.strength_finished;
1655         this.invincible_finished = spectatee.invincible_finished;
1656         this.pressedkeys = spectatee.pressedkeys;
1657         this.weapons = spectatee.weapons;
1658         this.vortex_charge = spectatee.vortex_charge;
1659         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1660         this.hagar_load = spectatee.hagar_load;
1661         this.arc_heat_percent = spectatee.arc_heat_percent;
1662         this.minelayer_mines = spectatee.minelayer_mines;
1663         this.punchangle = spectatee.punchangle;
1664         this.view_ofs = spectatee.view_ofs;
1665         this.velocity = spectatee.velocity;
1666         this.dmg_take = spectatee.dmg_take;
1667         this.dmg_save = spectatee.dmg_save;
1668         this.dmg_inflictor = spectatee.dmg_inflictor;
1669         this.v_angle = spectatee.v_angle;
1670         this.angles = spectatee.v_angle;
1671         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1672         this.revive_progress = spectatee.revive_progress;
1673         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1674                 this.fixangle = true;
1675         setorigin(this, spectatee.origin);
1676         setsize(this, spectatee.mins, spectatee.maxs);
1677         SetZoomState(this, spectatee.zoomstate);
1678
1679     anticheat_spectatecopy(this, spectatee);
1680         this.hud = spectatee.hud;
1681         if(spectatee.vehicle)
1682     {
1683         this.angles = spectatee.v_angle;
1684
1685         //this.fixangle = false;
1686         //this.velocity = spectatee.vehicle.velocity;
1687         this.vehicle_health = spectatee.vehicle_health;
1688         this.vehicle_shield = spectatee.vehicle_shield;
1689         this.vehicle_energy = spectatee.vehicle_energy;
1690         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1691         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1692         this.vehicle_reload1 = spectatee.vehicle_reload1;
1693         this.vehicle_reload2 = spectatee.vehicle_reload2;
1694
1695         //msg_entity = this;
1696
1697        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1698             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1699            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1700            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1701
1702         //WriteByte (MSG_ONE, SVC_SETVIEW);
1703         //    WriteEntity(MSG_ONE, this);
1704         //makevectors(spectatee.v_angle);
1705         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1706     }
1707 }
1708
1709 bool SpectateUpdate(entity this)
1710 {
1711         if(!this.enemy)
1712                 return false;
1713
1714         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1715         {
1716                 SetSpectatee(this, NULL);
1717                 return false;
1718         }
1719
1720         SpectateCopy(this, this.enemy);
1721
1722         return true;
1723 }
1724
1725 bool SpectateSet(entity this)
1726 {
1727         if(!IS_PLAYER(this.enemy))
1728                 return false;
1729
1730         ClientData_Touch(this.enemy);
1731
1732         msg_entity = this;
1733         WriteByte(MSG_ONE, SVC_SETVIEW);
1734         WriteEntity(MSG_ONE, this.enemy);
1735         set_movetype(this, MOVETYPE_NONE);
1736         accuracy_resend(this);
1737
1738         if(!SpectateUpdate(this))
1739                 PutObserverInServer(this);
1740
1741         return true;
1742 }
1743
1744 void SetSpectatee_status(entity this, int spectatee_num)
1745 {
1746         int oldspectatee_status = this.spectatee_status;
1747         this.spectatee_status = spectatee_num;
1748
1749         if (this.spectatee_status != oldspectatee_status)
1750         {
1751                 ClientData_Touch(this);
1752                 if (g_race || g_cts) race_InitSpectator();
1753         }
1754 }
1755
1756 void SetSpectatee(entity this, entity spectatee)
1757 {
1758         entity old_spectatee = this.enemy;
1759
1760         this.enemy = spectatee;
1761
1762         // WEAPONTODO
1763         // these are required to fix the spectator bug with arc
1764         if(old_spectatee)
1765         {
1766                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1767                 {
1768                         .entity weaponentity = weaponentities[slot];
1769                         if(old_spectatee.(weaponentity).arc_beam)
1770                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1771                 }
1772         }
1773         if(this.enemy)
1774         {
1775                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1776                 {
1777                         .entity weaponentity = weaponentities[slot];
1778                         if(this.enemy.(weaponentity).arc_beam)
1779                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1780                 }
1781         }
1782
1783         if (this.enemy)
1784                 SetSpectatee_status(this, etof(this.enemy));
1785
1786         // needed to update spectator list
1787         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1788 }
1789
1790 bool Spectate(entity this, entity pl)
1791 {
1792         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1793                 return false;
1794         pl = M_ARGV(1, entity);
1795
1796         SetSpectatee(this, pl);
1797         return SpectateSet(this);
1798 }
1799
1800 bool SpectateNext(entity this)
1801 {
1802         entity ent = find(this.enemy, classname, STR_PLAYER);
1803
1804         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1805                 ent = M_ARGV(1, entity);
1806         else if (!ent)
1807                 ent = find(ent, classname, STR_PLAYER);
1808
1809         if(ent) { SetSpectatee(this, ent); }
1810
1811         return SpectateSet(this);
1812 }
1813
1814 bool SpectatePrev(entity this)
1815 {
1816         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1817         entity ent = findchain(classname, STR_PLAYER);
1818         if (!ent) // no player
1819                 return false;
1820
1821         entity first = ent;
1822         // skip players until current spectated player
1823         if(this.enemy)
1824         while(ent && ent != this.enemy)
1825                 ent = ent.chain;
1826
1827         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1828         {
1829                 case MUT_SPECPREV_FOUND:
1830                     ent = M_ARGV(1, entity);
1831                     break;
1832                 case MUT_SPECPREV_RETURN:
1833                     return true;
1834                 case MUT_SPECPREV_CONTINUE:
1835                 default:
1836                 {
1837                         if(ent.chain)
1838                                 ent = ent.chain;
1839                         else
1840                                 ent = first;
1841                         break;
1842                 }
1843         }
1844
1845         SetSpectatee(this, ent);
1846         return SpectateSet(this);
1847 }
1848
1849 /*
1850 =============
1851 ShowRespawnCountdown()
1852
1853 Update a respawn countdown display.
1854 =============
1855 */
1856 void ShowRespawnCountdown(entity this)
1857 {
1858         float number;
1859         if(!IS_DEAD(this)) // just respawned?
1860                 return;
1861         else
1862         {
1863                 number = ceil(this.respawn_time - time);
1864                 if(number <= 0)
1865                         return;
1866                 if(number <= this.respawn_countdown)
1867                 {
1868                         this.respawn_countdown = number - 1;
1869                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1870                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1871                 }
1872         }
1873 }
1874
1875 .bool team_selected;
1876 bool ShowTeamSelection(entity this)
1877 {
1878         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1879                 return false;
1880         stuffcmd(this, "menu_showteamselect\n");
1881         return true;
1882 }
1883 void Join(entity this)
1884 {
1885         TRANSMUTE(Player, this);
1886
1887         if(!this.team_selected)
1888         if(autocvar_g_campaign || autocvar_g_balance_teams)
1889                 JoinBestTeam(this, false, true);
1890
1891         if(autocvar_g_campaign)
1892                 campaign_bots_may_start = true;
1893
1894         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1895
1896         PutClientInServer(this);
1897
1898         if(teamplay && this.team != -1)
1899                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
1900         else
1901                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
1902         this.team_selected = false;
1903 }
1904
1905 /**
1906  * Determines whether the player is allowed to join. This depends on cvar
1907  * g_maxplayers, if it isn't used this function always return true, otherwise
1908  * it checks whether the number of currently playing players exceeds g_maxplayers.
1909  * @return int number of free slots for players, 0 if none
1910  */
1911 int nJoinAllowed(entity this, entity ignore)
1912 {
1913         if(!ignore)
1914         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1915         // so report 0 free slots if restricted
1916         {
1917                 if(autocvar_g_forced_team_otherwise == "spectate")
1918                         return 0;
1919                 if(autocvar_g_forced_team_otherwise == "spectator")
1920                         return 0;
1921         }
1922
1923         if(this && this.team_forced < 0)
1924                 return 0; // forced spectators can never join
1925
1926         // TODO simplify this
1927         int totalClients = 0;
1928         int currentlyPlaying = 0;
1929         FOREACH_CLIENT(true, LAMBDA(
1930                 if(it != ignore)
1931                         ++totalClients;
1932                 if(IS_REAL_CLIENT(it))
1933                 if(IS_PLAYER(it) || it.caplayer)
1934                         ++currentlyPlaying;
1935         ));
1936
1937         float free_slots = 0;
1938         if (!autocvar_g_maxplayers)
1939                 free_slots = maxclients - totalClients;
1940         else if(currentlyPlaying < autocvar_g_maxplayers)
1941                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1942
1943         static float join_prevent_msg_time = 0;
1944         if(this && ignore && !free_slots && time > join_prevent_msg_time)
1945         {
1946                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1947                 join_prevent_msg_time = time + 3;
1948         }
1949
1950         return free_slots;
1951 }
1952
1953 /**
1954  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1955  * g_maxplayers_spectator_blocktime seconds
1956  */
1957 void checkSpectatorBlock(entity this)
1958 {
1959         if(IS_SPEC(this) || IS_OBSERVER(this))
1960         if(!this.caplayer)
1961         if(IS_REAL_CLIENT(this))
1962         {
1963                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1964                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1965                         dropclient(this);
1966                 }
1967         }
1968 }
1969
1970 void PrintWelcomeMessage(entity this)
1971 {
1972         if(this.motd_actived_time == 0)
1973         {
1974                 if (autocvar_g_campaign) {
1975                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1976                                 this.motd_actived_time = time;
1977                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1978                         }
1979                 } else {
1980                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1981                                 this.motd_actived_time = time;
1982                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1983                         }
1984                 }
1985         }
1986         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1987         {
1988                 if (autocvar_g_campaign) {
1989                         if (PHYS_INPUT_BUTTON_INFO(this))
1990                                 this.motd_actived_time = time;
1991                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1992                                 this.motd_actived_time = 0;
1993                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1994                         }
1995                 } else {
1996                         if (PHYS_INPUT_BUTTON_INFO(this))
1997                                 this.motd_actived_time = time;
1998                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1999                                 this.motd_actived_time = 0;
2000                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2001                         }
2002                 }
2003         }
2004         else //if(this.motd_actived_time < 0) // just connected, motd is active
2005         {
2006                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2007                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
2008                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2009                 {
2010                         // instanctly hide MOTD
2011                         this.motd_actived_time = 0;
2012                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2013                 }
2014         }
2015 }
2016
2017 bool joinAllowed(entity this)
2018 {
2019         if (this.version_mismatch) return false;
2020         if (!nJoinAllowed(this, this)) return false;
2021         if (teamplay && lockteams) return false;
2022         if (ShowTeamSelection(this)) return false;
2023         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2024         return true;
2025 }
2026
2027 void ObserverThink(entity this)
2028 {
2029         if ( this.impulse )
2030         {
2031                 MinigameImpulse(this, this.impulse);
2032                 this.impulse = 0;
2033         }
2034
2035         if (this.flags & FL_JUMPRELEASED) {
2036                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2037                         this.flags &= ~FL_JUMPRELEASED;
2038                         this.flags |= FL_SPAWNING;
2039                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2040                         this.flags &= ~FL_JUMPRELEASED;
2041                         if(SpectateNext(this)) {
2042                                 TRANSMUTE(Spectator, this);
2043                         }
2044                 } else {
2045                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2046                         set_movetype(this, preferred_movetype);
2047                 }
2048         } else {
2049                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2050                         this.flags |= FL_JUMPRELEASED;
2051                         if(this.flags & FL_SPAWNING)
2052                         {
2053                                 this.flags &= ~FL_SPAWNING;
2054                                 Join(this);
2055                                 return;
2056                         }
2057                 }
2058         }
2059 }
2060
2061 void SpectatorThink(entity this)
2062 {
2063         if ( this.impulse )
2064         {
2065                 if(MinigameImpulse(this, this.impulse))
2066                         this.impulse = 0;
2067
2068                 if (this.impulse == IMP_weapon_drop.impulse)
2069                 {
2070                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2071                         this.impulse = 0;
2072                         return;
2073                 }
2074         }
2075
2076         if (this.flags & FL_JUMPRELEASED) {
2077                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2078                         this.flags &= ~FL_JUMPRELEASED;
2079                         this.flags |= FL_SPAWNING;
2080                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2081                         this.flags &= ~FL_JUMPRELEASED;
2082                         if(SpectateNext(this)) {
2083                                 TRANSMUTE(Spectator, this);
2084                         } else {
2085                                 TRANSMUTE(Observer, this);
2086                                 PutClientInServer(this);
2087                         }
2088                         this.impulse = 0;
2089                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2090                         this.flags &= ~FL_JUMPRELEASED;
2091                         if(SpectatePrev(this)) {
2092                                 TRANSMUTE(Spectator, this);
2093                         } else {
2094                                 TRANSMUTE(Observer, this);
2095                                 PutClientInServer(this);
2096                         }
2097                         this.impulse = 0;
2098                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2099                         this.flags &= ~FL_JUMPRELEASED;
2100                         TRANSMUTE(Observer, this);
2101                         PutClientInServer(this);
2102                 } else {
2103                         if(!SpectateUpdate(this))
2104                                 PutObserverInServer(this);
2105                 }
2106         } else {
2107                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2108                         this.flags |= FL_JUMPRELEASED;
2109                         if(this.flags & FL_SPAWNING)
2110                         {
2111                                 this.flags &= ~FL_SPAWNING;
2112                                 Join(this);
2113                                 return;
2114                         }
2115                 }
2116                 if(!SpectateUpdate(this))
2117                         PutObserverInServer(this);
2118         }
2119
2120         this.flags |= FL_CLIENT | FL_NOTARGET;
2121 }
2122
2123 void vehicles_enter (entity pl, entity veh);
2124 void PlayerUseKey(entity this)
2125 {
2126         if (!IS_PLAYER(this))
2127                 return;
2128
2129         if(this.vehicle)
2130         {
2131                 if(!gameover)
2132                 {
2133                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2134                         return;
2135                 }
2136         }
2137         else if(autocvar_g_vehicles_enter)
2138         {
2139                 if(!STAT(FROZEN, this))
2140                 if(!IS_DEAD(this))
2141                 if(!gameover)
2142                 {
2143                         entity head, closest_target = NULL;
2144                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2145
2146                         while(head) // find the closest acceptable target to enter
2147                         {
2148                                 if(IS_VEHICLE(head))
2149                                 if(!IS_DEAD(head))
2150                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2151                                 if(head.takedamage != DAMAGE_NO)
2152                                 {
2153                                         if(closest_target)
2154                                         {
2155                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2156                                                 { closest_target = head; }
2157                                         }
2158                                         else { closest_target = head; }
2159                                 }
2160
2161                                 head = head.chain;
2162                         }
2163
2164                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2165                 }
2166         }
2167
2168         // a use key was pressed; call handlers
2169         MUTATOR_CALLHOOK(PlayerUseKey, this);
2170 }
2171
2172
2173 /*
2174 =============
2175 PlayerPreThink
2176
2177 Called every frame for each client before the physics are run
2178 =============
2179 */
2180 .float usekeypressed;
2181 .float last_vehiclecheck;
2182 .int items_added;
2183 void PlayerPreThink (entity this)
2184 {
2185         WarpZone_PlayerPhysics_FixVAngle(this);
2186
2187     STAT(GAMESTARTTIME, this) = game_starttime;
2188         STAT(ROUNDSTARTTIME, this) = round_starttime;
2189         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2190         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2191
2192         STAT(WEAPONSINMAP, this) = weaponsInMap;
2193
2194         if (frametime) {
2195                 // physics frames: update anticheat stuff
2196                 anticheat_prethink(this);
2197         }
2198
2199         if (blockSpectators && frametime) {
2200                 // WORKAROUND: only use dropclient in server frames (frametime set).
2201                 // Never use it in cl_movement frames (frametime zero).
2202                 checkSpectatorBlock(this);
2203     }
2204
2205         zoomstate_set = false;
2206
2207         // Check for nameless players
2208         if (isInvisibleString(this.netname)) {
2209                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2210                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2211         }
2212         if (this.netname != this.netname_previous) {
2213                 if (autocvar_sv_eventlog) {
2214                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2215         }
2216                 if (this.netname_previous) strunzone(this.netname_previous);
2217                 this.netname_previous = strzone(this.netname);
2218         }
2219
2220         // version nagging
2221         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2222         this.version_nagtime = 0;
2223         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2224             // git client
2225         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2226             // git server
2227             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2228         } else {
2229             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2230             if (r < 0) { // old client
2231                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2232             } else if (r > 0) { // old server
2233                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2234             }
2235         }
2236     }
2237
2238         // GOD MODE info
2239         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2240         {
2241                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2242                 this.max_armorvalue = 0;
2243         }
2244
2245         if (STAT(FROZEN, this) == 2)
2246         {
2247                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2248                 this.health = max(1, this.revive_progress * start_health);
2249                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2250
2251                 if (this.revive_progress >= 1)
2252                         Unfreeze(this);
2253         }
2254         else if (STAT(FROZEN, this) == 3)
2255         {
2256                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2257                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2258
2259                 if (this.health < 1)
2260                 {
2261                         if (this.vehicle)
2262                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2263                         if(this.event_damage)
2264                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2265                 }
2266                 else if (this.revive_progress <= 0)
2267                         Unfreeze(this);
2268         }
2269
2270         MUTATOR_CALLHOOK(PlayerPreThink, this);
2271
2272         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2273         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2274         {
2275                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2276                 {
2277                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2278                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2279                         {
2280                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2281                         }
2282                         else if(!it.owner)
2283                         {
2284                                 if(!it.team || SAME_TEAM(this, it))
2285                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2286                                 else if(autocvar_g_vehicles_steal)
2287                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2288                         }
2289                 });
2290
2291                 this.last_vehiclecheck = time + 1;
2292         }
2293
2294         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2295         {
2296                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2297                         PlayerUseKey(this);
2298                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2299         }
2300
2301         if (IS_REAL_CLIENT(this))
2302                 PrintWelcomeMessage(this);
2303
2304         if (IS_PLAYER(this)) {
2305                 CheckRules_Player(this);
2306
2307                 if (intermission_running) {
2308                         IntermissionThink(this);
2309                         return;
2310                 }
2311
2312                 if (timeout_status == TIMEOUT_ACTIVE) {
2313             // don't allow the player to turn around while game is paused
2314                         // FIXME turn this into CSQC stuff
2315                         this.v_angle = this.lastV_angle;
2316                         this.angles = this.lastV_angle;
2317                         this.fixangle = true;
2318                 }
2319
2320                 if (frametime) player_powerups(this);
2321
2322                 if (IS_DEAD(this)) {
2323                         if (this.personal && g_race_qualifying) {
2324                                 if (time > this.respawn_time) {
2325                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2326                                         respawn(this);
2327                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2328                                 }
2329                         } else {
2330                                 if (frametime) player_anim(this);
2331                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2332
2333                                 switch(this.deadflag)
2334                                 {
2335                                         case DEAD_DYING:
2336                                         {
2337                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2338                                                         this.deadflag = DEAD_RESPAWNING;
2339                                                 else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2340                                                         this.deadflag = DEAD_DEAD;
2341                                                 break;
2342                                         }
2343                                         case DEAD_DEAD:
2344                                         {
2345                                                 if (button_pressed)
2346                                                         this.deadflag = DEAD_RESPAWNABLE;
2347                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2348                                                         this.deadflag = DEAD_RESPAWNING;
2349                                                 break;
2350                                         }
2351                                         case DEAD_RESPAWNABLE:
2352                                         {
2353                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2354                                                         this.deadflag = DEAD_RESPAWNING;
2355                                                 break;
2356                                         }
2357                                         case DEAD_RESPAWNING:
2358                                         {
2359                                                 if (time > this.respawn_time)
2360                                                 {
2361                                                         this.respawn_time = time + 1; // only retry once a second
2362                                                         this.respawn_time_max = this.respawn_time;
2363                                                         respawn(this);
2364                                                 }
2365                                                 break;
2366                                         }
2367                                 }
2368
2369                                 ShowRespawnCountdown(this);
2370
2371                                 if (this.respawn_flags & RESPAWN_SILENT)
2372                                         STAT(RESPAWN_TIME, this) = 0;
2373                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2374                                 {
2375                                         if (time < this.respawn_time)
2376                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2377                                         else if (this.deadflag != DEAD_RESPAWNING)
2378                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2379                                 }
2380                                 else
2381                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2382                         }
2383
2384                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2385                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2386                                 STAT(RESPAWN_TIME, this) *= -1;
2387
2388                         return;
2389                 }
2390
2391                 this.prevorigin = this.origin;
2392
2393                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2394                 if (this.hook.state) {
2395                         do_crouch = false;
2396                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2397                         do_crouch = false;
2398                 } else if (this.vehicle) {
2399                         do_crouch = false;
2400                 } else if (STAT(FROZEN, this)) {
2401                         do_crouch = false;
2402         }
2403
2404                 if (do_crouch) {
2405                         if (!this.crouch) {
2406                                 this.crouch = true;
2407                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2408                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2409                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2410                         }
2411                 } else if (this.crouch) {
2412             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2413             if (!trace_startsolid) {
2414                 this.crouch = false;
2415                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2416                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2417             }
2418                 }
2419
2420                 FixPlayermodel(this);
2421
2422                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2423                 //if(frametime)
2424                 {
2425                         this.items &= ~this.items_added;
2426
2427                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2428                         {
2429                                 .entity weaponentity = weaponentities[slot];
2430                                 W_WeaponFrame(this, weaponentity);
2431
2432                                 if(slot == 0)
2433                                 {
2434                                         this.clip_load = this.(weaponentity).clip_load;
2435                                         this.clip_size = this.(weaponentity).clip_size;
2436                                 }
2437                         }
2438
2439                         this.items_added = 0;
2440                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2441                 this.items_added |= IT_FUEL;
2442
2443                         this.items |= this.items_added;
2444                 }
2445
2446                 player_regen(this);
2447
2448                 // WEAPONTODO: Add a weapon request for this
2449                 // rot vortex charge to the charge limit
2450                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2451                 {
2452                         .entity weaponentity = weaponentities[slot];
2453                         if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2454                                 this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2455                 }
2456
2457                 if (frametime) player_anim(this);
2458
2459                 // secret status
2460                 secrets_setstatus(this);
2461
2462                 // monsters status
2463                 monsters_setstatus(this);
2464
2465                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2466         }
2467         else if (gameover) {
2468                 if (intermission_running) IntermissionThink(this);
2469                 return;
2470         }
2471         else if (IS_OBSERVER(this)) {
2472                 ObserverThink(this);
2473         }
2474         else if (IS_SPEC(this)) {
2475                 SpectatorThink(this);
2476         }
2477
2478         // WEAPONTODO: Add weapon request for this
2479         if (!zoomstate_set) {
2480                 bool wep_zoomed = false;
2481                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2482                 {
2483                         .entity weaponentity = weaponentities[slot];
2484                         Weapon thiswep = this.(weaponentity).m_weapon;
2485                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2486                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2487                 }
2488                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2489     }
2490
2491         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2492         {
2493                 this.teamkill_soundtime = 0;
2494
2495                 entity e = this.teamkill_soundsource;
2496                 entity oldpusher = e.pusher;
2497                 e.pusher = this;
2498                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2499                 e.pusher = oldpusher;
2500         }
2501
2502         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2503                 this.taunt_soundtime = 0;
2504                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2505         }
2506
2507         target_voicescript_next(this);
2508
2509         // WEAPONTODO: Move into weaponsystem somehow
2510         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2511         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2512         {
2513                 .entity weaponentity = weaponentities[slot];
2514                 if(this.(weaponentity).m_weapon == WEP_Null)
2515                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2516         }
2517 }
2518
2519 void DrownPlayer(entity this)
2520 {
2521         if(IS_DEAD(this))
2522                 return;
2523
2524         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2525         {
2526                 if(this.air_finished < time)
2527                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2528                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2529                 this.dmg = 2;
2530         }
2531         else if (this.air_finished < time)
2532         {       // drown!
2533                 if (this.pain_finished < time)
2534                 {
2535                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2536                         this.pain_finished = time + 0.5;
2537                 }
2538         }
2539 }
2540
2541 .bool move_qcphysics;
2542
2543 void Player_Physics(entity this)
2544 {
2545         set_movetype(this, this.move_movetype);
2546
2547         if(!this.move_qcphysics)
2548                 return;
2549
2550         if(!frametime && !this.pm_frametime)
2551                 return;
2552
2553         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2554
2555         this.pm_frametime = 0;
2556 }
2557
2558 /*
2559 =============
2560 PlayerPostThink
2561
2562 Called every frame for each client after the physics are run
2563 =============
2564 */
2565 .float idlekick_lasttimeleft;
2566 void PlayerPostThink (entity this)
2567 {
2568         Player_Physics(this);
2569
2570         if (sv_maxidle > 0)
2571         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2572         if (IS_REAL_CLIENT(this))
2573         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2574         {
2575                 int totalClients = 0;
2576                 if(sv_maxidle_slots > 0)
2577                 {
2578                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2579                         {
2580                                 ++totalClients;
2581                         });
2582                 }
2583
2584                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2585                 { /* do nothing */ }
2586                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2587                 {
2588                         if (this.idlekick_lasttimeleft)
2589                         {
2590                                 this.idlekick_lasttimeleft = 0;
2591                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2592                         }
2593                 }
2594                 else
2595                 {
2596                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2597                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2598                                 if (!this.idlekick_lasttimeleft)
2599                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2600                         }
2601                         if (timeleft <= 0) {
2602                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2603                                 dropclient(this);
2604                                 return;
2605                         }
2606                         else if (timeleft <= 10) {
2607                                 if (timeleft != this.idlekick_lasttimeleft) {
2608                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2609                 }
2610                                 this.idlekick_lasttimeleft = timeleft;
2611                         }
2612                 }
2613         }
2614
2615         CheatFrame(this);
2616
2617         //CheckPlayerJump();
2618
2619         if (IS_PLAYER(this)) {
2620                 DrownPlayer(this);
2621                 CheckRules_Player(this);
2622                 UpdateChatBubble(this);
2623                 if (this.impulse) ImpulseCommands(this);
2624                 if (intermission_running) return; // intermission or finale
2625                 GetPressedKeys(this);
2626         }
2627
2628         if (this.waypointsprite_attachedforcarrier) {
2629             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2630                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2631     }
2632
2633         playerdemo_write(this);
2634
2635         CSQCMODEL_AUTOUPDATE(this);
2636 }