qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50 float headshot;
  51 float damage_headshotbonus; // bonus multiplier for head shots, set to 0 after use
  52
  53 .float dmg_team;
  54 .float teamkill_complain;
  55 .float teamkill_soundtime;
  56 .entity teamkill_soundsource;
  57 .entity pusher;
  58 .float istypefrag;
  59 .float taunt_soundtime;
  60
  61
  62 float IsDifferentTeam(entity a, entity b)
  63 {
  64         if(teamplay)
  65         {
  66                 if(a.team == b.team)
  67                         return 0;
  68         }
  69         else
  70         {
  71                 if(a == b)
  72                         return 0;
  73         }
  74         return 1;
  75 }
  76
  77 float IsFlying(entity a)
  78 {
  79         if(a.flags & FL_ONGROUND)
  80                 return 0;
  81         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  82                 return 0;
  83         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  84         if(trace_fraction < 1)
  85                 return 0;
  86         return 1;
  87 }
  88
  89 vector GetHeadshotMins(entity targ)
  90 {
  91         return '-0.5 0 0' * PL_HEAD_x + '0 -0.5 0' * PL_HEAD_y + '0 0 1' * (targ.maxs_z - PL_HEAD_z);
  92 }
  93 vector GetHeadshotMaxs(entity targ)
  94 {
  95         return '0.5 0 0' * PL_HEAD_x + '0 0.5 0' * PL_HEAD_y + '0 0 1' * targ.maxs_z;
  96 }
  97
  98 void UpdateFrags(entity player, float f)
  99 {
 100         PlayerTeamScore_AddScore(player, f);
 101 }
 102
 103 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
 104 void W_SwitchWeapon_Force(entity e, float w);
 105 entity GiveFrags_randomweapons;
 106 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
 107 {
 108         // TODO route through PlayerScores instead
 109         if(gameover) return;
 110
 111         if(f < 0)
 112         {
 113                 if(targ == attacker)
 114                 {
 115                         // suicide
 116                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 117                 }
 118                 else
 119                 {
 120                         // teamkill
 121                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 122                 }
 123         }
 124         else
 125         {
 126                 // regular frag
 127                 PlayerScore_Add(attacker, SP_KILLS, 1);
 128                 if(targ.playerid)
 129                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 130         }
 131
 132         PlayerScore_Add(targ, SP_DEATHS, 1);
 133
 134         if(g_arena || g_ca)
 135                 if(autocvar_g_arena_roundbased)
 136                         return;
 137
 138         if(targ != attacker) // not for suicides
 139         if(g_weaponarena_random)
 140         {
 141                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 142                 float culprit;
 143                 culprit = DEATH_WEAPONOF(deathtype);
 144                 if(!culprit)
 145                         culprit = attacker.weapon;
 146                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 147                         culprit = attacker.weapon;
 148
 149                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 150                 {
 151                         // no exchange
 152                 }
 153                 else
 154                 {
 155                         if(!GiveFrags_randomweapons)
 156                         {
 157                                 GiveFrags_randomweapons = spawn();
 158                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 159                         }
 160
 161                         if(inWarmupStage)
 162                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 163                         else
 164                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 165
 166                         // all others (including the culprit): remove
 167                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 168                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 169
 170                         // among the remaining ones, choose one by random
 171                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 172
 173                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 174                         {
 175                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 176                                 WEPSET_ANDNOT_EW(attacker, culprit);
 177                         }
 178                 }
 179
 180                 // after a frag, choose another random weapon set
 181                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 182                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 183         }
 184
 185         // FIXME fix the mess this is (we have REAL points now!)
 186         entity oldself;
 187         oldself = self;
 188         self = attacker;
 189         frag_attacker = attacker;
 190         frag_target = targ;
 191         frag_score = f;
 192         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 193         {
 194                 f = frag_score;
 195                 self = oldself;
 196         }
 197         else
 198         {
 199                 self = oldself;
 200                 if(g_runematch)
 201                 {
 202                         f = RunematchHandleFrags(attacker, targ, f);
 203                 }
 204                 else if(g_lms)
 205                 {
 206                         // remove a life
 207                         float tl;
 208                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 209                         if(tl < lms_lowest_lives)
 210                                 lms_lowest_lives = tl;
 211                         if(tl <= 0)
 212                         {
 213                                 if(!lms_next_place)
 214                                         lms_next_place = player_count;
 215                                 else
 216                                         lms_next_place = min(lms_next_place, player_count);
 217                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 218                                 --lms_next_place;
 219                         }
 220                         f = 0;
 221                 }
 222         }
 223
 224         attacker.totalfrags += f;
 225
 226         if(f)
 227                 UpdateFrags(attacker, f);
 228 }
 229
 230 string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 231 {
 232         string health_output = string_null;
 233         string ping_output = string_null;
 234         string handicap_output = string_null;
 235         string output = string_null;
 236
 237         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 238         {
 239                 // health/armor of attacker (person who killed you)
 240                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 241                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 242
 243                 // ping display
 244                 if(autocvar_sv_fraginfo_ping)
 245                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 246
 247                 // handicap display
 248                 if(autocvar_sv_fraginfo_handicap)
 249                 {
 250                         if(autocvar_sv_fraginfo_handicap == 2)
 251                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 252                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 253                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 254                 }
 255
 256                 // format the string
 257                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 258                         ping_output, (handicap_output ? "^7 / " : ""),
 259                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 260
 261                 // add new line to the beginning if there is a message
 262                 if(output) { output = strcat("\n", output); }
 263         }
 264
 265         return output;
 266 }
 267
 268 string AppendItemcodes(string s, entity player)
 269 {
 270         float w;
 271         w = player.weapon;
 272         //if(w == 0)
 273         //      w = player.switchweapon;
 274         if(w == 0)
 275                 w = player.cnt; // previous weapon!
 276         s = strcat(s, ftos(w));
 277         if(time < player.strength_finished)
 278                 s = strcat(s, "S");
 279         if(time < player.invincible_finished)
 280                 s = strcat(s, "I");
 281         if(player.flagcarried != world)
 282                 s = strcat(s, "F");
 283         if(player.BUTTON_CHAT)
 284                 s = strcat(s, "T");
 285         if(player.kh_next)
 286                 s = strcat(s, "K");
 287         if(player.runes)
 288                 s = strcat(s, "|", ftos(player.runes));
 289         return s;
 290 }
 291
 292 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 293 {
 294         string s;
 295         if(!autocvar_sv_eventlog)
 296                 return;
 297         s = strcat(":kill:", mode);
 298         s = strcat(s, ":", ftos(killer.playerid));
 299         s = strcat(s, ":", ftos(killed.playerid));
 300         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 301         s = strcat(s, ":items=");
 302         s = AppendItemcodes(s, killer);
 303         if(killed != killer)
 304         {
 305                 s = strcat(s, ":victimitems=");
 306                 s = AppendItemcodes(s, killed);
 307         }
 308         GameLogEcho(s);
 309 }
 310
 311 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 312 {
 313         float handled, hits;
 314         if(DEATH_ISSPECIAL(deathtype))
 315         {
 316                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 317                         { if(deathtype == max(0, name)) \
 318                         { \
 319                                 #if msg_death != NO_MSG \
 320                                         if not(murder) \
 321                                         { \
 322                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death, s1, s2, f1, f2, f3); \
 323                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death, s1, s2, f1, f2, f3); \
 324                                                 ++handled; \
 325                                         } \
 326                                 #else \
 327                                 #if msg_death_by != NO_MSG \
 328                                         if(murder) \
 329                                         { \
 330                                                 Send_Notification(notif_target, MSG_ONE, MSG_DEATH, msg_death_by, s1, s2, f1, f2, f3); \
 331                                                 Send_Notification_ToAll(notif_target, TRUE, MSG_INFO, INFO_##msg_death_by, s1, s2, f1, f2, f3); \
 332                                                 ++handled; \
 333                                         } \
 334                                 #endif \
 335                                 #endif \
 336                                 ++hits; \
 337                         } }
 338
 339                 DEATHTYPES
 340                 #undef DEATHTYPE
 341
 342                 if not(hits)
 343                 {
 344                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 345                         //return;
 346                 }
 347                 if not(handled)
 348                 {
 349                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 350                         return;
 351                 }
 352         }
 353 }
 354
 355 void Obituary_WeaponDeath(entity notif_target, float deathtype, string s1, string s2, float f1, float f2, float f3)
 356 {
 357         float handled, hits;
 358         if(DEATH_ISSPECIAL(deathtype))
 359         {
 360                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 361                         { if(deathtype == max(0, name)) \
 362                         { \
 363                                 ++hits; \
 364                         } }
 365
 366                 DEATHTYPES
 367                 #undef DEATHTYPE
 368
 369                 if not(hits)
 370                 {
 371                         backtrace("Unhandled deathtype. Please notify Samual!\n");
 372                         //return;
 373                 }
 374                 if not(handled)
 375                 {
 376                         print(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 377                         return;
 378                 }
 379         }
 380 }
 381
 382 .float FRAG_VERBOSE;
 383
 384 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 385 {
 386         // Sanity check
 387         if not(targ.classname == "player") { backtrace("Obituary called on non-player?!\n"); return; }
 388
 389         // Declarations
 390         string  s, a, msg;
 391         float w, type;
 392
 393         string s1 = NO_STR_ARG, s2 = NO_STR_ARG;
 394         float f1 = NO_FL_ARG, f2 = NO_FL_ARG, f3 = NO_FL_ARG;
 395         float notif_firstblood;
 396
 397
 398         print(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 399
 400
 401         // =======
 402         // SUICIDE
 403         // =======
 404         if(targ == attacker)
 405         {
 406                 if(DEATH_ISSPECIAL(deathtype))
 407                 {
 408                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 409                         {
 410                                 s1 = targ.netname;
 411                                 f1 = targ.team;
 412                         }
 413                         else
 414                         {
 415                                 switch(deathtype)
 416                                 {
 417                                         case DEATH_MIRRORDAMAGE:
 418                                         {
 419                                                 s1 = targ.netname;
 420                                                 f1 = targ.team;
 421                                                 //f2 = targ.killcount;
 422                                                 break;
 423                                         }
 424
 425                                         default:
 426                                         {
 427                                                 s1 = targ.netname;
 428                                                 s2 = NO_STR_ARG;
 429                                                 f1 = f2 = f3 = NO_FL_ARG;
 430                                                 break;
 431                                         }
 432                                 }
 433                                 LogDeath("suicide", deathtype, targ, targ);
 434                                 GiveFrags(attacker, targ, -1, deathtype);
 435                         }
 436                         Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 437                 }
 438                 else if(DEATH_WEAPONOF(deathtype))
 439                 {
 440                         print("death was a weapon!\n");
 441                 }
 442                 else
 443                 {
 444                         backtrace("what the hell happened here?\n");
 445                 }
 446         }
 447
 448
 449         // ======
 450         // MURDER
 451         // ======
 452         else if(attacker.classname == "player")
 453         {
 454                 if(!IsDifferentTeam(attacker, targ))
 455                 {
 456                         if(DEATH_ISSPECIAL(deathtype))
 457                         {
 458                                 backtrace("hmm death was special?\n");
 459                         }
 460                         else if(DEATH_WEAPONOF(deathtype))
 461                         {
 462                                 print("death was a weapon!\n");
 463                         }
 464                         else
 465                         {
 466                                 backtrace("what the hell happened here?\n");
 467                         }
 468
 469                         LogDeath("tk", deathtype, attacker, targ);
 470                         GiveFrags(attacker, targ, -1, deathtype);
 471                 }
 472                 else
 473                 {
 474                         s1 = attacker.netname;
 475                         s2 = targ.netname;
 476
 477                         attacker.FRAG_VERBOSE = TRUE;
 478                         targ.FRAG_VERBOSE = TRUE;
 479
 480                         LogDeath("frag", deathtype, attacker, targ);
 481                         GiveFrags(attacker, targ, 1, deathtype);
 482
 483                         attacker.taunt_soundtime = time + 1;
 484                         attacker.killcount = attacker.killcount + 1;
 485                         if(targ.killcount > 2) { Send_KillNotification(s, ftos(targ.killcount), a, KILL_END_SPREE, MSG_SPREE); }
 486
 487                         #define ADD_ACHIEVEMENT_CASE(numa,numb) \
 488                                 case numa: \
 489                                 { \
 490                                         AnnounceTo(attacker, strcat(#numb, "kills")); \
 491                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##numa, 1); \
 492                                         break; \
 493                                 }
 494                         switch(attacker.killcount)
 495                         {
 496                                 ADD_ACHIEVEMENT_CASE(3, 03)
 497                                 ADD_ACHIEVEMENT_CASE(5, 05)
 498                                 ADD_ACHIEVEMENT_CASE(10, 10)
 499                                 ADD_ACHIEVEMENT_CASE(15, 15)
 500                                 ADD_ACHIEVEMENT_CASE(20, 20)
 501                                 ADD_ACHIEVEMENT_CASE(25, 25)
 502                                 ADD_ACHIEVEMENT_CASE(30, 30)
 503                                 default: break;
 504                         }
 505                         #undef ADD_ACHIEVEMENT_CASE
 506
 507                         if(!checkrules_firstblood)
 508                         {
 509                                 checkrules_firstblood = TRUE;
 510                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 511                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 512                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 513                         }
 514
 515                         if(notif_firstblood) // first blood, no kill sprees yet
 516                         {
 517                                 if(targ.istypefrag)
 518                                 {
 519                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAG_FIRST),
 520                                                 s2, NO_STR_ARG, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 521
 522                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_FIRST_VERBOSE : DEATH_MURDER_TYPEFRAGGED_FIRST),
 523                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 524                                 }
 525                                 else
 526                                 {
 527                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_FIRST_VERBOSE : DEATH_MURDER_FRAG_FIRST),
 528                                                 s2, NO_STR_ARG, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG, NO_FL_ARG);
 529
 530                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_FIRST_VERBOSE : DEATH_MURDER_FRAGGED_FIRST),
 531                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 532                                 }
 533                                 //Send_Notification(world, MSG_INFO, INFO_DEATH_FRAG_FIRSTBLOOD, s1, s2, attacker.team, NO_FL_ARG, NO_FL_ARG);
 534                         }
 535                         else // normal frags, kill sprees listed
 536                         {
 537                                 if(targ.istypefrag)
 538                                 {
 539                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAG_VERBOSE : DEATH_MURDER_TYPEFRAG),
 540                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 541
 542                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_TYPEFRAGGED_VERBOSE : DEATH_MURDER_TYPEFRAGGED),
 543                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 544                                 }
 545                                 else
 546                                 {
 547                                         Send_Notification(attacker, MSG_ONE, MSG_DEATH, (attacker.FRAG_VERBOSE ? DEATH_MURDER_FRAG_VERBOSE : DEATH_MURDER_FRAG),
 548                                                 s2, NO_STR_ARG, attacker.killcount, (attacker.FRAG_VERBOSE ? ((clienttype(targ) == CLIENTTYPE_BOT) ? BOT_PING : targ.ping) : NO_FL_ARG), NO_FL_ARG);
 549
 550                                         Send_Notification(targ, MSG_ONE, MSG_DEATH, (targ.FRAG_VERBOSE ? DEATH_MURDER_FRAGGED_VERBOSE : DEATH_MURDER_FRAGGED),
 551                                                 s1, NO_STR_ARG, (targ.FRAG_VERBOSE ? attacker.health : NO_FL_ARG), (targ.FRAG_VERBOSE ? attacker.armorvalue : NO_FL_ARG), (targ.FRAG_VERBOSE ? ((clienttype(attacker) == CLIENTTYPE_BOT) ? BOT_PING : attacker.ping) : NO_FL_ARG));
 552                                 }
 553                                 //if(DEATH_WEAPONOF(deathtype)) { Send_Notification(world, MSG_WEAPON, 50, s1, s2, attacker.killcount, targ.killcount, Obituary_Score_Position); }
 554                                 //else { Obituary_SpecialDeath(world, deathtype, s1, s2, attacker.killcount, targ.killcount, Obituary_Score_Position); }
 555                         }
 556                 }
 557         }
 558
 559         // =============
 560         // ACCIDENT/TRAP
 561         // =============
 562         else
 563         {
 564                 switch(deathtype)
 565                 {
 566                         case DEATH_HURTTRIGGER:
 567                         {
 568                                 s1 = targ.netname;
 569                                 s2 = inflictor.message;
 570                                 break;
 571                         }
 572
 573                         case DEATH_CUSTOM:
 574                         {
 575                                 s1 = targ.netname;
 576                                 s2 = deathmessage;
 577                                 break;
 578                         }
 579
 580                         default:
 581                         {
 582                                 s1 = targ.netname;
 583                                 s2 = NO_STR_ARG;
 584                                 f1 = f2 = f3 = NO_FL_ARG;
 585                                 break;
 586                         }
 587                 }
 588
 589                 if(strstrofs(msg, "%", 0) < 0) { msg = strcat("%s ", msg); }
 590
 591                 LogDeath("accident", deathtype, targ, targ);
 592                 GiveFrags(targ, targ, -1, deathtype);
 593                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5) {
 594                         AnnounceTo(targ, "botlike");
 595                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 596                 }
 597                 Obituary_SpecialDeath(targ, FALSE, deathtype, s1, s2, f1, f2, NO_FL_ARG);
 598         }
 599
 600         targ.death_origin = targ.origin;
 601         if(targ != attacker)
 602                 targ.killer_origin = attacker.origin;
 603
 604         // FIXME: this should go in PutClientInServer
 605         if (targ.killcount)
 606                 targ.killcount = 0;
 607 }
 608
 609 // these are updated by each Damage call for use in button triggering and such
 610 entity damage_targ;
 611 entity damage_inflictor;
 612 entity damage_attacker;
 613
 614 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 615 {
 616         float mirrordamage;
 617         float mirrorforce;
 618         float teamdamage0;
 619         entity attacker_save;
 620         mirrordamage = 0;
 621         mirrorforce = 0;
 622
 623         if (gameover || targ.killcount == -666)
 624                 return;
 625
 626         entity oldself;
 627         oldself = self;
 628         self = targ;
 629         damage_targ = targ;
 630         damage_inflictor = inflictor;
 631         damage_attacker = attacker;
 632                 attacker_save = attacker;
 633
 634         if(targ.classname == "player")
 635                 if(targ.hook)
 636                         if(targ.hook.aiment)
 637                                 if(targ.hook.aiment == attacker)
 638                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 639
 640         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 641         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 642         {
 643                 if(targ.classname == "player")
 644                         if not(IsDifferentTeam(targ, attacker))
 645                         {
 646                                 self = oldself;
 647                                 return;
 648                         }
 649         }
 650
 651         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 652         {
 653                 // These are ALWAYS lethal
 654                 // No damage modification here
 655                 // Instead, prepare the victim for his death...
 656                 targ.armorvalue = 0;
 657                 targ.spawnshieldtime = 0;
 658                 targ.health = 0.9; // this is < 1
 659                 targ.flags -= targ.flags & FL_GODMODE;
 660                 damage = 100000;
 661         }
 662         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 663         {
 664                 // no processing
 665         }
 666         else
 667         {
 668                 /*
 669                 skill based bot damage? gtfo. (tZork)
 670                 if (targ.classname == "player")
 671                 if (attacker.classname == "player")
 672                 if (!targ.isbot)
 673                 if (attacker.isbot)
 674                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 675         */
 676
 677                 // nullify damage if teamplay is on
 678                 if(deathtype != DEATH_TELEFRAG)
 679                 if(attacker.classname == "player")
 680                 {
 681                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 682                         {
 683                                 damage = 0;
 684                                 force = '0 0 0';
 685                         }
 686                         else if(!IsDifferentTeam(attacker, targ))
 687                         {
 688                                 if(autocvar_teamplay_mode == 1)
 689                                         damage = 0;
 690                                 else if(attacker != targ)
 691                                 {
 692                                         if(autocvar_teamplay_mode == 3)
 693                                                 damage = 0;
 694                                         else if(autocvar_teamplay_mode == 4)
 695                                         {
 696                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 697                                                 {
 698                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 699                                                         attacker.dmg_team = attacker.dmg_team + damage;
 700                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 701                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 702                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 703                                                         if(g_minstagib)
 704                                                         {
 705                                                                 if(autocvar_g_friendlyfire == 0)
 706                                                                         damage = 0;
 707                                                         }
 708                                                         else if(g_ca)
 709                                                                 damage = 0;
 710                                                         else
 711                                                                 damage = autocvar_g_friendlyfire * damage;
 712                                                         // mirrordamage will be used LATER
 713
 714                                                         if(autocvar_g_mirrordamage_virtual)
 715                                                         {
 716                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 717                                                                 attacker.dmg_take += v_x;
 718                                                                 attacker.dmg_save += v_y;
 719                                                                 attacker.dmg_inflictor = inflictor;
 720                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 721                                                                 mirrorforce = 0;
 722                                                         }
 723
 724                                                         if(autocvar_g_friendlyfire_virtual)
 725                                                         {
 726                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 727                                                                 targ.dmg_take += v_x;
 728                                                                 targ.dmg_save += v_y;
 729                                                                 targ.dmg_inflictor = inflictor;
 730                                                                 damage = 0;
 731                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 732                                                                         force = '0 0 0';
 733                                                         }
 734                                                 }
 735                                                 else
 736                                                         damage = 0;
 737                                         }
 738                                 }
 739                         }
 740                 }
 741
 742                 if(targ.classname == "player")
 743                 if(attacker.classname == "player")
 744                 if(attacker != targ)
 745                 {
 746                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 747                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 748                 }
 749
 750                 if(targ.classname == "player")
 751                 if (g_minstagib)
 752                 {
 753                         if ((deathtype == DEATH_FALL)  ||
 754                                 (deathtype == DEATH_DROWN) ||
 755                                 (deathtype == DEATH_SLIME) ||
 756                                 (deathtype == DEATH_LAVA)  ||
 757                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 758                         {
 759                                 self = oldself;
 760                                 return;
 761                         }
 762                         if(damage > 0)
 763                             damage = 10000;
 764                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 765                         {
 766                                 targ.armorvalue -= 1;
 767                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 768                                 damage = 0;
 769                                 targ.hitsound += 1;
 770                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 771                         }
 772                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 773                         {
 774                                 damage = 0;
 775                                 mirrordamage = 0;
 776                                 if (targ != attacker)
 777                                 {
 778                                         if ((targ.health >= 1) && (targ.classname == "player"))
 779                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 780                                         force = '0 0 0';
 781                                         // keep mirrorforce
 782                                         attacker = targ;
 783                                 }
 784                         }
 785                 }
 786
 787                 if not(DEATH_ISSPECIAL(deathtype))
 788                 {
 789                         damage *= g_weapondamagefactor;
 790                         mirrordamage *= g_weapondamagefactor;
 791                         force = force * g_weaponforcefactor;
 792                         mirrorforce *= g_weaponforcefactor;
 793                 }
 794
 795                 // should this be changed at all? If so, in what way?
 796                 frag_attacker = attacker;
 797                 frag_target = targ;
 798                 frag_damage = damage;
 799                 frag_force = force;
 800         frag_deathtype = deathtype;
 801                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 802                 damage = frag_damage;
 803                 force = frag_force;
 804
 805                 // apply strength multiplier
 806                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 807                 {
 808                         if(targ == attacker)
 809                         {
 810                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 811                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 812                         }
 813                         else
 814                         {
 815                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 816                                 force = force * autocvar_g_balance_powerup_strength_force;
 817                         }
 818                 }
 819
 820                 // apply invincibility multiplier
 821                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 822                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 823
 824                 if (targ == attacker)
 825                 {
 826                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 827                                 damage = 0;
 828                         else
 829                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 830                 }
 831
 832                 if(g_runematch)
 833                 {
 834                         // apply strength rune
 835                         if (attacker.runes & RUNE_STRENGTH)
 836                         {
 837                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 838                                 {
 839                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 840                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 841                                 }
 842                                 else
 843                                 {
 844                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 845                                         force = force * autocvar_g_balance_rune_strength_force;
 846                                 }
 847                         }
 848                         else if (attacker.runes & CURSE_WEAK)
 849                         {
 850                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 851                                 force = force * autocvar_g_balance_curse_weak_force;
 852                         }
 853
 854                         // apply defense rune
 855                         if (targ.runes & RUNE_DEFENSE)
 856                         {
 857                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 858                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 859                                 else
 860                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 861                         }
 862                         else if (targ.runes & CURSE_VULNER)
 863                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 864                 }
 865
 866                 // count the damage
 867                 if(attacker)
 868                 if(!targ.deadflag)
 869                 if(targ.takedamage == DAMAGE_AIM)
 870                 if(targ != attacker)
 871                 {
 872                         if(damage_headshotbonus)
 873                         {
 874                                 if(targ.classname == "player")
 875                                 {
 876                                         // HEAD SHOT:
 877                                         // find height of hit on player axis
 878                                         // if above view_ofs and below maxs, and also in the middle half of the bbox, it is head shot
 879                                         vector headmins, headmaxs, org;
 880                                         org = antilag_takebackorigin(targ, time - ANTILAG_LATENCY(attacker));
 881                                         headmins = org + GetHeadshotMins(targ);
 882                                         headmaxs = org + GetHeadshotMaxs(targ);
 883                                         if(trace_hits_box(railgun_start, railgun_end, headmins, headmaxs))
 884                                         {
 885                                                 deathtype |= HITTYPE_HEADSHOT;
 886                                         }
 887                                 }
 888                                 else if(targ.classname == "turret_head")
 889                                 {
 890                                         deathtype |= HITTYPE_HEADSHOT;
 891                                 }
 892                                 if(deathtype & HITTYPE_HEADSHOT)
 893                                         if(damage_headshotbonus > 0)
 894                                                 damage *= 1 + damage_headshotbonus;
 895                         }
 896
 897                         entity victim;
 898                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 899                                 victim = targ.owner;
 900                         else
 901                                 victim = targ;
 902
 903                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 904                         {
 905                                 if(IsDifferentTeam(victim, attacker))
 906                                 {
 907                                         if(damage > 0)
 908                                         {
 909                                                 if(deathtype != DEATH_FIRE)
 910                                                 {
 911                                                         if(victim.BUTTON_CHAT)
 912                                                                 attacker.typehitsound += 1;
 913                                                         else
 914                                                                 attacker.hitsound += 1;
 915                                                 }
 916
 917                                                 damage_goodhits += 1;
 918                                                 damage_gooddamage += damage;
 919
 920                                                 if not(DEATH_ISSPECIAL(deathtype))
 921                                                 {
 922                                                         if(targ.classname == "player") // don't do this for vehicles
 923                                                         if(!g_minstagib)
 924                                                         if(IsFlying(victim))
 925                                                                 yoda = 1;
 926
 927                                                         if(g_minstagib)
 928                                                         if(victim.items & IT_STRENGTH)
 929                                                                 yoda = 1;
 930
 931                                                         if(deathtype & HITTYPE_HEADSHOT)
 932                                                                 headshot = 1;
 933                                                 }
 934                                         }
 935                                 }
 936                                 else
 937                                 {
 938                                         if(deathtype != DEATH_FIRE)
 939                                         {
 940                                                 attacker.typehitsound += 1;
 941                                         }
 942                                         if(mirrordamage > 0)
 943                                                 if(time > attacker.teamkill_complain)
 944                                                 {
 945                                                         attacker.teamkill_complain = time + 5;
 946                                                         attacker.teamkill_soundtime = time + 0.4;
 947                                                         attacker.teamkill_soundsource = targ;
 948                                                 }
 949                                 }
 950                         }
 951                 }
 952         }
 953
 954         // apply push
 955         if (self.damageforcescale)
 956         if (vlen(force))
 957         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 958         {
 959                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 960                 if(self.movetype == MOVETYPE_PHYSICS)
 961                 {
 962                         entity farcent;
 963                         farcent = spawn();
 964                         farcent.classname = "farce";
 965                         farcent.enemy = self;
 966                         farcent.movedir = farce * 10;
 967                         if(self.mass)
 968                                 farcent.movedir = farcent.movedir * self.mass;
 969                         farcent.origin = hitloc;
 970                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 971                         farcent.nextthink = time + 0.1;
 972                         farcent.think = SUB_Remove;
 973                 }
 974                 else
 975                         self.velocity = self.velocity + farce;
 976                 self.flags &~= FL_ONGROUND;
 977                 UpdateCSQCProjectile(self);
 978         }
 979         // apply damage
 980         if (damage != 0 || (self.damageforcescale && vlen(force)))
 981         if (self.event_damage)
 982                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 983         self = oldself;
 984
 985         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 986         {
 987                 if(g_runematch)
 988                 {
 989                         if (attacker.runes & RUNE_VAMPIRE)
 990                         {
 991                         // apply vampire rune
 992                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 993                                 {
 994                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 995                                         attacker.health = bound(
 996                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 997                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 998                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 999                                 }
1000                                 else
1001                                 {
1002                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
1003                                         attacker.health = bound(
1004                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
1005                                                                                         // empathy won't let you gain health in the same way...
1006                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
1007                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
1008                                         }
1009                         }
1010                         // apply empathy curse
1011                         else if (attacker.runes & CURSE_EMPATHY)
1012                         {
1013                                 attacker.health = bound(
1014                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
1015                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
1016                                         attacker.health);
1017                         }
1018                 }
1019         }
1020
1021         // apply mirror damage if any
1022         if(mirrordamage > 0 || mirrorforce > 0)
1023         {
1024                 attacker = attacker_save;
1025                 if(g_minstagib)
1026                 if(mirrordamage > 0)
1027                 {
1028                         // just lose extra LIVES, don't kill the player for mirror damage
1029                         if(attacker.armorvalue > 0)
1030                         {
1031                                 attacker.armorvalue = attacker.armorvalue - 1;
1032                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
1033                                 attacker.hitsound += 1;
1034                         }
1035                         mirrordamage = 0;
1036                 }
1037
1038                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
1039                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
1040         }
1041 }
1042
1043 float RadiusDamage_running;
1044 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
1045         // Returns total damage applies to creatures
1046 {
1047         entity  targ;
1048         vector  blastorigin;
1049         vector  force;
1050         float   total_damage_to_creatures;
1051         entity  next;
1052         float   tfloordmg;
1053         float   tfloorforce;
1054
1055         float stat_damagedone;
1056
1057         if(RadiusDamage_running)
1058         {
1059                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
1060                 return 0;
1061         }
1062
1063         RadiusDamage_running = 1;
1064
1065         tfloordmg = autocvar_g_throughfloor_damage;
1066         tfloorforce = autocvar_g_throughfloor_force;
1067
1068         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
1069         total_damage_to_creatures = 0;
1070
1071         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
1072                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
1073                 {
1074                         force = inflictor.velocity;
1075                         if(vlen(force) == 0)
1076                                 force = '0 0 -1';
1077                         else
1078                                 force = normalize(force);
1079                         if(forceintensity >= 0)
1080                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1081                         else
1082                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1083                 }
1084
1085         stat_damagedone = 0;
1086
1087         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1088         while (targ)
1089         {
1090                 next = targ.chain;
1091                 if (targ != inflictor)
1092                         if (ignore != targ) if(targ.takedamage)
1093                         {
1094                                 vector nearest;
1095                                 vector diff;
1096                                 float power;
1097
1098                                 // LordHavoc: measure distance to nearest point on target (not origin)
1099                                 // (this guarentees 100% damage on a touch impact)
1100                                 nearest = targ.WarpZone_findradius_nearest;
1101                                 diff = targ.WarpZone_findradius_dist;
1102                                 // round up a little on the damage to ensure full damage on impacts
1103                                 // and turn the distance into a fraction of the radius
1104                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1105                                 //bprint(" ");
1106                                 //bprint(ftos(power));
1107                                 //if (targ == attacker)
1108                                 //      print(ftos(power), "\n");
1109                                 if (power > 0)
1110                                 {
1111                                         float finaldmg;
1112                                         if (power > 1)
1113                                                 power = 1;
1114                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1115                                         if (finaldmg > 0)
1116                                         {
1117                                                 float a;
1118                                                 float c;
1119                                                 vector hitloc;
1120                                                 vector myblastorigin;
1121                                                 vector center;
1122
1123                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1124
1125                                                 // if it's a player, use the view origin as reference
1126                                                 center = CENTER_OR_VIEWOFS(targ);
1127
1128                                                 force = normalize(center - myblastorigin);
1129                                                 force = force * (finaldmg / coredamage) * forceintensity;
1130                                                 hitloc = nearest;
1131
1132                                                 if(targ != directhitentity)
1133                                                 {
1134                                                         float hits;
1135                                                         float total;
1136                                                         float hitratio;
1137                                                         float mininv_f, mininv_d;
1138
1139                                                         // test line of sight to multiple positions on box,
1140                                                         // and do damage if any of them hit
1141                                                         hits = 0;
1142
1143                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1144                                                         // so for a given max stddev:
1145                                                         // n = (1 / (2 * max stddev of hitratio))^2
1146
1147                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1148                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1149
1150                                                         if(autocvar_g_throughfloor_debug)
1151                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1152
1153                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1154
1155                                                         if(autocvar_g_throughfloor_debug)
1156                                                                 print(sprintf(" steps=%f", total));
1157
1158                                                         if (targ.classname == "player")
1159                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1160                                                         else
1161                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1162
1163                                                         if(autocvar_g_throughfloor_debug)
1164                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1165
1166                                                         for(c = 0; c < total; ++c)
1167                                                         {
1168                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1169                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1170                                                                 if (trace_fraction == 1 || trace_ent == targ)
1171                                                                 {
1172                                                                         ++hits;
1173                                                                         if (hits > 1)
1174                                                                                 hitloc = hitloc + nearest;
1175                                                                         else
1176                                                                                 hitloc = nearest;
1177                                                                 }
1178                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1179                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1180                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1181                                                         }
1182
1183                                                         nearest = hitloc * (1 / max(1, hits));
1184                                                         hitratio = (hits / total);
1185                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1186                                                         finaldmg = finaldmg * a;
1187                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1188                                                         force = force * a;
1189
1190                                                         if(autocvar_g_throughfloor_debug)
1191                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1192                                                 }
1193
1194                                                 // laser force adjustments :P
1195                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1196                                                 {
1197                                                         if (targ == attacker)
1198                                                         {
1199                                                                 vector vel;
1200
1201                                                                 float force_zscale;
1202                                                                 float force_velocitybiasramp;
1203                                                                 float force_velocitybias;
1204
1205                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1206                                                                 if(deathtype & HITTYPE_SECONDARY)
1207                                                                 {
1208                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1209                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1210                                                                 }
1211                                                                 else
1212                                                                 {
1213                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1214                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1215                                                                 }
1216
1217                                                                 vel = targ.velocity;
1218                                                                 vel_z = 0;
1219                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1220                                                                 force =
1221                                                                         vlen(force)
1222                                                                         *
1223                                                                         normalize(normalize(force) + vel);
1224
1225                                                                 force_z *= force_zscale;
1226                                                         }
1227                                                         else
1228                                                         {
1229                                                                 if(deathtype & HITTYPE_SECONDARY)
1230                                                                 {
1231                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1232                                                                 }
1233                                                                 else
1234                                                                 {
1235                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1236                                                                 }
1237                                                         }
1238                                                 }
1239
1240                                                 //if (targ == attacker)
1241                                                 //{
1242                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1243                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1244                                                 //      print(" (", ftos(a), ")\n");
1245                                                 //}
1246                                                 if(finaldmg || vlen(force))
1247                                                 {
1248                                                         if(targ.iscreature)
1249                                                         {
1250                                                                 total_damage_to_creatures += finaldmg;
1251
1252                                                                 if(accuracy_isgooddamage(attacker, targ))
1253                                                                         stat_damagedone += finaldmg;
1254                                                         }
1255
1256                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1257                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1258                                                         else
1259                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1260                                                 }
1261                                         }
1262                                 }
1263                         }
1264                 targ = next;
1265         }
1266
1267         RadiusDamage_running = 0;
1268
1269         if(!DEATH_ISSPECIAL(deathtype))
1270                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1271
1272         return total_damage_to_creatures;
1273 }
1274
1275 .float fire_damagepersec;
1276 .float fire_endtime;
1277 .float fire_deathtype;
1278 .entity fire_owner;
1279 .float fire_hitsound;
1280 .entity fire_burner;
1281
1282 void fireburner_think();
1283
1284 float Fire_IsBurning(entity e)
1285 {
1286         return (time < e.fire_endtime);
1287 }
1288
1289 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1290 {
1291         float dps;
1292         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1293
1294         if(e.classname == "player")
1295         {
1296                 if(e.deadflag)
1297                         return -1;
1298         }
1299         else
1300         {
1301                 if(!e.fire_burner)
1302                 {
1303                         // print("adding a fire burner to ", e.classname, "\n");
1304                         e.fire_burner = spawn();
1305                         e.fire_burner.classname = "fireburner";
1306                         e.fire_burner.think = fireburner_think;
1307                         e.fire_burner.nextthink = time;
1308                         e.fire_burner.owner = e;
1309                 }
1310         }
1311
1312         t = max(t, 0.1);
1313         dps = d / t;
1314         if(Fire_IsBurning(e))
1315         {
1316                 mintime = e.fire_endtime - time;
1317                 maxtime = max(mintime, t);
1318
1319                 mindps = e.fire_damagepersec;
1320                 maxdps = max(mindps, dps);
1321
1322                 if(maxtime > mintime || maxdps > mindps)
1323                 {
1324                         // Constraints:
1325
1326                         // damage we have right now
1327                         mindamage = mindps * mintime;
1328
1329                         // damage we want to get
1330                         maxdamage = mindamage + d;
1331
1332                         // but we can't exceed maxtime * maxdps!
1333                         totaldamage = min(maxdamage, maxtime * maxdps);
1334
1335                         // LEMMA:
1336                         // Look at:
1337                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1338                         // We see:
1339                         // totaldamage <= maxtime * maxdps
1340                         // ==> totaldamage / maxdps <= maxtime.
1341                         // We also see:
1342                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1343                         //                     >= min(mintime, maxtime)
1344                         // ==> totaldamage / maxdps >= mintime.
1345
1346                         /*
1347                         // how long do we damage then?
1348                         // at least as long as before
1349                         // but, never exceed maxdps
1350                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1351                         */
1352
1353                         // alternate:
1354                         // at most as long as maximum allowed
1355                         // but, never below mindps
1356                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1357
1358                         // assuming t > mintime, dps > mindps:
1359                         // we get d = t * dps = maxtime * maxdps
1360                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1361                         // totaldamage / maxdps = maxtime
1362                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1363                         // FROM THIS:
1364                         // a) totaltime = max(mintime, maxtime) = maxtime
1365                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1366
1367                         // assuming t <= mintime:
1368                         // we get maxtime = mintime
1369                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1370                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1371
1372                         // assuming dps <= mindps:
1373                         // we get mindps = maxdps.
1374                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1375                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1376                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1377
1378                         e.fire_damagepersec = totaldamage / totaltime;
1379                         e.fire_endtime = time + totaltime;
1380                         if(totaldamage > 1.2 * mindamage)
1381                         {
1382                                 e.fire_deathtype = dt;
1383                                 if(e.fire_owner != o)
1384                                 {
1385                                         e.fire_owner = o;
1386                                         e.fire_hitsound = FALSE;
1387                                 }
1388                         }
1389                         if(accuracy_isgooddamage(o, e))
1390                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1391                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1392                 }
1393                 else
1394                         return 0;
1395         }
1396         else
1397         {
1398                 e.fire_damagepersec = dps;
1399                 e.fire_endtime = time + t;
1400                 e.fire_deathtype = dt;
1401                 e.fire_owner = o;
1402                 e.fire_hitsound = FALSE;
1403                 if(accuracy_isgooddamage(o, e))
1404                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1405                 return d;
1406         }
1407 }
1408
1409 void Fire_ApplyDamage(entity e)
1410 {
1411         float t, d, hi, ty;
1412         entity o;
1413
1414         if not(Fire_IsBurning(e))
1415                 return;
1416
1417         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1418         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1419                 o = e.fire_owner;
1420
1421         // water and slime stop fire
1422         if(e.waterlevel)
1423         if(e.watertype != CONTENT_LAVA)
1424                 e.fire_endtime = 0;
1425
1426         // ice stops fire
1427         if(e.freezetag_frozen)
1428                 e.fire_endtime = 0;
1429
1430         t = min(frametime, e.fire_endtime - time);
1431         d = e.fire_damagepersec * t;
1432
1433         hi = e.fire_owner.hitsound;
1434         ty = e.fire_owner.typehitsound;
1435         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1436         if(e.fire_hitsound && e.fire_owner)
1437         {
1438                 e.fire_owner.hitsound = hi;
1439                 e.fire_owner.typehitsound = ty;
1440         }
1441         e.fire_hitsound = TRUE;
1442
1443         if not(IS_INDEPENDENT_PLAYER(e))
1444         FOR_EACH_PLAYER(other) if(e != other)
1445         {
1446                 if(other.classname == "player")
1447                 if(other.deadflag == DEAD_NO)
1448                 if not(IS_INDEPENDENT_PLAYER(other))
1449                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1450                 {
1451                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1452                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1453                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1454                 }
1455         }
1456 }
1457
1458 void Fire_ApplyEffect(entity e)
1459 {
1460         if(Fire_IsBurning(e))
1461                 e.effects |= EF_FLAME;
1462         else
1463                 e.effects &~= EF_FLAME;
1464 }
1465
1466 void fireburner_think()
1467 {
1468         // for players, this is done in the regular loop
1469         if(wasfreed(self.owner))
1470         {
1471                 remove(self);
1472                 return;
1473         }
1474         Fire_ApplyEffect(self.owner);
1475         if(!Fire_IsBurning(self.owner))
1476         {
1477                 self.owner.fire_burner = world;
1478                 remove(self);
1479                 return;
1480         }
1481         Fire_ApplyDamage(self.owner);
1482         self.nextthink = time;
1483 }