qcsrc/server/client.qc

   1 #include "client.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include "anticheat.qh"
   7 #include "impulse.qh"
   8 #include "player.qh"
   9 #include "ipban.qh"
  10 #include "miscfunctions.qh"
  11 #include "portals.qh"
  12 #include "teamplay.qh"
  13 #include "spawnpoints.qh"
  14 #include "resources.qh"
  15 #include "g_damage.qh"
  16 #include "handicap.qh"
  17 #include "g_hook.qh"
  18 #include "command/common.qh"
  19 #include "command/vote.qh"
  20 #include "cheats.qh"
  21 #include "g_world.qh"
  22 #include "race.qh"
  23 #include "antilag.qh"
  24 #include "campaign.qh"
  25 #include "command/common.qh"
  26 #include "scores_rules.qh"
  27
  28 #include "bot/api.qh"
  29
  30 #include "../common/ent_cs.qh"
  31 #include "../common/wepent.qh"
  32 #include <common/state.qh>
  33
  34 #include <common/effects/qc/globalsound.qh>
  35
  36 #include "../common/mapobjects/func/conveyor.qh"
  37 #include "../common/mapobjects/teleporters.qh"
  38 #include "../common/mapobjects/target/spawnpoint.qh"
  39
  40 #include "../common/vehicles/all.qh"
  41
  42 #include "weapons/hitplot.qh"
  43 #include "weapons/weaponsystem.qh"
  44
  45 #include "../common/net_notice.qh"
  46 #include "../common/net_linked.qh"
  47 #include "../common/physics/player.qh"
  48
  49 #include <common/vehicles/sv_vehicles.qh>
  50
  51 #include "../common/items/_mod.qh"
  52
  53 #include "../common/mutators/mutator/waypoints/all.qh"
  54 #include "../common/mutators/mutator/instagib/sv_instagib.qh"
  55 #include <common/gamemodes/_mod.qh>
  56
  57 #include "../common/mapobjects/subs.qh"
  58 #include "../common/mapobjects/triggers.qh"
  59 #include "../common/mapobjects/trigger/secret.qh"
  60
  61 #include "../common/minigames/sv_minigames.qh"
  62
  63 #include "../common/items/inventory.qh"
  64
  65 #include "../common/monsters/sv_monsters.qh"
  66
  67 #include "../lib/warpzone/server.qh"
  68
  69 #include <common/mutators/mutator/overkill/oknex.qh>
  70
  71 STATIC_METHOD(Client, Add, void(Client this, int _team))
  72 {
  73     ClientConnect(this);
  74     TRANSMUTE(Player, this);
  75     this.frame = 12; // 7
  76     this.team = _team;
  77     PutClientInServer(this);
  78 }
  79
  80 STATIC_METHOD(Client, Remove, void(Client this))
  81 {
  82     TRANSMUTE(Observer, this);
  83     PutClientInServer(this);
  84     ClientDisconnect(this);
  85 }
  86
  87 void send_CSQC_teamnagger() {
  88         WriteHeader(MSG_BROADCAST, TE_CSQC_TEAMNAGGER);
  89 }
  90
  91 int CountSpectators(entity player, entity to)
  92 {
  93         if(!player) { return 0; } // not sure how, but best to be safe
  94
  95         int spec_count = 0;
  96
  97         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
  98         {
  99                 spec_count++;
 100         });
 101
 102         return spec_count;
 103 }
 104
 105 void WriteSpectators(entity player, entity to)
 106 {
 107         if(!player) { return; } // not sure how, but best to be safe
 108
 109         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_SPEC(it) && it != to && it.enemy == player,
 110         {
 111                 WriteByte(MSG_ENTITY, num_for_edict(it));
 112         });
 113 }
 114
 115 bool ClientData_Send(entity this, entity to, int sf)
 116 {
 117         assert(to == this.owner, return false);
 118
 119         entity e = to;
 120         if (IS_SPEC(e)) e = e.enemy;
 121
 122         sf = 0;
 123         if (CS(e).race_completed)       sf |= BIT(0); // forced scoreboard
 124         if (CS(to).spectatee_status)    sf |= BIT(1); // spectator ent number follows
 125         if (CS(e).zoomstate)            sf |= BIT(2); // zoomed
 126         if (autocvar_sv_showspectators) sf |= BIT(4); // show spectators
 127
 128         WriteHeader(MSG_ENTITY, ENT_CLIENT_CLIENTDATA);
 129         WriteByte(MSG_ENTITY, sf);
 130
 131         if (sf & BIT(1))
 132                 WriteByte(MSG_ENTITY, CS(to).spectatee_status);
 133
 134         if(sf & BIT(4))
 135         {
 136                 float specs = CountSpectators(e, to);
 137                 WriteByte(MSG_ENTITY, specs);
 138                 WriteSpectators(e, to);
 139         }
 140
 141         return true;
 142 }
 143
 144 void ClientData_Attach(entity this)
 145 {
 146         Net_LinkEntity(CS(this).clientdata = new_pure(clientdata), false, 0, ClientData_Send);
 147         CS(this).clientdata.drawonlytoclient = this;
 148         CS(this).clientdata.owner = this;
 149 }
 150
 151 void ClientData_Detach(entity this)
 152 {
 153         delete(CS(this).clientdata);
 154         CS(this).clientdata = NULL;
 155 }
 156
 157 void ClientData_Touch(entity e)
 158 {
 159         entity cd = CS(e).clientdata;
 160         if (cd) { cd.SendFlags = 1; }
 161
 162         // make it spectatable
 163         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != e && IS_SPEC(it) && it.enemy == e,
 164         {
 165                 entity cd = CS(it).clientdata;
 166                 if (cd) { cd.SendFlags = 1; }
 167         });
 168 }
 169
 170
 171 /*
 172 =============
 173 CheckPlayerModel
 174
 175 Checks if the argument string can be a valid playermodel.
 176 Returns a valid one in doubt.
 177 =============
 178 */
 179 string FallbackPlayerModel;
 180 string CheckPlayerModel(string plyermodel) {
 181         if(FallbackPlayerModel != cvar_defstring("_cl_playermodel"))
 182         {
 183                 // note: we cannot summon Don Strunzone here, some player may
 184                 // still have the model string set. In case anyone manages how
 185                 // to change a cvar default, we'll have a small leak here.
 186                 FallbackPlayerModel = strzone(cvar_defstring("_cl_playermodel"));
 187         }
 188         // only in right path
 189         if( substring(plyermodel,0,14) != "models/player/")
 190                 return FallbackPlayerModel;
 191         // only good file extensions
 192         if(substring(plyermodel,-4,4) != ".zym")
 193         if(substring(plyermodel,-4,4) != ".dpm")
 194         if(substring(plyermodel,-4,4) != ".iqm")
 195         if(substring(plyermodel,-4,4) != ".md3")
 196         if(substring(plyermodel,-4,4) != ".psk")
 197                 return FallbackPlayerModel;
 198         // forbid the LOD models
 199         if(substring(plyermodel, -9,5) == "_lod1")
 200                 return FallbackPlayerModel;
 201         if(substring(plyermodel, -9,5) == "_lod2")
 202                 return FallbackPlayerModel;
 203         if(plyermodel != strtolower(plyermodel))
 204                 return FallbackPlayerModel;
 205         // also, restrict to server models
 206         if(autocvar_sv_servermodelsonly)
 207         {
 208                 if(!fexists(plyermodel))
 209                         return FallbackPlayerModel;
 210         }
 211         return plyermodel;
 212 }
 213
 214 void setplayermodel(entity e, string modelname)
 215 {
 216         precache_model(modelname);
 217         _setmodel(e, modelname);
 218         player_setupanimsformodel(e);
 219         if(!autocvar_g_debug_globalsounds)
 220                 UpdatePlayerSounds(e);
 221 }
 222
 223 /** putting a client as observer in the server */
 224 void PutObserverInServer(entity this)
 225 {
 226     bool mutator_returnvalue = MUTATOR_CALLHOOK(MakePlayerObserver, this);
 227         PlayerState_detach(this);
 228
 229         if (IS_PLAYER(this))
 230         {
 231                 if(GetResourceAmount(this, RESOURCE_HEALTH) >= 1)
 232                 {
 233                         // despawn effect
 234                         Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
 235                 }
 236
 237                 // was a player, recount votes and ready status
 238                 if(IS_REAL_CLIENT(this))
 239                 {
 240                         if (vote_called) { VoteCount(false); }
 241                         ReadyCount();
 242                 }
 243     }
 244
 245     {
 246         entity spot = SelectSpawnPoint(this, true);
 247         if (!spot) LOG_FATAL("No spawnpoints for observers?!?");
 248         this.angles = vec2(spot.angles);
 249         this.fixangle = true;
 250         // offset it so that the spectator spawns higher off the ground, looks better this way
 251         setorigin(this, spot.origin + STAT(PL_VIEW_OFS, this));
 252         if (IS_REAL_CLIENT(this))
 253         {
 254             msg_entity = this;
 255             WriteByte(MSG_ONE, SVC_SETVIEW);
 256             WriteEntity(MSG_ONE, this);
 257         }
 258         // give the spectator some space between walls for MOVETYPE_FLY_WORLDONLY
 259         // so that your view doesn't go into the ceiling with MOVETYPE_FLY_WORLDONLY, previously "PL_VIEW_OFS"
 260         if(!autocvar_g_debug_globalsounds)
 261         {
 262                 // needed for player sounds
 263                 this.model = "";
 264                 FixPlayermodel(this);
 265         }
 266         setmodel(this, MDL_Null);
 267         setsize(this, STAT(PL_CROUCH_MIN, this), STAT(PL_CROUCH_MAX, this));
 268         this.view_ofs = '0 0 0';
 269     }
 270
 271     RemoveGrapplingHooks(this);
 272         Portal_ClearAll(this);
 273         Unfreeze(this);
 274         SetSpectatee(this, NULL);
 275
 276         if (this.alivetime)
 277         {
 278                 if (!warmup_stage)
 279                         PlayerStats_GameReport_Event_Player(this, PLAYERSTATS_ALIVETIME, time - this.alivetime);
 280                 this.alivetime = 0;
 281         }
 282
 283         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 284
 285         WaypointSprite_PlayerDead(this);
 286
 287         if (mutator_returnvalue) {
 288             // mutator prevents resetting teams+score
 289         } else {
 290                 Player_SetTeamIndex(this, -1);
 291                 this.frags = FRAGS_SPECTATOR;
 292         PlayerScore_Clear(this);  // clear scores when needed
 293     }
 294
 295         if (CS(this).killcount != FRAGS_SPECTATOR)
 296         {
 297                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_SPECTATE, this.netname);
 298                 if(!game_stopped)
 299                 if(autocvar_g_chat_nospectators == 1 || (!warmup_stage && autocvar_g_chat_nospectators == 2))
 300                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_CHAT_NOSPECTATORS);
 301
 302                 if(!CS(this).just_joined)
 303                         LogTeamchange(this.playerid, -1, TEAM_CHANGE_SPECTATOR);
 304                 else
 305                         CS(this).just_joined = false;
 306         }
 307
 308         accuracy_resend(this);
 309
 310         CS(this).spectatortime = time;
 311         if(this.bot_attack)
 312                 IL_REMOVE(g_bot_targets, this);
 313         this.bot_attack = false;
 314         if(this.monster_attack)
 315                 IL_REMOVE(g_monster_targets, this);
 316         this.monster_attack = false;
 317     STAT(HUD, this) = HUD_NORMAL;
 318         TRANSMUTE(Observer, this);
 319         this.iscreature = false;
 320         this.teleportable = TELEPORT_SIMPLE;
 321         if(this.damagedbycontents)
 322                 IL_REMOVE(g_damagedbycontents, this);
 323         this.damagedbycontents = false;
 324         SetResourceAmountExplicit(this, RESOURCE_HEALTH, FRAGS_SPECTATOR);
 325         SetSpectatee_status(this, etof(this));
 326         this.takedamage = DAMAGE_NO;
 327         this.solid = SOLID_NOT;
 328         set_movetype(this, MOVETYPE_FLY_WORLDONLY); // user preference is controlled by playerprethink
 329         this.flags = FL_CLIENT | FL_NOTARGET;
 330         this.effects = 0;
 331         SetResourceAmountExplicit(this, RESOURCE_ARMOR, autocvar_g_balance_armor_start); // was 666?!
 332         this.pauserotarmor_finished = 0;
 333         this.pauserothealth_finished = 0;
 334         this.pauseregen_finished = 0;
 335         this.damageforcescale = 0;
 336         this.death_time = 0;
 337         this.respawn_flags = 0;
 338         this.respawn_time = 0;
 339         STAT(RESPAWN_TIME, this) = 0;
 340         this.alpha = 0;
 341         this.scale = 0;
 342         this.fade_time = 0;
 343         this.pain_frame = 0;
 344         this.pain_finished = 0;
 345         this.strength_finished = 0;
 346         this.invincible_finished = 0;
 347         this.superweapons_finished = 0;
 348         this.dphitcontentsmask = 0;
 349         this.pushltime = 0;
 350         this.istypefrag = 0;
 351         setthink(this, func_null);
 352         this.nextthink = 0;
 353         this.deadflag = DEAD_NO;
 354         this.crouch = false;
 355         STAT(REVIVE_PROGRESS, this) = 0;
 356         this.revival_time = 0;
 357
 358         this.items = 0;
 359         STAT(WEAPONS, this) = '0 0 0';
 360         this.drawonlytoclient = this;
 361
 362         this.viewloc = NULL;
 363
 364         //this.spawnpoint_targ = NULL; // keep it so they can return to where they were?
 365
 366         this.weaponmodel = "";
 367         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 368         {
 369                 this.weaponentities[slot] = NULL;
 370         }
 371         this.exteriorweaponentity = NULL;
 372         CS(this).killcount = FRAGS_SPECTATOR;
 373         this.velocity = '0 0 0';
 374         this.avelocity = '0 0 0';
 375         this.punchangle = '0 0 0';
 376         this.punchvector = '0 0 0';
 377         this.oldvelocity = this.velocity;
 378         this.fire_endtime = -1;
 379         this.event_damage = func_null;
 380         this.event_heal = func_null;
 381
 382         for(int slot = 0; slot < MAX_AXH; ++slot)
 383         {
 384                 entity axh = this.(AuxiliaryXhair[slot]);
 385                 this.(AuxiliaryXhair[slot]) = NULL;
 386
 387                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 388                         delete(axh);
 389         }
 390 }
 391
 392 int player_getspecies(entity this)
 393 {
 394         get_model_parameters(this.model, this.skin);
 395         int s = get_model_parameters_species;
 396         get_model_parameters(string_null, 0);
 397         if (s < 0) return SPECIES_HUMAN;
 398         return s;
 399 }
 400
 401 .float model_randomizer;
 402 void FixPlayermodel(entity player)
 403 {
 404         string defaultmodel = "";
 405         int defaultskin = 0;
 406         if(autocvar_sv_defaultcharacter)
 407         {
 408                 if(teamplay)
 409                 {
 410                         switch(player.team)
 411                         {
 412                                 case NUM_TEAM_1: defaultmodel = autocvar_sv_defaultplayermodel_red; defaultskin = autocvar_sv_defaultplayerskin_red; break;
 413                                 case NUM_TEAM_2: defaultmodel = autocvar_sv_defaultplayermodel_blue; defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 414                                 case NUM_TEAM_3: defaultmodel = autocvar_sv_defaultplayermodel_yellow; defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 415                                 case NUM_TEAM_4: defaultmodel = autocvar_sv_defaultplayermodel_pink; defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 416                         }
 417                 }
 418
 419                 if(defaultmodel == "")
 420                 {
 421                         defaultmodel = autocvar_sv_defaultplayermodel;
 422                         defaultskin = autocvar_sv_defaultplayerskin;
 423                 }
 424
 425                 int n = tokenize_console(defaultmodel);
 426                 if(n > 0)
 427                 {
 428                         defaultmodel = argv(floor(n * CS(player).model_randomizer));
 429                         // However, do NOT randomize if the player-selected model is in the list.
 430                         for (int i = 0; i < n; ++i)
 431                                 if ((argv(i) == player.playermodel && defaultskin == stof(player.playerskin)) || argv(i) == strcat(player.playermodel, ":", player.playerskin))
 432                                         defaultmodel = argv(i);
 433                 }
 434
 435                 int i = strstrofs(defaultmodel, ":", 0);
 436                 if(i >= 0)
 437                 {
 438                         defaultskin = stof(substring(defaultmodel, i+1, -1));
 439                         defaultmodel = substring(defaultmodel, 0, i);
 440                 }
 441         }
 442         if(autocvar_sv_defaultcharacterskin && !defaultskin)
 443         {
 444                 if(teamplay)
 445                 {
 446                         switch(player.team)
 447                         {
 448                                 case NUM_TEAM_1: defaultskin = autocvar_sv_defaultplayerskin_red; break;
 449                                 case NUM_TEAM_2: defaultskin = autocvar_sv_defaultplayerskin_blue; break;
 450                                 case NUM_TEAM_3: defaultskin = autocvar_sv_defaultplayerskin_yellow; break;
 451                                 case NUM_TEAM_4: defaultskin = autocvar_sv_defaultplayerskin_pink; break;
 452                         }
 453                 }
 454
 455                 if(!defaultskin)
 456                         defaultskin = autocvar_sv_defaultplayerskin;
 457         }
 458
 459         MUTATOR_CALLHOOK(FixPlayermodel, defaultmodel, defaultskin, player);
 460         defaultmodel = M_ARGV(0, string);
 461         defaultskin = M_ARGV(1, int);
 462
 463         bool chmdl = false;
 464         int oldskin;
 465         if(defaultmodel != "")
 466         {
 467                 if (defaultmodel != player.model)
 468                 {
 469                         vector m1 = player.mins;
 470                         vector m2 = player.maxs;
 471                         setplayermodel (player, defaultmodel);
 472                         setsize (player, m1, m2);
 473                         chmdl = true;
 474                 }
 475
 476                 oldskin = player.skin;
 477                 player.skin = defaultskin;
 478         } else {
 479                 if (player.playermodel != player.model || player.playermodel == "")
 480                 {
 481                         player.playermodel = CheckPlayerModel(player.playermodel); // this is never "", so no endless loop
 482                         vector m1 = player.mins;
 483                         vector m2 = player.maxs;
 484                         setplayermodel (player, player.playermodel);
 485                         setsize (player, m1, m2);
 486                         chmdl = true;
 487                 }
 488
 489                 if(!autocvar_sv_defaultcharacterskin)
 490                 {
 491                         oldskin = player.skin;
 492                         player.skin = stof(player.playerskin);
 493                 }
 494                 else
 495                 {
 496                         oldskin = player.skin;
 497                         player.skin = defaultskin;
 498                 }
 499         }
 500
 501         if(chmdl || oldskin != player.skin) // model or skin has changed
 502         {
 503                 player.species = player_getspecies(player); // update species
 504                 if(!autocvar_g_debug_globalsounds)
 505                         UpdatePlayerSounds(player); // update skin sounds
 506         }
 507
 508         if(!teamplay)
 509                 if(strlen(autocvar_sv_defaultplayercolors))
 510                         if(player.clientcolors != stof(autocvar_sv_defaultplayercolors))
 511                                 setcolor(player, stof(autocvar_sv_defaultplayercolors));
 512 }
 513
 514 void PutPlayerInServer(entity this)
 515 {
 516         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
 517
 518         PlayerState_attach(this);
 519         accuracy_resend(this);
 520
 521         if (this.team < 0)
 522                 TeamBalance_JoinBestTeam(this);
 523
 524         entity spot = SelectSpawnPoint(this, false);
 525         if (!spot) {
 526                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_NOSPAWNS);
 527                 return; // spawn failed
 528         }
 529
 530         TRANSMUTE(Player, this);
 531
 532         CS(this).wasplayer = true;
 533         this.iscreature = true;
 534         this.teleportable = TELEPORT_NORMAL;
 535         if(!this.damagedbycontents)
 536                 IL_PUSH(g_damagedbycontents, this);
 537         this.damagedbycontents = true;
 538         set_movetype(this, MOVETYPE_WALK);
 539         this.solid = SOLID_SLIDEBOX;
 540         this.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_SOLID;
 541         if (autocvar_g_playerclip_collisions)
 542                 this.dphitcontentsmask |= DPCONTENTS_PLAYERCLIP;
 543         if (IS_BOT_CLIENT(this) && autocvar_g_botclip_collisions)
 544                 this.dphitcontentsmask |= DPCONTENTS_BOTCLIP;
 545         this.frags = FRAGS_PLAYER;
 546         if (INDEPENDENT_PLAYERS) MAKE_INDEPENDENT_PLAYER(this);
 547         this.flags = FL_CLIENT | FL_PICKUPITEMS;
 548         if (autocvar__notarget)
 549                 this.flags |= FL_NOTARGET;
 550         this.takedamage = DAMAGE_AIM;
 551         this.effects = EF_TELEPORT_BIT | EF_RESTARTANIM_BIT;
 552
 553         if (warmup_stage) {
 554                 SetResourceAmount(this, RESOURCE_SHELLS, warmup_start_ammo_shells);
 555                 SetResourceAmount(this, RESOURCE_BULLETS, warmup_start_ammo_nails);
 556                 SetResourceAmount(this, RESOURCE_ROCKETS, warmup_start_ammo_rockets);
 557                 SetResourceAmount(this, RESOURCE_CELLS, warmup_start_ammo_cells);
 558                 SetResourceAmount(this, RESOURCE_PLASMA, warmup_start_ammo_plasma);
 559                 SetResourceAmount(this, RESOURCE_FUEL, warmup_start_ammo_fuel);
 560                 SetResourceAmount(this, RESOURCE_HEALTH, warmup_start_health);
 561                 SetResourceAmount(this, RESOURCE_ARMOR, warmup_start_armorvalue);
 562                 STAT(WEAPONS, this) = WARMUP_START_WEAPONS;
 563         } else {
 564                 SetResourceAmount(this, RESOURCE_SHELLS, start_ammo_shells);
 565                 SetResourceAmount(this, RESOURCE_BULLETS, start_ammo_nails);
 566                 SetResourceAmount(this, RESOURCE_ROCKETS, start_ammo_rockets);
 567                 SetResourceAmount(this, RESOURCE_CELLS, start_ammo_cells);
 568                 SetResourceAmount(this, RESOURCE_PLASMA, start_ammo_plasma);
 569                 SetResourceAmount(this, RESOURCE_FUEL, start_ammo_fuel);
 570                 SetResourceAmount(this, RESOURCE_HEALTH, start_health);
 571                 SetResourceAmount(this, RESOURCE_ARMOR, start_armorvalue);
 572                 STAT(WEAPONS, this) = start_weapons;
 573                 if (MUTATOR_CALLHOOK(ForbidRandomStartWeapons, this) == false)
 574                 {
 575                         GiveRandomWeapons(this, random_start_weapons_count,
 576                                 autocvar_g_random_start_weapons, random_start_ammo);
 577                 }
 578         }
 579         SetSpectatee_status(this, 0);
 580
 581         PS(this).dual_weapons = '0 0 0';
 582
 583         this.superweapons_finished = (STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS) ? time + autocvar_g_balance_superweapons_time : 0;
 584
 585         this.items = start_items;
 586
 587         this.spawnshieldtime = time + autocvar_g_spawnshieldtime;
 588         this.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 589         this.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 590         this.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 591         this.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 592         if (!sv_ready_restart_after_countdown && time < game_starttime)
 593         {
 594                 float f = game_starttime - time;
 595                 this.spawnshieldtime += f;
 596                 this.pauserotarmor_finished += f;
 597                 this.pauserothealth_finished += f;
 598                 this.pauseregen_finished += f;
 599         }
 600
 601         this.damageforcescale = 2;
 602         this.death_time = 0;
 603         this.respawn_flags = 0;
 604         this.respawn_time = 0;
 605         STAT(RESPAWN_TIME, this) = 0;
 606         this.scale = autocvar_sv_player_scale;
 607         this.fade_time = 0;
 608         this.pain_frame = 0;
 609         this.pain_finished = 0;
 610         this.pushltime = 0;
 611         setthink(this, func_null); // players have no think function
 612         this.nextthink = 0;
 613         this.dmg_team = 0;
 614         PS(this).ballistics_density = autocvar_g_ballistics_density_player;
 615
 616         this.deadflag = DEAD_NO;
 617
 618         this.angles = spot.angles;
 619         this.angles_z = 0; // never spawn tilted even if the spot says to
 620         if (IS_BOT_CLIENT(this))
 621                 this.v_angle = this.angles;
 622         this.fixangle = true; // turn this way immediately
 623         this.oldvelocity = this.velocity = '0 0 0';
 624         this.avelocity = '0 0 0';
 625         this.punchangle = '0 0 0';
 626         this.punchvector = '0 0 0';
 627
 628         this.strength_finished = 0;
 629         this.invincible_finished = 0;
 630         this.fire_endtime = -1;
 631         STAT(REVIVE_PROGRESS, this) = 0;
 632         this.revival_time = 0;
 633
 634         this.air_finished = time + 12;
 635         this.waterlevel = WATERLEVEL_NONE;
 636         this.watertype = CONTENT_EMPTY;
 637
 638         entity spawnevent = new_pure(spawnevent);
 639         spawnevent.owner = this;
 640         Net_LinkEntity(spawnevent, false, 0.5, SpawnEvent_Send);
 641
 642         // Cut off any still running player sounds.
 643         stopsound(this, CH_PLAYER_SINGLE);
 644
 645         this.model = "";
 646         FixPlayermodel(this);
 647         this.drawonlytoclient = NULL;
 648
 649         this.viewloc = NULL;
 650
 651         for(int slot = 0; slot < MAX_AXH; ++slot)
 652         {
 653                 entity axh = this.(AuxiliaryXhair[slot]);
 654                 this.(AuxiliaryXhair[slot]) = NULL;
 655
 656                 if(axh.owner == this && axh != NULL && !wasfreed(axh))
 657                         delete(axh);
 658         }
 659
 660         this.spawnpoint_targ = NULL;
 661
 662         this.crouch = false;
 663         this.view_ofs = STAT(PL_VIEW_OFS, this);
 664         setsize(this, STAT(PL_MIN, this), STAT(PL_MAX, this));
 665         this.spawnorigin = spot.origin;
 666         setorigin(this, spot.origin + '0 0 1' * (1 - this.mins.z - 24));
 667         // don't reset back to last position, even if new position is stuck in solid
 668         this.oldorigin = this.origin;
 669         if(this.conveyor)
 670                 IL_REMOVE(g_conveyed, this);
 671         this.conveyor = NULL; // prevent conveyors at the previous location from moving a freshly spawned player
 672         STAT(HUD, this) = HUD_NORMAL;
 673
 674         this.event_damage = PlayerDamage;
 675         this.event_heal = PlayerHeal;
 676
 677         if(!this.bot_attack)
 678                 IL_PUSH(g_bot_targets, this);
 679         this.bot_attack = true;
 680         if(!this.monster_attack)
 681                 IL_PUSH(g_monster_targets, this);
 682         this.monster_attack = true;
 683         navigation_dynamicgoal_init(this, false);
 684
 685         PHYS_INPUT_BUTTON_ATCK(this) = PHYS_INPUT_BUTTON_JUMP(this) = PHYS_INPUT_BUTTON_ATCK2(this) = false;
 686
 687         // player was spectator
 688         if (CS(this).killcount == FRAGS_SPECTATOR) {
 689                 PlayerScore_Clear(this);
 690                 CS(this).killcount = 0;
 691                 CS(this).startplaytime = time;
 692         }
 693
 694         for (int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 695         {
 696                 .entity weaponentity = weaponentities[slot];
 697                 entity oldwep = this.(weaponentity);
 698                 CL_SpawnWeaponentity(this, weaponentity);
 699                 if(oldwep && oldwep.owner == this)
 700                         this.(weaponentity).m_gunalign = oldwep.m_gunalign;
 701         }
 702         this.alpha = default_player_alpha;
 703         this.colormod = '1 1 1' * autocvar_g_player_brightness;
 704         this.exteriorweaponentity.alpha = default_weapon_alpha;
 705
 706         this.speedrunning = false;
 707
 708         target_voicescript_clear(this);
 709
 710         // reset fields the weapons may use
 711         FOREACH(Weapons, true, {
 712                 it.wr_resetplayer(it, this);
 713                         // reload all reloadable weapons
 714                 if (it.spawnflags & WEP_FLAG_RELOADABLE) {
 715                         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 716                         {
 717                                 .entity weaponentity = weaponentities[slot];
 718                                 this.(weaponentity).weapon_load[it.m_id] = it.reloading_ammo;
 719                         }
 720                 }
 721         });
 722
 723         {
 724                 string s = spot.target;
 725                 spot.target = string_null;
 726                 SUB_UseTargets(spot, this, NULL);
 727                 spot.target = s;
 728         }
 729
 730         Unfreeze(this);
 731
 732         MUTATOR_CALLHOOK(PlayerSpawn, this, spot);
 733
 734         if (autocvar_spawn_debug)
 735         {
 736                 sprint(this, strcat("spawnpoint origin:  ", vtos(spot.origin), "\n"));
 737                 delete(spot); // usefull for checking if there are spawnpoints, that let drop through the floor
 738         }
 739
 740         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 741         {
 742                 .entity weaponentity = weaponentities[slot];
 743                 if(slot == 0 || autocvar_g_weaponswitch_debug == 1)
 744                         this.(weaponentity).m_switchweapon = w_getbestweapon(this, weaponentity);
 745                 else
 746                         this.(weaponentity).m_switchweapon = WEP_Null;
 747                 this.(weaponentity).m_weapon = WEP_Null;
 748                 this.(weaponentity).weaponname = "";
 749                 this.(weaponentity).m_switchingweapon = WEP_Null;
 750                 this.(weaponentity).cnt = -1;
 751         }
 752
 753         MUTATOR_CALLHOOK(PlayerWeaponSelect, this);
 754
 755         if (CS(this).impulse) ImpulseCommands(this);
 756
 757         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 758         {
 759                 .entity weaponentity = weaponentities[slot];
 760                 W_WeaponFrame(this, weaponentity);
 761         }
 762
 763         if (!warmup_stage && !this.alivetime)
 764                 this.alivetime = time;
 765
 766         antilag_clear(this, CS(this));
 767 }
 768
 769 /** Called when a client spawns in the server */
 770 void PutClientInServer(entity this)
 771 {
 772         if (IS_BOT_CLIENT(this)) {
 773                 TRANSMUTE(Player, this);
 774         } else if (IS_REAL_CLIENT(this)) {
 775                 msg_entity = this;
 776                 WriteByte(MSG_ONE, SVC_SETVIEW);
 777                 WriteEntity(MSG_ONE, this);
 778         }
 779         if (game_stopped)
 780                 TRANSMUTE(Observer, this);
 781
 782         SetSpectatee(this, NULL);
 783
 784         // reset player keys
 785         if(PS(this))
 786                 PS(this).itemkeys = 0;
 787
 788         MUTATOR_CALLHOOK(PutClientInServer, this);
 789
 790         if (IS_OBSERVER(this)) {
 791                 PutObserverInServer(this);
 792         } else if (IS_PLAYER(this)) {
 793                 PutPlayerInServer(this);
 794         }
 795 }
 796
 797 // TODO do we need all these fields, or should we stop autodetecting runtime
 798 // changes and just have a console command to update this?
 799 bool ClientInit_SendEntity(entity this, entity to, int sf)
 800 {
 801         WriteHeader(MSG_ENTITY, _ENT_CLIENT_INIT);
 802         return = true;
 803         msg_entity = to;
 804         // MSG_INIT replacement
 805         // TODO: make easier to use
 806         Registry_send_all();
 807         W_PROP_reload(MSG_ONE, to);
 808         ClientInit_misc(this);
 809         MUTATOR_CALLHOOK(Ent_Init);
 810 }
 811 void ClientInit_misc(entity this)
 812 {
 813         int channel = MSG_ONE;
 814         WriteHeader(channel, ENT_CLIENT_INIT);
 815         WriteByte(channel, g_nexball_meter_period * 32);
 816         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[0]));
 817         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[1]));
 818         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[2]));
 819         WriteInt24_t(channel, compressShotOrigin(hook_shotorigin[3]));
 820         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[0]));
 821         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[1]));
 822         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[2]));
 823         WriteInt24_t(channel, compressShotOrigin(arc_shotorigin[3]));
 824
 825         if(sv_foginterval && world.fog != "")
 826                 WriteString(channel, world.fog);
 827         else
 828                 WriteString(channel, "");
 829         WriteByte(channel, this.count * 255.0); // g_balance_armor_blockpercent
 830         WriteByte(channel, this.cnt * 255.0); // g_balance_damagepush_speedfactor
 831         WriteByte(channel, serverflags);
 832         WriteCoord(channel, autocvar_g_trueaim_minrange);
 833 }
 834
 835 void ClientInit_CheckUpdate(entity this)
 836 {
 837         this.nextthink = time;
 838         if(this.count != autocvar_g_balance_armor_blockpercent)
 839         {
 840                 this.count = autocvar_g_balance_armor_blockpercent;
 841                 this.SendFlags |= 1;
 842         }
 843         if(this.cnt != autocvar_g_balance_damagepush_speedfactor)
 844         {
 845                 this.cnt = autocvar_g_balance_damagepush_speedfactor;
 846                 this.SendFlags |= 1;
 847         }
 848 }
 849
 850 void ClientInit_Spawn()
 851 {
 852         entity e = new_pure(clientinit);
 853         setthink(e, ClientInit_CheckUpdate);
 854         Net_LinkEntity(e, false, 0, ClientInit_SendEntity);
 855
 856         ClientInit_CheckUpdate(e);
 857 }
 858
 859 /*
 860 =============
 861 SetNewParms
 862 =============
 863 */
 864 void SetNewParms ()
 865 {
 866         // initialize parms for a new player
 867         parm1 = -(86400 * 366);
 868
 869         MUTATOR_CALLHOOK(SetNewParms);
 870 }
 871
 872 /*
 873 =============
 874 SetChangeParms
 875 =============
 876 */
 877 void SetChangeParms (entity this)
 878 {
 879         // save parms for level change
 880         parm1 = CS(this).parm_idlesince - time;
 881
 882         MUTATOR_CALLHOOK(SetChangeParms);
 883 }
 884
 885 /*
 886 =============
 887 DecodeLevelParms
 888 =============
 889 */
 890 void DecodeLevelParms(entity this)
 891 {
 892         // load parms
 893         CS(this).parm_idlesince = parm1;
 894         if (CS(this).parm_idlesince == -(86400 * 366))
 895                 CS(this).parm_idlesince = time;
 896
 897         // whatever happens, allow 60 seconds of idling directly after connect for map loading
 898         CS(this).parm_idlesince = max(CS(this).parm_idlesince, time - sv_maxidle + 60);
 899
 900         MUTATOR_CALLHOOK(DecodeLevelParms);
 901 }
 902
 903 /*
 904 =============
 905 ClientKill
 906
 907 Called when a client types 'kill' in the console
 908 =============
 909 */
 910
 911 .float clientkill_nexttime;
 912 void ClientKill_Now_TeamChange(entity this)
 913 {
 914         if(this.killindicator_teamchange == -1)
 915         {
 916                 TeamBalance_JoinBestTeam(this);
 917         }
 918         else if(this.killindicator_teamchange == -2)
 919         {
 920                 if(blockSpectators)
 921                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
 922                 PutObserverInServer(this);
 923         }
 924         else
 925                 SV_ChangeTeam(this, this.killindicator_teamchange - 1);
 926         this.killindicator_teamchange = 0;
 927 }
 928
 929 void ClientKill_Now(entity this)
 930 {
 931         if(this.vehicle)
 932         {
 933             vehicles_exit(this.vehicle, VHEF_RELEASE);
 934             if(!this.killindicator_teamchange)
 935             {
 936             this.vehicle_health = -1;
 937             Damage(this, this, this, 1 , DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 938             }
 939         }
 940
 941         if(this.killindicator && !wasfreed(this.killindicator))
 942                 delete(this.killindicator);
 943
 944         this.killindicator = NULL;
 945
 946         if(this.killindicator_teamchange)
 947                 ClientKill_Now_TeamChange(this);
 948
 949         if (!IS_SPEC(this) && !IS_OBSERVER(this) && MUTATOR_CALLHOOK(ClientKill_Now, this) == false)
 950         {
 951                 Damage(this, this, this, 100000, DEATH_KILL.m_id, DMG_NOWEP, this.origin, '0 0 0');
 952         }
 953
 954         // now I am sure the player IS dead
 955 }
 956 void KillIndicator_Think(entity this)
 957 {
 958         if (game_stopped)
 959         {
 960                 this.owner.killindicator = NULL;
 961                 delete(this);
 962                 return;
 963         }
 964
 965         if (this.owner.alpha < 0 && !this.owner.vehicle)
 966         {
 967                 this.owner.killindicator = NULL;
 968                 delete(this);
 969                 return;
 970         }
 971
 972         if(this.cnt <= 0)
 973         {
 974                 ClientKill_Now(this.owner);
 975                 return;
 976         }
 977     else if(this.count == 1) // count == 1 means that it's silent
 978     {
 979         this.nextthink = time + 1;
 980         this.cnt -= 1;
 981     }
 982         else
 983         {
 984                 if(this.cnt <= 10)
 985                         setmodel(this, MDL_NUM(this.cnt));
 986                 if(IS_REAL_CLIENT(this.owner))
 987                 {
 988                         if(this.cnt <= 10)
 989                                 { Send_Notification(NOTIF_ONE, this.owner, MSG_ANNCE, Announcer_PickNumber(CNT_KILL, this.cnt)); }
 990                 }
 991                 this.nextthink = time + 1;
 992                 this.cnt -= 1;
 993         }
 994 }
 995
 996 float clientkilltime;
 997 void ClientKill_TeamChange (entity this, float targetteam) // 0 = don't change, -1 = auto, -2 = spec
 998 {
 999         float killtime;
1000         float starttime;
1001
1002         if (game_stopped)
1003                 return;
1004
1005         killtime = autocvar_g_balance_kill_delay;
1006
1007     if(MUTATOR_CALLHOOK(ClientKill, this, killtime))
1008         return;
1009     killtime = M_ARGV(1, float);
1010
1011         this.killindicator_teamchange = targetteam;
1012
1013     if(!this.killindicator)
1014         {
1015                 if(!IS_DEAD(this))
1016                 {
1017                         killtime = max(killtime, this.clientkill_nexttime - time);
1018                         this.clientkill_nexttime = time + killtime + autocvar_g_balance_kill_antispam;
1019                 }
1020
1021                 if(killtime <= 0 || !IS_PLAYER(this) || IS_DEAD(this))
1022                 {
1023                         ClientKill_Now(this);
1024                 }
1025                 else
1026                 {
1027                         starttime = max(time, clientkilltime);
1028
1029                         this.killindicator = spawn();
1030                         this.killindicator.owner = this;
1031                         this.killindicator.scale = 0.5;
1032                         setattachment(this.killindicator, this, "");
1033                         setorigin(this.killindicator, '0 0 52');
1034                         setthink(this.killindicator, KillIndicator_Think);
1035                         this.killindicator.nextthink = starttime + (this.lip) * 0.05;
1036                         clientkilltime = max(clientkilltime, this.killindicator.nextthink + 0.05);
1037                         this.killindicator.cnt = ceil(killtime);
1038                         this.killindicator.count = bound(0, ceil(killtime), 10);
1039                         //sprint(this, strcat("^1You'll be dead in ", ftos(this.killindicator.cnt), " seconds\n"));
1040
1041                         IL_EACH(g_clones, it.enemy == this && !(it.effects & CSQCMODEL_EF_RESPAWNGHOST),
1042                         {
1043                                 it.killindicator = spawn();
1044                                 it.killindicator.owner = it;
1045                                 it.killindicator.scale = 0.5;
1046                                 setattachment(it.killindicator, it, "");
1047                                 setorigin(it.killindicator, '0 0 52');
1048                                 setthink(it.killindicator, KillIndicator_Think);
1049                                 it.killindicator.nextthink = starttime + (it.lip) * 0.05;
1050                                 //clientkilltime = max(clientkilltime, it.killindicator.nextthink + 0.05);
1051                                 it.killindicator.cnt = ceil(killtime);
1052                         });
1053                         this.lip = 0;
1054                 }
1055         }
1056         if(this.killindicator)
1057         {
1058                 if(targetteam == 0) // just die
1059                 {
1060                         this.killindicator.colormod = '0 0 0';
1061                         if(IS_REAL_CLIENT(this))
1062                         if(this.killindicator.cnt > 0)
1063                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SUICIDE, this.killindicator.cnt);
1064                 }
1065                 else if(targetteam == -1) // auto
1066                 {
1067                         this.killindicator.colormod = '0 1 0';
1068                         if(IS_REAL_CLIENT(this))
1069                         if(this.killindicator.cnt > 0)
1070                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_AUTO, this.killindicator.cnt);
1071                 }
1072                 else if(targetteam == -2) // spectate
1073                 {
1074                         this.killindicator.colormod = '0.5 0.5 0.5';
1075                         if(IS_REAL_CLIENT(this))
1076                         if(this.killindicator.cnt > 0)
1077                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_TEAMCHANGE_SPECTATE, this.killindicator.cnt);
1078                 }
1079                 else
1080                 {
1081                         this.killindicator.colormod = Team_ColorRGB(targetteam);
1082                         if(IS_REAL_CLIENT(this))
1083                         if(this.killindicator.cnt > 0)
1084                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, APP_TEAM_NUM(targetteam, CENTER_TEAMCHANGE), this.killindicator.cnt);
1085                 }
1086         }
1087
1088 }
1089
1090 void ClientKill (entity this)
1091 {
1092         // TODO: once .health is removed, will need to check it here for the "already dead" message!
1093
1094         if(game_stopped) return;
1095         if(this.player_blocked) return;
1096         if(STAT(FROZEN, this)) return;
1097
1098         ClientKill_TeamChange(this, 0);
1099 }
1100
1101 void FixClientCvars(entity e)
1102 {
1103         // send prediction settings to the client
1104         stuffcmd(e, "\nin_bindmap 0 0\n");
1105         if(autocvar_g_antilag == 3) // client side hitscan
1106                 stuffcmd(e, "cl_cmd settemp cl_prydoncursor_notrace 0\n");
1107         if(autocvar_sv_gentle)
1108                 stuffcmd(e, "cl_cmd settemp cl_gentle 1\n");
1109
1110         stuffcmd(e, sprintf("\ncl_jumpspeedcap_min \"%s\"\n", autocvar_sv_jumpspeedcap_min));
1111         stuffcmd(e, sprintf("\ncl_jumpspeedcap_max \"%s\"\n", autocvar_sv_jumpspeedcap_max));
1112
1113         stuffcmd(e, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
1114
1115         MUTATOR_CALLHOOK(FixClientCvars, e);
1116 }
1117
1118 bool findinlist_abbrev(string tofind, string list)
1119 {
1120         if(list == "" || tofind == "")
1121                 return false; // empty list or search, just return
1122
1123         // this function allows abbreviated strings!
1124         FOREACH_WORD(list, it == substring(tofind, 0, strlen(it)),
1125         {
1126                 return true;
1127         });
1128
1129         return false;
1130 }
1131
1132 bool PlayerInIPList(entity p, string iplist)
1133 {
1134         // some safety checks (never allow local?)
1135         if(p.netaddress == "local" || p.netaddress == "" || !IS_REAL_CLIENT(p))
1136                 return false;
1137
1138         return findinlist_abbrev(p.netaddress, iplist);
1139 }
1140
1141 bool PlayerInIDList(entity p, string idlist)
1142 {
1143         // NOTE: we do NOT check crypto_idfp_signed here, an unsigned ID is fine too for this
1144         if(!p.crypto_idfp)
1145                 return false;
1146
1147         return findinlist_abbrev(p.crypto_idfp, idlist);
1148 }
1149
1150 bool PlayerInList(entity player, string list)
1151 {
1152         return boolean(PlayerInIDList(player, list) || PlayerInIPList(player, list));
1153 }
1154
1155 #ifdef DP_EXT_PRECONNECT
1156 /*
1157 =============
1158 ClientPreConnect
1159
1160 Called once (not at each match start) when a client begins a connection to the server
1161 =============
1162 */
1163 void ClientPreConnect(entity this)
1164 {
1165         if(autocvar_sv_eventlog)
1166         {
1167                 GameLogEcho(sprintf(":connect:%d:%d:%s",
1168                         this.playerid,
1169                         etof(this),
1170                         ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot")
1171                 ));
1172         }
1173 }
1174 #endif
1175
1176 string GetClientVersionMessage(entity this)
1177 {
1178         if (CS(this).version_mismatch) {
1179                 if(CS(this).version < autocvar_gameversion) {
1180                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1181                                 "\n^3Your client version is outdated.\n\n\n### YOU WON'T BE ABLE TO PLAY ON THIS SERVER ###\n\n\nPlease update!!!^8");
1182                 } else {
1183                         return strcat("This is Xonotic ", autocvar_g_xonoticversion,
1184                                 "\n^3This server is using an outdated Xonotic version.\n\n\n ### THIS SERVER IS INCOMPATIBLE AND THUS YOU CANNOT JOIN ###.^8");
1185                 }
1186         } else {
1187                 return strcat("Welcome to Xonotic ", autocvar_g_xonoticversion);
1188         }
1189 }
1190
1191 string getwelcomemessage(entity this)
1192 {
1193         MUTATOR_CALLHOOK(BuildMutatorsPrettyString, "");
1194         string modifications = M_ARGV(0, string);
1195
1196         if(g_weaponarena)
1197         {
1198                 if(g_weaponarena_random)
1199                         modifications = strcat(modifications, ", ", ftos(g_weaponarena_random), " of ", g_weaponarena_list, " Arena");
1200                 else
1201                         modifications = strcat(modifications, ", ", g_weaponarena_list, " Arena");
1202         }
1203         else if(cvar("g_balance_blaster_weaponstartoverride") == 0)
1204                 modifications = strcat(modifications, ", No start weapons");
1205         if(cvar("sv_gravity") < stof(cvar_defstring("sv_gravity")))
1206                 modifications = strcat(modifications, ", Low gravity");
1207         if(g_weapon_stay && !g_cts)
1208                 modifications = strcat(modifications, ", Weapons stay");
1209         if(g_jetpack)
1210                 modifications = strcat(modifications, ", Jet pack");
1211         if(autocvar_g_powerups == 0)
1212                 modifications = strcat(modifications, ", No powerups");
1213         if(autocvar_g_powerups > 0)
1214                 modifications = strcat(modifications, ", Powerups");
1215         modifications = substring(modifications, 2, strlen(modifications) - 2);
1216
1217         string versionmessage = GetClientVersionMessage(this);
1218         string s = strcat(versionmessage, "^8\n^8\nmatch type is ^1", gamemode_name, "^8\n");
1219
1220         if(modifications != "")
1221                 s = strcat(s, "^8\nactive modifications: ^3", modifications, "^8\n");
1222
1223         if(cache_lastmutatormsg != autocvar_g_mutatormsg)
1224         {
1225                 strcpy(cache_lastmutatormsg, autocvar_g_mutatormsg);
1226                 strcpy(cache_mutatormsg, cache_lastmutatormsg);
1227         }
1228
1229         if (cache_mutatormsg != "") {
1230                 s = strcat(s, "\n\n^8special gameplay tips: ^7", cache_mutatormsg);
1231         }
1232
1233         string mutator_msg = "";
1234         MUTATOR_CALLHOOK(BuildGameplayTipsString, mutator_msg);
1235         mutator_msg = M_ARGV(0, string);
1236
1237         s = strcat(s, mutator_msg); // trust that the mutator will do proper formatting
1238
1239         string motd = autocvar_sv_motd;
1240         if (motd != "") {
1241                 s = strcat(s, "\n\n^8MOTD: ^7", strreplace("\\n", "\n", motd));
1242         }
1243         return s;
1244 }
1245
1246 /**
1247 =============
1248 ClientConnect
1249
1250 Called when a client connects to the server
1251 =============
1252 */
1253 void ClientConnect(entity this)
1254 {
1255         if (Ban_MaybeEnforceBanOnce(this)) return;
1256         assert(!IS_CLIENT(this), return);
1257         this.flags |= FL_CLIENT;
1258         assert(player_count >= 0, player_count = 0);
1259
1260 #ifdef WATERMARK
1261         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_WATERMARK, WATERMARK);
1262 #endif
1263         TRANSMUTE(Client, this);
1264         CS(this).version_nagtime = time + 10 + random() * 10;
1265
1266         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_CONNECT, this.netname);
1267
1268         bot_clientconnect(this);
1269
1270         Player_DetermineForcedTeam(this);
1271
1272         TRANSMUTE(Observer, this);
1273
1274         PlayerStats_GameReport_AddEvent(sprintf("kills-%d", this.playerid));
1275
1276         // always track bots, don't ask for cl_allow_uidtracking
1277         if (IS_BOT_CLIENT(this))
1278                 PlayerStats_GameReport_AddPlayer(this);
1279         else
1280                 CS(this).allowed_timeouts = autocvar_sv_timeout_number;
1281
1282         if (autocvar_sv_eventlog)
1283                 GameLogEcho(strcat(":join:", ftos(this.playerid), ":", ftos(etof(this)), ":", ((IS_REAL_CLIENT(this)) ? this.netaddress : "bot"), ":", playername(this, false)));
1284
1285         CS(this).just_joined = true;  // stop spamming the eventlog with additional lines when the client connects
1286
1287         stuffcmd(this, clientstuff, "\n");
1288         stuffcmd(this, "cl_particles_reloadeffects\n"); // TODO do we still need this?
1289
1290         FixClientCvars(this);
1291
1292         // get version info from player
1293         stuffcmd(this, "cmd clientversion $gameversion\n");
1294
1295         // notify about available teams
1296         if (teamplay)
1297         {
1298                 entity balance = TeamBalance_CheckAllowedTeams(this);
1299                 int t = TeamBalance_GetAllowedTeams(balance);
1300                 TeamBalance_Destroy(balance);
1301                 stuffcmd(this, sprintf("set _teams_available %d\n", t));
1302         }
1303         else
1304         {
1305                 stuffcmd(this, "set _teams_available 0\n");
1306         }
1307
1308         bot_relinkplayerlist();
1309
1310         CS(this).spectatortime = time;
1311         if (blockSpectators)
1312         {
1313                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_SPECTATE_WARNING, autocvar_g_maxplayers_spectator_blocktime);
1314         }
1315
1316         CS(this).jointime = time;
1317
1318         if (IS_REAL_CLIENT(this))
1319         {
1320                 if (g_weaponarena_weapons == WEPSET(TUBA))
1321                         stuffcmd(this, "cl_cmd settemp chase_active 1\n");
1322         }
1323
1324         if (!sv_foginterval && world.fog != "")
1325                 stuffcmd(this, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1326
1327         if (autocvar_sv_teamnagger && !(autocvar_bot_vs_human && AvailableTeams() == 2))
1328                 if(!MUTATOR_CALLHOOK(HideTeamNagger, this))
1329                         send_CSQC_teamnagger();
1330
1331         CSQCMODEL_AUTOINIT(this);
1332
1333         CS(this).model_randomizer = random();
1334
1335         if (IS_REAL_CLIENT(this))
1336                 sv_notice_join(this);
1337
1338         // update physics stats (players can spawn before physics runs)
1339         Physics_UpdateStats(this);
1340
1341         IL_EACH(g_initforplayer, it.init_for_player, {
1342                 it.init_for_player(it, this);
1343         });
1344
1345         Handicap_Initialize(this);
1346
1347         MUTATOR_CALLHOOK(ClientConnect, this);
1348
1349         if (IS_REAL_CLIENT(this))
1350         {
1351                 if (!autocvar_g_campaign && !IS_PLAYER(this))
1352                 {
1353                         CS(this).motd_actived_time = -1;
1354                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
1355                 }
1356         }
1357 }
1358 /*
1359 =============
1360 ClientDisconnect
1361
1362 Called when a client disconnects from the server
1363 =============
1364 */
1365 .entity chatbubbleentity;
1366 void ClientDisconnect(entity this)
1367 {
1368         assert(IS_CLIENT(this), return);
1369
1370         PlayerStats_GameReport_FinalizePlayer(this);
1371         if (this.vehicle) vehicles_exit(this.vehicle, VHEF_RELEASE);
1372         if (CS(this).active_minigame) part_minigame(this);
1373         if (IS_PLAYER(this)) Send_Effect(EFFECT_SPAWN_NEUTRAL, this.origin, '0 0 0', 1);
1374
1375         if (autocvar_sv_eventlog)
1376                 GameLogEcho(strcat(":part:", ftos(this.playerid)));
1377
1378         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_DISCONNECT, this.netname);
1379
1380         if(IS_SPEC(this))
1381                 SetSpectatee(this, NULL);
1382
1383     MUTATOR_CALLHOOK(ClientDisconnect, this);
1384
1385         strfree(CS(this).netname_previous); // needs to be before the CS entity is removed!
1386         strfree(CS(this).weaponorder_byimpulse);
1387         ClientState_detach(this);
1388
1389         Portal_ClearAll(this);
1390
1391         Unfreeze(this);
1392
1393         RemoveGrapplingHooks(this);
1394
1395         // Here, everything has been done that requires this player to be a client.
1396
1397         this.flags &= ~FL_CLIENT;
1398
1399         if (this.chatbubbleentity) delete(this.chatbubbleentity);
1400         if (this.killindicator) delete(this.killindicator);
1401
1402         WaypointSprite_PlayerGone(this);
1403
1404         bot_relinkplayerlist();
1405
1406         strfree(this.clientstatus);
1407         if (this.personal) delete(this.personal);
1408
1409         this.playerid = 0;
1410         ReadyCount();
1411         if (vote_called && IS_REAL_CLIENT(this)) VoteCount(false);
1412
1413         ONREMOVE(this);
1414 }
1415
1416 void ChatBubbleThink(entity this)
1417 {
1418         this.nextthink = time;
1419         if ((this.owner.alpha < 0) || this.owner.chatbubbleentity != this)
1420         {
1421                 if(this.owner) // but why can that ever be NULL?
1422                         this.owner.chatbubbleentity = NULL;
1423                 delete(this);
1424                 return;
1425         }
1426
1427         this.mdl = "";
1428
1429         if ( !IS_DEAD(this.owner) && IS_PLAYER(this.owner) )
1430         {
1431                 if ( CS(this.owner).active_minigame )
1432                         this.mdl = "models/sprites/minigame_busy.iqm";
1433                 else if (PHYS_INPUT_BUTTON_CHAT(this.owner))
1434                         this.mdl = "models/misc/chatbubble.spr";
1435         }
1436
1437         if ( this.model != this.mdl )
1438                 _setmodel(this, this.mdl);
1439
1440 }
1441
1442 void UpdateChatBubble(entity this)
1443 {
1444         if (this.alpha < 0)
1445                 return;
1446         // spawn a chatbubble entity if needed
1447         if (!this.chatbubbleentity)
1448         {
1449                 this.chatbubbleentity = new(chatbubbleentity);
1450                 this.chatbubbleentity.owner = this;
1451                 this.chatbubbleentity.exteriormodeltoclient = this;
1452                 setthink(this.chatbubbleentity, ChatBubbleThink);
1453                 this.chatbubbleentity.nextthink = time;
1454                 setmodel(this.chatbubbleentity, MDL_CHAT); // precision set below
1455                 //setorigin(this.chatbubbleentity, this.origin + '0 0 15' + this.maxs_z * '0 0 1');
1456                 setorigin(this.chatbubbleentity, '0 0 15' + this.maxs_z * '0 0 1');
1457                 setattachment(this.chatbubbleentity, this, "");  // sticks to moving player better, also conserves bandwidth
1458                 this.chatbubbleentity.mdl = this.chatbubbleentity.model;
1459                 //this.chatbubbleentity.model = "";
1460                 this.chatbubbleentity.effects = EF_LOWPRECISION;
1461         }
1462 }
1463
1464
1465 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
1466 // added to the model skins
1467 /*void UpdateColorModHack()
1468 {
1469         float c;
1470         c = this.clientcolors & 15;
1471         // LordHavoc: only bothering to support white, green, red, yellow, blue
1472              if (!teamplay) this.colormod = '0 0 0';
1473         else if (c ==  0) this.colormod = '1.00 1.00 1.00';
1474         else if (c ==  3) this.colormod = '0.10 1.73 0.10';
1475         else if (c ==  4) this.colormod = '1.73 0.10 0.10';
1476         else if (c == 12) this.colormod = '1.22 1.22 0.10';
1477         else if (c == 13) this.colormod = '0.10 0.10 1.73';
1478         else this.colormod = '1 1 1';
1479 }*/
1480
1481 void respawn(entity this)
1482 {
1483         if(this.alpha >= 0 && autocvar_g_respawn_ghosts)
1484         {
1485                 this.solid = SOLID_NOT;
1486                 this.takedamage = DAMAGE_NO;
1487                 set_movetype(this, MOVETYPE_FLY);
1488                 this.velocity = '0 0 1' * autocvar_g_respawn_ghosts_speed;
1489                 this.avelocity = randomvec() * autocvar_g_respawn_ghosts_speed * 3 - randomvec() * autocvar_g_respawn_ghosts_speed * 3;
1490                 this.effects |= CSQCMODEL_EF_RESPAWNGHOST;
1491                 Send_Effect(EFFECT_RESPAWN_GHOST, this.origin, '0 0 0', 1);
1492                 if(autocvar_g_respawn_ghosts_maxtime)
1493                         SUB_SetFade (this, time + autocvar_g_respawn_ghosts_maxtime / 2 + random () * (autocvar_g_respawn_ghosts_maxtime - autocvar_g_respawn_ghosts_maxtime / 2), 1.5);
1494         }
1495
1496         CopyBody(this, 1);
1497
1498         this.effects |= EF_NODRAW; // prevent another CopyBody
1499         PutClientInServer(this);
1500 }
1501
1502 void PrintToChat(entity client, string text)
1503 {
1504         text = strcat("\{1}^7", text, "\n");
1505         sprint(client, text);
1506 }
1507
1508 void DebugPrintToChat(entity client, string text)
1509 {
1510         if (autocvar_developer)
1511         {
1512                 PrintToChat(client, text);
1513         }
1514 }
1515
1516 void PrintToChatAll(string text)
1517 {
1518         text = strcat("\{1}^7", text, "\n");
1519         bprint(text);
1520 }
1521
1522 void DebugPrintToChatAll(string text)
1523 {
1524         if (autocvar_developer)
1525         {
1526                 PrintToChatAll(text);
1527         }
1528 }
1529
1530 void PrintToChatTeam(int team_num, string text)
1531 {
1532         text = strcat("\{1}^7", text, "\n");
1533         FOREACH_CLIENT(IS_REAL_CLIENT(it),
1534         {
1535                 if (it.team == team_num)
1536                 {
1537                         sprint(it, text);
1538                 }
1539         });
1540 }
1541
1542 void DebugPrintToChatTeam(int team_num, string text)
1543 {
1544         if (autocvar_developer)
1545         {
1546                 PrintToChatTeam(team_num, text);
1547         }
1548 }
1549
1550 void play_countdown(entity this, float finished, Sound samp)
1551 {
1552         TC(Sound, samp);
1553         if(IS_REAL_CLIENT(this))
1554                 if(floor(finished - time - frametime) != floor(finished - time))
1555                         if(finished - time < 6)
1556                                 sound (this, CH_INFO, samp, VOL_BASE, ATTEN_NORM);
1557 }
1558
1559 void player_powerups(entity this)
1560 {
1561         // add a way to see what the items were BEFORE all of these checks for the mutator hook
1562         int items_prev = this.items;
1563
1564         if((this.items & IT_USING_JETPACK) && !IS_DEAD(this) && !game_stopped)
1565                 this.modelflags |= MF_ROCKET;
1566         else
1567                 this.modelflags &= ~MF_ROCKET;
1568
1569         this.effects &= ~(EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT | EF_FLAME | EF_NODEPTHTEST);
1570
1571         if((this.alpha < 0 || IS_DEAD(this)) && !this.vehicle) // don't apply the flags if the player is gibbed
1572                 return;
1573
1574         Fire_ApplyDamage(this);
1575         Fire_ApplyEffect(this);
1576
1577         if (!MUTATOR_IS_ENABLED(mutator_instagib))
1578         {
1579                 if (this.items & ITEM_Strength.m_itemid)
1580                 {
1581                         play_countdown(this, this.strength_finished, SND_POWEROFF);
1582                         this.effects = this.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
1583                         if (time > this.strength_finished)
1584                         {
1585                                 this.items = this.items - (this.items & ITEM_Strength.m_itemid);
1586                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_STRENGTH, this.netname);
1587                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_STRENGTH);
1588                         }
1589                 }
1590                 else
1591                 {
1592                         if (time < this.strength_finished)
1593                         {
1594                                 this.items = this.items | ITEM_Strength.m_itemid;
1595                                 if(!g_cts)
1596                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_STRENGTH, this.netname);
1597                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_STRENGTH);
1598                         }
1599                 }
1600                 if (this.items & ITEM_Shield.m_itemid)
1601                 {
1602                         play_countdown(this, this.invincible_finished, SND_POWEROFF);
1603                         this.effects = this.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
1604                         if (time > this.invincible_finished)
1605                         {
1606                                 this.items = this.items - (this.items & ITEM_Shield.m_itemid);
1607                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERDOWN_SHIELD, this.netname);
1608                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERDOWN_SHIELD);
1609                         }
1610                 }
1611                 else
1612                 {
1613                         if (time < this.invincible_finished)
1614                         {
1615                                 this.items = this.items | ITEM_Shield.m_itemid;
1616                                 if(!g_cts)
1617                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_POWERUP_SHIELD, this.netname);
1618                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_POWERUP_SHIELD);
1619                         }
1620                 }
1621                 if (this.items & IT_SUPERWEAPON)
1622                 {
1623                         if (!(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS))
1624                         {
1625                                 this.superweapons_finished = 0;
1626                                 this.items = this.items - (this.items & IT_SUPERWEAPON);
1627                                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_LOST, this.netname);
1628                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_LOST);
1629                         }
1630                         else if (this.items & IT_UNLIMITED_SUPERWEAPONS)
1631                         {
1632                                 // don't let them run out
1633                         }
1634                         else
1635                         {
1636                                 play_countdown(this, this.superweapons_finished, SND_POWEROFF);
1637                                 if (time > this.superweapons_finished)
1638                                 {
1639                                         this.items = this.items - (this.items & IT_SUPERWEAPON);
1640                                         STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1641                                         //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_BROKEN, this.netname);
1642                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_BROKEN);
1643                                 }
1644                         }
1645                 }
1646                 else if(STAT(WEAPONS, this) & WEPSET_SUPERWEAPONS)
1647                 {
1648                         if (time < this.superweapons_finished || (this.items & IT_UNLIMITED_SUPERWEAPONS))
1649                         {
1650                                 this.items = this.items | IT_SUPERWEAPON;
1651                                 if(!g_cts)
1652                                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_SUPERWEAPON_PICKUP, this.netname);
1653                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_SUPERWEAPON_PICKUP);
1654                         }
1655                         else
1656                         {
1657                                 this.superweapons_finished = 0;
1658                                 STAT(WEAPONS, this) &= ~WEPSET_SUPERWEAPONS;
1659                         }
1660                 }
1661                 else
1662                 {
1663                         this.superweapons_finished = 0;
1664                 }
1665         }
1666
1667         if(autocvar_g_nodepthtestplayers)
1668                 this.effects = this.effects | EF_NODEPTHTEST;
1669
1670         if(autocvar_g_fullbrightplayers)
1671                 this.effects = this.effects | EF_FULLBRIGHT;
1672
1673         if (time >= game_starttime)
1674         if (time < this.spawnshieldtime)
1675                 this.effects = this.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
1676
1677         MUTATOR_CALLHOOK(PlayerPowerups, this, items_prev);
1678 }
1679
1680 float CalcRegen(float current, float stable, float regenfactor, float regenframetime)
1681 {
1682         if(current > stable)
1683                 return current;
1684         else if(current > stable - 0.25) // when close enough, "snap"
1685                 return stable;
1686         else
1687                 return min(stable, current + (stable - current) * regenfactor * regenframetime);
1688 }
1689
1690 float CalcRot(float current, float stable, float rotfactor, float rotframetime)
1691 {
1692         if(current < stable)
1693                 return current;
1694         else if(current < stable + 0.25) // when close enough, "snap"
1695                 return stable;
1696         else
1697                 return max(stable, current + (stable - current) * rotfactor * rotframetime);
1698 }
1699
1700 float CalcRotRegen(float current, float regenstable, float regenfactor, float regenlinear, float regenframetime, float rotstable, float rotfactor, float rotlinear, float rotframetime, float limit)
1701 {
1702         if(current > rotstable)
1703         {
1704                 if(rotframetime > 0)
1705                 {
1706                         current = CalcRot(current, rotstable, rotfactor, rotframetime);
1707                         current = max(rotstable, current - rotlinear * rotframetime);
1708                 }
1709         }
1710         else if(current < regenstable)
1711         {
1712                 if(regenframetime > 0)
1713                 {
1714                         current = CalcRegen(current, regenstable, regenfactor, regenframetime);
1715                         current = min(regenstable, current + regenlinear * regenframetime);
1716                 }
1717         }
1718
1719         if(current > limit)
1720                 current = limit;
1721
1722         return current;
1723 }
1724
1725 void player_regen(entity this)
1726 {
1727         float max_mod, regen_mod, rot_mod, limit_mod;
1728         max_mod = regen_mod = rot_mod = limit_mod = 1;
1729
1730         float regen_health = autocvar_g_balance_health_regen;
1731         float regen_health_linear = autocvar_g_balance_health_regenlinear;
1732         float regen_health_rot = autocvar_g_balance_health_rot;
1733         float regen_health_rotlinear = autocvar_g_balance_health_rotlinear;
1734         float regen_health_stable = autocvar_g_balance_health_regenstable;
1735         float regen_health_rotstable = autocvar_g_balance_health_rotstable;
1736         bool mutator_returnvalue = MUTATOR_CALLHOOK(PlayerRegen, this, max_mod, regen_mod, rot_mod, limit_mod, regen_health, regen_health_linear, regen_health_rot,
1737                 regen_health_rotlinear, regen_health_stable, regen_health_rotstable);
1738         max_mod = M_ARGV(1, float);
1739         regen_mod = M_ARGV(2, float);
1740         rot_mod = M_ARGV(3, float);
1741         limit_mod = M_ARGV(4, float);
1742         regen_health = M_ARGV(5, float);
1743         regen_health_linear = M_ARGV(6, float);
1744         regen_health_rot = M_ARGV(7, float);
1745         regen_health_rotlinear = M_ARGV(8, float);
1746         regen_health_stable = M_ARGV(9, float);
1747         regen_health_rotstable = M_ARGV(10, float);
1748
1749         if(!mutator_returnvalue)
1750         if(!STAT(FROZEN, this))
1751         {
1752                 float mina, maxa, limith, limita;
1753                 maxa = autocvar_g_balance_armor_rotstable;
1754                 mina = autocvar_g_balance_armor_regenstable;
1755                 limith = GetResourceLimit(this, RESOURCE_HEALTH);
1756                 limita = GetResourceLimit(this, RESOURCE_ARMOR);
1757
1758                 regen_health_rotstable = regen_health_rotstable * max_mod;
1759                 regen_health_stable = regen_health_stable * max_mod;
1760                 limith = limith * limit_mod;
1761                 limita = limita * limit_mod;
1762
1763                 SetResourceAmount(this, RESOURCE_ARMOR, CalcRotRegen(GetResourceAmount(this, RESOURCE_ARMOR), mina, autocvar_g_balance_armor_regen, autocvar_g_balance_armor_regenlinear,
1764                                                                         regen_mod * frametime * (time > this.pauseregen_finished), maxa, autocvar_g_balance_armor_rot, autocvar_g_balance_armor_rotlinear,
1765                                                                         rot_mod * frametime * (time > this.pauserotarmor_finished), limita));
1766                 SetResourceAmount(this, RESOURCE_HEALTH, CalcRotRegen(GetResourceAmount(this, RESOURCE_HEALTH), regen_health_stable, regen_health, regen_health_linear,
1767                                                                         regen_mod * frametime * (time > this.pauseregen_finished), regen_health_rotstable, regen_health_rot, regen_health_rotlinear,
1768                                                                         rot_mod * frametime * (time > this.pauserothealth_finished), limith));
1769         }
1770
1771         // if player rotted to death...  die!
1772         // check this outside above checks, as player may still be able to rot to death
1773         if(GetResourceAmount(this, RESOURCE_HEALTH) < 1)
1774         {
1775                 if(this.vehicle)
1776                         vehicles_exit(this.vehicle, VHEF_RELEASE);
1777                 if(this.event_damage)
1778                         this.event_damage(this, this, this, 1, DEATH_ROT.m_id, DMG_NOWEP, this.origin, '0 0 0');
1779         }
1780
1781         if (!(this.items & IT_UNLIMITED_WEAPON_AMMO))
1782         {
1783                 float minf, maxf, limitf;
1784
1785                 maxf = autocvar_g_balance_fuel_rotstable;
1786                 minf = autocvar_g_balance_fuel_regenstable;
1787                 limitf = GetResourceLimit(this, RESOURCE_FUEL);
1788
1789                 SetResourceAmount(this, RESOURCE_FUEL, CalcRotRegen(GetResourceAmount(this, RESOURCE_FUEL), minf, autocvar_g_balance_fuel_regen, autocvar_g_balance_fuel_regenlinear,
1790                                                                                 frametime * (time > this.pauseregen_finished) * ((this.items & ITEM_JetpackRegen.m_itemid) != 0),
1791                                                                                 maxf, autocvar_g_balance_fuel_rot, autocvar_g_balance_fuel_rotlinear, frametime * (time > this.pauserotfuel_finished), limitf));
1792         }
1793 }
1794
1795 bool zoomstate_set;
1796 void SetZoomState(entity this, float newzoom)
1797 {
1798         if(newzoom != CS(this).zoomstate)
1799         {
1800                 CS(this).zoomstate = newzoom;
1801                 ClientData_Touch(this);
1802         }
1803         zoomstate_set = true;
1804 }
1805
1806 void GetPressedKeys(entity this)
1807 {
1808         MUTATOR_CALLHOOK(GetPressedKeys, this);
1809         int keys = STAT(PRESSED_KEYS, this);
1810         keys = BITSET(keys, KEY_FORWARD,        CS(this).movement.x > 0);
1811         keys = BITSET(keys, KEY_BACKWARD,       CS(this).movement.x < 0);
1812         keys = BITSET(keys, KEY_RIGHT,          CS(this).movement.y > 0);
1813         keys = BITSET(keys, KEY_LEFT,           CS(this).movement.y < 0);
1814
1815         keys = BITSET(keys, KEY_JUMP,           PHYS_INPUT_BUTTON_JUMP(this));
1816         keys = BITSET(keys, KEY_CROUCH,         PHYS_INPUT_BUTTON_CROUCH(this));
1817         keys = BITSET(keys, KEY_ATCK,           PHYS_INPUT_BUTTON_ATCK(this));
1818         keys = BITSET(keys, KEY_ATCK2,          PHYS_INPUT_BUTTON_ATCK2(this));
1819         CS(this).pressedkeys = keys; // store for other users
1820
1821         STAT(PRESSED_KEYS, this) = keys;
1822 }
1823
1824 /*
1825 ======================
1826 spectate mode routines
1827 ======================
1828 */
1829
1830 void SpectateCopy(entity this, entity spectatee)
1831 {
1832         TC(Client, this); TC(Client, spectatee);
1833
1834         MUTATOR_CALLHOOK(SpectateCopy, spectatee, this);
1835         PS(this) = PS(spectatee);
1836         this.armortype = spectatee.armortype;
1837         SetResourceAmountExplicit(this, RESOURCE_ARMOR, GetResourceAmount(spectatee, RESOURCE_ARMOR));
1838         SetResourceAmountExplicit(this, RESOURCE_CELLS, GetResourceAmount(spectatee, RESOURCE_CELLS));
1839         SetResourceAmountExplicit(this, RESOURCE_PLASMA, GetResourceAmount(spectatee, RESOURCE_PLASMA));
1840         SetResourceAmountExplicit(this, RESOURCE_SHELLS, GetResourceAmount(spectatee, RESOURCE_SHELLS));
1841         SetResourceAmountExplicit(this, RESOURCE_BULLETS, GetResourceAmount(spectatee, RESOURCE_BULLETS));
1842         SetResourceAmountExplicit(this, RESOURCE_ROCKETS, GetResourceAmount(spectatee, RESOURCE_ROCKETS));
1843         SetResourceAmountExplicit(this, RESOURCE_FUEL, GetResourceAmount(spectatee, RESOURCE_FUEL));
1844         this.effects = spectatee.effects & EFMASK_CHEAP; // eat performance
1845         SetResourceAmountExplicit(this, RESOURCE_HEALTH, GetResourceAmount(spectatee, RESOURCE_HEALTH));
1846         CS(this).impulse = 0;
1847         this.items = spectatee.items;
1848         STAT(LAST_PICKUP, this) = STAT(LAST_PICKUP, spectatee);
1849         STAT(HIT_TIME, this) = STAT(HIT_TIME, spectatee);
1850         this.strength_finished = spectatee.strength_finished;
1851         this.invincible_finished = spectatee.invincible_finished;
1852         this.superweapons_finished = spectatee.superweapons_finished;
1853         STAT(PRESSED_KEYS, this) = STAT(PRESSED_KEYS, spectatee);
1854         STAT(WEAPONS, this) = STAT(WEAPONS, spectatee);
1855         this.punchangle = spectatee.punchangle;
1856         this.view_ofs = spectatee.view_ofs;
1857         this.velocity = spectatee.velocity;
1858         this.dmg_take = spectatee.dmg_take;
1859         this.dmg_save = spectatee.dmg_save;
1860         this.dmg_inflictor = spectatee.dmg_inflictor;
1861         this.v_angle = spectatee.v_angle;
1862         this.angles = spectatee.v_angle;
1863         STAT(FROZEN, this) = STAT(FROZEN, spectatee);
1864         STAT(REVIVE_PROGRESS, this) = STAT(REVIVE_PROGRESS, spectatee);
1865         this.viewloc = spectatee.viewloc;
1866         if(!PHYS_INPUT_BUTTON_USE(this) && STAT(CAMERA_SPECTATOR, this) != 2)
1867                 this.fixangle = true;
1868         setorigin(this, spectatee.origin);
1869         setsize(this, spectatee.mins, spectatee.maxs);
1870         SetZoomState(this, CS(spectatee).zoomstate);
1871
1872     anticheat_spectatecopy(this, spectatee);
1873         STAT(HUD, this) = STAT(HUD, spectatee);
1874         if(spectatee.vehicle)
1875     {
1876         this.angles = spectatee.v_angle;
1877
1878         //this.fixangle = false;
1879         //this.velocity = spectatee.vehicle.velocity;
1880         this.vehicle_health = spectatee.vehicle_health;
1881         this.vehicle_shield = spectatee.vehicle_shield;
1882         this.vehicle_energy = spectatee.vehicle_energy;
1883         this.vehicle_ammo1 = spectatee.vehicle_ammo1;
1884         this.vehicle_ammo2 = spectatee.vehicle_ammo2;
1885         this.vehicle_reload1 = spectatee.vehicle_reload1;
1886         this.vehicle_reload2 = spectatee.vehicle_reload2;
1887
1888         //msg_entity = this;
1889
1890        // WriteByte (MSG_ONE, SVC_SETVIEWANGLES);
1891             //WriteAngle(MSG_ONE,  spectatee.v_angle.x);
1892            // WriteAngle(MSG_ONE,  spectatee.v_angle.y);
1893            // WriteAngle(MSG_ONE,  spectatee.v_angle.z);
1894
1895         //WriteByte (MSG_ONE, SVC_SETVIEW);
1896         //    WriteEntity(MSG_ONE, this);
1897         //makevectors(spectatee.v_angle);
1898         //setorigin(this, spectatee.origin - v_forward * 400 + v_up * 300);*/
1899     }
1900 }
1901
1902 bool SpectateUpdate(entity this)
1903 {
1904         if(!this.enemy)
1905                 return false;
1906
1907         if(!IS_PLAYER(this.enemy) || this == this.enemy)
1908         {
1909                 SetSpectatee(this, NULL);
1910                 return false;
1911         }
1912
1913         SpectateCopy(this, this.enemy);
1914
1915         return true;
1916 }
1917
1918 bool SpectateSet(entity this)
1919 {
1920         if(!IS_PLAYER(this.enemy))
1921                 return false;
1922
1923         ClientData_Touch(this.enemy);
1924
1925         msg_entity = this;
1926         WriteByte(MSG_ONE, SVC_SETVIEW);
1927         WriteEntity(MSG_ONE, this.enemy);
1928         set_movetype(this, MOVETYPE_NONE);
1929         accuracy_resend(this);
1930
1931         if(!SpectateUpdate(this))
1932                 PutObserverInServer(this);
1933
1934         return true;
1935 }
1936
1937 void SetSpectatee_status(entity this, int spectatee_num)
1938 {
1939         int oldspectatee_status = CS(this).spectatee_status;
1940         CS(this).spectatee_status = spectatee_num;
1941
1942         if (CS(this).spectatee_status != oldspectatee_status)
1943         {
1944                 ClientData_Touch(this);
1945                 if (g_race || g_cts) race_InitSpectator();
1946         }
1947 }
1948
1949 void SetSpectatee(entity this, entity spectatee)
1950 {
1951         if(IS_BOT_CLIENT(this))
1952                 return; // bots abuse .enemy, this code is useless to them
1953
1954         entity old_spectatee = this.enemy;
1955
1956         this.enemy = spectatee;
1957
1958         // WEAPONTODO
1959         // these are required to fix the spectator bug with arc
1960         if(old_spectatee)
1961         {
1962                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1963                 {
1964                         .entity weaponentity = weaponentities[slot];
1965                         if(old_spectatee.(weaponentity).arc_beam)
1966                                 old_spectatee.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1967                 }
1968         }
1969         if(this.enemy)
1970         {
1971                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1972                 {
1973                         .entity weaponentity = weaponentities[slot];
1974                         if(this.enemy.(weaponentity).arc_beam)
1975                                 this.enemy.(weaponentity).arc_beam.SendFlags |= ARC_SF_SETTINGS;
1976                 }
1977         }
1978
1979         if (this.enemy)
1980                 SetSpectatee_status(this, etof(this.enemy));
1981
1982         // needed to update spectator list
1983         if(old_spectatee) { ClientData_Touch(old_spectatee); }
1984 }
1985
1986 bool Spectate(entity this, entity pl)
1987 {
1988         if(MUTATOR_CALLHOOK(SpectateSet, this, pl))
1989                 return false;
1990         pl = M_ARGV(1, entity);
1991
1992         SetSpectatee(this, pl);
1993         return SpectateSet(this);
1994 }
1995
1996 bool SpectateNext(entity this)
1997 {
1998         entity ent = find(this.enemy, classname, STR_PLAYER);
1999
2000         if (MUTATOR_CALLHOOK(SpectateNext, this, ent))
2001                 ent = M_ARGV(1, entity);
2002         else if (!ent)
2003                 ent = find(ent, classname, STR_PLAYER);
2004
2005         if(ent) { SetSpectatee(this, ent); }
2006
2007         return SpectateSet(this);
2008 }
2009
2010 bool SpectatePrev(entity this)
2011 {
2012         // NOTE: chain order is from the highest to the lower entnum (unlike find)
2013         entity ent = findchain(classname, STR_PLAYER);
2014         if (!ent) // no player
2015                 return false;
2016
2017         entity first = ent;
2018         // skip players until current spectated player
2019         if(this.enemy)
2020         while(ent && ent != this.enemy)
2021                 ent = ent.chain;
2022
2023         switch (MUTATOR_CALLHOOK(SpectatePrev, this, ent, first))
2024         {
2025                 case MUT_SPECPREV_FOUND:
2026                     ent = M_ARGV(1, entity);
2027                     break;
2028                 case MUT_SPECPREV_RETURN:
2029                     return true;
2030                 case MUT_SPECPREV_CONTINUE:
2031                 default:
2032                 {
2033                         if(ent.chain)
2034                                 ent = ent.chain;
2035                         else
2036                                 ent = first;
2037                         break;
2038                 }
2039         }
2040
2041         SetSpectatee(this, ent);
2042         return SpectateSet(this);
2043 }
2044
2045 /*
2046 =============
2047 ShowRespawnCountdown()
2048
2049 Update a respawn countdown display.
2050 =============
2051 */
2052 void ShowRespawnCountdown(entity this)
2053 {
2054         float number;
2055         if(!IS_DEAD(this)) // just respawned?
2056                 return;
2057         else
2058         {
2059                 number = ceil(this.respawn_time - time);
2060                 if(number <= 0)
2061                         return;
2062                 if(number <= this.respawn_countdown)
2063                 {
2064                         this.respawn_countdown = number - 1;
2065                         if(ceil(this.respawn_time - (time + 0.5)) == number) // only say it if it is the same number even in 0.5s; to prevent overlapping sounds
2066                                 { Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_RESPAWN, number)); }
2067                 }
2068         }
2069 }
2070
2071 .bool team_selected;
2072 bool ShowTeamSelection(entity this)
2073 {
2074         if (!teamplay || autocvar_g_campaign || autocvar_g_balance_teams || this.team_selected || (CS(this).wasplayer && autocvar_g_changeteam_banned) || Player_HasRealForcedTeam(this))
2075                 return false;
2076         stuffcmd(this, "menu_showteamselect\n");
2077         return true;
2078 }
2079 void Join(entity this)
2080 {
2081         TRANSMUTE(Player, this);
2082
2083         if(!this.team_selected)
2084         if(autocvar_g_campaign || autocvar_g_balance_teams)
2085                 TeamBalance_JoinBestTeam(this);
2086
2087         if(autocvar_g_campaign)
2088                 campaign_bots_may_start = true;
2089
2090         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_PREVENT_JOIN);
2091
2092         PutClientInServer(this);
2093
2094         if(IS_PLAYER(this))
2095         if(teamplay && this.team != -1)
2096         {
2097                 //Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(this.team, INFO_JOIN_PLAY_TEAM), this.netname);
2098         }
2099         else
2100                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_JOIN_PLAY, this.netname);
2101         this.team_selected = false;
2102 }
2103
2104 /**
2105  * Determines whether the player is allowed to join. This depends on cvar
2106  * g_maxplayers, if it isn't used this function always return true, otherwise
2107  * it checks whether the number of currently playing players exceeds g_maxplayers.
2108  * @return int number of free slots for players, 0 if none
2109  */
2110 int nJoinAllowed(entity this, entity ignore)
2111 {
2112         if(!ignore)
2113         // this is called that way when checking if anyone may be able to join (to build qcstatus)
2114         // so report 0 free slots if restricted
2115         {
2116                 if(autocvar_g_forced_team_otherwise == "spectate")
2117                         return 0;
2118                 if(autocvar_g_forced_team_otherwise == "spectator")
2119                         return 0;
2120         }
2121
2122         if(this && (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2123                 return 0; // forced spectators can never join
2124
2125         // TODO simplify this
2126         int totalClients = 0;
2127         int currentlyPlaying = 0;
2128         FOREACH_CLIENT(true, {
2129                 if(it != ignore)
2130                         ++totalClients;
2131                 if(IS_REAL_CLIENT(it))
2132                 if(IS_PLAYER(it) || it.caplayer)
2133                         ++currentlyPlaying;
2134         });
2135
2136         float free_slots = 0;
2137         if (!autocvar_g_maxplayers)
2138                 free_slots = maxclients - totalClients;
2139         else if(currentlyPlaying < autocvar_g_maxplayers)
2140                 free_slots = min(maxclients - totalClients, autocvar_g_maxplayers - currentlyPlaying);
2141
2142         static float join_prevent_msg_time = 0;
2143         if(this && ignore && !free_slots && time > join_prevent_msg_time)
2144         {
2145                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_JOIN_PREVENT);
2146                 join_prevent_msg_time = time + 3;
2147         }
2148
2149         return free_slots;
2150 }
2151
2152 /**
2153  * Checks whether the client is an observer or spectator, if so, he will get kicked after
2154  * g_maxplayers_spectator_blocktime seconds
2155  */
2156 void checkSpectatorBlock(entity this)
2157 {
2158         if(IS_SPEC(this) || IS_OBSERVER(this))
2159         if(!this.caplayer)
2160         if(IS_REAL_CLIENT(this))
2161         {
2162                 if( time > (CS(this).spectatortime + autocvar_g_maxplayers_spectator_blocktime) ) {
2163                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_QUIT_KICK_SPECTATING);
2164                         dropclient(this);
2165                 }
2166         }
2167 }
2168
2169 void PrintWelcomeMessage(entity this)
2170 {
2171         if(CS(this).motd_actived_time == 0)
2172         {
2173                 if (autocvar_g_campaign) {
2174                         if ((IS_PLAYER(this) && PHYS_INPUT_BUTTON_INFO(this)) || (!IS_PLAYER(this))) {
2175                                 CS(this).motd_actived_time = time;
2176                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, campaign_message);
2177                         }
2178                 } else {
2179                         if (PHYS_INPUT_BUTTON_INFO(this)) {
2180                                 CS(this).motd_actived_time = time;
2181                                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_MOTD, getwelcomemessage(this));
2182                         }
2183                 }
2184         }
2185         else if(CS(this).motd_actived_time > 0) // showing MOTD or campaign message
2186         {
2187                 if (autocvar_g_campaign) {
2188                         if (PHYS_INPUT_BUTTON_INFO(this))
2189                                 CS(this).motd_actived_time = time;
2190                         else if ((time - CS(this).motd_actived_time > 2) && IS_PLAYER(this)) { // hide it some seconds after BUTTON_INFO has been released
2191                                 CS(this).motd_actived_time = 0;
2192                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2193                         }
2194                 } else {
2195                         if (PHYS_INPUT_BUTTON_INFO(this))
2196                                 CS(this).motd_actived_time = time;
2197                         else if (time - CS(this).motd_actived_time > 2) { // hide it some seconds after BUTTON_INFO has been released
2198                                 CS(this).motd_actived_time = 0;
2199                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2200                         }
2201                 }
2202         }
2203         else //if(CS(this).motd_actived_time < 0) // just connected, motd is active
2204         {
2205                 if(PHYS_INPUT_BUTTON_INFO(this)) // BUTTON_INFO hides initial MOTD
2206                         CS(this).motd_actived_time = -2; // wait until BUTTON_INFO gets released
2207                 else if(CS(this).motd_actived_time == -2 || IS_PLAYER(this) || IS_SPEC(this))
2208                 {
2209                         // instanctly hide MOTD
2210                         CS(this).motd_actived_time = 0;
2211                         Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_MOTD);
2212                 }
2213         }
2214 }
2215
2216 const int MIN_SPEC_TIME = 1;
2217 bool joinAllowed(entity this)
2218 {
2219         if (CS(this).version_mismatch) return false;
2220         if (time < CS(this).jointime + MIN_SPEC_TIME) return false;
2221         if (!nJoinAllowed(this, this)) return false;
2222         if (teamplay && lockteams) return false;
2223         if (MUTATOR_CALLHOOK(ForbidSpawn, this)) return false;
2224         if (ShowTeamSelection(this)) return false;
2225         return true;
2226 }
2227
2228 .int items_added;
2229 .string shootfromfixedorigin;
2230 bool PlayerThink(entity this)
2231 {
2232         if (game_stopped || intermission_running) {
2233                 this.modelflags &= ~MF_ROCKET;
2234                 if(intermission_running)
2235                         IntermissionThink(this);
2236                 return false;
2237         }
2238
2239         if (timeout_status == TIMEOUT_ACTIVE) {
2240         // don't allow the player to turn around while game is paused
2241                 // FIXME turn this into CSQC stuff
2242                 this.v_angle = this.lastV_angle;
2243                 this.angles = this.lastV_angle;
2244                 this.fixangle = true;
2245         }
2246
2247         if (frametime) player_powerups(this);
2248
2249         if (IS_DEAD(this)) {
2250                 if (this.personal && g_race_qualifying) {
2251                         if (time > this.respawn_time) {
2252                                 STAT(RESPAWN_TIME, this) = this.respawn_time = time + 1; // only retry once a second
2253                                 respawn(this);
2254                                 CS(this).impulse = CHIMPULSE_SPEEDRUN.impulse;
2255                         }
2256                 } else {
2257                         if (frametime) player_anim(this);
2258
2259                         if (this.respawn_flags & RESPAWN_DENY)
2260                         {
2261                                 STAT(RESPAWN_TIME, this) = 0;
2262                                 return false;
2263                         }
2264
2265                         bool button_pressed = (PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this) || PHYS_INPUT_BUTTON_ATCK2(this) || PHYS_INPUT_BUTTON_HOOK(this) || PHYS_INPUT_BUTTON_USE(this));
2266
2267                         switch(this.deadflag)
2268                         {
2269                                 case DEAD_DYING:
2270                                 {
2271                                         if ((this.respawn_flags & RESPAWN_FORCE) && !(this.respawn_time < this.respawn_time_max))
2272                                                 this.deadflag = DEAD_RESPAWNING;
2273                                         else if (!button_pressed || (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE)))
2274                                                 this.deadflag = DEAD_DEAD;
2275                                         break;
2276                                 }
2277                                 case DEAD_DEAD:
2278                                 {
2279                                         if (button_pressed)
2280                                                 this.deadflag = DEAD_RESPAWNABLE;
2281                                         else if (time >= this.respawn_time_max && (this.respawn_flags & RESPAWN_FORCE))
2282                                                 this.deadflag = DEAD_RESPAWNING;
2283                                         break;
2284                                 }
2285                                 case DEAD_RESPAWNABLE:
2286                                 {
2287                                         if (!button_pressed || (this.respawn_flags & RESPAWN_FORCE))
2288                                                 this.deadflag = DEAD_RESPAWNING;
2289                                         break;
2290                                 }
2291                                 case DEAD_RESPAWNING:
2292                                 {
2293                                         if (time > this.respawn_time)
2294                                         {
2295                                                 this.respawn_time = time + 1; // only retry once a second
2296                                                 this.respawn_time_max = this.respawn_time;
2297                                                 respawn(this);
2298                                         }
2299                                         break;
2300                                 }
2301                         }
2302
2303                         ShowRespawnCountdown(this);
2304
2305                         if (this.respawn_flags & RESPAWN_SILENT)
2306                                 STAT(RESPAWN_TIME, this) = 0;
2307                         else if ((this.respawn_flags & RESPAWN_FORCE) && this.respawn_time < this.respawn_time_max)
2308                         {
2309                                 if (time < this.respawn_time)
2310                                         STAT(RESPAWN_TIME, this) = this.respawn_time;
2311                                 else if (this.deadflag != DEAD_RESPAWNING)
2312                                         STAT(RESPAWN_TIME, this) = -this.respawn_time_max;
2313                         }
2314                         else
2315                                 STAT(RESPAWN_TIME, this) = this.respawn_time;
2316                 }
2317
2318                 // if respawning, invert stat_respawn_time to indicate this, the client translates it
2319                 if (this.deadflag == DEAD_RESPAWNING && STAT(RESPAWN_TIME, this) > 0)
2320                         STAT(RESPAWN_TIME, this) *= -1;
2321
2322                 return false;
2323         }
2324
2325         FixPlayermodel(this);
2326
2327         if (this.shootfromfixedorigin != autocvar_g_shootfromfixedorigin) {
2328                 this.shootfromfixedorigin = autocvar_g_shootfromfixedorigin;
2329                 stuffcmd(this, sprintf("\ncl_shootfromfixedorigin \"%s\"\n", autocvar_g_shootfromfixedorigin));
2330         }
2331
2332         // LordHavoc: allow firing on move frames (sub-ticrate), this gives better timing on slow servers
2333         //if(frametime)
2334         {
2335                 this.items &= ~this.items_added;
2336
2337                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2338                 {
2339                         .entity weaponentity = weaponentities[slot];
2340                         W_WeaponFrame(this, weaponentity);
2341                 }
2342
2343                 this.items_added = 0;
2344                 if ((this.items & ITEM_Jetpack.m_itemid) && ((this.items & ITEM_JetpackRegen.m_itemid) || GetResourceAmount(this, RESOURCE_FUEL) >= 0.01))
2345             this.items_added |= IT_FUEL;
2346
2347                 this.items |= this.items_added;
2348         }
2349
2350         player_regen(this);
2351
2352         // WEAPONTODO: Add a weapon request for this
2353         // rot vortex charge to the charge limit
2354         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2355         {
2356                 .entity weaponentity = weaponentities[slot];
2357                 if (WEP_CVAR(vortex, charge_rot_rate) && this.(weaponentity).vortex_charge > WEP_CVAR(vortex, charge_limit) && this.(weaponentity).vortex_charge_rottime < time)
2358                         this.(weaponentity).vortex_charge = bound(WEP_CVAR(vortex, charge_limit), this.(weaponentity).vortex_charge - WEP_CVAR(vortex, charge_rot_rate) * frametime / W_TICSPERFRAME, 1);
2359         }
2360
2361         if (frametime) player_anim(this);
2362
2363         // secret status
2364         secrets_setstatus(this);
2365
2366         // monsters status
2367         monsters_setstatus(this);
2368
2369         this.dmg_team = max(0, this.dmg_team - autocvar_g_teamdamage_resetspeed * frametime);
2370
2371         return true;
2372 }
2373
2374 .bool would_spectate;
2375 void ObserverThink(entity this)
2376 {
2377         if ( CS(this).impulse )
2378         {
2379                 MinigameImpulse(this, CS(this).impulse);
2380                 CS(this).impulse = 0;
2381         }
2382
2383         if (this.flags & FL_JUMPRELEASED) {
2384                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2385                         this.flags &= ~FL_JUMPRELEASED;
2386                         this.flags |= FL_SPAWNING;
2387                 } else if(PHYS_INPUT_BUTTON_ATCK(this) && !CS(this).version_mismatch || this.would_spectate) {
2388                         this.flags &= ~FL_JUMPRELEASED;
2389                         if(SpectateNext(this)) {
2390                                 TRANSMUTE(Spectator, this);
2391                         }
2392                 } else {
2393                         int preferred_movetype = ((!PHYS_INPUT_BUTTON_USE(this) ? CS(this).cvar_cl_clippedspectating : !CS(this).cvar_cl_clippedspectating) ? MOVETYPE_FLY_WORLDONLY : MOVETYPE_NOCLIP);
2394                         set_movetype(this, preferred_movetype);
2395                 }
2396         } else {
2397                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_JUMP(this))) {
2398                         this.flags |= FL_JUMPRELEASED;
2399                         if(this.flags & FL_SPAWNING)
2400                         {
2401                                 this.flags &= ~FL_SPAWNING;
2402                                 Join(this);
2403                                 return;
2404                         }
2405                 }
2406         }
2407 }
2408
2409 void SpectatorThink(entity this)
2410 {
2411         if ( CS(this).impulse )
2412         {
2413                 if(MinigameImpulse(this, CS(this).impulse))
2414                         CS(this).impulse = 0;
2415
2416                 if (CS(this).impulse == IMP_weapon_drop.impulse)
2417                 {
2418                         STAT(CAMERA_SPECTATOR, this) = (STAT(CAMERA_SPECTATOR, this) + 1) % 3;
2419                         CS(this).impulse = 0;
2420                         return;
2421                 }
2422         }
2423
2424         if (this.flags & FL_JUMPRELEASED) {
2425                 if (PHYS_INPUT_BUTTON_JUMP(this) && joinAllowed(this)) {
2426                         this.flags &= ~FL_JUMPRELEASED;
2427                         this.flags |= FL_SPAWNING;
2428                 } else if(PHYS_INPUT_BUTTON_ATCK(this) || CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18 || (CS(this).impulse >= 200 && CS(this).impulse <= 209)) {
2429                         this.flags &= ~FL_JUMPRELEASED;
2430                         if(SpectateNext(this)) {
2431                                 TRANSMUTE(Spectator, this);
2432                         } else {
2433                                 TRANSMUTE(Observer, this);
2434                                 PutClientInServer(this);
2435                         }
2436                         CS(this).impulse = 0;
2437                 } else if(CS(this).impulse == 12 || CS(this).impulse == 16  || CS(this).impulse == 19 || (CS(this).impulse >= 220 && CS(this).impulse <= 229)) {
2438                         this.flags &= ~FL_JUMPRELEASED;
2439                         if(SpectatePrev(this)) {
2440                                 TRANSMUTE(Spectator, this);
2441                         } else {
2442                                 TRANSMUTE(Observer, this);
2443                                 PutClientInServer(this);
2444                         }
2445                         CS(this).impulse = 0;
2446                 } else if (PHYS_INPUT_BUTTON_ATCK2(this)) {
2447                         this.would_spectate = false;
2448                         this.flags &= ~FL_JUMPRELEASED;
2449                         TRANSMUTE(Observer, this);
2450                         PutClientInServer(this);
2451                 } else {
2452                         if(!SpectateUpdate(this))
2453                         {
2454                                 if(!SpectateNext(this))
2455                                 {
2456                                         PutObserverInServer(this);
2457                                         this.would_spectate = true;
2458                                 }
2459                         }
2460                 }
2461         } else {
2462                 if (!(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this))) {
2463                         this.flags |= FL_JUMPRELEASED;
2464                         if(this.flags & FL_SPAWNING)
2465                         {
2466                                 this.flags &= ~FL_SPAWNING;
2467                                 Join(this);
2468                                 return;
2469                         }
2470                 }
2471                 if(!SpectateUpdate(this))
2472                         PutObserverInServer(this);
2473         }
2474
2475         this.flags |= FL_CLIENT | FL_NOTARGET;
2476 }
2477
2478 void PlayerUseKey(entity this)
2479 {
2480         if (!IS_PLAYER(this))
2481                 return;
2482
2483         if(this.vehicle)
2484         {
2485                 if(!game_stopped)
2486                 {
2487                         vehicles_exit(this.vehicle, VHEF_NORMAL);
2488                         return;
2489                 }
2490         }
2491         else if(autocvar_g_vehicles_enter)
2492         {
2493                 if(!STAT(FROZEN, this))
2494                 if(!IS_DEAD(this))
2495                 if(!game_stopped)
2496                 {
2497                         entity head, closest_target = NULL;
2498                         head = WarpZone_FindRadius(this.origin, autocvar_g_vehicles_enter_radius, true);
2499
2500                         while(head) // find the closest acceptable target to enter
2501                         {
2502                                 if(IS_VEHICLE(head))
2503                                 if(!IS_DEAD(head))
2504                                 if(!head.owner || ((head.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(head.owner, this)))
2505                                 if(head.takedamage != DAMAGE_NO)
2506                                 {
2507                                         if(closest_target)
2508                                         {
2509                                                 if(vlen2(this.origin - head.origin) < vlen2(this.origin - closest_target.origin))
2510                                                 { closest_target = head; }
2511                                         }
2512                                         else { closest_target = head; }
2513                                 }
2514
2515                                 head = head.chain;
2516                         }
2517
2518                         if(closest_target) { vehicles_enter(this, closest_target); return; }
2519                 }
2520         }
2521
2522         // a use key was pressed; call handlers
2523         MUTATOR_CALLHOOK(PlayerUseKey, this);
2524 }
2525
2526
2527 /*
2528 =============
2529 PlayerPreThink
2530
2531 Called every frame for each client before the physics are run
2532 =============
2533 */
2534 .float last_vehiclecheck;
2535 void PlayerPreThink (entity this)
2536 {
2537         STAT(GUNALIGN, this) = CS(this).cvar_cl_gunalign; // TODO
2538         STAT(MOVEVARS_CL_TRACK_CANJUMP, this) = CS(this).cvar_cl_movement_track_canjump;
2539
2540         WarpZone_PlayerPhysics_FixVAngle(this);
2541
2542         if (frametime) {
2543                 // physics frames: update anticheat stuff
2544                 anticheat_prethink(this);
2545         }
2546
2547         if (blockSpectators && frametime) {
2548                 // WORKAROUND: only use dropclient in server frames (frametime set).
2549                 // Never use it in cl_movement frames (frametime zero).
2550                 checkSpectatorBlock(this);
2551         }
2552
2553         zoomstate_set = false;
2554
2555         // Check for nameless players
2556         if (this.netname == "" || this.netname != CS(this).netname_previous)
2557         {
2558                 bool assume_unchanged = (CS(this).netname_previous == "");
2559                 if (isInvisibleString(this.netname))
2560                 {
2561                         this.netname = strzone(sprintf("Player#%d", this.playerid));
2562                         assume_unchanged = false;
2563                         // stuffcmd(this, strcat("name ", this.netname, "\n")); // maybe?
2564                 }
2565                 if (!assume_unchanged && autocvar_sv_eventlog)
2566                         GameLogEcho(strcat(":name:", ftos(this.playerid), ":", playername(this, false)));
2567                 strcpy(CS(this).netname_previous, this.netname);
2568         }
2569
2570         // version nagging
2571         if (CS(this).version_nagtime && CS(this).cvar_g_xonoticversion && time > CS(this).version_nagtime) {
2572         CS(this).version_nagtime = 0;
2573         if (strstrofs(CS(this).cvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(CS(this).cvar_g_xonoticversion, "autobuild", 0) >= 0) {
2574             // git client
2575         } else if (strstrofs(autocvar_g_xonoticversion, "git", 0) >= 0 || strstrofs(autocvar_g_xonoticversion, "autobuild", 0) >= 0) {
2576             // git server
2577             Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_BETA, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2578         } else {
2579             int r = vercmp(CS(this).cvar_g_xonoticversion, autocvar_g_xonoticversion);
2580             if (r < 0) { // old client
2581                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OUTDATED, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2582             } else if (r > 0) { // old server
2583                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_VERSION_OLD, autocvar_g_xonoticversion, CS(this).cvar_g_xonoticversion);
2584             }
2585         }
2586     }
2587
2588         // GOD MODE info
2589         if (!(this.flags & FL_GODMODE) && this.max_armorvalue)
2590         {
2591                 Send_Notification(NOTIF_ONE_ONLY, this, MSG_INFO, INFO_GODMODE_OFF, this.max_armorvalue);
2592                 this.max_armorvalue = 0;
2593         }
2594
2595         if(IS_PLAYER(this))
2596         {
2597                 if (STAT(FROZEN, this) == 2)
2598                 {
2599                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) + frametime * this.revive_speed, 1);
2600                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(1, STAT(REVIVE_PROGRESS, this) * start_health));
2601                         this.iceblock.alpha = bound(0.2, 1 - STAT(REVIVE_PROGRESS, this), 1);
2602
2603                         if (STAT(REVIVE_PROGRESS, this) >= 1)
2604                                 Unfreeze(this);
2605                 }
2606                 else if (STAT(FROZEN, this) == 3)
2607                 {
2608                         STAT(REVIVE_PROGRESS, this) = bound(0, STAT(REVIVE_PROGRESS, this) - frametime * this.revive_speed, 1);
2609                         SetResourceAmountExplicit(this, RESOURCE_HEALTH, max(0, autocvar_g_nades_ice_health + (start_health-autocvar_g_nades_ice_health) * STAT(REVIVE_PROGRESS, this)));
2610
2611                         if (GetResourceAmount(this, RESOURCE_HEALTH) < 1)
2612                         {
2613                                 if (this.vehicle)
2614                                         vehicles_exit(this.vehicle, VHEF_RELEASE);
2615                                 if(this.event_damage)
2616                                         this.event_damage(this, this, this.frozen_by, 1, DEATH_NADE_ICE_FREEZE.m_id, DMG_NOWEP, this.origin, '0 0 0');
2617                         }
2618                         else if (STAT(REVIVE_PROGRESS, this) <= 0)
2619                                 Unfreeze(this);
2620                 }
2621         }
2622
2623         MUTATOR_CALLHOOK(PlayerPreThink, this);
2624
2625         if(autocvar_g_vehicles_enter && (time > this.last_vehiclecheck) && !game_stopped && !this.vehicle)
2626         if(IS_PLAYER(this) && !STAT(FROZEN, this) && !IS_DEAD(this))
2627         {
2628                 FOREACH_ENTITY_RADIUS(this.origin, autocvar_g_vehicles_enter_radius, IS_VEHICLE(it),
2629                 {
2630                         if(!IS_DEAD(it) && it.takedamage != DAMAGE_NO)
2631                         if((it.vehicle_flags & VHF_MULTISLOT) && SAME_TEAM(it.owner, this))
2632                         {
2633                                 Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_GUNNER);
2634                         }
2635                         else if(!it.owner)
2636                         {
2637                                 if(!it.team || SAME_TEAM(this, it))
2638                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER);
2639                                 else if(autocvar_g_vehicles_steal)
2640                                         Send_Notification(NOTIF_ONE, this, MSG_CENTER, CENTER_VEHICLE_ENTER_STEAL);
2641                         }
2642                 });
2643
2644                 this.last_vehiclecheck = time + 1;
2645         }
2646
2647         if(!CS(this).cvar_cl_newusekeysupported) // FIXME remove this - it was a stupid idea to begin with, we can JUST use the button
2648         {
2649                 if(PHYS_INPUT_BUTTON_USE(this) && !CS(this).usekeypressed)
2650                         PlayerUseKey(this);
2651                 CS(this).usekeypressed = PHYS_INPUT_BUTTON_USE(this);
2652         }
2653
2654         if (IS_REAL_CLIENT(this))
2655                 PrintWelcomeMessage(this);
2656
2657         if (IS_PLAYER(this)) {
2658                 if (IS_REAL_CLIENT(this) && time < CS(this).jointime + MIN_SPEC_TIME)
2659                         error("Client can't be spawned as player on connection!");
2660                 if(!PlayerThink(this))
2661                         return;
2662         }
2663         else if (game_stopped || intermission_running) {
2664                 if(intermission_running)
2665                         IntermissionThink(this);
2666                 return;
2667         }
2668         else if (IS_REAL_CLIENT(this) && !CS(this).autojoin_checked && time >= CS(this).jointime + MIN_SPEC_TIME)
2669         {
2670                 CS(this).autojoin_checked = true;
2671                 // don't do this in ClientConnect
2672                 // many things can go wrong if a client is spawned as player on connection
2673                 if (MUTATOR_CALLHOOK(AutoJoinOnConnection, this)
2674                         || (!(autocvar_sv_spectate || autocvar_g_campaign || (Player_GetForcedTeamIndex(this) == TEAM_FORCE_SPECTATOR))
2675                                 && (!teamplay || autocvar_g_balance_teams)))
2676                 {
2677                         campaign_bots_may_start = true;
2678                         Join(this);
2679                         return;
2680                 }
2681         }
2682         else if (IS_OBSERVER(this)) {
2683                 ObserverThink(this);
2684         }
2685         else if (IS_SPEC(this)) {
2686                 SpectatorThink(this);
2687         }
2688
2689         // WEAPONTODO: Add weapon request for this
2690         if (!zoomstate_set) {
2691                 bool wep_zoomed = false;
2692                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2693                 {
2694                         .entity weaponentity = weaponentities[slot];
2695                         Weapon thiswep = this.(weaponentity).m_weapon;
2696                         if(thiswep != WEP_Null && thiswep.wr_zoom)
2697                                 wep_zoomed += thiswep.wr_zoom(thiswep, this);
2698                 }
2699                 SetZoomState(this, PHYS_INPUT_BUTTON_ZOOM(this) || PHYS_INPUT_BUTTON_ZOOMSCRIPT(this) || wep_zoomed);
2700     }
2701
2702         if (CS(this).teamkill_soundtime && time > CS(this).teamkill_soundtime)
2703         {
2704                 CS(this).teamkill_soundtime = 0;
2705
2706                 entity e = CS(this).teamkill_soundsource;
2707                 entity oldpusher = e.pusher;
2708                 e.pusher = this;
2709                 PlayerSound(e, playersound_teamshoot, CH_VOICE, VOL_BASEVOICE, VOICETYPE_LASTATTACKER_ONLY);
2710                 e.pusher = oldpusher;
2711         }
2712
2713         if (CS(this).taunt_soundtime && time > CS(this).taunt_soundtime) {
2714                 CS(this).taunt_soundtime = 0;
2715                 PlayerSound(this, playersound_taunt, CH_VOICE, VOL_BASEVOICE, VOICETYPE_AUTOTAUNT);
2716         }
2717
2718         target_voicescript_next(this);
2719
2720         // WEAPONTODO: Move into weaponsystem somehow
2721         // if a player goes unarmed after holding a loaded weapon, empty his clip size and remove the crosshair ammo ring
2722         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2723         {
2724                 .entity weaponentity = weaponentities[slot];
2725                 if(this.(weaponentity).m_weapon == WEP_Null)
2726                         this.(weaponentity).clip_load = this.(weaponentity).clip_size = 0;
2727         }
2728 }
2729
2730 void DrownPlayer(entity this)
2731 {
2732         if(IS_DEAD(this) || game_stopped || time < game_starttime)
2733                 return;
2734
2735         if (this.waterlevel != WATERLEVEL_SUBMERGED || this.vehicle)
2736         {
2737                 if(this.air_finished < time)
2738                         PlayerSound(this, playersound_gasp, CH_PLAYER, VOL_BASE, VOICETYPE_PLAYERSOUND);
2739                 this.air_finished = time + autocvar_g_balance_contents_drowndelay;
2740         }
2741         else if (this.air_finished < time)
2742         {       // drown!
2743                 if (this.pain_finished < time)
2744                 {
2745                         Damage (this, NULL, NULL, autocvar_g_balance_contents_playerdamage_drowning * autocvar_g_balance_contents_damagerate, DEATH_DROWN.m_id, DMG_NOWEP, this.origin, '0 0 0');
2746                         this.pain_finished = time + 0.5;
2747                 }
2748         }
2749 }
2750
2751 .bool move_qcphysics;
2752
2753 void Player_Physics(entity this)
2754 {
2755         set_movetype(this, this.move_movetype);
2756
2757         if(!this.move_qcphysics)
2758                 return;
2759
2760         if(!frametime && !CS(this).pm_frametime)
2761                 return;
2762
2763         Movetype_Physics_NoMatchTicrate(this, CS(this).pm_frametime, true);
2764
2765         CS(this).pm_frametime = 0;
2766 }
2767
2768 /*
2769 =============
2770 PlayerPostThink
2771
2772 Called every frame for each client after the physics are run
2773 =============
2774 */
2775 void PlayerPostThink (entity this)
2776 {
2777         Player_Physics(this);
2778
2779         if (sv_maxidle > 0)
2780         if (frametime) // WORKAROUND: only use dropclient in server frames (frametime set). Never use it in cl_movement frames (frametime zero).
2781         if (IS_REAL_CLIENT(this))
2782         if (IS_PLAYER(this) || sv_maxidle_spectatorsareidle)
2783         {
2784                 int totalClients = 0;
2785                 if(sv_maxidle_slots > 0)
2786                 {
2787                         FOREACH_CLIENT(IS_REAL_CLIENT(it) || sv_maxidle_slots_countbots,
2788                         {
2789                                 ++totalClients;
2790                         });
2791                 }
2792
2793                 if (sv_maxidle_slots > 0 && (maxclients - totalClients) > sv_maxidle_slots)
2794                 { /* do nothing */ }
2795                 else if (time - CS(this).parm_idlesince < 1) // instead of (time == this.parm_idlesince) to support sv_maxidle <= 10
2796                 {
2797                         if (CS(this).idlekick_lasttimeleft)
2798                         {
2799                                 CS(this).idlekick_lasttimeleft = 0;
2800                                 Kill_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CPID_IDLING);
2801                         }
2802                 }
2803                 else
2804                 {
2805                         float timeleft = ceil(sv_maxidle - (time - CS(this).parm_idlesince));
2806                         if (timeleft == min(10, sv_maxidle - 1)) { // - 1 to support sv_maxidle <= 10
2807                                 if (!CS(this).idlekick_lasttimeleft)
2808                                         Send_Notification(NOTIF_ONE_ONLY, this, MSG_CENTER, CENTER_DISCONNECT_IDLING, timeleft);
2809                         }
2810                         if (timeleft <= 0) {
2811                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_QUIT_KICK_IDLING, this.netname);
2812                                 dropclient(this);
2813                                 return;
2814                         }
2815                         else if (timeleft <= 10) {
2816                                 if (timeleft != CS(this).idlekick_lasttimeleft) {
2817                                     Send_Notification(NOTIF_ONE, this, MSG_ANNCE, Announcer_PickNumber(CNT_IDLE, timeleft));
2818                 }
2819                                 CS(this).idlekick_lasttimeleft = timeleft;
2820                         }
2821                 }
2822         }
2823
2824         CheatFrame(this);
2825
2826         if (game_stopped)
2827         {
2828                 this.solid = SOLID_NOT;
2829                 this.takedamage = DAMAGE_NO;
2830                 set_movetype(this, MOVETYPE_NONE);
2831         }
2832
2833         if (IS_PLAYER(this)) {
2834                 if(this.death_time == time && IS_DEAD(this))
2835                 {
2836                         // player's bbox gets resized now, instead of in the damage event that killed the player,
2837                         // once all the damage events of this frame have been processed with normal size
2838                         this.maxs.z = 5;
2839                         setsize(this, this.mins, this.maxs);
2840                 }
2841                 DrownPlayer(this);
2842                 UpdateChatBubble(this);
2843                 if (CS(this).impulse) ImpulseCommands(this);
2844                 if (game_stopped)
2845                 {
2846                         CSQCMODEL_AUTOUPDATE(this);
2847                         return;
2848                 }
2849                 GetPressedKeys(this);
2850         }
2851
2852         if (this.waypointsprite_attachedforcarrier) {
2853             vector v = healtharmor_maxdamage(GetResourceAmount(this, RESOURCE_HEALTH), GetResourceAmount(this, RESOURCE_ARMOR), autocvar_g_balance_armor_blockpercent, DEATH_WEAPON.m_id);
2854                 WaypointSprite_UpdateHealth(this.waypointsprite_attachedforcarrier, '1 0 0' * v);
2855     }
2856
2857         CSQCMODEL_AUTOUPDATE(this);
2858 }
2859
2860 // hack to copy the button fields from the client entity to the Client State
2861 void PM_UpdateButtons(entity this, entity store)
2862 {
2863         if(this.impulse)
2864                 store.impulse = this.impulse;
2865         this.impulse = 0;
2866
2867         bool typing = this.buttonchat;
2868
2869         store.button0 = (typing) ? 0 : this.button0;
2870         //button1?!
2871         store.button2 = (typing) ? 0 : this.button2;
2872         store.button3 = (typing) ? 0 : this.button3;
2873         store.button4 = this.button4;
2874         store.button5 = (typing) ? 0 : this.button5;
2875         store.button6 = this.button6;
2876         store.button7 = this.button7;
2877         store.button8 = this.button8;
2878         store.button9 = this.button9;
2879         store.button10 = this.button10;
2880         store.button11 = this.button11;
2881         store.button12 = this.button12;
2882         store.button13 = this.button13;
2883         store.button14 = this.button14;
2884         store.button15 = this.button15;
2885         store.button16 = this.button16;
2886         store.buttonuse = this.buttonuse;
2887         store.buttonchat = this.buttonchat;
2888
2889         store.cursor_active = this.cursor_active;
2890         store.cursor_screen = this.cursor_screen;
2891         store.cursor_trace_start = this.cursor_trace_start;
2892         store.cursor_trace_endpos = this.cursor_trace_endpos;
2893         store.cursor_trace_ent = this.cursor_trace_ent;
2894
2895         store.ping = this.ping;
2896         store.ping_packetloss = this.ping_packetloss;
2897         store.ping_movementloss = this.ping_movementloss;
2898
2899         store.v_angle = this.v_angle;
2900         store.movement = (typing) ? '0 0 0' : this.movement;
2901 }
2902
2903 NET_HANDLE(fpsreport, bool)
2904 {
2905         int fps = ReadShort();
2906         PlayerScore_Set(sender, SP_FPS, fps);
2907         return true;
2908 }