qcsrc/server/func_breakable.qc

   1 .entity sprite;
   2
   3 .float dmg;
   4 .float dmg_edge;
   5 .float dmg_radius;
   6 .float dmg_force;
   7 .float debrismovetype;
   8 .float debrissolid;
   9 .vector debrisvelocity;
  10 .vector debrisvelocityjitter;
  11 .vector debrisavelocityjitter;
  12 .float debristime;
  13 .float debristimejitter;
  14 .float debrisfadetime;
  15 .float debrisdamageforcescale;
  16 .float debrisskin;
  17
  18 .string mdl_dead; // or "" to hide when broken
  19 .string debris; // space separated list of debris models
  20 // other fields:
  21 //   mdl = particle effect name
  22 //   count = particle effect multiplier
  23 //   targetname = target to trigger to unbreak the model
  24 //   target = targets to trigger when broken
  25 //   health = amount of damage it can take
  26 //   spawnflags:
  27 //     1 = start disabled (needs to be triggered to activate)
  28 //     2 = indicate damage
  29 // notes:
  30 //   for mdl_dead to work, origin must be set (using a common/origin brush).
  31 //   Otherwise mdl_dead will be displayed at the map origin, and nobody would
  32 //   want that!
  33
  34 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force);
  35
  36 //
  37 // func_breakable
  38 // - basically func_assault_destructible for general gameplay use
  39 //
  40 void LaunchDebris (string debrisname, vector force) =
  41 {
  42         local   entity dbr;
  43
  44         dbr = spawn();
  45         setorigin(dbr, self.absmin
  46                    + '1 0 0' * random() * (self.absmax_x - self.absmin_x)
  47                    + '0 1 0' * random() * (self.absmax_y - self.absmin_y)
  48                    + '0 0 1' * random() * (self.absmax_z - self.absmin_z));
  49         setmodel (dbr, debrisname );
  50         dbr.skin = self.debrisskin;
  51         dbr.colormap = self.colormap; // inherit team colors
  52         dbr.owner = self; // do not be affected by our own explosion
  53         dbr.movetype = self.debrismovetype;
  54         dbr.solid = self.debrissolid;
  55         if(dbr.solid != SOLID_BSP) // SOLID_BSP has exact collision, MAYBE this works? TODO check this out
  56                 setsize(dbr, '0 0 0', '0 0 0'); // needed for performance, until engine can deal better with it
  57         dbr.velocity_x = self.debrisvelocity_x + self.debrisvelocityjitter_x * crandom();
  58         dbr.velocity_y = self.debrisvelocity_y + self.debrisvelocityjitter_y * crandom();
  59         dbr.velocity_z = self.debrisvelocity_z + self.debrisvelocityjitter_z * crandom();
  60         self.velocity = self.velocity + force * self.debrisdamageforcescale;
  61         dbr.avelocity_x = random()*self.debrisavelocityjitter_x;
  62         dbr.avelocity_y = random()*self.debrisavelocityjitter_y;
  63         dbr.avelocity_z = random()*self.debrisavelocityjitter_z;
  64         dbr.damageforcescale = self.debrisdamageforcescale;
  65         if(dbr.damageforcescale)
  66                 dbr.takedamage = DAMAGE_YES;
  67         SUB_SetFade(dbr, time + self.debristime + crandom() * self.debristimejitter, self.debrisfadetime);
  68 };
  69
  70 void func_breakable_colormod()
  71 {
  72         float h;
  73         if not(self.spawnflags & 2)
  74                 return;
  75         h = self.health / self.max_health;
  76         if(h < 0.25)
  77                 self.colormod = '1 0 0';
  78         else if(h <= 0.75)
  79                 self.colormod = '1 0 0' + '0 1 0' * (2 * h - 0.5);
  80         else
  81                 self.colormod = '1 1 1';
  82 }
  83
  84 void func_breakable_look_destroyed()
  85 {
  86         local float floor_z;
  87
  88         if(self.solid == SOLID_BSP) // in case a misc_follow moved me, save the current origin first
  89                 self.dropped_origin = self.origin;
  90
  91         if(self.mdl_dead == "")
  92                 self.model = "";
  93         else {
  94                 if (self.origin == '0 0 0')     {       // probably no origin brush, so don't spawn in the middle of the map..
  95                         floor_z = self.absmin_z;
  96                         setorigin(self,((self.absmax+self.absmin)*.5));
  97                         self.origin_z = floor_z;
  98                 }
  99                 setmodel(self, self.mdl_dead);
 100         }
 101
 102         self.solid = SOLID_NOT;
 103 }
 104
 105 void func_breakable_look_restore()
 106 {
 107         setmodel(self, self.mdl);
 108         if(self.mdl_dead != "") // only do this if we use mdl_dead, to behave better with misc_follow
 109                 setorigin(self, self.dropped_origin);
 110         self.solid = SOLID_BSP;
 111 }
 112
 113 void func_breakable_behave_destroyed()
 114 {
 115         self.health = self.max_health;
 116         self.takedamage = DAMAGE_NO;
 117         self.event_damage = SUB_Null;
 118         self.state = 1;
 119         func_breakable_colormod();
 120 }
 121
 122 void func_breakable_behave_restore()
 123 {
 124         self.health = self.max_health;
 125         if(self.sprite)
 126         {
 127                 WaypointSprite_UpdateMaxHealth(self.sprite, self.max_health);
 128                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 129         }
 130         self.takedamage = DAMAGE_AIM;
 131         self.event_damage = func_breakable_damage;
 132         self.state = 0;
 133         func_breakable_colormod();
 134 }
 135
 136 void func_breakable_destroyed()
 137 {
 138         func_breakable_look_destroyed();
 139         func_breakable_behave_destroyed();
 140 }
 141
 142 void func_breakable_restore()
 143 {
 144         func_breakable_look_restore();
 145         func_breakable_behave_restore();
 146 }
 147
 148 vector debrisforce; // global, set before calling this
 149 void func_breakable_destroy() {
 150         float n, i;
 151         string oldmsg;
 152
 153         activator = self.owner;
 154         self.owner = world; // set by W_PrepareExplosionByDamage
 155
 156         // now throw around the debris
 157         n = tokenize_console(self.debris);
 158         for(i = 0; i < n; ++i)
 159                 LaunchDebris(argv(i), debrisforce);
 160
 161         func_breakable_destroyed();
 162
 163         if(self.noise)
 164                 sound (self, CHAN_AUTO, self.noise, VOL_BASE, ATTN_NORM);
 165
 166         if(self.dmg)
 167                 RadiusDamage(self, activator, self.dmg, self.dmg_edge, self.dmg_radius, self, self.dmg_force, DEATH_HURTTRIGGER, world);
 168
 169         if(self.cnt)
 170                 pointparticles(self.cnt, self.absmin * 0.5 + self.absmax * 0.5, '0 0 0', self.count);
 171
 172         if(self.respawntime)
 173         {
 174                 self.think = func_breakable_restore;
 175                 self.nextthink = time + self.respawntime;
 176         }
 177
 178         oldmsg = self.message;
 179         self.message = "";
 180         SUB_UseTargets();
 181         self.message = oldmsg;
 182 }
 183
 184 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 185 {
 186         if(self.state == 1)
 187                 return;
 188         if(self.spawnflags & DOOR_NOSPLASH)
 189                 if(!(DEATH_ISSPECIAL(deathtype)) && (deathtype & HITTYPE_SPLASH))
 190                         return;
 191         if(self.team)
 192                 if(attacker.team == self.team)
 193                         return;
 194         self.health = self.health - damage;
 195         if(self.sprite)
 196         {
 197                 WaypointSprite_Ping(self.sprite);
 198                 WaypointSprite_UpdateHealth(self.sprite, self.health);
 199         }
 200         func_breakable_colormod();
 201
 202         if(self.health <= 0)
 203         {
 204                 debrisforce = force;
 205                 W_PrepareExplosionByDamage(attacker, func_breakable_destroy);
 206         }
 207 }
 208
 209 void func_breakable_reset()
 210 {
 211         self.team = self.team_saved;
 212         func_breakable_look_restore();
 213         if(self.spawnflags & 1)
 214                 func_breakable_behave_destroyed();
 215         else
 216                 func_breakable_behave_restore();
 217 }
 218
 219 // destructible walls that can be used to trigger target_objective_decrease
 220 void spawnfunc_func_breakable() {
 221         float n, i;
 222         if(!self.health)
 223                 self.health = 100;
 224         self.max_health = self.health;
 225
 226         // yes, I know, MOVETYPE_NONE is not available here, not that one would want it here anyway
 227         if(!self.debrismovetype) self.debrismovetype = MOVETYPE_BOUNCE;
 228         if(!self.debrissolid) self.debrissolid = SOLID_NOT;
 229         if(self.debrisvelocity == '0 0 0') self.debrisvelocity = '0 0 140';
 230         if(self.debrisvelocityjitter == '0 0 0') self.debrisvelocityjitter = '70 70 70';
 231         if(self.debrisavelocityjitter == '0 0 0') self.debrisavelocityjitter = '600 600 600';
 232         if(!self.debristime) self.debristime = 3.5;
 233         if(!self.debristimejitter) self.debristime = 2.5;
 234
 235         if(self.mdl != "")
 236                 self.cnt = particleeffectnum(self.mdl);
 237         if(self.count == 0)
 238                 self.count = 1;
 239
 240         if(!self.message)
 241                 self.message = "got too close to an explosion";
 242         if(!self.message2)
 243                 self.message2 = "was pushed into an explosion by";
 244         if(!self.dmg_radius)
 245                 self.dmg_radius = 150;
 246         if(!self.dmg_force)
 247                 self.dmg_force = 200;
 248
 249         self.mdl = self.model;
 250         SetBrushEntityModel();
 251
 252         self.use = func_breakable_restore;
 253
 254         // precache all the models
 255         if (self.mdl_dead)
 256                 precache_model(self.mdl_dead);
 257         n = tokenize_console(self.debris);
 258         for(i = 0; i < n; ++i)
 259                 precache_model(argv(i));
 260         if(self.noise)
 261                 precache_sound(self.noise);
 262
 263         self.team_saved = self.team;
 264         self.dropped_origin = self.origin;
 265
 266         self.reset = func_breakable_reset;
 267         func_breakable_reset();
 268 }
 269
 270 // for use in maps with a "model" key set
 271 void spawnfunc_misc_breakablemodel() {
 272         spawnfunc_func_breakable();
 273 }