qcsrc/server/g_damage.qc

   1 .float dmg;
   2 .float dmg_edge;
   3 .float dmg_force;
   4 .float dmg_radius;
   5
   6 float Damage_DamageInfo_SendEntity(entity to, float sf)
   7 {
   8         WriteByte(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
   9         WriteShort(MSG_ENTITY, self.projectiledeathtype);
  10         WriteCoord(MSG_ENTITY, floor(self.origin_x));
  11         WriteCoord(MSG_ENTITY, floor(self.origin_y));
  12         WriteCoord(MSG_ENTITY, floor(self.origin_z));
  13         WriteByte(MSG_ENTITY, bound(1, self.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, self.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, self.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, self.oldorigin_x);
  17         WriteByte(MSG_ENTITY, self.species);
  18         return TRUE;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, float deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = spawn();
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, FALSE, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 float checkrules_firstblood;
  46
  47 float yoda;
  48 float damage_goodhits;
  49 float damage_gooddamage;
  50
  51 .float dmg_team;
  52 .float teamkill_complain;
  53 .float teamkill_soundtime;
  54 .entity teamkill_soundsource;
  55 .entity pusher;
  56 .float istypefrag;
  57 .float taunt_soundtime;
  58
  59
  60 float IsDifferentTeam(entity a, entity b)
  61 {
  62         if(teamplay)
  63         {
  64                 if(a.team == b.team)
  65                         return 0;
  66         }
  67         else
  68         {
  69                 if(a == b)
  70                         return 0;
  71         }
  72         return 1;
  73 }
  74
  75 float IsFlying(entity a)
  76 {
  77         if(a.flags & FL_ONGROUND)
  78                 return 0;
  79         if(a.waterlevel >= WATERLEVEL_SWIMMING)
  80                 return 0;
  81         traceline(a.origin, a.origin - '0 0 48', MOVE_NORMAL, a);
  82         if(trace_fraction < 1)
  83                 return 0;
  84         return 1;
  85 }
  86
  87 void UpdateFrags(entity player, float f)
  88 {
  89         PlayerTeamScore_AddScore(player, f);
  90 }
  91
  92 // NOTE: f=0 means still count as a (positive) kill, but count no frags for it
  93 void W_SwitchWeapon_Force(entity e, float w);
  94 entity GiveFrags_randomweapons;
  95 void GiveFrags (entity attacker, entity targ, float f, float deathtype)
  96 {
  97         // TODO route through PlayerScores instead
  98         if(gameover) return;
  99
 100         if(f < 0)
 101         {
 102                 if(targ == attacker)
 103                 {
 104                         // suicide
 105                         PlayerScore_Add(attacker, SP_SUICIDES, 1);
 106                 }
 107                 else
 108                 {
 109                         // teamkill
 110                         PlayerScore_Add(attacker, SP_KILLS, -1); // or maybe add a teamkills field?
 111                 }
 112         }
 113         else
 114         {
 115                 // regular frag
 116                 PlayerScore_Add(attacker, SP_KILLS, 1);
 117                 if(targ.playerid)
 118                         PlayerStats_Event(attacker, sprintf("kills-%d", targ.playerid), 1);
 119         }
 120
 121         PlayerScore_Add(targ, SP_DEATHS, 1);
 122
 123         if(g_arena || g_ca)
 124                 if(autocvar_g_arena_roundbased)
 125                         return;
 126
 127         if(targ != attacker) // not for suicides
 128         if(g_weaponarena_random)
 129         {
 130                 // after a frag, exchange the current weapon (or the culprit, if detectable) by a new random weapon
 131                 float culprit;
 132                 culprit = DEATH_WEAPONOF(deathtype);
 133                 if(!culprit)
 134                         culprit = attacker.weapon;
 135                 else if(!WEPSET_CONTAINS_EW(attacker, culprit))
 136                         culprit = attacker.weapon;
 137
 138                 if(g_weaponarena_random_with_laser && culprit == WEP_LASER)
 139                 {
 140                         // no exchange
 141                 }
 142                 else
 143                 {
 144                         if(!GiveFrags_randomweapons)
 145                         {
 146                                 GiveFrags_randomweapons = spawn();
 147                                 GiveFrags_randomweapons.classname = "GiveFrags_randomweapons";
 148                         }
 149
 150                         if(inWarmupStage)
 151                                 WEPSET_COPY_EA(GiveFrags_randomweapons, warmup_start_weapons);
 152                         else
 153                                 WEPSET_COPY_EA(GiveFrags_randomweapons, start_weapons);
 154
 155                         // all others (including the culprit): remove
 156                         WEPSET_ANDNOT_EE(GiveFrags_randomweapons, attacker);
 157                         WEPSET_ANDNOT_EW(GiveFrags_randomweapons, culprit);
 158
 159                         // among the remaining ones, choose one by random
 160                         W_RandomWeapons(GiveFrags_randomweapons, 1);
 161
 162                         if(!WEPSET_EMPTY_E(GiveFrags_randomweapons))
 163                         {
 164                                 WEPSET_OR_EE(attacker, GiveFrags_randomweapons);
 165                                 WEPSET_ANDNOT_EW(attacker, culprit);
 166                         }
 167                 }
 168
 169                 // after a frag, choose another random weapon set
 170                 if not(WEPSET_CONTAINS_EW(attacker, attacker.weapon))
 171                         W_SwitchWeapon_Force(attacker, w_getbestweapon(attacker));
 172         }
 173
 174         // FIXME fix the mess this is (we have REAL points now!)
 175         entity oldself;
 176         oldself = self;
 177         self = attacker;
 178         frag_attacker = attacker;
 179         frag_target = targ;
 180         frag_score = f;
 181         if(MUTATOR_CALLHOOK(GiveFragsForKill))
 182         {
 183                 f = frag_score;
 184                 self = oldself;
 185         }
 186         else
 187         {
 188                 self = oldself;
 189                 if(g_runematch)
 190                 {
 191                         f = RunematchHandleFrags(attacker, targ, f);
 192                 }
 193                 else if(g_lms)
 194                 {
 195                         // remove a life
 196                         float tl;
 197                         tl = PlayerScore_Add(targ, SP_LMS_LIVES, -1);
 198                         if(tl < lms_lowest_lives)
 199                                 lms_lowest_lives = tl;
 200                         if(tl <= 0)
 201                         {
 202                                 if(!lms_next_place)
 203                                         lms_next_place = player_count;
 204                                 else
 205                                         lms_next_place = min(lms_next_place, player_count);
 206                                 PlayerScore_Add(targ, SP_LMS_RANK, lms_next_place); // won't ever spawn again
 207                                 --lms_next_place;
 208                         }
 209                         f = 0;
 210                 }
 211         }
 212
 213         attacker.totalfrags += f;
 214
 215         if(f)
 216                 UpdateFrags(attacker, f);
 217 }
 218
 219 string AppendItemcodes(string s, entity player)
 220 {
 221         float w;
 222         w = player.weapon;
 223         //if(w == 0)
 224         //      w = player.switchweapon;
 225         if(w == 0)
 226                 w = player.cnt; // previous weapon!
 227         s = strcat(s, ftos(w));
 228         if(time < player.strength_finished)
 229                 s = strcat(s, "S");
 230         if(time < player.invincible_finished)
 231                 s = strcat(s, "I");
 232         if(player.flagcarried != world)
 233                 s = strcat(s, "F");
 234         if(player.BUTTON_CHAT)
 235                 s = strcat(s, "T");
 236         if(player.kh_next)
 237                 s = strcat(s, "K");
 238         if(player.runes)
 239                 s = strcat(s, "|", ftos(player.runes));
 240         return s;
 241 }
 242
 243 void LogDeath(string mode, float deathtype, entity killer, entity killed)
 244 {
 245         string s;
 246         if(!autocvar_sv_eventlog)
 247                 return;
 248         s = strcat(":kill:", mode);
 249         s = strcat(s, ":", ftos(killer.playerid));
 250         s = strcat(s, ":", ftos(killed.playerid));
 251         s = strcat(s, ":type=", Deathtype_Name(deathtype));
 252         s = strcat(s, ":items=");
 253         s = AppendItemcodes(s, killer);
 254         if(killed != killer)
 255         {
 256                 s = strcat(s, ":victimitems=");
 257                 s = AppendItemcodes(s, killed);
 258         }
 259         GameLogEcho(s);
 260 }
 261
 262 #define INFO_NO_MSG 0
 263
 264 void Obituary_SpecialDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2, float f3)
 265 {
 266         float handled = 0, hits = 0;
 267         if(DEATH_ISSPECIAL(deathtype))
 268         {
 269                 #define DEATHTYPE(name,msg_death,msg_death_by,position) \
 270                         { if(deathtype == max(0, name)) \
 271                         { \
 272                                 #if msg_death != NO_MSG \
 273                                         if not(murder) \
 274                                         { \
 275                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 276                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death, s1, s2, s3, "", f1, f2, f3, 0); \
 277                                                 ++handled; \
 278                                         } \
 279                                 #endif \
 280                                 #if msg_death_by != NO_MSG \
 281                                         if(murder) \
 282                                         { \
 283                                                 Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_DEATH, msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 284                                                 Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, INFO_##msg_death_by, s1, s2, s3, "", f1, f2, f3, 0); \
 285                                                 ++handled; \
 286                                         } \
 287                                 #endif \
 288                                 ++hits; \
 289                         } }
 290
 291                 DEATHTYPES
 292                 #undef DEATHTYPE
 293
 294                 if not(hits)
 295                 {
 296                         backtrace("Obituary_SpecialDeath(): Unhandled deathtype- Please notify Samual!\n");
 297                 }
 298                 if not(handled)
 299                 {
 300                         dprint(sprintf("Obituary_SpecialDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification!\n", Deathtype_Name(deathtype), deathtype));
 301                         return;
 302                 }
 303         }
 304 }
 305
 306 float w_deathtype;
 307 float Obituary_WeaponDeath(entity notif_target, float murder, float deathtype, string s1, string s2, string s3, float f1, float f2)
 308 {
 309         float death_weapon = DEATH_WEAPONOF(deathtype);
 310
 311         if(death_weapon)
 312         {
 313                 w_deathtype = deathtype;
 314                 float death_message = weapon_action(death_weapon, ((murder) ? WR_KILLMESSAGE : WR_SUICIDEMESSAGE));
 315                 w_deathtype = FALSE;
 316
 317                 if(death_message)
 318                 {
 319                         Send_Notification_WOVA(NOTIF_ONE, notif_target, MSG_WEAPON, death_message, s1, s2, s3, "", f1, f2, 0, 0);
 320                         Send_Notification_WOVA(NOTIF_ANY_EXCEPT, notif_target, MSG_INFO, msg_weapon_notifs[death_message - 1].nent_msginfo.nent_id, s1, s2, s3, "", f1, f2, 0, 0);
 321                         //print(Get_Field_Value(F_INFVAL, MSG_WEAPON, death_message), "\n");
 322                 }
 323                 else { dprint(sprintf("Obituary_WeaponDeath(): ^1Deathtype ^7(%s-%d)^1 has no notification for weapon %d!\n", Deathtype_Name(deathtype), deathtype, death_weapon)); }
 324
 325                 return TRUE;
 326         }
 327         return FALSE;
 328 }
 329
 330 void Obituary(entity attacker, entity inflictor, entity targ, float deathtype)
 331 {
 332         // Sanity check
 333         if not(targ.classname == STR_PLAYER) { backtrace("Obituary called on non-player?!\n"); return; }
 334
 335         // Declarations
 336         float notif_firstblood = FALSE;
 337         float kill_count_to_attacker, kill_count_to_target;
 338
 339         // Set final information for the death
 340         targ.death_origin = targ.origin;
 341         if(targ != attacker) { targ.killer_origin = attacker.origin; }
 342         string deathlocation = NearestLocation(targ.death_origin);
 343
 344         #ifdef NOTIFICATIONS_DEBUG
 345         dprint(
 346                 sprintf("Obituary(%s, %s, %s, %s = %d);\n",
 347                         attacker.netname,
 348                         inflictor.netname,
 349                         targ.netname,
 350                         Deathtype_Name(deathtype),
 351                         deathtype
 352                 )
 353         );
 354         #endif
 355
 356         // =======
 357         // SUICIDE
 358         // =======
 359         if(targ == attacker)
 360         {
 361                 if(DEATH_ISSPECIAL(deathtype))
 362                 {
 363                         if(deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 364                         {
 365                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.team, 0, 0);
 366                         }
 367                         else
 368                         {
 369                                 switch(deathtype)
 370                                 {
 371                                         case DEATH_MIRRORDAMAGE:
 372                                         {
 373                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 374                                                 break;
 375                                         }
 376
 377                                         default:
 378                                         {
 379                                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 380                                                 break;
 381                                         }
 382                                 }
 383                                 LogDeath("suicide", deathtype, targ, targ);
 384                                 GiveFrags(attacker, targ, -1, deathtype);
 385                         }
 386                 }
 387                 else if not(Obituary_WeaponDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0))
 388                 {
 389                         backtrace("SUICIDE: what the hell happened here?\n");
 390                 }
 391         }
 392
 393         // ======
 394         // MURDER
 395         // ======
 396         else if(attacker.classname == "player")
 397         {
 398                 if(!IsDifferentTeam(attacker, targ))
 399                 {
 400                         LogDeath("tk", deathtype, attacker, targ);
 401                         GiveFrags(attacker, targ, -1, deathtype);
 402
 403                         attacker.killcount = 0;
 404
 405                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAG, targ.netname);
 406                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_TEAMKILL_FRAGGED, attacker.netname);
 407                         Send_Notification(NOTIF_ANY, world, MSG_INFO, APP_TEAM_NUM_4(targ.team, INFO_DEATH_TEAMKILL_), targ.netname, attacker.netname, targ.killcount);
 408
 409                         // In this case, the death message will ALWAYS be "foo was betrayed by bar"
 410                         // No need for specific death/weapon messages...
 411                 }
 412                 else
 413                 {
 414                         LogDeath("frag", deathtype, attacker, targ);
 415                         GiveFrags(attacker, targ, 1, deathtype);
 416
 417                         attacker.taunt_soundtime = time + 1;
 418                         attacker.killcount = attacker.killcount + 1;
 419
 420                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 421                                 case counta: \
 422                                 { \
 423                                         AnnounceTo(attacker, strcat(#countb, "kills")); \
 424                                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_KILL_SPREE_##counta, 1); \
 425                                         break; \
 426                                 }
 427                         switch(attacker.killcount)
 428                         {
 429                                 KILL_SPREE_LIST
 430                                 default: break;
 431                         }
 432                         #undef SPREE_ITEM
 433
 434                         if(!checkrules_firstblood)
 435                         {
 436                                 checkrules_firstblood = TRUE;
 437                                 notif_firstblood = TRUE; // modify the current messages so that they too show firstblood information
 438                                 PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_FIRSTBLOOD, 1);
 439                                 PlayerStats_Event(targ, PLAYERSTATS_ACHIEVEMENT_FIRSTVICTIM, 1);
 440
 441                                 // tell spree_inf and spree_cen that this is a first-blood and first-victim event
 442                                 kill_count_to_attacker = -1;
 443                                 kill_count_to_target = -2;
 444                         }
 445                         else
 446                         {
 447                                 kill_count_to_attacker = attacker.killcount;
 448                                 kill_count_to_target = 0;
 449                         }
 450
 451                         if(targ.istypefrag)
 452                         {
 453                                 if(attacker.FRAG_VERBOSE)
 454                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 455                                 else
 456                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAG, targ.netname, kill_count_to_attacker);
 457
 458                                 if(targ.FRAG_VERBOSE)
 459                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 460                                 else
 461                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_TYPEFRAGGED, attacker.netname, kill_count_to_target);
 462                         }
 463                         else
 464                         {
 465                                 if(attacker.FRAG_VERBOSE)
 466                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG_VERBOSE, targ.netname, kill_count_to_attacker, (IS_BOT_CLIENT(targ) ? NO_MSG : targ.ping));
 467                                 else
 468                                         Send_Notification(NOTIF_ONE, attacker, MSG_CENTER, CENTER_DEATH_MURDER_FRAG, targ.netname, kill_count_to_attacker);
 469
 470                                 if(targ.FRAG_VERBOSE)
 471                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED_VERBOSE, attacker.netname, kill_count_to_target, attacker.health, attacker.armorvalue, (IS_BOT_CLIENT(attacker) ? NO_MSG : attacker.ping));
 472                                 else
 473                                         Send_Notification(NOTIF_ONE, targ, MSG_CENTER, CENTER_DEATH_MURDER_FRAGGED, attacker.netname, kill_count_to_target);
 474                         }
 475
 476                         if not(Obituary_WeaponDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker))
 477                                 Obituary_SpecialDeath(targ, TRUE, deathtype, targ.netname, attacker.netname, deathlocation, targ.killcount, kill_count_to_attacker, 0);
 478                 }
 479         }
 480
 481         // =============
 482         // ACCIDENT/TRAP
 483         // =============
 484         else
 485         {
 486                 switch(deathtype)
 487                 {
 488                         // For now, we're just forcing HURTTRIGGER to behave as "DEATH_VOID" and giving it no special options...
 489                         // Later on you will only be able to make custom messages using DEATH_CUSTOM,
 490                         // and there will be a REAL DEATH_VOID implementation which mappers will use.
 491                         /*case DEATH_HURTTRIGGER:
 492                         {
 493                                 s1 = targ.netname;
 494                                 s2 = inflictor.message;
 495                                 if(strstrofs(s2, "%", 0) < 0) { s2 = strcat("%s ", s2); }
 496                                 break;
 497                         }*/
 498
 499                         case DEATH_CUSTOM:
 500                         {
 501                                 Obituary_SpecialDeath(targ, FALSE, deathtype,
 502                                         targ.netname,
 503                                         ((strstrofs(deathmessage, "%", 0) < 0) ? strcat("%s ", deathmessage) : deathmessage),
 504                                         deathlocation,
 505                                         targ.killcount,
 506                                         0,
 507                                         0);
 508                                 break;
 509                         }
 510
 511                         default:
 512                         {
 513                                 Obituary_SpecialDeath(targ, FALSE, deathtype, targ.netname, deathlocation, "", targ.killcount, 0, 0);
 514                                 break;
 515                         }
 516                 }
 517
 518                 LogDeath("accident", deathtype, targ, targ);
 519                 GiveFrags(targ, targ, -1, deathtype);
 520
 521                 if(PlayerScore_Add(targ, SP_SCORE, 0) == -5)
 522                 {
 523                         AnnounceTo(targ, "botlike");
 524                         PlayerStats_Event(attacker, PLAYERSTATS_ACHIEVEMENT_BOTLIKE, 1);
 525                 }
 526         }
 527
 528         // reset target kill count
 529         if(targ.killcount) { targ.killcount = 0; }
 530 }
 531
 532 // these are updated by each Damage call for use in button triggering and such
 533 entity damage_targ;
 534 entity damage_inflictor;
 535 entity damage_attacker;
 536
 537 void Damage (entity targ, entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 538 {
 539         float mirrordamage;
 540         float mirrorforce;
 541         float complainteamdamage = 0;
 542         entity attacker_save;
 543         mirrordamage = 0;
 544         mirrorforce = 0;
 545
 546         if (gameover || targ.killcount == -666)
 547                 return;
 548
 549         entity oldself;
 550         oldself = self;
 551         self = targ;
 552         damage_targ = targ;
 553         damage_inflictor = inflictor;
 554         damage_attacker = attacker;
 555                 attacker_save = attacker;
 556
 557         if(targ.classname == "player")
 558                 if(targ.hook)
 559                         if(targ.hook.aiment)
 560                                 if(targ.hook.aiment == attacker)
 561                                         RemoveGrapplingHook(targ); // STOP THAT, you parasite!
 562
 563         // special rule: gravity bomb does not hit team mates (other than for disconnecting the hook)
 564         if(DEATH_ISWEAPON(deathtype, WEP_HOOK) || DEATH_ISWEAPON(deathtype, WEP_TUBA))
 565         {
 566                 if(targ.classname == "player")
 567                         if not(IsDifferentTeam(targ, attacker))
 568                         {
 569                                 self = oldself;
 570                                 return;
 571                         }
 572         }
 573
 574         if(deathtype == DEATH_KILL || deathtype == DEATH_TEAMCHANGE || deathtype == DEATH_AUTOTEAMCHANGE)
 575         {
 576                 // These are ALWAYS lethal
 577                 // No damage modification here
 578                 // Instead, prepare the victim for his death...
 579                 targ.armorvalue = 0;
 580                 targ.spawnshieldtime = 0;
 581                 targ.health = 0.9; // this is < 1
 582                 targ.flags -= targ.flags & FL_GODMODE;
 583                 damage = 100000;
 584         }
 585         else if(deathtype == DEATH_MIRRORDAMAGE || deathtype == DEATH_NOAMMO)
 586         {
 587                 // no processing
 588         }
 589         else
 590         {
 591                 /*
 592                 skill based bot damage? gtfo. (tZork)
 593                 if (targ.classname == "player")
 594                 if (attacker.classname == "player")
 595                 if (!targ.isbot)
 596                 if (attacker.isbot)
 597                         damage = damage * bound(0.1, (skill + 5) * 0.1, 1);
 598         */
 599
 600                 // nullify damage if teamplay is on
 601                 if(deathtype != DEATH_TELEFRAG)
 602                 if(attacker.classname == "player")
 603                 {
 604                         if(targ.classname == "player" && targ != attacker && (IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(targ)))
 605                         {
 606                                 damage = 0;
 607                                 force = '0 0 0';
 608                         }
 609                         else if(!IsDifferentTeam(attacker, targ))
 610                         {
 611                                 if(autocvar_teamplay_mode == 1)
 612                                         damage = 0;
 613                                 else if(attacker != targ)
 614                                 {
 615                                         if(autocvar_teamplay_mode == 3)
 616                                                 damage = 0;
 617                                         else if(autocvar_teamplay_mode == 4)
 618                                         {
 619                                                 if(targ.classname == "player" && targ.deadflag == DEAD_NO)
 620                                                 {
 621                                                         attacker.dmg_team = attacker.dmg_team + damage;
 622                                                         complainteamdamage = attacker.dmg_team - autocvar_g_teamdamage_threshold;
 623                                                         if(complainteamdamage > 0 && !g_ca) // FIXME why is g_ca ruled out here? Why not just g_mirrordamage 0 on CA servers?
 624                                                                 mirrordamage = autocvar_g_mirrordamage * complainteamdamage;
 625                                                         mirrorforce = autocvar_g_mirrordamage * vlen(force);
 626                                                         if(g_minstagib)
 627                                                         {
 628                                                                 if(autocvar_g_friendlyfire == 0)
 629                                                                         damage = 0;
 630                                                         }
 631                                                         else if(g_ca)
 632                                                                 damage = 0;
 633                                                         else
 634                                                                 damage = autocvar_g_friendlyfire * damage;
 635                                                         // mirrordamage will be used LATER
 636
 637                                                         if(autocvar_g_mirrordamage_virtual)
 638                                                         {
 639                                                                 vector v  = healtharmor_applydamage(attacker.armorvalue, autocvar_g_balance_armor_blockpercent, mirrordamage);
 640                                                                 attacker.dmg_take += v_x;
 641                                                                 attacker.dmg_save += v_y;
 642                                                                 attacker.dmg_inflictor = inflictor;
 643                                                                 mirrordamage = v_z; // = 0, to make fteqcc stfu
 644                                                                 mirrorforce = 0;
 645                                                         }
 646
 647                                                         if(autocvar_g_friendlyfire_virtual)
 648                                                         {
 649                                                                 vector v = healtharmor_applydamage(targ.armorvalue, autocvar_g_balance_armor_blockpercent, damage);
 650                                                                 targ.dmg_take += v_x;
 651                                                                 targ.dmg_save += v_y;
 652                                                                 targ.dmg_inflictor = inflictor;
 653                                                                 damage = 0;
 654                                                                 if(!autocvar_g_friendlyfire_virtual_force)
 655                                                                         force = '0 0 0';
 656                                                         }
 657                                                 }
 658                                                 else
 659                                                         damage = 0;
 660                                         }
 661                                 }
 662                         }
 663                 }
 664
 665                 if(targ.classname == "player")
 666                 if(attacker.classname == "player")
 667                 if(attacker != targ)
 668                 {
 669                         targ.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 670                         attacker.lms_traveled_distance = autocvar_g_lms_campcheck_distance;
 671                 }
 672
 673                 if(targ.classname == "player")
 674                 if (g_minstagib)
 675                 {
 676                         if ((deathtype == DEATH_FALL)  ||
 677                                 (deathtype == DEATH_DROWN) ||
 678                                 (deathtype == DEATH_SLIME) ||
 679                                 (deathtype == DEATH_LAVA)  ||
 680                                 (!DEATH_ISWEAPON(deathtype, WEP_LASER) && damage > 0 && damage < 100))
 681                         {
 682                                 self = oldself;
 683                                 return;
 684                         }
 685                         if(damage > 0)
 686                             damage = 10000;
 687                         if (targ.armorvalue && (deathtype == WEP_MINSTANEX) && damage)
 688                         {
 689                                 targ.armorvalue -= 1;
 690                                 centerprint(targ, strcat("^3Remaining extra lives: ",ftos(targ.armorvalue)));
 691                                 damage = 0;
 692                                 targ.hitsound += 1;
 693                                 attacker.hitsound += 1; // TODO change this to a future specific hitsound for armor hit
 694                         }
 695                         if (DEATH_ISWEAPON(deathtype, WEP_LASER))
 696                         {
 697                                 damage = 0;
 698                                 mirrordamage = 0;
 699                                 complainteamdamage = 0;
 700                                 if (targ != attacker)
 701                                 {
 702                                         if ((targ.health >= 1) && (targ.classname == "player"))
 703                                                 centerprint(attacker, "Secondary fire inflicts no damage!");
 704                                         force = '0 0 0';
 705                                         // keep mirrorforce
 706                                         attacker = targ;
 707                                 }
 708                         }
 709                 }
 710
 711                 if not(DEATH_ISSPECIAL(deathtype))
 712                 {
 713                         damage *= g_weapondamagefactor;
 714                         mirrordamage *= g_weapondamagefactor;
 715                         complainteamdamage *= g_weapondamagefactor;
 716                         force = force * g_weaponforcefactor;
 717                         mirrorforce *= g_weaponforcefactor;
 718                 }
 719
 720                 // should this be changed at all? If so, in what way?
 721                 frag_attacker = attacker;
 722                 frag_target = targ;
 723                 frag_damage = damage;
 724                 frag_force = force;
 725         frag_deathtype = deathtype;
 726                 MUTATOR_CALLHOOK(PlayerDamage_Calculate);
 727                 damage = frag_damage;
 728                 force = frag_force;
 729
 730                 // apply strength multiplier
 731                 if ((attacker.items & IT_STRENGTH) && !g_minstagib)
 732                 {
 733                         if(targ == attacker)
 734                         {
 735                                 damage = damage * autocvar_g_balance_powerup_strength_selfdamage;
 736                                 force = force * autocvar_g_balance_powerup_strength_selfforce;
 737                         }
 738                         else
 739                         {
 740                                 damage = damage * autocvar_g_balance_powerup_strength_damage;
 741                                 force = force * autocvar_g_balance_powerup_strength_force;
 742                         }
 743                 }
 744
 745                 // apply invincibility multiplier
 746                 if (targ.items & IT_INVINCIBLE && !g_minstagib)
 747                         damage = damage * autocvar_g_balance_powerup_invincible_takedamage;
 748
 749                 if (targ == attacker)
 750                 {
 751                         if(g_ca || (g_cts && !autocvar_g_cts_selfdamage))
 752                                 damage = 0;
 753                         else
 754                                 damage = damage * autocvar_g_balance_selfdamagepercent; // Partial damage if the attacker hits himself
 755                 }
 756
 757                 if(g_runematch)
 758                 {
 759                         // apply strength rune
 760                         if (attacker.runes & RUNE_STRENGTH)
 761                         {
 762                                 if(attacker.runes & CURSE_WEAK) // have both curse & rune
 763                                 {
 764                                         damage = damage * autocvar_g_balance_rune_strength_combo_damage;
 765                                         force = force * autocvar_g_balance_rune_strength_combo_force;
 766                                 }
 767                                 else
 768                                 {
 769                                         damage = damage * autocvar_g_balance_rune_strength_damage;
 770                                         force = force * autocvar_g_balance_rune_strength_force;
 771                                 }
 772                         }
 773                         else if (attacker.runes & CURSE_WEAK)
 774                         {
 775                                 damage = damage * autocvar_g_balance_curse_weak_damage;
 776                                 force = force * autocvar_g_balance_curse_weak_force;
 777                         }
 778
 779                         // apply defense rune
 780                         if (targ.runes & RUNE_DEFENSE)
 781                         {
 782                                 if (targ.runes & CURSE_VULNER) // have both curse & rune
 783                                         damage = damage * autocvar_g_balance_rune_defense_combo_takedamage;
 784                                 else
 785                                         damage = damage * autocvar_g_balance_rune_defense_takedamage;
 786                         }
 787                         else if (targ.runes & CURSE_VULNER)
 788                                 damage = damage * autocvar_g_balance_curse_vulner_takedamage;
 789                 }
 790
 791                 // count the damage
 792                 if(attacker)
 793                 if(!targ.deadflag)
 794                 if(targ.takedamage == DAMAGE_AIM)
 795                 if(targ != attacker)
 796                 {
 797                         entity victim;
 798                         if((targ.vehicle_flags & VHF_ISVEHICLE) && targ.owner)
 799                                 victim = targ.owner;
 800                         else
 801                                 victim = targ;
 802
 803                         if(victim.classname == "player" || victim.turrcaps_flags & TFL_TURRCAPS_ISTURRET)
 804                         {
 805                                 if(IsDifferentTeam(victim, attacker))
 806                                 {
 807                                         if(damage > 0)
 808                                         {
 809                                                 if(deathtype != DEATH_FIRE)
 810                                                 {
 811                                                         if(victim.BUTTON_CHAT)
 812                                                                 attacker.typehitsound += 1;
 813                                                         else
 814                                                                 attacker.hitsound += 1;
 815                                                 }
 816
 817                                                 damage_goodhits += 1;
 818                                                 damage_gooddamage += damage;
 819
 820                                                 if not(DEATH_ISSPECIAL(deathtype))
 821                                                 {
 822                                                         if(targ.classname == "player") // don't do this for vehicles
 823                                                         if(!g_minstagib)
 824                                                         if(IsFlying(victim))
 825                                                                 yoda = 1;
 826
 827                                                         if(g_minstagib)
 828                                                         if(victim.items & IT_STRENGTH)
 829                                                                 yoda = 1;
 830                                                 }
 831                                         }
 832                                 }
 833                                 else
 834                                 {
 835                                         if(deathtype != DEATH_FIRE)
 836                                         {
 837                                                 attacker.typehitsound += 1;
 838                                         }
 839                                         if(complainteamdamage > 0)
 840                                                 if(time > attacker.teamkill_complain)
 841                                                 {
 842                                                         attacker.teamkill_complain = time + 5;
 843                                                         attacker.teamkill_soundtime = time + 0.4;
 844                                                         attacker.teamkill_soundsource = targ;
 845                                                 }
 846                                 }
 847                         }
 848                 }
 849         }
 850
 851         // apply push
 852         if (self.damageforcescale)
 853         if (vlen(force))
 854         if (self.classname != "player" || time >= self.spawnshieldtime || g_midair)
 855         {
 856                 vector farce = damage_explosion_calcpush(self.damageforcescale * force, self.velocity, autocvar_g_balance_damagepush_speedfactor);
 857                 if(self.movetype == MOVETYPE_PHYSICS)
 858                 {
 859                         entity farcent;
 860                         farcent = spawn();
 861                         farcent.classname = "farce";
 862                         farcent.enemy = self;
 863                         farcent.movedir = farce * 10;
 864                         if(self.mass)
 865                                 farcent.movedir = farcent.movedir * self.mass;
 866                         farcent.origin = hitloc;
 867                         farcent.forcetype = FORCETYPE_FORCEATPOS;
 868                         farcent.nextthink = time + 0.1;
 869                         farcent.think = SUB_Remove;
 870                 }
 871                 else
 872                         self.velocity = self.velocity + farce;
 873                 self.flags &~= FL_ONGROUND;
 874                 UpdateCSQCProjectile(self);
 875         }
 876         // apply damage
 877         if (damage != 0 || (self.damageforcescale && vlen(force)))
 878         if (self.event_damage)
 879                 self.event_damage (inflictor, attacker, damage, deathtype, hitloc, force);
 880         self = oldself;
 881
 882         if(targ.classname == "player" && attacker.classname == "player" && attacker != targ && attacker.health > 2)
 883         {
 884                 if(g_runematch)
 885                 {
 886                         if (attacker.runes & RUNE_VAMPIRE)
 887                         {
 888                         // apply vampire rune
 889                                 if (attacker.runes & CURSE_EMPATHY) // have the curse too
 890                                 {
 891                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb;
 892                                         attacker.health = bound(
 893                                                 autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 40
 894                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_combo_absorb,
 895                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 896                                 }
 897                                 else
 898                                 {
 899                                         //attacker.health = attacker.health + damage * autocvar_g_balance_rune_vampire_absorb;
 900                                         attacker.health = bound(
 901                                                 attacker.health,        // LA: was 3, but changed so that you can't lose health
 902                                                                                         // empathy won't let you gain health in the same way...
 903                                                 attacker.health + damage * autocvar_g_balance_rune_vampire_absorb,
 904                                                 autocvar_g_balance_rune_vampire_maxhealth);     // LA: was 1000, now 500
 905                                         }
 906                         }
 907                         // apply empathy curse
 908                         else if (attacker.runes & CURSE_EMPATHY)
 909                         {
 910                                 attacker.health = bound(
 911                                         autocvar_g_balance_curse_empathy_minhealth, // LA: was 3, now 20
 912                                         attacker.health + damage * autocvar_g_balance_curse_empathy_takedamage,
 913                                         attacker.health);
 914                         }
 915                 }
 916         }
 917
 918         // apply mirror damage if any
 919         if(mirrordamage > 0 || mirrorforce > 0)
 920         {
 921                 attacker = attacker_save;
 922                 if(g_minstagib)
 923                 if(mirrordamage > 0)
 924                 {
 925                         // just lose extra LIVES, don't kill the player for mirror damage
 926                         if(attacker.armorvalue > 0)
 927                         {
 928                                 attacker.armorvalue = attacker.armorvalue - 1;
 929                                 centerprint(attacker, strcat("^3Remaining extra lives: ",ftos(attacker.armorvalue)));
 930                                 attacker.hitsound += 1;
 931                         }
 932                         mirrordamage = 0;
 933                 }
 934
 935                 force = normalize(attacker.origin + attacker.view_ofs - hitloc) * mirrorforce;
 936                 Damage(attacker, inflictor, attacker, mirrordamage, DEATH_MIRRORDAMAGE, attacker.origin, force);
 937         }
 938 }
 939
 940 float RadiusDamage_running;
 941 float RadiusDamage (entity inflictor, entity attacker, float coredamage, float edgedamage, float rad, entity ignore, float forceintensity, float deathtype, entity directhitentity)
 942         // Returns total damage applies to creatures
 943 {
 944         entity  targ;
 945         vector  blastorigin;
 946         vector  force;
 947         float   total_damage_to_creatures;
 948         entity  next;
 949         float   tfloordmg;
 950         float   tfloorforce;
 951
 952         float stat_damagedone;
 953
 954         if(RadiusDamage_running)
 955         {
 956                 backtrace("RadiusDamage called recursively! Expect stuff to go HORRIBLY wrong.");
 957                 return 0;
 958         }
 959
 960         RadiusDamage_running = 1;
 961
 962         tfloordmg = autocvar_g_throughfloor_damage;
 963         tfloorforce = autocvar_g_throughfloor_force;
 964
 965         blastorigin = (inflictor.origin + (inflictor.mins + inflictor.maxs) * 0.5);
 966         total_damage_to_creatures = 0;
 967
 968         if(deathtype != (WEP_HOOK | HITTYPE_SECONDARY | HITTYPE_BOUNCE)) // only send gravity bomb damage once
 969                 if(DEATH_WEAPONOF(deathtype) != WEP_TUBA) // do not send tuba damage (bandwidth hog)
 970                 {
 971                         force = inflictor.velocity;
 972                         if(vlen(force) == 0)
 973                                 force = '0 0 -1';
 974                         else
 975                                 force = normalize(force);
 976                         if(forceintensity >= 0)
 977                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, rad, forceintensity * force, deathtype, 0, attacker);
 978                         else
 979                                 Damage_DamageInfo(blastorigin, coredamage, edgedamage, -rad, (-forceintensity) * force, deathtype, 0, attacker);
 980                 }
 981
 982         stat_damagedone = 0;
 983
 984         targ = WarpZone_FindRadius (blastorigin, rad + MAX_DAMAGEEXTRARADIUS, FALSE);
 985         while (targ)
 986         {
 987                 next = targ.chain;
 988                 if (targ != inflictor)
 989                         if (ignore != targ) if(targ.takedamage)
 990                         {
 991                                 vector nearest;
 992                                 vector diff;
 993                                 float power;
 994
 995                                 // LordHavoc: measure distance to nearest point on target (not origin)
 996                                 // (this guarentees 100% damage on a touch impact)
 997                                 nearest = targ.WarpZone_findradius_nearest;
 998                                 diff = targ.WarpZone_findradius_dist;
 999                                 // round up a little on the damage to ensure full damage on impacts
1000                                 // and turn the distance into a fraction of the radius
1001                                 power = 1 - ((vlen (diff) - bound(MIN_DAMAGEEXTRARADIUS, targ.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
1002                                 //bprint(" ");
1003                                 //bprint(ftos(power));
1004                                 //if (targ == attacker)
1005                                 //      print(ftos(power), "\n");
1006                                 if (power > 0)
1007                                 {
1008                                         float finaldmg;
1009                                         if (power > 1)
1010                                                 power = 1;
1011                                         finaldmg = coredamage * power + edgedamage * (1 - power);
1012                                         if (finaldmg > 0)
1013                                         {
1014                                                 float a;
1015                                                 float c;
1016                                                 vector hitloc;
1017                                                 vector myblastorigin;
1018                                                 vector center;
1019
1020                                                 myblastorigin = WarpZone_TransformOrigin(targ, blastorigin);
1021
1022                                                 // if it's a player, use the view origin as reference
1023                                                 center = CENTER_OR_VIEWOFS(targ);
1024
1025                                                 force = normalize(center - myblastorigin);
1026                                                 force = force * (finaldmg / coredamage) * forceintensity;
1027                                                 hitloc = nearest;
1028
1029                                                 if(targ != directhitentity)
1030                                                 {
1031                                                         float hits;
1032                                                         float total;
1033                                                         float hitratio;
1034                                                         float mininv_f, mininv_d;
1035
1036                                                         // test line of sight to multiple positions on box,
1037                                                         // and do damage if any of them hit
1038                                                         hits = 0;
1039
1040                                                         // we know: max stddev of hitratio = 1 / (2 * sqrt(n))
1041                                                         // so for a given max stddev:
1042                                                         // n = (1 / (2 * max stddev of hitratio))^2
1043
1044                                                         mininv_d = (finaldmg * (1-tfloordmg)) / autocvar_g_throughfloor_damage_max_stddev;
1045                                                         mininv_f = (vlen(force) * (1-tfloorforce)) / autocvar_g_throughfloor_force_max_stddev;
1046
1047                                                         if(autocvar_g_throughfloor_debug)
1048                                                                 print(sprintf("THROUGHFLOOR: D=%f F=%f max(dD)=1/%f max(dF)=1/%f", finaldmg, vlen(force), mininv_d, mininv_f));
1049
1050                                                         total = 0.25 * pow(max(mininv_f, mininv_d), 2);
1051
1052                                                         if(autocvar_g_throughfloor_debug)
1053                                                                 print(sprintf(" steps=%f", total));
1054
1055                                                         if (targ.classname == "player")
1056                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_player, total, autocvar_g_throughfloor_max_steps_player));
1057                                                         else
1058                                                                 total = ceil(bound(autocvar_g_throughfloor_min_steps_other, total, autocvar_g_throughfloor_max_steps_other));
1059
1060                                                         if(autocvar_g_throughfloor_debug)
1061                                                                 print(sprintf(" steps=%f dD=%f dF=%f", total, finaldmg * (1-tfloordmg) / (2 * sqrt(total)), vlen(force) * (1-tfloorforce) / (2 * sqrt(total))));
1062
1063                                                         for(c = 0; c < total; ++c)
1064                                                         {
1065                                                                 //traceline(targ.WarpZone_findradius_findorigin, nearest, MOVE_NOMONSTERS, inflictor);
1066                                                                 WarpZone_TraceLine(blastorigin, WarpZone_UnTransformOrigin(targ, nearest), MOVE_NOMONSTERS, inflictor);
1067                                                                 if (trace_fraction == 1 || trace_ent == targ)
1068                                                                 {
1069                                                                         ++hits;
1070                                                                         if (hits > 1)
1071                                                                                 hitloc = hitloc + nearest;
1072                                                                         else
1073                                                                                 hitloc = nearest;
1074                                                                 }
1075                                                                 nearest_x = targ.origin_x + targ.mins_x + random() * targ.size_x;
1076                                                                 nearest_y = targ.origin_y + targ.mins_y + random() * targ.size_y;
1077                                                                 nearest_z = targ.origin_z + targ.mins_z + random() * targ.size_z;
1078                                                         }
1079
1080                                                         nearest = hitloc * (1 / max(1, hits));
1081                                                         hitratio = (hits / total);
1082                                                         a = bound(0, tfloordmg + (1-tfloordmg) * hitratio, 1);
1083                                                         finaldmg = finaldmg * a;
1084                                                         a = bound(0, tfloorforce + (1-tfloorforce) * hitratio, 1);
1085                                                         force = force * a;
1086
1087                                                         if(autocvar_g_throughfloor_debug)
1088                                                                 print(sprintf(" D=%f F=%f\n", finaldmg, vlen(force)));
1089                                                 }
1090
1091                                                 // laser force adjustments :P
1092                                                 if(DEATH_WEAPONOF(deathtype) == WEP_LASER)
1093                                                 {
1094                                                         if (targ == attacker)
1095                                                         {
1096                                                                 vector vel;
1097
1098                                                                 float force_zscale;
1099                                                                 float force_velocitybiasramp;
1100                                                                 float force_velocitybias;
1101
1102                                                                 force_velocitybiasramp = autocvar_sv_maxspeed;
1103                                                                 if(deathtype & HITTYPE_SECONDARY)
1104                                                                 {
1105                                                                         force_zscale = autocvar_g_balance_laser_secondary_force_zscale;
1106                                                                         force_velocitybias = autocvar_g_balance_laser_secondary_force_velocitybias;
1107                                                                 }
1108                                                                 else
1109                                                                 {
1110                                                                         force_zscale = autocvar_g_balance_laser_primary_force_zscale;
1111                                                                         force_velocitybias = autocvar_g_balance_laser_primary_force_velocitybias;
1112                                                                 }
1113
1114                                                                 vel = targ.velocity;
1115                                                                 vel_z = 0;
1116                                                                 vel = normalize(vel) * bound(0, vlen(vel) / force_velocitybiasramp, 1) * force_velocitybias;
1117                                                                 force =
1118                                                                         vlen(force)
1119                                                                         *
1120                                                                         normalize(normalize(force) + vel);
1121
1122                                                                 force_z *= force_zscale;
1123                                                         }
1124                                                         else
1125                                                         {
1126                                                                 if(deathtype & HITTYPE_SECONDARY)
1127                                                                 {
1128                                                                         force *= autocvar_g_balance_laser_secondary_force_other_scale;
1129                                                                 }
1130                                                                 else
1131                                                                 {
1132                                                                         force *= autocvar_g_balance_laser_primary_force_other_scale;
1133                                                                 }
1134                                                         }
1135                                                 }
1136
1137                                                 //if (targ == attacker)
1138                                                 //{
1139                                                 //      print("hits ", ftos(hits), " / ", ftos(total));
1140                                                 //      print(" finaldmg ", ftos(finaldmg), " force ", vtos(force));
1141                                                 //      print(" (", ftos(a), ")\n");
1142                                                 //}
1143                                                 if(finaldmg || vlen(force))
1144                                                 {
1145                                                         if(targ.iscreature)
1146                                                         {
1147                                                                 total_damage_to_creatures += finaldmg;
1148
1149                                                                 if(accuracy_isgooddamage(attacker, targ))
1150                                                                         stat_damagedone += finaldmg;
1151                                                         }
1152
1153                                                         if(targ == directhitentity || DEATH_ISSPECIAL(deathtype))
1154                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype, nearest, force);
1155                                                         else
1156                                                                 Damage (targ, inflictor, attacker, finaldmg, deathtype | HITTYPE_SPLASH, nearest, force);
1157                                                 }
1158                                         }
1159                                 }
1160                         }
1161                 targ = next;
1162         }
1163
1164         RadiusDamage_running = 0;
1165
1166         if(!DEATH_ISSPECIAL(deathtype))
1167                 accuracy_add(attacker, DEATH_WEAPONOFWEAPONDEATH(deathtype), 0, min(coredamage, stat_damagedone));
1168
1169         return total_damage_to_creatures;
1170 }
1171
1172 .float fire_damagepersec;
1173 .float fire_endtime;
1174 .float fire_deathtype;
1175 .entity fire_owner;
1176 .float fire_hitsound;
1177 .entity fire_burner;
1178
1179 void fireburner_think();
1180
1181 float Fire_IsBurning(entity e)
1182 {
1183         return (time < e.fire_endtime);
1184 }
1185
1186 float Fire_AddDamage(entity e, entity o, float d, float t, float dt)
1187 {
1188         float dps;
1189         float maxtime, mintime, maxdamage, mindamage, maxdps, mindps, totaldamage, totaltime;
1190
1191         if(e.classname == "player")
1192         {
1193                 if(e.deadflag)
1194                         return -1;
1195         }
1196         else
1197         {
1198                 if(!e.fire_burner)
1199                 {
1200                         // print("adding a fire burner to ", e.classname, "\n");
1201                         e.fire_burner = spawn();
1202                         e.fire_burner.classname = "fireburner";
1203                         e.fire_burner.think = fireburner_think;
1204                         e.fire_burner.nextthink = time;
1205                         e.fire_burner.owner = e;
1206                 }
1207         }
1208
1209         t = max(t, 0.1);
1210         dps = d / t;
1211         if(Fire_IsBurning(e))
1212         {
1213                 mintime = e.fire_endtime - time;
1214                 maxtime = max(mintime, t);
1215
1216                 mindps = e.fire_damagepersec;
1217                 maxdps = max(mindps, dps);
1218
1219                 if(maxtime > mintime || maxdps > mindps)
1220                 {
1221                         // Constraints:
1222
1223                         // damage we have right now
1224                         mindamage = mindps * mintime;
1225
1226                         // damage we want to get
1227                         maxdamage = mindamage + d;
1228
1229                         // but we can't exceed maxtime * maxdps!
1230                         totaldamage = min(maxdamage, maxtime * maxdps);
1231
1232                         // LEMMA:
1233                         // Look at:
1234                         // totaldamage = min(mindamage + d, maxtime * maxdps)
1235                         // We see:
1236                         // totaldamage <= maxtime * maxdps
1237                         // ==> totaldamage / maxdps <= maxtime.
1238                         // We also see:
1239                         // totaldamage / mindps = min(mindamage / mindps + d, maxtime * maxdps / mindps)
1240                         //                     >= min(mintime, maxtime)
1241                         // ==> totaldamage / maxdps >= mintime.
1242
1243                         /*
1244                         // how long do we damage then?
1245                         // at least as long as before
1246                         // but, never exceed maxdps
1247                         totaltime = max(mintime, totaldamage / maxdps); // always <= maxtime due to lemma
1248                         */
1249
1250                         // alternate:
1251                         // at most as long as maximum allowed
1252                         // but, never below mindps
1253                         totaltime = min(maxtime, totaldamage / mindps); // always >= mintime due to lemma
1254
1255                         // assuming t > mintime, dps > mindps:
1256                         // we get d = t * dps = maxtime * maxdps
1257                         // totaldamage = min(maxdamage, maxtime * maxdps) = min(... + d, maxtime * maxdps) = maxtime * maxdps
1258                         // totaldamage / maxdps = maxtime
1259                         // totaldamage / mindps > totaldamage / maxdps = maxtime
1260                         // FROM THIS:
1261                         // a) totaltime = max(mintime, maxtime) = maxtime
1262                         // b) totaltime = min(maxtime, totaldamage / maxdps) = maxtime
1263
1264                         // assuming t <= mintime:
1265                         // we get maxtime = mintime
1266                         // a) totaltime = max(mintime, ...) >= mintime, also totaltime <= maxtime by the lemma, therefore totaltime = mintime = maxtime
1267                         // b) totaltime = min(maxtime, ...) <= maxtime, also totaltime >= mintime by the lemma, therefore totaltime = mintime = maxtime
1268
1269                         // assuming dps <= mindps:
1270                         // we get mindps = maxdps.
1271                         // With this, the lemma says that mintime <= totaldamage / mindps = totaldamage / maxdps <= maxtime.
1272                         // a) totaltime = max(mintime, totaldamage / maxdps) = totaldamage / maxdps
1273                         // b) totaltime = min(maxtime, totaldamage / mindps) = totaldamage / maxdps
1274
1275                         e.fire_damagepersec = totaldamage / totaltime;
1276                         e.fire_endtime = time + totaltime;
1277                         if(totaldamage > 1.2 * mindamage)
1278                         {
1279                                 e.fire_deathtype = dt;
1280                                 if(e.fire_owner != o)
1281                                 {
1282                                         e.fire_owner = o;
1283                                         e.fire_hitsound = FALSE;
1284                                 }
1285                         }
1286                         if(accuracy_isgooddamage(o, e))
1287                                 accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, max(0, totaldamage - mindamage));
1288                         return max(0, totaldamage - mindamage); // can never be negative, but to make sure
1289                 }
1290                 else
1291                         return 0;
1292         }
1293         else
1294         {
1295                 e.fire_damagepersec = dps;
1296                 e.fire_endtime = time + t;
1297                 e.fire_deathtype = dt;
1298                 e.fire_owner = o;
1299                 e.fire_hitsound = FALSE;
1300                 if(accuracy_isgooddamage(o, e))
1301                         accuracy_add(o, DEATH_WEAPONOFWEAPONDEATH(dt), 0, d);
1302                 return d;
1303         }
1304 }
1305
1306 void Fire_ApplyDamage(entity e)
1307 {
1308         float t, d, hi, ty;
1309         entity o;
1310
1311         if not(Fire_IsBurning(e))
1312                 return;
1313
1314         for(t = 0, o = e.owner; o.owner && t < 16; o = o.owner, ++t);
1315         if(clienttype(o) == CLIENTTYPE_NOTACLIENT)
1316                 o = e.fire_owner;
1317
1318         // water and slime stop fire
1319         if(e.waterlevel)
1320         if(e.watertype != CONTENT_LAVA)
1321                 e.fire_endtime = 0;
1322
1323         // ice stops fire
1324         if(e.freezetag_frozen)
1325                 e.fire_endtime = 0;
1326
1327         t = min(frametime, e.fire_endtime - time);
1328         d = e.fire_damagepersec * t;
1329
1330         hi = e.fire_owner.hitsound;
1331         ty = e.fire_owner.typehitsound;
1332         Damage(e, e, e.fire_owner, d, e.fire_deathtype, e.origin, '0 0 0');
1333         if(e.fire_hitsound && e.fire_owner)
1334         {
1335                 e.fire_owner.hitsound = hi;
1336                 e.fire_owner.typehitsound = ty;
1337         }
1338         e.fire_hitsound = TRUE;
1339
1340         if not(IS_INDEPENDENT_PLAYER(e))
1341         FOR_EACH_PLAYER(other) if(e != other)
1342         {
1343                 if(other.classname == "player")
1344                 if(other.deadflag == DEAD_NO)
1345                 if not(IS_INDEPENDENT_PLAYER(other))
1346                 if(boxesoverlap(e.absmin, e.absmax, other.absmin, other.absmax))
1347                 {
1348                         t = autocvar_g_balance_firetransfer_time * (e.fire_endtime - time);
1349                         d = autocvar_g_balance_firetransfer_damage * e.fire_damagepersec * t;
1350                         Fire_AddDamage(other, o, d, t, DEATH_FIRE);
1351                 }
1352         }
1353 }
1354
1355 void Fire_ApplyEffect(entity e)
1356 {
1357         if(Fire_IsBurning(e))
1358                 e.effects |= EF_FLAME;
1359         else
1360                 e.effects &~= EF_FLAME;
1361 }
1362
1363 void fireburner_think()
1364 {
1365         // for players, this is done in the regular loop
1366         if(wasfreed(self.owner))
1367         {
1368                 remove(self);
1369                 return;
1370         }
1371         Fire_ApplyEffect(self.owner);
1372         if(!Fire_IsBurning(self.owner))
1373         {
1374                 self.owner.fire_burner = world;
1375                 remove(self);
1376                 return;
1377         }
1378         Fire_ApplyDamage(self.owner);
1379         self.nextthink = time;
1380 }