qcsrc/server/command/vote.qc

   1 #include "../../common/command/command.qh"
   2 #include "vote.qh"
   3
   4 #include "common.qh"
   5
   6 #include "../g_damage.qh"
   7 #include "../g_world.qh"
   8 #include "../race.qh"
   9 #include "../round_handler.qh"
  10 #include "../scores.qh"
  11
  12 #include "../mutators/all.qh"
  13
  14 #include "../../common/constants.qh"
  15 #include "../../common/mapinfo.qh"
  16 #include "../../common/notifications.qh"
  17 #include "../../common/playerstats.qh"
  18 #include "../../common/util.qh"
  19
  20 // =============================================
  21 //  Server side voting code, reworked by Samual
  22 //  Last updated: December 27th, 2011
  23 // =============================================
  24
  25 //  Nagger for players to know status of voting
  26 bool Nagger_SendEntity(entity this, entity to, float sendflags)
  27 {
  28         int nags, i, f, b;
  29         entity e;
  30         WriteHeader(MSG_ENTITY, ENT_CLIENT_NAGGER);
  31
  32         // bits:
  33         //   1 = ready
  34         //   2 = player needs to ready up
  35         //   4 = vote
  36         //   8 = player needs to vote
  37         //  16 = warmup
  38         // sendflags:
  39         //  64 = vote counts
  40         // 128 = vote string
  41
  42         nags = 0;
  43         if (readycount)
  44         {
  45                 nags |= BIT(0);
  46                 if (to.ready == 0) nags |= BIT(1);
  47         }
  48         if (vote_called)
  49         {
  50                 nags |= BIT(2);
  51                 if (to.vote_selection == 0) nags |= BIT(3);
  52         }
  53         if (warmup_stage) nags |= BIT(4);
  54
  55         if (sendflags & BIT(6)) nags |= BIT(6);
  56
  57         if (sendflags & BIT(7)) nags |= BIT(7);
  58
  59         if (!(nags & 4))  // no vote called? send no string
  60                 nags &= ~(BIT(6) | BIT(7));
  61
  62         WriteByte(MSG_ENTITY, nags);
  63
  64         if (nags & BIT(6))
  65         {
  66                 WriteByte(MSG_ENTITY, vote_accept_count);
  67                 WriteByte(MSG_ENTITY, vote_reject_count);
  68                 WriteByte(MSG_ENTITY, vote_needed_overall);
  69                 WriteChar(MSG_ENTITY, to.vote_selection);
  70         }
  71
  72         if (nags & BIT(7)) WriteString(MSG_ENTITY, vote_called_display);
  73
  74         if (nags & 1)
  75         {
  76                 for (i = 1; i <= maxclients; i += 8)
  77                 {
  78                         for (f = 0, e = edict_num(i), b = 1; b < 256; b *= 2, e = nextent(e))
  79                                 if (!IS_REAL_CLIENT(e) || e.ready) f |= b;
  80                         WriteByte(MSG_ENTITY, f);
  81                 }
  82         }
  83
  84         return true;
  85 }
  86
  87 void Nagger_Init()
  88 {
  89         Net_LinkEntity(nagger = new(nagger), false, 0, Nagger_SendEntity);
  90         make_pure(nagger);
  91 }
  92
  93 void Nagger_VoteChanged()
  94 {
  95         if (nagger) nagger.SendFlags |= BIT(7);
  96 }
  97
  98 void Nagger_VoteCountChanged()
  99 {
 100         if (nagger) nagger.SendFlags |= BIT(6);
 101 }
 102
 103 void Nagger_ReadyCounted()
 104 {
 105         if (nagger) nagger.SendFlags |= BIT(0);
 106 }
 107
 108 // If the vote_caller is still here, return their name, otherwise vote_caller_name
 109 string OriginalCallerName()
 110 {
 111         if (IS_REAL_CLIENT(vote_caller)) return vote_caller.netname;
 112         return vote_caller_name;
 113 }
 114
 115 // =======================
 116 //  Game logic for voting
 117 // =======================
 118
 119 void VoteReset()
 120 {
 121         entity tmp_player;
 122
 123         FOR_EACH_CLIENT(tmp_player)
 124         {
 125                 tmp_player.vote_selection = 0;
 126         }
 127
 128         if (vote_called)
 129         {
 130                 strunzone(vote_called_command);
 131                 strunzone(vote_called_display);
 132                 strunzone(vote_caller_name);
 133         }
 134
 135         vote_called = VOTE_NULL;
 136         vote_caller = world;
 137         vote_caller_name = string_null;
 138         vote_endtime = 0;
 139
 140         vote_called_command = string_null;
 141         vote_called_display = string_null;
 142
 143         vote_parsed_command = string_null;
 144         vote_parsed_display = string_null;
 145
 146         Nagger_VoteChanged();
 147 }
 148
 149 void VoteStop(entity stopper)
 150 {
 151         bprint("\{1}^2* ^3", GetCallerName(stopper), "^2 stopped ^3", OriginalCallerName(), "^2's vote\n");
 152         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vstop:", ftos(stopper.playerid)));
 153         // Don't force them to wait for next vote, this way they can e.g. correct their vote.
 154         if ((vote_caller) && (stopper == vote_caller))   vote_caller.vote_waittime = time + autocvar_sv_vote_stop;
 155         VoteReset();
 156 }
 157
 158 void VoteAccept()
 159 {
 160         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ^1", vote_called_display, "^2 was accepted\n");
 161
 162         if ((vote_called == VOTE_MASTER) && vote_caller) vote_caller.vote_master = 1;
 163         else localcmd(strcat(vote_called_command, "\n"));
 164
 165         if (vote_caller)   vote_caller.vote_waittime = 0;  // people like your votes, you don't need to wait to vote again
 166
 167         VoteReset();
 168         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_ACCEPT);
 169 }
 170
 171 void VoteReject()
 172 {
 173         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 was rejected\n");
 174         VoteReset();
 175         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 176 }
 177
 178 void VoteTimeout()
 179 {
 180         bprint("\{1}^2* ^3", OriginalCallerName(), "^2's vote for ", vote_called_display, "^2 timed out\n");
 181         VoteReset();
 182         Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_FAIL);
 183 }
 184
 185 void VoteSpam(float notvoters, float mincount, string result)
 186 {
 187         bprint(strcat(
 188                 strcat("\{1}^2* vote results: ^1", ftos(vote_accept_count)),
 189                 strcat("^2:^1", ftos(vote_reject_count)),
 190                 ((mincount >= 0) ? strcat("^2 (^1", ftos(mincount), "^2 needed)") : "^2"),
 191                 strcat(", ^1", ftos(vote_abstain_count), "^2 didn't care"),
 192                 strcat(", ^1", ftos(notvoters), strcat("^2 didn't ", ((mincount >= 0) ? "" : "have to "), "vote\n"))));
 193
 194         if (autocvar_sv_eventlog)
 195         {
 196                 GameLogEcho(strcat(
 197                         strcat(":vote:v", result, ":", ftos(vote_accept_count)),
 198                         strcat(":", ftos(vote_reject_count)),
 199                         strcat(":", ftos(vote_abstain_count)),
 200                         strcat(":", ftos(notvoters)),
 201                         strcat(":", ftos(mincount))));
 202         }
 203 }
 204
 205 void VoteCount(float first_count)
 206 {
 207         // declarations
 208         vote_accept_count = vote_reject_count = vote_abstain_count = 0;
 209
 210         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 211             || ((autocvar_sv_vote_nospectators == 1) && (warmup_stage || gameover))
 212             || (autocvar_sv_vote_nospectators == 0));
 213
 214         float vote_player_count = 0, notvoters = 0;
 215         float vote_real_player_count = 0, vote_real_accept_count = 0;
 216         float vote_real_reject_count = 0, vote_real_abstain_count = 0;
 217         float vote_needed_of_voted, final_needed_votes;
 218         float vote_factor_overall, vote_factor_of_voted;
 219
 220         entity tmp_player;
 221
 222         Nagger_VoteCountChanged();
 223
 224         // add up all the votes from each connected client
 225         FOR_EACH_REALCLIENT(tmp_player)
 226         {
 227                 ++vote_player_count;
 228                 if (IS_PLAYER(tmp_player))   ++vote_real_player_count;
 229                 switch (tmp_player.vote_selection)
 230                 {
 231                         case VOTE_SELECT_REJECT:
 232                         { ++vote_reject_count;
 233                           { if (IS_PLAYER(tmp_player)) ++vote_real_reject_count; } break;
 234                         }
 235                         case VOTE_SELECT_ACCEPT:
 236                         { ++vote_accept_count;
 237                           { if (IS_PLAYER(tmp_player)) ++vote_real_accept_count; } break;
 238                         }
 239                         case VOTE_SELECT_ABSTAIN:
 240                         { ++vote_abstain_count;
 241                           { if (IS_PLAYER(tmp_player)) ++vote_real_abstain_count; } break;
 242                         }
 243                         default: break;
 244                 }
 245         }
 246
 247         // Check to see if there are enough players on the server to allow master voting... otherwise, vote master could be used for evil.
 248         if ((vote_called == VOTE_MASTER) && autocvar_sv_vote_master_playerlimit > vote_player_count)
 249         {
 250                 if (vote_caller)   vote_caller.vote_waittime = 0;
 251                 print_to(vote_caller, "^1There are not enough players on this server to allow you to become vote master.");
 252                 VoteReset();
 253                 return;
 254         }
 255
 256         // if spectators aren't allowed to vote and there are players in a match, then only count the players in the vote and ignore spectators.
 257         if (!spectators_allowed && (vote_real_player_count > 0))
 258         {
 259                 vote_accept_count = vote_real_accept_count;
 260                 vote_reject_count = vote_real_reject_count;
 261                 vote_abstain_count = vote_real_abstain_count;
 262                 vote_player_count = vote_real_player_count;
 263         }
 264
 265         // people who have no opinion in any way :D
 266         notvoters = (vote_player_count - vote_accept_count - vote_reject_count - vote_abstain_count);
 267
 268         // determine the goal for the vote to be passed or rejected normally
 269         vote_factor_overall = bound(0.5, autocvar_sv_vote_majority_factor, 0.999);
 270         vote_needed_overall = floor((vote_player_count - vote_abstain_count) * vote_factor_overall) + 1;
 271
 272         // if the vote times out, determine the amount of votes needed of the people who actually already voted
 273         vote_factor_of_voted = bound(0.5, autocvar_sv_vote_majority_factor_of_voted, 0.999);
 274         vote_needed_of_voted = floor((vote_accept_count + vote_reject_count) * vote_factor_of_voted) + 1;
 275
 276         // are there any players at all on the server? it could be an admin vote
 277         if (vote_player_count == 0 && first_count)
 278         {
 279                 VoteSpam(0, -1, "yes");  // no players at all, just accept it
 280                 VoteAccept();
 281                 return;
 282         }
 283
 284         // since there ARE players, finally calculate the result of the vote
 285         if (vote_accept_count >= vote_needed_overall)
 286         {
 287                 VoteSpam(notvoters, -1, "yes");  // there is enough acceptions to pass the vote
 288                 VoteAccept();
 289                 return;
 290         }
 291
 292         if (vote_reject_count > vote_player_count - vote_abstain_count - vote_needed_overall)
 293         {
 294                 VoteSpam(notvoters, -1, "no");  // there is enough rejections to deny the vote
 295                 VoteReject();
 296                 return;
 297         }
 298
 299         // there is not enough votes in either direction, now lets just calculate what the voters have said
 300         if (time > vote_endtime)
 301         {
 302                 final_needed_votes = vote_needed_overall;
 303
 304                 if (autocvar_sv_vote_majority_factor_of_voted)
 305                 {
 306                         if (vote_accept_count >= vote_needed_of_voted)
 307                         {
 308                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "yes");
 309                                 VoteAccept();
 310                                 return;
 311                         }
 312
 313                         if (vote_accept_count + vote_reject_count > 0)
 314                         {
 315                                 VoteSpam(notvoters, min(vote_needed_overall, vote_needed_of_voted), "no");
 316                                 VoteReject();
 317                                 return;
 318                         }
 319
 320                         final_needed_votes = min(vote_needed_overall, vote_needed_of_voted);
 321                 }
 322
 323                 // it didn't pass or fail, so not enough votes to even make a decision.
 324                 VoteSpam(notvoters, final_needed_votes, "timeout");
 325                 VoteTimeout();
 326         }
 327 }
 328
 329 void VoteThink()
 330 {
 331         if (vote_endtime > 0)        // a vote was called
 332         {
 333                 if (time > vote_endtime) // time is up
 334                         VoteCount(false);
 335         }
 336 }
 337
 338
 339 // =======================
 340 //  Game logic for warmup
 341 // =======================
 342
 343 // Resets the state of all clients, items, weapons, waypoints, ... of the map.
 344 void reset_map(float dorespawn)
 345 {
 346         SELFPARAM();
 347
 348         if (time <= game_starttime && round_handler_IsActive())
 349                 round_handler_Reset(game_starttime);
 350
 351         MUTATOR_CALLHOOK(reset_map_global);
 352
 353         for (entity e = world; (e = nextent(e)); )
 354         {
 355                 setself(e);
 356                 if (IS_NOT_A_CLIENT(self))
 357                 {
 358                         if (self.reset)
 359                         {
 360                                 self.reset();
 361                                 continue;
 362                         }
 363
 364                         if (self.team_saved) self.team = self.team_saved;
 365
 366                         if (self.flags & FL_PROJECTILE)  // remove any projectiles left
 367                                 remove(self);
 368                 }
 369         }
 370
 371         // Waypoints and assault start come LAST
 372         for (entity e = world; (e = nextent(e)); )
 373         {
 374                 setself(e);
 375                 if (IS_NOT_A_CLIENT(self))
 376                 {
 377                         if (self.reset2)
 378                         {
 379                                 self.reset2();
 380                                 continue;
 381                         }
 382                 }
 383         }
 384
 385         entity e;
 386         FOR_EACH_PLAYER(e)
 387         if (e.frozen) WITH(entity, self, e, Unfreeze(self));
 388
 389         // Moving the player reset code here since the player-reset depends
 390         // on spawnpoint entities which have to be reset first --blub
 391         if (dorespawn)
 392         {
 393                 if (!MUTATOR_CALLHOOK(reset_map_players))
 394                 {
 395                         FOR_EACH_CLIENT(e)  // reset all players
 396                         {
 397                                 setself(e);
 398                                 /*
 399                                 only reset players if a restart countdown is active
 400                                 this can either be due to cvar sv_ready_restart_after_countdown having set
 401                                 restart_mapalreadyrestarted to 1 after the countdown ended or when
 402                                 sv_ready_restart_after_countdown is not used and countdown is still running
 403                                 */
 404                                 if (restart_mapalreadyrestarted || (time < game_starttime))
 405                                 {
 406                                         // NEW: changed behaviour so that it prevents that previous spectators/observers suddenly spawn as players
 407                                         if (IS_PLAYER(self))
 408                                         {
 409                                                 // PlayerScore_Clear(self);
 410                                                 self.killcount = 0;
 411                                                 // stop the player from moving so that he stands still once he gets respawned
 412                                                 self.velocity = '0 0 0';
 413                                                 self.avelocity = '0 0 0';
 414                                                 self.movement = '0 0 0';
 415                                                 PutClientInServer();
 416                                         }
 417                                 }
 418                         }
 419
 420                         setself(this);
 421                 }
 422         }
 423 }
 424
 425 // Restarts the map after the countdown is over (and cvar sv_ready_restart_after_countdown is set)
 426 void ReadyRestart_think()
 427 {
 428         SELFPARAM();
 429         restart_mapalreadyrestarted = 1;
 430         reset_map(true);
 431         Score_ClearAll();
 432         remove(self);
 433 }
 434
 435 // Forces a restart of the game without actually reloading the map // this is a mess...
 436 void ReadyRestart_force()
 437 {
 438         entity tmp_player, restart_timer;
 439
 440         bprint("^1Server is restarting...\n");
 441
 442         VoteReset();
 443
 444         // clear overtime, we have to decrease timelimit to its original value again.
 445         if (checkrules_overtimesadded > 0 && g_race_qualifying != 2)   cvar_set("timelimit", ftos(autocvar_timelimit - (checkrules_overtimesadded * autocvar_timelimit_overtime)));
 446         checkrules_suddendeathend = checkrules_overtimesadded = checkrules_suddendeathwarning = 0;
 447
 448         readyrestart_happened = 1;
 449         game_starttime = time + RESTART_COUNTDOWN;
 450
 451         // clear player attributes
 452         FOR_EACH_CLIENT(tmp_player)
 453         {
 454                 tmp_player.alivetime = 0;
 455                 tmp_player.killcount = 0;
 456                 PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, -PS_GR_P_ADDVAL(tmp_player, PLAYERSTATS_ALIVETIME, 0));
 457         }
 458
 459         restart_mapalreadyrestarted = 0; // reset this var, needed when cvar sv_ready_restart_repeatable is in use
 460
 461         // disable the warmup global for the server
 462         warmup_stage = 0;                // once the game is restarted the game is in match stage
 463
 464         // reset the .ready status of all players (also spectators)
 465         FOR_EACH_REALCLIENT(tmp_player)
 466         {
 467                 tmp_player.ready = 0;
 468         }
 469         readycount = 0;
 470         Nagger_ReadyCounted();  // NOTE: this causes a resend of that entity, and will also turn off warmup state on the client
 471
 472         // lock teams with lockonrestart
 473         if (autocvar_teamplay_lockonrestart && teamplay)
 474         {
 475                 lockteams = 1;
 476                 bprint("^1The teams are now locked.\n");
 477         }
 478
 479         // initiate the restart-countdown-announcer entity
 480         if (autocvar_sv_ready_restart_after_countdown)
 481         {
 482                 restart_timer = spawn();
 483                 restart_timer.think = ReadyRestart_think;
 484                 restart_timer.nextthink = game_starttime;
 485         }
 486
 487         // after a restart every players number of allowed timeouts gets reset, too
 488         if (autocvar_sv_timeout)
 489         {
 490                 FOR_EACH_REALPLAYER(tmp_player)
 491                 {
 492                         tmp_player.allowed_timeouts = autocvar_sv_timeout_number;
 493                 }
 494                 // reset map immediately if this cvar is not set
 495                 if (!autocvar_sv_ready_restart_after_countdown)   reset_map(true); }
 496         if (autocvar_sv_eventlog)   GameLogEcho(":restart"); }
 497
 498 void ReadyRestart()
 499 {
 500         // no assault support yet...
 501         if (g_assault | gameover | intermission_running | race_completing) localcmd("restart\n");
 502         else localcmd("\nsv_hook_gamerestart\n");
 503
 504         // Reset ALL scores, but only do that at the beginning of the countdown if sv_ready_restart_after_countdown is off!
 505         // Otherwise scores could be manipulated during the countdown.
 506         if (!autocvar_sv_ready_restart_after_countdown)   Score_ClearAll();
 507         ReadyRestart_force();
 508 }
 509
 510 // Count the players who are ready and determine whether or not to restart the match
 511 void ReadyCount()
 512 {
 513         entity tmp_player;
 514         float ready_needed_factor, ready_needed_count;
 515         float t_ready = 0, t_players = 0;
 516
 517         FOR_EACH_REALCLIENT(tmp_player)
 518         {
 519                 if (IS_PLAYER(tmp_player) || tmp_player.caplayer == 1)
 520                 {
 521                         ++t_players;
 522                         if (tmp_player.ready)   ++t_ready; }
 523         }
 524
 525         readycount = t_ready;
 526
 527         Nagger_ReadyCounted();
 528
 529         ready_needed_factor = bound(0.5, cvar("g_warmup_majority_factor"), 0.999);
 530         ready_needed_count = floor(t_players * ready_needed_factor) + 1;
 531
 532         if (readycount >= ready_needed_count) ReadyRestart();
 533 }
 534
 535
 536 // ======================================
 537 //  Supporting functions for VoteCommand
 538 // ======================================
 539
 540 float Votecommand_check_assignment(entity caller, float assignment)
 541 {
 542         float from_server = (!caller);
 543
 544         if ((assignment == VC_ASGNMNT_BOTH)
 545             || ((!from_server && assignment == VC_ASGNMNT_CLIENTONLY)
 546             || (from_server && assignment == VC_ASGNMNT_SERVERONLY))) return true;
 547
 548         return false;
 549 }
 550
 551 string VoteCommand_extractcommand(string input, float startpos, float argc)
 552 {
 553         string output;
 554
 555         if ((argc - 1) < startpos) output = "";
 556         else output = substring(input, argv_start_index(startpos), argv_end_index(-1) - argv_start_index(startpos));
 557
 558         return output;
 559 }
 560
 561 float VoteCommand_checknasty(string vote_command)
 562 {
 563         if ((strstrofs(vote_command, ";", 0) >= 0)
 564             || (strstrofs(vote_command, "\n", 0) >= 0)
 565             || (strstrofs(vote_command, "\r", 0) >= 0)
 566             || (strstrofs(vote_command, "$", 0) >= 0)) return false;
 567
 568         return true;
 569 }
 570
 571 float VoteCommand_checkinlist(string vote_command, string list)
 572 {
 573         string l = strcat(" ", list, " ");
 574
 575         if (strstrofs(l, strcat(" ", vote_command, " "), 0) >= 0) return true;
 576
 577         return false;
 578 }
 579
 580 string ValidateMap(string validated_map, entity caller)
 581 {
 582         validated_map = MapInfo_FixName(validated_map);
 583
 584         if (!validated_map)
 585         {
 586                 print_to(caller, "This map is not available on this server.");
 587                 return string_null;
 588         }
 589
 590         if (!autocvar_sv_vote_override_mostrecent && caller)
 591         {
 592                 if (Map_IsRecent(validated_map))
 593                 {
 594                         print_to(caller, "This server does not allow for recent maps to be played again. Please be patient for some rounds.");
 595                         return string_null;
 596                 }
 597         }
 598
 599         if (!MapInfo_CheckMap(validated_map))
 600         {
 601                 print_to(caller, strcat("^1Invalid mapname, \"^3", validated_map, "^1\" does not support the current game mode."));
 602                 return string_null;
 603         }
 604
 605         return validated_map;
 606 }
 607
 608 float VoteCommand_checkargs(float startpos, float argc)
 609 {
 610         float p, q, check, minargs;
 611         string cvarname = strcat("sv_vote_command_restriction_", argv(startpos));
 612         string cmdrestriction = cvar_string(cvarname);  // note: this warns on undefined cvar. We want that.
 613         string charlist, arg;
 614         float checkmate;
 615
 616         if (cmdrestriction == "") return true;
 617
 618         ++startpos;  // skip command name
 619
 620         // check minimum arg count
 621
 622         // 0 args: argc == startpos
 623         // 1 args: argc == startpos + 1
 624         // ...
 625
 626         minargs = stof(cmdrestriction);
 627         if (argc - startpos < minargs) return false;
 628
 629         p = strstrofs(cmdrestriction, ";", 0);  // find first semicolon
 630
 631         for ( ; ; )
 632         {
 633                 // we know that at any time, startpos <= argc - minargs
 634                 // so this means: argc-minargs >= startpos >= argc, thus
 635                 // argc-minargs >= argc, thus minargs <= 0, thus all minargs
 636                 // have been seen already
 637
 638                 if (startpos >= argc) // all args checked? GOOD
 639                         break;
 640
 641                 if (p < 0)            // no more args? FAIL
 642                 {
 643                         // exception: exactly minargs left, this one included
 644                         if (argc - startpos == minargs) break;
 645
 646                         // otherwise fail
 647                         return false;
 648                 }
 649
 650                 // cut to next semicolon
 651                 q = strstrofs(cmdrestriction, ";", p + 1);  // find next semicolon
 652                 if (q < 0) charlist = substring(cmdrestriction, p + 1, -1);
 653                 else charlist = substring(cmdrestriction, p + 1, q - (p + 1));
 654
 655                 // in case we ever want to allow semicolons in VoteCommand_checknasty
 656                 // charlist = strreplace("^^", ";", charlist);
 657
 658                 if (charlist != "")
 659                 {
 660                         // verify the arg only contains allowed chars
 661                         arg = argv(startpos);
 662                         checkmate = strlen(arg);
 663                         for (check = 0; check < checkmate; ++check)
 664                                 if (strstrofs(charlist, substring(arg, check, 1), 0) < 0) return false;
 665                         // not allowed character
 666                         // all characters are allowed. FINE.
 667                 }
 668
 669                 ++startpos;
 670                 --minargs;
 671                 p = q;
 672         }
 673
 674         return true;
 675 }
 676
 677 float VoteCommand_parse(entity caller, string vote_command, string vote_list, float startpos, float argc)
 678 {
 679         string first_command;
 680
 681         first_command = argv(startpos);
 682
 683         /*printf("VoteCommand_parse(): Command: '%s', Length: %f.\n",
 684             substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)),
 685             strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos)))
 686         );*/
 687
 688         if (
 689             (autocvar_sv_vote_limit > 0)
 690             &&
 691             (strlen(substring(vote_command, argv_start_index(startpos), strlen(vote_command) - argv_start_index(startpos))) > autocvar_sv_vote_limit)
 692            )   return false;
 693
 694         if (!VoteCommand_checkinlist(first_command, vote_list)) return false;
 695
 696         if (!VoteCommand_checkargs(startpos, argc)) return false;
 697
 698         switch (first_command) // now go through and parse the proper commands to adjust as needed.
 699         {
 700                 case "kick":
 701                 case "kickban":    // catch all kick/kickban commands
 702                 {
 703                         entity victim = GetIndexedEntity(argc, (startpos + 1));
 704                         float accepted = VerifyClientEntity(victim, true, false);
 705
 706                         if (accepted > 0)
 707                         {
 708                                 string reason = ((argc > next_token) ? substring(vote_command, argv_start_index(next_token), strlen(vote_command) - argv_start_index(next_token)) : "No reason provided");
 709                                 string command_arguments;
 710
 711                                 if (first_command == "kickban") command_arguments = strcat(ftos(autocvar_g_ban_default_bantime), " ", ftos(autocvar_g_ban_default_masksize), " ~");
 712                                 else command_arguments = reason;
 713
 714                                 vote_parsed_command = strcat(first_command, " # ", ftos(num_for_edict(victim)), " ", command_arguments);
 715                                 vote_parsed_display = strcat("^1", vote_command, " (^7", victim.netname, "^1): ", reason);
 716                         }
 717                         else { print_to(caller, strcat("vcall: ", GetClientErrorString(accepted, argv(startpos + 1)), ".\n")); return false; }
 718
 719                         break;
 720                 }
 721
 722                 case "map":
 723                 case "chmap":
 724                 case "gotomap":  // re-direct all map selection commands to gotomap
 725                 {
 726                         vote_command = ValidateMap(argv(startpos + 1), caller);
 727                         if (!vote_command)   return false;
 728                         vote_parsed_command = strcat("gotomap ", vote_command);
 729                         vote_parsed_display = strzone(strcat("^1", vote_parsed_command));
 730
 731                         break;
 732                 }
 733
 734                 default:
 735                 {
 736                         vote_parsed_command = vote_command;
 737                         vote_parsed_display = strzone(strcat("^1", vote_command));
 738
 739                         break;
 740                 }
 741         }
 742
 743         return true;
 744 }
 745
 746
 747 // =======================
 748 //  Command Sub-Functions
 749 // =======================
 750
 751 void VoteCommand_abstain(float request, entity caller)  // CLIENT ONLY
 752 {
 753         switch (request)
 754         {
 755                 case CMD_REQUEST_COMMAND:
 756                 {
 757                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 758                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 759                         {
 760                                 print_to(caller, "^1You have already voted.");
 761                         }
 762
 763                         else  // everything went okay, continue changing vote
 764                         {
 765                                 print_to(caller, "^1You abstained from your vote.");
 766                                 caller.vote_selection = VOTE_SELECT_ABSTAIN;
 767                                 msg_entity = caller;
 768                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
 769
 770                         return;
 771                 }
 772
 773                 default:
 774                 case CMD_REQUEST_USAGE:
 775                 {
 776                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote abstain"));
 777                         print_to(caller, "  No arguments required.");
 778                         return;
 779                 }
 780         }
 781 }
 782
 783 void VoteCommand_call(float request, entity caller, float argc, string vote_command)  // BOTH
 784 {
 785         switch (request)
 786         {
 787                 case CMD_REQUEST_COMMAND:
 788                 {
 789                         float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 790                             || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 791                             || (autocvar_sv_vote_nospectators == 0));
 792
 793                         float tmp_playercount = 0;
 794                         entity tmp_player;
 795
 796                         vote_command = VoteCommand_extractcommand(vote_command, 2, argc);
 797
 798                         if (!autocvar_sv_vote_call && caller) { print_to(caller, "^1Vote calling is not allowed."); }
 799                         else if (!autocvar_sv_vote_gamestart && time < game_starttime)
 800                         {
 801                                 print_to(caller, "^1Vote calling is not allowed before the match has started.");
 802                         }
 803                         else if (vote_called)
 804                         {
 805                                 print_to(caller, "^1There is already a vote called.");
 806                         }
 807                         else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 808                         {
 809                                 print_to(caller, "^1Only players can call a vote.");
 810                         }
 811                         else if (caller && !IS_CLIENT(caller))
 812                         {
 813                                 print_to(caller, "^1Only connected clients can vote.");
 814                         }
 815                         else if (timeout_status)
 816                         {
 817                                 print_to(caller, "^1You can not call a vote while a timeout is active.");
 818                         }
 819                         else if (caller && (time < caller.vote_waittime))
 820                         {
 821                                 print_to(caller, strcat("^1You have to wait ^2", ftos(ceil(caller.vote_waittime - time)), "^1 seconds before you can again call a vote."));
 822                         }
 823                         else if (!VoteCommand_checknasty(vote_command))
 824                         {
 825                                 print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 826                         }
 827                         else if (!VoteCommand_parse(caller, vote_command, autocvar_sv_vote_commands, 2, argc))
 828                         {
 829                                 print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 830                         }
 831
 832                         else  // everything went okay, continue with calling the vote
 833                         {
 834                                 vote_caller = caller;  // remember who called the vote
 835                                 vote_caller_name = strzone(GetCallerName(vote_caller));
 836                                 vote_called = VOTE_NORMAL;
 837                                 vote_called_command = strzone(vote_parsed_command);
 838                                 vote_called_display = strzone(vote_parsed_display);
 839                                 vote_endtime = time + autocvar_sv_vote_timeout;
 840
 841                                 if (caller)
 842                                 {
 843                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 844                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 845                                         msg_entity = caller;
 846                                 }
 847
 848                                 FOR_EACH_REALCLIENT(tmp_player)
 849                                 {
 850                                         ++tmp_playercount;
 851                                 }
 852                                 if (tmp_playercount > 1)   Send_Notification(NOTIF_ALL, world, MSG_ANNCE, ANNCE_VOTE_CALL);  // don't announce a "vote now" sound if player is alone
 853
 854                                 bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote for ", vote_called_display, "\n");
 855                                 if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 856                                 Nagger_VoteChanged();
 857                                 VoteCount(true);  // needed if you are the only one
 858                         }
 859
 860                         return;
 861                 }
 862
 863                 default:
 864                 case CMD_REQUEST_USAGE:
 865                 {
 866                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote call command"));
 867                         print_to(caller, "  Where 'command' is the command to request a vote upon.");
 868                         print_to(caller, strcat("Examples: ", GetCommandPrefix(caller), " vote call gotomap dance"));
 869                         print_to(caller, strcat("          ", GetCommandPrefix(caller), " vote call endmatch"));
 870                         return;
 871                 }
 872         }
 873 }
 874
 875 void VoteCommand_master(float request, entity caller, float argc, string vote_command)  // CLIENT ONLY
 876 {
 877         switch (request)
 878         {
 879                 case CMD_REQUEST_COMMAND:
 880                 {
 881                         if (autocvar_sv_vote_master)
 882                         {
 883                                 switch (strtolower(argv(2)))
 884                                 {
 885                                         case "do":
 886                                         {
 887                                                 vote_command = VoteCommand_extractcommand(vote_command, 3, argc);
 888
 889                                                 if (!caller.vote_master) { print_to(caller, "^1You do not have vote master privelages."); }
 890                                                 else if (!VoteCommand_checknasty(vote_command))
 891                                                 {
 892                                                         print_to(caller, "^1Syntax error in command, see 'vhelp' for more info.");
 893                                                 }
 894                                                 else if (!VoteCommand_parse(caller, vote_command, strcat(autocvar_sv_vote_commands, " ", autocvar_sv_vote_master_commands), 3, argc))
 895                                                 {
 896                                                         print_to(caller, "^1This command is not acceptable, see 'vhelp' for more info.");
 897                                                 }
 898
 899                                                 else  // everything went okay, proceed with command
 900                                                 {
 901                                                         localcmd(strcat(vote_parsed_command, "\n"));
 902                                                         print_to(caller, strcat("Executing command '", vote_parsed_display, "' on server."));
 903                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 used their ^3master^2 status to do \"^2", vote_parsed_display, "^2\".\n");
 904                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vdo:", ftos(caller.playerid), ":", vote_parsed_display)); }
 905
 906                                                 return;
 907                                         }
 908
 909                                         case "login":
 910                                         {
 911                                                 if (autocvar_sv_vote_master_password == "") { print_to(caller, "^1Login to vote master is not allowed."); }
 912                                                 else if (caller.vote_master)
 913                                                 {
 914                                                         print_to(caller, "^1You are already logged in as vote master.");
 915                                                 }
 916                                                 else if (autocvar_sv_vote_master_password != argv(3))
 917                                                 {
 918                                                         print_to(caller, strcat("Rejected vote master login from ", GetCallerName(caller)));
 919                                                 }
 920
 921                                                 else  // everything went okay, proceed with giving this player master privilages
 922                                                 {
 923                                                         caller.vote_master = true;
 924                                                         print_to(caller, strcat("Accepted vote master login from ", GetCallerName(caller)));
 925                                                         bprint("\{1}^2* ^3", GetCallerName(caller), "^2 logged in as ^3master^2\n");
 926                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vlogin:", ftos(caller.playerid))); }
 927
 928                                                 return;
 929                                         }
 930
 931                                         default:  // calling a vote for master
 932                                         {
 933                                                 float spectators_allowed = ((autocvar_sv_vote_nospectators != 2)
 934                                                     || ((autocvar_sv_vote_nospectators == 1) && warmup_stage)
 935                                                     || (autocvar_sv_vote_nospectators == 0));
 936
 937                                                 if (!autocvar_sv_vote_master_callable) { print_to(caller, "^1Vote to become vote master is not allowed."); }
 938                                                 else if (vote_called)
 939                                                 {
 940                                                         print_to(caller, "^1There is already a vote called.");
 941                                                 }
 942                                                 else if (!spectators_allowed && (caller && !IS_PLAYER(caller)))
 943                                                 {
 944                                                         print_to(caller, "^1Only players can call a vote.");
 945                                                 }
 946                                                 else if (timeout_status)
 947                                                 {
 948                                                         print_to(caller, "^1You can not call a vote while a timeout is active.");
 949                                                 }
 950
 951                                                 else  // everything went okay, continue with creating vote
 952                                                 {
 953                                                         vote_caller = caller;
 954                                                         vote_caller_name = strzone(GetCallerName(vote_caller));
 955                                                         vote_called = VOTE_MASTER;
 956                                                         vote_called_command = strzone("XXX");
 957                                                         vote_called_display = strzone("^3master");
 958                                                         vote_endtime = time + autocvar_sv_vote_timeout;
 959
 960                                                         caller.vote_selection = VOTE_SELECT_ACCEPT;
 961                                                         caller.vote_waittime = time + autocvar_sv_vote_wait;
 962
 963                                                         bprint("\{1}^2* ^3", OriginalCallerName(), "^2 calls a vote to become ^3master^2.\n");
 964                                                         if (autocvar_sv_eventlog)   GameLogEcho(strcat(":vote:vcall:", ftos(vote_caller.playerid), ":", vote_called_display));
 965                                                         Nagger_VoteChanged();
 966                                                         VoteCount(true);  // needed if you are the only one
 967                                                 }
 968
 969                                                 return;
 970                                         }
 971                                 }
 972                         }
 973                         else { print_to(caller, "^1Master control of voting is not allowed."); }
 974
 975                         return;
 976                 }
 977
 978                 default:
 979                 case CMD_REQUEST_USAGE:
 980                 {
 981                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote master [action [command | password]]"));
 982                         print_to(caller, "  If action is left blank, it calls a vote for you to become master.");
 983                         print_to(caller, "  Otherwise the actions are either 'do' a command or 'login' as master.");
 984                         return;
 985                 }
 986         }
 987 }
 988
 989 void VoteCommand_no(float request, entity caller)  // CLIENT ONLY
 990 {
 991         switch (request)
 992         {
 993                 case CMD_REQUEST_COMMAND:
 994                 {
 995                         if (!vote_called) { print_to(caller, "^1No vote called."); }
 996                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
 997                         {
 998                                 print_to(caller, "^1You have already voted.");
 999                         }
1000                         else if (((caller == vote_caller) || caller.vote_master) && autocvar_sv_vote_no_stops_vote)
1001                         {
1002                                 VoteStop(caller);
1003                         }
1004
1005                         else  // everything went okay, continue changing vote
1006                         {
1007                                 print_to(caller, "^1You rejected the vote.");
1008                                 caller.vote_selection = VOTE_SELECT_REJECT;
1009                                 msg_entity = caller;
1010                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1011
1012                         return;
1013                 }
1014
1015                 default:
1016                 case CMD_REQUEST_USAGE:
1017                 {
1018                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote no"));
1019                         print_to(caller, "  No arguments required.");
1020                         return;
1021                 }
1022         }
1023 }
1024
1025 void VoteCommand_status(float request, entity caller)  // BOTH
1026 {
1027         switch (request)
1028         {
1029                 case CMD_REQUEST_COMMAND:
1030                 {
1031                         if (vote_called) print_to(caller, strcat("^7Vote for ", vote_called_display, "^7 called by ^7", OriginalCallerName(), "^7."));
1032                         else print_to(caller, "^1No vote called.");
1033
1034                         return;
1035                 }
1036
1037                 default:
1038                 case CMD_REQUEST_USAGE:
1039                 {
1040                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote status"));
1041                         print_to(caller, "  No arguments required.");
1042                         return;
1043                 }
1044         }
1045 }
1046
1047 void VoteCommand_stop(float request, entity caller)  // BOTH
1048 {
1049         switch (request)
1050         {
1051                 case CMD_REQUEST_COMMAND:
1052                 {
1053                         if (!vote_called)   print_to(caller, "^1No vote called.");
1054                         else if ((caller == vote_caller) || !caller || caller.vote_master)   VoteStop(caller);
1055                         else   print_to(caller, "^1You are not allowed to stop that vote.");
1056                         return;
1057                 }
1058
1059                 default:
1060                 case CMD_REQUEST_USAGE:
1061                 {
1062                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote stop"));
1063                         print_to(caller, "  No arguments required.");
1064                         return;
1065                 }
1066         }
1067 }
1068
1069 void VoteCommand_yes(float request, entity caller)  // CLIENT ONLY
1070 {
1071         switch (request)
1072         {
1073                 case CMD_REQUEST_COMMAND:
1074                 {
1075                         if (!vote_called) { print_to(caller, "^1No vote called."); }
1076                         else if (caller.vote_selection != VOTE_SELECT_NULL && !autocvar_sv_vote_change)
1077                         {
1078                                 print_to(caller, "^1You have already voted.");
1079                         }
1080
1081                         else  // everything went okay, continue changing vote
1082                         {
1083                                 print_to(caller, "^1You accepted the vote.");
1084                                 caller.vote_selection = VOTE_SELECT_ACCEPT;
1085                                 msg_entity = caller;
1086                                 if (!autocvar_sv_vote_singlecount)   VoteCount(false); }
1087
1088                         return;
1089                 }
1090
1091                 default:
1092                 case CMD_REQUEST_USAGE:
1093                 {
1094                         print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote yes"));
1095                         print_to(caller, "  No arguments required.");
1096                         return;
1097                 }
1098         }
1099 }
1100
1101 /* use this when creating a new command, making sure to place it in alphabetical order... also,
1102 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
1103 void VoteCommand_(float request)
1104 {
1105     switch(request)
1106     {
1107         case CMD_REQUEST_COMMAND:
1108         {
1109
1110             return;
1111         }
1112
1113         default:
1114         case CMD_REQUEST_USAGE:
1115         {
1116             print_to(caller, strcat("\nUsage:^3 ", GetCommandPrefix(caller), " vote ");
1117             print_to(caller, "  No arguments required.");
1118             return;
1119         }
1120     }
1121 }
1122 */
1123
1124
1125 // ================================
1126 //  Macro system for vote commands
1127 // ================================
1128
1129 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
1130 #define VOTE_COMMANDS(request, caller, arguments, command) \
1131         VOTE_COMMAND("abstain", VoteCommand_abstain(request, caller), "Abstain your vote in current vote", VC_ASGNMNT_CLIENTONLY) \
1132         VOTE_COMMAND("call", VoteCommand_call(request, caller, arguments, command), "Create a new vote for players to decide on", VC_ASGNMNT_BOTH) \
1133         VOTE_COMMAND("help", VoteCommand_macro_help(caller, arguments), "Shows this information", VC_ASGNMNT_BOTH) \
1134         VOTE_COMMAND("master", VoteCommand_master(request, caller, arguments, command), "Full control over all voting and vote commands", VC_ASGNMNT_CLIENTONLY) \
1135         VOTE_COMMAND("no", VoteCommand_no(request, caller), "Select no in current vote", VC_ASGNMNT_CLIENTONLY) \
1136         VOTE_COMMAND("status", VoteCommand_status(request, caller), "Prints information about current vote", VC_ASGNMNT_BOTH) \
1137         VOTE_COMMAND("stop", VoteCommand_stop(request, caller), "Immediately end a vote", VC_ASGNMNT_BOTH) \
1138         VOTE_COMMAND("yes", VoteCommand_yes(request, caller), "Select yes in current vote", VC_ASGNMNT_CLIENTONLY) \
1139         /* nothing */
1140
1141 void VoteCommand_macro_help(entity caller, float argc)
1142 {
1143         string command_origin = GetCommandPrefix(caller);
1144
1145         if (argc == 2 || argv(2) == "help")  // help display listing all commands
1146         {
1147                 print_to(caller, "\nVoting commands:\n");
1148                 #define VOTE_COMMAND(name, function, description, assignment) \
1149                         { if (Votecommand_check_assignment(caller, assignment)) { print_to(caller, strcat("  ^2", name, "^7: ", description)); } }
1150
1151                 VOTE_COMMANDS(0, caller, 0, "");
1152 #undef VOTE_COMMAND
1153
1154                 print_to(caller, strcat("\nUsage:^3 ", command_origin, " vote COMMAND...^7, where possible commands are listed above.\n"));
1155                 print_to(caller, strcat("For help about a specific command, type ", command_origin, " vote help COMMAND"));
1156                 print_to(caller, strcat("\n^7You can call a vote for or execute these commands: ^3", autocvar_sv_vote_commands, "^7 and maybe further ^3arguments^7"));
1157         }
1158         else  // usage for individual command
1159         {
1160                 #define VOTE_COMMAND(name, function, description, assignment) \
1161                         { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(2))) { function; return; } } }
1162
1163                 VOTE_COMMANDS(CMD_REQUEST_USAGE, caller, argc, "");
1164 #undef VOTE_COMMAND
1165         }
1166 }
1167
1168 float VoteCommand_macro_command(entity caller, float argc, string vote_command)
1169 {
1170         #define VOTE_COMMAND(name, function, description, assignment) \
1171                 { if (Votecommand_check_assignment(caller, assignment)) { if (name == strtolower(argv(1))) { function; return true; } } }
1172
1173         VOTE_COMMANDS(CMD_REQUEST_COMMAND, caller, argc, vote_command);
1174 #undef VOTE_COMMAND
1175
1176         return false;
1177 }
1178
1179
1180 // ======================================
1181 //  Main function handling vote commands
1182 // ======================================
1183
1184 void VoteCommand(float request, entity caller, float argc, string vote_command)
1185 {
1186         // Guide for working with argc arguments by example:
1187         // argc:   1    - 2      - 3     - 4
1188         // argv:   0    - 1      - 2     - 3
1189         // cmd     vote - master - login - password
1190
1191         switch (request)
1192         {
1193                 case CMD_REQUEST_COMMAND:
1194                 {
1195                         if (VoteCommand_macro_command(caller, argc, vote_command)) return;
1196                 }
1197
1198                 default:
1199                         print_to(caller, strcat(((argv(1) != "") ? strcat("Unknown vote command \"", argv(1), "\"") : "No command provided"), ". For a list of supported commands, try ", GetCommandPrefix(caller), " vote help.\n"));
1200                 case CMD_REQUEST_USAGE:
1201                 {
1202                         VoteCommand_macro_help(caller, argc);
1203                         return;
1204                 }
1205         }
1206 }