qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/weapons/accuracy.qh>
  27 #include <server/world.qh>
  28
  29 // =============================================
  30 //  Server side voting code, reworked by Samual
  31 //  Last updated: December 27th, 2011
  32 // =============================================
  33
  34 //  Nagger for players to know status of voting
  35 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  36 {
  37         int nags, i, f, b;
  38         entity e;
  39         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  40
  41         // bits:
  42         //   1 = ready
  43         //   2 = player needs to ready up
  44         //   4 = vote
  45         //   8 = player needs to vote
  46         //  16 = warmup
  47         // sendflags:
  48         //  64 = vote counts
  49         // 128 = vote string
  50
  51         nags = 0;
  52         if (readycount)
  53         {
  54                 nags |= BIT(0);
  55                 if (to.ready == 0) nags |= BIT(1);
  56         }
  57         if (vote_called)
  58         {
  59                 nags |= BIT(2);
  60                 if (to.vote_selection == 0) nags |= BIT(3);
  61         }
  62         if (warmup_stage) nags |= BIT(4);
  63
  64         if (sendflags & BIT(6)) nags |= BIT(6);
  65
  66         if (sendflags & BIT(7)) nags |= BIT(7);
  67
  68         if (!(nags & 4))  // no vote called? send no string
  69                 nags &= ~(BIT(6) | BIT(7));
  70
  71         WriteByte(MSG_ENTITY, nags);
  72
  73         if (nags & BIT(6))
  74         {
  75                 WriteByte(MSG_ENTITY, vote_accept_count);
  76                 WriteByte(MSG_ENTITY, vote_reject_count);
  77                 WriteByte(MSG_ENTITY, vote_needed_overall);
  78                 WriteChar(MSG_ENTITY, to.vote_selection);
  79         }
  80
  81         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  82
  83         if (nags & 1)
  84         {
  85                 for (i = 1; i <= maxclients; i += 8)
  86                 {
  87                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  88                                 if (!IS_REAL_CLIENT(e) || e.ready)
  89                                         f |= b;
  90                         WriteByte(MSG_ENTITY, f);
  91                 }
  92         }
  93
  94         return true;
  95 }
  96
  97 void Nagger_Init()
  98 {
  99         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 100 }
 101
 102 void Nagger_VoteChanged()
 103 {
 104         if (nagger) nagger.SendFlags |= BIT(7);
 105 }
 106
 107 void Nagger_VoteCountChanged()
 108 {
 109         if (nagger) nagger.SendFlags |= BIT(6);
 110 }
 111
 112 void Nagger_ReadyCounted()
 113 {
 114         if (nagger) nagger.SendFlags |= BIT(0);
 115 }
 116
 117 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 118 string OriginalCallerName()
 119 {
 120         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 121         return vote_caller_name;
 122 }
 123
 124 // =======================
 125 //  Game logic for voting
 126 // =======================
 127
 128 void VoteReset()
 129 {
 130         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 131
 132         if (vote_called)
 133         {
 134                 strfree(vote_called_command);
 135                 strfree(vote_called_display);
 136                 strfree(vote_caller_name);
 137         }
 138
 139         vote_called = VOTE_NULL;
 140         vote_caller = NULL;
 141         vote_endtime = 0;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 206
 207 void VoteCount(float first_count)
 208 {
 209         // declarations
 210         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 211
 212         float vote_player_count = 0, notvoters = 0;
 213         float vote_real_player_count = 0, vote_real_accept_count = 0;
 214         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 215         float vote_needed_of_voted, final_needed_votes;
 216         float vote_factor_overall, vote_factor_of_voted;
 217
 218         Nagger_VoteCountChanged();
 219
 220         // add up all the votes from each connected client
 221         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 222                 // z411
 223                 if(vote_target_type == VOTE_TARGET_TEAM && it.team != vote_caller.team) continue;
 224                 if(vote_target_type == VOTE_TARGET_SINGLE && it != vote_target) continue;
 225
 226                 ++vote_player_count;
 227                 if (IS_PLAYER(it))   ++vote_real_player_count;
 228                 switch (it.vote_selection)
 229                 {
 230                         case VOTE_SELECT_REJECT:
 231                         { ++vote_reject_count;
 232                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 233                         }
 234                         case VOTE_SELECT_ACCEPT:
 235                         { ++vote_accept_count;
 236                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 237                         }
 238                         case VOTE_SELECT_ABSTAIN:
 239                         { ++vote_abstain_count;
 240                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 241                         }
 242                         default: break;
 243                 }
 244         });
 245
 246         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 247         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 248         {
 249                 if (vote_caller)   vote_caller.vote_waittime = 0;
 250                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 251                 VoteReset();
 252                 return;
 253         }
 254
 255         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 256         if (!spectators_allowed && (vote_real_player_count > 0))
 257         {
 258                 vote_accept_count = vote_real_accept_count;
 259                 vote_reject_count = vote_real_reject_count;
 260                 vote_abstain_count = vote_real_abstain_count;
 261                 vote_player_count = vote_real_player_count;
 262         }
 263
 264         // people who have no opinion in any way :D
 265         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 266
 267         // determine the goal for the vote to be passed or rejected normally
 268         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 269         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 270
 271         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 272         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 273         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 274
 275         // are there any players at all on the server? it could be an admin vote
 276         if (vote_player_count == 0 && first_count)
 277         {
 278                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 279                 VoteAccept();
 280                 return;
 281         }
 282
 283         // since there ARE players, finally calculate the result of the vote
 284         if (vote_accept_count >= vote_needed_overall)
 285         {
 286                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 287                 VoteAccept();
 288                 return;
 289         }
 290
 291         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 292         {
 293                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 294                 VoteReject();
 295                 return;
 296         }
 297
 298         // there is not enough votes in either direction, now lets just calculate what the voters have said
 299         if (time > vote_endtime)
 300         {
 301                 final_needed_votes = vote_needed_overall;
 302
 303                 if (autocvar_sv_vote_majority_factor_of_voted)
 304                 {
 305                         if (vote_accept_count >= vote_needed_of_voted)
 306                         {
 307                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 308                                 VoteAccept();
 309                                 return;
 310                         }
 311
 312                         if (vote_accept_count + vote_reject_count > 0)
 313                         {
 314                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 315                                 VoteReject();
 316                                 return;
 317                         }
 318
 319                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 320                 }
 321
 322                 // it didn't pass or fail, so not enough votes to even make a decision.
 323                 VoteSpam(notvoters, final_needed_votes, "timeout");
 324                 VoteTimeout();
 325         }
 326 }
 327
 328 void VoteThink()
 329 {
 330         if (vote_endtime > 0)        // a vote was called
 331         {
 332                 if (time > vote_endtime) // time is up
 333                         VoteCount(false);
 334         }
 335 }
 336
 337
 338 // =======================
 339 //  Game logic for warmup
 340 // =======================
 341
 342 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 343 void reset_map(bool dorespawn, bool is_fake_round_start)
 344 {
 345         if (time <= game_starttime)
 346         {
 347                 if (game_stopped)
 348                         return;
 349
 350                 if (!is_fake_round_start)
 351                         PlayerStats_GameReport_Reset_All();
 352                 if (round_handler_IsActive())
 353                         round_handler_Reset(game_starttime);
 354         }
 355
 356         if (shuffleteams_on_reset_map)
 357         {
 358                 shuffleteams();
 359                 shuffleteams_on_reset_map = false;
 360         }
 361
 362         FOREACH_CLIENT(true, {
 363                 if (time <= game_starttime)
 364                         accuracy_reset(it); // for spectators too because weapon accuracy is persistent
 365                 if (!IS_PLAYER(it))
 366                         continue;
 367                 if (STAT(FROZEN, it))
 368                         Unfreeze(it, false);
 369                 player_powerups_remove_all(it);
 370                 entity store = PS(it);
 371                 if (store)
 372                 {
 373                         Inventory_clear(store.inventory);
 374                         Inventory_update(store);
 375                 }
 376         });
 377
 378         MUTATOR_CALLHOOK(reset_map_global);
 379
 380         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 381         {
 382                 if(IS_CLIENT(it))
 383                         continue;
 384                 if (it.reset)
 385                 {
 386                         it.reset(it);
 387                         continue;
 388                 }
 389                 if (it.team_saved) it.team = it.team_saved;
 390                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 391         });
 392
 393         // Waypoints and assault start come LAST
 394         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 395                 if (it.reset2) it.reset2(it);
 396         });
 397
 398         // Moving the player reset code here since the player-reset depends
 399         // on spawnpoint entities which have to be reset first --blub
 400         if (dorespawn)
 401         {
 402                 if (!MUTATOR_CALLHOOK(reset_map_players))
 403                 {
 404                         FOREACH_CLIENT(IS_PLAYER(it),
 405                         {
 406                                 // PlayerScore_Clear(it);
 407                                 CS(it).killcount = 0;
 408                                 // stop the player from moving so that he stands still once he gets respawned
 409                                 it.velocity = '0 0 0';
 410                                 it.avelocity = '0 0 0';
 411                                 CS(it).movement = '0 0 0';
 412                                 PutClientInServer(it);
 413                         });
 414                 }
 415         }
 416 }
 417
 418 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 419 void ReadyRestart_think(entity this)
 420 {
 421         reset_map(true, false);
 422         Score_ClearAll();
 423         Inventory_ClearAll();
 424         delete(this);
 425 }
 426
 427 // Forces a restart of the game without actually reloading the map // this is a mess...
 428 void ReadyRestart_force(bool is_fake_round_start)
 429 {
 430         if (time <= game_starttime && game_stopped)
 431                 return;
 432         if (!is_fake_round_start)
 433                 bprint("^1Match is restarting...\n");
 434
 435         VoteReset();
 436
 437         // clear overtime, we have to decrease timelimit to its original value again.
 438         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 439                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 440         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 441
 442         if(warmup_stage)
 443                 game_starttime = time; // Warmup: No countdown in warmup
 444         else
 445                 game_starttime = time + RESTART_COUNTDOWN; // Go into match mode
 446
 447         // clear player attributes
 448         FOREACH_CLIENT(IS_PLAYER(it), {
 449                 it.alivetime = 0;
 450                 CS(it).killcount = 0;
 451         });
 452
 453         // if we're ending the warmup stage call the corresponding hook
 454         if(!is_fake_round_start && !warmup_stage)
 455                 localcmd("\nsv_hook_warmupend\n");
 456
 457         // reset the .ready status of all players (also spectators)
 458         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 459                 it.ready = false;
 460                 Kill_Notification(NOTIF_ONE_ONLY, it, MSG_CENTER, CPID_MISSING_READY);
 461         });
 462         readycount = 0;
 463         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 464
 465         // lock teams with lockonrestart
 466         if (autocvar_teamplay_lockonrestart && teamplay)
 467                 lockteams = !warmup_stage;
 468
 469         // initiate the restart-countdown-announcer entity
 470         if (!is_fake_round_start && sv_ready_restart_after_countdown && !warmup_stage)
 471         {
 472                 entity restart_timer = new_pure(restart_timer);
 473                 setthink(restart_timer, ReadyRestart_think);
 474                 restart_timer.nextthink = game_starttime;
 475         }
 476
 477         // after a restart every players number of allowed timeouts gets reset, too
 478         if (autocvar_sv_timeout)
 479         {
 480                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 481         }
 482
 483         if (!sv_ready_restart_after_countdown || warmup_stage) reset_map(true, is_fake_round_start);
 484         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 485 }
 486
 487 void ReadyRestart(bool forceWarmupEnd)
 488 {
 489         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 490         else localcmd("\nsv_hook_readyrestart\n");
 491
 492         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 493         // Otherwise scores could be manipulated during the countdown.
 494         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 495
 496         if(forceWarmupEnd)
 497                 warmup_stage = 0; // forcefully end warmup and go to match stage
 498         else
 499                 warmup_stage = cvar("g_warmup"); // go into warmup if it's enabled, otherwise restart into match stage
 500
 501         ReadyRestart_force(false);
 502 }
 503
 504 // Count the players who are ready and determine whether or not to restart the match
 505 void ReadyCount()
 506 {
 507         float ready_needed_factor, ready_needed_count;
 508         float t_ready = 0, t_players = 0;
 509
 510         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || INGAME_JOINED(it)), {
 511                 ++t_players;
 512                 if (it.ready) ++t_ready;
 513         });
 514
 515         readycount = t_ready;
 516
 517         Nagger_ReadyCounted();
 518
 519         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 520         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 521
 522         if (readycount >= ready_needed_count) ReadyRestart(true);
 523 }
 524
 525
 526 // ======================================
 527 //  Supporting functions for VoteCommand
 528 // ======================================
 529
 530 float Votecommand_check_assignment(entity caller, float assignment)
 531 {
 532         float from_server = (!caller);
 533
 534         if ((assignment == VC_ASGNMNT_BOTH)
 535             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 536             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 537
 538         return false;
 539 }
 540
 541 string VoteCommand_extractcommand(string input, float startpos, int argc)
 542 {
 543         string output;
 544
 545         if ((argc - 1) < startpos) output = "";
 546         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 547
 548         return output;
 549 }
 550
 551 float VoteCommand_checknasty(string vote_command)
 552 {
 553         if ((strstrofs(vote_command, ";", 0) >= 0)
 554             || (strstrofs(vote_command, "\n", 0) >= 0)
 555             || (strstrofs(vote_command, "\r", 0) >= 0)
 556             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 557
 558         return true;
 559 }
 560
 561 // NOTE: requires input to be surrounded by spaces
 562 string VoteCommand_checkreplacements(string input)
 563 {
 564         string output = input;
 565         // allow gotomap replacements
 566         output = strreplace(" map ", " gotomap ", output);
 567         output = strreplace(" chmap ", " gotomap ", output);
 568         return output;
 569 }
 570
 571 float VoteCommand_checkinlist(string vote_command, string list)
 572 {
 573         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 574
 575         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 576
 577         return false;
 578 }
 579
 580 string ValidateMap(string validated_map, entity caller)
 581 {
 582         validated_map = MapInfo_FixName(validated_map);
 583
 584         if (!validated_map)
 585         {
 586                 print_to(caller, "This map is not available on this server.");
 587                 return string_null;
 588         }
 589
 590         if (!autocvar_sv_vote_override_mostrecent && caller)
 591         {
 592                 if (Map_IsRecent(validated_map))
 593                 {
 594                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 595                         return string_null;
 596                 }
 597         }
 598
 599         if (!MapInfo_CheckMap(validated_map))
 600         {
 601                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 602                 return string_null;
 603         }
 604
 605         return validated_map;
 606 }
 607
 608 float VoteCommand_checkargs(float startpos, int argc)
 609 {
 610         float p, q, check, minargs;
 611         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 612         string cmdrestriction = "";  // No we don't.
 613         string charlist, arg;
 614         float checkmate;
 615
 616         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 617                 cmdrestriction = cvar_string(cvarname);
 618         else
 619                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 620
 621         if (cmdrestriction == "") return true;
 622
 623         ++startpos;  // skip command name
 624
 625         // check minimum arg count
 626
 627         // 0 args: argc == startpos
 628         // 1 args: argc == startpos + 1
 629         // ...
 630
 631         minargs = stof(cmdrestriction);
 632         if (argc - startpos < minargs) return false;
 633
 634         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 635
 636         for ( ; ; )
 637         {
 638                 // we know that at any time, startpos <= argc - minargs
 639                 // so this means: argc-minargs >= startpos >= argc, thus
 640                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 641                 // have been seen already
 642
 643                 if (startpos >= argc) // all args checked? GOOD
 644                         break;
 645
 646                 if (p < 0)            // no more args? FAIL
 647                 {
 648                         // exception: exactly minargs left, this one included
 649                         if (argc - startpos == minargs) break;
 650
 651                         // otherwise fail
 652                         return false;
 653                 }
 654
 655                 // cut to next semicolon
 656                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 657                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 658                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 659
 660                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 661                 // charlist = strreplace("^^", ";", charlist);
 662
 663                 if (charlist != "")
 664                 {
 665                         // verify the arg only contains allowed chars
 666                         arg = argv(startpos);
 667                         checkmate = strlen(arg);
 668                         for (check = 0; check < checkmate; ++check)
 669                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 670                         // not allowed character
 671                         // all characters are allowed. FINE.
 672                 }
 673
 674                 ++startpos;
 675                 --minargs;
 676                 p = q;
 677         }
 678
 679         return true;
 680 }
 681
 682 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 683 {
 684         string first_command = argv(startpos);
 685         int missing_chars = argv_start_index(startpos);
 686
 687         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 688                 return 0;
 689
 690         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 691
 692         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 693
 694         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 695         {
 696                 case MUT_VOTEPARSE_CONTINUE: { break; }
 697                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 698                 case MUT_VOTEPARSE_INVALID: { return -1; }
 699                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 700         }
 701
 702         vote_target_type = VOTE_TARGET_ALL;
 703
 704         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 705         {
 706                 case "kick":
 707                 case "kickban":    // catch all kick/kickban commands
 708                 {
 709                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 710                         float accepted = VerifyClientEntity(victim, true, false);
 711
 712                         if (accepted > 0)
 713                         {
 714                                 string reason = "No reason provided";
 715                                 if(argc > next_token)
 716                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 717
 718                                 string command_arguments = reason;
 719                                 if (first_command == "kickban")
 720                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 721
 722                                 if (first_command == "kick") // z411 : Use our kick implementation - kind of hacky...
 723                                         vote_parsed_command = strcat("defer 2 \"sv_cmd kickkick # ", ftos(etof(victim)), " ", command_arguments, "\"");
 724                                 else
 725                                         vote_parsed_command = strcat("defer 2 \"", first_command, " # ", ftos(etof(victim)), " ", command_arguments, "\"");
 726
 727                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 728                         }
 729                         else
 730                         {
 731                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 732                                 return 0;
 733                         }
 734
 735                         break;
 736                 }
 737
 738                 case "map":
 739                 case "chmap":
 740                 case "gotomap":  // re-direct all map selection commands to gotomap
 741                 {
 742                         vote_command = ValidateMap(argv(startpos + 1), caller);
 743                         if (!vote_command)  return -1;
 744                         vote_parsed_command = strcat("defer 2 \"gotomap ", vote_command, "\"");
 745                         vote_parsed_display = strzone(strcat("^1gotomap ", vote_command));
 746
 747                         break;
 748                 }
 749
 750                 // z411 team calls
 751                 case "teamname":
 752                 {
 753                         if (teamplay && Team_IsValidTeam(caller.team)) {
 754                                 vote_target_type = VOTE_TARGET_TEAM;
 755
 756                                 string tmname = strtolower(Static_Team_ColorName(caller.team));
 757                                 string newname = argv(startpos + 1);
 758
 759                                 vote_parsed_command = strcat(first_command, " ", tmname, " \"", newname, "\"");
 760                                 vote_parsed_display = strzone(strcat("^3(Team) ^1", first_command, " ^2", newname));
 761                         } else { print_to(caller, "vcall: Not in a team\n"); return 0; }
 762
 763                         break;
 764                 }
 765
 766                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 767                 // maybe fallback instead of aborting if map name is invalid?
 768                 case "nextmap":
 769                 {
 770                         vote_command = ValidateMap(argv(startpos + 1), caller);
 771                         if (!vote_command)  return -1;
 772                         vote_parsed_command = strcat("nextmap ", vote_command);
 773                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 774
 775                         break;
 776                 }
 777
 778                 case "timelimit": // include restrictions on the maximum votable time limit
 779                 {
 780                         float timelimit_vote = stof(argv(startpos + 1));
 781                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 782                         {
 783                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 784                                 return -1;
 785                         }
 786                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 787                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 788                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 789
 790                         break;
 791                 }
 792
 793                 case "restart":
 794                 case "resetmatch":  // re-direct all match restarting to resetmatch
 795                 {
 796                         vote_parsed_command = "resetmatch";
 797                         vote_parsed_display = strzone("^1resetmatch");
 798
 799                         break;
 800                 }
 801
 802                 case "allready":
 803                 {
 804                         if(!warmup_stage) {
 805                                 print_to(caller, "Game already started. Use the resetmatch command to restart the match.");
 806                                 return -1;
 807                         }
 808
 809                         vote_parsed_command = vote_command;
 810                         vote_parsed_display = strzone(strcat("^1", vote_command));
 811                         break;
 812                 }
 813
 814                 default:
 815                 {
 816                         vote_parsed_command = vote_command;
 817                         vote_parsed_display = strzone(strcat("^1", vote_command));
 818
 819                         break;
 820                 }
 821         }
 822
 823         return 1;
 824 }
 825
 826
 827 // =======================
 828 //  Command Sub-Functions
 829 // =======================
 830
 831 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 832 {
 833         switch (request)
 834         {
 835                 case CMD_REQUEST_COMMAND:
 836                 {
 837                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 838                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 839                         {
 840                                 print_to(caller, "^1You have already voted.");
 841                         }
 842
 843                         else  // everything went okay, continue changing vote
 844                         {
 845                                 print_to(caller, "^1You abstained from your vote.");
 846                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 847                                 msg_entity = caller;
 848                                 if (!autocvar_sv_vote_singlecount)
 849                                         VoteCount(false);
 850                         }
 851
 852                         return;
 853                 }
 854
 855                 default:
 856                 case CMD_REQUEST_USAGE:
 857                 {
 858                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 859                         print_to(caller, "  No arguments required.");
 860                         return;
 861                 }
 862         }
 863 }
 864
 865 void print_available_commands_to(entity caller)
 866 {
 867         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 868 }
 869
 870 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 871 {
 872         switch (request)
 873         {
 874                 case CMD_REQUEST_COMMAND:
 875                 {
 876                         float tmp_playercount = 0;
 877                         int parse_error;
 878
 879                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 880
 881                         if (!autocvar_sv_vote_call && caller)
 882                         {
 883                                 print_to(caller, "^1Vote calling is not allowed.");
 884                         }
 885                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 886                         {
 887                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 888                         }
 889                         else if (vote_called)
 890                         {
 891                                 print_to(caller, "^1There is already a vote called.");
 892                         }
 893                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 894                         {
 895                                 print_to(caller, "^1Only players can call a vote.");
 896                         }
 897                         else if (caller && !IS_CLIENT(caller))
 898                         {
 899                                 print_to(caller, "^1Only connected clients can vote.");
 900                         }
 901                         else if (timeout_status && vote_command != "timein")
 902                         {
 903                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 904                         }
 905                         else if (caller && (time < caller.vote_waittime))
 906                         {
 907                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 908                         }
 909                         else if (!VoteCommand_checknasty(vote_command))
 910                         {
 911                                 print_to(caller, "^1Syntax error in command.");
 912                         }
 913                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 914                         {
 915                                 if(parse_error == 0)
 916                                 {
 917                                         if (vote_called_command == "")
 918                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 919                                         else
 920                                                 print_to(caller, "^1This command is not acceptable or not available.");
 921                                 }
 922                         }
 923                         else  // everything went okay, continue with calling the vote
 924                         {
 925                                 vote_caller = caller;  // remember who called the vote
 926                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 927                                 vote_called = VOTE_NORMAL;
 928                                 vote_called_command = strzone(vote_parsed_command);
 929                                 vote_called_display = strzone(vote_parsed_display);
 930                                 vote_endtime = time + autocvar_sv_vote_timeout;
 931
 932                                 if (caller)
 933                                 {
 934                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 935                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 936                                         msg_entity = caller;
 937                                 }
 938
 939                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 940
 941                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 942                                 if (autocvar_sv_eventlog)
 943                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 944                                 Nagger_VoteChanged();
 945                                 VoteCount(true);  // needed if you are the only one
 946
 947                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 948                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 949                         }
 950
 951                         return;
 952                 }
 953
 954                 default:
 955                 case CMD_REQUEST_USAGE:
 956                 {
 957                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 958                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 959                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 960                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 961                         print_available_commands_to(caller);
 962                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 963                         return;
 964                 }
 965         }
 966 }
 967
 968 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 969 {
 970         switch (request)
 971         {
 972                 case CMD_REQUEST_COMMAND:
 973                 {
 974                         if (autocvar_sv_vote_master)
 975                         {
 976                                 switch (strtolower(argv(2)))
 977                                 {
 978                                         case "do":
 979                                         {
 980                                                 int parse_error;
 981                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 982
 983                                                 if (!caller.vote_master)
 984                                                         print_to(caller, "^1You do not have vote master privileges.");
 985                                                 else if (!VoteCommand_checknasty(vote_command))
 986                                                 {
 987                                                         print_to(caller, "^1Syntax error in command.");
 988                                                 }
 989                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 990                                                 {
 991                                                         if(parse_error == 0)
 992                                                         {
 993                                                                 if (vote_called_command == "")
 994                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 995                                                                 else
 996                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 997                                                         }
 998                                                 }
 999                                                 else  // everything went okay, proceed with command
1000                                                 {
1001                                                         localcmd(strcat(vote_parsed_command, "\n"));
1002                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
1003                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
1004                                                         if (autocvar_sv_eventlog)
1005                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
1006                                                 }
1007
1008                                                 return;
1009                                         }
1010
1011                                         case "login":
1012                                         {
1013                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
1014                                                 else if (caller.vote_master)
1015                                                 {
1016                                                         print_to(caller, "^1You are already logged in as vote master.");
1017                                                 }
1018                                                 else if (autocvar_sv_vote_master_password != argv(3))
1019                                                 {
1020                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
1021                                                 }
1022                                                 else  // everything went okay, proceed with giving this player master privilages
1023                                                 {
1024                                                         caller.vote_master = true;
1025                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
1026                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
1027                                                         if (autocvar_sv_eventlog)
1028                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
1029                                                 }
1030
1031                                                 return;
1032                                         }
1033
1034                                         default:  // calling a vote for master
1035                                         {
1036                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
1037                                                 else if (vote_called)
1038                                                 {
1039                                                         print_to(caller, "^1There is already a vote called.");
1040                                                 }
1041                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1042                                                 {
1043                                                         print_to(caller, "^1Only players can call a vote.");
1044                                                 }
1045                                                 else if (timeout_status)
1046                                                 {
1047                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1048                                                 }
1049                                                 else  // everything went okay, continue with creating vote
1050                                                 {
1051                                                         vote_caller = caller;
1052                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1053                                                         vote_called = VOTE_MASTER;
1054                                                         vote_called_command = strzone("XXX");
1055                                                         vote_called_display = strzone("^3master");
1056                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1057
1058                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1059                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1060
1061                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1062                                                         if (autocvar_sv_eventlog)
1063                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1064                                                         Nagger_VoteChanged();
1065                                                         VoteCount(true);  // needed if you are the only one
1066                                                 }
1067
1068                                                 return;
1069                                         }
1070                                 }
1071                         }
1072                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1073
1074                         return;
1075                 }
1076
1077                 default:
1078                 case CMD_REQUEST_USAGE:
1079                 {
1080                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1081                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1082                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1083                         return;
1084                 }
1085         }
1086 }
1087
1088 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1089 {
1090         switch (request)
1091         {
1092                 case CMD_REQUEST_COMMAND:
1093                 {
1094                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1095                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1096                         {
1097                                 print_to(caller, "^1You have already voted.");
1098                         }
1099                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1100                         {
1101                                 VoteStop(caller);
1102                         }
1103
1104                         else  // everything went okay, continue changing vote
1105                         {
1106                                 print_to(caller, "^1You rejected the vote.");
1107                                 caller.vote_selection = VOTE_SELECT_REJECT;
1108                                 msg_entity = caller;
1109                                 if (!autocvar_sv_vote_singlecount)
1110                                         VoteCount(false);
1111                         }
1112
1113                         return;
1114                 }
1115
1116                 default:
1117                 case CMD_REQUEST_USAGE:
1118                 {
1119                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1120                         print_to(caller, "  No arguments required.");
1121                         return;
1122                 }
1123         }
1124 }
1125
1126 void VoteCommand_status(int request, entity caller)  // BOTH
1127 {
1128         switch (request)
1129         {
1130                 case CMD_REQUEST_COMMAND:
1131                 {
1132                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1133                         else print_to(caller, "^1No vote called.");
1134
1135                         return;
1136                 }
1137
1138                 default:
1139                 case CMD_REQUEST_USAGE:
1140                 {
1141                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1142                         print_to(caller, "  No arguments required.");
1143                         return;
1144                 }
1145         }
1146 }
1147
1148 void VoteCommand_stop(int request, entity caller)  // BOTH
1149 {
1150         switch (request)
1151         {
1152                 case CMD_REQUEST_COMMAND:
1153                 {
1154                         if (!vote_called)   print_to(caller, "^1No vote called.");
1155                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1156                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1157                         return;
1158                 }
1159
1160                 default:
1161                 case CMD_REQUEST_USAGE:
1162                 {
1163                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1164                         print_to(caller, "  No arguments required.");
1165                         return;
1166                 }
1167         }
1168 }
1169
1170 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1171 {
1172         switch (request)
1173         {
1174                 case CMD_REQUEST_COMMAND:
1175                 {
1176                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1177                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1178                         {
1179                                 print_to(caller, "^1You have already voted.");
1180                         }
1181                         else  // everything went okay, continue changing vote
1182                         {
1183                                 print_to(caller, "^1You accepted the vote.");
1184                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1185                                 msg_entity = caller;
1186                                 if (!autocvar_sv_vote_singlecount)
1187                                         VoteCount(false);
1188                         }
1189
1190                         return;
1191                 }
1192
1193                 default:
1194                 case CMD_REQUEST_USAGE:
1195                 {
1196                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1197                         print_to(caller, "  No arguments required.");
1198                         return;
1199                 }
1200         }
1201 }
1202
1203 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1204 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1205 void VoteCommand_(int request)
1206 {
1207     switch(request)
1208     {
1209         case CMD_REQUEST_COMMAND:
1210         {
1211
1212             return;
1213         }
1214
1215         default:
1216         case CMD_REQUEST_USAGE:
1217         {
1218             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1219             print_to(caller, "  No arguments required.");
1220             return;
1221         }
1222     }
1223 }
1224 */
1225
1226
1227 // ================================
1228 //  Macro system for vote commands
1229 // ================================
1230
1231 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1232 #define VOTE_COMMANDS(request, caller, arguments, command) \
1233         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1234         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1235         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1236         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1237         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1238         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1239         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1240         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1241         /* nothing */
1242
1243 void VoteCommand_macro_help(entity caller, int argc)
1244 {
1245         string command_origin = GetCommandPrefix(caller);
1246
1247         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1248         {
1249                 print_to(caller, "\nVoting commands:\n");
1250                 #define VOTE_COMMAND(name, function, description, assignment) \
1251                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1252
1253                 VOTE_COMMANDS(0, caller, 0, "");
1254                 #undef VOTE_COMMAND
1255
1256                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1257                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1258                 print_available_commands_to(caller);
1259         }
1260         else  // usage for individual command
1261         {
1262                 #define VOTE_COMMAND(name, function, description, assignment) \
1263                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1264
1265                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1266                 #undef VOTE_COMMAND
1267
1268                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1269                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1270                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1271                 else if (argv(2) != "")
1272                         print_to(caller, "No documentation exists for this vote");
1273         }
1274 }
1275
1276 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1277 {
1278         #define VOTE_COMMAND(name, function, description, assignment) \
1279                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1280
1281         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1282         #undef VOTE_COMMAND
1283
1284         return false;
1285 }
1286
1287
1288 // ======================================
1289 //  Main function handling vote commands
1290 // ======================================
1291
1292 void VoteCommand(int request, entity caller, int argc, string vote_command)
1293 {
1294         // Guide for working with argc arguments by example:
1295         // argc:   1    - 2      - 3     - 4
1296         // argv:   0    - 1      - 2     - 3
1297         // cmd     vote - master - login - password
1298
1299         switch (request)
1300         {
1301                 case CMD_REQUEST_COMMAND:
1302                 {
1303                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1304                 }
1305
1306                 default:
1307                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1308                 case CMD_REQUEST_USAGE:
1309                 {
1310                         VoteCommand_macro_help(caller, argc);
1311                         return;
1312                 }
1313         }
1314 }