qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/all.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteByte(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if (readycount)
  44         {
  45                 nags |= BIT(0);
  46                 if (to.ready == 0) nags |= BIT(1);
  47         }
  48         if (vote_called)
  49         {
  50                 nags |= BIT(2);
  51                 if (to.vote_selection == 0) nags |= BIT(3);
  52         }
  53         if (warmup_stage) nags |= BIT(4);
  54
  55         if (sendflags & BIT(6)) nags |= BIT(6);
  56
  57         if (sendflags & BIT(7)) nags |= BIT(7);
  58
  59         if (!(nags & 4))  // no vote called? send no string
  60                 nags &= ~(BIT(6) | BIT(7));
  61
  62         WriteByte(MSG_ENTITY, nags);
  63
  64         if (nags & BIT(6))
  65         {
  66                 WriteByte(MSG_ENTITY, vote_accept_count);
  67                 WriteByte(MSG_ENTITY, vote_reject_count);
  68                 WriteByte(MSG_ENTITY, vote_needed_overall);
  69                 WriteChar(MSG_ENTITY, to.vote_selection);
  70         }
  71
  72         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  73
  74         if (nags & 1)
  75         {
  76                 for (i = 1; i <= maxclients; i += 8)
  77                 {
  78                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  79                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  80                         WriteByte(MSG_ENTITY, f);
  81                 }
  82         }
  83
  84         return true;
  85 }
  86
  87 void Nagger_Init()
  88 {
  89         Net_LinkEntity(nagger = spawn(), false, 0, Nagger_SendEntity);
  90 }
  91
  92 void Nagger_VoteChanged()
  93 {
  94         if (nagger) nagger.SendFlags |= BIT(7);
  95 }
  96
  97 void Nagger_VoteCountChanged()
  98 {
  99         if (nagger) nagger.SendFlags |= BIT(6);
 100 }
 101
 102 void Nagger_ReadyCounted()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(0);
 105 }
 106
 107 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 108 string OriginalCallerName()
 109 {
 110         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 111         return vote_caller_name;
 112 }
 113
 114 // =======================
 115 //  Game logic for voting
 116 // =======================
 117
 118 void VoteReset()
 119 {
 120         entity tmp_player;
 121
 122         FOR_EACH_CLIENT(tmp_player)
 123         {
 124                 tmp_player.vote_selection = 0;
 125         }
 126
 127         if (vote_called)
 128         {
 129                 strunzone(vote_called_command);
 130                 strunzone(vote_called_display);
 131                 strunzone(vote_caller_name);
 132         }
 133
 134         vote_called = VOTE_NULL;
 135         vote_caller = world;
 136         vote_caller_name = string_null;
 137         vote_endtime = 0;
 138
 139         vote_called_command = string_null;
 140         vote_called_display = string_null;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 void VoteCount(float first_count)
 205 {
 206         // declarations
 207         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 208
 209         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 210             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 211             || (autocvar_sv_vote_nospectators == 0));
 212
 213         float vote_player_count = 0, notvoters = 0;
 214         float vote_real_player_count = 0, vote_real_accept_count = 0;
 215         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 216         float vote_needed_of_voted, final_needed_votes;
 217         float vote_factor_overall, vote_factor_of_voted;
 218
 219         entity tmp_player;
 220
 221         Nagger_VoteCountChanged();
 222
 223         // add up all the votes from each connected client
 224         FOR_EACH_REALCLIENT(tmp_player)
 225         {
 226                 ++vote_player_count;
 227                 if (IS_PLAYER(tmp_player))   ++vote_real_player_count;
 228                 switch (tmp_player.vote_selection)
 229                 {
 230                         case VOTE_SELECT_REJECT:
 231                         { ++vote_reject_count;
 232                           { if (IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break;
 233                         }
 234                         case VOTE_SELECT_ACCEPT:
 235                         { ++vote_accept_count;
 236                           { if (IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break;
 237                         }
 238                         case VOTE_SELECT_ABSTAIN:
 239                         { ++vote_abstain_count;
 240                           { if (IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break;
 241                         }
 242                         default: break;
 243                 }
 244         }
 245
 246         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 247         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 248         {
 249                 if (vote_caller)   vote_caller.vote_waittime = 0;
 250                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 251                 VoteReset();
 252                 return;
 253         }
 254
 255         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 256         if (!spectators_allowed && (vote_real_player_count > 0))
 257         {
 258                 vote_accept_count = vote_real_accept_count;
 259                 vote_reject_count = vote_real_reject_count;
 260                 vote_abstain_count = vote_real_abstain_count;
 261                 vote_player_count = vote_real_player_count;
 262         }
 263
 264         // people who have no opinion in any way :D
 265         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 266
 267         // determine the goal for the vote to be passed or rejected normally
 268         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 269         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 270
 271         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 272         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 273         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 274
 275         // are there any players at all on the server? it could be an admin vote
 276         if (vote_player_count == 0 && first_count)
 277         {
 278                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 279                 VoteAccept();
 280                 return;
 281         }
 282
 283         // since there ARE players, finally calculate the result of the vote
 284         if (vote_accept_count >= vote_needed_overall)
 285         {
 286                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 287                 VoteAccept();
 288                 return;
 289         }
 290
 291         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 292         {
 293                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 294                 VoteReject();
 295                 return;
 296         }
 297
 298         // there is not enough votes in either direction, now lets just calculate what the voters have said
 299         if (time > vote_endtime)
 300         {
 301                 final_needed_votes = vote_needed_overall;
 302
 303                 if (autocvar_sv_vote_majority_factor_of_voted)
 304                 {
 305                         if (vote_accept_count >= vote_needed_of_voted)
 306                         {
 307                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 308                                 VoteAccept();
 309                                 return;
 310                         }
 311
 312                         if (vote_accept_count + vote_reject_count > 0)
 313                         {
 314                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 315                                 VoteReject();
 316                                 return;
 317                         }
 318
 319                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 320                 }
 321
 322                 // it didn't pass or fail, so not enough votes to even make a decision.
 323                 VoteSpam(notvoters, final_needed_votes, "timeout");
 324                 VoteTimeout();
 325         }
 326 }
 327
 328 void VoteThink()
 329 {
 330         if (vote_endtime > 0)        // a vote was called
 331         {
 332                 if (time > vote_endtime) // time is up
 333                         VoteCount(false);
 334         }
 335 }
 336
 337
 338 // =======================
 339 //  Game logic for warmup
 340 // =======================
 341
 342 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 343 void reset_map(float dorespawn)
 344 {
 345         SELFPARAM();
 346
 347         if (time <= game_starttime && round_handler_IsActive()) round_handler_Reset(game_starttime);
 348
 349         MUTATOR_CALLHOOK(reset_map_global);
 350
 351         for (entity e = world; (e = nextent(e)); )
 352         {
 353                 setself(e);
 354                 if (IS_NOT_A_CLIENT(self))
 355                 {
 356                         if (self.reset)
 357                         {
 358                                 self.reset();
 359                                 continue;
 360                         }
 361
 362                         if (self.team_saved) self.team = self.team_saved;
 363
 364                         if (self.flags & FL_PROJECTILE)  // remove any projectiles left
 365                                 remove(self);
 366                 }
 367         }
 368
 369         // Waypoints and assault start come LAST
 370         for (entity e = world; (e = nextent(e)); )
 371         {
 372                 setself(e);
 373                 if (IS_NOT_A_CLIENT(self))
 374                 {
 375                         if (self.reset2)
 376                         {
 377                                 self.reset2();
 378                                 continue;
 379                         }
 380                 }
 381         }
 382
 383         entity e;
 384         FOR_EACH_PLAYER(e)
 385         if (e.frozen) WITH(entity, self, e, Unfreeze(self));
 386
 387         // Moving the player reset code here since the player-reset depends
 388         // on spawnpoint entities which have to be reset first --blub
 389         if (dorespawn)
 390         {
 391                 if (!MUTATOR_CALLHOOK(reset_map_players))
 392                 {
 393                         FOR_EACH_CLIENT(e)  // reset all players
 394                         {
 395                                 setself(e);
 396                                 /*
 397                                 only reset players if a restart countdown is active
 398                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 399                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 400                                 sv_ready_restart_after_countdown is not used and countdown is still running
 401                                 */
 402                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 403                                 {
 404                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 405                                         if (IS_PLAYER(self))
 406                                         {
 407                                                 // PlayerScore_Clear(self);
 408                                                 self.killcount = 0;
 409                                                 // stop the player from moving so that he stands still once he gets respawned
 410                                                 self.velocity = '0 0 0';
 411                                                 self.avelocity = '0 0 0';
 412                                                 self.movement = '0 0 0';
 413                                                 PutClientInServer();
 414                                         }
 415                                 }
 416                         }
 417
 418                         setself(this);
 419                 }
 420         }
 421 }
 422
 423 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 424 void ReadyRestart_think()
 425 {
 426         SELFPARAM();
 427         restart_mapalreadyrestarted = 1;
 428         reset_map(true);
 429         Score_ClearAll();
 430         remove(self);
 431 }
 432
 433 // Forces a restart of the game without actually reloading the map // this is a mess...
 434 void ReadyRestart_force()
 435 {
 436         entity tmp_player, restart_timer;
 437
 438         bprint("^1Server is restarting...\n");
 439
 440         VoteReset();
 441
 442         // clear overtime, we have to decrease timelimit to its original value again.
 443         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)   cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 444         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 445
 446         readyrestart_happened = 1;
 447         game_starttime = time + RESTART_COUNTDOWN;
 448
 449         // clear player attributes
 450         FOR_EACH_CLIENT(tmp_player)
 451         {
 452                 tmp_player.alivetime = 0;
 453                 tmp_player.killcount = 0;
 454                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 455         }
 456
 457         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 458
 459         // disable the warmup global for the server
 460         warmup_stage = 0;                // once the game is restarted the game is in match stage
 461
 462         // reset the .ready status of all players (also spectators)
 463         FOR_EACH_REALCLIENT(tmp_player)
 464         {
 465                 tmp_player.ready = 0;
 466         }
 467         readycount = 0;
 468         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 469
 470         // lock teams with lockonrestart
 471         if (autocvar_teamplay_lockonrestart && teamplay)
 472         {
 473                 lockteams = 1;
 474                 bprint("^1The teams are now locked.\n");
 475         }
 476
 477         // initiate the restart-countdown-announcer entity
 478         if (autocvar_sv_ready_restart_after_countdown)
 479         {
 480                 restart_timer = spawn();
 481                 restart_timer.think = ReadyRestart_think;
 482                 restart_timer.nextthink = game_starttime;
 483         }
 484
 485         // after a restart every players number of allowed timeouts gets reset, too
 486         if (autocvar_sv_timeout)
 487         {
 488                 FOR_EACH_REALPLAYER(tmp_player)
 489                 {
 490                         tmp_player.allowed_timeouts = autocvar_sv_timeout_number;
 491                 }
 492                 // reset map immediately if this cvar is not set
 493                 if (!autocvar_sv_ready_restart_after_countdown)   reset_map(true); }
 494         if (autocvar_sv_eventlog)   GameLogEcho(":restart"); }
 495
 496 void ReadyRestart()
 497 {
 498         // no assault support yet...
 499         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 500         else localcmd("\nsv_hook_gamerestart\n");
 501
 502         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 503         // Otherwise scores could be manipulated during the countdown.
 504         if (!autocvar_sv_ready_restart_after_countdown)   Score_ClearAll();
 505         ReadyRestart_force();
 506 }
 507
 508 // Count the players who are ready and determine whether or not to restart the match
 509 void ReadyCount()
 510 {
 511         entity tmp_player;
 512         float ready_needed_factor, ready_needed_count;
 513         float t_ready = 0, t_players = 0;
 514
 515         FOR_EACH_REALCLIENT(tmp_player)
 516         {
 517                 if (IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 518                 {
 519                         ++t_players;
 520                         if (tmp_player.ready)   ++t_ready; }
 521         }
 522
 523         readycount = t_ready;
 524
 525         Nagger_ReadyCounted();
 526
 527         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 528         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 529
 530         if (readycount >= ready_needed_count) ReadyRestart();
 531 }
 532
 533
 534 // ======================================
 535 //  Supporting functions for VoteCommand
 536 // ======================================
 537
 538 float Votecommand_check_assignment(entity caller, float assignment)
 539 {
 540         float from_server = (!caller);
 541
 542         if ((assignment == VC_ASGNMNT_BOTH)
 543             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 544             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 545
 546         return false;
 547 }
 548
 549 string VoteCommand_extractcommand(string input, float startpos, float argc)
 550 {
 551         string output;
 552
 553         if ((argc - 1) < startpos) output = "";
 554         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 555
 556         return output;
 557 }
 558
 559 float VoteCommand_checknasty(string vote_command)
 560 {
 561         if ((strstrofs(vote_command, ";", 0) >= 0)
 562             || (strstrofs(vote_command, "\n", 0) >= 0)
 563             || (strstrofs(vote_command, "\r", 0) >= 0)
 564             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 565
 566         return true;
 567 }
 568
 569 float VoteCommand_checkinlist(string vote_command, string list)
 570 {
 571         string l = strcat(" ", list, " ");
 572
 573         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 574
 575         return false;
 576 }
 577
 578 string ValidateMap(string validated_map, entity caller)
 579 {
 580         validated_map = MapInfo_FixName(validated_map);
 581
 582         if (!validated_map)
 583         {
 584                 print_to(caller, "This map is not available on this server.");
 585                 return string_null;
 586         }
 587
 588         if (!autocvar_sv_vote_override_mostrecent && caller)
 589         {
 590                 if (Map_IsRecent(validated_map))
 591                 {
 592                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 593                         return string_null;
 594                 }
 595         }
 596
 597         if (!MapInfo_CheckMap(validated_map))
 598         {
 599                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 600                 return string_null;
 601         }
 602
 603         return validated_map;
 604 }
 605
 606 float VoteCommand_checkargs(float startpos, float argc)
 607 {
 608         float p, q, check, minargs;
 609         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 610         string cmdrestriction = cvar_string(cvarname);  // note: this warns on undefined cvar. We want that.
 611         string charlist, arg;
 612         float checkmate;
 613
 614         if (cmdrestriction == "") return true;
 615
 616         ++startpos;  // skip command name
 617
 618         // check minimum arg count
 619
 620         // 0 args: argc == startpos
 621         // 1 args: argc == startpos + 1
 622         // ...
 623
 624         minargs = stof(cmdrestriction);
 625         if (argc - startpos < minargs) return false;
 626
 627         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 628
 629         for ( ; ; )
 630         {
 631                 // we know that at any time, startpos <= argc - minargs
 632                 // so this means: argc-minargs >= startpos >= argc, thus
 633                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 634                 // have been seen already
 635
 636                 if (startpos >= argc) // all args checked? GOOD
 637                         break;
 638
 639                 if (p < 0)            // no more args? FAIL
 640                 {
 641                         // exception: exactly minargs left, this one included
 642                         if (argc - startpos == minargs) break;
 643
 644                         // otherwise fail
 645                         return false;
 646                 }
 647
 648                 // cut to next semicolon
 649                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 650                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 651                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 652
 653                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 654                 // charlist = strreplace("^^", ";", charlist);
 655
 656                 if (charlist != "")
 657                 {
 658                         // verify the arg only contains allowed chars
 659                         arg = argv(startpos);
 660                         checkmate = strlen(arg);
 661                         for (check = 0; check < checkmate; ++check)
 662                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 663                         // not allowed character
 664                         // all characters are allowed. FINE.
 665                 }
 666
 667                 ++startpos;
 668                 --minargs;
 669                 p = q;
 670         }
 671
 672         return true;
 673 }
 674
 675 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 676 {
 677         string first_command;
 678
 679         first_command = argv(startpos);
 680
 681         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 682             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 683             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 684         );*/
 685
 686         if (
 687             (autocvar_sv_vote_limit > 0)
 688             &&
 689             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 690            )   return false;
 691
 692         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 693
 694         if (!VoteCommand_checkargs(startpos, argc)) return false;
 695
 696         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 697         {
 698                 case "kick":
 699                 case "kickban":    // catch all kick/kickban commands
 700                 {
 701                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 702                         float accepted = VerifyClientEntity(victim, true, false);
 703
 704                         if (accepted > 0)
 705                         {
 706                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 707                                 string command_arguments;
 708
 709                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 710                                 else command_arguments = reason;
 711
 712                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 713                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 714                         }
 715                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 716
 717                         break;
 718                 }
 719
 720                 case "map":
 721                 case "chmap":
 722                 case "gotomap":  // re-direct all map selection commands to gotomap
 723                 {
 724                         vote_command = ValidateMap(argv(startpos + 1), caller);
 725                         if (!vote_command)   return false;
 726                         vote_parsed_command = strcat("gotomap ", vote_command);
 727                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 728
 729                         break;
 730                 }
 731
 732                 default:
 733                 {
 734                         vote_parsed_command = vote_command;
 735                         vote_parsed_display = strzone(strcat("^1", vote_command));
 736
 737                         break;
 738                 }
 739         }
 740
 741         return true;
 742 }
 743
 744
 745 // =======================
 746 //  Command Sub-Functions
 747 // =======================
 748
 749 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 750 {
 751         switch (request)
 752         {
 753                 case CMD_REQUEST_COMMAND:
 754                 {
 755                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 756                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 757                         {
 758                                 print_to(caller, "^1You have already voted.");
 759                         }
 760
 761                         else  // everything went okay, continue changing vote
 762                         {
 763                                 print_to(caller, "^1You abstained from your vote.");
 764                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 765                                 msg_entity = caller;
 766                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 767
 768                         return;
 769                 }
 770
 771                 default:
 772                 case CMD_REQUEST_USAGE:
 773                 {
 774                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 775                         print_to(caller, "  No arguments required.");
 776                         return;
 777                 }
 778         }
 779 }
 780
 781 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 782 {
 783         switch (request)
 784         {
 785                 case CMD_REQUEST_COMMAND:
 786                 {
 787                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 788                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 789                             || (autocvar_sv_vote_nospectators == 0));
 790
 791                         float tmp_playercount = 0;
 792                         entity tmp_player;
 793
 794                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 795
 796                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 797                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 798                         {
 799                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 800                         }
 801                         else if (vote_called)
 802                         {
 803                                 print_to(caller, "^1There is already a vote called.");
 804                         }
 805                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 806                         {
 807                                 print_to(caller, "^1Only players can call a vote.");
 808                         }
 809                         else if (caller && !IS_CLIENT(caller))
 810                         {
 811                                 print_to(caller, "^1Only connected clients can vote.");
 812                         }
 813                         else if (timeout_status)
 814                         {
 815                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 816                         }
 817                         else if (caller && (time < caller.vote_waittime))
 818                         {
 819                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 820                         }
 821                         else if (!VoteCommand_checknasty(vote_command))
 822                         {
 823                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 824                         }
 825                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 826                         {
 827                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 828                         }
 829
 830                         else  // everything went okay, continue with calling the vote
 831                         {
 832                                 vote_caller = caller;  // remember who called the vote
 833                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 834                                 vote_called = VOTE_NORMAL;
 835                                 vote_called_command = strzone(vote_parsed_command);
 836                                 vote_called_display = strzone(vote_parsed_display);
 837                                 vote_endtime = time + autocvar_sv_vote_timeout;
 838
 839                                 if (caller)
 840                                 {
 841                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 842                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 843                                         msg_entity = caller;
 844                                 }
 845
 846                                 FOR_EACH_REALCLIENT(tmp_player)
 847                                 {
 848                                         ++tmp_playercount;
 849                                 }
 850                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 851
 852                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 853                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 854                                 Nagger_VoteChanged();
 855                                 VoteCount(true);  // needed if you are the only one
 856                         }
 857
 858                         return;
 859                 }
 860
 861                 default:
 862                 case CMD_REQUEST_USAGE:
 863                 {
 864                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 865                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 866                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 867                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 868                         return;
 869                 }
 870         }
 871 }
 872
 873 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 874 {
 875         switch (request)
 876         {
 877                 case CMD_REQUEST_COMMAND:
 878                 {
 879                         if (autocvar_sv_vote_master)
 880                         {
 881                                 switch (strtolower(argv(2)))
 882                                 {
 883                                         case "do":
 884                                         {
 885                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 886
 887                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 888                                                 else if (!VoteCommand_checknasty(vote_command))
 889                                                 {
 890                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 891                                                 }
 892                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 893                                                 {
 894                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 895                                                 }
 896
 897                                                 else  // everything went okay, proceed with command
 898                                                 {
 899                                                         localcmd(strcat(vote_parsed_command, "\n"));
 900                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 901                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 902                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 903
 904                                                 return;
 905                                         }
 906
 907                                         case "login":
 908                                         {
 909                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 910                                                 else if (caller.vote_master)
 911                                                 {
 912                                                         print_to(caller, "^1You are already logged in as vote master.");
 913                                                 }
 914                                                 else if (autocvar_sv_vote_master_password != argv(3))
 915                                                 {
 916                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 917                                                 }
 918
 919                                                 else  // everything went okay, proceed with giving this player master privilages
 920                                                 {
 921                                                         caller.vote_master = true;
 922                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 923                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 924                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 925
 926                                                 return;
 927                                         }
 928
 929                                         default:  // calling a vote for master
 930                                         {
 931                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 932                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 933                                                     || (autocvar_sv_vote_nospectators == 0));
 934
 935                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 936                                                 else if (vote_called)
 937                                                 {
 938                                                         print_to(caller, "^1There is already a vote called.");
 939                                                 }
 940                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 941                                                 {
 942                                                         print_to(caller, "^1Only players can call a vote.");
 943                                                 }
 944                                                 else if (timeout_status)
 945                                                 {
 946                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 947                                                 }
 948
 949                                                 else  // everything went okay, continue with creating vote
 950                                                 {
 951                                                         vote_caller = caller;
 952                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 953                                                         vote_called = VOTE_MASTER;
 954                                                         vote_called_command = strzone("XXX");
 955                                                         vote_called_display = strzone("^3master");
 956                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 957
 958                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 959                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 960
 961                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 962                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 963                                                         Nagger_VoteChanged();
 964                                                         VoteCount(true);  // needed if you are the only one
 965                                                 }
 966
 967                                                 return;
 968                                         }
 969                                 }
 970                         }
 971                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 972
 973                         return;
 974                 }
 975
 976                 default:
 977                 case CMD_REQUEST_USAGE:
 978                 {
 979                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 980                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 981                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 982                         return;
 983                 }
 984         }
 985 }
 986
 987 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 988 {
 989         switch (request)
 990         {
 991                 case CMD_REQUEST_COMMAND:
 992                 {
 993                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 994                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 995                         {
 996                                 print_to(caller, "^1You have already voted.");
 997                         }
 998                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
 999                         {
1000                                 VoteStop(caller);
1001                         }
1002
1003                         else  // everything went okay, continue changing vote
1004                         {
1005                                 print_to(caller, "^1You rejected the vote.");
1006                                 caller.vote_selection = VOTE_SELECT_REJECT;
1007                                 msg_entity = caller;
1008                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1009
1010                         return;
1011                 }
1012
1013                 default:
1014                 case CMD_REQUEST_USAGE:
1015                 {
1016                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1017                         print_to(caller, "  No arguments required.");
1018                         return;
1019                 }
1020         }
1021 }
1022
1023 void VoteCommand_status(float request, entity caller)  // BOTH
1024 {
1025         switch (request)
1026         {
1027                 case CMD_REQUEST_COMMAND:
1028                 {
1029                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1030                         else print_to(caller, "^1No vote called.");
1031
1032                         return;
1033                 }
1034
1035                 default:
1036                 case CMD_REQUEST_USAGE:
1037                 {
1038                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1039                         print_to(caller, "  No arguments required.");
1040                         return;
1041                 }
1042         }
1043 }
1044
1045 void VoteCommand_stop(float request, entity caller)  // BOTH
1046 {
1047         switch (request)
1048         {
1049                 case CMD_REQUEST_COMMAND:
1050                 {
1051                         if (!vote_called)   print_to(caller, "^1No vote called.");
1052                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1053                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1054                         return;
1055                 }
1056
1057                 default:
1058                 case CMD_REQUEST_USAGE:
1059                 {
1060                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1061                         print_to(caller, "  No arguments required.");
1062                         return;
1063                 }
1064         }
1065 }
1066
1067 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1068 {
1069         switch (request)
1070         {
1071                 case CMD_REQUEST_COMMAND:
1072                 {
1073                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1074                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1075                         {
1076                                 print_to(caller, "^1You have already voted.");
1077                         }
1078
1079                         else  // everything went okay, continue changing vote
1080                         {
1081                                 print_to(caller, "^1You accepted the vote.");
1082                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1083                                 msg_entity = caller;
1084                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1085
1086                         return;
1087                 }
1088
1089                 default:
1090                 case CMD_REQUEST_USAGE:
1091                 {
1092                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1093                         print_to(caller, "  No arguments required.");
1094                         return;
1095                 }
1096         }
1097 }
1098
1099 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1100 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1101 void VoteCommand_(float request)
1102 {
1103     switch(request)
1104     {
1105         case CMD_REQUEST_COMMAND:
1106         {
1107
1108             return;
1109         }
1110
1111         default:
1112         case CMD_REQUEST_USAGE:
1113         {
1114             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1115             print_to(caller, "  No arguments required.");
1116             return;
1117         }
1118     }
1119 }
1120 */
1121
1122
1123 // ================================
1124 //  Macro system for vote commands
1125 // ================================
1126
1127 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1128 #define VOTE_COMMANDS(request, caller, arguments, command) \
1129         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1130         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1131         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1132         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1133         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1134         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1135         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1136         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1137         /* nothing */
1138
1139 void VoteCommand_macro_help(entity caller, float argc)
1140 {
1141         string command_origin = GetCommandPrefix(caller);
1142
1143         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1144         {
1145                 print_to(caller, "\nVoting commands:\n");
1146                 #define VOTE_COMMAND(name, function, description, assignment) \
1147                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1148
1149                 VOTE_COMMANDS(0, caller, 0, "");
1150 #undef VOTE_COMMAND
1151
1152                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1153                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1154                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1155         }
1156         else  // usage for individual command
1157         {
1158                 #define VOTE_COMMAND(name, function, description, assignment) \
1159                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1160
1161                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1162 #undef VOTE_COMMAND
1163         }
1164 }
1165
1166 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1167 {
1168         #define VOTE_COMMAND(name, function, description, assignment) \
1169                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1170
1171         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1172 #undef VOTE_COMMAND
1173
1174         return false;
1175 }
1176
1177
1178 // ======================================
1179 //  Main function handling vote commands
1180 // ======================================
1181
1182 void VoteCommand(float request, entity caller, float argc, string vote_command)
1183 {
1184         // Guide for working with argc arguments by example:
1185         // argc:   1    - 2      - 3     - 4
1186         // argv:   0    - 1      - 2     - 3
1187         // cmd     vote - master - login - password
1188
1189         switch (request)
1190         {
1191                 case CMD_REQUEST_COMMAND:
1192                 {
1193                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1194                 }
1195
1196                 default:
1197                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1198                 case CMD_REQUEST_USAGE:
1199                 {
1200                         VoteCommand_macro_help(caller, argc);
1201                         return;
1202                 }
1203         }
1204 }