qcsrc/server/command/common.qc

   1 #include "common.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/monsters/_mod.qh>
   6 #include <common/notifications/all.qh>
   7 #include <common/stats.qh>
   8 #include <common/vehicles/all.qh>
   9 #include <common/weapons/_all.qh>
  10 #include <lib/warpzone/common.qh>
  11 #include <server/campaign.qh>
  12 #include <server/chat.qh>
  13 #include <server/client.qh>
  14 #include <server/command/common.qh>
  15 #include <server/mutators/_mod.qh>
  16 #include <server/scores.qh>
  17 #include <server/world.qh>
  18
  19
  20 // ====================================================
  21 //  Shared code for server commands, written by Samual
  22 //  Last updated: December 27th, 2011
  23 // ====================================================
  24
  25 // select the proper prefix for usage and other messages
  26 string GetCommandPrefix(entity caller)
  27 {
  28         if (caller) return "cmd";
  29         else return "sv_cmd";
  30 }
  31
  32 // if client return player nickname, or if server return admin nickname
  33 string GetCallerName(entity caller)
  34 {
  35         if (caller) return playername(caller.netname, caller.team, false);
  36         else return ((autocvar_sv_adminnick != "") ? autocvar_sv_adminnick : "SERVER ADMIN"); // autocvar_hostname
  37 }
  38
  39 // verify that the client provided is acceptable for kicking
  40 float VerifyKickableEntity(entity client)
  41 {
  42         if (!IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  43         return CLIENT_ACCEPTABLE;
  44 }
  45
  46 // verify that the client provided is acceptable for use
  47 float VerifyClientEntity(entity client, float must_be_real, float must_be_bots)
  48 {
  49         if (!IS_CLIENT(client)) return CLIENT_DOESNT_EXIST;
  50         else if (must_be_real && !IS_REAL_CLIENT(client)) return CLIENT_NOT_REAL;
  51         else if (must_be_bots && !IS_BOT_CLIENT(client)) return CLIENT_NOT_BOT;
  52
  53         return CLIENT_ACCEPTABLE;
  54 }
  55
  56 // if the client is not acceptable, return a string to be used for error messages
  57 string GetClientErrorString_color(float clienterror, string original_input, string col)
  58 {
  59         switch (clienterror)
  60         {
  61                 case CLIENT_DOESNT_EXIST:
  62                 { return strcat(col, "Client '", original_input, col, "' doesn't exist");
  63                 }
  64                 case CLIENT_NOT_REAL:
  65                 { return strcat(col, "Client '", original_input, col, "' is not real");
  66                 }
  67                 case CLIENT_NOT_BOT:
  68                 { return strcat(col, "Client '", original_input, col, "' is not a bot");
  69                 }
  70                 default:
  71                 { return "Incorrect usage of GetClientErrorString";
  72                 }
  73         }
  74 }
  75
  76 // is this entity number even in the possible range of entities?
  77 float VerifyClientNumber(float tmp_number)
  78 {
  79         if ((tmp_number < 1) || (tmp_number > maxclients)) return false;
  80         else return true;
  81 }
  82
  83 entity GetIndexedEntity(int argc, float start_index)
  84 {
  85         entity selection;
  86         float tmp_number, index;
  87         string tmp_string;
  88
  89         next_token = -1;
  90         index = start_index;
  91         selection = NULL;
  92
  93         if (argc > start_index)
  94         {
  95                 if (substring(argv(index), 0, 1) == "#")
  96                 {
  97                         tmp_string = substring(argv(index), 1, -1);
  98                         ++index;
  99
 100                         if (tmp_string != "")  // is it all one token? like #1
 101                         {
 102                                 tmp_number = stof(tmp_string);
 103                         }
 104                         else if (argc > index)  // no, it's two tokens? # 1
 105                         {
 106                                 tmp_number = stof(argv(index));
 107                                 ++index;
 108                         }
 109                         else
 110                         {
 111                                 tmp_number = 0;
 112                         }
 113                 }
 114                 else  // maybe it's ONLY a number?
 115                 {
 116                         tmp_number = stof(argv(index));
 117                         ++index;
 118                 }
 119
 120                 if (VerifyClientNumber(tmp_number))
 121                 {
 122                         selection = edict_num(tmp_number);  // yes, it was a number
 123                 }
 124                 else  // no, maybe it's a name?
 125                 {
 126                         FOREACH_CLIENT(true, {
 127                                 if(strdecolorize(it.netname) == strdecolorize(argv(start_index)))
 128                                 {
 129                                         selection = it;
 130                                         break; // no reason to keep looking
 131                                 }
 132                         });
 133
 134                         index = (start_index + 1);
 135                 }
 136         }
 137
 138         next_token = index;
 139         // print(strcat("start_index: ", ftos(start_index), ", next_token: ", ftos(next_token), ", edict: ", ftos(num_for_edict(selection)), ".\n"));
 140         return selection;
 141 }
 142
 143 // find a player which matches the input string, and return their entity
 144 entity GetFilteredEntity(string input)
 145 {
 146         entity selection;
 147         float tmp_number;
 148
 149         if (substring(input, 0, 1) == "#") tmp_number = stof(substring(input, 1, -1));
 150         else tmp_number = stof(input);
 151
 152         if (VerifyClientNumber(tmp_number))
 153         {
 154                 selection = edict_num(tmp_number);
 155         }
 156         else
 157         {
 158                 selection = NULL;
 159                 FOREACH_CLIENT(true, {
 160                         if(strdecolorize(it.netname) == strdecolorize(input))
 161                         {
 162                                 selection = it;
 163                                 break; // no reason to keep looking
 164                         }
 165                 });
 166         }
 167
 168         return selection;
 169 }
 170
 171 // switch between sprint and print depending on whether the receiver is the server or a player
 172 void print_to(entity to, string input)
 173 {
 174         if (to) sprint(to, strcat(input, "\n"));
 175         else print(input, "\n");
 176 }
 177
 178 // ==========================================
 179 //  Supporting functions for common commands
 180 // ==========================================
 181
 182 // used by CommonCommand_timeout() and CommonCommand_timein() to handle game pausing and messaging and such.
 183 void timeout_handler_reset(entity this)
 184 {
 185         timeout_caller = NULL;
 186         timeout_time = 0;
 187         timeout_leadtime = 0;
 188
 189         delete(this);
 190 }
 191
 192 void timeout_handler_think(entity this)
 193 {
 194         switch (timeout_status)
 195         {
 196                 case TIMEOUT_ACTIVE:
 197                 {
 198                         if (timeout_time > 0)  // countdown is still going
 199                         {
 200                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ENDING, timeout_time);
 201
 202                                 if (timeout_time == autocvar_sv_timeout_resumetime) // play a warning sound when only <sv_timeout_resumetime> seconds are left
 203                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_PREPARE);
 204
 205                                 //this.nextthink = time + TIMEOUT_SLOWMO_VALUE;       // think again in one second
 206                                 this.nextthink = time + 1;
 207                                 timeout_time -= 1;                                  // decrease the time counter
 208                         }
 209                         else if (timeout_time == -1)  // infinite timer
 210                         {
 211                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_ONGOING);
 212                                 this.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 213                         }
 214                         else  // time to end the timeout
 215                         {
 216                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_TIMEIN);
 217                                 timeout_status = TIMEOUT_INACTIVE;
 218                                 float total_time = time - timeout_last;
 219
 220                                 // reset the slowmo value back to normal
 221                                 // z411 TODO
 222                                 //cvar_set("slowmo", ftos(orig_slowmo));
 223
 224                                 // Disable timeout and fix times
 225                                 game_timeout = false;
 226                                 timeout_total_time += total_time;
 227                                 game_starttime += total_time;
 228                                 round_starttime += total_time;
 229                                 if(round_handler && round_handler_GetEndTime() > 0)
 230                                         round_handler.round_endtime += total_time;
 231
 232                                 LOG_INFOF("Timeout lasted %d secs", total_time);
 233                                 timeout_last = 0;
 234
 235                                 // unlock the view for players so they can move around again
 236                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 237                                         it.fixangle = false;
 238                                 });
 239
 240                                 timeout_handler_reset(this);
 241                         }
 242
 243                         return;
 244                 }
 245
 246                 case TIMEOUT_LEADTIME:
 247                 {
 248                         if (timeout_leadtime > 0)  // countdown is still going
 249                         {
 250                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_TIMEOUT_BEGINNING, timeout_leadtime);
 251
 252                                 this.nextthink = time + 1; // think again in one second
 253                                 timeout_leadtime -= 1;     // decrease the time counter
 254                         }
 255                         else  // time to begin the timeout
 256                         {
 257                                 timeout_status = TIMEOUT_ACTIVE;
 258
 259                                 // set the slowmo value to the timeout default slowmo value
 260                                 //cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 261                                 game_timeout = true;
 262                                 timeout_last = time;
 263
 264                                 // play timeout sound
 265                                 sound(NULL, CH_INFO, SND_TIMEOUT, VOL_BASE, ATTN_NONE);
 266
 267                                 // reset all the flood variables
 268                                 FOREACH_CLIENT(true, {
 269                                         it.nickspamcount = it.nickspamtime = it.floodcontrol_chat =
 270                                                 it.floodcontrol_chatteam = it.floodcontrol_chattell =
 271                                                         it.floodcontrol_voice = it.floodcontrol_voiceteam = 0;
 272                                 });
 273
 274                                 // copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 275                                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), {
 276                                         it.lastV_angle = it.v_angle;
 277                                 });
 278
 279                                 this.nextthink = time;  // think again next frame to handle it under TIMEOUT_ACTIVE code
 280                         }
 281
 282                         return;
 283                 }
 284
 285
 286                 case TIMEOUT_INACTIVE:
 287                 default:
 288                 {
 289                         timeout_handler_reset(this);
 290                         return;
 291                 }
 292         }
 293 }
 294
 295
 296 // ===================================================
 297 //  Common commands used in both sv_cmd.qc and cmd.qc
 298 // ===================================================
 299
 300 void CommonCommand_cvar_changes(int request, entity caller)
 301 {
 302         switch (request)
 303         {
 304                 case CMD_REQUEST_COMMAND:
 305                 {
 306                         print_to(caller, cvar_changes);
 307                         return;  // never fall through to usage
 308                 }
 309
 310                 default:
 311                 case CMD_REQUEST_USAGE:
 312                 {
 313                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_changes"));
 314                         print_to(caller, "  No arguments required.");
 315                         print_to(caller, "See also: ^2cvar_purechanges^7");
 316                         return;
 317                 }
 318         }
 319 }
 320
 321 void CommonCommand_cvar_purechanges(int request, entity caller)
 322 {
 323         switch (request)
 324         {
 325                 case CMD_REQUEST_COMMAND:
 326                 {
 327                         print_to(caller, cvar_purechanges);
 328                         return;  // never fall through to usage
 329                 }
 330
 331                 default:
 332                 case CMD_REQUEST_USAGE:
 333                 {
 334                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " cvar_purechanges"));
 335                         print_to(caller, "  No arguments required.");
 336                         print_to(caller, "See also: ^2cvar_changes^7");
 337                         return;
 338                 }
 339         }
 340 }
 341
 342 void CommonCommand_editmob(int request, entity caller, int argc)
 343 {
 344         switch (request)
 345         {
 346                 case CMD_REQUEST_COMMAND:
 347                 {
 348                         if (autocvar_g_campaign) { print_to(caller, "Monster editing is disabled in singleplayer"); return; }
 349                         // no checks for g_monsters here, as it may be toggled mid match which existing monsters
 350
 351                         if (caller)
 352                         {
 353                                 makevectors(caller.v_angle);
 354                                 WarpZone_TraceLine(caller.origin + caller.view_ofs, caller.origin + caller.view_ofs + v_forward * 100, MOVE_NORMAL, caller);
 355                         }
 356
 357                         entity mon = trace_ent;
 358                         bool is_visible = IS_MONSTER(mon);
 359                         string argument = argv(2);
 360
 361                         switch (argv(1))
 362                         {
 363                                 case "name":
 364                                 {
 365                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 366                                         if (!argument)   break;  // escape to usage
 367                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 368                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 369                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 370
 371                                         string mon_oldname = mon.monster_name;
 372
 373                                         mon.monster_name = argument;
 374                                         if (mon.sprite)   WaypointSprite_UpdateSprites(mon.sprite, WP_Monster, WP_Null, WP_Null);
 375                                         print_to(caller, sprintf("Your pet '%s' is now known as '%s'", mon_oldname, mon.monster_name));
 376                                         return;
 377                                 }
 378                                 case "spawn":
 379                                 {
 380                                         if (!caller) { print_to(caller, "Only players can spawn monsters"); return; }
 381                                         if (!argv(2))   break;  // escape to usage
 382
 383                                         int moveflag, tmp_moncount = 0;
 384                                         string arg_lower = strtolower(argument);
 385                                         moveflag = (argv(3)) ? stof(argv(3)) : 1;  // follow owner if not defined
 386
 387                                         if (arg_lower == "list") { print_to(caller, monsterlist_reply); return; }
 388
 389                                         IL_EACH(g_monsters, it.realowner == caller,
 390                                         {
 391                                                 ++tmp_moncount;
 392                                         });
 393
 394                                         if (!autocvar_g_monsters) { print_to(caller, "Monsters are disabled"); return; }
 395                                         if (autocvar_g_monsters_max <= 0 || autocvar_g_monsters_max_perplayer <= 0) { print_to(caller, "Monster spawning is disabled"); return; }
 396                                         if (!IS_PLAYER(caller)) { print_to(caller, "You must be playing to spawn a monster"); return; }
 397                                         if (MUTATOR_CALLHOOK(AllowMobSpawning, caller)) { print_to(caller, M_ARGV(1, string)); return; }
 398                                         if (caller.vehicle) { print_to(caller, "You can't spawn monsters while driving a vehicle"); return; }
 399                                         if (STAT(FROZEN, caller)) { print_to(caller, "You can't spawn monsters while frozen"); return; }
 400                                         if (IS_DEAD(caller)) { print_to(caller, "You can't spawn monsters while dead"); return; }
 401                                         if (tmp_moncount >= autocvar_g_monsters_max) { print_to(caller, "The maximum monster count has been reached"); return; }
 402                                         if (tmp_moncount >= autocvar_g_monsters_max_perplayer) { print_to(caller, "You can't spawn any more monsters"); return; }
 403
 404                                         bool found = false;
 405                                         FOREACH(Monsters, it != MON_Null && it.netname == arg_lower,
 406                                         {
 407                                                 found = true;
 408                                                 break;
 409                                         });
 410
 411                                         if (!found && arg_lower != "random" && arg_lower != "anyrandom") { print_to(caller, "Invalid monster"); return; }
 412
 413                                         totalspawned += 1;
 414                                         WarpZone_TraceBox(CENTER_OR_VIEWOFS(caller), caller.mins, caller.maxs, CENTER_OR_VIEWOFS(caller) + v_forward * 150, true, caller);
 415                                         mon = spawnmonster(spawn(), arg_lower, MON_Null, caller, caller, trace_endpos, false, false, moveflag);
 416                                         print_to(caller, strcat("Spawned ", mon.monster_name));
 417                                         return;
 418                                 }
 419                                 case "kill":
 420                                 {
 421                                         if (!caller) { print_to(caller, "Only players can kill monsters"); return; }
 422                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 423                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 424
 425                                         Damage(mon, NULL, NULL, GetResource(mon, RES_HEALTH) + mon.max_health + 200, DEATH_KILL.m_id, DMG_NOWEP, mon.origin, '0 0 0');
 426                                         print_to(caller, strcat("Your pet '", mon.monster_name, "' has been brutally mutilated"));
 427                                         return;
 428                                 }
 429                                 case "skin":
 430                                 {
 431                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 432                                         if (!argument)   break;  // escape to usage
 433                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 434                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 435                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 436                                         if (mon.monsterdef == MON_MAGE) { print_to(caller, "Mage skins can't be changed"); return; }  // TODO
 437
 438                                         mon.skin = stof(argument);
 439                                         print_to(caller, strcat("Monster skin successfully changed to ", ftos(mon.skin)));
 440                                         return;
 441                                 }
 442                                 case "movetarget":
 443                                 {
 444                                         if (!caller) { print_to(caller, "Only players can edit monsters"); return; }
 445                                         if (!argument)   break;  // escape to usage
 446                                         if (!autocvar_g_monsters_edit) { print_to(caller, "Monster editing is disabled"); return; }
 447                                         if (!is_visible) { print_to(caller, "You must look at your monster to edit it"); return; }
 448                                         if (mon.realowner != caller && autocvar_g_monsters_edit < 2) { print_to(caller, "This monster does not belong to you"); return; }
 449
 450                                         mon.monster_moveflags = stof(argument);
 451                                         print_to(caller, strcat("Monster move target successfully changed to ", ftos(mon.monster_moveflags)));
 452                                         return;
 453                                 }
 454                                 case "butcher":
 455                                 {
 456                                         if (caller) { print_to(caller, "This command is not available to players"); return; }
 457                                         if (MUTATOR_CALLHOOK(AllowMobButcher)) { LOG_INFO(M_ARGV(0, string)); return; }
 458
 459                                         int tmp_remcount = 0;
 460
 461                                         IL_EACH(g_monsters, true,
 462                                         {
 463                                                 Monster_Remove(it);
 464                                                 ++tmp_remcount;
 465                                         });
 466                                         IL_CLEAR(g_monsters);
 467
 468                                         monsters_total = monsters_killed = totalspawned = 0;
 469
 470                                         print_to(caller, (tmp_remcount) ? sprintf("Killed %d monster%s", tmp_remcount, (tmp_remcount == 1) ? "" : "s") : "No monsters to kill");
 471                                         return;
 472                                 }
 473                         }
 474                 }
 475
 476                 default:
 477                 case CMD_REQUEST_USAGE:
 478                 {
 479                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " editmob <command> [<arguments>]"));
 480                         print_to(caller, "  Where <command> can be butcher spawn skin movetarget kill name");
 481                         print_to(caller, "  spawn, skin, movetarget and name require <arguments>");
 482                         print_to(caller, "  spawn also takes arguments list and random");
 483                         print_to(caller, "  Monster will follow owner if third argument of spawn command is not defined");
 484                         return;
 485                 }
 486         }
 487 }
 488
 489 void CommonCommand_info(int request, entity caller, int argc)
 490 {
 491         switch (request)
 492         {
 493                 case CMD_REQUEST_COMMAND:
 494                 {
 495                         string command = cvar_string(strcat("sv_info_", argv(1)));
 496
 497                         if (command) wordwrap_sprint(caller, command, 1000);
 498                         else print_to(caller, "ERROR: unsupported info command");
 499
 500                         return;  // never fall through to usage
 501                 }
 502
 503                 default:
 504                 case CMD_REQUEST_USAGE:
 505                 {
 506                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " info <request>"));
 507                         print_to(caller, "  Where <request> is the suffixed string appended onto the request for cvar.");
 508                         return;
 509                 }
 510         }
 511 }
 512
 513 void CommonCommand_ladder(int request, entity caller)
 514 {
 515         switch (request)
 516         {
 517                 case CMD_REQUEST_COMMAND:
 518                 {
 519                         print_to(caller, ladder_reply);
 520                         return;  // never fall through to usage
 521                 }
 522
 523                 default:
 524                 case CMD_REQUEST_USAGE:
 525                 {
 526                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " ladder"));
 527                         print_to(caller, "  No arguments required.");
 528                         return;
 529                 }
 530         }
 531 }
 532
 533 void CommonCommand_lsmaps(int request, entity caller)
 534 {
 535         switch (request)
 536         {
 537                 case CMD_REQUEST_COMMAND:
 538                 {
 539                         print_to(caller, lsmaps_reply);
 540                         return;  // never fall through to usage
 541                 }
 542
 543                 default:
 544                 case CMD_REQUEST_USAGE:
 545                 {
 546                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " lsmaps"));
 547                         print_to(caller, "  No arguments required.");
 548                         return;
 549                 }
 550         }
 551 }
 552
 553 void CommonCommand_printmaplist(int request, entity caller)
 554 {
 555         switch (request)
 556         {
 557                 case CMD_REQUEST_COMMAND:
 558                 {
 559                         print_to(caller, maplist_reply);
 560                         return;  // never fall through to usage
 561                 }
 562
 563                 default:
 564                 case CMD_REQUEST_USAGE:
 565                 {
 566                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " printmaplist"));
 567                         print_to(caller, "  No arguments required.");
 568                         return;
 569                 }
 570         }
 571 }
 572
 573 void CommonCommand_rankings(int request, entity caller)
 574 {
 575         switch (request)
 576         {
 577                 case CMD_REQUEST_COMMAND:
 578                 {
 579                         print_to(caller, rankings_reply);
 580                         return;  // never fall through to usage
 581                 }
 582
 583                 default:
 584                 case CMD_REQUEST_USAGE:
 585                 {
 586                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " rankings"));
 587                         print_to(caller, "  No arguments required.");
 588                         return;
 589                 }
 590         }
 591 }
 592
 593 void CommonCommand_records(int request, entity caller)
 594 {
 595         switch (request)
 596         {
 597                 case CMD_REQUEST_COMMAND:
 598                 {
 599                         int num = stoi(argv(1));
 600                         if(num > 0 && num <= 10 && records_reply[num - 1] != "")
 601                                 print_to(caller, records_reply[num - 1]);
 602                         else
 603                         {
 604                                 for (int i = 0; i < 10; ++i)
 605                                         if (records_reply[i] != "") print_to(caller, records_reply[i]);
 606                         }
 607
 608                         return;  // never fall through to usage
 609                 }
 610
 611                 default:
 612                 case CMD_REQUEST_USAGE:
 613                 {
 614                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " records [<pagenum>]"));
 615                         print_to(caller, "  Without arguments it prints all records (all pages) for the current gametype,");
 616                         print_to(caller, "  otherwise if there are multiple pages it only prints page <pagenum> (1..10),");
 617                         return;
 618                 }
 619         }
 620 }
 621
 622 void CommonCommand_teamstatus(int request, entity caller)
 623 {
 624         switch (request)
 625         {
 626                 case CMD_REQUEST_COMMAND:
 627                 {
 628                         Score_NicePrint(caller);
 629                         return;  // never fall through to usage
 630                 }
 631
 632                 default:
 633                 case CMD_REQUEST_USAGE:
 634                 {
 635                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " teamstatus"));
 636                         print_to(caller, "  No arguments required.");
 637                         return;
 638                 }
 639         }
 640 }
 641
 642 void CommonCommand_time(int request, entity caller)
 643 {
 644         switch (request)
 645         {
 646                 case CMD_REQUEST_COMMAND:
 647                 {
 648                         print_to(caller, strcat("time = ", ftos(time)));
 649                         print_to(caller, strcat("frame start = ", ftos(gettime(GETTIME_FRAMESTART))));
 650                         print_to(caller, strcat("realtime = ", ftos(gettime(GETTIME_REALTIME))));
 651                         print_to(caller, strcat("hires = ", ftos(gettime(GETTIME_HIRES))));
 652                         print_to(caller, strcat("uptime = ", ftos(gettime(GETTIME_UPTIME))));
 653                         print_to(caller, strcat("localtime = ", strftime(true, "%a %b %d %H:%M:%S %Z %Y")));
 654                         print_to(caller, strcat("gmtime = ", strftime(false, "%a %b %d %H:%M:%S %Z %Y")));
 655                         return;
 656                 }
 657
 658                 default:
 659                 case CMD_REQUEST_USAGE:
 660                 {
 661                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " time"));
 662                         print_to(caller, "  No arguments required.");
 663                         return;
 664                 }
 665         }
 666 }
 667
 668 void CommonCommand_timein(int request, entity caller)
 669 {
 670         switch (request)
 671         {
 672                 case CMD_REQUEST_COMMAND:
 673                 {
 674                         if (!caller || autocvar_sv_timeout)
 675                         {
 676                                 if (!timeout_status) { print_to(caller, "^7Error: There is no active timeout called."); }
 677                                 else if (caller && (caller != timeout_caller))
 678                                 {
 679                                         print_to(caller, "^7Error: You are not allowed to stop the active timeout.");
 680                                 }
 681
 682                                 else  // everything should be okay, continue aborting timeout
 683                                 {
 684                                         switch (timeout_status)
 685                                         {
 686                                                 case TIMEOUT_LEADTIME:
 687                                                 {
 688                                                         timeout_status = TIMEOUT_INACTIVE;
 689                                                         timeout_time = 0;
 690                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 691                                                         bprint(strcat("^7The timeout was aborted by ", GetCallerName(caller), " !\n"));
 692                                                         return;
 693                                                 }
 694
 695                                                 case TIMEOUT_ACTIVE:
 696                                                 {
 697                                                         timeout_time = autocvar_sv_timeout_resumetime;
 698                                                         timeout_handler.nextthink = time;  // timeout_handler has to take care of it immediately
 699                                                         bprint(strcat("\{1}^1Attention: ^7", GetCallerName(caller), " resumed the game! Prepare for battle!\n"));
 700                                                         return;
 701                                                 }
 702
 703                                                 default: LOG_TRACE("timeout status was inactive, but this code was executed anyway?");
 704                                                         return;
 705                                         }
 706                                 }
 707                         }
 708                         else { print_to(caller, "^1Timeins are not allowed to be called, enable them with sv_timeout 1.\n"); }
 709
 710                         return;  // never fall through to usage
 711                 }
 712
 713                 default:
 714                 case CMD_REQUEST_USAGE:
 715                 {
 716                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timein"));
 717                         print_to(caller, "  No arguments required.");
 718                         return;
 719                 }
 720         }
 721 }
 722
 723 void CommonCommand_timeout(int request, entity caller)  // DEAR GOD THIS COMMAND IS TERRIBLE.
 724 {
 725         switch (request)
 726         {
 727                 case CMD_REQUEST_COMMAND:
 728                 {
 729                         if (!caller || autocvar_sv_timeout)
 730                         {
 731                                 float last_possible_timeout = ((autocvar_timelimit * 60) - autocvar_sv_timeout_leadtime - 1);
 732
 733                                 if (timeout_status) { print_to(caller, "^7Error: A timeout is already active."); }
 734                                 else if (vote_called)
 735                                 {
 736                                         print_to(caller, "^7Error: You can not call a timeout while a vote is active.");
 737                                 }
 738                                 else if (warmup_stage && !autocvar_g_warmup_allow_timeout)
 739                                 {
 740                                         print_to(caller, "^7Error: You can not call a timeout in warmup-stage.");
 741                                 }
 742                                 else if (time < game_starttime)
 743                                 {
 744                                         print_to(caller, "^7Error: You can not call a timeout while the map is being restarted.");
 745                                 }
 746                                 else if (caller && (CS(caller).allowed_timeouts < 1))
 747                                 {
 748                                         print_to(caller, "^7Error: You already used all your timeout calls for this map.");
 749                                 }
 750                                 else if (caller && !IS_PLAYER(caller))
 751                                 {
 752                                         print_to(caller, "^7Error: You must be a player to call a timeout.");
 753                                 }
 754                                 else if ((autocvar_timelimit) && (last_possible_timeout < time - game_starttime))
 755                                 {
 756                                         print_to(caller, "^7Error: It is too late to call a timeout now!");
 757                                 }
 758
 759                                 else  // everything should be okay, proceed with starting the timeout
 760                                 {
 761                                         if (caller)   CS(caller).allowed_timeouts -= 1;
 762                                         // write a bprint who started the timeout (and how many they have left)
 763                                         bprint("\{1}", GetCallerName(caller), " ^7called a timeout", (caller ? strcat(" (", ftos(CS(caller).allowed_timeouts), " timeout(s) left)") : ""), "!\n");
 764
 765                                         timeout_status = TIMEOUT_LEADTIME;
 766                                         timeout_caller = caller;
 767                                         timeout_time = autocvar_sv_timeout_length;
 768                                         timeout_leadtime = autocvar_sv_timeout_leadtime;
 769
 770                                         timeout_handler = new(timeout_handler);
 771                                         setthink(timeout_handler, timeout_handler_think);
 772                                         timeout_handler.nextthink = time;  // always let the entity think asap
 773
 774                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_TIMEOUT);
 775                                 }
 776                         }
 777                         else { print_to(caller, "^1Timeouts are not allowed to be called, enable them with sv_timeout 1.\n"); }
 778
 779                         return;  // never fall through to usage
 780                 }
 781
 782                 default:
 783                 case CMD_REQUEST_USAGE:
 784                 {
 785                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " timeout"));
 786                         print_to(caller, "  No arguments required.");
 787                         return;
 788                 }
 789         }
 790 }
 791
 792 void CommonCommand_who(int request, entity caller, int argc)
 793 {
 794         switch (request)
 795         {
 796                 case CMD_REQUEST_COMMAND:
 797                 {
 798                         float total_listed_players, is_bot;
 799
 800                         float privacy = (caller && autocvar_sv_status_privacy);
 801                         string separator = strreplace("%", " ", strcat((argv(1) ? argv(1) : " "), "^7"));
 802                         string tmp_netaddress, tmp_crypto_idfp;
 803
 804                         print_to(caller, strcat("List of client information", (privacy ? " (some data is hidden for privacy)" : ""), ":"));
 805                         print_to(caller, sprintf(strreplace(" ", separator, " %-4s %-20s %-5s %-3s %-9s %-16s %s "),
 806                                 "ent", "nickname", "ping", "pl", "time", "ip", "crypto_id"));
 807
 808                         total_listed_players = 0;
 809                         FOREACH_CLIENT(true, {
 810                                 is_bot = (IS_BOT_CLIENT(it));
 811
 812                                 if (is_bot)
 813                                 {
 814                                         tmp_netaddress = "null/botclient";
 815                                         tmp_crypto_idfp = "null/botclient";
 816                                 }
 817                                 else if (privacy)
 818                                 {
 819                                         tmp_netaddress = "hidden";
 820                                         tmp_crypto_idfp = "hidden";
 821                                 }
 822                                 else
 823                                 {
 824                                         tmp_netaddress = it.netaddress;
 825                                         tmp_crypto_idfp = it.crypto_idfp;
 826                                 }
 827
 828                                 print_to(caller, sprintf(strreplace(" ", separator, " #%-3d %-20.20s %-5d %-3d %-9s %-16s %s "),
 829                                         etof(it),
 830                                         it.netname,
 831                                         CS(it).ping,
 832                                         CS(it).ping_packetloss,
 833                                         process_time(1, time - CS(it).jointime),
 834                                         tmp_netaddress,
 835                                         tmp_crypto_idfp));
 836
 837                                 ++total_listed_players;
 838                         });
 839
 840                         print_to(caller, strcat("Finished listing ", ftos(total_listed_players), " client(s) out of ", ftos(maxclients), " slots."));
 841
 842                         return;  // never fall through to usage
 843                 }
 844
 845                 default:
 846                 case CMD_REQUEST_USAGE:
 847                 {
 848                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " who [<separator>]"));
 849                         print_to(caller, "  Where <separator> is the optional string to separate the values with, default is a space.");
 850                         return;
 851                 }
 852         }
 853 }
 854
 855 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 856 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 857 void CommonCommand_(int request, entity caller)
 858 {
 859     switch(request)
 860     {
 861         case CMD_REQUEST_COMMAND:
 862         {
 863
 864             return; // never fall through to usage
 865         }
 866
 867         default:
 868         case CMD_REQUEST_USAGE:
 869         {
 870             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " "));
 871             print_to(caller, "  No arguments required.");
 872             return;
 873         }
 874     }
 875 }
 876 */