qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 220 {
 221         string health_output = string_null;
 222         string ping_output = string_null;
 223         string handicap_output = string_null;
 224         string output = string_null;
 225
 226         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 227         {
 228                 // health/armor of attacker (person who killed you)
 229                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 230                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 231
 232                 // ping display
 233                 if(autocvar_sv_fraginfo_ping)
 234                         ping_output = ((IS_BOT_CLIENT(player)) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 235
 236                 // handicap display
 237                 if(autocvar_sv_fraginfo_handicap)
 238                 {
 239                         if(autocvar_sv_fraginfo_handicap == 2)
 240                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 241                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 242                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 243                 }
 244
 245                 // format the string
 246                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 247                         ping_output, (handicap_output ? "^7 / " : ""),
 248                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 249
 250                 // add new line to the beginning if there is a message
 251                 if(output) { output = strcat("\n", output); }
 252         }
 253
 254         return output;
 255 }
 256
 257 string AppendItemcodes(string s, entity player)
 258 {
 259         float w;
 260         w = player.weapon;
 261         //if(w == 0)
 262         //      w = player.switchweapon;
 263         if(w == 0)
 264                 w = player.cnt; // previous weapon!
 265         s = strcat(s, ftos(w));
 266         if(time < player.strength_finished)
 267                 s = strcat(s, "S");
 268         if(time < player.invincible_finished)
 269                 s = strcat(s, "I");
 270         if(player.flagcarried != world)
 271                 s = strcat(s, "F");
 272         if(player.BUTTON_CHAT)
 273                 s = strcat(s, "T");
 274         if(player.kh_next)
 275                 s = strcat(s, "K");
 276         if(player.runes)
 277                 s = strcat(s, "|", ftos(player.runes));
 278         return s;
 279 }
 280
 281 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 282 {
 283         string s;
 284         if(!autocvar_sv_eventlog)
 285                 return;
 286         s = strcat(":kill:", mode);
 287         s = strcat(s, ":", ftos(killer.playerid));
 288         s = strcat(s, ":", ftos(killed.playerid));
 289         s = strcat(s, ":type=", ftos(deathtype));
 290         s = strcat(s, ":items=");
 291         s = AppendItemcodes(s, killer);
 292         if(killed != killer)
 293         {
 294                 s = strcat(s, ":victimitems=");
 295                 s = AppendItemcodes(s, killed);
 296         }
 297         GameLogEcho(s);
 298 }
 299
 300 void Send_KillNotification (string s1, string s2, string s3, float msg, float type)
 301 {
 302         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
 303         WriteByte(MSG_BROADCAST, TE_CSQC_KILLNOTIFY);
 304         WriteString(MSG_BROADCAST, s1);
 305         WriteString(MSG_BROADCAST, s2);
 306         WriteString(MSG_BROADCAST, s3);
 307         WriteShort(MSG_BROADCAST, msg);
 308         WriteByte(MSG_BROADCAST, type);
 309 }
 310
 311 // Function is used to send a generic centerprint whose content CSQC gets to decide (gentle version or not in the below cases)
 312 void Send_CSQC_KillCenterprint(entity e, string s1, string s2, float msg, float type)
 313 {
 314         if (IS_REAL_CLIENT(e))
 315         {
 316                 msg_entity = e;
 317                 WRITESPECTATABLE_MSG_ONE({
 318                         WriteByte(MSG_ONE, SVC_TEMPENTITY);
 319                         WriteByte(MSG_ONE, TE_CSQC_KILLCENTERPRINT);
 320                         WriteString(MSG_ONE, s1);
 321                         WriteString(MSG_ONE, s2);
 322                         WriteShort(MSG_ONE, msg);
 323                         WriteByte(MSG_ONE, type);
 324                 });
 325         }
 326 }
 327
 328 void Obituary (entity attacker, entity inflictor, entity targ, float deathtype)
 329 {
 330         string  s, a, msg;
 331         float type;
 332
 333         if (IS_PLAYER(targ))
 334         {
 335                 s = targ.netname;
 336                 a = attacker.netname;
 337
 338                 if (targ == attacker) // suicides
 339                 {
 340                         if (deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 341                                 msg = ColoredTeamName(targ.team); // TODO: check if needed?
 342                         else
 343                                 msg = "";
 344             if(!g_cts) // no "killed your own dumb self" message in CTS
 345                 Send_CSQC_KillCenterprint(targ, msg, "", deathtype, MSG_SUICIDE);
 346
 347                         if(deathtype != DEATH_TEAMCHANGE && deathtype != DEATH_QUIET)
 348                         {
 349                                 LogDeath("suicide", deathtype, targ, targ);
 350                                 GiveFrags(attacker, targ, -1, deathtype);
 351                         }
 352
 353                         if (targ.killcount > 2)
 354                                 msg = ftos(targ.killcount);
 355                         else
 356                                 msg = "";
 357                         if(teamplay && deathtype == DEATH_MIRRORDAMAGE)
 358                         {
 359                                 if(attacker.team == COLOR_TEAM1)
 360                                         deathtype = KILL_TEAM_RED;
 361                                 else
 362                                         deathtype = KILL_TEAM_BLUE;
 363                         }
 364
 365                         Send_KillNotification(s, msg, "", deathtype, MSG_SUICIDE);
 366                 }
 367                 else if (IS_PLAYER(attacker))
 368                 {
 369                         if(!IsDifferentTeam(attacker, targ))
 370                         {
 371                                 if(attacker.team == COLOR_TEAM1)
 372                                         type = KILL_TEAM_RED;
 373                                 else
 374                                         type = KILL_TEAM_BLUE;
 375
 376                                 GiveFrags(attacker, targ, -1, deathtype);
 377
 378                                 Send_CSQC_KillCenterprint(attacker, s, "", type, MSG_KILL);
 379
 380                                 if (targ.killcount > 2)
 381                                         msg = ftos(targ.killcount);
 382                                 else
 383                                         msg = "";
 384
 385                                 if (attacker.killcount > 2) {
 386                                         msg = ftos(attacker.killcount);
 387                                         type = KILL_TEAM_SPREE;
 388                                 }
 389                                 Send_KillNotification(a, s, msg, type, MSG_KILL);
 390
 391                                 attacker.killcount = 0;
 392
 393                                 LogDeath("tk", deathtype, attacker, targ);
 394                         }
 395                         else
 396                         {
 397                                 if (!checkrules_firstblood)
 398                                 {
 399                                         checkrules_firstblood = TRUE;
 400                                         Send_KillNotification(a, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 401                                         // TODO: make these print a newline if they dont
 402                                         Send_CSQC_KillCenterprint(attacker, "", "", KILL_FIRST_BLOOD, MSG_KILL);
 403                                         Send_CSQC_KillCenterprint(targ, "", "", KILL_FIRST_VICTIM, MSG_KILL);
 404                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 405                                         PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 406                                 }
 407
 408                                 if(targ.istypefrag) {
 409                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_TYPEFRAG, MSG_KILL);
 410                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_TYPEFRAGGED, MSG_KILL);
 411                                 } else {
 412                                         Send_CSQC_KillCenterprint(attacker, s, Obituary_ExtraFragInfo(targ), KILL_FRAG, MSG_KILL);
 413                                         Send_CSQC_KillCenterprint(targ, a, Obituary_ExtraFragInfo(attacker), KILL_FRAGGED, MSG_KILL);
 414                                 }
 415
 416                                 attacker.taunt_soundtime = time + 1;
 417
 418                                 if (deathtype == DEATH_HURTTRIGGER && inflictor.message2 != "")
 419                                         msg = inflictor.message2;
 420                                 else if (deathtype == DEATH_CUSTOM)
 421                                         msg = deathmessage;
 422                                 else
 423                                         msg = "";
 424
 425                                 if(strstrofs(msg, "%", 0) < 0)
 426                                         msg = strcat("%s ", msg, " by %s");
 427
 428                                 Send_KillNotification(a, s, msg, deathtype, MSG_KILL);
 429
 430                                 GiveFrags(attacker, targ, 1, deathtype);
 431
 432                                 if (targ.killcount > 2) {
 433                                         Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE);
 434                                 }
 435
 436                                 attacker.killcount = attacker.killcount + 1;
 437
 438                                 if (attacker.killcount == 3)
 439                                 {
 440                                         Send_KillNotification(a, "", "", KILL_SPREE_3, MSG_SPREE);
 441                                         AnnounceTo(attacker, "03kills");
 442                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_3, 1);
 443                                 }
 444                                 else if (attacker.killcount == 5)
 445                                 {
 446                                         Send_KillNotification(a, "", "", KILL_SPREE_5, MSG_SPREE);
 447                                         AnnounceTo(attacker, "05kills");
 448                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_5, 1);
 449                                 }
 450                                 else if (attacker.killcount == 10)
 451                                 {
 452                                         Send_KillNotification(a, "", "", KILL_SPREE_10, MSG_SPREE);
 453                                         AnnounceTo(attacker, "10kills");
 454                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_10, 1);
 455                                 }
 456                                 else if (attacker.killcount == 15)
 457                                 {
 458                                         Send_KillNotification(a, "", "", KILL_SPREE_15, MSG_SPREE);
 459                                         AnnounceTo(attacker, "15kills");
 460                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_15, 1);
 461                                 }
 462                                 else if (attacker.killcount == 20)
 463                                 {
 464                                         Send_KillNotification(a, "", "", KILL_SPREE_20, MSG_SPREE);
 465                                         AnnounceTo(attacker, "20kills");
 466                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_20, 1);
 467                                 }
 468                                 else if (attacker.killcount == 25)
 469                                 {
 470                                         Send_KillNotification(a, "", "", KILL_SPREE_25, MSG_SPREE);
 471                                         AnnounceTo(attacker, "25kills");
 472                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_25, 1);
 473                                 }
 474                                 else if (attacker.killcount == 30)
 475                                 {
 476                                         Send_KillNotification(a, "", "", KILL_SPREE_30, MSG_SPREE);
 477                                         AnnounceTo(attacker, "30kills");
 478                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_30, 1);
 479                                 }
 480                                 else if (attacker.killcount > 2) {
 481                                         Send_KillNotification(a, ftos(attacker.killcount), "", KILL_SPREE, MSG_SPREE);
 482                                 }
 483                                 LogDeath("frag", deathtype, attacker, targ);
 484                         }
 485                 }
 486                 else
 487                 {
 488                         Send_CSQC_KillCenterprint(targ, "", "", deathtype, MSG_KILL_ACTION);
 489                         if (deathtype == DEATH_HURTTRIGGER && inflictor.message != "")
 490                                 msg = inflictor.message;
 491                         else if (deathtype == DEATH_CUSTOM)
 492                                 msg = deathmessage;
 493                         else
 494                                 msg = "";
 495                         if(strstrofs(msg, "%", 0) < 0)
 496                                 msg = strcat("%s ", msg);
 497
 498                         GiveFrags(targ, targ, -1, deathtype);
 499                         if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 500                                 AnnounceTo(targ, "botlike");
 501                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 502                         }
 503                         Send_KillNotification(s, msg, "", deathtype, MSG_KILL_ACTION);
 504
 505                         if (targ.killcount > 2)
 506                                 Send_KillNotification(s, ftos(targ.killcount), "", 0, MSG_KILL_ACTION_SPREE);
 507
 508                         LogDeath("accident", deathtype, targ, targ);
 509                 }
 510
 511                 targ.death_origin = targ.origin;
 512                 if(targ != attacker)
 513                         targ.killer_origin = attacker.origin;
 514
 515                 // FIXME: this should go in PutClientInServer
 516                 if (targ.killcount)
 517                         targ.killcount = 0;
 518         }
 519 }
 520
 521 // these are updated by each Damage call for use in button triggering and such
 522 entity damage_targ;
 523 entity damage_inflictor;
 524 entity damage_attacker;
 525
 526 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 527 {
 528         float mirrordamage;
 529         float mirrorforce;
 530         float complainteamdamage = 0;
 531         entity attacker_save;
 532         mirrordamage = 0;
 533         mirrorforce = 0;
 534
 535         if (gameover || targ.killcount == -666)
 536                 return;
 537
 538         entity oldself;
 539         oldself = self;
 540         self = targ;
 541         damage_targ = targ;
 542         damage_inflictor = inflictor;
 543         damage_attacker = attacker;
 544                 attacker_save = attacker;
 545
 546         if(IS_PLAYER(targ))
 547                 if(targ.hook)
 548                         if(targ.hook.aiment)
 549                                 if(targ.hook.aiment == attacker)
 550                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 551
 552         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 553         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 554         {
 555                 if(IS_PLAYER(targ))
 556                         if not(IsDifferentTeam(targ, attacker))
 557                         {
 558                                 self = oldself;
 559                                 return;
 560                         }
 561         }
 562
 563         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE || deathtype == DEATH_QUIET)
 564         {
 565                 // These are ALWAYS lethal
 566                 // No damage modification here
 567                 // Instead, prepare the victim for his death...
 568                 targ.armorvalue = 0;
 569                 targ.spawnshieldtime = 0;
 570                 targ.health = 0.9; // this is < 1
 571                 targ.flags -= targ.flags & FL_GODMODE;
 572                 damage = 100000;
 573         }
 574         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 575         {
 576                 // no processing
 577         }
 578         else
 579         {
 580                 // nullify damage if teamplay is on
 581                 if(deathtype != DEATH_TELEFRAG)
 582                 if(IS_PLAYER(attacker))
 583                 {
 584                         if(IS_PLAYER(targ) && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 585                         {
 586                                 damage = 0;
 587                                 force = '0 0 0';
 588                         }
 589                         else if(!IsDifferentTeam(attacker, targ))
 590                         {
 591                                 if(autocvar_teamplay_mode == 1)
 592                                         damage = 0;
 593                                 else if(attacker != targ)
 594                                 {
 595                                         if(autocvar_teamplay_mode == 3)
 596                                                 damage = 0;
 597                                         else if(autocvar_teamplay_mode == 4)
 598                                         {
 599                                                 if(IS_PLAYER(targ) && targ.deadflag == DEAD_NO)
 600                                                 {
 601                                                         attacker.dmg_team = attacker.dmg_team + damage;
 602                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 603                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 604                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 605                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 606                                                         if(g_minstagib)
 607                                                         {
 608                                                                 if(autocvar_g_friendlyfire == 0)
 609                                                                         damage = 0;
 610                                                         }
 611                                                         else if(g_ca)
 612                                                                 damage = 0;
 613                                                         else
 614                                                                 damage = autocvar_g_friendlyfire * damage;
 615                                                         // mirrordamage will be used LATER
 616
 617                                                         if(autocvar_g_mirrordamage_virtual)
 618                                                         {
 619                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 620                                                                 attacker.dmg_take += v_x;
 621                                                                 attacker.dmg_save += v_y;
 622                                                                 attacker.dmg_inflictor = inflictor;
 623                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 624                                                                 mirrorforce = 0;
 625                                                         }
 626
 627                                                         if(autocvar_g_friendlyfire_virtual)
 628                                                         {
 629                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 630                                                                 targ.dmg_take += v_x;
 631                                                                 targ.dmg_save += v_y;
 632                                                                 targ.dmg_inflictor = inflictor;
 633                                                                 damage = 0;
 634                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 635                                                                         force = '0 0 0';
 636                                                         }
 637                                                 }
 638                                                 else
 639                                                         damage = 0;
 640                                         }
 641                                 }
 642                         }
 643                 }
 644
 645                 if(IS_PLAYER(targ))
 646                 if(IS_PLAYER(attacker))
 647                 if(attacker != targ)
 648                 {
 649                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 650                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 651                 }
 652
 653                 if(IS_PLAYER(targ))
 654                 if (g_minstagib)
 655                 {
 656                         if ((deathtype == DEATH_FALL)  ||
 657                                 (deathtype == DEATH_DROWN) ||
 658                                 (deathtype == DEATH_SLIME) ||
 659                                 (deathtype == DEATH_LAVA)  ||
 660                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 661                         {
 662                                 self = oldself;
 663                                 return;
 664                         }
 665                         if(damage > 0)
 666                             damage = 10000;
 667                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 668                         {
 669                                 targ.armorvalue -= 1;
 670                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 671                                 damage = 0;
 672                                 targ.hitsound += 1;
 673                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 674                         }
 675                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 676                         {
 677                                 damage = 0;
 678                                 mirrordamage = 0;
 679                                 complainteamdamage = 0;
 680                                 if (targ != attacker)
 681                                 {
 682                                         if ((targ.health >= 1) && (IS_PLAYER(targ)))
 683                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 684                                         force = '0 0 0';
 685                                         // keep mirrorforce
 686                                         attacker = targ;
 687                                 }
 688                         }
 689                 }
 690
 691                 if not(DEATH_ISSPECIAL(deathtype))
 692                 {
 693                         damage *= g_weapondamagefactor;
 694                         mirrordamage *= g_weapondamagefactor;
 695                         complainteamdamage *= g_weapondamagefactor;
 696                         force = force * g_weaponforcefactor;
 697                         mirrorforce *= g_weaponforcefactor;
 698                 }
 699
 700                 // should this be changed at all? If so, in what way?
 701                 frag_attacker = attacker;
 702                 frag_target = targ;
 703                 frag_damage = damage;
 704                 frag_force = force;
 705         frag_deathtype = deathtype;
 706                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 707                 damage = frag_damage;
 708                 force = frag_force;
 709
 710                 // apply strength multiplier
 711                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 712                 {
 713                         if(targ == attacker)
 714                         {
 715                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 716                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 717                         }
 718                         else
 719                         {
 720                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 721                                 force = force * autocvar_g_balance_powerup_strength_force;
 722                         }
 723                 }
 724
 725                 // apply invincibility multiplier
 726                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 727                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 728
 729                 if (targ == attacker)
 730                 {
 731                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 732                                 damage = 0;
 733                         else
 734                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 735                 }
 736
 737                 if(g_runematch)
 738                 {
 739                         // apply strength rune
 740                         if (attacker.runes & RUNE_STRENGTH)
 741                         {
 742                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 743                                 {
 744                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 745                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 746                                 }
 747                                 else
 748                                 {
 749                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 750                                         force = force * autocvar_g_balance_rune_strength_force;
 751                                 }
 752                         }
 753                         else if (attacker.runes & CURSE_WEAK)
 754                         {
 755                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 756                                 force = force * autocvar_g_balance_curse_weak_force;
 757                         }
 758
 759                         // apply defense rune
 760                         if (targ.runes & RUNE_DEFENSE)
 761                         {
 762                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 763                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 764                                 else
 765                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 766                         }
 767                         else if (targ.runes & CURSE_VULNER)
 768                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 769                 }
 770
 771                 // count the damage
 772                 if(attacker)
 773                 if(!targ.deadflag)
 774                 if(targ.takedamage == DAMAGE_AIM)
 775                 if(targ != attacker)
 776                 {
 777                         entity victim;
 778                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 779                                 victim = targ.owner;
 780                         else
 781                                 victim = targ;
 782
 783                         if(IS_PLAYER(victim) || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 784                         {
 785                                 if(IsDifferentTeam(victim, attacker))
 786                                 {
 787                                         if(damage > 0)
 788                                         {
 789                                                 if(deathtype != DEATH_FIRE)
 790                                                 {
 791                                                         if(victim.BUTTON_CHAT)
 792                                                                 attacker.typehitsound += 1;
 793                                                         else
 794                                                                 attacker.hitsound += 1;
 795                                                 }
 796
 797                                                 damage_goodhits += 1;
 798                                                 damage_gooddamage += damage;
 799
 800                                                 if not(DEATH_ISSPECIAL(deathtype))
 801                                                 {
 802                                                         if(IS_PLAYER(targ)) // don't do this for vehicles
 803                                                         if(!g_minstagib)
 804                                                         if(IsFlying(victim))
 805                                                                 yoda = 1;
 806
 807                                                         if(g_minstagib)
 808                                                         if(victim.items & IT_STRENGTH)
 809                                                                 yoda = 1;
 810                                                 }
 811                                         }
 812                                 }
 813                                 else
 814                                 {
 815                                         if(deathtype != DEATH_FIRE)
 816                                         {
 817                                                 attacker.typehitsound += 1;
 818                                         }
 819                                         if(complainteamdamage > 0)
 820                                                 if(time > attacker.teamkill_complain)
 821                                                 {
 822                                                         attacker.teamkill_complain = time + 5;
 823                                                         attacker.teamkill_soundtime = time + 0.4;
 824                                                         attacker.teamkill_soundsource = targ;
 825                                                 }
 826                                 }
 827                         }
 828                 }
 829         }
 830
 831         // apply push
 832         if (self.damageforcescale)
 833         if (vlen(force))
 834         if (!IS_PLAYER(self) || time >= self.spawnshieldtime || g_midair)
 835         {
 836                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 837                 if(self.movetype == MOVETYPE_PHYSICS)
 838                 {
 839                         entity farcent;
 840                         farcent = spawn();
 841                         farcent.classname = "farce";
 842                         farcent.enemy = self;
 843                         farcent.movedir = farce * 10;
 844                         if(self.mass)
 845                                 farcent.movedir = farcent.movedir * self.mass;
 846                         farcent.origin = hitloc;
 847                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 848                         farcent.nextthink = time + 0.1;
 849                         farcent.think = SUB_Remove;
 850                 }
 851                 else
 852                         self.velocity = self.velocity + farce;
 853                 self.flags &~= FL_ONGROUND;
 854                 UpdateCSQCProjectile(self);
 855         }
 856         // apply damage
 857         if (damage != 0 || (self.damageforcescale && vlen(force)))
 858         if (self.event_damage)
 859                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 860         self = oldself;
 861
 862         if(IS_PLAYER(targ) && IS_PLAYER(attacker) && attacker != targ && attacker.health > 2)
 863         {
 864                 if(g_runematch)
 865                 {
 866                         if (attacker.runes & RUNE_VAMPIRE)
 867                         {
 868                         // apply vampire rune
 869                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 870                                 {
 871                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 872                                         attacker.health = bound(
 873                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 874                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 875                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 876                                 }
 877                                 else
 878                                 {
 879                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 880                                         attacker.health = bound(
 881                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 882                                                                                         // empathy won't let you gain health in the same way...
 883                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 884                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 885                                         }
 886                         }
 887                         // apply empathy curse
 888                         else if (attacker.runes & CURSE_EMPATHY)
 889                         {
 890                                 attacker.health = bound(
 891                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 892                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 893                                         attacker.health);
 894                         }
 895                 }
 896         }
 897
 898         // apply mirror damage if any
 899         if(mirrordamage > 0 || mirrorforce > 0)
 900         {
 901                 attacker = attacker_save;
 902                 if(g_minstagib)
 903                 if(mirrordamage > 0)
 904                 {
 905                         // just lose extra LIVES, don't kill the player for mirror damage
 906                         if(attacker.armorvalue > 0)
 907                         {
 908                                 attacker.armorvalue = attacker.armorvalue - 1;
 909                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 910                                 attacker.hitsound += 1;
 911                         }
 912                         mirrordamage = 0;
 913                 }
 914
 915                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 916                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 917         }
 918 }
 919
 920 float RadiusDamage_running;
 921 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 922         // Returns total damage applies to creatures
 923 {
 924         entity  targ;
 925         vector  blastorigin;
 926         vector  force;
 927         float   total_damage_to_creatures;
 928         entity  next;
 929         float   tfloordmg;
 930         float   tfloorforce;
 931
 932         float stat_damagedone;
 933
 934         if(RadiusDamage_running)
 935         {
 936                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 937                 return 0;
 938         }
 939
 940         RadiusDamage_running = 1;
 941
 942         tfloordmg = autocvar_g_throughfloor_damage;
 943         tfloorforce = autocvar_g_throughfloor_force;
 944
 945         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 946         total_damage_to_creatures = 0;
 947
 948         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 949                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 950                 {
 951                         force = inflictor.velocity;
 952                         if(vlen(force) == 0)
 953                                 force = '0 0 -1';
 954                         else
 955                                 force = normalize(force);
 956                         if(forceintensity >= 0)
 957                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 958                         else
 959                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 960                 }
 961
 962         stat_damagedone = 0;
 963
 964         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 965         while (targ)
 966         {
 967                 next = targ.chain;
 968                 if (targ != inflictor)
 969                         if (ignore != targ) if(targ.takedamage)
 970                         {
 971                                 vector nearest;
 972                                 vector diff;
 973                                 float power;
 974
 975                                 // LordHavoc: measure distance to nearest point on target (not origin)
 976                                 // (this guarentees 100% damage on a touch impact)
 977                                 nearest = targ.WarpZone_findradius_nearest;
 978                                 diff = targ.WarpZone_findradius_dist;
 979                                 // round up a little on the damage to ensure full damage on impacts
 980                                 // and turn the distance into a fraction of the radius
 981                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 982                                 //bprint(" ");
 983                                 //bprint(ftos(power));
 984                                 //if (targ == attacker)
 985                                 //      print(ftos(power), "\n");
 986                                 if (power > 0)
 987                                 {
 988                                         float finaldmg;
 989                                         if (power > 1)
 990                                                 power = 1;
 991                                         finaldmg = coredamage * power + edgedamage * (1 - power);
 992                                         if (finaldmg > 0)
 993                                         {
 994                                                 float a;
 995                                                 float c;
 996                                                 vector hitloc;
 997                                                 vector myblastorigin;
 998                                                 vector center;
 999
1000                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1001
1002                                                 // if it's a player, use the view origin as reference
1003                                                 center = CENTER_OR_VIEWOFS(targ);
1004
1005                                                 force = normalize(center - myblastorigin);
1006                                                 force = force * (finaldmg / coredamage) * forceintensity;
1007                                                 hitloc = nearest;
1008
1009                                                 if(targ != directhitentity)
1010                                                 {
1011                                                         float hits;
1012                                                         float total;
1013                                                         float hitratio;
1014                                                         float mininv_f, mininv_d;
1015
1016                                                         // test line of sight to multiple positions on box,
1017                                                         // and do damage if any of them hit
1018                                                         hits = 0;
1019
1020                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1021                                                         // so for a given max stddev:
1022                                                         // n = (1 / (2 * max stddev of hitratio))^2
1023
1024                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1025                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1026
1027                                                         if(autocvar_g_throughfloor_debug)
1028                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1029
1030                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1031
1032                                                         if(autocvar_g_throughfloor_debug)
1033                                                                 print(sprintf(" steps=%f", total));
1034
1035                                                         if (IS_PLAYER(targ))
1036                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1037                                                         else
1038                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1039
1040                                                         if(autocvar_g_throughfloor_debug)
1041                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1042
1043                                                         for(c = 0; c < total; ++c)
1044                                                         {
1045                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1046                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1047                                                                 if (trace_fraction == 1 || trace_ent == targ)
1048                                                                 {
1049                                                                         ++hits;
1050                                                                         if (hits > 1)
1051                                                                                 hitloc = hitloc + nearest;
1052                                                                         else
1053                                                                                 hitloc = nearest;
1054                                                                 }
1055                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1056                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1057                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1058                                                         }
1059
1060                                                         nearest = hitloc * (1 / max(1, hits));
1061                                                         hitratio = (hits / total);
1062                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1063                                                         finaldmg = finaldmg * a;
1064                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1065                                                         force = force * a;
1066
1067                                                         if(autocvar_g_throughfloor_debug)
1068                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1069                                                 }
1070
1071                                                 // laser force adjustments :P
1072                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1073                                                 {
1074                                                         if (targ == attacker)
1075                                                         {
1076                                                                 vector vel;
1077
1078                                                                 float force_zscale;
1079                                                                 float force_velocitybiasramp;
1080                                                                 float force_velocitybias;
1081
1082                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1083                                                                 if(deathtype & HITTYPE_SECONDARY)
1084                                                                 {
1085                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1086                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1087                                                                 }
1088                                                                 else
1089                                                                 {
1090                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1091                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1092                                                                 }
1093
1094                                                                 vel = targ.velocity;
1095                                                                 vel_z = 0;
1096                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1097                                                                 force =
1098                                                                         vlen(force)
1099                                                                         *
1100                                                                         normalize(normalize(force) + vel);
1101
1102                                                                 force_z *= force_zscale;
1103                                                         }
1104                                                         else
1105                                                         {
1106                                                                 if(deathtype & HITTYPE_SECONDARY)
1107                                                                 {
1108                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1109                                                                 }
1110                                                                 else
1111                                                                 {
1112                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1113                                                                 }
1114                                                         }
1115                                                 }
1116
1117                                                 //if (targ == attacker)
1118                                                 //{
1119                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1120                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1121                                                 //      print(" (", ftos(a), ")\n");
1122                                                 //}
1123                                                 if(finaldmg || vlen(force))
1124                                                 {
1125                                                         if(targ.iscreature)
1126                                                         {
1127                                                                 total_damage_to_creatures += finaldmg;
1128
1129                                                                 if(accuracy_isgooddamage(attacker, targ))
1130                                                                         stat_damagedone += finaldmg;
1131                                                         }
1132
1133                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1134                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1135                                                         else
1136                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1137                                                 }
1138                                         }
1139                                 }
1140                         }
1141                 targ = next;
1142         }
1143
1144         RadiusDamage_running = 0;
1145
1146         if(!DEATH_ISSPECIAL(deathtype))
1147                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1148
1149         return total_damage_to_creatures;
1150 }
1151
1152 .float fire_damagepersec;
1153 .float fire_endtime;
1154 .float fire_deathtype;
1155 .entity fire_owner;
1156 .float fire_hitsound;
1157 .entity fire_burner;
1158
1159 void fireburner_think();
1160
1161 float Fire_IsBurning(entity e)
1162 {
1163         return (time < e.fire_endtime);
1164 }
1165
1166 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1167 {
1168         float dps;
1169         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1170
1171         if(IS_PLAYER(e))
1172         {
1173                 if(e.deadflag)
1174                         return -1;
1175         }
1176         else
1177         {
1178                 if(!e.fire_burner)
1179                 {
1180                         // print("adding a fire burner to ", e.classname, "\n");
1181                         e.fire_burner = spawn();
1182                         e.fire_burner.classname = "fireburner";
1183                         e.fire_burner.think = fireburner_think;
1184                         e.fire_burner.nextthink = time;
1185                         e.fire_burner.owner = e;
1186                 }
1187         }
1188
1189         t = max(t, 0.1);
1190         dps = d / t;
1191         if(Fire_IsBurning(e))
1192         {
1193                 mintime = e.fire_endtime - time;
1194                 maxtime = max(mintime, t);
1195
1196                 mindps = e.fire_damagepersec;
1197                 maxdps = max(mindps, dps);
1198
1199                 if(maxtime > mintime || maxdps > mindps)
1200                 {
1201                         // Constraints:
1202
1203                         // damage we have right now
1204                         mindamage = mindps * mintime;
1205
1206                         // damage we want to get
1207                         maxdamage = mindamage + d;
1208
1209                         // but we can't exceed maxtime * maxdps!
1210                         totaldamage = min(maxdamage, maxtime * maxdps);
1211
1212                         // LEMMA:
1213                         // Look at:
1214                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1215                         // We see:
1216                         // totaldamage <= maxtime * maxdps
1217                         // ==> totaldamage / maxdps <= maxtime.
1218                         // We also see:
1219                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1220                         //                     >= min(mintime, maxtime)
1221                         // ==> totaldamage / maxdps >= mintime.
1222
1223                         /*
1224                         // how long do we damage then?
1225                         // at least as long as before
1226                         // but, never exceed maxdps
1227                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1228                         */
1229
1230                         // alternate:
1231                         // at most as long as maximum allowed
1232                         // but, never below mindps
1233                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1234
1235                         // assuming t > mintime, dps > mindps:
1236                         // we get d = t * dps = maxtime * maxdps
1237                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1238                         // totaldamage / maxdps = maxtime
1239                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1240                         // FROM THIS:
1241                         // a) totaltime = max(mintime, maxtime) = maxtime
1242                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1243
1244                         // assuming t <= mintime:
1245                         // we get maxtime = mintime
1246                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1247                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1248
1249                         // assuming dps <= mindps:
1250                         // we get mindps = maxdps.
1251                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1252                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1253                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1254
1255                         e.fire_damagepersec = totaldamage / totaltime;
1256                         e.fire_endtime = time + totaltime;
1257                         if(totaldamage > 1.2 * mindamage)
1258                         {
1259                                 e.fire_deathtype = dt;
1260                                 if(e.fire_owner != o)
1261                                 {
1262                                         e.fire_owner = o;
1263                                         e.fire_hitsound = FALSE;
1264                                 }
1265                         }
1266                         if(accuracy_isgooddamage(o, e))
1267                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1268                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1269                 }
1270                 else
1271                         return 0;
1272         }
1273         else
1274         {
1275                 e.fire_damagepersec = dps;
1276                 e.fire_endtime = time + t;
1277                 e.fire_deathtype = dt;
1278                 e.fire_owner = o;
1279                 e.fire_hitsound = FALSE;
1280                 if(accuracy_isgooddamage(o, e))
1281                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1282                 return d;
1283         }
1284 }
1285
1286 void Fire_ApplyDamage(entity e)
1287 {
1288         float t, d, hi, ty;
1289         entity o;
1290
1291         if not(Fire_IsBurning(e))
1292                 return;
1293
1294         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1295         if(IS_NOT_A_CLIENT(o))
1296                 o = e.fire_owner;
1297
1298         // water and slime stop fire
1299         if(e.waterlevel)
1300         if(e.watertype != CONTENT_LAVA)
1301                 e.fire_endtime = 0;
1302
1303         // ice stops fire
1304         if(e.freezetag_frozen)
1305                 e.fire_endtime = 0;
1306
1307         t = min(frametime, e.fire_endtime - time);
1308         d = e.fire_damagepersec * t;
1309
1310         hi = e.fire_owner.hitsound;
1311         ty = e.fire_owner.typehitsound;
1312         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1313         if(e.fire_hitsound && e.fire_owner)
1314         {
1315                 e.fire_owner.hitsound = hi;
1316                 e.fire_owner.typehitsound = ty;
1317         }
1318         e.fire_hitsound = TRUE;
1319
1320         if not(IS_INDEPENDENT_PLAYER(e))
1321         FOR_EACH_PLAYER(other) if(e != other)
1322         {
1323                 if(IS_PLAYER(other))
1324                 if(other.deadflag == DEAD_NO)
1325                 if not(IS_INDEPENDENT_PLAYER(other))
1326                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1327                 {
1328                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1329                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1330                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1331                 }
1332         }
1333 }
1334
1335 void Fire_ApplyEffect(entity e)
1336 {
1337         if(Fire_IsBurning(e))
1338                 e.effects |= EF_FLAME;
1339         else
1340                 e.effects &~= EF_FLAME;
1341 }
1342
1343 void fireburner_think()
1344 {
1345         // for players, this is done in the regular loop
1346         if(wasfreed(self.owner))
1347         {
1348                 remove(self);
1349                 return;
1350         }
1351         Fire_ApplyEffect(self.owner);
1352         if(!Fire_IsBurning(self.owner))
1353         {
1354                 self.owner.fire_burner = world;
1355                 remove(self);
1356                 return;
1357         }
1358         Fire_ApplyDamage(self.owner);
1359         self.nextthink = time;
1360 }