qcsrc/server/func_breakable.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qc"
   5     #include "../dpdefs/dpextensions.qc"
   6     #include "../common/constants.qh"
   7     #include "../common/util.qh"
   8     #include "../common/monsters/monsters.qh"
   9     #include "../common/weapons/weapons.qh"
  10     #include "constants.qh"
  11     #include "defs.qh"
  12     #include "../common/deathtypes.qh"
  13     #include "mutators/mutators_include.qh"
  14     #include "../csqcmodellib/sv_model.qh"
  15 #endif
  16
  17 .entity sprite;
  18
  19 .float dmg;
  20 .float dmg_edge;
  21 .float dmg_radius;
  22 .float dmg_force;
  23 .float debrismovetype;
  24 .float debrissolid;
  25 .vector debrisvelocity;
  26 .vector debrisvelocityjitter;
  27 .vector debrisavelocityjitter;
  28 .float debristime;
  29 .float debristimejitter;
  30 .float debrisfadetime;
  31 .float debrisdamageforcescale;
  32 .float debrisskin;
  33
  34 .string mdl_dead; // or "" to hide when broken
  35 .string debris; // space separated list of debris models
  36 // other fields:
  37 //   mdl = particle effect name
  38 //   count = particle effect multiplier
  39 //   targetname = target to trigger to unbreak the model
  40 //   target = targets to trigger when broken
  41 //   health = amount of damage it can take
  42 //   spawnflags:
  43 //     1 = start disabled (needs to be triggered to activate)
  44 //     2 = indicate damage
  45 // notes:
  46 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  47 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  48 //   want that!
  49
  50 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  51
  52 //
  53 // func_breakable
  54 // - basically func_assault_destructible for general gameplay use
  55 //
  56 void LaunchDebris (string debrisname, vector force)
  57 {
  58         entity dbr = spawn();
  59         setorigin(dbr, self.absmin
  60                    + '1 0 0' * random() * (self.absmax.x - self.absmin.x)
  61                    + '0 1 0' * random() * (self.absmax.y - self.absmin.y)
  62                    + '0 0 1' * random() * (self.absmax.z - self.absmin.z));
  63         setmodel (dbr, debrisname );
  64         dbr.skin = self.debrisskin;
  65         dbr.colormap = self.colormap; // inherit team colors
  66         dbr.owner = self; // do not be affected by our own explosion
  67         dbr.movetype = self.debrismovetype;
  68         dbr.solid = self.debrissolid;
  69         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  70                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  71         dbr.velocity_x = self.debrisvelocity.x + self.debrisvelocityjitter.x * crandom();
  72         dbr.velocity_y = self.debrisvelocity.y + self.debrisvelocityjitter.y * crandom();
  73         dbr.velocity_z = self.debrisvelocity.z + self.debrisvelocityjitter.z * crandom();
  74         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  75         dbr.avelocity_x = random()*self.debrisavelocityjitter.x;
  76         dbr.avelocity_y = random()*self.debrisavelocityjitter.y;
  77         dbr.avelocity_z = random()*self.debrisavelocityjitter.z;
  78         dbr.damageforcescale = self.debrisdamageforcescale;
  79         if(dbr.damageforcescale)
  80                 dbr.takedamage = DAMAGE_YES;
  81         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  82 }
  83
  84 void func_breakable_colormod()
  85 {
  86         float h;
  87         if (!(self.spawnflags & 2))
  88                 return;
  89         h = self.health / self.max_health;
  90         if(h < 0.25)
  91                 self.colormod = '1 0 0';
  92         else if(h <= 0.75)
  93                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  94         else
  95                 self.colormod = '1 1 1';
  96
  97         CSQCMODEL_AUTOUPDATE();
  98 }
  99
 100 void func_breakable_look_destroyed()
 101 {
 102         float floorZ;
 103
 104         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
 105                 self.dropped_origin = self.origin;
 106
 107         if(self.mdl_dead == "")
 108                 self.model = "";
 109         else {
 110                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
 111                         floorZ = self.absmin.z;
 112                         setorigin(self,((self.absmax+self.absmin)*.5));
 113                         self.origin_z = floorZ;
 114                 }
 115                 setmodel(self, self.mdl_dead);
 116         }
 117
 118         self.solid = SOLID_NOT;
 119 }
 120
 121 void func_breakable_look_restore()
 122 {
 123         setmodel(self, self.mdl);
 124         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 125                 setorigin(self, self.dropped_origin);
 126         self.solid = SOLID_BSP;
 127 }
 128
 129 void func_breakable_behave_destroyed()
 130 {
 131         self.health = self.max_health;
 132         self.takedamage = DAMAGE_NO;
 133         self.bot_attack = false;
 134         self.event_damage = func_null;
 135         self.state = 1;
 136         func_breakable_colormod();
 137 }
 138
 139 void func_breakable_behave_restore()
 140 {
 141         self.health = self.max_health;
 142         if(self.sprite)
 143         {
 144                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 145                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 146         }
 147         self.takedamage = DAMAGE_AIM;
 148         self.bot_attack = true;
 149         self.event_damage = func_breakable_damage;
 150         self.state = 0;
 151         self.nextthink = 0; // cancel auto respawn
 152         func_breakable_colormod();
 153 }
 154
 155 void func_breakable_destroyed()
 156 {
 157         func_breakable_look_destroyed();
 158         func_breakable_behave_destroyed();
 159
 160         CSQCMODEL_AUTOUPDATE();
 161 }
 162
 163 void func_breakable_restore()
 164 {
 165         func_breakable_look_restore();
 166         func_breakable_behave_restore();
 167
 168         CSQCMODEL_AUTOUPDATE();
 169 }
 170
 171 vector debrisforce; // global, set before calling this
 172 void func_breakable_destroy() {
 173         float n, i;
 174         string oldmsg;
 175
 176         activator = self.owner;
 177         self.owner = world; // set by W_PrepareExplosionByDamage
 178
 179         // now throw around the debris
 180         n = tokenize_console(self.debris);
 181         for(i = 0; i < n; ++i)
 182                 LaunchDebris(argv(i), debrisforce);
 183
 184         func_breakable_destroyed();
 185
 186         if(self.noise)
 187                 sound (self, CH_TRIGGER, self.noise, VOL_BASE, ATTEN_NORM);
 188
 189         if(self.dmg)
 190                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, world, self.dmg_force, DEATH_HURTTRIGGER, world);
 191
 192         if(self.cnt)
 193                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 194
 195         if(self.respawntime)
 196         {
 197                 self.think = func_breakable_restore;
 198                 self.nextthink = time + self.respawntime + crandom() * self.respawntimejitter;
 199         }
 200
 201         oldmsg = self.message;
 202         self.message = "";
 203         SUB_UseTargets();
 204         self.message = oldmsg;
 205 }
 206
 207 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 208 {
 209         if(self.state == 1)
 210                 return;
 211         if(self.spawnflags & DOOR_NOSPLASH)
 212                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 213                         return;
 214         if(self.team)
 215                 if(attacker.team == self.team)
 216                         return;
 217         self.health = self.health - damage;
 218         if(self.sprite)
 219         {
 220                 WaypointSprite_Ping(self.sprite);
 221                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 222         }
 223         func_breakable_colormod();
 224
 225         if(self.health <= 0)
 226         {
 227                 debrisforce = force;
 228                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 229         }
 230 }
 231
 232 void func_breakable_reset()
 233 {
 234         self.team = self.team_saved;
 235         func_breakable_look_restore();
 236         if(self.spawnflags & 1)
 237                 func_breakable_behave_destroyed();
 238         else
 239                 func_breakable_behave_restore();
 240
 241         CSQCMODEL_AUTOUPDATE();
 242 }
 243
 244 // destructible walls that can be used to trigger target_objective_decrease
 245 void spawnfunc_func_breakable() {
 246         float n, i;
 247         if(!self.health)
 248                 self.health = 100;
 249         self.max_health = self.health;
 250
 251         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 252         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 253         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 254         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 255         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 256         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 257         if(!self.debristime) self.debristime = 3.5;
 258         if(!self.debristimejitter) self.debristime = 2.5;
 259
 260         if(self.mdl != "")
 261                 self.cnt = particleeffectnum(self.mdl);
 262         if(self.count == 0)
 263                 self.count = 1;
 264
 265         if(self.message == "")
 266                 self.message = "got too close to an explosion";
 267         if(self.message2 == "")
 268                 self.message2 = "was pushed into an explosion by";
 269         if(!self.dmg_radius)
 270                 self.dmg_radius = 150;
 271         if(!self.dmg_force)
 272                 self.dmg_force = 200;
 273
 274         self.mdl = self.model;
 275         SetBrushEntityModel();
 276
 277         self.use = func_breakable_restore;
 278
 279         // precache all the models
 280         if (self.mdl_dead)
 281                 precache_model(self.mdl_dead);
 282         n = tokenize_console(self.debris);
 283         for(i = 0; i < n; ++i)
 284                 precache_model(argv(i));
 285         if(self.noise)
 286                 precache_sound(self.noise);
 287
 288         self.team_saved = self.team;
 289         self.dropped_origin = self.origin;
 290
 291         self.reset = func_breakable_reset;
 292         func_breakable_reset();
 293
 294         CSQCMODEL_AUTOINIT();
 295 }
 296
 297 // for use in maps with a "model" key set
 298 void spawnfunc_misc_breakablemodel() {
 299         spawnfunc_func_breakable();
 300 }