qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 263 {
 264         if(DEATH_ISSPECIAL(deathtype))
 265         {
 266                 entity deathent = deathtypes[(deathtype - DT_FIRST) - 1];
 267                 if not(deathent) { backtrace("Obituary_SpecialDeath: Could not find deathtype entity!\n"); return; }
 268
 269                 if(murder)
 270                 {
 271                         if(deathent.death_msgmurder)
 272                         {
 273                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, deathent.death_msgmurder.nent_id, s1, s2, s3, "", f1, f2, f3, 0);
 274                                 Send_Notification_WOVA(NOTIF_ALL_EXCEPT, notif_target, MSG_INFO, deathent.death_msgmurder.nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, f3, 0);
 275                         }
 276                 }
 277                 else
 278                 {
 279                         if(deathent.death_msgself)
 280                         {
 281                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, deathent.death_msgself.nent_id, s1, s2, s3, "", f1, f2, f3, 0);
 282                                 Send_Notification_WOVA(NOTIF_ALL_EXCEPT, notif_target, MSG_INFO, deathent.death_msgself.nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, f3, 0);
 283                         }
 284                 }
 285         }
 286         else { backtrace("Obituary_SpecialDeath called without a special deathtype?\n"); return; }
 287 }
 288
 289 float w_deathtype;
 290 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 291 {
 292         float death_weapon = DEATH_WEAPONOF(deathtype);
 293         if(death_weapon)
 294         {
 295                 w_deathtype = deathtype;
 296                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 297                 w_deathtype = FALSE;
 298
 299                 if(death_message)
 300                 {
 301                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 302                         Send_Notification_WOVA(NOTIF_ALL_EXCEPT, notif_target, MSG_INFO, msg_multi_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 303                 }
 304                 else
 305                 {
 306                         dprint(sprintf(
 307                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n",
 308                                 Deathtype_Name(deathtype),
 309                                 deathtype,
 310                                 death_weapon
 311                         ));
 312                 }
 313
 314                 return TRUE;
 315         }
 316         return FALSE;
 317 }
 318
 319 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 320 {
 321         // Sanity check
 322         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 323
 324         // Declarations
 325         float notif_firstblood = FALSE;
 326         float kill_count_to_attacker, kill_count_to_target;
 327
 328         // Set final information for the death
 329         targ.death_origin = targ.origin;
 330         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 331         string deathlocation = NearestLocation(targ.death_origin);
 332
 333         #ifdef NOTIFICATIONS_DEBUG
 334         dprint(
 335                 sprintf(
 336                         "Obituary(%s, %s, %s, %s = %d);\n",
 337                         attacker.netname,
 338                         inflictor.netname,
 339                         targ.netname,
 340                         Deathtype_Name(deathtype),
 341                         deathtype
 342                 )
 343         );
 344         #endif
 345
 346         // =======
 347         // SUICIDE
 348         // =======
 349         if(targ == attacker)
 350         {
 351                 if(DEATH_ISSPECIAL(deathtype))
 352                 {
 353                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 354                         {
 355                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 356                         }
 357                         else
 358                         {
 359                                 switch(deathtype)
 360                                 {
 361                                         case DEATH_MIRRORDAMAGE:
 362                                         {
 363                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 364                                                 break;
 365                                         }
 366
 367                                         default:
 368                                         {
 369                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 370                                                 break;
 371                                         }
 372                                 }
 373                         }
 374                 }
 375                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 376                 {
 377                         backtrace("SUICIDE: what the hell happened here?\n");
 378                         return;
 379                 }
 380                 LogDeath("suicide", deathtype, targ, targ);
 381                 GiveFrags(attacker, targ, -1, deathtype);
 382         }
 383
 384         // ======
 385         // MURDER
 386         // ======
 387         else if(attacker.classname == "player")
 388         {
 389                 if(!IsDifferentTeam(attacker, targ))
 390                 {
 391                         LogDeath("tk", deathtype, attacker, targ);
 392                         GiveFrags(attacker, targ, -1, deathtype);
 393
 394                         attacker.killcount = 0;
 395
 396                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 397                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 398                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 399
 400                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 401                         // No need for specific death/weapon messages...
 402                 }
 403                 else
 404                 {
 405                         LogDeath("frag", deathtype, attacker, targ);
 406                         GiveFrags(attacker, targ, 1, deathtype);
 407
 408                         attacker.taunt_soundtime = time + 1;
 409                         attacker.killcount = attacker.killcount + 1;
 410
 411                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 412                                 case counta: \
 413                                 { \
 414                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 415                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 416                                         break; \
 417                                 }
 418                         switch(attacker.killcount)
 419                         {
 420                                 KILL_SPREE_LIST
 421                                 default: break;
 422                         }
 423                         #undef SPREE_ITEM
 424
 425                         if(!checkrules_firstblood)
 426                         {
 427                                 checkrules_firstblood = TRUE;
 428                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 429                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 430                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 431
 432                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 433                                 kill_count_to_attacker = -1;
 434                                 kill_count_to_target = -2;
 435                         }
 436                         else
 437                         {
 438                                 kill_count_to_attacker = attacker.killcount;
 439                                 kill_count_to_target = 0;
 440                         }
 441
 442                         if(targ.istypefrag)
 443                         {
 444                                 if(attacker.FRAG_VERBOSE)
 445                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 446                                 else
 447                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 448
 449                                 if(targ.FRAG_VERBOSE)
 450                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 451                                 else
 452                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 453                         }
 454                         else
 455                         {
 456                                 if(attacker.FRAG_VERBOSE)
 457                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 458                                 else
 459                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 460
 461                                 if(targ.FRAG_VERBOSE)
 462                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 463                                 else
 464                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 465                         }
 466
 467                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 468                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 469                 }
 470         }
 471
 472         // =============
 473         // ACCIDENT/TRAP
 474         // =============
 475         else
 476         {
 477                 switch(deathtype)
 478                 {
 479                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 480                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 481                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 482                         /*case DEATH_HURTTRIGGER:
 483                         {
 484                                 s1 = targ.netname;
 485                                 s2 = inflictor.message;
 486                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 487                                 break;
 488                         }*/
 489
 490                         case DEATH_CUSTOM:
 491                         {
 492                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 493                                         targ.netname,
 494                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 495                                         deathlocation,
 496                                         targ.killcount,
 497                                         0,
 498                                         0);
 499                                 break;
 500                         }
 501
 502                         default:
 503                         {
 504                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 505                                 break;
 506                         }
 507                 }
 508
 509                 LogDeath("accident", deathtype, targ, targ);
 510                 GiveFrags(targ, targ, -1, deathtype);
 511
 512                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 513                 {
 514                         AnnounceTo(targ, "botlike");
 515                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 516                 }
 517         }
 518
 519         // reset target kill count
 520         if(targ.killcount) { targ.killcount = 0; }
 521 }
 522
 523 // these are updated by each Damage call for use in button triggering and such
 524 entity damage_targ;
 525 entity damage_inflictor;
 526 entity damage_attacker;
 527
 528 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 529 {
 530         float mirrordamage;
 531         float mirrorforce;
 532         float complainteamdamage = 0;
 533         entity attacker_save;
 534         mirrordamage = 0;
 535         mirrorforce = 0;
 536
 537         if (gameover || targ.killcount == -666)
 538                 return;
 539
 540         entity oldself;
 541         oldself = self;
 542         self = targ;
 543         damage_targ = targ;
 544         damage_inflictor = inflictor;
 545         damage_attacker = attacker;
 546                 attacker_save = attacker;
 547
 548         if(targ.classname == "player")
 549                 if(targ.hook)
 550                         if(targ.hook.aiment)
 551                                 if(targ.hook.aiment == attacker)
 552                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 553
 554         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 555         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 556         {
 557                 if(targ.classname == "player")
 558                         if not(IsDifferentTeam(targ, attacker))
 559                         {
 560                                 self = oldself;
 561                                 return;
 562                         }
 563         }
 564
 565         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 566         {
 567                 // These are ALWAYS lethal
 568                 // No damage modification here
 569                 // Instead, prepare the victim for his death...
 570                 targ.armorvalue = 0;
 571                 targ.spawnshieldtime = 0;
 572                 targ.health = 0.9; // this is < 1
 573                 targ.flags -= targ.flags & FL_GODMODE;
 574                 damage = 100000;
 575         }
 576         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 577         {
 578                 // no processing
 579         }
 580         else
 581         {
 582                 /*
 583                 skill based bot damage? gtfo. (tZork)
 584                 if (targ.classname == "player")
 585                 if (attacker.classname == "player")
 586                 if (!targ.isbot)
 587                 if (attacker.isbot)
 588                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 589         */
 590
 591                 // nullify damage if teamplay is on
 592                 if(deathtype != DEATH_TELEFRAG)
 593                 if(attacker.classname == "player")
 594                 {
 595                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 596                         {
 597                                 damage = 0;
 598                                 force = '0 0 0';
 599                         }
 600                         else if(!IsDifferentTeam(attacker, targ))
 601                         {
 602                                 if(autocvar_teamplay_mode == 1)
 603                                         damage = 0;
 604                                 else if(attacker != targ)
 605                                 {
 606                                         if(autocvar_teamplay_mode == 3)
 607                                                 damage = 0;
 608                                         else if(autocvar_teamplay_mode == 4)
 609                                         {
 610                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 611                                                 {
 612                                                         attacker.dmg_team = attacker.dmg_team + damage;
 613                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 614                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 615                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 616                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 617                                                         if(g_minstagib)
 618                                                         {
 619                                                                 if(autocvar_g_friendlyfire == 0)
 620                                                                         damage = 0;
 621                                                         }
 622                                                         else if(g_ca)
 623                                                                 damage = 0;
 624                                                         else
 625                                                                 damage = autocvar_g_friendlyfire * damage;
 626                                                         // mirrordamage will be used LATER
 627
 628                                                         if(autocvar_g_mirrordamage_virtual)
 629                                                         {
 630                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 631                                                                 attacker.dmg_take += v_x;
 632                                                                 attacker.dmg_save += v_y;
 633                                                                 attacker.dmg_inflictor = inflictor;
 634                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 635                                                                 mirrorforce = 0;
 636                                                         }
 637
 638                                                         if(autocvar_g_friendlyfire_virtual)
 639                                                         {
 640                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 641                                                                 targ.dmg_take += v_x;
 642                                                                 targ.dmg_save += v_y;
 643                                                                 targ.dmg_inflictor = inflictor;
 644                                                                 damage = 0;
 645                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 646                                                                         force = '0 0 0';
 647                                                         }
 648                                                 }
 649                                                 else
 650                                                         damage = 0;
 651                                         }
 652                                 }
 653                         }
 654                 }
 655
 656                 if(targ.classname == "player")
 657                 if(attacker.classname == "player")
 658                 if(attacker != targ)
 659                 {
 660                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 661                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 662                 }
 663
 664                 if(targ.classname == "player")
 665                 if (g_minstagib)
 666                 {
 667                         if ((deathtype == DEATH_FALL)  ||
 668                                 (deathtype == DEATH_DROWN) ||
 669                                 (deathtype == DEATH_SLIME) ||
 670                                 (deathtype == DEATH_LAVA)  ||
 671                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 672                         {
 673                                 self = oldself;
 674                                 return;
 675                         }
 676                         if(damage > 0)
 677                             damage = 10000;
 678                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 679                         {
 680                                 targ.armorvalue -= 1;
 681                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 682                                 damage = 0;
 683                                 targ.hitsound += 1;
 684                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 685                         }
 686                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 687                         {
 688                                 damage = 0;
 689                                 mirrordamage = 0;
 690                                 complainteamdamage = 0;
 691                                 if (targ != attacker)
 692                                 {
 693                                         if ((targ.health >= 1) && (targ.classname == "player"))
 694                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 695                                         force = '0 0 0';
 696                                         // keep mirrorforce
 697                                         attacker = targ;
 698                                 }
 699                         }
 700                 }
 701
 702                 if not(DEATH_ISSPECIAL(deathtype))
 703                 {
 704                         damage *= g_weapondamagefactor;
 705                         mirrordamage *= g_weapondamagefactor;
 706                         complainteamdamage *= g_weapondamagefactor;
 707                         force = force * g_weaponforcefactor;
 708                         mirrorforce *= g_weaponforcefactor;
 709                 }
 710
 711                 // should this be changed at all? If so, in what way?
 712                 frag_attacker = attacker;
 713                 frag_target = targ;
 714                 frag_damage = damage;
 715                 frag_force = force;
 716         frag_deathtype = deathtype;
 717                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 718                 damage = frag_damage;
 719                 force = frag_force;
 720
 721                 // apply strength multiplier
 722                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 723                 {
 724                         if(targ == attacker)
 725                         {
 726                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 727                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 728                         }
 729                         else
 730                         {
 731                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 732                                 force = force * autocvar_g_balance_powerup_strength_force;
 733                         }
 734                 }
 735
 736                 // apply invincibility multiplier
 737                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 738                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 739
 740                 if (targ == attacker)
 741                 {
 742                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 743                                 damage = 0;
 744                         else
 745                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 746                 }
 747
 748                 if(g_runematch)
 749                 {
 750                         // apply strength rune
 751                         if (attacker.runes & RUNE_STRENGTH)
 752                         {
 753                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 754                                 {
 755                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 756                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 757                                 }
 758                                 else
 759                                 {
 760                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 761                                         force = force * autocvar_g_balance_rune_strength_force;
 762                                 }
 763                         }
 764                         else if (attacker.runes & CURSE_WEAK)
 765                         {
 766                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 767                                 force = force * autocvar_g_balance_curse_weak_force;
 768                         }
 769
 770                         // apply defense rune
 771                         if (targ.runes & RUNE_DEFENSE)
 772                         {
 773                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 774                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 775                                 else
 776                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 777                         }
 778                         else if (targ.runes & CURSE_VULNER)
 779                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 780                 }
 781
 782                 // count the damage
 783                 if(attacker)
 784                 if(!targ.deadflag)
 785                 if(targ.takedamage == DAMAGE_AIM)
 786                 if(targ != attacker)
 787                 {
 788                         entity victim;
 789                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 790                                 victim = targ.owner;
 791                         else
 792                                 victim = targ;
 793
 794                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 795                         {
 796                                 if(IsDifferentTeam(victim, attacker))
 797                                 {
 798                                         if(damage > 0)
 799                                         {
 800                                                 if(deathtype != DEATH_FIRE)
 801                                                 {
 802                                                         if(victim.BUTTON_CHAT)
 803                                                                 attacker.typehitsound += 1;
 804                                                         else
 805                                                                 attacker.hitsound += 1;
 806                                                 }
 807
 808                                                 damage_goodhits += 1;
 809                                                 damage_gooddamage += damage;
 810
 811                                                 if not(DEATH_ISSPECIAL(deathtype))
 812                                                 {
 813                                                         if(targ.classname == "player") // don't do this for vehicles
 814                                                         if(!g_minstagib)
 815                                                         if(IsFlying(victim))
 816                                                                 yoda = 1;
 817
 818                                                         if(g_minstagib)
 819                                                         if(victim.items & IT_STRENGTH)
 820                                                                 yoda = 1;
 821                                                 }
 822                                         }
 823                                 }
 824                                 else
 825                                 {
 826                                         if(deathtype != DEATH_FIRE)
 827                                         {
 828                                                 attacker.typehitsound += 1;
 829                                         }
 830                                         if(complainteamdamage > 0)
 831                                                 if(time > attacker.teamkill_complain)
 832                                                 {
 833                                                         attacker.teamkill_complain = time + 5;
 834                                                         attacker.teamkill_soundtime = time + 0.4;
 835                                                         attacker.teamkill_soundsource = targ;
 836                                                 }
 837                                 }
 838                         }
 839                 }
 840         }
 841
 842         // apply push
 843         if (self.damageforcescale)
 844         if (vlen(force))
 845         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 846         {
 847                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 848                 if(self.movetype == MOVETYPE_PHYSICS)
 849                 {
 850                         entity farcent;
 851                         farcent = spawn();
 852                         farcent.classname = "farce";
 853                         farcent.enemy = self;
 854                         farcent.movedir = farce * 10;
 855                         if(self.mass)
 856                                 farcent.movedir = farcent.movedir * self.mass;
 857                         farcent.origin = hitloc;
 858                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 859                         farcent.nextthink = time + 0.1;
 860                         farcent.think = SUB_Remove;
 861                 }
 862                 else
 863                         self.velocity = self.velocity + farce;
 864                 self.flags &~= FL_ONGROUND;
 865                 UpdateCSQCProjectile(self);
 866         }
 867         // apply damage
 868         if (damage != 0 || (self.damageforcescale && vlen(force)))
 869         if (self.event_damage)
 870                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 871         self = oldself;
 872
 873         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 874         {
 875                 if(g_runematch)
 876                 {
 877                         if (attacker.runes & RUNE_VAMPIRE)
 878                         {
 879                         // apply vampire rune
 880                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 881                                 {
 882                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 883                                         attacker.health = bound(
 884                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 885                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 886                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 887                                 }
 888                                 else
 889                                 {
 890                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 891                                         attacker.health = bound(
 892                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 893                                                                                         // empathy won't let you gain health in the same way...
 894                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 895                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 896                                         }
 897                         }
 898                         // apply empathy curse
 899                         else if (attacker.runes & CURSE_EMPATHY)
 900                         {
 901                                 attacker.health = bound(
 902                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 903                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 904                                         attacker.health);
 905                         }
 906                 }
 907         }
 908
 909         // apply mirror damage if any
 910         if(mirrordamage > 0 || mirrorforce > 0)
 911         {
 912                 attacker = attacker_save;
 913                 if(g_minstagib)
 914                 if(mirrordamage > 0)
 915                 {
 916                         // just lose extra LIVES, don't kill the player for mirror damage
 917                         if(attacker.armorvalue > 0)
 918                         {
 919                                 attacker.armorvalue = attacker.armorvalue - 1;
 920                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 921                                 attacker.hitsound += 1;
 922                         }
 923                         mirrordamage = 0;
 924                 }
 925
 926                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 927                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 928         }
 929 }
 930
 931 float RadiusDamage_running;
 932 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 933         // Returns total damage applies to creatures
 934 {
 935         entity  targ;
 936         vector  blastorigin;
 937         vector  force;
 938         float   total_damage_to_creatures;
 939         entity  next;
 940         float   tfloordmg;
 941         float   tfloorforce;
 942
 943         float stat_damagedone;
 944
 945         if(RadiusDamage_running)
 946         {
 947                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 948                 return 0;
 949         }
 950
 951         RadiusDamage_running = 1;
 952
 953         tfloordmg = autocvar_g_throughfloor_damage;
 954         tfloorforce = autocvar_g_throughfloor_force;
 955
 956         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 957         total_damage_to_creatures = 0;
 958
 959         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 960                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 961                 {
 962                         force = inflictor.velocity;
 963                         if(vlen(force) == 0)
 964                                 force = '0 0 -1';
 965                         else
 966                                 force = normalize(force);
 967                         if(forceintensity >= 0)
 968                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 969                         else
 970                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 971                 }
 972
 973         stat_damagedone = 0;
 974
 975         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 976         while (targ)
 977         {
 978                 next = targ.chain;
 979                 if (targ != inflictor)
 980                         if (ignore != targ) if(targ.takedamage)
 981                         {
 982                                 vector nearest;
 983                                 vector diff;
 984                                 float power;
 985
 986                                 // LordHavoc: measure distance to nearest point on target (not origin)
 987                                 // (this guarentees 100% damage on a touch impact)
 988                                 nearest = targ.WarpZone_findradius_nearest;
 989                                 diff = targ.WarpZone_findradius_dist;
 990                                 // round up a little on the damage to ensure full damage on impacts
 991                                 // and turn the distance into a fraction of the radius
 992                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 993                                 //bprint(" ");
 994                                 //bprint(ftos(power));
 995                                 //if (targ == attacker)
 996                                 //      print(ftos(power), "\n");
 997                                 if (power > 0)
 998                                 {
 999                                         float finaldmg;
1000                                         if (power > 1)
1001                                                 power = 1;
1002                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1003                                         if (finaldmg > 0)
1004                                         {
1005                                                 float a;
1006                                                 float c;
1007                                                 vector hitloc;
1008                                                 vector myblastorigin;
1009                                                 vector center;
1010
1011                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1012
1013                                                 // if it's a player, use the view origin as reference
1014                                                 center = CENTER_OR_VIEWOFS(targ);
1015
1016                                                 force = normalize(center - myblastorigin);
1017                                                 force = force * (finaldmg / coredamage) * forceintensity;
1018                                                 hitloc = nearest;
1019
1020                                                 if(targ != directhitentity)
1021                                                 {
1022                                                         float hits;
1023                                                         float total;
1024                                                         float hitratio;
1025                                                         float mininv_f, mininv_d;
1026
1027                                                         // test line of sight to multiple positions on box,
1028                                                         // and do damage if any of them hit
1029                                                         hits = 0;
1030
1031                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1032                                                         // so for a given max stddev:
1033                                                         // n = (1 / (2 * max stddev of hitratio))^2
1034
1035                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1036                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1037
1038                                                         if(autocvar_g_throughfloor_debug)
1039                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1040
1041                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1042
1043                                                         if(autocvar_g_throughfloor_debug)
1044                                                                 print(sprintf(" steps=%f", total));
1045
1046                                                         if (targ.classname == "player")
1047                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1048                                                         else
1049                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1050
1051                                                         if(autocvar_g_throughfloor_debug)
1052                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1053
1054                                                         for(c = 0; c < total; ++c)
1055                                                         {
1056                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1057                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1058                                                                 if (trace_fraction == 1 || trace_ent == targ)
1059                                                                 {
1060                                                                         ++hits;
1061                                                                         if (hits > 1)
1062                                                                                 hitloc = hitloc + nearest;
1063                                                                         else
1064                                                                                 hitloc = nearest;
1065                                                                 }
1066                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1067                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1068                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1069                                                         }
1070
1071                                                         nearest = hitloc * (1 / max(1, hits));
1072                                                         hitratio = (hits / total);
1073                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1074                                                         finaldmg = finaldmg * a;
1075                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1076                                                         force = force * a;
1077
1078                                                         if(autocvar_g_throughfloor_debug)
1079                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1080                                                 }
1081
1082                                                 // laser force adjustments :P
1083                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1084                                                 {
1085                                                         if (targ == attacker)
1086                                                         {
1087                                                                 vector vel;
1088
1089                                                                 float force_zscale;
1090                                                                 float force_velocitybiasramp;
1091                                                                 float force_velocitybias;
1092
1093                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1094                                                                 if(deathtype & HITTYPE_SECONDARY)
1095                                                                 {
1096                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1097                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1098                                                                 }
1099                                                                 else
1100                                                                 {
1101                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1102                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1103                                                                 }
1104
1105                                                                 vel = targ.velocity;
1106                                                                 vel_z = 0;
1107                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1108                                                                 force =
1109                                                                         vlen(force)
1110                                                                         *
1111                                                                         normalize(normalize(force) + vel);
1112
1113                                                                 force_z *= force_zscale;
1114                                                         }
1115                                                         else
1116                                                         {
1117                                                                 if(deathtype & HITTYPE_SECONDARY)
1118                                                                 {
1119                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1120                                                                 }
1121                                                                 else
1122                                                                 {
1123                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1124                                                                 }
1125                                                         }
1126                                                 }
1127
1128                                                 //if (targ == attacker)
1129                                                 //{
1130                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1131                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1132                                                 //      print(" (", ftos(a), ")\n");
1133                                                 //}
1134                                                 if(finaldmg || vlen(force))
1135                                                 {
1136                                                         if(targ.iscreature)
1137                                                         {
1138                                                                 total_damage_to_creatures += finaldmg;
1139
1140                                                                 if(accuracy_isgooddamage(attacker, targ))
1141                                                                         stat_damagedone += finaldmg;
1142                                                         }
1143
1144                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1145                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1146                                                         else
1147                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1148                                                 }
1149                                         }
1150                                 }
1151                         }
1152                 targ = next;
1153         }
1154
1155         RadiusDamage_running = 0;
1156
1157         if(!DEATH_ISSPECIAL(deathtype))
1158                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1159
1160         return total_damage_to_creatures;
1161 }
1162
1163 .float fire_damagepersec;
1164 .float fire_endtime;
1165 .float fire_deathtype;
1166 .entity fire_owner;
1167 .float fire_hitsound;
1168 .entity fire_burner;
1169
1170 void fireburner_think();
1171
1172 float Fire_IsBurning(entity e)
1173 {
1174         return (time < e.fire_endtime);
1175 }
1176
1177 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1178 {
1179         float dps;
1180         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1181
1182         if(e.classname == "player")
1183         {
1184                 if(e.deadflag)
1185                         return -1;
1186         }
1187         else
1188         {
1189                 if(!e.fire_burner)
1190                 {
1191                         // print("adding a fire burner to ", e.classname, "\n");
1192                         e.fire_burner = spawn();
1193                         e.fire_burner.classname = "fireburner";
1194                         e.fire_burner.think = fireburner_think;
1195                         e.fire_burner.nextthink = time;
1196                         e.fire_burner.owner = e;
1197                 }
1198         }
1199
1200         t = max(t, 0.1);
1201         dps = d / t;
1202         if(Fire_IsBurning(e))
1203         {
1204                 mintime = e.fire_endtime - time;
1205                 maxtime = max(mintime, t);
1206
1207                 mindps = e.fire_damagepersec;
1208                 maxdps = max(mindps, dps);
1209
1210                 if(maxtime > mintime || maxdps > mindps)
1211                 {
1212                         // Constraints:
1213
1214                         // damage we have right now
1215                         mindamage = mindps * mintime;
1216
1217                         // damage we want to get
1218                         maxdamage = mindamage + d;
1219
1220                         // but we can't exceed maxtime * maxdps!
1221                         totaldamage = min(maxdamage, maxtime * maxdps);
1222
1223                         // LEMMA:
1224                         // Look at:
1225                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1226                         // We see:
1227                         // totaldamage <= maxtime * maxdps
1228                         // ==> totaldamage / maxdps <= maxtime.
1229                         // We also see:
1230                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1231                         //                     >= min(mintime, maxtime)
1232                         // ==> totaldamage / maxdps >= mintime.
1233
1234                         /*
1235                         // how long do we damage then?
1236                         // at least as long as before
1237                         // but, never exceed maxdps
1238                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1239                         */
1240
1241                         // alternate:
1242                         // at most as long as maximum allowed
1243                         // but, never below mindps
1244                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1245
1246                         // assuming t > mintime, dps > mindps:
1247                         // we get d = t * dps = maxtime * maxdps
1248                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1249                         // totaldamage / maxdps = maxtime
1250                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1251                         // FROM THIS:
1252                         // a) totaltime = max(mintime, maxtime) = maxtime
1253                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1254
1255                         // assuming t <= mintime:
1256                         // we get maxtime = mintime
1257                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1258                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1259
1260                         // assuming dps <= mindps:
1261                         // we get mindps = maxdps.
1262                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1263                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1264                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1265
1266                         e.fire_damagepersec = totaldamage / totaltime;
1267                         e.fire_endtime = time + totaltime;
1268                         if(totaldamage > 1.2 * mindamage)
1269                         {
1270                                 e.fire_deathtype = dt;
1271                                 if(e.fire_owner != o)
1272                                 {
1273                                         e.fire_owner = o;
1274                                         e.fire_hitsound = FALSE;
1275                                 }
1276                         }
1277                         if(accuracy_isgooddamage(o, e))
1278                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1279                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1280                 }
1281                 else
1282                         return 0;
1283         }
1284         else
1285         {
1286                 e.fire_damagepersec = dps;
1287                 e.fire_endtime = time + t;
1288                 e.fire_deathtype = dt;
1289                 e.fire_owner = o;
1290                 e.fire_hitsound = FALSE;
1291                 if(accuracy_isgooddamage(o, e))
1292                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1293                 return d;
1294         }
1295 }
1296
1297 void Fire_ApplyDamage(entity e)
1298 {
1299         float t, d, hi, ty;
1300         entity o;
1301
1302         if not(Fire_IsBurning(e))
1303                 return;
1304
1305         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1306         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1307                 o = e.fire_owner;
1308
1309         // water and slime stop fire
1310         if(e.waterlevel)
1311         if(e.watertype != CONTENT_LAVA)
1312                 e.fire_endtime = 0;
1313
1314         // ice stops fire
1315         if(e.freezetag_frozen)
1316                 e.fire_endtime = 0;
1317
1318         t = min(frametime, e.fire_endtime - time);
1319         d = e.fire_damagepersec * t;
1320
1321         hi = e.fire_owner.hitsound;
1322         ty = e.fire_owner.typehitsound;
1323         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1324         if(e.fire_hitsound && e.fire_owner)
1325         {
1326                 e.fire_owner.hitsound = hi;
1327                 e.fire_owner.typehitsound = ty;
1328         }
1329         e.fire_hitsound = TRUE;
1330
1331         if not(IS_INDEPENDENT_PLAYER(e))
1332         FOR_EACH_PLAYER(other) if(e != other)
1333         {
1334                 if(other.classname == "player")
1335                 if(other.deadflag == DEAD_NO)
1336                 if not(IS_INDEPENDENT_PLAYER(other))
1337                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1338                 {
1339                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1340                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1341                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1342                 }
1343         }
1344 }
1345
1346 void Fire_ApplyEffect(entity e)
1347 {
1348         if(Fire_IsBurning(e))
1349                 e.effects |= EF_FLAME;
1350         else
1351                 e.effects &~= EF_FLAME;
1352 }
1353
1354 void fireburner_think()
1355 {
1356         // for players, this is done in the regular loop
1357         if(wasfreed(self.owner))
1358         {
1359                 remove(self);
1360                 return;
1361         }
1362         Fire_ApplyEffect(self.owner);
1363         if(!Fire_IsBurning(self.owner))
1364         {
1365                 self.owner.fire_burner = world;
1366                 remove(self);
1367                 return;
1368         }
1369         Fire_ApplyDamage(self.owner);
1370         self.nextthink = time;
1371 }