qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include "anticheat.qh"
   4 #include "impulse.qh"
   5 #include "player.qh"
   6 #include "ipban.qh"
   7 #include "miscfunctions.qh"
   8 #include "portals.qh"
   9 #include "teamplay.qh"
  10 #include "playerdemo.qh"
  11 #include "spawnpoints.qh"
  12 #include "g_damage.qh"
  13 #include "g_hook.qh"
  14 #include "command/common.qh"
  15 #include "cheats.qh"
  16 #include "g_world.qh"
  17 #include "race.qh"
  18 #include "antilag.qh"
  19 #include "campaign.qh"
  20 #include "command/common.qh"
  21 #include "scores_rules.qh"
  22
  23 #include "bot/api.qh"
  24
  25 #include "../common/ent_cs.qh"
  26 #include <common/state.qh>
  27
  28 #include <common/effects/qc/globalsound.qh>
  29
  30 #include "../common/triggers/func/conveyor.qh"
  31 #include "../common/triggers/teleporters.qh"
  32
  33 #include "../common/vehicles/all.qh"
  34
  35 #include "weapons/hitplot.qh"
  36 #include "weapons/weaponsystem.qh"
  37
  38 #include "../common/net_notice.qh"
  39 #include "../common/physics/player.qh"
  40
  41 #include "../common/items/_mod.qh"
  42
  43 #include "../common/mutators/mutator/waypoints/all.qh"
  44
  45 #include "../common/triggers/subs.qh"
  46 #include "../common/triggers/triggers.qh"
  47 #include "../common/triggers/trigger/secret.qh"
  48
  49 #include "../common/minigames/sv_minigames.qh"
  50
  51 #include "../common/items/inventory.qh"
  52
  53 #include "../common/monsters/sv_monsters.qh"
  54
  55 #include "../lib/warpzone/server.qh"
  56
  57 STATIC_METHOD(Client, Add, void(Client this, int _team))
  58 {
  59     ClientConnect(this);
  60     TRANSMUTE(Player, this);
  61     this.frame = 12; // 7
  62     this.team = _team;
  63     PutClientInServer(this);
  64 }
  65
  66 void PutObserverInServer(entity this);
  67
  68 STATIC_METHOD(Client, Remove, void(Client this))
  69 {
  70     TRANSMUTE(Observer, this);
  71     PutClientInServer(this);
  72     ClientDisconnect(this);
  73 }
  74
  75 void send_CSQC_teamnagger() {
  76         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  77 }
  78
  79 int CountSpectators(entity player, entity to)
  80 {
  81         if(!player) { return 0; } // not sure how, but best to be safe
  82
  83         int spec_count = 0;
  84
  85         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  86         {
  87                 spec_count++;
  88         });
  89
  90         return spec_count;
  91 }
  92
  93 void WriteSpectators(entity player, entity to)
  94 {
  95         if(!player) { return; } // not sure how, but best to be safe
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 WriteByte(MSG_ENTITY, num_for_edict(it));
 100         });
 101 }
 102
 103 bool ClientData_Send(entity this, entity to, int sf)
 104 {
 105         assert(to == this.owner, return false);
 106
 107         entity e = to;
 108         if (IS_SPEC(e)) e = e.enemy;
 109
 110         sf = 0;
 111         if (e.race_completed)       sf |= 1; // forced scoreboard
 112         if (to.spectatee_status)    sf |= 2; // spectator ent number follows
 113         if (e.zoomstate)            sf |= 4; // zoomed
 114         if (e.porto_v_angle_held)   sf |= 8; // angles held
 115         if (autocvar_sv_showspectators) sf |= 16; // show spectators
 116
 117         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 118         WriteByte(MSG_ENTITY, sf);
 119
 120         if (sf & 2)
 121         {
 122                 WriteByte(MSG_ENTITY, to.spectatee_status);
 123         }
 124         if (sf & 8)
 125         {
 126                 WriteAngle(MSG_ENTITY, e.v_angle.x);
 127                 WriteAngle(MSG_ENTITY, e.v_angle.y);
 128         }
 129
 130         if(sf & 16)
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(this.clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         this.clientdata.drawonlytoclient = this;
 144         this.clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(this.clientdata);
 150         this.clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         e.clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, LAMBDA(it.clientdata.SendFlags = 1));
 159 }
 160
 161 .string netname_previous;
 162
 163 void SetSpectatee(entity player, entity spectatee);
 164
 165
 166 /*
 167 =============
 168 CheckPlayerModel
 169
 170 Checks if the argument string can be a valid playermodel.
 171 Returns a valid one in doubt.
 172 =============
 173 */
 174 string FallbackPlayerModel;
 175 string CheckPlayerModel(string plyermodel) {
 176         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 177         {
 178                 // note: we cannot summon Don Strunzone here, some player may
 179                 // still have the model string set. In case anyone manages how
 180                 // to change a cvar default, we'll have a small leak here.
 181                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 182         }
 183         // only in right path
 184         if( substring(plyermodel,0,14) != "models/player/")
 185                 return FallbackPlayerModel;
 186         // only good file extensions
 187         if(substring(plyermodel,-4,4) != ".zym")
 188         if(substring(plyermodel,-4,4) != ".dpm")
 189         if(substring(plyermodel,-4,4) != ".iqm")
 190         if(substring(plyermodel,-4,4) != ".md3")
 191         if(substring(plyermodel,-4,4) != ".psk")
 192                 return FallbackPlayerModel;
 193         // forbid the LOD models
 194         if(substring(plyermodel, -9,5) == "_lod1")
 195                 return FallbackPlayerModel;
 196         if(substring(plyermodel, -9,5) == "_lod2")
 197                 return FallbackPlayerModel;
 198         if(plyermodel != strtolower(plyermodel))
 199                 return FallbackPlayerModel;
 200         // also, restrict to server models
 201         if(autocvar_sv_servermodelsonly)
 202         {
 203                 if(!fexists(plyermodel))
 204                         return FallbackPlayerModel;
 205         }
 206         return plyermodel;
 207 }
 208
 209 void setplayermodel(entity e, string modelname)
 210 {
 211         precache_model(modelname);
 212         _setmodel(e, modelname);
 213         player_setupanimsformodel(e);
 214         if(!autocvar_g_debug_globalsounds)
 215                 UpdatePlayerSounds(e);
 216 }
 217
 218 void FixPlayermodel(entity player);
 219 /** putting a client as observer in the server */
 220 void PutObserverInServer(entity this)
 221 {
 222     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 223         PlayerState_detach(this);
 224
 225         if (IS_PLAYER(this) && this.health >= 1) {
 226         // despawn effect
 227                 Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 228     }
 229
 230     {
 231         entity spot = SelectSpawnPoint(this, true);
 232         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 233         this.angles = spot.angles;
 234         this.angles_z = 0;
 235         this.fixangle = true;
 236         // offset it so that the spectator spawns higher off the ground, looks better this way
 237         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, NULL));
 238         this.prevorigin = this.origin;
 239         if (IS_REAL_CLIENT(this))
 240         {
 241             msg_entity = this;
 242             WriteByte(MSG_ONE, SVC_SETVIEW);
 243             WriteEntity(MSG_ONE, this);
 244         }
 245         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 246         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 247         if(!autocvar_g_debug_globalsounds)
 248         {
 249                 // needed for player sounds
 250                 this.model = "";
 251                 FixPlayermodel(this);
 252         }
 253         setmodel(this, MDL_Null);
 254         setsize(this, STAT(PL_CROUCH_MIN, NULL), STAT(PL_CROUCH_MAX, NULL));
 255         this.view_ofs = '0 0 0';
 256     }
 257
 258     RemoveGrapplingHook(this);
 259         Portal_ClearAll(this);
 260         Unfreeze(this);
 261         SetSpectatee(this, NULL);
 262
 263         if (this.alivetime)
 264         {
 265                 if (!warmup_stage)
 266                         PS_GR_P_ADDVAL(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 267                 this.alivetime = 0;
 268         }
 269
 270         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 271
 272         WaypointSprite_PlayerDead(this);
 273
 274         if (mutator_returnvalue) {
 275             // mutator prevents resetting teams+score
 276         } else {
 277                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 278         this.frags = FRAGS_SPECTATOR;
 279         PlayerScore_Clear(this);  // clear scores when needed
 280     }
 281
 282         if (this.killcount != FRAGS_SPECTATOR)
 283         {
 284                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 285                 if(!intermission_running)
 286                 if(autocvar_g_chat_nospectators == 1 || (!(warmup_stage || gameover) && autocvar_g_chat_nospectators == 2))
 287                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 288
 289                 if(this.just_joined == false) {
 290                         LogTeamchange(this.playerid, -1, 4);
 291                 } else
 292                         this.just_joined = false;
 293         }
 294
 295         accuracy_resend(this);
 296
 297         this.spectatortime = time;
 298         if(this.bot_attack)
 299                 IL_REMOVE(g_bot_targets, this);
 300         this.bot_attack = false;
 301     this.hud = HUD_NORMAL;
 302         TRANSMUTE(Observer, this);
 303         this.iscreature = false;
 304         this.teleportable = TELEPORT_SIMPLE;
 305         this.damagedbycontents = false;
 306         this.health = FRAGS_SPECTATOR;
 307         this.takedamage = DAMAGE_NO;
 308         this.solid = SOLID_NOT;
 309         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 310         this.flags = FL_CLIENT | FL_NOTARGET;
 311         this.armorvalue = 666;
 312         this.effects = 0;
 313         this.armorvalue = autocvar_g_balance_armor_start;
 314         this.pauserotarmor_finished = 0;
 315         this.pauserothealth_finished = 0;
 316         this.pauseregen_finished = 0;
 317         this.damageforcescale = 0;
 318         this.death_time = 0;
 319         this.respawn_flags = 0;
 320         this.respawn_time = 0;
 321         this.stat_respawn_time = 0;
 322         this.alpha = 0;
 323         this.scale = 0;
 324         this.fade_time = 0;
 325         this.pain_frame = 0;
 326         this.pain_finished = 0;
 327         this.strength_finished = 0;
 328         this.invincible_finished = 0;
 329         this.superweapons_finished = 0;
 330         this.pushltime = 0;
 331         this.istypefrag = 0;
 332         setthink(this, func_null);
 333         this.nextthink = 0;
 334         this.hook_time = 0;
 335         this.deadflag = DEAD_NO;
 336         this.crouch = false;
 337         this.revival_time = 0;
 338
 339         this.items = 0;
 340         this.weapons = '0 0 0';
 341         this.drawonlytoclient = this;
 342
 343         this.weaponname = "";
 344         this.weaponmodel = "";
 345         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 346         {
 347                 this.weaponentities[slot] = NULL;
 348         }
 349         this.exteriorweaponentity = NULL;
 350         this.killcount = FRAGS_SPECTATOR;
 351         this.velocity = '0 0 0';
 352         this.avelocity = '0 0 0';
 353         this.punchangle = '0 0 0';
 354         this.punchvector = '0 0 0';
 355         this.oldvelocity = this.velocity;
 356         this.fire_endtime = -1;
 357         this.event_damage = func_null;
 358
 359         STAT(ACTIVEWEAPON, this) = WEP_Null.m_id;
 360         STAT(SWITCHINGWEAPON, this) = WEP_Null.m_id;
 361         STAT(SWITCHWEAPON, this) = WEP_Null.m_id;
 362 }
 363
 364 int player_getspecies(entity this)
 365 {
 366         get_model_parameters(this.model, this.skin);
 367         int s = get_model_parameters_species;
 368         get_model_parameters(string_null, 0);
 369         if (s < 0) return SPECIES_HUMAN;
 370         return s;
 371 }
 372
 373 .float model_randomizer;
 374 void FixPlayermodel(entity player)
 375 {
 376         string defaultmodel = "";
 377         int defaultskin = 0;
 378         if(autocvar_sv_defaultcharacter)
 379         {
 380                 if(teamplay)
 381                 {
 382                         string s = Static_Team_ColorName_Lower(player.team);
 383                         if (s != "neutral")
 384                         {
 385                                 defaultmodel = cvar_string(strcat("sv_defaultplayermodel_", s));
 386                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 387                         }
 388                 }
 389
 390                 if(defaultmodel == "")
 391                 {
 392                         defaultmodel = autocvar_sv_defaultplayermodel;
 393                         defaultskin = autocvar_sv_defaultplayerskin;
 394                 }
 395
 396                 int n = tokenize_console(defaultmodel);
 397                 if(n > 0)
 398                 {
 399                         defaultmodel = argv(floor(n * player.model_randomizer));
 400                         // However, do NOT randomize if the player-selected model is in the list.
 401                         for (int i = 0; i < n; ++i)
 402                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 403                                         defaultmodel = argv(i);
 404                 }
 405
 406                 int i = strstrofs(defaultmodel, ":", 0);
 407                 if(i >= 0)
 408                 {
 409                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 410                         defaultmodel = substring(defaultmodel, 0, i);
 411                 }
 412         }
 413         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 414         {
 415                 if(teamplay)
 416                 {
 417                         string s = Static_Team_ColorName_Lower(player.team);
 418                         if (s != "neutral")
 419                                 defaultskin = cvar(strcat("sv_defaultplayerskin_", s));
 420                 }
 421
 422                 if(!defaultskin)
 423                         defaultskin = autocvar_sv_defaultplayerskin;
 424         }
 425
 426         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 427         defaultmodel = M_ARGV(0, string);
 428         defaultskin = M_ARGV(1, int);
 429
 430         bool chmdl = false;
 431         int oldskin;
 432         if(defaultmodel != "")
 433         {
 434                 if (defaultmodel != player.model)
 435                 {
 436                         vector m1 = player.mins;
 437                         vector m2 = player.maxs;
 438                         setplayermodel (player, defaultmodel);
 439                         setsize (player, m1, m2);
 440                         chmdl = true;
 441                 }
 442
 443                 oldskin = player.skin;
 444                 player.skin = defaultskin;
 445         } else {
 446                 if (player.playermodel != player.model || player.playermodel == "")
 447                 {
 448                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 449                         vector m1 = player.mins;
 450                         vector m2 = player.maxs;
 451                         setplayermodel (player, player.playermodel);
 452                         setsize (player, m1, m2);
 453                         chmdl = true;
 454                 }
 455
 456                 if(!autocvar_sv_defaultcharacterskin)
 457                 {
 458                         oldskin = player.skin;
 459                         player.skin = stof(player.playerskin);
 460                 }
 461                 else
 462                 {
 463                         oldskin = player.skin;
 464                         player.skin = defaultskin;
 465                 }
 466         }
 467
 468         if(chmdl || oldskin != player.skin) // model or skin has changed
 469         {
 470                 player.species = player_getspecies(player); // update species
 471                 if(!autocvar_g_debug_globalsounds)
 472                         UpdatePlayerSounds(player); // update skin sounds
 473         }
 474
 475         if(!teamplay)
 476                 if(strlen(autocvar_sv_defaultplayercolors))
 477                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 478                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 479 }
 480
 481
 482 /** Called when a client spawns in the server */
 483 void PutClientInServer(entity this)
 484 {
 485         if (IS_BOT_CLIENT(this)) {
 486                 TRANSMUTE(Player, this);
 487         } else if (IS_REAL_CLIENT(this)) {
 488                 msg_entity = this;
 489                 WriteByte(MSG_ONE, SVC_SETVIEW);
 490                 WriteEntity(MSG_ONE, this);
 491         }
 492         if (gameover) {
 493                 TRANSMUTE(Observer, this);
 494         }
 495
 496         SetSpectatee(this, NULL);
 497
 498         // reset player keys
 499         this.itemkeys = 0;
 500
 501         MUTATOR_CALLHOOK(PutClientInServer, this);
 502
 503         if (IS_OBSERVER(this)) {
 504                 PutObserverInServer(this);
 505         } else if (IS_PLAYER(this)) {
 506                 if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 507
 508                 PlayerState_attach(this);
 509                 accuracy_resend(this);
 510
 511                 if (this.team < 0)
 512                         JoinBestTeam(this, false, true);
 513
 514                 entity spot = SelectSpawnPoint(this, false);
 515                 if (!spot) {
 516                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 517                         return; // spawn failed
 518                 }
 519
 520                 TRANSMUTE(Player, this);
 521                 this.wasplayer = true;
 522                 this.iscreature = true;
 523                 this.teleportable = TELEPORT_NORMAL;
 524                 this.damagedbycontents = true;
 525                 set_movetype(this, MOVETYPE_WALK);
 526                 this.solid = SOLID_SLIDEBOX;
 527                 this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 528                 if (autocvar_g_playerclip_collisions)
 529                         this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 530                 if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 531                         this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 532                 this.frags = FRAGS_PLAYER;
 533                 if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 534                 this.flags = FL_CLIENT | FL_PICKUPITEMS;
 535                 if (autocvar__notarget)
 536                         this.flags |= FL_NOTARGET;
 537                 this.takedamage = DAMAGE_AIM;
 538                 this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 539                 this.dmg = 2; // WTF
 540
 541                 if (warmup_stage) {
 542                         this.ammo_shells = warmup_start_ammo_shells;
 543                         this.ammo_nails = warmup_start_ammo_nails;
 544                         this.ammo_rockets = warmup_start_ammo_rockets;
 545                         this.ammo_cells = warmup_start_ammo_cells;
 546                         this.ammo_plasma = warmup_start_ammo_plasma;
 547                         this.ammo_fuel = warmup_start_ammo_fuel;
 548                         this.health = warmup_start_health;
 549                         this.armorvalue = warmup_start_armorvalue;
 550                         this.weapons = WARMUP_START_WEAPONS;
 551                 } else {
 552                         this.ammo_shells = start_ammo_shells;
 553                         this.ammo_nails = start_ammo_nails;
 554                         this.ammo_rockets = start_ammo_rockets;
 555                         this.ammo_cells = start_ammo_cells;
 556                         this.ammo_plasma = start_ammo_plasma;
 557                         this.ammo_fuel = start_ammo_fuel;
 558                         this.health = start_health;
 559                         this.armorvalue = start_armorvalue;
 560                         this.weapons = start_weapons;
 561                 }
 562
 563                 this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 564
 565                 this.items = start_items;
 566
 567                 this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 568                 this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 569                 this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 570                 this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 571                 this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 572                 // extend the pause of rotting if client was reset at the beginning of the countdown
 573                 if (!autocvar_sv_ready_restart_after_countdown && time < game_starttime) { // TODO why is this cvar NOTted?
 574                         float f = game_starttime - time;
 575                         this.spawnshieldtime += f;
 576                         this.pauserotarmor_finished += f;
 577                         this.pauserothealth_finished += f;
 578                         this.pauseregen_finished += f;
 579                 }
 580                 this.damageforcescale = 2;
 581                 this.death_time = 0;
 582                 this.respawn_flags = 0;
 583                 this.respawn_time = 0;
 584                 this.stat_respawn_time = 0;
 585                 this.scale = autocvar_sv_player_scale;
 586                 this.fade_time = 0;
 587                 this.pain_frame = 0;
 588                 this.pain_finished = 0;
 589                 this.pushltime = 0;
 590                 setthink(this, func_null); // players have no think function
 591                 this.nextthink = 0;
 592                 this.dmg_team = 0;
 593                 this.ballistics_density = autocvar_g_ballistics_density_player;
 594
 595                 this.deadflag = DEAD_NO;
 596
 597                 this.angles = spot.angles;
 598                 this.angles_z = 0; // never spawn tilted even if the spot says to
 599                 if (IS_BOT_CLIENT(this))
 600                         this.v_angle = this.angles;
 601                 this.fixangle = true; // turn this way immediately
 602                 this.oldvelocity = this.velocity = '0 0 0';
 603                 this.avelocity = '0 0 0';
 604                 this.punchangle = '0 0 0';
 605                 this.punchvector = '0 0 0';
 606
 607                 this.strength_finished = 0;
 608                 this.invincible_finished = 0;
 609                 this.fire_endtime = -1;
 610                 this.revival_time = 0;
 611                 this.air_finished = time + 12;
 612
 613                 entity spawnevent = new_pure(spawnevent);
 614                 spawnevent.owner = this;
 615                 Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 616
 617                 // Cut off any still running player sounds.
 618                 stopsound(this, CH_PLAYER_SINGLE);
 619
 620                 this.model = "";
 621                 FixPlayermodel(this);
 622                 this.drawonlytoclient = NULL;
 623
 624                 this.crouch = false;
 625                 this.view_ofs = STAT(PL_VIEW_OFS, NULL);
 626                 setsize(this, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 627                 this.spawnorigin = spot.origin;
 628                 setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 629                 // don't reset back to last position, even if new position is stuck in solid
 630                 this.oldorigin = this.origin;
 631                 this.prevorigin = this.origin;
 632                 this.lastteleporttime = time; // prevent insane speeds due to changing origin
 633                 if(this.conveyor)
 634                         IL_REMOVE(g_conveyed, this);
 635                 this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 636                 this.hud = HUD_NORMAL;
 637
 638                 this.event_damage = PlayerDamage;
 639
 640                 if(!this.bot_attack)
 641                         IL_PUSH(g_bot_targets, this);
 642                 this.bot_attack = true;
 643                 this.monster_attack = true;
 644
 645                 PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 646
 647                 if (this.killcount == FRAGS_SPECTATOR) {
 648                         PlayerScore_Clear(this);
 649                         this.killcount = 0;
 650                 }
 651
 652                 for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 653                 {
 654                         CL_SpawnWeaponentity(this, weaponentities[slot]);
 655                 }
 656                 this.alpha = default_player_alpha;
 657                 this.colormod = '1 1 1' * autocvar_g_player_brightness;
 658                 this.exteriorweaponentity.alpha = default_weapon_alpha;
 659
 660                 this.speedrunning = false;
 661
 662                 target_voicescript_clear(this);
 663
 664                 // reset fields the weapons may use
 665                 FOREACH(Weapons, true, LAMBDA(
 666                         it.wr_resetplayer(it, this);
 667                         // reload all reloadable weapons
 668                         if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 669                                 this.weapon_load[it.m_id] = it.reloading_ammo;
 670                         }
 671                 ));
 672
 673                 {
 674                         string s = spot.target;
 675                         spot.target = string_null;
 676                         SUB_UseTargets(spot, this, NULL);
 677                         spot.target = s;
 678                 }
 679
 680                 Unfreeze(this);
 681
 682                 MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 683
 684                 if (autocvar_spawn_debug)
 685                 {
 686                         sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 687                         delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 688                 }
 689
 690                 PS(this).m_switchweapon = w_getbestweapon(this);
 691                 this.cnt = -1; // W_LastWeapon will not complain
 692                 PS(this).m_weapon = WEP_Null;
 693                 this.weaponname = "";
 694                 PS(this).m_switchingweapon = WEP_Null;
 695
 696                 if (!warmup_stage && !this.alivetime)
 697                         this.alivetime = time;
 698
 699                 antilag_clear(this, CS(this));
 700         }
 701 }
 702
 703 void ClientInit_misc(entity this);
 704
 705 .float ebouncefactor, ebouncestop; // electro's values
 706 // TODO do we need all these fields, or should we stop autodetecting runtime
 707 // changes and just have a console command to update this?
 708 bool ClientInit_SendEntity(entity this, entity to, int sf)
 709 {
 710         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 711         return = true;
 712         msg_entity = to;
 713         // MSG_INIT replacement
 714         // TODO: make easier to use
 715         Registry_send_all();
 716         W_PROP_reload(MSG_ONE, to);
 717         ClientInit_misc(this);
 718         MUTATOR_CALLHOOK(Ent_Init);
 719 }
 720 void ClientInit_misc(entity this)
 721 {
 722         int channel = MSG_ONE;
 723         WriteHeader(channel, ENT_CLIENT_INIT);
 724         WriteByte(channel, g_nexball_meter_period * 32);
 725         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 726         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 727         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 728         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 729         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 730         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 731         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 732         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 733
 734         if(sv_foginterval && world.fog != "")
 735                 WriteString(channel, world.fog);
 736         else
 737                 WriteString(channel, "");
 738         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 739         WriteByte(channel, serverflags); // client has to know if it should zoom or not
 740         WriteCoord(channel, autocvar_g_trueaim_minrange);
 741 }
 742
 743 void ClientInit_CheckUpdate(entity this)
 744 {
 745         this.nextthink = time;
 746         if(this.count != autocvar_g_balance_armor_blockpercent)
 747         {
 748                 this.count = autocvar_g_balance_armor_blockpercent;
 749                 this.SendFlags |= 1;
 750         }
 751 }
 752
 753 void ClientInit_Spawn()
 754 {
 755         entity e = new_pure(clientinit);
 756         setthink(e, ClientInit_CheckUpdate);
 757         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 758
 759         ClientInit_CheckUpdate(e);
 760 }
 761
 762 /*
 763 =============
 764 SetNewParms
 765 =============
 766 */
 767 void SetNewParms ()
 768 {
 769         // initialize parms for a new player
 770         parm1 = -(86400 * 366);
 771
 772         MUTATOR_CALLHOOK(SetNewParms);
 773 }
 774
 775 /*
 776 =============
 777 SetChangeParms
 778 =============
 779 */
 780 void SetChangeParms (entity this)
 781 {
 782         // save parms for level change
 783         parm1 = this.parm_idlesince - time;
 784
 785         MUTATOR_CALLHOOK(SetChangeParms);
 786 }
 787
 788 /*
 789 =============
 790 DecodeLevelParms
 791 =============
 792 */
 793 void DecodeLevelParms(entity this)
 794 {
 795         // load parms
 796         this.parm_idlesince = parm1;
 797         if (this.parm_idlesince == -(86400 * 366))
 798                 this.parm_idlesince = time;
 799
 800         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 801         this.parm_idlesince = max(this.parm_idlesince, time - sv_maxidle + 60);
 802
 803         MUTATOR_CALLHOOK(DecodeLevelParms);
 804 }
 805
 806 /*
 807 =============
 808 ClientKill
 809
 810 Called when a client types 'kill' in the console
 811 =============
 812 */
 813
 814 .float clientkill_nexttime;
 815 void ClientKill_Now_TeamChange(entity this)
 816 {
 817         if(this.killindicator_teamchange == -1)
 818         {
 819                 JoinBestTeam( this, false, true );
 820         }
 821         else if(this.killindicator_teamchange == -2)
 822         {
 823                 if(blockSpectators)
 824                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 825                 PutObserverInServer(this);
 826         }
 827         else
 828                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 829         this.killindicator_teamchange = 0;
 830 }
 831
 832 void ClientKill_Now(entity this)
 833 {
 834         if(this.vehicle)
 835         {
 836             vehicles_exit(this.vehicle, VHEF_RELEASE);
 837             if(!this.killindicator_teamchange)
 838             {
 839             this.vehicle_health = -1;
 840             Damage(this, this, this, 1 , DEATH_KILL.m_id, this.origin, '0 0 0');
 841             }
 842         }
 843
 844         if(this.killindicator && !wasfreed(this.killindicator))
 845                 delete(this.killindicator);
 846
 847         this.killindicator = NULL;
 848
 849         if(this.killindicator_teamchange)
 850                 ClientKill_Now_TeamChange(this);
 851
 852         if(!IS_SPEC(this) && !IS_OBSERVER(this))
 853                 Damage(this, this, this, 100000, DEATH_KILL.m_id, this.origin, '0 0 0');
 854
 855         // now I am sure the player IS dead
 856 }
 857 void KillIndicator_Think(entity this)
 858 {
 859         if (gameover)
 860         {
 861                 this.owner.killindicator = NULL;
 862                 delete(this);
 863                 return;
 864         }
 865
 866         if (this.owner.alpha < 0 && !this.owner.vehicle)
 867         {
 868                 this.owner.killindicator = NULL;
 869                 delete(this);
 870                 return;
 871         }
 872
 873         if(this.cnt <= 0)
 874         {
 875                 ClientKill_Now(this.owner);
 876                 return;
 877         }
 878     else if(g_cts && this.health == 1) // health == 1 means that it's silent
 879     {
 880         this.nextthink = time + 1;
 881         this.cnt -= 1;
 882     }
 883         else
 884         {
 885                 if(this.cnt <= 10)
 886                         setmodel(this, MDL_NUM(this.cnt));
 887                 if(IS_REAL_CLIENT(this.owner))
 888                 {
 889                         if(this.cnt <= 10)
 890                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 891                 }
 892                 this.nextthink = time + 1;
 893                 this.cnt -= 1;
 894         }
 895 }
 896
 897 float clientkilltime;
 898 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 899 {
 900         float killtime;
 901         float starttime;
 902
 903         if (gameover)
 904                 return;
 905
 906         killtime = autocvar_g_balance_kill_delay;
 907
 908         if(g_race_qualifying || g_cts)
 909                 killtime = 0;
 910
 911     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 912         return;
 913
 914         this.killindicator_teamchange = targetteam;
 915
 916     if(!this.killindicator)
 917         {
 918                 if(!IS_DEAD(this))
 919                 {
 920                         killtime = max(killtime, this.clientkill_nexttime - time);
 921                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
 922                 }
 923
 924                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
 925                 {
 926                         ClientKill_Now(this);
 927                 }
 928                 else
 929                 {
 930                         starttime = max(time, clientkilltime);
 931
 932                         this.killindicator = spawn();
 933                         this.killindicator.owner = this;
 934                         this.killindicator.scale = 0.5;
 935                         setattachment(this.killindicator, this, "");
 936                         setorigin(this.killindicator, '0 0 52');
 937                         setthink(this.killindicator, KillIndicator_Think);
 938                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
 939                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
 940                         this.killindicator.cnt = ceil(killtime);
 941                         this.killindicator.count = bound(0, ceil(killtime), 10);
 942                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
 943
 944                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
 945                         {
 946                                 it.killindicator = spawn();
 947                                 it.killindicator.owner = it;
 948                                 it.killindicator.scale = 0.5;
 949                                 setattachment(it.killindicator, it, "");
 950                                 setorigin(it.killindicator, '0 0 52');
 951                                 setthink(it.killindicator, KillIndicator_Think);
 952                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
 953                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
 954                                 it.killindicator.cnt = ceil(killtime);
 955                         });
 956                         this.lip = 0;
 957                 }
 958         }
 959         if(this.killindicator)
 960         {
 961                 if(targetteam == 0) // just die
 962                 {
 963                         this.killindicator.colormod = '0 0 0';
 964                         if(IS_REAL_CLIENT(this))
 965                         if(this.killindicator.cnt > 0)
 966                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
 967                 }
 968                 else if(targetteam == -1) // auto
 969                 {
 970                         this.killindicator.colormod = '0 1 0';
 971                         if(IS_REAL_CLIENT(this))
 972                         if(this.killindicator.cnt > 0)
 973                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
 974                 }
 975                 else if(targetteam == -2) // spectate
 976                 {
 977                         this.killindicator.colormod = '0.5 0.5 0.5';
 978                         if(IS_REAL_CLIENT(this))
 979                         if(this.killindicator.cnt > 0)
 980                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
 981                 }
 982                 else
 983                 {
 984                         this.killindicator.colormod = Team_ColorRGB(targetteam);
 985                         if(IS_REAL_CLIENT(this))
 986                         if(this.killindicator.cnt > 0)
 987                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
 988                 }
 989         }
 990
 991 }
 992
 993 void ClientKill (entity this)
 994 {
 995         if(gameover) return;
 996         if(this.player_blocked) return;
 997         if(STAT(FROZEN, this)) return;
 998
 999         ClientKill_TeamChange(this, 0);
1000 }
1001
1002 void FixClientCvars(entity e)
1003 {
1004         // send prediction settings to the client
1005         stuffcmd(e, "\nin_bindmap 0 0\n");
1006         if(autocvar_g_antilag == 3) // client side hitscan
1007                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1008         if(autocvar_sv_gentle)
1009                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1010
1011         MUTATOR_CALLHOOK(FixClientCvars, e);
1012 }
1013
1014 float PlayerInIDList(entity p, string idlist)
1015 {
1016         float n, i;
1017         string s;
1018
1019         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1020         if (!p.crypto_idfp)
1021                 return 0;
1022
1023         // this function allows abbreviated player IDs too!
1024         n = tokenize_console(idlist);
1025         for(i = 0; i < n; ++i)
1026         {
1027                 s = argv(i);
1028                 if(s == substring(p.crypto_idfp, 0, strlen(s)))
1029                         return 1;
1030         }
1031
1032         return 0;
1033 }
1034
1035 #ifdef DP_EXT_PRECONNECT
1036 /*
1037 =============
1038 ClientPreConnect
1039
1040 Called once (not at each match start) when a client begins a connection to the server
1041 =============
1042 */
1043 void ClientPreConnect ()
1044 {ENGINE_EVENT();
1045         if(autocvar_sv_eventlog)
1046         {
1047                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1048                         this.playerid,
1049                         etof(this),
1050                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1051                 ));
1052         }
1053 }
1054 #endif
1055
1056 /**
1057 =============
1058 ClientConnect
1059
1060 Called when a client connects to the server
1061 =============
1062 */
1063 void ClientConnect(entity this)
1064 {
1065         if (Ban_MaybeEnforceBanOnce(this)) return;
1066         assert(!IS_CLIENT(this), return);
1067         this.flags |= FL_CLIENT;
1068         assert(player_count >= 0, player_count = 0);
1069
1070 #ifdef WATERMARK
1071         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1072 #endif
1073         this.version_nagtime = time + 10 + random() * 10;
1074         TRANSMUTE(Client, this);
1075
1076         // identify the right forced team
1077         if (autocvar_g_campaign)
1078         {
1079                 if (IS_REAL_CLIENT(this)) // only players, not bots
1080                 {
1081                         switch (autocvar_g_campaign_forceteam)
1082                         {
1083                                 case 1: this.team_forced = NUM_TEAM_1; break;
1084                                 case 2: this.team_forced = NUM_TEAM_2; break;
1085                                 case 3: this.team_forced = NUM_TEAM_3; break;
1086                                 case 4: this.team_forced = NUM_TEAM_4; break;
1087                                 default: this.team_forced = 0;
1088                         }
1089                 }
1090         }
1091         else if (PlayerInIDList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1092         else if (PlayerInIDList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1093         else if (PlayerInIDList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1094         else if (PlayerInIDList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1095         else switch (autocvar_g_forced_team_otherwise)
1096         {
1097                 default: this.team_forced = 0; break;
1098                 case "red": this.team_forced = NUM_TEAM_1; break;
1099                 case "blue": this.team_forced = NUM_TEAM_2; break;
1100                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1101                 case "pink": this.team_forced = NUM_TEAM_4; break;
1102                 case "spectate":
1103                 case "spectator":
1104                         this.team_forced = -1;
1105                         break;
1106         }
1107         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1108
1109     {
1110         int id = this.playerid;
1111         this.playerid = 0; // silent
1112             JoinBestTeam(this, false, false); // if the team number is valid, keep it
1113             this.playerid = id;
1114     }
1115
1116         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1117                 TRANSMUTE(Observer, this);
1118         } else {
1119                 if (!teamplay || autocvar_g_balance_teams) {
1120                         TRANSMUTE(Player, this);
1121                         campaign_bots_may_start = true;
1122                 } else {
1123                         TRANSMUTE(Observer, this); // do it anyway
1124                 }
1125         }
1126
1127         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1128
1129         // always track bots, don't ask for cl_allow_uidtracking
1130     if (IS_BOT_CLIENT(this)) PlayerStats_GameReport_AddPlayer(this);
1131
1132         if (autocvar_sv_eventlog)
1133                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", this.netname));
1134
1135         LogTeamchange(this.playerid, this.team, 1);
1136
1137         this.just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1138
1139         this.netname_previous = strzone(this.netname);
1140
1141         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && IS_PLAYER(this)) ? APP_TEAM_ENT(this, INFO_JOIN_CONNECT_TEAM) : INFO_JOIN_CONNECT), this.netname);
1142
1143         stuffcmd(this, clientstuff, "\n");
1144         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1145
1146         FixClientCvars(this);
1147
1148         // get version info from player
1149         stuffcmd(this, "cmd clientversion $gameversion\n");
1150
1151         // notify about available teams
1152         if (teamplay)
1153         {
1154                 CheckAllowedTeams(this);
1155                 int t = 0;
1156                 if (c1 >= 0) t |= BIT(0);
1157                 if (c2 >= 0) t |= BIT(1);
1158                 if (c3 >= 0) t |= BIT(2);
1159                 if (c4 >= 0) t |= BIT(3);
1160                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1161         }
1162         else
1163         {
1164                 stuffcmd(this, "set _teams_available 0\n");
1165         }
1166
1167         bot_relinkplayerlist();
1168
1169         this.spectatortime = time;
1170         if (blockSpectators)
1171         {
1172                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1173         }
1174
1175         this.jointime = time;
1176         this.allowed_timeouts = autocvar_sv_timeout_number;
1177
1178         if (IS_REAL_CLIENT(this))
1179         {
1180                 if (!autocvar_g_campaign)
1181                 {
1182                         this.motd_actived_time = -1;
1183                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1184                 }
1185
1186                 if (g_weaponarena_weapons == WEPSET(TUBA))
1187                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1188         }
1189
1190         if (!sv_foginterval && world.fog != "")
1191                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1192
1193         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1194                 if (!g_ca && !g_cts && !g_race) // teamnagger is currently bad for ca, race & cts
1195                         send_CSQC_teamnagger();
1196
1197         CSQCMODEL_AUTOINIT(this);
1198
1199         this.model_randomizer = random();
1200
1201         if (IS_REAL_CLIENT(this))
1202                 sv_notice_join(this);
1203
1204         IL_EACH(g_initforplayer, it.init_for_player, {
1205                 it.init_for_player(it, this);
1206         });
1207
1208         MUTATOR_CALLHOOK(ClientConnect, this);
1209 }
1210 /*
1211 =============
1212 ClientDisconnect
1213
1214 Called when a client disconnects from the server
1215 =============
1216 */
1217 .entity chatbubbleentity;
1218 void ReadyCount();
1219 void ClientDisconnect(entity this)
1220 {
1221         assert(IS_CLIENT(this), return);
1222
1223         PlayerStats_GameReport_FinalizePlayer(this);
1224         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1225         if (this.active_minigame) part_minigame(this);
1226         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1227
1228         if (autocvar_sv_eventlog)
1229                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1230
1231         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1232
1233         SetSpectatee(this, NULL);
1234
1235     MUTATOR_CALLHOOK(ClientDisconnect, this);
1236
1237         ClientState_detach(this);
1238
1239         Portal_ClearAll(this);
1240
1241         Unfreeze(this);
1242
1243         RemoveGrapplingHook(this);
1244
1245         // Here, everything has been done that requires this player to be a client.
1246
1247         this.flags &= ~FL_CLIENT;
1248
1249         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1250         if (this.killindicator) delete(this.killindicator);
1251
1252         WaypointSprite_PlayerGone(this);
1253
1254         bot_relinkplayerlist();
1255
1256         if (this.netname_previous) strunzone(this.netname_previous);
1257         if (this.clientstatus) strunzone(this.clientstatus);
1258         if (this.weaponorder_byimpulse) strunzone(this.weaponorder_byimpulse);
1259         if (this.personal) delete(this.personal);
1260
1261         this.playerid = 0;
1262         ReadyCount();
1263         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1264 }
1265
1266 void ChatBubbleThink(entity this)
1267 {
1268         this.nextthink = time;
1269         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1270         {
1271                 if(this.owner) // but why can that ever be NULL?
1272                         this.owner.chatbubbleentity = NULL;
1273                 delete(this);
1274                 return;
1275         }
1276
1277         this.mdl = "";
1278
1279         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1280         {
1281                 if ( this.owner.active_minigame )
1282                         this.mdl = "models/sprites/minigame_busy.iqm";
1283                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1284                         this.mdl = "models/misc/chatbubble.spr";
1285         }
1286
1287         if ( this.model != this.mdl )
1288                 _setmodel(this, this.mdl);
1289
1290 }
1291
1292 void UpdateChatBubble(entity this)
1293 {
1294         if (this.alpha < 0)
1295                 return;
1296         // spawn a chatbubble entity if needed
1297         if (!this.chatbubbleentity)
1298         {
1299                 this.chatbubbleentity = new(chatbubbleentity);
1300                 this.chatbubbleentity.owner = this;
1301                 this.chatbubbleentity.exteriormodeltoclient = this;
1302                 setthink(this.chatbubbleentity, ChatBubbleThink);
1303                 this.chatbubbleentity.nextthink = time;
1304                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1305                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1306                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1307                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1308                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1309                 //this.chatbubbleentity.model = "";
1310                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1311         }
1312 }
1313
1314
1315 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1316 // added to the model skins
1317 /*void UpdateColorModHack()
1318 {
1319         float c;
1320         c = this.clientcolors & 15;
1321         // LordHavoc: only bothering to support white, green, red, yellow, blue
1322              if (!teamplay) this.colormod = '0 0 0';
1323         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1324         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1325         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1326         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1327         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1328         else this.colormod = '1 1 1';
1329 }*/
1330
1331 void respawn(entity this)
1332 {
1333         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1334         {
1335                 this.solid = SOLID_NOT;
1336                 this.takedamage = DAMAGE_NO;
1337                 set_movetype(this, MOVETYPE_FLY);
1338                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1339                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1340                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1341                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1342                 if(autocvar_g_respawn_ghosts_maxtime)
1343                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1344         }
1345
1346         CopyBody(this, 1);
1347
1348         this.effects |= EF_NODRAW; // prevent another CopyBody
1349         PutClientInServer(this);
1350 }
1351
1352 void play_countdown(entity this, float finished, Sound samp)
1353 {
1354     TC(Sound, samp);
1355         if(IS_REAL_CLIENT(this))
1356                 if(floor(finished - time - frametime) != floor(finished - time))
1357                         if(finished - time < 6)
1358                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1359 }
1360
1361 void player_powerups(entity this)
1362 {
1363         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1364         int items_prev = this.items;
1365
1366         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !gameover)
1367                 this.modelflags |= MF_ROCKET;
1368         else
1369                 this.modelflags &= ~MF_ROCKET;
1370
1371         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1372
1373         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1374                 return;
1375
1376         Fire_ApplyDamage(this);
1377         Fire_ApplyEffect(this);
1378
1379         if (!g_instagib)
1380         {
1381                 if (this.items & ITEM_Strength.m_itemid)
1382                 {
1383                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1384                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1385                         if (time > this.strength_finished)
1386                         {
1387                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1388                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1389                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1390                         }
1391                 }
1392                 else
1393                 {
1394                         if (time < this.strength_finished)
1395                         {
1396                                 this.items = this.items | ITEM_Strength.m_itemid;
1397                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1398                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1399                         }
1400                 }
1401                 if (this.items & ITEM_Shield.m_itemid)
1402                 {
1403                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1404                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1405                         if (time > this.invincible_finished)
1406                         {
1407                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1408                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1409                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1410                         }
1411                 }
1412                 else
1413                 {
1414                         if (time < this.invincible_finished)
1415                         {
1416                                 this.items = this.items | ITEM_Shield.m_itemid;
1417                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1418                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1419                         }
1420                 }
1421                 if (this.items & IT_SUPERWEAPON)
1422                 {
1423                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1424                         {
1425                                 this.superweapons_finished = 0;
1426                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1427                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1428                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1429                         }
1430                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1431                         {
1432                                 // don't let them run out
1433                         }
1434                         else
1435                         {
1436                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1437                                 if (time > this.superweapons_finished)
1438                                 {
1439                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1440                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1441                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1442                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1443                                 }
1444                         }
1445                 }
1446                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1447                 {
1448                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1449                         {
1450                                 this.items = this.items | IT_SUPERWEAPON;
1451                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1452                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1453                         }
1454                         else
1455                         {
1456                                 this.superweapons_finished = 0;
1457                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1458                         }
1459                 }
1460                 else
1461                 {
1462                         this.superweapons_finished = 0;
1463                 }
1464         }
1465
1466         if(autocvar_g_nodepthtestplayers)
1467                 this.effects = this.effects | EF_NODEPTHTEST;
1468
1469         if(autocvar_g_fullbrightplayers)
1470                 this.effects = this.effects | EF_FULLBRIGHT;
1471
1472         if (time >= game_starttime)
1473         if (time < this.spawnshieldtime)
1474                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1475
1476         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1477 }
1478
1479 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1480 {
1481         if(current > stable)
1482                 return current;
1483         else if(current > stable - 0.25) // when close enough, "snap"
1484                 return stable;
1485         else
1486                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1487 }
1488
1489 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1490 {
1491         if(current < stable)
1492                 return current;
1493         else if(current < stable + 0.25) // when close enough, "snap"
1494                 return stable;
1495         else
1496                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1497 }
1498
1499 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1500 {
1501         if(current > rotstable)
1502         {
1503                 if(rotframetime > 0)
1504                 {
1505                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1506                         current = max(rotstable, current - rotlinear * rotframetime);
1507                 }
1508         }
1509         else if(current < regenstable)
1510         {
1511                 if(regenframetime > 0)
1512                 {
1513                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1514                         current = min(regenstable, current + regenlinear * regenframetime);
1515                 }
1516         }
1517
1518         if(current > limit)
1519                 current = limit;
1520
1521         return current;
1522 }
1523
1524 void player_regen(entity this)
1525 {
1526         float max_mod, regen_mod, rot_mod, limit_mod;
1527         max_mod = regen_mod = rot_mod = limit_mod = 1;
1528
1529         float regen_health = autocvar_g_balance_health_regen;
1530         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1531         float regen_health_rot = autocvar_g_balance_health_rot;
1532         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1533         float regen_health_stable = autocvar_g_balance_health_regenstable;
1534         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1535         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1536                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1537         max_mod = M_ARGV(1, float);
1538         regen_mod = M_ARGV(2, float);
1539         rot_mod = M_ARGV(3, float);
1540         limit_mod = M_ARGV(4, float);
1541         regen_health = M_ARGV(5, float);
1542         regen_health_linear = M_ARGV(6, float);
1543         regen_health_rot = M_ARGV(7, float);
1544         regen_health_rotlinear = M_ARGV(8, float);
1545         regen_health_stable = M_ARGV(9, float);
1546         regen_health_rotstable = M_ARGV(10, float);
1547
1548
1549         if(!mutator_returnvalue)
1550         if(!STAT(FROZEN, this))
1551         {
1552                 float mina, maxa, limith, limita;
1553                 maxa = autocvar_g_balance_armor_rotstable;
1554                 mina = autocvar_g_balance_armor_regenstable;
1555                 limith = autocvar_g_balance_health_limit;
1556                 limita = autocvar_g_balance_armor_limit;
1557
1558                 regen_health_rotstable = regen_health_rotstable * max_mod;
1559                 regen_health_stable = regen_health_stable * max_mod;
1560                 limith = limith * limit_mod;
1561                 limita = limita * limit_mod;
1562
1563                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1564                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1565         }
1566
1567         // if player rotted to death...  die!
1568         // check this outside above checks, as player may still be able to rot to death
1569         if(this.health < 1)
1570         {
1571                 if(this.vehicle)
1572                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1573                 if(this.event_damage)
1574                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, this.origin, '0 0 0');
1575         }
1576
1577         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1578         {
1579                 float minf, maxf, limitf;
1580
1581                 maxf = autocvar_g_balance_fuel_rotstable;
1582                 minf = autocvar_g_balance_fuel_regenstable;
1583                 limitf = autocvar_g_balance_fuel_limit;
1584
1585                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1586         }
1587 }
1588
1589 bool zoomstate_set;
1590 void SetZoomState(entity this, float z)
1591 {
1592         if(z != this.zoomstate)
1593         {
1594                 this.zoomstate = z;
1595                 ClientData_Touch(this);
1596         }
1597         zoomstate_set = true;
1598 }
1599
1600 void GetPressedKeys(entity this)
1601 {
1602         MUTATOR_CALLHOOK(GetPressedKeys, this);
1603         int keys = this.pressedkeys;
1604         keys = BITSET(keys, KEY_FORWARD,        this.movement.x > 0);
1605         keys = BITSET(keys, KEY_BACKWARD,       this.movement.x < 0);
1606         keys = BITSET(keys, KEY_RIGHT,          this.movement.y > 0);
1607         keys = BITSET(keys, KEY_LEFT,           this.movement.y < 0);
1608
1609         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1610         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1611         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1612         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1613         this.pressedkeys = keys;
1614 }
1615
1616 /*
1617 ======================
1618 spectate mode routines
1619 ======================
1620 */
1621
1622 void SpectateCopy(entity this, entity spectatee)
1623 {
1624     TC(Client, this); TC(Client, spectatee);
1625
1626         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1627         PS(this) = PS(spectatee);
1628         this.armortype = spectatee.armortype;
1629         this.armorvalue = spectatee.armorvalue;
1630         this.ammo_cells = spectatee.ammo_cells;
1631         this.ammo_plasma = spectatee.ammo_plasma;
1632         this.ammo_shells = spectatee.ammo_shells;
1633         this.ammo_nails = spectatee.ammo_nails;
1634         this.ammo_rockets = spectatee.ammo_rockets;
1635         this.ammo_fuel = spectatee.ammo_fuel;
1636         this.clip_load = spectatee.clip_load;
1637         this.clip_size = spectatee.clip_size;
1638         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1639         this.health = spectatee.health;
1640         this.impulse = 0;
1641         this.items = spectatee.items;
1642         this.last_pickup = spectatee.last_pickup;
1643         this.hit_time = spectatee.hit_time;
1644         this.strength_finished = spectatee.strength_finished;
1645         this.invincible_finished = spectatee.invincible_finished;
1646         this.pressedkeys = spectatee.pressedkeys;
1647         this.weapons = spectatee.weapons;
1648         this.vortex_charge = spectatee.vortex_charge;
1649         this.vortex_chargepool_ammo = spectatee.vortex_chargepool_ammo;
1650         this.hagar_load = spectatee.hagar_load;
1651         this.arc_heat_percent = spectatee.arc_heat_percent;
1652         this.minelayer_mines = spectatee.minelayer_mines;
1653         this.punchangle = spectatee.punchangle;
1654         this.view_ofs = spectatee.view_ofs;
1655         this.velocity = spectatee.velocity;
1656         this.dmg_take = spectatee.dmg_take;
1657         this.dmg_save = spectatee.dmg_save;
1658         this.dmg_inflictor = spectatee.dmg_inflictor;
1659         this.v_angle = spectatee.v_angle;
1660         this.angles = spectatee.v_angle;
1661         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1662         this.revive_progress = spectatee.revive_progress;
1663         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1664                 this.fixangle = true;
1665         setorigin(this, spectatee.origin);
1666         setsize(this, spectatee.mins, spectatee.maxs);
1667         SetZoomState(this, spectatee.zoomstate);
1668
1669     anticheat_spectatecopy(this, spectatee);
1670         this.hud = spectatee.hud;
1671         if(spectatee.vehicle)
1672     {
1673         this.angles = spectatee.v_angle;
1674
1675         //this.fixangle = false;
1676         //this.velocity = spectatee.vehicle.velocity;
1677         this.vehicle_health = spectatee.vehicle_health;
1678         this.vehicle_shield = spectatee.vehicle_shield;
1679         this.vehicle_energy = spectatee.vehicle_energy;
1680         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1681         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1682         this.vehicle_reload1 = spectatee.vehicle_reload1;
1683         this.vehicle_reload2 = spectatee.vehicle_reload2;
1684
1685         //msg_entity = this;
1686
1687        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1688             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1689            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1690            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1691
1692         //WriteByte (MSG_ONE, SVC_SETVIEW);
1693         //    WriteEntity(MSG_ONE, this);
1694         //makevectors(spectatee.v_angle);
1695         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1696     }
1697 }
1698
1699 bool SpectateUpdate(entity this)
1700 {
1701         if(!this.enemy)
1702             return false;
1703
1704         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1705         {
1706                 SetSpectatee(this, NULL);
1707                 return false;
1708         }
1709
1710         SpectateCopy(this, this.enemy);
1711
1712         return true;
1713 }
1714
1715 bool SpectateSet(entity this)
1716 {
1717         if(!IS_PLAYER(this.enemy))
1718                 return false;
1719
1720         ClientData_Touch(this.enemy);
1721
1722         msg_entity = this;
1723         WriteByte(MSG_ONE, SVC_SETVIEW);
1724         WriteEntity(MSG_ONE, this.enemy);
1725         set_movetype(this, MOVETYPE_NONE);
1726         accuracy_resend(this);
1727
1728         if(!SpectateUpdate(this))
1729                 PutObserverInServer(this);
1730
1731         return true;
1732 }
1733
1734 void SetSpectatee(entity this, entity spectatee)
1735 {
1736         entity old_spectatee = this.enemy;
1737
1738         this.enemy = spectatee;
1739
1740         // WEAPONTODO
1741         // these are required to fix the spectator bug with arc
1742         if(old_spectatee)
1743         {
1744                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1745                 {
1746                         .entity weaponentity = weaponentities[slot];
1747                         if(old_spectatee.(weaponentity).arc_beam)
1748                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1749                 }
1750         }
1751         if(this.enemy)
1752         {
1753                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1754                 {
1755                         .entity weaponentity = weaponentities[slot];
1756                         if(this.enemy.(weaponentity).arc_beam)
1757                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1758                 }
1759         }
1760
1761         // needed to update spectator list
1762         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1763 }
1764
1765 bool Spectate(entity this, entity pl)
1766 {
1767         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1768                 return false;
1769         pl = M_ARGV(1, entity);
1770
1771         SetSpectatee(this, pl);
1772         return SpectateSet(this);
1773 }
1774
1775 bool SpectateNext(entity this)
1776 {
1777         entity ent = find(this.enemy, classname, STR_PLAYER);
1778
1779         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1780                 ent = M_ARGV(1, entity);
1781         else if (!ent)
1782                 ent = find(ent, classname, STR_PLAYER);
1783
1784         if(ent) { SetSpectatee(this, ent); }
1785
1786         return SpectateSet(this);
1787 }
1788
1789 bool SpectatePrev(entity this)
1790 {
1791         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1792         entity ent = findchain(classname, STR_PLAYER);
1793         if (!ent) // no player
1794                 return false;
1795
1796         entity first = ent;
1797         // skip players until current spectated player
1798         if(this.enemy)
1799         while(ent && ent != this.enemy)
1800                 ent = ent.chain;
1801
1802         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1803         {
1804                 case MUT_SPECPREV_FOUND:
1805                     ent = M_ARGV(1, entity);
1806                     break;
1807                 case MUT_SPECPREV_RETURN:
1808                     return true;
1809                 case MUT_SPECPREV_CONTINUE:
1810                 default:
1811                 {
1812                         if(ent.chain)
1813                                 ent = ent.chain;
1814                         else
1815                                 ent = first;
1816                         break;
1817                 }
1818         }
1819
1820         SetSpectatee(this, ent);
1821         return SpectateSet(this);
1822 }
1823
1824 /*
1825 =============
1826 ShowRespawnCountdown()
1827
1828 Update a respawn countdown display.
1829 =============
1830 */
1831 void ShowRespawnCountdown(entity this)
1832 {
1833         float number;
1834         if(!IS_DEAD(this)) // just respawned?
1835                 return;
1836         else
1837         {
1838                 number = ceil(this.respawn_time - time);
1839                 if(number <= 0)
1840                         return;
1841                 if(number <= this.respawn_countdown)
1842                 {
1843                         this.respawn_countdown = number - 1;
1844                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1845                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1846                 }
1847         }
1848 }
1849
1850 .float caplayer;
1851
1852 void LeaveSpectatorMode(entity this)
1853 {
1854         if(this.caplayer)
1855                 return;
1856         if(nJoinAllowed(this, this))
1857         {
1858                 if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || (this.wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1859                 {
1860                         TRANSMUTE(Player, this);
1861
1862                         SetSpectatee(this, NULL);
1863
1864                         if(autocvar_g_campaign || autocvar_g_balance_teams)
1865                                 { JoinBestTeam(this, false, true); }
1866
1867                         if(autocvar_g_campaign)
1868                                 { campaign_bots_may_start = true; }
1869
1870                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
1871
1872                         PutClientInServer(this);
1873
1874                         if(IS_PLAYER(this)) { Send_Notification(NOTIF_ALL, NULL, MSG_INFO, ((teamplay && this.team != -1) ? APP_TEAM_ENT(this, INFO_JOIN_PLAY_TEAM) : INFO_JOIN_PLAY), this.netname); }
1875                 }
1876                 else
1877                         stuffcmd(this, "menu_showteamselect\n");
1878         }
1879         else
1880         {
1881                 // Player may not join because g_maxplayers is set
1882                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
1883         }
1884 }
1885
1886 /**
1887  * Determines whether the player is allowed to join. This depends on cvar
1888  * g_maxplayers, if it isn't used this function always return true, otherwise
1889  * it checks whether the number of currently playing players exceeds g_maxplayers.
1890  * @return int number of free slots for players, 0 if none
1891  */
1892 bool nJoinAllowed(entity this, entity ignore)
1893 {
1894         if(!ignore)
1895         // this is called that way when checking if anyone may be able to join (to build qcstatus)
1896         // so report 0 free slots if restricted
1897         {
1898                 if(autocvar_g_forced_team_otherwise == "spectate")
1899                         return false;
1900                 if(autocvar_g_forced_team_otherwise == "spectator")
1901                         return false;
1902         }
1903
1904         if(this.team_forced < 0)
1905                 return false; // forced spectators can never join
1906
1907         // TODO simplify this
1908         int totalClients = 0;
1909         int currentlyPlaying = 0;
1910         FOREACH_CLIENT(true, LAMBDA(
1911                 if(it != ignore)
1912                         ++totalClients;
1913                 if(IS_REAL_CLIENT(it))
1914                 if(IS_PLAYER(it) || it.caplayer)
1915                         ++currentlyPlaying;
1916         ));
1917
1918         if (!autocvar_g_maxplayers)
1919                 return maxclients - totalClients;
1920
1921         if(currentlyPlaying < autocvar_g_maxplayers)
1922                 return min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
1923
1924         return false;
1925 }
1926
1927 /**
1928  * Checks whether the client is an observer or spectator, if so, he will get kicked after
1929  * g_maxplayers_spectator_blocktime seconds
1930  */
1931 void checkSpectatorBlock(entity this)
1932 {
1933         if(IS_SPEC(this) || IS_OBSERVER(this))
1934         if(!this.caplayer)
1935         if(IS_REAL_CLIENT(this))
1936         {
1937                 if( time > (this.spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
1938                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
1939                         dropclient(this);
1940                 }
1941         }
1942 }
1943
1944 void PrintWelcomeMessage(entity this)
1945 {
1946         if(this.motd_actived_time == 0)
1947         {
1948                 if (autocvar_g_campaign) {
1949                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
1950                                 this.motd_actived_time = time;
1951                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
1952                         }
1953                 } else {
1954                         if (PHYS_INPUT_BUTTON_INFO(this)) {
1955                                 this.motd_actived_time = time;
1956                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1957                         }
1958                 }
1959         }
1960         else if(this.motd_actived_time > 0) // showing MOTD or campaign message
1961         {
1962                 if (autocvar_g_campaign) {
1963                         if (PHYS_INPUT_BUTTON_INFO(this))
1964                                 this.motd_actived_time = time;
1965                         else if ((time - this.motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
1966                                 this.motd_actived_time = 0;
1967                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1968                         }
1969                 } else {
1970                         if (PHYS_INPUT_BUTTON_INFO(this))
1971                                 this.motd_actived_time = time;
1972                         else if (time - this.motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
1973                                 this.motd_actived_time = 0;
1974                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1975                         }
1976                 }
1977         }
1978         else //if(this.motd_actived_time < 0) // just connected, motd is active
1979         {
1980                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
1981                         this.motd_actived_time = -2; // wait until BUTTON_INFO gets released
1982                 else if(this.motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
1983                 {
1984                         // instanctly hide MOTD
1985                         this.motd_actived_time = 0;
1986                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
1987                 }
1988         }
1989 }
1990
1991 void ObserverThink(entity this)
1992 {
1993         if ( this.impulse )
1994         {
1995                 MinigameImpulse(this, this.impulse);
1996                 this.impulse = 0;
1997         }
1998         if (this.flags & FL_JUMPRELEASED) {
1999                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2000                         this.flags &= ~FL_JUMPRELEASED;
2001                         this.flags |= FL_SPAWNING;
2002                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !this.version_mismatch) {
2003                         this.flags &= ~FL_JUMPRELEASED;
2004                         if(SpectateNext(this)) {
2005                                 TRANSMUTE(Spectator, this);
2006                         }
2007                 } else {
2008                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? this.cvar_cl_clippedspectating : !this.cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2009                         set_movetype(this, preferred_movetype);
2010                 }
2011         } else {
2012                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2013                         this.flags |= FL_JUMPRELEASED;
2014                         if(this.flags & FL_SPAWNING)
2015                         {
2016                                 this.flags &= ~FL_SPAWNING;
2017                                 LeaveSpectatorMode(this);
2018                                 return;
2019                         }
2020                 }
2021         }
2022 }
2023
2024 void SpectatorThink(entity this)
2025 {
2026         if ( this.impulse )
2027         {
2028                 if(MinigameImpulse(this, this.impulse))
2029                         this.impulse = 0;
2030
2031                 if (this.impulse == IMP_weapon_drop.impulse)
2032                 {
2033                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2034                         this.impulse = 0;
2035                         return;
2036                 }
2037         }
2038         if (this.flags & FL_JUMPRELEASED) {
2039                 if (PHYS_INPUT_BUTTON_JUMP(this) && !this.version_mismatch) {
2040                         this.flags &= ~FL_JUMPRELEASED;
2041                         this.flags |= FL_SPAWNING;
2042                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || this.impulse == 10 || this.impulse == 15 || this.impulse == 18 || (this.impulse >= 200 && this.impulse <= 209)) {
2043                         this.flags &= ~FL_JUMPRELEASED;
2044                         if(SpectateNext(this)) {
2045                                 TRANSMUTE(Spectator, this);
2046                         } else {
2047                                 TRANSMUTE(Observer, this);
2048                                 PutClientInServer(this);
2049                         }
2050                         this.impulse = 0;
2051                 } else if(this.impulse == 12 || this.impulse == 16  || this.impulse == 19 || (this.impulse >= 220 && this.impulse <= 229)) {
2052                         this.flags &= ~FL_JUMPRELEASED;
2053                         if(SpectatePrev(this)) {
2054                                 TRANSMUTE(Spectator, this);
2055                         } else {
2056                                 TRANSMUTE(Observer, this);
2057                                 PutClientInServer(this);
2058                         }
2059                         this.impulse = 0;
2060                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2061                         this.flags &= ~FL_JUMPRELEASED;
2062                         TRANSMUTE(Observer, this);
2063                         PutClientInServer(this);
2064                 } else {
2065                         if(!SpectateUpdate(this))
2066                                 PutObserverInServer(this);
2067                 }
2068         } else {
2069                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2070                         this.flags |= FL_JUMPRELEASED;
2071                         if(this.flags & FL_SPAWNING)
2072                         {
2073                                 this.flags &= ~FL_SPAWNING;
2074                                 LeaveSpectatorMode(this);
2075                                 return;
2076                         }
2077                 }
2078                 if(!SpectateUpdate(this))
2079                         PutObserverInServer(this);
2080         }
2081
2082         this.flags |= FL_CLIENT | FL_NOTARGET;
2083 }
2084
2085 void vehicles_enter (entity pl, entity veh);
2086 void PlayerUseKey(entity this)
2087 {
2088         if (!IS_PLAYER(this))
2089                 return;
2090
2091         if(this.vehicle)
2092         {
2093                 if(!gameover)
2094                 {
2095                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2096                         return;
2097                 }
2098         }
2099         else if(autocvar_g_vehicles_enter)
2100         {
2101                 if(!STAT(FROZEN, this))
2102                 if(!IS_DEAD(this))
2103                 if(!gameover)
2104                 {
2105                         entity head, closest_target = NULL;
2106                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2107
2108                         while(head) // find the closest acceptable target to enter
2109                         {
2110                                 if(IS_VEHICLE(head))
2111                                 if(!IS_DEAD(head))
2112                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2113                                 if(head.takedamage != DAMAGE_NO)
2114                                 {
2115                                         if(closest_target)
2116                                         {
2117                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2118                                                 { closest_target = head; }
2119                                         }
2120                                         else { closest_target = head; }
2121                                 }
2122
2123                                 head = head.chain;
2124                         }
2125
2126                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2127                 }
2128         }
2129
2130         // a use key was pressed; call handlers
2131         MUTATOR_CALLHOOK(PlayerUseKey, this);
2132 }
2133
2134
2135 /*
2136 =============
2137 PlayerPreThink
2138
2139 Called every frame for each client before the physics are run
2140 =============
2141 */
2142 .float usekeypressed;
2143 .float last_vehiclecheck;
2144 .int items_added;
2145 void PlayerPreThink (entity this)
2146 {
2147         WarpZone_PlayerPhysics_FixVAngle(this);
2148
2149     STAT(GAMESTARTTIME, this) = game_starttime;
2150         STAT(ROUNDSTARTTIME, this) = round_starttime;
2151         STAT(ALLOW_OLDVORTEXBEAM, this) = autocvar_g_allow_oldvortexbeam;
2152         STAT(LEADLIMIT, this) = autocvar_leadlimit;
2153
2154         STAT(WEAPONSINMAP, this) = weaponsInMap;
2155
2156         if (frametime) {
2157                 // physics frames: update anticheat stuff
2158                 anticheat_prethink(this);
2159         }
2160
2161         if (blockSpectators && frametime) {
2162                 // WORKAROUND: only use dropclient in server frames (frametime set).
2163                 // Never use it in cl_movement frames (frametime zero).
2164                 checkSpectatorBlock(this);
2165     }
2166
2167         zoomstate_set = false;
2168
2169         // Check for nameless players
2170         if (isInvisibleString(this.netname)) {
2171                 this.netname = strzone(sprintf("Player#%d", this.playerid));
2172                 // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2173         }
2174         if (this.netname != this.netname_previous) {
2175                 if (autocvar_sv_eventlog) {
2176                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", this.netname));
2177         }
2178                 if (this.netname_previous) strunzone(this.netname_previous);
2179                 this.netname_previous = strzone(this.netname);
2180         }
2181
2182         // version nagging
2183         if (this.version_nagtime && this.cvar_g_xonoticversion && time > this.version_nagtime) {
2184         this.version_nagtime = 0;
2185         if (strstrofs(this.cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(this.cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2186             // git client
2187         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2188             // git server
2189             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2190         } else {
2191             int r = vercmp(this.cvar_g_xonoticversion, autocvar_g_xonoticversion);
2192             if (r < 0) { // old client
2193                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2194             } else if (r > 0) { // old server
2195                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, this.cvar_g_xonoticversion);
2196             }
2197         }
2198     }
2199
2200         // GOD MODE info
2201         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2202         {
2203                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2204                 this.max_armorvalue = 0;
2205         }
2206
2207         if (STAT(FROZEN, this) == 2)
2208         {
2209                 this.revive_progress = bound(0, this.revive_progress + frametime * this.revive_speed, 1);
2210                 this.health = max(1, this.revive_progress * start_health);
2211                 this.iceblock.alpha = bound(0.2, 1 - this.revive_progress, 1);
2212
2213                 if (this.revive_progress >= 1)
2214                         Unfreeze(this);
2215         }
2216         else if (STAT(FROZEN, this) == 3)
2217         {
2218                 this.revive_progress = bound(0, this.revive_progress - frametime * this.revive_speed, 1);
2219                 this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * this.revive_progress );
2220
2221                 if (this.health < 1)
2222                 {
2223                         if (this.vehicle)
2224                                 vehicles_exit(this.vehicle, VHEF_RELEASE);
2225                         if(this.event_damage)
2226                                 this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, this.origin, '0 0 0');
2227                 }
2228                 else if (this.revive_progress <= 0)
2229                         Unfreeze(this);
2230         }
2231
2232         MUTATOR_CALLHOOK(PlayerPreThink, this);
2233
2234         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !gameover && !this.vehicle)
2235         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2236         {
2237                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2238                 {
2239                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2240                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2241                         {
2242                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2243                         }
2244                         else if(!it.owner)
2245                         {
2246                                 if(!it.team || SAME_TEAM(this, it))
2247                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2248                                 else if(autocvar_g_vehicles_steal)
2249                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2250                         }
2251                 });
2252
2253                 this.last_vehiclecheck = time + 1;
2254         }
2255
2256         if(!this.cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2257         {
2258                 if(PHYS_INPUT_BUTTON_USE(this) && !this.usekeypressed)
2259                         PlayerUseKey(this);
2260                 this.usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2261         }
2262
2263         if (IS_REAL_CLIENT(this))
2264                 PrintWelcomeMessage(this);
2265
2266         if (IS_PLAYER(this)) {
2267                 CheckRules_Player(this);
2268
2269                 if (intermission_running) {
2270                         IntermissionThink(this);
2271                         return;
2272                 }
2273
2274                 if (timeout_status == TIMEOUT_ACTIVE) {
2275             // don't allow the player to turn around while game is paused
2276                         // FIXME turn this into CSQC stuff
2277                         this.v_angle = this.lastV_angle;
2278                         this.angles = this.lastV_angle;
2279                         this.fixangle = true;
2280                 }
2281
2282                 if (frametime) player_powerups(this);
2283
2284                 if (IS_DEAD(this)) {
2285                         if (this.personal && g_race_qualifying) {
2286                                 if (time > this.respawn_time) {
2287                                         STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2288                                         respawn(this);
2289                                         this.impulse = CHIMPULSE_SPEEDRUN.impulse;
2290                                 }
2291                         } else {
2292                                 if (frametime) player_anim(this);
2293                                 bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2294
2295                                 switch(this.deadflag)
2296                                 {
2297                                         case DEAD_DYING:
2298                                         {
2299                                                 if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2300                                                         this.deadflag = DEAD_RESPAWNING;
2301                                                 else if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2302                                                         this.deadflag = DEAD_DEAD;
2303                                                 break;
2304                                         }
2305                                         case DEAD_DEAD:
2306                                         {
2307                                                 if (button_pressed)
2308                                                         this.deadflag = DEAD_RESPAWNABLE;
2309                                                 else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2310                                                         this.deadflag = DEAD_RESPAWNING;
2311                                                 break;
2312                                         }
2313                                         case DEAD_RESPAWNABLE:
2314                                         {
2315                                                 if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2316                                                         this.deadflag = DEAD_RESPAWNING;
2317                                                 break;
2318                                         }
2319                                         case DEAD_RESPAWNING:
2320                                         {
2321                                                 if (time > this.respawn_time)
2322                                                 {
2323                                                         this.respawn_time = time + 1; // only retry once a second
2324                                                         this.respawn_time_max = this.respawn_time;
2325                                                         respawn(this);
2326                                                 }
2327                                                 break;
2328                                         }
2329                                 }
2330
2331                                 ShowRespawnCountdown(this);
2332
2333                                 if (this.respawn_flags & RESPAWN_SILENT)
2334                                         STAT(RESPAWN_TIME, this) = 0;
2335                                 else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2336                                 {
2337                                         if (time < this.respawn_time)
2338                                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2339                                         else if (this.deadflag != DEAD_RESPAWNING)
2340                                                 STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2341                                 }
2342                                 else
2343                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2344                         }
2345
2346                         // if respawning, invert stat_respawn_time to indicate this, the client translates it
2347                         if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2348                                 STAT(RESPAWN_TIME, this) *= -1;
2349
2350                         return;
2351                 }
2352
2353                 this.prevorigin = this.origin;
2354
2355                 bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2356                 if (this.hook.state) {
2357                         do_crouch = false;
2358                 } else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2359                         do_crouch = false;
2360                 } else if (this.vehicle) {
2361                         do_crouch = false;
2362                 } else if (STAT(FROZEN, this)) {
2363                         do_crouch = false;
2364         }
2365
2366                 if (do_crouch) {
2367                         if (!this.crouch) {
2368                                 this.crouch = true;
2369                                 this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2370                                 setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2371                                 // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2372                         }
2373                 } else if (this.crouch) {
2374             tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2375             if (!trace_startsolid) {
2376                 this.crouch = false;
2377                 this.view_ofs = STAT(PL_VIEW_OFS, this);
2378                 setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2379             }
2380                 }
2381
2382                 FixPlayermodel(this);
2383
2384                 // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2385                 //if(frametime)
2386                 {
2387                         this.items &= ~this.items_added;
2388
2389                         //for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2390                         //{
2391                                 //.entity weaponentity = weaponentities[slot];
2392                                 //W_WeaponFrame(this, weaponentity);
2393                         //}
2394                         .entity weaponentity = weaponentities[0]; // TODO
2395                         W_WeaponFrame(this, weaponentity);
2396
2397                         this.items_added = 0;
2398                         if (this.items & ITEM_Jetpack.m_itemid && (this.items & ITEM_JetpackRegen.m_itemid || this.ammo_fuel >= 0.01))
2399                 this.items_added |= IT_FUEL;
2400
2401                         this.items |= this.items_added;
2402                 }
2403
2404                 player_regen(this);
2405
2406                 // WEAPONTODO: Add a weapon request for this
2407                 // rot vortex charge to the charge limit
2408                 if (WEP_CVAR(vortex, charge_rot_rate) && this.vortex_charge > WEP_CVAR(vortex, charge_limit) && this.vortex_charge_rottime < time)
2409                         this.vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2410
2411                 if (frametime) player_anim(this);
2412
2413                 // secret status
2414                 secrets_setstatus(this);
2415
2416                 // monsters status
2417                 monsters_setstatus(this);
2418
2419                 this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2420         }
2421         else if (gameover) {
2422                 if (intermission_running) IntermissionThink(this);
2423                 return;
2424         }
2425         else if (IS_OBSERVER(this)) {
2426                 ObserverThink(this);
2427         }
2428         else if (IS_SPEC(this)) {
2429                 SpectatorThink(this);
2430         }
2431
2432         // WEAPONTODO: Add weapon request for this
2433         if (!zoomstate_set) {
2434                 SetZoomState(this,
2435                         PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this)
2436                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_VORTEX)
2437                         || (PHYS_INPUT_BUTTON_ATCK2(this) && PS(this).m_weapon == WEP_RIFLE && WEP_CVAR(rifle, secondary) == 0)
2438                 );
2439     }
2440
2441         int oldspectatee_status = this.spectatee_status;
2442         if (IS_SPEC(this)) {
2443                 this.spectatee_status = etof(this.enemy);
2444         } else if (IS_OBSERVER(this)) {
2445                 this.spectatee_status = etof(this);
2446         } else {
2447                 this.spectatee_status = 0;
2448     }
2449         if (this.spectatee_status != oldspectatee_status) {
2450                 ClientData_Touch(this);
2451                 if (g_race || g_cts) race_InitSpectator();
2452         }
2453
2454         if (this.teamkill_soundtime && time > this.teamkill_soundtime)
2455         {
2456                 this.teamkill_soundtime = 0;
2457
2458                 entity e = this.teamkill_soundsource;
2459                 entity oldpusher = e.pusher;
2460                 e.pusher = this;
2461                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2462                 e.pusher = oldpusher;
2463         }
2464
2465         if (this.taunt_soundtime && time > this.taunt_soundtime) {
2466                 this.taunt_soundtime = 0;
2467                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2468         }
2469
2470         target_voicescript_next(this);
2471
2472         // WEAPONTODO: Move into weaponsystem somehow
2473         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2474         if (PS(this).m_weapon == WEP_Null)
2475                 this.clip_load = this.clip_size = 0;
2476 }
2477
2478 void DrownPlayer(entity this)
2479 {
2480         if(IS_DEAD(this))
2481                 return;
2482
2483         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2484         {
2485                 if(this.air_finished < time)
2486                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2487                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2488                 this.dmg = 2;
2489         }
2490         else if (this.air_finished < time)
2491         {       // drown!
2492                 if (this.pain_finished < time)
2493                 {
2494                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, this.origin, '0 0 0');
2495                         this.pain_finished = time + 0.5;
2496                 }
2497         }
2498 }
2499
2500 .bool move_qcphysics;
2501
2502 void Player_Physics(entity this)
2503 {
2504         set_movetype(this, ((this.move_qcphysics) ? MOVETYPE_NONE : this.move_movetype));
2505
2506         if(!this.move_qcphysics)
2507                 return;
2508
2509         int mt = this.move_movetype;
2510
2511         if(mt == MOVETYPE_PUSH || mt == MOVETYPE_FAKEPUSH || mt == MOVETYPE_PHYSICS)
2512         {
2513                 this.move_qcphysics = false;
2514                 set_movetype(this, mt);
2515                 return;
2516         }
2517
2518         if(!frametime && !this.pm_frametime)
2519                 return;
2520
2521         Movetype_Physics_NoMatchTicrate(this, this.pm_frametime, true);
2522
2523         this.pm_frametime = 0;
2524 }
2525
2526 /*
2527 =============
2528 PlayerPostThink
2529
2530 Called every frame for each client after the physics are run
2531 =============
2532 */
2533 .float idlekick_lasttimeleft;
2534 void PlayerPostThink (entity this)
2535 {
2536         Player_Physics(this);
2537
2538         if (sv_maxidle > 0)
2539         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2540         if (IS_REAL_CLIENT(this))
2541         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2542         {
2543                 int totalClients = 0;
2544                 if(sv_maxidle_slots > 0)
2545                 {
2546                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2547                         {
2548                                 ++totalClients;
2549                         });
2550                 }
2551
2552                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2553                 { /* do nothing */ }
2554                 else if (time - this.parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2555                 {
2556                         if (this.idlekick_lasttimeleft)
2557                         {
2558                                 this.idlekick_lasttimeleft = 0;
2559                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2560                         }
2561                 }
2562                 else
2563                 {
2564                         float timeleft = ceil(sv_maxidle - (time - this.parm_idlesince));
2565                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2566                                 if (!this.idlekick_lasttimeleft)
2567                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2568                         }
2569                         if (timeleft <= 0) {
2570                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2571                                 dropclient(this);
2572                                 return;
2573                         }
2574                         else if (timeleft <= 10) {
2575                                 if (timeleft != this.idlekick_lasttimeleft) {
2576                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2577                 }
2578                                 this.idlekick_lasttimeleft = timeleft;
2579                         }
2580                 }
2581         }
2582
2583         CheatFrame(this);
2584
2585         //CheckPlayerJump();
2586
2587         if (IS_PLAYER(this)) {
2588                 DrownPlayer(this);
2589                 CheckRules_Player(this);
2590                 UpdateChatBubble(this);
2591                 if (this.impulse) ImpulseCommands(this);
2592                 if (intermission_running) return; // intermission or finale
2593                 GetPressedKeys(this);
2594         }
2595
2596         if (this.waypointsprite_attachedforcarrier) {
2597             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2598                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2599     }
2600
2601         playerdemo_write(this);
2602
2603         CSQCMODEL_AUTOUPDATE(this);
2604 }