qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 #define INFO_NO_MSG 0 // so that compilation works with the INFO_##msg_death stuff
 263 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 264 {
 265         float handled = 0, hits = 0;
 266         if(DEATH_ISSPECIAL(deathtype))
 267         {
 268                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 269                         { if(deathtype == max(0, name)) \
 270                         { \
 271                                 #if msg_death != NO_MSG \
 272                                         if not(murder) \
 273                                         { \
 274                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 275                                                 Send_Notification_WOVA(NOTIF_ALL_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 276                                                 ++handled; \
 277                                         } \
 278                                 #endif \
 279                                 #if msg_death_by != NO_MSG \
 280                                         if(murder) \
 281                                         { \
 282                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 283                                                 Send_Notification_WOVA(NOTIF_ALL_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 284                                                 ++handled; \
 285                                         } \
 286                                 #endif \
 287                                 ++hits; \
 288                         } }
 289
 290                 DEATHTYPES
 291                 #undef DEATHTYPE
 292
 293                 if not(hits)
 294                 {
 295                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 296                 }
 297                 if not(handled)
 298                 {
 299                         dprint(sprintf(
 300                                 "Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n",
 301                                 Deathtype_Name(deathtype),
 302                                 deathtype
 303                         ));
 304                         return;
 305                 }
 306         }
 307 }
 308
 309 float w_deathtype;
 310 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 311 {
 312         float death_weapon = DEATH_WEAPONOF(deathtype);
 313         if(death_weapon)
 314         {
 315                 w_deathtype = deathtype;
 316                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 317                 w_deathtype = FALSE;
 318
 319                 if(death_message)
 320                 {
 321                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_MULTI, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 322                         Send_Notification_WOVA(NOTIF_ALL_EXCEPT, notif_target, MSG_INFO, msg_multi_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 323                 }
 324                 else
 325                 {
 326                         dprint(sprintf(
 327                                 "Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n",
 328                                 Deathtype_Name(deathtype),
 329                                 deathtype,
 330                                 death_weapon
 331                         ));
 332                 }
 333
 334                 return TRUE;
 335         }
 336         return FALSE;
 337 }
 338
 339 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 340 {
 341         // Sanity check
 342         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 343
 344         // Declarations
 345         float notif_firstblood = FALSE;
 346         float kill_count_to_attacker, kill_count_to_target;
 347
 348         // Set final information for the death
 349         targ.death_origin = targ.origin;
 350         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 351         string deathlocation = NearestLocation(targ.death_origin);
 352
 353         #ifdef NOTIFICATIONS_DEBUG
 354         dprint(
 355                 sprintf(
 356                         "Obituary(%s, %s, %s, %s = %d);\n",
 357                         attacker.netname,
 358                         inflictor.netname,
 359                         targ.netname,
 360                         Deathtype_Name(deathtype),
 361                         deathtype
 362                 )
 363         );
 364         #endif
 365
 366         // =======
 367         // SUICIDE
 368         // =======
 369         if(targ == attacker)
 370         {
 371                 if(DEATH_ISSPECIAL(deathtype))
 372                 {
 373                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 374                         {
 375                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 376                         }
 377                         else
 378                         {
 379                                 switch(deathtype)
 380                                 {
 381                                         case DEATH_MIRRORDAMAGE:
 382                                         {
 383                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 384                                                 break;
 385                                         }
 386
 387                                         default:
 388                                         {
 389                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 390                                                 break;
 391                                         }
 392                                 }
 393                         }
 394                 }
 395                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 396                 {
 397                         backtrace("SUICIDE: what the hell happened here?\n");
 398                         return;
 399                 }
 400                 LogDeath("suicide", deathtype, targ, targ);
 401                 GiveFrags(attacker, targ, -1, deathtype);
 402         }
 403
 404         // ======
 405         // MURDER
 406         // ======
 407         else if(attacker.classname == "player")
 408         {
 409                 if(!IsDifferentTeam(attacker, targ))
 410                 {
 411                         LogDeath("tk", deathtype, attacker, targ);
 412                         GiveFrags(attacker, targ, -1, deathtype);
 413
 414                         attacker.killcount = 0;
 415
 416                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 417                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 418                         Send_Notification(NOTIF_ALL, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 419
 420                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 421                         // No need for specific death/weapon messages...
 422                 }
 423                 else
 424                 {
 425                         LogDeath("frag", deathtype, attacker, targ);
 426                         GiveFrags(attacker, targ, 1, deathtype);
 427
 428                         attacker.taunt_soundtime = time + 1;
 429                         attacker.killcount = attacker.killcount + 1;
 430
 431                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 432                                 case counta: \
 433                                 { \
 434                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 435                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 436                                         break; \
 437                                 }
 438                         switch(attacker.killcount)
 439                         {
 440                                 KILL_SPREE_LIST
 441                                 default: break;
 442                         }
 443                         #undef SPREE_ITEM
 444
 445                         if(!checkrules_firstblood)
 446                         {
 447                                 checkrules_firstblood = TRUE;
 448                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 449                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 450                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 451
 452                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 453                                 kill_count_to_attacker = -1;
 454                                 kill_count_to_target = -2;
 455                         }
 456                         else
 457                         {
 458                                 kill_count_to_attacker = attacker.killcount;
 459                                 kill_count_to_target = 0;
 460                         }
 461
 462                         if(targ.istypefrag)
 463                         {
 464                                 if(attacker.FRAG_VERBOSE)
 465                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 466                                 else
 467                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 468
 469                                 if(targ.FRAG_VERBOSE)
 470                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 471                                 else
 472                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 473                         }
 474                         else
 475                         {
 476                                 if(attacker.FRAG_VERBOSE)
 477                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 478                                 else
 479                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 480
 481                                 if(targ.FRAG_VERBOSE)
 482                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 483                                 else
 484                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 485                         }
 486
 487                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 488                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 489                 }
 490         }
 491
 492         // =============
 493         // ACCIDENT/TRAP
 494         // =============
 495         else
 496         {
 497                 switch(deathtype)
 498                 {
 499                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 500                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 501                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 502                         /*case DEATH_HURTTRIGGER:
 503                         {
 504                                 s1 = targ.netname;
 505                                 s2 = inflictor.message;
 506                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 507                                 break;
 508                         }*/
 509
 510                         case DEATH_CUSTOM:
 511                         {
 512                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 513                                         targ.netname,
 514                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 515                                         deathlocation,
 516                                         targ.killcount,
 517                                         0,
 518                                         0);
 519                                 break;
 520                         }
 521
 522                         default:
 523                         {
 524                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 525                                 break;
 526                         }
 527                 }
 528
 529                 LogDeath("accident", deathtype, targ, targ);
 530                 GiveFrags(targ, targ, -1, deathtype);
 531
 532                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 533                 {
 534                         AnnounceTo(targ, "botlike");
 535                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 536                 }
 537         }
 538
 539         // reset target kill count
 540         if(targ.killcount) { targ.killcount = 0; }
 541 }
 542
 543 // these are updated by each Damage call for use in button triggering and such
 544 entity damage_targ;
 545 entity damage_inflictor;
 546 entity damage_attacker;
 547
 548 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 549 {
 550         float mirrordamage;
 551         float mirrorforce;
 552         float complainteamdamage = 0;
 553         entity attacker_save;
 554         mirrordamage = 0;
 555         mirrorforce = 0;
 556
 557         if (gameover || targ.killcount == -666)
 558                 return;
 559
 560         entity oldself;
 561         oldself = self;
 562         self = targ;
 563         damage_targ = targ;
 564         damage_inflictor = inflictor;
 565         damage_attacker = attacker;
 566                 attacker_save = attacker;
 567
 568         if(targ.classname == "player")
 569                 if(targ.hook)
 570                         if(targ.hook.aiment)
 571                                 if(targ.hook.aiment == attacker)
 572                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 573
 574         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 575         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 576         {
 577                 if(targ.classname == "player")
 578                         if not(IsDifferentTeam(targ, attacker))
 579                         {
 580                                 self = oldself;
 581                                 return;
 582                         }
 583         }
 584
 585         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 586         {
 587                 // These are ALWAYS lethal
 588                 // No damage modification here
 589                 // Instead, prepare the victim for his death...
 590                 targ.armorvalue = 0;
 591                 targ.spawnshieldtime = 0;
 592                 targ.health = 0.9; // this is < 1
 593                 targ.flags -= targ.flags & FL_GODMODE;
 594                 damage = 100000;
 595         }
 596         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 597         {
 598                 // no processing
 599         }
 600         else
 601         {
 602                 /*
 603                 skill based bot damage? gtfo. (tZork)
 604                 if (targ.classname == "player")
 605                 if (attacker.classname == "player")
 606                 if (!targ.isbot)
 607                 if (attacker.isbot)
 608                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 609         */
 610
 611                 // nullify damage if teamplay is on
 612                 if(deathtype != DEATH_TELEFRAG)
 613                 if(attacker.classname == "player")
 614                 {
 615                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 616                         {
 617                                 damage = 0;
 618                                 force = '0 0 0';
 619                         }
 620                         else if(!IsDifferentTeam(attacker, targ))
 621                         {
 622                                 if(autocvar_teamplay_mode == 1)
 623                                         damage = 0;
 624                                 else if(attacker != targ)
 625                                 {
 626                                         if(autocvar_teamplay_mode == 3)
 627                                                 damage = 0;
 628                                         else if(autocvar_teamplay_mode == 4)
 629                                         {
 630                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 631                                                 {
 632                                                         attacker.dmg_team = attacker.dmg_team + damage;
 633                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 634                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 635                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 636                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 637                                                         if(g_minstagib)
 638                                                         {
 639                                                                 if(autocvar_g_friendlyfire == 0)
 640                                                                         damage = 0;
 641                                                         }
 642                                                         else if(g_ca)
 643                                                                 damage = 0;
 644                                                         else
 645                                                                 damage = autocvar_g_friendlyfire * damage;
 646                                                         // mirrordamage will be used LATER
 647
 648                                                         if(autocvar_g_mirrordamage_virtual)
 649                                                         {
 650                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 651                                                                 attacker.dmg_take += v_x;
 652                                                                 attacker.dmg_save += v_y;
 653                                                                 attacker.dmg_inflictor = inflictor;
 654                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 655                                                                 mirrorforce = 0;
 656                                                         }
 657
 658                                                         if(autocvar_g_friendlyfire_virtual)
 659                                                         {
 660                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 661                                                                 targ.dmg_take += v_x;
 662                                                                 targ.dmg_save += v_y;
 663                                                                 targ.dmg_inflictor = inflictor;
 664                                                                 damage = 0;
 665                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 666                                                                         force = '0 0 0';
 667                                                         }
 668                                                 }
 669                                                 else
 670                                                         damage = 0;
 671                                         }
 672                                 }
 673                         }
 674                 }
 675
 676                 if(targ.classname == "player")
 677                 if(attacker.classname == "player")
 678                 if(attacker != targ)
 679                 {
 680                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 681                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 682                 }
 683
 684                 if(targ.classname == "player")
 685                 if (g_minstagib)
 686                 {
 687                         if ((deathtype == DEATH_FALL)  ||
 688                                 (deathtype == DEATH_DROWN) ||
 689                                 (deathtype == DEATH_SLIME) ||
 690                                 (deathtype == DEATH_LAVA)  ||
 691                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 692                         {
 693                                 self = oldself;
 694                                 return;
 695                         }
 696                         if(damage > 0)
 697                             damage = 10000;
 698                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 699                         {
 700                                 targ.armorvalue -= 1;
 701                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 702                                 damage = 0;
 703                                 targ.hitsound += 1;
 704                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 705                         }
 706                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 707                         {
 708                                 damage = 0;
 709                                 mirrordamage = 0;
 710                                 complainteamdamage = 0;
 711                                 if (targ != attacker)
 712                                 {
 713                                         if ((targ.health >= 1) && (targ.classname == "player"))
 714                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 715                                         force = '0 0 0';
 716                                         // keep mirrorforce
 717                                         attacker = targ;
 718                                 }
 719                         }
 720                 }
 721
 722                 if not(DEATH_ISSPECIAL(deathtype))
 723                 {
 724                         damage *= g_weapondamagefactor;
 725                         mirrordamage *= g_weapondamagefactor;
 726                         complainteamdamage *= g_weapondamagefactor;
 727                         force = force * g_weaponforcefactor;
 728                         mirrorforce *= g_weaponforcefactor;
 729                 }
 730
 731                 // should this be changed at all? If so, in what way?
 732                 frag_attacker = attacker;
 733                 frag_target = targ;
 734                 frag_damage = damage;
 735                 frag_force = force;
 736         frag_deathtype = deathtype;
 737                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 738                 damage = frag_damage;
 739                 force = frag_force;
 740
 741                 // apply strength multiplier
 742                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 743                 {
 744                         if(targ == attacker)
 745                         {
 746                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 747                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 748                         }
 749                         else
 750                         {
 751                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 752                                 force = force * autocvar_g_balance_powerup_strength_force;
 753                         }
 754                 }
 755
 756                 // apply invincibility multiplier
 757                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 758                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 759
 760                 if (targ == attacker)
 761                 {
 762                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 763                                 damage = 0;
 764                         else
 765                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 766                 }
 767
 768                 if(g_runematch)
 769                 {
 770                         // apply strength rune
 771                         if (attacker.runes & RUNE_STRENGTH)
 772                         {
 773                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 774                                 {
 775                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 776                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 777                                 }
 778                                 else
 779                                 {
 780                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 781                                         force = force * autocvar_g_balance_rune_strength_force;
 782                                 }
 783                         }
 784                         else if (attacker.runes & CURSE_WEAK)
 785                         {
 786                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 787                                 force = force * autocvar_g_balance_curse_weak_force;
 788                         }
 789
 790                         // apply defense rune
 791                         if (targ.runes & RUNE_DEFENSE)
 792                         {
 793                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 794                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 795                                 else
 796                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 797                         }
 798                         else if (targ.runes & CURSE_VULNER)
 799                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 800                 }
 801
 802                 // count the damage
 803                 if(attacker)
 804                 if(!targ.deadflag)
 805                 if(targ.takedamage == DAMAGE_AIM)
 806                 if(targ != attacker)
 807                 {
 808                         entity victim;
 809                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 810                                 victim = targ.owner;
 811                         else
 812                                 victim = targ;
 813
 814                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 815                         {
 816                                 if(IsDifferentTeam(victim, attacker))
 817                                 {
 818                                         if(damage > 0)
 819                                         {
 820                                                 if(deathtype != DEATH_FIRE)
 821                                                 {
 822                                                         if(victim.BUTTON_CHAT)
 823                                                                 attacker.typehitsound += 1;
 824                                                         else
 825                                                                 attacker.hitsound += 1;
 826                                                 }
 827
 828                                                 damage_goodhits += 1;
 829                                                 damage_gooddamage += damage;
 830
 831                                                 if not(DEATH_ISSPECIAL(deathtype))
 832                                                 {
 833                                                         if(targ.classname == "player") // don't do this for vehicles
 834                                                         if(!g_minstagib)
 835                                                         if(IsFlying(victim))
 836                                                                 yoda = 1;
 837
 838                                                         if(g_minstagib)
 839                                                         if(victim.items & IT_STRENGTH)
 840                                                                 yoda = 1;
 841                                                 }
 842                                         }
 843                                 }
 844                                 else
 845                                 {
 846                                         if(deathtype != DEATH_FIRE)
 847                                         {
 848                                                 attacker.typehitsound += 1;
 849                                         }
 850                                         if(complainteamdamage > 0)
 851                                                 if(time > attacker.teamkill_complain)
 852                                                 {
 853                                                         attacker.teamkill_complain = time + 5;
 854                                                         attacker.teamkill_soundtime = time + 0.4;
 855                                                         attacker.teamkill_soundsource = targ;
 856                                                 }
 857                                 }
 858                         }
 859                 }
 860         }
 861
 862         // apply push
 863         if (self.damageforcescale)
 864         if (vlen(force))
 865         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 866         {
 867                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 868                 if(self.movetype == MOVETYPE_PHYSICS)
 869                 {
 870                         entity farcent;
 871                         farcent = spawn();
 872                         farcent.classname = "farce";
 873                         farcent.enemy = self;
 874                         farcent.movedir = farce * 10;
 875                         if(self.mass)
 876                                 farcent.movedir = farcent.movedir * self.mass;
 877                         farcent.origin = hitloc;
 878                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 879                         farcent.nextthink = time + 0.1;
 880                         farcent.think = SUB_Remove;
 881                 }
 882                 else
 883                         self.velocity = self.velocity + farce;
 884                 self.flags &~= FL_ONGROUND;
 885                 UpdateCSQCProjectile(self);
 886         }
 887         // apply damage
 888         if (damage != 0 || (self.damageforcescale && vlen(force)))
 889         if (self.event_damage)
 890                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 891         self = oldself;
 892
 893         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 894         {
 895                 if(g_runematch)
 896                 {
 897                         if (attacker.runes & RUNE_VAMPIRE)
 898                         {
 899                         // apply vampire rune
 900                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 901                                 {
 902                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 903                                         attacker.health = bound(
 904                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 905                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 906                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 907                                 }
 908                                 else
 909                                 {
 910                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 911                                         attacker.health = bound(
 912                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 913                                                                                         // empathy won't let you gain health in the same way...
 914                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 915                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 916                                         }
 917                         }
 918                         // apply empathy curse
 919                         else if (attacker.runes & CURSE_EMPATHY)
 920                         {
 921                                 attacker.health = bound(
 922                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 923                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 924                                         attacker.health);
 925                         }
 926                 }
 927         }
 928
 929         // apply mirror damage if any
 930         if(mirrordamage > 0 || mirrorforce > 0)
 931         {
 932                 attacker = attacker_save;
 933                 if(g_minstagib)
 934                 if(mirrordamage > 0)
 935                 {
 936                         // just lose extra LIVES, don't kill the player for mirror damage
 937                         if(attacker.armorvalue > 0)
 938                         {
 939                                 attacker.armorvalue = attacker.armorvalue - 1;
 940                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 941                                 attacker.hitsound += 1;
 942                         }
 943                         mirrordamage = 0;
 944                 }
 945
 946                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 947                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 948         }
 949 }
 950
 951 float RadiusDamage_running;
 952 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 953         // Returns total damage applies to creatures
 954 {
 955         entity  targ;
 956         vector  blastorigin;
 957         vector  force;
 958         float   total_damage_to_creatures;
 959         entity  next;
 960         float   tfloordmg;
 961         float   tfloorforce;
 962
 963         float stat_damagedone;
 964
 965         if(RadiusDamage_running)
 966         {
 967                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 968                 return 0;
 969         }
 970
 971         RadiusDamage_running = 1;
 972
 973         tfloordmg = autocvar_g_throughfloor_damage;
 974         tfloorforce = autocvar_g_throughfloor_force;
 975
 976         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 977         total_damage_to_creatures = 0;
 978
 979         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 980                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 981                 {
 982                         force = inflictor.velocity;
 983                         if(vlen(force) == 0)
 984                                 force = '0 0 -1';
 985                         else
 986                                 force = normalize(force);
 987                         if(forceintensity >= 0)
 988                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 989                         else
 990                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 991                 }
 992
 993         stat_damagedone = 0;
 994
 995         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 996         while (targ)
 997         {
 998                 next = targ.chain;
 999                 if (targ != inflictor)
1000                         if (ignore != targ) if(targ.takedamage)
1001                         {
1002                                 vector nearest;
1003                                 vector diff;
1004                                 float power;
1005
1006                                 // LordHavoc: measure distance to nearest point on target (not origin)
1007                                 // (this guarentees 100% damage on a touch impact)
1008                                 nearest = targ.WarpZone_findradius_nearest;
1009                                 diff = targ.WarpZone_findradius_dist;
1010                                 // round up a little on the damage to ensure full damage on impacts
1011                                 // and turn the distance into a fraction of the radius
1012                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1013                                 //bprint(" ");
1014                                 //bprint(ftos(power));
1015                                 //if (targ == attacker)
1016                                 //      print(ftos(power), "\n");
1017                                 if (power > 0)
1018                                 {
1019                                         float finaldmg;
1020                                         if (power > 1)
1021                                                 power = 1;
1022                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1023                                         if (finaldmg > 0)
1024                                         {
1025                                                 float a;
1026                                                 float c;
1027                                                 vector hitloc;
1028                                                 vector myblastorigin;
1029                                                 vector center;
1030
1031                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1032
1033                                                 // if it's a player, use the view origin as reference
1034                                                 center = CENTER_OR_VIEWOFS(targ);
1035
1036                                                 force = normalize(center - myblastorigin);
1037                                                 force = force * (finaldmg / coredamage) * forceintensity;
1038                                                 hitloc = nearest;
1039
1040                                                 if(targ != directhitentity)
1041                                                 {
1042                                                         float hits;
1043                                                         float total;
1044                                                         float hitratio;
1045                                                         float mininv_f, mininv_d;
1046
1047                                                         // test line of sight to multiple positions on box,
1048                                                         // and do damage if any of them hit
1049                                                         hits = 0;
1050
1051                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1052                                                         // so for a given max stddev:
1053                                                         // n = (1 / (2 * max stddev of hitratio))^2
1054
1055                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1056                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1057
1058                                                         if(autocvar_g_throughfloor_debug)
1059                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1060
1061                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1062
1063                                                         if(autocvar_g_throughfloor_debug)
1064                                                                 print(sprintf(" steps=%f", total));
1065
1066                                                         if (targ.classname == "player")
1067                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1068                                                         else
1069                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1070
1071                                                         if(autocvar_g_throughfloor_debug)
1072                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1073
1074                                                         for(c = 0; c < total; ++c)
1075                                                         {
1076                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1077                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1078                                                                 if (trace_fraction == 1 || trace_ent == targ)
1079                                                                 {
1080                                                                         ++hits;
1081                                                                         if (hits > 1)
1082                                                                                 hitloc = hitloc + nearest;
1083                                                                         else
1084                                                                                 hitloc = nearest;
1085                                                                 }
1086                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1087                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1088                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1089                                                         }
1090
1091                                                         nearest = hitloc * (1 / max(1, hits));
1092                                                         hitratio = (hits / total);
1093                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1094                                                         finaldmg = finaldmg * a;
1095                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1096                                                         force = force * a;
1097
1098                                                         if(autocvar_g_throughfloor_debug)
1099                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1100                                                 }
1101
1102                                                 // laser force adjustments :P
1103                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1104                                                 {
1105                                                         if (targ == attacker)
1106                                                         {
1107                                                                 vector vel;
1108
1109                                                                 float force_zscale;
1110                                                                 float force_velocitybiasramp;
1111                                                                 float force_velocitybias;
1112
1113                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1114                                                                 if(deathtype & HITTYPE_SECONDARY)
1115                                                                 {
1116                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1117                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1118                                                                 }
1119                                                                 else
1120                                                                 {
1121                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1122                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1123                                                                 }
1124
1125                                                                 vel = targ.velocity;
1126                                                                 vel_z = 0;
1127                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1128                                                                 force =
1129                                                                         vlen(force)
1130                                                                         *
1131                                                                         normalize(normalize(force) + vel);
1132
1133                                                                 force_z *= force_zscale;
1134                                                         }
1135                                                         else
1136                                                         {
1137                                                                 if(deathtype & HITTYPE_SECONDARY)
1138                                                                 {
1139                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1140                                                                 }
1141                                                                 else
1142                                                                 {
1143                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1144                                                                 }
1145                                                         }
1146                                                 }
1147
1148                                                 //if (targ == attacker)
1149                                                 //{
1150                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1151                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1152                                                 //      print(" (", ftos(a), ")\n");
1153                                                 //}
1154                                                 if(finaldmg || vlen(force))
1155                                                 {
1156                                                         if(targ.iscreature)
1157                                                         {
1158                                                                 total_damage_to_creatures += finaldmg;
1159
1160                                                                 if(accuracy_isgooddamage(attacker, targ))
1161                                                                         stat_damagedone += finaldmg;
1162                                                         }
1163
1164                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1165                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1166                                                         else
1167                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1168                                                 }
1169                                         }
1170                                 }
1171                         }
1172                 targ = next;
1173         }
1174
1175         RadiusDamage_running = 0;
1176
1177         if(!DEATH_ISSPECIAL(deathtype))
1178                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1179
1180         return total_damage_to_creatures;
1181 }
1182
1183 .float fire_damagepersec;
1184 .float fire_endtime;
1185 .float fire_deathtype;
1186 .entity fire_owner;
1187 .float fire_hitsound;
1188 .entity fire_burner;
1189
1190 void fireburner_think();
1191
1192 float Fire_IsBurning(entity e)
1193 {
1194         return (time < e.fire_endtime);
1195 }
1196
1197 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1198 {
1199         float dps;
1200         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1201
1202         if(e.classname == "player")
1203         {
1204                 if(e.deadflag)
1205                         return -1;
1206         }
1207         else
1208         {
1209                 if(!e.fire_burner)
1210                 {
1211                         // print("adding a fire burner to ", e.classname, "\n");
1212                         e.fire_burner = spawn();
1213                         e.fire_burner.classname = "fireburner";
1214                         e.fire_burner.think = fireburner_think;
1215                         e.fire_burner.nextthink = time;
1216                         e.fire_burner.owner = e;
1217                 }
1218         }
1219
1220         t = max(t, 0.1);
1221         dps = d / t;
1222         if(Fire_IsBurning(e))
1223         {
1224                 mintime = e.fire_endtime - time;
1225                 maxtime = max(mintime, t);
1226
1227                 mindps = e.fire_damagepersec;
1228                 maxdps = max(mindps, dps);
1229
1230                 if(maxtime > mintime || maxdps > mindps)
1231                 {
1232                         // Constraints:
1233
1234                         // damage we have right now
1235                         mindamage = mindps * mintime;
1236
1237                         // damage we want to get
1238                         maxdamage = mindamage + d;
1239
1240                         // but we can't exceed maxtime * maxdps!
1241                         totaldamage = min(maxdamage, maxtime * maxdps);
1242
1243                         // LEMMA:
1244                         // Look at:
1245                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1246                         // We see:
1247                         // totaldamage <= maxtime * maxdps
1248                         // ==> totaldamage / maxdps <= maxtime.
1249                         // We also see:
1250                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1251                         //                     >= min(mintime, maxtime)
1252                         // ==> totaldamage / maxdps >= mintime.
1253
1254                         /*
1255                         // how long do we damage then?
1256                         // at least as long as before
1257                         // but, never exceed maxdps
1258                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1259                         */
1260
1261                         // alternate:
1262                         // at most as long as maximum allowed
1263                         // but, never below mindps
1264                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1265
1266                         // assuming t > mintime, dps > mindps:
1267                         // we get d = t * dps = maxtime * maxdps
1268                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1269                         // totaldamage / maxdps = maxtime
1270                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1271                         // FROM THIS:
1272                         // a) totaltime = max(mintime, maxtime) = maxtime
1273                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1274
1275                         // assuming t <= mintime:
1276                         // we get maxtime = mintime
1277                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1278                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1279
1280                         // assuming dps <= mindps:
1281                         // we get mindps = maxdps.
1282                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1283                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1284                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1285
1286                         e.fire_damagepersec = totaldamage / totaltime;
1287                         e.fire_endtime = time + totaltime;
1288                         if(totaldamage > 1.2 * mindamage)
1289                         {
1290                                 e.fire_deathtype = dt;
1291                                 if(e.fire_owner != o)
1292                                 {
1293                                         e.fire_owner = o;
1294                                         e.fire_hitsound = FALSE;
1295                                 }
1296                         }
1297                         if(accuracy_isgooddamage(o, e))
1298                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1299                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1300                 }
1301                 else
1302                         return 0;
1303         }
1304         else
1305         {
1306                 e.fire_damagepersec = dps;
1307                 e.fire_endtime = time + t;
1308                 e.fire_deathtype = dt;
1309                 e.fire_owner = o;
1310                 e.fire_hitsound = FALSE;
1311                 if(accuracy_isgooddamage(o, e))
1312                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1313                 return d;
1314         }
1315 }
1316
1317 void Fire_ApplyDamage(entity e)
1318 {
1319         float t, d, hi, ty;
1320         entity o;
1321
1322         if not(Fire_IsBurning(e))
1323                 return;
1324
1325         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1326         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1327                 o = e.fire_owner;
1328
1329         // water and slime stop fire
1330         if(e.waterlevel)
1331         if(e.watertype != CONTENT_LAVA)
1332                 e.fire_endtime = 0;
1333
1334         // ice stops fire
1335         if(e.freezetag_frozen)
1336                 e.fire_endtime = 0;
1337
1338         t = min(frametime, e.fire_endtime - time);
1339         d = e.fire_damagepersec * t;
1340
1341         hi = e.fire_owner.hitsound;
1342         ty = e.fire_owner.typehitsound;
1343         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1344         if(e.fire_hitsound && e.fire_owner)
1345         {
1346                 e.fire_owner.hitsound = hi;
1347                 e.fire_owner.typehitsound = ty;
1348         }
1349         e.fire_hitsound = TRUE;
1350
1351         if not(IS_INDEPENDENT_PLAYER(e))
1352         FOR_EACH_PLAYER(other) if(e != other)
1353         {
1354                 if(other.classname == "player")
1355                 if(other.deadflag == DEAD_NO)
1356                 if not(IS_INDEPENDENT_PLAYER(other))
1357                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1358                 {
1359                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1360                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1361                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1362                 }
1363         }
1364 }
1365
1366 void Fire_ApplyEffect(entity e)
1367 {
1368         if(Fire_IsBurning(e))
1369                 e.effects |= EF_FLAME;
1370         else
1371                 e.effects &~= EF_FLAME;
1372 }
1373
1374 void fireburner_think()
1375 {
1376         // for players, this is done in the regular loop
1377         if(wasfreed(self.owner))
1378         {
1379                 remove(self);
1380                 return;
1381         }
1382         Fire_ApplyEffect(self.owner);
1383         if(!Fire_IsBurning(self.owner))
1384         {
1385                 self.owner.fire_burner = world;
1386                 remove(self);
1387                 return;
1388         }
1389         Fire_ApplyDamage(self.owner);
1390         self.nextthink = time;
1391 }