qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         return TRUE;
  18 }
  19
  20 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, entity dmgowner)
  21 {
  22         // TODO maybe call this from non-edgedamage too?
  23         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  24
  25         entity e;
  26
  27         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  28                 deathtype |= 0x8000;
  29
  30         e = spawn();
  31         setorigin(e, org);
  32         e.projectiledeathtype = deathtype;
  33         e.dmg = coredamage;
  34         e.dmg_edge = edgedamage;
  35         e.dmg_radius = rad;
  36         e.dmg_force = vlen(force);
  37         e.velocity = force;
  38
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40
  41         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  42 }
  43
  44 #define DAMAGE_CENTERPRINT_SPACER NEWLINES
  45
  46 float checkrules_firstblood;
  47
  48 float yoda;
  49 float damage_goodhits;
  50 float damage_gooddamage;
  51 float headshot;
  52 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  53
  54 .float dmg_team;
  55 .float teamkill_complain;
  56 .float teamkill_soundtime;
  57 .entity teamkill_soundsource;
  58 .entity pusher;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teams_matter)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 106 {
 107         float w;
 108
 109         // TODO route through PlayerScores instead
 110         if(gameover) return;
 111
 112         if(f < 0)
 113         {
 114                 if(targ == attacker)
 115                 {
 116                         // suicide
 117                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 118                 }
 119                 else
 120                 {
 121                         // teamkill
 122                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 123                         PlayerStats_Event(attacker, PLAYERSTATS_KILLS, -1);
 124                 }
 125         }
 126         else
 127         {
 128                 // regular frag
 129                 PlayerScore_Add(attacker, SP_KILLS, 1);
 130                 PlayerStats_Event(attacker, PLAYERSTATS_KILLS, 1);
 131         }
 132
 133         PlayerScore_Add(targ, SP_DEATHS, 1);
 134
 135         if(g_arena || g_ca)
 136                 if(autocvar_g_arena_roundbased)
 137                         return;
 138
 139         if(targ != attacker) // not for suicides
 140         if(g_weaponarena_random)
 141         {
 142                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 143                 float culprit;
 144                 culprit = DEATH_WEAPONOF(deathtype);
 145                 if(!culprit || !(attacker.weapons & W_WeaponBit(culprit)))
 146                         culprit = attacker.weapon;
 147
 148                 if(g_weaponarena_random_with_laser && culprit == WEPBIT_LASER)
 149                 {
 150                         // no exchange
 151                 }
 152                 else
 153                 {
 154                         if(inWarmupStage)
 155                                 w = warmup_start_weapons;
 156                         else
 157                                 w = start_weapons;
 158
 159                         // all others (including the culprit): remove
 160                         w &~= attacker.weapons;
 161
 162                         // among the remaining ones, choose one by random
 163                         w = randombits(w, 1, FALSE);
 164                         if(w)
 165                         {
 166                                 attacker.weapons |= w;
 167                                 attacker.weapons &~= W_WeaponBit(culprit);
 168                         }
 169                 }
 170
 171                 // after a frag, choose another random weapon set
 172                 if not(attacker.weapons & W_WeaponBit(attacker.weapon))
 173                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 174         }
 175
 176         // FIXME fix the mess this is (we have REAL points now!)
 177         entity oldself;
 178         oldself = self;
 179         self = attacker;
 180         frag_attacker = attacker;
 181         frag_target = targ;
 182         frag_score = f;
 183         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 184         {
 185                 f = frag_score;
 186                 self = oldself;
 187         }
 188         else
 189         {
 190                 self = oldself;
 191                 if(g_runematch)
 192                 {
 193                         f = RunematchHandleFrags(attacker, targ, f);
 194                 }
 195                 else if(g_lms)
 196                 {
 197                         // remove a life
 198                         float tl;
 199                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 200                         if(tl < lms_lowest_lives)
 201                                 lms_lowest_lives = tl;
 202                         if(tl <= 0)
 203                         {
 204                                 if(!lms_next_place)
 205                                         lms_next_place = player_count;
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211                 else if(g_ctf)
 212                 {
 213                         if(g_ctf_ignore_frags)
 214                                 f = 0;
 215                 }
 216         }
 217
 218         attacker.totalfrags += f;
 219
 220         if(f)
 221                 UpdateFrags(attacker, f);
 222 }
 223
 224 string AppendItemcodes(string s, entity player)
 225 {
 226         float w;
 227         w = player.weapon;
 228         //if(w == 0)
 229         //      w = player.switchweapon;
 230         if(w == 0)
 231                 w = player.cnt; // previous weapon!
 232         s = strcat(s, ftos(w));
 233         if(time < player.strength_finished)
 234                 s = strcat(s, "S");
 235         if(time < player.invincible_finished)
 236                 s = strcat(s, "I");
 237         if(player.flagcarried != world)
 238                 s = strcat(s, "F");
 239         if(player.BUTTON_CHAT)
 240                 s = strcat(s, "T");
 241         if(player.kh_next)
 242                 s = strcat(s, "K");
 243         if(player.runes)
 244                 s = strcat(s, "|", ftos(player.runes));
 245         return s;
 246 }
 247
 248 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 249 {
 250         string s;
 251         if(!autocvar_sv_eventlog)
 252                 return;
 253         s = strcat(":kill:", mode);
 254         s = strcat(s, ":", ftos(killer.playerid));
 255         s = strcat(s, ":", ftos(killed.playerid));
 256         s = strcat(s, ":type=", ftos(deathtype));
 257         s = strcat(s, ":items=");
 258         s = AppendItemcodes(s, killer);
 259         if(killed != killer)
 260         {
 261                 s = strcat(s, ":victimitems=");
 262                 s = AppendItemcodes(s, killed);
 263         }
 264         GameLogEcho(s);
 265 }
 266
 267 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 268 {
 269         WriteByte(MSG_ALL, SVC_TEMPENTITY);
 270         WriteByte(MSG_ALL, TE_CSQC_NOTIFY);
 271         WriteByte(MSG_ALL, CSQC_KILLNOTIFY);
 272         WriteString(MSG_ALL, s1);
 273         WriteString(MSG_ALL, s2);
 274         WriteString(MSG_ALL, s3);
 275         WriteShort(MSG_ALL, msg);
 276         WriteByte(MSG_ALL, type);
 277 }
 278
 279 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 280 void Send_CSQC_Centerprint(entity e, string s1, string s2, float msg, float type)
 281 {
 282         if (clienttype(e) == CLIENTTYPE_REAL)
 283         {
 284                 msg_entity = e;
 285                 WRITESPECTATABLE_MSG_ONE({
 286                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 287                         WriteByte(MSG_ONE, TE_CSQC_NOTIFY);
 288                         WriteByte(MSG_ONE, CSQC_CENTERPRINT);
 289                         WriteString(MSG_ONE, s1);
 290                         WriteString(MSG_ONE, s2);
 291                         WriteShort(MSG_ONE, msg);
 292                         WriteByte(MSG_ONE, type);
 293                 });
 294         }
 295 }
 296
 297 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 298 {
 299         string  s, a, msg;
 300         float w, type;
 301
 302         if (targ.classname == "player" || targ.classname == "corpse")
 303         {
 304                 if (targ.classname == "corpse")
 305                         s = "A corpse";
 306                 else
 307                         s = targ.netname;
 308
 309                 a = attacker.netname;
 310
 311                 if (targ == attacker) // suicides
 312                 {
 313                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 314                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 315             if(!g_cts) // no "killed your own dumb self" message in CTS
 316                 Send_CSQC_Centerprint(targ, msg, "", deathtype, MSG_SUICIDE);
 317
 318                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 319                         {
 320                                 LogDeath("suicide", deathtype, targ, targ);
 321                                 GiveFrags(attacker, targ, -1, deathtype);
 322                         }
 323
 324                         if (targ.killcount > 2)
 325                                 msg = ftos(targ.killcount);
 326                         if(teams_matter && deathtype == DEATH_MIRRORDAMAGE)
 327                         {
 328                                 if(attacker.team == COLOR_TEAM1)
 329                                         deathtype = KILL_TEAM_RED;
 330                                 else
 331                                         deathtype = KILL_TEAM_BLUE;
 332                         }
 333
 334                         Send_KillNotification(s, msg, ftos(w), deathtype, MSG_SUICIDE);
 335                 }
 336                 else if (attacker.classname == "player" || attacker.classname == "gib")
 337                 {
 338                         if(teams_matter && attacker.team == targ.team)
 339                         {
 340                                 if(attacker.team == COLOR_TEAM1)
 341                                         type = KILL_TEAM_RED;
 342                                 else
 343                                         type = KILL_TEAM_BLUE;
 344
 345                                 GiveFrags(attacker, targ, -1, deathtype);
 346
 347                                 Send_CSQC_Centerprint(attacker, s, "", type, MSG_KILL);
 348
 349                                 if (targ.killcount > 2) {
 350                                         msg = ftos(targ.killcount);
 351                                 }
 352
 353                                 if (attacker.killcount > 2) {
 354                                         msg = ftos(attacker.killcount);
 355                                         type = KILL_TEAM_SPREE;
 356                                 }
 357                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 358
 359                                 attacker.killcount = 0;
 360
 361                                 LogDeath("tk", deathtype, attacker, targ);
 362                         }
 363                         else
 364                         {
 365                                 if (!checkrules_firstblood)
 366                                 {
 367                                         checkrules_firstblood = TRUE;
 368                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 369                                         // TODO: make these print a newline if they dont
 370                                         Send_CSQC_Centerprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 371                                         Send_CSQC_Centerprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 372                                 }
 373
 374                                 if((autocvar_sv_fragmessage_information_typefrag) && (targ.BUTTON_CHAT)) {
 375                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_TYPEFRAG, MSG_KILL);
 376                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 377                                 } else {
 378                                         Send_CSQC_Centerprint(attacker, s, GetAdvancedDeathReports(targ), KILL_FRAG, MSG_KILL);
 379                                         Send_CSQC_Centerprint(targ, a, GetAdvancedDeathReports(attacker), KILL_FRAGGED, MSG_KILL);
 380                                 }
 381
 382                                 attacker.taunt_soundtime = time + 1;
 383
 384                                 // TODO: fix this?
 385                                 if (deathtype == DEATH_CUSTOM)
 386                                         msg = deathmessage;
 387                                 else
 388                                         msg = inflictor.message2;
 389
 390                                 if(strstrofs(msg, "%", 0) < 0)
 391                                         msg = strcat("%s ", msg, " by %s");
 392
 393                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 394
 395                                 if(g_ctf && targ.flagcarried)
 396                                 {
 397                                         UpdateFrags(attacker, ctf_score_value("score_kill"));
 398                                         PlayerScore_Add(attacker, SP_CTF_FCKILLS, 1);
 399                                         GiveFrags(attacker, targ, 0, deathtype); // for logging
 400                                 }
 401                                 else
 402                                         GiveFrags(attacker, targ, 1, deathtype);
 403
 404                                 if (targ.killcount > 2) {
 405                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 406                                 }
 407
 408                                 attacker.killcount = attacker.killcount + 1;
 409
 410                                 if (attacker.killcount > 2) {
 411                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 412                                 }
 413                                 else if (attacker.killcount == 3)
 414                                 {
 415                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 416                                         AnnounceTo(attacker, "03kills");
 417                                 }
 418                                 else if (attacker.killcount == 5)
 419                                 {
 420                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 421                                         AnnounceTo(attacker, "05kills");
 422                                 }
 423                                 else if (attacker.killcount == 10)
 424                                 {
 425                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 426                                         AnnounceTo(attacker, "10kills");
 427                                 }
 428                                 else if (attacker.killcount == 15)
 429                                 {
 430                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 431                                         AnnounceTo(attacker, "15kills");
 432                                 }
 433                                 else if (attacker.killcount == 20)
 434                                 {
 435                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 436                                         AnnounceTo(attacker, "20kills");
 437                                 }
 438                                 else if (attacker.killcount == 25)
 439                                 {
 440                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 441                                         AnnounceTo(attacker, "25kills");
 442                                 }
 443                                 else if (attacker.killcount == 30)
 444                                 {
 445                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 446                                         AnnounceTo(attacker, "30kills");
 447                                 }
 448                                 LogDeath("frag", deathtype, attacker, targ);
 449                         }
 450                 }
 451                 else
 452                 {
 453                         Send_CSQC_Centerprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 454                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 455                                 msg = inflictor.message;
 456                         else if (deathtype == DEATH_CUSTOM)
 457                                 msg = deathmessage;
 458                         if(strstrofs(msg, "%", 0) < 0)
 459                                 msg = strcat("%s ", msg);
 460
 461                         GiveFrags(targ, targ, -1, deathtype);
 462                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 463                                 AnnounceTo(targ, "botlike");
 464                         }
 465                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 466
 467                         if (targ.killcount > 2)
 468                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 469
 470                         LogDeath("accident", deathtype, targ, targ);
 471                 }
 472
 473                 targ.death_origin = targ.origin;
 474                 if(targ != attacker)
 475                         targ.killer_origin = attacker.origin;
 476
 477                 // FIXME: this should go in PutClientInServer
 478                 if (targ.killcount)
 479                         targ.killcount = 0;
 480         }
 481 }
 482
 483 // these are updated by each Damage call for use in button triggering and such
 484 entity damage_targ;
 485 entity damage_inflictor;
 486 entity damage_attacker;
 487 .float prevhitsound;
 488
 489 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 490 {
 491         float mirrordamage;
 492         float mirrorforce;
 493         float teamdamage0;
 494         entity attacker_save;
 495         mirrordamage = 0;
 496         mirrorforce = 0;
 497
 498         if (gameover || targ.killcount == -666)
 499                 return;
 500
 501         local entity oldself;
 502         oldself = self;
 503         self = targ;
 504         damage_targ = targ;
 505         damage_inflictor = inflictor;
 506         damage_attacker = attacker;
 507                 attacker_save = attacker;
 508
 509         if(targ.classname == "player")
 510                 if(targ.hook)
 511                         if(targ.hook.aiment)
 512                                 if(targ.hook.aiment == attacker)
 513                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 514
 515         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 516         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 517         {
 518                 if(targ.classname == "player")
 519                         if not(IsDifferentTeam(targ, attacker))
 520                         {
 521                                 self = oldself;
 522                                 return;
 523                         }
 524         }
 525
 526         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 527         {
 528                 // These are ALWAYS lethal
 529                 // No damage modification here
 530                 // Instead, prepare the victim for his death...
 531                 targ.armorvalue = 0;
 532                 targ.spawnshieldtime = 0;
 533                 targ.health = 0.9; // this is < 1
 534                 targ.flags -= targ.flags & FL_GODMODE;
 535                 damage = 100000;
 536         }
 537         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 538         {
 539                 // no processing
 540         }
 541         else
 542         {
 543                 if (targ.classname == "player")
 544                 if (attacker.classname == "player")
 545                 if (!targ.isbot)
 546                 if (attacker.isbot)
 547                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 548
 549                 // nullify damage if teamplay is on
 550                 if(deathtype != DEATH_TELEFRAG)
 551                 if(attacker.classname == "player")
 552                 {
 553                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 554                         {
 555                                 damage = 0;
 556                                 force = '0 0 0';
 557                         }
 558                         else if(teams_matter && attacker.team == targ.team)
 559                         {
 560                                 if(autocvar_teamplay_mode == 1)
 561                                         damage = 0;
 562                                 else if(attacker != targ)
 563                                 {
 564                                         if(autocvar_teamplay_mode == 3)
 565                                                 damage = 0;
 566                                         else if(autocvar_teamplay_mode == 4)
 567                                         {
 568                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 569                                                 {
 570                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 571                                                         attacker.dmg_team = attacker.dmg_team + damage;
 572                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 573                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 574                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 575                                                         if(g_minstagib)
 576                                                         {
 577                                                                 if(autocvar_g_friendlyfire == 0)
 578                                                                         damage = 0;
 579                                                         }
 580                                                         else if(g_ca)
 581                                                                 damage = 0;
 582                                                         else
 583                                                                 damage = autocvar_g_friendlyfire * damage;
 584                                                         // mirrordamage will be used LATER
 585                                                 }
 586                                                 else
 587                                                         damage = 0;
 588                                         }
 589                                 }
 590                         }
 591                 }
 592
 593                 if(targ.classname == "player")
 594                 if(attacker.classname == "player")
 595                 if(attacker != targ)
 596                 {
 597                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 598                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 599                 }
 600
 601                 if(targ.classname == "player")
 602                 if (g_minstagib)
 603                 {
 604                         if ((deathtype == DEATH_FALL)  ||
 605                                 (deathtype == DEATH_DROWN) ||
 606                                 (deathtype == DEATH_SLIME) ||
 607                                 (deathtype == DEATH_LAVA)  ||
 608                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 609                         {
 610                                 self = oldself;
 611                                 return;
 612                         }
 613                         if(damage > 0)
 614                             damage = 10000;
 615                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 616                         {
 617                                 targ.armorvalue -= 1;
 618                                 centerprint(targ, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(targ.armorvalue)));
 619                                 damage = 0;
 620                                 targ.hitsound += 1;
 621                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 622                         }
 623                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 624                         {
 625                                 damage = 0;
 626                                 if (targ != attacker)
 627                                 {
 628                                         if ((targ.health >= 1) && (targ.classname == "player"))
 629                                                 centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "Secondary fire inflicts no damage!"));
 630                                         damage = 0;
 631                                         mirrordamage = 0;
 632                                         force = '0 0 0';
 633                                         // keep mirrorforce
 634                                         attacker = targ;
 635                                 }
 636                         }
 637                 }
 638
 639                 if not(DEATH_ISSPECIAL(deathtype))
 640                 {
 641                         damage *= g_weapondamagefactor;
 642                         mirrordamage *= g_weapondamagefactor;
 643                         force = force * g_weaponforcefactor;
 644                         mirrorforce *= g_weaponforcefactor;
 645                 }
 646
 647                 // should this be changed at all? If so, in what way?
 648                 frag_attacker = attacker;
 649                 frag_target = targ;
 650                 frag_damage = damage;
 651                 frag_force = force;
 652         frag_deathtype = deathtype;
 653                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 654                 damage = frag_damage;
 655                 force = frag_force;
 656
 657                 // apply strength multiplier
 658                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 659                 {
 660                         if(targ == attacker)
 661                         {
 662                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 663                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 664                         }
 665                         else
 666                         {
 667                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 668                                 force = force * autocvar_g_balance_powerup_strength_force;
 669                         }
 670                 }
 671
 672                 // apply invincibility multiplier
 673                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 674                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 675
 676                 if (targ == attacker)
 677                 {
 678                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 679                                 damage = 0;
 680                         else
 681                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 682                 }
 683
 684                 // CTF: reduce damage/force
 685                 if(g_ctf)
 686                 if(targ == attacker)
 687                 if(targ.flagcarried)
 688                 {
 689                         damage = damage * autocvar_g_ctf_flagcarrier_selfdamage;
 690                         force = force * autocvar_g_ctf_flagcarrier_selfforce;
 691                 }
 692
 693                 if(g_runematch)
 694                 {
 695                         // apply strength rune
 696                         if (attacker.runes & RUNE_STRENGTH)
 697                         {
 698                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 699                                 {
 700                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 701                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 702                                 }
 703                                 else
 704                                 {
 705                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 706                                         force = force * autocvar_g_balance_rune_strength_force;
 707                                 }
 708                         }
 709                         else if (attacker.runes & CURSE_WEAK)
 710                         {
 711                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 712                                 force = force * autocvar_g_balance_curse_weak_force;
 713                         }
 714
 715                         // apply defense rune
 716                         if (targ.runes & RUNE_DEFENSE)
 717                         {
 718                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 719                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 720                                 else
 721                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 722                         }
 723                         else if (targ.runes & CURSE_VULNER)
 724                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 725                 }
 726
 727                 // count the damage
 728                 if(attacker)
 729                 if(!targ.deadflag)
 730                 if(targ.takedamage == DAMAGE_AIM)
 731                 if(targ != attacker)
 732                 {
 733                         if(targ.classname == "player")
 734                         {
 735                                 // HEAD SHOT:
 736                                 // find height of hit on player axis
 737                                 // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 738                                 vector headmins, headmaxs, org;
 739                                 org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 740                                 headmins = org + GetHeadshotMins(targ);
 741                                 headmaxs = org + GetHeadshotMaxs(targ);
 742                                 if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 743                                 {
 744                                         deathtype |= HITTYPE_HEADSHOT;
 745                                 }
 746                         }
 747                         else if(targ.classname == "turret_head")
 748                         {
 749                                 deathtype |= HITTYPE_HEADSHOT;
 750                         }
 751                         if(deathtype & HITTYPE_HEADSHOT)
 752                                 damage *= 1 + damage_headshotbonus;
 753
 754                         if(targ.classname == "player")
 755                         {
 756                                 if(IsDifferentTeam(targ, attacker))
 757                                 {
 758                                         if(damage > 0)
 759                                         {
 760                                                 if(attacker.weapon != WEP_ELECTRO && attacker.weapon != WEP_LASER || ((attacker.weapon == WEP_ELECTRO && autocvar_g_balance_electro_lightning || attacker.weapon == WEP_LASER) && attacker.prevhitsound + autocvar_sv_hitsound_antispam_time < time))
 761                                                 {
 762                                                         if(targ.BUTTON_CHAT)
 763                                                                 attacker.typehitsound += 1;
 764                                                         else
 765                                                                 attacker.hitsound += 1;
 766                                                         attacker.prevhitsound = time;
 767                                                 }
 768
 769                                                 damage_goodhits += 1;
 770                                                 damage_gooddamage += damage;
 771
 772                                                 if not(DEATH_ISSPECIAL(deathtype))
 773                                                 {
 774                                                         if(!g_minstagib)
 775                                                         if(IsFlying(targ))
 776                                                                 yoda = 1;
 777
 778                                                         if(g_minstagib)
 779                                                         if(targ.items & IT_STRENGTH)
 780                                                                 yoda = 1;
 781
 782                                                         if(deathtype & HITTYPE_HEADSHOT)
 783                                                                 headshot = 1;
 784                                                 }
 785                                                 if(g_ca)
 786                                                         PlayerScore_Add(attacker, SP_SCORE, damage * autocvar_g_ca_damage2score_multiplier);
 787                                         }
 788                                 }
 789                                 else
 790                                 {
 791                                         if(deathtype != DEATH_FIRE)
 792                                                 attacker.typehitsound += 1;
 793                                         if(mirrordamage > 0)
 794                                                 if(time > attacker.teamkill_complain)
 795                                                 {
 796                                                         attacker.teamkill_complain = time + 5;
 797                                                         attacker.teamkill_soundtime = time + 0.4;
 798                                                         attacker.teamkill_soundsource = targ;
 799                                                 }
 800                                 }
 801                         }
 802                 }
 803         }
 804
 805         // apply push
 806         if (self.damageforcescale)
 807         if (vlen(force))
 808         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 809         {
 810                 self.velocity = self.velocity + self.damageforcescale * force;
 811                 self.flags &~= FL_ONGROUND;
 812                 UpdateCSQCProjectile(self);
 813         }
 814         // apply damage
 815         if (damage != 0 || (self.damageforcescale && vlen(force)))
 816         if (self.event_damage)
 817                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 818         self = oldself;
 819
 820         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 821         {
 822                 if(g_runematch)
 823                 {
 824                         if (attacker.runes & RUNE_VAMPIRE)
 825                         {
 826                         // apply vampire rune
 827                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 828                                 {
 829                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 830                                         attacker.health = bound(
 831                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 832                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 833                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 834                                 }
 835                                 else
 836                                 {
 837                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 838                                         attacker.health = bound(
 839                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 840                                                                                         // empathy won't let you gain health in the same way...
 841                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 842                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 843                                         }
 844                         }
 845                         // apply empathy curse
 846                         else if (attacker.runes & CURSE_EMPATHY)
 847                         {
 848                                 attacker.health = bound(
 849                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 850                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 851                                         attacker.health);
 852                         }
 853                 }
 854         }
 855
 856         // apply mirror damage if any
 857         if(mirrordamage > 0 || mirrorforce > 0)
 858         {
 859                 attacker = attacker_save;
 860                 if(g_minstagib)
 861                         if(mirrordamage > 0)
 862                         {
 863                                 // just lose extra LIVES, don't kill the player for mirror damage
 864                                 if(attacker.armorvalue > 0)
 865                                 {
 866                                         attacker.armorvalue = attacker.armorvalue - 1;
 867                                         centerprint(attacker, strcat(DAMAGE_CENTERPRINT_SPACER, "^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 868                                         attacker.hitsound += 1;
 869                                 }
 870                                 mirrordamage = 0;
 871                         }
 872                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 873                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 874         }
 875 }
 876
 877 float RadiusDamage_running;
 878 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 879 // Returns total damage applies to creatures
 880 {
 881         entity  targ;
 882         float   finaldmg;
 883         float   power;
 884         vector  blastorigin;
 885         vector  force;
 886         vector  diff;
 887         vector  center;
 888         vector  nearest;
 889         float   total_damage_to_creatures;
 890         entity  next;
 891         float   tfloordmg;
 892         float   tfloorforce;
 893
 894         float stat_damagedone;
 895
 896         if(RadiusDamage_running)
 897         {
 898                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 899                 return 0;
 900         }
 901
 902         RadiusDamage_running = 1;
 903
 904         tfloordmg = autocvar_g_throughfloor_damage;
 905         tfloorforce = autocvar_g_throughfloor_force;
 906
 907         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 908         total_damage_to_creatures = 0;
 909
 910         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 911         if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 912         {
 913                 force = inflictor.velocity;
 914                 if(vlen(force) == 0)
 915                         force = '0 0 -1';
 916                 else
 917                         force = normalize(force);
 918                 if(forceintensity >= 0)
 919                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, attacker);
 920                 else
 921                         Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, attacker);
 922         }
 923
 924         stat_damagedone = 0;
 925
 926         targ = WarpZone_FindRadius (blastorigin, rad, FALSE);
 927         while (targ)
 928         {
 929                 next = targ.chain;
 930                 if (targ != inflictor)
 931                         if (ignore != targ) if(targ.takedamage)
 932                         {
 933                                 // LordHavoc: measure distance to nearest point on target (not origin)
 934                                 // (this guarentees 100% damage on a touch impact)
 935                                 nearest = targ.WarpZone_findradius_nearest;
 936                                 diff = targ.WarpZone_findradius_dist;
 937                                 // round up a little on the damage to ensure full damage on impacts
 938                                 // and turn the distance into a fraction of the radius
 939                                 power = 1 - ((vlen (diff) - 2) / rad);
 940                                 //bprint(" ");
 941                                 //bprint(ftos(power));
 942                                 //if (targ == attacker)
 943                                 //      print(ftos(power), "\n");
 944                                 if (power > 0)
 945                                 {
 946                                         if (power > 1)
 947                                                 power = 1;
 948                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 949                                         if (finaldmg > 0)
 950                                         {
 951                                                 local float a;
 952                                                 local float c;
 953                                                 local float hits;
 954                                                 local float total;
 955                                                 local float hitratio;
 956                                                 local vector hitloc;
 957                                                 local vector myblastorigin;
 958                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 959                                                 center = targ.origin + (targ.mins + targ.maxs) * 0.5;
 960                                                 // if it's a player, use the view origin as reference
 961                                                 if (targ.classname == "player")
 962                                                         center = targ.origin + targ.view_ofs;
 963                                                 force = normalize(center - myblastorigin);
 964                                                 force = force * (finaldmg / coredamage) * forceintensity;
 965                                                 // test line of sight to multiple positions on box,
 966                                                 // and do damage if any of them hit
 967                                                 hits = 0;
 968                                                 if (targ.classname == "player")
 969                                                         total = ceil(bound(1, finaldmg, 50));
 970                                                 else
 971                                                         total = ceil(bound(1, finaldmg/10, 5));
 972                                                 hitloc = nearest;
 973                                                 c = 0;
 974                                                 while (c < total)
 975                                                 {
 976                                                         //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 977                                                         WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 978                                                         if (trace_fraction == 1 || trace_ent == targ)
 979                                                         {
 980                                                                 hits = hits + 1;
 981                                                                 if (hits > 1)
 982                                                                         hitloc = hitloc + nearest;
 983                                                                 else
 984                                                                         hitloc = nearest;
 985                                                         }
 986                                                         nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 987                                                         nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 988                                                         nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 989                                                         c = c + 1;
 990                                                 }
 991                                                 nearest = hitloc * (1 / max(1, hits));
 992                                                 hitratio = (hits / total);
 993                                                 a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 994                                                 finaldmg = finaldmg * a;
 995                                                 a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 996                                                 force = force * a;
 997
 998                                                 // laser force adjustments :P
 999                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1000                                                 {
1001                                                         vector vel;
1002
1003                                                         float force_zscale;
1004                                                         float force_velocitybiasramp;
1005                                                         float force_velocitybias;
1006
1007                                                         force_velocitybiasramp = autocvar_sv_maxspeed;
1008                                                         if(deathtype & HITTYPE_SECONDARY)
1009                                                         {
1010                                                                 force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1011                                                                 force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1012                                                         }
1013                                                         else
1014                                                         {
1015                                                                 force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1016                                                                 force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1017                                                         }
1018
1019                                                         vel = targ.velocity;
1020                                                         vel_z = 0;
1021                                                         vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1022                                                         force =
1023                                                                 vlen(force)
1024                                                                 *
1025                                                                 normalize(normalize(force) + vel);
1026
1027                                                         force_z *= force_zscale;
1028                                                 }
1029
1030                                                 //if (targ == attacker)
1031                                                 //{
1032                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1033                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1034                                                 //      print(" (", ftos(a), ")\n");
1035                                                 //}
1036                                                 if(hits || tfloordmg || tfloorforce)
1037                                                 {
1038                                                         if(targ.iscreature)
1039                                                         {
1040                                                                 total_damage_to_creatures += finaldmg;
1041
1042                                                                 if(accuracy_isgooddamage(attacker, targ))
1043                                                                         stat_damagedone += finaldmg;
1044                                                         }
1045
1046                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1047                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1048                                                         else
1049                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1050                                                 }
1051                                         }
1052                                 }
1053                         }
1054                 targ = next;
1055         }
1056
1057         RadiusDamage_running = 0;
1058
1059         if(!DEATH_ISSPECIAL(deathtype))
1060                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1061
1062         return total_damage_to_creatures;
1063 }
1064
1065 .float fire_damagepersec;
1066 .float fire_endtime;
1067 .float fire_deathtype;
1068 .entity fire_owner;
1069 .float fire_hitsound;
1070 .entity fire_burner;
1071
1072 void fireburner_think();
1073
1074 float Fire_IsBurning(entity e)
1075 {
1076         return (time < e.fire_endtime);
1077 }
1078
1079 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1080 {
1081         float dps;
1082         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1083
1084         if(e.classname == "player")
1085         {
1086                 if(e.deadflag)
1087                         return -1;
1088         }
1089         else
1090         {
1091                 if(!e.fire_burner)
1092                 {
1093                         // print("adding a fire burner to ", e.classname, "\n");
1094                         e.fire_burner = spawn();
1095                         e.fire_burner.classname = "fireburner";
1096                         e.fire_burner.think = fireburner_think;
1097                         e.fire_burner.nextthink = time;
1098                         e.fire_burner.owner = e;
1099                 }
1100         }
1101
1102         t = max(t, 0.1);
1103         dps = d / t;
1104         if(Fire_IsBurning(e))
1105         {
1106                 mintime = e.fire_endtime - time;
1107                 maxtime = max(mintime, t);
1108
1109                 mindps = e.fire_damagepersec;
1110                 maxdps = max(mindps, dps);
1111
1112                 if(maxtime > mintime || maxdps > mindps)
1113                 {
1114                         mindamage = mindps * mintime;
1115                         maxdamage = mindamage + d;
1116
1117                         // interval [mintime, maxtime] * [mindps, maxdps]
1118                         // intersected with
1119                         // [mindamage, maxdamage]
1120                         // maximum of this!
1121
1122                         if(maxdamage >= maxtime * maxdps)
1123                         {
1124                                 totaltime = maxtime;
1125                                 totaldamage = maxtime * maxdps;
1126
1127                                 // this branch increases totaldamage if either t > mintime, or dps > mindps
1128                         }
1129                         else
1130                         {
1131                                 // maxdamage is inside the interval!
1132                                 // first, try to use mindps; only if this fails, increase dps as needed
1133                                 totaltime = min(maxdamage / mindps, maxtime); // maxdamage / mindps >= mindamage / mindps = mintime
1134                                 totaldamage = maxdamage;
1135                                 // can totaldamage / totaltime be >= maxdps?
1136                                 // max(mindps, maxdamage / maxtime) >= maxdps?
1137                                 // we know maxdamage < maxtime * maxdps
1138                                 // so it cannot be
1139
1140                                 // this branch ALWAYS increases totaldamage, but requires maxdamage < maxtime * maxdps
1141                         }
1142
1143                         // total conditions for increasing:
1144                         //     maxtime > mintime OR maxdps > mindps OR maxtime * maxdps > maxdamage
1145                         // however:
1146                         //     if maxtime = mintime, maxdps = mindps
1147                         // then:
1148                         //     maxdamage = mindamage + d
1149                         //     mindamage = mindps * mintime = maxdps * maxtime < maxdamage!
1150                         // so the last condition is not needed
1151
1152                         e.fire_damagepersec = totaldamage / totaltime;
1153                         e.fire_endtime = time + totaltime;
1154                         if(totaldamage > 1.2 * mindamage)
1155                         {
1156                                 e.fire_deathtype = dt;
1157                                 if(e.fire_owner != o)
1158                                 {
1159                                         e.fire_owner = o;
1160                                         e.fire_hitsound = FALSE;
1161                                 }
1162                         }
1163                         if(accuracy_isgooddamage(o, e))
1164                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1165                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1166                 }
1167                 else
1168                         return 0;
1169         }
1170         else
1171         {
1172                 e.fire_damagepersec = dps;
1173                 e.fire_endtime = time + t;
1174                 e.fire_deathtype = dt;
1175                 e.fire_owner = o;
1176                 e.fire_hitsound = FALSE;
1177                 if(accuracy_isgooddamage(o, e))
1178                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1179                 return d;
1180         }
1181 }
1182
1183 void Fire_ApplyDamage(entity e)
1184 {
1185         float t, d, hi, ty;
1186         entity o;
1187
1188         if not(Fire_IsBurning(e))
1189                 return;
1190
1191         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1192         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1193                 o = e.fire_owner;
1194
1195         // water and slime stop fire
1196         if(e.waterlevel)
1197         if(e.watertype != CONTENT_LAVA)
1198                 e.fire_endtime = 0;
1199
1200         t = min(frametime, e.fire_endtime - time);
1201         d = e.fire_damagepersec * t;
1202
1203         hi = e.fire_owner.hitsound;
1204         ty = e.fire_owner.typehitsound;
1205         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1206         if(e.fire_hitsound && e.fire_owner)
1207         {
1208                 e.fire_owner.hitsound = hi;
1209                 e.fire_owner.typehitsound = ty;
1210         }
1211         e.fire_hitsound = TRUE;
1212
1213         if not(IS_INDEPENDENT_PLAYER(e))
1214         FOR_EACH_PLAYER(other) if(e != other)
1215         {
1216                 if(other.classname == "player")
1217                 if(other.deadflag == DEAD_NO)
1218                 if not(IS_INDEPENDENT_PLAYER(other))
1219                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1220                 {
1221                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1222                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1223                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1224                 }
1225         }
1226 }
1227
1228 void Fire_ApplyEffect(entity e)
1229 {
1230         if(Fire_IsBurning(e))
1231                 e.effects |= EF_FLAME;
1232         else
1233                 e.effects &~= EF_FLAME;
1234 }
1235
1236 void fireburner_think()
1237 {
1238         // for players, this is done in the regular loop
1239         if(wasfreed(self.owner))
1240         {
1241                 remove(self);
1242                 return;
1243         }
1244         Fire_ApplyEffect(self.owner);
1245         if(!Fire_IsBurning(self.owner))
1246         {
1247                 self.owner.fire_burner = world;
1248                 remove(self);
1249                 return;
1250         }
1251         Fire_ApplyDamage(self.owner);
1252         self.nextthink = time;
1253 }