qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <server/client.qh>
   4 #include <common/weapons/_all.qh>
   5 #include <common/stats.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/miscfunctions.qh>
   8
   9 #include <common/command/_mod.qh>
  10 #include "vote.qh"
  11
  12 #include "common.qh"
  13
  14 #include "../damage.qh"
  15 #include "../world.qh"
  16 #include "../teamplay.qh"
  17 #include "../race.qh"
  18 #include "../round_handler.qh"
  19 #include "../scores.qh"
  20
  21 #include <server/mutators/_mod.qh>
  22 #include <common/gamemodes/_mod.qh>
  23
  24 #include <common/constants.qh>
  25 #include <common/net_linked.qh>
  26 #include <common/mapinfo.qh>
  27 #include <common/notifications/all.qh>
  28 #include <common/playerstats.qh>
  29 #include <common/util.qh>
  30
  31 // =============================================
  32 //  Server side voting code, reworked by Samual
  33 //  Last updated: December 27th, 2011
  34 // =============================================
  35
  36 //  Nagger for players to know status of voting
  37 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  38 {
  39         int nags, i, f, b;
  40         entity e;
  41         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  42
  43         // bits:
  44         //   1 = ready
  45         //   2 = player needs to ready up
  46         //   4 = vote
  47         //   8 = player needs to vote
  48         //  16 = warmup
  49         // sendflags:
  50         //  64 = vote counts
  51         // 128 = vote string
  52
  53         nags = 0;
  54         if (readycount)
  55         {
  56                 nags |= BIT(0);
  57                 if (to.ready == 0) nags |= BIT(1);
  58         }
  59         if (vote_called)
  60         {
  61                 nags |= BIT(2);
  62                 if (to.vote_selection == 0) nags |= BIT(3);
  63         }
  64         if (warmup_stage) nags |= BIT(4);
  65
  66         if (sendflags & BIT(6)) nags |= BIT(6);
  67
  68         if (sendflags & BIT(7)) nags |= BIT(7);
  69
  70         if (!(nags & 4))  // no vote called? send no string
  71                 nags &= ~(BIT(6) | BIT(7));
  72
  73         WriteByte(MSG_ENTITY, nags);
  74
  75         if (nags & BIT(6))
  76         {
  77                 WriteByte(MSG_ENTITY, vote_accept_count);
  78                 WriteByte(MSG_ENTITY, vote_reject_count);
  79                 WriteByte(MSG_ENTITY, vote_needed_overall);
  80                 WriteChar(MSG_ENTITY, to.vote_selection);
  81         }
  82
  83         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  84
  85         if (nags & 1)
  86         {
  87                 for (i = 1; i <= maxclients; i += 8)
  88                 {
  89                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  90                                 if (!IS_REAL_CLIENT(e) || e.ready)
  91                                         f |= b;
  92                         WriteByte(MSG_ENTITY, f);
  93                 }
  94         }
  95
  96         return true;
  97 }
  98
  99 void Nagger_Init()
 100 {
 101         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
 102 }
 103
 104 void Nagger_VoteChanged()
 105 {
 106         if (nagger) nagger.SendFlags |= BIT(7);
 107 }
 108
 109 void Nagger_VoteCountChanged()
 110 {
 111         if (nagger) nagger.SendFlags |= BIT(6);
 112 }
 113
 114 void Nagger_ReadyCounted()
 115 {
 116         if (nagger) nagger.SendFlags |= BIT(0);
 117 }
 118
 119 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 120 string OriginalCallerName()
 121 {
 122         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller, false);
 123         return vote_caller_name;
 124 }
 125
 126 // =======================
 127 //  Game logic for voting
 128 // =======================
 129
 130 void VoteReset()
 131 {
 132         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 133
 134         if (vote_called)
 135         {
 136                 strfree(vote_called_command);
 137                 strfree(vote_called_display);
 138                 strfree(vote_caller_name);
 139         }
 140
 141         vote_called = VOTE_NULL;
 142         vote_caller = NULL;
 143         vote_endtime = 0;
 144
 145         vote_parsed_command = string_null;
 146         vote_parsed_display = string_null;
 147
 148         Nagger_VoteChanged();
 149 }
 150
 151 void VoteStop(entity stopper)
 152 {
 153         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 154         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 155         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 156         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 157         VoteReset();
 158 }
 159
 160 void VoteAccept()
 161 {
 162         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 163
 164         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 165         else localcmd(strcat(vote_called_command, "\n"));
 166
 167         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 168
 169         VoteReset();
 170         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 171 }
 172
 173 void VoteReject()
 174 {
 175         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 176         VoteReset();
 177         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 178 }
 179
 180 void VoteTimeout()
 181 {
 182         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 183         VoteReset();
 184         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 185 }
 186
 187 void VoteSpam(float notvoters, float mincount, string result)
 188 {
 189         bprint(strcat(
 190                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 191                 strcat("^2:^1", ftos(vote_reject_count)),
 192                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 193                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 194                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 195
 196         if (autocvar_sv_eventlog)
 197         {
 198                 GameLogEcho(strcat(
 199                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 200                         strcat(":", ftos(vote_reject_count)),
 201                         strcat(":", ftos(vote_abstain_count)),
 202                         strcat(":", ftos(notvoters)),
 203                         strcat(":", ftos(mincount))));
 204         }
 205 }
 206
 207 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 208
 209 void VoteCount(float first_count)
 210 {
 211         // declarations
 212         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 213
 214         float vote_player_count = 0, notvoters = 0;
 215         float vote_real_player_count = 0, vote_real_accept_count = 0;
 216         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 217         float vote_needed_of_voted, final_needed_votes;
 218         float vote_factor_overall, vote_factor_of_voted;
 219
 220         Nagger_VoteCountChanged();
 221
 222         // add up all the votes from each connected client
 223         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 224                 ++vote_player_count;
 225                 if (IS_PLAYER(it))   ++vote_real_player_count;
 226                 switch (it.vote_selection)
 227                 {
 228                         case VOTE_SELECT_REJECT:
 229                         { ++vote_reject_count;
 230                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 231                         }
 232                         case VOTE_SELECT_ACCEPT:
 233                         { ++vote_accept_count;
 234                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 235                         }
 236                         case VOTE_SELECT_ABSTAIN:
 237                         { ++vote_abstain_count;
 238                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 239                         }
 240                         default: break;
 241                 }
 242         });
 243
 244         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 245         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 246         {
 247                 if (vote_caller)   vote_caller.vote_waittime = 0;
 248                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 249                 VoteReset();
 250                 return;
 251         }
 252
 253         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 254         if (!spectators_allowed && (vote_real_player_count > 0))
 255         {
 256                 vote_accept_count = vote_real_accept_count;
 257                 vote_reject_count = vote_real_reject_count;
 258                 vote_abstain_count = vote_real_abstain_count;
 259                 vote_player_count = vote_real_player_count;
 260         }
 261
 262         // people who have no opinion in any way :D
 263         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 264
 265         // determine the goal for the vote to be passed or rejected normally
 266         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 267         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 268
 269         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 270         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 271         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 272
 273         // are there any players at all on the server? it could be an admin vote
 274         if (vote_player_count == 0 && first_count)
 275         {
 276                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 277                 VoteAccept();
 278                 return;
 279         }
 280
 281         // since there ARE players, finally calculate the result of the vote
 282         if (vote_accept_count >= vote_needed_overall)
 283         {
 284                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 285                 VoteAccept();
 286                 return;
 287         }
 288
 289         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 290         {
 291                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 292                 VoteReject();
 293                 return;
 294         }
 295
 296         // there is not enough votes in either direction, now lets just calculate what the voters have said
 297         if (time > vote_endtime)
 298         {
 299                 final_needed_votes = vote_needed_overall;
 300
 301                 if (autocvar_sv_vote_majority_factor_of_voted)
 302                 {
 303                         if (vote_accept_count >= vote_needed_of_voted)
 304                         {
 305                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 306                                 VoteAccept();
 307                                 return;
 308                         }
 309
 310                         if (vote_accept_count + vote_reject_count > 0)
 311                         {
 312                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 313                                 VoteReject();
 314                                 return;
 315                         }
 316
 317                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 318                 }
 319
 320                 // it didn't pass or fail, so not enough votes to even make a decision.
 321                 VoteSpam(notvoters, final_needed_votes, "timeout");
 322                 VoteTimeout();
 323         }
 324 }
 325
 326 void VoteThink()
 327 {
 328         if (vote_endtime > 0)        // a vote was called
 329         {
 330                 if (time > vote_endtime) // time is up
 331                         VoteCount(false);
 332         }
 333 }
 334
 335
 336 // =======================
 337 //  Game logic for warmup
 338 // =======================
 339
 340 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 341 void reset_map(bool dorespawn)
 342 {
 343         if (time <= game_starttime)
 344         {
 345                 if (game_stopped)
 346                         return;
 347                 if (round_handler_IsActive())
 348                         round_handler_Reset(game_starttime);
 349         }
 350
 351         if (shuffleteams_on_reset_map)
 352         {
 353                 shuffleteams();
 354                 shuffleteams_on_reset_map = false;
 355         }
 356         MUTATOR_CALLHOOK(reset_map_global);
 357
 358         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 359         {
 360                 if(IS_CLIENT(it))
 361                         continue;
 362                 if (it.reset)
 363                 {
 364                         it.reset(it);
 365                         continue;
 366                 }
 367                 if (it.team_saved) it.team = it.team_saved;
 368                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 369         });
 370
 371         // Waypoints and assault start come LAST
 372         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 373                 if (it.reset2) it.reset2(it);
 374         });
 375
 376         FOREACH_CLIENT(IS_PLAYER(it) && STAT(FROZEN, it), { Unfreeze(it, false); });
 377
 378         // Moving the player reset code here since the player-reset depends
 379         // on spawnpoint entities which have to be reset first --blub
 380         if (dorespawn)
 381         {
 382                 if (!MUTATOR_CALLHOOK(reset_map_players))
 383                 {
 384                         if (restart_mapalreadyrestarted || (time < game_starttime))
 385                         {
 386                                 FOREACH_CLIENT(IS_PLAYER(it),
 387                                 {
 388                                         /*
 389                                         only reset players if a restart countdown is active
 390                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 391                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 392                                         sv_ready_restart_after_countdown is not used and countdown is still running
 393                                         */
 394                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 395                                         // PlayerScore_Clear(it);
 396                                         CS(it).killcount = 0;
 397                                         // stop the player from moving so that he stands still once he gets respawned
 398                                         it.velocity = '0 0 0';
 399                                         it.avelocity = '0 0 0';
 400                                         CS(it).movement = '0 0 0';
 401                                         PutClientInServer(it);
 402                                 });
 403                         }
 404                 }
 405         }
 406 }
 407
 408 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 409 void ReadyRestart_think(entity this)
 410 {
 411         restart_mapalreadyrestarted = true;
 412         reset_map(true);
 413         Score_ClearAll();
 414         delete(this);
 415 }
 416
 417 // Forces a restart of the game without actually reloading the map // this is a mess...
 418 void ReadyRestart_force()
 419 {
 420         if (time <= game_starttime && game_stopped)
 421                 return;
 422
 423         bprint("^1Server is restarting...\n");
 424
 425         VoteReset();
 426
 427         // clear overtime, we have to decrease timelimit to its original value again.
 428         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 429                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 430         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 431
 432         readyrestart_happened = true;
 433         game_starttime = time + RESTART_COUNTDOWN;
 434
 435         // clear player attributes
 436         FOREACH_CLIENT(IS_PLAYER(it), {
 437                 it.alivetime = 0;
 438                 CS(it).killcount = 0;
 439                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 440                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 441         });
 442
 443         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 444
 445         // disable the warmup global for the server
 446         if(warmup_stage)
 447                 localcmd("\nsv_hook_warmupend\n");
 448         warmup_stage = 0;                // once the game is restarted the game is in match stage
 449
 450         // reset the .ready status of all players (also spectators)
 451         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 452         readycount = 0;
 453         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 454
 455         // lock teams with lockonrestart
 456         if (autocvar_teamplay_lockonrestart && teamplay)
 457         {
 458                 lockteams = true;
 459                 bprint("^1The teams are now locked.\n");
 460         }
 461
 462         // initiate the restart-countdown-announcer entity
 463         if (sv_ready_restart_after_countdown)
 464         {
 465                 entity restart_timer = new_pure(restart_timer);
 466                 setthink(restart_timer, ReadyRestart_think);
 467                 restart_timer.nextthink = game_starttime;
 468         }
 469
 470         // after a restart every players number of allowed timeouts gets reset, too
 471         if (autocvar_sv_timeout)
 472         {
 473                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 474         }
 475
 476         if (!sv_ready_restart_after_countdown) reset_map(true);
 477         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 478 }
 479
 480 void ReadyRestart()
 481 {
 482         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 483         else localcmd("\nsv_hook_readyrestart\n");
 484
 485         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 486         // Otherwise scores could be manipulated during the countdown.
 487         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 488         ReadyRestart_force();
 489 }
 490
 491 // Count the players who are ready and determine whether or not to restart the match
 492 void ReadyCount()
 493 {
 494         float ready_needed_factor, ready_needed_count;
 495         float t_ready = 0, t_players = 0;
 496
 497         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 498                 ++t_players;
 499                 if (it.ready) ++t_ready;
 500         });
 501
 502         readycount = t_ready;
 503
 504         Nagger_ReadyCounted();
 505
 506         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 507         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 508
 509         if (readycount >= ready_needed_count) ReadyRestart();
 510 }
 511
 512
 513 // ======================================
 514 //  Supporting functions for VoteCommand
 515 // ======================================
 516
 517 float Votecommand_check_assignment(entity caller, float assignment)
 518 {
 519         float from_server = (!caller);
 520
 521         if ((assignment == VC_ASGNMNT_BOTH)
 522             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 523             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 524
 525         return false;
 526 }
 527
 528 string VoteCommand_extractcommand(string input, float startpos, int argc)
 529 {
 530         string output;
 531
 532         if ((argc - 1) < startpos) output = "";
 533         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 534
 535         return output;
 536 }
 537
 538 float VoteCommand_checknasty(string vote_command)
 539 {
 540         if ((strstrofs(vote_command, ";", 0) >= 0)
 541             || (strstrofs(vote_command, "\n", 0) >= 0)
 542             || (strstrofs(vote_command, "\r", 0) >= 0)
 543             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 544
 545         return true;
 546 }
 547
 548 // NOTE: requires input to be surrounded by spaces
 549 string VoteCommand_checkreplacements(string input)
 550 {
 551         string output = input;
 552         // allow gotomap replacements
 553         output = strreplace(" map ", " gotomap ", output);
 554         output = strreplace(" chmap ", " gotomap ", output);
 555         return output;
 556 }
 557
 558 float VoteCommand_checkinlist(string vote_command, string list)
 559 {
 560         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 561
 562         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 563
 564         return false;
 565 }
 566
 567 string ValidateMap(string validated_map, entity caller)
 568 {
 569         validated_map = MapInfo_FixName(validated_map);
 570
 571         if (!validated_map)
 572         {
 573                 print_to(caller, "This map is not available on this server.");
 574                 return string_null;
 575         }
 576
 577         if (!autocvar_sv_vote_override_mostrecent && caller)
 578         {
 579                 if (Map_IsRecent(validated_map))
 580                 {
 581                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 582                         return string_null;
 583                 }
 584         }
 585
 586         if (!MapInfo_CheckMap(validated_map))
 587         {
 588                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 589                 return string_null;
 590         }
 591
 592         return validated_map;
 593 }
 594
 595 float VoteCommand_checkargs(float startpos, int argc)
 596 {
 597         float p, q, check, minargs;
 598         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 599         string cmdrestriction = "";  // No we don't.
 600         string charlist, arg;
 601         float checkmate;
 602
 603         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 604                 cmdrestriction = cvar_string(cvarname);
 605         else
 606                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 607
 608         if (cmdrestriction == "") return true;
 609
 610         ++startpos;  // skip command name
 611
 612         // check minimum arg count
 613
 614         // 0 args: argc == startpos
 615         // 1 args: argc == startpos + 1
 616         // ...
 617
 618         minargs = stof(cmdrestriction);
 619         if (argc - startpos < minargs) return false;
 620
 621         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 622
 623         for ( ; ; )
 624         {
 625                 // we know that at any time, startpos <= argc - minargs
 626                 // so this means: argc-minargs >= startpos >= argc, thus
 627                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 628                 // have been seen already
 629
 630                 if (startpos >= argc) // all args checked? GOOD
 631                         break;
 632
 633                 if (p < 0)            // no more args? FAIL
 634                 {
 635                         // exception: exactly minargs left, this one included
 636                         if (argc - startpos == minargs) break;
 637
 638                         // otherwise fail
 639                         return false;
 640                 }
 641
 642                 // cut to next semicolon
 643                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 644                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 645                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 646
 647                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 648                 // charlist = strreplace("^^", ";", charlist);
 649
 650                 if (charlist != "")
 651                 {
 652                         // verify the arg only contains allowed chars
 653                         arg = argv(startpos);
 654                         checkmate = strlen(arg);
 655                         for (check = 0; check < checkmate; ++check)
 656                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 657                         // not allowed character
 658                         // all characters are allowed. FINE.
 659                 }
 660
 661                 ++startpos;
 662                 --minargs;
 663                 p = q;
 664         }
 665
 666         return true;
 667 }
 668
 669 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 670 {
 671         string first_command = argv(startpos);
 672         int missing_chars = argv_start_index(startpos);
 673
 674         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 675                 return 0;
 676
 677         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 678
 679         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 680
 681         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 682         {
 683                 case MUT_VOTEPARSE_CONTINUE: { break; }
 684                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 685                 case MUT_VOTEPARSE_INVALID: { return -1; }
 686                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 687         }
 688
 689         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 690         {
 691                 case "kick":
 692                 case "kickban":    // catch all kick/kickban commands
 693                 {
 694                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 695                         float accepted = VerifyClientEntity(victim, true, false);
 696
 697                         if (accepted > 0)
 698                         {
 699                                 string reason = "No reason provided";
 700                                 if(argc > next_token)
 701                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 702
 703                                 string command_arguments = reason;
 704                                 if (first_command == "kickban")
 705                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 706
 707                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 708                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 709                         }
 710                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return 0; }
 711
 712                         break;
 713                 }
 714
 715                 case "map":
 716                 case "chmap":
 717                 case "gotomap":  // re-direct all map selection commands to gotomap
 718                 {
 719                         vote_command = ValidateMap(argv(startpos + 1), caller);
 720                         if (!vote_command)  return -1;
 721                         vote_parsed_command = strcat("gotomap ", vote_command);
 722                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 723
 724                         break;
 725                 }
 726
 727                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 728                 // maybe fallback instead of aborting if map name is invalid?
 729                 case "nextmap":
 730                 {
 731                         vote_command = ValidateMap(argv(startpos + 1), caller);
 732                         if (!vote_command)  return -1;
 733                         vote_parsed_command = strcat("nextmap ", vote_command);
 734                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 735
 736                         break;
 737                 }
 738
 739                 case "timelimit": // include restrictions on the maximum votable time limit
 740                 {
 741                         float timelimit_vote = stof(argv(startpos + 1));
 742                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 743                         {
 744                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 745                                 return -1;
 746                         }
 747                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 748                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 749                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 750
 751                         break;
 752                 }
 753
 754                 case "restart":
 755                 {
 756                         // add a delay so that vote result can be seen and announcer can be heard
 757                         // if the vote is accepted
 758                         vote_parsed_command = strcat("defer 1 ", vote_command);
 759                         vote_parsed_display = strzone(strcat("^1", vote_command));
 760
 761                         break;
 762                 }
 763
 764                 default:
 765                 {
 766                         vote_parsed_command = vote_command;
 767                         vote_parsed_display = strzone(strcat("^1", vote_command));
 768
 769                         break;
 770                 }
 771         }
 772
 773         return 1;
 774 }
 775
 776
 777 // =======================
 778 //  Command Sub-Functions
 779 // =======================
 780
 781 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 782 {
 783         switch (request)
 784         {
 785                 case CMD_REQUEST_COMMAND:
 786                 {
 787                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 788                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 789                         {
 790                                 print_to(caller, "^1You have already voted.");
 791                         }
 792
 793                         else  // everything went okay, continue changing vote
 794                         {
 795                                 print_to(caller, "^1You abstained from your vote.");
 796                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 797                                 msg_entity = caller;
 798                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 799
 800                         return;
 801                 }
 802
 803                 default:
 804                 case CMD_REQUEST_USAGE:
 805                 {
 806                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 807                         print_to(caller, "  No arguments required.");
 808                         return;
 809                 }
 810         }
 811 }
 812
 813 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 814 {
 815         switch (request)
 816         {
 817                 case CMD_REQUEST_COMMAND:
 818                 {
 819                         float tmp_playercount = 0;
 820                         int parse_error;
 821
 822                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 823
 824                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 825                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 826                         {
 827                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 828                         }
 829                         else if (vote_called)
 830                         {
 831                                 print_to(caller, "^1There is already a vote called.");
 832                         }
 833                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 834                         {
 835                                 print_to(caller, "^1Only players can call a vote.");
 836                         }
 837                         else if (caller && !IS_CLIENT(caller))
 838                         {
 839                                 print_to(caller, "^1Only connected clients can vote.");
 840                         }
 841                         else if (timeout_status && vote_command != "timein")
 842                         {
 843                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 844                         }
 845                         else if (caller && (time < caller.vote_waittime))
 846                         {
 847                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 848                         }
 849                         else if (!VoteCommand_checknasty(vote_command))
 850                         {
 851                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 852                         }
 853                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 854                         {
 855                                 if(parse_error == 0)
 856                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 857                         }
 858                         else  // everything went okay, continue with calling the vote
 859                         {
 860                                 vote_caller = caller;  // remember who called the vote
 861                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 862                                 vote_called = VOTE_NORMAL;
 863                                 vote_called_command = strzone(vote_parsed_command);
 864                                 vote_called_display = strzone(vote_parsed_display);
 865                                 vote_endtime = time + autocvar_sv_vote_timeout;
 866
 867                                 if (caller)
 868                                 {
 869                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 870                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 871                                         msg_entity = caller;
 872                                 }
 873
 874                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 875
 876                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 877                                 if (autocvar_sv_eventlog)
 878                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 879                                 Nagger_VoteChanged();
 880                                 VoteCount(true);  // needed if you are the only one
 881
 882                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 883                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 884                         }
 885
 886                         return;
 887                 }
 888
 889                 default:
 890                 case CMD_REQUEST_USAGE:
 891                 {
 892                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 893                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 894                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 895                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 896                         return;
 897                 }
 898         }
 899 }
 900
 901 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 902 {
 903         switch (request)
 904         {
 905                 case CMD_REQUEST_COMMAND:
 906                 {
 907                         if (autocvar_sv_vote_master)
 908                         {
 909                                 switch (strtolower(argv(2)))
 910                                 {
 911                                         case "do":
 912                                         {
 913                                                 int parse_error;
 914                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 915
 916                                                 if (!caller.vote_master)
 917                                                         print_to(caller, "^1You do not have vote master privileges.");
 918                                                 else if (!VoteCommand_checknasty(vote_command))
 919                                                 {
 920                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 921                                                 }
 922                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 923                                                 {
 924                                                         if(parse_error == 0)
 925                                                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 926                                                 }
 927                                                 else  // everything went okay, proceed with command
 928                                                 {
 929                                                         localcmd(strcat(vote_parsed_command, "\n"));
 930                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 931                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 932                                                         if (autocvar_sv_eventlog)
 933                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 934                                                 }
 935
 936                                                 return;
 937                                         }
 938
 939                                         case "login":
 940                                         {
 941                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 942                                                 else if (caller.vote_master)
 943                                                 {
 944                                                         print_to(caller, "^1You are already logged in as vote master.");
 945                                                 }
 946                                                 else if (autocvar_sv_vote_master_password != argv(3))
 947                                                 {
 948                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 949                                                 }
 950                                                 else  // everything went okay, proceed with giving this player master privilages
 951                                                 {
 952                                                         caller.vote_master = true;
 953                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 954                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 955                                                         if (autocvar_sv_eventlog)
 956                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 957                                                 }
 958
 959                                                 return;
 960                                         }
 961
 962                                         default:  // calling a vote for master
 963                                         {
 964                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 965                                                 else if (vote_called)
 966                                                 {
 967                                                         print_to(caller, "^1There is already a vote called.");
 968                                                 }
 969                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 970                                                 {
 971                                                         print_to(caller, "^1Only players can call a vote.");
 972                                                 }
 973                                                 else if (timeout_status)
 974                                                 {
 975                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 976                                                 }
 977                                                 else  // everything went okay, continue with creating vote
 978                                                 {
 979                                                         vote_caller = caller;
 980                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 981                                                         vote_called = VOTE_MASTER;
 982                                                         vote_called_command = strzone("XXX");
 983                                                         vote_called_display = strzone("^3master");
 984                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 985
 986                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 987                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 988
 989                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 990                                                         if (autocvar_sv_eventlog)
 991                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 992                                                         Nagger_VoteChanged();
 993                                                         VoteCount(true);  // needed if you are the only one
 994                                                 }
 995
 996                                                 return;
 997                                         }
 998                                 }
 999                         }
1000                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1001
1002                         return;
1003                 }
1004
1005                 default:
1006                 case CMD_REQUEST_USAGE:
1007                 {
1008                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
1009                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
1010                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
1011                         return;
1012                 }
1013         }
1014 }
1015
1016 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1017 {
1018         switch (request)
1019         {
1020                 case CMD_REQUEST_COMMAND:
1021                 {
1022                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1023                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1024                         {
1025                                 print_to(caller, "^1You have already voted.");
1026                         }
1027                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1028                         {
1029                                 VoteStop(caller);
1030                         }
1031
1032                         else  // everything went okay, continue changing vote
1033                         {
1034                                 print_to(caller, "^1You rejected the vote.");
1035                                 caller.vote_selection = VOTE_SELECT_REJECT;
1036                                 msg_entity = caller;
1037                                 if (!autocvar_sv_vote_singlecount)
1038                                         VoteCount(false);
1039                         }
1040
1041                         return;
1042                 }
1043
1044                 default:
1045                 case CMD_REQUEST_USAGE:
1046                 {
1047                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1048                         print_to(caller, "  No arguments required.");
1049                         return;
1050                 }
1051         }
1052 }
1053
1054 void VoteCommand_status(int request, entity caller)  // BOTH
1055 {
1056         switch (request)
1057         {
1058                 case CMD_REQUEST_COMMAND:
1059                 {
1060                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1061                         else print_to(caller, "^1No vote called.");
1062
1063                         return;
1064                 }
1065
1066                 default:
1067                 case CMD_REQUEST_USAGE:
1068                 {
1069                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1070                         print_to(caller, "  No arguments required.");
1071                         return;
1072                 }
1073         }
1074 }
1075
1076 void VoteCommand_stop(int request, entity caller)  // BOTH
1077 {
1078         switch (request)
1079         {
1080                 case CMD_REQUEST_COMMAND:
1081                 {
1082                         if (!vote_called)   print_to(caller, "^1No vote called.");
1083                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1084                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1085                         return;
1086                 }
1087
1088                 default:
1089                 case CMD_REQUEST_USAGE:
1090                 {
1091                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1092                         print_to(caller, "  No arguments required.");
1093                         return;
1094                 }
1095         }
1096 }
1097
1098 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1099 {
1100         switch (request)
1101         {
1102                 case CMD_REQUEST_COMMAND:
1103                 {
1104                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1105                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1106                         {
1107                                 print_to(caller, "^1You have already voted.");
1108                         }
1109                         else  // everything went okay, continue changing vote
1110                         {
1111                                 print_to(caller, "^1You accepted the vote.");
1112                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1113                                 msg_entity = caller;
1114                                 if (!autocvar_sv_vote_singlecount)
1115                                         VoteCount(false);
1116                         }
1117
1118                         return;
1119                 }
1120
1121                 default:
1122                 case CMD_REQUEST_USAGE:
1123                 {
1124                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1125                         print_to(caller, "  No arguments required.");
1126                         return;
1127                 }
1128         }
1129 }
1130
1131 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1132 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1133 void VoteCommand_(int request)
1134 {
1135     switch(request)
1136     {
1137         case CMD_REQUEST_COMMAND:
1138         {
1139
1140             return;
1141         }
1142
1143         default:
1144         case CMD_REQUEST_USAGE:
1145         {
1146             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1147             print_to(caller, "  No arguments required.");
1148             return;
1149         }
1150     }
1151 }
1152 */
1153
1154
1155 // ================================
1156 //  Macro system for vote commands
1157 // ================================
1158
1159 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1160 #define VOTE_COMMANDS(request, caller, arguments, command) \
1161         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1162         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1163         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1164         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1165         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1166         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1167         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1168         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1169         /* nothing */
1170
1171 void VoteCommand_macro_help(entity caller, int argc)
1172 {
1173         string command_origin = GetCommandPrefix(caller);
1174
1175         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1176         {
1177                 print_to(caller, "\nVoting commands:\n");
1178                 #define VOTE_COMMAND(name, function, description, assignment) \
1179                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1180
1181                 VOTE_COMMANDS(0, caller, 0, "");
1182 #undef VOTE_COMMAND
1183
1184                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1185                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1186                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1187         }
1188         else  // usage for individual command
1189         {
1190                 #define VOTE_COMMAND(name, function, description, assignment) \
1191                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1192
1193                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1194 #undef VOTE_COMMAND
1195
1196                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1197                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1198                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1199                 else
1200                         print_to(caller, "No documentation exists for this vote");
1201         }
1202 }
1203
1204 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1205 {
1206         #define VOTE_COMMAND(name, function, description, assignment) \
1207                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1208
1209         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1210 #undef VOTE_COMMAND
1211
1212         return false;
1213 }
1214
1215
1216 // ======================================
1217 //  Main function handling vote commands
1218 // ======================================
1219
1220 void VoteCommand(int request, entity caller, int argc, string vote_command)
1221 {
1222         // Guide for working with argc arguments by example:
1223         // argc:   1    - 2      - 3     - 4
1224         // argv:   0    - 1      - 2     - 3
1225         // cmd     vote - master - login - password
1226
1227         switch (request)
1228         {
1229                 case CMD_REQUEST_COMMAND:
1230                 {
1231                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1232                 }
1233
1234                 default:
1235                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1236                 case CMD_REQUEST_USAGE:
1237                 {
1238                         VoteCommand_macro_help(caller, argc);
1239                         return;
1240                 }
1241         }
1242 }