qcsrc/server/g_hook.qc

   1 /*============================================
   2
   3       Wazat's Xonotic Grappling Hook
   4
   5         Contact: Wazat1@gmail.com
   6
   7
   8 Installation instructions:
   9 --------------------------
  10
  11 1. Place hook.c in your gamec source directory with the other source files.
  12
  13 2. Add this line to the bottom of progs.src:
  14
  15 gamec/hook.c
  16
  17 3. Open defs.h and add these lines to the very bottom:
  18
  19 // Wazat's grappling hook
  20 .entity         hook;
  21 void GrapplingHookFrame();
  22 void RemoveGrapplingHook(entity pl);
  23 void SetGrappleHookBindings();
  24 // hook impulses
  25 float GRAPHOOK_FIRE             = 20;
  26 float GRAPHOOK_RELEASE          = 21;
  27 // (note: you can change the hook impulse #'s to whatever you please)
  28
  29 4. Open client.c and add this to the top of PutClientInServer():
  30
  31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
  32
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
  34
  35         // Wazat's grappling hook
  36         SetGrappleHookBindings();
  37
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
  39
  40         GrapplingHookFrame();
  41
  42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
  43 bind ctrl "+hook"
  44
  45 And you should be done!
  46
  47
  48 ============================================*/
  49
  50 .float hook_length;
  51 .float hook_switchweapon;
  52
  53 void RemoveGrapplingHook(entity pl)
  54 {
  55         if(pl.hook == world)
  56                 return;
  57         remove(pl.hook);
  58         pl.hook = world;
  59         if(pl.movetype == MOVETYPE_FLY)
  60                 pl.movetype = MOVETYPE_WALK;
  61
  62         //pl.disableclientprediction = FALSE;
  63 }
  64
  65 void GrapplingHookThink();
  66 void GrapplingHook_Stop()
  67 {
  68         pointparticles(particleeffectnum("grapple_impact"), self.origin, '0 0 0', 1);
  69         sound (self, CH_SHOTS, "weapons/hook_impact.wav", VOL_BASE, ATTN_NORM);
  70
  71         self.state = 1;
  72         self.think = GrapplingHookThink;
  73         self.nextthink = time;
  74         self.touch = SUB_Null;
  75         self.velocity = '0 0 0';
  76         self.movetype = MOVETYPE_NONE;
  77         self.hook_length = -1;
  78 }
  79
  80 .vector hook_start, hook_end;
  81 float GrapplingHookSend(entity to, float sf)
  82 {
  83         WriteByte(MSG_ENTITY, ENT_CLIENT_HOOK);
  84         sf = sf & 0x7F;
  85         if(sound_allowed(MSG_BROADCAST, self.realowner))
  86                 sf |= 0x80;
  87         WriteByte(MSG_ENTITY, sf);
  88         if(sf & 1)
  89         {
  90                 WriteByte(MSG_ENTITY, num_for_edict(self.realowner));
  91         }
  92         if(sf & 2)
  93         {
  94                 WriteCoord(MSG_ENTITY, self.hook_start_x);
  95                 WriteCoord(MSG_ENTITY, self.hook_start_y);
  96                 WriteCoord(MSG_ENTITY, self.hook_start_z);
  97         }
  98         if(sf & 4)
  99         {
 100                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 101                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 102                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 103         }
 104         return TRUE;
 105 }
 106
 107 void GrapplingHookThink()
 108 {
 109         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch, s;
 110         vector dir, org, end, v0, dv, v, myorg, vs;
 111         if(self.realowner.health <= 0 || self.realowner.hook != self)   // how did that happen?
 112         {                                                                                                               // well, better fix it anyway
 113                 remove(self);
 114                 return;
 115         }
 116         if(LostMovetypeFollow(self))
 117         {
 118                 RemoveGrapplingHook(self.realowner);
 119                 return;
 120         }
 121         if(self.aiment)
 122                 WarpZone_RefSys_AddIncrementally(self, self.aiment);
 123
 124         self.nextthink = time;
 125
 126         s = self.realowner.cvar_cl_gunalign;
 127         if(s != 1 && s != 2 && s != 4)
 128                 s = 3; // default value
 129         --s;
 130         vs = hook_shotorigin[s];
 131
 132         makevectors(self.realowner.v_angle);
 133         org = self.realowner.origin + self.realowner.view_ofs + v_forward * vs_x + v_right * -vs_y + v_up * vs_z;
 134         myorg = WarpZone_RefSys_TransformOrigin(self.realowner, self, org);
 135
 136         if(self.hook_length < 0)
 137                 self.hook_length = vlen(myorg - self.origin);
 138
 139         if(self.state == 1)
 140         {
 141                 pullspeed = autocvar_g_balance_grapplehook_speed_pull;//2000;
 142                 // speed the rope is pulled with
 143
 144                 rubberforce = autocvar_g_balance_grapplehook_force_rubber;//2000;
 145                 // force the rope will use if it is stretched
 146
 147                 rubberforce_overstretch = autocvar_g_balance_grapplehook_force_rubber_overstretch;//1000;
 148                 // force the rope will use if it is stretched
 149
 150                 minlength = autocvar_g_balance_grapplehook_length_min;//100;
 151                 // minimal rope length
 152                 // if the rope goes below this length, it isn't pulled any more
 153
 154                 ropestretch = autocvar_g_balance_grapplehook_stretch;//400;
 155                 // if the rope is stretched by more than this amount, more rope is
 156                 // given to you again
 157
 158                 ropeairfriction = autocvar_g_balance_grapplehook_airfriction;//0.2
 159                 // while hanging on the rope, this friction component will help you a
 160                 // bit to control the rope
 161
 162                 dir = self.origin - myorg;
 163                 dist = vlen(dir);
 164                 dir = normalize(dir);
 165
 166                 if(autocvar_g_grappling_hook_tarzan)
 167                 {
 168                         v = v0 = WarpZone_RefSys_TransformVelocity(self.realowner, self, self.realowner.velocity);
 169
 170                         // first pull the rope...
 171                         if(self.realowner.hook_state & HOOK_PULLING)
 172                         {
 173                                 newlength = self.hook_length;
 174                                 newlength = max(newlength - pullspeed * frametime, minlength);
 175
 176                                 if(newlength < dist - ropestretch) // overstretched?
 177                                 {
 178                                         newlength = dist - ropestretch;
 179                                         if(v * dir < 0) // only if not already moving in hook direction
 180                                                 v = v + frametime * dir * rubberforce_overstretch;
 181                                 }
 182
 183                                 self.hook_length = newlength;
 184                         }
 185
 186                         if(self.realowner.hook_state & HOOK_RELEASING)
 187                         {
 188                                 newlength = dist;
 189                                 self.hook_length = newlength;
 190                         }
 191                         else
 192                         {
 193                                 // then pull the player
 194                                 spd = bound(0, (dist - self.hook_length) / ropestretch, 1);
 195                                 v = v * (1 - frametime * ropeairfriction);
 196                                 v = v + frametime * dir * spd * rubberforce;
 197
 198                                 dv = ((v - v0) * dir) * dir;
 199                                 if(autocvar_g_grappling_hook_tarzan >= 2)
 200                                 {
 201                                         if(self.aiment.movetype == MOVETYPE_WALK)
 202                                         {
 203                                                 v = v - dv * 0.5;
 204                                                 self.aiment.velocity = self.aiment.velocity - dv * 0.5;
 205                                                 self.aiment.flags &~= FL_ONGROUND;
 206                                                 self.aiment.pusher = self.realowner;
 207                                                 self.aiment.pushltime = time + autocvar_g_maxpushtime;
 208                                         }
 209                                 }
 210
 211                                 self.realowner.flags &~= FL_ONGROUND;
 212                         }
 213
 214                         self.realowner.velocity = WarpZone_RefSys_TransformVelocity(self, self.realowner, v);
 215                 }
 216                 else
 217                 {
 218                         end = self.origin - dir*50;
 219                         dist = vlen(end - myorg);
 220                         if(dist < 200)
 221                                 spd = dist * (pullspeed / 200);
 222                         else
 223                                 spd = pullspeed;
 224                         if(spd < 50)
 225                                 spd = 0;
 226                         self.realowner.velocity = dir*spd;
 227                         self.realowner.movetype = MOVETYPE_FLY;
 228
 229                         self.realowner.flags &~= FL_ONGROUND;
 230                 }
 231         }
 232
 233         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 234         myorg = WarpZone_RefSys_TransformOrigin(self, self.realowner, self.origin); // + v_forward * (-9);
 235
 236         if(myorg != self.hook_start)
 237         {
 238                 self.SendFlags |= 2;
 239                 self.hook_start = myorg;
 240         }
 241         if(org != self.hook_end)
 242         {
 243                 self.SendFlags |= 4;
 244                 self.hook_end = org;
 245         }
 246 }
 247
 248 void GrapplingHookTouch (void)
 249 {
 250         PROJECTILE_TOUCH;
 251
 252         GrapplingHook_Stop();
 253
 254         if(other)
 255                 if(other.movetype != MOVETYPE_NONE)
 256                 {
 257                         SetMovetypeFollow(self, other);
 258                         WarpZone_RefSys_BeginAddingIncrementally(self, self.aiment);
 259                 }
 260
 261         //self.realowner.disableclientprediction = TRUE;
 262 }
 263
 264 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 265 {
 266         if(self.health > 0)
 267         {
 268                 self.health = self.health - damage;
 269                 if (self.health <= 0)
 270                 {
 271                         if(attacker != self.realowner)
 272                         {
 273                                 self.realowner.pusher = attacker;
 274                                 self.realowner.pushltime = time + autocvar_g_maxpushtime;
 275                         }
 276                         RemoveGrapplingHook(self.realowner);
 277                 }
 278         }
 279 }
 280
 281 void FireGrapplingHook (void)
 282 {
 283         local entity missile;
 284         local vector org;
 285         float s;
 286         vector vs;
 287
 288         if((arena_roundbased && time < warmup) || (time < game_starttime))
 289                 return;
 290
 291     if(self.freezetag_frozen)
 292         return;
 293
 294         makevectors(self.v_angle);
 295
 296         s = self.cvar_cl_gunalign;
 297         if(s != 1 && s != 2 && s != 4)
 298                 s = 3; // default value
 299         --s;
 300         vs = hook_shotorigin[s];
 301
 302         // UGLY WORKAROUND: play this on CH_WEAPON_B so it can't cut off fire sounds
 303         sound (self, CH_WEAPON_B, "weapons/hook_fire.wav", VOL_BASE, ATTN_NORM);
 304         org = self.origin + self.view_ofs + v_forward * vs_x + v_right * -vs_y + v_up * vs_z;
 305
 306         tracebox(self.origin + self.view_ofs, '-3 -3 -3', '3 3 3', org, MOVE_NORMAL, self);
 307         org = trace_endpos;
 308
 309         pointparticles(particleeffectnum("grapple_muzzleflash"), org, '0 0 0', 1);
 310
 311         missile = WarpZone_RefSys_SpawnSameRefSys(self);
 312         missile.owner = missile.realowner = self;
 313         self.hook = missile;
 314         missile.classname = "grapplinghook";
 315
 316         missile.movetype = MOVETYPE_FLY;
 317         PROJECTILE_MAKETRIGGER(missile);
 318
 319         //setmodel (missile, "models/hook.md3"); // precision set below
 320         setsize (missile, '-3 -3 -3', '3 3 3');
 321         setorigin (missile, org);
 322
 323         missile.state = 0; // not latched onto anything
 324
 325         W_SetupProjectileVelocityEx(missile, v_forward, v_up, autocvar_g_balance_grapplehook_speed_fly, 0, 0, 0, FALSE);
 326
 327         missile.angles = vectoangles (missile.velocity);
 328         //missile.glow_color = 250; // 244, 250
 329         //missile.glow_size = 120;
 330         missile.touch = GrapplingHookTouch;
 331         missile.think = GrapplingHookThink;
 332         missile.nextthink = time;
 333
 334         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;
 335
 336         missile.health = autocvar_g_balance_grapplehook_health;//120
 337         missile.event_damage = GrapplingHook_Damage;
 338         missile.takedamage = DAMAGE_AIM;
 339         missile.damageforcescale = 0;
 340
 341         missile.hook_start = missile.hook_end = missile.origin;
 342
 343         Net_LinkEntity(missile, FALSE, 0, GrapplingHookSend);
 344 }
 345
 346 //  void GrapplingHookFrame()
 347 //  {
 348 //         // this function has been modified for Xonotic
 349 // -       if (self.BUTTON_HOOK && g_grappling_hook)
 350 //         {
 351 // -               if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
 352 // -                       if (timeoutStatus != 2) //only allow the player to fire the grappling hook if the game is not paused (timeout)
 353 // -                               FireGrapplingHook();
 354 //         }
 355 // -       else
 356 //         {
 357 //                 if (self.hook)
 358 //                         RemoveGrapplingHook(self);
 359 //         }
 360 // -       self.button6_pressed_before = self.BUTTON_HOOK;
 361 //         /*
 362 //         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 363 //         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 364
 365 void GrapplingHookFrame()
 366 {
 367         if(g_grappling_hook && timeoutStatus != 2 && self.weapon != WEP_HOOK)
 368         {
 369                 // offhand hook controls
 370                 if(self.BUTTON_HOOK)
 371                 {
 372                         if not(self.hook || (self.hook_state & HOOK_WAITING_FOR_RELEASE))
 373                         {
 374                                 self.hook_state |= HOOK_FIRING;
 375                                 self.hook_state |= HOOK_WAITING_FOR_RELEASE;
 376                         }
 377                 }
 378                 else
 379                 {
 380                         self.hook_state |= HOOK_REMOVING;
 381                         self.hook_state &~= HOOK_WAITING_FOR_RELEASE;
 382                 }
 383
 384                 self.hook_state &~= HOOK_RELEASING;
 385                 if(self.BUTTON_CROUCH)
 386                 {
 387                         self.hook_state &~= HOOK_PULLING;
 388                         //self.hook_state |= HOOK_RELEASING;
 389                 }
 390                 else
 391                 {
 392                         self.hook_state |= HOOK_PULLING;
 393                         //self.hook_state &~= HOOK_RELEASING;
 394                 }
 395         }
 396         else if(!(self.items & IT_JETPACK) && !g_grappling_hook && self.switchweapon != WEP_HOOK)
 397         {
 398                 if(self.BUTTON_HOOK && !self.hook_switchweapon)
 399                         W_SwitchWeapon(WEP_HOOK);
 400         }
 401         self.hook_switchweapon = self.BUTTON_HOOK;
 402
 403         if(!g_grappling_hook && self.weapon != WEP_HOOK)
 404         {
 405                 self.hook_state &~= HOOK_FIRING;
 406                 self.hook_state |= HOOK_REMOVING;
 407         }
 408
 409         if (self.hook_state & HOOK_FIRING)
 410         {
 411                 if (self.hook)
 412                         RemoveGrapplingHook(self);
 413                 FireGrapplingHook();
 414                 self.hook_state &~= HOOK_FIRING;
 415         }
 416         else if(self.hook_state & HOOK_REMOVING)
 417         {
 418                 if (self.hook)
 419                         RemoveGrapplingHook(self);
 420                 self.hook_state &~= HOOK_REMOVING;
 421         }
 422
 423         /*
 424         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 425         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 426         {
 427                 self.movetype = MOVETYPE_WALK;
 428         }
 429         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && g_grappling_hook)
 430         {
 431                 // fire hook
 432                 FireGrapplingHook();
 433                 return;
 434         }
 435         else if(self.hookimpulse == GRAPHOOK_RELEASE)
 436         {
 437                 // remove hook, reset movement type
 438                 RemoveGrapplingHook(self);
 439                 return;
 440         }
 441         */
 442         /*else // make sure the player's movetype is correct
 443         {
 444                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
 445                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 446                 {
 447                         self.movetype = MOVETYPE_WALK;
 448                 }
 449         }*/
 450         // note: The hook entity does the actual pulling
 451 }
 452
 453 void GrappleHookInit()
 454 {
 455         if(g_grappling_hook)
 456         {
 457                 hook_shotorigin[0] = '8 8 -12';
 458                 hook_shotorigin[1] = '8 8 -12';
 459                 hook_shotorigin[2] = '8 8 -12';
 460                 hook_shotorigin[3] = '8 8 -12';
 461         }
 462         else
 463         {
 464                 weapon_action(WEP_HOOK, WR_PRECACHE);
 465                 hook_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 1);
 466                 hook_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 2);
 467                 hook_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 3);
 468                 hook_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_HOOK), FALSE, FALSE, 4);
 469         }
 470 }
 471
 472 void SetGrappleHookBindings()
 473 {
 474         // this function has been modified for Xonotic
 475         // don't remove these lines! old server or demos coud overwrite the new aliases
 476         stuffcmd(self, "alias +hook +button6\n");
 477         stuffcmd(self, "alias -hook -button6\n");
 478 }