qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 Announce("prepareforbattle");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i, adding, pureadding;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221         if(cvar_purechanges)
 222                 strunzone(cvar_purechanges);
 223         cvar_purechanges = string_null;
 224         cvar_purechanges_count = 0;
 225
 226         h = buf_create();
 227         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 228         n = buf_getsize(h);
 229
 230         adding = TRUE;
 231         pureadding = TRUE;
 232
 233         for(i = 0; i < n; ++i)
 234         {
 235                 k = bufstr_get(h, i);
 236
 237 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 238 #define BADCVAR(p) if(k == p) continue
 239                 // internal
 240                 BADPREFIX("csqc_");
 241                 BADPREFIX("cvar_check_");
 242                 BADCVAR("gamecfg");
 243                 BADCVAR("g_configversion");
 244                 BADCVAR("g_maplist_index");
 245                 BADCVAR("halflifebsp");
 246                 BADPREFIX("sv_world");
 247
 248                 // client
 249                 BADPREFIX("chase_");
 250                 BADPREFIX("cl_");
 251                 BADPREFIX("con_");
 252                 BADPREFIX("scoreboard_");
 253                 BADPREFIX("g_campaign");
 254                 BADPREFIX("gl_");
 255                 BADPREFIX("joy");
 256                 BADPREFIX("hud_");
 257                 BADPREFIX("menu_");
 258                 BADPREFIX("net_slist_");
 259                 BADPREFIX("r_");
 260                 BADPREFIX("sbar_");
 261                 BADPREFIX("scr_");
 262                 BADPREFIX("userbind");
 263                 BADPREFIX("v_");
 264                 BADPREFIX("vid_");
 265                 BADPREFIX("crosshair");
 266                 BADCVAR("mod_q3bsp_lightmapmergepower");
 267                 BADCVAR("mod_q3bsp_nolightmaps");
 268
 269                 // private
 270                 BADCVAR("serverconfig");
 271                 BADPREFIX("g_ban_");
 272                 BADPREFIX("g_chat_flood_");
 273                 BADPREFIX("g_voice_flood_");
 274                 BADPREFIX("rcon_");
 275                 BADPREFIX("settemp_");
 276                 BADPREFIX("sv_allowdownloads_");
 277                 BADPREFIX("sv_autodemo");
 278                 BADPREFIX("sv_curl_");
 279                 BADPREFIX("sv_eventlog");
 280                 BADPREFIX("sv_logscores_");
 281                 BADPREFIX("sv_master");
 282                 BADCVAR("g_banned_list");
 283                 BADCVAR("log_dest_udp");
 284                 BADCVAR("log_file");
 285                 BADCVAR("net_address");
 286                 BADCVAR("port");
 287                 BADCVAR("savedgamecfg");
 288                 BADCVAR("sv_heartbeatperiod");
 289                 BADCVAR("sv_vote_master_password");
 290                 BADCVAR("sys_colortranslation");
 291                 BADCVAR("sys_specialcharactertranslation");
 292                 BADCVAR("timestamps");
 293                 BADCVAR("net_address");
 294                 BADCVAR("net_address_ipv6");
 295                 BADPREFIX("sv_weaponstats_");
 296                 BADCVAR("developer");
 297                 BADPREFIX("developer_");
 298
 299                 // mapinfo
 300                 BADCVAR("timelimit");
 301                 BADCVAR("fraglimit");
 302                 BADCVAR("g_arena");
 303                 BADCVAR("g_ca");
 304                 BADCVAR("g_assault");
 305                 BADCVAR("g_ctf");
 306                 BADCVAR("g_dm");
 307                 BADCVAR("g_domination");
 308                 BADCVAR("g_keyhunt");
 309                 BADCVAR("g_keyhunt_teams");
 310                 BADCVAR("g_onslaught");
 311                 BADCVAR("g_race");
 312                 BADCVAR("g_cts");
 313                 BADCVAR("g_runematch");
 314                 BADCVAR("g_tdm");
 315                 BADCVAR("g_nexball");
 316                 BADCVAR("teamplay");
 317
 318                 // long
 319                 BADCVAR("hostname");
 320                 BADCVAR("g_maplist");
 321                 BADCVAR("g_maplist_mostrecent");
 322                 BADCVAR("sv_motd");
 323
 324                 v = cvar_string(k);
 325                 d = cvar_defstring(k);
 326                 if(v == d)
 327                         continue;
 328
 329                 if(adding)
 330                 {
 331                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 332                         if(strlen(cvar_changes) > 16384)
 333                         {
 334                                 cvar_changes = "// too many settings have been changed to show them here\n";
 335                                 adding = 0;
 336                         }
 337                 }
 338
 339                 // now check if the changes are actually gameplay relevant
 340
 341                 // does nothing visible
 342                 BADPREFIX("prvm_");
 343
 344                 // allowed changes to server admins (please sync this to server.cfg)
 345                 // vi commands:
 346                 //   :/"impure"/,$d
 347                 //   :g!,^\/\/[^ /],d
 348                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 349                 //   :%!sort
 350                 // yes, this does contain some redundant stuff, don't really care
 351                 BADCVAR("bot_number");
 352                 BADCVAR("bot_prefix");
 353                 BADCVAR("bot_suffix");
 354                 BADCVAR("capturelimit_override");
 355                 BADCVAR("fraglimit_override");
 356                 BADCVAR("gametype");
 357                 BADCVAR("g_antilag");
 358                 BADCVAR("g_balance_teams");
 359                 BADCVAR("g_balance_teams_force");
 360                 BADCVAR("g_ban_sync_trusted_servers");
 361                 BADCVAR("g_ban_sync_uri");
 362                 BADCVAR("g_ctf_capture_limit");
 363                 BADCVAR("g_ctf_ignore_frags");
 364                 BADCVAR("g_ctf_win_mode");
 365                 BADCVAR("g_domination_point_limit");
 366                 BADCVAR("g_fullbrightitems");
 367                 BADCVAR("g_fullbrightplayers");
 368                 BADCVAR("g_keyhunt_point_limit");
 369                 BADCVAR("g_keyhunt_teams_override");
 370                 BADCVAR("g_lms_lives_override");
 371                 BADCVAR("g_maplist");
 372                 BADCVAR("g_maplist_check_waypoints");
 373                 BADCVAR("g_maplist_mostrecent_count");
 374                 BADCVAR("g_maplist_shuffle");
 375                 BADCVAR("g_maplist_votable");
 376                 BADCVAR("g_maplist_votable_abstain");
 377                 BADCVAR("g_maplist_votable_nodetail");
 378                 BADCVAR("g_maplist_votable_suggestions");
 379                 BADCVAR("g_nexball_goallimit");
 380                 BADCVAR("g_runematch_point_limit");
 381                 BADCVAR("g_start_delay");
 382                 BADCVAR("hostname");
 383                 BADCVAR("log_file");
 384                 BADCVAR("maxplayers");
 385                 BADCVAR("minplayers");
 386                 BADCVAR("net_address");
 387                 BADCVAR("port");
 388                 BADCVAR("rcon_password");
 389                 BADCVAR("rcon_restricted_commands");
 390                 BADCVAR("rcon_restricted_password");
 391                 BADCVAR("skill");
 392                 BADCVAR("sv_autoscreenshot");
 393                 BADCVAR("sv_curl_defaulturl");
 394                 BADCVAR("sv_defaultcharacter");
 395                 BADCVAR("sv_defaultplayermodel");
 396                 BADCVAR("sv_defaultplayerskin");
 397                 BADCVAR("sv_maxrate");
 398                 BADCVAR("sv_motd");
 399                 BADCVAR("sv_public");
 400                 BADCVAR("sv_ready_restart");
 401                 BADCVAR("sv_status_privacy");
 402                 BADCVAR("sv_vote_call");
 403                 BADCVAR("sv_vote_commands");
 404                 BADCVAR("sv_vote_majority_factor");
 405                 BADCVAR("sv_vote_master");
 406                 BADCVAR("sv_vote_master_commands");
 407                 BADCVAR("sv_vote_master_password");
 408                 BADCVAR("sv_vote_simple_majority_factor");
 409                 BADCVAR("timelimit_override");
 410 #undef BADPREFIX
 411 #undef BADCVAR
 412
 413                 if(pureadding)
 414                 {
 415                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 416                         if(strlen(cvar_purechanges) > 16384)
 417                         {
 418                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 419                                 pureadding = 0;
 420                         }
 421                 }
 422                 ++cvar_purechanges_count;
 423         }
 424         buf_del(h);
 425         if(cvar_changes == "")
 426                 cvar_changes = "// this server runs at default server settings\n";
 427         else
 428                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 429         cvar_changes = strzone(cvar_changes);
 430         if(cvar_purechanges == "")
 431                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 432         else
 433                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 434         cvar_purechanges = strzone(cvar_purechanges);
 435 }
 436
 437 void detect_maptype()
 438 {
 439 #if 0
 440         vector o, v;
 441         float i;
 442
 443         for(;;)
 444         {
 445                 o = world.mins;
 446                 o_x += random() * (world.maxs_x - world.mins_x);
 447                 o_y += random() * (world.maxs_y - world.mins_y);
 448                 o_z += random() * (world.maxs_z - world.mins_z);
 449
 450                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 451                 if(trace_fraction == 1)
 452                         continue;
 453
 454                 v = trace_endpos;
 455
 456                 for(i = 0; i < 64; i += 4)
 457                 {
 458                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 459         if(trace_fraction == 1)
 460                 continue;
 461                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 462                 }
 463
 464                 break;
 465         }
 466 #endif
 467 }
 468
 469 entity randomseed;
 470 float RandomSeed_Send(entity to, float sf)
 471 {
 472         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 473         WriteShort(MSG_ENTITY, self.cnt);
 474         return TRUE;
 475 }
 476 void RandomSeed_Think()
 477 {
 478         self.cnt = bound(0, floor(random() * 65536), 65535);
 479         self.nextthink = time + 5;
 480
 481         self.SendFlags |= 1;
 482 }
 483 void RandomSeed_Spawn()
 484 {
 485         randomseed = spawn();
 486         randomseed.think = RandomSeed_Think;
 487         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 488
 489         entity oldself;
 490         oldself = self;
 491         self = randomseed;
 492         self.think(); // sets random seed and nextthink
 493         self = oldself;
 494 }
 495
 496 void spawnfunc___init_dedicated_server(void)
 497 {
 498         // handler for _init/_init map (only for dedicated server initialization)
 499
 500         world_initialized = -1; // don't complain
 501         cvar = cvar_normal;
 502         cvar_string = cvar_string_normal;
 503         cvar_set = cvar_set_normal;
 504
 505         remove = remove_unsafely;
 506
 507         entity e;
 508         e = spawn();
 509         e.think = GotoFirstMap;
 510         e.nextthink = time; // this is usually 1 at this point
 511
 512         e = spawn();
 513         e.classname = "info_player_deathmatch"; // safeguard against player joining
 514
 515         self.classname = "worldspawn"; // safeguard against various stuff ;)
 516
 517         MapInfo_Enumerate();
 518         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 519 }
 520
 521 void Map_MarkAsRecent(string m);
 522 float world_already_spawned;
 523 void RegisterWeapons();
 524 void Nagger_Init();
 525 void ClientInit_Spawn();
 526 void WeaponStats_Init();
 527 void WeaponStats_Shutdown();
 528 void spawnfunc_worldspawn (void)
 529 {
 530         float fd, l, i, j, n;
 531         string s, col;
 532
 533         cvar = cvar_normal;
 534         cvar_string = cvar_string_normal;
 535         cvar_set = cvar_set_normal;
 536
 537         if(world_already_spawned)
 538                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 539         world_already_spawned = TRUE;
 540
 541         remove = remove_safely; // during spawning, watch what you remove!
 542
 543         check_unacceptable_compiler_bugs();
 544
 545         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 546
 547         compressShortVector_init();
 548
 549         allowed_to_spawn = TRUE;
 550
 551         local entity head;
 552         head = nextent(world);
 553         maxclients = 0;
 554         while(head)
 555         {
 556                 ++maxclients;
 557                 head = nextent(head);
 558         }
 559
 560         // needs to be done so early as they would still spawn
 561         RegisterWeapons();
 562
 563         ServerProgsDB = db_load("server.db");
 564
 565         TemporaryDB = db_create();
 566
 567         /*
 568         TODO sound pack system
 569         // initialize sound pack system
 570         soundpack = cvar_string("g_soundpack");
 571         if(soundpack != "")
 572                 soundpack = strcat(soundpack, "/");
 573         soundpack = strzone(soundpack);
 574         */
 575
 576         // 0 normal
 577         lightstyle(0, "m");
 578
 579         // 1 FLICKER (first variety)
 580         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 581
 582         // 2 SLOW STRONG PULSE
 583         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 584
 585         // 3 CANDLE (first variety)
 586         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 587
 588         // 4 FAST STROBE
 589         lightstyle(4, "mamamamamama");
 590
 591         // 5 GENTLE PULSE 1
 592         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 593
 594         // 6 FLICKER (second variety)
 595         lightstyle(6, "nmonqnmomnmomomno");
 596
 597         // 7 CANDLE (second variety)
 598         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 599
 600         // 8 CANDLE (third variety)
 601         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 602
 603         // 9 SLOW STROBE (fourth variety)
 604         lightstyle(9, "aaaaaaaazzzzzzzz");
 605
 606         // 10 FLUORESCENT FLICKER
 607         lightstyle(10, "mmamammmmammamamaaamammma");
 608
 609         // 11 SLOW PULSE NOT FADE TO BLACK
 610         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 611
 612         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 613
 614         // 63 testing
 615         lightstyle(63, "a");
 616
 617         if(cvar("g_campaign"))
 618                 CampaignPreInit();
 619
 620         Map_MarkAsRecent(mapname);
 621
 622         precache_model ("null"); // we need this one before InitGameplayMode
 623         InitGameplayMode();
 624         readlevelcvars();
 625         GrappleHookInit();
 626         ElectroInit();
 627         LaserInit();
 628
 629         player_count = 0;
 630         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 631         if(bot_waypoints_for_items == 1)
 632                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 633                         bot_waypoints_for_items = 0;
 634
 635         // for setting by mapinfo
 636         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 637         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 638
 639         precache();
 640
 641         WaypointSprite_Init();
 642
 643         //if (g_domination)
 644         //      dom_init();
 645
 646         GameLogInit(); // prepare everything
 647         if(cvar("sv_eventlog"))
 648         {
 649                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 650                 s = strcat(s, ftos(random()));
 651                 matchid = strzone(s);
 652
 653                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 654                 s = ":gameinfo:mutators:LIST";
 655
 656                 ret_string = s;
 657                 MUTATOR_CALLHOOK(BuildMutatorsString);
 658                 s = ret_string;
 659
 660                 if(cvar("g_grappling_hook"))
 661                         s = strcat(s, ":grappling_hook");
 662                 if(!cvar("g_use_ammunition"))
 663                         s = strcat(s, ":no_use_ammunition");
 664                 if(!cvar("g_pickup_items"))
 665                         s = strcat(s, ":no_pickup_items");
 666                 if(cvar_string("g_weaponarena") != "0")
 667                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 668                 if(cvar("g_vampire"))
 669                         s = strcat(s, ":vampire");
 670                 if(cvar("g_laserguided_missile"))
 671                         s = strcat(s, ":laserguided_missile");
 672                 if(cvar("g_norecoil"))
 673                         s = strcat(s, ":norecoil");
 674                 if(cvar("g_midair"))
 675                         s = strcat(s, ":midair");
 676                 if(cvar("g_minstagib"))
 677                         s = strcat(s, ":minstagib");
 678                 GameLogEcho(s);
 679                 GameLogEcho(":gameinfo:end");
 680         }
 681         else
 682                 matchid = strzone(ftos(random()));
 683
 684         cvar_set("nextmap", "");
 685
 686         SetDefaultAlpha();
 687
 688         if(cvar("g_campaign"))
 689                 CampaignPostInit();
 690
 691         fteqcc_testbugs();
 692
 693         Ban_LoadBans();
 694
 695         MapInfo_Enumerate();
 696         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 697
 698         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 699         {
 700                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 701                 if(fd != -1)
 702                 {
 703                         while((s = fgets(fd)))
 704                         {
 705                                 l = tokenize_console(s);
 706                                 if(l < 2)
 707                                         continue;
 708                                 if(argv(0) == "cd")
 709                                 {
 710                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 711                                         print("  cdtrack ", argv(2), "\n");
 712                                 }
 713                                 else if(argv(0) == "fog")
 714                                 {
 715                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 716                                         print("  \"fog\" \"", s, "\"\n");
 717                                 }
 718                                 else if(argv(0) == "set")
 719                                 {
 720                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 721                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 722                                 }
 723                                 else if(argv(0) != "//")
 724                                 {
 725                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 726                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 727                                 }
 728                         }
 729                         fclose(fd);
 730                 }
 731         }
 732
 733         WeaponStats_Init();
 734
 735         addstat(STAT_WEAPONS, AS_INT, weapons);
 736         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 737         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 738         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 739         Nagger_Init();
 740
 741         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 742         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 743         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 744         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 745         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 746         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 747         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 748         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 749         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 750         addstat(STAT_LAST_PICKUP, AS_FLOAT, last_pickup);
 751
 752         addstat(STAT_NEX_CHARGE, AS_FLOAT, nex_charge);
 753
 754         if(g_ca)
 755         {
 756                 addstat(STAT_REDALIVE, AS_INT, redalive_stat);
 757                 addstat(STAT_BLUEALIVE, AS_INT, bluealive_stat);
 758         }
 759         // g_movementspeed hack
 760         addstat(STAT_MOVEVARS_AIRSPEEDLIMIT_NONQW, AS_FLOAT, stat_sv_airspeedlimit_nonqw);
 761         addstat(STAT_MOVEVARS_AIRACCEL_QW, AS_FLOAT, stat_sv_airaccel_qw);
 762         addstat(STAT_MOVEVARS_AIRSTRAFEACCEL_QW, AS_FLOAT, stat_sv_airstrafeaccel_qw);
 763
 764         next_pingtime = time + 5;
 765
 766         detect_maptype();
 767
 768         lsmaps_reply = "^7Maps available: ";
 769         lsnewmaps_reply = "^7Maps without a record set: ";
 770         for(i = 0, j = 0; i < MapInfo_count; ++i)
 771         {
 772                 if(MapInfo_Get_ByID(i))
 773                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 774                         {
 775                                 if(mod(i, 2))
 776                                         col = "^2";
 777                                 else
 778                                         col = "^3";
 779                                 ++j;
 780                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 781                                 if(g_race && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, RACE_RECORD, "time"))))
 782                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 783                                 else if(g_cts && !stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, CTS_RECORD, "time"))))
 784                                         lsnewmaps_reply = strcat(lsnewmaps_reply, col, MapInfo_Map_bspname, " ");
 785                         }
 786         }
 787         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 788         if (!g_race && !g_cts)
 789                 lsnewmaps_reply = "Need to be playing race or CTS for lsnewmaps to work.";
 790         lsnewmaps_reply = strzone(strcat(lsnewmaps_reply, "\n"));
 791
 792         maplist_reply = "^7Maps in list: ";
 793         n = tokenize_console(cvar_string("g_maplist"));
 794         for(i = 0, j = 0; i < n; ++i)
 795         {
 796                 if(MapInfo_CheckMap(argv(i)))
 797                 {
 798                         if(mod(j, 2))
 799                                 col = "^2";
 800                         else
 801                                 col = "^3";
 802                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 803                         ++j;
 804                 }
 805         }
 806         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 807         MapInfo_ClearTemps();
 808
 809         for(i = 0; i < 10; ++i)
 810         {
 811                 records_reply[i] = strzone(getrecords(i));
 812         }
 813
 814         rankings_reply = strzone(getrankings());
 815
 816         ClientInit_Spawn();
 817         RandomSeed_Spawn();
 818         PingPLReport_Spawn();
 819
 820         CheatInit();
 821
 822         localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 823
 824         // fill sv_curl_serverpackages from .serverpackage files
 825         if(cvar("sv_curl_serverpackages_auto"))
 826         {
 827                 fd = search_begin("*.serverpackage", TRUE, FALSE);
 828                 s = "";
 829                 if(fd >= 0)
 830                 {
 831                         j = search_getsize(fd);
 832                         for(i = 0; i < j; ++i)
 833                                 s = strcat(s, " ", search_getfilename(fd, i));
 834                         search_end(fd);
 835                 }
 836                 cvar_set("sv_curl_serverpackages", substring(s, 1, -1));
 837         }
 838
 839         world_initialized = 1;
 840 }
 841
 842 void spawnfunc_light (void)
 843 {
 844         //makestatic (self); // Who the f___ did that?
 845         remove(self);
 846 }
 847
 848 float TryFile( string pFilename )
 849 {
 850         local float lHandle;
 851         dprint("TryFile(\"", pFilename, "\")\n");
 852         lHandle = fopen( pFilename, FILE_READ );
 853         if( lHandle != -1 ) {
 854                 fclose( lHandle );
 855                 return TRUE;
 856         } else {
 857                 return FALSE;
 858         }
 859 };
 860
 861 string GetGametype()
 862 {
 863         return GametypeNameFromType(game);
 864 }
 865
 866 string getmapname_stored;
 867 string GetMapname()
 868 {
 869         return mapname;
 870 }
 871
 872 float Map_Count, Map_Current;
 873 string Map_Current_Name;
 874
 875 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 876 float GetMaplistPosition()
 877 {
 878         float pos, idx;
 879         string map;
 880
 881         map = GetMapname();
 882         idx = cvar("g_maplist_index");
 883
 884         if(idx >= 0)
 885                 if(idx < Map_Count)
 886                         if(map == argv(idx))
 887                                 return idx;
 888
 889         for(pos = 0; pos < Map_Count; ++pos)
 890                 if(map == argv(pos))
 891                         return pos;
 892
 893         // resume normal maplist rotation if current map is not in g_maplist
 894         return idx;
 895 }
 896
 897 float MapHasRightSize(string map)
 898 {
 899         float fh;
 900         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 901         if(cvar("g_maplist_check_waypoints"))
 902         {
 903                 dprint("checkwp "); dprint(map);
 904                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 905                 if(fh < 0)
 906                 {
 907                         dprint(": no waypoints\n");
 908                         return FALSE;
 909                 }
 910                 dprint(": has waypoints\n");
 911                 fclose(fh);
 912         }
 913
 914         // open map size restriction file
 915         dprint("opensize "); dprint(map);
 916         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 917         if(fh >= 0)
 918         {
 919                 float mapmin, mapmax;
 920                 dprint(": ok, ");
 921                 mapmin = stof(fgets(fh));
 922                 mapmax = stof(fgets(fh));
 923                 fclose(fh);
 924                 if(player_count < mapmin)
 925                 {
 926                         dprint("not enough\n");
 927                         return FALSE;
 928                 }
 929                 if(player_count > mapmax)
 930                 {
 931                         dprint("too many\n");
 932                         return FALSE;
 933                 }
 934                 dprint("right size\n");
 935                 return TRUE;
 936         }
 937         dprint(": not found\n");
 938         return TRUE;
 939 }
 940
 941 string Map_Filename(float position)
 942 {
 943         return strcat("maps/", argv(position), ".bsp");
 944 }
 945
 946 string strwords(string s, float w)
 947 {
 948         float endpos;
 949         for(endpos = 0; w && endpos >= 0; --w)
 950                 endpos = strstrofs(s, " ", endpos + 1);
 951         if(endpos < 0)
 952                 return s;
 953         else
 954                 return substring(s, 0, endpos);
 955 }
 956
 957 float strhasword(string s, string w)
 958 {
 959         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 960 }
 961
 962 void Map_MarkAsRecent(string m)
 963 {
 964         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 965 }
 966
 967 float Map_IsRecent(string m)
 968 {
 969         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 970 }
 971
 972 float Map_Check(float position, float pass)
 973 {
 974         string filename;
 975         string map_next;
 976         map_next = argv(position);
 977         if(pass <= 1)
 978         {
 979                 if(Map_IsRecent(map_next))
 980                         return 0;
 981         }
 982         filename = Map_Filename(position);
 983         if(MapInfo_CheckMap(map_next))
 984         {
 985                 if(pass == 2)
 986                         return 1;
 987                 if(MapHasRightSize(map_next))
 988                         return 1;
 989                 return 0;
 990         }
 991         else
 992                 dprint( "Couldn't select '", filename, "'..\n" );
 993
 994         return 0;
 995 }
 996
 997 void Map_Goto_SetStr(string nextmapname)
 998 {
 999         if(getmapname_stored != "")
1000                 strunzone(getmapname_stored);
1001         if(nextmapname == "")
1002                 getmapname_stored = "";
1003         else
1004                 getmapname_stored = strzone(nextmapname);
1005 }
1006
1007 void Map_Goto_SetFloat(float position)
1008 {
1009         cvar_set("g_maplist_index", ftos(position));
1010         Map_Goto_SetStr(argv(position));
1011 }
1012
1013 void GameResetCfg()
1014 {
1015         // settings persist, except...
1016         localcmd("\nsettemp_restore\n");
1017 };
1018
1019 void Map_Goto()
1020 {
1021         GameResetCfg();
1022         MapInfo_LoadMap(getmapname_stored);
1023 }
1024
1025 // return codes of map selectors:
1026 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
1027 //   -2 = permanent failure
1028 float() MaplistMethod_Iterate = // usual method
1029 {
1030         float pass, i;
1031
1032         for(pass = 1; pass <= 2; ++pass)
1033         {
1034                 for(i = 1; i < Map_Count; ++i)
1035                 {
1036                         float mapindex;
1037                         mapindex = mod(i + Map_Current, Map_Count);
1038                         if(Map_Check(mapindex, pass))
1039                                 return mapindex;
1040                 }
1041         }
1042         return -1;
1043 }
1044
1045 float() MaplistMethod_Repeat = // fallback method
1046 {
1047         if(Map_Check(Map_Current, 2))
1048                 return Map_Current;
1049         return -2;
1050 }
1051
1052 float() MaplistMethod_Random = // random map selection
1053 {
1054         float i, imax;
1055
1056         imax = 42;
1057
1058         for(i = 0; i <= imax; ++i)
1059         {
1060                 float mapindex;
1061                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
1062                 if(Map_Check(mapindex, 1))
1063                         return mapindex;
1064         }
1065         return -1;
1066 }
1067
1068 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
1069 // the exponent sets a bias on the map selection:
1070 // the higher the exponent, the less likely "shortly repeated" same maps are
1071 {
1072         float i, j, imax, insertpos;
1073
1074         imax = 42;
1075
1076         for(i = 0; i <= imax; ++i)
1077         {
1078                 string newlist;
1079
1080                 // now reinsert this at another position
1081                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
1082                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
1083                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
1084                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
1085
1086                 // insert the current map there
1087                 newlist = "";
1088                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
1089                         newlist = strcat(newlist, " ", argv(j));
1090                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
1091                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
1092                         newlist = strcat(newlist, " ", argv(j));
1093                 newlist = substring(newlist, 1, strlen(newlist) - 1);
1094                 cvar_set("g_maplist", newlist);
1095                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1096
1097                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
1098                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
1099                 if(Map_Check(Map_Current, 1))
1100                         return Map_Current;
1101         }
1102         return -1;
1103 }
1104
1105 void Maplist_Init()
1106 {
1107         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1108         if(Map_Count == 0)
1109         {
1110                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
1111                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1112                 if(cvar("g_maplist_shuffle"))
1113                         ShuffleMaplist();
1114                 localcmd("\nmenu_cmd sync\n");
1115                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
1116         }
1117         if(Map_Count == 0)
1118                 error("empty maplist, cannot select a new map");
1119         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
1120
1121         if(Map_Current_Name)
1122                 strunzone(Map_Current_Name);
1123         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
1124         // this may or may not be correct, but who cares, in the worst case a map
1125         // isn't chosen in the first pass that should have been
1126 }
1127
1128 string GetNextMap()
1129 {
1130         float nextMap;
1131
1132         Maplist_Init();
1133         nextMap = -1;
1134
1135         if(nextMap == -1)
1136                 if(cvar("g_maplist_shuffle") > 0)
1137                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
1138
1139         if(nextMap == -1)
1140                 if(cvar("g_maplist_selectrandom"))
1141                         nextMap = MaplistMethod_Random();
1142
1143         if(nextMap == -1)
1144                 nextMap = MaplistMethod_Iterate();
1145
1146         if(nextMap == -1)
1147                 nextMap = MaplistMethod_Repeat();
1148
1149         if(nextMap >= 0)
1150         {
1151                 Map_Goto_SetFloat(nextMap);
1152                 return getmapname_stored;
1153         }
1154
1155         return "";
1156 };
1157
1158 float DoNextMapOverride()
1159 {
1160         if(cvar("g_campaign"))
1161         {
1162                 CampaignPostIntermission();
1163                 alreadychangedlevel = TRUE;
1164                 return TRUE;
1165         }
1166         if(cvar("quit_when_empty"))
1167         {
1168                 if(player_count <= currentbots)
1169                 {
1170                         localcmd("quit\n");
1171                         alreadychangedlevel = TRUE;
1172                         return TRUE;
1173                 }
1174         }
1175         if(cvar_string("quit_and_redirect") != "")
1176         {
1177                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1178                 alreadychangedlevel = TRUE;
1179                 return TRUE;
1180         }
1181         if (cvar("samelevel")) // if samelevel is set, stay on same level
1182         {
1183                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1184                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1185                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1186                 localcmd("restart\n");
1187                 //changelevel (mapname);
1188                 alreadychangedlevel = TRUE;
1189                 return TRUE;
1190         }
1191         if(cvar_string("nextmap") != "")
1192                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1193                 {
1194                         Map_Goto_SetStr(cvar_string("nextmap"));
1195                         Map_Goto();
1196                         alreadychangedlevel = TRUE;
1197                         return TRUE;
1198                 }
1199         if(cvar("lastlevel"))
1200         {
1201                 GameResetCfg();
1202                 localcmd("set lastlevel 0\ntogglemenu\n");
1203                 alreadychangedlevel = TRUE;
1204                 return TRUE;
1205         }
1206         return FALSE;
1207 };
1208
1209 void GotoNextMap()
1210 {
1211         //local string nextmap;
1212         //local float n, nummaps;
1213         //local string s;
1214         if (alreadychangedlevel)
1215                 return;
1216         alreadychangedlevel = TRUE;
1217
1218         {
1219                 string nextMap;
1220                 float allowReset;
1221
1222                 for(allowReset = 1; allowReset >= 0; --allowReset)
1223                 {
1224                         nextMap = GetNextMap();
1225                         if(nextMap != "")
1226                                 break;
1227
1228                         if(allowReset)
1229                         {
1230                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1231                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1232                                 if(cvar("g_maplist_shuffle"))
1233                                         ShuffleMaplist();
1234                                 localcmd("\nmenu_cmd sync\n");
1235                         }
1236                         else
1237                         {
1238                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1239                         }
1240                 }
1241                 Map_Goto();
1242         }
1243 };
1244
1245
1246 /*
1247 ============
1248 IntermissionThink
1249
1250 When the player presses attack or jump, change to the next level
1251 ============
1252 */
1253 .float autoscreenshot;
1254 void() MapVote_Start;
1255 void() MapVote_Think;
1256 float mapvote_initialized;
1257 void IntermissionThink()
1258 {
1259         FixIntermissionClient(self);
1260
1261         if(cvar("sv_autoscreenshot"))
1262         if(self.autoscreenshot > 0)
1263         if(time > self.autoscreenshot)
1264         {
1265                 self.autoscreenshot = -1;
1266                 if(clienttype(self) == CLIENTTYPE_REAL)
1267                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1268                 return;
1269         }
1270
1271         if (time < intermission_exittime)
1272                 return;
1273
1274         if(!mapvote_initialized)
1275                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1276                         return;
1277
1278         MapVote_Start();
1279 };
1280
1281 /*
1282 ============
1283 FindIntermission
1284
1285 Returns the entity to view from
1286 ============
1287 */
1288 /*
1289 entity FindIntermission()
1290 {
1291         local   entity spot;
1292         local   float cyc;
1293
1294 // look for info_intermission first
1295         spot = find (world, classname, "info_intermission");
1296         if (spot)
1297         {       // pick a random one
1298                 cyc = random() * 4;
1299                 while (cyc > 1)
1300                 {
1301                         spot = find (spot, classname, "info_intermission");
1302                         if (!spot)
1303                                 spot = find (spot, classname, "info_intermission");
1304                         cyc = cyc - 1;
1305                 }
1306                 return spot;
1307         }
1308
1309 // then look for the start position
1310         spot = find (world, classname, "info_player_start");
1311         if (spot)
1312                 return spot;
1313
1314 // testinfo_player_start is only found in regioned levels
1315         spot = find (world, classname, "testplayerstart");
1316         if (spot)
1317                 return spot;
1318
1319 // then look for the start position
1320         spot = find (world, classname, "info_player_deathmatch");
1321         if (spot)
1322                 return spot;
1323
1324         //objerror ("FindIntermission: no spot");
1325         return world;
1326 };
1327 */
1328
1329 /*
1330 ===============================================================================
1331
1332 RULES
1333
1334 ===============================================================================
1335 */
1336
1337 void DumpStats(float final)
1338 {
1339         local float file;
1340         local string s;
1341         local float to_console;
1342         local float to_eventlog;
1343         local float to_file;
1344         local float i;
1345
1346         to_console = cvar("sv_logscores_console");
1347         to_eventlog = cvar("sv_eventlog");
1348         to_file = cvar("sv_logscores_file");
1349
1350         if(!final)
1351         {
1352                 to_console = TRUE; // always print printstats replies
1353                 to_eventlog = FALSE; // but never print them to the event log
1354         }
1355
1356         if(to_eventlog)
1357                 if(cvar("sv_eventlog_console"))
1358                         to_console = FALSE; // otherwise we get the output twice
1359
1360         if(final)
1361                 s = ":scores:";
1362         else
1363                 s = ":status:";
1364         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1365
1366         if(to_console)
1367                 print(s, "\n");
1368         if(to_eventlog)
1369                 GameLogEcho(s);
1370         if(to_file)
1371         {
1372                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1373                 if(file == -1)
1374                         to_file = FALSE;
1375                 else
1376                         fputs(file, strcat(s, "\n"));
1377         }
1378
1379         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1380         if(to_console)
1381                 print(s, "\n");
1382         if(to_eventlog)
1383                 GameLogEcho(s);
1384         if(to_file)
1385                 fputs(file, strcat(s, "\n"));
1386
1387         FOR_EACH_CLIENT(other)
1388         {
1389                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1390                 {
1391                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1392                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1393                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1394                                 s = strcat(s, ftos(other.team), ":");
1395                         else
1396                                 s = strcat(s, "spectator:");
1397
1398                         if(to_console)
1399                                 print(s, other.netname, "\n");
1400                         if(to_eventlog)
1401                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1402                         if(to_file)
1403                                 fputs(file, strcat(s, other.netname, "\n"));
1404                 }
1405         }
1406
1407         if(teams_matter)
1408         {
1409                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1410                 if(to_console)
1411                         print(s, "\n");
1412                 if(to_eventlog)
1413                         GameLogEcho(s);
1414                 if(to_file)
1415                         fputs(file, strcat(s, "\n"));
1416
1417                 for(i = 1; i < 16; ++i)
1418                 {
1419                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1420                         s = strcat(s, ":", ftos(i));
1421                         if(to_console)
1422                                 print(s, "\n");
1423                         if(to_eventlog)
1424                                 GameLogEcho(s);
1425                         if(to_file)
1426                                 fputs(file, strcat(s, "\n"));
1427                 }
1428         }
1429
1430         if(to_console)
1431                 print(":end\n");
1432         if(to_eventlog)
1433                 GameLogEcho(":end");
1434         if(to_file)
1435         {
1436                 fputs(file, ":end\n");
1437                 fclose(file);
1438         }
1439 }
1440
1441 void FixIntermissionClient(entity e)
1442 {
1443         string s;
1444         if(!e.autoscreenshot) // initial call
1445         {
1446                 e.angles = e.v_angle;
1447                 e.angles_x = -e.angles_x;
1448                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1449                 e.health = -2342;
1450                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1451                 e.solid = SOLID_NOT;
1452                 e.movetype = MOVETYPE_NONE;
1453                 e.takedamage = DAMAGE_NO;
1454                 if(e.weaponentity)
1455                 {
1456                         e.weaponentity.effects = EF_NODRAW;
1457                         if (e.weaponentity.weaponentity)
1458                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1459                 }
1460                 if(clienttype(e) == CLIENTTYPE_REAL)
1461                 {
1462                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1463                         s = cvar_string("sv_intermission_cdtrack");
1464                         if(s != "")
1465                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1466                         msg_entity = e;
1467                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1468                 }
1469         }
1470
1471         //e.velocity = '0 0 0';
1472         //e.fixangle = TRUE;
1473
1474         // TODO halt weapon animation
1475 }
1476
1477
1478 /*
1479 go to the next level for deathmatch
1480 only called if a time or frag limit has expired
1481 */
1482 void NextLevel()
1483 {
1484         float i;
1485
1486         gameover = TRUE;
1487
1488         intermission_running = 1;
1489
1490 // enforce a wait time before allowing changelevel
1491         if(player_count > 0)
1492                 intermission_exittime = time + cvar("sv_mapchange_delay");
1493         else
1494                 intermission_exittime = -1;
1495
1496         /*
1497         WriteByte (MSG_ALL, SVC_CDTRACK);
1498         WriteByte (MSG_ALL, 3);
1499         WriteByte (MSG_ALL, 3);
1500         // done in FixIntermission
1501         */
1502
1503         //pos = FindIntermission ();
1504
1505         VoteReset();
1506
1507         DumpStats(TRUE);
1508
1509         if(cvar("sv_eventlog"))
1510                 GameLogEcho(":gameover");
1511
1512         GameLogClose();
1513
1514 // TO DO
1515
1516 // save the stats to a text file on the client
1517 // stuffcmd(other, log_stats "stats/file_name");
1518 // bprint stats
1519 // stuffcmd(other, log_stats "");
1520 // use a filename similar to the demo name
1521         // string file_name;
1522         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1523
1524 // write a stats parser for the menu
1525
1526         if(cvar("sv_accuracy_data_send")) {
1527                 string stats_to_send;
1528
1529                 FOR_EACH_CLIENT(other) {  // make the string to send
1530                         FixIntermissionClient(other);
1531
1532                         if(other.cvar_cl_accuracy_data_share) {
1533                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1534
1535                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1536                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1537
1538                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1539
1540                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1541                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1542
1543                                 stats_to_send = strcat(stats_to_send, "\n");
1544                         }
1545                 }
1546
1547                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1548                         Score_NicePrint(other);  // print the score
1549
1550                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1551                                 bprint(stats_to_send);
1552                 }
1553         } else { // ye olde message
1554                 FOR_EACH_PLAYER(other) {
1555                         FixIntermissionClient(other);
1556
1557                         if(other.winning)
1558                                 bprint(other.netname, " ^7wins.\n");
1559                 }
1560         }
1561
1562         if(cvar("g_campaign"))
1563                 CampaignPreIntermission();
1564
1565         localcmd("\nsv_hook_gameend\n");
1566 }
1567
1568 /*
1569 ============
1570 CheckRules_Player
1571
1572 Exit deathmatch games upon conditions
1573 ============
1574 */
1575 void CheckRules_Player()
1576 {
1577         if (gameover)   // someone else quit the game already
1578                 return;
1579
1580         if(self.deadflag == DEAD_NO)
1581                 self.play_time += frametime;
1582
1583         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1584         //   (div0: and that in CheckRules_World please)
1585 };
1586
1587 float checkrules_equality;
1588 float checkrules_suddendeathwarning;
1589 float checkrules_suddendeathend;
1590 float checkrules_overtimesadded; //how many overtimes have been already added
1591
1592 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1593 float WINNING_YES = 1; // winner found
1594 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1595 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1596
1597 float InitiateSuddenDeath()
1598 {
1599         // Check first whether normal overtimes could be added before initiating suddendeath mode
1600         // - for this timelimit_overtime needs to be >0 of course
1601         // - also check the winning condition calculated in the previous frame and only add normal overtime
1602         //   again, if at the point at which timelimit would be extended again, still no winner was found
1603         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1604         {
1605                 return 1; // need to call InitiateOvertime later
1606         }
1607         else
1608         {
1609                 if(!checkrules_suddendeathend)
1610                 {
1611                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1612                         if(g_race && !g_race_qualifying)
1613                                 race_StartCompleting();
1614                 }
1615                 return 0;
1616         }
1617 }
1618
1619 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1620 {
1621         ++checkrules_overtimesadded;
1622         //add one more overtime by simply extending the timelimit
1623         float tl;
1624         tl = cvar("timelimit");
1625         tl += cvar("timelimit_overtime");
1626         cvar_set("timelimit", ftos(tl));
1627         string minutesPlural;
1628         if (cvar("timelimit_overtime") == 1)
1629                 minutesPlural = " ^3minute";
1630         else
1631                 minutesPlural = " ^3minutes";
1632
1633         bcenterprint(
1634                 strcat(
1635                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1636                         ftos(cvar("timelimit_overtime")),
1637                         minutesPlural,
1638                         " to the game!"
1639                 )
1640         );
1641 }
1642
1643 float GetWinningCode(float fraglimitreached, float equality)
1644 {
1645         if(cvar("g_campaign") == 1)
1646                 if(fraglimitreached)
1647                         return WINNING_YES;
1648                 else
1649                         return WINNING_NO;
1650
1651         else
1652                 if(equality)
1653                         if(fraglimitreached)
1654                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1655                         else
1656                                 return WINNING_NEVER;
1657                 else
1658                         if(fraglimitreached)
1659                                 return WINNING_YES;
1660                         else
1661                                 return WINNING_NO;
1662 }
1663
1664 // set the .winning flag for exactly those players with a given field value
1665 void SetWinners(.float field, float value)
1666 {
1667         entity head;
1668         FOR_EACH_PLAYER(head)
1669                 head.winning = (head.field == value);
1670 }
1671
1672 // set the .winning flag for those players with a given field value
1673 void AddWinners(.float field, float value)
1674 {
1675         entity head;
1676         FOR_EACH_PLAYER(head)
1677                 if(head.field == value)
1678                         head.winning = 1;
1679 }
1680
1681 // clear the .winning flags
1682 void ClearWinners(void)
1683 {
1684         entity head;
1685         FOR_EACH_PLAYER(head)
1686                 head.winning = 0;
1687 }
1688
1689 // Onslaught winning condition:
1690 // game terminates if only one team has a working generator (or none)
1691 float WinningCondition_Onslaught()
1692 {
1693         entity head;
1694         local float t1, t2, t3, t4;
1695
1696         WinningConditionHelper(); // set worldstatus
1697
1698         if(inWarmupStage)
1699                 return WINNING_NO;
1700
1701         // first check if the game has ended
1702         t1 = t2 = t3 = t4 = 0;
1703         head = find(world, classname, "onslaught_generator");
1704         while (head)
1705         {
1706                 if (head.health > 0)
1707                 {
1708                         if (head.team == COLOR_TEAM1) t1 = 1;
1709                         if (head.team == COLOR_TEAM2) t2 = 1;
1710                         if (head.team == COLOR_TEAM3) t3 = 1;
1711                         if (head.team == COLOR_TEAM4) t4 = 1;
1712                 }
1713                 head = find(head, classname, "onslaught_generator");
1714         }
1715         if (t1 + t2 + t3 + t4 < 2)
1716         {
1717                 // game over, only one team remains (or none)
1718                 ClearWinners();
1719                 if (t1) SetWinners(team, COLOR_TEAM1);
1720                 if (t2) SetWinners(team, COLOR_TEAM2);
1721                 if (t3) SetWinners(team, COLOR_TEAM3);
1722                 if (t4) SetWinners(team, COLOR_TEAM4);
1723                 dprint("Have a winner, ending game.\n");
1724                 return WINNING_YES;
1725         }
1726
1727         // Two or more teams remain
1728         return WINNING_NO;
1729 }
1730
1731 float LMS_NewPlayerLives()
1732 {
1733         float fl;
1734         fl = cvar("fraglimit");
1735         if(fl == 0)
1736                 fl = 999;
1737
1738         // first player has left the game for dying too much? Nobody else can get in.
1739         if(lms_lowest_lives < 1)
1740                 return 0;
1741
1742         if(!cvar("g_lms_join_anytime"))
1743                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1744                         return 0;
1745
1746         return bound(1, lms_lowest_lives, fl);
1747 }
1748
1749 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1750 // they win. Otherwise the defending team wins once the timelimit passes.
1751 void assault_new_round();
1752 float WinningCondition_Assault()
1753 {
1754         local float status;
1755
1756         WinningConditionHelper(); // set worldstatus
1757
1758         status = WINNING_NO;
1759         // as the timelimit has not yet passed just assume the defending team will win
1760         if(assault_attacker_team == COLOR_TEAM1)
1761         {
1762                 SetWinners(team, COLOR_TEAM2);
1763         }
1764         else
1765         {
1766                 SetWinners(team, COLOR_TEAM1);
1767         }
1768
1769         local entity ent;
1770         ent = find(world, classname, "target_assault_roundend");
1771         if(ent)
1772         {
1773                 if(ent.winning) // round end has been triggered by attacking team
1774                 {
1775                         bprint("ASSAULT: round completed...\n");
1776                         SetWinners(team, assault_attacker_team);
1777
1778                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1779
1780                         if(ent.cnt == 1 || cvar("g_campaign")) // this was the second round
1781                         {
1782                                 status = WINNING_YES;
1783                         }
1784                         else
1785                         {
1786                                 local entity oldself;
1787                                 oldself = self;
1788                                 self = ent;
1789                                 assault_new_round();
1790                                 self = oldself;
1791                         }
1792                 }
1793         }
1794
1795         return status;
1796 }
1797
1798 // LMS winning condition: game terminates if and only if there's at most one
1799 // one player who's living lives. Top two scores being equal cancels the time
1800 // limit.
1801 float WinningCondition_LMS()
1802 {
1803         entity head, head2;
1804         float have_player;
1805         float have_players;
1806         float l;
1807
1808         have_player = FALSE;
1809         have_players = FALSE;
1810         l = LMS_NewPlayerLives();
1811
1812         head = find(world, classname, "player");
1813         if(head)
1814                 have_player = TRUE;
1815         head2 = find(head, classname, "player");
1816         if(head2)
1817                 have_players = TRUE;
1818
1819         if(have_player)
1820         {
1821                 // we have at least one player
1822                 if(have_players)
1823                 {
1824                         // two or more active players - continue with the game
1825                 }
1826                 else
1827                 {
1828                         // exactly one player?
1829
1830                         ClearWinners();
1831                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1832
1833                         if(l)
1834                         {
1835                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1836                                 return WINNING_NO;
1837                         }
1838                         else
1839                         {
1840                                 // a winner!
1841                                 // and assign him his first place
1842                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1843                                 return WINNING_YES;
1844                         }
1845                 }
1846         }
1847         else
1848         {
1849                 // nobody is playing at all...
1850                 if(l)
1851                 {
1852                         // wait for players...
1853                 }
1854                 else
1855                 {
1856                         // SNAFU (maybe a draw game?)
1857                         ClearWinners();
1858                         dprint("No players, ending game.\n");
1859                         return WINNING_YES;
1860                 }
1861         }
1862
1863         // When we get here, we have at least two players who are actually LIVING,
1864         // now check if the top two players have equal score.
1865         WinningConditionHelper();
1866
1867         ClearWinners();
1868         if(WinningConditionHelper_winner)
1869                 WinningConditionHelper_winner.winning = TRUE;
1870         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1871                 return WINNING_NEVER;
1872
1873         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1874         return WINNING_NO;
1875 }
1876
1877 void ShuffleMaplist()
1878 {
1879         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1880 }
1881
1882 float leaderfrags;
1883 float WinningCondition_Scores(float limit, float leadlimit)
1884 {
1885         float limitreached;
1886
1887         // TODO make everything use THIS winning condition (except LMS)
1888         WinningConditionHelper();
1889
1890         if(teams_matter)
1891         {
1892                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1893                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1894                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1895                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1896         }
1897
1898         ClearWinners();
1899         if(WinningConditionHelper_winner)
1900                 WinningConditionHelper_winner.winning = 1;
1901         if(WinningConditionHelper_winnerteam >= 0)
1902                 SetWinners(team, WinningConditionHelper_winnerteam);
1903
1904         if(WinningConditionHelper_lowerisbetter)
1905         {
1906                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1907                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1908                 limit = -limit;
1909         }
1910
1911         if(WinningConditionHelper_zeroisworst)
1912                 leadlimit = 0; // not supported in this mode
1913
1914         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1915         // these modes always score in increments of 1, thus this makes sense
1916         {
1917                 if(leaderfrags != WinningConditionHelper_topscore)
1918                 {
1919                         leaderfrags = WinningConditionHelper_topscore;
1920
1921                         if (limit)
1922                         if (leaderfrags == limit - 1)
1923                                 Announce("1fragleft");
1924                         else if (leaderfrags == limit - 2)
1925                                 Announce("2fragsleft");
1926                         else if (leaderfrags == limit - 3)
1927                                 Announce("3fragsleft");
1928                 }
1929         }
1930
1931         limitreached = FALSE;
1932         if(limit)
1933                 if(WinningConditionHelper_topscore >= limit)
1934                         limitreached = TRUE;
1935         if(leadlimit)
1936         {
1937                 float leadlimitreached;
1938                 leadlimitreached = (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1939                 if(cvar("leadlimit_and_fraglimit"))
1940                         limitreached = (limitreached && leadlimitreached);
1941                 else
1942                         limitreached = (limitreached || leadlimitreached);
1943         }
1944
1945         return GetWinningCode(
1946                 WinningConditionHelper_topscore && limitreached,
1947                 WinningConditionHelper_equality
1948         );
1949 }
1950
1951 float WinningCondition_Race(float fraglimit)
1952 {
1953         float wc;
1954         entity p;
1955         float n, c;
1956
1957         n = 0;
1958         c = 0;
1959         FOR_EACH_PLAYER(p)
1960         {
1961                 ++n;
1962                 if(p.race_completed)
1963                         ++c;
1964         }
1965         if(n && (n == c))
1966                 return WINNING_YES;
1967         wc = WinningCondition_Scores(fraglimit, 0);
1968
1969         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1970         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1971         // do NOT support equality when the laps are all raced!
1972                 return WINNING_STARTSUDDENDEATHOVERTIME;
1973         else
1974                 return WINNING_NEVER;
1975         return wc;
1976 }
1977
1978 void ReadyRestart();
1979 float WinningCondition_QualifyingThenRace(float limit)
1980 {
1981         float wc;
1982         wc = WinningCondition_Scores(limit, 0);
1983
1984         // NEVER initiate overtime
1985         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1986         {
1987                 return WINNING_YES;
1988         }
1989
1990         return wc;
1991 }
1992
1993 float WinningCondition_RanOutOfSpawns()
1994 {
1995         entity head;
1996
1997         if(have_team_spawns <= 0)
1998                 return WINNING_NO;
1999
2000         if(!some_spawn_has_been_used)
2001                 return WINNING_NO;
2002
2003         team1_score = team2_score = team3_score = team4_score = 0;
2004
2005         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
2006         {
2007                 if(head.team == COLOR_TEAM1)
2008                         team1_score = 1;
2009                 else if(head.team == COLOR_TEAM2)
2010                         team2_score = 1;
2011                 else if(head.team == COLOR_TEAM3)
2012                         team3_score = 1;
2013                 else if(head.team == COLOR_TEAM4)
2014                         team4_score = 1;
2015         }
2016
2017         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
2018         {
2019                 if(head.team == COLOR_TEAM1)
2020                         team1_score = 1;
2021                 else if(head.team == COLOR_TEAM2)
2022                         team2_score = 1;
2023                 else if(head.team == COLOR_TEAM3)
2024                         team3_score = 1;
2025                 else if(head.team == COLOR_TEAM4)
2026                         team4_score = 1;
2027         }
2028
2029         ClearWinners();
2030         if(team1_score + team2_score + team3_score + team4_score == 0)
2031         {
2032                 checkrules_equality = TRUE;
2033                 return WINNING_YES;
2034         }
2035         else if(team1_score + team2_score + team3_score + team4_score == 1)
2036         {
2037                 float t, i;
2038                 if(team1_score) t = COLOR_TEAM1;
2039                 if(team2_score) t = COLOR_TEAM2;
2040                 if(team3_score) t = COLOR_TEAM3;
2041                 if(team4_score) t = COLOR_TEAM4;
2042                 CheckAllowedTeams(world);
2043                 for(i = 0; i < MAX_TEAMSCORE; ++i)
2044                 {
2045                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
2046                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
2047                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
2048                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
2049                 }
2050
2051                 AddWinners(team, t);
2052                 return WINNING_YES;
2053         }
2054         else
2055                 return WINNING_NO;
2056 }
2057
2058 /*
2059 ============
2060 CheckRules_World
2061
2062 Exit deathmatch games upon conditions
2063 ============
2064 */
2065 void CheckRules_World()
2066 {
2067         float timelimit;
2068         float fraglimit;
2069         float leadlimit;
2070
2071         VoteThink();
2072         MapVote_Think();
2073
2074         SetDefaultAlpha();
2075
2076         /*
2077         MapVote_Think should now do that part
2078         if (intermission_running)
2079                 if (time >= intermission_exittime + 60)
2080                 {
2081                         if(!DoNextMapOverride())
2082                                 GotoNextMap();
2083                         return;
2084                 }
2085         */
2086
2087         if (gameover)   // someone else quit the game already
2088         {
2089                 if(player_count == 0) // Nobody there? Then let's go to the next map
2090                         MapVote_Start();
2091                         // this will actually check the player count in the next frame
2092                         // again, but this shouldn't hurt
2093                 return;
2094         }
2095
2096         timelimit = cvar("timelimit") * 60;
2097         fraglimit = cvar("fraglimit");
2098         leadlimit = cvar("leadlimit");
2099
2100         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
2101         {
2102                 if(timelimit > 0)
2103                         timelimit = 0; // timelimit is not made for warmup
2104                 if(fraglimit > 0)
2105                         fraglimit = 0; // no fraglimit for now
2106                 leadlimit = 0; // no leadlimit for now
2107         }
2108
2109         if(g_onslaught)
2110                 timelimit = 0; // ONS has its own overtime rule
2111
2112         if(timelimit > 0)
2113         {
2114                 timelimit += game_starttime;
2115         }
2116         else if (timelimit < 0)
2117         {
2118                 // endmatch
2119                 NextLevel();
2120                 return;
2121         }
2122
2123         float wantovertime;
2124         wantovertime = 0;
2125
2126         if(checkrules_suddendeathend)
2127         {
2128                 if(!checkrules_suddendeathwarning)
2129                 {
2130                         checkrules_suddendeathwarning = TRUE;
2131                         if(g_race && !g_race_qualifying)
2132                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
2133                         else
2134                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
2135                 }
2136         }
2137         else
2138         {
2139                 if (timelimit && time >= timelimit)
2140                 {
2141                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
2142                         {
2143                                 float totalplayers;
2144                                 float playerswithlaps;
2145                                 float readyplayers;
2146                                 entity head;
2147                                 totalplayers = playerswithlaps = readyplayers = 0;
2148                                 FOR_EACH_PLAYER(head)
2149                                 {
2150                                         ++totalplayers;
2151                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
2152                                                 ++playerswithlaps;
2153                                         if(head.ready)
2154                                                 ++readyplayers;
2155                                 }
2156
2157                                 // at least 2 of the players have completed a lap: start the RACE
2158                                 // otherwise, the players should end the qualifying on their own
2159                                 if(readyplayers || playerswithlaps >= 2)
2160                                 {
2161                                         checkrules_suddendeathend = 0;
2162                                         ReadyRestart(); // go to race
2163                                         return;
2164                                 }
2165                                 else
2166                                         wantovertime |= InitiateSuddenDeath();
2167                         }
2168                         else
2169                                 wantovertime |= InitiateSuddenDeath();
2170                 }
2171         }
2172
2173         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2174         {
2175                 NextLevel();
2176                 return;
2177         }
2178
2179         float checkrules_status;
2180         checkrules_status = WinningCondition_RanOutOfSpawns();
2181         if(checkrules_status == WINNING_YES)
2182         {
2183                 bprint("Hey! Someone ran out of spawns!\n");
2184         }
2185         else if(g_race && !g_race_qualifying && timelimit >= 0)
2186         {
2187                 checkrules_status = WinningCondition_Race(fraglimit);
2188                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2189         }
2190         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2191         {
2192                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2193                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2194         }
2195         else if(g_assault)
2196         {
2197                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2198         }
2199         else if(g_lms)
2200         {
2201                 checkrules_status = WinningCondition_LMS();
2202         }
2203         else if (g_onslaught)
2204         {
2205                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2206         }
2207         else
2208         {
2209                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2210                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2211         }
2212
2213         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2214         {
2215                 checkrules_status = WINNING_NEVER;
2216                 checkrules_overtimesadded = -1;
2217                 wantovertime |= InitiateSuddenDeath();
2218         }
2219
2220         if(checkrules_status == WINNING_NEVER)
2221                 // equality cases! Nobody wins if the overtime ends in a draw.
2222                 ClearWinners();
2223
2224         if(wantovertime)
2225         {
2226                 if(checkrules_status == WINNING_NEVER)
2227                         InitiateOvertime();
2228                 else
2229                         checkrules_status = WINNING_YES;
2230         }
2231
2232         if(checkrules_suddendeathend)
2233                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2234                         checkrules_status = WINNING_YES;
2235
2236         if(checkrules_status == WINNING_YES)
2237         {
2238                 //print("WINNING\n");
2239                 NextLevel();
2240         }
2241 };
2242
2243 float mapvote_nextthink;
2244 float mapvote_initialized;
2245 float mapvote_keeptwotime;
2246 float mapvote_timeout;
2247 string mapvote_message;
2248 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2249 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2250 float mapvote_screenshot_dirs_count;
2251
2252 float mapvote_count;
2253 float mapvote_count_real;
2254 string mapvote_maps[MAPVOTE_COUNT];
2255 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2256 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2257 float mapvote_maps_suggested[MAPVOTE_COUNT];
2258 string mapvote_suggestions[MAPVOTE_COUNT];
2259 float mapvote_suggestion_ptr;
2260 float mapvote_maxlen;
2261 float mapvote_voters;
2262 float mapvote_votes[MAPVOTE_COUNT];
2263 float mapvote_run;
2264 float mapvote_detail;
2265 float mapvote_abstain;
2266 .float mapvote;
2267
2268 void MapVote_ClearAllVotes()
2269 {
2270         FOR_EACH_CLIENT(other)
2271                 other.mapvote = 0;
2272 }
2273
2274 string MapVote_Suggest(string m)
2275 {
2276         float i;
2277         if(m == "")
2278                 return "That's not how to use this command.";
2279         if(!cvar("g_maplist_votable_suggestions"))
2280                 return "Suggestions are not accepted on this server.";
2281         if(mapvote_initialized)
2282                 return "Can't suggest - voting is already in progress!";
2283         m = MapInfo_FixName(m);
2284         if(!m)
2285                 return "The map you suggested is not available on this server.";
2286         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2287                 if(Map_IsRecent(m))
2288                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2289
2290         if(!MapInfo_CheckMap(m))
2291                 return "The map you suggested does not support the current game mode.";
2292         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2293                 if(mapvote_suggestions[i] == m)
2294                         return "This map was already suggested.";
2295         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2296         {
2297                 i = floor(random() * mapvote_suggestion_ptr);
2298         }
2299         else
2300         {
2301                 i = mapvote_suggestion_ptr;
2302                 mapvote_suggestion_ptr += 1;
2303         }
2304         if(mapvote_suggestions[i] != "")
2305                 strunzone(mapvote_suggestions[i]);
2306         mapvote_suggestions[i] = strzone(m);
2307         if(cvar("sv_eventlog"))
2308                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2309         return strcat("Suggestion of ", m, " accepted.");
2310 }
2311
2312 void MapVote_AddVotable(string nextMap, float isSuggestion)
2313 {
2314         float j, i, o;
2315         string pakfile, mapfile;
2316
2317         if(nextMap == "")
2318                 return;
2319         for(j = 0; j < mapvote_count; ++j)
2320                 if(mapvote_maps[j] == nextMap)
2321                         return;
2322         if(strlen(nextMap) > mapvote_maxlen)
2323                 mapvote_maxlen = strlen(nextMap);
2324         mapvote_maps[mapvote_count] = strzone(nextMap);
2325         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2326
2327         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2328         {
2329                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2330                 pakfile = whichpack(strcat(mapfile, ".tga"));
2331                 if(pakfile == "")
2332                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2333                 if(pakfile == "")
2334                         pakfile = whichpack(strcat(mapfile, ".png"));
2335                 if(pakfile != "")
2336                         break;
2337         }
2338         if(i >= mapvote_screenshot_dirs_count)
2339                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2340         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2341                 pakfile = substring(pakfile, o, -1);
2342
2343         mapvote_maps_screenshot_dir[mapvote_count] = i;
2344         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2345
2346         mapvote_count += 1;
2347 }
2348
2349 void MapVote_Spawn();
2350 void MapVote_Init()
2351 {
2352         float i;
2353         float nmax, smax;
2354
2355         MapVote_ClearAllVotes();
2356
2357         mapvote_count = 0;
2358         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2359         mapvote_abstain = cvar("g_maplist_votable_abstain");
2360
2361         if(mapvote_abstain)
2362                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2363         else
2364                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2365         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2366
2367         // we need this for AddVotable, as that cycles through the screenshot dirs
2368         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2369         if(mapvote_screenshot_dirs_count == 0)
2370                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2371         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2372         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2373                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2374
2375         if(mapvote_suggestion_ptr)
2376                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2377                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2378
2379         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2380                 MapVote_AddVotable(GetNextMap(), FALSE);
2381
2382         if(mapvote_count == 0)
2383         {
2384                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2385                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2386                 if(cvar("g_maplist_shuffle"))
2387                         ShuffleMaplist();
2388                 localcmd("\nmenu_cmd sync\n");
2389                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2390                         MapVote_AddVotable(GetNextMap(), FALSE);
2391         }
2392
2393         mapvote_count_real = mapvote_count;
2394         if(mapvote_abstain)
2395                 MapVote_AddVotable("don't care", 0);
2396
2397         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2398
2399         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2400         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2401         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2402                 mapvote_keeptwotime = 0;
2403         mapvote_message = "Choose a map and press its key!";
2404
2405         MapVote_Spawn();
2406 }
2407
2408 void MapVote_SendPicture(float id)
2409 {
2410         msg_entity = self;
2411         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2412         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2413         WriteByte(MSG_ONE, id);
2414         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2415 }
2416
2417 float GameCommand_MapVote(string cmd)
2418 {
2419         if(!intermission_running)
2420                 return FALSE;
2421
2422         if(cmd == "mv_getpic")
2423         {
2424                 MapVote_SendPicture(stof(argv(1)));
2425                 return TRUE;
2426         }
2427
2428         return FALSE;
2429 }
2430
2431 float MapVote_GetMapMask()
2432 {
2433         float mask, i, power;
2434         mask = 0;
2435         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2436                 if(mapvote_maps[i] != "")
2437                         mask |= power;
2438         return mask;
2439 }
2440
2441 entity mapvote_ent;
2442 float MapVote_SendEntity(entity to, float sf)
2443 {
2444         float i;
2445
2446         if(sf & 1)
2447                 sf &~= 2; // if we send 1, we don't need to also send 2
2448
2449         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2450         WriteByte(MSG_ENTITY, sf);
2451
2452         if(sf & 1)
2453         {
2454                 // flag 1 == initialization
2455                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2456                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2457                 WriteString(MSG_ENTITY, "");
2458                 WriteByte(MSG_ENTITY, mapvote_count);
2459                 WriteByte(MSG_ENTITY, mapvote_abstain);
2460                 WriteByte(MSG_ENTITY, mapvote_detail);
2461                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2462                 if(mapvote_count <= 8)
2463                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2464                 else
2465                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2466                 for(i = 0; i < mapvote_count; ++i)
2467                         if(mapvote_maps[i] != "")
2468                         {
2469                                 if(mapvote_abstain && i == mapvote_count - 1)
2470                                 {
2471                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2472                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2473                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2474                                 }
2475                                 else
2476                                 {
2477                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2478                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2479                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2480                                 }
2481                         }
2482         }
2483
2484         if(sf & 2)
2485         {
2486                 // flag 2 == update of mask
2487                 if(mapvote_count <= 8)
2488                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2489                 else
2490                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2491         }
2492
2493         if(sf & 4)
2494         {
2495                 if(mapvote_detail)
2496                         for(i = 0; i < mapvote_count; ++i)
2497                                 if(mapvote_maps[i] != "")
2498                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2499
2500                 WriteByte(MSG_ENTITY, to.mapvote);
2501         }
2502
2503         return TRUE;
2504 }
2505
2506 void MapVote_Spawn()
2507 {
2508         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2509 }
2510
2511 void MapVote_TouchMask()
2512 {
2513         mapvote_ent.SendFlags |= 2;
2514 }
2515
2516 void MapVote_TouchVotes(entity voter)
2517 {
2518         mapvote_ent.SendFlags |= 4;
2519 }
2520
2521 float MapVote_Finished(float mappos)
2522 {
2523         string result;
2524         float i;
2525         float didntvote;
2526
2527         if(cvar("sv_eventlog"))
2528         {
2529                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2530                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2531                 didntvote = mapvote_voters;
2532                 for(i = 0; i < mapvote_count; ++i)
2533                         if(mapvote_maps[i] != "")
2534                         {
2535                                 didntvote -= mapvote_votes[i];
2536                                 if(i != mappos)
2537                                 {
2538                                         result = strcat(result, ":", mapvote_maps[i]);
2539                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2540                                 }
2541                         }
2542                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2543
2544                 GameLogEcho(result);
2545                 if(mapvote_maps_suggested[mappos])
2546                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2547         }
2548
2549         FOR_EACH_REALCLIENT(other)
2550                 FixClientCvars(other);
2551
2552         Map_Goto_SetStr(mapvote_maps[mappos]);
2553         Map_Goto();
2554         alreadychangedlevel = TRUE;
2555         return TRUE;
2556 }
2557 void MapVote_CheckRules_1()
2558 {
2559         float i;
2560
2561         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2562         {
2563                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2564                 mapvote_votes[i] = 0;
2565         }
2566
2567         mapvote_voters = 0;
2568         FOR_EACH_REALCLIENT(other)
2569         {
2570                 ++mapvote_voters;
2571                 if(other.mapvote)
2572                 {
2573                         i = other.mapvote - 1;
2574                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2575                         mapvote_votes[i] = mapvote_votes[i] + 1;
2576                 }
2577         }
2578 }
2579
2580 float MapVote_CheckRules_2()
2581 {
2582         float i;
2583         float firstPlace, secondPlace;
2584         float firstPlaceVotes, secondPlaceVotes;
2585         float mapvote_voters_real;
2586         string result;
2587
2588         if(mapvote_count_real == 1)
2589                 return MapVote_Finished(0);
2590
2591         mapvote_voters_real = mapvote_voters;
2592         if(mapvote_abstain)
2593                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2594
2595         RandomSelection_Init();
2596         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2597                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2598         firstPlace = RandomSelection_chosen_float;
2599         firstPlaceVotes = RandomSelection_best_priority;
2600         //dprint("First place: ", ftos(firstPlace), "\n");
2601         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2602
2603         RandomSelection_Init();
2604         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2605                 if(i != firstPlace)
2606                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2607         secondPlace = RandomSelection_chosen_float;
2608         secondPlaceVotes = RandomSelection_best_priority;
2609         //dprint("Second place: ", ftos(secondPlace), "\n");
2610         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2611
2612         if(firstPlace == -1)
2613                 error("No first place in map vote... WTF?");
2614
2615         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2616                 return MapVote_Finished(firstPlace);
2617
2618         if(mapvote_keeptwotime)
2619                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2620                 {
2621                         float didntvote;
2622                         MapVote_TouchMask();
2623                         mapvote_message = "Now decide between the TOP TWO!";
2624                         mapvote_keeptwotime = 0;
2625                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2626                         result = strcat(result, ":", ftos(firstPlaceVotes));
2627                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2628                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2629                         didntvote = mapvote_voters;
2630                         for(i = 0; i < mapvote_count; ++i)
2631                                 if(mapvote_maps[i] != "")
2632                                 {
2633                                         didntvote -= mapvote_votes[i];
2634                                         if(i != firstPlace)
2635                                                 if(i != secondPlace)
2636                                                 {
2637                                                         result = strcat(result, ":", mapvote_maps[i]);
2638                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2639                                                         if(i < mapvote_count_real)
2640                                                         {
2641                                                                 strunzone(mapvote_maps[i]);
2642                                                                 mapvote_maps[i] = "";
2643                                                                 strunzone(mapvote_maps_pakfile[i]);
2644                                                                 mapvote_maps_pakfile[i] = "";
2645                                                         }
2646                                                 }
2647                                 }
2648                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2649                         if(cvar("sv_eventlog"))
2650                                 GameLogEcho(result);
2651                 }
2652
2653         return FALSE;
2654 }
2655 void MapVote_Tick()
2656 {
2657         float keeptwo;
2658         float totalvotes;
2659
2660         keeptwo = mapvote_keeptwotime;
2661         MapVote_CheckRules_1(); // count
2662         if(MapVote_CheckRules_2()) // decide
2663                 return;
2664
2665         totalvotes = 0;
2666         FOR_EACH_REALCLIENT(other)
2667         {
2668                 // hide scoreboard again
2669                 if(other.health != 2342)
2670                 {
2671                         other.health = 2342;
2672                         other.impulse = 0;
2673                         if(clienttype(other) == CLIENTTYPE_REAL)
2674                         {
2675                                 msg_entity = other;
2676                                 WriteByte(MSG_ONE, SVC_FINALE);
2677                                 WriteString(MSG_ONE, "");
2678                         }
2679                 }
2680
2681                 // clear possibly invalid votes
2682                 if(mapvote_maps[other.mapvote - 1] == "")
2683                         other.mapvote = 0;
2684                 // use impulses as new vote
2685                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2686                         if(mapvote_maps[other.impulse - 1] != "")
2687                         {
2688                                 other.mapvote = other.impulse;
2689                                 MapVote_TouchVotes(other);
2690                         }
2691                 other.impulse = 0;
2692
2693                 if(other.mapvote)
2694                         ++totalvotes;
2695         }
2696
2697         MapVote_CheckRules_1(); // just count
2698 }
2699 void MapVote_Start()
2700 {
2701         if(mapvote_run)
2702                 return;
2703
2704         MapInfo_Enumerate();
2705         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2706                 mapvote_run = TRUE;
2707 }
2708 void MapVote_Think()
2709 {
2710         if(!mapvote_run)
2711                 return;
2712
2713         if(alreadychangedlevel)
2714                 return;
2715
2716         if(time < mapvote_nextthink)
2717                 return;
2718         //dprint("tick\n");
2719
2720         mapvote_nextthink = time + 0.5;
2721
2722         if(!mapvote_initialized)
2723         {
2724                 if(cvar("rescan_pending") == 1)
2725                 {
2726                         cvar_set("rescan_pending", "2");
2727                         localcmd("fs_rescan\nrescan_pending 3\n");
2728                         return;
2729                 }
2730                 else if(cvar("rescan_pending") == 2)
2731                 {
2732                         return;
2733                 }
2734                 else if(cvar("rescan_pending") == 3)
2735                 {
2736                         // now build missing mapinfo files
2737                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2738                                 return;
2739
2740                         // we're done, start the timer
2741                         cvar_set("rescan_pending", "0");
2742                 }
2743
2744                 mapvote_initialized = TRUE;
2745                 if(DoNextMapOverride())
2746                         return;
2747                 if(!cvar("g_maplist_votable") || player_count <= 0)
2748                 {
2749                         GotoNextMap();
2750                         return;
2751                 }
2752                 MapVote_Init();
2753         }
2754
2755         MapVote_Tick();
2756 };
2757
2758 string GotoMap(string m)
2759 {
2760         if(!MapInfo_CheckMap(m))
2761                 return "The map you chose is not available on this server.";
2762         cvar_set("nextmap", m);
2763         cvar_set("timelimit", "-1");
2764         if(mapvote_initialized || alreadychangedlevel)
2765         {
2766                 if(DoNextMapOverride())
2767                         return "Map switch initiated.";
2768                 else
2769                         return "Hm... no. For some reason I like THIS map more.";
2770         }
2771         else
2772                 return "Map switch will happen after scoreboard.";
2773 }
2774
2775
2776 void EndFrame()
2777 {
2778         float altime;
2779         FOR_EACH_REALCLIENT(self)
2780         {
2781                 if(self.classname == "spectator")
2782                 {
2783                         if(self.enemy.typehitsound)
2784                                 play2(self, "misc/typehit.wav");
2785                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2786                                 play2(self, "misc/hit.wav");
2787                 }
2788                 else
2789                 {
2790                         if(self.typehitsound)
2791                                 play2(self, "misc/typehit.wav");
2792                         else if(self.hitsound && self.cvar_cl_hitsound)
2793                                 play2(self, "misc/hit.wav");
2794                 }
2795         }
2796         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2797         // add 1 frametime because after this, engine SV_Physics
2798         // increases time by a frametime and then networks the frame
2799         // add another frametime because client shows everything with
2800         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2801         // needed!
2802         FOR_EACH_CLIENT(self)
2803         {
2804                 self.hitsound = FALSE;
2805                 self.typehitsound = FALSE;
2806                 antilag_record(self, altime);
2807         }
2808 }
2809
2810
2811 /*
2812  * RedirectionThink:
2813  * returns TRUE if redirecting
2814  */
2815 float redirection_timeout;
2816 float redirection_nextthink;
2817 float RedirectionThink()
2818 {
2819         float clients_found;
2820
2821         if(redirection_target == "")
2822                 return FALSE;
2823
2824         if(!redirection_timeout)
2825         {
2826                 cvar_set("sv_public", "-2");
2827                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2828                 if(redirection_target == "self")
2829                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2830                 else
2831                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2832         }
2833
2834         if(time < redirection_nextthink)
2835                 return TRUE;
2836
2837         redirection_nextthink = time + 1;
2838
2839         clients_found = 0;
2840         FOR_EACH_REALCLIENT(self)
2841         {
2842                 print("Redirecting: sending connect command to ", self.netname, "\n");
2843                 if(redirection_target == "self")
2844                         stuffcmd(self, "\ndisconnect; reconnect\n");
2845                 else
2846                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2847                 ++clients_found;
2848         }
2849
2850         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2851
2852         if(time > redirection_timeout || clients_found == 0)
2853                 localcmd("\nwait; wait; wait; quit\n");
2854
2855         return TRUE;
2856 }
2857
2858 void TargetMusic_RestoreGame();
2859 void RestoreGame()
2860 {
2861         // Loaded from a save game
2862         // some things then break, so let's work around them...
2863
2864         // Progs DB (capture records)
2865         ServerProgsDB = db_load("server.db");
2866
2867         // Mapinfo
2868         MapInfo_Shutdown();
2869         MapInfo_Enumerate();
2870         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2871         WeaponStats_Init();
2872
2873         TargetMusic_RestoreGame();
2874 }
2875
2876 void SV_Shutdown()
2877 {
2878         if(gameover > 1) // shutting down already?
2879                 return;
2880
2881         gameover = 2; // 2 = server shutting down
2882
2883         if(world_initialized > 0)
2884         {
2885                 world_initialized = 0;
2886                 print("Saving persistent data...\n");
2887                 Ban_SaveBans();
2888                 if(!cheatcount_total)
2889                 {
2890                         if(cvar("sv_db_saveasdump"))
2891                                 db_dump(ServerProgsDB, "server.db");
2892                         else
2893                                 db_save(ServerProgsDB, "server.db");
2894                 }
2895                 if(cvar("developer"))
2896                 {
2897                         if(cvar("sv_db_saveasdump"))
2898                                 db_dump(TemporaryDB, "server-temp.db");
2899                         else
2900                                 db_save(TemporaryDB, "server-temp.db");
2901                 }
2902                 CheatShutdown(); // must be after cheatcount check
2903                 db_close(ServerProgsDB);
2904                 db_close(TemporaryDB);
2905                 print("done!\n");
2906                 // tell the bot system the game is ending now
2907                 bot_endgame();
2908
2909                 WeaponStats_Shutdown();
2910                 MapInfo_Shutdown();
2911         }
2912         else if(world_initialized == 0)
2913         {
2914                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2915         }
2916 }