qcsrc/server/command/vote.qc

   1 #include "vote.qh"
   2
   3 #include <common/command/_mod.qh>
   4 #include <common/constants.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/items/inventory.qh>
   7 #include <common/mapinfo.qh>
   8 #include <common/net_linked.qh>
   9 #include <common/notifications/all.qh>
  10 #include <common/playerstats.qh>
  11 #include <common/stats.qh>
  12 #include <common/util.qh>
  13 #include <common/weapons/_all.qh>
  14 #include <server/client.qh>
  15 #include <server/command/banning.qh>
  16 #include <server/command/common.qh>
  17 #include <server/command/vote.qh>
  18 #include <server/damage.qh>
  19 #include <server/gamelog.qh>
  20 #include <server/intermission.qh>
  21 #include <server/mutators/_mod.qh>
  22 #include <server/race.qh>
  23 #include <server/round_handler.qh>
  24 #include <server/scores.qh>
  25 #include <server/teamplay.qh>
  26 #include <server/world.qh>
  27
  28 // =============================================
  29 //  Server side voting code, reworked by Samual
  30 //  Last updated: December 27th, 2011
  31 // =============================================
  32
  33 //  Nagger for players to know status of voting
  34 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  35 {
  36         int nags, i, f, b;
  37         entity e;
  38         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  39
  40         // bits:
  41         //   1 = ready
  42         //   2 = player needs to ready up
  43         //   4 = vote
  44         //   8 = player needs to vote
  45         //  16 = warmup
  46         // sendflags:
  47         //  64 = vote counts
  48         // 128 = vote string
  49
  50         nags = 0;
  51         if (readycount)
  52         {
  53                 nags |= BIT(0);
  54                 if (to.ready == 0) nags |= BIT(1);
  55         }
  56         if (vote_called)
  57         {
  58                 nags |= BIT(2);
  59                 if (to.vote_selection == 0) nags |= BIT(3);
  60         }
  61         if (warmup_stage) nags |= BIT(4);
  62
  63         if (sendflags & BIT(6)) nags |= BIT(6);
  64
  65         if (sendflags & BIT(7)) nags |= BIT(7);
  66
  67         if (!(nags & 4))  // no vote called? send no string
  68                 nags &= ~(BIT(6) | BIT(7));
  69
  70         WriteByte(MSG_ENTITY, nags);
  71
  72         if (nags & BIT(6))
  73         {
  74                 WriteByte(MSG_ENTITY, vote_accept_count);
  75                 WriteByte(MSG_ENTITY, vote_reject_count);
  76                 WriteByte(MSG_ENTITY, vote_needed_overall);
  77                 WriteChar(MSG_ENTITY, to.vote_selection);
  78         }
  79
  80         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  81
  82         if (nags & 1)
  83         {
  84                 for (i = 1; i <= maxclients; i += 8)
  85                 {
  86                         for (f = 0, e = edict_num(i), b = BIT(0); b < BIT(8); b <<= 1, e = nextent(e))
  87                                 if (!IS_REAL_CLIENT(e) || e.ready)
  88                                         f |= b;
  89                         WriteByte(MSG_ENTITY, f);
  90                 }
  91         }
  92
  93         return true;
  94 }
  95
  96 void Nagger_Init()
  97 {
  98         Net_LinkEntity(nagger = new_pure(nagger), false, 0, Nagger_SendEntity);
  99 }
 100
 101 void Nagger_VoteChanged()
 102 {
 103         if (nagger) nagger.SendFlags |= BIT(7);
 104 }
 105
 106 void Nagger_VoteCountChanged()
 107 {
 108         if (nagger) nagger.SendFlags |= BIT(6);
 109 }
 110
 111 void Nagger_ReadyCounted()
 112 {
 113         if (nagger) nagger.SendFlags |= BIT(0);
 114 }
 115
 116 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 117 string OriginalCallerName()
 118 {
 119         if (IS_REAL_CLIENT(vote_caller)) return playername(vote_caller.netname, vote_caller.team, false);
 120         return vote_caller_name;
 121 }
 122
 123 // =======================
 124 //  Game logic for voting
 125 // =======================
 126
 127 void VoteReset()
 128 {
 129         FOREACH_CLIENT(true, { it.vote_selection = 0; });
 130
 131         if (vote_called)
 132         {
 133                 strfree(vote_called_command);
 134                 strfree(vote_called_display);
 135                 strfree(vote_caller_name);
 136         }
 137
 138         vote_called = VOTE_NULL;
 139         vote_caller = NULL;
 140         vote_endtime = 0;
 141
 142         vote_parsed_command = string_null;
 143         vote_parsed_display = string_null;
 144
 145         Nagger_VoteChanged();
 146 }
 147
 148 void VoteStop(entity stopper)
 149 {
 150         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 151         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 152         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 153         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 154         VoteReset();
 155 }
 156
 157 void VoteAccept()
 158 {
 159         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 160
 161         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 162         else localcmd(strcat(vote_called_command, "\n"));
 163
 164         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 165
 166         VoteReset();
 167         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 168 }
 169
 170 void VoteReject()
 171 {
 172         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 173         VoteReset();
 174         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 175 }
 176
 177 void VoteTimeout()
 178 {
 179         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 180         VoteReset();
 181         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_FAIL);
 182 }
 183
 184 void VoteSpam(float notvoters, float mincount, string result)
 185 {
 186         bprint(strcat(
 187                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 188                 strcat("^2:^1", ftos(vote_reject_count)),
 189                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 190                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 191                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 192
 193         if (autocvar_sv_eventlog)
 194         {
 195                 GameLogEcho(strcat(
 196                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 197                         strcat(":", ftos(vote_reject_count)),
 198                         strcat(":", ftos(vote_abstain_count)),
 199                         strcat(":", ftos(notvoters)),
 200                         strcat(":", ftos(mincount))));
 201         }
 202 }
 203
 204 #define spectators_allowed (!autocvar_sv_vote_nospectators || (autocvar_sv_vote_nospectators == 1 && (warmup_stage || intermission_running)))
 205
 206 void VoteCount(float first_count)
 207 {
 208         // declarations
 209         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 210
 211         float vote_player_count = 0, notvoters = 0;
 212         float vote_real_player_count = 0, vote_real_accept_count = 0;
 213         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 214         float vote_needed_of_voted, final_needed_votes;
 215         float vote_factor_overall, vote_factor_of_voted;
 216
 217         Nagger_VoteCountChanged();
 218
 219         // add up all the votes from each connected client
 220         FOREACH_CLIENT(IS_REAL_CLIENT(it) && IS_CLIENT(it), {
 221                 ++vote_player_count;
 222                 if (IS_PLAYER(it))   ++vote_real_player_count;
 223                 switch (it.vote_selection)
 224                 {
 225                         case VOTE_SELECT_REJECT:
 226                         { ++vote_reject_count;
 227                           { if (IS_PLAYER(it)) ++vote_real_reject_count; } break;
 228                         }
 229                         case VOTE_SELECT_ACCEPT:
 230                         { ++vote_accept_count;
 231                           { if (IS_PLAYER(it)) ++vote_real_accept_count; } break;
 232                         }
 233                         case VOTE_SELECT_ABSTAIN:
 234                         { ++vote_abstain_count;
 235                           { if (IS_PLAYER(it)) ++vote_real_abstain_count; } break;
 236                         }
 237                         default: break;
 238                 }
 239         });
 240
 241         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 242         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 243         {
 244                 if (vote_caller)   vote_caller.vote_waittime = 0;
 245                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 246                 VoteReset();
 247                 return;
 248         }
 249
 250         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 251         if (!spectators_allowed && (vote_real_player_count > 0))
 252         {
 253                 vote_accept_count = vote_real_accept_count;
 254                 vote_reject_count = vote_real_reject_count;
 255                 vote_abstain_count = vote_real_abstain_count;
 256                 vote_player_count = vote_real_player_count;
 257         }
 258
 259         // people who have no opinion in any way :D
 260         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 261
 262         // determine the goal for the vote to be passed or rejected normally
 263         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 264         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 265
 266         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 267         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 268         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 269
 270         // are there any players at all on the server? it could be an admin vote
 271         if (vote_player_count == 0 && first_count)
 272         {
 273                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 274                 VoteAccept();
 275                 return;
 276         }
 277
 278         // since there ARE players, finally calculate the result of the vote
 279         if (vote_accept_count >= vote_needed_overall)
 280         {
 281                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 282                 VoteAccept();
 283                 return;
 284         }
 285
 286         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 287         {
 288                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 289                 VoteReject();
 290                 return;
 291         }
 292
 293         // there is not enough votes in either direction, now lets just calculate what the voters have said
 294         if (time > vote_endtime)
 295         {
 296                 final_needed_votes = vote_needed_overall;
 297
 298                 if (autocvar_sv_vote_majority_factor_of_voted)
 299                 {
 300                         if (vote_accept_count >= vote_needed_of_voted)
 301                         {
 302                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 303                                 VoteAccept();
 304                                 return;
 305                         }
 306
 307                         if (vote_accept_count + vote_reject_count > 0)
 308                         {
 309                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 310                                 VoteReject();
 311                                 return;
 312                         }
 313
 314                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 315                 }
 316
 317                 // it didn't pass or fail, so not enough votes to even make a decision.
 318                 VoteSpam(notvoters, final_needed_votes, "timeout");
 319                 VoteTimeout();
 320         }
 321 }
 322
 323 void VoteThink()
 324 {
 325         if (vote_endtime > 0)        // a vote was called
 326         {
 327                 if (time > vote_endtime) // time is up
 328                         VoteCount(false);
 329         }
 330 }
 331
 332
 333 // =======================
 334 //  Game logic for warmup
 335 // =======================
 336
 337 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 338 void reset_map(bool dorespawn)
 339 {
 340         if (time <= game_starttime)
 341         {
 342                 if (game_stopped)
 343                         return;
 344                 if (round_handler_IsActive())
 345                         round_handler_Reset(game_starttime);
 346         }
 347
 348         if (shuffleteams_on_reset_map)
 349         {
 350                 shuffleteams();
 351                 shuffleteams_on_reset_map = false;
 352         }
 353
 354         FOREACH_CLIENT(IS_PLAYER(it),
 355         {
 356                 if (STAT(FROZEN, it))
 357                         Unfreeze(it, false);
 358                 player_powerups_remove_all(it);
 359                 entity store = PS(it);
 360                 if (store)
 361                 {
 362                         Inventory_clear(store.inventory);
 363                         Inventory_update(store);
 364                 }
 365         });
 366
 367         MUTATOR_CALLHOOK(reset_map_global);
 368
 369         FOREACH_ENTITY_FLOAT_ORDERED(pure_data, false,
 370         {
 371                 if(IS_CLIENT(it))
 372                         continue;
 373                 if (it.reset)
 374                 {
 375                         it.reset(it);
 376                         continue;
 377                 }
 378                 if (it.team_saved) it.team = it.team_saved;
 379                 if (it.flags & FL_PROJECTILE) delete(it);  // remove any projectiles left
 380         });
 381
 382         // Waypoints and assault start come LAST
 383         FOREACH_ENTITY_ORDERED(IS_NOT_A_CLIENT(it), {
 384                 if (it.reset2) it.reset2(it);
 385         });
 386
 387         // Moving the player reset code here since the player-reset depends
 388         // on spawnpoint entities which have to be reset first --blub
 389         if (dorespawn)
 390         {
 391                 if (!MUTATOR_CALLHOOK(reset_map_players))
 392                 {
 393                         if (restart_mapalreadyrestarted || (time < game_starttime))
 394                         {
 395                                 FOREACH_CLIENT(IS_PLAYER(it),
 396                                 {
 397                                         /*
 398                                         only reset players if a restart countdown is active
 399                                         this can either be due to cvar sv_ready_restart_after_countdown having set
 400                                         restart_mapalreadyrestarted to 1 after the countdown ended or when
 401                                         sv_ready_restart_after_countdown is not used and countdown is still running
 402                                         */
 403                                         // PlayerScore_Clear(it);
 404                                         CS(it).killcount = 0;
 405                                         // stop the player from moving so that he stands still once he gets respawned
 406                                         it.velocity = '0 0 0';
 407                                         it.avelocity = '0 0 0';
 408                                         CS(it).movement = '0 0 0';
 409                                         PutClientInServer(it);
 410                                 });
 411                         }
 412                 }
 413         }
 414 }
 415
 416 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 417 void ReadyRestart_think(entity this)
 418 {
 419         restart_mapalreadyrestarted = true;
 420         reset_map(true);
 421         Score_ClearAll();
 422         delete(this);
 423 }
 424
 425 // Forces a restart of the game without actually reloading the map // this is a mess...
 426 void ReadyRestart_force()
 427 {
 428         if (time <= game_starttime && game_stopped)
 429                 return;
 430
 431         bprint("^1Server is restarting...\n");
 432
 433         VoteReset();
 434
 435         // clear overtime, we have to decrease timelimit to its original value again.
 436         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)
 437                 cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 438         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 439
 440         readyrestart_happened = true;
 441         game_starttime = time + RESTART_COUNTDOWN;
 442
 443         // clear player attributes
 444         FOREACH_CLIENT(IS_PLAYER(it), {
 445                 it.alivetime = 0;
 446                 CS(it).killcount = 0;
 447                 float val = PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, 0);
 448                 PlayerStats_GameReport_Event_Player(it, PLAYERSTATS_ALIVETIME, -val);
 449         });
 450
 451         restart_mapalreadyrestarted = false; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 452
 453         // disable the warmup global for the server
 454         if(warmup_stage)
 455                 localcmd("\nsv_hook_warmupend\n");
 456         warmup_stage = 0;                // once the game is restarted the game is in match stage
 457
 458         // reset the .ready status of all players (also spectators)
 459         FOREACH_CLIENT(IS_REAL_CLIENT(it), { it.ready = false; });
 460         readycount = 0;
 461         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 462
 463         // lock teams with lockonrestart
 464         if (autocvar_teamplay_lockonrestart && teamplay)
 465         {
 466                 lockteams = true;
 467                 bprint("^1The teams are now locked.\n");
 468         }
 469
 470         // initiate the restart-countdown-announcer entity
 471         if (sv_ready_restart_after_countdown)
 472         {
 473                 entity restart_timer = new_pure(restart_timer);
 474                 setthink(restart_timer, ReadyRestart_think);
 475                 restart_timer.nextthink = game_starttime;
 476         }
 477
 478         // after a restart every players number of allowed timeouts gets reset, too
 479         if (autocvar_sv_timeout)
 480         {
 481                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it), { CS(it).allowed_timeouts = autocvar_sv_timeout_number; });
 482         }
 483
 484         if (!sv_ready_restart_after_countdown) reset_map(true);
 485         if (autocvar_sv_eventlog) GameLogEcho(":restart");
 486 }
 487
 488 void ReadyRestart()
 489 {
 490         if (MUTATOR_CALLHOOK(ReadyRestart_Deny) || intermission_running || race_completing) localcmd("restart\n");
 491         else localcmd("\nsv_hook_readyrestart\n");
 492
 493         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 494         // Otherwise scores could be manipulated during the countdown.
 495         if (!sv_ready_restart_after_countdown) Score_ClearAll();
 496         ReadyRestart_force();
 497 }
 498
 499 // Count the players who are ready and determine whether or not to restart the match
 500 void ReadyCount()
 501 {
 502         float ready_needed_factor, ready_needed_count;
 503         float t_ready = 0, t_players = 0;
 504
 505         FOREACH_CLIENT(IS_REAL_CLIENT(it) && (IS_PLAYER(it) || it.caplayer == 1), {
 506                 ++t_players;
 507                 if (it.ready) ++t_ready;
 508         });
 509
 510         readycount = t_ready;
 511
 512         Nagger_ReadyCounted();
 513
 514         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 515         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 516
 517         if (readycount >= ready_needed_count) ReadyRestart();
 518 }
 519
 520
 521 // ======================================
 522 //  Supporting functions for VoteCommand
 523 // ======================================
 524
 525 float Votecommand_check_assignment(entity caller, float assignment)
 526 {
 527         float from_server = (!caller);
 528
 529         if ((assignment == VC_ASGNMNT_BOTH)
 530             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 531             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 532
 533         return false;
 534 }
 535
 536 string VoteCommand_extractcommand(string input, float startpos, int argc)
 537 {
 538         string output;
 539
 540         if ((argc - 1) < startpos) output = "";
 541         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 542
 543         return output;
 544 }
 545
 546 float VoteCommand_checknasty(string vote_command)
 547 {
 548         if ((strstrofs(vote_command, ";", 0) >= 0)
 549             || (strstrofs(vote_command, "\n", 0) >= 0)
 550             || (strstrofs(vote_command, "\r", 0) >= 0)
 551             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 552
 553         return true;
 554 }
 555
 556 // NOTE: requires input to be surrounded by spaces
 557 string VoteCommand_checkreplacements(string input)
 558 {
 559         string output = input;
 560         // allow gotomap replacements
 561         output = strreplace(" map ", " gotomap ", output);
 562         output = strreplace(" chmap ", " gotomap ", output);
 563         return output;
 564 }
 565
 566 float VoteCommand_checkinlist(string vote_command, string list)
 567 {
 568         string l = VoteCommand_checkreplacements(strcat(" ", list, " "));
 569
 570         if (strstrofs(l, VoteCommand_checkreplacements(strcat(" ", vote_command, " ")), 0) >= 0) return true;
 571
 572         return false;
 573 }
 574
 575 string ValidateMap(string validated_map, entity caller)
 576 {
 577         validated_map = MapInfo_FixName(validated_map);
 578
 579         if (!validated_map)
 580         {
 581                 print_to(caller, "This map is not available on this server.");
 582                 return string_null;
 583         }
 584
 585         if (!autocvar_sv_vote_override_mostrecent && caller)
 586         {
 587                 if (Map_IsRecent(validated_map))
 588                 {
 589                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 590                         return string_null;
 591                 }
 592         }
 593
 594         if (!MapInfo_CheckMap(validated_map))
 595         {
 596                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 597                 return string_null;
 598         }
 599
 600         return validated_map;
 601 }
 602
 603 float VoteCommand_checkargs(float startpos, int argc)
 604 {
 605         float p, q, check, minargs;
 606         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 607         string cmdrestriction = "";  // No we don't.
 608         string charlist, arg;
 609         float checkmate;
 610
 611         if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
 612                 cmdrestriction = cvar_string(cvarname);
 613         else
 614                 LOG_INFO("NOTE: ", cvarname, " does not exist, no restrictions will be applied.");
 615
 616         if (cmdrestriction == "") return true;
 617
 618         ++startpos;  // skip command name
 619
 620         // check minimum arg count
 621
 622         // 0 args: argc == startpos
 623         // 1 args: argc == startpos + 1
 624         // ...
 625
 626         minargs = stof(cmdrestriction);
 627         if (argc - startpos < minargs) return false;
 628
 629         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 630
 631         for ( ; ; )
 632         {
 633                 // we know that at any time, startpos <= argc - minargs
 634                 // so this means: argc-minargs >= startpos >= argc, thus
 635                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 636                 // have been seen already
 637
 638                 if (startpos >= argc) // all args checked? GOOD
 639                         break;
 640
 641                 if (p < 0)            // no more args? FAIL
 642                 {
 643                         // exception: exactly minargs left, this one included
 644                         if (argc - startpos == minargs) break;
 645
 646                         // otherwise fail
 647                         return false;
 648                 }
 649
 650                 // cut to next semicolon
 651                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 652                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 653                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 654
 655                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 656                 // charlist = strreplace("^^", ";", charlist);
 657
 658                 if (charlist != "")
 659                 {
 660                         // verify the arg only contains allowed chars
 661                         arg = argv(startpos);
 662                         checkmate = strlen(arg);
 663                         for (check = 0; check < checkmate; ++check)
 664                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 665                         // not allowed character
 666                         // all characters are allowed. FINE.
 667                 }
 668
 669                 ++startpos;
 670                 --minargs;
 671                 p = q;
 672         }
 673
 674         return true;
 675 }
 676
 677 int VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, int argc)
 678 {
 679         string first_command = argv(startpos);
 680         int missing_chars = argv_start_index(startpos);
 681
 682         if (autocvar_sv_vote_limit > 0 && strlen(vote_command) > autocvar_sv_vote_limit)
 683                 return 0;
 684
 685         if (!VoteCommand_checkinlist(first_command, vote_list)) return 0;
 686
 687         if (!VoteCommand_checkargs(startpos, argc)) return 0;
 688
 689         switch (MUTATOR_CALLHOOK(VoteCommand_Parse, caller, first_command, vote_command, startpos, argc))
 690         {
 691                 case MUT_VOTEPARSE_CONTINUE: { break; }
 692                 case MUT_VOTEPARSE_SUCCESS: { return 1; }
 693                 case MUT_VOTEPARSE_INVALID: { return -1; }
 694                 case MUT_VOTEPARSE_UNACCEPTABLE: { return 0; }
 695         }
 696
 697         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 698         {
 699                 case "kick":
 700                 case "kickban":    // catch all kick/kickban commands
 701                 {
 702                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 703                         float accepted = VerifyClientEntity(victim, true, false);
 704
 705                         if (accepted > 0)
 706                         {
 707                                 string reason = "No reason provided";
 708                                 if(argc > next_token)
 709                                         reason = substring(vote_command, argv_start_index(next_token) - missing_chars, -1);
 710
 711                                 string command_arguments = reason;
 712                                 if (first_command == "kickban")
 713                                         command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 714
 715                                 vote_parsed_command = strcat(first_command, " # ", ftos(etof(victim)), " ", command_arguments);
 716                                 vote_parsed_display = sprintf("^1%s #%d ^7%s^1 %s", first_command, etof(victim), victim.netname, reason);
 717                         }
 718                         else
 719                         {
 720                                 print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n"));
 721                                 return 0;
 722                         }
 723
 724                         break;
 725                 }
 726
 727                 case "map":
 728                 case "chmap":
 729                 case "gotomap":  // re-direct all map selection commands to gotomap
 730                 {
 731                         vote_command = ValidateMap(argv(startpos + 1), caller);
 732                         if (!vote_command)  return -1;
 733                         vote_parsed_command = strcat("gotomap ", vote_command);
 734                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 735
 736                         break;
 737                 }
 738
 739                 // TODO: replicate the old behaviour of being able to vote for maps from different modes on multimode servers (possibly support it in gotomap too)
 740                 // maybe fallback instead of aborting if map name is invalid?
 741                 case "nextmap":
 742                 {
 743                         vote_command = ValidateMap(argv(startpos + 1), caller);
 744                         if (!vote_command)  return -1;
 745                         vote_parsed_command = strcat("nextmap ", vote_command);
 746                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 747
 748                         break;
 749                 }
 750
 751                 case "timelimit": // include restrictions on the maximum votable time limit
 752                 {
 753                         float timelimit_vote = stof(argv(startpos + 1));
 754                         if(timelimit_vote > autocvar_timelimit_max || timelimit_vote < autocvar_timelimit_min)
 755                         {
 756                                 print_to(caller, strcat("Invalid timelimit vote, accepted values are between ", ftos(autocvar_timelimit_min), " and ", ftos(autocvar_timelimit_max), "."));
 757                                 return -1;
 758                         }
 759                         timelimit_vote = bound(autocvar_timelimit_min, timelimit_vote, autocvar_timelimit_max);
 760                         vote_parsed_command = strcat("timelimit ", ftos(timelimit_vote));
 761                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 762
 763                         break;
 764                 }
 765
 766                 case "restart":
 767                 {
 768                         // add a delay so that vote result can be seen and announcer can be heard
 769                         // if the vote is accepted
 770                         vote_parsed_command = strcat("defer 1 ", vote_command);
 771                         vote_parsed_display = strzone(strcat("^1", vote_command));
 772
 773                         break;
 774                 }
 775
 776                 default:
 777                 {
 778                         vote_parsed_command = vote_command;
 779                         vote_parsed_display = strzone(strcat("^1", vote_command));
 780
 781                         break;
 782                 }
 783         }
 784
 785         return 1;
 786 }
 787
 788
 789 // =======================
 790 //  Command Sub-Functions
 791 // =======================
 792
 793 void VoteCommand_abstain(int request, entity caller)  // CLIENT ONLY
 794 {
 795         switch (request)
 796         {
 797                 case CMD_REQUEST_COMMAND:
 798                 {
 799                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 800                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 801                         {
 802                                 print_to(caller, "^1You have already voted.");
 803                         }
 804
 805                         else  // everything went okay, continue changing vote
 806                         {
 807                                 print_to(caller, "^1You abstained from your vote.");
 808                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 809                                 msg_entity = caller;
 810                                 if (!autocvar_sv_vote_singlecount)
 811                                         VoteCount(false);
 812                         }
 813
 814                         return;
 815                 }
 816
 817                 default:
 818                 case CMD_REQUEST_USAGE:
 819                 {
 820                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 821                         print_to(caller, "  No arguments required.");
 822                         return;
 823                 }
 824         }
 825 }
 826
 827 void print_available_commands_to(entity caller)
 828 {
 829         print_to(caller, strcat("You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
 830 }
 831
 832 void VoteCommand_call(int request, entity caller, int argc, string vote_command)  // BOTH
 833 {
 834         switch (request)
 835         {
 836                 case CMD_REQUEST_COMMAND:
 837                 {
 838                         float tmp_playercount = 0;
 839                         int parse_error;
 840
 841                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 842
 843                         if (!autocvar_sv_vote_call && caller)
 844                         {
 845                                 print_to(caller, "^1Vote calling is not allowed.");
 846                         }
 847                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 848                         {
 849                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 850                         }
 851                         else if (vote_called)
 852                         {
 853                                 print_to(caller, "^1There is already a vote called.");
 854                         }
 855                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 856                         {
 857                                 print_to(caller, "^1Only players can call a vote.");
 858                         }
 859                         else if (caller && !IS_CLIENT(caller))
 860                         {
 861                                 print_to(caller, "^1Only connected clients can vote.");
 862                         }
 863                         else if (timeout_status && vote_command != "timein")
 864                         {
 865                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 866                         }
 867                         else if (caller && (time < caller.vote_waittime))
 868                         {
 869                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 870                         }
 871                         else if (!VoteCommand_checknasty(vote_command))
 872                         {
 873                                 print_to(caller, "^1Syntax error in command.");
 874                         }
 875                         else if ((parse_error = VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc)) <= 0)
 876                         {
 877                                 if(parse_error == 0)
 878                                 {
 879                                         if (vote_called_command == "")
 880                                                 VoteCommand_call(CMD_REQUEST_USAGE, caller, argc, vote_command);
 881                                         else
 882                                                 print_to(caller, "^1This command is not acceptable or not available.");
 883                                 }
 884                         }
 885                         else  // everything went okay, continue with calling the vote
 886                         {
 887                                 vote_caller = caller;  // remember who called the vote
 888                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 889                                 vote_called = VOTE_NORMAL;
 890                                 vote_called_command = strzone(vote_parsed_command);
 891                                 vote_called_display = strzone(vote_parsed_display);
 892                                 vote_endtime = time + autocvar_sv_vote_timeout;
 893
 894                                 if (caller)
 895                                 {
 896                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 897                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 898                                         msg_entity = caller;
 899                                 }
 900
 901                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++tmp_playercount; });
 902
 903                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 904                                 if (autocvar_sv_eventlog)
 905                                         GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 906                                 Nagger_VoteChanged();
 907                                 VoteCount(true);  // needed if you are the only one
 908
 909                                 if (tmp_playercount > 1 && vote_called != VOTE_NULL)
 910                                         Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_VOTE_CALL);
 911                         }
 912
 913                         return;
 914                 }
 915
 916                 default:
 917                 case CMD_REQUEST_USAGE:
 918                 {
 919                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call <command>"));
 920                         print_to(caller, "  Where <command> is the command to request a vote upon.");
 921                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 922                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 923                         print_available_commands_to(caller);
 924                         print_to(caller, "Shortcuts: ^2vcall <command>, vend, vmap, vkick, ...");
 925                         return;
 926                 }
 927         }
 928 }
 929
 930 void VoteCommand_master(int request, entity caller, int argc, string vote_command)  // CLIENT ONLY
 931 {
 932         switch (request)
 933         {
 934                 case CMD_REQUEST_COMMAND:
 935                 {
 936                         if (autocvar_sv_vote_master)
 937                         {
 938                                 switch (strtolower(argv(2)))
 939                                 {
 940                                         case "do":
 941                                         {
 942                                                 int parse_error;
 943                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 944
 945                                                 if (!caller.vote_master)
 946                                                         print_to(caller, "^1You do not have vote master privileges.");
 947                                                 else if (!VoteCommand_checknasty(vote_command))
 948                                                 {
 949                                                         print_to(caller, "^1Syntax error in command.");
 950                                                 }
 951                                                 else if ((parse_error = VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc)) <= 0)
 952                                                 {
 953                                                         if(parse_error == 0)
 954                                                         {
 955                                                                 if (vote_called_command == "")
 956                                                                         VoteCommand_master(CMD_REQUEST_USAGE, caller, argc, vote_command);
 957                                                                 else
 958                                                                         print_to(caller, "^1This command is not acceptable or not available.");
 959                                                         }
 960                                                 }
 961                                                 else  // everything went okay, proceed with command
 962                                                 {
 963                                                         localcmd(strcat(vote_parsed_command, "\n"));
 964                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 965                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 966                                                         if (autocvar_sv_eventlog)
 967                                                                 GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display));
 968                                                 }
 969
 970                                                 return;
 971                                         }
 972
 973                                         case "login":
 974                                         {
 975                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 976                                                 else if (caller.vote_master)
 977                                                 {
 978                                                         print_to(caller, "^1You are already logged in as vote master.");
 979                                                 }
 980                                                 else if (autocvar_sv_vote_master_password != argv(3))
 981                                                 {
 982                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 983                                                 }
 984                                                 else  // everything went okay, proceed with giving this player master privilages
 985                                                 {
 986                                                         caller.vote_master = true;
 987                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 988                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 989                                                         if (autocvar_sv_eventlog)
 990                                                                 GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid)));
 991                                                 }
 992
 993                                                 return;
 994                                         }
 995
 996                                         default:  // calling a vote for master
 997                                         {
 998                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 999                                                 else if (vote_called)
1000                                                 {
1001                                                         print_to(caller, "^1There is already a vote called.");
1002                                                 }
1003                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
1004                                                 {
1005                                                         print_to(caller, "^1Only players can call a vote.");
1006                                                 }
1007                                                 else if (timeout_status)
1008                                                 {
1009                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
1010                                                 }
1011                                                 else  // everything went okay, continue with creating vote
1012                                                 {
1013                                                         vote_caller = caller;
1014                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
1015                                                         vote_called = VOTE_MASTER;
1016                                                         vote_called_command = strzone("XXX");
1017                                                         vote_called_display = strzone("^3master");
1018                                                         vote_endtime = time + autocvar_sv_vote_timeout;
1019
1020                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
1021                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
1022
1023                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
1024                                                         if (autocvar_sv_eventlog)
1025                                                                 GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
1026                                                         Nagger_VoteChanged();
1027                                                         VoteCount(true);  // needed if you are the only one
1028                                                 }
1029
1030                                                 return;
1031                                         }
1032                                 }
1033                         }
1034                         else { print_to(caller, "^1Master control of voting is not allowed."); }
1035
1036                         return;
1037                 }
1038
1039                 default:
1040                 case CMD_REQUEST_USAGE:
1041                 {
1042                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [<action> [<command> | <password>]]"));
1043                         print_to(caller, "  If <action> is left blank, it calls a vote for you to become master.");
1044                         print_to(caller, "  Otherwise it can be either 'do' (to run <command>) or 'login' as master.");
1045                         return;
1046                 }
1047         }
1048 }
1049
1050 void VoteCommand_no(int request, entity caller)  // CLIENT ONLY
1051 {
1052         switch (request)
1053         {
1054                 case CMD_REQUEST_COMMAND:
1055                 {
1056                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1057                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1058                         {
1059                                 print_to(caller, "^1You have already voted.");
1060                         }
1061                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1062                         {
1063                                 VoteStop(caller);
1064                         }
1065
1066                         else  // everything went okay, continue changing vote
1067                         {
1068                                 print_to(caller, "^1You rejected the vote.");
1069                                 caller.vote_selection = VOTE_SELECT_REJECT;
1070                                 msg_entity = caller;
1071                                 if (!autocvar_sv_vote_singlecount)
1072                                         VoteCount(false);
1073                         }
1074
1075                         return;
1076                 }
1077
1078                 default:
1079                 case CMD_REQUEST_USAGE:
1080                 {
1081                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1082                         print_to(caller, "  No arguments required.");
1083                         return;
1084                 }
1085         }
1086 }
1087
1088 void VoteCommand_status(int request, entity caller)  // BOTH
1089 {
1090         switch (request)
1091         {
1092                 case CMD_REQUEST_COMMAND:
1093                 {
1094                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1095                         else print_to(caller, "^1No vote called.");
1096
1097                         return;
1098                 }
1099
1100                 default:
1101                 case CMD_REQUEST_USAGE:
1102                 {
1103                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1104                         print_to(caller, "  No arguments required.");
1105                         return;
1106                 }
1107         }
1108 }
1109
1110 void VoteCommand_stop(int request, entity caller)  // BOTH
1111 {
1112         switch (request)
1113         {
1114                 case CMD_REQUEST_COMMAND:
1115                 {
1116                         if (!vote_called)   print_to(caller, "^1No vote called.");
1117                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1118                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1119                         return;
1120                 }
1121
1122                 default:
1123                 case CMD_REQUEST_USAGE:
1124                 {
1125                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1126                         print_to(caller, "  No arguments required.");
1127                         return;
1128                 }
1129         }
1130 }
1131
1132 void VoteCommand_yes(int request, entity caller)  // CLIENT ONLY
1133 {
1134         switch (request)
1135         {
1136                 case CMD_REQUEST_COMMAND:
1137                 {
1138                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1139                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1140                         {
1141                                 print_to(caller, "^1You have already voted.");
1142                         }
1143                         else  // everything went okay, continue changing vote
1144                         {
1145                                 print_to(caller, "^1You accepted the vote.");
1146                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1147                                 msg_entity = caller;
1148                                 if (!autocvar_sv_vote_singlecount)
1149                                         VoteCount(false);
1150                         }
1151
1152                         return;
1153                 }
1154
1155                 default:
1156                 case CMD_REQUEST_USAGE:
1157                 {
1158                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1159                         print_to(caller, "  No arguments required.");
1160                         return;
1161                 }
1162         }
1163 }
1164
1165 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1166 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1167 void VoteCommand_(int request)
1168 {
1169     switch(request)
1170     {
1171         case CMD_REQUEST_COMMAND:
1172         {
1173
1174             return;
1175         }
1176
1177         default:
1178         case CMD_REQUEST_USAGE:
1179         {
1180             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1181             print_to(caller, "  No arguments required.");
1182             return;
1183         }
1184     }
1185 }
1186 */
1187
1188
1189 // ================================
1190 //  Macro system for vote commands
1191 // ================================
1192
1193 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1194 #define VOTE_COMMANDS(request, caller, arguments, command) \
1195         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1196         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1197         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1198         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1199         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1200         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1201         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1202         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1203         /* nothing */
1204
1205 void VoteCommand_macro_help(entity caller, int argc)
1206 {
1207         string command_origin = GetCommandPrefix(caller);
1208
1209         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1210         {
1211                 print_to(caller, "\nVoting commands:\n");
1212                 #define VOTE_COMMAND(name, function, description, assignment) \
1213                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1214
1215                 VOTE_COMMANDS(0, caller, 0, "");
1216                 #undef VOTE_COMMAND
1217
1218                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote <command>^7, where possible commands are listed above.\n"));
1219                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help <command>"));
1220                 print_available_commands_to(caller);
1221         }
1222         else  // usage for individual command
1223         {
1224                 #define VOTE_COMMAND(name, function, description, assignment) \
1225                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1226
1227                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1228                 #undef VOTE_COMMAND
1229
1230                 string cvarname = strcat("sv_vote_command_help_", argv(2));
1231                 if(cvar_type(cvarname) & CVAR_TYPEFLAG_EXISTS)
1232                         wordwrap_sprint(caller, cvar_string(cvarname), 1000);
1233                 else if (argv(2) != "")
1234                         print_to(caller, "No documentation exists for this vote");
1235         }
1236 }
1237
1238 float VoteCommand_macro_command(entity caller, int argc, string vote_command)
1239 {
1240         #define VOTE_COMMAND(name, function, description, assignment) \
1241                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1242
1243         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1244         #undef VOTE_COMMAND
1245
1246         return false;
1247 }
1248
1249
1250 // ======================================
1251 //  Main function handling vote commands
1252 // ======================================
1253
1254 void VoteCommand(int request, entity caller, int argc, string vote_command)
1255 {
1256         // Guide for working with argc arguments by example:
1257         // argc:   1    - 2      - 3     - 4
1258         // argv:   0    - 1      - 2     - 3
1259         // cmd     vote - master - login - password
1260
1261         switch (request)
1262         {
1263                 case CMD_REQUEST_COMMAND:
1264                 {
1265                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1266                 }
1267
1268                 default:
1269                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1270                 case CMD_REQUEST_USAGE:
1271                 {
1272                         VoteCommand_macro_help(caller, argc);
1273                         return;
1274                 }
1275         }
1276 }