qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(targ != attacker) // not for suicides
 124         if(g_weaponarena_random)
 125         {
 126                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 127                 float culprit;
 128                 culprit = DEATH_WEAPONOF(deathtype);
 129                 if(!culprit)
 130                         culprit = attacker.weapon;
 131                 else if(!(attacker.weapons & WepSet_FromWeapon(culprit)))
 132                         culprit = attacker.weapon;
 133
 134                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 135                 {
 136                         // no exchange
 137                 }
 138                 else
 139                 {
 140                         if(!GiveFrags_randomweapons)
 141                         {
 142                                 GiveFrags_randomweapons = spawn();
 143                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 144                         }
 145
 146                         if(warmup_stage)
 147                                 GiveFrags_randomweapons.weapons = warmup_start_weapons;
 148                         else
 149                                 GiveFrags_randomweapons.weapons = start_weapons;
 150
 151                         // all others (including the culprit): remove
 152                         GiveFrags_randomweapons.weapons &= ~attacker.weapons;
 153                         GiveFrags_randomweapons.weapons &= ~WepSet_FromWeapon(culprit);
 154
 155                         // among the remaining ones, choose one by random
 156                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 157
 158                         if(GiveFrags_randomweapons.weapons)
 159                         {
 160                                 attacker.weapons |= GiveFrags_randomweapons.weapons;
 161                                 attacker.weapons &= ~WepSet_FromWeapon(culprit);
 162                         }
 163                 }
 164
 165                 // after a frag, choose another random weapon set
 166                 if not(attacker.weapons & WepSet_FromWeapon(attacker.weapon))
 167                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 168         }
 169
 170         // FIXME fix the mess this is (we have REAL points now!)
 171         entity oldself;
 172         oldself = self;
 173         self = attacker;
 174         frag_attacker = attacker;
 175         frag_target = targ;
 176         frag_score = f;
 177         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 178         {
 179                 f = frag_score;
 180                 self = oldself;
 181         }
 182         else
 183         {
 184                 self = oldself;
 185         }
 186
 187         attacker.totalfrags += f;
 188
 189         if(f)
 190                 UpdateFrags(attacker, f);
 191 }
 192
 193 string AppendItemcodes(string s, entity player)
 194 {
 195         float w;
 196         w = player.weapon;
 197         //if(w == 0)
 198         //      w = player.switchweapon;
 199         if(w == 0)
 200                 w = player.cnt; // previous weapon!
 201         s = strcat(s, ftos(w));
 202         if(time < player.strength_finished)
 203                 s = strcat(s, "S");
 204         if(time < player.invincible_finished)
 205                 s = strcat(s, "I");
 206         if(player.flagcarried != world)
 207                 s = strcat(s, "F");
 208         if(player.BUTTON_CHAT)
 209                 s = strcat(s, "T");
 210         if(player.kh_next)
 211                 s = strcat(s, "K");
 212         return s;
 213 }
 214
 215 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 216 {
 217         string s;
 218         if(!autocvar_sv_eventlog)
 219                 return;
 220         s = strcat(":kill:", mode);
 221         s = strcat(s, ":", ftos(killer.playerid));
 222         s = strcat(s, ":", ftos(killed.playerid));
 223         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 224         s = strcat(s, ":items=");
 225         s = AppendItemcodes(s, killer);
 226         if(killed != killer)
 227         {
 228                 s = strcat(s, ":victimitems=");
 229                 s = AppendItemcodes(s, killed);
 230         }
 231         GameLogEcho(s);
 232 }
 233
 234 void Obituary_SpecialDeath(
 235         entity notif_target,
 236         float murder,
 237         float deathtype,
 238         string s1, string s2, string s3,
 239         float f1, float f2, float f3)
 240 {
 241         if(DEATH_ISSPECIAL(deathtype))
 242         {
 243                 entity deathent = deathtypes[(deathtype - DT_FIRST)];
 244                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 245
 246                 if(murder)
 247                 {
 248                         if(deathent.death_msgmurder)
 249                         {
 250                                 Send_Notification_WOCOVA(
 251                                         NOTIF_ONE,
 252                                         notif_target,
 253                                         MSG_MULTI,
 254                                         deathent.death_msgmurder.nent_id,
 255                                         s1, s2, s3, "",
 256                                         f1, f2, f3, 0
 257                                 );
 258                                 Send_Notification_WOCOVA(
 259                                         NOTIF_ALL_EXCEPT,
 260                                         notif_target,
 261                                         MSG_INFO,
 262                                         deathent.death_msgmurder.nent_msginfo.nent_id,
 263                                         s1, s2, s3, "",
 264                                         f1, f2, f3, 0
 265                                 );
 266                         }
 267                 }
 268                 else
 269                 {
 270                         if(deathent.death_msgself)
 271                         {
 272                                 Send_Notification_WOCOVA(
 273                                         NOTIF_ONE,
 274                                         notif_target,
 275                                         MSG_MULTI,
 276                                         deathent.death_msgself.nent_id,
 277                                         s1, s2, s3, "",
 278                                         f1, f2, f3, 0
 279                                 );
 280                                 Send_Notification_WOCOVA(
 281                                         NOTIF_ALL_EXCEPT,
 282                                         notif_target,
 283                                         MSG_INFO,
 284                                         deathent.death_msgself.nent_msginfo.nent_id,
 285                                         s1, s2, s3, "",
 286                                         f1, f2, f3, 0
 287                                 );
 288                         }
 289                 }
 290         }
 291         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 292 }
 293
 294 float w_deathtype;
 295 float Obituary_WeaponDeath(
 296         entity notif_target,
 297         float murder,
 298         float deathtype,
 299         string s1, string s2, string s3,
 300         float f1, float f2)
 301 {
 302         float death_weapon = DEATH_WEAPONOF(deathtype);
 303         if(death_weapon)
 304         {
 305                 w_deathtype = deathtype;
 306                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 307                 w_deathtype = FALSE;
 308
 309                 if(death_message)
 310                 {
 311                         Send_Notification_WOCOVA(
 312                                 NOTIF_ONE,
 313                                 notif_target,
 314                                 MSG_MULTI,
 315                                 death_message,
 316                                 s1, s2, s3, "",
 317                                 f1, f2, 0, 0
 318                         );
 319                         Send_Notification_WOCOVA(
 320                                 NOTIF_ALL_EXCEPT,
 321                                 notif_target,
 322                                 MSG_INFO,
 323                                 msg_multi_notifs[death_message - 1].nent_msginfo.nent_id,
 324                                 s1, s2, s3, "",
 325                                 f1, f2, 0, 0
 326                         );
 327                 }
 328                 else
 329                 {
 330                         dprint(sprintf(
 331                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%d)^1 has no notification for weapon %d!\n",
 332                                 deathtype,
 333                                 death_weapon
 334                         ));
 335                 }
 336
 337                 return TRUE;
 338         }
 339         return FALSE;
 340 }
 341
 342 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 343 {
 344         // Sanity check
 345         if not(IS_PLAYER(targ)) { backtrace("Obituary called on non-player?!\n"); return; }
 346
 347         // Declarations
 348         float notif_firstblood = FALSE;
 349         float kill_count_to_attacker, kill_count_to_target;
 350
 351         // Set final information for the death
 352         targ.death_origin = targ.origin;
 353         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 354         string deathlocation = (autocvar_notification_server_allows_location ? NearestLocation(targ.death_origin) : "");
 355
 356         #ifdef NOTIFICATIONS_DEBUG
 357         Debug_Notification(
 358                 sprintf(
 359                         "Obituary(%s, %s, %s, %s = %d);\n",
 360                         attacker.netname,
 361                         inflictor.netname,
 362                         targ.netname,
 363                         Deathtype_Name(deathtype),
 364                         deathtype
 365                 )
 366         );
 367         #endif
 368
 369         // =======
 370         // SUICIDE
 371         // =======
 372         if(targ == attacker)
 373         {
 374                 if(DEATH_ISSPECIAL(deathtype))
 375                 {
 376                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 377                         {
 378                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 379                         }
 380                         else
 381                         {
 382                                 switch(deathtype)
 383                                 {
 384                                         case DEATH_MIRRORDAMAGE:
 385                                         {
 386                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 387                                                 break;
 388                                         }
 389
 390                                         default:
 391                                         {
 392                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 393                                                 break;
 394                                         }
 395                                 }
 396                         }
 397                 }
 398                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 399                 {
 400                         backtrace("SUICIDE: what the hell happened here?\n");
 401                         return;
 402                 }
 403                 LogDeath("suicide", deathtype, targ, targ);
 404                 GiveFrags(attacker, targ, -1, deathtype);
 405         }
 406
 407         // ======
 408         // MURDER
 409         // ======
 410         else if(IS_PLAYER(attacker))
 411         {
 412                 if(!IsDifferentTeam(attacker, targ))
 413                 {
 414                         LogDeath("tk", deathtype, attacker, targ);
 415                         GiveFrags(attacker, targ, -1, deathtype);
 416
 417                         attacker.killcount = 0;
 418
 419                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 420                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 421                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, deathlocation, targ.killcount);
 422
 423                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 424                         // No need for specific death/weapon messages...
 425                 }
 426                 else
 427                 {
 428                         LogDeath("frag", deathtype, attacker, targ);
 429                         GiveFrags(attacker, targ, 1, deathtype);
 430
 431                         attacker.taunt_soundtime = time + 1;
 432                         attacker.killcount = attacker.killcount + 1;
 433
 434                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 435                                 case counta: \
 436                                 { \
 437                                         Send_Notification(NOTIF_ONE, attacker, MSG_ANNCE, ANNCE_KILLSTREAK_##countb); \
 438                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 439                                         break; \
 440                                 }
 441                         switch(attacker.killcount)
 442                         {
 443                                 KILL_SPREE_LIST
 444                                 default: break;
 445                         }
 446                         #undef SPREE_ITEM
 447
 448                         if(!checkrules_firstblood)
 449                         {
 450                                 checkrules_firstblood = TRUE;
 451                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 452                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 453                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 454
 455                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 456                                 kill_count_to_attacker = -1;
 457                                 kill_count_to_target = -2;
 458                         }
 459                         else
 460                         {
 461                                 kill_count_to_attacker = attacker.killcount;
 462                                 kill_count_to_target = 0;
 463                         }
 464
 465                         if(targ.istypefrag)
 466                         {
 467                                 Send_Notification(
 468                                         NOTIF_ONE,
 469                                         attacker,
 470                                         MSG_CHOICE,
 471                                         CHOICE_TYPEFRAG,
 472                                         targ.netname,
 473                                         kill_count_to_attacker,
 474                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 475                                 );
 476                                 Send_Notification(
 477                                         NOTIF_ONE,
 478                                         targ,
 479                                         MSG_CHOICE,
 480                                         CHOICE_TYPEFRAGGED,
 481                                         attacker.netname,
 482                                         kill_count_to_target,
 483                                         attacker.health,
 484                                         attacker.armorvalue,
 485                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 486                                 );
 487                         }
 488                         else
 489                         {
 490                                 Send_Notification(
 491                                         NOTIF_ONE,
 492                                         attacker,
 493                                         MSG_CHOICE,
 494                                         CHOICE_FRAG,
 495                                         targ.netname,
 496                                         kill_count_to_attacker,
 497                                         (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping)
 498                                 );
 499                                 Send_Notification(
 500                                         NOTIF_ONE,
 501                                         targ,
 502                                         MSG_CHOICE,
 503                                         CHOICE_FRAGGED,
 504                                         attacker.netname,
 505                                         kill_count_to_target,
 506                                         attacker.health,
 507                                         attacker.armorvalue,
 508                                         (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping)
 509                                 );
 510                         }
 511
 512                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 513                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 514                 }
 515         }
 516
 517         // =============
 518         // ACCIDENT/TRAP
 519         // =============
 520         else
 521         {
 522                 switch(deathtype)
 523                 {
 524                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 525                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 526                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 527                         /*case DEATH_HURTTRIGGER:
 528                         {
 529                                 s1 = targ.netname;
 530                                 s2 = inflictor.message;
 531                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 532                                 break;
 533                         }*/
 534
 535                         case DEATH_CUSTOM:
 536                         {
 537                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 538                                         targ.netname,
 539                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 540                                         deathlocation,
 541                                         targ.killcount,
 542                                         0,
 543                                         0);
 544                                 break;
 545                         }
 546
 547                         default:
 548                         {
 549                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 550                                 break;
 551                         }
 552                 }
 553
 554                 LogDeath("accident", deathtype, targ, targ);
 555                 GiveFrags(targ, targ, -1, deathtype);
 556
 557                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 558                 {
 559                         Send_Notification(NOTIF_ONE, targ, MSG_ANNCE, ANNCE_ACHIEVEMENT_BOTLIKE);
 560                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 561                 }
 562         }
 563
 564         // reset target kill count
 565         if(targ.killcount) { targ.killcount = 0; }
 566 }
 567
 568 // these are updated by each Damage call for use in button triggering and such
 569 entity damage_targ;
 570 entity damage_inflictor;
 571 entity damage_attacker;
 572
 573 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 574 {
 575         float mirrordamage;
 576         float mirrorforce;
 577         float complainteamdamage = 0;
 578         entity attacker_save;
 579         mirrordamage = 0;
 580         mirrorforce = 0;
 581
 582         if (gameover || targ.killcount == -666)
 583                 return;
 584
 585         entity oldself;
 586         oldself = self;
 587         self = targ;
 588         damage_targ = targ;
 589         damage_inflictor = inflictor;
 590         damage_attacker = attacker;
 591                 attacker_save = attacker;
 592
 593         if(IS_PLAYER(targ))
 594                 if(targ.hook)
 595                         if(targ.hook.aiment)
 596                                 if(targ.hook.aiment == attacker)
 597                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 598
 599         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 600         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 601         {
 602                 if(IS_PLAYER(targ))
 603                         if not(IsDifferentTeam(targ, attacker))
 604                         {
 605                                 self = oldself;
 606                                 return;
 607                         }
 608         }
 609
 610         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 611         {
 612                 // These are ALWAYS lethal
 613                 // No damage modification here
 614                 // Instead, prepare the victim for his death...
 615                 targ.armorvalue = 0;
 616                 targ.spawnshieldtime = 0;
 617                 targ.health = 0.9; // this is < 1
 618                 targ.flags -= targ.flags & FL_GODMODE;
 619                 damage = 100000;
 620         }
 621         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 622         {
 623                 // no processing
 624         }
 625         else
 626         {
 627                 // nullify damage if teamplay is on
 628                 if(deathtype != DEATH_TELEFRAG)
 629                 if(IS_PLAYER(attacker))
 630                 {
 631                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 632                         {
 633                                 damage = 0;
 634                                 force = '0 0 0';
 635                         }
 636                         else if(!IsDifferentTeam(attacker, targ))
 637                         {
 638                                 if(autocvar_teamplay_mode == 1)
 639                                         damage = 0;
 640                                 else if(attacker != targ)
 641                                 {
 642                                         if(autocvar_teamplay_mode == 3)
 643                                                 damage = 0;
 644                                         else if(autocvar_teamplay_mode == 4)
 645                                         {
 646                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 647                                                 {
 648                                                         attacker.dmg_team = attacker.dmg_team + damage;
 649                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 650                                                         if(complainteamdamage > 0)
 651                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 652                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 653                                                         damage = autocvar_g_friendlyfire * damage;
 654                                                         // mirrordamage will be used LATER
 655
 656                                                         if(autocvar_g_mirrordamage_virtual)
 657                                                         {
 658                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 659                                                                 attacker.dmg_take += v_x;
 660                                                                 attacker.dmg_save += v_y;
 661                                                                 attacker.dmg_inflictor = inflictor;
 662                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 663                                                                 mirrorforce = 0;
 664                                                         }
 665
 666                                                         if(autocvar_g_friendlyfire_virtual)
 667                                                         {
 668                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 669                                                                 targ.dmg_take += v_x;
 670                                                                 targ.dmg_save += v_y;
 671                                                                 targ.dmg_inflictor = inflictor;
 672                                                                 damage = 0;
 673                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 674                                                                         force = '0 0 0';
 675                                                         }
 676                                                 }
 677                                                 else
 678                                                         damage = 0;
 679                                         }
 680                                 }
 681                         }
 682                 }
 683
 684                 if not(DEATH_ISSPECIAL(deathtype))
 685                 {
 686                         damage *= g_weapondamagefactor;
 687                         mirrordamage *= g_weapondamagefactor;
 688                         complainteamdamage *= g_weapondamagefactor;
 689                         force = force * g_weaponforcefactor;
 690                         mirrorforce *= g_weaponforcefactor;
 691                 }
 692
 693                 // should this be changed at all? If so, in what way?
 694                 frag_attacker = attacker;
 695                 frag_target = targ;
 696                 frag_damage = damage;
 697                 frag_force = force;
 698         frag_deathtype = deathtype;
 699                 frag_mirrordamage = mirrordamage;
 700                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 701                 damage = frag_damage;
 702                 mirrordamage = frag_mirrordamage;
 703                 force = frag_force;
 704
 705                 if not(g_minstagib)
 706                 {
 707                         // apply strength multiplier
 708                         if (attacker.items & IT_STRENGTH)
 709                         {
 710                                 if(targ == attacker)
 711                                 {
 712                                         damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 713                                         force = force * autocvar_g_balance_powerup_strength_selfforce;
 714                                 }
 715                                 else
 716                                 {
 717                                         damage = damage * autocvar_g_balance_powerup_strength_damage;
 718                                         force = force * autocvar_g_balance_powerup_strength_force;
 719                                 }
 720                         }
 721
 722                         // apply invincibility multiplier
 723                         if (targ.items & IT_INVINCIBLE)
 724                                 damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 725                 }
 726
 727                 if (targ == attacker)
 728                 {
 729                         if(g_cts && !autocvar_g_cts_selfdamage)
 730                                 damage = 0;
 731                         else
 732                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 733                 }
 734
 735                 // count the damage
 736                 if(attacker)
 737                 if(!targ.deadflag)
 738                 if(targ.takedamage == DAMAGE_AIM)
 739                 if(targ != attacker)
 740                 {
 741                         entity victim;
 742                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 743                                 victim = targ.owner;
 744                         else
 745                                 victim = targ;
 746
 747                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 748                         {
 749                                 if(IsDifferentTeam(victim, attacker))
 750                                 {
 751                                         if(damage > 0)
 752                                         {
 753                                                 if(deathtype != DEATH_FIRE)
 754                                                 {
 755                                                         if(victim.BUTTON_CHAT)
 756                                                                 attacker.typehitsound += 1;
 757                                                         else
 758                                                                 attacker.hitsound += 1;
 759                                                 }
 760
 761                                                 damage_goodhits += 1;
 762                                                 damage_gooddamage += damage;
 763
 764                                                 if not(DEATH_ISSPECIAL(deathtype))
 765                                                 {
 766                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 767                                                         if(IsFlying(victim))
 768                                                                 yoda = 1;
 769                                                 }
 770                                         }
 771                                 }
 772                                 else
 773                                 {
 774                                         if(deathtype != DEATH_FIRE)
 775                                         {
 776                                                 attacker.typehitsound += 1;
 777                                         }
 778                                         if(complainteamdamage > 0)
 779                                                 if(time > attacker.teamkill_complain)
 780                                                 {
 781                                                         attacker.teamkill_complain = time + 5;
 782                                                         attacker.teamkill_soundtime = time + 0.4;
 783                                                         attacker.teamkill_soundsource = targ;
 784                                                 }
 785                                 }
 786                         }
 787                 }
 788         }
 789
 790         // apply push
 791         if (self.damageforcescale)
 792         if (vlen(force))
 793         if (!IS_PLAYER(self) || time >= self.spawnshieldtime)
 794         {
 795                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 796                 if(self.movetype == MOVETYPE_PHYSICS)
 797                 {
 798                         entity farcent;
 799                         farcent = spawn();
 800                         farcent.classname = "farce";
 801                         farcent.enemy = self;
 802                         farcent.movedir = farce * 10;
 803                         if(self.mass)
 804                                 farcent.movedir = farcent.movedir * self.mass;
 805                         farcent.origin = hitloc;
 806                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 807                         farcent.nextthink = time + 0.1;
 808                         farcent.think = SUB_Remove;
 809                 }
 810                 else
 811                         self.velocity = self.velocity + farce;
 812                 self.flags &= ~FL_ONGROUND;
 813                 UpdateCSQCProjectile(self);
 814         }
 815         // apply damage
 816         if (damage != 0 || (self.damageforcescale && vlen(force)))
 817         if (self.event_damage)
 818                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 819         self = oldself;
 820
 821         // apply mirror damage if any
 822         if(mirrordamage > 0 || mirrorforce > 0)
 823         {
 824                 attacker = attacker_save;
 825
 826                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 827                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 828         }
 829 }
 830
 831 float RadiusDamage_running;
 832 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 833         // Returns total damage applies to creatures
 834 {
 835         entity  targ;
 836         vector  blastorigin;
 837         vector  force;
 838         float   total_damage_to_creatures;
 839         entity  next;
 840         float   tfloordmg;
 841         float   tfloorforce;
 842
 843         float stat_damagedone;
 844
 845         if(RadiusDamage_running)
 846         {
 847                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 848                 return 0;
 849         }
 850
 851         RadiusDamage_running = 1;
 852
 853         tfloordmg = autocvar_g_throughfloor_damage;
 854         tfloorforce = autocvar_g_throughfloor_force;
 855
 856         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 857         total_damage_to_creatures = 0;
 858
 859         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 860                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 861                 {
 862                         force = inflictor.velocity;
 863                         if(vlen(force) == 0)
 864                                 force = '0 0 -1';
 865                         else
 866                                 force = normalize(force);
 867                         if(forceintensity >= 0)
 868                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 869                         else
 870                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 871                 }
 872
 873         stat_damagedone = 0;
 874
 875         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 876         while (targ)
 877         {
 878                 next = targ.chain;
 879                 if (targ != inflictor)
 880                         if (ignore != targ) if(targ.takedamage)
 881                         {
 882                                 vector nearest;
 883                                 vector diff;
 884                                 float power;
 885
 886                                 // LordHavoc: measure distance to nearest point on target (not origin)
 887                                 // (this guarentees 100% damage on a touch impact)
 888                                 nearest = targ.WarpZone_findradius_nearest;
 889                                 diff = targ.WarpZone_findradius_dist;
 890                                 // round up a little on the damage to ensure full damage on impacts
 891                                 // and turn the distance into a fraction of the radius
 892                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 893                                 //bprint(" ");
 894                                 //bprint(ftos(power));
 895                                 //if (targ == attacker)
 896                                 //      print(ftos(power), "\n");
 897                                 if (power > 0)
 898                                 {
 899                                         float finaldmg;
 900                                         if (power > 1)
 901                                                 power = 1;
 902                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 903                                         if (finaldmg > 0)
 904                                         {
 905                                                 float a;
 906                                                 float c;
 907                                                 vector hitloc;
 908                                                 vector myblastorigin;
 909                                                 vector center;
 910
 911                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
 912
 913                                                 // if it's a player, use the view origin as reference
 914                                                 center = CENTER_OR_VIEWOFS(targ);
 915
 916                                                 force = normalize(center - myblastorigin);
 917                                                 force = force * (finaldmg / coredamage) * forceintensity;
 918                                                 hitloc = nearest;
 919
 920                                                 if(targ != directhitentity)
 921                                                 {
 922                                                         float hits;
 923                                                         float total;
 924                                                         float hitratio;
 925                                                         float mininv_f, mininv_d;
 926
 927                                                         // test line of sight to multiple positions on box,
 928                                                         // and do damage if any of them hit
 929                                                         hits = 0;
 930
 931                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
 932                                                         // so for a given max stddev:
 933                                                         // n = (1 / (2 * max stddev of hitratio))^2
 934
 935                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
 936                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
 937
 938                                                         if(autocvar_g_throughfloor_debug)
 939                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
 940
 941                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
 942
 943                                                         if(autocvar_g_throughfloor_debug)
 944                                                                 print(sprintf(" steps=%f", total));
 945
 946                                                         if (IS_PLAYER(targ))
 947                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
 948                                                         else
 949                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
 950
 951                                                         if(autocvar_g_throughfloor_debug)
 952                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
 953
 954                                                         for(c = 0; c < total; ++c)
 955                                                         {
 956                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
 957                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
 958                                                                 if (trace_fraction == 1 || trace_ent == targ)
 959                                                                 {
 960                                                                         ++hits;
 961                                                                         if (hits > 1)
 962                                                                                 hitloc = hitloc + nearest;
 963                                                                         else
 964                                                                                 hitloc = nearest;
 965                                                                 }
 966                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
 967                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
 968                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
 969                                                         }
 970
 971                                                         nearest = hitloc * (1 / max(1, hits));
 972                                                         hitratio = (hits / total);
 973                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
 974                                                         finaldmg = finaldmg * a;
 975                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
 976                                                         force = force * a;
 977
 978                                                         if(autocvar_g_throughfloor_debug)
 979                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
 980                                                 }
 981
 982                                                 // laser force adjustments :P
 983                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
 984                                                 {
 985                                                         if (targ == attacker)
 986                                                         {
 987                                                                 vector vel;
 988
 989                                                                 float force_zscale;
 990                                                                 float force_velocitybiasramp;
 991                                                                 float force_velocitybias;
 992
 993                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
 994                                                                 if(deathtype & HITTYPE_SECONDARY)
 995                                                                 {
 996                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
 997                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
 998                                                                 }
 999                                                                 else
1000                                                                 {
1001                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1002                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1003                                                                 }
1004
1005                                                                 vel = targ.velocity;
1006                                                                 vel_z = 0;
1007                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1008                                                                 force =
1009                                                                         vlen(force)
1010                                                                         *
1011                                                                         normalize(normalize(force) + vel);
1012
1013                                                                 force_z *= force_zscale;
1014                                                         }
1015                                                         else
1016                                                         {
1017                                                                 if(deathtype & HITTYPE_SECONDARY)
1018                                                                 {
1019                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1020                                                                 }
1021                                                                 else
1022                                                                 {
1023                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1024                                                                 }
1025                                                         }
1026                                                 }
1027
1028                                                 //if (targ == attacker)
1029                                                 //{
1030                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1031                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1032                                                 //      print(" (", ftos(a), ")\n");
1033                                                 //}
1034                                                 if(finaldmg || vlen(force))
1035                                                 {
1036                                                         if(targ.iscreature)
1037                                                         {
1038                                                                 total_damage_to_creatures += finaldmg;
1039
1040                                                                 if(accuracy_isgooddamage(attacker, targ))
1041                                                                         stat_damagedone += finaldmg;
1042                                                         }
1043
1044                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1045                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1046                                                         else
1047                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1048                                                 }
1049                                         }
1050                                 }
1051                         }
1052                 targ = next;
1053         }
1054
1055         RadiusDamage_running = 0;
1056
1057         if(!DEATH_ISSPECIAL(deathtype))
1058                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1059
1060         return total_damage_to_creatures;
1061 }
1062
1063 .float fire_damagepersec;
1064 .float fire_endtime;
1065 .float fire_deathtype;
1066 .entity fire_owner;
1067 .float fire_hitsound;
1068 .entity fire_burner;
1069
1070 void fireburner_think();
1071
1072 float Fire_IsBurning(entity e)
1073 {
1074         return (time < e.fire_endtime);
1075 }
1076
1077 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1078 {
1079         float dps;
1080         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1081
1082         if(IS_PLAYER(e))
1083         {
1084                 if(e.deadflag)
1085                         return -1;
1086         }
1087         else
1088         {
1089                 if(!e.fire_burner)
1090                 {
1091                         // print("adding a fire burner to ", e.classname, "\n");
1092                         e.fire_burner = spawn();
1093                         e.fire_burner.classname = "fireburner";
1094                         e.fire_burner.think = fireburner_think;
1095                         e.fire_burner.nextthink = time;
1096                         e.fire_burner.owner = e;
1097                 }
1098         }
1099
1100         t = max(t, 0.1);
1101         dps = d / t;
1102         if(Fire_IsBurning(e))
1103         {
1104                 mintime = e.fire_endtime - time;
1105                 maxtime = max(mintime, t);
1106
1107                 mindps = e.fire_damagepersec;
1108                 maxdps = max(mindps, dps);
1109
1110                 if(maxtime > mintime || maxdps > mindps)
1111                 {
1112                         // Constraints:
1113
1114                         // damage we have right now
1115                         mindamage = mindps * mintime;
1116
1117                         // damage we want to get
1118                         maxdamage = mindamage + d;
1119
1120                         // but we can't exceed maxtime * maxdps!
1121                         totaldamage = min(maxdamage, maxtime * maxdps);
1122
1123                         // LEMMA:
1124                         // Look at:
1125                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1126                         // We see:
1127                         // totaldamage <= maxtime * maxdps
1128                         // ==> totaldamage / maxdps <= maxtime.
1129                         // We also see:
1130                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1131                         //                     >= min(mintime, maxtime)
1132                         // ==> totaldamage / maxdps >= mintime.
1133
1134                         /*
1135                         // how long do we damage then?
1136                         // at least as long as before
1137                         // but, never exceed maxdps
1138                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1139                         */
1140
1141                         // alternate:
1142                         // at most as long as maximum allowed
1143                         // but, never below mindps
1144                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1145
1146                         // assuming t > mintime, dps > mindps:
1147                         // we get d = t * dps = maxtime * maxdps
1148                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1149                         // totaldamage / maxdps = maxtime
1150                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1151                         // FROM THIS:
1152                         // a) totaltime = max(mintime, maxtime) = maxtime
1153                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1154
1155                         // assuming t <= mintime:
1156                         // we get maxtime = mintime
1157                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1158                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1159
1160                         // assuming dps <= mindps:
1161                         // we get mindps = maxdps.
1162                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1163                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1164                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1165
1166                         e.fire_damagepersec = totaldamage / totaltime;
1167                         e.fire_endtime = time + totaltime;
1168                         if(totaldamage > 1.2 * mindamage)
1169                         {
1170                                 e.fire_deathtype = dt;
1171                                 if(e.fire_owner != o)
1172                                 {
1173                                         e.fire_owner = o;
1174                                         e.fire_hitsound = FALSE;
1175                                 }
1176                         }
1177                         if(accuracy_isgooddamage(o, e))
1178                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1179                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1180                 }
1181                 else
1182                         return 0;
1183         }
1184         else
1185         {
1186                 e.fire_damagepersec = dps;
1187                 e.fire_endtime = time + t;
1188                 e.fire_deathtype = dt;
1189                 e.fire_owner = o;
1190                 e.fire_hitsound = FALSE;
1191                 if(accuracy_isgooddamage(o, e))
1192                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1193                 return d;
1194         }
1195 }
1196
1197 void Fire_ApplyDamage(entity e)
1198 {
1199         float t, d, hi, ty;
1200         entity o;
1201
1202         if not(Fire_IsBurning(e))
1203                 return;
1204
1205         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1206         if(IS_NOT_A_CLIENT(o))
1207                 o = e.fire_owner;
1208
1209         // water and slime stop fire
1210         if(e.waterlevel)
1211         if(e.watertype != CONTENT_LAVA)
1212                 e.fire_endtime = 0;
1213
1214         // ice stops fire
1215         if(e.freezetag_frozen)
1216                 e.fire_endtime = 0;
1217
1218         t = min(frametime, e.fire_endtime - time);
1219         d = e.fire_damagepersec * t;
1220
1221         hi = e.fire_owner.hitsound;
1222         ty = e.fire_owner.typehitsound;
1223         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1224         if(e.fire_hitsound && e.fire_owner)
1225         {
1226                 e.fire_owner.hitsound = hi;
1227                 e.fire_owner.typehitsound = ty;
1228         }
1229         e.fire_hitsound = TRUE;
1230
1231         if not(IS_INDEPENDENT_PLAYER(e))
1232         FOR_EACH_PLAYER(other) if(e != other)
1233         {
1234                 if(IS_PLAYER(other))
1235                 if(other.deadflag == DEAD_NO)
1236                 if not(IS_INDEPENDENT_PLAYER(other))
1237                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1238                 {
1239                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1240                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1241                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1242                 }
1243         }
1244 }
1245
1246 void Fire_ApplyEffect(entity e)
1247 {
1248         if(Fire_IsBurning(e))
1249                 e.effects |= EF_FLAME;
1250         else
1251                 e.effects &= ~EF_FLAME;
1252 }
1253
1254 void fireburner_think()
1255 {
1256         // for players, this is done in the regular loop
1257         if(wasfreed(self.owner))
1258         {
1259                 remove(self);
1260                 return;
1261         }
1262         Fire_ApplyEffect(self.owner);
1263         if(!Fire_IsBurning(self.owner))
1264         {
1265                 self.owner.fire_burner = world;
1266                 remove(self);
1267                 return;
1268         }
1269         Fire_ApplyDamage(self.owner);
1270         self.nextthink = time;
1271 }