qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 /*string Obituary_ExtraFragInfo(entity player) // Extra fragmessage information
 220 {
 221         string health_output = string_null;
 222         string ping_output = string_null;
 223         string handicap_output = string_null;
 224         string output = string_null;
 225
 226         if(autocvar_sv_fraginfo && ((autocvar_sv_fraginfo == 2) || inWarmupStage))
 227         {
 228                 // health/armor of attacker (person who killed you)
 229                 if(autocvar_sv_fraginfo_stats && (player.health >= 1))
 230                         health_output = strcat("^7(Health ^1", ftos(rint(player.health)), "^7 / Armor ^2", ftos(rint(player.armorvalue)), "^7)");
 231
 232                 // ping display
 233                 if(autocvar_sv_fraginfo_ping)
 234                         ping_output = ((clienttype(player) == CLIENTTYPE_BOT) ? "^2Bot" : strcat("Ping ", ((player.ping >= 150) ? "^1" : "^2"), ftos(rint(player.ping)), "ms"));
 235
 236                 // handicap display
 237                 if(autocvar_sv_fraginfo_handicap)
 238                 {
 239                         if(autocvar_sv_fraginfo_handicap == 2)
 240                                 handicap_output = strcat(output, strcat("Handicap ^2", ((player.cvar_cl_handicap <= 1) ? "Off" : ftos(rint(player.cvar_cl_handicap)))));
 241                         else if(player.cvar_cl_handicap) // with _handicap 1, only show this if there actually is a handicap enabled.
 242                                 handicap_output = strcat("Handicap ^2", ftos(rint(player.cvar_cl_handicap)));
 243                 }
 244
 245                 // format the string
 246                 output = strcat(health_output, (health_output ? ((ping_output || handicap_output) ? " ^7(" : "") : ((ping_output || handicap_output) ? "^7(" : "")),
 247                         ping_output, (handicap_output ? "^7 / " : ""),
 248                         handicap_output, ((ping_output || handicap_output) ? "^7)" : ""));
 249
 250                 // add new line to the beginning if there is a message
 251                 if(output) { output = strcat("\n", output); }
 252         }
 253
 254         return output;
 255 }*/
 256
 257 string AppendItemcodes(string s, entity player)
 258 {
 259         float w;
 260         w = player.weapon;
 261         //if(w == 0)
 262         //      w = player.switchweapon;
 263         if(w == 0)
 264                 w = player.cnt; // previous weapon!
 265         s = strcat(s, ftos(w));
 266         if(time < player.strength_finished)
 267                 s = strcat(s, "S");
 268         if(time < player.invincible_finished)
 269                 s = strcat(s, "I");
 270         if(player.flagcarried != world)
 271                 s = strcat(s, "F");
 272         if(player.BUTTON_CHAT)
 273                 s = strcat(s, "T");
 274         if(player.kh_next)
 275                 s = strcat(s, "K");
 276         if(player.runes)
 277                 s = strcat(s, "|", ftos(player.runes));
 278         return s;
 279 }
 280
 281 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 282 {
 283         string s;
 284         if(!autocvar_sv_eventlog)
 285                 return;
 286         s = strcat(":kill:", mode);
 287         s = strcat(s, ":", ftos(killer.playerid));
 288         s = strcat(s, ":", ftos(killed.playerid));
 289         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 290         s = strcat(s, ":items=");
 291         s = AppendItemcodes(s, killer);
 292         if(killed != killer)
 293         {
 294                 s = strcat(s, ":victimitems=");
 295                 s = AppendItemcodes(s, killed);
 296         }
 297         GameLogEcho(s);
 298 }
 299
 300 #define INFO_NO_MSG 0
 301
 302 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2, float f3)
 303 {
 304         float handled = 0, hits = 0;
 305         if(DEATH_ISSPECIAL(deathtype))
 306         {
 307                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 308                         { if(deathtype == max(0, name)) \
 309                         { \
 310                                 #if msg_death != NO_MSG \
 311                                         if not(murder) \
 312                                         { \
 313                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, "", "", f1, f2, f3, 0); \
 314                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, "", "", f1, f2, f3, 0); \
 315                                                 ++handled; \
 316                                         } \
 317                                 #endif \
 318                                 #if msg_death_by != NO_MSG \
 319                                         if(murder) \
 320                                         { \
 321                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, "", "", f1, f2, f3, 0); \
 322                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, "", "", f1, f2, f3, 0); \
 323                                                 ++handled; \
 324                                         } \
 325                                 #endif \
 326                                 ++hits; \
 327                         } }
 328
 329                 DEATHTYPES
 330                 #undef DEATHTYPE
 331
 332                 if not(hits)
 333                 {
 334                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 335                 }
 336                 if not(handled)
 337                 {
 338                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 339                         return;
 340                 }
 341         }
 342 }
 343
 344 float w_deathtype;
 345 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, float f1, float f2)
 346 {
 347         float death_weapon = DEATH_WEAPONOF(deathtype);
 348
 349         if(death_weapon)
 350         {
 351                 w_deathtype = deathtype;
 352                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 353                 w_deathtype = FALSE;
 354
 355                 if(death_message)
 356                 {
 357                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, "", "", f1, f2, 0, 0);
 358                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, "", "", f1, f2, 0, 0);
 359                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 360                 }
 361                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 362
 363                 return TRUE;
 364         }
 365         return FALSE;
 366 }
 367
 368 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 369 {
 370         // Sanity check
 371         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 372
 373         // Declarations
 374         float notif_firstblood = FALSE;
 375
 376         //dprint(sprintf("Obituary(): Deathtype = %s (%d), Attacker = %s, Inflictor = %s, Target = %s...\n", Deathtype_Name(deathtype), deathtype, attacker.netname, inflictor.netname, targ.netname));
 377
 378         // =======
 379         // SUICIDE
 380         // =======
 381         if(targ == attacker)
 382         {
 383                 if(DEATH_ISSPECIAL(deathtype))
 384                 {
 385                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 386                         {
 387                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, "", targ.team, 0, 0);
 388                         }
 389                         else
 390                         {
 391                                 switch(deathtype)
 392                                 {
 393                                         case DEATH_MIRRORDAMAGE:
 394                                         {
 395                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, "", targ.killcount, 0, 0);
 396                                                 break;
 397                                         }
 398
 399                                         default:
 400                                         {
 401                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, "", targ.killcount, 0, 0);
 402                                                 break;
 403                                         }
 404                                 }
 405                                 LogDeath("suicide", deathtype, targ, targ);
 406                                 GiveFrags(attacker, targ, -1, deathtype);
 407                         }
 408                 }
 409                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, "", targ.killcount, 0))
 410                 {
 411                         backtrace("SUICIDE: what the hell happened here?\n");
 412                 }
 413         }
 414
 415         // ======
 416         // MURDER
 417         // ======
 418         else if(attacker.classname == "player")
 419         {
 420                 if(!IsDifferentTeam(attacker, targ))
 421                 {
 422                         LogDeath("tk", deathtype, attacker, targ);
 423                         GiveFrags(attacker, targ, -1, deathtype);
 424
 425                         attacker.killcount = 0;
 426
 427                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 428                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 429                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 430
 431                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 432                         // No need for specific death/weapon messages...
 433                 }
 434                 else
 435                 {
 436                         LogDeath("frag", deathtype, attacker, targ);
 437                         GiveFrags(attacker, targ, 1, deathtype);
 438
 439                         attacker.taunt_soundtime = time + 1;
 440                         attacker.killcount = attacker.killcount + 1;
 441
 442                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 443                                 case counta: \
 444                                 { \
 445                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 446                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 447                                         break; \
 448                                 }
 449                         switch(attacker.killcount)
 450                         {
 451                                 KILL_SPREE_LIST
 452                                 default: break;
 453                         }
 454                         #undef SPREE_ITEM
 455
 456                         if(!checkrules_firstblood)
 457                         {
 458                                 checkrules_firstblood = TRUE;
 459                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 460                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 461                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 462                         }
 463
 464                         float kill_count_to_attacker;
 465                         float kill_count_to_target;
 466                         if(notif_firstblood)
 467                         {
 468                                 kill_count_to_attacker = -1;
 469                                 kill_count_to_target = -2;
 470                         }
 471                         else
 472                         {
 473                                 kill_count_to_attacker = attacker.killcount;
 474                                 kill_count_to_target = 0;
 475                         }
 476
 477                         if(targ.istypefrag)
 478                         {
 479                                 if(attacker.FRAG_VERBOSE)
 480                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 481                                 else
 482                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 483
 484                                 if(targ.FRAG_VERBOSE)
 485                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 486                                 else
 487                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 488                         }
 489                         else
 490                         {
 491                                 if(attacker.FRAG_VERBOSE)
 492                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 493                                 else
 494                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 495
 496                                 if(targ.FRAG_VERBOSE)
 497                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 498                                 else
 499                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 500                         }
 501
 502                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, targ.killcount, kill_count_to_attacker))
 503                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, targ.killcount, kill_count_to_attacker, 0);
 504                 }
 505         }
 506
 507         // =============
 508         // ACCIDENT/TRAP
 509         // =============
 510         else
 511         {
 512                 switch(deathtype)
 513                 {
 514                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 515                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 516                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 517                         /*case DEATH_HURTTRIGGER:
 518                         {
 519                                 s1 = targ.netname;
 520                                 s2 = inflictor.message;
 521                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 522                                 break;
 523                         }*/
 524
 525                         case DEATH_CUSTOM:
 526                         {
 527                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 528                                         targ.netname,
 529                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 530                                         targ.killcount,
 531                                         0,
 532                                         0);
 533                                 break;
 534                         }
 535
 536                         default:
 537                         {
 538                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, "", targ.killcount, 0, 0);
 539                                 break;
 540                         }
 541                 }
 542
 543                 LogDeath("accident", deathtype, targ, targ);
 544                 GiveFrags(targ, targ, -1, deathtype);
 545
 546                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 547                 {
 548                         AnnounceTo(targ, "botlike");
 549                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 550                 }
 551         }
 552
 553         // Set final information for the death
 554         targ.death_origin = targ.origin;
 555         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 556         if(targ.killcount) { targ.killcount = 0; }
 557 }
 558
 559 // these are updated by each Damage call for use in button triggering and such
 560 entity damage_targ;
 561 entity damage_inflictor;
 562 entity damage_attacker;
 563
 564 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 565 {
 566         float mirrordamage;
 567         float mirrorforce;
 568         float teamdamage0;
 569         entity attacker_save;
 570         mirrordamage = 0;
 571         mirrorforce = 0;
 572
 573         if (gameover || targ.killcount == -666)
 574                 return;
 575
 576         entity oldself;
 577         oldself = self;
 578         self = targ;
 579         damage_targ = targ;
 580         damage_inflictor = inflictor;
 581         damage_attacker = attacker;
 582                 attacker_save = attacker;
 583
 584         if(targ.classname == "player")
 585                 if(targ.hook)
 586                         if(targ.hook.aiment)
 587                                 if(targ.hook.aiment == attacker)
 588                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 589
 590         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 591         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 592         {
 593                 if(targ.classname == "player")
 594                         if not(IsDifferentTeam(targ, attacker))
 595                         {
 596                                 self = oldself;
 597                                 return;
 598                         }
 599         }
 600
 601         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 602         {
 603                 // These are ALWAYS lethal
 604                 // No damage modification here
 605                 // Instead, prepare the victim for his death...
 606                 targ.armorvalue = 0;
 607                 targ.spawnshieldtime = 0;
 608                 targ.health = 0.9; // this is < 1
 609                 targ.flags -= targ.flags & FL_GODMODE;
 610                 damage = 100000;
 611         }
 612         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 613         {
 614                 // no processing
 615         }
 616         else
 617         {
 618                 /*
 619                 skill based bot damage? gtfo. (tZork)
 620                 if (targ.classname == "player")
 621                 if (attacker.classname == "player")
 622                 if (!targ.isbot)
 623                 if (attacker.isbot)
 624                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 625         */
 626
 627                 // nullify damage if teamplay is on
 628                 if(deathtype != DEATH_TELEFRAG)
 629                 if(attacker.classname == "player")
 630                 {
 631                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 632                         {
 633                                 damage = 0;
 634                                 force = '0 0 0';
 635                         }
 636                         else if(!IsDifferentTeam(attacker, targ))
 637                         {
 638                                 if(autocvar_teamplay_mode == 1)
 639                                         damage = 0;
 640                                 else if(attacker != targ)
 641                                 {
 642                                         if(autocvar_teamplay_mode == 3)
 643                                                 damage = 0;
 644                                         else if(autocvar_teamplay_mode == 4)
 645                                         {
 646                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 647                                                 {
 648                                                         teamdamage0 = max(attacker.dmg_team, autocvar_g_teamdamage_threshold);
 649                                                         attacker.dmg_team = attacker.dmg_team + damage;
 650                                                         if(attacker.dmg_team > teamdamage0 && !g_ca)
 651                                                                 mirrordamage = autocvar_g_mirrordamage * (attacker.dmg_team - teamdamage0);
 652                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 653                                                         if(g_minstagib)
 654                                                         {
 655                                                                 if(autocvar_g_friendlyfire == 0)
 656                                                                         damage = 0;
 657                                                         }
 658                                                         else if(g_ca)
 659                                                                 damage = 0;
 660                                                         else
 661                                                                 damage = autocvar_g_friendlyfire * damage;
 662                                                         // mirrordamage will be used LATER
 663
 664                                                         if(autocvar_g_mirrordamage_virtual)
 665                                                         {
 666                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 667                                                                 attacker.dmg_take += v_x;
 668                                                                 attacker.dmg_save += v_y;
 669                                                                 attacker.dmg_inflictor = inflictor;
 670                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 671                                                                 mirrorforce = 0;
 672                                                         }
 673
 674                                                         if(autocvar_g_friendlyfire_virtual)
 675                                                         {
 676                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 677                                                                 targ.dmg_take += v_x;
 678                                                                 targ.dmg_save += v_y;
 679                                                                 targ.dmg_inflictor = inflictor;
 680                                                                 damage = 0;
 681                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 682                                                                         force = '0 0 0';
 683                                                         }
 684                                                 }
 685                                                 else
 686                                                         damage = 0;
 687                                         }
 688                                 }
 689                         }
 690                 }
 691
 692                 if(targ.classname == "player")
 693                 if(attacker.classname == "player")
 694                 if(attacker != targ)
 695                 {
 696                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 697                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 698                 }
 699
 700                 if(targ.classname == "player")
 701                 if (g_minstagib)
 702                 {
 703                         if ((deathtype == DEATH_FALL)  ||
 704                                 (deathtype == DEATH_DROWN) ||
 705                                 (deathtype == DEATH_SLIME) ||
 706                                 (deathtype == DEATH_LAVA)  ||
 707                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 708                         {
 709                                 self = oldself;
 710                                 return;
 711                         }
 712                         if(damage > 0)
 713                             damage = 10000;
 714                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 715                         {
 716                                 targ.armorvalue -= 1;
 717                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 718                                 damage = 0;
 719                                 targ.hitsound += 1;
 720                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 721                         }
 722                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 723                         {
 724                                 damage = 0;
 725                                 mirrordamage = 0;
 726                                 if (targ != attacker)
 727                                 {
 728                                         if ((targ.health >= 1) && (targ.classname == "player"))
 729                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 730                                         force = '0 0 0';
 731                                         // keep mirrorforce
 732                                         attacker = targ;
 733                                 }
 734                         }
 735                 }
 736
 737                 if not(DEATH_ISSPECIAL(deathtype))
 738                 {
 739                         damage *= g_weapondamagefactor;
 740                         mirrordamage *= g_weapondamagefactor;
 741                         force = force * g_weaponforcefactor;
 742                         mirrorforce *= g_weaponforcefactor;
 743                 }
 744
 745                 // should this be changed at all? If so, in what way?
 746                 frag_attacker = attacker;
 747                 frag_target = targ;
 748                 frag_damage = damage;
 749                 frag_force = force;
 750         frag_deathtype = deathtype;
 751                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 752                 damage = frag_damage;
 753                 force = frag_force;
 754
 755                 // apply strength multiplier
 756                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 757                 {
 758                         if(targ == attacker)
 759                         {
 760                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 761                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 762                         }
 763                         else
 764                         {
 765                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 766                                 force = force * autocvar_g_balance_powerup_strength_force;
 767                         }
 768                 }
 769
 770                 // apply invincibility multiplier
 771                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 772                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 773
 774                 if (targ == attacker)
 775                 {
 776                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 777                                 damage = 0;
 778                         else
 779                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 780                 }
 781
 782                 if(g_runematch)
 783                 {
 784                         // apply strength rune
 785                         if (attacker.runes & RUNE_STRENGTH)
 786                         {
 787                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 788                                 {
 789                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 790                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 791                                 }
 792                                 else
 793                                 {
 794                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 795                                         force = force * autocvar_g_balance_rune_strength_force;
 796                                 }
 797                         }
 798                         else if (attacker.runes & CURSE_WEAK)
 799                         {
 800                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 801                                 force = force * autocvar_g_balance_curse_weak_force;
 802                         }
 803
 804                         // apply defense rune
 805                         if (targ.runes & RUNE_DEFENSE)
 806                         {
 807                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 808                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 809                                 else
 810                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 811                         }
 812                         else if (targ.runes & CURSE_VULNER)
 813                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 814                 }
 815
 816                 // count the damage
 817                 if(attacker)
 818                 if(!targ.deadflag)
 819                 if(targ.takedamage == DAMAGE_AIM)
 820                 if(targ != attacker)
 821                 {
 822                         entity victim;
 823                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 824                                 victim = targ.owner;
 825                         else
 826                                 victim = targ;
 827
 828                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 829                         {
 830                                 if(IsDifferentTeam(victim, attacker))
 831                                 {
 832                                         if(damage > 0)
 833                                         {
 834                                                 if(deathtype != DEATH_FIRE)
 835                                                 {
 836                                                         if(victim.BUTTON_CHAT)
 837                                                                 attacker.typehitsound += 1;
 838                                                         else
 839                                                                 attacker.hitsound += 1;
 840                                                 }
 841
 842                                                 damage_goodhits += 1;
 843                                                 damage_gooddamage += damage;
 844
 845                                                 if not(DEATH_ISSPECIAL(deathtype))
 846                                                 {
 847                                                         if(targ.classname == "player") // don't do this for vehicles
 848                                                         if(!g_minstagib)
 849                                                         if(IsFlying(victim))
 850                                                                 yoda = 1;
 851
 852                                                         if(g_minstagib)
 853                                                         if(victim.items & IT_STRENGTH)
 854                                                                 yoda = 1;
 855                                                 }
 856                                         }
 857                                 }
 858                                 else
 859                                 {
 860                                         if(deathtype != DEATH_FIRE)
 861                                         {
 862                                                 attacker.typehitsound += 1;
 863                                         }
 864                                         if(mirrordamage > 0)
 865                                                 if(time > attacker.teamkill_complain)
 866                                                 {
 867                                                         attacker.teamkill_complain = time + 5;
 868                                                         attacker.teamkill_soundtime = time + 0.4;
 869                                                         attacker.teamkill_soundsource = targ;
 870                                                 }
 871                                 }
 872                         }
 873                 }
 874         }
 875
 876         // apply push
 877         if (self.damageforcescale)
 878         if (vlen(force))
 879         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 880         {
 881                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 882                 if(self.movetype == MOVETYPE_PHYSICS)
 883                 {
 884                         entity farcent;
 885                         farcent = spawn();
 886                         farcent.classname = "farce";
 887                         farcent.enemy = self;
 888                         farcent.movedir = farce * 10;
 889                         if(self.mass)
 890                                 farcent.movedir = farcent.movedir * self.mass;
 891                         farcent.origin = hitloc;
 892                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 893                         farcent.nextthink = time + 0.1;
 894                         farcent.think = SUB_Remove;
 895                 }
 896                 else
 897                         self.velocity = self.velocity + farce;
 898                 self.flags &~= FL_ONGROUND;
 899                 UpdateCSQCProjectile(self);
 900         }
 901         // apply damage
 902         if (damage != 0 || (self.damageforcescale && vlen(force)))
 903         if (self.event_damage)
 904                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 905         self = oldself;
 906
 907         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 908         {
 909                 if(g_runematch)
 910                 {
 911                         if (attacker.runes & RUNE_VAMPIRE)
 912                         {
 913                         // apply vampire rune
 914                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 915                                 {
 916                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 917                                         attacker.health = bound(
 918                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 919                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 920                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 921                                 }
 922                                 else
 923                                 {
 924                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 925                                         attacker.health = bound(
 926                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 927                                                                                         // empathy won't let you gain health in the same way...
 928                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 929                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 930                                         }
 931                         }
 932                         // apply empathy curse
 933                         else if (attacker.runes & CURSE_EMPATHY)
 934                         {
 935                                 attacker.health = bound(
 936                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 937                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 938                                         attacker.health);
 939                         }
 940                 }
 941         }
 942
 943         // apply mirror damage if any
 944         if(mirrordamage > 0 || mirrorforce > 0)
 945         {
 946                 attacker = attacker_save;
 947                 if(g_minstagib)
 948                 if(mirrordamage > 0)
 949                 {
 950                         // just lose extra LIVES, don't kill the player for mirror damage
 951                         if(attacker.armorvalue > 0)
 952                         {
 953                                 attacker.armorvalue = attacker.armorvalue - 1;
 954                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 955                                 attacker.hitsound += 1;
 956                         }
 957                         mirrordamage = 0;
 958                 }
 959
 960                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 961                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 962         }
 963 }
 964
 965 float RadiusDamage_running;
 966 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 967         // Returns total damage applies to creatures
 968 {
 969         entity  targ;
 970         vector  blastorigin;
 971         vector  force;
 972         float   total_damage_to_creatures;
 973         entity  next;
 974         float   tfloordmg;
 975         float   tfloorforce;
 976
 977         float stat_damagedone;
 978
 979         if(RadiusDamage_running)
 980         {
 981                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 982                 return 0;
 983         }
 984
 985         RadiusDamage_running = 1;
 986
 987         tfloordmg = autocvar_g_throughfloor_damage;
 988         tfloorforce = autocvar_g_throughfloor_force;
 989
 990         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 991         total_damage_to_creatures = 0;
 992
 993         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 994                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 995                 {
 996                         force = inflictor.velocity;
 997                         if(vlen(force) == 0)
 998                                 force = '0 0 -1';
 999                         else
1000                                 force = normalize(force);
1001                         if(forceintensity >= 0)
1002                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
1003                         else
1004                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
1005                 }
1006
1007         stat_damagedone = 0;
1008
1009         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
1010         while (targ)
1011         {
1012                 next = targ.chain;
1013                 if (targ != inflictor)
1014                         if (ignore != targ) if(targ.takedamage)
1015                         {
1016                                 vector nearest;
1017                                 vector diff;
1018                                 float power;
1019
1020                                 // LordHavoc: measure distance to nearest point on target (not origin)
1021                                 // (this guarentees 100% damage on a touch impact)
1022                                 nearest = targ.WarpZone_findradius_nearest;
1023                                 diff = targ.WarpZone_findradius_dist;
1024                                 // round up a little on the damage to ensure full damage on impacts
1025                                 // and turn the distance into a fraction of the radius
1026                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1027                                 //bprint(" ");
1028                                 //bprint(ftos(power));
1029                                 //if (targ == attacker)
1030                                 //      print(ftos(power), "\n");
1031                                 if (power > 0)
1032                                 {
1033                                         float finaldmg;
1034                                         if (power > 1)
1035                                                 power = 1;
1036                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1037                                         if (finaldmg > 0)
1038                                         {
1039                                                 float a;
1040                                                 float c;
1041                                                 vector hitloc;
1042                                                 vector myblastorigin;
1043                                                 vector center;
1044
1045                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1046
1047                                                 // if it's a player, use the view origin as reference
1048                                                 center = CENTER_OR_VIEWOFS(targ);
1049
1050                                                 force = normalize(center - myblastorigin);
1051                                                 force = force * (finaldmg / coredamage) * forceintensity;
1052                                                 hitloc = nearest;
1053
1054                                                 if(targ != directhitentity)
1055                                                 {
1056                                                         float hits;
1057                                                         float total;
1058                                                         float hitratio;
1059                                                         float mininv_f, mininv_d;
1060
1061                                                         // test line of sight to multiple positions on box,
1062                                                         // and do damage if any of them hit
1063                                                         hits = 0;
1064
1065                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1066                                                         // so for a given max stddev:
1067                                                         // n = (1 / (2 * max stddev of hitratio))^2
1068
1069                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1070                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1071
1072                                                         if(autocvar_g_throughfloor_debug)
1073                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1074
1075                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1076
1077                                                         if(autocvar_g_throughfloor_debug)
1078                                                                 print(sprintf(" steps=%f", total));
1079
1080                                                         if (targ.classname == "player")
1081                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1082                                                         else
1083                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1084
1085                                                         if(autocvar_g_throughfloor_debug)
1086                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1087
1088                                                         for(c = 0; c < total; ++c)
1089                                                         {
1090                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1091                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1092                                                                 if (trace_fraction == 1 || trace_ent == targ)
1093                                                                 {
1094                                                                         ++hits;
1095                                                                         if (hits > 1)
1096                                                                                 hitloc = hitloc + nearest;
1097                                                                         else
1098                                                                                 hitloc = nearest;
1099                                                                 }
1100                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1101                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1102                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1103                                                         }
1104
1105                                                         nearest = hitloc * (1 / max(1, hits));
1106                                                         hitratio = (hits / total);
1107                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1108                                                         finaldmg = finaldmg * a;
1109                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1110                                                         force = force * a;
1111
1112                                                         if(autocvar_g_throughfloor_debug)
1113                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1114                                                 }
1115
1116                                                 // laser force adjustments :P
1117                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1118                                                 {
1119                                                         if (targ == attacker)
1120                                                         {
1121                                                                 vector vel;
1122
1123                                                                 float force_zscale;
1124                                                                 float force_velocitybiasramp;
1125                                                                 float force_velocitybias;
1126
1127                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1128                                                                 if(deathtype & HITTYPE_SECONDARY)
1129                                                                 {
1130                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1131                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1132                                                                 }
1133                                                                 else
1134                                                                 {
1135                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1136                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1137                                                                 }
1138
1139                                                                 vel = targ.velocity;
1140                                                                 vel_z = 0;
1141                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1142                                                                 force =
1143                                                                         vlen(force)
1144                                                                         *
1145                                                                         normalize(normalize(force) + vel);
1146
1147                                                                 force_z *= force_zscale;
1148                                                         }
1149                                                         else
1150                                                         {
1151                                                                 if(deathtype & HITTYPE_SECONDARY)
1152                                                                 {
1153                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1154                                                                 }
1155                                                                 else
1156                                                                 {
1157                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1158                                                                 }
1159                                                         }
1160                                                 }
1161
1162                                                 //if (targ == attacker)
1163                                                 //{
1164                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1165                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1166                                                 //      print(" (", ftos(a), ")\n");
1167                                                 //}
1168                                                 if(finaldmg || vlen(force))
1169                                                 {
1170                                                         if(targ.iscreature)
1171                                                         {
1172                                                                 total_damage_to_creatures += finaldmg;
1173
1174                                                                 if(accuracy_isgooddamage(attacker, targ))
1175                                                                         stat_damagedone += finaldmg;
1176                                                         }
1177
1178                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1179                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1180                                                         else
1181                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1182                                                 }
1183                                         }
1184                                 }
1185                         }
1186                 targ = next;
1187         }
1188
1189         RadiusDamage_running = 0;
1190
1191         if(!DEATH_ISSPECIAL(deathtype))
1192                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1193
1194         return total_damage_to_creatures;
1195 }
1196
1197 .float fire_damagepersec;
1198 .float fire_endtime;
1199 .float fire_deathtype;
1200 .entity fire_owner;
1201 .float fire_hitsound;
1202 .entity fire_burner;
1203
1204 void fireburner_think();
1205
1206 float Fire_IsBurning(entity e)
1207 {
1208         return (time < e.fire_endtime);
1209 }
1210
1211 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1212 {
1213         float dps;
1214         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1215
1216         if(e.classname == "player")
1217         {
1218                 if(e.deadflag)
1219                         return -1;
1220         }
1221         else
1222         {
1223                 if(!e.fire_burner)
1224                 {
1225                         // print("adding a fire burner to ", e.classname, "\n");
1226                         e.fire_burner = spawn();
1227                         e.fire_burner.classname = "fireburner";
1228                         e.fire_burner.think = fireburner_think;
1229                         e.fire_burner.nextthink = time;
1230                         e.fire_burner.owner = e;
1231                 }
1232         }
1233
1234         t = max(t, 0.1);
1235         dps = d / t;
1236         if(Fire_IsBurning(e))
1237         {
1238                 mintime = e.fire_endtime - time;
1239                 maxtime = max(mintime, t);
1240
1241                 mindps = e.fire_damagepersec;
1242                 maxdps = max(mindps, dps);
1243
1244                 if(maxtime > mintime || maxdps > mindps)
1245                 {
1246                         // Constraints:
1247
1248                         // damage we have right now
1249                         mindamage = mindps * mintime;
1250
1251                         // damage we want to get
1252                         maxdamage = mindamage + d;
1253
1254                         // but we can't exceed maxtime * maxdps!
1255                         totaldamage = min(maxdamage, maxtime * maxdps);
1256
1257                         // LEMMA:
1258                         // Look at:
1259                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1260                         // We see:
1261                         // totaldamage <= maxtime * maxdps
1262                         // ==> totaldamage / maxdps <= maxtime.
1263                         // We also see:
1264                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1265                         //                     >= min(mintime, maxtime)
1266                         // ==> totaldamage / maxdps >= mintime.
1267
1268                         /*
1269                         // how long do we damage then?
1270                         // at least as long as before
1271                         // but, never exceed maxdps
1272                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1273                         */
1274
1275                         // alternate:
1276                         // at most as long as maximum allowed
1277                         // but, never below mindps
1278                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1279
1280                         // assuming t > mintime, dps > mindps:
1281                         // we get d = t * dps = maxtime * maxdps
1282                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1283                         // totaldamage / maxdps = maxtime
1284                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1285                         // FROM THIS:
1286                         // a) totaltime = max(mintime, maxtime) = maxtime
1287                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1288
1289                         // assuming t <= mintime:
1290                         // we get maxtime = mintime
1291                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1292                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1293
1294                         // assuming dps <= mindps:
1295                         // we get mindps = maxdps.
1296                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1297                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1298                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1299
1300                         e.fire_damagepersec = totaldamage / totaltime;
1301                         e.fire_endtime = time + totaltime;
1302                         if(totaldamage > 1.2 * mindamage)
1303                         {
1304                                 e.fire_deathtype = dt;
1305                                 if(e.fire_owner != o)
1306                                 {
1307                                         e.fire_owner = o;
1308                                         e.fire_hitsound = FALSE;
1309                                 }
1310                         }
1311                         if(accuracy_isgooddamage(o, e))
1312                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1313                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1314                 }
1315                 else
1316                         return 0;
1317         }
1318         else
1319         {
1320                 e.fire_damagepersec = dps;
1321                 e.fire_endtime = time + t;
1322                 e.fire_deathtype = dt;
1323                 e.fire_owner = o;
1324                 e.fire_hitsound = FALSE;
1325                 if(accuracy_isgooddamage(o, e))
1326                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1327                 return d;
1328         }
1329 }
1330
1331 void Fire_ApplyDamage(entity e)
1332 {
1333         float t, d, hi, ty;
1334         entity o;
1335
1336         if not(Fire_IsBurning(e))
1337                 return;
1338
1339         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1340         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1341                 o = e.fire_owner;
1342
1343         // water and slime stop fire
1344         if(e.waterlevel)
1345         if(e.watertype != CONTENT_LAVA)
1346                 e.fire_endtime = 0;
1347
1348         // ice stops fire
1349         if(e.freezetag_frozen)
1350                 e.fire_endtime = 0;
1351
1352         t = min(frametime, e.fire_endtime - time);
1353         d = e.fire_damagepersec * t;
1354
1355         hi = e.fire_owner.hitsound;
1356         ty = e.fire_owner.typehitsound;
1357         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1358         if(e.fire_hitsound && e.fire_owner)
1359         {
1360                 e.fire_owner.hitsound = hi;
1361                 e.fire_owner.typehitsound = ty;
1362         }
1363         e.fire_hitsound = TRUE;
1364
1365         if not(IS_INDEPENDENT_PLAYER(e))
1366         FOR_EACH_PLAYER(other) if(e != other)
1367         {
1368                 if(other.classname == "player")
1369                 if(other.deadflag == DEAD_NO)
1370                 if not(IS_INDEPENDENT_PLAYER(other))
1371                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1372                 {
1373                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1374                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1375                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1376                 }
1377         }
1378 }
1379
1380 void Fire_ApplyEffect(entity e)
1381 {
1382         if(Fire_IsBurning(e))
1383                 e.effects |= EF_FLAME;
1384         else
1385                 e.effects &~= EF_FLAME;
1386 }
1387
1388 void fireburner_think()
1389 {
1390         // for players, this is done in the regular loop
1391         if(wasfreed(self.owner))
1392         {
1393                 remove(self);
1394                 return;
1395         }
1396         Fire_ApplyEffect(self.owner);
1397         if(!Fire_IsBurning(self.owner))
1398         {
1399                 self.owner.fire_burner = world;
1400                 remove(self);
1401                 return;
1402         }
1403         Fire_ApplyDamage(self.owner);
1404         self.nextthink = time;
1405 }