qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(autocvar_g_running_guns)
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = autocvar_g_balance_cloaked_alpha;
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = autocvar_g_player_alpha;
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!autocvar_developer_fteqccbugs)
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         entity plr;
 105         if (timeoutStatus == 1) {
 106                 if (remainingLeadTime > 0) {
 107                         //centerprint the information to every player
 108                         FOR_EACH_REALCLIENT(plr) {
 109                                 if(plr.classname == "player") {
 110                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout begins in %d seconds!", 1, remainingLeadTime);
 111                                 }
 112                         }
 113                         remainingLeadTime -= 1;
 114                         //think again in 1 second:
 115                         self.nextthink = time + 1;
 116                 }
 117                 else {
 118                         //now pause the game:
 119                         timeoutStatus = 2;
 120                         //reset all the flood variables
 121                         FOR_EACH_CLIENT(plr) {
 122                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 123                         }
 124                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 125                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 126                         FOR_EACH_REALPLAYER(plr) {
 127                                 plr.lastV_angle = plr.v_angle;
 128                         }
 129                         self.nextthink = time;
 130                 }
 131         }
 132         else if (timeoutStatus == 2) {
 133                 if (remainingTimeoutTime > 0) {
 134                         FOR_EACH_REALCLIENT(plr) {
 135                                 if(plr.classname == "player") {
 136                                         Send_CSQC_Centerprint_Generic(plr, CPID_TIMEOUT_COUNTDOWN, "Timeout ends in %d seconds!", 1, remainingTimeoutTime);
 137                                 }
 138                         }
 139                         if(remainingTimeoutTime == autocvar_sv_timeout_resumetime) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 140                                 Announce("prepareforbattle");
 141                         }
 142                         remainingTimeoutTime -= 1;
 143                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 144                 }
 145                 else {
 146                         //unpause the game again
 147                         remainingTimeoutTime = timeoutStatus = 0;
 148                         cvar_set("slowmo", ftos(orig_slowmo));
 149                         //and unlock the fixed view again once there is no timeout active anymore
 150                         FOR_EACH_REALPLAYER(plr) {
 151                                 plr.fixangle = FALSE;
 152                         }
 153                         //get rid of the countdown message
 154                         FOR_EACH_REALCLIENT(plr) {
 155                                 if(plr.classname == "player") {
 156                                         Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 157                                 }
 158                         }
 159                         remove(self);
 160                         return;
 161                 }
 162
 163         }
 164         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 165                 FOR_EACH_REALCLIENT(plr) {
 166                         if(plr.classname == "player") {
 167                                 Send_CSQC_Centerprint_Generic_Expire(plr, CPID_TIMEOUT_COUNTDOWN);
 168                         }
 169                 }
 170                 remove(self);
 171                 return;
 172         }
 173 }
 174
 175 void GotoFirstMap()
 176 {
 177         float n;
 178         if(autocvar__sv_init)
 179         {
 180                 // cvar_set("_sv_init", "0");
 181                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 182                 // to this "init" map on a dedicated server will cause no permanent
 183                 // harm
 184                 if(autocvar_g_maplist_shuffle)
 185                         ShuffleMaplist();
 186                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 187                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 188
 189                 MapInfo_Enumerate();
 190                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 191
 192                 if(!DoNextMapOverride())
 193                         GotoNextMap();
 194
 195                 return;
 196         }
 197
 198         if(time < 5)
 199         {
 200                 self.nextthink = time;
 201         }
 202         else
 203         {
 204                 self.nextthink = time + 1;
 205                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 206         }
 207 }
 208
 209 void cvar_changes_init()
 210 {
 211         float h;
 212         string k, v, d;
 213         float n, i, adding, pureadding;
 214
 215         if(cvar_changes)
 216                 strunzone(cvar_changes);
 217         cvar_changes = string_null;
 218         if(cvar_purechanges)
 219                 strunzone(cvar_purechanges);
 220         cvar_purechanges = string_null;
 221         cvar_purechanges_count = 0;
 222
 223         h = buf_create();
 224         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 225         n = buf_getsize(h);
 226
 227         adding = TRUE;
 228         pureadding = TRUE;
 229
 230         for(i = 0; i < n; ++i)
 231         {
 232                 k = bufstr_get(h, i);
 233
 234 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 235 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 236 #define BADCVAR(p) if(k == p) continue
 237
 238                 // general excludes and namespaces for server admin used cvars
 239                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 240
 241                 // internal
 242                 BADPREFIX("csqc_");
 243                 BADPREFIX("cvar_check_");
 244                 BADCVAR("gamecfg");
 245                 BADCVAR("g_configversion");
 246                 BADCVAR("g_maplist_index");
 247                 BADCVAR("halflifebsp");
 248                 BADPREFIX("sv_world");
 249
 250                 // client
 251                 BADPREFIX("chase_");
 252                 BADPREFIX("cl_");
 253                 BADPREFIX("con_");
 254                 BADPREFIX("scoreboard_");
 255                 BADPREFIX("g_campaign");
 256                 BADPREFIX("g_waypointsprite_");
 257                 BADPREFIX("gl_");
 258                 BADPREFIX("joy");
 259                 BADPREFIX("hud_");
 260                 BADPREFIX("m_");
 261                 BADPREFIX("menu_");
 262                 BADPREFIX("net_slist_");
 263                 BADPREFIX("r_");
 264                 BADPREFIX("sbar_");
 265                 BADPREFIX("scr_");
 266                 BADPREFIX("snd_");
 267                 BADPREFIX("show");
 268                 BADPREFIX("sensitivity");
 269                 BADPREFIX("userbind");
 270                 BADPREFIX("v_");
 271                 BADPREFIX("vid_");
 272                 BADPREFIX("crosshair");
 273                 BADCVAR("mod_q3bsp_lightmapmergepower");
 274                 BADCVAR("mod_q3bsp_nolightmaps");
 275                 BADCVAR("fov");
 276                 BADCVAR("mastervolume");
 277                 BADCVAR("volume");
 278                 BADCVAR("bgmvolume");
 279
 280                 // private
 281                 BADCVAR("developer");
 282                 BADCVAR("log_dest_udp");
 283                 BADCVAR("log_file");
 284                 BADCVAR("net_address");
 285                 BADCVAR("net_address_ipv6");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("serverconfig");
 289                 BADCVAR("sv_heartbeatperiod");
 290                 BADCVAR("sv_vote_master_password");
 291                 BADCVAR("sys_colortranslation");
 292                 BADCVAR("sys_specialcharactertranslation");
 293                 BADCVAR("timeformat");
 294                 BADCVAR("timestamps");
 295                 BADPREFIX("developer_");
 296                 BADPREFIX("g_ban_");
 297                 BADPREFIX("g_banned_list");
 298                 BADPREFIX("g_chat_flood_");
 299                 BADPREFIX("g_playerstats_");
 300                 BADPREFIX("g_voice_flood_");
 301                 BADPREFIX("rcon_");
 302                 BADPREFIX("settemp_");
 303                 BADPREFIX("sv_allowdownloads_");
 304                 BADPREFIX("sv_autodemo");
 305                 BADPREFIX("sv_curl_");
 306                 BADPREFIX("sv_eventlog");
 307                 BADPREFIX("sv_logscores_");
 308                 BADPREFIX("sv_master");
 309                 BADPREFIX("sv_weaponstats_");
 310
 311                 // these can contain player IDs, so better hide
 312                 BADPREFIX("g_forced_team_");
 313
 314                 // mapinfo
 315                 BADCVAR("fraglimit");
 316                 BADCVAR("g_arena");
 317                 BADCVAR("g_assault");
 318                 BADCVAR("g_ca");
 319                 BADCVAR("g_ctf");
 320                 BADCVAR("g_cts");
 321                 BADCVAR("g_dm");
 322                 BADCVAR("g_domination");
 323                 BADCVAR("g_domination_default_teams");
 324                 BADCVAR("g_freezetag");
 325                 BADCVAR("g_keepaway");
 326                 BADCVAR("g_keyhunt");
 327                 BADCVAR("g_keyhunt_teams");
 328                 BADCVAR("g_keyhunt_teams");
 329                 BADCVAR("g_lms");
 330                 BADCVAR("g_nexball");
 331                 BADCVAR("g_onslaught");
 332                 BADCVAR("g_race");
 333                 BADCVAR("g_race_qualifying_timelimit");
 334                 BADCVAR("g_runematch");
 335                 BADCVAR("g_tdm");
 336                 BADCVAR("g_tdm_teams");
 337                 BADCVAR("leadlimit");
 338                 BADCVAR("nextmap");
 339                 BADCVAR("teamplay");
 340                 BADCVAR("timelimit");
 341
 342                 // long
 343                 BADCVAR("hostname");
 344                 BADCVAR("g_maplist");
 345                 BADCVAR("g_maplist_mostrecent");
 346                 BADCVAR("sv_motd");
 347
 348                 v = cvar_string(k);
 349                 d = cvar_defstring(k);
 350                 if(v == d)
 351                         continue;
 352
 353                 if(adding)
 354                 {
 355                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 356                         if(strlen(cvar_changes) > 16384)
 357                         {
 358                                 cvar_changes = "// too many settings have been changed to show them here\n";
 359                                 adding = 0;
 360                         }
 361                 }
 362
 363                 // now check if the changes are actually gameplay relevant
 364
 365                 // does nothing visible
 366                 BADCVAR("captureleadlimit_override");
 367                 BADCVAR("g_arena_point_leadlimit");
 368                 BADCVAR("g_balance_kill_delay");
 369                 BADCVAR("g_ca_point_leadlimit");
 370                 BADCVAR("g_ctf_captimerecord_always");
 371                 BADCVAR("g_ctf_capture_leadlimit");
 372                 BADCVAR("g_ctf_flag_capture_effects");
 373                 BADCVAR("g_ctf_flag_glowtrails");
 374                 BADCVAR("g_ctf_flag_pickup_effects");
 375                 BADCVAR("g_domination_point_leadlimit");
 376                 BADCVAR("g_forced_respawn");
 377                 BADCVAR("g_keyhunt_point_leadlimit");
 378                 BADCVAR("g_nexball_goalleadlimit");
 379                 BADCVAR("g_runematch_point_leadlimit");
 380                 BADCVAR("leadlimit_and_fraglimit");
 381                 BADCVAR("leadlimit_override");
 382                 BADCVAR("pausable");
 383                 BADCVAR("sv_checkforpacketsduringsleep");
 384                 BADCVAR("sv_timeout");
 385                 BADCVAR("welcome_message_time");
 386                 BADPREFIX("crypto_");
 387                 BADPREFIX("g_chat_");
 388                 BADPREFIX("g_ctf_captimerecord_");
 389                 BADPREFIX("g_maplist_votable_");
 390                 BADPREFIX("net_");
 391                 BADPREFIX("prvm_");
 392                 BADPREFIX("skill_");
 393                 BADPREFIX("sv_fragmessage_");
 394                 BADPREFIX("sv_maxidle_");
 395                 BADPREFIX("sv_vote_");
 396                 BADPREFIX("timelimit_");
 397                 BADCVAR("gameversion");
 398                 BADPREFIX("gameversion_");
 399
 400                 // allowed changes to server admins (please sync this to server.cfg)
 401                 // vi commands:
 402                 //   :/"impure"/,$d
 403                 //   :g!,^\/\/[^ /],d
 404                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 405                 //   :%!sort
 406                 // yes, this does contain some redundant stuff, don't really care
 407                 BADCVAR("bot_number");
 408                 BADCVAR("bot_prefix");
 409                 BADCVAR("bot_suffix");
 410                 BADCVAR("bot_config_file");
 411                 BADCVAR("capturelimit_override");
 412                 BADCVAR("fraglimit_override");
 413                 BADCVAR("gametype");
 414                 BADCVAR("g_antilag");
 415                 BADCVAR("g_balance_teams");
 416                 BADCVAR("g_balance_teams_force");
 417                 BADCVAR("g_ban_sync_trusted_servers");
 418                 BADCVAR("g_ban_sync_uri");
 419                 BADCVAR("g_ctf_capture_limit");
 420                 BADCVAR("g_ctf_ignore_frags");
 421                 BADCVAR("g_ctf_win_mode");
 422                 BADCVAR("g_domination_point_limit");
 423                 BADCVAR("g_friendlyfire");
 424                 BADCVAR("g_fullbrightitems");
 425                 BADCVAR("g_fullbrightplayers");
 426                 BADCVAR("g_keyhunt_point_limit");
 427                 BADCVAR("g_keyhunt_teams_override");
 428                 BADCVAR("g_lms_lives_override");
 429                 BADCVAR("g_maplist");
 430                 BADCVAR("g_maplist_check_waypoints");
 431                 BADCVAR("g_maplist_mostrecent_count");
 432                 BADCVAR("g_maplist_shuffle");
 433                 BADCVAR("g_maplist_votable");
 434                 BADCVAR("g_maplist_votable_abstain");
 435                 BADCVAR("g_maplist_votable_nodetail");
 436                 BADCVAR("g_maplist_votable_suggestions");
 437                 BADCVAR("g_maxplayers");
 438                 BADCVAR("g_minstagib");
 439                 BADCVAR("g_mirrordamage");
 440                 BADCVAR("g_nexball_goallimit");
 441                 BADCVAR("g_runematch_point_limit");
 442                 BADCVAR("g_start_delay");
 443                 BADCVAR("g_warmup");
 444                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 445                 BADCVAR("hostname");
 446                 BADCVAR("log_file");
 447                 BADCVAR("maxplayers");
 448                 BADCVAR("minplayers");
 449                 BADCVAR("net_address");
 450                 BADCVAR("port");
 451                 BADCVAR("rcon_password");
 452                 BADCVAR("rcon_restricted_commands");
 453                 BADCVAR("rcon_restricted_password");
 454                 BADCVAR("skill");
 455                 BADCVAR("sv_adminnick");
 456                 BADCVAR("sv_autoscreenshot");
 457                 BADCVAR("sv_curl_defaulturl");
 458                 BADCVAR("sv_defaultcharacter");
 459                 BADCVAR("sv_defaultplayercolors");
 460                 BADCVAR("sv_defaultplayermodel");
 461                 BADCVAR("sv_defaultplayerskin");
 462                 BADCVAR("sv_maxidle");
 463                 BADCVAR("sv_maxrate");
 464                 BADCVAR("sv_motd");
 465                 BADCVAR("sv_public");
 466                 BADCVAR("sv_ready_restart");
 467                 BADCVAR("sv_status_privacy");
 468                 BADCVAR("sv_vote_call");
 469                 BADCVAR("sv_vote_commands");
 470                 BADCVAR("sv_vote_majority_factor");
 471                 BADCVAR("sv_vote_master");
 472                 BADCVAR("sv_vote_master_commands");
 473                 BADCVAR("sv_vote_master_password");
 474                 BADCVAR("sv_vote_simple_majority_factor");
 475                 BADCVAR("sys_ticrate");
 476                 BADCVAR("teamplay_mode");
 477                 BADCVAR("timelimit_override");
 478                 BADPREFIX("g_warmup_");
 479
 480                 if(autocvar_g_minstagib)
 481                 {
 482                         BADCVAR("g_grappling_hook");
 483                         BADCVAR("g_jetpack");
 484                 }
 485 #undef BADPREFIX
 486 #undef BADCVAR
 487
 488                 if(pureadding)
 489                 {
 490                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 491                         if(strlen(cvar_purechanges) > 16384)
 492                         {
 493                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 494                                 pureadding = 0;
 495                         }
 496                 }
 497                 ++cvar_purechanges_count;
 498                 // WARNING: this variable is used for the server list
 499                 // NEVER dare to skip this code!
 500                 // Hacks to intentionally appearing as "pure server" even though you DO have
 501                 // modified settings may be punished by removal from the server list.
 502                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 503                 // though.
 504         }
 505         buf_del(h);
 506         if(cvar_changes == "")
 507                 cvar_changes = "// this server runs at default server settings\n";
 508         else
 509                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 510         cvar_changes = strzone(cvar_changes);
 511         if(cvar_purechanges == "")
 512                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 513         else
 514                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 515         cvar_purechanges = strzone(cvar_purechanges);
 516 }
 517
 518 void detect_maptype()
 519 {
 520 #if 0
 521         vector o, v;
 522         float i;
 523
 524         for(;;)
 525         {
 526                 o = world.mins;
 527                 o_x += random() * (world.maxs_x - world.mins_x);
 528                 o_y += random() * (world.maxs_y - world.mins_y);
 529                 o_z += random() * (world.maxs_z - world.mins_z);
 530
 531                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 532                 if(trace_fraction == 1)
 533                         continue;
 534
 535                 v = trace_endpos;
 536
 537                 for(i = 0; i < 64; i += 4)
 538                 {
 539                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 540         if(trace_fraction == 1)
 541                 continue;
 542                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 543                 }
 544
 545                 break;
 546         }
 547 #endif
 548 }
 549
 550 entity randomseed;
 551 float RandomSeed_Send(entity to, float sf)
 552 {
 553         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 554         WriteShort(MSG_ENTITY, self.cnt);
 555         return TRUE;
 556 }
 557 void RandomSeed_Think()
 558 {
 559         self.cnt = bound(0, floor(random() * 65536), 65535);
 560         self.nextthink = time + 5;
 561
 562         self.SendFlags |= 1;
 563 }
 564 void RandomSeed_Spawn()
 565 {
 566         randomseed = spawn();
 567         randomseed.think = RandomSeed_Think;
 568         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 569
 570         entity oldself;
 571         oldself = self;
 572         self = randomseed;
 573         self.think(); // sets random seed and nextthink
 574         self = oldself;
 575 }
 576
 577 void spawnfunc___init_dedicated_server(void)
 578 {
 579         // handler for _init/_init map (only for dedicated server initialization)
 580
 581         world_initialized = -1; // don't complain
 582         cvar = cvar_normal;
 583         cvar_string = cvar_string_normal;
 584         cvar_set = cvar_set_normal;
 585
 586         remove = remove_unsafely;
 587
 588         entity e;
 589         e = spawn();
 590         e.think = GotoFirstMap;
 591         e.nextthink = time; // this is usually 1 at this point
 592
 593         e = spawn();
 594         e.classname = "info_player_deathmatch"; // safeguard against player joining
 595
 596         self.classname = "worldspawn"; // safeguard against various stuff ;)
 597
 598         MapInfo_Enumerate();
 599         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 600 }
 601
 602 void Map_MarkAsRecent(string m);
 603 float world_already_spawned;
 604 void RegisterWeapons();
 605 void Nagger_Init();
 606 void ClientInit_Spawn();
 607 void WeaponStats_Init();
 608 void WeaponStats_Shutdown();
 609 void spawnfunc_worldspawn (void)
 610 {
 611         float fd, l, i, j, n;
 612         string s, col;
 613
 614         cvar = cvar_normal;
 615         cvar_string = cvar_string_normal;
 616         cvar_set = cvar_set_normal;
 617
 618         if(world_already_spawned)
 619                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 620         world_already_spawned = TRUE;
 621
 622         remove = remove_safely; // during spawning, watch what you remove!
 623
 624         check_unacceptable_compiler_bugs();
 625
 626         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 627
 628         compressShortVector_init();
 629
 630         allowed_to_spawn = TRUE;
 631
 632         entity head;
 633         head = nextent(world);
 634         maxclients = 0;
 635         while(head)
 636         {
 637                 ++maxclients;
 638                 head = nextent(head);
 639         }
 640
 641         // needs to be done so early as they would still spawn
 642         RegisterWeapons();
 643
 644         ServerProgsDB = db_load("server.db");
 645
 646         TemporaryDB = db_create();
 647
 648         // 0 normal
 649         lightstyle(0, "m");
 650
 651         // 1 FLICKER (first variety)
 652         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 653
 654         // 2 SLOW STRONG PULSE
 655         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 656
 657         // 3 CANDLE (first variety)
 658         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 659
 660         // 4 FAST STROBE
 661         lightstyle(4, "mamamamamama");
 662
 663         // 5 GENTLE PULSE 1
 664         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 665
 666         // 6 FLICKER (second variety)
 667         lightstyle(6, "nmonqnmomnmomomno");
 668
 669         // 7 CANDLE (second variety)
 670         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 671
 672         // 8 CANDLE (third variety)
 673         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 674
 675         // 9 SLOW STROBE (fourth variety)
 676         lightstyle(9, "aaaaaaaazzzzzzzz");
 677
 678         // 10 FLUORESCENT FLICKER
 679         lightstyle(10, "mmamammmmammamamaaamammma");
 680
 681         // 11 SLOW PULSE NOT FADE TO BLACK
 682         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 683
 684         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 685
 686         // 63 testing
 687         lightstyle(63, "a");
 688
 689         if(autocvar_g_campaign)
 690                 CampaignPreInit();
 691
 692         Map_MarkAsRecent(mapname);
 693
 694         precache_model ("null"); // we need this one before InitGameplayMode
 695         InitGameplayMode();
 696         readlevelcvars();
 697         GrappleHookInit();
 698         ElectroInit();
 699         LaserInit();
 700
 701         player_count = 0;
 702         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 703         if(bot_waypoints_for_items == 1)
 704                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 705                         bot_waypoints_for_items = 0;
 706
 707         precache();
 708
 709         WaypointSprite_Init();
 710
 711         //if (g_domination)
 712         //      dom_init();
 713
 714         GameLogInit(); // prepare everything
 715         if(autocvar_sv_eventlog)
 716         {
 717                 s = sprintf("%d.%s.%06d", ftos(autocvar_sv_eventlog_files_counter), strftime(FALSE, "%s"), floor(random() * 1000000));
 718                 matchid = strzone(s);
 719
 720                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 721                 s = ":gameinfo:mutators:LIST";
 722
 723                 ret_string = s;
 724                 MUTATOR_CALLHOOK(BuildMutatorsString);
 725                 s = ret_string;
 726
 727                 // simple, probably not good in the mutator system
 728                 if(autocvar_g_grappling_hook)
 729                         s = strcat(s, ":grappling_hook");
 730
 731                 // initialiation stuff, not good in the mutator system
 732                 if(!autocvar_g_use_ammunition)
 733                         s = strcat(s, ":no_use_ammunition");
 734
 735                 // initialiation stuff, not good in the mutator system
 736                 if(!autocvar_g_pickup_items)
 737                         s = strcat(s, ":no_pickup_items");
 738
 739                 // initialiation stuff, not good in the mutator system
 740                 if(autocvar_g_weaponarena != "0")
 741                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 742
 743                 // TODO to mutator system
 744                 if(autocvar_g_norecoil)
 745                         s = strcat(s, ":norecoil");
 746
 747                 // TODO to mutator system
 748                 if(autocvar_g_midair)
 749                         s = strcat(s, ":midair");
 750
 751                 // TODO to mutator system
 752                 if(autocvar_g_minstagib)
 753                         s = strcat(s, ":minstagib");
 754
 755                 GameLogEcho(s);
 756                 GameLogEcho(":gameinfo:end");
 757         }
 758         else
 759                 matchid = strzone(ftos(random()));
 760
 761         cvar_set("nextmap", "");
 762
 763         SetDefaultAlpha();
 764
 765         if(autocvar_g_campaign)
 766                 CampaignPostInit();
 767
 768         fteqcc_testbugs();
 769
 770         Ban_LoadBans();
 771
 772         MapInfo_Enumerate();
 773         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 774
 775         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 776         {
 777                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 778                 if(fd != -1)
 779                 {
 780                         while((s = fgets(fd)))
 781                         {
 782                                 l = tokenize_console(s);
 783                                 if(l < 2)
 784                                         continue;
 785                                 if(argv(0) == "cd")
 786                                 {
 787                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 788                                         print("  cdtrack ", argv(2), "\n");
 789                                 }
 790                                 else if(argv(0) == "fog")
 791                                 {
 792                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 793                                         print("  \"fog\" \"", s, "\"\n");
 794                                 }
 795                                 else if(argv(0) == "set")
 796                                 {
 797                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 798                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 799                                 }
 800                                 else if(argv(0) != "//")
 801                                 {
 802                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 803                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 804                                 }
 805                         }
 806                         fclose(fd);
 807                 }
 808         }
 809
 810         WeaponStats_Init();
 811
 812         addstat(STAT_WEAPONS, AS_INT, weapons);
 813         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 814         addstat(STAT_SWITCHINGWEAPON, AS_INT, switchingweapon);
 815         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 816         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 817         Nagger_Init();
 818
 819         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 820         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 821         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 822         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 823         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 824         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 825         addstat(STAT_WEAPON_CLIPLOAD, AS_INT, clip_load);
 826         addstat(STAT_WEAPON_CLIPSIZE, AS_INT, clip_size);
 827         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 828         addstat(STAT_HIT_TIME, AS_FLOAT, hit_time);
 829         addstat(STAT_TYPEHIT_TIME, AS_FLOAT, typehit_time);
 830         addstat(STAT_LAYED_MINES, AS_INT, minelayer_mines);
 831
 832         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 833         addstat(STAT_NEX_CHARGEPOOL, AS_FLOAT, nex_chargepool_ammo);
 834
 835         addstat(STAT_HAGAR_LOAD, AS_INT, hagar_load);
 836
 837         if(g_ca || g_freezetag)
 838         {
 839                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 840                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 841                 addstat(STAT_YELLOWALIVE, AS_INT, yellowalive_stat);
 842                 addstat(STAT_PINKALIVE, AS_INT, pinkalive_stat);
 843         }
 844         if(g_freezetag)
 845         {
 846                 addstat(STAT_FROZEN, AS_INT, freezetag_frozen);
 847                 addstat(STAT_REVIVE_PROGRESS, AS_FLOAT, freezetag_revive_progress);
 848         }
 849
 850         // g_movementspeed hack
 851         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 852         addstat(STAT_MOVEVARS_MAXSPEED, AS_FLOAT, stat_sv_maxspeed);
 853         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 854         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 855
 856         next_pingtime = time + 5;
 857
 858         detect_maptype();
 859
 860         lsmaps_reply = "^7Maps available: ";
 861         lsnewmaps_reply = "^7Maps without a record set: ";
 862         for(i = 0, j = 0; i < MapInfo_count; ++i)
 863         {
 864                 if(MapInfo_Get_ByID(i))
 865                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 866                         {
 867                                 if(mod(i, 2))
 868                                         col = "^2";
 869                                 else
 870                                         col = "^3";
 871                                 ++j;
 872                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 873                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 874                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 875                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 876                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 877                         }
 878         }
 879         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 880         if (!g_race && !g_cts)
 881                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 882         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 883
 884         maplist_reply = "^7Maps in list: ";
 885         n = tokenize_console(autocvar_g_maplist);
 886         for(i = 0, j = 0; i < n; ++i)
 887         {
 888                 if(MapInfo_CheckMap(argv(i)))
 889                 {
 890                         if(mod(j, 2))
 891                                 col = "^2";
 892                         else
 893                                 col = "^3";
 894                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 895                         ++j;
 896                 }
 897         }
 898         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 899         MapInfo_ClearTemps();
 900
 901         for(i = 0; i < 10; ++i)
 902         {
 903                 records_reply[i] = strzone(getrecords(i));
 904         }
 905         if(g_cts)
 906                 ladder_reply = strzone(getladder());
 907
 908         rankings_reply = strzone(getrankings());
 909
 910         ClientInit_Spawn();
 911         RandomSeed_Spawn();
 912         PingPLReport_Spawn();
 913
 914         CheatInit();
 915
 916         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 917
 918         // fill sv_curl_serverpackages from .serverpackage files
 919         if(autocvar_sv_curl_serverpackages_auto)
 920         {
 921                 s = "";
 922                 n = tokenize_console(cvar_string("sv_curl_serverpackages"));
 923                 for(i = 0; i < n; ++i)
 924                         if(substring(argv(i), -14, -1) != ".serverpackage")
 925                                 s = strcat(s, " ", argv(i));
 926                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 927                 if(fd >= 0)
 928                 {
 929                         j = search_getsize(fd);
 930                         for(i = 0; i < j; ++i)
 931                                 s = strcat(s, " ", search_getfilename(fd, i));
 932                         search_end(fd);
 933                 }
 934                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 935         }
 936
 937         PlayerStats_Init();
 938
 939         world_initialized = 1;
 940 }
 941
 942 void spawnfunc_light (void)
 943 {
 944         //makestatic (self); // Who the f___ did that?
 945         remove(self);
 946 }
 947
 948 string GetGametype()
 949 {
 950         return GametypeNameFromType(game);
 951 }
 952
 953 string getmapname_stored;
 954 string GetMapname()
 955 {
 956         return mapname;
 957 }
 958
 959 float Map_Count, Map_Current;
 960 string Map_Current_Name;
 961
 962 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 963 float GetMaplistPosition()
 964 {
 965         float pos, idx;
 966         string map;
 967
 968         map = GetMapname();
 969         idx = autocvar_g_maplist_index;
 970
 971         if(idx >= 0)
 972                 if(idx < Map_Count)
 973                         if(map == argv(idx))
 974                                 return idx;
 975
 976         for(pos = 0; pos < Map_Count; ++pos)
 977                 if(map == argv(pos))
 978                         return pos;
 979
 980         // resume normal maplist rotation if current map is not in g_maplist
 981         return idx;
 982 }
 983
 984 float MapHasRightSize(string map)
 985 {
 986         float fh;
 987         if(currentbots || autocvar_bot_number || player_count < autocvar_minplayers)
 988         if(autocvar_g_maplist_check_waypoints)
 989         {
 990                 dprint("checkwp "); dprint(map);
 991                 if(!fexists(strcat("maps/", map, ".waypoints")))
 992                 {
 993                         dprint(": no waypoints\n");
 994                         return FALSE;
 995                 }
 996                 dprint(": has waypoints\n");
 997         }
 998
 999         // open map size restriction file
1000         dprint("opensize "); dprint(map);
1001         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
1002         if(fh >= 0)
1003         {
1004                 float mapmin, mapmax;
1005                 dprint(": ok, ");
1006                 mapmin = stof(fgets(fh));
1007                 mapmax = stof(fgets(fh));
1008                 fclose(fh);
1009                 if(player_count < mapmin)
1010                 {
1011                         dprint("not enough\n");
1012                         return FALSE;
1013                 }
1014                 if(player_count > mapmax)
1015                 {
1016                         dprint("too many\n");
1017                         return FALSE;
1018                 }
1019                 dprint("right size\n");
1020                 return TRUE;
1021         }
1022         dprint(": not found\n");
1023         return TRUE;
1024 }
1025
1026 string Map_Filename(float position)
1027 {
1028         return strcat("maps/", argv(position), ".bsp");
1029 }
1030
1031 string strwords(string s, float w)
1032 {
1033         float endpos;
1034         for(endpos = 0; w && endpos >= 0; --w)
1035                 endpos = strstrofs(s, " ", endpos + 1);
1036         if(endpos < 0)
1037                 return s;
1038         else
1039                 return substring(s, 0, endpos);
1040 }
1041
1042 float strhasword(string s, string w)
1043 {
1044         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
1045 }
1046
1047 void Map_MarkAsRecent(string m)
1048 {
1049         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", autocvar_g_maplist_mostrecent), max(0, autocvar_g_maplist_mostrecent_count)));
1050 }
1051
1052 float Map_IsRecent(string m)
1053 {
1054         return strhasword(autocvar_g_maplist_mostrecent, m);
1055 }
1056
1057 float Map_Check(float position, float pass)
1058 {
1059         string filename;
1060         string map_next;
1061         map_next = argv(position);
1062         if(pass <= 1)
1063         {
1064                 if(Map_IsRecent(map_next))
1065                         return 0;
1066         }
1067         filename = Map_Filename(position);
1068         if(MapInfo_CheckMap(map_next))
1069         {
1070                 if(pass == 2)
1071                         return 1;
1072                 if(MapHasRightSize(map_next))
1073                         return 1;
1074                 return 0;
1075         }
1076         else
1077                 dprint( "Couldn't select '", filename, "'..\n" );
1078
1079         return 0;
1080 }
1081
1082 void Map_Goto_SetStr(string nextmapname)
1083 {
1084         if(getmapname_stored != "")
1085                 strunzone(getmapname_stored);
1086         if(nextmapname == "")
1087                 getmapname_stored = "";
1088         else
1089                 getmapname_stored = strzone(nextmapname);
1090 }
1091
1092 void Map_Goto_SetFloat(float position)
1093 {
1094         cvar_set("g_maplist_index", ftos(position));
1095         Map_Goto_SetStr(argv(position));
1096 }
1097
1098 void GameResetCfg()
1099 {
1100         // settings persist, except...
1101         localcmd("\nsettemp_restore\n");
1102 }
1103
1104 void Map_Goto()
1105 {
1106         GameResetCfg();
1107         MapInfo_LoadMap(getmapname_stored);
1108 }
1109
1110 // return codes of map selectors:
1111 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1112 //   -2 = permanent failure
1113 float() MaplistMethod_Iterate = // usual method
1114 {
1115         float pass, i;
1116
1117         for(pass = 1; pass <= 2; ++pass)
1118         {
1119                 for(i = 1; i < Map_Count; ++i)
1120                 {
1121                         float mapindex;
1122                         mapindex = mod(i + Map_Current, Map_Count);
1123                         if(Map_Check(mapindex, pass))
1124                                 return mapindex;
1125                 }
1126         }
1127         return -1;
1128 }
1129
1130 float() MaplistMethod_Repeat = // fallback method
1131 {
1132         if(Map_Check(Map_Current, 2))
1133                 return Map_Current;
1134         return -2;
1135 }
1136
1137 float() MaplistMethod_Random = // random map selection
1138 {
1139         float i, imax;
1140
1141         imax = 42;
1142
1143         for(i = 0; i <= imax; ++i)
1144         {
1145                 float mapindex;
1146                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1147                 if(Map_Check(mapindex, 1))
1148                         return mapindex;
1149         }
1150         return -1;
1151 }
1152
1153 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1154 // the exponent sets a bias on the map selection:
1155 // the higher the exponent, the less likely "shortly repeated" same maps are
1156 {
1157         float i, j, imax, insertpos;
1158
1159         imax = 42;
1160
1161         for(i = 0; i <= imax; ++i)
1162         {
1163                 string newlist;
1164
1165                 // now reinsert this at another position
1166                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1167                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1168                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1169                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1170
1171                 // insert the current map there
1172                 newlist = "";
1173                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1174                         newlist = strcat(newlist, " ", argv(j));
1175                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1176                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1177                         newlist = strcat(newlist, " ", argv(j));
1178                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1179                 cvar_set("g_maplist", newlist);
1180                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1181
1182                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1183                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1184                 if(Map_Check(Map_Current, 1))
1185                         return Map_Current;
1186         }
1187         return -1;
1188 }
1189
1190 void Maplist_Init()
1191 {
1192         Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1193         if(Map_Count == 0)
1194         {
1195                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1196                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1197                 if(autocvar_g_maplist_shuffle)
1198                         ShuffleMaplist();
1199                 localcmd("\nmenu_cmd sync\n");
1200                 Map_Count = tokenizebyseparator(autocvar_g_maplist, " ");
1201         }
1202         if(Map_Count == 0)
1203                 error("empty maplist, cannot select a new map");
1204         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1205
1206         if(Map_Current_Name)
1207                 strunzone(Map_Current_Name);
1208         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1209         // this may or may not be correct, but who cares, in the worst case a map
1210         // isn't chosen in the first pass that should have been
1211 }
1212
1213 string GetNextMap()
1214 {
1215         float nextMap;
1216
1217         Maplist_Init();
1218         nextMap = -1;
1219
1220         if(nextMap == -1)
1221                 if(autocvar_g_maplist_shuffle > 0)
1222                         nextMap = MaplistMethod_Shuffle(autocvar_g_maplist_shuffle + 1);
1223
1224         if(nextMap == -1)
1225                 if(autocvar_g_maplist_selectrandom)
1226                         nextMap = MaplistMethod_Random();
1227
1228         if(nextMap == -1)
1229                 nextMap = MaplistMethod_Iterate();
1230
1231         if(nextMap == -1)
1232                 nextMap = MaplistMethod_Repeat();
1233
1234         if(nextMap >= 0)
1235         {
1236                 Map_Goto_SetFloat(nextMap);
1237                 return getmapname_stored;
1238         }
1239
1240         return "";
1241 }
1242
1243 float DoNextMapOverride()
1244 {
1245         if(autocvar_g_campaign)
1246         {
1247                 CampaignPostIntermission();
1248                 alreadychangedlevel = TRUE;
1249                 return TRUE;
1250         }
1251         if(autocvar_quit_when_empty)
1252         {
1253                 if(player_count <= currentbots)
1254                 {
1255                         localcmd("quit\n");
1256                         alreadychangedlevel = TRUE;
1257                         return TRUE;
1258                 }
1259         }
1260         if(autocvar_quit_and_redirect != "")
1261         {
1262                 redirection_target = strzone(autocvar_quit_and_redirect);
1263                 alreadychangedlevel = TRUE;
1264                 return TRUE;
1265         }
1266         if (autocvar_samelevel) // if samelevel is set, stay on same level
1267         {
1268                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1269                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1270                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1271                 localcmd("restart\n");
1272                 //changelevel (mapname);
1273                 alreadychangedlevel = TRUE;
1274                 return TRUE;
1275         }
1276         if(autocvar_nextmap != "")
1277                 if(MapInfo_CheckMap(autocvar_nextmap))
1278                 {
1279                         Map_Goto_SetStr(autocvar_nextmap);
1280                         Map_Goto();
1281                         alreadychangedlevel = TRUE;
1282                         return TRUE;
1283                 }
1284         if(autocvar_lastlevel)
1285         {
1286                 GameResetCfg();
1287                 localcmd("set lastlevel 0\ntogglemenu\n");
1288                 alreadychangedlevel = TRUE;
1289                 return TRUE;
1290         }
1291         return FALSE;
1292 }
1293
1294 void GotoNextMap()
1295 {
1296         //string nextmap;
1297         //float n, nummaps;
1298         //string s;
1299         if (alreadychangedlevel)
1300                 return;
1301         alreadychangedlevel = TRUE;
1302
1303         {
1304                 string nextMap;
1305                 float allowReset;
1306
1307                 for(allowReset = 1; allowReset >= 0; --allowReset)
1308                 {
1309                         nextMap = GetNextMap();
1310                         if(nextMap != "")
1311                                 break;
1312
1313                         if(allowReset)
1314                         {
1315                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1316                                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1317                                 if(autocvar_g_maplist_shuffle)
1318                                         ShuffleMaplist();
1319                                 localcmd("\nmenu_cmd sync\n");
1320                         }
1321                         else
1322                         {
1323                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1324                         }
1325                 }
1326                 Map_Goto();
1327         }
1328 }
1329
1330
1331 /*
1332 ============
1333 IntermissionThink
1334
1335 When the player presses attack or jump, change to the next level
1336 ============
1337 */
1338 .float autoscreenshot;
1339 void() MapVote_Start;
1340 void() MapVote_Think;
1341 float mapvote_initialized;
1342 void IntermissionThink()
1343 {
1344         FixIntermissionClient(self);
1345
1346         if(autocvar_sv_autoscreenshot)
1347         if(self.autoscreenshot > 0)
1348         if(time > self.autoscreenshot)
1349         {
1350                 self.autoscreenshot = -1;
1351                 if(clienttype(self) == CLIENTTYPE_REAL)
1352                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1353                 return;
1354         }
1355
1356         if (time < intermission_exittime)
1357                 return;
1358
1359         if(!mapvote_initialized)
1360                 if (time < intermission_exittime + 10 && !(self.BUTTON_ATCK || self.BUTTON_JUMP || self.BUTTON_ATCK2 || self.BUTTON_HOOK || self.BUTTON_USE))
1361                         return;
1362
1363         MapVote_Start();
1364 }
1365
1366 /*
1367 ============
1368 FindIntermission
1369
1370 Returns the entity to view from
1371 ============
1372 */
1373 /*
1374 entity FindIntermission()
1375 {
1376         local   entity spot;
1377         local   float cyc;
1378
1379 // look for info_intermission first
1380         spot = find (world, classname, "info_intermission");
1381         if (spot)
1382         {       // pick a random one
1383                 cyc = random() * 4;
1384                 while (cyc > 1)
1385                 {
1386                         spot = find (spot, classname, "info_intermission");
1387                         if (!spot)
1388                                 spot = find (spot, classname, "info_intermission");
1389                         cyc = cyc - 1;
1390                 }
1391                 return spot;
1392         }
1393
1394 // then look for the start position
1395         spot = find (world, classname, "info_player_start");
1396         if (spot)
1397                 return spot;
1398
1399 // testinfo_player_start is only found in regioned levels
1400         spot = find (world, classname, "testplayerstart");
1401         if (spot)
1402                 return spot;
1403
1404 // then look for the start position
1405         spot = find (world, classname, "info_player_deathmatch");
1406         if (spot)
1407                 return spot;
1408
1409         //objerror ("FindIntermission: no spot");
1410         return world;
1411 }
1412 */
1413
1414 /*
1415 ===============================================================================
1416
1417 RULES
1418
1419 ===============================================================================
1420 */
1421
1422 void DumpStats(float final)
1423 {
1424         float file;
1425         string s;
1426         float to_console;
1427         float to_eventlog;
1428         float to_file;
1429         float i;
1430
1431         to_console = autocvar_sv_logscores_console;
1432         to_eventlog = autocvar_sv_eventlog;
1433         to_file = autocvar_sv_logscores_file;
1434
1435         if(!final)
1436         {
1437                 to_console = TRUE; // always print printstats replies
1438                 to_eventlog = FALSE; // but never print them to the event log
1439         }
1440
1441         if(to_eventlog)
1442                 if(autocvar_sv_eventlog_console)
1443                         to_console = FALSE; // otherwise we get the output twice
1444
1445         if(final)
1446                 s = ":scores:";
1447         else
1448                 s = ":status:";
1449         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1450
1451         if(to_console)
1452                 print(s, "\n");
1453         if(to_eventlog)
1454                 GameLogEcho(s);
1455         if(to_file)
1456         {
1457                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1458                 if(file == -1)
1459                         to_file = FALSE;
1460                 else
1461                         fputs(file, strcat(s, "\n"));
1462         }
1463
1464         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1465         if(to_console)
1466                 print(s, "\n");
1467         if(to_eventlog)
1468                 GameLogEcho(s);
1469         if(to_file)
1470                 fputs(file, strcat(s, "\n"));
1471
1472         FOR_EACH_CLIENT(other)
1473         {
1474                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && autocvar_sv_logscores_bots))
1475                 {
1476                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1477                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1478                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1479                                 s = strcat(s, ftos(other.team), ":");
1480                         else
1481                                 s = strcat(s, "spectator:");
1482
1483                         if(to_console)
1484                                 print(s, other.netname, "\n");
1485                         if(to_eventlog)
1486                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1487                         if(to_file)
1488                                 fputs(file, strcat(s, other.netname, "\n"));
1489                 }
1490         }
1491
1492         if(teamplay)
1493         {
1494                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1495                 if(to_console)
1496                         print(s, "\n");
1497                 if(to_eventlog)
1498                         GameLogEcho(s);
1499                 if(to_file)
1500                         fputs(file, strcat(s, "\n"));
1501
1502                 for(i = 1; i < 16; ++i)
1503                 {
1504                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1505                         s = strcat(s, ":", ftos(i));
1506                         if(to_console)
1507                                 print(s, "\n");
1508                         if(to_eventlog)
1509                                 GameLogEcho(s);
1510                         if(to_file)
1511                                 fputs(file, strcat(s, "\n"));
1512                 }
1513         }
1514
1515         if(to_console)
1516                 print(":end\n");
1517         if(to_eventlog)
1518                 GameLogEcho(":end");
1519         if(to_file)
1520         {
1521                 fputs(file, ":end\n");
1522                 fclose(file);
1523         }
1524 }
1525
1526 void FixIntermissionClient(entity e)
1527 {
1528         string s;
1529         if(!e.autoscreenshot) // initial call
1530         {
1531                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1532                 e.health = -2342;
1533                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1534                 e.solid = SOLID_NOT;
1535                 e.movetype = MOVETYPE_NONE;
1536                 e.takedamage = DAMAGE_NO;
1537                 if(e.weaponentity)
1538                 {
1539                         e.weaponentity.effects = EF_NODRAW;
1540                         if (e.weaponentity.weaponentity)
1541                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1542                 }
1543                 if(clienttype(e) == CLIENTTYPE_REAL)
1544                 {
1545                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1546                         s = autocvar_sv_intermission_cdtrack;
1547                         if(s != "")
1548                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1549                         msg_entity = e;
1550                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1551                 }
1552         }
1553 }
1554
1555
1556 /*
1557 go to the next level for deathmatch
1558 only called if a time or frag limit has expired
1559 */
1560 void NextLevel()
1561 {
1562         gameover = TRUE;
1563
1564         intermission_running = 1;
1565
1566 // enforce a wait time before allowing changelevel
1567         if(player_count > 0)
1568                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1569         else
1570                 intermission_exittime = -1;
1571
1572         /*
1573         WriteByte (MSG_ALL, SVC_CDTRACK);
1574         WriteByte (MSG_ALL, 3);
1575         WriteByte (MSG_ALL, 3);
1576         // done in FixIntermission
1577         */
1578
1579         //pos = FindIntermission ();
1580
1581         VoteReset();
1582
1583         DumpStats(TRUE);
1584
1585         // send statistics
1586         entity e;
1587         PlayerStats_EndMatch(1);
1588         FOR_EACH_CLIENT(e)
1589                 PlayerStats_AddGlobalInfo(e);
1590         PlayerStats_Shutdown();
1591         WeaponStats_Shutdown();
1592
1593         if(autocvar_sv_eventlog)
1594                 GameLogEcho(":gameover");
1595
1596         GameLogClose();
1597
1598         FOR_EACH_PLAYER(other) {
1599                 FixIntermissionClient(other);
1600                 if(other.winning)
1601                         bprint(other.netname, " ^7wins.\n");
1602         }
1603
1604         if(autocvar_g_campaign)
1605                 CampaignPreIntermission();
1606
1607         localcmd("\nsv_hook_gameend\n");
1608 }
1609
1610 /*
1611 ============
1612 CheckRules_Player
1613
1614 Exit deathmatch games upon conditions
1615 ============
1616 */
1617 void CheckRules_Player()
1618 {
1619         if (gameover)   // someone else quit the game already
1620                 return;
1621
1622         if(self.deadflag == DEAD_NO)
1623                 self.play_time += frametime;
1624
1625         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1626         //   (div0: and that in CheckRules_World please)
1627 }
1628
1629 float checkrules_equality;
1630 float checkrules_suddendeathwarning;
1631 float checkrules_suddendeathend;
1632 float checkrules_overtimesadded; //how many overtimes have been already added
1633
1634 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1635 float WINNING_YES = 1; // winner found
1636 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1637 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1638
1639 float InitiateSuddenDeath()
1640 {
1641         // Check first whether normal overtimes could be added before initiating suddendeath mode
1642         // - for this timelimit_overtime needs to be >0 of course
1643         // - also check the winning condition calculated in the previous frame and only add normal overtime
1644         //   again, if at the point at which timelimit would be extended again, still no winner was found
1645         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < autocvar_timelimit_overtimes) && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1646         {
1647                 return 1; // need to call InitiateOvertime later
1648         }
1649         else
1650         {
1651                 if(!checkrules_suddendeathend)
1652                 {
1653                         checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1654                         if(g_race && !g_race_qualifying)
1655                                 race_StartCompleting();
1656                 }
1657                 return 0;
1658         }
1659 }
1660
1661 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1662 {
1663         ++checkrules_overtimesadded;
1664         //add one more overtime by simply extending the timelimit
1665         float tl;
1666         tl = autocvar_timelimit;
1667         tl += autocvar_timelimit_overtime;
1668         cvar_set("timelimit", ftos(tl));
1669         string minutesPlural;
1670         if (autocvar_timelimit_overtime == 1)
1671                 minutesPlural = " ^3minute";
1672         else
1673                 minutesPlural = " ^3minutes";
1674
1675         bcenterprint(
1676                 strcat(
1677                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1678                         ftos(autocvar_timelimit_overtime),
1679                         minutesPlural,
1680                         " to the game!"
1681                 )
1682         );
1683 }
1684
1685 float GetWinningCode(float fraglimitreached, float equality)
1686 {
1687         if(autocvar_g_campaign == 1)
1688                 if(fraglimitreached)
1689                         return WINNING_YES;
1690                 else
1691                         return WINNING_NO;
1692
1693         else
1694                 if(equality)
1695                         if(fraglimitreached)
1696                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1697                         else
1698                                 return WINNING_NEVER;
1699                 else
1700                         if(fraglimitreached)
1701                                 return WINNING_YES;
1702                         else
1703                                 return WINNING_NO;
1704 }
1705
1706 // set the .winning flag for exactly those players with a given field value
1707 void SetWinners(.float field, float value)
1708 {
1709         entity head;
1710         FOR_EACH_PLAYER(head)
1711                 head.winning = (head.field == value);
1712 }
1713
1714 // set the .winning flag for those players with a given field value
1715 void AddWinners(.float field, float value)
1716 {
1717         entity head;
1718         FOR_EACH_PLAYER(head)
1719                 if(head.field == value)
1720                         head.winning = 1;
1721 }
1722
1723 // clear the .winning flags
1724 void ClearWinners(void)
1725 {
1726         entity head;
1727         FOR_EACH_PLAYER(head)
1728                 head.winning = 0;
1729 }
1730
1731 // Onslaught winning condition:
1732 // game terminates if only one team has a working generator (or none)
1733 float WinningCondition_Onslaught()
1734 {
1735         entity head;
1736         float t1, t2, t3, t4;
1737
1738         WinningConditionHelper(); // set worldstatus
1739
1740         if(inWarmupStage)
1741                 return WINNING_NO;
1742
1743         // first check if the game has ended
1744         t1 = t2 = t3 = t4 = 0;
1745         head = find(world, classname, "onslaught_generator");
1746         while (head)
1747         {
1748                 if (head.health > 0)
1749                 {
1750                         if (head.team == COLOR_TEAM1) t1 = 1;
1751                         if (head.team == COLOR_TEAM2) t2 = 1;
1752                         if (head.team == COLOR_TEAM3) t3 = 1;
1753                         if (head.team == COLOR_TEAM4) t4 = 1;
1754                 }
1755                 head = find(head, classname, "onslaught_generator");
1756         }
1757         if (t1 + t2 + t3 + t4 < 2)
1758         {
1759                 // game over, only one team remains (or none)
1760                 ClearWinners();
1761                 if (t1) SetWinners(team, COLOR_TEAM1);
1762                 if (t2) SetWinners(team, COLOR_TEAM2);
1763                 if (t3) SetWinners(team, COLOR_TEAM3);
1764                 if (t4) SetWinners(team, COLOR_TEAM4);
1765                 dprint("Have a winner, ending game.\n");
1766                 return WINNING_YES;
1767         }
1768
1769         // Two or more teams remain
1770         return WINNING_NO;
1771 }
1772
1773 float LMS_NewPlayerLives()
1774 {
1775         float fl;
1776         fl = autocvar_fraglimit;
1777         if(fl == 0)
1778                 fl = 999;
1779
1780         // first player has left the game for dying too much? Nobody else can get in.
1781         if(lms_lowest_lives < 1)
1782                 return 0;
1783
1784         if(!autocvar_g_lms_join_anytime)
1785                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
1786                         return 0;
1787
1788         return bound(1, lms_lowest_lives, fl);
1789 }
1790
1791 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1792 // they win. Otherwise the defending team wins once the timelimit passes.
1793 void assault_new_round();
1794 float WinningCondition_Assault()
1795 {
1796         float status;
1797
1798         WinningConditionHelper(); // set worldstatus
1799
1800         status = WINNING_NO;
1801         // as the timelimit has not yet passed just assume the defending team will win
1802         if(assault_attacker_team == COLOR_TEAM1)
1803         {
1804                 SetWinners(team, COLOR_TEAM2);
1805         }
1806         else
1807         {
1808                 SetWinners(team, COLOR_TEAM1);
1809         }
1810
1811         entity ent;
1812         ent = find(world, classname, "target_assault_roundend");
1813         if(ent)
1814         {
1815                 if(ent.winning) // round end has been triggered by attacking team
1816                 {
1817                         bprint("ASSAULT: round completed...\n");
1818                         SetWinners(team, assault_attacker_team);
1819
1820                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1821
1822                         if(ent.cnt == 1 || autocvar_g_campaign) // this was the second round
1823                         {
1824                                 status = WINNING_YES;
1825                         }
1826                         else
1827                         {
1828                                 entity oldself;
1829                                 oldself = self;
1830                                 self = ent;
1831                                 assault_new_round();
1832                                 self = oldself;
1833                         }
1834                 }
1835         }
1836
1837         return status;
1838 }
1839
1840 // LMS winning condition: game terminates if and only if there's at most one
1841 // one player who's living lives. Top two scores being equal cancels the time
1842 // limit.
1843 float WinningCondition_LMS()
1844 {
1845         entity head, head2;
1846         float have_player;
1847         float have_players;
1848         float l;
1849
1850         have_player = FALSE;
1851         have_players = FALSE;
1852         l = LMS_NewPlayerLives();
1853
1854         head = find(world, classname, "player");
1855         if(head)
1856                 have_player = TRUE;
1857         head2 = find(head, classname, "player");
1858         if(head2)
1859                 have_players = TRUE;
1860
1861         if(have_player)
1862         {
1863                 // we have at least one player
1864                 if(have_players)
1865                 {
1866                         // two or more active players - continue with the game
1867                 }
1868                 else
1869                 {
1870                         // exactly one player?
1871
1872                         ClearWinners();
1873                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1874
1875                         if(l)
1876                         {
1877                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1878                                 return WINNING_NO;
1879                         }
1880                         else
1881                         {
1882                                 // a winner!
1883                                 // and assign him his first place
1884                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1885                                 return WINNING_YES;
1886                         }
1887                 }
1888         }
1889         else
1890         {
1891                 // nobody is playing at all...
1892                 if(l)
1893                 {
1894                         // wait for players...
1895                 }
1896                 else
1897                 {
1898                         // SNAFU (maybe a draw game?)
1899                         ClearWinners();
1900                         dprint("No players, ending game.\n");
1901                         return WINNING_YES;
1902                 }
1903         }
1904
1905         // When we get here, we have at least two players who are actually LIVING,
1906         // now check if the top two players have equal score.
1907         WinningConditionHelper();
1908
1909         ClearWinners();
1910         if(WinningConditionHelper_winner)
1911                 WinningConditionHelper_winner.winning = TRUE;
1912         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1913                 return WINNING_NEVER;
1914
1915         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1916         return WINNING_NO;
1917 }
1918
1919 void ShuffleMaplist()
1920 {
1921         cvar_set("g_maplist", shufflewords(autocvar_g_maplist));
1922 }
1923
1924 float leaderfrags;
1925 float WinningCondition_Scores(float limit, float leadlimit)
1926 {
1927         float limitreached;
1928
1929         // TODO make everything use THIS winning condition (except LMS)
1930         WinningConditionHelper();
1931
1932         if(teamplay)
1933         {
1934                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1935                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1936                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1937                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1938         }
1939
1940         ClearWinners();
1941         if(WinningConditionHelper_winner)
1942                 WinningConditionHelper_winner.winning = 1;
1943         if(WinningConditionHelper_winnerteam >= 0)
1944                 SetWinners(team, WinningConditionHelper_winnerteam);
1945
1946         if(WinningConditionHelper_lowerisbetter)
1947         {
1948                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1949                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1950                 limit = -limit;
1951         }
1952
1953         if(WinningConditionHelper_zeroisworst)
1954                 leadlimit = 0; // not supported in this mode
1955
1956         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1957         // these modes always score in increments of 1, thus this makes sense
1958         {
1959                 if(leaderfrags != WinningConditionHelper_topscore)
1960                 {
1961                         leaderfrags = WinningConditionHelper_topscore;
1962
1963                         if (limit)
1964                         if (leaderfrags == limit - 1)
1965                                 Announce("1fragleft");
1966                         else if (leaderfrags == limit - 2)
1967                                 Announce("2fragsleft");
1968                         else if (leaderfrags == limit - 3)
1969                                 Announce("3fragsleft");
1970                 }
1971         }
1972
1973         limitreached = FALSE;
1974         if(limit)
1975                 if(WinningConditionHelper_topscore >= limit)
1976                         limitreached = TRUE;
1977         if(leadlimit)
1978         {
1979                 float leadlimitreached;
1980                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1981                 if(autocvar_leadlimit_and_fraglimit)
1982                         limitreached = (limitreached && leadlimitreached);
1983                 else
1984                         limitreached = (limitreached || leadlimitreached);
1985         }
1986
1987         return GetWinningCode(
1988                 WinningConditionHelper_topscore && limitreached,
1989                 WinningConditionHelper_equality
1990         );
1991 }
1992
1993 float WinningCondition_Race(float fraglimit)
1994 {
1995         float wc;
1996         entity p;
1997         float n, c;
1998
1999         n = 0;
2000         c = 0;
2001         FOR_EACH_PLAYER(p)
2002         {
2003                 ++n;
2004                 if(p.race_completed)
2005                         ++c;
2006         }
2007         if(n && (n == c))
2008                 return WINNING_YES;
2009         wc = WinningCondition_Scores(fraglimit, 0);
2010
2011         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
2012         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2013         // do NOT support equality when the laps are all raced!
2014                 return WINNING_STARTSUDDENDEATHOVERTIME;
2015         else
2016                 return WINNING_NEVER;
2017         return wc;
2018 }
2019
2020 void ReadyRestart();
2021 float WinningCondition_QualifyingThenRace(float limit)
2022 {
2023         float wc;
2024         wc = WinningCondition_Scores(limit, 0);
2025
2026         // NEVER initiate overtime
2027         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
2028         {
2029                 return WINNING_YES;
2030         }
2031
2032         return wc;
2033 }
2034
2035 float WinningCondition_RanOutOfSpawns()
2036 {
2037         entity head;
2038
2039         if(have_team_spawns <= 0)
2040                 return WINNING_NO;
2041
2042         if(!some_spawn_has_been_used)
2043                 return WINNING_NO;
2044
2045         team1_score = team2_score = team3_score = team4_score = 0;
2046
2047         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2048         {
2049                 if(head.team == COLOR_TEAM1)
2050                         team1_score = 1;
2051                 else if(head.team == COLOR_TEAM2)
2052                         team2_score = 1;
2053                 else if(head.team == COLOR_TEAM3)
2054                         team3_score = 1;
2055                 else if(head.team == COLOR_TEAM4)
2056                         team4_score = 1;
2057         }
2058
2059         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2060         {
2061                 if(head.team == COLOR_TEAM1)
2062                         team1_score = 1;
2063                 else if(head.team == COLOR_TEAM2)
2064                         team2_score = 1;
2065                 else if(head.team == COLOR_TEAM3)
2066                         team3_score = 1;
2067                 else if(head.team == COLOR_TEAM4)
2068                         team4_score = 1;
2069         }
2070
2071         ClearWinners();
2072         if(team1_score + team2_score + team3_score + team4_score == 0)
2073         {
2074                 checkrules_equality = TRUE;
2075                 return WINNING_YES;
2076         }
2077         else if(team1_score + team2_score + team3_score + team4_score == 1)
2078         {
2079                 float t, i;
2080                 if(team1_score) t = COLOR_TEAM1;
2081                 if(team2_score) t = COLOR_TEAM2;
2082                 if(team3_score) t = COLOR_TEAM3;
2083                 if(team4_score) t = COLOR_TEAM4;
2084                 CheckAllowedTeams(world);
2085                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2086                 {
2087                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2088                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2089                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2090                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2091                 }
2092
2093                 AddWinners(team, t);
2094                 return WINNING_YES;
2095         }
2096         else
2097                 return WINNING_NO;
2098 }
2099
2100 /*
2101 ============
2102 CheckRules_World
2103
2104 Exit deathmatch games upon conditions
2105 ============
2106 */
2107 void CheckRules_World()
2108 {
2109         float timelimit;
2110         float fraglimit;
2111         float leadlimit;
2112
2113         VoteThink();
2114         MapVote_Think();
2115
2116         SetDefaultAlpha();
2117
2118         /*
2119         MapVote_Think should now do that part
2120         if (intermission_running)
2121                 if (time >= intermission_exittime + 60)
2122                 {
2123                         if(!DoNextMapOverride())
2124                                 GotoNextMap();
2125                         return;
2126                 }
2127         */
2128
2129         if (gameover)   // someone else quit the game already
2130         {
2131                 if(player_count == 0) // Nobody there? Then let's go to the next map
2132                         MapVote_Start();
2133                         // this will actually check the player count in the next frame
2134                         // again, but this shouldn't hurt
2135                 return;
2136         }
2137
2138         timelimit = autocvar_timelimit * 60;
2139         fraglimit = autocvar_fraglimit;
2140         leadlimit = autocvar_leadlimit;
2141
2142         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2143         {
2144                 if(timelimit > 0)
2145                         timelimit = 0; // timelimit is not made for warmup
2146                 if(fraglimit > 0)
2147                         fraglimit = 0; // no fraglimit for now
2148                 leadlimit = 0; // no leadlimit for now
2149         }
2150
2151         if(g_onslaught)
2152                 timelimit = 0; // ONS has its own overtime rule
2153
2154         if(timelimit > 0)
2155         {
2156                 timelimit += game_starttime;
2157         }
2158         else if (timelimit < 0)
2159         {
2160                 // endmatch
2161                 NextLevel();
2162                 return;
2163         }
2164
2165         float wantovertime;
2166         wantovertime = 0;
2167
2168         if(checkrules_suddendeathend)
2169         {
2170                 if(!checkrules_suddendeathwarning)
2171                 {
2172                         checkrules_suddendeathwarning = TRUE;
2173                         if(g_race && !g_race_qualifying)
2174                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2175                         else
2176                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2177                 }
2178         }
2179         else
2180         {
2181                 if (timelimit && time >= timelimit)
2182                 {
2183                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2184                         {
2185                                 float totalplayers;
2186                                 float playerswithlaps;
2187                                 float readyplayers;
2188                                 entity head;
2189                                 totalplayers = playerswithlaps = readyplayers = 0;
2190                                 FOR_EACH_PLAYER(head)
2191                                 {
2192                                         ++totalplayers;
2193                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2194                                                 ++playerswithlaps;
2195                                         if(head.ready)
2196                                                 ++readyplayers;
2197                                 }
2198
2199                                 // at least 2 of the players have completed a lap: start the RACE
2200                                 // otherwise, the players should end the qualifying on their own
2201                                 if(readyplayers || playerswithlaps >= 2)
2202                                 {
2203                                         checkrules_suddendeathend = 0;
2204                                         ReadyRestart(); // go to race
2205                                         return;
2206                                 }
2207                                 else
2208                                         wantovertime |= InitiateSuddenDeath();
2209                         }
2210                         else
2211                                 wantovertime |= InitiateSuddenDeath();
2212                 }
2213         }
2214
2215         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2216         {
2217                 NextLevel();
2218                 return;
2219         }
2220
2221         float checkrules_status;
2222         checkrules_status = WinningCondition_RanOutOfSpawns();
2223         if(checkrules_status == WINNING_YES)
2224         {
2225                 bprint("Hey! Someone ran out of spawns!\n");
2226         }
2227         else if(g_race && !g_race_qualifying && timelimit >= 0)
2228         {
2229                 checkrules_status = WinningCondition_Race(fraglimit);
2230                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2231         }
2232         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2233         {
2234                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2235                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2236         }
2237         else if(g_assault)
2238         {
2239                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2240         }
2241         else if(g_lms)
2242         {
2243                 checkrules_status = WinningCondition_LMS();
2244         }
2245         else if (g_onslaught)
2246         {
2247                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2248         }
2249         else
2250         {
2251                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2252                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2253         }
2254
2255         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2256         {
2257                 checkrules_status = WINNING_NEVER;
2258                 checkrules_overtimesadded = -1;
2259                 wantovertime |= InitiateSuddenDeath();
2260         }
2261
2262         if(checkrules_status == WINNING_NEVER)
2263                 // equality cases! Nobody wins if the overtime ends in a draw.
2264                 ClearWinners();
2265
2266         if(wantovertime)
2267         {
2268                 if(checkrules_status == WINNING_NEVER)
2269                         InitiateOvertime();
2270                 else
2271                         checkrules_status = WINNING_YES;
2272         }
2273
2274         if(checkrules_suddendeathend)
2275                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2276                         checkrules_status = WINNING_YES;
2277
2278         if(checkrules_status == WINNING_YES)
2279         {
2280                 //print("WINNING\n");
2281                 NextLevel();
2282         }
2283 }
2284
2285 float mapvote_nextthink;
2286 float mapvote_initialized;
2287 float mapvote_keeptwotime;
2288 float mapvote_timeout;
2289 string mapvote_message;
2290 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2291 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2292 float mapvote_screenshot_dirs_count;
2293
2294 float mapvote_count;
2295 float mapvote_count_real;
2296 string mapvote_maps[MAPVOTE_COUNT];
2297 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2298 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2299 float mapvote_maps_suggested[MAPVOTE_COUNT];
2300 string mapvote_suggestions[MAPVOTE_COUNT];
2301 float mapvote_suggestion_ptr;
2302 float mapvote_voters;
2303 float mapvote_votes[MAPVOTE_COUNT];
2304 float mapvote_run;
2305 float mapvote_detail;
2306 float mapvote_abstain;
2307 .float mapvote;
2308
2309 void MapVote_ClearAllVotes()
2310 {
2311         FOR_EACH_CLIENT(other)
2312                 other.mapvote = 0;
2313 }
2314
2315 string MapVote_Suggest(string m)
2316 {
2317         float i;
2318         if(m == "")
2319                 return "That's not how to use this command.";
2320         if(!autocvar_g_maplist_votable_suggestions)
2321                 return "Suggestions are not accepted on this server.";
2322         if(mapvote_initialized)
2323                 return "Can't suggest - voting is already in progress!";
2324         m = MapInfo_FixName(m);
2325         if(!m)
2326                 return "The map you suggested is not available on this server.";
2327         if(!autocvar_g_maplist_votable_suggestions_override_mostrecent)
2328                 if(Map_IsRecent(m))
2329                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2330
2331         if(!MapInfo_CheckMap(m))
2332                 return "The map you suggested does not support the current game mode.";
2333         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2334                 if(mapvote_suggestions[i] == m)
2335                         return "This map was already suggested.";
2336         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2337         {
2338                 i = floor(random() * mapvote_suggestion_ptr);
2339         }
2340         else
2341         {
2342                 i = mapvote_suggestion_ptr;
2343                 mapvote_suggestion_ptr += 1;
2344         }
2345         if(mapvote_suggestions[i] != "")
2346                 strunzone(mapvote_suggestions[i]);
2347         mapvote_suggestions[i] = strzone(m);
2348         if(autocvar_sv_eventlog)
2349                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2350         return strcat("Suggestion of ", m, " accepted.");
2351 }
2352
2353 void MapVote_AddVotable(string nextMap, float isSuggestion)
2354 {
2355         float j, i, o;
2356         string pakfile, mapfile;
2357
2358         if(nextMap == "")
2359                 return;
2360         for(j = 0; j < mapvote_count; ++j)
2361                 if(mapvote_maps[j] == nextMap)
2362                         return;
2363         // suggestions might be no longer valid/allowed after gametype switch!
2364         if(isSuggestion)
2365                 if(!MapInfo_CheckMap(nextMap))
2366                         return;
2367         mapvote_maps[mapvote_count] = strzone(nextMap);
2368         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2369
2370         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2371         {
2372                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2373                 pakfile = whichpack(strcat(mapfile, ".tga"));
2374                 if(pakfile == "")
2375                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2376                 if(pakfile == "")
2377                         pakfile = whichpack(strcat(mapfile, ".png"));
2378                 if(pakfile != "")
2379                         break;
2380         }
2381         if(i >= mapvote_screenshot_dirs_count)
2382                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2383         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2384                 pakfile = substring(pakfile, o, -1);
2385
2386         mapvote_maps_screenshot_dir[mapvote_count] = i;
2387         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2388
2389         mapvote_count += 1;
2390 }
2391
2392 void MapVote_Spawn();
2393 void MapVote_Init()
2394 {
2395         float i;
2396         float nmax, smax;
2397
2398         MapVote_ClearAllVotes();
2399
2400         mapvote_count = 0;
2401         mapvote_detail = !autocvar_g_maplist_votable_nodetail;
2402         mapvote_abstain = autocvar_g_maplist_votable_abstain;
2403
2404         if(mapvote_abstain)
2405                 nmax = min(MAPVOTE_COUNT - 1, autocvar_g_maplist_votable);
2406         else
2407                 nmax = min(MAPVOTE_COUNT, autocvar_g_maplist_votable);
2408         smax = min3(nmax, autocvar_g_maplist_votable_suggestions, mapvote_suggestion_ptr);
2409
2410         // we need this for AddVotable, as that cycles through the screenshot dirs
2411         mapvote_screenshot_dirs_count = tokenize_console(autocvar_g_maplist_votable_screenshot_dir);
2412         if(mapvote_screenshot_dirs_count == 0)
2413                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2414         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2415         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2416                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2417
2418         if(mapvote_suggestion_ptr)
2419                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2420                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2421
2422         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2423                 MapVote_AddVotable(GetNextMap(), FALSE);
2424
2425         if(mapvote_count == 0)
2426         {
2427                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2428                 cvar_set("g_maplist", MapInfo_ListAllAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2429                 if(autocvar_g_maplist_shuffle)
2430                         ShuffleMaplist();
2431                 localcmd("\nmenu_cmd sync\n");
2432                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2433                         MapVote_AddVotable(GetNextMap(), FALSE);
2434         }
2435
2436         mapvote_count_real = mapvote_count;
2437         if(mapvote_abstain)
2438                 MapVote_AddVotable("don't care", 0);
2439
2440         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2441
2442         mapvote_keeptwotime = time + autocvar_g_maplist_votable_keeptwotime;
2443         mapvote_timeout = time + autocvar_g_maplist_votable_timeout;
2444         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2445                 mapvote_keeptwotime = 0;
2446         mapvote_message = "Choose a map and press its key!";
2447
2448         MapVote_Spawn();
2449 }
2450
2451 void MapVote_SendPicture(float id)
2452 {
2453         msg_entity = self;
2454         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2455         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2456         WriteByte(MSG_ONE, id);
2457         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2458 }
2459
2460 float GameCommand_MapVote(string cmd)
2461 {
2462         if(!intermission_running)
2463                 return FALSE;
2464
2465         if(cmd == "mv_getpic")
2466         {
2467                 MapVote_SendPicture(stof(argv(1)));
2468                 return TRUE;
2469         }
2470
2471         return FALSE;
2472 }
2473
2474 float MapVote_GetMapMask()
2475 {
2476         float mask, i, power;
2477         mask = 0;
2478         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2479                 if(mapvote_maps[i] != "")
2480                         mask |= power;
2481         return mask;
2482 }
2483
2484 entity mapvote_ent;
2485 float MapVote_SendEntity(entity to, float sf)
2486 {
2487         float i;
2488
2489         if(sf & 1)
2490                 sf &~= 2; // if we send 1, we don't need to also send 2
2491
2492         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2493         WriteByte(MSG_ENTITY, sf);
2494
2495         if(sf & 1)
2496         {
2497                 // flag 1 == initialization
2498                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2499                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2500                 WriteString(MSG_ENTITY, "");
2501                 WriteByte(MSG_ENTITY, mapvote_count);
2502                 WriteByte(MSG_ENTITY, mapvote_abstain);
2503                 WriteByte(MSG_ENTITY, mapvote_detail);
2504                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2505                 if(mapvote_count <= 8)
2506                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2507                 else
2508                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2509                 for(i = 0; i < mapvote_count; ++i)
2510                         if(mapvote_maps[i] != "")
2511                         {
2512                                 if(mapvote_abstain && i == mapvote_count - 1)
2513                                 {
2514                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2515                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2516                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2517                                 }
2518                                 else
2519                                 {
2520                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2521                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2522                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2523                                 }
2524                         }
2525         }
2526
2527         if(sf & 2)
2528         {
2529                 // flag 2 == update of mask
2530                 if(mapvote_count <= 8)
2531                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2532                 else
2533                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2534         }
2535
2536         if(sf & 4)
2537         {
2538                 if(mapvote_detail)
2539                         for(i = 0; i < mapvote_count; ++i)
2540                                 if(mapvote_maps[i] != "")
2541                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2542
2543                 WriteByte(MSG_ENTITY, to.mapvote);
2544         }
2545
2546         return TRUE;
2547 }
2548
2549 void MapVote_Spawn()
2550 {
2551         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2552 }
2553
2554 void MapVote_TouchMask()
2555 {
2556         mapvote_ent.SendFlags |= 2;
2557 }
2558
2559 void MapVote_TouchVotes(entity voter)
2560 {
2561         mapvote_ent.SendFlags |= 4;
2562 }
2563
2564 float MapVote_Finished(float mappos)
2565 {
2566         string result;
2567         float i;
2568         float didntvote;
2569
2570         if(autocvar_sv_eventlog)
2571         {
2572                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2573                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2574                 didntvote = mapvote_voters;
2575                 for(i = 0; i < mapvote_count; ++i)
2576                         if(mapvote_maps[i] != "")
2577                         {
2578                                 didntvote -= mapvote_votes[i];
2579                                 if(i != mappos)
2580                                 {
2581                                         result = strcat(result, ":", mapvote_maps[i]);
2582                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2583                                 }
2584                         }
2585                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2586
2587                 GameLogEcho(result);
2588                 if(mapvote_maps_suggested[mappos])
2589                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2590         }
2591
2592         FOR_EACH_REALCLIENT(other)
2593                 FixClientCvars(other);
2594
2595         Map_Goto_SetStr(mapvote_maps[mappos]);
2596         Map_Goto();
2597         alreadychangedlevel = TRUE;
2598         return TRUE;
2599 }
2600 void MapVote_CheckRules_1()
2601 {
2602         float i;
2603
2604         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2605         {
2606                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2607                 mapvote_votes[i] = 0;
2608         }
2609
2610         mapvote_voters = 0;
2611         FOR_EACH_REALCLIENT(other)
2612         {
2613                 ++mapvote_voters;
2614                 if(other.mapvote)
2615                 {
2616                         i = other.mapvote - 1;
2617                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2618                         mapvote_votes[i] = mapvote_votes[i] + 1;
2619                 }
2620         }
2621 }
2622
2623 float MapVote_CheckRules_2()
2624 {
2625         float i;
2626         float firstPlace, secondPlace;
2627         float firstPlaceVotes, secondPlaceVotes;
2628         float mapvote_voters_real;
2629         string result;
2630
2631         if(mapvote_count_real == 1)
2632                 return MapVote_Finished(0);
2633
2634         mapvote_voters_real = mapvote_voters;
2635         if(mapvote_abstain)
2636                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2637
2638         RandomSelection_Init();
2639         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2640                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2641         firstPlace = RandomSelection_chosen_float;
2642         firstPlaceVotes = RandomSelection_best_priority;
2643         //dprint("First place: ", ftos(firstPlace), "\n");
2644         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2645
2646         RandomSelection_Init();
2647         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2648                 if(i != firstPlace)
2649                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2650         secondPlace = RandomSelection_chosen_float;
2651         secondPlaceVotes = RandomSelection_best_priority;
2652         //dprint("Second place: ", ftos(secondPlace), "\n");
2653         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2654
2655         if(firstPlace == -1)
2656                 error("No first place in map vote... WTF?");
2657
2658         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2659                 return MapVote_Finished(firstPlace);
2660
2661         if(mapvote_keeptwotime)
2662                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2663                 {
2664                         float didntvote;
2665                         MapVote_TouchMask();
2666                         mapvote_message = "Now decide between the TOP TWO!";
2667                         mapvote_keeptwotime = 0;
2668                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2669                         result = strcat(result, ":", ftos(firstPlaceVotes));
2670                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2671                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2672                         didntvote = mapvote_voters;
2673                         for(i = 0; i < mapvote_count; ++i)
2674                                 if(mapvote_maps[i] != "")
2675                                 {
2676                                         didntvote -= mapvote_votes[i];
2677                                         if(i != firstPlace)
2678                                                 if(i != secondPlace)
2679                                                 {
2680                                                         result = strcat(result, ":", mapvote_maps[i]);
2681                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2682                                                         if(i < mapvote_count_real)
2683                                                         {
2684                                                                 strunzone(mapvote_maps[i]);
2685                                                                 mapvote_maps[i] = "";
2686                                                                 strunzone(mapvote_maps_pakfile[i]);
2687                                                                 mapvote_maps_pakfile[i] = "";
2688                                                         }
2689                                                 }
2690                                 }
2691                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2692                         if(autocvar_sv_eventlog)
2693                                 GameLogEcho(result);
2694                 }
2695
2696         return FALSE;
2697 }
2698 void MapVote_Tick()
2699 {
2700         float keeptwo;
2701         float totalvotes;
2702
2703         keeptwo = mapvote_keeptwotime;
2704         MapVote_CheckRules_1(); // count
2705         if(MapVote_CheckRules_2()) // decide
2706                 return;
2707
2708         totalvotes = 0;
2709         FOR_EACH_REALCLIENT(other)
2710         {
2711                 // hide scoreboard again
2712                 if(other.health != 2342)
2713                 {
2714                         other.health = 2342;
2715                         other.impulse = 0;
2716                         if(clienttype(other) == CLIENTTYPE_REAL)
2717                         {
2718                                 msg_entity = other;
2719                                 WriteByte(MSG_ONE, SVC_FINALE);
2720                                 WriteString(MSG_ONE, "");
2721                         }
2722                 }
2723
2724                 // clear possibly invalid votes
2725                 if(mapvote_maps[other.mapvote - 1] == "")
2726                         other.mapvote = 0;
2727                 // use impulses as new vote
2728                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2729                         if(mapvote_maps[other.impulse - 1] != "")
2730                         {
2731                                 other.mapvote = other.impulse;
2732                                 MapVote_TouchVotes(other);
2733                         }
2734                 other.impulse = 0;
2735
2736                 if(other.mapvote)
2737                         ++totalvotes;
2738         }
2739
2740         MapVote_CheckRules_1(); // just count
2741 }
2742 void MapVote_Start()
2743 {
2744         if(mapvote_run)
2745                 return;
2746
2747         // wait for stats to be sent first
2748         if(!playerstats_waitforme)
2749                 return;
2750
2751         MapInfo_Enumerate();
2752         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2753                 mapvote_run = TRUE;
2754 }
2755 void MapVote_Think()
2756 {
2757         if(!mapvote_run)
2758                 return;
2759
2760         if(alreadychangedlevel)
2761                 return;
2762
2763         if(time < mapvote_nextthink)
2764                 return;
2765         //dprint("tick\n");
2766
2767         mapvote_nextthink = time + 0.5;
2768
2769         if(!mapvote_initialized)
2770         {
2771                 if(autocvar_rescan_pending == 1)
2772                 {
2773                         cvar_set("rescan_pending", "2");
2774                         localcmd("fs_rescan\nrescan_pending 3\n");
2775                         return;
2776                 }
2777                 else if(autocvar_rescan_pending == 2)
2778                 {
2779                         return;
2780                 }
2781                 else if(autocvar_rescan_pending == 3)
2782                 {
2783                         // now build missing mapinfo files
2784                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2785                                 return;
2786
2787                         // we're done, start the timer
2788                         cvar_set("rescan_pending", "0");
2789                 }
2790
2791                 mapvote_initialized = TRUE;
2792                 if(DoNextMapOverride())
2793                         return;
2794                 if(!autocvar_g_maplist_votable || player_count <= 0)
2795                 {
2796                         GotoNextMap();
2797                         return;
2798                 }
2799                 MapVote_Init();
2800         }
2801
2802         MapVote_Tick();
2803 }
2804
2805 string GotoMap(string m)
2806 {
2807         if(!MapInfo_CheckMap(m))
2808                 return "The map you chose is not available on this server.";
2809         cvar_set("nextmap", m);
2810         cvar_set("timelimit", "-1");
2811         if(mapvote_initialized || alreadychangedlevel)
2812         {
2813                 if(DoNextMapOverride())
2814                         return "Map switch initiated.";
2815                 else
2816                         return "Hm... no. For some reason I like THIS map more.";
2817         }
2818         else
2819                 return "Map switch will happen after scoreboard.";
2820 }
2821
2822
2823 void EndFrame()
2824 {
2825         float altime;
2826         FOR_EACH_REALCLIENT(self)
2827         {
2828                 if(self.classname == "spectator")
2829                 {
2830                         if(self.enemy.typehitsound)
2831                                 self.typehit_time = time;
2832                         else if(self.enemy.hitsound)
2833                                 self.hit_time = time;
2834                 }
2835                 else
2836                 {
2837                         if(self.typehitsound)
2838                                 self.typehit_time = time;
2839                         else if(self.hitsound)
2840                                 self.hit_time = time;
2841                 }
2842         }
2843         altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2844         // add 1 frametime because after this, engine SV_Physics
2845         // increases time by a frametime and then networks the frame
2846         // add another frametime because client shows everything with
2847         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2848         // needed!
2849         FOR_EACH_CLIENT(self)
2850         {
2851                 self.hitsound = FALSE;
2852                 self.typehitsound = FALSE;
2853                 antilag_record(self, altime);
2854         }
2855 }
2856
2857
2858 /*
2859  * RedirectionThink:
2860  * returns TRUE if redirecting
2861  */
2862 float redirection_timeout;
2863 float redirection_nextthink;
2864 float RedirectionThink()
2865 {
2866         float clients_found;
2867
2868         if(redirection_target == "")
2869                 return FALSE;
2870
2871         if(!redirection_timeout)
2872         {
2873                 cvar_set("sv_public", "-2");
2874                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2875                 if(redirection_target == "self")
2876                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2877                 else
2878                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2879         }
2880
2881         if(time < redirection_nextthink)
2882                 return TRUE;
2883
2884         redirection_nextthink = time + 1;
2885
2886         clients_found = 0;
2887         FOR_EACH_REALCLIENT(self)
2888         {
2889                 print("Redirecting: sending connect command to ", self.netname, "\n");
2890                 if(redirection_target == "self")
2891                         stuffcmd(self, "\ndisconnect; reconnect\n");
2892                 else
2893                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2894                 ++clients_found;
2895         }
2896
2897         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2898
2899         if(time > redirection_timeout || clients_found == 0)
2900                 localcmd("\nwait; wait; wait; quit\n");
2901
2902         return TRUE;
2903 }
2904
2905 void TargetMusic_RestoreGame();
2906 void RestoreGame()
2907 {
2908         // Loaded from a save game
2909         // some things then break, so let's work around them...
2910
2911         // Progs DB (capture records)
2912         ServerProgsDB = db_load("server.db");
2913
2914         // Mapinfo
2915         MapInfo_Shutdown();
2916         MapInfo_Enumerate();
2917         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2918         WeaponStats_Init();
2919
2920         TargetMusic_RestoreGame();
2921 }
2922
2923 void SV_Shutdown()
2924 {
2925         entity e;
2926
2927         if(gameover > 1) // shutting down already?
2928                 return;
2929
2930         gameover = 2; // 2 = server shutting down
2931
2932         if(world_initialized > 0)
2933         {
2934                 world_initialized = 0;
2935                 print("Saving persistent data...\n");
2936                 Ban_SaveBans();
2937
2938                 PlayerStats_EndMatch(0);
2939                 FOR_EACH_CLIENT(e)
2940                         PlayerStats_AddGlobalInfo(e);
2941                 PlayerStats_Shutdown();
2942
2943                 if(!cheatcount_total)
2944                 {
2945                         if(autocvar_sv_db_saveasdump)
2946                                 db_dump(ServerProgsDB, "server.db");
2947                         else
2948                                 db_save(ServerProgsDB, "server.db");
2949                 }
2950                 if(autocvar_developer)
2951                 {
2952                         if(autocvar_sv_db_saveasdump)
2953                                 db_dump(TemporaryDB, "server-temp.db");
2954                         else
2955                                 db_save(TemporaryDB, "server-temp.db");
2956                 }
2957                 CheatShutdown(); // must be after cheatcount check
2958                 db_close(ServerProgsDB);
2959                 db_close(TemporaryDB);
2960                 print("done!\n");
2961                 // tell the bot system the game is ending now
2962                 bot_endgame();
2963
2964                 WeaponStats_Shutdown();
2965                 MapInfo_Shutdown();
2966         }
2967         else if(world_initialized == 0)
2968         {
2969                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2970         }
2971 }