qcsrc/server/command/cmd.qc

   1 #include "cmd.qh"
   2 #include <common/command/_mod.qh>
   3
   4 #include "common.qh"
   5 #include "vote.qh"
   6
   7 #include "../campaign.qh"
   8 #include "../cheats.qh"
   9 #include "../player.qh"
  10 #include "../ipban.qh"
  11 #include "../mapvoting.qh"
  12 #include "../scores.qh"
  13 #include "../teamplay.qh"
  14
  15 #include "../mutators/_mod.qh"
  16
  17 #ifdef SVQC
  18         #include <common/vehicles/all.qh>
  19 #endif
  20
  21 #include <common/constants.qh>
  22 #include <common/deathtypes/all.qh>
  23 #include <common/effects/all.qh>
  24 #include <common/mapinfo.qh>
  25 #include <common/notifications/all.qh>
  26 #include <common/physics/player.qh>
  27 #include <common/teams.qh>
  28 #include <common/util.qh>
  29 #include <common/triggers/triggers.qh>
  30
  31 #include <common/minigames/sv_minigames.qh>
  32
  33 #include <common/monsters/_mod.qh>
  34 #include <common/monsters/sv_spawn.qh>
  35 #include <common/monsters/sv_monsters.qh>
  36
  37 #include <lib/warpzone/common.qh>
  38
  39 void ClientKill_TeamChange(entity this, float targetteam);  // 0 = don't change, -1 = auto, -2 = spec
  40
  41 // =========================================================
  42 //  Server side networked commands code, reworked by Samual
  43 //  Last updated: December 28th, 2011
  44 // =========================================================
  45
  46 bool SV_ParseClientCommand_floodcheck(entity this)
  47 {
  48         entity store = IS_CLIENT(this) ? CS(this) : this; // unfortunately, we need to store these on the client initially
  49
  50         if (!timeout_status)  // not while paused
  51         {
  52                 if (time <= (store.cmd_floodtime + autocvar_sv_clientcommand_antispam_time))
  53                 {
  54                         store.cmd_floodcount += 1;
  55                         if (store.cmd_floodcount > autocvar_sv_clientcommand_antispam_count)   return false;  // too much spam, halt
  56                 }
  57                 else
  58                 {
  59                         store.cmd_floodtime = time;
  60                         store.cmd_floodcount = 1;
  61                 }
  62         }
  63         return true;  // continue, as we're not flooding yet
  64 }
  65
  66
  67 // =======================
  68 //  Command Sub-Functions
  69 // =======================
  70
  71 void ClientCommand_autoswitch(entity caller, float request, float argc)
  72 {
  73         switch (request)
  74         {
  75                 case CMD_REQUEST_COMMAND:
  76                 {
  77                         if (argv(1) != "")
  78                         {
  79                                 CS(caller).autoswitch = InterpretBoolean(argv(1));
  80                                 sprint(caller, strcat("^1autoswitch is currently turned ", (CS(caller).autoswitch ? "on" : "off"), ".\n"));
  81                                 return;
  82                         }
  83                 }
  84
  85                 default:
  86                         sprint(caller, "Incorrect parameters for ^2autoswitch^7\n");
  87                 case CMD_REQUEST_USAGE:
  88                 {
  89                         sprint(caller, "\nUsage:^3 cmd autoswitch selection\n");
  90                         sprint(caller, "  Where 'selection' controls if autoswitch is on or off.\n");
  91                         return;
  92                 }
  93         }
  94 }
  95
  96 void ClientCommand_clientversion(entity caller, float request, float argc)  // internal command, used only by code
  97 {
  98         switch (request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         if (argv(1) != "")
 103                         {
 104                                 if (IS_CLIENT(caller))
 105                                 {
 106                                         CS(caller).version = ((argv(1) == "$gameversion") ? 1 : stof(argv(1)));
 107
 108                                         if (CS(caller).version < autocvar_gameversion_min || CS(caller).version > autocvar_gameversion_max)
 109                                         {
 110                                                 CS(caller).version_mismatch = true;
 111                                                 ClientKill_TeamChange(caller, -2);  // observe
 112                                         }
 113                                         else if (autocvar_g_campaign || autocvar_g_balance_teams)
 114                                         {
 115                                                 // JoinBestTeam(caller, false, true);
 116                                         }
 117                                         else if (teamplay && !autocvar_sv_spectate && !(caller.team_forced > 0))
 118                                         {
 119                                                 TRANSMUTE(Observer, caller);  // really?
 120                                                 stuffcmd(caller, "menu_showteamselect\n");
 121                                         }
 122                                 }
 123
 124                                 return;
 125                         }
 126                 }
 127
 128                 default:
 129                         sprint(caller, "Incorrect parameters for ^2clientversion^7\n");
 130                 case CMD_REQUEST_USAGE:
 131                 {
 132                         sprint(caller, "\nUsage:^3 cmd clientversion version\n");
 133                         sprint(caller, "  Where 'version' is the game version reported by caller.\n");
 134                         return;
 135                 }
 136         }
 137 }
 138
 139 void ClientCommand_mv_getpicture(entity caller, float request, float argc)  // internal command, used only by code
 140 {
 141         switch (request)
 142         {
 143                 case CMD_REQUEST_COMMAND:
 144                 {
 145                         if (argv(1) != "")
 146                         {
 147                                 if (intermission_running) MapVote_SendPicture(caller, stof(argv(1)));
 148
 149                                 return;
 150                         }
 151                 }
 152
 153                 default:
 154                         sprint(caller, "Incorrect parameters for ^2mv_getpicture^7\n");
 155                 case CMD_REQUEST_USAGE:
 156                 {
 157                         sprint(caller, "\nUsage:^3 cmd mv_getpicture mapid\n");
 158                         sprint(caller, "  Where 'mapid' is the id number of the map to request an image of on the map vote selection menu.\n");
 159                         return;
 160                 }
 161         }
 162 }
 163
 164 bool joinAllowed(entity this);
 165 void Join(entity this);
 166 void ClientCommand_join(entity caller, float request)
 167 {
 168         switch (request)
 169         {
 170                 case CMD_REQUEST_COMMAND:
 171                 {
 172                         if (!game_stopped)
 173                         if (IS_CLIENT(caller) && !IS_PLAYER(caller))
 174                         if (joinAllowed(caller))
 175                                 Join(caller);
 176
 177                         return;  // never fall through to usage
 178                 }
 179
 180                 default:
 181                 case CMD_REQUEST_USAGE:
 182                 {
 183                         sprint(caller, "\nUsage:^3 cmd join\n");
 184                         sprint(caller, "  No arguments required.\n");
 185                         return;
 186                 }
 187         }
 188 }
 189
 190 void ClientCommand_physics(entity caller, float request, float argc)
 191 {
 192         switch (request)
 193         {
 194                 case CMD_REQUEST_COMMAND:
 195                 {
 196                         string command = strtolower(argv(1));
 197
 198                         if (!autocvar_g_physics_clientselect)
 199                         {
 200                                 sprint(caller, "Client physics selection is currently disabled.\n");
 201                                 return;
 202                         }
 203
 204                         if (command == "list" || command == "help")
 205                         {
 206                                 sprint(caller, strcat("Available physics sets: \n\n", autocvar_g_physics_clientselect_options, " default\n"));
 207                                 return;
 208                         }
 209
 210                         if (Physics_Valid(command) || command == "default")
 211                         {
 212                                 stuffcmd(caller, strcat("\nseta cl_physics ", command, "\nsendcvar cl_physics\n"));
 213                                 sprint(caller, strcat("^2Physics set successfully changed to ^3", command, "\n"));
 214                                 return;
 215                         }
 216                 }
 217
 218                 default:
 219                         sprint(caller, strcat("Current physics set: ^3", CS(caller).cvar_cl_physics, "\n"));
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         sprint(caller, "\nUsage:^3 cmd physics <physics>\n");
 223                         sprint(caller, "  See 'cmd physics list' for available physics sets.\n");
 224                         sprint(caller, "  Argument 'default' resets to standard physics.\n");
 225                         return;
 226                 }
 227         }
 228 }
 229
 230 void ClientCommand_ready(entity caller, float request)  // todo: anti-spam for toggling readyness
 231 {
 232         switch (request)
 233         {
 234                 case CMD_REQUEST_COMMAND:
 235                 {
 236                         if (IS_CLIENT(caller))
 237                         {
 238                                 if (warmup_stage || autocvar_sv_ready_restart || g_race_qualifying == 2)
 239                                 {
 240                                         if (!readyrestart_happened || autocvar_sv_ready_restart_repeatable)
 241                                         {
 242                                                 if (time < game_starttime) // game is already restarting
 243                                                         return;
 244                                                 if (caller.ready)            // toggle
 245                                                 {
 246                                                         caller.ready = false;
 247                                                         bprint(playername(caller, false), "^2 is ^1NOT^2 ready\n");
 248                                                 }
 249                                                 else
 250                                                 {
 251                                                         caller.ready = true;
 252                                                         bprint(playername(caller, false), "^2 is ready\n");
 253                                                 }
 254
 255                                                 // cannot reset the game while a timeout is active!
 256                                                 if (!timeout_status) ReadyCount();
 257                                         }
 258                                         else
 259                                         {
 260                                                 sprint(caller, "^1Game has already been restarted\n");
 261                                         }
 262                                 }
 263                         }
 264                         return;  // never fall through to usage
 265                 }
 266
 267                 default:
 268                 case CMD_REQUEST_USAGE:
 269                 {
 270                         sprint(caller, "\nUsage:^3 cmd ready\n");
 271                         sprint(caller, "  No arguments required.\n");
 272                         return;
 273                 }
 274         }
 275 }
 276
 277 void ClientCommand_say(entity caller, float request, float argc, string command)
 278 {
 279         switch (request)
 280         {
 281                 case CMD_REQUEST_COMMAND:
 282                 {
 283                         if (argc >= 2)   Say(caller, false, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 284                         return;  // never fall through to usage
 285                 }
 286
 287                 default:
 288                 case CMD_REQUEST_USAGE:
 289                 {
 290                         sprint(caller, "\nUsage:^3 cmd say <message>\n");
 291                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 292                         return;
 293                 }
 294         }
 295 }
 296
 297 void ClientCommand_say_team(entity caller, float request, float argc, string command)
 298 {
 299         switch (request)
 300         {
 301                 case CMD_REQUEST_COMMAND:
 302                 {
 303                         if (argc >= 2)   Say(caller, true, NULL, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)), 1);
 304                         return;  // never fall through to usage
 305                 }
 306
 307                 default:
 308                 case CMD_REQUEST_USAGE:
 309                 {
 310                         sprint(caller, "\nUsage:^3 cmd say_team <message>\n");
 311                         sprint(caller, "  Where 'message' is the string of text to say.\n");
 312                         return;
 313                 }
 314         }
 315 }
 316
 317 .bool team_selected;
 318 void ClientCommand_selectteam(entity caller, float request, float argc)
 319 {
 320         switch (request)
 321         {
 322                 case CMD_REQUEST_COMMAND:
 323                 {
 324                         if (argv(1) != "")
 325                         {
 326                                 if (IS_CLIENT(caller))
 327                                 {
 328                                         if (teamplay)
 329                                         {
 330                                                 if (caller.team_forced <= 0)
 331                                                 {
 332                                                         if (!lockteams)
 333                                                         {
 334                                                                 float selection;
 335
 336                                                                 switch (argv(1))
 337                                                                 {
 338                                                                         case "red": selection = NUM_TEAM_1;
 339                                                                                 break;
 340                                                                         case "blue": selection = NUM_TEAM_2;
 341                                                                                 break;
 342                                                                         case "yellow": selection = NUM_TEAM_3;
 343                                                                                 break;
 344                                                                         case "pink": selection = NUM_TEAM_4;
 345                                                                                 break;
 346                                                                         case "auto": selection = (-1);
 347                                                                                 break;
 348
 349                                                                         default: selection = 0;
 350                                                                                 break;
 351                                                                 }
 352
 353                                                                 if (selection)
 354                                                                 {
 355                                                                         if (caller.team == selection && selection != -1 && !IS_DEAD(caller))
 356                                                                         {
 357                                                                                 sprint(caller, "^7You already are on that team.\n");
 358                                                                         }
 359                                                                         else if (CS(caller).wasplayer && autocvar_g_changeteam_banned)
 360                                                                         {
 361                                                                                 sprint(caller, "^1You cannot change team, forbidden by the server.\n");
 362                                                                         }
 363                                                                         else
 364                                                                         {
 365                                                                                 if (autocvar_g_balance_teams && autocvar_g_balance_teams_prevent_imbalance)
 366                                                                                 {
 367                                                                                         CheckAllowedTeams(caller);
 368                                                                                         GetTeamCounts(caller);
 369                                                                                         if (!TeamSmallerEqThanTeam(Team_TeamToNumber(selection), Team_TeamToNumber(caller.team), caller))
 370                                                                                         {
 371                                                                                                 Send_Notification(NOTIF_ONE, caller, MSG_INFO, INFO_TEAMCHANGE_LARGERTEAM);
 372                                                                                                 return;
 373                                                                                         }
 374                                                                                 }
 375                                                                                 ClientKill_TeamChange(caller, selection);
 376                                                                         }
 377                                                                         if(!IS_PLAYER(caller))
 378                                                                                 caller.team_selected = true; // avoids asking again for team selection on join
 379                                                                 }
 380                                                         }
 381                                                         else
 382                                                         {
 383                                                                 sprint(caller, "^7The game has already begun, you must wait until the next map to be able to join a team.\n");
 384                                                         }
 385                                                 }
 386                                                 else
 387                                                 {
 388                                                         sprint(caller, "^7selectteam can not be used as your team is forced\n");
 389                                                 }
 390                                         }
 391                                         else
 392                                         {
 393                                                 sprint(caller, "^7selectteam can only be used in teamgames\n");
 394                                         }
 395                                 }
 396                                 return;
 397                         }
 398                 }
 399
 400                 default:
 401                         sprint(caller, "Incorrect parameters for ^2selectteam^7\n");
 402                 case CMD_REQUEST_USAGE:
 403                 {
 404                         sprint(caller, "\nUsage:^3 cmd selectteam team\n");
 405                         sprint(caller, "  Where 'team' is the prefered team to try and join.\n");
 406                         sprint(caller, "  Full list of options here: \"red, blue, yellow, pink, auto\"\n");
 407                         return;
 408                 }
 409         }
 410 }
 411
 412 void ClientCommand_selfstuff(entity caller, float request, string command)
 413 {
 414         switch (request)
 415         {
 416                 case CMD_REQUEST_COMMAND:
 417                 {
 418                         if (argv(1) != "")
 419                         {
 420                                 stuffcmd(caller, substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 421                                 return;
 422                         }
 423                 }
 424
 425                 default:
 426                         sprint(caller, "Incorrect parameters for ^2selfstuff^7\n");
 427                 case CMD_REQUEST_USAGE:
 428                 {
 429                         sprint(caller, "\nUsage:^3 cmd selfstuff <command>\n");
 430                         sprint(caller, "  Where 'command' is the string to be stuffed to your client.\n");
 431                         return;
 432                 }
 433         }
 434 }
 435
 436 void ClientCommand_sentcvar(entity caller, float request, float argc, string command)
 437 {
 438         switch (request)
 439         {
 440                 case CMD_REQUEST_COMMAND:
 441                 {
 442                         if (argv(1) != "")
 443                         {
 444                                 // float tokens;
 445                                 string s;
 446
 447                                 if (argc == 2)  // undefined cvar: use the default value on the server then
 448                                 {
 449                                         s = strcat(substring(command, argv_start_index(0), argv_end_index(1) - argv_start_index(0)), " \"", cvar_defstring(argv(1)), "\"");
 450                                         tokenize_console(s);
 451                                 }
 452
 453                                 GetCvars(caller, 1);
 454
 455                                 return;
 456                         }
 457                 }
 458
 459                 default:
 460                         sprint(caller, "Incorrect parameters for ^2sentcvar^7\n");
 461                 case CMD_REQUEST_USAGE:
 462                 {
 463                         sprint(caller, "\nUsage:^3 cmd sentcvar <cvar>\n");
 464                         sprint(caller, "  Where 'cvar' is the cvar plus arguments to send to the server.\n");
 465                         return;
 466                 }
 467         }
 468 }
 469
 470 void ClientCommand_spectate(entity caller, float request)
 471 {
 472         switch (request)
 473         {
 474                 case CMD_REQUEST_COMMAND:
 475                 {
 476                         if (!intermission_running && IS_CLIENT(caller))
 477                         {
 478                                 if((IS_SPEC(caller) || IS_OBSERVER(caller)) && argv(1) != "")
 479                                 {
 480                                         entity client = GetFilteredEntity(argv(1));
 481                                         int spec_accepted = VerifyClientEntity(client, false, false);
 482                                         if(spec_accepted > 0 && IS_PLAYER(client))
 483                                         {
 484                                                 if(Spectate(caller, client))
 485                                                         return; // fall back to regular handling
 486                                         }
 487                                 }
 488
 489                                 int mutator_returnvalue = MUTATOR_CALLHOOK(ClientCommand_Spectate, caller);
 490
 491                                 if (mutator_returnvalue == MUT_SPECCMD_RETURN) return;
 492
 493                                 if ((IS_PLAYER(caller) || mutator_returnvalue == MUT_SPECCMD_FORCE))
 494                                 if (autocvar_sv_spectate == 1)
 495                                         ClientKill_TeamChange(caller, -2); // observe
 496                         }
 497                         return; // never fall through to usage
 498                 }
 499
 500                 default:
 501                 case CMD_REQUEST_USAGE:
 502                 {
 503                         sprint(caller, "\nUsage:^3 cmd spectate <client>\n");
 504                         sprint(caller, "  Where 'client' can be the player to spectate.\n");
 505                         return;
 506                 }
 507         }
 508 }
 509
 510 void ClientCommand_suggestmap(entity caller, float request, float argc)
 511 {
 512         switch (request)
 513         {
 514                 case CMD_REQUEST_COMMAND:
 515                 {
 516                         if (argv(1) != "")
 517                         {
 518                                 sprint(caller, strcat(MapVote_Suggest(caller, argv(1)), "\n"));
 519                                 return;
 520                         }
 521                 }
 522
 523                 default:
 524                         sprint(caller, "Incorrect parameters for ^2suggestmap^7\n");
 525                 case CMD_REQUEST_USAGE:
 526                 {
 527                         sprint(caller, "\nUsage:^3 cmd suggestmap map\n");
 528                         sprint(caller, "  Where 'map' is the name of the map to suggest.\n");
 529                         return;
 530                 }
 531         }
 532 }
 533
 534 void ClientCommand_tell(entity caller, float request, float argc, string command)
 535 {
 536         switch (request)
 537         {
 538                 case CMD_REQUEST_COMMAND:
 539                 {
 540                         if (argc >= 3)
 541                         {
 542                                 if(!IS_CLIENT(caller) && IS_REAL_CLIENT(caller)) // connecting
 543                                 {
 544                                         print_to(caller, "You can't ^2tell^7 a message while connecting.");
 545                                         return;
 546                                 }
 547
 548                                 entity tell_to = GetIndexedEntity(argc, 1);
 549                                 float tell_accepted = VerifyClientEntity(tell_to, true, false);
 550
 551                                 if (tell_accepted > 0)   // the target is a real client
 552                                 {
 553                                         if (tell_to != caller) // and we're allowed to send to them :D
 554                                         {
 555                                                 // workaround for argv indexes indexing ascii chars instead of utf8 chars
 556                                                 // In this case when the player name contains utf8 chars
 557                                                 // the message gets partially trimmed in the beginning.
 558                                                 // Potentially this bug affects any substring call that uses
 559                                                 // argv_start_index and argv_end_index.
 560
 561                                                 string utf8_enable_save = cvar_string("utf8_enable");
 562                                                 cvar_set("utf8_enable", "0");
 563                                                 string msg = substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token));
 564                                                 cvar_set("utf8_enable", utf8_enable_save);
 565
 566                                                 Say(caller, false, tell_to, msg, true);
 567                                                 return;
 568                                         }
 569                                         else { print_to(caller, "You can't ^2tell^7 a message to yourself."); return; }
 570                                 }
 571                                 else if (argv(1) == "#0")
 572                                 {
 573                                         trigger_magicear_processmessage_forallears(caller, -1, NULL, substring(command, argv_start_index(next_token), argv_end_index(-1) - argv_start_index(next_token)));
 574                                         return;
 575                                 }
 576                                 else { print_to(caller, strcat("tell: ", GetClientErrorString(tell_accepted, argv(1)), ".")); return; }
 577                         }
 578                 }
 579
 580                 default:
 581                         sprint(caller, "Incorrect parameters for ^2tell^7\n");
 582                 case CMD_REQUEST_USAGE:
 583                 {
 584                         sprint(caller, "\nUsage:^3 cmd tell client <message>\n");
 585                         sprint(caller, "  Where 'client' is the entity number or name of the player to send 'message' to.\n");
 586                         return;
 587                 }
 588         }
 589 }
 590
 591 void ClientCommand_voice(entity caller, float request, float argc, string command)
 592 {
 593         switch (request)
 594         {
 595                 case CMD_REQUEST_COMMAND:
 596                 {
 597                         if (argv(1) != "")
 598                         {
 599                                 entity e = GetVoiceMessage(argv(1));
 600                                 if (!e)
 601                                 {
 602                                         sprint(caller, sprintf("Invalid voice. Use one of: %s\n", allvoicesamples));
 603                                         return;
 604                                 }
 605                                 if (argc >= 3) VoiceMessage(caller, e, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 606                                 else VoiceMessage(caller, e, "");
 607
 608                                 return;
 609                         }
 610                 }
 611
 612                 default:
 613                         sprint(caller, "Incorrect parameters for ^2voice^7\n");
 614                 case CMD_REQUEST_USAGE:
 615                 {
 616                         sprint(caller, "\nUsage:^3 cmd voice messagetype <soundname>\n");
 617                         sprint(caller, "  'messagetype' is the type of broadcast to do, like team only or such,\n");
 618                         sprint(caller, "  and 'soundname' is the string/filename of the sound/voice message to play.\n");
 619                         return;
 620                 }
 621         }
 622 }
 623
 624 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 625 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 626 void ClientCommand_(entity caller, float request)
 627 {
 628     switch(request)
 629     {
 630         case CMD_REQUEST_COMMAND:
 631         {
 632
 633             return; // never fall through to usage
 634         }
 635
 636         default:
 637         case CMD_REQUEST_USAGE:
 638         {
 639             sprint(caller, "\nUsage:^3 cmd \n");
 640             sprint(caller, "  No arguments required.\n");
 641             return;
 642         }
 643     }
 644 }
 645 */
 646
 647
 648 // =====================================
 649 //  Macro system for networked commands
 650 // =====================================
 651
 652 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 653 #define CLIENT_COMMANDS(ent, request, arguments, command) \
 654         CLIENT_COMMAND("autoswitch", ClientCommand_autoswitch(ent, request, arguments), "Whether or not to switch automatically when getting a better weapon") \
 655         CLIENT_COMMAND("clientversion", ClientCommand_clientversion(ent, request, arguments), "Release version of the game") \
 656         CLIENT_COMMAND("mv_getpicture", ClientCommand_mv_getpicture(ent, request, arguments), "Retrieve mapshot picture from the server") \
 657         CLIENT_COMMAND("join", ClientCommand_join(ent, request), "Become a player in the game") \
 658         CLIENT_COMMAND("physics", ClientCommand_physics(ent, request, arguments), "Change physics set") \
 659         CLIENT_COMMAND("ready", ClientCommand_ready(ent, request), "Qualify as ready to end warmup stage (or restart server if allowed)") \
 660         CLIENT_COMMAND("say", ClientCommand_say(ent, request, arguments, command), "Print a message to chat to all players") \
 661         CLIENT_COMMAND("say_team", ClientCommand_say_team(ent, request, arguments, command), "Print a message to chat to all team mates") \
 662         CLIENT_COMMAND("selectteam", ClientCommand_selectteam(ent, request, arguments), "Attempt to choose a team to join into") \
 663         CLIENT_COMMAND("selfstuff", ClientCommand_selfstuff(ent, request, command), "Stuffcmd a command to your own client") \
 664         CLIENT_COMMAND("sentcvar", ClientCommand_sentcvar(ent, request, arguments, command), "New system for sending a client cvar to the server") \
 665         CLIENT_COMMAND("spectate", ClientCommand_spectate(ent, request), "Become an observer") \
 666         CLIENT_COMMAND("suggestmap", ClientCommand_suggestmap(ent, request, arguments), "Suggest a map to the mapvote at match end") \
 667         CLIENT_COMMAND("tell", ClientCommand_tell(ent, request, arguments, command), "Send a message directly to a player") \
 668         CLIENT_COMMAND("voice", ClientCommand_voice(ent, request, arguments, command), "Send voice message via sound") \
 669         CLIENT_COMMAND("minigame", ClientCommand_minigame(ent, request, arguments, command), "Start a minigame") \
 670         /* nothing */
 671
 672 void ClientCommand_macro_help(entity caller)
 673 {
 674         #define CLIENT_COMMAND(name, function, description) \
 675                 { sprint(caller, "  ^2", name, "^7: ", description, "\n"); }
 676
 677         CLIENT_COMMANDS(NULL, 0, 0, "");
 678 #undef CLIENT_COMMAND
 679 }
 680
 681 float ClientCommand_macro_command(float argc, entity caller, string command)
 682 {
 683         #define CLIENT_COMMAND(name, function, description) \
 684                 { if (name == strtolower(argv(0))) { function; return true; } }
 685
 686         CLIENT_COMMANDS(caller, CMD_REQUEST_COMMAND, argc, command);
 687 #undef CLIENT_COMMAND
 688
 689         return false;
 690 }
 691
 692 float ClientCommand_macro_usage(float argc, entity caller)
 693 {
 694         #define CLIENT_COMMAND(name, function, description) \
 695                 { if (name == strtolower(argv(1))) { function; return true; } }
 696
 697         CLIENT_COMMANDS(caller, CMD_REQUEST_USAGE, argc, "");
 698 #undef CLIENT_COMMAND
 699
 700         return false;
 701 }
 702
 703 void ClientCommand_macro_write_aliases(float fh)
 704 {
 705         #define CLIENT_COMMAND(name, function, description) \
 706                 { CMD_Write_Alias("qc_cmd_cmd", name, description); }
 707
 708         CLIENT_COMMANDS(NULL, 0, 0, "");
 709 #undef CLIENT_COMMAND
 710 }
 711
 712 // ======================================
 713 //  Main Function Called By Engine (cmd)
 714 // ======================================
 715 // If this function exists, server game code parses clientcommand before the engine code gets it.
 716
 717 void SV_ParseClientCommand(entity this, string command)
 718 {
 719         // If invalid UTF-8, don't even parse it
 720         string command2 = "";
 721         float len = strlen(command);
 722         float i;
 723         for (i = 0; i < len; ++i)
 724                 command2 = strcat(command2, chr2str(str2chr(command, i)));
 725         if (command != command2) return;
 726
 727         // if we're banned, don't even parse the command
 728         if (Ban_MaybeEnforceBanOnce(this)) return;
 729
 730         float argc = tokenize_console(command);
 731
 732         // Guide for working with argc arguments by example:
 733         // argc:   1    - 2      - 3     - 4
 734         // argv:   0    - 1      - 2     - 3
 735         // cmd     vote - master - login - password
 736
 737         // for floodcheck
 738         switch (strtolower(argv(0)))
 739         {
 740                 // exempt commands which are not subject to floodcheck
 741                 case "begin": break;                               // handled by engine in host_cmd.c
 742                 case "download": break;                            // handled by engine in cl_parse.c
 743                 case "mv_getpicture": break;                       // handled by server in this file
 744                 case "pause": break;                               // handled by engine in host_cmd.c
 745                 case "prespawn": break;                            // handled by engine in host_cmd.c
 746                 case "sentcvar": break;                            // handled by server in this file
 747                 case "spawn": break;                               // handled by engine in host_cmd.c
 748                 case "c2s": Net_ClientCommand(this, command); return; // handled by net.qh
 749
 750                 default:
 751                         if (SV_ParseClientCommand_floodcheck(this)) break; // "true": continue, as we're not flooding yet
 752                         else return;                                   // "false": not allowed to continue, halt // print("^1ERROR: ^7ANTISPAM CAUGHT: ", command, ".\n");
 753         }
 754
 755         /* NOTE: should this be disabled? It can be spammy perhaps, but hopefully it's okay for now */
 756         if (argv(0) == "help")
 757         {
 758                 if (argc == 1)
 759                 {
 760                         sprint(this, "\nClient networked commands:\n");
 761                         ClientCommand_macro_help(this);
 762
 763                         sprint(this, "\nCommon networked commands:\n");
 764                         CommonCommand_macro_help(this);
 765
 766                         sprint(this, "\nUsage:^3 cmd COMMAND...^7, where possible commands are listed above.\n");
 767                         sprint(this, "For help about a specific command, type cmd help COMMAND\n");
 768                         return;
 769                 }
 770                 else if (CommonCommand_macro_usage(argc, this))  // Instead of trying to call a command, we're going to see detailed information about it
 771                 {
 772                         return;
 773                 }
 774                 else if (ClientCommand_macro_usage(argc, this))  // same, but for normal commands now
 775                 {
 776                         return;
 777                 }
 778         }
 779         else if (MUTATOR_CALLHOOK(SV_ParseClientCommand, this, strtolower(argv(0)), argc, command))
 780         {
 781                 return;  // handled by a mutator
 782         }
 783         else if (CheatCommand(this, argc))
 784         {
 785                 return;  // handled by server/cheats.qc
 786         }
 787         else if (CommonCommand_macro_command(argc, this, command))
 788         {
 789                 return;                                          // handled by server/command/common.qc
 790         }
 791         else if (ClientCommand_macro_command(argc, this, command)) // continue as usual and scan for normal commands
 792         {
 793                 return;                                          // handled by one of the above ClientCommand_* functions
 794         }
 795         else
 796         {
 797                 clientcommand(this, command);
 798         }
 799 }