qcsrc/server/compat/quake3.qc

   1 #include "quake3.qh"
   2
   3 #include <server/client.qh>
   4 #include <common/weapons/_all.qh>
   5 #include <common/stats.qh>
   6 #include <server/miscfunctions.qh>
   7 #include <server/items/items.qh>
   8 #include <server/items/spawning.qh>
   9 #include <server/resources.qh>
  10 #include <common/gamemodes/_mod.qh>
  11 #include <common/gamemodes/gamemode/ctf/sv_ctf.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/mapobjects/trigger/counter.qh>
  14 #include <common/mutators/mutator/buffs/buffs.qh>
  15 #include <common/notifications/all.qh>
  16
  17 /***********************
  18  * QUAKE 3 ENTITIES - So people can play quake3 maps with the xonotic weapons
  19  ***********************
  20
  21  * Map entities NOT handled in this file:
  22  holdable_invulnerability       Q3TA    buffs mutator
  23  holdable_kamikaze              Q3TA    buffs mutator
  24  holdable_teleporter            Q3A     buffs mutator
  25  item_ammoregen                 Q3TA    buffs mutator
  26  item_doubler                   Q3TA    buffs mutator
  27  item_guard                     Q3TA    buffs mutator
  28  item_scout                     Q3TA    buffs mutator
  29  item_armor_jacket              CPMA    quake2.qc
  30  item_flight                    Q3A     buffs mutator
  31  item_haste                     Q3A     buffs mutator
  32  item_health                    Q3A     quake.qc
  33  item_health_large              Q3A     items.qc
  34  item_health_small              Q3A     health.qh
  35  item_health_mega               Q3A     health.qh
  36  item_invis                     Q3A     buffs mutator
  37  item_quad                      Q3A     items.qc
  38  item_regen                     Q3A     buffs mutator
  39  weapon_machinegun              Q3A     machinegun.qh
  40  weapon_grenadelauncher         Q3A     mortar.qh
  41  weapon_rocketlauncher          Q3A     devastator.qh
  42  CTF spawnfuncs handled in sv_ctf.qc
  43
  44  NOTE: for best experience, you need to swap MGs with SGs in the map or it won't have a MG
  45 */
  46
  47 // SG -> MG || SG
  48 SPAWNFUNC_Q3_COND(weapon_shotgun, ammo_shells, (q3compat & Q3COMPAT_ARENA), WEP_MACHINEGUN, WEP_SHOTGUN)
  49
  50 // MG -> SG || MG
  51 // Technically we should replace weapon_machinegun with WEP_SHOTGUN if Q3COMPAT_ARENA, but it almost never occurs on Q3 maps
  52 SPAWNFUNC_Q3AMMO_COND(ammo_bullets, (q3compat & Q3COMPAT_ARENA), WEP_SHOTGUN, WEP_MACHINEGUN)
  53
  54 // GL -> Mortar
  55 SPAWNFUNC_Q3AMMO(ammo_grenades, WEP_MORTAR)
  56
  57 // Team Arena Proximity Launcher -> Mortar
  58 // It's more accurate to spawn Mine Layer but players prefer Mortar, and weapon_grenadelauncher is usually disabled by "notta" and weapon_prox_launcher placed at the same origin
  59 SPAWNFUNC_Q3(weapon_prox_launcher, ammo_mines, WEP_MORTAR)
  60
  61 // Team Arena Chaingun -> HLAC
  62 SPAWNFUNC_Q3(weapon_chaingun, ammo_belt, WEP_HLAC)
  63
  64 // Quake Live Heavy Machine Gun -> HLAC
  65 SPAWNFUNC_Q3(weapon_hmg, ammo_hmg, WEP_HLAC)
  66
  67 // Team Arena Nailgun -> Crylink || Quake Nailgun -> Electro
  68 SPAWNFUNC_Q3_COND(weapon_nailgun, ammo_nails, cvar("sv_mapformat_is_quake3"), WEP_CRYLINK, WEP_ELECTRO)
  69
  70 // LG -> Electro
  71 SPAWNFUNC_Q3(weapon_lightning, ammo_lightning, WEP_ELECTRO)
  72
  73 // Plasma -> Hagar
  74 SPAWNFUNC_Q3(weapon_plasmagun, ammo_cells, WEP_HAGAR)
  75
  76 // Rail -> Vortex
  77 SPAWNFUNC_Q3(weapon_railgun, ammo_slugs, WEP_VORTEX)
  78
  79 // BFG -> Crylink || Fireball
  80 SPAWNFUNC_Q3_COND(weapon_bfg, ammo_bfg, cvar_string("g_mod_balance") == "XDF", WEP_CRYLINK, WEP_FIREBALL)
  81
  82 // grappling hook -> hook
  83 SPAWNFUNC_WEAPON(weapon_grapplinghook, WEP_HOOK)
  84
  85 // RL -> RL
  86 SPAWNFUNC_Q3AMMO(ammo_rockets, WEP_DEVASTATOR)
  87
  88 // Gauntlet -> Tuba
  89 SPAWNFUNC_ITEM(weapon_gauntlet, WEP_TUBA)
  90
  91 // Armor
  92 SPAWNFUNC_ITEM(item_armor_body, ITEM_ArmorMega)
  93 SPAWNFUNC_ITEM(item_armor_combat, ITEM_ArmorBig)
  94 SPAWNFUNC_ITEM(item_armor_shard, ITEM_ArmorSmall)
  95 SPAWNFUNC_ITEM(item_armor_green, ITEM_ArmorMedium) // CCTF
  96
  97 // Battle Suit
  98 SPAWNFUNC_ITEM(item_enviro, ITEM_Shield)
  99
 100 // medkit -> armor (we have no holdables)
 101 SPAWNFUNC_ITEM(holdable_medkit, ITEM_ArmorBig)
 102
 103 .float wait;
 104 .float delay;
 105
 106 // weapon remove ent from df
 107 void target_init_verify(entity this)
 108 {
 109         entity trigger, targ;
 110         for(trigger = NULL; (trigger = find(trigger, classname, "trigger_multiple")); )
 111                 for(targ = NULL; (targ = find(targ, targetname, trigger.target)); )
 112                         if (targ.classname == "target_init" || targ.classname == "target_give" || targ.classname == "target_items")
 113                         {
 114                                 trigger.wait = 0;
 115                                 trigger.delay = 0;
 116                                 targ.wait = 0;
 117                                 targ.delay = 0;
 118
 119                                 //setsize(targ, trigger.mins, trigger.maxs);
 120                                 //setorigin(targ, trigger.origin);
 121                                 //remove(trigger);
 122                         }
 123 }
 124
 125 void target_init_use(entity this, entity actor, entity trigger)
 126 {
 127         if (!(this.spawnflags & 1))
 128         {
 129                 SetResource(actor, RES_ARMOR, start_armorvalue);
 130                 actor.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot;
 131         }
 132
 133         if (!(this.spawnflags & 2))
 134         {
 135                 SetResource(actor, RES_HEALTH, start_health);
 136                 actor.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot;
 137                 actor.pauseregen_finished = time + autocvar_g_balance_pause_health_regen;
 138         }
 139
 140         if (!(this.spawnflags & 4))
 141         {
 142                 if(this.spawnflags & 32) // spawn with only melee
 143                 {
 144                         SetResource(actor, RES_SHELLS, 0);
 145                         SetResource(actor, RES_BULLETS, 0);
 146                         SetResource(actor, RES_ROCKETS, 0);
 147                         SetResource(actor, RES_CELLS, 0);
 148                         SetResource(actor, RES_PLASMA, 0);
 149                         SetResource(actor, RES_FUEL, 0);
 150
 151                         STAT(WEAPONS, actor) = WEPSET(SHOTGUN);
 152                 }
 153                 else
 154                 {
 155                         SetResource(actor, RES_SHELLS, start_ammo_shells);
 156                         SetResource(actor, RES_BULLETS, start_ammo_nails);
 157                         SetResource(actor, RES_ROCKETS, start_ammo_rockets);
 158                         SetResource(actor, RES_CELLS, start_ammo_cells);
 159                         SetResource(actor, RES_PLASMA, start_ammo_plasma);
 160                         SetResource(actor, RES_FUEL, start_ammo_fuel);
 161
 162                         STAT(WEAPONS, actor) = start_weapons;
 163                 }
 164         }
 165
 166         if (!(this.spawnflags & 8))
 167         {
 168                 STAT(STRENGTH_FINISHED, actor) = 0;
 169                 STAT(INVINCIBLE_FINISHED, actor) = 0;
 170                 if(STAT(BUFFS, actor)) // TODO: make a dropbuffs function to handle this
 171                 {
 172                         int buffid = buff_FirstFromFlags(STAT(BUFFS, actor)).m_id;
 173                         Send_Notification(NOTIF_ONE, actor, MSG_MULTI, ITEM_BUFF_DROP, buffid);
 174                         sound(actor, CH_TRIGGER, SND_BUFF_LOST, VOL_BASE, ATTN_NORM);
 175                         if(!IS_INDEPENDENT_PLAYER(actor))
 176                                 Send_Notification(NOTIF_ALL_EXCEPT, actor, MSG_INFO, INFO_ITEM_BUFF_LOST, actor.netname, buffid);
 177                         STAT(BUFFS, actor) = 0;
 178                         STAT(BUFF_TIME, actor) = 0;
 179                 }
 180         }
 181
 182         if (!(this.spawnflags & 16))
 183         {
 184                 // We don't have holdables.
 185         }
 186
 187         SUB_UseTargets(this, actor, trigger);
 188 }
 189
 190 spawnfunc(target_init)
 191 {
 192         this.use = target_init_use;
 193         InitializeEntity(this, target_init_verify, INITPRIO_FINDTARGET);
 194 }
 195
 196 // weapon give ent from Q3
 197 void target_give_init(entity this)
 198 {
 199         IL_EACH(g_items, it.targetname == this.target,
 200         {
 201                 if (it.classname == "item_buff")
 202                 {
 203                         entity buff = buff_FirstFromFlags(STAT(BUFFS, it));
 204                         this.netname = cons(this.netname, buff.netname);
 205                         STAT(BUFF_TIME, this) += it.count;
 206                 }
 207                 else
 208                 {
 209                         if (it.ammo_rockets)
 210                                 this.ammo_rockets += it.ammo_rockets;
 211                         else if (it.ammo_cells)
 212                                 this.ammo_cells += it.ammo_cells;
 213                         else if (it.ammo_shells)
 214                                 this.ammo_shells += it.ammo_shells;
 215                         else if (it.ammo_nails)
 216                                 this.ammo_nails += it.ammo_nails;
 217                         else if (it.invincible_finished)
 218                                 this.invincible_finished += it.invincible_finished;
 219                         else if (it.strength_finished)
 220                                 this.strength_finished += it.strength_finished;
 221                         else if (it.health)
 222                                 this.health += it.health;
 223                         else if (it.armorvalue)
 224                                 this.armorvalue += it.armorvalue;
 225
 226                         this.netname = cons(this.netname, it.netname);
 227                 }
 228
 229                 //remove(it); // removing ents in init functions causes havoc, workaround:
 230                 setthink(it, SUB_Remove);
 231                 it.nextthink = time;
 232         });
 233         this.spawnflags = 2;
 234         this.spawnfunc_checked = true;
 235         spawnfunc_target_items(this);
 236         InitializeEntity(this, target_init_verify, INITPRIO_FINDTARGET);
 237 }
 238
 239 spawnfunc(target_give)
 240 {
 241         InitializeEntity(this, target_give_init, INITPRIO_FINDTARGET);
 242 }
 243
 244 void score_use(entity this, entity actor, entity trigger)
 245 {
 246         if(!IS_PLAYER(actor))
 247                 return;
 248         actor.fragsfilter_cnt += this.count;
 249 }
 250 spawnfunc(target_score)
 251 {
 252         if(!g_cts) { delete(this); return; }
 253
 254         if(!this.count)
 255                 this.count = 1;
 256         this.use = score_use;
 257 }
 258
 259 void fragsfilter_use(entity this, entity actor, entity trigger)
 260 {
 261         if(!IS_PLAYER(actor))
 262                 return;
 263         if(actor.fragsfilter_cnt >= this.frags)
 264                 SUB_UseTargets(this, actor, trigger);
 265 }
 266 spawnfunc(target_fragsFilter)
 267 {
 268         if(!g_cts) { delete(this); return; }
 269
 270         if(!this.frags)
 271                 this.frags = 1;
 272         this.use = fragsfilter_use;
 273 }
 274
 275 .bool notteam;
 276 .bool notsingle;
 277 .bool notfree;
 278 .bool notta;
 279 .bool notvq3;
 280 .bool notcpm;
 281 .string gametype;
 282 bool DoesQ3ARemoveThisEntity(entity this)
 283 {
 284         // Q3 style filters (DO NOT USE, THIS IS COMPAT ONLY)
 285
 286         // DeFRaG mappers use "notcpm" or "notvq3" to disable an entity in CPM or VQ3 physics
 287         // Xonotic is usually played with a CPM-based physics so we default to CPM mode
 288         if(cvar_string("g_mod_physics") == "Q3")
 289         {
 290                 if(this.notvq3)
 291                         return true;
 292         }
 293         else if(this.notcpm)
 294                 return true;
 295
 296         // Q3 mappers use "notq3a" or "notta" to disable an entity in Q3A or Q3TA
 297         // Xonotic has ~equivalent features to Team Arena
 298         if(this.notta)
 299                 return true;
 300
 301         if(this.notsingle)
 302                 if(maxclients == 1)
 303                         return true;
 304
 305         if(this.notteam)
 306                 if(teamplay)
 307                         return true;
 308
 309         if(this.notfree)
 310                 if(!teamplay)
 311                         return true;
 312
 313         if(this.gametype)
 314         {
 315                 string gametypename;
 316                 // From ioq3 g_spawn.c: static char *gametypeNames[] = {"ffa", "tournament", "single", "team", "ctf", "oneflag", "obelisk", "harvester"};
 317                 gametypename = "ffa";
 318                 if(teamplay)
 319                         gametypename = "team";
 320                 if(g_ctf)
 321                         gametypename = "ctf";
 322                 if(g_ctf && ctf_oneflag)
 323                         gametypename = "oneflag";
 324                 if(g_duel)
 325                         gametypename = "tournament";
 326                 if(maxclients == 1)
 327                         gametypename = "single";
 328                 // we do not have the other types (obelisk, harvester)
 329                 if(strstrofs(this.gametype, gametypename, 0) < 0)
 330                         return true;
 331         }
 332
 333         return false;
 334 }