qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "playerdemo.qh"
  14 #include "spawnpoints.qh"
  15 #include "resources.qh"
  16 #include "g_damage.qh"
  17 #include "handicap.qh"
  18 #include "g_hook.qh"
  19 #include "command/common.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/triggers/func/conveyor.qh"
  37 #include "../common/triggers/teleporters.qh"
  38 #include "../common/triggers/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include "../common/items/_mod.qh"
  50
  51 #include "../common/mutators/mutator/waypoints/all.qh"
  52
  53 #include "../common/triggers/subs.qh"
  54 #include "../common/triggers/triggers.qh"
  55 #include "../common/triggers/trigger/secret.qh"
  56
  57 #include "../common/minigames/sv_minigames.qh"
  58
  59 #include "../common/items/inventory.qh"
  60
  61 #include "../common/monsters/sv_monsters.qh"
  62
  63 #include "../lib/warpzone/server.qh"
  64
  65 STATIC_METHOD(Client, Add, void(Client this, int _team))
  66 {
  67     ClientConnect(this);
  68     TRANSMUTE(Player, this);
  69     this.frame = 12; // 7
  70     this.team = _team;
  71     PutClientInServer(this);
  72 }
  73
  74 void PutObserverInServer(entity this);
  75
  76 STATIC_METHOD(Client, Remove, void(Client this))
  77 {
  78     TRANSMUTE(Observer, this);
  79     PutClientInServer(this);
  80     ClientDisconnect(this);
  81 }
  82
  83 void send_CSQC_teamnagger() {
  84         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  85 }
  86
  87 int CountSpectators(entity player, entity to)
  88 {
  89         if(!player) { return 0; } // not sure how, but best to be safe
  90
  91         int spec_count = 0;
  92
  93         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  94         {
  95                 spec_count++;
  96         });
  97
  98         return spec_count;
  99 }
 100
 101 void WriteSpectators(entity player, entity to)
 102 {
 103         if(!player) { return; } // not sure how, but best to be safe
 104
 105         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 106         {
 107                 WriteByte(MSG_ENTITY, num_for_edict(it));
 108         });
 109 }
 110
 111 bool ClientData_Send(entity this, entity to, int sf)
 112 {
 113         assert(to == this.owner, return false);
 114
 115         entity e = to;
 116         if (IS_SPEC(e)) e = e.enemy;
 117
 118         sf = 0;
 119         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 120         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 121         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 122         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 123
 124         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 125         WriteByte(MSG_ENTITY, sf);
 126
 127         if (sf & BIT(1))
 128                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 129
 130         if(sf & BIT(4))
 131         {
 132                 float specs = CountSpectators(e, to);
 133                 WriteByte(MSG_ENTITY, specs);
 134                 WriteSpectators(e, to);
 135         }
 136
 137         return true;
 138 }
 139
 140 void ClientData_Attach(entity this)
 141 {
 142         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 143         CS(this).clientdata.drawonlytoclient = this;
 144         CS(this).clientdata.owner = this;
 145 }
 146
 147 void ClientData_Detach(entity this)
 148 {
 149         delete(CS(this).clientdata);
 150         CS(this).clientdata = NULL;
 151 }
 152
 153 void ClientData_Touch(entity e)
 154 {
 155         CS(e).clientdata.SendFlags = 1;
 156
 157         // make it spectatable
 158         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e, { CS(it).clientdata.SendFlags = 1; });
 159 }
 160
 161 void SetSpectatee(entity this, entity spectatee);
 162 void SetSpectatee_status(entity this, int spectatee_num);
 163
 164
 165 /*
 166 =============
 167 CheckPlayerModel
 168
 169 Checks if the argument string can be a valid playermodel.
 170 Returns a valid one in doubt.
 171 =============
 172 */
 173 string FallbackPlayerModel;
 174 string CheckPlayerModel(string plyermodel) {
 175         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 176         {
 177                 // note: we cannot summon Don Strunzone here, some player may
 178                 // still have the model string set. In case anyone manages how
 179                 // to change a cvar default, we'll have a small leak here.
 180                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 181         }
 182         // only in right path
 183         if( substring(plyermodel,0,14) != "models/player/")
 184                 return FallbackPlayerModel;
 185         // only good file extensions
 186         if(substring(plyermodel,-4,4) != ".zym")
 187         if(substring(plyermodel,-4,4) != ".dpm")
 188         if(substring(plyermodel,-4,4) != ".iqm")
 189         if(substring(plyermodel,-4,4) != ".md3")
 190         if(substring(plyermodel,-4,4) != ".psk")
 191                 return FallbackPlayerModel;
 192         // forbid the LOD models
 193         if(substring(plyermodel, -9,5) == "_lod1")
 194                 return FallbackPlayerModel;
 195         if(substring(plyermodel, -9,5) == "_lod2")
 196                 return FallbackPlayerModel;
 197         if(plyermodel != strtolower(plyermodel))
 198                 return FallbackPlayerModel;
 199         // also, restrict to server models
 200         if(autocvar_sv_servermodelsonly)
 201         {
 202                 if(!fexists(plyermodel))
 203                         return FallbackPlayerModel;
 204         }
 205         return plyermodel;
 206 }
 207
 208 void setplayermodel(entity e, string modelname)
 209 {
 210         precache_model(modelname);
 211         _setmodel(e, modelname);
 212         player_setupanimsformodel(e);
 213         if(!autocvar_g_debug_globalsounds)
 214                 UpdatePlayerSounds(e);
 215 }
 216
 217 void FixPlayermodel(entity player);
 218 /** putting a client as observer in the server */
 219 void PutObserverInServer(entity this)
 220 {
 221     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 222         PlayerState_detach(this);
 223
 224         if (IS_PLAYER(this))
 225         {
 226                 if(this.health >= 1)
 227                 {
 228                         // despawn effect
 229                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 230                 }
 231
 232                 // was a player, recount votes and ready status
 233                 if(IS_REAL_CLIENT(this))
 234                 {
 235                         if (vote_called) { VoteCount(false); }
 236                         ReadyCount();
 237                 }
 238     }
 239
 240     {
 241         entity spot = SelectSpawnPoint(this, true);
 242         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 243         this.angles = vec2(spot.angles);
 244         this.fixangle = true;
 245         // offset it so that the spectator spawns higher off the ground, looks better this way
 246         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 247         if (IS_REAL_CLIENT(this))
 248         {
 249             msg_entity = this;
 250             WriteByte(MSG_ONE, SVC_SETVIEW);
 251             WriteEntity(MSG_ONE, this);
 252         }
 253         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 254         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 255         if(!autocvar_g_debug_globalsounds)
 256         {
 257                 // needed for player sounds
 258                 this.model = "";
 259                 FixPlayermodel(this);
 260         }
 261         setmodel(this, MDL_Null);
 262         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 263         this.view_ofs = '0 0 0';
 264     }
 265
 266     RemoveGrapplingHooks(this);
 267         Portal_ClearAll(this);
 268         Unfreeze(this);
 269         SetSpectatee(this, NULL);
 270
 271         if (this.alivetime)
 272         {
 273                 if (!warmup_stage)
 274                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 275                 this.alivetime = 0;
 276         }
 277
 278         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 279
 280         WaypointSprite_PlayerDead(this);
 281
 282         if (mutator_returnvalue) {
 283             // mutator prevents resetting teams+score
 284         } else {
 285                 int oldteam = this.team;
 286                 this.team = -1;  // move this as it is needed to log the player spectating in eventlog
 287                 MUTATOR_CALLHOOK(Player_ChangedTeam, this, oldteam, this.team);
 288         this.frags = FRAGS_SPECTATOR;
 289         PlayerScore_Clear(this);  // clear scores when needed
 290     }
 291
 292         if (CS(this).killcount != FRAGS_SPECTATOR)
 293         {
 294                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 295                 if(!game_stopped)
 296                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 297                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 298
 299                 if(!CS(this).just_joined)
 300                         LogTeamchange(this.playerid, -1, 4);
 301                 else
 302                         CS(this).just_joined = false;
 303         }
 304
 305         accuracy_resend(this);
 306
 307         CS(this).spectatortime = time;
 308         if(this.bot_attack)
 309                 IL_REMOVE(g_bot_targets, this);
 310         this.bot_attack = false;
 311         if(this.monster_attack)
 312                 IL_REMOVE(g_monster_targets, this);
 313         this.monster_attack = false;
 314     STAT(HUD, this) = HUD_NORMAL;
 315         TRANSMUTE(Observer, this);
 316         this.iscreature = false;
 317         this.teleportable = TELEPORT_SIMPLE;
 318         if(this.damagedbycontents)
 319                 IL_REMOVE(g_damagedbycontents, this);
 320         this.damagedbycontents = false;
 321         this.health = FRAGS_SPECTATOR;
 322         SetSpectatee_status(this, etof(this));
 323         this.takedamage = DAMAGE_NO;
 324         this.solid = SOLID_NOT;
 325         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 326         this.flags = FL_CLIENT | FL_NOTARGET;
 327         this.armorvalue = 666;
 328         this.effects = 0;
 329         this.armorvalue = autocvar_g_balance_armor_start;
 330         this.pauserotarmor_finished = 0;
 331         this.pauserothealth_finished = 0;
 332         this.pauseregen_finished = 0;
 333         this.damageforcescale = 0;
 334         this.death_time = 0;
 335         this.respawn_flags = 0;
 336         this.respawn_time = 0;
 337         STAT(RESPAWN_TIME, this) = 0;
 338         this.alpha = 0;
 339         this.scale = 0;
 340         this.fade_time = 0;
 341         this.pain_frame = 0;
 342         this.pain_finished = 0;
 343         this.strength_finished = 0;
 344         this.invincible_finished = 0;
 345         this.superweapons_finished = 0;
 346         this.dphitcontentsmask = 0;
 347         this.pushltime = 0;
 348         this.istypefrag = 0;
 349         setthink(this, func_null);
 350         this.nextthink = 0;
 351         this.deadflag = DEAD_NO;
 352         this.crouch = false;
 353         STAT(REVIVE_PROGRESS, this) = 0;
 354         this.revival_time = 0;
 355
 356         this.items = 0;
 357         this.weapons = '0 0 0';
 358         this.drawonlytoclient = this;
 359
 360         this.viewloc = NULL;
 361
 362         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 363
 364         this.weaponmodel = "";
 365         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 366         {
 367                 this.weaponentities[slot] = NULL;
 368         }
 369         this.exteriorweaponentity = NULL;
 370         CS(this).killcount = FRAGS_SPECTATOR;
 371         this.velocity = '0 0 0';
 372         this.avelocity = '0 0 0';
 373         this.punchangle = '0 0 0';
 374         this.punchvector = '0 0 0';
 375         this.oldvelocity = this.velocity;
 376         this.fire_endtime = -1;
 377         this.event_damage = func_null;
 378
 379         for(int slot = 0; slot < MAX_AXH; ++slot)
 380         {
 381                 entity axh = this.(AuxiliaryXhair[slot]);
 382                 this.(AuxiliaryXhair[slot]) = NULL;
 383
 384                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 385                         delete(axh);
 386         }
 387 }
 388
 389 int player_getspecies(entity this)
 390 {
 391         get_model_parameters(this.model, this.skin);
 392         int s = get_model_parameters_species;
 393         get_model_parameters(string_null, 0);
 394         if (s < 0) return SPECIES_HUMAN;
 395         return s;
 396 }
 397
 398 .float model_randomizer;
 399 void FixPlayermodel(entity player)
 400 {
 401         string defaultmodel = "";
 402         int defaultskin = 0;
 403         if(autocvar_sv_defaultcharacter)
 404         {
 405                 if(teamplay)
 406                 {
 407                         switch(player.team)
 408                         {
 409                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 410                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 411                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 412                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 413                         }
 414                 }
 415
 416                 if(defaultmodel == "")
 417                 {
 418                         defaultmodel = autocvar_sv_defaultplayermodel;
 419                         defaultskin = autocvar_sv_defaultplayerskin;
 420                 }
 421
 422                 int n = tokenize_console(defaultmodel);
 423                 if(n > 0)
 424                 {
 425                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 426                         // However, do NOT randomize if the player-selected model is in the list.
 427                         for (int i = 0; i < n; ++i)
 428                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 429                                         defaultmodel = argv(i);
 430                 }
 431
 432                 int i = strstrofs(defaultmodel, ":", 0);
 433                 if(i >= 0)
 434                 {
 435                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 436                         defaultmodel = substring(defaultmodel, 0, i);
 437                 }
 438         }
 439         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 440         {
 441                 if(teamplay)
 442                 {
 443                         switch(player.team)
 444                         {
 445                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 446                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 447                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 448                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 449                         }
 450                 }
 451
 452                 if(!defaultskin)
 453                         defaultskin = autocvar_sv_defaultplayerskin;
 454         }
 455
 456         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 457         defaultmodel = M_ARGV(0, string);
 458         defaultskin = M_ARGV(1, int);
 459
 460         bool chmdl = false;
 461         int oldskin;
 462         if(defaultmodel != "")
 463         {
 464                 if (defaultmodel != player.model)
 465                 {
 466                         vector m1 = player.mins;
 467                         vector m2 = player.maxs;
 468                         setplayermodel (player, defaultmodel);
 469                         setsize (player, m1, m2);
 470                         chmdl = true;
 471                 }
 472
 473                 oldskin = player.skin;
 474                 player.skin = defaultskin;
 475         } else {
 476                 if (player.playermodel != player.model || player.playermodel == "")
 477                 {
 478                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 479                         vector m1 = player.mins;
 480                         vector m2 = player.maxs;
 481                         setplayermodel (player, player.playermodel);
 482                         setsize (player, m1, m2);
 483                         chmdl = true;
 484                 }
 485
 486                 if(!autocvar_sv_defaultcharacterskin)
 487                 {
 488                         oldskin = player.skin;
 489                         player.skin = stof(player.playerskin);
 490                 }
 491                 else
 492                 {
 493                         oldskin = player.skin;
 494                         player.skin = defaultskin;
 495                 }
 496         }
 497
 498         if(chmdl || oldskin != player.skin) // model or skin has changed
 499         {
 500                 player.species = player_getspecies(player); // update species
 501                 if(!autocvar_g_debug_globalsounds)
 502                         UpdatePlayerSounds(player); // update skin sounds
 503         }
 504
 505         if(!teamplay)
 506                 if(strlen(autocvar_sv_defaultplayercolors))
 507                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 508                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 509 }
 510
 511 void PutPlayerInServer(entity this)
 512 {
 513         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 514
 515         PlayerState_attach(this);
 516         accuracy_resend(this);
 517
 518         if (this.team < 0)
 519                 JoinBestTeamForBalance(this, true);
 520
 521         entity spot = SelectSpawnPoint(this, false);
 522         if (!spot) {
 523                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 524                 return; // spawn failed
 525         }
 526
 527         TRANSMUTE(Player, this);
 528
 529         CS(this).wasplayer = true;
 530         this.iscreature = true;
 531         this.teleportable = TELEPORT_NORMAL;
 532         if(!this.damagedbycontents)
 533                 IL_PUSH(g_damagedbycontents, this);
 534         this.damagedbycontents = true;
 535         set_movetype(this, MOVETYPE_WALK);
 536         this.solid = SOLID_SLIDEBOX;
 537         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 538         if (autocvar_g_playerclip_collisions)
 539                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 540         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 541                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 542         this.frags = FRAGS_PLAYER;
 543         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 544         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 545         if (autocvar__notarget)
 546                 this.flags |= FL_NOTARGET;
 547         this.takedamage = DAMAGE_AIM;
 548         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 549
 550         if (warmup_stage) {
 551                 this.ammo_shells = warmup_start_ammo_shells;
 552                 this.ammo_nails = warmup_start_ammo_nails;
 553                 this.ammo_rockets = warmup_start_ammo_rockets;
 554                 this.ammo_cells = warmup_start_ammo_cells;
 555                 this.ammo_plasma = warmup_start_ammo_plasma;
 556                 this.ammo_fuel = warmup_start_ammo_fuel;
 557                 this.health = warmup_start_health;
 558                 this.armorvalue = warmup_start_armorvalue;
 559                 this.weapons = WARMUP_START_WEAPONS;
 560         } else {
 561                 this.ammo_shells = start_ammo_shells;
 562                 this.ammo_nails = start_ammo_nails;
 563                 this.ammo_rockets = start_ammo_rockets;
 564                 this.ammo_cells = start_ammo_cells;
 565                 this.ammo_plasma = start_ammo_plasma;
 566                 this.ammo_fuel = start_ammo_fuel;
 567                 this.health = start_health;
 568                 this.armorvalue = start_armorvalue;
 569                 this.weapons = start_weapons;
 570                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 571                 {
 572                         GiveRandomWeapons(this, random_start_weapons_count,
 573                                 autocvar_g_random_start_weapons, random_start_ammo);
 574                 }
 575         }
 576         SetSpectatee_status(this, 0);
 577
 578         PS(this).dual_weapons = '0 0 0';
 579
 580         this.superweapons_finished = (this.weapons & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 581
 582         this.items = start_items;
 583
 584         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 585         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 586         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 587         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 588         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 589         if (!sv_ready_restart_after_countdown && time < game_starttime)
 590         {
 591                 float f = game_starttime - time;
 592                 this.spawnshieldtime += f;
 593                 this.pauserotarmor_finished += f;
 594                 this.pauserothealth_finished += f;
 595                 this.pauseregen_finished += f;
 596         }
 597
 598         this.damageforcescale = 2;
 599         this.death_time = 0;
 600         this.respawn_flags = 0;
 601         this.respawn_time = 0;
 602         STAT(RESPAWN_TIME, this) = 0;
 603         this.scale = autocvar_sv_player_scale;
 604         this.fade_time = 0;
 605         this.pain_frame = 0;
 606         this.pain_finished = 0;
 607         this.pushltime = 0;
 608         setthink(this, func_null); // players have no think function
 609         this.nextthink = 0;
 610         this.dmg_team = 0;
 611         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 612
 613         this.deadflag = DEAD_NO;
 614
 615         this.angles = spot.angles;
 616         this.angles_z = 0; // never spawn tilted even if the spot says to
 617         if (IS_BOT_CLIENT(this))
 618                 this.v_angle = this.angles;
 619         this.fixangle = true; // turn this way immediately
 620         this.oldvelocity = this.velocity = '0 0 0';
 621         this.avelocity = '0 0 0';
 622         this.punchangle = '0 0 0';
 623         this.punchvector = '0 0 0';
 624
 625         this.strength_finished = 0;
 626         this.invincible_finished = 0;
 627         this.fire_endtime = -1;
 628         STAT(REVIVE_PROGRESS, this) = 0;
 629         this.revival_time = 0;
 630
 631         this.air_finished = time + 12;
 632         this.waterlevel = WATERLEVEL_NONE;
 633         this.watertype = CONTENT_EMPTY;
 634
 635         entity spawnevent = new_pure(spawnevent);
 636         spawnevent.owner = this;
 637         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 638
 639         // Cut off any still running player sounds.
 640         stopsound(this, CH_PLAYER_SINGLE);
 641
 642         this.model = "";
 643         FixPlayermodel(this);
 644         this.drawonlytoclient = NULL;
 645
 646         this.viewloc = NULL;
 647
 648         for(int slot = 0; slot < MAX_AXH; ++slot)
 649         {
 650                 entity axh = this.(AuxiliaryXhair[slot]);
 651                 this.(AuxiliaryXhair[slot]) = NULL;
 652
 653                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 654                         delete(axh);
 655         }
 656
 657         this.spawnpoint_targ = NULL;
 658
 659         this.crouch = false;
 660         this.view_ofs = STAT(PL_VIEW_OFS, this);
 661         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 662         this.spawnorigin = spot.origin;
 663         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 664         // don't reset back to last position, even if new position is stuck in solid
 665         this.oldorigin = this.origin;
 666         if(this.conveyor)
 667                 IL_REMOVE(g_conveyed, this);
 668         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 669         STAT(HUD, this) = HUD_NORMAL;
 670
 671         this.event_damage = PlayerDamage;
 672
 673         if(!this.bot_attack)
 674                 IL_PUSH(g_bot_targets, this);
 675         this.bot_attack = true;
 676         if(!this.monster_attack)
 677                 IL_PUSH(g_monster_targets, this);
 678         this.monster_attack = true;
 679         navigation_dynamicgoal_init(this, false);
 680
 681         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 682
 683         // player was spectator
 684         if (CS(this).killcount == FRAGS_SPECTATOR) {
 685                 PlayerScore_Clear(this);
 686                 CS(this).killcount = 0;
 687                 CS(this).startplaytime = time;
 688         }
 689
 690         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 691         {
 692                 .entity weaponentity = weaponentities[slot];
 693                 entity oldwep = this.(weaponentity);
 694                 CL_SpawnWeaponentity(this, weaponentity);
 695                 if(oldwep && oldwep.owner == this)
 696                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 697         }
 698         this.alpha = default_player_alpha;
 699         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 700         this.exteriorweaponentity.alpha = default_weapon_alpha;
 701
 702         this.speedrunning = false;
 703
 704         target_voicescript_clear(this);
 705
 706         // reset fields the weapons may use
 707         FOREACH(Weapons, true, {
 708                 it.wr_resetplayer(it, this);
 709                         // reload all reloadable weapons
 710                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 711                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 712                         {
 713                                 .entity weaponentity = weaponentities[slot];
 714                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 715                         }
 716                 }
 717         });
 718
 719         {
 720                 string s = spot.target;
 721                 spot.target = string_null;
 722                 SUB_UseTargets(spot, this, NULL);
 723                 spot.target = s;
 724         }
 725
 726         Unfreeze(this);
 727
 728         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 729
 730         if (autocvar_spawn_debug)
 731         {
 732                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 733                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 734         }
 735
 736         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 737         {
 738                 .entity weaponentity = weaponentities[slot];
 739                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 740                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 741                 else
 742                         this.(weaponentity).m_switchweapon = WEP_Null;
 743                 this.(weaponentity).m_weapon = WEP_Null;
 744                 this.(weaponentity).weaponname = "";
 745                 this.(weaponentity).m_switchingweapon = WEP_Null;
 746                 this.(weaponentity).cnt = -1;
 747         }
 748
 749         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 750
 751         if (!warmup_stage && !this.alivetime)
 752                 this.alivetime = time;
 753
 754         antilag_clear(this, CS(this));
 755 }
 756
 757 /** Called when a client spawns in the server */
 758 void PutClientInServer(entity this)
 759 {
 760         if (IS_BOT_CLIENT(this)) {
 761                 TRANSMUTE(Player, this);
 762         } else if (IS_REAL_CLIENT(this)) {
 763                 msg_entity = this;
 764                 WriteByte(MSG_ONE, SVC_SETVIEW);
 765                 WriteEntity(MSG_ONE, this);
 766         }
 767         if (game_stopped)
 768                 TRANSMUTE(Observer, this);
 769
 770         SetSpectatee(this, NULL);
 771
 772         // reset player keys
 773         if(PS(this))
 774                 PS(this).itemkeys = 0;
 775
 776         MUTATOR_CALLHOOK(PutClientInServer, this);
 777
 778         if (IS_OBSERVER(this)) {
 779                 PutObserverInServer(this);
 780         } else if (IS_PLAYER(this)) {
 781                 PutPlayerInServer(this);
 782         }
 783 }
 784
 785 void ClientInit_misc(entity this);
 786
 787 // TODO do we need all these fields, or should we stop autodetecting runtime
 788 // changes and just have a console command to update this?
 789 bool ClientInit_SendEntity(entity this, entity to, int sf)
 790 {
 791         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 792         return = true;
 793         msg_entity = to;
 794         // MSG_INIT replacement
 795         // TODO: make easier to use
 796         Registry_send_all();
 797         W_PROP_reload(MSG_ONE, to);
 798         ClientInit_misc(this);
 799         MUTATOR_CALLHOOK(Ent_Init);
 800 }
 801 void ClientInit_misc(entity this)
 802 {
 803         int channel = MSG_ONE;
 804         WriteHeader(channel, ENT_CLIENT_INIT);
 805         WriteByte(channel, g_nexball_meter_period * 32);
 806         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 807         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 808         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 809         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 810         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 811         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 812         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 813         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 814
 815         if(sv_foginterval && world.fog != "")
 816                 WriteString(channel, world.fog);
 817         else
 818                 WriteString(channel, "");
 819         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 820         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 821         WriteByte(channel, serverflags);
 822         WriteCoord(channel, autocvar_g_trueaim_minrange);
 823 }
 824
 825 void ClientInit_CheckUpdate(entity this)
 826 {
 827         this.nextthink = time;
 828         if(this.count != autocvar_g_balance_armor_blockpercent)
 829         {
 830                 this.count = autocvar_g_balance_armor_blockpercent;
 831                 this.SendFlags |= 1;
 832         }
 833         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 834         {
 835                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 836                 this.SendFlags |= 1;
 837         }
 838 }
 839
 840 void ClientInit_Spawn()
 841 {
 842         entity e = new_pure(clientinit);
 843         setthink(e, ClientInit_CheckUpdate);
 844         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 845
 846         ClientInit_CheckUpdate(e);
 847 }
 848
 849 /*
 850 =============
 851 SetNewParms
 852 =============
 853 */
 854 void SetNewParms ()
 855 {
 856         // initialize parms for a new player
 857         parm1 = -(86400 * 366);
 858
 859         MUTATOR_CALLHOOK(SetNewParms);
 860 }
 861
 862 /*
 863 =============
 864 SetChangeParms
 865 =============
 866 */
 867 void SetChangeParms (entity this)
 868 {
 869         // save parms for level change
 870         parm1 = CS(this).parm_idlesince - time;
 871
 872         MUTATOR_CALLHOOK(SetChangeParms);
 873 }
 874
 875 /*
 876 =============
 877 DecodeLevelParms
 878 =============
 879 */
 880 void DecodeLevelParms(entity this)
 881 {
 882         // load parms
 883         CS(this).parm_idlesince = parm1;
 884         if (CS(this).parm_idlesince == -(86400 * 366))
 885                 CS(this).parm_idlesince = time;
 886
 887         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 888         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 889
 890         MUTATOR_CALLHOOK(DecodeLevelParms);
 891 }
 892
 893 /*
 894 =============
 895 ClientKill
 896
 897 Called when a client types 'kill' in the console
 898 =============
 899 */
 900
 901 .float clientkill_nexttime;
 902 void ClientKill_Now_TeamChange(entity this)
 903 {
 904         if(this.killindicator_teamchange == -1)
 905         {
 906                 JoinBestTeamForBalance(this, true);
 907         }
 908         else if(this.killindicator_teamchange == -2)
 909         {
 910                 if(blockSpectators)
 911                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 912                 PutObserverInServer(this);
 913         }
 914         else
 915                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 916         this.killindicator_teamchange = 0;
 917 }
 918
 919 void ClientKill_Now(entity this)
 920 {
 921         if(this.vehicle)
 922         {
 923             vehicles_exit(this.vehicle, VHEF_RELEASE);
 924             if(!this.killindicator_teamchange)
 925             {
 926             this.vehicle_health = -1;
 927             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 928             }
 929         }
 930
 931         if(this.killindicator && !wasfreed(this.killindicator))
 932                 delete(this.killindicator);
 933
 934         this.killindicator = NULL;
 935
 936         if(this.killindicator_teamchange)
 937                 ClientKill_Now_TeamChange(this);
 938
 939         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 940         {
 941                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 942         }
 943
 944         // now I am sure the player IS dead
 945 }
 946 void KillIndicator_Think(entity this)
 947 {
 948         if (game_stopped)
 949         {
 950                 this.owner.killindicator = NULL;
 951                 delete(this);
 952                 return;
 953         }
 954
 955         if (this.owner.alpha < 0 && !this.owner.vehicle)
 956         {
 957                 this.owner.killindicator = NULL;
 958                 delete(this);
 959                 return;
 960         }
 961
 962         if(this.cnt <= 0)
 963         {
 964                 ClientKill_Now(this.owner);
 965                 return;
 966         }
 967     else if(this.health == 1) // health == 1 means that it's silent
 968     {
 969         this.nextthink = time + 1;
 970         this.cnt -= 1;
 971     }
 972         else
 973         {
 974                 if(this.cnt <= 10)
 975                         setmodel(this, MDL_NUM(this.cnt));
 976                 if(IS_REAL_CLIENT(this.owner))
 977                 {
 978                         if(this.cnt <= 10)
 979                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 980                 }
 981                 this.nextthink = time + 1;
 982                 this.cnt -= 1;
 983         }
 984 }
 985
 986 float clientkilltime;
 987 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 988 {
 989         float killtime;
 990         float starttime;
 991
 992         if (game_stopped)
 993                 return;
 994
 995         killtime = autocvar_g_balance_kill_delay;
 996
 997     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
 998         return;
 999     killtime = M_ARGV(1, float);
1000
1001         this.killindicator_teamchange = targetteam;
1002
1003     if(!this.killindicator)
1004         {
1005                 if(!IS_DEAD(this))
1006                 {
1007                         killtime = max(killtime, this.clientkill_nexttime - time);
1008                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1009                 }
1010
1011                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1012                 {
1013                         ClientKill_Now(this);
1014                 }
1015                 else
1016                 {
1017                         starttime = max(time, clientkilltime);
1018
1019                         this.killindicator = spawn();
1020                         this.killindicator.owner = this;
1021                         this.killindicator.scale = 0.5;
1022                         setattachment(this.killindicator, this, "");
1023                         setorigin(this.killindicator, '0 0 52');
1024                         setthink(this.killindicator, KillIndicator_Think);
1025                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1026                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1027                         this.killindicator.cnt = ceil(killtime);
1028                         this.killindicator.count = bound(0, ceil(killtime), 10);
1029                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1030
1031                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1032                         {
1033                                 it.killindicator = spawn();
1034                                 it.killindicator.owner = it;
1035                                 it.killindicator.scale = 0.5;
1036                                 setattachment(it.killindicator, it, "");
1037                                 setorigin(it.killindicator, '0 0 52');
1038                                 setthink(it.killindicator, KillIndicator_Think);
1039                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1040                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1041                                 it.killindicator.cnt = ceil(killtime);
1042                         });
1043                         this.lip = 0;
1044                 }
1045         }
1046         if(this.killindicator)
1047         {
1048                 if(targetteam == 0) // just die
1049                 {
1050                         this.killindicator.colormod = '0 0 0';
1051                         if(IS_REAL_CLIENT(this))
1052                         if(this.killindicator.cnt > 0)
1053                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1054                 }
1055                 else if(targetteam == -1) // auto
1056                 {
1057                         this.killindicator.colormod = '0 1 0';
1058                         if(IS_REAL_CLIENT(this))
1059                         if(this.killindicator.cnt > 0)
1060                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1061                 }
1062                 else if(targetteam == -2) // spectate
1063                 {
1064                         this.killindicator.colormod = '0.5 0.5 0.5';
1065                         if(IS_REAL_CLIENT(this))
1066                         if(this.killindicator.cnt > 0)
1067                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1068                 }
1069                 else
1070                 {
1071                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1072                         if(IS_REAL_CLIENT(this))
1073                         if(this.killindicator.cnt > 0)
1074                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1075                 }
1076         }
1077
1078 }
1079
1080 void ClientKill (entity this)
1081 {
1082         if(game_stopped) return;
1083         if(this.player_blocked) return;
1084         if(STAT(FROZEN, this)) return;
1085
1086         ClientKill_TeamChange(this, 0);
1087 }
1088
1089 void FixClientCvars(entity e)
1090 {
1091         // send prediction settings to the client
1092         stuffcmd(e, "\nin_bindmap 0 0\n");
1093         if(autocvar_g_antilag == 3) // client side hitscan
1094                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1095         if(autocvar_sv_gentle)
1096                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1097
1098         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1099         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1100
1101         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1102
1103         MUTATOR_CALLHOOK(FixClientCvars, e);
1104 }
1105
1106 bool findinlist_abbrev(string tofind, string list)
1107 {
1108         if(list == "" || tofind == "")
1109                 return false; // empty list or search, just return
1110
1111         // this function allows abbreviated strings!
1112         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1113         {
1114                 return true;
1115         });
1116
1117         return false;
1118 }
1119
1120 bool PlayerInIPList(entity p, string iplist)
1121 {
1122         // some safety checks (never allow local?)
1123         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1124                 return false;
1125
1126         return findinlist_abbrev(p.netaddress, iplist);
1127 }
1128
1129 bool PlayerInIDList(entity p, string idlist)
1130 {
1131         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1132         if(!p.crypto_idfp)
1133                 return false;
1134
1135         return findinlist_abbrev(p.crypto_idfp, idlist);
1136 }
1137
1138 bool PlayerInList(entity player, string list)
1139 {
1140         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1141 }
1142
1143 #ifdef DP_EXT_PRECONNECT
1144 /*
1145 =============
1146 ClientPreConnect
1147
1148 Called once (not at each match start) when a client begins a connection to the server
1149 =============
1150 */
1151 void ClientPreConnect(entity this)
1152 {
1153         if(autocvar_sv_eventlog)
1154         {
1155                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1156                         this.playerid,
1157                         etof(this),
1158                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1159                 ));
1160         }
1161 }
1162 #endif
1163
1164 /**
1165 =============
1166 ClientConnect
1167
1168 Called when a client connects to the server
1169 =============
1170 */
1171 void ClientConnect(entity this)
1172 {
1173         if (Ban_MaybeEnforceBanOnce(this)) return;
1174         assert(!IS_CLIENT(this), return);
1175         this.flags |= FL_CLIENT;
1176         assert(player_count >= 0, player_count = 0);
1177
1178 #ifdef WATERMARK
1179         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1180 #endif
1181         TRANSMUTE(Client, this);
1182         CS(this).version_nagtime = time + 10 + random() * 10;
1183
1184         // identify the right forced team
1185         if (autocvar_g_campaign)
1186         {
1187                 if (IS_REAL_CLIENT(this)) // only players, not bots
1188                 {
1189                         switch (autocvar_g_campaign_forceteam)
1190                         {
1191                                 case 1: this.team_forced = NUM_TEAM_1; break;
1192                                 case 2: this.team_forced = NUM_TEAM_2; break;
1193                                 case 3: this.team_forced = NUM_TEAM_3; break;
1194                                 case 4: this.team_forced = NUM_TEAM_4; break;
1195                                 default: this.team_forced = 0;
1196                         }
1197                 }
1198         }
1199         else if (PlayerInList(this, autocvar_g_forced_team_red))    this.team_forced = NUM_TEAM_1;
1200         else if (PlayerInList(this, autocvar_g_forced_team_blue))   this.team_forced = NUM_TEAM_2;
1201         else if (PlayerInList(this, autocvar_g_forced_team_yellow)) this.team_forced = NUM_TEAM_3;
1202         else if (PlayerInList(this, autocvar_g_forced_team_pink))   this.team_forced = NUM_TEAM_4;
1203         else switch (autocvar_g_forced_team_otherwise)
1204         {
1205                 default: this.team_forced = 0; break;
1206                 case "red": this.team_forced = NUM_TEAM_1; break;
1207                 case "blue": this.team_forced = NUM_TEAM_2; break;
1208                 case "yellow": this.team_forced = NUM_TEAM_3; break;
1209                 case "pink": this.team_forced = NUM_TEAM_4; break;
1210                 case "spectate":
1211                 case "spectator":
1212                         this.team_forced = -1;
1213                         break;
1214         }
1215         if (!teamplay && this.team_forced > 0) this.team_forced = 0;
1216
1217         int playerid_save = this.playerid;
1218         this.playerid = 0; // silent
1219         JoinBestTeamForBalance(this, false); // if the team number is valid, keep it
1220         this.playerid = playerid_save;
1221
1222         if (autocvar_sv_spectate || autocvar_g_campaign || this.team_forced < 0) {
1223                 TRANSMUTE(Observer, this);
1224         } else {
1225                 if (!teamplay || autocvar_g_balance_teams) {
1226                         TRANSMUTE(Player, this);
1227                         campaign_bots_may_start = true;
1228                 } else {
1229                         TRANSMUTE(Observer, this); // do it anyway
1230                 }
1231         }
1232
1233         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1234
1235         // always track bots, don't ask for cl_allow_uidtracking
1236         if (IS_BOT_CLIENT(this))
1237                 PlayerStats_GameReport_AddPlayer(this);
1238         else
1239                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1240
1241         if (autocvar_sv_eventlog)
1242                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1243
1244         LogTeamchange(this.playerid, this.team, 1);
1245
1246         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1247
1248         if(teamplay && IS_PLAYER(this))
1249                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_CONNECT_TEAM), this.netname);
1250         else
1251                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1252
1253         stuffcmd(this, clientstuff, "\n");
1254         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1255
1256         FixClientCvars(this);
1257
1258         // get version info from player
1259         stuffcmd(this, "cmd clientversion $gameversion\n");
1260
1261         // notify about available teams
1262         if (teamplay)
1263         {
1264                 CheckAllowedTeams(this);
1265                 int t = GetAllowedTeams();
1266                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1267         }
1268         else
1269         {
1270                 stuffcmd(this, "set _teams_available 0\n");
1271         }
1272
1273         bot_relinkplayerlist();
1274
1275         CS(this).spectatortime = time;
1276         if (blockSpectators)
1277         {
1278                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1279         }
1280
1281         CS(this).jointime = time;
1282
1283         if (IS_REAL_CLIENT(this))
1284         {
1285                 if (g_weaponarena_weapons == WEPSET(TUBA))
1286                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1287         }
1288
1289         if (!sv_foginterval && world.fog != "")
1290                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1291
1292         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1293                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1294                         send_CSQC_teamnagger();
1295
1296         CSQCMODEL_AUTOINIT(this);
1297
1298         CS(this).model_randomizer = random();
1299
1300         if (IS_REAL_CLIENT(this))
1301                 sv_notice_join(this);
1302
1303         // update physics stats (players can spawn before physics runs)
1304         Physics_UpdateStats(this);
1305
1306         IL_EACH(g_initforplayer, it.init_for_player, {
1307                 it.init_for_player(it, this);
1308         });
1309
1310         Handicap_Initialize(this);
1311
1312         MUTATOR_CALLHOOK(ClientConnect, this);
1313
1314         if (IS_REAL_CLIENT(this))
1315         {
1316                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1317                 {
1318                         CS(this).motd_actived_time = -1;
1319                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1320                 }
1321         }
1322 }
1323 /*
1324 =============
1325 ClientDisconnect
1326
1327 Called when a client disconnects from the server
1328 =============
1329 */
1330 .entity chatbubbleentity;
1331 void ReadyCount();
1332 void ClientDisconnect(entity this)
1333 {
1334         assert(IS_CLIENT(this), return);
1335
1336         PlayerStats_GameReport_FinalizePlayer(this);
1337         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1338         if (CS(this).active_minigame) part_minigame(this);
1339         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1340
1341         if (autocvar_sv_eventlog)
1342                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1343
1344         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1345
1346         if(IS_SPEC(this))
1347                 SetSpectatee(this, NULL);
1348
1349     MUTATOR_CALLHOOK(ClientDisconnect, this);
1350
1351         if (CS(this).netname_previous) strunzone(CS(this).netname_previous); // needs to be before the CS entity is removed!
1352         if (CS(this).weaponorder_byimpulse) strunzone(CS(this).weaponorder_byimpulse);
1353         ClientState_detach(this);
1354
1355         Portal_ClearAll(this);
1356
1357         Unfreeze(this);
1358
1359         RemoveGrapplingHooks(this);
1360
1361         // Here, everything has been done that requires this player to be a client.
1362
1363         this.flags &= ~FL_CLIENT;
1364
1365         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1366         if (this.killindicator) delete(this.killindicator);
1367
1368         WaypointSprite_PlayerGone(this);
1369
1370         bot_relinkplayerlist();
1371
1372         if (this.clientstatus) strunzone(this.clientstatus);
1373         if (this.personal) delete(this.personal);
1374
1375         this.playerid = 0;
1376         ReadyCount();
1377         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1378
1379         ONREMOVE(this);
1380 }
1381
1382 void ChatBubbleThink(entity this)
1383 {
1384         this.nextthink = time;
1385         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1386         {
1387                 if(this.owner) // but why can that ever be NULL?
1388                         this.owner.chatbubbleentity = NULL;
1389                 delete(this);
1390                 return;
1391         }
1392
1393         this.mdl = "";
1394
1395         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1396         {
1397                 if ( CS(this.owner).active_minigame )
1398                         this.mdl = "models/sprites/minigame_busy.iqm";
1399                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1400                         this.mdl = "models/misc/chatbubble.spr";
1401         }
1402
1403         if ( this.model != this.mdl )
1404                 _setmodel(this, this.mdl);
1405
1406 }
1407
1408 void UpdateChatBubble(entity this)
1409 {
1410         if (this.alpha < 0)
1411                 return;
1412         // spawn a chatbubble entity if needed
1413         if (!this.chatbubbleentity)
1414         {
1415                 this.chatbubbleentity = new(chatbubbleentity);
1416                 this.chatbubbleentity.owner = this;
1417                 this.chatbubbleentity.exteriormodeltoclient = this;
1418                 setthink(this.chatbubbleentity, ChatBubbleThink);
1419                 this.chatbubbleentity.nextthink = time;
1420                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1421                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1422                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1423                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1424                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1425                 //this.chatbubbleentity.model = "";
1426                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1427         }
1428 }
1429
1430
1431 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1432 // added to the model skins
1433 /*void UpdateColorModHack()
1434 {
1435         float c;
1436         c = this.clientcolors & 15;
1437         // LordHavoc: only bothering to support white, green, red, yellow, blue
1438              if (!teamplay) this.colormod = '0 0 0';
1439         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1440         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1441         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1442         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1443         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1444         else this.colormod = '1 1 1';
1445 }*/
1446
1447 void respawn(entity this)
1448 {
1449         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1450         {
1451                 this.solid = SOLID_NOT;
1452                 this.takedamage = DAMAGE_NO;
1453                 set_movetype(this, MOVETYPE_FLY);
1454                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1455                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1456                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1457                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1458                 if(autocvar_g_respawn_ghosts_maxtime)
1459                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1460         }
1461
1462         CopyBody(this, 1);
1463
1464         this.effects |= EF_NODRAW; // prevent another CopyBody
1465         PutClientInServer(this);
1466 }
1467
1468 void play_countdown(entity this, float finished, Sound samp)
1469 {
1470     TC(Sound, samp);
1471         if(IS_REAL_CLIENT(this))
1472                 if(floor(finished - time - frametime) != floor(finished - time))
1473                         if(finished - time < 6)
1474                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1475 }
1476
1477 void player_powerups(entity this)
1478 {
1479         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1480         int items_prev = this.items;
1481
1482         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1483                 this.modelflags |= MF_ROCKET;
1484         else
1485                 this.modelflags &= ~MF_ROCKET;
1486
1487         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1488
1489         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1490                 return;
1491
1492         Fire_ApplyDamage(this);
1493         Fire_ApplyEffect(this);
1494
1495         if (!g_instagib)
1496         {
1497                 if (this.items & ITEM_Strength.m_itemid)
1498                 {
1499                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1500                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1501                         if (time > this.strength_finished)
1502                         {
1503                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1504                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1505                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1506                         }
1507                 }
1508                 else
1509                 {
1510                         if (time < this.strength_finished)
1511                         {
1512                                 this.items = this.items | ITEM_Strength.m_itemid;
1513                                 if(!g_cts)
1514                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1515                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1516                         }
1517                 }
1518                 if (this.items & ITEM_Shield.m_itemid)
1519                 {
1520                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1521                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1522                         if (time > this.invincible_finished)
1523                         {
1524                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1525                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1526                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1527                         }
1528                 }
1529                 else
1530                 {
1531                         if (time < this.invincible_finished)
1532                         {
1533                                 this.items = this.items | ITEM_Shield.m_itemid;
1534                                 if(!g_cts)
1535                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1536                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1537                         }
1538                 }
1539                 if (this.items & IT_SUPERWEAPON)
1540                 {
1541                         if (!(this.weapons & WEPSET_SUPERWEAPONS))
1542                         {
1543                                 this.superweapons_finished = 0;
1544                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1545                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1546                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1547                         }
1548                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1549                         {
1550                                 // don't let them run out
1551                         }
1552                         else
1553                         {
1554                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1555                                 if (time > this.superweapons_finished)
1556                                 {
1557                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1558                                         this.weapons &= ~WEPSET_SUPERWEAPONS;
1559                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1560                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1561                                 }
1562                         }
1563                 }
1564                 else if(this.weapons & WEPSET_SUPERWEAPONS)
1565                 {
1566                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1567                         {
1568                                 this.items = this.items | IT_SUPERWEAPON;
1569                                 if(!g_cts)
1570                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1571                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1572                         }
1573                         else
1574                         {
1575                                 this.superweapons_finished = 0;
1576                                 this.weapons &= ~WEPSET_SUPERWEAPONS;
1577                         }
1578                 }
1579                 else
1580                 {
1581                         this.superweapons_finished = 0;
1582                 }
1583         }
1584
1585         if(autocvar_g_nodepthtestplayers)
1586                 this.effects = this.effects | EF_NODEPTHTEST;
1587
1588         if(autocvar_g_fullbrightplayers)
1589                 this.effects = this.effects | EF_FULLBRIGHT;
1590
1591         if (time >= game_starttime)
1592         if (time < this.spawnshieldtime)
1593                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1594
1595         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1596 }
1597
1598 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1599 {
1600         if(current > stable)
1601                 return current;
1602         else if(current > stable - 0.25) // when close enough, "snap"
1603                 return stable;
1604         else
1605                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1606 }
1607
1608 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1609 {
1610         if(current < stable)
1611                 return current;
1612         else if(current < stable + 0.25) // when close enough, "snap"
1613                 return stable;
1614         else
1615                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1616 }
1617
1618 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1619 {
1620         if(current > rotstable)
1621         {
1622                 if(rotframetime > 0)
1623                 {
1624                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1625                         current = max(rotstable, current - rotlinear * rotframetime);
1626                 }
1627         }
1628         else if(current < regenstable)
1629         {
1630                 if(regenframetime > 0)
1631                 {
1632                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1633                         current = min(regenstable, current + regenlinear * regenframetime);
1634                 }
1635         }
1636
1637         if(current > limit)
1638                 current = limit;
1639
1640         return current;
1641 }
1642
1643 void player_regen(entity this)
1644 {
1645         float max_mod, regen_mod, rot_mod, limit_mod;
1646         max_mod = regen_mod = rot_mod = limit_mod = 1;
1647
1648         float regen_health = autocvar_g_balance_health_regen;
1649         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1650         float regen_health_rot = autocvar_g_balance_health_rot;
1651         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1652         float regen_health_stable = autocvar_g_balance_health_regenstable;
1653         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1654         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1655                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1656         max_mod = M_ARGV(1, float);
1657         regen_mod = M_ARGV(2, float);
1658         rot_mod = M_ARGV(3, float);
1659         limit_mod = M_ARGV(4, float);
1660         regen_health = M_ARGV(5, float);
1661         regen_health_linear = M_ARGV(6, float);
1662         regen_health_rot = M_ARGV(7, float);
1663         regen_health_rotlinear = M_ARGV(8, float);
1664         regen_health_stable = M_ARGV(9, float);
1665         regen_health_rotstable = M_ARGV(10, float);
1666
1667         if(!mutator_returnvalue)
1668         if(!STAT(FROZEN, this))
1669         {
1670                 float mina, maxa, limith, limita;
1671                 maxa = autocvar_g_balance_armor_rotstable;
1672                 mina = autocvar_g_balance_armor_regenstable;
1673                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1674                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1675
1676                 regen_health_rotstable = regen_health_rotstable * max_mod;
1677                 regen_health_stable = regen_health_stable * max_mod;
1678                 limith = limith * limit_mod;
1679                 limita = limita * limit_mod;
1680
1681                 this.armorvalue = CalcRotRegen(this.armorvalue, mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear, regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear, rot_mod * frametime * (time > this.pauserotarmor_finished), limita);
1682                 this.health = CalcRotRegen(this.health, regen_health_stable, regen_health, regen_health_linear, regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear, rot_mod * frametime * (time > this.pauserothealth_finished), limith);
1683         }
1684
1685         // if player rotted to death...  die!
1686         // check this outside above checks, as player may still be able to rot to death
1687         if(this.health < 1)
1688         {
1689                 if(this.vehicle)
1690                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1691                 if(this.event_damage)
1692                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1693         }
1694
1695         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1696         {
1697                 float minf, maxf, limitf;
1698
1699                 maxf = autocvar_g_balance_fuel_rotstable;
1700                 minf = autocvar_g_balance_fuel_regenstable;
1701                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1702
1703                 this.ammo_fuel = CalcRotRegen(this.ammo_fuel, minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear, frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0), maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf);
1704         }
1705         // Ugly hack to make sure the health and armor don't go beyond hard limit.
1706         // TODO: Remove this hack when all code uses GivePlayerHealth and
1707         // GivePlayerArmor.
1708         if (this.health > RESOURCE_AMOUNT_HARD_LIMIT)
1709         {
1710                 this.health = RESOURCE_AMOUNT_HARD_LIMIT;
1711         }
1712         if (this.armorvalue > RESOURCE_AMOUNT_HARD_LIMIT)
1713         {
1714                 this.armorvalue = RESOURCE_AMOUNT_HARD_LIMIT;
1715         }
1716         // End hack.
1717 }
1718
1719 bool zoomstate_set;
1720 void SetZoomState(entity this, float newzoom)
1721 {
1722         if(newzoom != CS(this).zoomstate)
1723         {
1724                 CS(this).zoomstate = newzoom;
1725                 ClientData_Touch(this);
1726         }
1727         zoomstate_set = true;
1728 }
1729
1730 void GetPressedKeys(entity this)
1731 {
1732         MUTATOR_CALLHOOK(GetPressedKeys, this);
1733         int keys = STAT(PRESSED_KEYS, this);
1734         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1735         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1736         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1737         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1738
1739         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1740         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1741         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1742         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1743         CS(this).pressedkeys = keys; // store for other users
1744
1745         STAT(PRESSED_KEYS, this) = keys;
1746 }
1747
1748 /*
1749 ======================
1750 spectate mode routines
1751 ======================
1752 */
1753
1754 void SpectateCopy(entity this, entity spectatee)
1755 {
1756     TC(Client, this); TC(Client, spectatee);
1757
1758         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1759         PS(this) = PS(spectatee);
1760         this.armortype = spectatee.armortype;
1761         this.armorvalue = spectatee.armorvalue;
1762         this.ammo_cells = spectatee.ammo_cells;
1763         this.ammo_plasma = spectatee.ammo_plasma;
1764         this.ammo_shells = spectatee.ammo_shells;
1765         this.ammo_nails = spectatee.ammo_nails;
1766         this.ammo_rockets = spectatee.ammo_rockets;
1767         this.ammo_fuel = spectatee.ammo_fuel;
1768         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1769         this.health = spectatee.health;
1770         CS(this).impulse = 0;
1771         this.items = spectatee.items;
1772         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1773         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1774         this.strength_finished = spectatee.strength_finished;
1775         this.invincible_finished = spectatee.invincible_finished;
1776         this.superweapons_finished = spectatee.superweapons_finished;
1777         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1778         this.weapons = spectatee.weapons;
1779         this.punchangle = spectatee.punchangle;
1780         this.view_ofs = spectatee.view_ofs;
1781         this.velocity = spectatee.velocity;
1782         this.dmg_take = spectatee.dmg_take;
1783         this.dmg_save = spectatee.dmg_save;
1784         this.dmg_inflictor = spectatee.dmg_inflictor;
1785         this.v_angle = spectatee.v_angle;
1786         this.angles = spectatee.v_angle;
1787         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1788         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1789         this.viewloc = spectatee.viewloc;
1790         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1791                 this.fixangle = true;
1792         setorigin(this, spectatee.origin);
1793         setsize(this, spectatee.mins, spectatee.maxs);
1794         SetZoomState(this, CS(spectatee).zoomstate);
1795
1796     anticheat_spectatecopy(this, spectatee);
1797         STAT(HUD, this) = STAT(HUD, spectatee);
1798         if(spectatee.vehicle)
1799     {
1800         this.angles = spectatee.v_angle;
1801
1802         //this.fixangle = false;
1803         //this.velocity = spectatee.vehicle.velocity;
1804         this.vehicle_health = spectatee.vehicle_health;
1805         this.vehicle_shield = spectatee.vehicle_shield;
1806         this.vehicle_energy = spectatee.vehicle_energy;
1807         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1808         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1809         this.vehicle_reload1 = spectatee.vehicle_reload1;
1810         this.vehicle_reload2 = spectatee.vehicle_reload2;
1811
1812         //msg_entity = this;
1813
1814        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1815             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1816            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1817            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1818
1819         //WriteByte (MSG_ONE, SVC_SETVIEW);
1820         //    WriteEntity(MSG_ONE, this);
1821         //makevectors(spectatee.v_angle);
1822         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1823     }
1824 }
1825
1826 bool SpectateUpdate(entity this)
1827 {
1828         if(!this.enemy)
1829                 return false;
1830
1831         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1832         {
1833                 SetSpectatee(this, NULL);
1834                 return false;
1835         }
1836
1837         SpectateCopy(this, this.enemy);
1838
1839         return true;
1840 }
1841
1842 bool SpectateSet(entity this)
1843 {
1844         if(!IS_PLAYER(this.enemy))
1845                 return false;
1846
1847         ClientData_Touch(this.enemy);
1848
1849         msg_entity = this;
1850         WriteByte(MSG_ONE, SVC_SETVIEW);
1851         WriteEntity(MSG_ONE, this.enemy);
1852         set_movetype(this, MOVETYPE_NONE);
1853         accuracy_resend(this);
1854
1855         if(!SpectateUpdate(this))
1856                 PutObserverInServer(this);
1857
1858         return true;
1859 }
1860
1861 void SetSpectatee_status(entity this, int spectatee_num)
1862 {
1863         int oldspectatee_status = CS(this).spectatee_status;
1864         CS(this).spectatee_status = spectatee_num;
1865
1866         if (CS(this).spectatee_status != oldspectatee_status)
1867         {
1868                 ClientData_Touch(this);
1869                 if (g_race || g_cts) race_InitSpectator();
1870         }
1871 }
1872
1873 void SetSpectatee(entity this, entity spectatee)
1874 {
1875         if(IS_BOT_CLIENT(this))
1876                 return; // bots abuse .enemy, this code is useless to them
1877
1878         entity old_spectatee = this.enemy;
1879
1880         this.enemy = spectatee;
1881
1882         // WEAPONTODO
1883         // these are required to fix the spectator bug with arc
1884         if(old_spectatee)
1885         {
1886                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1887                 {
1888                         .entity weaponentity = weaponentities[slot];
1889                         if(old_spectatee.(weaponentity).arc_beam)
1890                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1891                 }
1892         }
1893         if(this.enemy)
1894         {
1895                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1896                 {
1897                         .entity weaponentity = weaponentities[slot];
1898                         if(this.enemy.(weaponentity).arc_beam)
1899                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1900                 }
1901         }
1902
1903         if (this.enemy)
1904                 SetSpectatee_status(this, etof(this.enemy));
1905
1906         // needed to update spectator list
1907         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1908 }
1909
1910 bool Spectate(entity this, entity pl)
1911 {
1912         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1913                 return false;
1914         pl = M_ARGV(1, entity);
1915
1916         SetSpectatee(this, pl);
1917         return SpectateSet(this);
1918 }
1919
1920 bool SpectateNext(entity this)
1921 {
1922         entity ent = find(this.enemy, classname, STR_PLAYER);
1923
1924         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
1925                 ent = M_ARGV(1, entity);
1926         else if (!ent)
1927                 ent = find(ent, classname, STR_PLAYER);
1928
1929         if(ent) { SetSpectatee(this, ent); }
1930
1931         return SpectateSet(this);
1932 }
1933
1934 bool SpectatePrev(entity this)
1935 {
1936         // NOTE: chain order is from the highest to the lower entnum (unlike find)
1937         entity ent = findchain(classname, STR_PLAYER);
1938         if (!ent) // no player
1939                 return false;
1940
1941         entity first = ent;
1942         // skip players until current spectated player
1943         if(this.enemy)
1944         while(ent && ent != this.enemy)
1945                 ent = ent.chain;
1946
1947         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
1948         {
1949                 case MUT_SPECPREV_FOUND:
1950                     ent = M_ARGV(1, entity);
1951                     break;
1952                 case MUT_SPECPREV_RETURN:
1953                     return true;
1954                 case MUT_SPECPREV_CONTINUE:
1955                 default:
1956                 {
1957                         if(ent.chain)
1958                                 ent = ent.chain;
1959                         else
1960                                 ent = first;
1961                         break;
1962                 }
1963         }
1964
1965         SetSpectatee(this, ent);
1966         return SpectateSet(this);
1967 }
1968
1969 /*
1970 =============
1971 ShowRespawnCountdown()
1972
1973 Update a respawn countdown display.
1974 =============
1975 */
1976 void ShowRespawnCountdown(entity this)
1977 {
1978         float number;
1979         if(!IS_DEAD(this)) // just respawned?
1980                 return;
1981         else
1982         {
1983                 number = ceil(this.respawn_time - time);
1984                 if(number <= 0)
1985                         return;
1986                 if(number <= this.respawn_countdown)
1987                 {
1988                         this.respawn_countdown = number - 1;
1989                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
1990                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
1991                 }
1992         }
1993 }
1994
1995 .bool team_selected;
1996 bool ShowTeamSelection(entity this)
1997 {
1998         if(!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || this.team_forced > 0)
1999                 return false;
2000         stuffcmd(this, "menu_showteamselect\n");
2001         return true;
2002 }
2003 void Join(entity this)
2004 {
2005         TRANSMUTE(Player, this);
2006
2007         if(!this.team_selected)
2008         if(autocvar_g_campaign || autocvar_g_balance_teams)
2009                 JoinBestTeamForBalance(this, true);
2010
2011         if(autocvar_g_campaign)
2012                 campaign_bots_may_start = true;
2013
2014         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2015
2016         PutClientInServer(this);
2017
2018         if(IS_PLAYER(this))
2019         if(teamplay && this.team != -1)
2020                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2021         else
2022                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2023         this.team_selected = false;
2024 }
2025
2026 /**
2027  * Determines whether the player is allowed to join. This depends on cvar
2028  * g_maxplayers, if it isn't used this function always return true, otherwise
2029  * it checks whether the number of currently playing players exceeds g_maxplayers.
2030  * @return int number of free slots for players, 0 if none
2031  */
2032 int nJoinAllowed(entity this, entity ignore)
2033 {
2034         if(!ignore)
2035         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2036         // so report 0 free slots if restricted
2037         {
2038                 if(autocvar_g_forced_team_otherwise == "spectate")
2039                         return 0;
2040                 if(autocvar_g_forced_team_otherwise == "spectator")
2041                         return 0;
2042         }
2043
2044         if(this && this.team_forced < 0)
2045                 return 0; // forced spectators can never join
2046
2047         // TODO simplify this
2048         int totalClients = 0;
2049         int currentlyPlaying = 0;
2050         FOREACH_CLIENT(true, {
2051                 if(it != ignore)
2052                         ++totalClients;
2053                 if(IS_REAL_CLIENT(it))
2054                 if(IS_PLAYER(it) || it.caplayer)
2055                         ++currentlyPlaying;
2056         });
2057
2058         float free_slots = 0;
2059         if (!autocvar_g_maxplayers)
2060                 free_slots = maxclients - totalClients;
2061         else if(currentlyPlaying < autocvar_g_maxplayers)
2062                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2063
2064         static float join_prevent_msg_time = 0;
2065         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2066         {
2067                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2068                 join_prevent_msg_time = time + 3;
2069         }
2070
2071         return free_slots;
2072 }
2073
2074 /**
2075  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2076  * g_maxplayers_spectator_blocktime seconds
2077  */
2078 void checkSpectatorBlock(entity this)
2079 {
2080         if(IS_SPEC(this) || IS_OBSERVER(this))
2081         if(!this.caplayer)
2082         if(IS_REAL_CLIENT(this))
2083         {
2084                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2085                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2086                         dropclient(this);
2087                 }
2088         }
2089 }
2090
2091 void PrintWelcomeMessage(entity this)
2092 {
2093         if(CS(this).motd_actived_time == 0)
2094         {
2095                 if (autocvar_g_campaign) {
2096                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2097                                 CS(this).motd_actived_time = time;
2098                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2099                         }
2100                 } else {
2101                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2102                                 CS(this).motd_actived_time = time;
2103                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2104                         }
2105                 }
2106         }
2107         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2108         {
2109                 if (autocvar_g_campaign) {
2110                         if (PHYS_INPUT_BUTTON_INFO(this))
2111                                 CS(this).motd_actived_time = time;
2112                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2113                                 CS(this).motd_actived_time = 0;
2114                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2115                         }
2116                 } else {
2117                         if (PHYS_INPUT_BUTTON_INFO(this))
2118                                 CS(this).motd_actived_time = time;
2119                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2120                                 CS(this).motd_actived_time = 0;
2121                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2122                         }
2123                 }
2124         }
2125         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2126         {
2127                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2128                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2129                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2130                 {
2131                         // instanctly hide MOTD
2132                         CS(this).motd_actived_time = 0;
2133                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2134                 }
2135         }
2136 }
2137
2138 bool joinAllowed(entity this)
2139 {
2140         if (CS(this).version_mismatch) return false;
2141         if (!nJoinAllowed(this, this)) return false;
2142         if (teamplay && lockteams) return false;
2143         if (ShowTeamSelection(this)) return false;
2144         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2145         return true;
2146 }
2147
2148 .int items_added;
2149 .string shootfromfixedorigin;
2150 bool PlayerThink(entity this)
2151 {
2152         if (game_stopped || intermission_running) {
2153                 this.modelflags &= ~MF_ROCKET;
2154                 if(intermission_running)
2155                         IntermissionThink(this);
2156                 return false;
2157         }
2158
2159         if (timeout_status == TIMEOUT_ACTIVE) {
2160         // don't allow the player to turn around while game is paused
2161                 // FIXME turn this into CSQC stuff
2162                 this.v_angle = this.lastV_angle;
2163                 this.angles = this.lastV_angle;
2164                 this.fixangle = true;
2165         }
2166
2167         if (frametime) player_powerups(this);
2168
2169         if (IS_DEAD(this)) {
2170                 if (this.personal && g_race_qualifying) {
2171                         if (time > this.respawn_time) {
2172                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2173                                 respawn(this);
2174                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2175                         }
2176                 } else {
2177                         if (frametime) player_anim(this);
2178
2179                         if (this.respawn_flags & RESPAWN_DENY)
2180                         {
2181                                 STAT(RESPAWN_TIME, this) = 0;
2182                                 return false;
2183                         }
2184
2185                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2186
2187                         switch(this.deadflag)
2188                         {
2189                                 case DEAD_DYING:
2190                                 {
2191                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2192                                                 this.deadflag = DEAD_RESPAWNING;
2193                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2194                                                 this.deadflag = DEAD_DEAD;
2195                                         break;
2196                                 }
2197                                 case DEAD_DEAD:
2198                                 {
2199                                         if (button_pressed)
2200                                                 this.deadflag = DEAD_RESPAWNABLE;
2201                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2202                                                 this.deadflag = DEAD_RESPAWNING;
2203                                         break;
2204                                 }
2205                                 case DEAD_RESPAWNABLE:
2206                                 {
2207                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2208                                                 this.deadflag = DEAD_RESPAWNING;
2209                                         break;
2210                                 }
2211                                 case DEAD_RESPAWNING:
2212                                 {
2213                                         if (time > this.respawn_time)
2214                                         {
2215                                                 this.respawn_time = time + 1; // only retry once a second
2216                                                 this.respawn_time_max = this.respawn_time;
2217                                                 respawn(this);
2218                                         }
2219                                         break;
2220                                 }
2221                         }
2222
2223                         ShowRespawnCountdown(this);
2224
2225                         if (this.respawn_flags & RESPAWN_SILENT)
2226                                 STAT(RESPAWN_TIME, this) = 0;
2227                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2228                         {
2229                                 if (time < this.respawn_time)
2230                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2231                                 else if (this.deadflag != DEAD_RESPAWNING)
2232                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2233                         }
2234                         else
2235                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2236                 }
2237
2238                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2239                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2240                         STAT(RESPAWN_TIME, this) *= -1;
2241
2242                 return false;
2243         }
2244
2245         bool have_hook = false;
2246         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2247         {
2248                 .entity weaponentity = weaponentities[slot];
2249                 if(this.(weaponentity).hook.state)
2250                 {
2251                         have_hook = true;
2252                         break;
2253                 }
2254         }
2255         bool do_crouch = PHYS_INPUT_BUTTON_CROUCH(this);
2256         if (have_hook) {
2257                 do_crouch = false;
2258         //} else if (this.waterlevel >= WATERLEVEL_SWIMMING) {
2259                 //do_crouch = false;
2260         } else if (this.vehicle) {
2261                 do_crouch = false;
2262         } else if (STAT(FROZEN, this)) {
2263                 do_crouch = false;
2264     }
2265
2266         if (do_crouch) {
2267                 if (!this.crouch) {
2268                         this.crouch = true;
2269                         this.view_ofs = STAT(PL_CROUCH_VIEW_OFS, this);
2270                         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
2271                         // setanim(this, this.anim_duck, false, true, true); // this anim is BROKEN anyway
2272                 }
2273         } else if (this.crouch) {
2274         tracebox(this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), this.origin, false, this);
2275         if (!trace_startsolid) {
2276             this.crouch = false;
2277             this.view_ofs = STAT(PL_VIEW_OFS, this);
2278             setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
2279         }
2280         }
2281
2282         FixPlayermodel(this);
2283
2284         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2285                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2286                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2287         }
2288
2289         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2290         //if(frametime)
2291         {
2292                 this.items &= ~this.items_added;
2293
2294                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2295                 {
2296                         .entity weaponentity = weaponentities[slot];
2297                         W_WeaponFrame(this, weaponentity);
2298                 }
2299
2300                 this.items_added = 0;
2301                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || this.ammo_fuel >= 0.01))
2302             this.items_added |= IT_FUEL;
2303
2304                 this.items |= this.items_added;
2305         }
2306
2307         player_regen(this);
2308
2309         // WEAPONTODO: Add a weapon request for this
2310         // rot vortex charge to the charge limit
2311         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2312         {
2313                 .entity weaponentity = weaponentities[slot];
2314                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2315                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2316         }
2317
2318         if (frametime) player_anim(this);
2319
2320         // secret status
2321         secrets_setstatus(this);
2322
2323         // monsters status
2324         monsters_setstatus(this);
2325
2326         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2327
2328         return true;
2329 }
2330
2331 void ObserverThink(entity this)
2332 {
2333         if ( CS(this).impulse )
2334         {
2335                 MinigameImpulse(this, CS(this).impulse);
2336                 CS(this).impulse = 0;
2337         }
2338
2339         if (this.flags & FL_JUMPRELEASED) {
2340                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2341                         this.flags &= ~FL_JUMPRELEASED;
2342                         this.flags |= FL_SPAWNING;
2343                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch) {
2344                         this.flags &= ~FL_JUMPRELEASED;
2345                         if(SpectateNext(this)) {
2346                                 TRANSMUTE(Spectator, this);
2347                         }
2348                 } else {
2349                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2350                         set_movetype(this, preferred_movetype);
2351                 }
2352         } else {
2353                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2354                         this.flags |= FL_JUMPRELEASED;
2355                         if(this.flags & FL_SPAWNING)
2356                         {
2357                                 this.flags &= ~FL_SPAWNING;
2358                                 Join(this);
2359                                 return;
2360                         }
2361                 }
2362         }
2363 }
2364
2365 void SpectatorThink(entity this)
2366 {
2367         if ( CS(this).impulse )
2368         {
2369                 if(MinigameImpulse(this, CS(this).impulse))
2370                         CS(this).impulse = 0;
2371
2372                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2373                 {
2374                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2375                         CS(this).impulse = 0;
2376                         return;
2377                 }
2378         }
2379
2380         if (this.flags & FL_JUMPRELEASED) {
2381                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2382                         this.flags &= ~FL_JUMPRELEASED;
2383                         this.flags |= FL_SPAWNING;
2384                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2385                         this.flags &= ~FL_JUMPRELEASED;
2386                         if(SpectateNext(this)) {
2387                                 TRANSMUTE(Spectator, this);
2388                         } else {
2389                                 TRANSMUTE(Observer, this);
2390                                 PutClientInServer(this);
2391                         }
2392                         CS(this).impulse = 0;
2393                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2394                         this.flags &= ~FL_JUMPRELEASED;
2395                         if(SpectatePrev(this)) {
2396                                 TRANSMUTE(Spectator, this);
2397                         } else {
2398                                 TRANSMUTE(Observer, this);
2399                                 PutClientInServer(this);
2400                         }
2401                         CS(this).impulse = 0;
2402                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2403                         this.flags &= ~FL_JUMPRELEASED;
2404                         TRANSMUTE(Observer, this);
2405                         PutClientInServer(this);
2406                 } else {
2407                         if(!SpectateUpdate(this))
2408                                 PutObserverInServer(this);
2409                 }
2410         } else {
2411                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2412                         this.flags |= FL_JUMPRELEASED;
2413                         if(this.flags & FL_SPAWNING)
2414                         {
2415                                 this.flags &= ~FL_SPAWNING;
2416                                 Join(this);
2417                                 return;
2418                         }
2419                 }
2420                 if(!SpectateUpdate(this))
2421                         PutObserverInServer(this);
2422         }
2423
2424         this.flags |= FL_CLIENT | FL_NOTARGET;
2425 }
2426
2427 void vehicles_enter (entity pl, entity veh);
2428 void PlayerUseKey(entity this)
2429 {
2430         if (!IS_PLAYER(this))
2431                 return;
2432
2433         if(this.vehicle)
2434         {
2435                 if(!game_stopped)
2436                 {
2437                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2438                         return;
2439                 }
2440         }
2441         else if(autocvar_g_vehicles_enter)
2442         {
2443                 if(!STAT(FROZEN, this))
2444                 if(!IS_DEAD(this))
2445                 if(!game_stopped)
2446                 {
2447                         entity head, closest_target = NULL;
2448                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2449
2450                         while(head) // find the closest acceptable target to enter
2451                         {
2452                                 if(IS_VEHICLE(head))
2453                                 if(!IS_DEAD(head))
2454                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2455                                 if(head.takedamage != DAMAGE_NO)
2456                                 {
2457                                         if(closest_target)
2458                                         {
2459                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2460                                                 { closest_target = head; }
2461                                         }
2462                                         else { closest_target = head; }
2463                                 }
2464
2465                                 head = head.chain;
2466                         }
2467
2468                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2469                 }
2470         }
2471
2472         // a use key was pressed; call handlers
2473         MUTATOR_CALLHOOK(PlayerUseKey, this);
2474 }
2475
2476
2477 /*
2478 =============
2479 PlayerPreThink
2480
2481 Called every frame for each client before the physics are run
2482 =============
2483 */
2484 .float last_vehiclecheck;
2485 void PlayerPreThink (entity this)
2486 {
2487         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2488         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2489
2490         WarpZone_PlayerPhysics_FixVAngle(this);
2491
2492         if (frametime) {
2493                 // physics frames: update anticheat stuff
2494                 anticheat_prethink(this);
2495         }
2496
2497         if (blockSpectators && frametime) {
2498                 // WORKAROUND: only use dropclient in server frames (frametime set).
2499                 // Never use it in cl_movement frames (frametime zero).
2500                 checkSpectatorBlock(this);
2501         }
2502
2503         zoomstate_set = false;
2504
2505         // Check for nameless players
2506         if (this.netname == "" || this.netname != CS(this).netname_previous)
2507         {
2508                 bool assume_unchanged = (CS(this).netname_previous == "");
2509                 if (isInvisibleString(this.netname))
2510                 {
2511                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2512                         assume_unchanged = false;
2513                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2514                 }
2515                 if (!assume_unchanged && autocvar_sv_eventlog)
2516                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2517                 if (CS(this).netname_previous) strunzone(CS(this).netname_previous);
2518                 CS(this).netname_previous = strzone(this.netname);
2519         }
2520
2521         // version nagging
2522         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2523         CS(this).version_nagtime = 0;
2524         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2525             // git client
2526         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2527             // git server
2528             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2529         } else {
2530             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2531             if (r < 0) { // old client
2532                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2533             } else if (r > 0) { // old server
2534                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2535             }
2536         }
2537     }
2538
2539         // GOD MODE info
2540         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2541         {
2542                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2543                 this.max_armorvalue = 0;
2544         }
2545
2546         if(IS_PLAYER(this))
2547         {
2548                 if (STAT(FROZEN, this) == 2)
2549                 {
2550                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2551                         this.health = max(1, STAT(REVIVE_PROGRESS, this) * start_health);
2552                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2553
2554                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2555                                 Unfreeze(this);
2556                 }
2557                 else if (STAT(FROZEN, this) == 3)
2558                 {
2559                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2560                         this.health = max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this) );
2561
2562                         if (this.health < 1)
2563                         {
2564                                 if (this.vehicle)
2565                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2566                                 if(this.event_damage)
2567                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2568                         }
2569                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2570                                 Unfreeze(this);
2571                 }
2572         }
2573
2574         MUTATOR_CALLHOOK(PlayerPreThink, this);
2575
2576         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2577         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2578         {
2579                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2580                 {
2581                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2582                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2583                         {
2584                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2585                         }
2586                         else if(!it.owner)
2587                         {
2588                                 if(!it.team || SAME_TEAM(this, it))
2589                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2590                                 else if(autocvar_g_vehicles_steal)
2591                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2592                         }
2593                 });
2594
2595                 this.last_vehiclecheck = time + 1;
2596         }
2597
2598         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2599         {
2600                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2601                         PlayerUseKey(this);
2602                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2603         }
2604
2605         if (IS_REAL_CLIENT(this))
2606                 PrintWelcomeMessage(this);
2607
2608         if (IS_PLAYER(this)) {
2609                 if(!PlayerThink(this))
2610                         return;
2611         }
2612         else if (game_stopped || intermission_running) {
2613                 if(intermission_running)
2614                         IntermissionThink(this);
2615                 return;
2616         }
2617         else if (IS_OBSERVER(this)) {
2618                 ObserverThink(this);
2619         }
2620         else if (IS_SPEC(this)) {
2621                 SpectatorThink(this);
2622         }
2623
2624         // WEAPONTODO: Add weapon request for this
2625         if (!zoomstate_set) {
2626                 bool wep_zoomed = false;
2627                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2628                 {
2629                         .entity weaponentity = weaponentities[slot];
2630                         Weapon thiswep = this.(weaponentity).m_weapon;
2631                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2632                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2633                 }
2634                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2635     }
2636
2637         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2638         {
2639                 CS(this).teamkill_soundtime = 0;
2640
2641                 entity e = CS(this).teamkill_soundsource;
2642                 entity oldpusher = e.pusher;
2643                 e.pusher = this;
2644                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2645                 e.pusher = oldpusher;
2646         }
2647
2648         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2649                 CS(this).taunt_soundtime = 0;
2650                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2651         }
2652
2653         target_voicescript_next(this);
2654
2655         // WEAPONTODO: Move into weaponsystem somehow
2656         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2657         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2658         {
2659                 .entity weaponentity = weaponentities[slot];
2660                 if(this.(weaponentity).m_weapon == WEP_Null)
2661                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2662         }
2663 }
2664
2665 void DrownPlayer(entity this)
2666 {
2667         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2668                 return;
2669
2670         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2671         {
2672                 if(this.air_finished < time)
2673                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2674                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2675         }
2676         else if (this.air_finished < time)
2677         {       // drown!
2678                 if (this.pain_finished < time)
2679                 {
2680                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2681                         this.pain_finished = time + 0.5;
2682                 }
2683         }
2684 }
2685
2686 .bool move_qcphysics;
2687
2688 void Player_Physics(entity this)
2689 {
2690         set_movetype(this, this.move_movetype);
2691
2692         if(!this.move_qcphysics)
2693                 return;
2694
2695         if(!frametime && !CS(this).pm_frametime)
2696                 return;
2697
2698         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2699
2700         CS(this).pm_frametime = 0;
2701 }
2702
2703 /*
2704 =============
2705 PlayerPostThink
2706
2707 Called every frame for each client after the physics are run
2708 =============
2709 */
2710 void PlayerPostThink (entity this)
2711 {
2712         Player_Physics(this);
2713
2714         if (sv_maxidle > 0)
2715         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2716         if (IS_REAL_CLIENT(this))
2717         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2718         {
2719                 int totalClients = 0;
2720                 if(sv_maxidle_slots > 0)
2721                 {
2722                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2723                         {
2724                                 ++totalClients;
2725                         });
2726                 }
2727
2728                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2729                 { /* do nothing */ }
2730                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2731                 {
2732                         if (CS(this).idlekick_lasttimeleft)
2733                         {
2734                                 CS(this).idlekick_lasttimeleft = 0;
2735                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2736                         }
2737                 }
2738                 else
2739                 {
2740                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2741                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2742                                 if (!CS(this).idlekick_lasttimeleft)
2743                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2744                         }
2745                         if (timeleft <= 0) {
2746                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2747                                 dropclient(this);
2748                                 return;
2749                         }
2750                         else if (timeleft <= 10) {
2751                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2752                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2753                 }
2754                                 CS(this).idlekick_lasttimeleft = timeleft;
2755                         }
2756                 }
2757         }
2758
2759         CheatFrame(this);
2760
2761         if (game_stopped)
2762         {
2763                 this.solid = SOLID_NOT;
2764                 this.takedamage = DAMAGE_NO;
2765                 set_movetype(this, MOVETYPE_NONE);
2766         }
2767
2768         if (IS_PLAYER(this)) {
2769                 if(this.death_time == time && IS_DEAD(this))
2770                 {
2771                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2772                         // once all the damage events of this frame have been processed with normal size
2773                         this.maxs.z = 5;
2774                         setsize(this, this.mins, this.maxs);
2775                 }
2776                 DrownPlayer(this);
2777                 UpdateChatBubble(this);
2778                 if (CS(this).impulse) ImpulseCommands(this);
2779                 if (game_stopped)
2780                 {
2781                         CSQCMODEL_AUTOUPDATE(this);
2782                         return;
2783                 }
2784                 GetPressedKeys(this);
2785         }
2786
2787         if (this.waypointsprite_attachedforcarrier) {
2788             vector v = healtharmor_maxdamage(this.health, this.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2789                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2790     }
2791
2792         playerdemo_write(this);
2793
2794         CSQCMODEL_AUTOUPDATE(this);
2795 }
2796
2797 // hack to copy the button fields from the client entity to the Client State
2798 void PM_UpdateButtons(entity this, entity store)
2799 {
2800         if(this.impulse)
2801                 store.impulse = this.impulse;
2802         this.impulse = 0;
2803
2804         store.button0 = this.button0;
2805         store.button2 = this.button2;
2806         store.button3 = this.button3;
2807         store.button4 = this.button4;
2808         store.button5 = this.button5;
2809         store.button6 = this.button6;
2810         store.button7 = this.button7;
2811         store.button8 = this.button8;
2812         store.button9 = this.button9;
2813         store.button10 = this.button10;
2814         store.button11 = this.button11;
2815         store.button12 = this.button12;
2816         store.button13 = this.button13;
2817         store.button14 = this.button14;
2818         store.button15 = this.button15;
2819         store.button16 = this.button16;
2820         store.buttonuse = this.buttonuse;
2821         store.buttonchat = this.buttonchat;
2822
2823         store.cursor_active = this.cursor_active;
2824         store.cursor_screen = this.cursor_screen;
2825         store.cursor_trace_start = this.cursor_trace_start;
2826         store.cursor_trace_endpos = this.cursor_trace_endpos;
2827         store.cursor_trace_ent = this.cursor_trace_ent;
2828
2829         store.ping = this.ping;
2830         store.ping_packetloss = this.ping_packetloss;
2831         store.ping_movementloss = this.ping_movementloss;
2832
2833         store.v_angle = this.v_angle;
2834         store.movement = this.movement;
2835 }
2836
2837 NET_HANDLE(fpsreport, bool)
2838 {
2839         int fps = ReadShort();
2840         PlayerScore_Set(sender, SP_FPS, fps);
2841         return true;
2842 }